source: trunk/source/lib/pathnames.lisp @ 8765

Last change on this file since 8765 was 8765, checked in by gb, 13 years ago

In DIRECTORY, ignore emacs lockfiles by default.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 20.4 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   Portions copyright (C) 2001 Clozure Associates
5;;;   This file is part of OpenMCL. 
6;;;
7;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with OpenMCL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;pathnames.lisp Pathnames for Coral Common LISP
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require 'level-2)
23  (require 'backquote)
24)
25;(defconstant $accessDenied -5000) ; put this with other errnos
26(defconstant $afpAccessDenied -5000) ; which name to use?
27
28
29
30;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
31;ANSI CL logical pathnames
32
33
34(defvar *pathname-translations-pathname*
35  (make-pathname :host "ccl" :type "pathname-translations"))
36
37(defun load-logical-pathname-translations (host)
38  ;(setq host (verify-logical-host-name host))
39  (when (not (%str-assoc host %logical-host-translations%))
40    (setf (logical-pathname-translations host)
41          (with-open-file (file (merge-pathnames (make-pathname :name host :defaults nil)
42                                                 *pathname-translations-pathname*)
43                                :element-type 'base-char)
44            (read file)))
45    T))
46
47(defun back-translate-pathname (path &optional hosts)
48  (let ((newpath (back-translate-pathname-1 path hosts)))
49    (cond ((equalp path newpath)
50           ;; (fcomp-standard-source path)
51           (namestring (pathname path)))
52          (t newpath))))
53
54
55(defun back-translate-pathname-1 (path &optional hosts)
56  (dolist (host %logical-host-translations%)
57    (when (or (null hosts) (member (car host) hosts :test 'string-equal))
58      (dolist (trans (cdr host))
59        (when (pathname-match-p path (cadr trans))
60          (let* (newpath)         
61            (setq newpath (translate-pathname path (cadr trans) (car trans) :reversible t))
62            (return-from back-translate-pathname-1 
63              (if  (equalp path newpath) path (back-translate-pathname-1 newpath hosts))))))))
64  path)
65
66
67
68; must be after back-translate-pathname
69(defun physical-pathname-p (path)
70  (let* ((path (pathname path))
71         (dir (pathname-directory path)))
72    (and dir
73         (or (not (logical-pathname-p path))
74             (not (null (memq (pathname-host path) '(nil :unspecific))))))))
75
76
77
78;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
79;File or directory Manipulations
80
81(defun unix-rename (old-name new-name)
82  (with-cstrs ((old old-name)
83               (new new-name))
84    (let* ((res (#_rename old new)))
85      (declare (fixnum res))
86      (if (zerop res)
87        (values t nil)
88        (values nil (%get-errno))))))
89
90(defun rename-file (file new-name &key (if-exists :error))
91  "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
92  file, then the associated file is renamed."
93  (let* ((original (truename file))
94         (original-namestring (native-translated-namestring original))
95         (new-name (merge-pathnames new-name original))
96         (new-namestring (native-translated-namestring new-name)))
97    (unless new-namestring
98      (error "~S can't be created." new-name))
99    (unless (and (probe-file new-name)
100                 (not (if-exists if-exists new-name)))
101      (multiple-value-bind (res error)
102                           (unix-rename original-namestring
103                                        new-namestring)
104        (unless res
105          (error "Failed to rename ~A to ~A: ~A"
106                 original new-name error))
107        (when (streamp file)
108          (setf (stream-filename file)
109                (namestring (native-to-pathname new-namestring))))
110        (values new-name original (truename new-name))))))
111
112(defun copy-file (source-path dest-path &key (if-exists :error)
113                              (preserve-attributes nil))
114  (let* ((original (truename source-path))
115         (new-name (merge-pathnames dest-path original))
116         (buffer (make-array 4096 :element-type '(unsigned-byte 8))))
117    (with-open-file (in original :direction :input
118                        :element-type '(unsigned-byte 8))
119      (with-open-file (out new-name :direction :output
120                           :if-exists if-exists
121                           :element-type '(unsigned-byte 8))
122        (loop
123          as n = (stream-read-vector in buffer 0 4096) until (eql n 0)
124          do (stream-write-vector out buffer 0 n))))
125    (when preserve-attributes
126      (copy-file-attributes original new-name))
127    (values new-name original (truename new-name))))
128
129(defun recursive-copy-directory (source-path dest-path &key test (if-exists :error))
130  ;; TODO: Support :if-exists :supersede to blow away any files not in source dir
131  (assert (directoryp source-path)(source-path)
132          "source-path is not a directory in RECURSIVE-COPY-DIRECTORY")
133  (setq if-exists (require-type if-exists '(member :overwrite :error)))
134  (setq dest-path (ensure-directory-pathname dest-path))
135  (when (eq if-exists :error)
136    (when (probe-file dest-path)
137      (if-exists if-exists dest-path))
138    ;; Skip the probe-file in recursive calls, we already know it's ok.
139    (setq if-exists :overwrite))
140  (let* ((source-dir (ensure-directory-pathname source-path))
141         (pattern (make-pathname :name :wild :type :wild :defaults source-dir))
142         (source-files (directory pattern :test test :directories t :files t)))
143    (ensure-directories-exist dest-path)
144    (dolist (f source-files)
145      (when (or (null test) (funcall test f))
146        (if (directory-pathname-p f)
147            (let ((dest-file (make-pathname :name (first (last (pathname-directory f)))
148                                            :defaults dest-path)))
149              (recursive-copy-directory f dest-file :test test :if-exists if-exists))
150            (let* ((dest-file (make-pathname :name (pathname-name f)
151                                             :type (pathname-type f)
152                                             :defaults dest-path)))
153              (copy-file f dest-file :if-exists :supersede :preserve-attributes t)))))))
154
155;;; use with caution!
156;;; blows away a directory and all its contents
157(defun recursive-delete-directory (path &key (if-does-not-exist :error))
158  (setq path (ensure-directory-pathname path))
159  (setq if-does-not-exist (require-type if-does-not-exist '(member :error nil)))
160  (when (eq if-does-not-exist :error)
161    (unless (probe-file path)
162      (if-does-not-exist if-does-not-exist path)))
163  (when (probe-file path)
164      (if (directoryp path)
165          ;; it's a directory: blow it away
166          (let* ((pattern (make-pathname :name :wild :type :wild :defaults path))
167                 (files (directory pattern :directories nil :files t))
168                 (subdirs (directory pattern :directories t :files nil))
169                 (target-pathname (native-translated-namestring path)))
170            (dolist (f files)
171              (delete-file f))
172            (dolist (d subdirs)
173              (recursive-delete-directory d :if-does-not-exist if-does-not-exist))
174            (%rmdir target-pathname))
175          ;; it's not a directory: for safety's sake, signal an error
176          (error "Pathname '~A' is not a directory" path))))
177
178;;; It's not clear that we can support anything stronger than
179;;; "advisory" ("you pretend the file's locked & I will too") file
180;;; locking under Darwin.
181
182
183
184
185(defun create-directory (path &key (mode #o777))
186  (let* ((pathname (translate-logical-pathname (merge-pathnames path)))
187         (created-p nil)
188         (parent-dirs (let* ((pd (pathname-directory pathname)))
189                        (if (eq (car pd) :relative)
190                          (pathname-directory (merge-pathnames
191                                               pathname
192                                               (mac-default-directory)))
193                          pd)))
194         (nparents (length parent-dirs)))
195    (when (wild-pathname-p pathname)
196      (error 'file-error :error-type "Inappropriate use of wild pathname ~s"
197             :pathname pathname))
198    (do* ((i 1 (1+ i)))
199         ((> i nparents) (values pathname created-p))
200      (declare (fixnum i))
201      (let* ((parent (make-pathname
202                      :name :unspecific
203                      :type :unspecific
204                      :host (pathname-host pathname)
205                      :device (pathname-device pathname)
206                      :directory (subseq parent-dirs 0 i)))
207             (parent-name (native-translated-namestring parent))
208             (parent-kind (%unix-file-kind parent-name)))
209
210        (if parent-kind
211          (unless (eq parent-kind :directory)
212            (error 'simple-file-error
213                   :error-type "Can't create directory ~s, since file ~a exists and is not a directory"
214                   :pathname pathname
215                   :format-arguments (list parent-name)))
216          (let* ((result (%mkdir parent-name mode)))
217            (declare (fixnum result))
218            (if (< result 0)
219              (signal-file-error result parent-name)
220              (setq created-p t))))))))
221
222
223(defun ensure-directories-exist (pathspec &key verbose (mode #o777))
224  "Test whether the directories containing the specified file
225  actually exist, and attempt to create them if they do not.
226  The MODE argument is an extension to control the Unix permission
227  bits.  Portable programs should avoid using the :MODE keyword
228  argument."
229  (let* ((pathname (make-directory-pathname :directory (pathname-directory (translate-logical-pathname (merge-pathnames pathspec)))))
230         (created-p nil))
231    (when (wild-pathname-p pathname)
232      (error 'file-error
233             :error-type "Inappropriate use of wild pathname ~s"
234             :pathname pathname))
235    (let ((dir (pathname-directory pathname)))
236      (if (eq (car dir) :relative)
237        (setq dir (pathname-directory (merge-pathnames
238                                       pathname
239                                       (mac-default-directory)))))
240      (loop for i from 1 upto (length dir)
241            do (let ((newpath (make-pathname
242                               :name :unspecific
243                               :type :unspecific
244                               :host (pathname-host pathname)
245                               :device (pathname-device pathname)
246                               :directory (subseq dir 0 i))))
247                 (unless (probe-file newpath)
248                   (let ((namestring (native-translated-namestring newpath)))
249                     (when verbose
250                       (format *standard-output* "~&Creating directory: ~A~%"
251                               namestring))
252                     (%mkdir namestring mode)
253                     (unless (probe-file newpath)
254                       (error 'file-error
255                              :pathname namestring
256                              :error-type "Can't create directory ~S."))
257                     (setf created-p t)))))
258      (values pathspec created-p))))
259
260(defun dirpath-to-filepath (path)
261  (setq path (translate-logical-pathname (merge-pathnames path)))
262  (let* ((dir (pathname-directory path))
263         (super (butlast dir))
264         (name (car (last dir))))
265    (when (eq name :up)
266      (setq dir (remove-up (copy-list dir)))
267      (setq super (butlast dir))
268      (setq name (car (last dir))))
269    (when (null super)
270      (signal-file-error $xnocreate path))
271    (setq path (make-pathname :directory super :name name :defaults nil))))
272
273(defun filepath-to-dirpath (path)
274  (let* ((dir (pathname-directory path))
275         (rest (file-namestring path)))
276    (make-pathname :directory (append dir (list rest)) :defaults nil)))
277 
278
279
280;Takes a pathname, returns the truename of the directory if the pathname
281;names a directory, NIL if it names an ordinary file, error otherwise.
282;E.g. (directoryp "ccl;:foo:baz") might return #P"hd:mumble:foo:baz:" if baz
283;is a dir. - should we doc this - its exported?
284(defun directoryp (path)
285  (let* ((native (native-translated-namestring path))
286         (realpath (%realpath native)))
287    (if realpath (eq (%unix-file-kind realpath) :directory))))
288         
289
290;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
291;Wildcards
292
293
294
295 
296;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
297;Directory Traversing
298
299(defmacro with-open-dir ((dirent dir) &body body)
300  `(let ((,dirent (%open-dir ,dir)))
301     (when ,dirent
302       (unwind-protect
303           (progn ,@body)
304         (close-dir ,dirent)))))
305
306(defun directory (path &key (directories nil) ;; include subdirectories
307                            (files t)         ;; include files
308                            (all t)           ;; include Unix dot files (other than dot and dot dot)
309                            (directory-pathnames t) ;; return directories as directory-pathname-p's.
310                            (include-emacs-lockfiles nil) ;; inculde .#foo
311                            test              ;; Only return pathnames matching test
312                            (follow-links t)) ;; return truename's of matching files.
313  "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
314   given pathname. Note that the interaction between this ANSI-specified
315   TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
316   means this function can sometimes return files which don't have the same
317   directory as PATHNAME."
318  (let* ((keys (list :directories directories ;list defaulted key values
319                     :files files
320                     :all all
321                     :directory-pathnames directory-pathnames
322                     :test test
323                     :include-emacs-lockfiles include-emacs-lockfiles
324                     :follow-links follow-links))
325         (path (full-pathname (merge-pathnames path) :no-error nil))
326         (dir (directory-namestring path)))
327    (declare (dynamic-extent keys))
328    (if (null (pathname-directory path))
329      (setq dir (directory-namestring (setq path
330                                            (merge-pathnames path
331                                                             (mac-default-directory))))))
332    (assert (eq (car (pathname-directory path)) :absolute) ()
333            "full-pathname returned relative path ~s??" path)
334    ;; return sorted in alphabetical order, target-Xload-level-0 depends
335    ;; on this.
336    (nreverse
337     (delete-duplicates (%directory "/" dir path '(:absolute) keys) :test #'equal))))
338
339(defun %directory (dir rest path so-far keys)
340  (multiple-value-bind (sub-dir wild rest) (%split-dir rest)
341    (%some-specific dir sub-dir wild rest path so-far keys)))
342
343(defun %some-specific (dir sub-dir wild rest path so-far keys)
344  (let* ((start 1)
345         (end (length sub-dir))
346         (full-dir (if (eq start end) dir (%str-cat dir (%substr sub-dir start end)))))
347    (while (neq start end)
348      (let ((pos (position #\/ sub-dir :start start :end end)))
349        (push (%path-std-quotes (%substr sub-dir start pos) nil "/:;*") so-far)
350        (setq start (%i+ 1 pos))))
351    (cond ((null wild)
352           (%files-in-directory full-dir path so-far keys))
353          ((string= wild "**")
354           (%all-directories full-dir rest path so-far keys))
355          (t (%one-wild full-dir wild rest path so-far keys)))))
356
357; for a * or *x*y
358(defun %one-wild (dir wild rest path so-far keys)
359  (let ((result ()) (all (getf keys :all)) name subdir)
360    (with-open-dir (dirent dir)
361      (while (setq name (%read-dir dirent))
362        (when (and (or all (neq (%schar name 0) #\.))
363                   (not (string= name "."))
364                   (not (string= name ".."))
365                   (%path-pstr*= wild name)
366                   (eq (%unix-file-kind (setq subdir (%str-cat dir name)) t) :directory))
367          (let ((so-far (cons (%path-std-quotes name nil "/;:*") so-far)))
368            (declare (dynamic-extent so-far))
369            (setq result
370                  (nconc (%directory (%str-cat subdir "/") rest path so-far keys) result))))))
371    result))
372
373(defun %files-in-directory (dir path so-far keys)
374  (let ((name (pathname-name path))
375        (type (pathname-type path))
376        (directories (getf keys :directories))
377        (files (getf keys :files))
378        (directory-pathnames (getf keys :directory-pathnames))
379        (test (getf keys :test))
380        (follow-links (getf keys :follow-links))
381        (all (getf keys :all))
382        (include-emacs-lockfiles (getf keys :include-emacs-lockfiles))
383        (result ())
384        sub dir-list ans)
385    (if (not (or name type))
386      (when directories
387        (setq ans (if directory-pathnames
388                    (%cons-pathname (reverse so-far) nil nil)
389                    (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
390        (when (and ans (or (null test) (funcall test ans)))
391          (setq result (list ans))))
392      (with-open-dir (dirent dir)
393        (while (setq sub (%read-dir dirent))
394          (when (and (or all (neq (%schar sub 0) #\.))
395                     (or include-emacs-lockfiles
396                         (and (>= (length sub) 2)
397                              (not (string= sub ".#" :end1 2))))
398                     (not (string= sub "."))
399                     (not (string= sub ".."))
400                     (%file*= name type sub))
401            (setq ans
402                  (if (eq (%unix-file-kind (%str-cat dir sub) t) :directory)
403                    (when directories
404                      (let* ((std-sub (%path-std-quotes sub nil "/;:*")))
405                        (if directory-pathnames
406                          (%cons-pathname (reverse (cons std-sub so-far)) nil nil)
407                          (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) std-sub nil))))
408                    (when files
409                      (multiple-value-bind (name type) (%std-name-and-type sub)
410                        (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type)))))
411            (when (and ans (or (null test) (funcall test ans)))
412              (push (if follow-links (or (probe-file ans) ans) ans) result))))))
413    result))
414
415(defun %all-directories (dir rest path so-far keys)
416  (let ((do-files nil)
417        (do-dirs nil)
418        (result nil)
419        (name (pathname-name path))
420        (type (pathname-type path))
421        (all (getf keys :all))
422        (test (getf keys :test))
423        (directory-pathnames (getf keys :directory-pathnames))
424        (follow-links (getf keys :follow-links))
425        sub subfile dir-list ans)
426    ;; First process the case that the ** stands for 0 components
427    (multiple-value-bind (next-dir next-wild next-rest) (%split-dir rest)
428      (while (and next-wild ; Check for **/**/ which is the same as **/
429                  (string= next-dir "/")
430                  (string= next-wild "**"))
431        (setq rest next-rest)
432        (multiple-value-setq (next-dir next-wild next-rest) (%split-dir rest)))
433      (cond ((not (string= next-dir "/"))
434             (setq result
435                   (%some-specific dir next-dir next-wild next-rest path so-far keys)))
436            (next-wild
437             (setq result
438                   (%one-wild dir next-wild next-rest path so-far keys)))
439            ((or name type)
440             (when (getf keys :files) (setq do-files t))
441             (when (getf keys :directories) (setq do-dirs t)))
442            (t (when (getf keys :directories)
443                 (setq sub (if directory-pathnames
444                             (%cons-pathname (setq dir-list (reverse so-far)) nil nil)
445                             (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
446                 (when (or (null test) (funcall test sub))
447                   (setq result (list (if follow-links (truename sub) sub))))))))
448    ; now descend doing %all-dirs on dirs and collecting files & dirs if do-x is t
449    (with-open-dir (dirent dir)
450      (while (setq sub (%read-dir dirent))
451        (when (and (or all (neq (%schar sub 0) #\.))
452                   (not (string= sub "."))
453                   (not (string= sub "..")))
454          (if (eq (%unix-file-kind (setq subfile (%str-cat dir sub)) t) :directory)
455            (let* ((std-sub (%path-std-quotes sub nil "/;:*"))
456                   (so-far (cons std-sub so-far))
457                   (subdir (%str-cat subfile "/")))
458              (declare (dynamic-extent so-far))
459              (when (and do-dirs (%file*= name type sub))
460                (setq ans (if directory-pathnames
461                            (%cons-pathname (reverse so-far) nil nil)
462                            (%cons-pathname (or dir-list (setq dir-list (reverse (cdr so-far))))
463                                            std-sub nil)))
464                (when (or (null test) (funcall test ans))
465                  (push (if follow-links (truename ans) ans) result)))
466              (setq result (nconc (%all-directories subdir rest path so-far keys) result)))
467            (when (and do-files (%file*= name type sub))
468              (multiple-value-bind (name type) (%std-name-and-type sub)
469                (setq ans (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type))
470                (when (or (null test) (funcall test ans))
471                  (push (if follow-links (truename ans) ans) result))))))))
472    result))
473
474(defun %split-dir (dir &aux pos)                 ; dir ends in a "/".
475  ;"/foo/bar/../x*y/baz/../z*t/"  ->  "/foo/bar/../" "x*y" "/baz/../z*t/"
476  (if (null (setq pos (%path-mem "*" dir)))
477    (values dir nil nil)
478    (let (epos (len (length dir)))
479      (setq pos (if (setq pos (%path-mem-last "/" dir 0 pos)) (%i+ pos 1) 0)
480            epos (%path-mem "/" dir pos len))
481      (when (%path-mem-last-quoted "/" dir 0 pos)
482        (signal-file-error $xbadfilenamechar dir #\/))
483      (values (unless (%izerop pos) (namestring-unquote (%substr dir 0 pos)))
484              (%substr dir pos epos)
485              (%substr dir epos len)))))
486
487(defun %path-pstr*= (pattern pstr &optional (p-start 0))
488  (assert (eq p-start 0))
489  (%path-str*= pstr pattern))
490
491(defun %file*= (name-pat type-pat pstr)
492  (if (eq name-pat :wild) (setq name-pat "*"))
493  (if (eq type-pat :wild) (setq type-pat "*"))
494  (when (and (null name-pat) (null type-pat))
495    (return-from %file*= T))
496  (let* ((end (length pstr))
497         (pos (position #\. pstr :from-end t))
498         (type (and pos (%substr pstr (%i+ pos 1) end)))
499         (name (unless (eq (or pos end) 0) (if pos (%substr pstr 0 pos) pstr))))
500    (and (cond ((or (eq name-pat :unspecific) (null name-pat)) (null name))
501               (t (%path-pstr*= name-pat (or name ""))))
502         (cond ((or (null type-pat) (eq type-pat :unspecific)) (null type))
503               (t (%path-pstr*= type-pat (or type "")))))))
504
505(provide "PATHNAMES")
Note: See TracBrowser for help on using the repository browser.