source: trunk/source/tools/asdf.lisp @ 14687

Last change on this file since 14687 was 14687, checked in by rme, 9 years ago

ASDF 2.013 from upstream.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 157.1 KB
Line 
1;;; -*- mode: common-lisp; Base: 10 ; Syntax: ANSI-Common-Lisp -*-
2;;; This is ASDF 2.013: Another System Definition Facility.
3;;;
4;;; Feedback, bug reports, and patches are all welcome:
5;;; please mail to <asdf-devel@common-lisp.net>.
6;;; Note first that the canonical source for ASDF is presently
7;;; <URL:http://common-lisp.net/project/asdf/>.
8;;;
9;;; If you obtained this copy from anywhere else, and you experience
10;;; trouble using it, or find bugs, you may want to check at the
11;;; location above for a more recent version (and for documentation
12;;; and test files, if your copy came without them) before reporting
13;;; bugs.  There are usually two "supported" revisions - the git master
14;;; branch is the latest development version, whereas the git release
15;;; branch may be slightly older but is considered `stable'
16
17;;; -- LICENSE START
18;;; (This is the MIT / X Consortium license as taken from
19;;;  http://www.opensource.org/licenses/mit-license.html on or about
20;;;  Monday; July 13, 2009)
21;;;
22;;; Copyright (c) 2001-2010 Daniel Barlow and contributors
23;;;
24;;; Permission is hereby granted, free of charge, to any person obtaining
25;;; a copy of this software and associated documentation files (the
26;;; "Software"), to deal in the Software without restriction, including
27;;; without limitation the rights to use, copy, modify, merge, publish,
28;;; distribute, sublicense, and/or sell copies of the Software, and to
29;;; permit persons to whom the Software is furnished to do so, subject to
30;;; the following conditions:
31;;;
32;;; The above copyright notice and this permission notice shall be
33;;; included in all copies or substantial portions of the Software.
34;;;
35;;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
36;;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
37;;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
38;;; NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
39;;; LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
40;;; OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
41;;; WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
42;;;
43;;; -- LICENSE END
44
45;;; The problem with writing a defsystem replacement is bootstrapping:
46;;; we can't use defsystem to compile it.  Hence, all in one file.
47
48#+xcvb (module ())
49
50(cl:in-package #-genera :common-lisp-user #+genera :future-common-lisp-user)
51
52#+gcl (defpackage :asdf (:use :cl)) ;; GCL treats defpackage magically and needs this
53
54(eval-when (:compile-toplevel :load-toplevel :execute)
55  ;;; make package if it doesn't exist yet.
56  ;;; DEFPACKAGE may cause errors on discrepancies, so we avoid it.
57  (unless (find-package :asdf)
58    (make-package :asdf :use '(:common-lisp)))
59  ;;; Implementation-dependent tweaks
60  ;; (declaim (optimize (speed 2) (debug 2) (safety 3))) ; NO: rely on the implementation defaults.
61  #+allegro
62  (setf excl::*autoload-package-name-alist*
63        (remove "asdf" excl::*autoload-package-name-alist*
64                :test 'equalp :key 'car))
65  #+(and ecl (not ecl-bytecmp)) (require :cmp)
66  #+(and (or win32 windows mswindows mingw32) (not cygwin)) (pushnew :asdf-windows *features*)
67  #+(or unix cygwin) (pushnew :asdf-unix *features*))
68
69(in-package :asdf)
70
71;;;; Create packages in a way that is compatible with hot-upgrade.
72;;;; See https://bugs.launchpad.net/asdf/+bug/485687
73;;;; See more near the end of the file.
74
75(eval-when (:load-toplevel :compile-toplevel :execute)
76  (defvar *asdf-version* nil)
77  (defvar *upgraded-p* nil)
78  (let* (;; For bug reporting sanity, please always bump this version when you modify this file.
79         ;; Please also modify asdf.asd to reflect this change. The script bin/bump-version
80         ;; can help you do these changes in synch (look at the source for documentation).
81         ;; Relying on its automation, the version is now redundantly present on top of this file.
82         ;; "2.345" would be an official release
83         ;; "2.345.6" would be a development version in the official upstream
84         ;; "2.345.0.7" would be your seventh local modification of official release 2.345
85         ;; "2.345.6.7" would be your seventh local modification of development version 2.345.6
86         (asdf-version "2.013")
87         (existing-asdf (fboundp 'find-system))
88         (existing-version *asdf-version*)
89         (already-there (equal asdf-version existing-version)))
90    (unless (and existing-asdf already-there)
91      (when existing-asdf
92        (format *trace-output*
93         "~&; Upgrading ASDF package ~@[from version ~A ~]to version ~A~%"
94         existing-version asdf-version))
95      (labels
96          ((present-symbol-p (symbol package)
97             (member (nth-value 1 (find-symbol symbol package)) '(:internal :external)))
98           (present-symbols (package)
99             ;; #-genera (loop :for s :being :the :present-symbols :in package :collect s) #+genera
100             (let (l)
101               (do-symbols (s package)
102                 (when (present-symbol-p s package) (push s l)))
103               (reverse l)))
104           (unlink-package (package)
105             (let ((u (find-package package)))
106               (when u
107                 (ensure-unintern u (present-symbols u))
108                 (loop :for p :in (package-used-by-list u) :do
109                   (unuse-package u p))
110                 (delete-package u))))
111           (ensure-exists (name nicknames use)
112             (let ((previous
113                    (remove-duplicates
114                     (mapcar #'find-package (cons name nicknames))
115                     :from-end t)))
116               ;; do away with packages with conflicting (nick)names
117               (map () #'unlink-package (cdr previous))
118               ;; reuse previous package with same name
119               (let ((p (car previous)))
120                 (cond
121                   (p
122                    (rename-package p name nicknames)
123                    (ensure-use p use)
124                    p)
125                   (t
126                    (make-package name :nicknames nicknames :use use))))))
127           (find-sym (symbol package)
128             (find-symbol (string symbol) package))
129           (intern* (symbol package)
130             (intern (string symbol) package))
131           (remove-symbol (symbol package)
132             (let ((sym (find-sym symbol package)))
133               (when sym
134                 (unexport sym package)
135                 (unintern sym package)
136                 sym)))
137           (ensure-unintern (package symbols)
138             (loop :with packages = (list-all-packages)
139               :for sym :in symbols
140               :for removed = (remove-symbol sym package)
141               :when removed :do
142               (loop :for p :in packages :do
143                 (when (eq removed (find-sym sym p))
144                   (unintern removed p)))))
145           (ensure-shadow (package symbols)
146             (shadow symbols package))
147           (ensure-use (package use)
148             (dolist (used (reverse use))
149               (do-external-symbols (sym used)
150                 (unless (eq sym (find-sym sym package))
151                   (remove-symbol sym package)))
152               (use-package used package)))
153           (ensure-fmakunbound (package symbols)
154             (loop :for name :in symbols
155               :for sym = (find-sym name package)
156               :when sym :do (fmakunbound sym)))
157           (ensure-export (package export)
158             (let ((formerly-exported-symbols nil)
159                   (bothly-exported-symbols nil)
160                   (newly-exported-symbols nil))
161               (do-external-symbols (sym package)
162                 (if (member sym export :test 'string-equal)
163                     (push sym bothly-exported-symbols)
164                     (push sym formerly-exported-symbols)))
165               (loop :for sym :in export :do
166                 (unless (member sym bothly-exported-symbols :test 'string-equal)
167                   (push sym newly-exported-symbols)))
168               (loop :for user :in (package-used-by-list package)
169                 :for shadowing = (package-shadowing-symbols user) :do
170                 (loop :for new :in newly-exported-symbols
171                   :for old = (find-sym new user)
172                   :when (and old (not (member old shadowing)))
173                   :do (unintern old user)))
174               (loop :for x :in newly-exported-symbols :do
175                 (export (intern* x package)))))
176           (ensure-package (name &key nicknames use unintern fmakunbound shadow export)
177             (let* ((p (ensure-exists name nicknames use)))
178               (ensure-unintern p unintern)
179               (ensure-shadow p shadow)
180               (ensure-export p export)
181               (ensure-fmakunbound p fmakunbound)
182               p)))
183        (macrolet
184            ((pkgdcl (name &key nicknames use export
185                           redefined-functions unintern fmakunbound shadow)
186                 `(ensure-package
187                   ',name :nicknames ',nicknames :use ',use :export ',export
188                   :shadow ',shadow
189                   :unintern ',(append #-(or gcl ecl) redefined-functions unintern)
190                   :fmakunbound ',(append fmakunbound))))
191          (pkgdcl
192           :asdf
193           :nicknames (:asdf-utilities) ;; DEPRECATED! Do not use, for backward compatibility only.
194           :use (:common-lisp)
195           :redefined-functions
196           (#:perform #:explain #:output-files #:operation-done-p
197            #:perform-with-restarts #:component-relative-pathname
198            #:system-source-file #:operate #:find-component #:find-system
199            #:apply-output-translations #:translate-pathname* #:resolve-location
200            #:compile-file*)
201           :unintern
202           (#:*asdf-revision* #:around #:asdf-method-combination
203            #:split #:make-collector
204            #:output-files-for-system-and-operation) ; obsolete ASDF-BINARY-LOCATION function
205           :fmakunbound
206           (#:system-source-file
207            #:component-relative-pathname #:system-relative-pathname
208            #:process-source-registry
209            #:inherit-source-registry #:process-source-registry-directive)
210           :export
211           (#:defsystem #:oos #:operate #:find-system #:run-shell-command
212            #:system-definition-pathname #:find-component ; miscellaneous
213            #:compile-system #:load-system #:test-system #:clear-system
214            #:compile-op #:load-op #:load-source-op
215            #:test-op
216            #:operation               ; operations
217            #:feature                 ; sort-of operation
218            #:version                 ; metaphorically sort-of an operation
219            #:version-satisfies
220
221            #:input-files #:output-files #:output-file #:perform ; operation methods
222            #:operation-done-p #:explain
223
224            #:component #:source-file
225            #:c-source-file #:cl-source-file #:java-source-file
226            #:static-file
227            #:doc-file
228            #:html-file
229            #:text-file
230            #:source-file-type
231            #:module                     ; components
232            #:system
233            #:unix-dso
234
235            #:module-components          ; component accessors
236            #:module-components-by-name  ; component accessors
237            #:component-pathname
238            #:component-relative-pathname
239            #:component-name
240            #:component-version
241            #:component-parent
242            #:component-property
243            #:component-system
244
245            #:component-depends-on
246
247            #:system-description
248            #:system-long-description
249            #:system-author
250            #:system-maintainer
251            #:system-license
252            #:system-licence
253            #:system-source-file
254            #:system-source-directory
255            #:system-relative-pathname
256            #:map-systems
257
258            #:operation-description
259            #:operation-on-warnings
260            #:operation-on-failure
261            #:component-visited-p
262            ;;#:*component-parent-pathname*
263            #:*system-definition-search-functions*
264            #:*central-registry*         ; variables
265            #:*compile-file-warnings-behaviour*
266            #:*compile-file-failure-behaviour*
267            #:*resolve-symlinks*
268            #:*asdf-verbose*
269
270            #:asdf-version
271
272            #:operation-error #:compile-failed #:compile-warned #:compile-error
273            #:error-name
274            #:error-pathname
275            #:load-system-definition-error
276            #:error-component #:error-operation
277            #:system-definition-error
278            #:missing-component
279            #:missing-component-of-version
280            #:missing-dependency
281            #:missing-dependency-of-version
282            #:circular-dependency        ; errors
283            #:duplicate-names
284
285            #:try-recompiling
286            #:retry
287            #:accept                     ; restarts
288            #:coerce-entry-to-directory
289            #:remove-entry-from-registry
290
291            #:clear-configuration
292            #:*output-translations-parameter*
293            #:initialize-output-translations
294            #:disable-output-translations
295            #:clear-output-translations
296            #:ensure-output-translations
297            #:apply-output-translations
298            #:compile-file*
299            #:compile-file-pathname*
300            #:enable-asdf-binary-locations-compatibility
301            #:*default-source-registries*
302            #:*source-registry-parameter*
303            #:initialize-source-registry
304            #:compute-source-registry
305            #:clear-source-registry
306            #:ensure-source-registry
307            #:process-source-registry
308            #:system-registered-p
309            #:asdf-message
310
311            ;; Utilities
312            #:absolute-pathname-p
313            ;; #:aif #:it
314            ;; #:appendf
315            #:coerce-name
316            #:directory-pathname-p
317            ;; #:ends-with
318            #:ensure-directory-pathname
319            #:getenv
320            ;; #:get-uid
321            ;; #:length=n-p
322            ;; #:find-symbol*
323            #:merge-pathnames*
324            #:coerce-pathname
325            #:pathname-directory-pathname
326            #:read-file-forms
327            ;; #:remove-keys
328            ;; #:remove-keyword
329            #:resolve-symlinks
330            #:split-string
331            #:component-name-to-pathname-components
332            #:split-name-type
333            #:subdirectories
334            #:truenamize
335            #:while-collecting)))
336        #+genera (import 'scl:boolean :asdf)
337        (setf *asdf-version* asdf-version
338              *upgraded-p* (if existing-version
339                               (cons existing-version *upgraded-p*)
340                               *upgraded-p*))))))
341
342;;;; -------------------------------------------------------------------------
343;;;; User-visible parameters
344;;;;
345(defun asdf-version ()
346  "Exported interface to the version of ASDF currently installed. A string.
347You can compare this string with e.g.:
348(ASDF:VERSION-SATISFIES (ASDF:ASDF-VERSION) \"2.013\")."
349  *asdf-version*)
350
351(defvar *resolve-symlinks* t
352  "Determine whether or not ASDF resolves symlinks when defining systems.
353
354Defaults to T.")
355
356(defvar *compile-file-warnings-behaviour*
357  (or #+clisp :ignore :warn)
358  "How should ASDF react if it encounters a warning when compiling a file?
359Valid values are :error, :warn, and :ignore.")
360
361(defvar *compile-file-failure-behaviour*
362  (or #+sbcl :error #+clisp :ignore :warn)
363  "How should ASDF react if it encounters a failure (per the ANSI spec of COMPILE-FILE)
364when compiling a file?  Valid values are :error, :warn, and :ignore.
365Note that ASDF ALWAYS raises an error if it fails to create an output file when compiling.")
366
367(defvar *verbose-out* nil)
368
369(defvar *asdf-verbose* t)
370
371(defparameter +asdf-methods+
372  '(perform-with-restarts perform explain output-files operation-done-p))
373
374#+allegro
375(eval-when (:compile-toplevel :execute)
376  (defparameter *acl-warn-save*
377                (when (boundp 'excl:*warn-on-nested-reader-conditionals*)
378                  excl:*warn-on-nested-reader-conditionals*))
379  (when (boundp 'excl:*warn-on-nested-reader-conditionals*)
380    (setf excl:*warn-on-nested-reader-conditionals* nil)))
381
382;;;; -------------------------------------------------------------------------
383;;;; General Purpose Utilities
384
385(macrolet
386    ((defdef (def* def)
387       `(defmacro ,def* (name formals &rest rest)
388          `(progn
389             #+(or ecl gcl) (fmakunbound ',name)
390             ,(when (and #+ecl (symbolp name))
391                `(declaim (notinline ,name))) ; fails for setf functions on ecl
392             (,',def ,name ,formals ,@rest)))))
393  (defdef defgeneric* defgeneric)
394  (defdef defun* defun))
395
396(defmacro while-collecting ((&rest collectors) &body body)
397  "COLLECTORS should be a list of names for collections.  A collector
398defines a function that, when applied to an argument inside BODY, will
399add its argument to the corresponding collection.  Returns multiple values,
400a list for each collection, in order.
401   E.g.,
402\(while-collecting \(foo bar\)
403           \(dolist \(x '\(\(a 1\) \(b 2\) \(c 3\)\)\)
404             \(foo \(first x\)\)
405             \(bar \(second x\)\)\)\)
406Returns two values: \(A B C\) and \(1 2 3\)."
407  (let ((vars (mapcar #'(lambda (x) (gensym (symbol-name x))) collectors))
408        (initial-values (mapcar (constantly nil) collectors)))
409    `(let ,(mapcar #'list vars initial-values)
410       (flet ,(mapcar #'(lambda (c v) `(,c (x) (push x ,v) (values))) collectors vars)
411         ,@body
412         (values ,@(mapcar #'(lambda (v) `(reverse ,v)) vars))))))
413
414(defmacro aif (test then &optional else)
415  `(let ((it ,test)) (if it ,then ,else)))
416
417(defun* pathname-directory-pathname (pathname)
418  "Returns a new pathname with same HOST, DEVICE, DIRECTORY as PATHNAME,
419and NIL NAME, TYPE and VERSION components"
420  (when pathname
421    (make-pathname :name nil :type nil :version nil :defaults pathname)))
422
423(defun* normalize-pathname-directory-component (directory)
424  (cond
425    #-(or sbcl cmu)
426    ((stringp directory) `(:absolute ,directory) directory)
427    #+gcl
428    ((and (consp directory) (stringp (first directory)))
429     `(:absolute ,@directory))
430    ((or (null directory)
431         (and (consp directory) (member (first directory) '(:absolute :relative))))
432     directory)
433    (t
434     (error "Unrecognized pathname directory component ~S" directory))))
435
436(defun* merge-pathname-directory-components (specified defaults)
437  (let ((directory (normalize-pathname-directory-component specified)))
438    (ecase (first directory)
439      ((nil) defaults)
440      (:absolute specified)
441      (:relative
442       (let ((defdir (normalize-pathname-directory-component defaults))
443             (reldir (cdr directory)))
444         (cond
445           ((null defdir)
446            directory)
447           ((not (eq :back (first reldir)))
448            (append defdir reldir))
449           (t
450            (loop :with defabs = (first defdir)
451              :with defrev = (reverse (rest defdir))
452              :while (and (eq :back (car reldir))
453                          (or (and (eq :absolute defabs) (null defrev))
454                              (stringp (car defrev))))
455              :do (pop reldir) (pop defrev)
456              :finally (return (cons defabs (append (reverse defrev) reldir)))))))))))
457
458(defun* merge-pathnames* (specified &optional (defaults *default-pathname-defaults*))
459  "MERGE-PATHNAMES* is like MERGE-PATHNAMES except that if the SPECIFIED pathname
460does not have an absolute directory, then the HOST and DEVICE come from the DEFAULTS.
461Also, if either argument is NIL, then the other argument is returned unmodified."
462  (when (null specified) (return-from merge-pathnames* defaults))
463  (when (null defaults) (return-from merge-pathnames* specified))
464  (let* ((specified (pathname specified))
465         (defaults (pathname defaults))
466         (directory (normalize-pathname-directory-component (pathname-directory specified)))
467         (name (or (pathname-name specified) (pathname-name defaults)))
468         (type (or (pathname-type specified) (pathname-type defaults)))
469         (version (or (pathname-version specified) (pathname-version defaults))))
470    (labels ((ununspecific (x)
471               (if (eq x :unspecific) nil x))
472             (unspecific-handler (p)
473               (if (typep p 'logical-pathname) #'ununspecific #'identity)))
474      (multiple-value-bind (host device directory unspecific-handler)
475          (ecase (first directory)
476            ((:absolute)
477             (values (pathname-host specified)
478                     (pathname-device specified)
479                     directory
480                     (unspecific-handler specified)))
481            ((nil :relative)
482             (values (pathname-host defaults)
483                     (pathname-device defaults)
484                     (merge-pathname-directory-components directory (pathname-directory defaults))
485                     (unspecific-handler defaults))))
486        (make-pathname :host host :device device :directory directory
487                       :name (funcall unspecific-handler name)
488                       :type (funcall unspecific-handler type)
489                       :version (funcall unspecific-handler version))))))
490
491(defun* pathname-parent-directory-pathname (pathname)
492  "Returns a new pathname with same HOST, DEVICE, DIRECTORY as PATHNAME,
493and NIL NAME, TYPE and VERSION components"
494  (when pathname
495    (make-pathname :name nil :type nil :version nil
496                   :directory (merge-pathname-directory-components '(:relative :back) (pathname-directory pathname))
497                   :defaults pathname)))
498
499
500(define-modify-macro appendf (&rest args)
501  append "Append onto list") ;; only to be used on short lists.
502
503(define-modify-macro orf (&rest args)
504  or "or a flag")
505
506(defun* first-char (s)
507  (and (stringp s) (plusp (length s)) (char s 0)))
508
509(defun* last-char (s)
510  (and (stringp s) (plusp (length s)) (char s (1- (length s)))))
511
512(defun* errfmt (out format-string &rest format-args)
513  (declare (dynamic-extent format-args))
514  (apply #'format out
515         #-genera (format nil "~~@<~A~~:>" format-string) #+genera format-string
516         format-args))
517
518(defun* asdf-message (format-string &rest format-args)
519  (declare (dynamic-extent format-args))
520  (apply #'errfmt *verbose-out* format-string format-args))
521
522(defun* split-string (string &key max (separator '(#\Space #\Tab)))
523  "Split STRING into a list of components separated by
524any of the characters in the sequence SEPARATOR.
525If MAX is specified, then no more than max(1,MAX) components will be returned,
526starting the separation from the end, e.g. when called with arguments
527 \"a.b.c.d.e\" :max 3 :separator \".\" it will return (\"a.b.c\" \"d\" \"e\")."
528  (block nil
529    (let ((list nil) (words 0) (end (length string)))
530      (flet ((separatorp (char) (find char separator))
531             (done () (return (cons (subseq string 0 end) list))))
532        (loop
533          :for start = (if (and max (>= words (1- max)))
534                           (done)
535                           (position-if #'separatorp string :end end :from-end t)) :do
536          (when (null start)
537            (done))
538          (push (subseq string (1+ start) end) list)
539          (incf words)
540          (setf end start))))))
541
542(defun* split-name-type (filename)
543  (let ((unspecific
544         ;; Giving :unspecific as argument to make-pathname is not portable.
545         ;; See CLHS make-pathname and 19.2.2.2.3.
546         ;; We only use it on implementations that support it.
547         (or #+(or clozure gcl lispworks sbcl) :unspecific)))
548    (destructuring-bind (name &optional (type unspecific))
549        (split-string filename :max 2 :separator ".")
550      (if (equal name "")
551          (values filename unspecific)
552          (values name type)))))
553
554(defun* component-name-to-pathname-components (s &key force-directory force-relative)
555  "Splits the path string S, returning three values:
556A flag that is either :absolute or :relative, indicating
557   how the rest of the values are to be interpreted.
558A directory path --- a list of strings, suitable for
559   use with MAKE-PATHNAME when prepended with the flag
560   value.
561A filename with type extension, possibly NIL in the
562   case of a directory pathname.
563FORCE-DIRECTORY forces S to be interpreted as a directory
564pathname \(third return value will be NIL, final component
565of S will be treated as part of the directory path.
566
567The intention of this function is to support structured component names,
568e.g., \(:file \"foo/bar\"\), which will be unpacked to relative
569pathnames."
570  (check-type s string)
571  (when (find #\: s)
572    (error "a portable ASDF pathname designator cannot include a #\: character: ~S" s))
573  (let* ((components (split-string s :separator "/"))
574         (last-comp (car (last components))))
575    (multiple-value-bind (relative components)
576        (if (equal (first components) "")
577            (if (equal (first-char s) #\/)
578                (progn
579                  (when force-relative
580                    (error "absolute pathname designator not allowed: ~S" s))
581                  (values :absolute (cdr components)))
582                (values :relative nil))
583          (values :relative components))
584      (setf components (remove-if #'(lambda (x) (member x '("" ".") :test #'equal)) components))
585      (setf components (substitute :back ".." components :test #'equal))
586      (cond
587        ((equal last-comp "")
588         (values relative components nil)) ; "" already removed
589        (force-directory
590         (values relative components nil))
591        (t
592         (values relative (butlast components) last-comp))))))
593
594(defun* remove-keys (key-names args)
595  (loop :for (name val) :on args :by #'cddr
596    :unless (member (symbol-name name) key-names
597                    :key #'symbol-name :test 'equal)
598    :append (list name val)))
599
600(defun* remove-keyword (key args)
601  (loop :for (k v) :on args :by #'cddr
602    :unless (eq k key)
603    :append (list k v)))
604
605#+mcl
606(eval-when (:compile-toplevel :load-toplevel :execute)
607  (ccl:define-entry-point (_getenv "getenv") ((name :string)) :string))
608
609(defun* getenv (x)
610  (declare (ignorable x))
611  #+(or abcl clisp) (ext:getenv x)
612  #+allegro (sys:getenv x)
613  #+clozure (ccl:getenv x)
614  #+(or cmu scl) (cdr (assoc x ext:*environment-list* :test #'string=))
615  #+ecl (si:getenv x)
616  #+gcl (system:getenv x)
617  #+genera nil
618  #+lispworks (lispworks:environment-variable x)
619  #+mcl (ccl:with-cstrs ((name x))
620          (let ((value (_getenv name)))
621            (unless (ccl:%null-ptr-p value)
622              (ccl:%get-cstring value))))
623  #+sbcl (sb-ext:posix-getenv x)
624  #-(or abcl allegro clisp clozure cmu ecl gcl genera lispworks mcl sbcl scl)
625  (error "getenv not available on your implementation"))
626
627(defun* directory-pathname-p (pathname)
628  "Does PATHNAME represent a directory?
629
630A directory-pathname is a pathname _without_ a filename. The three
631ways that the filename components can be missing are for it to be NIL,
632:UNSPECIFIC or the empty string.
633
634Note that this does _not_ check to see that PATHNAME points to an
635actually-existing directory."
636  (when pathname
637    (let ((pathname (pathname pathname)))
638      (flet ((check-one (x)
639               (member x '(nil :unspecific "") :test 'equal)))
640        (and (not (wild-pathname-p pathname))
641             (check-one (pathname-name pathname))
642             (check-one (pathname-type pathname))
643             t)))))
644
645(defun* ensure-directory-pathname (pathspec)
646  "Converts the non-wild pathname designator PATHSPEC to directory form."
647  (cond
648   ((stringp pathspec)
649    (ensure-directory-pathname (pathname pathspec)))
650   ((not (pathnamep pathspec))
651    (error "Invalid pathname designator ~S" pathspec))
652   ((wild-pathname-p pathspec)
653    (error "Can't reliably convert wild pathname ~S" pathspec))
654   ((directory-pathname-p pathspec)
655    pathspec)
656   (t
657    (make-pathname :directory (append (or (pathname-directory pathspec)
658                                          (list :relative))
659                                      (list (file-namestring pathspec)))
660                   :name nil :type nil :version nil
661                   :defaults pathspec))))
662
663#+genera
664(unless (fboundp 'ensure-directories-exist)
665  (defun ensure-directories-exist (path)
666    (fs:create-directories-recursively (pathname path))))
667
668(defun* absolute-pathname-p (pathspec)
669  (and (typep pathspec '(or pathname string))
670       (eq :absolute (car (pathname-directory (pathname pathspec))))))
671
672(defun* length=n-p (x n) ;is it that (= (length x) n) ?
673  (check-type n (integer 0 *))
674  (loop
675    :for l = x :then (cdr l)
676    :for i :downfrom n :do
677    (cond
678      ((zerop i) (return (null l)))
679      ((not (consp l)) (return nil)))))
680
681(defun* ends-with (s suffix)
682  (check-type s string)
683  (check-type suffix string)
684  (let ((start (- (length s) (length suffix))))
685    (and (<= 0 start)
686         (string-equal s suffix :start1 start))))
687
688(defun* read-file-forms (file)
689  (with-open-file (in file)
690    (loop :with eof = (list nil)
691     :for form = (read in nil eof)
692     :until (eq form eof)
693     :collect form)))
694
695#+asdf-unix
696(progn
697  #+ecl #.(cl:and (cl:< ext:+ecl-version-number+ 100601)
698                  '(ffi:clines "#include <sys/types.h>" "#include <unistd.h>"))
699  (defun* get-uid ()
700    #+allegro (excl.osi:getuid)
701    #+clisp (loop :for s :in '("posix:uid" "LINUX:getuid")
702                  :for f = (ignore-errors (read-from-string s))
703                  :when f :return (funcall f))
704    #+(or cmu scl) (unix:unix-getuid)
705    #+ecl #.(cl:if (cl:< ext:+ecl-version-number+ 100601)
706                   '(ffi:c-inline () () :int "getuid()" :one-liner t)
707                   '(ext::getuid))
708    #+sbcl (sb-unix:unix-getuid)
709    #-(or allegro clisp cmu ecl sbcl scl)
710    (let ((uid-string
711           (with-output-to-string (*verbose-out*)
712             (run-shell-command "id -ur"))))
713      (with-input-from-string (stream uid-string)
714        (read-line stream)
715        (handler-case (parse-integer (read-line stream))
716          (error () (error "Unable to find out user ID")))))))
717
718(defun* pathname-root (pathname)
719  (make-pathname :host (pathname-host pathname)
720                 :device (pathname-device pathname)
721                 :directory '(:absolute)
722                 :name nil :type nil :version nil))
723
724(defun* find-symbol* (s p)
725  (find-symbol (string s) p))
726
727(defun* probe-file* (p)
728  "when given a pathname P, probes the filesystem for a file or directory
729with given pathname and if it exists return its truename."
730  (etypecase p
731   (null nil)
732   (string (probe-file* (parse-namestring p)))
733   (pathname (unless (wild-pathname-p p)
734               #.(or #+(or allegro clozure cmu ecl sbcl scl) '(probe-file p)
735                     #+clisp (aif (find-symbol (string '#:probe-pathname) :ext) `(ignore-errors (,it p)))
736                     '(ignore-errors (truename p)))))))
737
738(defun* truenamize (p)
739  "Resolve as much of a pathname as possible"
740  (block nil
741    (when (typep p '(or null logical-pathname)) (return p))
742    (let* ((p (merge-pathnames* p))
743           (directory (pathname-directory p)))
744      (when (typep p 'logical-pathname) (return p))
745      (let ((found (probe-file* p)))
746        (when found (return found)))
747      #-(or sbcl cmu) (when (stringp directory) (return p))
748      (when (not (eq :absolute (car directory))) (return p))
749      (let ((sofar (probe-file* (pathname-root p))))
750        (unless sofar (return p))
751        (flet ((solution (directories)
752                 (merge-pathnames*
753                  (make-pathname :host nil :device nil
754                                 :directory `(:relative ,@directories)
755                                 :name (pathname-name p)
756                                 :type (pathname-type p)
757                                 :version (pathname-version p))
758                  sofar)))
759          (loop :for component :in (cdr directory)
760            :for rest :on (cdr directory)
761            :for more = (probe-file*
762                         (merge-pathnames*
763                          (make-pathname :directory `(:relative ,component))
764                          sofar)) :do
765            (if more
766                (setf sofar more)
767                (return (solution rest)))
768            :finally
769            (return (solution nil))))))))
770
771(defun* resolve-symlinks (path)
772  #-allegro (truenamize path)
773  #+allegro (if (typep path 'logical-pathname)
774                path
775                (excl:pathname-resolve-symbolic-links path)))
776
777(defun* default-directory ()
778  (truenamize (pathname-directory-pathname *default-pathname-defaults*)))
779
780(defun* lispize-pathname (input-file)
781  (make-pathname :type "lisp" :defaults input-file))
782
783(defparameter *wild-file*
784  (make-pathname :name :wild :type :wild :version :wild :directory nil))
785(defparameter *wild-directory*
786  (make-pathname :directory '(:relative :wild) :name nil :type nil :version nil))
787(defparameter *wild-inferiors*
788  (make-pathname :directory '(:relative :wild-inferiors) :name nil :type nil :version nil))
789(defparameter *wild-path*
790  (merge-pathnames *wild-file* *wild-inferiors*))
791
792(defun* wilden (path)
793  (merge-pathnames* *wild-path* path))
794
795(defun directory-separator-for-host (&optional (pathname *default-pathname-defaults*))
796  (let ((foo (make-pathname :directory '(:absolute "FOO") :defaults pathname)))
797    (last-char (namestring foo))))
798
799(defun* directorize-pathname-host-device (pathname)
800  (let* ((root (pathname-root pathname))
801         (wild-root (wilden root))
802         (absolute-pathname (merge-pathnames* pathname root))
803         (separator (directory-separator-for-host root))
804         (root-namestring (namestring root))
805         (root-string
806          (substitute-if #\/
807                         #'(lambda (x) (or (eql x #\:)
808                                           (eql x separator)))
809                         root-namestring)))
810    (multiple-value-bind (relative path filename)
811        (component-name-to-pathname-components root-string :force-directory t)
812      (declare (ignore relative filename))
813      (let ((new-base
814             (make-pathname :defaults root
815                            :directory `(:absolute ,@path))))
816        (translate-pathname absolute-pathname wild-root (wilden new-base))))))
817
818;;;; -------------------------------------------------------------------------
819;;;; ASDF Interface, in terms of generic functions.
820(defgeneric* find-system (system &optional error-p))
821(defgeneric* perform-with-restarts (operation component))
822(defgeneric* perform (operation component))
823(defgeneric* operation-done-p (operation component))
824(defgeneric* explain (operation component))
825(defgeneric* output-files (operation component))
826(defgeneric* input-files (operation component))
827(defgeneric* component-operation-time (operation component))
828(defgeneric* operation-description (operation component)
829  (:documentation "returns a phrase that describes performing this operation
830on this component, e.g. \"loading /a/b/c\".
831You can put together sentences using this phrase."))
832
833(defgeneric* system-source-file (system)
834  (:documentation "Return the source file in which system is defined."))
835
836(defgeneric* component-system (component)
837  (:documentation "Find the top-level system containing COMPONENT"))
838
839(defgeneric* component-pathname (component)
840  (:documentation "Extracts the pathname applicable for a particular component."))
841
842(defgeneric* component-relative-pathname (component)
843  (:documentation "Returns a pathname for the component argument intended to be
844interpreted relative to the pathname of that component's parent.
845Despite the function's name, the return value may be an absolute
846pathname, because an absolute pathname may be interpreted relative to
847another pathname in a degenerate way."))
848
849(defgeneric* component-property (component property))
850
851(defgeneric* (setf component-property) (new-value component property))
852
853(defgeneric* version-satisfies (component version))
854
855(defgeneric* find-component (base path)
856  (:documentation "Finds the component with PATH starting from BASE module;
857if BASE is nil, then the component is assumed to be a system."))
858
859(defgeneric* source-file-type (component system))
860
861(defgeneric* operation-ancestor (operation)
862  (:documentation
863   "Recursively chase the operation's parent pointer until we get to
864the head of the tree"))
865
866(defgeneric* component-visited-p (operation component)
867  (:documentation "Returns the value stored by a call to
868VISIT-COMPONENT, if that has been called, otherwise NIL.
869This value stored will be a cons cell, the first element
870of which is a computed key, so not interesting.  The
871CDR wil be the DATA value stored by VISIT-COMPONENT; recover
872it as (cdr (component-visited-p op c)).
873  In the current form of ASDF, the DATA value retrieved is
874effectively a boolean, indicating whether some operations are
875to be performed in order to do OPERATION X COMPONENT.  If the
876data value is NIL, the combination had been explored, but no
877operations needed to be performed."))
878
879(defgeneric* visit-component (operation component data)
880  (:documentation "Record DATA as being associated with OPERATION
881and COMPONENT.  This is a side-effecting function:  the association
882will be recorded on the ROOT OPERATION \(OPERATION-ANCESTOR of the
883OPERATION\).
884  No evidence that DATA is ever interesting, beyond just being
885non-NIL.  Using the data field is probably very risky; if there is
886already a record for OPERATION X COMPONENT, DATA will be quietly
887discarded instead of recorded.
888  Starting with 2.006, TRAVERSE will store an integer in data,
889so that nodes can be sorted in decreasing order of traversal."))
890
891
892(defgeneric* (setf visiting-component) (new-value operation component))
893
894(defgeneric* component-visiting-p (operation component))
895
896(defgeneric* component-depends-on (operation component)
897  (:documentation
898   "Returns a list of dependencies needed by the component to perform
899    the operation.  A dependency has one of the following forms:
900
901      (<operation> <component>*), where <operation> is a class
902        designator and each <component> is a component
903        designator, which means that the component depends on
904        <operation> having been performed on each <component>; or
905
906      (FEATURE <feature>), which means that the component depends
907        on <feature>'s presence in *FEATURES*.
908
909    Methods specialized on subclasses of existing component types
910    should usually append the results of CALL-NEXT-METHOD to the
911    list."))
912
913(defgeneric* component-self-dependencies (operation component))
914
915(defgeneric* traverse (operation component)
916  (:documentation
917"Generate and return a plan for performing OPERATION on COMPONENT.
918
919The plan returned is a list of dotted-pairs. Each pair is the CONS
920of ASDF operation object and a COMPONENT object. The pairs will be
921processed in order by OPERATE."))
922
923
924;;;; -------------------------------------------------------------------------
925;;; Methods in case of hot-upgrade. See https://bugs.launchpad.net/asdf/+bug/485687
926(when *upgraded-p*
927   (when (find-class 'module nil)
928     (eval
929      `(defmethod update-instance-for-redefined-class :after
930           ((m module) added deleted plist &key)
931         (declare (ignorable deleted plist))
932         (when (or *asdf-verbose* *load-verbose*)
933           (asdf-message "~&; Updating ~A for ASDF ~A~%" m ,(asdf-version)))
934         (when (member 'components-by-name added)
935           (compute-module-components-by-name m))
936         (when (typep m 'system)
937           (when (member 'source-file added)
938             (%set-system-source-file
939              (probe-asd (component-name m) (component-pathname m)) m)
940             (when (equal (component-name m) "asdf")
941               (setf (component-version m) *asdf-version*))))))))
942
943;;;; -------------------------------------------------------------------------
944;;;; Classes, Conditions
945
946(define-condition system-definition-error (error) ()
947  ;; [this use of :report should be redundant, but unfortunately it's not.
948  ;; cmucl's lisp::output-instance prefers the kernel:slot-class-print-function
949  ;; over print-object; this is always conditions::%print-condition for
950  ;; condition objects, which in turn does inheritance of :report options at
951  ;; run-time.  fortunately, inheritance means we only need this kludge here in
952  ;; order to fix all conditions that build on it.  -- rgr, 28-Jul-02.]
953  #+cmu (:report print-object))
954
955(declaim (ftype (function (t) t)
956                format-arguments format-control
957                error-name error-pathname error-condition
958                duplicate-names-name
959                error-component error-operation
960                module-components module-components-by-name
961                circular-dependency-components
962                condition-arguments condition-form
963                condition-format condition-location
964                coerce-name)
965         (ftype (function (t t) t) (setf module-components-by-name)))
966
967
968(define-condition formatted-system-definition-error (system-definition-error)
969  ((format-control :initarg :format-control :reader format-control)
970   (format-arguments :initarg :format-arguments :reader format-arguments))
971  (:report (lambda (c s)
972               (apply #'errfmt s (format-control c) (format-arguments c)))))
973
974(define-condition load-system-definition-error (system-definition-error)
975  ((name :initarg :name :reader error-name)
976   (pathname :initarg :pathname :reader error-pathname)
977   (condition :initarg :condition :reader error-condition))
978  (:report (lambda (c s)
979             (errfmt s "Error while trying to load definition for system ~A from pathname ~A: ~A"
980                     (error-name c) (error-pathname c) (error-condition c)))))
981
982(define-condition circular-dependency (system-definition-error)
983  ((components :initarg :components :reader circular-dependency-components))
984  (:report (lambda (c s)
985             (errfmt s "Circular dependency: ~S" (circular-dependency-components c)))))
986
987(define-condition duplicate-names (system-definition-error)
988  ((name :initarg :name :reader duplicate-names-name))
989  (:report (lambda (c s)
990             (errfmt s "Error while defining system: multiple components are given same name ~A"
991                     (duplicate-names-name c)))))
992
993(define-condition missing-component (system-definition-error)
994  ((requires :initform "(unnamed)" :reader missing-requires :initarg :requires)
995   (parent :initform nil :reader missing-parent :initarg :parent)))
996
997(define-condition missing-component-of-version (missing-component)
998  ((version :initform nil :reader missing-version :initarg :version)))
999
1000(define-condition missing-dependency (missing-component)
1001  ((required-by :initarg :required-by :reader missing-required-by)))
1002
1003(define-condition missing-dependency-of-version (missing-dependency
1004                                                 missing-component-of-version)
1005  ())
1006
1007(define-condition operation-error (error)
1008  ((component :reader error-component :initarg :component)
1009   (operation :reader error-operation :initarg :operation))
1010  (:report (lambda (c s)
1011               (errfmt s "erred while invoking ~A on ~A"
1012                       (error-operation c) (error-component c)))))
1013(define-condition compile-error (operation-error) ())
1014(define-condition compile-failed (compile-error) ())
1015(define-condition compile-warned (compile-error) ())
1016
1017(define-condition invalid-configuration ()
1018  ((form :reader condition-form :initarg :form)
1019   (location :reader condition-location :initarg :location)
1020   (format :reader condition-format :initarg :format)
1021   (arguments :reader condition-arguments :initarg :arguments :initform nil))
1022  (:report (lambda (c s)
1023               (errfmt s "~? (will be skipped)"
1024                       (condition-format c)
1025                       (list* (condition-form c) (condition-location c)
1026                              (condition-arguments c))))))
1027(define-condition invalid-source-registry (invalid-configuration warning)
1028  ((format :initform "invalid source registry ~S~@[ in ~S~]~@{ ~@?~}")))
1029(define-condition invalid-output-translation (invalid-configuration warning)
1030  ((format :initform "invalid asdf output-translation ~S~@[ in ~S~]~@{ ~@?~}")))
1031
1032(defclass component ()
1033  ((name :accessor component-name :initarg :name :documentation
1034         "Component name: designator for a string composed of portable pathname characters")
1035   (version :accessor component-version :initarg :version)
1036   (description :accessor component-description :initarg :description)
1037   (long-description :accessor component-long-description :initarg :long-description)
1038   ;; This one below is used by POIU - http://www.cliki.net/poiu
1039   ;; a parallelizing extension of ASDF that compiles in multiple parallel
1040   ;; slave processes (forked on demand) and loads in the master process.
1041   ;; Maybe in the future ASDF may use it internally instead of in-order-to.
1042   (load-dependencies :accessor component-load-dependencies :initform nil)
1043   ;; In the ASDF object model, dependencies exist between *actions*
1044   ;; (an action is a pair of operation and component). They are represented
1045   ;; alists of operations to dependencies (other actions) in each component.
1046   ;; There are two kinds of dependencies, each stored in its own slot:
1047   ;; in-order-to and do-first dependencies. These two kinds are related to
1048   ;; the fact that some actions modify the filesystem,
1049   ;; whereas other actions modify the current image, and
1050   ;; this implies a difference in how to interpret timestamps.
1051   ;; in-order-to dependencies will trigger re-performing the action
1052   ;; when the timestamp of some dependency
1053   ;; makes the timestamp of current action out-of-date;
1054   ;; do-first dependencies do not trigger such re-performing.
1055   ;; Therefore, a FASL must be recompiled if it is obsoleted
1056   ;; by any of its FASL dependencies (in-order-to); but
1057   ;; it needn't be recompiled just because one of these dependencies
1058   ;; hasn't yet been loaded in the current image (do-first).
1059   ;; The names are crap, but they have been the official API since Dan Barlow's ASDF 1.52!
1060   ;; See our ASDF 2 paper for more complete explanations.
1061   (in-order-to :initform nil :initarg :in-order-to
1062                :accessor component-in-order-to)
1063   (do-first :initform nil :initarg :do-first
1064             :accessor component-do-first)
1065   ;; methods defined using the "inline" style inside a defsystem form:
1066   ;; need to store them somewhere so we can delete them when the system
1067   ;; is re-evaluated
1068   (inline-methods :accessor component-inline-methods :initform nil)
1069   (parent :initarg :parent :initform nil :reader component-parent)
1070   ;; no direct accessor for pathname, we do this as a method to allow
1071   ;; it to default in funky ways if not supplied
1072   (relative-pathname :initarg :pathname)
1073   (absolute-pathname)
1074   (operation-times :initform (make-hash-table)
1075                    :accessor component-operation-times)
1076   ;; XXX we should provide some atomic interface for updating the
1077   ;; component properties
1078   (properties :accessor component-properties :initarg :properties
1079               :initform nil)))
1080
1081(defun* component-find-path (component)
1082  (reverse
1083   (loop :for c = component :then (component-parent c)
1084     :while c :collect (component-name c))))
1085
1086(defmethod print-object ((c component) stream)
1087  (print-unreadable-object (c stream :type t :identity nil)
1088    (format stream "~{~S~^ ~}" (component-find-path c))))
1089
1090
1091;;;; methods: conditions
1092
1093(defmethod print-object ((c missing-dependency) s)
1094  (format s "~A, required by ~A"
1095          (call-next-method c nil) (missing-required-by c)))
1096
1097(defun* sysdef-error (format &rest arguments)
1098  (error 'formatted-system-definition-error :format-control
1099         format :format-arguments arguments))
1100
1101;;;; methods: components
1102
1103(defmethod print-object ((c missing-component) s)
1104  (format s "component ~S not found~@[ in ~A~]"
1105          (missing-requires c)
1106          (when (missing-parent c)
1107            (coerce-name (missing-parent c)))))
1108
1109(defmethod print-object ((c missing-component-of-version) s)
1110  (format s "component ~S does not match version ~A~@[ in ~A~]"
1111          (missing-requires c)
1112          (missing-version c)
1113          (when (missing-parent c)
1114            (component-name (missing-parent c)))))
1115
1116(defmethod component-system ((component component))
1117  (aif (component-parent component)
1118       (component-system it)
1119       component))
1120
1121(defvar *default-component-class* 'cl-source-file)
1122
1123(defun* compute-module-components-by-name (module)
1124  (let ((hash (make-hash-table :test 'equal)))
1125    (setf (module-components-by-name module) hash)
1126    (loop :for c :in (module-components module)
1127      :for name = (component-name c)
1128      :for previous = (gethash name (module-components-by-name module))
1129      :do
1130      (when previous
1131        (error 'duplicate-names :name name))
1132      :do (setf (gethash name (module-components-by-name module)) c))
1133    hash))
1134
1135(defclass module (component)
1136  ((components
1137    :initform nil
1138    :initarg :components
1139    :accessor module-components)
1140   (components-by-name
1141    :accessor module-components-by-name)
1142   ;; What to do if we can't satisfy a dependency of one of this module's
1143   ;; components.  This allows a limited form of conditional processing.
1144   (if-component-dep-fails
1145    :initform :fail
1146    :initarg :if-component-dep-fails
1147    :accessor module-if-component-dep-fails)
1148   (default-component-class
1149    :initform *default-component-class*
1150    :initarg :default-component-class
1151    :accessor module-default-component-class)))
1152
1153(defun* component-parent-pathname (component)
1154  ;; No default anymore (in particular, no *default-pathname-defaults*).
1155  ;; If you force component to have a NULL pathname, you better arrange
1156  ;; for any of its children to explicitly provide a proper absolute pathname
1157  ;; wherever a pathname is actually wanted.
1158  (let ((parent (component-parent component)))
1159    (when parent
1160      (component-pathname parent))))
1161
1162(defmethod component-pathname ((component component))
1163  (if (slot-boundp component 'absolute-pathname)
1164      (slot-value component 'absolute-pathname)
1165      (let ((pathname
1166             (merge-pathnames*
1167             (component-relative-pathname component)
1168             (pathname-directory-pathname (component-parent-pathname component)))))
1169        (unless (or (null pathname) (absolute-pathname-p pathname))
1170          (error "Invalid relative pathname ~S for component ~S"
1171                 pathname (component-find-path component)))
1172        (setf (slot-value component 'absolute-pathname) pathname)
1173        pathname)))
1174
1175(defmethod component-property ((c component) property)
1176  (cdr (assoc property (slot-value c 'properties) :test #'equal)))
1177
1178(defmethod (setf component-property) (new-value (c component) property)
1179  (let ((a (assoc property (slot-value c 'properties) :test #'equal)))
1180    (if a
1181        (setf (cdr a) new-value)
1182        (setf (slot-value c 'properties)
1183              (acons property new-value (slot-value c 'properties)))))
1184  new-value)
1185
1186(defclass system (module)
1187  (;; description and long-description are now available for all component's,
1188   ;; but now also inherited from component, but we add the legacy accessor
1189   (description :accessor system-description :initarg :description)
1190   (long-description :accessor system-long-description :initarg :long-description)
1191   (author :accessor system-author :initarg :author)
1192   (maintainer :accessor system-maintainer :initarg :maintainer)
1193   (licence :accessor system-licence :initarg :licence
1194            :accessor system-license :initarg :license)
1195   (source-file :reader system-source-file :initarg :source-file
1196                :writer %set-system-source-file)
1197   (defsystem-depends-on :reader system-defsystem-depends-on :initarg :defsystem-depends-on)))
1198
1199;;;; -------------------------------------------------------------------------
1200;;;; version-satisfies
1201
1202(defmethod version-satisfies ((c component) version)
1203  (unless (and version (slot-boundp c 'version))
1204    (return-from version-satisfies t))
1205  (version-satisfies (component-version c) version))
1206
1207(defmethod version-satisfies ((cver string) version)
1208  (let ((x (mapcar #'parse-integer
1209                   (split-string cver :separator ".")))
1210        (y (mapcar #'parse-integer
1211                   (split-string version :separator "."))))
1212    (labels ((bigger (x y)
1213               (cond ((not y) t)
1214                     ((not x) nil)
1215                     ((> (car x) (car y)) t)
1216                     ((= (car x) (car y))
1217                      (bigger (cdr x) (cdr y))))))
1218      (and (= (car x) (car y))
1219           (or (not (cdr y)) (bigger (cdr x) (cdr y)))))))
1220
1221;;;; -------------------------------------------------------------------------
1222;;;; Finding systems
1223
1224(defun* make-defined-systems-table ()
1225  (make-hash-table :test 'equal))
1226
1227(defvar *defined-systems* (make-defined-systems-table)
1228  "This is a hash table whose keys are strings, being the
1229names of the systems, and whose values are pairs, the first
1230element of which is a universal-time indicating when the
1231system definition was last updated, and the second element
1232of which is a system object.")
1233
1234(defun* coerce-name (name)
1235  (typecase name
1236    (component (component-name name))
1237    (symbol (string-downcase (symbol-name name)))
1238    (string name)
1239    (t (sysdef-error "invalid component designator ~A" name))))
1240
1241(defun* system-registered-p (name)
1242  (gethash (coerce-name name) *defined-systems*))
1243
1244(defun* clear-system (name)
1245  "Clear the entry for a system in the database of systems previously loaded.
1246Note that this does NOT in any way cause the code of the system to be unloaded."
1247  ;; There is no "unload" operation in Common Lisp, and a general such operation
1248  ;; cannot be portably written, considering how much CL relies on side-effects
1249  ;; to global data structures.
1250  (remhash (coerce-name name) *defined-systems*))
1251
1252(defun* map-systems (fn)
1253  "Apply FN to each defined system.
1254
1255FN should be a function of one argument. It will be
1256called with an object of type asdf:system."
1257  (maphash #'(lambda (_ datum)
1258               (declare (ignore _))
1259               (destructuring-bind (_ . def) datum
1260                 (declare (ignore _))
1261                 (funcall fn def)))
1262           *defined-systems*))
1263
1264;;; for the sake of keeping things reasonably neat, we adopt a
1265;;; convention that functions in this list are prefixed SYSDEF-
1266
1267(defparameter *system-definition-search-functions*
1268  '(sysdef-central-registry-search sysdef-source-registry-search sysdef-find-asdf))
1269
1270(defun* system-definition-pathname (system)
1271  (let ((system-name (coerce-name system)))
1272    (or
1273     (some #'(lambda (x) (funcall x system-name))
1274           *system-definition-search-functions*)
1275     (let ((system-pair (system-registered-p system-name)))
1276       (and system-pair
1277            (system-source-file (cdr system-pair)))))))
1278
1279(defvar *central-registry* nil
1280"A list of 'system directory designators' ASDF uses to find systems.
1281
1282A 'system directory designator' is a pathname or an expression
1283which evaluates to a pathname. For example:
1284
1285    (setf asdf:*central-registry*
1286          (list '*default-pathname-defaults*
1287                #p\"/home/me/cl/systems/\"
1288                #p\"/usr/share/common-lisp/systems/\"))
1289
1290This is for backward compatibilily.
1291Going forward, we recommend new users should be using the source-registry.
1292")
1293
1294(defun* probe-asd (name defaults)
1295  (block nil
1296    (when (directory-pathname-p defaults)
1297      (let ((file
1298             (make-pathname
1299              :defaults defaults :version :newest :case :local
1300              :name name
1301              :type "asd")))
1302        (when (probe-file* file)
1303          (return file)))
1304      #+(and asdf-windows (not clisp))
1305      (let ((shortcut
1306             (make-pathname
1307              :defaults defaults :version :newest :case :local
1308              :name (concatenate 'string name ".asd")
1309              :type "lnk")))
1310        (when (probe-file* shortcut)
1311          (let ((target (parse-windows-shortcut shortcut)))
1312            (when target
1313              (return (pathname target)))))))))
1314
1315(defun* sysdef-central-registry-search (system)
1316  (let ((name (coerce-name system))
1317        (to-remove nil)
1318        (to-replace nil))
1319    (block nil
1320      (unwind-protect
1321           (dolist (dir *central-registry*)
1322             (let ((defaults (eval dir)))
1323               (when defaults
1324                 (cond ((directory-pathname-p defaults)
1325                        (let ((file (probe-asd name defaults)))
1326                          (when file
1327                            (return file))))
1328                       (t
1329                        (restart-case
1330                            (let* ((*print-circle* nil)
1331                                   (message
1332                                    (errfmt nil
1333                                            "While searching for system ~S: ~S evaluated to ~S which is not a directory."
1334                                            system dir defaults)))
1335                              (error message))
1336                          (remove-entry-from-registry ()
1337                            :report "Remove entry from *central-registry* and continue"
1338                            (push dir to-remove))
1339                          (coerce-entry-to-directory ()
1340                            :report (lambda (s)
1341                                      (errfmt s "Coerce entry to ~a, replace ~a and continue."
1342                                              (ensure-directory-pathname defaults) dir))
1343                            (push (cons dir (ensure-directory-pathname defaults)) to-replace))))))))
1344        ;; cleanup
1345        (dolist (dir to-remove)
1346          (setf *central-registry* (remove dir *central-registry*)))
1347        (dolist (pair to-replace)
1348          (let* ((current (car pair))
1349                 (new (cdr pair))
1350                 (position (position current *central-registry*)))
1351            (setf *central-registry*
1352                  (append (subseq *central-registry* 0 position)
1353                          (list new)
1354                          (subseq *central-registry* (1+ position))))))))))
1355
1356(defun* make-temporary-package ()
1357  (flet ((try (counter)
1358           (ignore-errors
1359             (make-package (format nil "~A~D" :asdf counter)
1360                           :use '(:cl :asdf)))))
1361    (do* ((counter 0 (+ counter 1))
1362          (package (try counter) (try counter)))
1363         (package package))))
1364
1365(defun* safe-file-write-date (pathname)
1366  ;; If FILE-WRITE-DATE returns NIL, it's possible that
1367  ;; the user or some other agent has deleted an input file.
1368  ;; Also, generated files will not exist at the time planning is done
1369  ;; and calls operation-done-p which calls safe-file-write-date.
1370  ;; So it is very possible that we can't get a valid file-write-date,
1371  ;; and we can survive and we will continue the planning
1372  ;; as if the file were very old.
1373  ;; (or should we treat the case in a different, special way?)
1374  (or (and pathname (probe-file* pathname) (file-write-date pathname))
1375      (progn
1376        (when (and pathname *asdf-verbose*)
1377          (warn "Missing FILE-WRITE-DATE for ~S: treating it as zero."
1378                pathname))
1379        0)))
1380
1381(defmethod find-system (name &optional (error-p t))
1382  (find-system (coerce-name name) error-p))
1383
1384(defun load-sysdef (name pathname)
1385  ;; Tries to load system definition with canonical NAME from PATHNAME.
1386  (let ((package (make-temporary-package)))
1387    (unwind-protect
1388         (handler-bind
1389             ((error #'(lambda (condition)
1390                         (error 'load-system-definition-error
1391                                :name name :pathname pathname
1392                                :condition condition))))
1393           (let ((*package* package))
1394             (asdf-message
1395              "~&; Loading system definition from ~A into ~A~%"
1396              pathname package)
1397             (load pathname)))
1398      (delete-package package))))
1399
1400(defmethod find-system ((name string) &optional (error-p t))
1401  (catch 'find-system
1402    (let* ((in-memory (system-registered-p name)) ; load from disk if absent or newer on disk
1403           (on-disk (system-definition-pathname name)))
1404      (when (and on-disk
1405                 (or (not in-memory)
1406                     ;; don't reload if it's already been loaded,
1407                     ;; or its filestamp is in the future which means some clock is skewed
1408                     ;; and trying to load might cause an infinite loop.
1409                     (< (car in-memory) (safe-file-write-date on-disk) (get-universal-time))))
1410        (load-sysdef name on-disk))
1411      (let ((in-memory (system-registered-p name))) ; try again after loading from disk
1412        (cond
1413          (in-memory
1414           (when on-disk
1415             (setf (car in-memory) (safe-file-write-date on-disk)))
1416           (cdr in-memory))
1417          (error-p
1418           (error 'missing-component :requires name)))))))
1419
1420(defun* register-system (name system)
1421  (asdf-message "~&; Registering ~A as ~A~%" system name)
1422  (setf (gethash (coerce-name name) *defined-systems*)
1423        (cons (get-universal-time) system)))
1424
1425(defun* find-system-fallback (requested fallback &rest keys &key source-file &allow-other-keys)
1426  (setf fallback (coerce-name fallback)
1427        source-file (or source-file
1428                        (if *resolve-symlinks*
1429                            (or *compile-file-truename* *load-truename*)
1430                            (or *compile-file-pathname* *load-pathname*)))
1431        requested (coerce-name requested))
1432  (when (equal requested fallback)
1433    (let* ((registered (cdr (gethash fallback *defined-systems*)))
1434           (system (or registered
1435                       (apply 'make-instance 'system
1436                              :name fallback :source-file source-file keys))))
1437      (unless registered
1438        (register-system fallback system))
1439      (throw 'find-system system))))
1440
1441(defun* sysdef-find-asdf (name)
1442  ;; Bug: :version *asdf-version* won't be updated when ASDF is updated.
1443  (find-system-fallback name "asdf" :version *asdf-version*))
1444
1445
1446;;;; -------------------------------------------------------------------------
1447;;;; Finding components
1448
1449(defmethod find-component ((base string) path)
1450  (let ((s (find-system base nil)))
1451    (and s (find-component s path))))
1452
1453(defmethod find-component ((base symbol) path)
1454  (cond
1455    (base (find-component (coerce-name base) path))
1456    (path (find-component path nil))
1457    (t    nil)))
1458
1459(defmethod find-component ((base cons) path)
1460  (find-component (car base) (cons (cdr base) path)))
1461
1462(defmethod find-component ((module module) (name string))
1463  (unless (slot-boundp module 'components-by-name) ;; SBCL may miss the u-i-f-r-c method!!!
1464    (compute-module-components-by-name module))
1465  (values (gethash name (module-components-by-name module))))
1466
1467(defmethod find-component ((component component) (name symbol))
1468  (if name
1469      (find-component component (coerce-name name))
1470      component))
1471
1472(defmethod find-component ((module module) (name cons))
1473  (find-component (find-component module (car name)) (cdr name)))
1474
1475
1476;;; component subclasses
1477
1478(defclass source-file (component)
1479  ((type :accessor source-file-explicit-type :initarg :type :initform nil)))
1480
1481(defclass cl-source-file (source-file)
1482  ((type :initform "lisp")))
1483(defclass c-source-file (source-file)
1484  ((type :initform "c")))
1485(defclass java-source-file (source-file)
1486  ((type :initform "java")))
1487(defclass static-file (source-file) ())
1488(defclass doc-file (static-file) ())
1489(defclass html-file (doc-file)
1490  ((type :initform "html")))
1491
1492(defmethod source-file-type ((component module) (s module))
1493  (declare (ignorable component s))
1494  :directory)
1495(defmethod source-file-type ((component source-file) (s module))
1496  (declare (ignorable s))
1497  (source-file-explicit-type component))
1498
1499(defun* merge-component-name-type (name &key type defaults)
1500  ;; For backwards compatibility only, for people using internals.
1501  ;; Will be removed in a future release, e.g. 2.014.
1502  (coerce-pathname name :type type :defaults defaults))
1503
1504(defun* coerce-pathname (name &key type defaults)
1505  "coerce NAME into a PATHNAME.
1506When given a string, portably decompose it into a relative pathname:
1507#\\/ separates subdirectories. The last #\\/-separated string is as follows:
1508if TYPE is NIL, its last #\\. if any separates name and type from from type;
1509if TYPE is a string, it is the type, and the whole string is the name;
1510if TYPE is :DIRECTORY, the string is a directory component;
1511if the string is empty, it's a directory.
1512Any directory named .. is read as :BACK.
1513Host, device and version components are taken from DEFAULTS."
1514  ;; The defaults are required notably because they provide the default host
1515  ;; to the below make-pathname, which may crucially matter to people using
1516  ;; merge-pathnames with non-default hosts,  e.g. for logical-pathnames.
1517  ;; NOTE that the host and device slots will be taken from the defaults,
1518  ;; but that should only matter if you either (a) use absolute pathnames, or
1519  ;; (b) later merge relative pathnames with CL:MERGE-PATHNAMES instead of
1520  ;; ASDF:MERGE-PATHNAMES*
1521  (etypecase name
1522    ((or null pathname)
1523     name)
1524    (symbol
1525     (coerce-pathname (string-downcase name) :type type :defaults defaults))
1526    (string
1527     (multiple-value-bind (relative path filename)
1528         (component-name-to-pathname-components name :force-directory (eq type :directory)
1529                                                :force-relative t)
1530       (multiple-value-bind (name type)
1531           (cond
1532             ((or (eq type :directory) (null filename))
1533              (values nil nil))
1534             (type
1535              (values filename type))
1536             (t
1537              (split-name-type filename)))
1538         (let* ((defaults (pathname (or defaults *default-pathname-defaults*)))
1539                (host (pathname-host defaults))
1540                (device (pathname-device defaults)))
1541           (make-pathname :directory `(,relative ,@path)
1542                          :name name :type type
1543                          :host host :device device)))))))
1544
1545(defmethod component-relative-pathname ((component component))
1546  (coerce-pathname
1547   (or (slot-value component 'relative-pathname)
1548       (component-name component))
1549   :type (source-file-type component (component-system component))
1550   :defaults (component-parent-pathname component)))
1551
1552;;;; -------------------------------------------------------------------------
1553;;;; Operations
1554
1555;;; one of these is instantiated whenever #'operate is called
1556
1557(defclass operation ()
1558  (
1559   ;; as of danb's 2003-03-16 commit e0d02781, :force can be:
1560   ;; T to force the inside of existing system,
1561   ;;   but not recurse to other systems we depend on.
1562   ;; :ALL (or any other atom) to force all systems
1563   ;;   including other systems we depend on.
1564   ;; (SYSTEM1 SYSTEM2 ... SYSTEMN)
1565   ;;   to force systems named in a given list
1566   ;; However, but this feature never worked before ASDF 1.700 and is currently cerror'ed out.
1567   (forced :initform nil :initarg :force :accessor operation-forced)
1568   (original-initargs :initform nil :initarg :original-initargs
1569                      :accessor operation-original-initargs)
1570   (visited-nodes :initform (make-hash-table :test 'equal) :accessor operation-visited-nodes)
1571   (visiting-nodes :initform (make-hash-table :test 'equal) :accessor operation-visiting-nodes)
1572   (parent :initform nil :initarg :parent :accessor operation-parent)))
1573
1574(defmethod print-object ((o operation) stream)
1575  (print-unreadable-object (o stream :type t :identity t)
1576    (ignore-errors
1577      (prin1 (operation-original-initargs o) stream))))
1578
1579(defmethod shared-initialize :after ((operation operation) slot-names
1580                                     &key force
1581                                     &allow-other-keys)
1582  (declare (ignorable operation slot-names force))
1583  ;; empty method to disable initarg validity checking
1584  (values))
1585
1586(defun* node-for (o c)
1587  (cons (class-name (class-of o)) c))
1588
1589(defmethod operation-ancestor ((operation operation))
1590  (aif (operation-parent operation)
1591       (operation-ancestor it)
1592       operation))
1593
1594
1595(defun* make-sub-operation (c o dep-c dep-o)
1596  "C is a component, O is an operation, DEP-C is another
1597component, and DEP-O, confusingly enough, is an operation
1598class specifier, not an operation."
1599  (let* ((args (copy-list (operation-original-initargs o)))
1600         (force-p (getf args :force)))
1601    ;; note explicit comparison with T: any other non-NIL force value
1602    ;; (e.g. :recursive) will pass through
1603    (cond ((and (null (component-parent c))
1604                (null (component-parent dep-c))
1605                (not (eql c dep-c)))
1606           (when (eql force-p t)
1607             (setf (getf args :force) nil))
1608           (apply #'make-instance dep-o
1609                  :parent o
1610                  :original-initargs args args))
1611          ((subtypep (type-of o) dep-o)
1612           o)
1613          (t
1614           (apply #'make-instance dep-o
1615                  :parent o :original-initargs args args)))))
1616
1617
1618(defmethod visit-component ((o operation) (c component) data)
1619  (unless (component-visited-p o c)
1620    (setf (gethash (node-for o c)
1621                   (operation-visited-nodes (operation-ancestor o)))
1622          (cons t data))))
1623
1624(defmethod component-visited-p ((o operation) (c component))
1625  (gethash (node-for o c)
1626           (operation-visited-nodes (operation-ancestor o))))
1627
1628(defmethod (setf visiting-component) (new-value operation component)
1629  ;; MCL complains about unused lexical variables
1630  (declare (ignorable operation component))
1631  new-value)
1632
1633(defmethod (setf visiting-component) (new-value (o operation) (c component))
1634  (let ((node (node-for o c))
1635        (a (operation-ancestor o)))
1636    (if new-value
1637        (setf (gethash node (operation-visiting-nodes a)) t)
1638        (remhash node (operation-visiting-nodes a)))
1639    new-value))
1640
1641(defmethod component-visiting-p ((o operation) (c component))
1642  (let ((node (node-for o c)))
1643    (gethash node (operation-visiting-nodes (operation-ancestor o)))))
1644
1645(defmethod component-depends-on ((op-spec symbol) (c component))
1646  (component-depends-on (make-instance op-spec) c))
1647
1648(defmethod component-depends-on ((o operation) (c component))
1649  (cdr (assoc (class-name (class-of o))
1650              (component-in-order-to c))))
1651
1652(defmethod component-self-dependencies ((o operation) (c component))
1653  (let ((all-deps (component-depends-on o c)))
1654    (remove-if-not #'(lambda (x)
1655                       (member (component-name c) (cdr x) :test #'string=))
1656                   all-deps)))
1657
1658(defmethod input-files ((operation operation) (c component))
1659  (let ((parent (component-parent c))
1660        (self-deps (component-self-dependencies operation c)))
1661    (if self-deps
1662        (mapcan #'(lambda (dep)
1663                    (destructuring-bind (op name) dep
1664                      (output-files (make-instance op)
1665                                    (find-component parent name))))
1666                self-deps)
1667        ;; no previous operations needed?  I guess we work with the
1668        ;; original source file, then
1669        (list (component-pathname c)))))
1670
1671(defmethod input-files ((operation operation) (c module))
1672  (declare (ignorable operation c))
1673  nil)
1674
1675(defmethod component-operation-time (o c)
1676  (gethash (type-of o) (component-operation-times c)))
1677
1678(defmethod operation-done-p ((o operation) (c component))
1679  (let ((out-files (output-files o c))
1680        (in-files (input-files o c))
1681        (op-time (component-operation-time o c)))
1682    (flet ((earliest-out ()
1683             (reduce #'min (mapcar #'safe-file-write-date out-files)))
1684           (latest-in ()
1685             (reduce #'max (mapcar #'safe-file-write-date in-files))))
1686      (cond
1687        ((and (not in-files) (not out-files))
1688         ;; arbitrary decision: an operation that uses nothing to
1689         ;; produce nothing probably isn't doing much.
1690         ;; e.g. operations on systems, modules that have no immediate action,
1691         ;; but are only meaningful through traversed dependencies
1692         t)
1693        ((not out-files)
1694         ;; an operation without output-files is probably meant
1695         ;; for its side-effects in the current image,
1696         ;; assumed to be idem-potent,
1697         ;; e.g. LOAD-OP or LOAD-SOURCE-OP of some CL-SOURCE-FILE.
1698         (and op-time (>= op-time (latest-in))))
1699        ((not in-files)
1700         ;; an operation without output-files and no input-files
1701         ;; is probably meant for its side-effects on the file-system,
1702         ;; assumed to have to be done everytime.
1703         ;; (I don't think there is any such case in ASDF unless extended)
1704         nil)
1705        (t
1706         ;; an operation with both input and output files is assumed
1707         ;; as computing the latter from the former,
1708         ;; assumed to have been done if the latter are all older
1709         ;; than the former.
1710         ;; e.g. COMPILE-OP of some CL-SOURCE-FILE.
1711         ;; We use >= instead of > to play nice with generated files.
1712         ;; This opens a race condition if an input file is changed
1713         ;; after the output is created but within the same second
1714         ;; of filesystem time; but the same race condition exists
1715         ;; whenever the computation from input to output takes more
1716         ;; than one second of filesystem time (or just crosses the
1717         ;; second). So that's cool.
1718         (and
1719          (every #'probe-file* in-files)
1720          (every #'probe-file* out-files)
1721          (>= (earliest-out) (latest-in))))))))
1722
1723
1724
1725;;; For 1.700 I've done my best to refactor TRAVERSE
1726;;; by splitting it up in a bunch of functions,
1727;;; so as to improve the collection and use-detection algorithm. --fare
1728;;; The protocol is as follows: we pass around operation, dependency,
1729;;; bunch of other stuff, and a force argument. Return a force flag.
1730;;; The returned flag is T if anything has changed that requires a rebuild.
1731;;; The force argument is a list of components that will require a rebuild
1732;;; if the flag is T, at which point whoever returns the flag has to
1733;;; mark them all as forced, and whoever recurses again can use a NIL list
1734;;; as a further argument.
1735
1736(defvar *forcing* nil
1737  "This dynamically-bound variable is used to force operations in
1738recursive calls to traverse.")
1739
1740(defgeneric* do-traverse (operation component collect))
1741
1742(defun* %do-one-dep (operation c collect required-op required-c required-v)
1743  ;; collects a partial plan that results from performing required-op
1744  ;; on required-c, possibly with a required-vERSION
1745  (let* ((dep-c (or (let ((d (find-component (component-parent c) required-c)))
1746                      (and d (version-satisfies d required-v) d))
1747                    (if required-v
1748                        (error 'missing-dependency-of-version
1749                               :required-by c
1750                               :version required-v
1751                               :requires required-c)
1752                        (error 'missing-dependency
1753                               :required-by c
1754                               :requires required-c))))
1755         (op (make-sub-operation c operation dep-c required-op)))
1756    (do-traverse op dep-c collect)))
1757
1758(defun* do-one-dep (operation c collect required-op required-c required-v)
1759  ;; this function is a thin, error-handling wrapper around %do-one-dep.
1760  ;; Collects a partial plan per that function.
1761  (loop
1762    (restart-case
1763        (return (%do-one-dep operation c collect
1764                             required-op required-c required-v))
1765      (retry ()
1766        :report (lambda (s)
1767                  (errfmt s "Retry loading component ~S." required-c))
1768        :test
1769        (lambda (c)
1770          (or (null c)
1771              (and (typep c 'missing-dependency)
1772                   (equalp (missing-requires c)
1773                           required-c))))))))
1774
1775(defun* do-dep (operation c collect op dep)
1776  ;; type of arguments uncertain:
1777  ;; op seems to at least potentially be a symbol, rather than an operation
1778  ;; dep is a list of component names
1779  (cond ((eq op 'feature)
1780         (if (member (car dep) *features*)
1781             nil
1782             (error 'missing-dependency
1783                    :required-by c
1784                    :requires (car dep))))
1785        (t
1786         (let ((flag nil))
1787           (flet ((dep (op comp ver)
1788                    (when (do-one-dep operation c collect
1789                                      op comp ver)
1790                      (setf flag t))))
1791             (dolist (d dep)
1792               (if (atom d)
1793                   (dep op d nil)
1794                   ;; structured dependencies --- this parses keywords
1795                   ;; the keywords could be broken out and cleanly (extensibly)
1796                   ;; processed by EQL methods
1797                   (cond ((eq :version (first d))
1798                          ;; https://bugs.launchpad.net/asdf/+bug/527788
1799                          (dep op (second d) (third d)))
1800                         ;; This particular subform is not documented and
1801                         ;; has always been broken in the past.
1802                         ;; Therefore no one uses it, and I'm cerroring it out,
1803                         ;; after fixing it
1804                         ;; See https://bugs.launchpad.net/asdf/+bug/518467
1805                         ((eq :feature (first d))
1806                          (cerror "Continue nonetheless."
1807                                  "Congratulations, you're the first ever user of FEATURE dependencies! Please contact the asdf-devel mailing-list.")
1808                          (when (find (second d) *features* :test 'string-equal)
1809                            (dep op (third d) nil)))
1810                         (t
1811                          (error "Bad dependency ~a.  Dependencies must be (:version <version>), (:feature <feature> [version]), or a name" d))))))
1812           flag))))
1813
1814(defvar *visit-count* 0) ; counter that allows to sort nodes from operation-visited-nodes
1815
1816(defun* do-collect (collect x)
1817  (funcall collect x))
1818
1819(defmethod do-traverse ((operation operation) (c component) collect)
1820  (let ((flag nil)) ;; return value: must we rebuild this and its dependencies?
1821    (labels
1822        ((update-flag (x)
1823           (when x
1824             (setf flag t)))
1825         (dep (op comp)
1826           (update-flag (do-dep operation c collect op comp))))
1827      ;; Have we been visited yet? If so, just process the result.
1828      (aif (component-visited-p operation c)
1829           (progn
1830             (update-flag (cdr it))
1831             (return-from do-traverse flag)))
1832      ;; dependencies
1833      (when (component-visiting-p operation c)
1834        (error 'circular-dependency :components (list c)))
1835      (setf (visiting-component operation c) t)
1836      (unwind-protect
1837           (progn
1838             ;; first we check and do all the dependencies for the module.
1839             ;; Operations planned in this loop will show up
1840             ;; in the results, and are consumed below.
1841             (let ((*forcing* nil))
1842               ;; upstream dependencies are never forced to happen just because
1843               ;; the things that depend on them are....
1844               (loop
1845                 :for (required-op . deps) :in (component-depends-on operation c)
1846                 :do (dep required-op deps)))
1847             ;; constituent bits
1848             (let ((module-ops
1849                    (when (typep c 'module)
1850                      (let ((at-least-one nil)
1851                            ;; This is set based on the results of the
1852                            ;; dependencies and whether we are in the
1853                            ;; context of a *forcing* call...
1854                            ;; inter-system dependencies do NOT trigger
1855                            ;; building components
1856                            (*forcing*
1857                             (or *forcing*
1858                                 (and flag (not (typep c 'system)))))
1859                            (error nil))
1860                        (while-collecting (internal-collect)
1861                          (dolist (kid (module-components c))
1862                            (handler-case
1863                                (update-flag
1864                                 (do-traverse operation kid #'internal-collect))
1865                              (missing-dependency (condition)
1866                                (when (eq (module-if-component-dep-fails c)
1867                                          :fail)
1868                                  (error condition))
1869                                (setf error condition))
1870                              (:no-error (c)
1871                                (declare (ignore c))
1872                                (setf at-least-one t))))
1873                          (when (and (eq (module-if-component-dep-fails c)
1874                                         :try-next)
1875                                     (not at-least-one))
1876                            (error error)))))))
1877               (update-flag
1878                (or
1879                 *forcing*
1880                 (not (operation-done-p operation c))
1881                 ;; For sub-operations, check whether
1882                 ;; the original ancestor operation was forced,
1883                 ;; or names us amongst an explicit list of things to force...
1884                 ;; except that this check doesn't distinguish
1885                 ;; between all the things with a given name. Sigh.
1886                 ;; BROKEN!
1887                 (let ((f (operation-forced
1888                           (operation-ancestor operation))))
1889                   (and f (or (not (consp f)) ;; T or :ALL
1890                              (and (typep c 'system) ;; list of names of systems to force
1891                                   (member (component-name c) f
1892                                           :test #'string=)))))))
1893               (when flag
1894                 (let ((do-first (cdr (assoc (class-name (class-of operation))
1895                                             (component-do-first c)))))
1896                   (loop :for (required-op . deps) :in do-first
1897                     :do (do-dep operation c collect required-op deps)))
1898                 (do-collect collect (vector module-ops))
1899                 (do-collect collect (cons operation c)))))
1900             (setf (visiting-component operation c) nil)))
1901      (visit-component operation c (when flag (incf *visit-count*)))
1902      flag))
1903
1904(defun* flatten-tree (l)
1905  ;; You collected things into a list.
1906  ;; Most elements are just things to collect again.
1907  ;; A (simple-vector 1) indicate that you should recurse into its contents.
1908  ;; This way, in two passes (rather than N being the depth of the tree),
1909  ;; you can collect things with marginally constant-time append,
1910  ;; achieving linear time collection instead of quadratic time.
1911  (while-collecting (c)
1912    (labels ((r (x)
1913               (if (typep x '(simple-vector 1))
1914                   (r* (svref x 0))
1915                   (c x)))
1916             (r* (l)
1917               (dolist (x l) (r x))))
1918      (r* l))))
1919
1920(defmethod traverse ((operation operation) (c component))
1921  ;; cerror'ing a feature that seems to have NEVER EVER worked
1922  ;; ever since danb created it in his 2003-03-16 commit e0d02781.
1923  ;; It was both fixed and disabled in the 1.700 rewrite.
1924  (when (consp (operation-forced operation))
1925    (cerror "Continue nonetheless."
1926            "Congratulations, you're the first ever user of the :force (list of system names) feature! Please contact the asdf-devel mailing-list to collect a cookie.")
1927    (setf (operation-forced operation)
1928          (mapcar #'coerce-name (operation-forced operation))))
1929  (flatten-tree
1930   (while-collecting (collect)
1931     (let ((*visit-count* 0))
1932       (do-traverse operation c #'collect)))))
1933
1934(defmethod perform ((operation operation) (c source-file))
1935  (sysdef-error
1936   "required method PERFORM not implemented for operation ~A, component ~A"
1937   (class-of operation) (class-of c)))
1938
1939(defmethod perform ((operation operation) (c module))
1940  (declare (ignorable operation c))
1941  nil)
1942
1943(defmethod explain ((operation operation) (component component))
1944  (asdf-message "~&;;; ~A~%" (operation-description operation component)))
1945
1946(defmethod operation-description (operation component)
1947  (format nil "~A on component ~S" (class-of operation) (component-find-path component)))
1948
1949;;;; -------------------------------------------------------------------------
1950;;;; compile-op
1951
1952(defclass compile-op (operation)
1953  ((proclamations :initarg :proclamations :accessor compile-op-proclamations :initform nil)
1954   (on-warnings :initarg :on-warnings :accessor operation-on-warnings
1955                :initform *compile-file-warnings-behaviour*)
1956   (on-failure :initarg :on-failure :accessor operation-on-failure
1957               :initform *compile-file-failure-behaviour*)
1958   (flags :initarg :flags :accessor compile-op-flags
1959          :initform nil)))
1960
1961(defun output-file (operation component)
1962  "The unique output file of performing OPERATION on COMPONENT"
1963  (let ((files (output-files operation component)))
1964    (assert (length=n-p files 1))
1965    (first files)))
1966
1967(defmethod perform :before ((operation compile-op) (c source-file))
1968   (loop :for file :in (asdf:output-files operation c)
1969     :for pathname = (if (typep file 'logical-pathname)
1970                         (translate-logical-pathname file)
1971                         file)
1972     :do (ensure-directories-exist pathname)))
1973
1974(defmethod perform :after ((operation operation) (c component))
1975  (setf (gethash (type-of operation) (component-operation-times c))
1976        (get-universal-time)))
1977
1978(defvar *compile-op-compile-file-function* 'compile-file*
1979  "Function used to compile lisp files.")
1980
1981;;; perform is required to check output-files to find out where to put
1982;;; its answers, in case it has been overridden for site policy
1983(defmethod perform ((operation compile-op) (c cl-source-file))
1984  #-:broken-fasl-loader
1985  (let ((source-file (component-pathname c))
1986        ;; on some implementations, there are more than one output-file,
1987        ;; but the first one should always be the primary fasl that gets loaded.
1988        (output-file (first (output-files operation c)))
1989        (*compile-file-warnings-behaviour* (operation-on-warnings operation))
1990        (*compile-file-failure-behaviour* (operation-on-failure operation)))
1991    (multiple-value-bind (output warnings-p failure-p)
1992        (apply *compile-op-compile-file-function* source-file :output-file output-file
1993               (compile-op-flags operation))
1994      (when warnings-p
1995        (case (operation-on-warnings operation)
1996          (:warn (warn
1997                  "COMPILE-FILE warned while performing ~A on ~A."
1998                  operation c))
1999          (:error (error 'compile-warned :component c :operation operation))
2000          (:ignore nil)))
2001      (when failure-p
2002        (case (operation-on-failure operation)
2003          (:warn (warn
2004                  "COMPILE-FILE failed while performing ~A on ~A."
2005                  operation c))
2006          (:error (error 'compile-failed :component c :operation operation))
2007          (:ignore nil)))
2008      (unless output
2009        (error 'compile-error :component c :operation operation)))))
2010
2011(defmethod output-files ((operation compile-op) (c cl-source-file))
2012  (declare (ignorable operation))
2013  (let ((p (lispize-pathname (component-pathname c))))
2014    #-broken-fasl-loader (list (compile-file-pathname p))
2015    #+broken-fasl-loader (list p)))
2016
2017(defmethod perform ((operation compile-op) (c static-file))
2018  (declare (ignorable operation c))
2019  nil)
2020
2021(defmethod output-files ((operation compile-op) (c static-file))
2022  (declare (ignorable operation c))
2023  nil)
2024
2025(defmethod input-files ((operation compile-op) (c static-file))
2026  (declare (ignorable operation c))
2027  nil)
2028
2029(defmethod operation-description ((operation compile-op) component)
2030  (declare (ignorable operation))
2031  (format nil "compiling component ~S" (component-find-path component)))
2032
2033;;;; -------------------------------------------------------------------------
2034;;;; load-op
2035
2036(defclass basic-load-op (operation) ())
2037
2038(defclass load-op (basic-load-op) ())
2039
2040(defmethod perform ((o load-op) (c cl-source-file))
2041  (map () #'load (input-files o c)))
2042
2043(defmethod perform-with-restarts (operation component)
2044  (perform operation component))
2045
2046(defmethod perform-with-restarts ((o load-op) (c cl-source-file))
2047  (declare (ignorable o))
2048  (loop :with state = :initial
2049    :until (or (eq state :success)
2050               (eq state :failure)) :do
2051    (case state
2052      (:recompiled
2053       (setf state :failure)
2054       (call-next-method)
2055       (setf state :success))
2056      (:failed-load
2057       (setf state :recompiled)
2058       (perform (make-instance 'compile-op) c))
2059      (t
2060       (with-simple-restart
2061           (try-recompiling "Recompile ~a and try loading it again"
2062                            (component-name c))
2063         (setf state :failed-load)
2064         (call-next-method)
2065         (setf state :success))))))
2066
2067(defmethod perform-with-restarts ((o compile-op) (c cl-source-file))
2068  (loop :with state = :initial
2069    :until (or (eq state :success)
2070               (eq state :failure)) :do
2071    (case state
2072      (:recompiled
2073       (setf state :failure)
2074       (call-next-method)
2075       (setf state :success))
2076      (:failed-compile
2077       (setf state :recompiled)
2078       (perform-with-restarts o c))
2079      (t
2080       (with-simple-restart
2081           (try-recompiling "Try recompiling ~a"
2082                            (component-name c))
2083         (setf state :failed-compile)
2084         (call-next-method)
2085         (setf state :success))))))
2086
2087(defmethod perform ((operation load-op) (c static-file))
2088  (declare (ignorable operation c))
2089  nil)
2090
2091(defmethod operation-done-p ((operation load-op) (c static-file))
2092  (declare (ignorable operation c))
2093  t)
2094
2095(defmethod output-files ((operation operation) (c component))
2096  (declare (ignorable operation c))
2097  nil)
2098
2099(defmethod component-depends-on ((operation load-op) (c component))
2100  (declare (ignorable operation))
2101  (cons (list 'compile-op (component-name c))
2102        (call-next-method)))
2103
2104(defmethod operation-description ((operation load-op) component)
2105  (declare (ignorable operation))
2106  (format nil "loading component ~S" (component-find-path component)))
2107
2108
2109;;;; -------------------------------------------------------------------------
2110;;;; load-source-op
2111
2112(defclass load-source-op (basic-load-op) ())
2113
2114(defmethod perform ((o load-source-op) (c cl-source-file))
2115  (declare (ignorable o))
2116  (let ((source (component-pathname c)))
2117    (setf (component-property c 'last-loaded-as-source)
2118          (and (load source)
2119               (get-universal-time)))))
2120
2121(defmethod perform ((operation load-source-op) (c static-file))
2122  (declare (ignorable operation c))
2123  nil)
2124
2125(defmethod output-files ((operation load-source-op) (c component))
2126  (declare (ignorable operation c))
2127  nil)
2128
2129;;; FIXME: we simply copy load-op's dependencies.  this is Just Not Right.
2130(defmethod component-depends-on ((o load-source-op) (c component))
2131  (declare (ignorable o))
2132  (let ((what-would-load-op-do (cdr (assoc 'load-op
2133                                           (component-in-order-to c)))))
2134    (mapcar #'(lambda (dep)
2135                (if (eq (car dep) 'load-op)
2136                    (cons 'load-source-op (cdr dep))
2137                    dep))
2138            what-would-load-op-do)))
2139
2140(defmethod operation-done-p ((o load-source-op) (c source-file))
2141  (declare (ignorable o))
2142  (if (or (not (component-property c 'last-loaded-as-source))
2143          (> (safe-file-write-date (component-pathname c))
2144             (component-property c 'last-loaded-as-source)))
2145      nil t))
2146
2147(defmethod operation-description ((operation load-source-op) component)
2148  (declare (ignorable operation))
2149  (format nil "loading component ~S" (component-find-path component)))
2150
2151
2152;;;; -------------------------------------------------------------------------
2153;;;; test-op
2154
2155(defclass test-op (operation) ())
2156
2157(defmethod perform ((operation test-op) (c component))
2158  (declare (ignorable operation c))
2159  nil)
2160
2161(defmethod operation-done-p ((operation test-op) (c system))
2162  "Testing a system is _never_ done."
2163  (declare (ignorable operation c))
2164  nil)
2165
2166(defmethod component-depends-on :around ((o test-op) (c system))
2167  (declare (ignorable o))
2168  (cons `(load-op ,(component-name c)) (call-next-method)))
2169
2170
2171;;;; -------------------------------------------------------------------------
2172;;;; Invoking Operations
2173
2174(defgeneric* operate (operation-class system &key &allow-other-keys))
2175
2176(defmethod operate (operation-class system &rest args
2177                    &key ((:verbose *asdf-verbose*) *asdf-verbose*) version force
2178                    &allow-other-keys)
2179  (declare (ignore force))
2180  (let* ((*package* *package*)
2181         (*readtable* *readtable*)
2182         (op (apply #'make-instance operation-class
2183                    :original-initargs args
2184                    args))
2185         (*verbose-out* (if *asdf-verbose* *standard-output* (make-broadcast-stream)))
2186         (system (if (typep system 'component) system (find-system system))))
2187    (unless (version-satisfies system version)
2188      (error 'missing-component-of-version :requires system :version version))
2189    (let ((steps (traverse op system)))
2190      (with-compilation-unit ()
2191        (loop :for (op . component) :in steps :do
2192          (loop
2193            (restart-case
2194                (progn
2195                  (perform-with-restarts op component)
2196                  (return))
2197              (retry ()
2198                :report
2199                (lambda (s)
2200                  (errfmt s "Retry ~A." (operation-description op component))))
2201              (accept ()
2202                :report
2203                (lambda (s)
2204                  (errfmt s "Continue, treating ~A as having been successful."
2205                          (operation-description op component)))
2206                (setf (gethash (type-of op)
2207                               (component-operation-times component))
2208                      (get-universal-time))
2209                (return))))))
2210      (values op steps))))
2211
2212(defun* oos (operation-class system &rest args &key force verbose version
2213            &allow-other-keys)
2214  (declare (ignore force verbose version))
2215  (apply #'operate operation-class system args))
2216
2217(let ((operate-docstring
2218  "Operate does three things:
2219
22201. It creates an instance of OPERATION-CLASS using any keyword parameters
2221as initargs.
22222. It finds the  asdf-system specified by SYSTEM (possibly loading
2223it from disk).
22243. It then calls TRAVERSE with the operation and system as arguments
2225
2226The traverse operation is wrapped in WITH-COMPILATION-UNIT and error
2227handling code. If a VERSION argument is supplied, then operate also
2228ensures that the system found satisfies it using the VERSION-SATISFIES
2229method.
2230
2231Note that dependencies may cause the operation to invoke other
2232operations on the system or its components: the new operations will be
2233created with the same initargs as the original one.
2234"))
2235  (setf (documentation 'oos 'function)
2236        (format nil
2237                "Short for _operate on system_ and an alias for the OPERATE function. ~&~&~a"
2238                operate-docstring))
2239  (setf (documentation 'operate 'function)
2240        operate-docstring))
2241
2242(defun* load-system (system &rest args &key force verbose version
2243                    &allow-other-keys)
2244  "Shorthand for `(operate 'asdf:load-op system)`. See OPERATE for
2245details."
2246  (declare (ignore force verbose version))
2247  (apply #'operate 'load-op system args)
2248  t)
2249
2250(defun* compile-system (system &rest args &key force verbose version
2251                       &allow-other-keys)
2252  "Shorthand for `(operate 'asdf:compile-op system)`. See OPERATE
2253for details."
2254  (declare (ignore force verbose version))
2255  (apply #'operate 'compile-op system args)
2256  t)
2257
2258(defun* test-system (system &rest args &key force verbose version
2259                    &allow-other-keys)
2260  "Shorthand for `(operate 'asdf:test-op system)`. See OPERATE for
2261details."
2262  (declare (ignore force verbose version))
2263  (apply #'operate 'test-op system args)
2264  t)
2265
2266;;;; -------------------------------------------------------------------------
2267;;;; Defsystem
2268
2269(defun* load-pathname ()
2270  (let ((pn (or *load-pathname* *compile-file-pathname*)))
2271    (if *resolve-symlinks*
2272        (and pn (resolve-symlinks pn))
2273        pn)))
2274
2275(defun* determine-system-pathname (pathname pathname-supplied-p)
2276  ;; The defsystem macro calls us to determine
2277  ;; the pathname of a system as follows:
2278  ;; 1. the one supplied,
2279  ;; 2. derived from *load-pathname* via load-pathname
2280  ;; 3. taken from the *default-pathname-defaults* via default-directory
2281  (let* ((file-pathname (load-pathname))
2282         (directory-pathname (and file-pathname (pathname-directory-pathname file-pathname))))
2283    (or (and pathname-supplied-p
2284             (merge-pathnames* (coerce-pathname pathname :type :directory)
2285                               directory-pathname))
2286        directory-pathname
2287        (default-directory))))
2288
2289(defmacro defsystem (name &body options)
2290  (destructuring-bind (&key (pathname nil pathname-arg-p) (class 'system)
2291                            defsystem-depends-on &allow-other-keys)
2292      options
2293    (let ((component-options (remove-keys '(:class) options)))
2294      `(progn
2295         ;; system must be registered before we parse the body, otherwise
2296         ;; we recur when trying to find an existing system of the same name
2297         ;; to reuse options (e.g. pathname) from
2298         ,@(loop :for system :in defsystem-depends-on
2299             :collect `(load-system ,system))
2300         (let ((s (system-registered-p ',name)))
2301           (cond ((and s (eq (type-of (cdr s)) ',class))
2302                  (setf (car s) (get-universal-time)))
2303                 (s
2304                  (change-class (cdr s) ',class))
2305                 (t
2306                  (register-system (quote ,name)
2307                                   (make-instance ',class :name ',name))))
2308           (%set-system-source-file (load-pathname)
2309                                    (cdr (system-registered-p ',name))))
2310         (parse-component-form
2311          nil (list*
2312               :module (coerce-name ',name)
2313               :pathname
2314               ,(determine-system-pathname pathname pathname-arg-p)
2315               ',component-options))))))
2316
2317(defun* class-for-type (parent type)
2318  (or (loop :for symbol :in (list
2319                             type
2320                             (find-symbol* type *package*)
2321                             (find-symbol* type :asdf))
2322        :for class = (and symbol (find-class symbol nil))
2323        :when (and class (subtypep class 'component))
2324        :return class)
2325      (and (eq type :file)
2326           (or (module-default-component-class parent)
2327               (find-class *default-component-class*)))
2328      (sysdef-error "don't recognize component type ~A" type)))
2329
2330(defun* maybe-add-tree (tree op1 op2 c)
2331  "Add the node C at /OP1/OP2 in TREE, unless it's there already.
2332Returns the new tree (which probably shares structure with the old one)"
2333  (let ((first-op-tree (assoc op1 tree)))
2334    (if first-op-tree
2335        (progn
2336          (aif (assoc op2 (cdr first-op-tree))
2337               (if (find c (cdr it))
2338                   nil
2339                   (setf (cdr it) (cons c (cdr it))))
2340               (setf (cdr first-op-tree)
2341                     (acons op2 (list c) (cdr first-op-tree))))
2342          tree)
2343        (acons op1 (list (list op2 c)) tree))))
2344
2345(defun* union-of-dependencies (&rest deps)
2346  (let ((new-tree nil))
2347    (dolist (dep deps)
2348      (dolist (op-tree dep)
2349        (dolist (op  (cdr op-tree))
2350          (dolist (c (cdr op))
2351            (setf new-tree
2352                  (maybe-add-tree new-tree (car op-tree) (car op) c))))))
2353    new-tree))
2354
2355
2356(defvar *serial-depends-on* nil)
2357
2358(defun* sysdef-error-component (msg type name value)
2359  (sysdef-error (concatenate 'string msg
2360                             "~&The value specified for ~(~A~) ~A is ~S")
2361                type name value))
2362
2363(defun* check-component-input (type name weakly-depends-on
2364                              depends-on components in-order-to)
2365  "A partial test of the values of a component."
2366  (unless (listp depends-on)
2367    (sysdef-error-component ":depends-on must be a list."
2368                            type name depends-on))
2369  (unless (listp weakly-depends-on)
2370    (sysdef-error-component ":weakly-depends-on must be a list."
2371                            type name weakly-depends-on))
2372  (unless (listp components)
2373    (sysdef-error-component ":components must be NIL or a list of components."
2374                            type name components))
2375  (unless (and (listp in-order-to) (listp (car in-order-to)))
2376    (sysdef-error-component ":in-order-to must be NIL or a list of components."
2377                            type name in-order-to)))
2378
2379(defun* %remove-component-inline-methods (component)
2380  (dolist (name +asdf-methods+)
2381    (map ()
2382         ;; this is inefficient as most of the stored
2383         ;; methods will not be for this particular gf
2384         ;; But this is hardly performance-critical
2385         #'(lambda (m)
2386             (remove-method (symbol-function name) m))
2387         (component-inline-methods component)))
2388  ;; clear methods, then add the new ones
2389  (setf (component-inline-methods component) nil))
2390
2391(defun* %define-component-inline-methods (ret rest)
2392  (dolist (name +asdf-methods+)
2393    (let ((keyword (intern (symbol-name name) :keyword)))
2394      (loop :for data = rest :then (cddr data)
2395        :for key = (first data)
2396        :for value = (second data)
2397        :while data
2398        :when (eq key keyword) :do
2399        (destructuring-bind (op qual (o c) &body body) value
2400          (pushnew
2401           (eval `(defmethod ,name ,qual ((,o ,op) (,c (eql ,ret)))
2402                             ,@body))
2403           (component-inline-methods ret)))))))
2404
2405(defun* %refresh-component-inline-methods (component rest)
2406  (%remove-component-inline-methods component)
2407  (%define-component-inline-methods component rest))
2408
2409(defun* parse-component-form (parent options)
2410  (destructuring-bind
2411        (type name &rest rest &key
2412              ;; the following list of keywords is reproduced below in the
2413              ;; remove-keys form.  important to keep them in sync
2414              components pathname default-component-class
2415              perform explain output-files operation-done-p
2416              weakly-depends-on
2417              depends-on serial in-order-to
2418              ;; list ends
2419              &allow-other-keys) options
2420    (declare (ignorable perform explain output-files operation-done-p))
2421    (check-component-input type name weakly-depends-on depends-on components in-order-to)
2422
2423    (when (and parent
2424               (find-component parent name)
2425               ;; ignore the same object when rereading the defsystem
2426               (not
2427                (typep (find-component parent name)
2428                       (class-for-type parent type))))
2429      (error 'duplicate-names :name name))
2430
2431    (let* ((other-args (remove-keys
2432                        '(components pathname default-component-class
2433                          perform explain output-files operation-done-p
2434                          weakly-depends-on
2435                          depends-on serial in-order-to)
2436                        rest))
2437           (ret
2438            (or (find-component parent name)
2439                (make-instance (class-for-type parent type)))))
2440      (when weakly-depends-on
2441        (appendf depends-on (remove-if (complement #'find-system) weakly-depends-on)))
2442      (when *serial-depends-on*
2443        (push *serial-depends-on* depends-on))
2444      (apply #'reinitialize-instance ret
2445             :name (coerce-name name)
2446             :pathname pathname
2447             :parent parent
2448             other-args)
2449      (component-pathname ret) ; eagerly compute the absolute pathname
2450      (when (typep ret 'module)
2451        (setf (module-default-component-class ret)
2452              (or default-component-class
2453                  (and (typep parent 'module)
2454                       (module-default-component-class parent))))
2455        (let ((*serial-depends-on* nil))
2456          (setf (module-components ret)
2457                (loop
2458                  :for c-form :in components
2459                  :for c = (parse-component-form ret c-form)
2460                  :for name = (component-name c)
2461                  :collect c
2462                  :when serial :do (setf *serial-depends-on* name))))
2463        (compute-module-components-by-name ret))
2464
2465      (setf (component-load-dependencies ret) depends-on) ;; Used by POIU
2466
2467      (setf (component-in-order-to ret)
2468            (union-of-dependencies
2469             in-order-to
2470             `((compile-op (compile-op ,@depends-on))
2471               (load-op (load-op ,@depends-on)))))
2472      (setf (component-do-first ret) `((compile-op (load-op ,@depends-on))))
2473
2474      (%refresh-component-inline-methods ret rest)
2475      ret)))
2476
2477;;;; ---------------------------------------------------------------------------
2478;;;; run-shell-command
2479;;;;
2480;;;; run-shell-command functions for other lisp implementations will be
2481;;;; gratefully accepted, if they do the same thing.
2482;;;; If the docstring is ambiguous, send a bug report.
2483;;;;
2484;;;; We probably should move this functionality to its own system and deprecate
2485;;;; use of it from the asdf package. However, this would break unspecified
2486;;;; existing software, so until a clear alternative exists, we can't deprecate
2487;;;; it, and even after it's been deprecated, we will support it for a few
2488;;;; years so everyone has time to migrate away from it. -- fare 2009-12-01
2489
2490(defun* run-shell-command (control-string &rest args)
2491  "Interpolate ARGS into CONTROL-STRING as if by FORMAT, and
2492synchronously execute the result using a Bourne-compatible shell, with
2493output to *VERBOSE-OUT*.  Returns the shell's exit code."
2494  (let ((command (apply #'format nil control-string args)))
2495    (asdf-message "; $ ~A~%" command)
2496
2497    #+abcl
2498    (ext:run-shell-command command :output *verbose-out*)
2499
2500    #+allegro
2501    ;; will this fail if command has embedded quotes - it seems to work
2502    (multiple-value-bind (stdout stderr exit-code)
2503        (excl.osi:command-output
2504         (format nil "~a -c \"~a\""
2505                 #+mswindows "sh" #-mswindows "/bin/sh" command)
2506         :input nil :whole nil
2507         #+mswindows :show-window #+mswindows :hide)
2508      (asdf-message "~{~&; ~a~%~}~%" stderr)
2509      (asdf-message "~{~&; ~a~%~}~%" stdout)
2510      exit-code)
2511
2512    #+clisp                     ;XXX not exactly *verbose-out*, I know
2513    (or (ext:run-shell-command  command :output :terminal :wait t) 0)
2514
2515    #+clozure
2516    (nth-value 1
2517               (ccl:external-process-status
2518                (ccl:run-program "/bin/sh" (list "-c" command)
2519                                 :input nil :output *verbose-out*
2520                                 :wait t)))
2521
2522    #+ecl ;; courtesy of Juan Jose Garcia Ripoll
2523    (si:system command)
2524
2525    #+gcl
2526    (lisp:system command)
2527
2528    #+lispworks
2529    (system:call-system-showing-output
2530     command
2531     :shell-type "/bin/sh"
2532     :show-cmd nil
2533     :prefix ""
2534     :output-stream *verbose-out*)
2535
2536    #+sbcl
2537    (sb-ext:process-exit-code
2538     (apply #'sb-ext:run-program
2539            #+win32 "sh" #-win32 "/bin/sh"
2540            (list  "-c" command)
2541            :input nil :output *verbose-out*
2542            #+win32 '(:search t) #-win32 nil))
2543
2544    #+(or cmu scl)
2545    (ext:process-exit-code
2546     (ext:run-program
2547      "/bin/sh"
2548      (list  "-c" command)
2549      :input nil :output *verbose-out*))
2550
2551    #-(or abcl allegro clisp clozure cmu ecl gcl lispworks sbcl scl)
2552    (error "RUN-SHELL-COMMAND not implemented for this Lisp")))
2553
2554;;;; ---------------------------------------------------------------------------
2555;;;; system-relative-pathname
2556
2557(defmethod system-source-file ((system-name string))
2558  (system-source-file (find-system system-name)))
2559(defmethod system-source-file ((system-name symbol))
2560  (system-source-file (find-system system-name)))
2561
2562(defun* system-source-directory (system-designator)
2563  "Return a pathname object corresponding to the
2564directory in which the system specification (.asd file) is
2565located."
2566     (make-pathname :name nil
2567                 :type nil
2568                 :defaults (system-source-file system-designator)))
2569
2570(defun* relativize-directory (directory)
2571  (cond
2572    ((stringp directory)
2573     (list :relative directory))
2574    ((eq (car directory) :absolute)
2575     (cons :relative (cdr directory)))
2576    (t
2577     directory)))
2578
2579(defun* relativize-pathname-directory (pathspec)
2580  (let ((p (pathname pathspec)))
2581    (make-pathname
2582     :directory (relativize-directory (pathname-directory p))
2583     :defaults p)))
2584
2585(defun* system-relative-pathname (system name &key type)
2586  (merge-pathnames*
2587   (coerce-pathname name :type type)
2588   (system-source-directory system)))
2589
2590
2591;;; ---------------------------------------------------------------------------
2592;;; implementation-identifier
2593;;;
2594;;; produce a string to identify current implementation.
2595;;; Initially stolen from SLIME's SWANK, hacked since.
2596
2597(defparameter *implementation-features*
2598  '((:abcl :armedbear)
2599    (:acl :allegro)
2600    (:mcl :digitool) ; before clozure, so it won't get preempted by ccl
2601    (:ccl :clozure)
2602    (:corman :cormanlisp)
2603    (:lw :lispworks)
2604    :clisp :cmu :ecl :gcl :sbcl :scl :symbolics))
2605
2606(defparameter *os-features*
2607  '((:win :windows :mswindows :win32 :mingw32) ;; shorten things on windows
2608    (:solaris :sunos)
2609    (:linux :linux-target) ;; for GCL at least, must appear before :bsd.
2610    (:macosx :darwin :darwin-target :apple)
2611    :freebsd :netbsd :openbsd :bsd
2612    :unix
2613    :genera))
2614
2615(defparameter *architecture-features*
2616  '((:amd64 :x86-64 :x86_64 :x8664-target)
2617    (:x86 :i386 :i486 :i586 :i686 :pentium3 :pentium4 :pc386 :iapx386 :x8632-target)
2618    :hppa64
2619    :hppa
2620    (:ppc64 :ppc64-target)
2621    (:ppc32 :ppc32-target :ppc :powerpc)
2622    :sparc64
2623    (:sparc32 :sparc)
2624    (:arm :arm-target)
2625    (:java :java-1.4 :java-1.5 :java-1.6 :java-1.7)
2626    :imach))
2627
2628(defun* lisp-version-string ()
2629  (let ((s (lisp-implementation-version)))
2630    (declare (ignorable s))
2631    #+allegro (format nil
2632                      "~A~A~A~A"
2633                      excl::*common-lisp-version-number*
2634                      ;; ANSI vs MoDeRn - thanks to Robert Goldman and Charley Cox
2635                      (if (eq excl:*current-case-mode*
2636                              :case-sensitive-lower) "M" "A")
2637                      ;; Note if not using International ACL
2638                      ;; see http://www.franz.com/support/documentation/8.1/doc/operators/excl/ics-target-case.htm
2639                      (excl:ics-target-case
2640                       (:-ics "8")
2641                       (:+ics ""))
2642                      (if (member :64bit *features*) "-64bit" ""))
2643    #+armedbear (format nil "~a-fasl~a" s system::*fasl-version*)
2644    #+clisp (subseq s 0 (position #\space s)) ; strip build information (date, etc.)
2645    #+clozure (format nil "~d.~d-f~d" ; shorten for windows
2646                      ccl::*openmcl-major-version*
2647                      ccl::*openmcl-minor-version*
2648                      (logand ccl::fasl-version #xFF))
2649    #+cmu (substitute #\- #\/ s)
2650    #+ecl (format nil "~A~@[-~A~]" s
2651                  (let ((vcs-id (ext:lisp-implementation-vcs-id)))
2652                    (when (>= (length vcs-id) 8)
2653                      (subseq vcs-id 0 8))))
2654    #+gcl (subseq s (1+ (position #\space s)))
2655    #+genera (multiple-value-bind (major minor) (sct:get-system-version "System")
2656               (format nil "~D.~D" major minor))
2657    #+lispworks (format nil "~A~@[~A~]" s
2658                        (when (member :lispworks-64bit *features*) "-64bit"))
2659    ;; #+sbcl (format nil "~a-fasl~d" s sb-fasl:+fasl-file-version+) ; f-f-v redundant w/ version
2660    #+mcl (subseq s 8) ; strip the leading "Version "
2661    #+(or cormanlisp sbcl scl) s
2662    #-(or allegro armedbear clisp clozure cmu cormanlisp
2663          ecl gcl genera lispworks mcl sbcl scl) s))
2664
2665(defun* first-feature (features)
2666  (labels
2667      ((fp (thing)
2668         (etypecase thing
2669           (symbol
2670            (let ((feature (find thing *features*)))
2671              (when feature (return-from fp feature))))
2672           ;; allows features to be lists of which the first
2673           ;; member is the "main name", the rest being aliases
2674           (cons
2675            (dolist (subf thing)
2676              (when (find subf *features*) (return-from fp (first thing))))))
2677         nil))
2678    (loop :for f :in features
2679      :when (fp f) :return :it)))
2680
2681(defun* implementation-type ()
2682  (first-feature *implementation-features*))
2683
2684(defun* implementation-identifier ()
2685  (labels
2686      ((maybe-warn (value fstring &rest args)
2687         (cond (value)
2688               (t (apply #'warn fstring args)
2689                  "unknown"))))
2690    (let ((lisp (maybe-warn (implementation-type)
2691                            "No implementation feature found in ~a."
2692                            *implementation-features*))
2693          (os   (maybe-warn (first-feature *os-features*)
2694                            "No os feature found in ~a." *os-features*))
2695          (arch (or #-clisp
2696                    (maybe-warn (first-feature *architecture-features*)
2697                                "No architecture feature found in ~a."
2698                                *architecture-features*)))
2699          (version (maybe-warn (lisp-version-string)
2700                               "Don't know how to get Lisp implementation version.")))
2701      (substitute-if
2702       #\_ #'(lambda (x) (find x " /:\\(){}[]$#`'\""))
2703       (format nil "~(~a~@{~@[-~a~]~}~)" lisp version os arch)))))
2704
2705
2706;;; ---------------------------------------------------------------------------
2707;;; Generic support for configuration files
2708
2709(defparameter *inter-directory-separator*
2710  #+asdf-unix #\:
2711  #-asdf-unix #\;)
2712
2713(defun* user-homedir ()
2714  (truenamize (pathname-directory-pathname (user-homedir-pathname))))
2715
2716(defun* try-directory-subpath (x sub &key type)
2717  (let* ((p (and x (ensure-directory-pathname x)))
2718         (tp (and p (probe-file* p)))
2719         (sp (and tp (merge-pathnames* (coerce-pathname sub :type type) p)))
2720         (ts (and sp (probe-file* sp))))
2721    (and ts (values sp ts))))
2722(defun* user-configuration-directories ()
2723  (remove-if
2724   #'null
2725   (flet ((try (x sub) (try-directory-subpath x sub :type :directory)))
2726     `(,(try (getenv "XDG_CONFIG_HOME") "common-lisp/")
2727       ,@(loop :with dirs = (getenv "XDG_CONFIG_DIRS")
2728           :for dir :in (split-string dirs :separator ":")
2729           :collect (try dir "common-lisp/"))
2730       #+asdf-windows
2731        ,@`(#+lispworks ,(try (sys:get-folder-path :common-appdata) "common-lisp/config/")
2732            ;;; read-windows-registry HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\AppData
2733           ,(try (getenv "APPDATA") "common-lisp/config/"))
2734       ,(try (user-homedir) ".config/common-lisp/")))))
2735(defun* system-configuration-directories ()
2736  (remove-if
2737   #'null
2738   (append
2739    #+asdf-windows
2740    (flet ((try (x sub) (try-directory-subpath x sub :type :directory)))
2741      `(,@`(#+lispworks ,(try (sys:get-folder-path :local-appdata) "common-lisp/config/")
2742           ;;; read-windows-registry HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders\Common AppData
2743        ,(try (getenv "ALLUSERSPROFILE") "Application Data/common-lisp/config/"))))
2744    #+asdf-unix
2745    (list #p"/etc/common-lisp/"))))
2746(defun* in-first-directory (dirs x)
2747  (loop :for dir :in dirs
2748    :thereis (and dir (probe-file* (merge-pathnames* x (ensure-directory-pathname dir))))))
2749(defun* in-user-configuration-directory (x)
2750  (in-first-directory (user-configuration-directories) x))
2751(defun* in-system-configuration-directory (x)
2752  (in-first-directory (system-configuration-directories) x))
2753
2754(defun* configuration-inheritance-directive-p (x)
2755  (let ((kw '(:inherit-configuration :ignore-inherited-configuration)))
2756    (or (member x kw)
2757        (and (length=n-p x 1) (member (car x) kw)))))
2758
2759(defun* report-invalid-form (reporter &rest args)
2760  (etypecase reporter
2761    (null
2762     (apply 'error 'invalid-configuration args))
2763    (function
2764     (apply reporter args))
2765    ((or symbol string)
2766     (apply 'error reporter args))
2767    (cons
2768     (apply 'apply (append reporter args)))))
2769
2770(defvar *ignored-configuration-form* nil)
2771
2772(defun* validate-configuration-form (form tag directive-validator
2773                                    &key location invalid-form-reporter)
2774  (unless (and (consp form) (eq (car form) tag))
2775    (setf *ignored-configuration-form* t)
2776    (report-invalid-form invalid-form-reporter :form form :location location)
2777    (return-from validate-configuration-form nil))
2778  (loop :with inherit = 0 :with ignore-invalid-p = nil :with x = (list tag)
2779    :for directive :in (cdr form)
2780    :when (cond
2781            ((configuration-inheritance-directive-p directive)
2782             (incf inherit) t)
2783            ((eq directive :ignore-invalid-entries)
2784             (setf ignore-invalid-p t) t)
2785            ((funcall directive-validator directive)
2786             t)
2787            (ignore-invalid-p
2788             nil)
2789            (t
2790             (setf *ignored-configuration-form* t)
2791             (report-invalid-form invalid-form-reporter :form directive :location location)
2792             nil))
2793    :do (push directive x)
2794    :finally
2795    (unless (= inherit 1)
2796      (report-invalid-form invalid-form-reporter
2797             :arguments (list "One and only one of ~S or ~S is required"
2798                              :inherit-configuration :ignore-inherited-configuration)))
2799    (return (nreverse x))))
2800
2801(defun* validate-configuration-file (file validator &key description)
2802  (let ((forms (read-file-forms file)))
2803    (unless (length=n-p forms 1)
2804      (error "One and only one form allowed for ~A. Got: ~S~%" description forms))
2805    (funcall validator (car forms) :location file)))
2806
2807(defun* hidden-file-p (pathname)
2808  (equal (first-char (pathname-name pathname)) #\.))
2809
2810(defun* directory* (pathname-spec &rest keys &key &allow-other-keys)
2811  (apply 'directory pathname-spec
2812         (append keys '#.(or #+allegro '(:directories-are-files nil :follow-symbolic-links nil)
2813                             #+clozure '(:follow-links nil)
2814                             #+clisp '(:circle t :if-does-not-exist :ignore)
2815                             #+(or cmu scl) '(:follow-links nil :truenamep nil)
2816                             #+sbcl (when (find-symbol "RESOLVE-SYMLINKS" "SB-IMPL") '(:resolve-symlinks nil))))))
2817
2818(defun* validate-configuration-directory (directory tag validator &key invalid-form-reporter)
2819  "Map the VALIDATOR across the .conf files in DIRECTORY, the TAG will
2820be applied to the results to yield a configuration form.  Current
2821values of TAG include :source-registry and :output-translations."
2822  (let ((files (sort (ignore-errors
2823                       (remove-if
2824                        'hidden-file-p
2825                        (directory* (make-pathname :name :wild :type "conf" :defaults directory))))
2826                     #'string< :key #'namestring)))
2827    `(,tag
2828      ,@(loop :for file :in files :append
2829          (loop :with ignore-invalid-p = nil
2830            :for form :in (read-file-forms file)
2831            :when (eq form :ignore-invalid-entries)
2832              :do (setf ignore-invalid-p t)
2833            :else
2834              :when (funcall validator form)
2835                :collect form
2836              :else
2837                :when ignore-invalid-p
2838                  :do (setf *ignored-configuration-form* t)
2839                :else
2840                  :do (report-invalid-form invalid-form-reporter :form form :location file)))
2841      :inherit-configuration)))
2842
2843
2844;;; ---------------------------------------------------------------------------
2845;;; asdf-output-translations
2846;;;
2847;;; this code is heavily inspired from
2848;;; asdf-binary-translations, common-lisp-controller and cl-launch.
2849;;; ---------------------------------------------------------------------------
2850
2851(defvar *output-translations* ()
2852  "Either NIL (for uninitialized), or a list of one element,
2853said element itself being a sorted list of mappings.
2854Each mapping is a pair of a source pathname and destination pathname,
2855and the order is by decreasing length of namestring of the source pathname.")
2856
2857(defvar *user-cache*
2858  (flet ((try (x &rest sub) (and x `(,x ,@sub))))
2859    (or
2860     (try (getenv "XDG_CACHE_HOME") "common-lisp" :implementation)
2861     #+asdf-windows
2862     (try (getenv "APPDATA") "common-lisp" "cache" :implementation)
2863     '(:home ".cache" "common-lisp" :implementation))))
2864(defvar *system-cache*
2865  ;; No good default, plus there's a security problem
2866  ;; with other users messing with such directories.
2867  *user-cache*)
2868
2869(defun* output-translations ()
2870  (car *output-translations*))
2871
2872(defun* (setf output-translations) (new-value)
2873  (setf *output-translations*
2874        (list
2875         (stable-sort (copy-list new-value) #'>
2876                      :key #'(lambda (x)
2877                               (etypecase (car x)
2878                                 ((eql t) -1)
2879                                 (pathname
2880                                  (let ((directory (pathname-directory (car x))))
2881                                    (if (listp directory) (length directory) 0))))))))
2882  new-value)
2883
2884(defun* output-translations-initialized-p ()
2885  (and *output-translations* t))
2886
2887(defun* clear-output-translations ()
2888  "Undoes any initialization of the output translations.
2889You might want to call that before you dump an image that would be resumed
2890with a different configuration, so the configuration would be re-read then."
2891  (setf *output-translations* '())
2892  (values))
2893
2894(declaim (ftype (function (t &key (:directory boolean) (:wilden boolean))
2895                          (values (or null pathname) &optional))
2896                resolve-location))
2897
2898(defun* resolve-relative-location-component (super x &key directory wilden)
2899  (let* ((r (etypecase x
2900              (pathname x)
2901              (string x)
2902              (cons
2903               (return-from resolve-relative-location-component
2904                 (if (null (cdr x))
2905                     (resolve-relative-location-component
2906                      super (car x) :directory directory :wilden wilden)
2907                     (let* ((car (resolve-relative-location-component
2908                                  super (car x) :directory t :wilden nil))
2909                            (cdr (resolve-relative-location-component
2910                                  (merge-pathnames* car super) (cdr x)
2911                                  :directory directory :wilden wilden)))
2912                       (merge-pathnames* cdr car)))))
2913              ((eql :default-directory)
2914               (relativize-pathname-directory (default-directory)))
2915              ((eql :*/) *wild-directory*)
2916              ((eql :**/) *wild-inferiors*)
2917              ((eql :*.*.*) *wild-file*)
2918              ((eql :implementation) (implementation-identifier))
2919              ((eql :implementation-type) (string-downcase (implementation-type)))
2920              #+asdf-unix
2921              ((eql :uid) (princ-to-string (get-uid)))))
2922         (d (if (or (pathnamep x) (not directory)) r (ensure-directory-pathname r)))
2923         (s (if (or (pathnamep x) (not wilden)) d (wilden d))))
2924    (when (and (absolute-pathname-p s) (not (pathname-match-p s (wilden super))))
2925      (error "pathname ~S is not relative to ~S" s super))
2926    (merge-pathnames* s super)))
2927
2928(defvar *here-directory* nil
2929  "This special variable is bound to the currect directory during calls to
2930PROCESS-SOURCE-REGISTRY in order that we be able to interpret the :here
2931directive.")
2932
2933(defun* resolve-absolute-location-component (x &key directory wilden)
2934  (let* ((r
2935          (etypecase x
2936            (pathname x)
2937            (string (if directory (ensure-directory-pathname x) (parse-namestring x)))
2938            (cons
2939             (return-from resolve-absolute-location-component
2940               (if (null (cdr x))
2941                   (resolve-absolute-location-component
2942                    (car x) :directory directory :wilden wilden)
2943                   (let* ((car (resolve-absolute-location-component
2944                                (car x) :directory t :wilden nil))
2945                          (cdr (resolve-relative-location-component
2946                                car (cdr x) :directory directory :wilden wilden)))
2947                     (merge-pathnames* cdr car))))) ; XXX why is this not just "cdr" ?
2948            ((eql :root)
2949             ;; special magic! we encode such paths as relative pathnames,
2950             ;; but it means "relative to the root of the source pathname's host and device".
2951             (return-from resolve-absolute-location-component
2952               (let ((p (make-pathname :directory '(:relative))))
2953                 (if wilden (wilden p) p))))
2954            ((eql :home) (user-homedir))
2955            ((eql :here)
2956             (resolve-location (or *here-directory*
2957                                   ;; give semantics in the case of use interactively
2958                                   :default-directory)
2959                          :directory t :wilden nil))
2960            ((eql :user-cache) (resolve-location *user-cache* :directory t :wilden nil))
2961            ((eql :system-cache) (resolve-location *system-cache* :directory t :wilden nil))
2962            ((eql :default-directory) (default-directory))))
2963         (s (if (and wilden (not (pathnamep x)))
2964                (wilden r)
2965                r)))
2966    (unless (absolute-pathname-p s)
2967      (error "Not an absolute pathname ~S" s))
2968    s))
2969
2970(defun* resolve-location (x &key directory wilden)
2971  (if (atom x)
2972      (resolve-absolute-location-component x :directory directory :wilden wilden)
2973      (loop :with path = (resolve-absolute-location-component
2974                          (car x) :directory (and (or directory (cdr x)) t)
2975                          :wilden (and wilden (null (cdr x))))
2976        :for (component . morep) :on (cdr x)
2977        :for dir = (and (or morep directory) t)
2978        :for wild = (and wilden (not morep))
2979        :do (setf path (resolve-relative-location-component
2980                        path component :directory dir :wilden wild))
2981        :finally (return path))))
2982
2983(defun* location-designator-p (x)
2984  (flet ((absolute-component-p (c)
2985           (typep c '(or string pathname
2986                      (member :root :home :here :user-cache :system-cache :default-directory))))
2987         (relative-component-p (c)
2988           (typep c '(or string pathname
2989                      (member :default-directory :*/ :**/ :*.*.*
2990                        :implementation :implementation-type
2991                        #+asdf-unix :uid)))))
2992    (or (typep x 'boolean)
2993        (absolute-component-p x)
2994        (and (consp x) (absolute-component-p (first x)) (every #'relative-component-p (rest x))))))
2995
2996(defun* location-function-p (x)
2997  (and
2998   (consp x)
2999   (length=n-p x 2)
3000   (or (and (equal (first x) :function)
3001            (typep (second x) 'symbol))
3002       (and (equal (first x) 'lambda)
3003            (cddr x)
3004            (length=n-p (second x) 2)))))
3005
3006(defun* validate-output-translations-directive (directive)
3007  (or (member directive '(:enable-user-cache :disable-cache nil))
3008      (and (consp directive)
3009           (or (and (length=n-p directive 2)
3010                    (or (and (eq (first directive) :include)
3011                             (typep (second directive) '(or string pathname null)))
3012                        (and (location-designator-p (first directive))
3013                             (or (location-designator-p (second directive))
3014                                 (location-function-p (second directive))))))
3015               (and (length=n-p directive 1)
3016                    (location-designator-p (first directive)))))))
3017
3018(defun* validate-output-translations-form (form &key location)
3019  (validate-configuration-form
3020   form
3021   :output-translations
3022   'validate-output-translations-directive
3023   :location location :invalid-form-reporter 'invalid-output-translation))
3024
3025(defun* validate-output-translations-file (file)
3026  (validate-configuration-file
3027   file 'validate-output-translations-form :description "output translations"))
3028
3029(defun* validate-output-translations-directory (directory)
3030  (validate-configuration-directory
3031   directory :output-translations 'validate-output-translations-directive
3032   :invalid-form-reporter 'invalid-output-translation))
3033
3034(defun* parse-output-translations-string (string &key location)
3035  (cond
3036    ((or (null string) (equal string ""))
3037     '(:output-translations :inherit-configuration))
3038    ((not (stringp string))
3039     (error "environment string isn't: ~S" string))
3040    ((eql (char string 0) #\")
3041     (parse-output-translations-string (read-from-string string) :location location))
3042    ((eql (char string 0) #\()
3043     (validate-output-translations-form (read-from-string string) :location location))
3044    (t
3045     (loop
3046      :with inherit = nil
3047      :with directives = ()
3048      :with start = 0
3049      :with end = (length string)
3050      :with source = nil
3051      :for i = (or (position *inter-directory-separator* string :start start) end) :do
3052      (let ((s (subseq string start i)))
3053        (cond
3054          (source
3055           (push (list source (if (equal "" s) nil s)) directives)
3056           (setf source nil))
3057          ((equal "" s)
3058           (when inherit
3059             (error "only one inherited configuration allowed: ~S" string))
3060           (setf inherit t)
3061           (push :inherit-configuration directives))
3062          (t
3063           (setf source s)))
3064        (setf start (1+ i))
3065        (when (> start end)
3066          (when source
3067            (error "Uneven number of components in source to destination mapping ~S" string))
3068          (unless inherit
3069            (push :ignore-inherited-configuration directives))
3070          (return `(:output-translations ,@(nreverse directives)))))))))
3071
3072(defparameter *default-output-translations*
3073  '(environment-output-translations
3074    user-output-translations-pathname
3075    user-output-translations-directory-pathname
3076    system-output-translations-pathname
3077    system-output-translations-directory-pathname))
3078
3079(defun* wrapping-output-translations ()
3080  `(:output-translations
3081    ;; Some implementations have precompiled ASDF systems,
3082    ;; so we must disable translations for implementation paths.
3083    #+sbcl ,(let ((h (getenv "SBCL_HOME")))
3084                 (when (plusp (length h)) `((,(truenamize h) ,*wild-inferiors*) ())))
3085    #+ecl (,(translate-logical-pathname "SYS:**;*.*") ()) ; not needed: no precompiled ASDF system
3086    #+clozure ,(ignore-errors (list (wilden (let ((*default-pathname-defaults* #p"")) (truename #p"ccl:"))) ())) ; not needed: no precompiled ASDF system
3087    ;; All-import, here is where we want user stuff to be:
3088    :inherit-configuration
3089    ;; These are for convenience, and can be overridden by the user:
3090    #+abcl (#p"/___jar___file___root___/**/*.*" (:user-cache #p"**/*.*"))
3091    #+abcl (#p"jar:file:/**/*.jar!/**/*.*" (:function translate-jar-pathname))
3092    ;; We enable the user cache by default, and here is the place we do:
3093    :enable-user-cache))
3094
3095(defparameter *output-translations-file* (coerce-pathname "asdf-output-translations.conf"))
3096(defparameter *output-translations-directory* (coerce-pathname "asdf-output-translations.conf.d/"))
3097
3098(defun* user-output-translations-pathname ()
3099  (in-user-configuration-directory *output-translations-file* ))
3100(defun* system-output-translations-pathname ()
3101  (in-system-configuration-directory *output-translations-file*))
3102(defun* user-output-translations-directory-pathname ()
3103  (in-user-configuration-directory *output-translations-directory*))
3104(defun* system-output-translations-directory-pathname ()
3105  (in-system-configuration-directory *output-translations-directory*))
3106(defun* environment-output-translations ()
3107  (getenv "ASDF_OUTPUT_TRANSLATIONS"))
3108
3109(defgeneric* process-output-translations (spec &key inherit collect))
3110(declaim (ftype (function (t &key (:collect (or symbol function))) t)
3111                inherit-output-translations))
3112(declaim (ftype (function (t &key (:collect (or symbol function)) (:inherit list)) t)
3113                process-output-translations-directive))
3114
3115(defmethod process-output-translations ((x symbol) &key
3116                                        (inherit *default-output-translations*)
3117                                        collect)
3118  (process-output-translations (funcall x) :inherit inherit :collect collect))
3119(defmethod process-output-translations ((pathname pathname) &key inherit collect)
3120  (cond
3121    ((directory-pathname-p pathname)
3122     (process-output-translations (validate-output-translations-directory pathname)
3123                                  :inherit inherit :collect collect))
3124    ((probe-file* pathname)
3125     (process-output-translations (validate-output-translations-file pathname)
3126                                  :inherit inherit :collect collect))
3127    (t
3128     (inherit-output-translations inherit :collect collect))))
3129(defmethod process-output-translations ((string string) &key inherit collect)
3130  (process-output-translations (parse-output-translations-string string)
3131                               :inherit inherit :collect collect))
3132(defmethod process-output-translations ((x null) &key inherit collect)
3133  (declare (ignorable x))
3134  (inherit-output-translations inherit :collect collect))
3135(defmethod process-output-translations ((form cons) &key inherit collect)
3136  (dolist (directive (cdr (validate-output-translations-form form)))
3137    (process-output-translations-directive directive :inherit inherit :collect collect)))
3138
3139(defun* inherit-output-translations (inherit &key collect)
3140  (when inherit
3141    (process-output-translations (first inherit) :collect collect :inherit (rest inherit))))
3142
3143(defun* process-output-translations-directive (directive &key inherit collect)
3144  (if (atom directive)
3145      (ecase directive
3146        ((:enable-user-cache)
3147         (process-output-translations-directive '(t :user-cache) :collect collect))
3148        ((:disable-cache)
3149         (process-output-translations-directive '(t t) :collect collect))
3150        ((:inherit-configuration)
3151         (inherit-output-translations inherit :collect collect))
3152        ((:ignore-inherited-configuration :ignore-invalid-entries nil)
3153         nil))
3154      (let ((src (first directive))
3155            (dst (second directive)))
3156        (if (eq src :include)
3157            (when dst
3158              (process-output-translations (pathname dst) :inherit nil :collect collect))
3159            (when src
3160              (let ((trusrc (or (eql src t)
3161                                (let ((loc (resolve-location src :directory t :wilden t)))
3162                                  (if (absolute-pathname-p loc) (truenamize loc) loc)))))
3163                (cond
3164                  ((location-function-p dst)
3165                   (funcall collect
3166                            (list trusrc
3167                                  (if (symbolp (second dst))
3168                                      (fdefinition (second dst))
3169                                      (eval (second dst))))))
3170                  ((eq dst t)
3171                   (funcall collect (list trusrc t)))
3172                  (t
3173                   (let* ((trudst (make-pathname
3174                                   :defaults (if dst (resolve-location dst :directory t :wilden t) trusrc)))
3175                          (wilddst (merge-pathnames* *wild-file* trudst)))
3176                     (funcall collect (list wilddst t))
3177                     (funcall collect (list trusrc trudst)))))))))))
3178
3179(defun* compute-output-translations (&optional parameter)
3180  "read the configuration, return it"
3181  (remove-duplicates
3182   (while-collecting (c)
3183     (inherit-output-translations
3184      `(wrapping-output-translations ,parameter ,@*default-output-translations*) :collect #'c))
3185   :test 'equal :from-end t))
3186
3187(defvar *output-translations-parameter* nil)
3188
3189(defun* initialize-output-translations (&optional (parameter *output-translations-parameter*))
3190  "read the configuration, initialize the internal configuration variable,
3191return the configuration"
3192  (setf *output-translations-parameter* parameter
3193        (output-translations) (compute-output-translations parameter)))
3194
3195(defun* disable-output-translations ()
3196  "Initialize output translations in a way that maps every file to itself,
3197effectively disabling the output translation facility."
3198  (initialize-output-translations
3199   '(:output-translations :disable-cache :ignore-inherited-configuration)))
3200
3201;; checks an initial variable to see whether the state is initialized
3202;; or cleared. In the former case, return current configuration; in
3203;; the latter, initialize.  ASDF will call this function at the start
3204;; of (asdf:find-system).
3205(defun* ensure-output-translations ()
3206  (if (output-translations-initialized-p)
3207      (output-translations)
3208      (initialize-output-translations)))
3209
3210(defun* translate-pathname* (path absolute-source destination &optional root source)
3211  (declare (ignore source))
3212  (cond
3213    ((functionp destination)
3214     (funcall destination path absolute-source))
3215    ((eq destination t)
3216     path)
3217    ((not (pathnamep destination))
3218     (error "invalid destination"))
3219    ((not (absolute-pathname-p destination))
3220     (translate-pathname path absolute-source (merge-pathnames* destination root)))
3221    (root
3222     (translate-pathname (directorize-pathname-host-device path) absolute-source destination))
3223    (t
3224     (translate-pathname path absolute-source destination))))
3225
3226(defun* apply-output-translations (path)
3227  (etypecase path
3228    (logical-pathname
3229     path)
3230    ((or pathname string)
3231     (ensure-output-translations)
3232     (loop :with p = (truenamize path)
3233       :for (source destination) :in (car *output-translations*)
3234       :for root = (when (or (eq source t)
3235                             (and (pathnamep source)
3236                                  (not (absolute-pathname-p source))))
3237                     (pathname-root p))
3238       :for absolute-source = (cond
3239                                ((eq source t) (wilden root))
3240                                (root (merge-pathnames* source root))
3241                                (t source))
3242       :when (or (eq source t) (pathname-match-p p absolute-source))
3243       :return (translate-pathname* p absolute-source destination root source)
3244       :finally (return p)))))
3245
3246(defmethod output-files :around (operation component)
3247  "Translate output files, unless asked not to"
3248  (declare (ignorable operation component))
3249  (values
3250   (multiple-value-bind (files fixedp) (call-next-method)
3251     (if fixedp
3252         files
3253         (mapcar #'apply-output-translations files)))
3254   t))
3255
3256(defun* compile-file-pathname* (input-file &rest keys &key output-file &allow-other-keys)
3257  (or output-file
3258      (apply-output-translations
3259       (apply 'compile-file-pathname
3260              (truenamize (lispize-pathname input-file))
3261              keys))))
3262
3263(defun* tmpize-pathname (x)
3264  (make-pathname
3265   :name (format nil "ASDF-TMP-~A" (pathname-name x))
3266   :defaults x))
3267
3268(defun* delete-file-if-exists (x)
3269  (when (and x (probe-file* x))
3270    (delete-file x)))
3271
3272(defun* compile-file* (input-file &rest keys &key output-file &allow-other-keys)
3273  (let* ((output-file (or output-file (apply 'compile-file-pathname* input-file keys)))
3274         (tmp-file (tmpize-pathname output-file))
3275         (status :error))
3276    (multiple-value-bind (output-truename warnings-p failure-p)
3277        (apply 'compile-file input-file :output-file tmp-file keys)
3278      (cond
3279        (failure-p
3280         (setf status *compile-file-failure-behaviour*))
3281        (warnings-p
3282         (setf status *compile-file-warnings-behaviour*))
3283        (t
3284         (setf status :success)))
3285      (ecase status
3286        ((:success :warn :ignore)
3287         (delete-file-if-exists output-file)
3288         (when output-truename
3289           (rename-file output-truename output-file)
3290           (setf output-truename output-file)))
3291        (:error
3292         (delete-file-if-exists output-truename)
3293         (setf output-truename nil)))
3294      (values output-truename warnings-p failure-p))))
3295
3296#+abcl
3297(defun* translate-jar-pathname (source wildcard)
3298  (declare (ignore wildcard))
3299  (let* ((p (pathname (first (pathname-device source))))
3300         (root (format nil "/___jar___file___root___/~@[~A/~]"
3301                       (and (find :windows *features*)
3302                            (pathname-device p)))))
3303    (apply-output-translations
3304     (merge-pathnames*
3305      (relativize-pathname-directory source)
3306      (merge-pathnames*
3307       (relativize-pathname-directory (ensure-directory-pathname p))
3308       root)))))
3309
3310;;;; -----------------------------------------------------------------
3311;;;; Compatibility mode for ASDF-Binary-Locations
3312
3313(defmethod operate :before (operation-class system &rest args &key &allow-other-keys)
3314  (declare (ignorable operation-class system args))
3315  (when (find-symbol* '#:output-files-for-system-and-operation :asdf)
3316    (error "ASDF 2 is not compatible with ASDF-BINARY-LOCATIONS, which you are using.
3317ASDF 2 now achieves the same purpose with its builtin ASDF-OUTPUT-TRANSLATIONS,
3318which should be easier to configure. Please stop using ASDF-BINARY-LOCATIONS,
3319and instead use ASDF-OUTPUT-TRANSLATIONS. See the ASDF manual for details.
3320In case you insist on preserving your previous A-B-L configuration, but
3321do not know how to achieve the same effect with A-O-T, you may use function
3322ASDF:ENABLE-ASDF-BINARY-LOCATIONS-COMPATIBILITY as documented in the manual;
3323call that function where you would otherwise have loaded and configured A-B-L.")))
3324
3325(defun* enable-asdf-binary-locations-compatibility
3326    (&key
3327     (centralize-lisp-binaries nil)
3328     (default-toplevel-directory
3329         ;; Use ".cache/common-lisp" instead ???
3330         (merge-pathnames* (make-pathname :directory '(:relative ".fasls"))
3331                           (user-homedir)))
3332     (include-per-user-information nil)
3333     (map-all-source-files (or #+(or ecl clisp) t nil))
3334     (source-to-target-mappings nil))
3335  #+(or ecl clisp)
3336  (when (null map-all-source-files)
3337    (error "asdf:enable-asdf-binary-locations-compatibility doesn't support :map-all-source-files nil on ECL and CLISP"))
3338  (let* ((fasl-type (pathname-type (compile-file-pathname "foo.lisp")))
3339         (mapped-files (if map-all-source-files *wild-file*
3340                           (make-pathname :name :wild :version :wild :type fasl-type)))
3341         (destination-directory
3342          (if centralize-lisp-binaries
3343              `(,default-toplevel-directory
3344                ,@(when include-per-user-information
3345                        (cdr (pathname-directory (user-homedir))))
3346                :implementation ,*wild-inferiors*)
3347              `(:root ,*wild-inferiors* :implementation))))
3348    (initialize-output-translations
3349     `(:output-translations
3350       ,@source-to-target-mappings
3351       ((:root ,*wild-inferiors* ,mapped-files)
3352        (,@destination-directory ,mapped-files))
3353       (t t)
3354       :ignore-inherited-configuration))))
3355
3356;;;; -----------------------------------------------------------------
3357;;;; Windows shortcut support.  Based on:
3358;;;;
3359;;;; Jesse Hager: The Windows Shortcut File Format.
3360;;;; http://www.wotsit.org/list.asp?fc=13
3361
3362#+(and asdf-windows (not clisp))
3363(progn
3364(defparameter *link-initial-dword* 76)
3365(defparameter *link-guid* #(1 20 2 0 0 0 0 0 192 0 0 0 0 0 0 70))
3366
3367(defun* read-null-terminated-string (s)
3368  (with-output-to-string (out)
3369    (loop :for code = (read-byte s)
3370      :until (zerop code)
3371      :do (write-char (code-char code) out))))
3372
3373(defun* read-little-endian (s &optional (bytes 4))
3374  (loop
3375    :for i :from 0 :below bytes
3376    :sum (ash (read-byte s) (* 8 i))))
3377
3378(defun* parse-file-location-info (s)
3379  (let ((start (file-position s))
3380        (total-length (read-little-endian s))
3381        (end-of-header (read-little-endian s))
3382        (fli-flags (read-little-endian s))
3383        (local-volume-offset (read-little-endian s))
3384        (local-offset (read-little-endian s))
3385        (network-volume-offset (read-little-endian s))
3386        (remaining-offset (read-little-endian s)))
3387    (declare (ignore total-length end-of-header local-volume-offset))
3388    (unless (zerop fli-flags)
3389      (cond
3390        ((logbitp 0 fli-flags)
3391          (file-position s (+ start local-offset)))
3392        ((logbitp 1 fli-flags)
3393          (file-position s (+ start
3394                              network-volume-offset
3395                              #x14))))
3396      (concatenate 'string
3397        (read-null-terminated-string s)
3398        (progn
3399          (file-position s (+ start remaining-offset))
3400          (read-null-terminated-string s))))))
3401
3402(defun* parse-windows-shortcut (pathname)
3403  (with-open-file (s pathname :element-type '(unsigned-byte 8))
3404    (handler-case
3405        (when (and (= (read-little-endian s) *link-initial-dword*)
3406                   (let ((header (make-array (length *link-guid*))))
3407                     (read-sequence header s)
3408                     (equalp header *link-guid*)))
3409          (let ((flags (read-little-endian s)))
3410            (file-position s 76)        ;skip rest of header
3411            (when (logbitp 0 flags)
3412              ;; skip shell item id list
3413              (let ((length (read-little-endian s 2)))
3414                (file-position s (+ length (file-position s)))))
3415            (cond
3416              ((logbitp 1 flags)
3417                (parse-file-location-info s))
3418              (t
3419                (when (logbitp 2 flags)
3420                  ;; skip description string
3421                  (let ((length (read-little-endian s 2)))
3422                    (file-position s (+ length (file-position s)))))
3423                (when (logbitp 3 flags)
3424                  ;; finally, our pathname
3425                  (let* ((length (read-little-endian s 2))
3426                         (buffer (make-array length)))
3427                    (read-sequence buffer s)
3428                    (map 'string #'code-char buffer)))))))
3429      (end-of-file ()
3430        nil)))))
3431
3432;;;; -----------------------------------------------------------------
3433;;;; Source Registry Configuration, by Francois-Rene Rideau
3434;;;; See the Manual and https://bugs.launchpad.net/asdf/+bug/485918
3435
3436;; Using ack 1.2 exclusions
3437(defvar *default-source-registry-exclusions*
3438  '(".bzr" ".cdv"
3439    ;; "~.dep" "~.dot" "~.nib" "~.plst" ; we don't support ack wildcards
3440    ".git" ".hg" ".pc" ".svn" "CVS" "RCS" "SCCS" "_darcs"
3441    "_sgbak" "autom4te.cache" "cover_db" "_build"
3442    "debian")) ;; debian often build stuff under the debian directory... BAD.
3443
3444(defvar *source-registry-exclusions* *default-source-registry-exclusions*)
3445
3446(defvar *source-registry* ()
3447  "Either NIL (for uninitialized), or a list of one element,
3448said element itself being a list of directory pathnames where to look for .asd files")
3449
3450(defun* source-registry ()
3451  (car *source-registry*))
3452
3453(defun* (setf source-registry) (new-value)
3454  (setf *source-registry* (list new-value))
3455  new-value)
3456
3457(defun* source-registry-initialized-p ()
3458  (and *source-registry* t))
3459
3460(defun* clear-source-registry ()
3461  "Undoes any initialization of the source registry.
3462You might want to call that before you dump an image that would be resumed
3463with a different configuration, so the configuration would be re-read then."
3464  (setf *source-registry* '())
3465  (values))
3466
3467(defparameter *wild-asd*
3468  (make-pathname :directory nil :name :wild :type "asd" :version :newest))
3469
3470(defun directory-has-asd-files-p (directory)
3471  (ignore-errors
3472    (and (directory* (merge-pathnames* *wild-asd* directory)) t)))
3473
3474(defun subdirectories (directory)
3475  (let* ((directory (ensure-directory-pathname directory))
3476         #-(or cormanlisp genera)
3477         (wild (merge-pathnames*
3478                #-(or abcl allegro lispworks scl)
3479                *wild-directory*
3480                #+(or abcl allegro lispworks scl) "*.*"
3481                directory))
3482         (dirs
3483          #-(or cormanlisp genera)
3484          (ignore-errors
3485            (directory* wild . #.(or #+clozure '(:directories t :files nil)
3486                                     #+mcl '(:directories t))))
3487          #+cormanlisp (cl::directory-subdirs directory)
3488          #+genera (fs:directory-list directory))
3489         #+(or abcl allegro genera lispworks scl)
3490         (dirs (remove-if-not #+abcl #'extensions:probe-directory
3491                              #+allegro #'excl:probe-directory
3492                              #+lispworks #'lw:file-directory-p
3493                              #+genera #'(lambda (x) (getf (cdr x) :directory))
3494                              #-(or abcl allegro genera lispworks) #'directory-pathname-p
3495                              dirs))
3496         #+genera
3497         (dirs (mapcar #'(lambda (x) (ensure-directory-pathname (first x))) dirs)))
3498    dirs))
3499
3500(defun collect-sub*directories (directory collectp recursep collector)
3501  (when (funcall collectp directory)
3502    (funcall collector directory))
3503  (dolist (subdir (subdirectories directory))
3504    (when (funcall recursep subdir)
3505      (collect-sub*directories subdir collectp recursep collector))))
3506
3507(defun collect-sub*directories-with-asd
3508    (directory &key
3509     (exclude *default-source-registry-exclusions*)
3510     collect)
3511  (collect-sub*directories
3512   directory
3513   #'directory-has-asd-files-p
3514   #'(lambda (x) (not (member (car (last (pathname-directory x))) exclude :test #'equal)))
3515   collect))
3516
3517(defun* validate-source-registry-directive (directive)
3518  (or (member directive '(:default-registry))
3519      (and (consp directive)
3520           (let ((rest (rest directive)))
3521             (case (first directive)
3522               ((:include :directory :tree)
3523                (and (length=n-p rest 1)
3524                     (location-designator-p (first rest))))
3525               ((:exclude :also-exclude)
3526                (every #'stringp rest))
3527               ((:default-registry)
3528                (null rest)))))))
3529
3530(defun* validate-source-registry-form (form &key location)
3531  (validate-configuration-form
3532   form :source-registry 'validate-source-registry-directive
3533   :location location :invalid-form-reporter 'invalid-source-registry))
3534
3535(defun* validate-source-registry-file (file)
3536  (validate-configuration-file
3537   file 'validate-source-registry-form :description "a source registry"))
3538
3539(defun* validate-source-registry-directory (directory)
3540  (validate-configuration-directory
3541   directory :source-registry 'validate-source-registry-directive
3542   :invalid-form-reporter 'invalid-source-registry))
3543
3544(defun* parse-source-registry-string (string &key location)
3545  (cond
3546    ((or (null string) (equal string ""))
3547     '(:source-registry :inherit-configuration))
3548    ((not (stringp string))
3549     (error "environment string isn't: ~S" string))
3550    ((find (char string 0) "\"(")
3551     (validate-source-registry-form (read-from-string string) :location location))
3552    (t
3553     (loop
3554      :with inherit = nil
3555      :with directives = ()
3556      :with start = 0
3557      :with end = (length string)
3558      :for pos = (position *inter-directory-separator* string :start start) :do
3559      (let ((s (subseq string start (or pos end))))
3560        (cond
3561         ((equal "" s) ; empty element: inherit
3562          (when inherit
3563            (error "only one inherited configuration allowed: ~S" string))
3564          (setf inherit t)
3565          (push ':inherit-configuration directives))
3566         ((ends-with s "//")
3567          (push `(:tree ,(subseq s 0 (1- (length s)))) directives))
3568         (t
3569          (push `(:directory ,s) directives)))
3570        (cond
3571          (pos
3572           (setf start (1+ pos)))
3573          (t
3574           (unless inherit
3575             (push '(:ignore-inherited-configuration) directives))
3576           (return `(:source-registry ,@(nreverse directives))))))))))
3577
3578(defun* register-asd-directory (directory &key recurse exclude collect)
3579  (if (not recurse)
3580      (funcall collect directory)
3581      (collect-sub*directories-with-asd
3582       directory :exclude exclude :collect collect)))
3583
3584(defparameter *default-source-registries*
3585  '(environment-source-registry
3586    user-source-registry
3587    user-source-registry-directory
3588    system-source-registry
3589    system-source-registry-directory
3590    default-source-registry))
3591
3592(defparameter *source-registry-file* (coerce-pathname "source-registry.conf"))
3593(defparameter *source-registry-directory* (coerce-pathname "source-registry.conf.d/"))
3594
3595(defun* wrapping-source-registry ()
3596  `(:source-registry
3597    #+sbcl (:tree ,(truenamize (getenv "SBCL_HOME")))
3598    :inherit-configuration
3599    #+cmu (:tree #p"modules:")))
3600(defun* default-source-registry ()
3601  (flet ((try (x sub) (try-directory-subpath x sub :type :directory)))
3602    `(:source-registry
3603      #+sbcl (:directory ,(merge-pathnames* ".sbcl/systems/" (user-homedir)))
3604      (:directory ,(default-directory))
3605      ,@(let*
3606         #+asdf-unix
3607         ((datahome
3608           (or (getenv "XDG_DATA_HOME")
3609               (try (user-homedir) ".local/share/")))
3610          (datadirs
3611           (or (getenv "XDG_DATA_DIRS") "/usr/local/share:/usr/share"))
3612          (dirs (cons datahome (split-string datadirs :separator ":"))))
3613         #+asdf-windows
3614         ((datahome (getenv "APPDATA"))
3615          (datadir
3616           #+lispworks (sys:get-folder-path :local-appdata)
3617           #-lispworks (try (getenv "ALLUSERSPROFILE")
3618                            "Application Data"))
3619          (dirs (list datahome datadir)))
3620         #-(or asdf-unix asdf-windows)
3621         ((dirs ()))
3622         (loop :for dir :in dirs
3623           :collect `(:directory ,(try dir "common-lisp/systems/"))
3624           :collect `(:tree ,(try dir "common-lisp/source/"))))
3625      :inherit-configuration)))
3626(defun* user-source-registry ()
3627  (in-user-configuration-directory *source-registry-file*))
3628(defun* system-source-registry ()
3629  (in-system-configuration-directory *source-registry-file*))
3630(defun* user-source-registry-directory ()
3631  (in-user-configuration-directory *source-registry-directory*))
3632(defun* system-source-registry-directory ()
3633  (in-system-configuration-directory *source-registry-directory*))
3634(defun* environment-source-registry ()
3635  (getenv "CL_SOURCE_REGISTRY"))
3636
3637(defgeneric* process-source-registry (spec &key inherit register))
3638(declaim (ftype (function (t &key (:register (or symbol function))) t)
3639                inherit-source-registry))
3640(declaim (ftype (function (t &key (:register (or symbol function)) (:inherit list)) t)
3641                process-source-registry-directive))
3642
3643(defmethod process-source-registry ((x symbol) &key inherit register)
3644  (process-source-registry (funcall x) :inherit inherit :register register))
3645(defmethod process-source-registry ((pathname pathname) &key inherit register)
3646  (cond
3647    ((directory-pathname-p pathname)
3648     (let ((*here-directory* (truenamize pathname)))
3649       (process-source-registry (validate-source-registry-directory pathname)
3650                                :inherit inherit :register register)))
3651    ((probe-file* pathname)
3652     (let ((*here-directory* (pathname-directory-pathname pathname)))
3653       (process-source-registry (validate-source-registry-file pathname)
3654                                :inherit inherit :register register)))
3655    (t
3656     (inherit-source-registry inherit :register register))))
3657(defmethod process-source-registry ((string string) &key inherit register)
3658  (process-source-registry (parse-source-registry-string string)
3659                           :inherit inherit :register register))
3660(defmethod process-source-registry ((x null) &key inherit register)
3661  (declare (ignorable x))
3662  (inherit-source-registry inherit :register register))
3663(defmethod process-source-registry ((form cons) &key inherit register)
3664  (let ((*source-registry-exclusions* *default-source-registry-exclusions*))
3665    (dolist (directive (cdr (validate-source-registry-form form)))
3666      (process-source-registry-directive directive :inherit inherit :register register))))
3667
3668(defun* inherit-source-registry (inherit &key register)
3669  (when inherit
3670    (process-source-registry (first inherit) :register register :inherit (rest inherit))))
3671
3672(defun* process-source-registry-directive (directive &key inherit register)
3673  (destructuring-bind (kw &rest rest) (if (consp directive) directive (list directive))
3674    (ecase kw
3675      ((:include)
3676       (destructuring-bind (pathname) rest
3677         (process-source-registry (resolve-location pathname) :inherit nil :register register)))
3678      ((:directory)
3679       (destructuring-bind (pathname) rest
3680         (when pathname
3681           (funcall register (resolve-location pathname :directory t)))))
3682      ((:tree)
3683       (destructuring-bind (pathname) rest
3684         (when pathname
3685           (funcall register (resolve-location pathname :directory t)
3686                    :recurse t :exclude *source-registry-exclusions*))))
3687      ((:exclude)
3688       (setf *source-registry-exclusions* rest))
3689      ((:also-exclude)
3690       (appendf *source-registry-exclusions* rest))
3691      ((:default-registry)
3692       (inherit-source-registry '(default-source-registry) :register register))
3693      ((:inherit-configuration)
3694       (inherit-source-registry inherit :register register))
3695      ((:ignore-inherited-configuration)
3696       nil)))
3697  nil)
3698
3699(defun* flatten-source-registry (&optional parameter)
3700  (remove-duplicates
3701   (while-collecting (collect)
3702     (let ((*default-pathname-defaults* (default-directory)))
3703       (inherit-source-registry
3704        `(wrapping-source-registry
3705          ,parameter
3706          ,@*default-source-registries*)
3707        :register #'(lambda (directory &key recurse exclude)
3708                      (collect (list directory :recurse recurse :exclude exclude)))))
3709     :test 'equal :from-end t)))
3710
3711;; Will read the configuration and initialize all internal variables,
3712;; and return the new configuration.
3713(defun* compute-source-registry (&optional parameter)
3714  (while-collecting (collect)
3715    (dolist (entry (flatten-source-registry parameter))
3716      (destructuring-bind (directory &key recurse exclude) entry
3717        (register-asd-directory
3718         directory
3719         :recurse recurse :exclude exclude :collect #'collect)))))
3720
3721(defvar *source-registry-parameter* nil)
3722
3723(defun* initialize-source-registry (&optional (parameter *source-registry-parameter*))
3724  (setf *source-registry-parameter* parameter
3725        (source-registry) (compute-source-registry parameter)))
3726
3727;; Checks an initial variable to see whether the state is initialized
3728;; or cleared. In the former case, return current configuration; in
3729;; the latter, initialize.  ASDF will call this function at the start
3730;; of (asdf:find-system) to make sure the source registry is initialized.
3731;; However, it will do so *without* a parameter, at which point it
3732;; will be too late to provide a parameter to this function, though
3733;; you may override the configuration explicitly by calling
3734;; initialize-source-registry directly with your parameter.
3735(defun* ensure-source-registry (&optional parameter)
3736  (if (source-registry-initialized-p)
3737      (source-registry)
3738      (initialize-source-registry parameter)))
3739
3740(defun* sysdef-source-registry-search (system)
3741  (ensure-source-registry)
3742  (loop :with name = (coerce-name system)
3743    :for defaults :in (source-registry)
3744    :for file = (probe-asd name defaults)
3745    :when file :return file))
3746
3747(defun* clear-configuration ()
3748  (clear-source-registry)
3749  (clear-output-translations))
3750
3751;;;; -----------------------------------------------------------------
3752;;;; Hook into REQUIRE for ABCL, CLISP, ClozureCL, CMUCL, ECL and SBCL
3753;;;;
3754(defun* module-provide-asdf (name)
3755  (handler-bind
3756      ((style-warning #'muffle-warning)
3757       (missing-component (constantly nil))
3758       (error #'(lambda (e)
3759                  (errfmt *error-output* "ASDF could not load ~(~A~) because ~A.~%"
3760                          name e))))
3761    (let* ((*verbose-out* (make-broadcast-stream))
3762           (system (find-system (string-downcase name) nil)))
3763      (when system
3764        (load-system system)
3765        t))))
3766
3767#+(or abcl clisp clozure cmu ecl sbcl)
3768(let ((x (and #+clisp (find-symbol* '#:*module-provider-functions* :custom))))
3769  (when x
3770    (eval `(pushnew 'module-provide-asdf
3771            #+abcl sys::*module-provider-functions*
3772            #+clisp ,x
3773            #+clozure ccl:*module-provider-functions*
3774            #+cmu ext:*module-provider-functions*
3775            #+ecl si:*module-provider-functions*
3776            #+sbcl sb-ext:*module-provider-functions*))))
3777
3778
3779;;;; -------------------------------------------------------------------------
3780;;;; Cleanups after hot-upgrade.
3781;;;; Things to do in case we're upgrading from a previous version of ASDF.
3782;;;; See https://bugs.launchpad.net/asdf/+bug/485687
3783;;;;
3784
3785;;; If a previous version of ASDF failed to read some configuration, try again.
3786(when *ignored-configuration-form*
3787  (clear-configuration)
3788  (setf *ignored-configuration-form* nil))
3789
3790;;;; -----------------------------------------------------------------
3791;;;; Done!
3792(when *load-verbose*
3793  (asdf-message ";; ASDF, version ~a~%" (asdf-version)))
3794
3795#+allegro
3796(eval-when (:compile-toplevel :execute)
3797  (when (boundp 'excl:*warn-on-nested-reader-conditionals*)
3798    (setf excl:*warn-on-nested-reader-conditionals* *acl-warn-save*)))
3799
3800(pushnew :asdf *features*)
3801(pushnew :asdf2 *features*)
3802
3803(provide :asdf)
3804
3805;;; Local Variables:
3806;;; mode: lisp
3807;;; End:
Note: See TracBrowser for help on using the repository browser.