source: trunk/source/lib/pathnames.lisp @ 10642

Last change on this file since 10642 was 10642, checked in by gb, 13 years ago

rename on windows: destination file can't exist.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 20.4 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   Portions copyright (C) 2001 Clozure Associates
5;;;   This file is part of OpenMCL. 
6;;;
7;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with OpenMCL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;pathnames.lisp Pathnames for Coral Common LISP
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require 'level-2)
23  (require 'backquote)
24)
25;(defconstant $accessDenied -5000) ; put this with other errnos
26(defconstant $afpAccessDenied -5000) ; which name to use?
27
28
29
30;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
31;ANSI CL logical pathnames
32
33
34(defvar *pathname-translations-pathname*
35  (make-pathname :host "ccl" :type "pathname-translations"))
36
37(defun load-logical-pathname-translations (host)
38  ;(setq host (verify-logical-host-name host))
39  (when (not (%str-assoc host %logical-host-translations%))
40    (setf (logical-pathname-translations host)
41          (with-open-file (file (merge-pathnames (make-pathname :name host :defaults nil)
42                                                 *pathname-translations-pathname*)
43                                :element-type 'base-char)
44            (read file)))
45    T))
46
47(defun back-translate-pathname (path &optional hosts)
48  (let ((newpath (back-translate-pathname-1 path hosts)))
49    (cond ((equalp path newpath)
50           ;; (fcomp-standard-source path)
51           (namestring (pathname path)))
52          (t newpath))))
53
54
55(defun back-translate-pathname-1 (path &optional hosts)
56  (dolist (host %logical-host-translations%)
57    (when (or (null hosts) (member (car host) hosts :test 'string-equal))
58      (dolist (trans (cdr host))
59        (when (pathname-match-p path (cadr trans))
60          (let* (newpath)         
61            (setq newpath (translate-pathname path (cadr trans) (car trans) :reversible t))
62            (return-from back-translate-pathname-1 
63              (if  (equalp path newpath) path (back-translate-pathname-1 newpath hosts))))))))
64  path)
65
66
67
68; must be after back-translate-pathname
69(defun physical-pathname-p (path)
70  (let* ((path (pathname path))
71         (dir (pathname-directory path)))
72    (and dir
73         (or (not (logical-pathname-p path))
74             (not (null (memq (pathname-host path) '(nil :unspecific))))))))
75
76
77
78;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
79;File or directory Manipulations
80
81(defun unix-rename (old-name new-name)
82  (with-cstrs ((old old-name)
83               (new new-name))
84    #+windows-target
85    (#__unlink new)
86    (let* ((res (#_rename old new)))
87      (declare (fixnum res))
88      (if (zerop res)
89        (values t nil)
90        (values nil (%get-errno))))))
91
92(defun rename-file (file new-name &key (if-exists :error))
93  "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
94  file, then the associated file is renamed."
95  (let* ((original (truename file))
96         (original-namestring (native-translated-namestring original))
97         (new-name (merge-pathnames new-name original))
98         (new-namestring (native-translated-namestring new-name)))
99    (unless new-namestring
100      (error "~S can't be created." new-name))
101    (unless (and (probe-file new-name)
102                 (not (if-exists if-exists new-name)))
103      (multiple-value-bind (res error)
104                           (unix-rename original-namestring
105                                        new-namestring)
106        (unless res
107          (error "Failed to rename ~A to ~A: ~A"
108                 original new-name error))
109        (when (streamp file)
110          (setf (stream-filename file)
111                (namestring (native-to-pathname new-namestring))))
112        (values new-name original (truename new-name))))))
113
114(defun copy-file (source-path dest-path &key (if-exists :error)
115                              (preserve-attributes nil))
116  (let* ((original (truename source-path))
117         (new-name (merge-pathnames dest-path original))
118         (buffer (make-array 4096 :element-type '(unsigned-byte 8))))
119    (with-open-file (in original :direction :input
120                        :element-type '(unsigned-byte 8))
121      (with-open-file (out new-name :direction :output
122                           :if-exists if-exists
123                           :element-type '(unsigned-byte 8))
124        (loop
125          as n = (stream-read-vector in buffer 0 4096) until (eql n 0)
126          do (stream-write-vector out buffer 0 n))))
127    (when preserve-attributes
128      (copy-file-attributes original new-name))
129    (values new-name original (truename new-name))))
130
131(defun recursive-copy-directory (source-path dest-path &key test (if-exists :error))
132  ;; TODO: Support :if-exists :supersede to blow away any files not in source dir
133  (assert (directoryp source-path)(source-path)
134          "source-path is not a directory in RECURSIVE-COPY-DIRECTORY")
135  (setq if-exists (require-type if-exists '(member :overwrite :error)))
136  (setq dest-path (ensure-directory-pathname dest-path))
137  (when (eq if-exists :error)
138    (when (probe-file dest-path)
139      (if-exists if-exists dest-path))
140    ;; Skip the probe-file in recursive calls, we already know it's ok.
141    (setq if-exists :overwrite))
142  (let* ((source-dir (ensure-directory-pathname source-path))
143         (pattern (make-pathname :name :wild :type :wild :defaults source-dir))
144         (source-files (directory pattern :test test :directories t :files t)))
145    (ensure-directories-exist dest-path)
146    (dolist (f source-files)
147      (when (or (null test) (funcall test f))
148        (if (directory-pathname-p f)
149            (let ((dest-file (make-pathname :name (first (last (pathname-directory f)))
150                                            :defaults dest-path)))
151              (recursive-copy-directory f dest-file :test test :if-exists if-exists))
152            (let* ((dest-file (make-pathname :name (pathname-name f)
153                                             :type (pathname-type f)
154                                             :defaults dest-path)))
155              (copy-file f dest-file :if-exists :supersede :preserve-attributes t)))))))
156
157;;; use with caution!
158;;; blows away a directory and all its contents
159(defun recursive-delete-directory (path &key (if-does-not-exist :error))
160  (setq path (ensure-directory-pathname path))
161  (setq if-does-not-exist (require-type if-does-not-exist '(member :error nil)))
162  (when (eq if-does-not-exist :error)
163    (unless (probe-file path)
164      (if-does-not-exist if-does-not-exist path)))
165  (when (probe-file path)
166      (if (directoryp path)
167          ;; it's a directory: blow it away
168          (let* ((pattern (make-pathname :name :wild :type :wild :defaults path))
169                 (files (directory pattern :directories nil :files t))
170                 (subdirs (directory pattern :directories t :files nil))
171                 (target-pathname (native-translated-namestring path)))
172            (dolist (f files)
173              (delete-file f))
174            (dolist (d subdirs)
175              (recursive-delete-directory d :if-does-not-exist if-does-not-exist))
176            (%rmdir target-pathname))
177          ;; it's not a directory: for safety's sake, signal an error
178          (error "Pathname '~A' is not a directory" path))))
179
180;;; It's not clear that we can support anything stronger than
181;;; "advisory" ("you pretend the file's locked & I will too") file
182;;; locking under Darwin.
183
184
185
186
187(defun create-directory (path &key (mode #o777))
188  (let* ((pathname (translate-logical-pathname (merge-pathnames path)))
189         (created-p nil)
190         (parent-dirs (let* ((pd (pathname-directory pathname)))
191                        (if (eq (car pd) :relative)
192                          (pathname-directory (merge-pathnames
193                                               pathname
194                                               (mac-default-directory)))
195                          pd)))
196         (nparents (length parent-dirs)))
197    (when (wild-pathname-p pathname)
198      (error 'file-error :error-type "Inappropriate use of wild pathname ~s"
199             :pathname pathname))
200    (do* ((i 1 (1+ i)))
201         ((> i nparents) (values pathname created-p))
202      (declare (fixnum i))
203      (let* ((parent (make-pathname
204                      :name :unspecific
205                      :type :unspecific
206                      :host (pathname-host pathname)
207                      :device (pathname-device pathname)
208                      :directory (subseq parent-dirs 0 i)))
209             (parent-name (native-translated-namestring parent))
210             (parent-kind (%unix-file-kind parent-name)))
211
212        (if parent-kind
213          (unless (eq parent-kind :directory)
214            (error 'simple-file-error
215                   :error-type "Can't create directory ~s, since file ~a exists and is not a directory"
216                   :pathname pathname
217                   :format-arguments (list parent-name)))
218          (let* ((result (%mkdir parent-name mode)))
219            (declare (fixnum result))
220            (if (< result 0)
221              (signal-file-error result parent-name)
222              (setq created-p t))))))))
223
224
225(defun ensure-directories-exist (pathspec &key verbose (mode #o777))
226  "Test whether the directories containing the specified file
227  actually exist, and attempt to create them if they do not.
228  The MODE argument is an extension to control the Unix permission
229  bits.  Portable programs should avoid using the :MODE keyword
230  argument."
231  (let* ((pathname (make-directory-pathname :directory (pathname-directory (translate-logical-pathname (merge-pathnames pathspec)))))
232         (created-p nil))
233    (when (wild-pathname-p pathname)
234      (error 'file-error
235             :error-type "Inappropriate use of wild pathname ~s"
236             :pathname pathname))
237    (let ((dir (pathname-directory pathname)))
238      (if (eq (car dir) :relative)
239        (setq dir (pathname-directory (merge-pathnames
240                                       pathname
241                                       (mac-default-directory)))))
242      (loop for i from 1 upto (length dir)
243            do (let ((newpath (make-pathname
244                               :name :unspecific
245                               :type :unspecific
246                               :host (pathname-host pathname)
247                               :device (pathname-device pathname)
248                               :directory (subseq dir 0 i))))
249                 (unless (probe-file newpath)
250                   (let ((namestring (native-translated-namestring newpath)))
251                     (when verbose
252                       (format *standard-output* "~&Creating directory: ~A~%"
253                               namestring))
254                     (%mkdir namestring mode)
255                     (unless (probe-file newpath)
256                       (error 'file-error
257                              :pathname namestring
258                              :error-type "Can't create directory ~S."))
259                     (setf created-p t)))))
260      (values pathspec created-p))))
261
262(defun dirpath-to-filepath (path)
263  (setq path (translate-logical-pathname (merge-pathnames path)))
264  (let* ((dir (pathname-directory path))
265         (super (butlast dir))
266         (name (car (last dir))))
267    (when (eq name :up)
268      (setq dir (remove-up (copy-list dir)))
269      (setq super (butlast dir))
270      (setq name (car (last dir))))
271    (when (null super)
272      (signal-file-error $xnocreate path))
273    (setq path (make-pathname :directory super :name name :defaults nil))))
274
275(defun filepath-to-dirpath (path)
276  (let* ((dir (pathname-directory path))
277         (rest (file-namestring path)))
278    (make-pathname :directory (append dir (list rest)) :defaults nil)))
279 
280
281
282;Takes a pathname, returns the truename of the directory if the pathname
283;names a directory, NIL if it names an ordinary file, error otherwise.
284;E.g. (directoryp "ccl;:foo:baz") might return #P"hd:mumble:foo:baz:" if baz
285;is a dir. - should we doc this - its exported?
286(defun directoryp (path)
287  (let* ((native (native-translated-namestring path))
288         (realpath (%realpath native)))
289    (if realpath (eq (%unix-file-kind realpath) :directory))))
290         
291
292;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
293;Wildcards
294
295
296
297 
298;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
299;Directory Traversing
300
301(defmacro with-open-dir ((dirent dir) &body body)
302  `(let ((,dirent (%open-dir ,dir)))
303     (when ,dirent
304       (unwind-protect
305           (progn ,@body)
306         (close-dir ,dirent)))))
307
308(defun directory (path &key (directories nil) ;; include subdirectories
309                            (files t)         ;; include files
310                            (all t)           ;; include Unix dot files (other than dot and dot dot)
311                            (directory-pathnames t) ;; return directories as directory-pathname-p's.
312                            (include-emacs-lockfiles nil) ;; inculde .#foo
313                            test              ;; Only return pathnames matching test
314                            (follow-links t)) ;; return truename's of matching files.
315  "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
316   given pathname. Note that the interaction between this ANSI-specified
317   TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
318   means this function can sometimes return files which don't have the same
319   directory as PATHNAME."
320  (let* ((keys (list :directories directories ;list defaulted key values
321                     :files files
322                     :all all
323                     :directory-pathnames directory-pathnames
324                     :test test
325                     :include-emacs-lockfiles include-emacs-lockfiles
326                     :follow-links follow-links))
327         (path (full-pathname (merge-pathnames path) :no-error nil))
328         (dir (directory-namestring path)))
329    (declare (dynamic-extent keys))
330    (if (null (pathname-directory path))
331      (setq dir (directory-namestring (setq path
332                                            (merge-pathnames path
333                                                             (mac-default-directory))))))
334    (assert (eq (car (pathname-directory path)) :absolute) ()
335            "full-pathname returned relative path ~s??" path)
336    ;; return sorted in alphabetical order, target-Xload-level-0 depends
337    ;; on this.
338    (nreverse
339     (delete-duplicates (%directory "/" dir path '(:absolute) keys) :test #'equal))))
340
341(defun %directory (dir rest path so-far keys)
342  (multiple-value-bind (sub-dir wild rest) (%split-dir rest)
343    (%some-specific dir sub-dir wild rest path so-far keys)))
344
345(defun %some-specific (dir sub-dir wild rest path so-far keys)
346  (let* ((start 1)
347         (end (length sub-dir))
348         (full-dir (if (eq start end) dir (%str-cat dir (%substr sub-dir start end)))))
349    (while (neq start end)
350      (let ((pos (position #\/ sub-dir :start start :end end)))
351        (push (%path-std-quotes (%substr sub-dir start pos) nil "/:;*") so-far)
352        (setq start (%i+ 1 pos))))
353    (cond ((null wild)
354           (%files-in-directory full-dir path so-far keys))
355          ((string= wild "**")
356           (%all-directories full-dir rest path so-far keys))
357          (t (%one-wild full-dir wild rest path so-far keys)))))
358
359; for a * or *x*y
360(defun %one-wild (dir wild rest path so-far keys)
361  (let ((result ()) (all (getf keys :all)) name subdir)
362    (with-open-dir (dirent dir)
363      (while (setq name (%read-dir dirent))
364        (when (and (or all (neq (%schar name 0) #\.))
365                   (not (string= name "."))
366                   (not (string= name ".."))
367                   (%path-pstr*= wild name)
368                   (eq (%unix-file-kind (setq subdir (%str-cat dir name)) t) :directory))
369          (let ((so-far (cons (%path-std-quotes name nil "/;:*") so-far)))
370            (declare (dynamic-extent so-far))
371            (setq result
372                  (nconc (%directory (%str-cat subdir "/") rest path so-far keys) result))))))
373    result))
374
375(defun %files-in-directory (dir path so-far keys)
376  (let ((name (pathname-name path))
377        (type (pathname-type path))
378        (directories (getf keys :directories))
379        (files (getf keys :files))
380        (directory-pathnames (getf keys :directory-pathnames))
381        (test (getf keys :test))
382        (follow-links (getf keys :follow-links))
383        (all (getf keys :all))
384        (include-emacs-lockfiles (getf keys :include-emacs-lockfiles))
385        (result ())
386        sub dir-list ans)
387    (if (not (or name type))
388      (when directories
389        (setq ans (if directory-pathnames
390                    (%cons-pathname (reverse so-far) nil nil)
391                    (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
392        (when (and ans (or (null test) (funcall test ans)))
393          (setq result (list ans))))
394      (with-open-dir (dirent dir)
395        (while (setq sub (%read-dir dirent))
396          (when (and (or all (neq (%schar sub 0) #\.))
397                     (or include-emacs-lockfiles
398                         (and (>= (length sub) 2)
399                              (not (string= sub ".#" :end1 2))))
400                     (not (string= sub "."))
401                     (not (string= sub ".."))
402                     (%file*= name type sub))
403            (setq ans
404                  (if (eq (%unix-file-kind (%str-cat dir sub) t) :directory)
405                    (when directories
406                      (let* ((std-sub (%path-std-quotes sub nil "/;:*")))
407                        (if directory-pathnames
408                          (%cons-pathname (reverse (cons std-sub so-far)) nil nil)
409                          (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) std-sub nil))))
410                    (when files
411                      (multiple-value-bind (name type) (%std-name-and-type sub)
412                        (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type)))))
413            (when (and ans (or (null test) (funcall test ans)))
414              (push (if follow-links (or (probe-file ans) ans) ans) result))))))
415    result))
416
417(defun %all-directories (dir rest path so-far keys)
418  (let ((do-files nil)
419        (do-dirs nil)
420        (result nil)
421        (name (pathname-name path))
422        (type (pathname-type path))
423        (all (getf keys :all))
424        (test (getf keys :test))
425        (directory-pathnames (getf keys :directory-pathnames))
426        (follow-links (getf keys :follow-links))
427        sub subfile dir-list ans)
428    ;; First process the case that the ** stands for 0 components
429    (multiple-value-bind (next-dir next-wild next-rest) (%split-dir rest)
430      (while (and next-wild ; Check for **/**/ which is the same as **/
431                  (string= next-dir "/")
432                  (string= next-wild "**"))
433        (setq rest next-rest)
434        (multiple-value-setq (next-dir next-wild next-rest) (%split-dir rest)))
435      (cond ((not (string= next-dir "/"))
436             (setq result
437                   (%some-specific dir next-dir next-wild next-rest path so-far keys)))
438            (next-wild
439             (setq result
440                   (%one-wild dir next-wild next-rest path so-far keys)))
441            ((or name type)
442             (when (getf keys :files) (setq do-files t))
443             (when (getf keys :directories) (setq do-dirs t)))
444            (t (when (getf keys :directories)
445                 (setq sub (if directory-pathnames
446                             (%cons-pathname (setq dir-list (reverse so-far)) nil nil)
447                             (%cons-pathname (reverse (cdr so-far)) (car so-far) nil)))
448                 (when (or (null test) (funcall test sub))
449                   (setq result (list (if follow-links (truename sub) sub))))))))
450    ; now descend doing %all-dirs on dirs and collecting files & dirs if do-x is t
451    (with-open-dir (dirent dir)
452      (while (setq sub (%read-dir dirent))
453        (when (and (or all (neq (%schar sub 0) #\.))
454                   (not (string= sub "."))
455                   (not (string= sub "..")))
456          (if (eq (%unix-file-kind (setq subfile (%str-cat dir sub)) t) :directory)
457            (let* ((std-sub (%path-std-quotes sub nil "/;:*"))
458                   (so-far (cons std-sub so-far))
459                   (subdir (%str-cat subfile "/")))
460              (declare (dynamic-extent so-far))
461              (when (and do-dirs (%file*= name type sub))
462                (setq ans (if directory-pathnames
463                            (%cons-pathname (reverse so-far) nil nil)
464                            (%cons-pathname (or dir-list (setq dir-list (reverse (cdr so-far))))
465                                            std-sub nil)))
466                (when (or (null test) (funcall test ans))
467                  (push (if follow-links (truename ans) ans) result)))
468              (setq result (nconc (%all-directories subdir rest path so-far keys) result)))
469            (when (and do-files (%file*= name type sub))
470              (multiple-value-bind (name type) (%std-name-and-type sub)
471                (setq ans (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type))
472                (when (or (null test) (funcall test ans))
473                  (push (if follow-links (truename ans) ans) result))))))))
474    result))
475
476(defun %split-dir (dir &aux pos)                 ; dir ends in a "/".
477  ;"/foo/bar/../x*y/baz/../z*t/"  ->  "/foo/bar/../" "x*y" "/baz/../z*t/"
478  (if (null (setq pos (%path-mem "*" dir)))
479    (values dir nil nil)
480    (let (epos (len (length dir)))
481      (setq pos (if (setq pos (%path-mem-last "/" dir 0 pos)) (%i+ pos 1) 0)
482            epos (%path-mem "/" dir pos len))
483      (when (%path-mem-last-quoted "/" dir 0 pos)
484        (signal-file-error $xbadfilenamechar dir #\/))
485      (values (unless (%izerop pos) (namestring-unquote (%substr dir 0 pos)))
486              (%substr dir pos epos)
487              (%substr dir epos len)))))
488
489(defun %path-pstr*= (pattern pstr &optional (p-start 0))
490  (assert (eq p-start 0))
491  (%path-str*= pstr pattern))
492
493(defun %file*= (name-pat type-pat pstr)
494  (if (eq name-pat :wild) (setq name-pat "*"))
495  (if (eq type-pat :wild) (setq type-pat "*"))
496  (when (and (null name-pat) (null type-pat))
497    (return-from %file*= T))
498  (let* ((end (length pstr))
499         (pos (position #\. pstr :from-end t))
500         (type (and pos (%substr pstr (%i+ pos 1) end)))
501         (name (unless (eq (or pos end) 0) (if pos (%substr pstr 0 pos) pstr))))
502    (and (cond ((or (eq name-pat :unspecific) (null name-pat)) (null name))
503               (t (%path-pstr*= name-pat (or name ""))))
504         (cond ((or (null type-pat) (eq type-pat :unspecific)) (null type))
505               (t (%path-pstr*= type-pat (or type "")))))))
506
507(provide "PATHNAMES")
Note: See TracBrowser for help on using the repository browser.