source: trunk/source/lib/pathnames.lisp @ 15083

Last change on this file since 15083 was 15083, checked in by gb, 8 years ago

%%STAT-VALUES returns stat.st_dev. (I haven't checked to see
if it's called by any other name on non-Linux systems.)

DIRECTORY treats links to directories as directories when :FOLLOW-LINKS
is T (as it is by default.) The :DIRECTORIES argument now defaults to T.
AFAICT, fixes ticket:891.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 24.7 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   Portions copyright (C) 2001-2009 Clozure Associates
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;pathnames.lisp Pathnames for Coral Common LISP
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require 'level-2)
23  (require 'backquote)
24)
25;(defconstant $accessDenied -5000) ; put this with other errnos
26(defconstant $afpAccessDenied -5000) ; which name to use?
27
28
29
30;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
31;ANSI CL logical pathnames
32
33
34(defvar *pathname-translations-pathname*
35  (make-pathname :host "ccl" :type "pathname-translations"))
36
37(defun load-logical-pathname-translations (host)
38  ;(setq host (verify-logical-host-name host))
39  (when (not (%str-assoc host %logical-host-translations%))
40    (setf (logical-pathname-translations host)
41          (with-open-file (file (merge-pathnames (make-pathname :name host :defaults nil)
42                                                 *pathname-translations-pathname*)
43                                :element-type 'base-char)
44            (read file)))
45    T))
46
47(defun back-translate-pathname (path &optional hosts)
48  (let ((newpath (back-translate-pathname-1 path hosts)))
49    (cond ((equalp path newpath)
50           ;; (fcomp-standard-source path)
51           (namestring (pathname path)))
52          (t newpath))))
53
54
55(defun back-translate-pathname-1 (path &optional hosts)
56  (dolist (host %logical-host-translations%)
57    (when (or (null hosts) (member (car host) hosts :test 'string-equal))
58      (dolist (trans (cdr host))
59        (when (pathname-match-p path (cadr trans))
60          (let* (newpath)         
61            (setq newpath (translate-pathname path (cadr trans) (car trans) :reversible t))
62            (return-from back-translate-pathname-1 
63              (if  (equalp path newpath) path (back-translate-pathname-1 newpath hosts))))))))
64  path)
65
66
67
68; must be after back-translate-pathname
69(defun physical-pathname-p (path)
70  (let* ((path (pathname path))
71         (dir (pathname-directory path)))
72    (and dir
73         (or (not (logical-pathname-p path))
74             (not (null (memq (pathname-host path) '(nil :unspecific))))))))
75
76
77
78;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
79;File or directory Manipulations
80
81(defun unix-rename (old-name new-name)
82  (with-filename-cstrs ((old old-name)
83                        (new new-name))
84    #+windows-target
85    (#__wunlink new)
86    (let* ((res #-windows-target (#_rename old new)
87                #+windows-target (#__wrename old new)))
88      (declare (fixnum res))
89      (if (zerop res)
90        (values t nil)
91        (values nil (%get-errno))))))
92
93(defun rename-file (file new-name &key (if-exists :error))
94  "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
95  file, then the associated file is renamed."
96  (let* ((original (truename file))
97         (original-namestring (native-translated-namestring original))
98         (new-name (merge-pathnames new-name original))
99         (new-namestring (native-translated-namestring new-name)))
100    (unless new-namestring
101      (error "~S can't be created." new-name))
102    (unless (and (probe-file new-name)
103                 (not (if-exists if-exists new-name)))
104      (multiple-value-bind (res error)
105                           (unix-rename original-namestring
106                                        new-namestring)
107        (unless res
108          (error "Failed to rename ~A to ~A: ~A"
109                 original new-name error))
110        (when (streamp file)
111          (setf (stream-filename file)
112                (namestring (native-to-pathname new-namestring))))
113        (values new-name original (truename new-name))))))
114
115(defun copy-file (source-path dest-path &key (if-exists :error) (if-does-not-exist :create)
116                              (preserve-attributes nil))
117  (let* ((original (truename source-path))
118         (new-name (merge-pathnames dest-path original))
119         (buffer (make-array 4096 :element-type '(unsigned-byte 8))))
120    (with-open-file (in original :direction :input
121                        :element-type '(unsigned-byte 8))
122      (with-open-file (out new-name :direction :output
123                           :if-exists if-exists
124                           :if-does-not-exist if-does-not-exist
125                           :element-type '(unsigned-byte 8))
126        (loop
127          as n = (stream-read-vector in buffer 0 4096) until (eql n 0)
128          do (stream-write-vector out buffer 0 n))))
129    (when preserve-attributes
130      (copy-file-attributes original new-name))
131    (values new-name original (truename new-name))))
132
133(defun recursive-copy-directory (source-path dest-path &key test (if-exists :error))
134  ;; TODO: Support :if-exists :supersede to blow away any files not in source dir
135  (assert (directoryp source-path)(source-path)
136          "source-path is not a directory in RECURSIVE-COPY-DIRECTORY")
137  (setq if-exists (require-type if-exists '(member :overwrite :error)))
138  (setq dest-path (ensure-directory-pathname dest-path))
139  (when (eq if-exists :error)
140    (when (probe-file dest-path)
141      (if-exists if-exists dest-path))
142    ;; Skip the probe-file in recursive calls, we already know it's ok.
143    (setq if-exists :overwrite))
144  (let* ((source-dir (ensure-directory-pathname source-path))
145         (pattern (make-pathname :name :wild :type :wild :defaults source-dir))
146         (source-files (directory pattern :test test :directories t :files t)))
147    (ensure-directories-exist dest-path)
148    (dolist (f source-files)
149      (when (or (null test) (funcall test f))
150        (if (directory-pathname-p f)
151            (let ((dest-file (make-pathname :name (first (last (pathname-directory f)))
152                                            :defaults dest-path)))
153              (recursive-copy-directory f dest-file :test test :if-exists if-exists))
154            (let* ((dest-file (make-pathname :name (pathname-name f)
155                                             :type (pathname-type f)
156                                             :defaults dest-path)))
157              (copy-file f dest-file :if-exists :supersede :preserve-attributes t)))))))
158
159(defun delete-empty-directory (path)
160  (let* ((namestring (native-translated-namestring path))
161         (err (%rmdir namestring)))
162    (or (eql 0 err) (signal-file-error err path))))
163
164(defun delete-directory (path)
165  "Delete specified directory and all its contents."
166  (let ((namestring (native-translated-namestring path)))
167    (if (eq :directory (%unix-file-kind namestring t))
168      (let* ((dir (ensure-directory-pathname path))
169             (wild (make-pathname :name :wild :type :wild :defaults dir))
170             (files (directory wild :directories nil :files t
171                               :follow-links nil :include-emacs-lockfiles t))
172             (subdirs (directory wild :directories t :files nil
173                                 :follow-links nil
174                                 :include-emacs-lockfiles t)))
175        (dolist (f files)
176          (delete-file f))
177        (dolist (d subdirs)
178          (delete-directory d))
179        (delete-empty-directory path))
180      (error "~s is not a directory" path))))
181
182;;; use with caution!
183;;; blows away a directory and all its contents
184(defun recursive-delete-directory (path &key (if-does-not-exist :error))
185  (setq path (ensure-directory-pathname path))
186  (setq if-does-not-exist (require-type if-does-not-exist '(member :error nil)))
187  (when (eq if-does-not-exist :error)
188    (unless (probe-file path)
189      (if-does-not-exist if-does-not-exist path)))
190  (when (probe-file path)
191      (if (directoryp path)
192          ;; it's a directory: blow it away
193          (let* ((pattern (make-pathname :name :wild :type :wild :defaults path))
194                 (files (directory pattern :directories nil :files t))
195                 (subdirs (directory pattern :directories t :files nil))
196                 (target-pathname (native-translated-namestring path)))
197            (dolist (f files)
198              (delete-file f))
199            (dolist (d subdirs)
200              (recursive-delete-directory d :if-does-not-exist if-does-not-exist))
201            (%rmdir target-pathname))
202          ;; it's not a directory: for safety's sake, signal an error
203          (error "Pathname '~A' is not a directory" path))))
204
205;;; It's not clear that we can support anything stronger than
206;;; "advisory" ("you pretend the file's locked & I will too") file
207;;; locking under Darwin.
208
209
210
211
212(defun create-directory (path &key (mode #o777))
213  (let* ((pathname (translate-logical-pathname (merge-pathnames path)))
214         (created-p nil)
215         (parent-dirs (let* ((pd (pathname-directory pathname)))
216                        (if (eq (car pd) :relative)
217                          (pathname-directory (merge-pathnames
218                                               pathname
219                                               (mac-default-directory)))
220                          pd)))
221         (nparents (length parent-dirs)))
222    (when (wild-pathname-p pathname)
223      (error 'file-error :error-type "Inappropriate use of wild pathname ~s"
224             :pathname pathname))
225    (do* ((i 1 (1+ i)))
226         ((> i nparents) (values pathname created-p))
227      (declare (fixnum i))
228      (let* ((parent (make-pathname
229                      :name :unspecific
230                      :type :unspecific
231                      :host (pathname-host pathname)
232                      :device (pathname-device pathname)
233                      :directory (subseq parent-dirs 0 i)))
234             (parent-name (native-translated-namestring parent))
235             (parent-kind (%unix-file-kind parent-name)))
236
237        (if parent-kind
238          (unless (eq parent-kind :directory)
239            (error 'simple-file-error
240                   :error-type "Can't create directory ~s, since file ~a exists and is not a directory"
241                   :pathname pathname
242                   :format-arguments (list parent-name)))
243          (let* ((result (%mkdir parent-name mode)))
244            (declare (fixnum result))
245            (if (< result 0)
246              (signal-file-error result parent-name)
247              (setq created-p t))))))))
248
249
250(defun ensure-directories-exist (pathspec &key verbose (mode #o777))
251  "Test whether the directories containing the specified file
252  actually exist, and attempt to create them if they do not.
253  The MODE argument is an extension to control the Unix permission
254  bits.  Portable programs should avoid using the :MODE keyword
255  argument."
256  (let ((pathname (let ((pathspec (translate-logical-pathname (merge-pathnames pathspec))))
257                    (make-directory-pathname :device (pathname-device pathspec)
258                                             :directory (pathname-directory pathspec))))
259        (created-p nil))
260    (when (wild-pathname-p pathname)
261      (error 'file-error
262             :error-type "Inappropriate use of wild pathname ~s"
263             :pathname pathname))
264    (let ((dir (pathname-directory pathname)))
265      (if (eq (car dir) :relative)
266        (setq dir (pathname-directory (merge-pathnames
267                                       pathname
268                                       (mac-default-directory)))))
269      (loop for i from 1 upto (length dir)
270            do (let ((newpath (make-pathname
271                               :name :unspecific
272                               :type :unspecific
273                               :host (pathname-host pathname)
274                               :device (pathname-device pathname)
275                               :directory (subseq dir 0 i))))
276                 (unless (probe-file newpath)
277                   (let ((namestring (native-translated-namestring newpath)))
278                     (when verbose
279                       (format *standard-output* "~&Creating directory: ~A~%"
280                               namestring))
281                     (%mkdir namestring mode)
282                     (unless (probe-file newpath)
283                       (error 'file-error
284                              :pathname namestring
285                              :error-type "Can't create directory ~S."))
286                     (setf created-p t)))))
287      (values pathspec created-p))))
288
289(defun dirpath-to-filepath (path)
290  (setq path (translate-logical-pathname (merge-pathnames path)))
291  (let* ((dir (pathname-directory path))
292         (super (butlast dir))
293         (name (car (last dir))))
294    (when (eq name :up)
295      (setq dir (remove-up (copy-list dir)))
296      (setq super (butlast dir))
297      (setq name (car (last dir))))
298    (when (null super)
299      (signal-file-error $xnocreate path))
300    (setq path (make-pathname :directory super :name name :defaults nil))))
301
302(defun filepath-to-dirpath (path)
303  (let* ((dir (pathname-directory path))
304         (rest (file-namestring path)))
305    (make-pathname :directory (append dir (list rest)) :defaults nil)))
306 
307
308
309;Takes a pathname, returns the truename of the directory if the pathname
310;names a directory, NIL if it names an ordinary file, error otherwise.
311;E.g. (directoryp "ccl;:foo:baz") might return #P"hd:mumble:foo:baz:" if baz
312;is a dir. - should we doc this - its exported?
313(defun directoryp (path)
314  (let* ((native (native-translated-namestring path))
315         (realpath (%realpath native)))
316    (if realpath (eq (%unix-file-kind realpath) :directory))))
317         
318
319;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
320;Wildcards
321
322
323
324 
325;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
326;Directory Traversing
327
328(defun %path-cat (device dir subdir)
329  (if device
330      (%str-cat device ":" dir subdir)
331    (%str-cat dir subdir)))
332
333(defmacro with-open-dir ((dirent device dir state follow-links) &body body)
334  (let* ((namestring (gensym)))
335    `(let* ((,namestring (native-translated-namestring (make-pathname :device ,device :directory ,dir :defaults nil))))
336      (when (%new-directory-p ,namestring ,follow-links ,state)
337        (let* ((,dirent (%open-dir (native-translated-namestring (make-pathname :device ,device :directory ,dir :defaults nil)))))
338          (when ,dirent
339            (unwind-protect
340                 (progn ,@body)
341              (close-dir ,dirent))))))))
342
343(defun path-is-link (path)
344  "Returns T if PATH is a (hard or symbolic) link, NIL otherwise."
345  ;; Actually, it's a bit more subtle than that; it basically
346  ;; returns information about the last component of PATH.  If
347  ;; some enclosing directory name is a link but the last component
348  ;; isn't, this'll return false.
349  (eq (%unix-file-kind (native-translated-namestring path) t) :link))
350
351(defstruct (directory-result (:constructor %make-directory-result))
352  (truenames (make-hash-table :shared nil :test 'string= :hash-function 'sxhash))
353  (directories-seen ()))
354
355
356;;; If no component of the pathname involves a link we could avoid the call to
357;;; TRUENAME here.  Later ...
358(defun %add-directory-result (path result follow-links &optional followed-some-links)
359  (declare (ignore followed-some-links))
360  (let* ((truename (if follow-links (truename path) path))
361         (namestring (namestring truename))
362         (truenames (directory-result-truenames result)))
363    (or (gethash namestring truenames)
364        (setf (gethash namestring truenames) truename))))
365   
366
367(defun %process-directory-result (result)
368  (collect ((pairs))
369    (maphash (lambda (namestring truename) (pairs (cons namestring truename))) (directory-result-truenames result))
370    (mapcar #'cdr (sort (pairs) #'string< :key #'car))))
371
372(defun %new-directory-p (namestring follow-links result)
373  (multiple-value-bind (win mode size mtime inode uid blocksize rmtime  gid dev)
374      (%stat namestring (not follow-links))
375    (declare (ignore size mtime uid blocksize rmtime gid #+windows-target inode #+windows-target dev))
376    (when (and win (= (logand mode #$S_IFMT) #$S_IFDIR))
377      #+windows-target
378      (let* ((dirname (namestring (truename (pathname namestring)))))
379        (unless (member dirname (directory-result-directories-seen result) :test #'string=)
380          (push dirname (directory-result-directories-seen result))
381          t))
382      #-windows-target
383      (when (dolist (pair (directory-result-directories-seen result) t)
384              (when (and (eql inode (car pair))
385                         (eql dev (cdr pair)))
386                (return)))
387        (push (cons inode dev) (directory-result-directories-seen result))
388        t))))
389
390 
391(defun directory (path &key (directories t) ;; include subdirectories
392                            (files t)         ;; include files
393                            (all t)           ;; include Unix dot files (other than dot and dot dot)
394                            (directory-pathnames t) ;; return directories as directory-pathname-p's.
395                            (include-emacs-lockfiles nil) ;; inculde .#foo
396                            test              ;; Only return pathnames matching test
397                            (follow-links t)) ;; return truename's of matching files.
398  "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
399   given pathname. Note that the interaction between this ANSI-specified
400   TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
401   means this function can sometimes return files which don't have the same
402   directory as PATHNAME."
403  (let* ((keys (list :directories directories ;list defaulted key values
404                     :files files
405                     :all all
406                     :directory-pathnames directory-pathnames
407                     :test test
408                     :include-emacs-lockfiles include-emacs-lockfiles
409                     :follow-links follow-links))
410         (path (full-pathname (merge-pathnames path) :no-error nil))
411         (dir (directory-namestring path)))
412    (declare (dynamic-extent keys))
413    (if (null (pathname-directory path))
414      (setq dir (directory-namestring (setq path
415                                            (merge-pathnames path
416                                                             (mac-default-directory))))))
417    (assert (eq (car (pathname-directory path)) :absolute) ()
418            "full-pathname returned relative path ~s??" path)
419    (%process-directory-result (%directory "/" dir path '(:absolute) keys (%make-directory-result)))))
420
421(defun %directory (dir rest path so-far keys result)
422  (multiple-value-bind (sub-dir wild rest) (%split-dir rest)
423    (%some-specific dir sub-dir wild rest path so-far keys result)))
424
425(defun %some-specific (dir sub-dir wild rest path so-far keys result)
426  (let* ((start 1)
427         (end (length sub-dir))
428         (full-dir (if (eq start end) dir (%str-cat dir (%substr sub-dir start end)))))
429    (while (neq start end)
430      (let ((pos (position #\/ sub-dir :start start :end end)))
431        (push (%path-std-quotes (%substr sub-dir start pos) nil "/:;*") so-far)
432        (setq start (%i+ 1 pos))))
433    (cond ((null wild)
434           (%files-in-directory full-dir path so-far keys result))
435          ((string= wild "**")
436           (%all-directories full-dir rest path so-far keys result))
437          (t (%one-wild full-dir wild rest path so-far keys result)))))
438
439; for a * or *x*y
440(defun %one-wild (dir wild rest path so-far keys result)
441  (let ((device (pathname-device path))
442        (all (getf keys :all))
443        (follow-links (getf keys :follow-links))
444        name)
445    (with-open-dir (dirent device dir result follow-links)
446      (while (setq name (%read-dir dirent))
447        (when (and (or all (neq (%schar name 0) #\.))
448                   (not (string= name "."))
449                   (not (string= name ".."))
450                   (%path-pstr*= wild name)
451                   (eq (%unix-file-kind (%path-cat device dir name) (not follow-links)) :directory))
452          (let ((subdir (%path-cat nil dir name))
453                (so-far (cons (%path-std-quotes name nil "/;:*") so-far)))
454            (declare (dynamic-extent so-far))
455            (%directory (%str-cat subdir "/") rest path so-far keys result)
456))))
457    result))
458
459(defun %files-in-directory (dir path so-far keys result)
460  (let ((device (pathname-device path))
461        (name (pathname-name path))
462        (type (pathname-type path))
463        (directories (getf keys :directories))
464        (files (getf keys :files))
465        (directory-pathnames (getf keys :directory-pathnames))
466        (test (getf keys :test))
467        (follow-links (getf keys :follow-links))
468        (all (getf keys :all))
469        (include-emacs-lockfiles (getf keys :include-emacs-lockfiles))
470        sub dir-list ans)
471    (if (not (or name type))
472      (let (full-path)
473        (when (and directories
474                   (eq (%unix-file-kind (namestring (setq full-path (%cons-pathname (reverse so-far) nil nil nil device)))
475                                        (not follow-links))
476                       :directory))
477          (setq ans (if directory-pathnames full-path
478                      (%cons-pathname (reverse (cdr so-far)) (car so-far) nil nil device)))
479          (when (and ans (or (null test) (funcall test ans)))
480            (%add-directory-result ans result follow-links))))
481      (with-open-dir (dirent (pathname-device path) dir result follow-links)
482        (while (setq sub (%read-dir dirent))
483          (when (and (or all (neq (%schar sub 0) #\.))
484                     (or include-emacs-lockfiles
485                         (< (length sub) 2)
486                         (not (string= sub ".#" :end1 2)))
487                     (not (string= sub "."))
488                     (not (string= sub ".."))
489                     (%file*= name type sub))
490            (setq ans
491                  (if (eq (%unix-file-kind (%path-cat device dir sub) (not follow-links)) :directory)
492                    (when directories
493                      (let* ((std-sub (%path-std-quotes sub nil "/;:*")))
494                        (if directory-pathnames
495                          (%cons-pathname (reverse (cons std-sub so-far)) nil nil nil device)
496                          (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) std-sub nil nil device))))
497                    (when files
498                      (multiple-value-bind (name type) (%std-name-and-type sub)
499                        (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type nil device)))))
500            (when (and ans (or (null test) (funcall test ans)))
501              (%add-directory-result ans result follow-links))))))
502    result))
503
504(defun %all-directories (dir rest path so-far keys result)
505  (let ((do-files nil)
506        (do-dirs nil)
507        (device (pathname-device path))
508        (name (pathname-name path))
509        (type (pathname-type path))
510        (all (getf keys :all))
511        (test (getf keys :test))
512        (directory-pathnames (getf keys :directory-pathnames))
513        (follow-links (getf keys :follow-links))
514        sub dir-list ans)
515    ;; First process the case that the ** stands for 0 components
516    (multiple-value-bind (next-dir next-wild next-rest) (%split-dir rest)
517      (while (and next-wild ; Check for **/**/ which is the same as **/
518                  (string= next-dir "/")
519                  (string= next-wild "**"))
520        (setq rest next-rest)
521        (multiple-value-setq (next-dir next-wild next-rest) (%split-dir rest)))
522      (cond ((not (string= next-dir "/"))
523             (%some-specific dir next-dir next-wild next-rest path so-far keys result))
524            (next-wild
525             (%one-wild dir next-wild next-rest path so-far keys result))
526            ((or name type)
527             (when (getf keys :files) (setq do-files t))
528             (when (getf keys :directories) (setq do-dirs t)))
529            (t (when (getf keys :directories)
530                 (setq sub (if directory-pathnames
531                             (%cons-pathname (setq dir-list (reverse so-far)) nil nil nil device)
532                             (%cons-pathname (reverse (cdr so-far)) (car so-far) nil nil device)))
533                 (when (or (null test) (funcall test sub))
534                   (%add-directory-result sub result follow-links))))))
535    ;; now descend doing %all-dirs on dirs and collecting files & dirs
536    ;; if do-x is t
537    (with-open-dir (dirent device (%path-std-quotes dir nil "*;:") result follow-links)
538      (while (setq sub (%read-dir dirent))
539        (when (and (or all (neq (%schar sub 0) #\.))
540                   (not (string= sub "."))
541                   (not (string= sub "..")))
542          (if (eq (%unix-file-kind (%path-cat device dir sub) (not follow-links)) :directory)
543            (let* ((subfile (%path-cat nil dir sub))
544                   (std-sub (%path-std-quotes sub nil "/;:*"))
545                   (so-far (cons std-sub so-far))
546                   (subdir (%str-cat subfile  "/")))
547              (declare (dynamic-extent so-far))
548              (when (and do-dirs (%file*= name type sub))
549                (setq ans (if directory-pathnames
550                            (%cons-pathname (reverse so-far) nil nil nil device)
551                            (%cons-pathname (or dir-list (setq dir-list (reverse (cdr so-far))))
552                                            std-sub nil nil device)))
553                (when (or (null test) (funcall test ans))
554                  (%add-directory-result ans result follow-links)))
555              (%all-directories subdir rest path so-far keys result))
556            (when (and do-files (%file*= name type sub))
557              (multiple-value-bind (name type) (%std-name-and-type sub)
558                (setq ans (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type nil device))
559                (when (or (null test) (funcall test ans))
560                  (%add-directory-result ans result follow-links))))))))
561    result))
562
563(defun %split-dir (dir &aux pos)                 ; dir ends in a "/".
564  ;"/foo/bar/../x*y/baz/../z*t/"  ->  "/foo/bar/../" "x*y" "/baz/../z*t/"
565  (if (null (setq pos (%path-mem "*" dir)))
566    (values dir nil nil)
567    (let (epos (len (length dir)))
568      (setq pos (if (setq pos (%path-mem-last "/" dir 0 pos)) (%i+ pos 1) 0)
569            epos (%path-mem "/" dir pos len))
570      (when (%path-mem-last-quoted "/" dir 0 pos)
571        (signal-file-error $xbadfilenamechar dir #\/))
572      (values (unless (%izerop pos) (namestring-unquote (%substr dir 0 pos)))
573              (%substr dir pos epos)
574              (%substr dir epos len)))))
575
576(defun %path-pstr*= (pattern pstr &optional (p-start 0))
577  (assert (eq p-start 0))
578  (%path-str*= pstr pattern))
579
580(defun %file*= (name-pat type-pat pstr)
581  (if (eq name-pat :wild) (setq name-pat "*"))
582  (if (eq type-pat :wild) (setq type-pat "*"))
583  (when (and (null name-pat) (null type-pat))
584    (return-from %file*= T))
585  (let* ((end (length pstr))
586         (pos (position #\. pstr :from-end t))
587         (type (and pos (%substr pstr (%i+ pos 1) end)))
588         (name (unless (eq (or pos end) 0) (if pos (%substr pstr 0 pos) pstr))))
589    (and (cond ((or (eq name-pat :unspecific) (null name-pat)) (null name))
590               (t (%path-pstr*= name-pat (or name ""))))
591         (cond ((or (null type-pat) (eq type-pat :unspecific)) (null type))
592               (t (%path-pstr*= type-pat (or type "")))))))
593
594(provide "PATHNAMES")
Note: See TracBrowser for help on using the repository browser.