source: trunk/source/objc-bridge/objc-support.lisp @ 11427

Last change on this file since 11427 was 11427, checked in by gb, 11 years ago

Serialize MAYBE-MAP-OBJC-CLASSES. It might be possible to be less
restrictive here, but we're already doing an ff-call to get the
class count ...

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 19.1 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2
3(in-package "CCL")
4
5(eval-when (:compile-toplevel :load-toplevel :execute)
6  (require "BRIDGE"))
7
8(defun allocate-objc-object (class)
9  (#/alloc class))
10
11(defun conforms-to-protocol (thing protocol)
12  (#/conformsToProtocol: thing (objc-protocol-address protocol)))
13
14
15
16
17#+apple-objc
18(defun iterate-over-objc-classes (fn)
19  (let* ((n (#_objc_getClassList (%null-ptr) 0)))
20    (declare (fixnum n))
21    (%stack-block ((buffer (the fixnum (ash n target::word-shift))))
22      (#_objc_getClassList buffer n)
23      (do* ((i 0 (1+ i)))
24           ((= i n) (values))
25        (declare (fixnum i))
26        (funcall fn (paref buffer (:* :id) i))))))
27
28#+apple-objc
29(defun count-objc-classes ()
30  (#_objc_getClassList (%null-ptr) 0)) 
31
32#+gnu-objc
33(defun iterate-over-objc-classes (fn)
34  (rletZ ((enum-state :address))
35    (loop
36      (let* ((class (#_objc_next_class enum-state)))
37        (if (%null-ptr-p class)
38          (return)
39          (funcall fn class))))))
40
41#+gnu-objc
42(defun count-objc-classes ()
43  (let* ((n 0))
44    (declare (fixnum n))
45    (rletZ ((enum-state :address))
46      (if (%null-ptr-p (#_objc_next_class enum-state))
47        (return n)
48        (incf n)))))
49
50(defun %note-protocol (p)
51  (with-macptrs ((cname (objc-message-send p "name" :address)))
52    (let* ((namelen (%cstrlen cname))
53           (name (make-string namelen)))
54      (declare (dynamic-extent name))
55      (%str-from-ptr cname namelen name)
56      (let* ((proto (or (gethash name *objc-protocols*)
57                        (progn
58                          (setq name (subseq name 0))
59                          (setf (gethash name *objc-protocols*)
60                                (make-objc-protocol :name name))))))
61        (unless (objc-protocol-address proto)
62          (setf (objc-protocol-address proto) (%inc-ptr p 0)))
63        proto))))
64
65(defun note-class-protocols (class)
66  #-apple-objc-2.0
67  (do* ((protocols (pref class :objc_class.protocols)
68                   (pref protocols :objc_protocol_list.next)))
69       ((%null-ptr-p protocols))
70    (let* ((count (pref protocols :objc_protocol_list.count)))
71      (with-macptrs ((list (pref protocols :objc_protocol_list.list)))
72        (dotimes (i count)
73          (with-macptrs ((p (paref list (:* (:* (:struct :<P>rotocol))) i)))
74            (%note-protocol p))))))
75  #+apple-objc-2.0
76  (rlet ((p-out-count :int))
77    (with-macptrs ((protocols (#_class_copyProtocolList class p-out-count)))
78      (let* ((n (pref p-out-count :int)))
79        (dotimes (i n)
80          (with-macptrs ((p (paref protocols (:* (:* (:struct :<P>rotocol))) i)))
81            (%note-protocol p))))
82      (unless (%null-ptr-p protocols) (#_free protocols)))))
83           
84
85(defun map-objc-classes (&optional (lookup-in-database-p t))
86  (iterate-over-objc-classes
87   #'(lambda (class)
88       (note-class-protocols class)
89       (install-foreign-objc-class class lookup-in-database-p))))
90
91(let* ((nclasses 0)
92       (lock (make-lock)))
93  (declare (fixnum nclasses))
94  (defun maybe-map-objc-classes (&optional use-db)
95    (with-lock-grabbed (lock)
96      (let* ((new (count-objc-classes)))
97        (declare (fixnum new))
98        (unless (= nclasses new)
99          (setq nclasses new)
100          (map-objc-classes use-db))
101        t)))
102  (defun reset-objc-class-count ()
103    (with-lock-grabbed (lock)
104      (setq nclasses 0))))
105
106(register-objc-class-decls)
107(maybe-map-objc-classes t)
108(register-objc-init-messages)
109
110#+gnu-objc
111(defun iterate-over-class-methods (class method-function)
112  (do* ((mlist (pref class :objc_class.methods)
113               (pref mlist :objc_method_list.method_next)))
114       ((%null-ptr-p mlist))
115    (do* ((n (pref mlist :objc_method_list.method_count))
116          (i 0 (1+ i))
117          (method (pref mlist :objc_method_list.method_list)
118                  (%incf-ptr method (record-length :objc_method))))
119         ((= i n))
120      (declare (fixnum i n))
121      (funcall method-function method class))))
122
123#+gnu-objc
124(progn
125  ;; Er, um ... this needs lots-o-work.
126  (let* ((objc-class-count 0))
127    (defun reset-objc-class-count () (setq objc-class-count 0))
128    (defun note-all-library-methods (method-function)
129      (do* ((i objc-class-count (1+ i))
130            (class (id->objc-class i) (id->objc-class i)))
131           ((eq class 0))
132        (iterate-over-class-methods class method-function)
133        (iterate-over-class-methods (id->objc-metaclass i) method-function))))
134  (def-ccl-pointers revive-objc-classes ()
135    (reset-objc-class-count)))
136
137(defun retain-obcj-object (x)
138  (objc-message-send x "retain"))
139
140
141#+apple-objc-2.0
142(progn
143(defun setup-objc-exception-globals ()
144  (flet ((set-global (offset name)
145           (setf (%get-ptr (%int-to-ptr (+ (target-nil-value) (%kernel-global-offset offset))))
146                 (foreign-symbol-address name))))
147    (set-global 'x86::objc-2-personality "___objc_personality_v0")
148    (set-global 'x86::objc-2-begin-catch "_objc_begin_catch")
149    (set-global 'x86::objc-2-end-catch "_objc_end_catch")
150    (set-global 'x86::unwind-resume "__Unwind_Resume")))
151
152
153(def-ccl-pointers setup-objc-exception-handling ()
154  (setup-objc-exception-globals))
155
156(setup-objc-exception-globals)
157)
158
159
160(defvar *condition-id-map* (make-id-map) "Map lisp conditions to small integers")
161
162;;; Encapsulate an NSException in a lisp condition.
163(define-condition ns-exception (error)
164  ((ns-exception :initarg :ns-exception :accessor ns-exception))
165  (:report (lambda (c s)
166             (format s "Objective-C runtime exception: ~&~a"
167                     (nsobject-description (ns-exception c))))))
168
169
170
171(defclass ns-lisp-exception (ns::ns-exception)
172    ((condition :initarg :condition :initform nil :reader ns-lisp-exception-condition))
173  (:metaclass ns::+ns-object))
174
175(objc:defmethod #/init ((self ns-lisp-exception))
176  (#/initWithName:reason:userInfo: self #@"lisp exception" #@"lisp exception" +null-ptr+))
177
178
179(defun recognize-objc-exception (x)
180  (if (typep x 'ns:ns-exception)
181    (ns-exception->lisp-condition x)))
182
183(pushnew 'recognize-objc-exception *foreign-error-condition-recognizers*)
184
185(defun %make-nsstring-from-utf8-c-string (s)
186  (#/initWithUTF8String: (#/alloc ns:ns-string) s))
187
188
189(defun retain-objc-instance (instance)
190  (#/retain instance))
191
192;;; May have to create/release autorelease pools before the bridge
193;;; is fully reinitialized, so use low-level OBJC-MESSAGE-SEND
194;;; and @class.
195(defun create-autorelease-pool ()
196  (objc-message-send
197   (objc-message-send (@class "NSAutoreleasePool") "alloc") "init"))
198
199(defun release-autorelease-pool (p)
200  (objc-message-send p "release" :void))
201
202
203#-ascii-only
204(defun lisp-string-from-nsstring (nsstring)
205  ;; The NSData object created here is autoreleased.
206  (let* ((data (#/dataUsingEncoding:allowLossyConversion:
207                nsstring
208                #+little-endian-target #x9c000100
209                #+big-endian-target #x98000100
210                nil)))
211    (unless (%null-ptr-p data)
212      (let* ((nbytes (#/length data))
213             (string (make-string (ash nbytes -2))))
214        ;; BLT the 4-byte code-points from the NSData object
215        ;; to the string, return the string.
216        (%copy-ptr-to-ivector (#/bytes data) 0 string 0 nbytes)))))
217       
218
219
220#+ascii-only
221(defun lisp-string-from-nsstring (nsstring)
222  (with-macptrs (cstring)
223    (%setf-macptr cstring
224                  (#/cStringUsingEncoding: nsstring #$NSASCIIStringEncoding))
225    (unless (%null-ptr-p cstring)
226      (%get-cstring cstring))))
227
228
229(objc:defmethod #/reason ((self ns-lisp-exception))
230  (with-slots (condition) self
231    (if condition
232      (%make-nsstring (format nil "~A" condition))
233      (call-next-method))))
234
235(objc:defmethod #/description ((self ns-lisp-exception))
236  (#/stringWithFormat: ns:ns-string #@"Lisp exception: %@" (#/reason self)))
237
238
239                     
240(defun ns-exception->lisp-condition (nsexception)
241  (if (typep nsexception 'ns-lisp-exception)
242    (ns-lisp-exception-condition nsexception)
243    (make-condition 'ns-exception :ns-exception nsexception)))
244
245
246(defmethod ns-exception ((c condition))
247  "Map a lisp condition object to an NSException.  Note that instances
248of the NS-EXCEPTION condition class implement this by accessing an
249instance variable."
250  ;;; Create an NSLispException with a lispid that encapsulates
251  ;;; this condition.
252
253  ;; (dbg (format nil "~a" c))
254  ;;(#_NSLog #@"Lisp exception: %@" :id (%make-nsstring (format nil "~a" c)))
255  (make-instance 'ns-lisp-exception :condition c))
256
257
258
259#+apple-objc
260(progn
261
262
263#+ppc-target
264(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
265  ;; On PPC, the "address" of an external entry point is always
266  ;; aligned on a 32-bit word boundary.  On PPC32, it can always
267  ;; be represented as a fixnum; on PPC64, it might be a pointer
268  ;; instead.
269  ;; Note that this clobbers the actual (foreign) return address,
270  ;; replacing it with the address of #__NSRaiseError.  Note also
271  ;; that storing the NSException object as the return value has
272  ;; the desired effect of causing #__NSRaiseError to be called
273  ;; with that NSException as its argument (because r3 is used both
274  ;; as the canonical return value register and used to pass the
275  ;; first argument on PPC.)
276  (process-debug-condition *current-process* condition (%get-frame-ptr))
277  (let* ((addr (%reference-external-entry-point (load-time-value (external "__NSRaiseError")))))
278    (if (typep addr 'fixnum)
279      (%set-object return-address-pointer 0 addr)
280      (setf (%get-ptr return-address-pointer 0) addr)))
281  (setf (%get-ptr return-value-pointer 0) (ns-exception condition))
282  nil)
283
284#+x8664-target
285(progn
286(defloadvar *x8664-objc-callback-error-return-trampoline*
287    (let* ((code-bytes '(#x48 #x89 #xc7      ; movq %rax %rdi
288                         #x66 #x48 #x0f #x7e #xc0 ; movd %xmm0,%rax
289                         #x52                ; pushq %rdx
290                         #xff #xe0))         ; jmp *rax
291           (nbytes (length code-bytes))
292           (ptr (%allocate-callback-pointer 16)))
293      (dotimes (i nbytes ptr)
294        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
295
296(defun objc-callback-error-return (condition return-value-pointer return-address-pointer) 
297  ;; The callback glue reserves space for %rax at return-value-pointer-8,
298  ;; for %rdx at -16, for %xmm0 at -24.  Store NS-EXCEPTION in the
299  ;; %rax slot, the address of #_objc_exception_throw in the %rdx slot, the
300  ;; original return address in the %xmm0 slot, and force a return to
301  ;; the trampoline code above.
302  (process-debug-condition *current-process* condition (%get-frame-ptr))
303  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
304        (%get-ptr return-value-pointer -16) (%get-ptr return-address-pointer 0)
305        (%get-ptr return-address-pointer 0) *x8664-objc-callback-error-return-trampoline*)
306  ;; A foreign entry point is always an integer on x8664.
307  (let* ((addr (%reference-external-entry-point (load-time-value (external "_objc_exception_throw")))))
308    (if (< addr 0)                      ;unlikely
309      (setf (%%get-signed-longlong return-value-pointer -24) addr)
310      (setf (%%get-unsigned-longlong return-value-pointer -24) addr)))
311  nil)
312
313
314)
315
316#+x8632-target
317(progn
318
319(defloadvar *x8632-objc-callback-error-return-trampoline*
320    (let* ((code-bytes '(#x83 #xec #x10      ; subl $16,%esp
321                         #x89 #x04 #x24      ; movl %eax,(%esp)
322                         #x52                ; pushl %edx
323                         #xff #xe1))         ; jmp *ecx
324           (nbytes (length code-bytes))
325           (ptr (%allocate-callback-pointer 16)))
326      (dotimes (i nbytes ptr)
327        (setf (%get-unsigned-byte ptr i) (pop code-bytes)))))
328
329(defun objc-callback-error-return (condition return-value-pointer return-address-pointer)
330  (process-debug-condition *current-process* condition (%get-frame-ptr))
331  (let* ((addr (%reference-external-entry-point (load-time-value (external "__NSRaiseError")))))
332    (setf (%get-unsigned-long return-value-pointer -12 ) addr))
333  (setf (%get-ptr return-value-pointer -8) (ns-exception condition)
334        (%get-ptr return-value-pointer -4) (%get-ptr return-address-pointer)
335        (%get-ptr return-address-pointer) *x8632-objc-callback-error-return-trampoline*)
336  nil)
337)
338
339)
340
341
342
343(defun open-main-bundle ()
344  (#/mainBundle ns:ns-bundle))
345
346;;; Create a new immutable dictionary just like src, replacing the
347;;; value of each key in key-value-pairs with the corresponding value.
348(defun copy-dictionary (src &rest key-value-pairs)
349  (declare (dynamic-extent key-value-pairs))
350  ;(#_NSLog #@"src = %@" :id src)
351  (let* ((count (#/count src))
352         (enum (#/keyEnumerator src))
353         (keys (#/arrayWithCapacity: ns:ns-mutable-array count))
354         (values (#/arrayWithCapacity: ns:ns-mutable-array count)))
355    (loop
356        (let* ((nextkey (#/nextObject enum)))
357          (when (%null-ptr-p nextkey)
358            (return))
359          (do* ((kvps key-value-pairs (cddr kvps))
360                (newkey (car kvps) (car kvps))
361                (newval (cadr kvps) (cadr kvps)))
362               ((null kvps)
363                ;; Copy the key, value pair from the src dict
364                (#/addObject: keys nextkey)
365                (#/addObject: values (#/objectForKey: src nextkey)))
366            (when (#/isEqualToString: nextkey newkey)
367              (#/addObject: keys nextkey)
368              (#/addObject: values newval)
369              (return)))))
370    (make-instance 'ns:ns-dictionary
371                   :with-objects values
372                   :for-keys keys)))
373
374
375(defun nsobject-description (nsobject)
376  "Returns a lisp string that describes nsobject.  Note that some
377NSObjects describe themselves in more detail than others."
378  (with-autorelease-pool
379      (lisp-string-from-nsstring  (#/description nsobject))))
380
381
382
383
384;;; This can fail if the nsstring contains non-8-bit characters.
385(defun lisp-string-from-nsstring-substring (nsstring start length)
386  (%stack-block ((cstring (1+ length)))
387    (#/getCString:maxLength:range:remainingRange:
388       nsstring  cstring  length (ns:make-ns-range start length) +null-ptr+)
389    (%get-cstring cstring)))
390
391(def-standard-initial-binding *listener-autorelease-pool* nil)
392
393(setq *listener-autorelease-pool* (create-autorelease-pool))
394
395(define-toplevel-command :global rap () "Release and reestablish *LISTENER-AUTORELEASE-POOL*"
396  (when (eql *break-level* 0)
397    (without-interrupts
398     (when (boundp '*listener-autorelease-pool*)
399       (let* ((old *listener-autorelease-pool*))
400         (if old (release-autorelease-pool old))
401         (setq *listener-autorelease-pool* (create-autorelease-pool)))))))
402
403#+apple-objc
404(defun show-autorelease-pools ()
405  (objc-message-send (@class ns-autorelease-pool) "showPools" :void))
406
407#+gnu-objc
408(defun show-autorelease-pools ()
409  (do* ((current (objc-message-send (@class ns-autorelease-pool) "currentPool")
410                 (objc-message-send current "_parentAutoreleasePool"))
411        (i 0 (1+ i)))
412       ((%null-ptr-p current) (values))
413    (format t "~& ~d : ~a [~d]"
414            i
415            (nsobject-description current)
416            (pref current :<NSA>utorelease<P>ool._released_count))))
417
418(define-toplevel-command :global sap () "Log information about current thread's autorelease-pool(s) to C's standard error stream"
419  (show-autorelease-pools))
420
421(define-toplevel-command :global kap () "Release (but don't reestablish) *LISTENER-AUTORELEASE-POOL*"
422  (when (eql *break-level* 0)
423    (without-interrupts
424     (when (boundp '*listener-autorelease-pool*)
425       (let* ((p *listener-autorelease-pool*))
426         (setq *listener-autorelease-pool* nil)
427         (release-autorelease-pool p))))))
428
429;;; Use the interfaces for an add-on ObjC framework.  We need to
430;;; tell the bridge to reconsider what it knows about the type
431;;; signatures of ObjC messages, since the new headers may define
432;;; a method whose type signature differs from the message's existing
433;;; methods.  (This probably doesn't happen too often, but it's
434;;; possible that some SENDs that have already been compiled would
435;;; need to be recompiled with that augmented method type info, e.g.,
436;;; because ambiguity was introduced.)
437
438(defun augment-objc-interfaces (dirname)
439  (use-interface-dir dirname)
440  (register-objc-class-decls)
441  (update-objc-method-info))
442
443;;; A list of "standard" locations which are known to contain
444;;; framework bundles.  We should look in ~/Library/Frameworks/" first,
445;;; if it exists.
446(defparameter *standard-framework-directories*
447  (list #p"/Library/Frameworks/"
448        #p"/System/Library/Frameworks/"))
449
450
451
452;;; This has to run during application (re-)initializtion, so it
453;;; uses lower-level bridge features.
454(defun %reload-objc-framework (path)
455  (when (probe-file path)
456    (let* ((namestring (native-translated-namestring path)))
457      (with-cstrs ((cnamestring namestring))
458        (with-nsstr (nsnamestring cnamestring (length namestring))
459          (with-autorelease-pool
460              (let* ((bundle (objc-message-send (@class "NSBundle")
461                                                "bundleWithPath:"
462                                                :id nsnamestring :id)))
463                (unless (%null-ptr-p bundle)
464                  (objc-message-send bundle "load" :<BOOL>)))))))))
465
466
467(defun load-objc-extension-framework (name)
468  (let* ((dirs *standard-framework-directories*)
469         (home-frameworks (make-pathname :defaults nil
470                                         :directory
471                                         (append (pathname-directory
472                                                  (user-homedir-pathname))
473                                                 '("Library" "Frameworks"))))
474         (fname (list (format nil "~a.framework" name))))
475    (when (probe-file home-frameworks)
476      (pushnew home-frameworks dirs :test #'equalp))
477    (dolist (d dirs)
478      (let* ((path (probe-file (make-pathname :defaults nil
479                                              :directory (append (pathname-directory d)
480                                                                 fname)))))
481        (when path
482          (let* ((namestring (native-translated-namestring path)))
483            (with-cstrs ((cnamestring namestring))
484              (with-nsstr (nsnamestring cnamestring (length namestring))
485                (with-autorelease-pool
486                    (let* ((bundle (#/bundleWithPath: ns:ns-bundle nsnamestring))
487                           (winning (unless (%null-ptr-p bundle)
488                                      t)))
489                      (when winning
490                        (let* ((libpath (#/executablePath bundle)))
491                          (unless (%null-ptr-p libpath)
492                            (open-shared-library (lisp-string-from-nsstring
493                                                  libpath))))
494                        (#/load bundle)
495                        (pushnew path *extension-framework-paths*
496                                 :test #'equalp)
497                        (map-objc-classes)
498                        ;; Update info about init messages.
499                        (register-objc-init-messages))
500                      (return winning)))))))))))
501
502(defun objc:load-framework (framework-name interfaces-name)
503  (use-interface-dir interfaces-name)
504  (or (load-objc-extension-framework framework-name)
505      (error "Can't load ObjC framework ~s" framework-name))
506  (augment-objc-interfaces interfaces-name))
507
508                     
509(defmethod print-object ((p ns:protocol) stream)
510  (print-unreadable-object (p stream :type t)
511    (format stream "~a (#x~x)"
512            (%get-cstring (#/name p))
513            (%ptr-to-int p))))
514
515                                         
516(defmethod terminate ((instance objc:objc-object))
517  (objc-message-send instance "release"))
518
519
520(provide "OBJC-SUPPORT")
Note: See TracBrowser for help on using the repository browser.