source: trunk/source/objc-bridge/objc-support.lisp @ 14698

Last change on this file since 14698 was 14698, checked in by gb, 9 years ago

In LISP-STRING-FROM-NSSTRING, allow the NSString to contain embedded
#\NUL characters.

Fixes ticket:838.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 25.7 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2
3(in-package "CCL")
4
5(eval-when (:compile-toplevel :load-toplevel :execute)
6  (require "BRIDGE"))
7
8(defun allocate-objc-object (class)
9  (#/alloc class))
10
11(defun conforms-to-protocol (thing protocol)
12  (#/conformsToProtocol: thing (objc-protocol-address protocol)))
13
14
15
16
17#+(or apple-objc cocotron-objc)
18(defun iterate-over-objc-classes (fn)
19  (let* ((n (#_objc_getClassList (%null-ptr) 0)))
20    (declare (fixnum n))
21    (%stack-block ((buffer (the fixnum (ash n target::word-shift))))
22      (#_objc_getClassList buffer n)
23      (do* ((i 0 (1+ i)))
24           ((= i n) (values))
25        (declare (fixnum i))
26        (funcall fn (paref buffer (:* :id) i))))))
27
28#+(or apple-objc cocotron-objc)
29(defun count-objc-classes ()
30  (#_objc_getClassList (%null-ptr) 0)) 
31
32#+gnu-objc
33(defun iterate-over-objc-classes (fn)
34  (rletZ ((enum-state :address))
35    (loop
36      (let* ((class (#_objc_next_class enum-state)))
37        (if (%null-ptr-p class)
38          (return)
39          (funcall fn class))))))
40
41#+gnu-objc
42(defun count-objc-classes ()
43  (let* ((n 0))
44    (declare (fixnum n))
45    (rletZ ((enum-state :address))
46      (if (%null-ptr-p (#_objc_next_class enum-state))
47        (return n)
48        (incf n)))))
49
50
51(defun %note-protocol (p)
52  ;; In Cocotron (which is ultimately based on the GNU ObjC runtime),
53  ;; it may be the case that some Protocol objects aren't fully initialized
54  ;; when this code runs, hence the sleazy use of PREF here.
55  (with-macptrs ((cname #+cocotron-objc (pref p #>Protocol.nameCString)
56                        #-cocotron-objc (objc-message-send p "name" :address)))
57    (let* ((namelen (%cstrlen cname))
58           (name (make-string namelen)))
59      (declare (dynamic-extent name))
60      (%str-from-ptr cname namelen name)
61      (let* ((proto (or (gethash name *objc-protocols*)
62                        (progn
63                          (setq name (subseq name 0))
64                          (setf (gethash name *objc-protocols*)
65                                (make-objc-protocol :name name))))))
66        (unless (objc-protocol-address proto)
67          (setf (objc-protocol-address proto) (%inc-ptr p 0)))
68        proto))))
69
70(defun note-class-protocols (class)
71  #-(or apple-objc-2.0)
72  (do* ((protocols (pref class :objc_class.protocols)
73                   (pref protocols :objc_protocol_list.next)))
74       ((%null-ptr-p protocols))
75    (let* ((count (pref protocols :objc_protocol_list.count)))
76      (with-macptrs ((list (pref protocols :objc_protocol_list.list)))
77        (dotimes (i count)
78          (with-macptrs ((p (paref list (:* (:* (:struct :<P>rotocol))) i)))
79            (%note-protocol p))))))
80  #+(or apple-objc-2.0)
81  (rlet ((p-out-count :int 0))
82    (with-macptrs ((protocols (#_class_copyProtocolList class p-out-count)))
83      (let* ((n (pref p-out-count :int)))
84        (dotimes (i n)
85          (with-macptrs ((p (paref protocols (:* (:* (:struct :<P>rotocol))) i)))
86            (%note-protocol p))))
87      (unless (%null-ptr-p protocols) (#_free protocols)))))
88           
89
90(defun map-objc-classes (&optional (lookup-in-database-p t))
91  (iterate-over-objc-classes
92   #'(lambda (class)
93       (note-class-protocols class)
94       (install-foreign-objc-class class lookup-in-database-p))))
95
96(let* ((nclasses 0)
97       (lock (make-lock)))
98  (declare (fixnum nclasses))
99  (defun maybe-map-objc-classes (&optional use-db)
100    (with-lock-grabbed (lock)
101      (let* ((new (count-objc-classes)))
102        (declare (fixnum new))
103        (unless (= nclasses new)
104          (setq nclasses new)
105          (map-objc-classes use-db))
106        t)))
107  (defun reset-objc-class-count ()
108    (with-lock-grabbed (lock)
109      (setq nclasses 0))))
110
111(register-objc-class-decls)
112(maybe-map-objc-classes t)
113
114
115(defvar *class-init-keywords* (make-hash-table :test #'eq))
116
117(defun process-init-message (message-info)
118  (let* ((keys (objc-to-lisp-init (objc-message-info-message-name message-info))))
119    (when keys
120      (let* ((keyinfo (cons keys (objc-message-info-lisp-name message-info))))
121        (dolist (method (objc-message-info-methods message-info))
122          (when (and (eq :id (objc-method-info-result-type method))
123                     (let* ((flags (objc-method-info-flags method)))
124                       (not (or (memq :class flags)
125                                (memq :protocol flags)))))
126            (let* ((class (canonicalize-registered-class
127                           (find-objc-class (objc-method-info-class-name method)))))
128              (pushnew keyinfo (gethash class *class-init-keywords*)
129                       :test #'equal))))))))
130
131(register-objc-init-messages)
132(register-objc-set-messages)
133
134
135
136
137
138(defun all-init-keywords-for-class (c)
139  (let* ((keyinfo ()))
140    (dolist (class (class-precedence-list c))
141      (when (eq class ns:ns-object)
142        (return keyinfo))
143      (dolist (class-keys (gethash class *class-init-keywords*))
144        (pushnew class-keys keyinfo :test #'equal)))))
145
146(defun send-init-message-for-class (class initargs)
147  (let* ((all-keywords-for-class (all-init-keywords-for-class class)))
148    (multiple-value-bind (initfunction args)
149        (if all-keywords-for-class
150          (let* ((candidate-functions ())
151                 (candidate-arglists ())
152                 (missing-keyword (cons nil nil)))
153            (declare (dynamic-extent missing-keyword))
154            (dolist (keys-and-function all-keywords-for-class)
155              (collect ((arglist))
156                (destructuring-bind (keys . function) keys-and-function
157                  (dolist (key keys (progn (push function candidate-functions)
158                                           (push (arglist) candidate-arglists)))
159                    (let* ((val (getf initargs key missing-keyword)))
160                      (if (eq missing-keyword val)
161                        (return)
162                        (arglist val)))))))
163            (if candidate-functions
164              (if (null (cdr candidate-functions))
165                (values (car candidate-functions) (car candidate-arglists))
166                ;; Pick the longest match, if that's unique.  If there's
167                ;; no unique longest match, complain.
168                (let* ((maxlen 0)
169                       (maxfun ())
170                       (maxargs ())
171                       (duplicate-match nil))
172                  (declare (fixnum maxlen))
173                  (do* ((functions candidate-functions (cdr functions))
174                        (arglists candidate-arglists (cdr arglists)))
175                       ((null functions)
176                        (if duplicate-match
177                          (values nil nil)
178                          (values maxfun maxargs)))
179                    (let* ((arglist (car arglists))
180                           (n (length arglist)))
181                      (declare (fixnum n))
182                      (if (> n maxlen)
183                        (setq maxlen n
184                              duplicate-match nil
185                              maxargs arglist
186                              maxfun (car functions))
187                        (if (= n maxlen)
188                          (setq duplicate-match t)))))))
189              (values '#/init nil)))
190          (values '#/init nil))
191      (if initfunction
192        (let* ((instance (apply initfunction (#/alloc class) args)))
193          (ensure-lisp-slots instance class)
194          instance)
195        (error "Can't determine ObjC init function for class ~s and initargs ~s." class initargs)))))
196
197#+gnu-objc
198(defun iterate-over-class-methods (class method-function)
199  (do* ((mlist (pref class :objc_class.methods)
200               (pref mlist :objc_method_list.method_next)))
201       ((%null-ptr-p mlist))
202    (do* ((n (pref mlist :objc_method_list.method_count))
203          (i 0 (1+ i))
204          (method (pref mlist :objc_method_list.method_list)
205                  (%incf-ptr method (record-length :objc_method))))
206         ((= i n))
207      (declare (fixnum i n))
208      (funcall method-function method class))))
209
210#+gnu-objc
211(progn
212  ;; Er, um ... this needs lots-o-work.
213  (let* ((objc-class-count 0))
214    (defun reset-objc-class-count () (setq objc-class-count 0))
215    (defun note-all-library-methods (method-function)
216      (do* ((i objc-class-count (1+ i))
217            (class (id->objc-class i) (id->objc-class i)))
218           ((eq class 0))
219        (iterate-over-class-methods class method-function)
220        (iterate-over-class-methods (id->objc-metaclass i) method-function))))
221  (def-ccl-pointers revive-objc-classes ()
222    (reset-objc-class-count)))
223
224
225
226#+apple-objc-2.0
227(progn
228(defun setup-objc-exception-globals ()
229  (flet ((set-global (offset name)
230           (setf (%get-ptr (%int-to-ptr (+ (target-nil-value) (%kernel-global-offset offset))))
231                 (foreign-symbol-address name))))
232    (set-global 'objc-2-personality "___objc_personality_v0")
233    (set-global 'objc-2-begin-catch "objc_begin_catch")
234    (set-global 'objc-2-end-catch "objc_end_catch")
235    (set-global 'unwind-resume "__Unwind_Resume")))
236
237
238(def-ccl-pointers setup-objc-exception-handling ()
239  (setup-objc-exception-globals))
240
241(setup-objc-exception-globals)
242)
243
244
245(defvar *condition-id-map* (make-id-map) "Map lisp conditions to small integers")
246
247;;; Encapsulate an NSException in a lisp condition.
248(define-condition ns-exception (error)
249  ((ns-exception :initarg :ns-exception :accessor ns-exception))
250  (:report (lambda (c s)
251             (format s "Objective-C runtime exception: ~&~a"
252                     (nsobject-description (ns-exception c))))))
253
254(defun ensure-dealloc-method-for-class (class)
255  (let* ((direct-slots (class-direct-slots class))
256         (effective-slots (class-slots class)))
257    (when (and (dolist (d direct-slots)
258                 (when (and (typep d 'standard-direct-slot-definition)
259                            (eq :instance (slot-definition-allocation d)))
260                   (return t)))
261               (dolist (e effective-slots t)
262                 (when (and (typep e 'standard-effective-slot-definition)
263                            (eq :instance (slot-definition-allocation e))
264                            (not (find (slot-definition-name e)
265                                       direct-slots
266                                         :key #'slot-definition-name
267                                         :test #'eq)))
268                   (return))))
269      (eval `(objc:defmethod (#/dealloc :void) ((self ,(class-name class)))
270              (objc:remove-lisp-slots self)
271              (call-next-method))))))
272
273(eval-when (:compile-toplevel :execute)
274  (declaim (ftype (function (&rest t) t) objc-callback-error-return)))
275
276(defclass ns-lisp-exception (ns::ns-exception)
277    ((condition :initarg :condition :initform nil :reader ns-lisp-exception-condition))
278  (:metaclass ns::+ns-object))
279
280(objc:defmethod #/init ((self ns-lisp-exception))
281  (#/initWithName:reason:userInfo: self #@"lisp exception" #@"lisp exception" +null-ptr+))
282
283
284(defun recognize-objc-exception (x)
285  (if (typep x 'ns:ns-exception)
286    (ns-exception->lisp-condition x)))
287
288(pushnew 'recognize-objc-exception *foreign-error-condition-recognizers*)
289
290(defun objc:make-nsstring (string)
291  (with-encoded-cstrs :utf-8 ((s string))
292    (#/initWithUTF8String: (#/alloc ns:ns-string) s)))
293
294(defun %make-nsstring (string)
295  (objc:make-nsstring string))
296
297(defmacro with-autoreleased-nsstring ((nsstring lisp-string) &body body)
298  `(let* ((,nsstring (%make-nsstring ,lisp-string)))
299     (#/autorelease ,nsstring)
300     ,@body))
301
302(defmacro objc:with-autoreleased-nsstrings (speclist &body body)
303  (with-specs-aux 'with-autoreleased-nsstring speclist body))
304
305(defun retain-objc-instance (instance)
306  (#/retain instance))
307
308;;; May have to create/release autorelease pools before the bridge
309;;; is fully reinitialized, so use low-level OBJC-MESSAGE-SEND
310;;; and @class.
311(defun create-autorelease-pool ()
312  (objc-message-send
313   (objc-message-send (@class "NSAutoreleasePool") "alloc") "init"))
314
315(defun release-autorelease-pool (p)
316  (objc-message-send p "release" :void))
317
318
319(defun lisp-string-from-nsstring (nsstring)
320  (with-autorelease-pool
321      ;; It's not clear that it's even possible to lose information
322      ;; when converting to UTF-8, but allow lossage to occur, just in
323      ;; case.
324      (let* ((data (#/dataUsingEncoding:allowLossyConversion:
325                    nsstring #$NSUTF8StringEncoding t))
326             (len (#/length data)))
327        (if (= len 0)
328          ""
329          (let* ((bytes (#/bytes data))
330                 (nchars (utf-8-length-of-memory-encoding bytes len 0))
331                 (string (make-string nchars)))
332            (utf-8-memory-decode bytes len 0 string)
333            string)))))
334
335
336
337     
338
339
340
341
342(objc:defmethod #/reason ((self ns-lisp-exception))
343  (with-slots (condition) self
344    (if condition
345      (#/autorelease (%make-nsstring (format nil "~A" condition)))
346      (call-next-method))))
347
348(objc:defmethod #/description ((self ns-lisp-exception))
349  (#/stringWithFormat: ns:ns-string #@"Lisp exception: %@" (#/reason self)))
350
351
352                     
353(defun ns-exception->lisp-condition (nsexception)
354  (if (typep nsexception 'ns-lisp-exception)
355    (ns-lisp-exception-condition nsexception)
356    (make-condition 'ns-exception :ns-exception nsexception)))
357
358
359(defmethod ns-exception ((c condition))
360  "Map a lisp condition object to an NSException.  Note that instances
361of the NS-EXCEPTION condition class implement this by accessing an
362instance variable."
363  ;;; Create an NSLispException with a lispid that encapsulates
364  ;;; this condition.
365
366  ;; (dbg (format nil "~a" c))
367  ;;(#_NSLog #@"Lisp exception: %@" :id (%make-nsstring (format nil "~a" c)))
368  (make-instance 'ns-lisp-exception :condition c))
369
370
371
372#+(or apple-objc cocotron-objc)         ; not really
373(progn
374
375
376#+ppc-target
377(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
378  ;; On PPC, the "address" of an external entry point is always
379  ;; aligned on a 32-bit word boundary.  On PPC32, it can always
380  ;; be represented as a fixnum; on PPC64, it might be a pointer
381  ;; instead.
382  ;; Note that this clobbers the actual (foreign) return address,
383  ;; replacing it with the address of #__NSRaiseError.  Note also
384  ;; that storing the NSException object as the return value has
385  ;; the desired effect of causing #__NSRaiseError to be called
386  ;; with that NSException as its argument (because r3 is used both
387  ;; as the canonical return value register and used to pass the
388  ;; first argument on PPC.)
389  (process-debug-condition *current-process* condition (%get-frame-ptr))
390  (let* ((addr (%reference-external-entry-point (load-time-value (external "__NSRaiseError")))))
391    (if (typep addr 'fixnum)
392      (%set-object return-address-pointer 0 addr)
393      (setf (%get-ptr return-address-pointer 0) addr)))
394  (setf (%get-ptr return-value-pointer 0) (ns-exception condition))
395  nil)
396
397#+x8664-target
398(progn
399(defloadvar *x8664-objc-callback-error-return-trampoline*
400    (let* ((code-bytes '(#x48 #x89 #xc7      ; movq %rax %rdi
401                         #x66 #x48 #x0f #x7e #xc0 ; movd %xmm0,%rax
402                         #x52                ; pushq %rdx
403                         #xff #xe0))         ; jmp *rax
404           (nbytes (length code-bytes))
405           (ptr (%allocate-callback-pointer 16)))
406      (dotimes (i nbytes ptr)
407        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
408
409(defun objc-callback-error-return (condition return-value-pointer return-address-pointer) 
410  ;; The callback glue reserves space for %rax at return-value-pointer-8,
411  ;; for %rdx at -16, for %xmm0 at -24.  Store NS-EXCEPTION in the
412  ;; %rax slot, the address of #_objc_exception_throw in the %rdx slot, the
413  ;; original return address in the %xmm0 slot, and force a return to
414  ;; the trampoline code above.
415  (process-debug-condition *current-process* condition (%get-frame-ptr))
416  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
417        (%get-ptr return-value-pointer -16) (%get-ptr return-address-pointer 0)
418        (%get-ptr return-address-pointer 0) *x8664-objc-callback-error-return-trampoline*)
419  ;; A foreign entry point is always an integer on x8664.
420  (let* ((addr (%reference-external-entry-point (load-time-value (external "_objc_exception_throw")))))
421    (if (< addr 0)                      ;unlikely
422      (setf (%%get-signed-longlong return-value-pointer -24) addr)
423      (setf (%%get-unsigned-longlong return-value-pointer -24) addr)))
424  nil)
425
426
427)
428
429#+x8632-target
430(progn
431
432(defloadvar *x8632-objc-callback-error-return-trampoline*
433    (let* ((code-bytes '(#x83 #xec #x10      ; subl $16,%esp
434                         #x89 #x04 #x24      ; movl %eax,(%esp)
435                         #x52                ; pushl %edx
436                         #xff #xe1))         ; jmp *ecx
437           (nbytes (length code-bytes))
438           (ptr (%allocate-callback-pointer 16)))
439      (dotimes (i nbytes ptr)
440        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
441
442(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
443  (process-debug-condition *current-process* condition (%get-frame-ptr))
444  (let* ((addr (%reference-external-entry-point (load-time-value (external #+cocotron-objc "_NSRaiseException" #-cocotron-objc "__NSRaiseError")))))
445    (setf (%get-unsigned-long return-value-pointer -12 ) addr))
446  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
447        (%get-ptr return-value-pointer -4) (%get-ptr return-address-pointer)
448        (%get-ptr return-address-pointer) *x8632-objc-callback-error-return-trampoline*)
449  nil)
450)
451
452)
453
454
455
456(defun open-main-bundle ()
457  (#/mainBundle ns:ns-bundle))
458
459;;; Create a new immutable dictionary just like src, replacing the
460;;; value of each key in key-value-pairs with the corresponding value.
461(defun copy-dictionary (src &rest key-value-pairs)
462  (declare (dynamic-extent key-value-pairs))
463  ;(#_NSLog #@"src = %@" :id src)
464  (let* ((count (#/count src))
465         (enum (#/keyEnumerator src))
466         (keys (#/arrayWithCapacity: ns:ns-mutable-array count))
467         (values (#/arrayWithCapacity: ns:ns-mutable-array count)))
468    (loop
469        (let* ((nextkey (#/nextObject enum)))
470          (when (%null-ptr-p nextkey)
471            (return))
472          (do* ((kvps key-value-pairs (cddr kvps))
473                (newkey (car kvps) (car kvps))
474                (newval (cadr kvps) (cadr kvps)))
475               ((null kvps)
476                ;; Copy the key, value pair from the src dict
477                (#/addObject: keys nextkey)
478                (#/addObject: values (#/objectForKey: src nextkey)))
479            (when (#/isEqualToString: nextkey newkey)
480              (#/addObject: keys nextkey)
481              (#/addObject: values newval)
482              (return)))))
483    (make-instance 'ns:ns-dictionary
484                   :with-objects values
485                   :for-keys keys)))
486
487
488
489
490(defparameter *objc-description-max-length* 1024 "Limit on the length of NSObject description strings if non-NIL.")
491
492(defun %cf-instance-p (instance)
493  #-apple-objc (declare (ignore instance))
494  #+apple-objc
495  (> (objc-message-send instance "_cfTypeID" #>CFTypeID) 1))
496 
497
498(defun initialized-nsobject-p (nsobject)
499  (or (objc-class-p nsobject)
500      (objc-metaclass-p nsobject)
501      (has-lisp-slot-vector nsobject)
502      (let* ((cf-p (%cf-instance-p nsobject)) 
503             (isize (if cf-p (external-call "malloc_size" :address nsobject :size_t) (%objc-class-instance-size (#/class nsobject))))
504             (skip (if cf-p (+ (record-length :id) 4 #+64-bit-target 4) (record-length :id))))
505        (declare (fixnum isize skip))
506        (or (> skip isize)
507            (do* ((i skip (1+ i)))
508                 ((>= i isize))
509              (declare (fixnum i))
510              (unless (zerop (the (unsigned-byte 8) (%get-unsigned-byte nsobject i)))
511                (return t)))))))
512 
513(defun nsobject-description (nsobject)
514  "Returns a lisp string that describes nsobject.  Note that some
515NSObjects describe themselves in more detail than others."
516  (if (initialized-nsobject-p nsobject)
517    (with-autorelease-pool
518        (let* ((desc (#/description nsobject)))
519          (if (or (null *objc-description-max-length*)
520                  (< (#/length desc) *objc-description-max-length*))
521            (lisp-string-from-nsstring desc)
522            (ns:with-ns-range (r 0 *objc-description-max-length*)
523              (format nil "~a[...]"(lisp-string-from-nsstring (#/substringWithRange: desc r)))))))
524    "[uninitialized]"))
525
526
527
528
529
530(defun lisp-string-from-nsstring-substring (nsstring start length)
531  (let* ((substring (#/substringWithRange: nsstring (ns:make-ns-range start length))))
532    (lisp-string-from-nsstring substring)))
533
534(def-standard-initial-binding *listener-autorelease-pool* nil)
535
536(setq *listener-autorelease-pool* (create-autorelease-pool))
537
538(define-toplevel-command :global rap () "Release and reestablish *LISTENER-AUTORELEASE-POOL*"
539  (when (eql *break-level* 0)
540    (without-interrupts
541     (when (boundp '*listener-autorelease-pool*)
542       (let* ((old *listener-autorelease-pool*))
543         (if old (release-autorelease-pool old))
544         (setq *listener-autorelease-pool* (create-autorelease-pool)))))))
545
546#+apple-objc
547(defun show-autorelease-pools ()
548  (objc-message-send (@class ns-autorelease-pool) "showPools" :void))
549
550#+gnu-objc
551(defun show-autorelease-pools ()
552  (do* ((current (objc-message-send (@class ns-autorelease-pool) "currentPool")
553                 (objc-message-send current "_parentAutoreleasePool"))
554        (i 0 (1+ i)))
555       ((%null-ptr-p current) (values))
556    (format t "~& ~d : ~a [~d]"
557            i
558            (nsobject-description current)
559            (pref current :<NSA>utorelease<P>ool._released_count))))
560
561#+cocotron-objc
562(defun show-autorelease-pools ()
563  (%string-to-stderr  "No info about current thread's autorelease pools is available"))
564
565(define-toplevel-command :global sap () "Log information about current thread's autorelease-pool(s) to C's standard error stream"
566  (show-autorelease-pools))
567
568(define-toplevel-command :global kap () "Release (but don't reestablish) *LISTENER-AUTORELEASE-POOL*"
569  (when (eql *break-level* 0)
570    (without-interrupts
571     (when (boundp '*listener-autorelease-pool*)
572       (let* ((p *listener-autorelease-pool*))
573         (setq *listener-autorelease-pool* nil)
574         (release-autorelease-pool p))))))
575
576;;; Use the interfaces for an add-on ObjC framework.  We need to
577;;; tell the bridge to reconsider what it knows about the type
578;;; signatures of ObjC messages, since the new headers may define
579;;; a method whose type signature differs from the message's existing
580;;; methods.  (This probably doesn't happen too often, but it's
581;;; possible that some SENDs that have already been compiled would
582;;; need to be recompiled with that augmented method type info, e.g.,
583;;; because ambiguity was introduced.)
584
585(defun augment-objc-interfaces (dirname)
586  (use-interface-dir dirname)
587  (register-objc-class-decls)
588  (update-objc-method-info))
589
590;;; A list of "standard" locations which are known to contain
591;;; framework bundles.  We should look in ~/Library/Frameworks/" first,
592;;; if it exists.
593(defparameter *standard-framework-directories*
594  (list #p"/Library/Frameworks/"
595        #p"/System/Library/Frameworks/"))
596
597
598
599;;; This has to run during application (re-)initializtion, so it
600;;; uses lower-level bridge features.
601(defun %reload-objc-framework (path)
602  (when (probe-file path)
603    (let* ((namestring (native-translated-namestring path)))
604      (with-cstrs ((cnamestring namestring))
605        (with-nsstr (nsnamestring cnamestring (length namestring))
606          (with-autorelease-pool
607              (let* ((bundle (objc-message-send (@class "NSBundle")
608                                                "bundleWithPath:"
609                                                :id nsnamestring :id)))
610                (unless (%null-ptr-p bundle)
611                  (objc-message-send bundle "load" :<BOOL>)))))))))
612
613
614(defun load-objc-extension-framework (name)
615  (let* ((dirs *standard-framework-directories*)
616         (home-frameworks (make-pathname :defaults nil
617                                         :directory
618                                         (append (pathname-directory
619                                                  (user-homedir-pathname))
620                                                 '("Library" "Frameworks"))))
621         (fname (list (format nil "~a.framework" name))))
622    (when (probe-file home-frameworks)
623      (pushnew home-frameworks dirs :test #'equalp))
624    (dolist (d dirs)
625      (let* ((path (probe-file (make-pathname :defaults nil
626                                              :directory (append (pathname-directory d)
627                                                                 fname)))))
628        (when path
629          (let* ((namestring (native-translated-namestring path)))
630            (with-cstrs ((cnamestring namestring))
631              (with-nsstr (nsnamestring cnamestring (length namestring))
632                (with-autorelease-pool
633                    (let* ((bundle (#/bundleWithPath: ns:ns-bundle nsnamestring))
634                           (winning (unless (%null-ptr-p bundle)
635                                      t)))
636                      (when winning
637                        (let* ((libpath (#/executablePath bundle)))
638                          (unless (%null-ptr-p libpath)
639                            (open-shared-library (lisp-string-from-nsstring
640                                                  libpath))))
641                        (#/load bundle)
642                        (pushnew path *extension-framework-paths*
643                                 :test #'equalp)
644                        (map-objc-classes)
645                        ;; Update info about init messages.
646                        (register-objc-init-messages)
647                        (register-objc-set-messages))
648                      (return winning)))))))))))
649
650(defun objc:load-framework (framework-name interfaces-name)
651  (use-interface-dir interfaces-name)
652  (or (load-objc-extension-framework framework-name)
653      (error "Can't load ObjC framework ~s" framework-name))
654  (augment-objc-interfaces interfaces-name))
655
656                     
657(defmethod print-object ((p ns:protocol) stream)
658  (print-unreadable-object (p stream :type t)
659    (format stream "~a (#x~x)"
660            (%get-cstring (#/name p))
661            (%ptr-to-int p))))
662
663                                         
664(defmethod terminate ((instance objc:objc-object))
665  (objc-message-send instance "release"))
666
667
668(provide "OBJC-SUPPORT")
Note: See TracBrowser for help on using the repository browser.