source: trunk/source/objc-bridge/objc-support.lisp @ 11907

Last change on this file since 11907 was 11907, checked in by gb, 10 years ago

When updating ObjC 2.x exception globals, if any global has a non-NULL
value, treat that value as a pointer to be updaed with the value of
the foreign symbol.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 19.5 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2
3(in-package "CCL")
4
5(eval-when (:compile-toplevel :load-toplevel :execute)
6  (require "BRIDGE"))
7
8(defun allocate-objc-object (class)
9  (#/alloc class))
10
11(defun conforms-to-protocol (thing protocol)
12  (#/conformsToProtocol: thing (objc-protocol-address protocol)))
13
14
15
16
17#+apple-objc
18(defun iterate-over-objc-classes (fn)
19  (let* ((n (#_objc_getClassList (%null-ptr) 0)))
20    (declare (fixnum n))
21    (%stack-block ((buffer (the fixnum (ash n target::word-shift))))
22      (#_objc_getClassList buffer n)
23      (do* ((i 0 (1+ i)))
24           ((= i n) (values))
25        (declare (fixnum i))
26        (funcall fn (paref buffer (:* :id) i))))))
27
28#+apple-objc
29(defun count-objc-classes ()
30  (#_objc_getClassList (%null-ptr) 0)) 
31
32#+gnu-objc
33(defun iterate-over-objc-classes (fn)
34  (rletZ ((enum-state :address))
35    (loop
36      (let* ((class (#_objc_next_class enum-state)))
37        (if (%null-ptr-p class)
38          (return)
39          (funcall fn class))))))
40
41#+gnu-objc
42(defun count-objc-classes ()
43  (let* ((n 0))
44    (declare (fixnum n))
45    (rletZ ((enum-state :address))
46      (if (%null-ptr-p (#_objc_next_class enum-state))
47        (return n)
48        (incf n)))))
49
50(defun %note-protocol (p)
51  (with-macptrs ((cname (objc-message-send p "name" :address)))
52    (let* ((namelen (%cstrlen cname))
53           (name (make-string namelen)))
54      (declare (dynamic-extent name))
55      (%str-from-ptr cname namelen name)
56      (let* ((proto (or (gethash name *objc-protocols*)
57                        (progn
58                          (setq name (subseq name 0))
59                          (setf (gethash name *objc-protocols*)
60                                (make-objc-protocol :name name))))))
61        (unless (objc-protocol-address proto)
62          (setf (objc-protocol-address proto) (%inc-ptr p 0)))
63        proto))))
64
65(defun note-class-protocols (class)
66  #-apple-objc-2.0
67  (do* ((protocols (pref class :objc_class.protocols)
68                   (pref protocols :objc_protocol_list.next)))
69       ((%null-ptr-p protocols))
70    (let* ((count (pref protocols :objc_protocol_list.count)))
71      (with-macptrs ((list (pref protocols :objc_protocol_list.list)))
72        (dotimes (i count)
73          (with-macptrs ((p (paref list (:* (:* (:struct :<P>rotocol))) i)))
74            (%note-protocol p))))))
75  #+apple-objc-2.0
76  (rlet ((p-out-count :int))
77    (with-macptrs ((protocols (#_class_copyProtocolList class p-out-count)))
78      (let* ((n (pref p-out-count :int)))
79        (dotimes (i n)
80          (with-macptrs ((p (paref protocols (:* (:* (:struct :<P>rotocol))) i)))
81            (%note-protocol p))))
82      (unless (%null-ptr-p protocols) (#_free protocols)))))
83           
84
85(defun map-objc-classes (&optional (lookup-in-database-p t))
86  (iterate-over-objc-classes
87   #'(lambda (class)
88       (note-class-protocols class)
89       (install-foreign-objc-class class lookup-in-database-p))))
90
91(let* ((nclasses 0)
92       (lock (make-lock)))
93  (declare (fixnum nclasses))
94  (defun maybe-map-objc-classes (&optional use-db)
95    (with-lock-grabbed (lock)
96      (let* ((new (count-objc-classes)))
97        (declare (fixnum new))
98        (unless (= nclasses new)
99          (setq nclasses new)
100          (map-objc-classes use-db))
101        t)))
102  (defun reset-objc-class-count ()
103    (with-lock-grabbed (lock)
104      (setq nclasses 0))))
105
106(register-objc-class-decls)
107(maybe-map-objc-classes t)
108(register-objc-init-messages)
109
110#+gnu-objc
111(defun iterate-over-class-methods (class method-function)
112  (do* ((mlist (pref class :objc_class.methods)
113               (pref mlist :objc_method_list.method_next)))
114       ((%null-ptr-p mlist))
115    (do* ((n (pref mlist :objc_method_list.method_count))
116          (i 0 (1+ i))
117          (method (pref mlist :objc_method_list.method_list)
118                  (%incf-ptr method (record-length :objc_method))))
119         ((= i n))
120      (declare (fixnum i n))
121      (funcall method-function method class))))
122
123#+gnu-objc
124(progn
125  ;; Er, um ... this needs lots-o-work.
126  (let* ((objc-class-count 0))
127    (defun reset-objc-class-count () (setq objc-class-count 0))
128    (defun note-all-library-methods (method-function)
129      (do* ((i objc-class-count (1+ i))
130            (class (id->objc-class i) (id->objc-class i)))
131           ((eq class 0))
132        (iterate-over-class-methods class method-function)
133        (iterate-over-class-methods (id->objc-metaclass i) method-function))))
134  (def-ccl-pointers revive-objc-classes ()
135    (reset-objc-class-count)))
136
137(defun retain-obcj-object (x)
138  (objc-message-send x "retain"))
139
140
141#+apple-objc-2.0
142(progn
143(defun setup-objc-exception-globals ()
144  (flet ((set-global (offset name)
145           (with-macptrs (p (%int-to-ptr (+ (target-nil-value) (%kernel-global-offset offset))))
146            (unless (%null-ptr-p (%get-ptr p))
147              (%setf-macptr p (%get-ptr p)))
148            (setf (%get-ptr p)
149                  (foreign-symbol-address name)))))
150    (set-global 'objc-2-personality "___objc_personality_v0")
151    (set-global 'objc-2-begin-catch "_objc_begin_catch")
152    (set-global 'objc-2-end-catch "_objc_end_catch")
153    (set-global 'unwind-resume "__Unwind_Resume")))
154
155
156(def-ccl-pointers setup-objc-exception-handling ()
157  (setup-objc-exception-globals))
158
159(setup-objc-exception-globals)
160)
161
162
163(defvar *condition-id-map* (make-id-map) "Map lisp conditions to small integers")
164
165;;; Encapsulate an NSException in a lisp condition.
166(define-condition ns-exception (error)
167  ((ns-exception :initarg :ns-exception :accessor ns-exception))
168  (:report (lambda (c s)
169             (format s "Objective-C runtime exception: ~&~a"
170                     (nsobject-description (ns-exception c))))))
171
172
173
174(defclass ns-lisp-exception (ns::ns-exception)
175    ((condition :initarg :condition :initform nil :reader ns-lisp-exception-condition))
176  (:metaclass ns::+ns-object))
177
178(objc:defmethod #/init ((self ns-lisp-exception))
179  (#/initWithName:reason:userInfo: self #@"lisp exception" #@"lisp exception" +null-ptr+))
180
181
182(defun recognize-objc-exception (x)
183  (if (typep x 'ns:ns-exception)
184    (ns-exception->lisp-condition x)))
185
186(pushnew 'recognize-objc-exception *foreign-error-condition-recognizers*)
187
188(defun %make-nsstring (string)
189  (with-encoded-cstrs :utf-8 ((s string))
190    (#/initWithUTF8String: (#/alloc ns:ns-string) s)))
191
192(defmacro with-autoreleased-nsstring ((nsstring lisp-string) &body body)
193  `(let* ((,nsstring (%make-nsstring ,lisp-string)))
194     (#/autorelease ,nsstring)
195     ,@body))
196
197(defmacro with-autoreleased-nsstrings (speclist &body body)
198  (with-specs-aux 'with-autoreleased-nsstring speclist body))
199
200(defun retain-objc-instance (instance)
201  (#/retain instance))
202
203;;; May have to create/release autorelease pools before the bridge
204;;; is fully reinitialized, so use low-level OBJC-MESSAGE-SEND
205;;; and @class.
206(defun create-autorelease-pool ()
207  (objc-message-send
208   (objc-message-send (@class "NSAutoreleasePool") "alloc") "init"))
209
210(defun release-autorelease-pool (p)
211  (objc-message-send p "release" :void))
212
213
214#-ascii-only
215(defun lisp-string-from-nsstring (nsstring)
216  ;; The NSData object created here is autoreleased.
217  (let* ((data (#/dataUsingEncoding:allowLossyConversion:
218                nsstring
219                #+little-endian-target #x9c000100
220                #+big-endian-target #x98000100
221                nil)))
222    (unless (%null-ptr-p data)
223      (let* ((nbytes (#/length data))
224             (string (make-string (ash nbytes -2))))
225        ;; BLT the 4-byte code-points from the NSData object
226        ;; to the string, return the string.
227        (%copy-ptr-to-ivector (#/bytes data) 0 string 0 nbytes)))))
228       
229
230
231#+ascii-only
232(defun lisp-string-from-nsstring (nsstring)
233  (with-macptrs (cstring)
234    (%setf-macptr cstring
235                  (#/cStringUsingEncoding: nsstring #$NSASCIIStringEncoding))
236    (unless (%null-ptr-p cstring)
237      (%get-cstring cstring))))
238
239
240(objc:defmethod #/reason ((self ns-lisp-exception))
241  (with-slots (condition) self
242    (if condition
243      (#/autorelease (%make-nsstring (format nil "~A" condition)))
244      (call-next-method))))
245
246(objc:defmethod #/description ((self ns-lisp-exception))
247  (#/stringWithFormat: ns:ns-string #@"Lisp exception: %@" (#/reason self)))
248
249
250                     
251(defun ns-exception->lisp-condition (nsexception)
252  (if (typep nsexception 'ns-lisp-exception)
253    (ns-lisp-exception-condition nsexception)
254    (make-condition 'ns-exception :ns-exception nsexception)))
255
256
257(defmethod ns-exception ((c condition))
258  "Map a lisp condition object to an NSException.  Note that instances
259of the NS-EXCEPTION condition class implement this by accessing an
260instance variable."
261  ;;; Create an NSLispException with a lispid that encapsulates
262  ;;; this condition.
263
264  ;; (dbg (format nil "~a" c))
265  ;;(#_NSLog #@"Lisp exception: %@" :id (%make-nsstring (format nil "~a" c)))
266  (make-instance 'ns-lisp-exception :condition c))
267
268
269
270#+apple-objc
271(progn
272
273
274#+ppc-target
275(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
276  ;; On PPC, the "address" of an external entry point is always
277  ;; aligned on a 32-bit word boundary.  On PPC32, it can always
278  ;; be represented as a fixnum; on PPC64, it might be a pointer
279  ;; instead.
280  ;; Note that this clobbers the actual (foreign) return address,
281  ;; replacing it with the address of #__NSRaiseError.  Note also
282  ;; that storing the NSException object as the return value has
283  ;; the desired effect of causing #__NSRaiseError to be called
284  ;; with that NSException as its argument (because r3 is used both
285  ;; as the canonical return value register and used to pass the
286  ;; first argument on PPC.)
287  (process-debug-condition *current-process* condition (%get-frame-ptr))
288  (let* ((addr (%reference-external-entry-point (load-time-value (external "__NSRaiseError")))))
289    (if (typep addr 'fixnum)
290      (%set-object return-address-pointer 0 addr)
291      (setf (%get-ptr return-address-pointer 0) addr)))
292  (setf (%get-ptr return-value-pointer 0) (ns-exception condition))
293  nil)
294
295#+x8664-target
296(progn
297(defloadvar *x8664-objc-callback-error-return-trampoline*
298    (let* ((code-bytes '(#x48 #x89 #xc7      ; movq %rax %rdi
299                         #x66 #x48 #x0f #x7e #xc0 ; movd %xmm0,%rax
300                         #x52                ; pushq %rdx
301                         #xff #xe0))         ; jmp *rax
302           (nbytes (length code-bytes))
303           (ptr (%allocate-callback-pointer 16)))
304      (dotimes (i nbytes ptr)
305        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
306
307(defun objc-callback-error-return (condition return-value-pointer return-address-pointer) 
308  ;; The callback glue reserves space for %rax at return-value-pointer-8,
309  ;; for %rdx at -16, for %xmm0 at -24.  Store NS-EXCEPTION in the
310  ;; %rax slot, the address of #_objc_exception_throw in the %rdx slot, the
311  ;; original return address in the %xmm0 slot, and force a return to
312  ;; the trampoline code above.
313  (process-debug-condition *current-process* condition (%get-frame-ptr))
314  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
315        (%get-ptr return-value-pointer -16) (%get-ptr return-address-pointer 0)
316        (%get-ptr return-address-pointer 0) *x8664-objc-callback-error-return-trampoline*)
317  ;; A foreign entry point is always an integer on x8664.
318  (let* ((addr (%reference-external-entry-point (load-time-value (external "_objc_exception_throw")))))
319    (if (< addr 0)                      ;unlikely
320      (setf (%%get-signed-longlong return-value-pointer -24) addr)
321      (setf (%%get-unsigned-longlong return-value-pointer -24) addr)))
322  nil)
323
324
325)
326
327#+x8632-target
328(progn
329
330(defloadvar *x8632-objc-callback-error-return-trampoline*
331    (let* ((code-bytes '(#x83 #xec #x10      ; subl $16,%esp
332                         #x89 #x04 #x24      ; movl %eax,(%esp)
333                         #x52                ; pushl %edx
334                         #xff #xe1))         ; jmp *ecx
335           (nbytes (length code-bytes))
336           (ptr (%allocate-callback-pointer 16)))
337      (dotimes (i nbytes ptr)
338        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
339
340(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
341  (process-debug-condition *current-process* condition (%get-frame-ptr))
342  (let* ((addr (%reference-external-entry-point (load-time-value (external "__NSRaiseError")))))
343    (setf (%get-unsigned-long return-value-pointer -12 ) addr))
344  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
345        (%get-ptr return-value-pointer -4) (%get-ptr return-address-pointer)
346        (%get-ptr return-address-pointer) *x8632-objc-callback-error-return-trampoline*)
347  nil)
348)
349
350)
351
352
353
354(defun open-main-bundle ()
355  (#/mainBundle ns:ns-bundle))
356
357;;; Create a new immutable dictionary just like src, replacing the
358;;; value of each key in key-value-pairs with the corresponding value.
359(defun copy-dictionary (src &rest key-value-pairs)
360  (declare (dynamic-extent key-value-pairs))
361  ;(#_NSLog #@"src = %@" :id src)
362  (let* ((count (#/count src))
363         (enum (#/keyEnumerator src))
364         (keys (#/arrayWithCapacity: ns:ns-mutable-array count))
365         (values (#/arrayWithCapacity: ns:ns-mutable-array count)))
366    (loop
367        (let* ((nextkey (#/nextObject enum)))
368          (when (%null-ptr-p nextkey)
369            (return))
370          (do* ((kvps key-value-pairs (cddr kvps))
371                (newkey (car kvps) (car kvps))
372                (newval (cadr kvps) (cadr kvps)))
373               ((null kvps)
374                ;; Copy the key, value pair from the src dict
375                (#/addObject: keys nextkey)
376                (#/addObject: values (#/objectForKey: src nextkey)))
377            (when (#/isEqualToString: nextkey newkey)
378              (#/addObject: keys nextkey)
379              (#/addObject: values newval)
380              (return)))))
381    (make-instance 'ns:ns-dictionary
382                   :with-objects values
383                   :for-keys keys)))
384
385
386(defun nsobject-description (nsobject)
387  "Returns a lisp string that describes nsobject.  Note that some
388NSObjects describe themselves in more detail than others."
389  (with-autorelease-pool
390      (lisp-string-from-nsstring  (#/description nsobject))))
391
392
393
394
395;;; This can fail if the nsstring contains non-8-bit characters.
396(defun lisp-string-from-nsstring-substring (nsstring start length)
397  (%stack-block ((cstring (1+ length)))
398    (#/getCString:maxLength:range:remainingRange:
399       nsstring  cstring  length (ns:make-ns-range start length) +null-ptr+)
400    (%get-cstring cstring)))
401
402(def-standard-initial-binding *listener-autorelease-pool* nil)
403
404(setq *listener-autorelease-pool* (create-autorelease-pool))
405
406(define-toplevel-command :global rap () "Release and reestablish *LISTENER-AUTORELEASE-POOL*"
407  (when (eql *break-level* 0)
408    (without-interrupts
409     (when (boundp '*listener-autorelease-pool*)
410       (let* ((old *listener-autorelease-pool*))
411         (if old (release-autorelease-pool old))
412         (setq *listener-autorelease-pool* (create-autorelease-pool)))))))
413
414#+apple-objc
415(defun show-autorelease-pools ()
416  (objc-message-send (@class ns-autorelease-pool) "showPools" :void))
417
418#+gnu-objc
419(defun show-autorelease-pools ()
420  (do* ((current (objc-message-send (@class ns-autorelease-pool) "currentPool")
421                 (objc-message-send current "_parentAutoreleasePool"))
422        (i 0 (1+ i)))
423       ((%null-ptr-p current) (values))
424    (format t "~& ~d : ~a [~d]"
425            i
426            (nsobject-description current)
427            (pref current :<NSA>utorelease<P>ool._released_count))))
428
429(define-toplevel-command :global sap () "Log information about current thread's autorelease-pool(s) to C's standard error stream"
430  (show-autorelease-pools))
431
432(define-toplevel-command :global kap () "Release (but don't reestablish) *LISTENER-AUTORELEASE-POOL*"
433  (when (eql *break-level* 0)
434    (without-interrupts
435     (when (boundp '*listener-autorelease-pool*)
436       (let* ((p *listener-autorelease-pool*))
437         (setq *listener-autorelease-pool* nil)
438         (release-autorelease-pool p))))))
439
440;;; Use the interfaces for an add-on ObjC framework.  We need to
441;;; tell the bridge to reconsider what it knows about the type
442;;; signatures of ObjC messages, since the new headers may define
443;;; a method whose type signature differs from the message's existing
444;;; methods.  (This probably doesn't happen too often, but it's
445;;; possible that some SENDs that have already been compiled would
446;;; need to be recompiled with that augmented method type info, e.g.,
447;;; because ambiguity was introduced.)
448
449(defun augment-objc-interfaces (dirname)
450  (use-interface-dir dirname)
451  (register-objc-class-decls)
452  (update-objc-method-info))
453
454;;; A list of "standard" locations which are known to contain
455;;; framework bundles.  We should look in ~/Library/Frameworks/" first,
456;;; if it exists.
457(defparameter *standard-framework-directories*
458  (list #p"/Library/Frameworks/"
459        #p"/System/Library/Frameworks/"))
460
461
462
463;;; This has to run during application (re-)initializtion, so it
464;;; uses lower-level bridge features.
465(defun %reload-objc-framework (path)
466  (when (probe-file path)
467    (let* ((namestring (native-translated-namestring path)))
468      (with-cstrs ((cnamestring namestring))
469        (with-nsstr (nsnamestring cnamestring (length namestring))
470          (with-autorelease-pool
471              (let* ((bundle (objc-message-send (@class "NSBundle")
472                                                "bundleWithPath:"
473                                                :id nsnamestring :id)))
474                (unless (%null-ptr-p bundle)
475                  (objc-message-send bundle "load" :<BOOL>)))))))))
476
477
478(defun load-objc-extension-framework (name)
479  (let* ((dirs *standard-framework-directories*)
480         (home-frameworks (make-pathname :defaults nil
481                                         :directory
482                                         (append (pathname-directory
483                                                  (user-homedir-pathname))
484                                                 '("Library" "Frameworks"))))
485         (fname (list (format nil "~a.framework" name))))
486    (when (probe-file home-frameworks)
487      (pushnew home-frameworks dirs :test #'equalp))
488    (dolist (d dirs)
489      (let* ((path (probe-file (make-pathname :defaults nil
490                                              :directory (append (pathname-directory d)
491                                                                 fname)))))
492        (when path
493          (let* ((namestring (native-translated-namestring path)))
494            (with-cstrs ((cnamestring namestring))
495              (with-nsstr (nsnamestring cnamestring (length namestring))
496                (with-autorelease-pool
497                    (let* ((bundle (#/bundleWithPath: ns:ns-bundle nsnamestring))
498                           (winning (unless (%null-ptr-p bundle)
499                                      t)))
500                      (when winning
501                        (let* ((libpath (#/executablePath bundle)))
502                          (unless (%null-ptr-p libpath)
503                            (open-shared-library (lisp-string-from-nsstring
504                                                  libpath))))
505                        (#/load bundle)
506                        (pushnew path *extension-framework-paths*
507                                 :test #'equalp)
508                        (map-objc-classes)
509                        ;; Update info about init messages.
510                        (register-objc-init-messages))
511                      (return winning)))))))))))
512
513(defun objc:load-framework (framework-name interfaces-name)
514  (use-interface-dir interfaces-name)
515  (or (load-objc-extension-framework framework-name)
516      (error "Can't load ObjC framework ~s" framework-name))
517  (augment-objc-interfaces interfaces-name))
518
519                     
520(defmethod print-object ((p ns:protocol) stream)
521  (print-unreadable-object (p stream :type t)
522    (format stream "~a (#x~x)"
523            (%get-cstring (#/name p))
524            (%ptr-to-int p))))
525
526                                         
527(defmethod terminate ((instance objc:objc-object))
528  (objc-message-send instance "release"))
529
530
531(provide "OBJC-SUPPORT")
Note: See TracBrowser for help on using the repository browser.