source: trunk/source/lib/pathnames.lisp @ 11640

Last change on this file since 11640 was 11640, checked in by gb, 11 years ago

Add :IF-DOES-NOT-EXIST arg to COPY-FILE.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 20.5 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   Portions copyright (C) 2001 Clozure Associates
5;;;   This file is part of OpenMCL. 
6;;;
7;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with OpenMCL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;pathnames.lisp Pathnames for Coral Common LISP
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require 'level-2)
23  (require 'backquote)
24)
25;(defconstant $accessDenied -5000) ; put this with other errnos
26(defconstant $afpAccessDenied -5000) ; which name to use?
27
28
29
30;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
31;ANSI CL logical pathnames
32
33
34(defvar *pathname-translations-pathname*
35  (make-pathname :host "ccl" :type "pathname-translations"))
36
37(defun load-logical-pathname-translations (host)
38  ;(setq host (verify-logical-host-name host))
39  (when (not (%str-assoc host %logical-host-translations%))
40    (setf (logical-pathname-translations host)
41          (with-open-file (file (merge-pathnames (make-pathname :name host :defaults nil)
42                                                 *pathname-translations-pathname*)
43                                :element-type 'base-char)
44            (read file)))
45    T))
46
47(defun back-translate-pathname (path &optional hosts)
48  (let ((newpath (back-translate-pathname-1 path hosts)))
49    (cond ((equalp path newpath)
50           ;; (fcomp-standard-source path)
51           (namestring (pathname path)))
52          (t newpath))))
53
54
55(defun back-translate-pathname-1 (path &optional hosts)
56  (dolist (host %logical-host-translations%)
57    (when (or (null hosts) (member (car host) hosts :test 'string-equal))
58      (dolist (trans (cdr host))
59        (when (pathname-match-p path (cadr trans))
60          (let* (newpath)         
61            (setq newpath (translate-pathname path (cadr trans) (car trans) :reversible t))
62            (return-from back-translate-pathname-1 
63              (if  (equalp path newpath) path (back-translate-pathname-1 newpath hosts))))))))
64  path)
65
66
67
68; must be after back-translate-pathname
69(defun physical-pathname-p (path)
70  (let* ((path (pathname path))
71         (dir (pathname-directory path)))
72    (and dir
73         (or (not (logical-pathname-p path))
74             (not (null (memq (pathname-host path) '(nil :unspecific))))))))
75
76
77
78;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
79;File or directory Manipulations
80
81(defun unix-rename (old-name new-name)
82  (with-cstrs ((old old-name)
83               (new new-name))
84    #+windows-target
85    (#__unlink new)
86    (let* ((res (#_rename old new)))
87      (declare (fixnum res))
88      (if (zerop res)
89        (values t nil)
90        (values nil (%get-errno))))))
91
92(defun rename-file (file new-name &key (if-exists :error))
93  "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
94  file, then the associated file is renamed."
95  (let* ((original (truename file))
96         (original-namestring (native-translated-namestring original))
97         (new-name (merge-pathnames new-name original))
98         (new-namestring (native-translated-namestring new-name)))
99    (unless new-namestring
100      (error "~S can't be created." new-name))
101    (unless (and (probe-file new-name)
102                 (not (if-exists if-exists new-name)))
103      (multiple-value-bind (res error)
104                           (unix-rename original-namestring
105                                        new-namestring)
106        (unless res
107          (error "Failed to rename ~A to ~A: ~A"
108                 original new-name error))
109        (when (streamp file)
110          (setf (stream-filename file)
111                (namestring (native-to-pathname new-namestring))))
112        (values new-name original (truename new-name))))))
113
114(defun copy-file (source-path dest-path &key (if-exists :error) (if-does-not-exist :create)
115                              (preserve-attributes nil))
116  (let* ((original (truename source-path))
117         (new-name (merge-pathnames dest-path original))
118         (buffer (make-array 4096 :element-type '(unsigned-byte 8))))
119    (with-open-file (in original :direction :input
120                        :element-type '(unsigned-byte 8))
121      (with-open-file (out new-name :direction :output
122                           :if-exists if-exists
123                           :if-does-not-exist if-does-not-exist
124                           :element-type '(unsigned-byte 8))
125        (loop
126          as n = (stream-read-vector in buffer 0 4096) until (eql n 0)
127          do (stream-write-vector out buffer 0 n))))
128    (when preserve-attributes
129      (copy-file-attributes original new-name))
130    (values new-name original (truename new-name))))
131
132(defun recursive-copy-directory (source-path dest-path &key test (if-exists :error))
133  ;; TODO: Support :if-exists :supersede to blow away any files not in source dir
134  (assert (directoryp source-path)(source-path)
135          "source-path is not a directory in RECURSIVE-COPY-DIRECTORY")
136  (setq if-exists (require-type if-exists '(member :overwrite :error)))
137  (setq dest-path (ensure-directory-pathname dest-path))
138  (when (eq if-exists :error)
139    (when (probe-file dest-path)
140      (if-exists if-exists dest-path))
141    ;; Skip the probe-file in recursive calls, we already know it's ok.
142    (setq if-exists :overwrite))
143  (let* ((source-dir (ensure-directory-pathname source-path))
144         (pattern (make-pathname :name :wild :type :wild :defaults source-dir))
145         (source-files (directory pattern :test test :directories t :files t)))
146    (ensure-directories-exist dest-path)
147    (dolist (f source-files)
148      (when (or (null test) (funcall test f))
149        (if (directory-pathname-p f)
150            (let ((dest-file (make-pathname :name (first (last (pathname-directory f)))
151                                            :defaults dest-path)))
152              (recursive-copy-directory f dest-file :test test :if-exists if-exists))
153            (let* ((dest-file (make-pathname :name (pathname-name f)
154                                             :type (pathname-type f)
155                                             :defaults dest-path)))
156              (copy-file f dest-file :if-exists :supersede :preserve-attributes t)))))))
157
158;;; use with caution!
159;;; blows away a directory and all its contents
160(defun recursive-delete-directory (path &key (if-does-not-exist :error))
161  (setq path (ensure-directory-pathname path))
162  (setq if-does-not-exist (require-type if-does-not-exist '(member :error nil)))
163  (when (eq if-does-not-exist :error)
164    (unless (probe-file path)
165      (if-does-not-exist if-does-not-exist path)))
166  (when (probe-file path)
167      (if (directoryp path)
168          ;; it's a directory: blow it away
169          (let* ((pattern (make-pathname :name :wild :type :wild :defaults path))
170                 (files (directory pattern :directories nil :files t))
171                 (subdirs (directory pattern :directories t :files nil))
172                 (target-pathname (native-translated-namestring path)))
173            (dolist (f files)
174              (delete-file f))
175            (dolist (d subdirs)
176              (recursive-delete-directory d :if-does-not-exist if-does-not-exist))
177            (%rmdir target-pathname))
178          ;; it's not a directory: for safety's sake, signal an error
179          (error "Pathname '~A' is not a directory" path))))
180
181;;; It's not clear that we can support anything stronger than
182;;; "advisory" ("you pretend the file's locked & I will too") file
183;;; locking under Darwin.
184
185
186
187
188(defun create-directory (path &key (mode #o777))
189  (let* ((pathname (translate-logical-pathname (merge-pathnames path)))
190         (created-p nil)
191         (parent-dirs (let* ((pd (pathname-directory pathname)))
192                        (if (eq (car pd) :relative)
193                          (pathname-directory (merge-pathnames
194                                               pathname
195                                               (mac-default-directory)))
196                          pd)))
197         (nparents (length parent-dirs)))
198    (when (wild-pathname-p pathname)
199      (error 'file-error :error-type "Inappropriate use of wild pathname ~s"
200             :pathname pathname))
201    (do* ((i 1 (1+ i)))
202         ((> i nparents) (values pathname created-p))
203      (declare (fixnum i))
204      (let* ((parent (make-pathname
205                      :name :unspecific
206                      :type :unspecific
207                      :host (pathname-host pathname)
208                      :device (pathname-device pathname)
209                      :directory (subseq parent-dirs 0 i)))
210             (parent-name (native-translated-namestring parent))
211             (parent-kind (%unix-file-kind parent-name)))
212
213        (if parent-kind
214          (unless (eq parent-kind :directory)
215            (error 'simple-file-error
216                   :error-type "Can't create directory ~s, since file ~a exists and is not a directory"
217                   :pathname pathname
218                   :format-arguments (list parent-name)))
219          (let* ((result (%mkdir parent-name mode)))
220            (declare (fixnum result))
221            (if (< result 0)
222              (signal-file-error result parent-name)
223              (setq created-p t))))))))
224
225
226(defun ensure-directories-exist (pathspec &key verbose (mode #o777))
227  "Test whether the directories containing the specified file
228  actually exist, and attempt to create them if they do not.
229  The MODE argument is an extension to control the Unix permission
230  bits.  Portable programs should avoid using the :MODE keyword
231  argument."
232  (let* ((pathname (make-directory-pathname :directory (pathname-directory (translate-logical-pathname (merge-pathnames pathspec)))))
233         (created-p nil))
234    (when (wild-pathname-p pathname)
235      (error 'file-error
236             :error-type "Inappropriate use of wild pathname ~s"
237             :pathname pathname))
238    (let ((dir (pathname-directory pathname)))
239      (if (eq (car dir) :relative)
240        (setq dir (pathname-directory (merge-pathnames
241                                       pathname
242                                       (mac-default-directory)))))
243      (loop for i from 1 upto (length dir)
244            do (let ((newpath (make-pathname
245                               :name :unspecific
246                               :type :unspecific
247                               :host (pathname-host pathname)
248                               :device (pathname-device pathname)
249                               :directory (subseq dir 0 i))))
250                 (unless (probe-file newpath)
251                   (let ((namestring (native-translated-namestring newpath)))
252                     (when verbose
253                       (format *standard-output* "~&Creating directory: ~A~%"
254                               namestring))
255                     (%mkdir namestring mode)
256                     (unless (probe-file newpath)
257                       (error 'file-error
258                              :pathname namestring
259                              :error-type "Can't create directory ~S."))
260                     (setf created-p t)))))
261      (values pathspec created-p))))
262
263(defun dirpath-to-filepath (path)
264  (setq path (translate-logical-pathname (merge-pathnames path)))
265  (let* ((dir (pathname-directory path))
266         (super (butlast dir))
267         (name (car (last dir))))
268    (when (eq name :up)
269      (setq dir (remove-up (copy-list dir)))
270      (setq super (butlast dir))
271      (setq name (car (last dir))))
272    (when (null super)
273      (signal-file-error $xnocreate path))
274    (setq path (make-pathname :directory super :name name :defaults nil))))
275
276(defun filepath-to-dirpath (path)
277  (let* ((dir (pathname-directory path))
278         (rest (file-namestring path)))
279    (make-pathname :directory (append dir (list rest)) :defaults nil)))
280 
281
282
283;Takes a pathname, returns the truename of the directory if the pathname
284;names a directory, NIL if it names an ordinary file, error otherwise.
285;E.g. (directoryp "ccl;:foo:baz") might return #P"hd:mumble:foo:baz:" if baz
286;is a dir. - should we doc this - its exported?
287(defun directoryp (path)
288  (let* ((native (native-translated-namestring path))
289         (realpath (%realpath native)))
290    (if realpath (eq (%unix-file-kind realpath) :directory))))
291         
292
293;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
294;Wildcards
295
296
297
298 
299;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
300;Directory Traversing
301
302(defmacro with-open-dir ((dirent dir) &body body)
303  `(let ((,dirent (%open-dir ,dir)))
304     (when ,dirent
305       (unwind-protect
306           (progn ,@body)
307         (close-dir ,dirent)))))
308
309(defun directory (path &key (directories nil) ;; include subdirectories
310                            (files t)         ;; include files
311                            (all t)           ;; include Unix dot files (other than dot and dot dot)
312                            (directory-pathnames t) ;; return directories as directory-pathname-p's.
313                            (include-emacs-lockfiles nil) ;; inculde .#foo
314                            test              ;; Only return pathnames matching test
315                            (follow-links t)) ;; return truename's of matching files.
316  "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
317   given pathname. Note that the interaction between this ANSI-specified
318   TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
319   means this function can sometimes return files which don't have the same
320   directory as PATHNAME."
321  (let* ((keys (list :directories directories ;list defaulted key values
322                     :files files
323                     :all all
324                     :directory-pathnames directory-pathnames
325                     :test test
326                     :include-emacs-lockfiles include-emacs-lockfiles
327                     :follow-links follow-links))
328         (path (full-pathname (merge-pathnames path) :no-error nil))
329         (dir (directory-namestring path)))
330    (declare (dynamic-extent keys))
331    (if (null (pathname-directory path))
332      (setq dir (directory-namestring (setq path
333                                            (merge-pathnames path
334                                                             (mac-default-directory))))))
335    (assert (eq (car (pathname-directory path)) :absolute) ()
336            "full-pathname returned relative path ~s??" path)
337    ;; return sorted in alphabetical order, target-Xload-level-0 depends
338    ;; on this.
339    (nreverse
340     (delete-duplicates (%directory "/" dir path '(:absolute) keys) :test #'equal))))
341
342(defun %directory (dir rest path so-far keys)
343  (multiple-value-bind (sub-dir wild rest) (%split-dir rest)
344    (%some-specific dir sub-dir wild rest path so-far keys)))
345
346(defun %some-specific (dir sub-dir wild rest path so-far keys)
347  (let* ((start 1)
348         (end (length sub-dir))
349         (full-dir (if (eq start end) dir (%str-cat dir (%substr sub-dir start end)))))
350    (while (neq start end)
351      (let ((pos (position #\/ sub-dir :start start :end end)))
352        (push (%path-std-quotes (%substr sub-dir start pos) nil "/:;*") so-far)
353        (setq start (%i+ 1 pos))))
354    (cond ((null wild)
355           (%files-in-directory full-dir path so-far keys))
356          ((string= wild "**")
357           (%all-directories full-dir rest path so-far keys))
358          (t (%one-wild full-dir wild rest path so-far keys)))))
359
360; for a * or *x*y
361(defun %one-wild (dir wild rest path so-far keys)
362  (let ((result ()) (all (getf keys :all)) name subdir)
363    (with-open-dir (dirent dir)
364      (while (setq name (%read-dir dirent))
365        (when (and (or all (neq (%schar name 0) #\.))
366                   (not (string= name "."))
367                   (not (string= name ".."))
368                   (%path-pstr*= wild name)
369                   (eq (%unix-file-kind (setq subdir (%str-cat dir name)) t) :directory))
370          (let ((so-far (cons (%path-std-quotes name nil "/;:*") so-far)))
371            (declare (dynamic-extent so-far))
372            (setq result
373                  (nconc (%directory (%str-cat subdir "/") rest path so-far keys) result))))))
374    result))
375
376(defun %files-in-directory (dir path so-far keys)
377  (let ((name (pathname-name path))
378        (type (pathname-type path))
379        (directories (getf keys :directories))
380        (files (getf keys :files))
381        (directory-pathnames (getf keys :directory-pathnames))
382        (test (getf keys :test))
383        (follow-links (getf keys :follow-links))
384        (all (getf keys :all))
385        (include-emacs-lockfiles (getf keys :include-emacs-lockfiles))
386        (result ())
387        sub dir-list ans)
388    (if (not (or name type))
389      (when directories
390        (setq ans (if directory-pathnames
391                    (%cons-pathname (reverse so-far) nil nil)
392                    (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
393        (when (and ans (or (null test) (funcall test ans)))
394          (setq result (list ans))))
395      (with-open-dir (dirent dir)
396        (while (setq sub (%read-dir dirent))
397          (when (and (or all (neq (%schar sub 0) #\.))
398                     (or include-emacs-lockfiles
399                         (< (length sub) 2)
400                         (not (string= sub ".#" :end1 2)))
401                     (not (string= sub "."))
402                     (not (string= sub ".."))
403                     (%file*= name type sub))
404            (setq ans
405                  (if (eq (%unix-file-kind (%str-cat dir sub) t) :directory)
406                    (when directories
407                      (let* ((std-sub (%path-std-quotes sub nil "/;:*")))
408                        (if directory-pathnames
409                          (%cons-pathname (reverse (cons std-sub so-far)) nil nil)
410                          (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) std-sub nil))))
411                    (when files
412                      (multiple-value-bind (name type) (%std-name-and-type sub)
413                        (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type)))))
414            (when (and ans (or (null test) (funcall test ans)))
415              (push (if follow-links (or (probe-file ans) ans) ans) result))))))
416    result))
417
418(defun %all-directories (dir rest path so-far keys)
419  (let ((do-files nil)
420        (do-dirs nil)
421        (result nil)
422        (name (pathname-name path))
423        (type (pathname-type path))
424        (all (getf keys :all))
425        (test (getf keys :test))
426        (directory-pathnames (getf keys :directory-pathnames))
427        (follow-links (getf keys :follow-links))
428        sub subfile dir-list ans)
429    ;; First process the case that the ** stands for 0 components
430    (multiple-value-bind (next-dir next-wild next-rest) (%split-dir rest)
431      (while (and next-wild ; Check for **/**/ which is the same as **/
432                  (string= next-dir "/")
433                  (string= next-wild "**"))
434        (setq rest next-rest)
435        (multiple-value-setq (next-dir next-wild next-rest) (%split-dir rest)))
436      (cond ((not (string= next-dir "/"))
437             (setq result
438                   (%some-specific dir next-dir next-wild next-rest path so-far keys)))
439            (next-wild
440             (setq result
441                   (%one-wild dir next-wild next-rest path so-far keys)))
442            ((or name type)
443             (when (getf keys :files) (setq do-files t))
444             (when (getf keys :directories) (setq do-dirs t)))
445            (t (when (getf keys :directories)
446                 (setq sub (if directory-pathnames
447                             (%cons-pathname (setq dir-list (reverse so-far)) nil nil)
448                             (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
449                 (when (or (null test) (funcall test sub))
450                   (setq result (list (if follow-links (truename sub) sub))))))))
451    ; now descend doing %all-dirs on dirs and collecting files & dirs if do-x is t
452    (with-open-dir (dirent dir)
453      (while (setq sub (%read-dir dirent))
454        (when (and (or all (neq (%schar sub 0) #\.))
455                   (not (string= sub "."))
456                   (not (string= sub "..")))
457          (if (eq (%unix-file-kind (setq subfile (%str-cat dir sub)) t) :directory)
458            (let* ((std-sub (%path-std-quotes sub nil "/;:*"))
459                   (so-far (cons std-sub so-far))
460                   (subdir (%str-cat subfile "/")))
461              (declare (dynamic-extent so-far))
462              (when (and do-dirs (%file*= name type sub))
463                (setq ans (if directory-pathnames
464                            (%cons-pathname (reverse so-far) nil nil)
465                            (%cons-pathname (or dir-list (setq dir-list (reverse (cdr so-far))))
466                                            std-sub nil)))
467                (when (or (null test) (funcall test ans))
468                  (push (if follow-links (truename ans) ans) result)))
469              (setq result (nconc (%all-directories subdir rest path so-far keys) result)))
470            (when (and do-files (%file*= name type sub))
471              (multiple-value-bind (name type) (%std-name-and-type sub)
472                (setq ans (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type))
473                (when (or (null test) (funcall test ans))
474                  (push (if follow-links (truename ans) ans) result))))))))
475    result))
476
477(defun %split-dir (dir &aux pos)                 ; dir ends in a "/".
478  ;"/foo/bar/../x*y/baz/../z*t/"  ->  "/foo/bar/../" "x*y" "/baz/../z*t/"
479  (if (null (setq pos (%path-mem "*" dir)))
480    (values dir nil nil)
481    (let (epos (len (length dir)))
482      (setq pos (if (setq pos (%path-mem-last "/" dir 0 pos)) (%i+ pos 1) 0)
483            epos (%path-mem "/" dir pos len))
484      (when (%path-mem-last-quoted "/" dir 0 pos)
485        (signal-file-error $xbadfilenamechar dir #\/))
486      (values (unless (%izerop pos) (namestring-unquote (%substr dir 0 pos)))
487              (%substr dir pos epos)
488              (%substr dir epos len)))))
489
490(defun %path-pstr*= (pattern pstr &optional (p-start 0))
491  (assert (eq p-start 0))
492  (%path-str*= pstr pattern))
493
494(defun %file*= (name-pat type-pat pstr)
495  (if (eq name-pat :wild) (setq name-pat "*"))
496  (if (eq type-pat :wild) (setq type-pat "*"))
497  (when (and (null name-pat) (null type-pat))
498    (return-from %file*= T))
499  (let* ((end (length pstr))
500         (pos (position #\. pstr :from-end t))
501         (type (and pos (%substr pstr (%i+ pos 1) end)))
502         (name (unless (eq (or pos end) 0) (if pos (%substr pstr 0 pos) pstr))))
503    (and (cond ((or (eq name-pat :unspecific) (null name-pat)) (null name))
504               (t (%path-pstr*= name-pat (or name ""))))
505         (cond ((or (null type-pat) (eq type-pat :unspecific)) (null type))
506               (t (%path-pstr*= type-pat (or type "")))))))
507
508(provide "PATHNAMES")
Note: See TracBrowser for help on using the repository browser.