source: trunk/source/objc-bridge/bridge.lisp @ 12438

Last change on this file since 12438 was 12438, checked in by gb, 10 years ago

Conditionalize for Cocotron/Win32. Seems to mostly work (except for
some issue related to registering new selectors) and Cocotron issue #331.
Smoke-tested on OSX; seems to be OK, but there's a non-zero chance that
I broke something.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 61.9 KB
Line 
1;;;; -*- Mode: Lisp; Package: CCL -*-
2;;;; bridge.lisp
3;;;;
4;;;; A Lisp bridge for Cocoa
5;;;;
6;;;; This provides:
7;;;;   (1) Convenient Lisp syntax for instantiating ObjC classes
8;;;;   (2) Convenient Lisp syntax for invoking ObjC methods
9;;;;
10;;;; Copyright (c) 2003 Randall D. Beer
11;;;;
12;;;; This software is licensed under the terms of the Lisp Lesser GNU Public
13;;;; License, known as the LLGPL.  The LLGPL consists of a preamble and
14;;;; the LGPL. Where these conflict, the preamble takes precedence.  The
15;;;; LLGPL is available online at http://opensource.franz.com/preamble.html.
16;;;;
17;;;; Please send comments and bug reports to <beer@eecs.cwru.edu>
18
19;;; Temporary package and module stuff
20
21(in-package "CCL")
22
23(require "OBJC-RUNTIME")
24(require "NAME-TRANSLATION")
25
26;;; Used in PRINT-OBJECT methods.
27
28(defun describe-macptr-allocation-and-address (p stream)
29  (format stream " ~@[~a ~](#x~x)"
30          (%macptr-allocation-string p)
31          (%ptr-to-int p)))
32
33(defstruct typed-foreign-struct-info
34  foreign-type
35  lisp-class-name
36  initializer
37  constructor
38  with-form-name
39  predicate-name)
40
41(defparameter *typed-foreign-struct-info* ())
42
43(defun note-typed-foreign-struct-info (foreign-type lisp-class-name initializer constructor with-form-name predicate-name)
44  (let* ((info (find foreign-type *typed-foreign-struct-info* :test #'equal :key #'typed-foreign-struct-info-foreign-type)))
45    (unless info
46      (setq info (make-typed-foreign-struct-info :foreign-type foreign-type))
47      (push info *typed-foreign-struct-info*))
48    (setf (typed-foreign-struct-info-lisp-class-name info) lisp-class-name
49          (typed-foreign-struct-info-initializer info) initializer
50          (typed-foreign-struct-info-constructor info) constructor
51          (typed-foreign-struct-info-with-form-name info) with-form-name
52          (typed-foreign-struct-info-predicate-name info) predicate-name)
53    info))
54 
55;;; This gets installed as the COMPILER-MACRO-FUNCTION on any dispatch
56;;; function associated with a method that passes structures by value.
57(defun hoist-struct-constructors (whole env)
58  (declare (ignorable env))
59  (destructuring-bind (operator receiver &rest args) whole
60    ;;See if any arguments are "obviously" known structure-creation forms.
61    (if (null (dolist (arg args)
62                (if (and (consp arg)
63                         (find (car arg) *typed-foreign-struct-info* :key #'typed-foreign-struct-info-constructor))
64                  (return t))))
65      whole
66      ;;; Simplest to hoist one call, then let compiler-macroexpand
67      ;;; call us again.
68      (let* ((with-name nil)
69             (info nil)
70             (temp (gensym)))
71        (collect ((new-args))
72          (new-args operator)
73          (new-args receiver)
74          (dolist (arg args)
75            (if (or info
76                    (atom arg)
77                    (not (setq info (find (car arg) *typed-foreign-struct-info* :key #'typed-foreign-struct-info-constructor))))
78              (new-args arg)
79              (progn
80                (setq with-name (typed-foreign-struct-info-with-form-name info))
81                (if (cdr arg)
82                  (new-args `(progn (,(typed-foreign-struct-info-initializer info)
83                                     ,temp
84                                     ,@(cdr arg))
85                              ,temp))
86                  (new-args temp)))))
87          `(,with-name (,temp)
88            (values ,(new-args))))))))
89         
90       
91     
92(defun define-typed-foreign-struct-accessor (type-name lisp-accessor-name foreign-accessor &optional (transform-output #'identity) (transform-input #'identity))
93  (let* ((arg (gensym))
94         (val (gensym)))
95    `(progn
96      (declaim (inline ,lisp-accessor-name))
97      (defun ,lisp-accessor-name (,arg)
98        (if (typep ,arg ',type-name)
99          ,(funcall transform-input `(pref ,arg ,foreign-accessor))
100          (report-bad-arg ,arg ',type-name)))
101      (declaim (inline (setf ,lisp-accessor-name)))
102      (defun (setf ,lisp-accessor-name) (,val ,arg)
103        (if (typep ,arg ',type-name)
104          (setf (pref ,arg ,foreign-accessor) ,(funcall transform-output val))
105          (report-bad-arg ,arg ',type-name))))))
106
107(defun define-typed-foreign-struct-accessors (type-name tuples)
108  (collect ((body))
109    (dolist (tuple tuples `(progn ,@(body)))
110      (body (apply #'define-typed-foreign-struct-accessor type-name (cdr tuple))))))
111
112(defun define-typed-foreign-struct-initializer (init-function-name  tuples)
113  (when init-function-name
114    (let* ((struct (gensym)))
115      (collect ((initforms)
116                (args))
117        (args struct)
118        (dolist (tuple tuples)
119          (destructuring-bind (arg-name lisp-accessor foreign-accessor &optional (transform #'identity)) tuple
120            (declare (ignore lisp-accessor))
121            (args arg-name)
122            (initforms `(setf (pref ,struct ,foreign-accessor) ,(funcall transform arg-name)))))
123        `(progn
124          (declaim (inline ,init-function-name))
125          (defun ,init-function-name ,(args)
126            (declare (ignorable ,struct))
127            ,@(initforms)
128            ,struct))))))
129
130(defun define-typed-foreign-struct-creation-function (creation-function-name init-function-name foreign-type accessors)
131  (when creation-function-name
132    (let* ((struct (gensym))
133           (arg-names (mapcar #'car accessors)))
134      `(defun ,creation-function-name ,arg-names
135        (let* ((,struct (make-gcable-record ,foreign-type)))
136          (,init-function-name ,struct ,@arg-names)
137          ,struct)))))
138
139(defun define-typed-foreign-struct-class-with-form (with-form-name foreign-type init-function-name)
140  (declare (ignorable init-function-name))
141  (when with-form-name
142  `(defmacro ,with-form-name ((instance &rest inits) &body body)
143    (multiple-value-bind (body decls) (parse-body body nil)
144      `(rlet ((,instance ,,foreign-type))
145        ,@decls
146        ,@(when inits
147                `((,',init-function-name ,instance ,@inits)))
148        ,@body)))))
149         
150
151(defmacro define-typed-foreign-struct-class (class-name (foreign-type predicate-name init-function-name creation-function-name with-form-name) &rest accessors)
152  (let* ((arg (gensym)))
153    `(progn
154      (%register-type-ordinal-class (parse-foreign-type ',foreign-type) ',class-name)
155      (def-foreign-type ,class-name  ,foreign-type)
156      (declaim (inline ,predicate-name))
157      (note-typed-foreign-struct-info ',foreign-type ',class-name ',init-function-name ',creation-function-name ',with-form-name ',predicate-name)
158      (defun ,predicate-name (,arg)
159        (and (typep ,arg 'macptr)
160             (<= (the fixnum (%macptr-domain ,arg)) 1)
161             (= (the fixnum (%macptr-type ,arg))
162                (foreign-type-ordinal (load-time-value (parse-foreign-type ',foreign-type))))))
163      (eval-when (:compile-toplevel :load-toplevel :execute)
164        (setf (type-predicate ',class-name) ',predicate-name))
165      ,(define-typed-foreign-struct-initializer init-function-name accessors)
166      ,(define-typed-foreign-struct-creation-function creation-function-name init-function-name foreign-type accessors)
167      ,(define-typed-foreign-struct-class-with-form with-form-name foreign-type init-function-name)
168      ,(define-typed-foreign-struct-accessors class-name accessors)
169      ',class-name)))
170
171(eval-when (:compile-toplevel :load-toplevel :execute)
172  (defun wrap-cg-float (x)
173    `(float ,x +cgfloat-zero+)))
174
175
176#+darwin-target
177(progn
178;;; AEDesc (Apple Event Descriptor)
179
180(define-typed-foreign-struct-class ns::aedesc (:<AED>esc ns::aedesc-p ns::init-aedesc ns::make-aedesc ns::with-aedesc)
181  (descriptor-type ns::aedesc-descriptor-type :<AED>esc.descriptor<T>ype)
182  (data-handle ns::aedesc-data-handle :<AED>esc.data<H>andle))
183
184
185(defmethod print-object ((a ns::aedesc) stream)
186  (print-unreadable-object (a stream :type t :identity (%gcable-ptr-p a))
187    (unless (%null-ptr-p a)
188      (format stream "~s ~s"
189              (ns::aedesc-descriptor-type a)
190              (ns::aedesc-data-handle a)))
191    (describe-macptr-allocation-and-address a stream)))
192)
193
194;;; It's not clear how useful this would be; I think that it's
195;;; part of the ObjC 2.0 extensible iteration stuff ("foreach").
196#+apple-objc-2.0
197(define-typed-foreign-struct-class ns::ns-fast-enumeration-state (:<NSF>ast<E>numeration<S>tate ns::ns-fast-enumeration-state-p ns::init-ns-fast-enumeration-state ns::make-ns-fast-enumeration-state ns::with-ns-fast-enumeration-state))
198
199;;; NSAffineTransformStruct CGAffineTransform
200(define-typed-foreign-struct-class ns::ns-affine-transform-struct (:<NSA>ffine<T>ransform<S>truct ns::ns-affine-transform-struct-p ns::init-ns-affine-transform-struct ns::make-ns-affine-transform-struct ns::wint-ns-affine-transform-struct)
201    (m11 ns::ns-affine-transform-struct-m11 :<NSA>ffine<T>ransform<S>truct.m11 wrap-cg-float)
202    (m12 ns::ns-affine-transform-struct-m12 :<NSA>ffine<T>ransform<S>truct.m12 wrap-cg-float)
203    (m21 ns::ns-affine-transform-struct-m21 :<NSA>ffine<T>ransform<S>truct.m21 wrap-cg-float)
204    (m22 ns::ns-affine-transform-struct-m22 :<NSA>ffine<T>ransform<S>truct.m22 wrap-cg-float)
205    (tx ns::ns-affine-transform-struct-tx :<NSA>ffine<T>ransform<S>truct.t<X> wrap-cg-float)
206    (ty ns::ns-affine-transform-struct-ty :<NSA>ffine<T>ransform<S>truct.t<Y> wrap-cg-float))
207
208
209(defmethod print-object ((transform ns::ns-affine-transform-struct) stream)
210  (print-unreadable-object (transform stream :type t :identity t)
211    (format stream "~s ~s ~s ~s ~s ~s"
212            (ns::ns-affine-transform-struct-m11 transform)
213            (ns::ns-affine-transform-struct-m12 transform)
214            (ns::ns-affine-transform-struct-m21 transform)
215            (ns::ns-affine-transform-struct-m22 transform)
216            (ns::ns-affine-transform-struct-tx transform)
217            (ns::ns-affine-transform-struct-ty transform))
218    (describe-macptr-allocation-and-address transform stream)))
219
220
221
222
223
224;;; An <NSA>ffine<T>ransform<S>truct is identical to a
225;;; (:struct :<GGA>ffine<T>ransform), except for the names of its fields.
226
227(setf (foreign-type-ordinal (parse-foreign-type '(:struct :<GGA>ffine<T>ransform)))
228      (foreign-type-ordinal (parse-foreign-type :<NSA>ffine<T>ransform<S>truct)))
229
230
231(eval-when (:compile-toplevel :load-toplevel :execute)
232  (defun unwrap-boolean (form)
233    `(not (eql 0 ,form)))
234  (defun wrap-boolean (form)
235    `(if ,form 1 0)))
236
237#-cocotron-objc                         ;nyi
238(progn
239;;; NSDecimal
240(define-typed-foreign-struct-class ns::ns-decimal (:<NSD>ecimal ns::ns-decimal-p nil nil nil)
241  (nil ns::ns-decimal-exponent :<NSD>ecimal._exponent)
242  (nil ns::ns-decimal-length :<NSD>ecimal._length)
243  (nil ns::ns-decimal-is-negative :<NSD>ecimal._is<N>egative wrap-boolean unwrap-boolean)
244  (nil ns::ns-decimal-is-compact :<NSD>ecimal._is<C>ompact wrap-boolean unwrap-boolean))
245 
246
247(defun ns::init-ns-decimal (data exponent length is-negative is-compact mantissa)
248  (setf (pref data :<NSD>ecimal._exponent) exponent
249        (pref data :<NSD>ecimal._length) length
250        (pref data :<NSD>ecimal._is<N>egative) (if is-negative 1 0)
251        (pref data :<NSD>ecimal._is<C>ompact) (if is-compact 1 0))
252    (let* ((v (coerce mantissa '(vector (unsigned-byte 16) 8))))
253      (declare (type (simple-array (unsigned-byte 16) (8)) v))
254      (with-macptrs ((m (pref data :<NSD>ecimal._mantissa)))
255        (dotimes (i 8)
256          (setf (paref m (:* (:unsigned 16)) i) (aref v i))))))
257
258(defun ns::make-ns-decimal (exponent length is-negative is-compact mantissa) 
259  (let* ((data (make-gcable-record :<NSD>ecimal)))
260    (ns::init-ns-decimal data exponent length is-negative is-compact mantissa)
261    data))
262
263
264
265
266(defun ns::ns-decimal-mantissa (decimal)
267  (if (typep decimal 'ns::ns-decimal)
268    (let* ((dest (make-array 8 :element-type '(unsigned-byte 16))))
269      (with-macptrs ((m (pref decimal :<NSD>ecimal._mantissa)))
270        (dotimes (i 8 dest)
271        (setf (aref dest i) (paref m (:* (:unsigned 16)) i)))))
272    (report-bad-arg decimal 'ns::ns-decimal)))
273
274(defun (setf ns::ns-decimal-mantissa) (new decimal)
275  (if (typep decimal 'ns::ns-decimal)
276    (let* ((src (coerce new '(simple-array (unsigned-byte 16) (8)))))
277      (declare (type (simple-array (unsigned-byte 16) 8) src))
278      (with-macptrs ((m (pref decimal :<NSD>ecimal._mantissa)))
279        (dotimes (i 8 new)
280          (setf (paref m (:* (:unsigned 16)) i) (aref src i)))))
281    (report-bad-arg decimal 'ns::ns-decimal)))
282
283(defmethod print-object ((d ns::ns-decimal) stream)
284  (print-unreadable-object (d stream :type t :identity t)
285    (unless (%null-ptr-p d)
286      (format stream "exponent = ~d, length = ~s, is-negative = ~s, is-compact = ~s, mantissa = ~s" (ns::ns-decimal-exponent d) (ns::ns-decimal-length d) (ns::ns-decimal-is-negative d) (ns::ns-decimal-is-compact d) (ns::ns-decimal-mantissa d)))
287    (describe-macptr-allocation-and-address d stream)))
288
289)
290
291   
292;;; NSRect
293
294(define-typed-foreign-struct-class ns::ns-rect (:<NSR>ect ns::ns-rect-p ns::init-ns-rect ns::make-ns-rect ns::with-ns-rect)
295  (x ns::ns-rect-x :<NSR>ect.origin.x wrap-cg-float)
296  (y ns::ns-rect-y :<NSR>ect.origin.y wrap-cg-float)
297  (width ns::ns-rect-width :<NSR>ect.size.width wrap-cg-float)
298  (height ns::ns-rect-height :<NSR>ect.size.height wrap-cg-float))
299
300
301(defmethod print-object ((r ns::ns-rect) stream)
302  (print-unreadable-object (r stream :type t :identity t)
303    (unless (%null-ptr-p r)
304      (flet ((maybe-round (x)
305               (multiple-value-bind (q r) (round x)
306                 (if (zerop r) q x))))
307        (format stream "~s X ~s @ ~s,~s"
308                (maybe-round (ns::ns-rect-width r))
309                (maybe-round (ns::ns-rect-height r))
310                (maybe-round (ns::ns-rect-x r))
311                (maybe-round (ns::ns-rect-y r)))
312        (describe-macptr-allocation-and-address r stream)))))
313
314
315
316;;; NSSize
317(define-typed-foreign-struct-class ns::ns-size (:<NSS>ize ns::ns-size-p ns::init-ns-size ns::make-ns-size ns::with-ns-size)
318  (width ns::ns-size-width :<NSS>ize.width wrap-cg-float)
319  (height ns::ns-size-height :<NSS>ize.height wrap-cg-float))
320
321
322(defmethod print-object ((s ns::ns-size) stream)
323  (flet ((maybe-round (x)
324           (multiple-value-bind (q r) (round x)
325             (if (zerop r) q x))))
326    (unless (%null-ptr-p s)
327      (print-unreadable-object (s stream :type t :identity t)
328        (format stream "~s X ~s"
329                (maybe-round (ns::ns-size-width s))
330                (maybe-round (ns::ns-size-height s)))))
331    (describe-macptr-allocation-and-address s stream)))
332
333
334;;; NSPoint
335(define-typed-foreign-struct-class ns::ns-point (:<NSP>oint ns::ns-point-p ns::init-ns-point ns::make-ns-point ns::with-ns-point)
336  (x ns::ns-point-x :<NSP>oint.x wrap-cg-float)
337  (y ns::ns-point-y :<NSP>oint.y wrap-cg-float))
338
339(defmethod print-object ((p ns::ns-point) stream)
340  (flet ((maybe-round (x)
341           (multiple-value-bind (q r) (round x)
342             (if (zerop r) q x))))
343    (print-unreadable-object (p stream :type t :identity t)
344      (unless (%null-ptr-p p)
345        (format stream "~s,~s"
346                (maybe-round (ns::ns-point-x p))
347                (maybe-round (ns::ns-point-y p))))
348      (describe-macptr-allocation-and-address p stream))))
349
350
351;;; NSRange
352(define-typed-foreign-struct-class ns::ns-range (:<NSR>ange ns::ns-range-p ns::init-ns-range ns::make-ns-range ns::with-ns-range)
353  (location ns::ns-range-location :<NSR>ange.location)
354  (length ns::ns-range-length :<NSR>ange.length ))
355
356(defmethod print-object ((r ns::ns-range) stream)
357  (print-unreadable-object (r stream :type t :identity t)
358    (unless (%null-ptr-p r)
359      (format stream "~s/~s"
360              (ns::ns-range-location r)
361              (ns::ns-range-length r)))
362    (describe-macptr-allocation-and-address r stream)))
363
364
365;;; String might be stack allocated; make a copy before complaining
366;;; about it.
367(defun check-objc-message-name (string)
368  (dotimes (i (length string))
369    (let* ((ch (char string i)))
370      (unless (or (alpha-char-p ch)
371                  (digit-char-p ch 10)
372                  (eql ch #\:)
373                  (eql ch #\_))
374        (error "Illegal character ~s in ObjC message name ~s"
375               ch (copy-seq string)))))
376  (when (and (position #\: string)
377             (not (eql (char string (1- (length string))) #\:)))
378    (error "ObjC message name ~s contains colons, but last character is not a colon" (copy-seq string))))
379     
380
381(setf (pkg.intern-hook (find-package "NSFUN"))
382      'get-objc-message-info)
383
384(set-dispatch-macro-character #\# #\/ 
385                              (lambda (stream subchar numarg)
386                                (declare (ignorable subchar numarg))
387                                (let* ((token (make-array 16 :element-type 'character :fill-pointer 0 :adjustable t))
388                                       (attrtab (rdtab.ttab *readtable*)))
389                                  (when (peek-char t stream nil nil)
390                                    (loop
391                                      (multiple-value-bind (char attr)
392                                          (%next-char-and-attr stream attrtab)
393                                        (unless (eql attr $cht_cnst)
394                                          (when char (unread-char char stream))
395                                          (return))
396                                        (vector-push-extend char token))))
397                                  (unless *read-suppress*
398                                    (unless (> (length token) 0)
399                                      (signal-reader-error stream "Invalid token after #/."))
400                                    (check-objc-message-name token)
401                                    (intern token "NSFUN")))))
402
403
404;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
405;;;;                              Utilities                                 ;;;;
406;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
407
408;;; Return separate lists of the keys and values in a keyword/value list
409
410(defun keys-and-vals (klist)
411  (when (oddp (length klist))
412    (error "Invalid keyword/value list: ~S" klist))
413  (loop for l = klist then (cddr l)
414        until (null l)
415        collect (first l) into keys
416        collect (second l) into vals
417        finally (return (values keys vals))))
418
419
420;;; Return the typestring for an ObjC METHOD
421
422(defun method-typestring (method)
423  (%get-cstring #+(or apple-objc-2.0 cocotron-objc)
424                (#_method_getTypeEncoding method)
425                #-(or apple-objc-2.0 cocotron-objc)
426                (pref method :objc_method.method_types)))
427
428
429;;; Parse the ObjC message from a SENDxxx macro
430
431(defun parse-message (args)
432  (let ((f (first args))
433        (nargs (length args)))
434    (cond ((or (= nargs 1) (= nargs 2))
435           ;; (THING {VARGS})
436           (if (constantp f)
437               (%parse-message (cons (eval f) (rest args)))
438             (values f (rest args) nil)))
439          ;; (THING1 ARG1 ... THINGN ARGN)
440          ((evenp nargs)
441           (multiple-value-bind (ks vs) (keys-and-vals args)
442             (if (every #'constantp ks)
443                 (%parse-message (mapcan #'list (mapcar #'eval ks) vs))
444               (values f (rest args) nil))))
445          ;; (THING1 ARG1 ... THINGN ARGN VARGS)
446          (t (multiple-value-bind (ks vs) (keys-and-vals (butlast args))
447               (if (every #'constantp ks)
448                   (%parse-message 
449                    (nconc (mapcan #'list (mapcar #'eval ks) vs) (last args)))
450                 (values f (rest args) nil)))))))
451
452
453;;; Parse the ObjC message from the evaluated args of a %SENDxxx function
454
455(defun %parse-message (args)
456  (let ((f (first args))
457        (l (first (last args))))
458    (cond ((stringp f)
459           ;; (STRING-with-N-colons ARG1 ... ARGN {LIST})
460           (let* ((n (count #\: (the simple-string f)))
461                  (message-info (need-objc-message-info f))
462                  (args (rest args))
463                  (nargs (length args)))
464             (cond ((and (= nargs 1)
465                         (getf (objc-message-info-flags message-info)
466                               :accepts-varargs))
467                    (values f nil l))
468                   ((= nargs n) (values f args nil))
469                   ((= nargs (1+ n)) (values f (butlast args) l))
470                   (t (error "Improperly formatted argument list: ~S" args)))))
471          ((keywordp f)
472           ;; (KEY1 ARG1 ... KEYN ARGN {LIST}) or (KEY LIST)
473           (let ((nargs (length args)))
474             (cond ((and (= nargs 2) (consp l)
475                         (let* ((info (need-objc-message-info
476                                       (lisp-to-objc-message (list f)))))
477                           (getf (objc-message-info-flags info)
478                                 :accepts-varargs)))
479                    (values (lisp-to-objc-message (list f)) nil l))
480                   ((evenp nargs)
481                    (multiple-value-bind (ks vs) (keys-and-vals args)
482                      (values (lisp-to-objc-message ks) vs nil)))
483                   ((and (> nargs 1) (listp l))
484                    (multiple-value-bind (ks vs) (keys-and-vals (butlast args))
485                      (values (lisp-to-objc-message ks) vs l)))
486                 (t (error "Improperly formatted argument list: ~S" args)))))
487          ((symbolp f)
488           ;; (SYMBOL {LIST})
489           (let ((nargs (length (rest args))))
490             (cond ((= nargs 0) (values (lisp-to-objc-message (list f)) nil nil))
491                   ((= nargs 1) (values (lisp-to-objc-message (list f)) nil l))
492                   (t (error "Improperly formatted argument list: ~S" args)))))
493           (t (error "Improperly formatted argument list: ~S" args)))))
494
495
496;;; Return the declared type of FORM in ENV
497
498(defun declared-type (form env)
499  (cond ((symbolp form)
500         (multiple-value-bind (ignore ignore decls) 
501                              (variable-information form env)
502           (declare (ignore ignore))
503           (or (cdr (assoc 'type decls)) t)))
504        ((and (consp form) (eq (first form) 'the))
505         (second form))
506        (t t)))
507
508
509;;; Return the current optimization setting of KEY in ENV
510
511(defun optimization-setting (key &optional env)
512  (cadr (assoc key (declaration-information 'optimize env))))
513
514
515;;; Return the ObjC class named CNAME
516
517(defun find-objc-class (cname)
518  (%objc-class-classptr 
519   (if (symbolp cname) 
520       (find-class cname)
521     (load-objc-class-descriptor cname))))
522
523
524;;; Return the class object of an ObjC object O, signalling an error
525;;; if O is not an ObjC object
526                     
527(defun objc-class-of (o)
528  (if (objc-object-p o)
529      (class-of o)
530    (progn
531      #+debug
532      (#_NSLog #@"class name = %s" :address (pref (pref o :objc_object.isa)
533                                                  :objc_class.name))
534      (error "~S is not an ObjC object" o))))
535
536
537;;; Returns the ObjC class corresponding to the declared type OTYPE if
538;;; possible, NIL otherwise
539
540(defun get-objc-class-from-declaration (otype)
541  (cond ((symbolp otype) (lookup-objc-class (lisp-to-objc-classname otype)))
542        ((and (consp otype) (eq (first otype) '@metaclass))
543         (let* ((name (second otype))
544                (c
545                 (typecase name
546                   (string (lookup-objc-class name))
547                   (symbol (lookup-objc-class (lisp-to-objc-classname name)))
548                   (t (error "Improper metaclass typespec: ~S" otype)))))
549           (unless (null c) (objc-class-of c))))))
550
551
552;;; Returns the selector of MSG
553
554(defun get-selector (msg)
555  (%get-selector (load-objc-selector msg)))
556
557
558;;; Get the instance method structure corresponding to SEL for CLASS
559
560(defun get-method (class sel)
561  (let ((m (class-get-instance-method class sel)))
562    (if (%null-ptr-p m)
563      (error "Instances of ObjC class ~S cannot respond to the message ~S" 
564             (objc-class-name class)
565             (lisp-string-from-sel sel))
566      m)))
567
568
569;;; Get the class method structure corresponding to SEL for CLASS
570
571(defun get-class-method (class sel)
572  (let ((m (class-get-class-method class sel)))
573    (if (%null-ptr-p m)
574      (error "ObjC class ~S cannot respond to the message ~S" 
575             (objc-class-name class)
576             (lisp-string-from-sel sel))
577      m)))
578
579
580;;; For some reason, these types sometimes show up as :STRUCTs even though they
581;;; are not structure tags, but type names
582
583(defun fudge-objc-type (ftype)
584  (if (equal ftype '(:STRUCT :<NSD>ecimal))
585      :<NSD>ecimal
586    ftype))
587
588
589;;; Returns T if the result spec requires a STRET for its return, NIL otherwise
590;;; RSPEC may be either a number (in which case it is interpreted as a number
591;;; of words) or a foreign type spec acceptable to PARSE-FOREIGN-TYPE. STRETS
592;;; must be used when a structure larger than 4 bytes is returned
593
594(defun requires-stret-p (rspec)
595  (when (member rspec '(:DOUBLE-FLOAT :UNSIGNED-DOUBLEWORD :SIGNED-DOUBLEWORD) 
596                :test #'eq)
597    (return-from requires-stret-p nil))
598  (setq rspec (fudge-objc-type rspec))
599  (if (numberp rspec) 
600    (> rspec 1)
601    (> (ensure-foreign-type-bits (parse-foreign-type rspec)) target::nbits-in-word)))
602
603
604;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
605;;;;                      Stret Convenience Stuff                           ;;;;
606;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
607
608;;; Allocate any temporary storage necessary to hold strets required
609;;; AT TOPLEVEL in the value forms.  Special recognition is given to
610;;; SENDs involving strets and to stret pseudo-functions
611;;; NS-MAKE-POINT, NS-MAKE-RANGE, NS-MAKE-RECT and NS-MAKE-SIZE
612
613(defmacro slet (varforms &body body &environment env)
614  (multiple-value-bind (clean-body decls) (parse-body body env nil)
615    (loop with r and s
616          for (var val) in varforms
617          do (multiple-value-setq (r s) (sletify val t var))
618          collect r into rvarforms
619          unless (null s) collect s into stretforms
620          finally 
621          (return
622           `(rlet ,rvarforms
623              ,@decls
624              ,@stretforms
625              ,@clean-body)))))
626
627
628;;; Note that SLET* does not allow declarations
629
630(defmacro slet* (varforms &body body &environment env)
631  (if (= (length varforms) 1)
632      `(slet ,varforms ,@body)
633    `(slet ,(list (first varforms))
634       (slet* ,(rest varforms) ,@body))))
635
636
637;;; Collect the info necessary to transform a SLET into an RLET
638
639(defun sletify (form &optional errorp (var (gensym)))
640  (if (listp form)
641    (case (first form)
642      (ns-make-point 
643       (assert (= (length form) 3))
644       `(,var :<NSP>oint :x ,(second form) :y ,(third form)))
645      (ns-make-rect 
646       (assert (= (length form) 5))
647       `(,var :<NSR>ect :origin.x ,(second form) :origin.y ,(third form)
648               :size.width ,(fourth form) :size.height ,(fifth form)))
649      (ns-make-range 
650       (assert (= (length form) 3))
651       `(,var :<NSR>ange :location ,(second form) :length ,(third form)))
652      (ns-make-size
653       (assert (= (length form) 3))
654       `(,var :<NSS>ize :width ,(second form) :height ,(third form)))
655      (send
656       (let* ((info (get-objc-message-info (parse-message (cddr form)))))
657         (if (null info)
658           (error "Can't determine message being sent in ~s" form))
659         (let* ((rtype (objc-method-info-result-type
660                        (car (objc-message-info-methods info)))))
661           (if (getf (objc-message-info-flags info) :returns-structure)
662             (values `(,var ,(if (typep rtype 'foreign-type)
663                                 (unparse-foreign-type rtype)
664                                 rtype))
665                     `(send/stret ,var ,@(rest form)))
666             (if errorp
667               (error "NonSTRET SEND in ~S" form)
668               form)))))
669      (send-super
670       (let* ((info (get-objc-message-info (parse-message (cddr form)))))
671         (if (null info)
672           (error "Can't determine message being sent in ~s" form))
673         (let* ((rtype (objc-method-info-result-type
674                        (car (objc-message-info-methods info)))))
675           (if (getf (objc-message-info-flags info) :returns-structure)
676             (values `(,var ,(if (typep rtype 'foreign-type)
677                                 (unparse-foreign-type rtype)
678                                 rtype))
679                     `(send-super/stret ,var ,@(rest form)))
680             (if errorp
681               (error "NonSTRET SEND-SUPER in ~S" form)
682               form)))))
683      (t (if errorp
684           (error "Unrecognized STRET call in ~S" form)
685           form)))
686    (if errorp
687      (error "Unrecognized STRET call in ~S" form)
688      form)))
689
690
691;;; Process the arguments to a message send as an implicit SLET, collecting
692;;; the info necessary to build the corresponding RLET
693
694(defun sletify-message-args (args)
695  (loop with svf and sif
696        for a in args
697        do (multiple-value-setq (svf sif) (sletify a))
698        unless (null sif) collect sif into sifs
699        unless (equal svf a)
700          do (setf a (first svf))
701          and collect svf into svfs
702        collect a into nargs
703        finally (return (values nargs svfs sifs))))
704 
705 
706;;; Convenience macros for some common Cocoa structures.  More
707;;; could be added
708
709(defmacro ns-max-range (r) 
710  (let ((rtemp (gensym)))
711    `(let ((,rtemp ,r))
712       (+ (pref ,rtemp :<NSR>ange.location) (pref ,rtemp :<NSR>ange.length)))))
713(defmacro ns-min-x (r) `(pref ,r :<NSR>ect.origin.x))
714(defmacro ns-min-y (r) `(pref ,r :<NSR>ect.origin.y))
715(defmacro ns-max-x (r)
716  (let ((rtemp (gensym)))
717    `(let ((,rtemp ,r))
718       (+ (pref ,r :<NSR>ect.origin.x) 
719          (pref ,r :<NSR>ect.size.width)))))
720(defmacro ns-max-y (r)
721  (let ((rtemp (gensym)))
722    `(let ((,rtemp ,r))
723       (+ (pref ,r :<NSR>ect.origin.y)
724          (pref ,r :<NSR>ect.size.height)))))
725(defmacro ns-mid-x (r)
726  (let ((rtemp (gensym)))
727    `(let ((,rtemp ,r))
728       (* 0.5 (+ (ns-min-x ,rtemp) (ns-max-x ,rtemp))))))
729(defmacro ns-mid-y (r)
730  (let ((rtemp (gensym)))
731    `(let ((,rtemp ,r))
732       (* 0.5 (+ (ns-min-y ,rtemp) (ns-max-y ,rtemp))))))
733(defmacro ns-height (r) `(pref ,r :<NSR>ect.size.height))
734(defmacro ns-width (r) `(pref ,r :<NSR>ect.size.width))
735
736
737;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
738;;;;                             Type Stuff                                 ;;;;
739;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
740
741
742
743(defvar *objc-message-info* (make-hash-table :test #'equal :size 800))
744
745(defun result-type-requires-structure-return (result-type)
746  ;; Use objc-msg-send-stret for all methods that return
747  ;; record types.
748  (or (typep result-type 'foreign-record-type)
749      (and (not (typep result-type 'foreign-type))
750           (typep (parse-foreign-type result-type) 'foreign-record-type))))
751
752(defvar *objc-method-signatures* (make-hash-table :test #'equal))
753
754(defstruct objc-method-signature-info
755  type-signature
756  function
757  super-function)
758
759(defun objc-method-signature-info (sig)
760  (or (gethash sig *objc-method-signatures*)
761      (setf (gethash sig *objc-method-signatures*)
762            (make-objc-method-signature-info
763             :type-signature sig
764             :function (compile-send-function-for-signature  sig)
765             :super-function (%compile-send-function-for-signature  sig t)))))
766
767(defun concise-foreign-type (ftype)
768  (if (typep ftype 'foreign-record-type)
769    (let* ((name (foreign-record-type-name ftype)))
770      (if name
771        `(,(foreign-record-type-kind ftype) ,name)
772        (unparse-foreign-type ftype)))
773    (if (objc-id-type-p ftype)
774      :id
775      (if (typep ftype 'foreign-pointer-type)
776        (let* ((to (foreign-pointer-type-to ftype)))
777          (if (null to)
778            '(:* :void)
779            `(:* ,(concise-foreign-type to))))
780        (if (typep ftype 'foreign-type)
781          (unparse-foreign-type ftype)
782          ftype)))))
783
784
785;;; Not a perfect mechanism.
786(defclass objc-dispatch-function (funcallable-standard-object)
787    ()
788  (:metaclass funcallable-standard-class))
789
790(defmethod print-object ((o objc-dispatch-function) stream)
791  (print-unreadable-object (o stream :type t :identity t)
792    (let* ((name (function-name o)))
793      (when name
794        (format stream "~s" name)))))
795
796
797
798
799(declaim (inline check-receiver))
800
801;;; Return a NULL pointer if RECEIVER is a null pointer.
802;;; Otherwise, insist that it's an ObjC object of some sort, and return NIL.
803(defun check-receiver (receiver)
804  (if (%null-ptr-p receiver)
805    (%null-ptr)
806    (let* ((domain (%macptr-domain receiver))
807           (valid (eql domain *objc-object-domain*)))
808      (declare (fixnum domain))
809      (when (zerop domain)
810        (if (recognize-objc-object receiver)
811          (progn (%set-macptr-domain receiver *objc-object-domain*)
812                 (setq valid t))))
813      (unless valid
814        (report-bad-arg receiver 'objc:objc-object)))))
815
816(defmethod shared-initialize :after ((gf objc-dispatch-function) slot-names &key message-info &allow-other-keys)
817  (declare (ignore slot-names))
818  (if message-info
819    (let* ((ambiguous-methods (getf (objc-message-info-flags message-info) :ambiguous))
820           (selector (objc-message-info-selector message-info))
821           (first-method (car (objc-message-info-methods message-info))))
822      (lfun-bits gf (dpb (1+ (objc-message-info-req-args message-info))
823                         $lfbits-numreq
824                         (logior (ash
825                                  (if (getf (objc-message-info-flags message-info)
826                                            :accepts-varargs)
827                                    1
828                                    0)
829                                  $lfbits-rest-bit)
830                                 (logandc2 (lfun-bits gf) (ash 1 $lfbits-aok-bit)))))
831      (flet ((signature-function-for-method (m)
832               (let* ((signature-info (objc-method-info-signature-info m)))
833                 (or (objc-method-signature-info-function signature-info)
834                     (setf (objc-method-signature-info-function signature-info)
835                           (compile-send-function-for-signature
836                                    (objc-method-signature-info-type-signature signature-info)))))))
837                     
838      (if (null ambiguous-methods)
839        ;; Pick an arbitrary method, since all methods have the same
840        ;; signature.
841        (let* ((function (signature-function-for-method first-method)))
842          (set-funcallable-instance-function
843           gf
844           (nfunction
845            send-unambiguous-message
846            (lambda (receiver &rest args)
847               (declare (dynamic-extent args))
848               (or (check-receiver receiver)
849                   (with-ns-exceptions-as-errors 
850                       (apply function receiver selector args)))))))
851        (let* ((protocol-pairs (mapcar #'(lambda (pm)
852                                           (cons (lookup-objc-protocol
853                                                  (objc-method-info-class-name pm))
854                                                 (signature-function-for-method
855                                                  pm)))
856                                       (objc-message-info-protocol-methods message-info)))
857               (method-pairs (mapcar #'(lambda (group)
858                                         (cons (mapcar #'(lambda (m)
859                                                           (get-objc-method-info-class m))
860                                                       group)
861                                               (signature-function-for-method (car group))))
862                                     (objc-message-info-ambiguous-methods message-info)))
863               (default-function (if method-pairs
864                                   (prog1 (cdar (last method-pairs))
865                                     (setq method-pairs (nbutlast method-pairs)))
866                                   (prog1 (cdr (last protocol-pairs))
867                                     (setq protocol-pairs (nbutlast protocol-pairs))))))
868          (set-funcallable-instance-function
869           gf
870           (nfunction
871            send-unambiguous-message
872            (lambda (receiver &rest args)
873               (declare (dynamic-extent args))
874               (or (check-receiver receiver)
875                   (let* ((function
876                           (or (dolist (pair protocol-pairs)
877                                 (when (conforms-to-protocol receiver (car pair))
878                                   (return (cdr pair))))
879                               (block m
880                                 (dolist (pair method-pairs default-function)
881                                   (dolist (class (car pair))
882                                     (when (typep receiver class)
883                                       (return-from m (cdr pair)))))))))
884                     (with-ns-exceptions-as-errors
885                         (apply function receiver selector args)))))))))))
886    (with-slots (name) gf
887      (set-funcallable-instance-function
888       gf
889       #'(lambda (&rest args)
890           (error "Unknown ObjC message ~a called with arguments ~s"
891                  (symbol-name name) args))))))
892                                             
893
894(defun %call-next-objc-method (self class selector sig &rest args)
895  (declare (dynamic-extent args))
896  (rlet ((s :objc_super #+(or apple-objc cocotron-objc) :receiver #+gnu-objc :self self
897            #+(or apple-objc-2.0 cocotron-objc)  :super_class #-(or apple-objc-2.0 cocotron-objc) :class
898            #+(or apple-objc-2.0 cocotron-objc) (#_class_getSuperclass class)
899            #-(or apple-objc-2.0 cocotron-objc) (pref class :objc_class.super_class)))
900    (let* ((siginfo (objc-method-signature-info sig))
901           (function (or (objc-method-signature-info-super-function siginfo)
902                         (setf (objc-method-signature-info-super-function siginfo)
903                               (%compile-send-function-for-signature sig t)))))
904      (with-ns-exceptions-as-errors
905          (apply function s selector args)))))
906
907
908(defun %call-next-objc-class-method (self class selector sig &rest args)
909  (rlet ((s :objc_super #+(or apple-objc cocotron-objc) :receiver #+gnu-objc :self self
910            #+(or apple-objc-2.0 cocotron-objc) :super_class #-(or apple-objc-2.0 cocotron-objc) :class
911            #+(or apple-objc-2.0 cocotron-objc) (#_class_getSuperclass (pref class :objc_class.isa))
912            #-(or apple-objc-2.0 cocotron-objc) (pref (pref class #+apple-objc :objc_class.isa #+gnu-objc :objc_class.class_pointer) :objc_class.super_class)))
913    (let* ((siginfo (objc-method-signature-info sig))
914           (function (or (objc-method-signature-info-super-function siginfo)
915                         (setf (objc-method-signature-info-super-function siginfo)
916                               (%compile-send-function-for-signature sig t)))))
917      (with-ns-exceptions-as-errors
918          (apply function s selector args)))))
919
920(defun postprocess-objc-message-info (message-info)
921  (let* ((objc-name (objc-message-info-message-name message-info))
922         (lisp-name (or (objc-message-info-lisp-name message-info)
923                        (setf (objc-message-info-lisp-name message-info)
924                              (compute-objc-to-lisp-function-name  objc-name))))
925         (gf (or (fboundp lisp-name)
926                 (setf (fdefinition lisp-name)
927                       (make-instance 'objc-dispatch-function :name lisp-name)))))
928
929    (unless (objc-message-info-selector message-info)
930      (setf (objc-message-info-selector message-info)
931            (ensure-objc-selector (objc-message-info-message-name message-info))))
932   
933    (flet ((reduce-to-ffi-type (ftype)
934             (concise-foreign-type ftype)))
935      (flet ((ensure-method-signature (m)
936               (or (objc-method-info-signature m)
937                   (setf (objc-method-info-signature m)
938                         (let* ((sig 
939                                 (cons (reduce-to-ffi-type
940                                        (objc-method-info-result-type m))
941                                       (mapcar #'reduce-to-ffi-type
942                                               (objc-method-info-arglist m)))))
943                           (setf (objc-method-info-signature-info m)
944                                 (objc-method-signature-info sig))
945                           sig)))))
946        (let* ((methods (objc-message-info-methods message-info))
947               (signatures ())
948               (protocol-methods)
949               (signature-alist ()))
950          (labels ((signatures-equal (xs ys)
951                     (and xs
952                          ys
953                          (do* ((xs xs (cdr xs))
954                                (ys ys (cdr ys)))
955                               ((or (null xs) (null ys))
956                                (and (null xs) (null ys)))
957                            (unless (foreign-type-= (ensure-foreign-type (car xs))
958                                                    (ensure-foreign-type (car ys)))
959                              (return nil))))))
960            (dolist (m methods)
961              (let* ((signature (ensure-method-signature m)))
962                (pushnew signature signatures :test #'signatures-equal)
963                (if (getf (objc-method-info-flags m) :protocol)
964                  (push m protocol-methods)
965                  (let* ((pair (assoc signature signature-alist :test #'signatures-equal)))
966                    (if pair
967                      (push m (cdr pair))
968                      (push (cons signature (list m)) signature-alist)))))))
969          (setf (objc-message-info-ambiguous-methods message-info)
970                (mapcar #'cdr
971                        (sort signature-alist
972                              #'(lambda (x y)
973                                  (< (length (cdr x))
974                                     (length (cdr y)))))))
975          (setf (objc-message-info-flags message-info) nil)
976          (setf (objc-message-info-protocol-methods message-info)
977                protocol-methods)
978          (when (cdr signatures)
979            (setf (getf (objc-message-info-flags message-info) :ambiguous) t))
980          (let* ((first-method (car methods))
981                 (first-sig (objc-method-info-signature first-method))
982                 (first-sig-len (length first-sig)))
983            (setf (objc-message-info-req-args message-info)
984                  (1- first-sig-len))
985            ;; Whether some arg/result types vary or not, we want to insist
986            ;; on (a) either no methods take a variable number of arguments,
987            ;; or all do, and (b) either no method uses structure-return
988            ;; conventions, or all do. (It's not clear that these restrictions
989            ;; are entirely reasonable in the long run; in the short term,
990            ;; they'll help get things working.)
991            (flet ((method-returns-structure (m)
992                     (result-type-requires-structure-return
993                      (objc-method-info-result-type m)))
994                   (method-accepts-varargs (m)
995                     (eq (car (last (objc-method-info-arglist m)))
996                         *void-foreign-type*))
997                   (method-has-structure-arg (m)
998                     (dolist (arg (objc-method-info-arglist m))
999                       (when (typep (ensure-foreign-type arg) 'foreign-record-type)
1000                         (return t)))))
1001              (when (dolist (method methods)
1002                      (when (method-has-structure-arg method)
1003                        (return t)))
1004                (setf (compiler-macro-function lisp-name)
1005                      'hoist-struct-constructors))
1006              (let* ((first-result-is-structure (method-returns-structure first-method))
1007                     (first-accepts-varargs (method-accepts-varargs first-method)))
1008                (if (dolist (m (cdr methods) t)
1009                      (unless (eq (method-returns-structure m)
1010                                  first-result-is-structure)
1011                        (return nil)))
1012                  (if first-result-is-structure
1013                    (setf (getf (objc-message-info-flags message-info)
1014                                :returns-structure) t)))
1015                (if (dolist (m (cdr methods) t)
1016                      (unless (eq (method-accepts-varargs m)
1017                                  first-accepts-varargs)
1018                        (return nil)))
1019                  (if first-accepts-varargs
1020                    (progn
1021                      (setf (getf (objc-message-info-flags message-info)
1022                                  :accepts-varargs) t)
1023                      (decf (objc-message-info-req-args message-info)))))))))
1024        (reinitialize-instance gf :message-info message-info)))))
1025         
1026;;; -may- need to invalidate cached info whenever new interface files
1027;;; are made accessible.  Probably the right thing to do is to insist
1028;;; that (known) message signatures be updated in that case.
1029(defun get-objc-message-info (message-name &optional (use-database t))
1030  (setq message-name (string message-name))
1031  (or (gethash message-name *objc-message-info*)
1032      (and use-database
1033           (let* ((info (lookup-objc-message-info message-name)))
1034             (when info
1035               (setf (gethash message-name *objc-message-info*) info)
1036               (postprocess-objc-message-info info)
1037               info)))))
1038
1039(defun need-objc-message-info (message-name)
1040  (or (get-objc-message-info message-name)
1041      (error "Undeclared message: ~s" message-name)))
1042
1043;;; Should be called after using new interfaces that may define
1044;;; new methods on existing messages.
1045(defun update-objc-method-info ()
1046  (maphash #'(lambda (message-name info)
1047               (lookup-objc-message-info message-name info)
1048               (postprocess-objc-message-info info))
1049           *objc-message-info*))
1050
1051
1052;;; Of the method declarations (OBJC-METHOD-INFO structures) associated
1053;;; with the message-declaration (OBJC-MESSAGE-INFO structure) M,
1054;;; return the one that seems to be applicable for the object O.
1055;;; (If there's no ambiguity among the declared methods, any method
1056;;; will do; this just tells runtime %SEND functions how to compose
1057;;; an %FF-CALL).
1058(defun %lookup-objc-method-info (m o)
1059  (let* ((methods (objc-message-info-methods m))
1060         (ambiguous (getf (objc-message-info-flags m) :ambiguous)))
1061    (if (not ambiguous)
1062      (car methods)
1063      (or 
1064       (dolist (method methods)
1065         (let* ((mclass (get-objc-method-info-class method)))
1066           (if (typep o mclass)
1067             (return method))))
1068       (error "Can't determine ObjC method type signature for message ~s, object ~s" (objc-message-info-message-name m) o)))))
1069
1070(defun resolve-existing-objc-method-info (message-info class-name class-p result-type args)
1071  (let* ((method-info (dolist (m (objc-message-info-methods message-info))
1072                        (when (and (eq (getf (objc-method-info-flags m) :class-p)
1073                                       class-p)
1074                                   (equal (objc-method-info-class-name m)
1075                                          class-name))
1076                          (return m)))))
1077    (when method-info
1078      (unless (and (foreign-type-= (ensure-foreign-type (objc-method-info-result-type method-info))
1079                                   (parse-foreign-type result-type))
1080                   (do* ((existing (objc-method-info-arglist method-info) (cdr existing))
1081                         (proposed args (cdr proposed)))
1082                        ((null existing) (null proposed))
1083                     (unless (foreign-type-= (ensure-foreign-type (car existing))
1084                                             (parse-foreign-type (car proposed)))
1085                       (return nil))))
1086        (cerror "Redefine existing method to have new type signature."
1087                "The method ~c[~a ~a] is already declared to have type signature ~s; the new declaration ~s is incompatible." (if class-p #\+ #\-) class-name (objc-message-info-message-name message-info) (objc-method-info-signature method-info) (cons result-type args))
1088        (setf (objc-method-info-arglist method-info) args
1089              (objc-method-info-result-type method-info) result-type
1090              (objc-method-info-signature method-info) nil
1091              (objc-method-info-signature-info method-info) nil))
1092      method-info)))
1093
1094(defvar *objc-verbose* nil)
1095
1096;;; Still not right; we have to worry about type conflicts with
1097;;; shadowed methods, as well.
1098(defun %declare-objc-method (message-name class-name class-p result-type args)
1099  (let* ((info (get-objc-message-info message-name)))
1100    (unless info
1101      (when (or *objc-verbose* *compile-print*)
1102        (format *error-output* "~&; Note: defining new ObjC message ~c[~a ~a]" (if class-p #\+ #\-) class-name message-name))
1103      (setq info (make-objc-message-info :message-name message-name))
1104      (setf (gethash message-name *objc-message-info*) info))
1105    (let* ((was-ambiguous (getf (objc-message-info-flags info) :ambiguous))
1106           (method-info (or (resolve-existing-objc-method-info info class-name class-p result-type args)
1107                            (make-objc-method-info :message-info info
1108                                                   :class-name class-name
1109                                                   :result-type result-type
1110                                                   :arglist args
1111                                                   :flags (if class-p '(:class t))))))
1112      (pushnew method-info (objc-message-info-methods info))
1113      (postprocess-objc-message-info info)
1114      (if (and (getf (objc-message-info-flags info) :ambiguous)
1115               (not was-ambiguous))
1116        (warn "previously declared methods on ~s all had the same type signature, but ~s introduces ambiguity" message-name method-info))
1117           
1118      (objc-method-info-signature method-info))))
1119
1120
1121
1122;;; TRANSLATE-FOREIGN-ARG-TYPE doesn't accept :VOID
1123
1124(defun translate-foreign-result-type (ftype)
1125  (ensure-foreign-type-bits (parse-foreign-type ftype))
1126  (if (eq ftype :void)
1127    :void
1128    (translate-foreign-arg-type ftype)))
1129
1130
1131
1132
1133
1134;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1135;;;;                        Invoking ObjC Methods                           ;;;;
1136;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1137
1138
1139;;; The SEND and SEND/STRET macros
1140
1141(defmacro send (o msg &rest args &environment env)
1142  (make-optimized-send o msg args env))
1143
1144(defmacro send/stret (s o msg &rest args &environment env)
1145  (make-optimized-send o msg args env s))
1146
1147
1148
1149
1150;;; Optimize special cases of SEND and SEND/STRET
1151
1152(defun make-optimized-send (o msg args env  &optional s super sclassname)
1153  (multiple-value-bind (msg args vargs) (parse-message (cons msg args))
1154    (let* ((message-info (get-objc-message-info msg)))
1155      (if (null message-info)
1156        (error "Unknown message: ~S" msg))
1157      ;; If a vararg exists, make sure that the message can accept it
1158      (when (and vargs (not (getf (objc-message-info-flags message-info)
1159                                  :accepts-varargs)))
1160        (error "Message ~S cannot accept a variable number of arguments" msg))
1161      (unless (= (length args) (objc-message-info-req-args message-info))
1162        (error "Message ~S requires ~a ~d args, but ~d were provided."
1163               msg
1164               (if vargs "at least" "exactly")
1165               (objc-message-info-req-args message-info)
1166               (length args)))
1167      (multiple-value-bind (args svarforms sinitforms) (sletify-message-args args)
1168        (let* ((ambiguous (getf (objc-message-info-flags message-info) :ambiguous))
1169               (methods (objc-message-info-methods message-info))
1170               (method (if (not ambiguous) (car methods))))
1171          (when ambiguous
1172            (let* ((class (if sclassname 
1173                            (find-objc-class sclassname)
1174                            (get-objc-class-from-declaration (declared-type o env)))))
1175              (if class
1176                (dolist (m methods)
1177                  (unless (getf (objc-method-info-flags m) :protocol)
1178                    (let* ((mclass (or (get-objc-method-info-class m)
1179                                       (error "Can't find ObjC class named ~s"
1180                                              (objc-method-info-class-name m)))))
1181                      (when (and class (subtypep class mclass))
1182                        (return (setq method m)))))))))
1183          (if method
1184            (build-call-from-method-info method
1185                                         args
1186                                         vargs
1187                                         o
1188                                         msg
1189                                         svarforms
1190                                         sinitforms
1191                                         s
1192                                         super)
1193            (build-ambiguous-send-form message-info
1194                                       args
1195                                       vargs
1196                                       o
1197                                       msg
1198                                       svarforms
1199                                       sinitforms
1200                                       s
1201                                       super)))))))
1202
1203   
1204;;; WITH-NS-EXCEPTIONS-AS-ERRORS is only available in OpenMCL 0.14 and above
1205
1206#-openmcl-native-threads
1207(defmacro with-ns-exceptions-as-errors (&body body)
1208  `(progn ,@body))
1209
1210
1211;;; Return a call to the method specified by SEL on object O, with the args
1212;;; specified by ARGSPECS.  This decides whether a normal or stret call is
1213;;; needed and, if the latter, uses the memory S to hold the result. If SUPER
1214;;; is nonNIL, then this builds a send to super.  Finally, this also
1215;;; coerces return #$YES/#$NO values to T/NIL. The entire call takes place
1216;;; inside an implicit SLET.
1217
1218(defun build-call (o sel msg argspecs svarforms sinitforms &optional s super)
1219  `(with-ns-exceptions-as-errors
1220     (rlet ,svarforms
1221       ,@sinitforms
1222       ,(let ((rspec (first (last argspecs))))
1223          (if (requires-stret-p rspec)
1224            (if (null s)
1225              ;; STRET required but not provided
1226              (error "The message ~S must be sent using SEND/STRET" msg)
1227              ;; STRET required and provided, use stret send
1228              (if (null super)
1229                ;; Regular stret send
1230                `(progn
1231                   (objc-message-send-stret ,s ,o ,(cadr sel)
1232                    ,@(append (butlast argspecs) (list :void)))
1233                   ,s)
1234                ;; Super stret send
1235                `(progn
1236                   (objc-message-send-super-stret ,s ,super ,(cadr sel)
1237                    ,@(append (butlast argspecs) (list :void)))
1238                   ,s)))
1239            (if (null s)
1240              ;; STRET not required and not provided, use send
1241              (if (null super)
1242                ;; Regular send
1243                (if (eq rspec :<BOOL>)
1244                  `(coerce-from-bool
1245                    (objc-message-send ,o ,(cadr sel) ,@argspecs))
1246                  `(objc-message-send ,o ,(cadr sel) ,@argspecs))
1247                ;; Super send
1248                (if (eq rspec :<BOOL>)
1249                  `(coerce-from-bool
1250                    (objc-message-send-super ,super ,(cadr sel) ,@argspecs))
1251                  `(objc-message-send-super ,super ,(cadr sel) ,@argspecs)))
1252              ;; STRET not required but provided
1253              (error "The message ~S must be sent using SEND" msg)))))))
1254
1255(defun objc-id-type-p (foreign-type)
1256  (and (typep foreign-type 'foreign-pointer-type)
1257       (let* ((to (foreign-pointer-type-to foreign-type)))
1258         (and (typep to 'foreign-record-type)
1259              (eq :struct (foreign-record-type-kind to))
1260              (not (null (progn (ensure-foreign-type-bits to) (foreign-record-type-fields to))))
1261              (let* ((target (foreign-record-field-type (car (foreign-record-type-fields to)))))
1262                (and (typep target 'foreign-pointer-type)
1263                     (let* ((target-to (foreign-pointer-type-to target)))
1264                       (and (typep target-to 'foreign-record-type)
1265                            (eq :struct (foreign-record-type-kind target-to))
1266                            (eq :objc_class (foreign-record-type-name target-to))))))))))
1267
1268(defun unique-objc-classes-in-method-info-list (method-info-list)
1269  (if (cdr method-info-list)                     ; if more than 1 class
1270    (flet ((subclass-of-some-other-class (c)
1271             (let* ((c-class (get-objc-method-info-class c)))
1272               (dolist (other method-info-list)
1273                 (unless (eq other c)
1274                   (when (subtypep c-class (get-objc-method-info-class other))
1275                   (return t)))))))
1276      (remove-if #'subclass-of-some-other-class method-info-list))
1277    method-info-list))
1278 
1279(defun get-objc-method-info-class (method-info)
1280  (or (objc-method-info-class-pointer method-info)
1281      (setf (objc-method-info-class-pointer method-info)
1282            (let* ((c (lookup-objc-class (objc-method-info-class-name method-info) nil)))
1283              (when c
1284                (let* ((meta-p (getf (objc-method-info-flags method-info) :class)))
1285                  (if meta-p
1286                    (with-macptrs ((m (pref c :objc_class.isa)))
1287                      (canonicalize-registered-metaclass m))
1288                    (canonicalize-registered-class c))))))))
1289
1290;;; Generate some sort of CASE or COND to handle an ambiguous message
1291;;; send (where the signature of the FF-CALL depends on the type of the
1292;;; receiver.)
1293;;; AMBIGUOUS-METHODS is a list of lists of OBJC-METHOD-INFO structures,
1294;;; where the methods in each sublist share the same type signature.  It's
1295;;; sorted so that more unique method/signature combinations appear first
1296;;; (and are easier to special-case via TYPECASE.)
1297(defun build-send-case (ambiguous-methods
1298                        args
1299                        vargs
1300                        receiver
1301                        msg
1302                        s
1303                        super
1304                        protocol-methods)
1305  (flet ((method-class-name (m)
1306           (let* ((mclass (get-objc-method-info-class m)))
1307             (unless mclass
1308               (error "Can't find class with ObjC name ~s"
1309                      (objc-method-info-class-name m)))
1310             (class-name mclass))))
1311
1312    (collect ((clauses))
1313      (let* ((protocol (gensym))
1314             (protocol-address (gensym)))
1315        (dolist (method protocol-methods)
1316          (let* ((protocol-name (objc-method-info-class-name method)))
1317            (clauses `((let* ((,protocol (lookup-objc-protocol ,protocol-name))
1318                              (,protocol-address (and ,protocol (objc-protocol-address ,protocol))))
1319                         (and ,protocol-address
1320                              (objc-message-send ,receiver
1321                                                 "conformsToProtocol:"
1322                                                 :address ,protocol-address
1323                                                 :<BOOL>)))
1324                       ,(build-internal-call-from-method-info
1325                         method args vargs receiver msg s super))))))
1326      (do* ((methods ambiguous-methods (cdr methods)))
1327           ((null (cdr methods))
1328            (when ambiguous-methods
1329              (clauses `(t
1330                         ,(build-internal-call-from-method-info
1331                           (caar methods) args vargs receiver msg s super)))))
1332        (clauses `(,(if (cdar methods)
1333                        `(or ,@(mapcar #'(lambda (m)
1334                                           `(typep ,receiver
1335                                             ',(method-class-name m)))
1336                                       (unique-objc-classes-in-method-info-list
1337                                        (car methods))))
1338                        `(typep ,receiver ',(method-class-name (caar methods))))
1339                   ,(build-internal-call-from-method-info
1340                     (caar methods) args vargs receiver msg s super))))
1341      `(cond
1342        ,@(clauses)))))
1343
1344(defun build-ambiguous-send-form (message-info args vargs o msg svarforms sinitforms s super)
1345  (let* ((receiver (gensym))
1346         (caseform (build-send-case
1347                    (objc-message-info-ambiguous-methods message-info)
1348                    args
1349                    vargs
1350                    receiver
1351                    msg
1352                    s
1353                    super
1354                    (objc-message-info-protocol-methods message-info))))
1355    `(with-ns-exceptions-as-errors
1356      (rlet ,svarforms
1357        ,@sinitforms
1358        (let* ((,receiver ,o))
1359          ,caseform)))))
1360
1361
1362;;; Generate the "internal" part of a method call; the "external" part
1363;;; has established ObjC exception handling and handled structure-return
1364;;  details
1365(defun build-internal-call-from-method-info (method-info args vargs o msg s super)
1366  (let* ((arglist ()))
1367    (collect ((specs))
1368      (do* ((args args (cdr args))
1369            (argtypes (objc-method-info-arglist method-info) (cdr argtypes))
1370            (reptypes (cdr (objc-method-info-signature method-info)) (cdr reptypes)))
1371           ((null args) (setq arglist (append (specs) vargs)))
1372        (let* ((reptype (if (objc-id-type-p (car argtypes)) :id (car reptypes)))
1373               (arg (car args)))
1374          (specs reptype)
1375          (specs arg)))
1376      ;;(break "~& arglist = ~s" arglist)
1377      (if (result-type-requires-structure-return
1378           (objc-method-info-result-type method-info))
1379        (if (null s)
1380          ;; STRET required but not provided
1381          (error "The message ~S must be sent using SEND/STRET" msg)
1382          (if (null super)
1383            `(objc-message-send-stret ,s ,o ,msg ,@arglist ,(car (objc-method-info-signature method-info)))
1384            `(objc-message-send-super-stret ,s ,super ,msg ,@arglist ,(car (objc-method-info-signature method-info)))))
1385        (if s
1386          ;; STRET provided but not required
1387          (error "The message ~S must be sent using SEND" msg)
1388          (let* ((result-spec (car (objc-method-info-signature method-info)))
1389                 (form (if super
1390                         `(objc-message-send-super ,super ,msg ,@arglist ,result-spec)
1391                         `(objc-message-send ,o ,msg ,@arglist ,result-spec))))
1392            form))))))
1393 
1394(defun build-call-from-method-info (method-info args vargs o  msg  svarforms sinitforms s super)
1395  `(with-ns-exceptions-as-errors
1396    (rlet ,svarforms
1397      ,@sinitforms
1398      ,(build-internal-call-from-method-info
1399        method-info
1400        args
1401        vargs
1402        o
1403        msg
1404        s
1405        super))))
1406
1407 
1408
1409;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1410;;;;                       Instantiating ObjC Class                         ;;;;
1411;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1412
1413;;; A MAKE-INSTANCE like interface to ObjC object creation
1414
1415(defun make-objc-instance (cname &rest initargs)
1416  (declare (dynamic-extent initargs))
1417  (multiple-value-bind (ks vs) (keys-and-vals initargs)
1418    (declare (dynamic-extent ks vs))
1419    (let* ((class (etypecase cname
1420                    (string (canonicalize-registered-class 
1421                             (find-objc-class cname)))
1422                    (symbol (find-class cname))
1423                    (class cname))))
1424      (send-objc-init-message (#/alloc class) ks vs))))
1425
1426
1427
1428
1429
1430;;; Provide the BRIDGE module
1431
1432(provide "BRIDGE")
Note: See TracBrowser for help on using the repository browser.