source: trunk/source/lib/macros.lisp @ 8764

Last change on this file since 8764 was 8764, checked in by gb, 13 years ago

DEFGENERIC, DEFMETHOD: note the lambda list, possibly introducing
&ALLOW-OTHER-KEYS when &KEY is specified.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 142.3 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;;; Macros (and functions/constants used at macroexpand-time) ONLY.
18
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require "LEVEL-2")
23  (require "BACKQUOTE")
24  (require "DEFSTRUCT-MACROS"))
25
26;; Constants
27
28(defmacro defconstant (sym val &optional (doc () doc-p) &environment env)
29  "Define a global constant, saying that the value is constant and may be
30  compiled into code. If the variable already has a value, and this is not
31  EQL to the new value, the code is not portable (undefined behavior). The
32  third argument is an optional documentation string for the variable."
33  (setq sym (require-type sym 'symbol)
34        doc (if doc-p (require-type doc 'string)))
35  `(progn
36     (eval-when (:compile-toplevel)
37       (define-compile-time-constant ',sym ',val ,env))
38     (eval-when (:load-toplevel :execute)
39       (%defconstant ',sym ,val ,@(if doc-p (list doc))))))
40
41;; Lists
42
43(defmacro %car (x)
44  `(car (the cons ,x)))
45
46(defmacro %cdr (x)
47  `(cdr (the cons ,x)))
48
49(defmacro %caar (x)
50 `(%car (%car ,x)))
51
52(defmacro %cadr (x)
53 `(%car (%cdr ,x)))
54
55(defmacro %cdar (x)
56 `(%cdr (%car ,x)))
57
58(defmacro %cddr (x)
59 `(%cdr (%cdr ,x)))
60
61(defmacro %caaar (x)
62 `(%car (%car (%car ,x))))
63
64(defmacro %caadr (x)
65 `(%car (%car (%cdr ,x))))
66
67(defmacro %cadar (x)
68 `(%car (%cdr (%car ,x))))
69
70(defmacro %caddr (x)
71 `(%car (%cdr (%cdr ,x))))
72
73(defmacro %cdaar (x)
74 `(%cdr (%car (%car ,x))))
75
76(defmacro %cdadr (x)
77 `(%cdr (%car (%cdr ,x))))
78
79(defmacro %cddar (x)
80 `(%cdr (%cdr (%car ,x))))
81
82(defmacro %cdddr (x)
83 `(%cdr (%cdr (%cdr ,x))))
84
85(defmacro %rplaca (x y)
86  `(rplaca (the cons ,x) ,y))
87
88(defmacro %rplacd (x y)
89  `(rplacd (the cons ,x) ,y))
90
91; These are open-coded by the compiler to isolate platform
92; dependencies.
93
94(defmacro %unbound-marker-8 ()
95  `(%unbound-marker))
96
97(defmacro %slot-missing-marker ()
98  `(%illegal-marker))
99
100
101
102
103(defmacro %null-ptr () '(%int-to-ptr 0))
104
105;;;Assorted useful macro definitions
106
107(defmacro def-accessors (ref &rest names)
108  (define-accessors ref names))
109
110(defmacro def-accessor-macros (ref &rest names)
111  (define-accessors ref names t))
112
113(defun define-accessors (ref names &optional no-constants
114                             &aux (arg (gensym)) (index 0) progn types)
115  (when (listp ref)
116    (setq types ref
117          ref (pop names)))
118  (dolist (name names)
119    (when name
120      (unless (listp name) (setq name (list name)))
121      (dolist (sym name)
122        (when sym
123          (push `(defmacro ,sym (,arg) (list ',ref ,arg ,index)) progn)
124          (unless no-constants
125            (push `(defconstant ,sym ,index) progn)))))
126    (setq index (1+ index)))
127 `(progn
128    ,.(nreverse progn)
129    ,@(if types `((add-accessor-types ',types ',names)))
130    ,index))
131
132(defmacro specialv (var)
133  `(locally (declare (special ,var)) ,var))
134
135
136(defmacro prog1 (valform &rest otherforms)
137 (let ((val (gensym)))
138 `(let ((,val ,valform))
139   ,@otherforms
140   ,val)))
141
142(defmacro prog2 (first second &rest others)
143 `(progn ,first (prog1 ,second ,@others)))
144
145(defmacro prog (inits &body body &environment env)
146  (multiple-value-bind (forms decls) (parse-body body env nil)
147    `(block nil
148       (let ,inits
149         ,@decls
150         (tagbody ,@forms)))))
151
152(defmacro prog* (inits &body body &environment env)
153  (multiple-value-bind (forms decls) (parse-body body env nil)
154    `(block nil
155       (let* ,inits
156         ,@decls
157         (tagbody ,@forms)))))
158
159
160(defmacro %stack-block ((&rest specs) &body forms &aux vars lets)
161  (dolist (spec specs)
162    (destructuring-bind (var ptr &key clear) spec
163      (push var vars)
164      (push `(,var (%new-ptr ,ptr ,clear)) lets)))
165  `(let* ,(nreverse lets)
166     (declare (dynamic-extent ,@vars))
167     (declare (type macptr ,@vars))
168     (declare (unsettable ,@vars))
169     ,@forms))
170
171(defmacro %vstack-block (spec &body forms)
172  `(%stack-block (,spec) ,@forms))
173
174(defmacro dolist ((varsym list &optional ret) &body body &environment env)
175  (if (not (symbolp varsym)) (signal-program-error $XNotSym varsym))
176  (let* ((toplab (gensym))
177         (tstlab (gensym))
178         (lstsym (gensym)))
179    (multiple-value-bind (forms decls) (parse-body body env nil)
180     `(block nil
181       (let* ((,lstsym ,list) ,varsym)
182        ,@decls
183          (tagbody
184            (go ,tstlab)
185            ,toplab
186            (setq ,lstsym (cdr (the list ,lstsym)))
187            ,@forms
188            ,tstlab
189            (setq ,varsym (car ,lstsym))
190            (if ,lstsym (go ,toplab)))
191          ,@(if ret `((progn  ,ret))))))))
192
193
194(defmacro dovector ((varsym vector &optional ret) &body body &environment env)
195  (if (not (symbolp varsym))(signal-program-error $XNotSym varsym))
196  (let* ((toplab (gensym))
197         (tstlab (gensym))
198         (lengthsym (gensym))
199         (indexsym (gensym))
200         (vecsym (gensym)))
201    (multiple-value-bind (forms decls) (parse-body body env nil)
202     `(let* ((,vecsym ,vector)
203             (,lengthsym (length ,vecsym))
204             (,indexsym 0)
205             ,varsym)
206        ,@decls
207        ,@(let ((type (nx-form-type vector env)))
208            (unless (eq type t)
209              `((declare (type ,type ,vecsym)))))
210        (block nil
211          (tagbody
212            (go ,tstlab)
213            ,toplab
214            (setq ,varsym (locally (declare (optimize (speed 3) (safety 0)))
215                            (aref ,vecsym ,indexsym))
216                  ,indexsym (%i+ ,indexsym 1))
217            ,@forms
218            ,tstlab
219            (if (%i< ,indexsym ,lengthsym) (go ,toplab)))
220          ,@(if ret `((progn (setq ,varsym nil) ,ret))))))))
221
222(defmacro report-bad-arg (&rest args)
223  `(values (%badarg ,@args)))
224
225(defmacro %cons-restart (name action report interactive test)
226 `(gvector :istruct 'restart ,name ,action ,report ,interactive ,test))
227
228(defmacro restart-bind (clauses &body body)
229  "Executes forms in a dynamic context where the given restart bindings are
230   in effect. Users probably want to use RESTART-CASE. When clauses contain
231   the same restart name, FIND-RESTART will find the first such clause."
232  (let* ((restarts (mapcar #'(lambda (clause) 
233                               (list (make-symbol (symbol-name (require-type (car clause) 'symbol)))
234                                     `(%cons-restart nil nil nil nil nil)))
235                           clauses))
236         (bindings (mapcar #'(lambda (clause name)
237                              `(make-restart ,(car name) ',(car clause)
238                                             ,@(cdr clause)))
239                           clauses restarts))
240        (cluster (gensym)))
241    `(let* (,@restarts)
242       (declare (dynamic-extent ,@(mapcar #'car restarts)))
243       (let* ((,cluster (list ,@bindings))
244              (%restarts% (cons ,cluster %restarts%)))
245         (declare (dynamic-extent ,cluster %restarts%))
246         (progn
247           ,@body)))))
248
249(defmacro handler-bind (clauses &body body)
250  "(HANDLER-BIND ( {(type handler)}* )  body)
251   Executes body in a dynamic context where the given handler bindings are
252   in effect. Each handler must take the condition being signalled as an
253   argument. The bindings are searched first to last in the event of a
254   signalled condition."
255  (let* ((fns)
256         (decls)         
257         (bindings (mapcan #'(lambda (clause)
258                               (destructuring-bind (condition handler) clause
259                                 (if (and (consp handler)(eq (car handler) 'function)
260                                          (consp (cadr handler))(eq (car (cadr handler)) 'lambda))
261                                   (let ((fn (gensym)))
262                                     (push `(,fn ,handler) fns)
263                                     (push `(declare (dynamic-extent ,fn)) decls)
264                                     `(',condition ,fn))
265                                   (list `',condition
266                                         `,handler))))
267                           clauses))
268        (cluster (gensym)))   
269    `(let* (,@fns
270            (,cluster (list ,@bindings))
271            (%handlers% (cons ,cluster %handlers%)))
272       (declare (dynamic-extent ,cluster %handlers%))
273       ,@decls
274       (progn
275         ,@body))))
276
277(defmacro restart-case (&environment env form &rest clauses)
278  "(RESTART-CASE form
279   {(case-name arg-list {keyword value}* body)}*)
280   The form is evaluated in a dynamic context where the clauses have special
281   meanings as points to which control may be transferred (see INVOKE-RESTART).
282   When clauses contain the same case-name, FIND-RESTART will find the first
283   such clause. If Expression is a call to SIGNAL, ERROR, CERROR or WARN (or
284   macroexpands into such) then the signalled condition will be associated with
285   the new restarts."
286  (let ((cluster nil))
287    (when clauses (setq cluster (gensym) form (restart-case-form form env cluster)))
288    (flet ((restart-case-1 (name arglist &rest forms)
289             (let (interactive report test)
290               (loop
291                 (case (car forms)
292                   (:interactive (setq interactive (cadr forms)))
293                   (:report (setq report (cadr forms)))
294                   (:test (setq test (cadr forms)))
295                   (t (return nil)))
296                 (setq forms (cddr forms)))
297               (when (and report (not (stringp report)))
298                 (setq report `#',report))
299               (when interactive
300                 (setq interactive `#',interactive))
301               (when test
302                 (setq test `#',test))
303               (values (require-type name 'symbol) arglist report interactive test forms))))
304      (cond ((null clauses) form)
305            ((and (null (cdr clauses)) (null (cadr (car clauses))))
306             (let ((block (gensym)) 
307                   (restart-name (gensym)))
308               (multiple-value-bind (name arglist report interactive test body)
309                                    (apply #'restart-case-1 (car clauses))
310                 (declare (ignore arglist))
311                 `(block ,block
312                    (let* ((,restart-name (%cons-restart ',name () ,report ,interactive ,test))
313                           (,cluster (list ,restart-name))
314                           (%restarts% (cons ,cluster %restarts%)))
315                      (declare (dynamic-extent ,restart-name ,cluster %restarts%))
316                      (catch ,cluster (return-from ,block ,form)))
317                    ,@body))))
318            (t
319             (let ((block (gensym)) (val (gensym))
320                   (index -1) restarts restart-names restart-name cases)
321               (while clauses
322                 (setq index (1+ index))
323                 (multiple-value-bind (name arglist report interactive test body)
324                                      (apply #'restart-case-1 (pop clauses))
325                   (push (setq restart-name (make-symbol (symbol-name name))) restart-names)
326                   (push (list restart-name `(%cons-restart ',name ,index ,report ,interactive ,test))
327                         restarts)
328                   (when (null clauses) (setq index t))
329                   (push `(,index (apply #'(lambda ,arglist ,@body) ,val))
330                         cases)))
331               `(block ,block
332                  (let ((,val (let* (,@restarts
333                                     (,cluster (list ,@(reverse restart-names)))
334                                     (%restarts% (cons ,cluster %restarts%)))
335                                (declare (dynamic-extent ,@restart-names ,cluster %restarts%))
336                                (catch ,cluster (return-from ,block ,form)))))
337                    (case (pop ,val)
338                      ,@(nreverse cases))))))))))
339
340
341; Anything this hairy should die a slow and painful death.
342; Unless, of course, I grossly misunderstand...
343(defun restart-case-form (form env clustername)
344  (let ((expansion (macroexpand form env))
345        (head nil))
346    (if (and (listp expansion)          ; already an ugly hack, made uglier by %error case ...
347             (memq (setq head (pop expansion)) '(signal error cerror warn %error)))
348      (let ((condform nil)
349            (signalform nil)
350            (cname (gensym)))
351        (case head
352          (cerror
353           (destructuring-bind 
354             (continue cond &rest args) expansion
355             (setq condform `(condition-arg ,cond (list ,@args) 'simple-error)
356                   signalform `(cerror ,continue ,cname))))
357          ((signal error warn)
358           (destructuring-bind
359             (cond &rest args) expansion
360             (setq condform `(condition-arg ,cond (list ,@args) ,(if (eq head 'warning)
361                                                                   ''simple-warning
362                                                                   (if (eq head 'error)
363                                                                     ''simple-error
364                                                                     ''simple-condition)))
365                   signalform `(,head ,cname))))
366          (t ;%error
367           (destructuring-bind (cond args fp) expansion
368             (setq condform `(condition-arg ,cond ,args 'simple-error)
369                   signalform `(%error ,cname nil ,fp)))))
370        `(let ((,cname ,condform))
371           (with-condition-restarts ,cname ,clustername
372             ,signalform)))
373      form)))
374     
375
376(defmacro handler-case (form &rest clauses)
377  "(HANDLER-CASE form
378   { (type ([var]) body) }* )
379   Execute FORM in a context with handlers established for the condition
380   types. A peculiar property allows type to be :NO-ERROR. If such a clause
381   occurs, and form returns normally, all its values are passed to this clause
382   as if by MULTIPLE-VALUE-CALL.  The :NO-ERROR clause accepts more than one
383   var specification."
384  (let* ((no-error-clause (assoc :no-error clauses)))
385    (if no-error-clause
386      (let* ((normal-return (gensym))
387             (error-return (gensym)))
388        `(block ,error-return
389          (multiple-value-call #'(lambda ,@(cdr no-error-clause))
390            (block ,normal-return
391              (return-from ,error-return
392                (handler-case (return-from ,normal-return ,form)
393                  ,@(remove no-error-clause clauses)))))))
394      (flet ((handler-case (type var &rest body)
395               (when (eq type :no-error)
396                 (signal-program-error "Duplicate :no-error clause. "))
397           (values type var body)))
398        (cond ((null clauses) form)
399          ((null (cdr clauses))
400           (let ((block   (gensym))
401                 (cluster (gensym)))
402             (multiple-value-bind (type var body)
403                                  (apply #'handler-case (car clauses))
404               (if var
405                 `(block ,block
406                    ((lambda ,var ,@body)
407                      (let* ((,cluster (list ',type))
408                            (%handlers% (cons ,cluster %handlers%)))
409                       (declare (dynamic-extent ,cluster %handlers%))
410                       (catch ,cluster (return-from ,block ,form)))))
411                 `(block ,block
412                    (let* ((,cluster (list ',type))
413                           (%handlers% (cons ,cluster %handlers%)))
414                      (declare (dynamic-extent ,cluster %handlers%))
415                      (catch ,cluster (return-from ,block ,form)))
416                    (locally ,@body))))))
417          (t (let ((block (gensym)) (cluster (gensym)) (val (gensym))
418                   (index -1) handlers cases)
419               (while clauses
420                 (setq index (1+ index))
421                 (multiple-value-bind (type var body)
422                                      (apply #'handler-case (pop clauses))                   
423                   (push `',type handlers)
424                   (push index handlers)
425                   (when (null clauses) (setq index t))
426                   (push (if var
427                           `(,index ((lambda ,var ,@body) ,val))
428                           `(,index (locally ,@body))) cases)))
429               `(block ,block
430                  (let ((,val (let* ((,cluster (list ,@(nreverse handlers)))
431                                     (%handlers% (cons ,cluster %handlers%)))
432                                (declare (dynamic-extent ,cluster %handlers%))
433                                (catch ,cluster (return-from ,block ,form)))))
434                    (case (pop ,val)
435                      ,@(nreverse cases)))))))))))
436
437(defmacro with-simple-restart ((restart-name format-string &rest format-args)
438                               &body body
439                               &aux (cluster (gensym)) (temp (make-symbol (symbol-name restart-name))))
440  "(WITH-SIMPLE-RESTART (restart-name format-string format-arguments)
441   body)
442   If restart-name is not invoked, then all values returned by forms are
443   returned. If control is transferred to this restart, it immediately
444   returns the values NIL and T."
445  (unless (and (stringp format-string)
446               (null format-args)
447               (not (%str-member #\~ (ensure-simple-string format-string))))
448    (let ((stream (gensym)))
449      (setq format-string `#'(lambda (,stream) (format ,stream ,format-string ,@format-args)))))
450  `(let* ((,temp (%cons-restart ',restart-name
451                                'simple-restart
452                                ,format-string
453                                nil
454                                nil))
455          (,cluster (list ,temp))
456          (%restarts% (cons ,cluster %restarts%)))
457     (declare (dynamic-extent ,temp ,cluster %restarts%))
458     (catch ,cluster ,@body)))
459
460;Like with-simple-restart but takes a pre-consed restart.  Not CL.
461(defmacro with-restart (restart &body body &aux (cluster (gensym)))
462  `(let* ((,cluster (list ,restart))
463          (%restarts% (cons ,cluster %restarts%)))
464     (declare (dynamic-extent ,cluster %restarts%))
465     (catch ,cluster ,@body)))
466
467(defmacro ignore-errors (&rest forms)
468  "Execute FORMS handling ERROR conditions, returning the result of the last
469  form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
470  `(handler-case (progn ,@forms)
471     (error (condition) (values nil condition))))
472
473(defmacro def-kernel-restart (&environment env errno name arglist &body body)
474  (multiple-value-bind (body decls)
475                       (parse-body body env)
476    `(let* ((fn (nfunction ,name (lambda ,arglist ,@decls (block ,name ,@body))))
477            (pair (assq ,errno ccl::*kernel-restarts*)))
478       (if pair
479         (rplacd pair fn)
480         (push (cons ,errno fn) ccl::*kernel-restarts*))
481       fn)))
482
483
484;;; Setf.
485
486;  If you change anything here, be sure to make the corresponding change
487;  in get-setf-method.
488(defmacro setf (&rest args &environment env)
489  "Takes pairs of arguments like SETQ. The first is a place and the second
490  is the value that is supposed to go into that place. Returns the last
491  value. The place argument may be any of the access forms for which SETF
492  knows a corresponding setting form."
493  (let ((temp (length args))
494        (accessor nil))
495    (cond ((eq temp 2)
496           (let* ((form (car args)) 
497                  (value (cadr args)))
498             ;This must match get-setf-method .
499             (if (atom form)
500               (progn
501                 (unless (symbolp form)(signal-program-error $XNotSym form))
502                 `(setq ,form ,value))
503               (multiple-value-bind (ftype local-p)
504                                    (function-information (setq accessor (car form)) ENV)
505                 (if local-p
506                   (if (eq ftype :function)
507                     ;Local function, so don't use global setf definitions.
508                     (default-setf form value env)
509                     `(setf ,(macroexpand-1 form env) ,value))
510                   (cond
511                    ((setq temp (%setf-method accessor))
512                     (if (symbolp temp)
513                       `(,temp ,@(cdar args) ,value)
514                       (multiple-value-bind (dummies vals storevars setter #|getter|#)
515                                            (funcall temp form env)
516                         (do* ((d dummies (cdr d))
517                               (v vals (cdr v))
518                               (let-list nil))
519                              ((null d)
520                               (setq let-list (nreverse let-list))
521                               `(let* ,let-list
522                                  (declare (ignorable ,@dummies))
523                                  (multiple-value-bind ,storevars ,value
524                                    #|,getter|#
525                                    ,setter)))
526                           (push (list (car d) (car v)) let-list)))))
527                    ((and (type-and-refinfo-p (setq temp (or (environment-structref-info accessor env)
528                                                             (and #-bccl (boundp '%structure-refs%)
529                                                                  (gethash accessor %structure-refs%)))))
530                          (not (refinfo-r/o (if (consp temp) (%cdr temp) temp))))
531                     (if (consp temp)
532                       ;; strip off type, but add in a require-type
533                       (let ((type (%car temp)))
534                         `(the ,type (setf ,(defstruct-ref-transform (%cdr temp) (%cdar args))
535                                           (require-type ,value ',type))))
536                       `(setf ,(defstruct-ref-transform temp (%cdar args))
537                              ,value)))
538                    (t
539                     (multiple-value-bind (res win)
540                                          (macroexpand-1 form env)
541                       (if win
542                         `(setf ,res ,value)
543                         (default-setf form value env))))))))))
544          ((oddp temp)
545           (error "Odd number of args to SETF : ~s." args))
546          (t (do* ((a args (cddr a)) (l nil))
547                  ((null a) `(progn ,@(nreverse l)))
548               (push `(setf ,(car a) ,(cadr a)) l))))))
549
550
551(defun default-setf (setter value &optional env)
552  (let* ((reader (car setter))
553         (args (cdr setter))
554         (gensyms (mapcar #'(lambda (sym) (declare (ignore sym)) (gensym)) args))
555         types declares)
556    (flet ((form-type (form)
557             (nx-form-type form env)))
558      (declare (dynamic-extent #'form-type))
559      (setq types (mapcar #'form-type args)))
560    (dolist (sym gensyms)
561      (let ((sym-type (pop types)))
562        (unless (eq sym-type t)
563          (push `(type ,sym-type ,sym) declares))))
564    `(let ,(mapcar #'list gensyms args)
565       ,@(and declares (list `(declare ,@(nreverse declares))))
566       (funcall #'(setf ,reader) ,value ,@gensyms))))
567
568;; Establishing these setf-inverses is something that should
569;; happen at compile-time
570(defsetf elt set-elt)
571(defsetf car set-car)
572(defsetf first set-car)
573(defsetf cdr set-cdr)
574(defsetf rest set-cdr)
575(defsetf uvref uvset)
576(defsetf aref aset)
577(defsetf svref svset)
578(defsetf %svref %svset)
579(defsetf char set-char)
580(defsetf schar set-schar)
581(defsetf %scharcode %set-scharcode)
582(defsetf symbol-value set)
583(defsetf symbol-plist set-symbol-plist)
584(defsetf fill-pointer set-fill-pointer)
585
586; This sux; it calls the compiler twice (once to shove the macro in the
587; environment, once to dump it into the file.)
588(defmacro defmacro  (name arglist &body body &environment env)
589  (unless (symbolp name)(signal-program-error $XNotSym name))
590  (unless (listp arglist) (signal-program-error "~S is not a list." arglist))
591  (multiple-value-bind (lambda-form doc)
592                       (parse-macro-1 name arglist body env)
593    (let* ((normalized (normalize-lambda-list arglist t t))
594           (body-pos (position '&body normalized))
595           (argstring (let ((temp nil))
596                        (dolist (arg normalized)
597                          (if (eq arg '&aux)
598                            (return)
599                            (push arg temp)))
600                        (format nil "~:a" (nreverse temp)))))
601      (if (and body-pos (memq '&optional normalized)) (decf body-pos))
602      `(progn
603         (eval-when (:compile-toplevel)
604           (define-compile-time-macro ',name ',lambda-form ',env))
605         (eval-when (:load-toplevel :execute)
606           (%macro 
607            (nfunction ,name ,lambda-form)
608            '(,doc ,body-pos . ,argstring))
609           ',name)))))
610
611(defmacro define-symbol-macro (name expansion &environment env)
612  (unless (symbolp name)(signal-program-error $XNotSym name))
613  `(progn
614    (eval-when (:compile-toplevel)
615      (define-compile-time-symbol-macro ',name ',expansion ',env))
616    (eval-when (:load-toplevel :execute)
617      (%define-symbol-macro ',name ',expansion))))
618
619;; ---- allow inlining setf functions
620(defmacro defun (spec args &body body &environment env &aux global-name inline-spec)
621  "Define a function at top level."
622  (validate-function-name spec)
623  (setq args (require-type args 'list))
624  (setq body (require-type body 'list))
625  (multiple-value-bind (forms decls doc) (parse-body body env t)
626    (cond ((symbolp spec)
627           (setq global-name spec)
628           (setq inline-spec spec)
629           (setq body `(block ,spec ,@forms)))
630          ((and (consp spec) (eq 'setf (%car spec)))
631           (setq inline-spec spec)
632           (setq body `(block ,(cadr spec) ,@forms)))
633          (t (setq body `(progn ,@forms))))
634    (let* ((lambda-expression `(lambda ,args 
635                                ,@(if global-name
636                                    `((declare (global-function-name ,global-name))))
637                                ,@decls ,body))
638           (info (if (and inline-spec
639                          (or (null env)
640                              (definition-environment env t))
641                          (nx-declared-inline-p inline-spec env)
642                          (not (and (symbolp inline-spec)
643                                    (gethash inline-spec *NX1-ALPHATIZERS*))))
644                   (cons doc lambda-expression)
645                   doc)))
646      `(progn
647         (eval-when (:compile-toplevel)
648           (note-function-info ',spec ',lambda-expression ,env))
649         (%defun (nfunction ,spec ,lambda-expression) ',info)
650         ',spec))))
651
652(defmacro %defvar-init (var initform doc)
653  `(unless (%defvar ',var ,doc)
654     (setq ,var ,initform)))
655
656(defmacro defvar (&environment env var &optional (value () value-p) doc)
657  "Define a global variable at top level. Declare the variable
658  SPECIAL and, optionally, initialize it. If the variable already has a
659  value, the old value is not clobbered. The third argument is an optional
660  documentation string for the variable."
661  (if (and doc (not (stringp doc))) (report-bad-arg doc 'string))
662  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
663    (setq doc nil))
664 `(progn
665    (eval-when (:compile-toplevel)
666      (note-variable-info ',var ,value-p ,env))
667    ,(if value-p
668       `(%defvar-init ,var ,value ,doc)
669       `(%defvar ',var))
670    ',var))
671         
672(defmacro def-standard-initial-binding (name &optional (form name) &environment env)
673  `(progn
674    (eval-when (:compile-toplevel)
675      (note-variable-info ',name t ,env))   
676    (define-standard-initial-binding ',name #'(lambda () ,form))
677    ',name))
678
679(defmacro defparameter (&environment env var value &optional doc)
680  "Define a parameter that is not normally changed by the program,
681  but that may be changed without causing an error. Declare the
682  variable special and sets its value to VAL, overwriting any
683  previous value. The third argument is an optional documentation
684  string for the parameter."
685  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
686  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
687    (setq doc nil))
688  `(progn
689     (eval-when (:compile-toplevel)
690       (note-variable-info ',var t ,env))
691     (%defparameter ',var ,value ,doc)))
692
693
694(defmacro defstatic (&environment env var value &optional doc)
695  "Syntax is like DEFPARAMETER.  Proclaims the symbol to be special,
696but also asserts that it will never be given a per-thread dynamic
697binding.  The value of the variable can be changed (via SETQ, etc.),
698but since all threads access the same static binding of the variable,
699such changes should be made with care."
700  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
701  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
702    (setq doc nil))
703  `(progn
704     (eval-when (:compile-toplevel)
705       (note-variable-info ',var :global ,env))
706     (%defglobal ',var ,value ,doc)))
707
708
709(defmacro defglobal (&rest args)
710  "Synonym for DEFSTATIC."
711  `(defstatic ,@args))
712
713
714(defmacro defloadvar (&environment env var value &optional doc)
715  `(progn
716     (defstatic ,var ,nil ,@(if doc `(,doc)))
717     (def-ccl-pointers ,var ()
718       (setq ,var ,value))
719     ',var))
720
721
722
723
724(defmacro qlfun (name args &body body)
725  `(nfunction ,name (lambda ,args ,@body)))
726
727(defmacro lfun-bits-known-function (f)
728  (let* ((temp (gensym)))
729    `(let* ((,temp (function-to-function-vector ,f)))
730      (%svref ,temp (the fixnum (1- (the fixnum (uvsize ,temp))))))))
731
732; %Pascal-Functions% Entry
733; Used by "l1;ppc-callback-support" & "lib;dumplisp"
734(def-accessor-macros %svref
735  pfe.routine-descriptor
736  pfe.proc-info
737  pfe.lisp-function
738  pfe.sym
739  pfe.without-interrupts
740  pfe.trace-p)
741
742(defmacro cond (&rest args &aux clause)
743  (when args
744     (setq clause (car args))
745     (if (cdr clause)         
746         `(if ,(car clause) (progn ,@(cdr clause)) (cond ,@(cdr args)))
747       (if (cdr args) `(or ,(car clause) (cond ,@(cdr args)))
748                      `(values ,(car clause))))))
749
750(defmacro and (&rest args)
751  "And Form*
752AND evaluates each form in sequence, from left to right.  If any form
753returns NIL, AND returns NIL; otherwise, AND returns the values(s) returned
754by the last form.  If there are no forms, AND returns T."
755  (if (null args) t
756    (if (null (cdr args)) (car args)
757      `(if ,(car args) (and ,@(cdr args))))))
758
759(defmacro or (&rest args)
760  "Or Form*
761OR evaluates each Form, in sequence, from left to right.
762If any Form but the last returns a non-NIL value, OR returns that
763single value (without evaluating any subsequent Forms.)  If OR evaluates
764the last Form, it returns all values returned by that Form.  If there
765are no Forms, OR returns NIL."
766  (if args
767    (if (cdr args)
768      (do* ((temp (gensym))
769            (handle (list nil))
770            (forms `(let ((,temp ,(pop args)))
771                     (if ,temp ,temp ,@handle))))
772           ((null (cdr args))
773            (%rplaca handle (%car args))
774            forms)
775        (%rplaca handle `(if (setq ,temp ,(%car args)) 
776                          ,temp 
777                          ,@(setq handle (list nil))))
778        (setq args (%cdr args)))
779      (%car args))))
780
781(defmacro case (key &body forms)
782  "CASE Keyform {({(Key*) | Key} Form*)}*
783  Evaluates the Forms in the first clause with a Key EQL to the value of
784  Keyform. If a singleton key is T then the clause is a default clause."
785   (let ((key-var (gensym)))
786     `(let ((,key-var ,key))
787        (declare (ignorable ,key-var))
788        (cond ,@(case-aux forms key-var nil nil)))))
789
790(defmacro ccase (keyplace &body forms)
791  "CCASE Keyform {({(Key*) | Key} Form*)}*
792  Evaluates the Forms in the first clause with a Key EQL to the value of
793  Keyform. If none of the keys matches then a correctable error is
794  signalled."
795  (let* ((key-var (gensym))
796         (tag (gensym)))
797    `(prog (,key-var)
798       ,tag
799       (setq ,key-var ,keyplace)
800       (return (cond ,@(case-aux forms key-var tag keyplace))))))
801
802(defmacro ecase (key &body forms)
803  "ECASE Keyform {({(Key*) | Key} Form*)}*
804  Evaluates the Forms in the first clause with a Key EQL to the value of
805  Keyform. If none of the keys matches then an error is signalled."
806  (let* ((key-var (gensym)))
807    `(let ((,key-var ,key))
808       (declare (ignorable ,key-var))
809       (cond ,@(case-aux forms key-var 'ecase nil)))))
810       
811(defun case-aux (clauses key-var e-c-p placename &optional (used-keys (list (list '%case-core))))
812  (if clauses
813    (let* ((key-list (caar clauses))
814           (stype (if e-c-p (if (eq e-c-p 'ecase) e-c-p 'ccase) 'case))
815           (test (cond ((and (not e-c-p)
816                             (or (eq key-list 't)
817                                 (eq key-list 'otherwise)))
818                        t)
819                       (key-list
820                        (cons 'or
821                              (case-key-testers key-var used-keys key-list stype)))))
822           (consequent-list (or (%cdar clauses) '(nil))))
823      (if (eq test t)
824        (progn
825          (when (%cdr clauses) (warn "~s or ~s clause in the middle of a ~s statement.  Subsequent clauses ignored."
826                                     't 'otherwise 'case))
827          (cons (cons t consequent-list) nil))
828        (cons (cons test consequent-list)
829              (case-aux (%cdr clauses) key-var e-c-p placename used-keys))))
830    (when e-c-p
831      (setq used-keys `(member ,@(mapcar #'car (cdr used-keys))))
832      (if (eq e-c-p 'ecase)
833        `((t (values (%err-disp #.$XWRONGTYPE ,key-var ',used-keys))))
834        `((t (setf ,placename (ensure-value-of-type ,key-var ',used-keys ',placename))
835           (go ,e-c-p)))))))
836
837
838;;; We don't want to descend list structure more than once (like this has
839;;; been doing for the last 18 years or so.)
840(defun case-key-testers (symbol used-keys atom-or-list statement-type &optional recursive)
841  (if (or recursive (atom atom-or-list))
842    (progn
843      (if (assoc atom-or-list used-keys)
844        (warn "Duplicate keyform ~s in ~s statement." atom-or-list statement-type)
845        (nconc used-keys (list (cons atom-or-list t))))
846      `((,(if (typep atom-or-list '(and number (not fixnum)))
847              'eql
848              'eq)
849         ,symbol ',atom-or-list)))
850    (nconc (case-key-testers symbol used-keys (car atom-or-list) statement-type t)
851           (when (cdr atom-or-list)
852             (case-key-testers symbol used-keys (%cdr atom-or-list) statement-type nil)))))
853
854
855; generate the COND body of a {C,E}TYPECASE form
856(defun typecase-aux (key-var clauses &optional e-c-p keyform)
857  (let* ((construct (if e-c-p (if (eq e-c-p 'etypecase) e-c-p 'ctypecase) 'typecase))
858         (types ())
859         (body ())
860         otherwise-seen-p)
861    (flet ((bad-clause (c) 
862             (error "Invalid clause ~S in ~S form." c construct)))
863      (dolist (clause clauses)
864        (if (atom clause)
865            (bad-clause clause))
866        (if otherwise-seen-p
867            (error "OTHERWISE must be final clause in ~S form." construct))
868        (destructuring-bind (typespec &body consequents) clause
869          (when (eq construct 'typecase)
870            (if (eq typespec 'otherwise)
871                (progn (setq typespec t)
872                       (setq otherwise-seen-p t))))
873          (unless
874              (dolist (already types nil)
875                (when (subtypep typespec already)
876                  (warn "Clause ~S ignored in ~S form - shadowed by ~S ." clause construct (assq already clauses))
877                  (return t)))
878            (push typespec types)
879            (setq typespec `(typep ,key-var ',typespec))
880            (push `(,typespec nil ,@consequents) body))))
881      (when e-c-p
882        (setq types `(or ,@(nreverse types)))
883        (if (eq construct 'etypecase)
884            (push `(t (values (%err-disp #.$XWRONGTYPE ,key-var ',types))) body)
885            (push `(t (setf ,keyform (ensure-value-of-type  ,key-var ',types ',keyform))
886                      (go ,e-c-p)) body))))
887    `(cond ,@(nreverse body))))
888
889(defmacro typecase (keyform &body clauses)
890  "TYPECASE Keyform {(Type Form*)}*
891  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
892  is true."
893  (let ((key-var (gensym)))
894    `(let ((,key-var ,keyform))
895       (declare (ignorable ,key-var))
896       ,(typecase-aux key-var clauses))))
897
898(defmacro etypecase (keyform &body clauses)
899  "ETYPECASE Keyform {(Type Form*)}*
900  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
901  is true. If no form is satisfied then an error is signalled."
902  (let ((key-var (gensym)))
903    `(let ((,key-var ,keyform))
904       (declare (ignorable ,key-var))
905       ,(typecase-aux key-var clauses 'etypecase))))
906
907(defmacro ctypecase (keyplace &body clauses)
908  "CTYPECASE Key {(Type Form*)}*
909  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
910  is true. If no form is satisfied then a correctable error is signalled."
911  (let ((key-var (gensym))
912        (tag (gensym)))
913    `(prog (,key-var)
914       ,tag
915       (setq ,key-var ,keyplace)
916       (return ,(typecase-aux key-var clauses tag keyplace)))))
917
918(defmacro destructuring-bind (lambda-list expression &body body)
919  "Bind the variables in LAMBDA-LIST to the contents of ARG-LIST."
920  (multiple-value-bind (bindings decls)
921      (%destructure-lambda-list  lambda-list expression nil nil)
922    `(let* ,(nreverse bindings)
923      ,@(when decls `((declare ,@decls)))
924      ,@body)))
925
926(defmacro make-destructure-state (tail whole lambda)
927  `(gvector :istruct 'destructure-state ,tail ,whole ,lambda))
928
929
930; This is supposedly ANSI CL.
931(defmacro lambda (&whole lambda-expression (&rest paramlist) &body body)
932  (unless (lambda-expression-p lambda-expression)
933    (warn "Invalid lambda expression: ~s" lambda-expression))
934  `(function (lambda ,paramlist ,@body)))
935
936
937(defmacro when (test &body body)
938  "If the first argument is true, the rest of the forms are
939  evaluated as a PROGN."
940 `(if ,test
941   (progn ,@body)))
942
943(defmacro unless (test &body body)
944  "If the first argument is not true, the rest of the forms are
945  evaluated as a PROGN."
946 `(if (not ,test)
947   (progn ,@body)))
948
949(defmacro return (&optional (form nil form-p))
950  `(return-from nil ,@(if form-p `(,form))))
951
952; since they use tagbody, while & until BOTH return NIL
953(defmacro while (test &body body)
954  (let ((testlab (gensym))
955        (toplab (gensym)))
956    `(tagbody
957       (go ,testlab)
958      ,toplab
959      (progn ,@body)
960      ,testlab
961      (when ,test (go ,toplab)))))
962
963(defmacro until (test &body body)
964  (let ((testlab (gensym))
965        (toplab (gensym)))
966    `(tagbody
967       (go ,testlab)
968      ,toplab
969      (progn ,@body)
970      ,testlab
971      (if (not ,test)
972        (go ,toplab)))))
973
974(defmacro psetq (&whole call &body pairs &environment env)
975  "PSETQ {var value}*
976   Set the variables to the values, like SETQ, except that assignments
977   happen in parallel, i.e. no assignments take place until all the
978   forms have been evaluated."
979  (when pairs
980   (if (evenp (length pairs))
981     (do* ((l pairs (%cddr l))
982           (sym (%car l) (%car l)))
983          ((null l) (%pset pairs))
984       (unless (symbolp sym) (report-bad-arg sym 'symbol))
985       (when (nth-value 1 (macroexpand-1 sym env))
986         (return `(psetf ,@pairs))))
987     (error "Uneven number of args in the call ~S" call))))
988
989; generates body for psetq.
990; "pairs" is a proper list whose length is not odd.
991(defun %pset (pairs)
992 (when pairs
993   (let (vars vals gensyms let-list var val sets)
994      (loop
995        (setq var (pop pairs)
996              val (pop pairs))
997        (if (null pairs) (return))
998        (push var vars)
999        (push val vals)
1000        (push (gensym) gensyms))
1001      (dolist (g gensyms)
1002        (push g sets)
1003        (push (pop vars) sets)
1004        (push (list g (pop vals)) let-list))
1005      (push val sets)
1006      (push var sets)
1007      `(progn
1008         (let ,let-list
1009           (setq ,@sets))
1010         nil))))
1011
1012
1013(eval-when (:compile-toplevel :load-toplevel :execute)
1014(defun do-loop (binder setter env var-init-steps end-test result body)
1015  (let ((toptag (gensym))
1016        (testtag (gensym)))
1017    (multiple-value-bind (forms decls) (parse-body body env nil)
1018      `(block nil
1019         (,binder ,(do-let-vars var-init-steps)
1020                  ,@decls
1021                  (tagbody ; crocks-r-us.
1022                    (go ,testtag)
1023                    ,toptag
1024                    (tagbody
1025                      ,@forms)
1026                    (,setter ,@(do-step-vars var-init-steps))
1027                    ,testtag
1028                    (unless ,end-test
1029                      (go ,toptag)))
1030                  ,@result)))))
1031)
1032
1033(defmacro do (&environment env var-init-steps (&optional end-test &rest result) &body body)
1034  "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1035  Iteration construct. Each Var is initialized in parallel to the value of the
1036  specified Init form. On subsequent iterations, the Vars are assigned the
1037  value of the Step form (if any) in parallel. The Test is evaluated before
1038  each evaluation of the body Forms. When the Test is true, the Exit-Forms
1039  are evaluated as a PROGN, with the result being the value of the DO. A block
1040  named NIL is established around the entire expansion, allowing RETURN to be
1041  used as an alternate exit mechanism."
1042  (do-loop 'let 'psetq env var-init-steps end-test result body))
1043
1044(defmacro do* (&environment env var-init-steps (&optional end-test &rest result) &body body)
1045  "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1046  Iteration construct. Each Var is initialized sequentially (like LET*) to the
1047  value of the specified Init form. On subsequent iterations, the Vars are
1048  sequentially assigned the value of the Step form (if any). The Test is
1049  evaluated before each evaluation of the body Forms. When the Test is true,
1050  the Exit-Forms are evaluated as a PROGN, with the result being the value
1051  of the DO. A block named NIL is established around the entire expansion,
1052  allowing RETURN to be used as an laternate exit mechanism."
1053  (do-loop 'let* 'setq env var-init-steps end-test result body))
1054
1055
1056(defun do-let-vars (var-init-steps)
1057  (if var-init-steps
1058      (cons (list (do-let-vars-var (car var-init-steps))
1059                  (do-let-vars-init (car var-init-steps)))
1060             (do-let-vars (cdr var-init-steps)))))
1061
1062(defun do-let-vars-var (var-init-step)
1063  (if (consp var-init-step)
1064       (car var-init-step)
1065       var-init-step))
1066
1067(defun do-let-vars-init (var-init-step)
1068   (if (consp var-init-step)
1069        (cadr var-init-step)
1070        nil))
1071
1072(defun do-step-vars (var-init-steps)
1073    (if var-init-steps
1074        (if (do-step-vars-step? (car var-init-steps))
1075             (append (list (do-let-vars-var (car var-init-steps))
1076                           (do-step-vars-step (car var-init-steps)))
1077                     (do-step-vars (cdr var-init-steps)))
1078             (do-step-vars (cdr var-init-steps)))))
1079
1080(defun do-step-vars-step? (var-init-step)
1081  (if (consp var-init-step)
1082       (cddr var-init-step)))
1083
1084(defun do-step-vars-step (var-init-step)
1085  (if (consp var-init-step)
1086       (caddr var-init-step)))
1087
1088
1089(defmacro dotimes ((i n &optional result) &body body &environment env)
1090  (multiple-value-bind (forms decls)
1091                       (parse-body body env)
1092    (if (not (symbolp i))(signal-program-error $Xnotsym i))
1093    (let* ((toptag (gensym))
1094           (limit (gensym)))
1095      `(block nil
1096        (let ((,limit ,n) (,i 0))
1097         ,@decls
1098         (declare (unsettable ,i))
1099           (if (int>0-p ,limit)
1100             (tagbody
1101               ,toptag
1102               ,@forms
1103               (locally
1104                (declare (settable ,i))
1105                (setq ,i (1+ ,i)))
1106               (unless (eql ,i ,limit) (go ,toptag))))
1107           ,result)))))
1108 
1109(defun do-syms-result (var resultform)
1110  (unless (eq var resultform)
1111    (if (and (consp resultform) (not (quoted-form-p resultform)))
1112      `(progn (setq ,var nil) ,resultform)
1113      resultform)))
1114
1115(defun expand-package-iteration-macro (iteration-function var pkg-spec resultform body env)
1116  (multiple-value-bind (body decls) (parse-body body env nil)
1117    (let* ((ftemp (gensym))
1118           (vtemp (gensym))
1119           (ptemp (gensym))
1120           (result (do-syms-result var resultform)))
1121      `(block nil
1122        (let* ((,var nil)
1123               (,ptemp ,pkg-spec))
1124          ,@decls
1125           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1126             (declare (dynamic-extent #',ftemp))
1127             (,iteration-function ,ptemp #',ftemp))
1128           ,@(when result `(,result)))))))
1129
1130(defmacro do-symbols ((var &optional pkg result) &body body &environment env)
1131  "DO-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECLARATION}* {TAG | FORM}*
1132   Executes the FORMs at least once for each symbol accessible in the given
1133   PACKAGE with VAR bound to the current symbol."
1134  (expand-package-iteration-macro 'iterate-over-accessable-symbols var pkg result body env))
1135
1136(defmacro do-present-symbols ((var &optional pkg result) &body body &environment env)
1137  (expand-package-iteration-macro 'iterate-over-present-symbols var pkg result body env))
1138
1139(defmacro do-external-symbols ((var &optional pkg result) &body body &environment env)
1140  "DO-EXTERNAL-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECL}* {TAG | FORM}*
1141   Executes the FORMs once for each external symbol in the given PACKAGE with
1142   VAR bound to the current symbol."
1143  (expand-package-iteration-macro 'iterate-over-external-symbols var pkg result body env))
1144
1145(defmacro do-all-symbols ((var &optional resultform)
1146                          &body body &environment env)
1147  "DO-ALL-SYMBOLS (VAR [RESULT-FORM]) {DECLARATION}* {TAG | FORM}*
1148   Executes the FORMs once for each symbol in every package with VAR bound
1149   to the current symbol."
1150  (multiple-value-bind (body decls) (parse-body body env nil)
1151    (let* ((ftemp (gensym))
1152           (vtemp (gensym))
1153           (result (do-syms-result var resultform)))
1154      `(block nil
1155        (let* ((,var nil))
1156         ,@decls
1157           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1158             (declare (dynamic-extent #',ftemp))
1159             (iterate-over-all-symbols #',ftemp))
1160           ,@(when result `(,result)))))))
1161
1162(defmacro multiple-value-list (form)
1163  `(multiple-value-call #'list ,form))
1164
1165
1166
1167
1168(defmacro %i> (x y)
1169  `(> (the fixnum ,x) (the fixnum ,y)))
1170
1171(defmacro %i< (x y)
1172  `(< (the fixnum ,x) (the fixnum ,y)))
1173
1174(defmacro %i<= (x y)
1175 `(not (%i> ,x ,y)))
1176
1177(defmacro %i>= (x y)
1178 `(not (%i< ,x ,y)))
1179
1180(defmacro bitset (bit number)
1181  `(logior (ash 1 ,bit) ,number))
1182
1183(defmacro bitclr (bit number)
1184  `(logand (lognot (ash 1 ,bit)) ,number))
1185
1186(defmacro bitopf ((op bit place) &environment env)
1187  (multiple-value-bind (vars vals stores store-form access-form)
1188                       (get-setf-method place env)
1189    (let* ((constant-bit-p (constantp bit))
1190           (bitvar (if constant-bit-p bit (gensym))))
1191      `(let ,(unless constant-bit-p `((,bitvar ,bit)))          ; compiler isn't smart enough
1192         (let* ,(mapcar #'list `(,@vars ,@stores) `(,@vals (,op ,bitvar ,access-form)))
1193           ,store-form)))))
1194
1195(defmacro bitsetf (bit place)
1196  `(bitopf (bitset ,bit ,place)))
1197
1198(defmacro bitclrf (bit place)
1199  `(bitopf (bitclr ,bit ,place)))
1200
1201(defmacro %svref (v i)
1202  (let* ((vtemp (make-symbol "VECTOR"))
1203           (itemp (make-symbol "INDEX")))
1204      `(let* ((,vtemp ,v)
1205              (,itemp ,i))
1206         (locally (declare (optimize (speed 3) (safety 0)))
1207           (svref ,vtemp ,itemp)))))
1208
1209(defmacro %svset (v i new &environment env)
1210  (let* ((vtemp (make-symbol "VECTOR"))
1211         (itemp (make-symbol "INDEX"))
1212         (ntemp (make-symbol "NEW")))
1213    `(let* ((,vtemp ,v)
1214            (,itemp ,i)
1215            (,ntemp ,new))
1216      (locally (declare (optimize (speed 3) (safety 0)))
1217        (setf (svref ,vtemp ,itemp) ,ntemp)))))
1218
1219
1220(defmacro %schar (v i)
1221  (let* ((vtemp (make-symbol "STRING"))
1222         (itemp (make-symbol "INDEX")))
1223    `(let* ((,vtemp ,v)
1224            (,itemp ,i))
1225       (locally (declare (optimize (speed 3) (safety 0)))
1226         (schar ,vtemp ,itemp)))))
1227
1228(defmacro %set-schar (v i new)
1229  (let* ((vtemp (make-symbol "STRING"))
1230         (itemp (make-symbol "INDEX"))
1231         (ntemp (make-symbol "NEW")))
1232      `(let* ((,vtemp ,v)
1233              (,itemp ,i)
1234              (,ntemp ,new))
1235         (locally (declare (optimize (speed 3) (safety 0)))
1236           (setf (schar ,vtemp ,itemp) ,ntemp)))))
1237
1238
1239
1240(defmacro %char-code (c) `(char-code (the character ,c)))
1241(defmacro %code-char (i) `(code-char (the (mod 256) ,i)))
1242
1243(defmacro %izerop (x) `(eq ,x 0))
1244(defmacro %iminusp (x) `(< (the fixnum ,x) 0))
1245(defmacro %i+ (&rest (&optional (n0 0) &rest others))
1246  (if others
1247    `(the fixnum (+ (the fixnum ,n0) (%i+ ,@others)))
1248    `(the fixnum ,n0)))
1249(defmacro %i- (x y &rest others) 
1250  (if (not others)
1251    `(the fixnum (- (the fixnum ,x) (the fixnum ,y)))
1252    `(the fixnum (- (the fixnum ,x) (the fixnum (%i+ ,y ,@others))))))
1253
1254
1255(defmacro %i* (x y) `(the fixnum (* (the fixnum ,x) (the fixnum ,y))))
1256
1257(defmacro %ilogbitp (b i)
1258  (target-word-size-case
1259   (32
1260    `(logbitp (the (integer 0 29) ,b) (the fixnum ,i)))
1261   (64
1262    `(logbitp (the (integer 0 60) ,b) (the fixnum ,i)))))
1263
1264;;; Seq-Dispatch does an efficient type-dispatch on the given Sequence.
1265
1266(defmacro seq-dispatch (sequence list-form array-form)
1267  `(if (sequence-type ,sequence)
1268       ,list-form
1269       ,array-form))
1270
1271
1272(defsetf %get-byte %set-byte)
1273(defsetf %get-unsigned-byte %set-unsigned-byte)
1274(defsetf %get-signed-byte %set-byte)
1275(defsetf %get-word %set-word)
1276(defsetf %get-signed-word %set-word)
1277(defsetf %get-unsigned-word %set-unsigned-word)
1278(defsetf %get-long %set-long)
1279(defsetf %get-signed-long %set-long)
1280(defsetf %get-unsigned-long %set-unsigned-long)
1281(defsetf %get-full-long %set-long)
1282(defsetf %get-point %set-long)
1283(defsetf %get-ptr %set-ptr)
1284(defsetf %get-double-float %set-double-float)
1285(defsetf %get-single-float %set-single-float)
1286(defsetf %get-bit %set-bit)
1287(defsetf %get-unsigned-long-long %set-unsigned-long-long)
1288(defsetf %%get-unsigned-longlong %%set-unsigned-longlong)
1289(defsetf %get-signed-long-long %set-signed-long-long)
1290(defsetf %%get-signed-longlong %%set-signed-longlong)
1291(defsetf %get-bitfield %set-bitfield)
1292
1293(defmacro %ilognot (int) `(%i- -1 ,int))
1294
1295(defmacro %ilogior2 (x y) 
1296  `(logior (the fixnum ,x) (the fixnum ,y)))
1297
1298(defmacro %ilogior (body &body args)
1299   (while args
1300     (setq body (list '%ilogior2 body (pop args))))
1301   body)
1302
1303(defmacro %ilogand2 (x y)
1304  `(logand (the fixnum ,x) (the fixnum ,y)))
1305
1306(defmacro %ilogand (body &body args)
1307   (while args
1308     (setq body (list '%ilogand2 body (pop args))))
1309   body)
1310
1311(defmacro %ilogxor2 (x y)
1312  `(logxor (the fixnum ,x) (the fixnum ,y)))
1313
1314(defmacro %ilogxor (body &body args)
1315   (while args
1316     (setq body (list '%ilogxor2 body (pop args))))
1317   body)
1318
1319(defmacro with-macptrs (varlist &rest body &environment env)
1320  (multiple-value-bind (body other-decls) (parse-body body env)
1321    (collect ((temp-bindings)
1322              (temp-decls)
1323              (bindings)
1324              (our-decls)
1325              (inits))
1326      (dolist (var varlist)
1327        (let* ((temp (gensym)))
1328          (temp-decls temp)
1329        (if (consp var)
1330          (progn
1331            (our-decls (car var))
1332            (temp-bindings `(,temp (%null-ptr)))
1333            (bindings `(,(car var) ,temp))
1334            (if (cdr var)
1335              (inits `(%setf-macptr ,temp ,@(cdr var)))))
1336          (progn
1337            (our-decls var)
1338            (temp-bindings  `(,temp  (%null-ptr)))
1339            (bindings `(,var ,temp))))))
1340  `(let* ,(temp-bindings)
1341    (declare (dynamic-extent ,@(temp-decls)))
1342    (declare (type macptr ,@(temp-decls)))
1343    ,@(inits)
1344    (let* ,(bindings)
1345      (declare (type macptr ,@(our-decls)))
1346      ,@other-decls
1347      ,@body)))))
1348
1349
1350(defmacro with-loading-file (filename &rest body)
1351   `(let ((*loading-files* (cons ,filename (locally (declare (special *loading-files*))
1352                                                    *loading-files*))))
1353      (declare (special *loading-files*))
1354      ,@body))
1355
1356(defmacro with-input-from-string ((var string &key index start end) &body forms &environment env)
1357  "Create an input string stream, provide an opportunity to perform
1358operations on the stream (returning zero or more values), and then close
1359the string stream.
1360
1361STRING is evaluated first, and VAR is bound to a character input string
1362stream that supplies characters from the subsequence of the resulting
1363string bounded by start and end. BODY is executed as an implicit progn."
1364  (multiple-value-bind (forms decls) (parse-body forms env nil)
1365    `(let ((,var
1366            ,(cond ((null end)
1367                    `(make-string-input-stream ,string ,(or start 0)))
1368                   ((symbolp end)
1369                    `(if ,end
1370                      (make-string-input-stream ,string ,(or start 0) ,end)
1371                      (make-string-input-stream ,string ,(or start 0))))
1372                   (t
1373                    `(make-string-input-stream ,string ,(or start 0) ,end)))))
1374      ,@decls
1375      (unwind-protect
1376           (multiple-value-prog1
1377               (progn ,@forms)
1378             ,@(if index `((setf ,index (string-input-stream-index ,var)))))
1379        (close ,var)))))
1380
1381(defmacro with-output-to-string ((var &optional string &key (element-type 'base-char element-type-p))
1382                                 &body body 
1383                                 &environment env)
1384  "Create a character output stream, perform a series of operations that
1385may send results to this stream, and then close the stream.  BODY is
1386executed as an implicit progn with VAR bound to an output string stream.
1387All output to that string stream is saved in a string."
1388  (let ((string-var (gensym "string")))
1389    (multiple-value-bind (forms decls) (parse-body body env nil)
1390      `(let* ((,string-var ,string)
1391              (,var (if ,string-var
1392                      ,@(if element-type-p
1393                            `((progn
1394                                ,element-type
1395                                (%make-string-output-stream ,string-var)))
1396                            `((%make-string-output-stream ,string-var)))
1397                      ,@(if element-type-p
1398                            `((make-string-output-stream :element-type ,element-type))
1399                            `((make-string-output-stream))))))
1400         ,@decls
1401         (unwind-protect
1402              (progn
1403                ,@forms
1404                ,@(if string () `((get-output-stream-string ,var))))
1405           (close ,var))))))
1406
1407(defmacro with-output-to-truncating-string-stream ((var len) &body body
1408                                                   &environment env)
1409  (multiple-value-bind (forms decls) (parse-body body env nil)
1410    `(let* ((,var (make-truncating-string-stream ,len)))
1411      ,@decls
1412      (unwind-protect
1413           (progn
1414             ,@forms
1415             (values (get-output-stream-string ,var)
1416                     (slot-value ,var 'truncated)))
1417        (close ,var)))))
1418
1419(defmacro with-open-file ((var . args) &body body &aux (stream (gensym))(done (gensym)))
1420  "Use open to create a file stream to file named by filespec. Filespec is
1421the name of the file to be opened. Options are used as keyword arguments
1422to open."
1423  `(let (,stream ,done)
1424     (unwind-protect
1425       (multiple-value-prog1
1426         (let ((,var (setq ,stream (open ,@args))))
1427           ,@body)
1428         (setq ,done t))
1429       (when ,stream (close ,stream :abort (null ,done))))))
1430
1431(defmacro with-compilation-unit ((&key override) &body body)
1432  "WITH-COMPILATION-UNIT ({Key Value}*) Form*
1433  This form affects compilations that take place within its dynamic extent. It
1434  is intended to be wrapped around the compilation of all files in the same
1435  system. These keywords are defined:
1436    :OVERRIDE Boolean-Form
1437        One of the effects of this form is to delay undefined warnings
1438        until the end of the form, instead of giving them at the end of each
1439        compilation. If OVERRIDE is NIL (the default), then the outermost
1440        WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
1441        OVERRIDE true causes that form to grab any enclosed warnings, even if
1442        it is enclosed by another WITH-COMPILATION-UNIT."
1443  `(let* ((*outstanding-deferred-warnings* (%defer-warnings ,override)))
1444     (multiple-value-prog1 (progn ,@body) (report-deferred-warnings))))
1445
1446; Yow! Another Done Fun.
1447(defmacro with-standard-io-syntax (&body body &environment env)
1448  "Bind the reader and printer control variables to values that enable READ
1449   to reliably read the results of PRINT. These values are:
1450       *PACKAGE*                        the COMMON-LISP-USER package
1451       *PRINT-ARRAY*                    T
1452       *PRINT-BASE*                     10
1453       *PRINT-CASE*                     :UPCASE
1454       *PRINT-CIRCLE*                   NIL
1455       *PRINT-ESCAPE*                   T
1456       *PRINT-GENSYM*                   T
1457       *PRINT-LENGTH*                   NIL
1458       *PRINT-LEVEL*                    NIL
1459       *PRINT-LINES*                    NIL
1460       *PRINT-MISER-WIDTH*              NIL
1461       *PRINT-PRETTY*                   NIL
1462       *PRINT-RADIX*                    NIL
1463       *PRINT-READABLY*                 T
1464       *PRINT-RIGHT-MARGIN*             NIL
1465       *READ-BASE*                      10
1466       *READ-DEFAULT-FLOAT-FORMAT*      SINGLE-FLOAT
1467       *READ-EVAL*                      T
1468       *READ-SUPPRESS*                  NIL
1469       *READTABLE*                      the standard readtable"
1470  (multiple-value-bind (decls body) (parse-body body env)
1471    `(let ((*package* (find-package "CL-USER"))
1472           (*print-array* t)
1473           (*print-base* 10.)
1474           (*print-case* :upcase)
1475           (*print-circle* nil)
1476           (*print-escape* t)
1477           (*print-gensym* t)
1478           (*print-length* nil)
1479           (*print-level* nil)
1480           (*print-lines* nil) ; This doesn't exist as of 5/15/90 - does now
1481           (*print-miser-width* nil)
1482           (*print-pprint-dispatch* nil)
1483           (*print-pretty* nil)
1484           (*print-radix* nil)
1485           (*print-readably* t)
1486           (*print-right-margin* nil)
1487           (*read-base* 10.)
1488           (*read-default-float-format* 'single-float)
1489           (*read-eval* t) ; Also MIA as of 5/15/90
1490           (*read-suppress* nil)
1491           (*readtable* %initial-readtable%))
1492       ,@decls
1493       ,@body)))
1494
1495(defmacro with-self-bound-io-control-vars (&body body)
1496  `(let (
1497         (*print-array* *print-array*)
1498         (*print-base* *print-base*)
1499         (*print-case* *print-case*)
1500         (*print-circle* *print-circle*)
1501         (*print-escape* *print-escape*)
1502         (*print-gensym* *print-gensym*)
1503         (*print-length* *print-length*)
1504         (*print-level* *print-level*)
1505         (*print-lines* *print-lines*)
1506         (*print-miser-width* *print-miser-width*)
1507         (*print-pprint-dispatch* *print-pprint-dispatch*)
1508         (*print-pretty* *print-pretty*)
1509         (*print-radix* *print-radix*)
1510         (*print-readably* *print-readably*)
1511         (*print-right-margin* *print-right-margin*)
1512         (*read-base* *read-base*)
1513         (*read-default-float-format* *read-default-float-format*)
1514         (*read-eval* *read-eval*)
1515         (*read-suppress* *read-suppress*)
1516         (*readtable* *readtable*))
1517     ,@body))
1518
1519(defmacro print-unreadable-object (&environment env (object stream &key type identity) &body forms)
1520  "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
1521  with object-type prefix and object-identity suffix, and executing the
1522  code in BODY to provide possible further output."
1523  (multiple-value-bind (body decls) (parse-body forms env)
1524    (if body
1525      (let ((thunk (gensym)))
1526        `(let ((,thunk #'(lambda () ,@decls ,@body)))
1527           (declare (dynamic-extent ,thunk))
1528          (%print-unreadable-object ,object ,stream ,type ,identity ,thunk)))
1529      `(%print-unreadable-object ,object ,stream ,type ,identity nil))))
1530;; Pointers and Handles
1531
1532;;Add function to lisp system pointer functions, and run it if it's not already
1533;; there.
1534(defmacro def-ccl-pointers (name arglist &body body &aux (old (gensym)))
1535  `(flet ((,name ,arglist ,@body))
1536     (let ((,old (member ',name *lisp-system-pointer-functions* :key #'function-name)))
1537       (if ,old
1538         (rplaca ,old #',name)
1539         (progn
1540           (push #',name *lisp-system-pointer-functions*)
1541           (,name))))))
1542
1543(defmacro def-load-pointers (name arglist &body body &aux (old (gensym)))
1544  `(flet ((,name ,arglist ,@body))
1545     (let ((,old (member ',name *lisp-user-pointer-functions* :key #'function-name)))
1546       (if ,old
1547         (rplaca ,old #',name)
1548         (progn
1549           (push #',name *lisp-user-pointer-functions*)
1550           (,name))))))
1551
1552;Queue up some code to run after ccl all loaded up, or, if ccl is already
1553;loaded up, just run it right now.
1554(defmacro queue-fixup (&rest body &aux (fn (gensym)))
1555  `(let ((,fn #'(lambda () ,@body)))
1556     (if (eq %lisp-system-fixups% T)
1557       (funcall ,fn)
1558       (push (cons ,fn *loading-file-source-file*) %lisp-system-fixups%))))
1559
1560(defmacro %incf-ptr (p &optional (by 1))
1561  (if (symbolp p)  ;once-only
1562    `(%setf-macptr (the macptr ,p) (%inc-ptr ,p ,by))
1563    (let ((var (gensym)))
1564      `(let ((,var ,p)) (%setf-macptr (the macptr ,var) (%inc-ptr ,var ,by))))))
1565
1566(defmacro with-string-from-cstring ((s ptr) &body body)
1567  (let* ((len (gensym))
1568         (p (gensym)))
1569    `(let* ((,p ,ptr)
1570            (,len (%cstrlen ,p))
1571            (,s (make-string ,len)))
1572      (declare (fixnum ,len))
1573      (%copy-ptr-to-ivector ,p 0 ,s 0 ,len)
1574      (locally
1575          ,@body))))
1576
1577
1578(defmacro with-cstr ((sym str &optional start end) &rest body &environment env)
1579  (multiple-value-bind (body decls) (parse-body body env nil)
1580    (if (and (base-string-p str) (null start) (null end))
1581      (let ((strlen (%i+ (length str) 1)))
1582        `(%stack-block ((,sym ,strlen))
1583           ,@decls
1584           (%cstr-pointer ,str ,sym)
1585           ,@body))
1586      (let ((strname (gensym))
1587            (start-name (gensym))
1588            (end-name (gensym)))
1589        `(let ((,strname ,str)
1590               ,@(if (or start end)
1591                   `((,start-name ,(or start 0))
1592                     (,end-name ,(or end `(length ,strname))))))
1593           (%vstack-block (,sym
1594                           (the fixnum
1595                             (1+
1596                              (the fixnum
1597                                ,(if (or start end)
1598                                     `(byte-length
1599                                       ,strname ,start-name ,end-name)
1600                                     `(length ,strname))))))
1601             ,@decls
1602             ,(if (or start end)
1603                `(%cstr-segment-pointer ,strname ,sym ,start-name ,end-name)
1604                `(%cstr-pointer ,strname ,sym))
1605             ,@body))))))
1606
1607(defmacro with-utf-8-cstr ((sym str) &body body)
1608  (let* ((data (gensym))
1609         (offset (gensym))
1610         (string (gensym))
1611         (len (gensym))
1612         (noctets (gensym))
1613         (end (gensym)))
1614    `(let* ((,string ,str)
1615            (,len (length ,string)))
1616      (multiple-value-bind (,data ,offset) (array-data-and-offset ,string)
1617        (let* ((,end (+ ,offset ,len))
1618               (,noctets (utf-8-octets-in-string ,data ,offset ,end)))
1619          (%stack-block ((,sym (1+ ,noctets)))
1620            (utf-8-memory-encode ,data ,sym 0 ,offset ,end)
1621            (setf (%get-unsigned-byte ,sym ,noctets) 0)
1622            ,@body))))))
1623
1624
1625
1626
1627
1628(defmacro with-pointers (speclist &body body)
1629   (with-specs-aux 'with-pointer speclist body))
1630
1631
1632
1633(defmacro with-cstrs (speclist &body body)
1634   (with-specs-aux 'with-cstr speclist body))
1635
1636(defmacro with-utf-8-cstrs (speclist &body body)
1637   (with-specs-aux 'with-utf-8-cstr speclist body))
1638
1639(defmacro with-encoded-cstr ((encoding-name (sym string &optional start end))
1640                             &rest body &environment env)
1641  (let* ((encoding (get-character-encoding encoding-name))
1642         (str (gensym))
1643         (len (gensym))
1644         (nzeros (floor (character-encoding-code-unit-size encoding) 8)))
1645    (collect ((trailing-zeros))
1646      (case nzeros
1647        (1 (trailing-zeros `(setf (%get-unsigned-byte ,sym ,len) 0)))
1648        (2 (trailing-zeros `(setf (%get-unsigned-word ,sym ,len) 0)))
1649        (4 (trailing-zeros `(setf (%get-unsigned-long ,sym ,len) 0)))
1650        (t 
1651         (dotimes (i nzeros)
1652           (trailing-zeros `(setf (%get-unsigned-byte ,sym (the fixnum (+ ,len ,i))) 0)))))
1653      (multiple-value-bind (body decls) (parse-body body env nil)
1654        `(let* ((,str ,string))
1655          (%stack-block ((,sym (cstring-encoded-length-in-bytes ,encoding ,str ,start ,end)))
1656            ,@decls
1657            (let* ((,len (encode-string-to-memory ,encoding ,sym 0 ,str ,start ,end)))
1658              (declare (fixnum ,len))
1659              ,@(trailing-zeros)
1660              ,@body)))))))
1661
1662(defmacro with-encoded-cstrs (encoding-name bindings &body body)
1663  (with-specs-aux 'with-encoded-cstr (mapcar #'(lambda (b)
1664                                                 `(,encoding-name ,b))
1665                                             bindings) body))
1666
1667
1668(defun with-specs-aux (name spec-list original-body)
1669  (multiple-value-bind (body decls) (parse-body original-body nil)
1670    (when decls (error "declarations not allowed in ~s" original-body))
1671    (setq body (cons 'progn body))
1672    (dolist (spec (reverse spec-list))
1673      (setq body (list name spec body)))
1674    body))
1675
1676
1677(defmacro type-predicate (type)
1678  `(get-type-predicate ,type))
1679
1680(defsetf type-predicate set-type-predicate)
1681
1682(defun adjust-defmethod-lambda-list (ll)
1683  ;; If the lambda list contains &key, ensure that it also contains
1684  ;; &allow-other-keys
1685  (if (or (not (memq '&key ll))
1686          (memq '&allow-other-keys ll))
1687    ll
1688    (if (memq '&aux ll)
1689      (let* ((ll (copy-list ll))
1690             (aux (memq '&aux ll)))
1691        (setf (car aux) '&allow-other-keys
1692              (cdr aux) (cons '&aux (cdr aux)))
1693        ll)
1694      (append ll '(&allow-other-keys)))))
1695
1696(defmacro defmethod (name &rest args &environment env)
1697  (multiple-value-bind (function-form specializers-form qualifiers lambda-list documentation specializers)
1698                       (parse-defmethod name args env)   
1699    `(progn
1700       (eval-when (:compile-toplevel)
1701         (note-function-info ',name '(lambda ,(adjust-defmethod-lambda-list lambda-list)) ,env))
1702       (compiler-let ((*nx-method-warning-name* 
1703                       (list ',name
1704                             ,@(mapcar #'(lambda (x) `',x) qualifiers)
1705                             ',specializers)))
1706         (ensure-method ',name ,specializers-form
1707                        :function ,function-form
1708                        :qualifiers ',qualifiers
1709                        :lambda-list ',lambda-list
1710                        ,@(if documentation `(:documentation ,documentation)))))))
1711
1712
1713(defun seperate-defmethod-decls (decls)
1714  (let (outer inner)
1715    (dolist (decl decls)
1716      (if (neq (car decl) 'declare)
1717        (push decl outer)
1718        (let (outer-list inner-list)
1719          (dolist (d (cdr decl))
1720            (if (and (listp d) (eq (car d) 'dynamic-extent))
1721              (let (in out)
1722                (dolist (fspec (cdr d))
1723                  (if (and (listp fspec)
1724                           (eq (car fspec) 'function)
1725                           (listp (cdr fspec))
1726                           (null (cddr fspec))
1727                           (memq (cadr fspec) '(call-next-method next-method-p)))
1728                    (push fspec in)
1729                    (push fspec out)))
1730                (when out
1731                  (push `(dynamic-extent ,@(nreverse out)) outer-list))
1732                (when in
1733                  (push `(dynamic-extent ,@(nreverse in)) inner-list)))
1734              (push d outer-list)))
1735          (when outer-list
1736            (push `(declare ,@(nreverse outer-list)) outer))
1737          (when inner-list
1738            (push `(declare ,@(nreverse inner-list)) inner)))))
1739    (values (nreverse outer) (nreverse inner))))
1740                   
1741
1742(defun parse-defmethod (name args env)
1743  (validate-function-name name)
1744  (let (qualifiers lambda-list parameters specializers specializers-form refs types temp)
1745    (until (listp (car args))
1746      (push (pop args) qualifiers))
1747    (setq lambda-list (pop args))
1748    (while (and lambda-list (not (memq (car lambda-list) lambda-list-keywords)))
1749      (let ((p (pop lambda-list)))
1750        (cond ((consp p)
1751               (unless (and (consp (%cdr p)) (null (%cddr p)))
1752                 (signal-program-error "Illegal arg ~S" p))
1753               (push (%car p) parameters)
1754               (push (%car p) refs)
1755               (setq p (%cadr p))
1756               (cond ((and (consp p) (eq (%car p) 'eql)
1757                           (consp (%cdr p)) (null (%cddr p)))
1758                      (push `(list 'eql ,(%cadr p)) specializers-form)
1759                      (push p specializers))
1760                     ((or (setq temp (non-nil-symbol-p p))
1761                          (specializer-p p))
1762                      (push `',p specializers-form)
1763                      (push p specializers)
1764                      (unless (or (eq p t) (not temp))
1765                        ;Should be `(guaranteed-type ...).
1766                        (push `(type ,p ,(%car parameters)) types)))
1767                     (t (signal-program-error "Illegal arg ~S" p))))
1768              (t
1769               (push p parameters)
1770               (push t specializers-form)
1771               (push t specializers)))))
1772    (setq lambda-list (nreconc parameters lambda-list))
1773    (multiple-value-bind (body decls doc) (parse-body args env t)
1774      (multiple-value-bind (outer-decls inner-decls) 
1775                           (seperate-defmethod-decls decls)
1776        (let* ((methvar (make-symbol "NEXT-METHOD-CONTEXT"))
1777               (cnm-args (gensym))
1778               (lambda-form `(lambda ,(list* '&method methvar lambda-list)
1779                               (declare ;,@types
1780                                (ignorable ,@refs))
1781                               ,@outer-decls
1782                               (block ,(if (consp name) (cadr name) name)
1783                                 (flet ((call-next-method (&rest ,cnm-args)
1784                                          (declare (dynamic-extent ,cnm-args))
1785                                          (if ,cnm-args
1786                                            (apply #'%call-next-method-with-args ,methvar ,cnm-args)
1787                                            (%call-next-method ,methvar)))
1788                                        (next-method-p () (%next-method-p ,methvar)))
1789                                   (declare (inline call-next-method next-method-p))
1790                                   ,@inner-decls
1791                                   ,@body)))))
1792          (values
1793           (if name `(nfunction ,name ,lambda-form) `(function ,lambda-form))
1794           `(list ,@(nreverse specializers-form))
1795           (nreverse qualifiers)
1796           lambda-list
1797           doc
1798           (nreverse specializers)))))))
1799
1800(defmacro anonymous-method (name &rest args &environment env)
1801  (multiple-value-bind (function-form specializers-form qualifiers method-class documentation)
1802                       (parse-defmethod name args env)
1803   
1804    `(%anonymous-method
1805      ,function-form
1806      ,specializers-form
1807      ',qualifiers
1808      ,@(if (or method-class documentation) `(',method-class))
1809      ,@(if documentation `(,documentation)))))
1810
1811
1812
1813(defmacro defclass (class-name superclasses slots &rest class-options &environment env)
1814  (flet ((duplicate-options (where) (signal-program-error "Duplicate options in ~S" where))
1815         (illegal-option (option) (signal-program-error "Illegal option ~s" option))
1816         (make-initfunction (form)
1817           (cond ((or (eq form 't)
1818                      (equal form ''t))
1819                  '(function true))
1820                 ((or (eq form 'nil)
1821                      (equal form ''nil))
1822                  '(function false))
1823                 (t
1824                  `(function (lambda () ,form))))))
1825    (setq class-name (require-type class-name '(and symbol (not null))))
1826    (setq superclasses (mapcar #'(lambda (s) (require-type s 'symbol)) superclasses))
1827    (let* ((options-seen ())
1828           (signatures ())
1829           (slot-names))
1830      (flet ((canonicalize-defclass-option (option)
1831               (let* ((option-name (car option)))
1832                 (if (member option-name options-seen :test #'eq)
1833                   (duplicate-options class-options)
1834                   (push option-name options-seen))
1835                 (case option-name
1836                   (:default-initargs
1837                       (let ((canonical ())
1838                             (initargs-seen ()))
1839                         (let (key val (tail (cdr option)))
1840                           (loop (when (null tail) (return nil))
1841                              (setq key (pop tail)
1842                                    val (pop tail))
1843                              (when (memq key initargs-seen)
1844                                (SIGNAL-PROGRAM-error "Duplicate initialization argument name ~S in :DEFAULT-INITARGS of DEFCLASS ~S" key class-name))
1845                              (push key initargs-seen)
1846                              (push ``(,',key ,',val  ,,(make-initfunction val)) canonical))
1847                           `(':direct-default-initargs (list ,@(nreverse canonical))))))
1848                   (:metaclass
1849                    (unless (and (cadr option)
1850                                 (typep (cadr option) 'symbol))
1851                      (illegal-option option))
1852                    `(:metaclass  ',(cadr option)))
1853                   (:documentation
1854                    `(:documentation ',(cadr option)))
1855                   (t
1856                     (list `',option-name `',(cdr option))))))
1857             (canonicalize-slot-spec (slot)
1858               (if (null slot) (signal-program-error "Illegal slot NIL"))
1859               (if (not (listp slot)) (setq slot (list slot)))
1860               (let* ((slot-name (require-type (car slot) 'symbol))
1861                      (initargs nil)
1862                      (other-options ())
1863                      (initform nil)
1864                      (initform-p nil)
1865                      (initfunction nil)
1866                      (type nil)
1867                      (type-p nil)
1868                      (allocation nil)
1869                      (allocation-p nil)
1870                      (documentation nil)
1871                      (documentation-p nil)
1872                      (readers nil)
1873                      (writers nil))
1874                 (when (memq slot-name slot-names)
1875                   (SIGNAL-PROGRAM-error "Multiple slots named ~S in DEFCLASS ~S" slot-name class-name))
1876                 (push slot-name slot-names)
1877                 (do ((options (cdr slot) (cddr options))
1878                      name)
1879                     ((null options))
1880                   (when (null (cdr options)) (signal-program-error "Illegal slot spec ~S" slot))
1881                   (case (car options)
1882                     (:reader
1883                      (setq name (cadr options))
1884                      (push name signatures)
1885                      (push name readers))
1886                     (:writer                     
1887                      (setq name (cadr options))
1888                      (push name signatures)
1889                      (push name writers))
1890                     (:accessor
1891                      (setq name (cadr options))
1892                      (push name signatures)
1893                      (push name readers)
1894                      (push `(setf ,name) signatures)
1895                      (push `(setf ,name) writers))
1896                     (:initarg
1897                      (push (require-type (cadr options) 'symbol) initargs))
1898                     (:type
1899                      (if type-p
1900                        (duplicate-options slot)
1901                        (setq type-p t))
1902                      ;(when (null (cadr options)) (signal-program-error "Illegal options ~S" options))
1903                      (setq type (cadr options)))
1904                     (:initform
1905                      (if initform-p
1906                        (duplicate-options slot)
1907                        (setq initform-p t))
1908                      (let ((option (cadr options)))
1909                        (setq initform `',option
1910                              initfunction
1911                              (if (constantp option)
1912                                `(constantly ,option)
1913                                `#'(lambda () ,option)))))
1914                     (:allocation
1915                      (if allocation-p
1916                        (duplicate-options slot)
1917                        (setq allocation-p t))
1918                      (setq allocation (cadr options)))
1919                     (:documentation
1920                      (if documentation-p
1921                        (duplicate-options slot)
1922                        (setq documentation-p t))
1923                      (setq documentation (cadr options)))
1924                     (t
1925                      (let* ((pair (or (assq (car options) other-options)
1926                                       (car (push (list (car options)) other-options)))))
1927                        (push (cadr options) (cdr pair))))))
1928                 `(list :name ',slot-name
1929                   ,@(when allocation `(:allocation ',allocation))
1930                   ,@(when initform-p `(:initform ,initform
1931                                        :initfunction ,initfunction))
1932                   ,@(when initargs `(:initargs ',initargs))
1933                   ,@(when readers `(:readers ',readers))
1934                   ,@(when writers `(:writers ',writers))
1935                   ,@(when type-p `(:type ',type))
1936                   ,@(when documentation-p `(:documentation ,documentation))
1937                   ,@(mapcan #'(lambda (opt)
1938                                 `(',(car opt) ',(if (null (cddr opt))
1939                                                     (cadr opt)
1940                                                     (cdr opt)))) other-options)))))
1941        (let* ((direct-superclasses superclasses)
1942               (direct-slot-specs (mapcar #'canonicalize-slot-spec slots))
1943               (other-options (apply #'append (mapcar #'canonicalize-defclass-option class-options ))))
1944          `(progn
1945            (eval-when (:compile-toplevel)
1946              (%compile-time-defclass ',class-name ,env)
1947              (progn
1948                ,@(mapcar #'(lambda (s) `(note-function-info ',s nil ,env))
1949                          signatures)))
1950              (ensure-class-for-defclass ',class-name
1951                            :direct-superclasses ',direct-superclasses
1952                            :direct-slots ,`(list ,@direct-slot-specs)
1953                            ,@other-options)))))))
1954
1955(defmacro define-method-combination (name &rest rest &environment env)
1956  (setq name (require-type name 'symbol))
1957  (cond ((or (null rest) (and (car rest) (symbolp (car rest))))
1958         `(short-form-define-method-combination ',name ',rest))
1959        ((listp (car rest))
1960         (destructuring-bind (lambda-list method-group-specifiers . forms) rest
1961           (long-form-define-method-combination 
1962            name lambda-list method-group-specifiers forms env)))
1963        (t (%badarg (car rest) '(or (and null symbol) list)))))
1964
1965(defmacro defgeneric (function-name lambda-list &rest options-and-methods &environment env)
1966  (fboundp function-name)             ; type-check
1967  (multiple-value-bind (method-combination generic-function-class options methods)
1968                       (parse-defgeneric function-name t lambda-list options-and-methods)
1969    (let ((gf (gensym)))
1970      `(progn
1971         (eval-when (:compile-toplevel)
1972           (note-function-info ',function-name '(lambda ,lambda-list nil) ,env))
1973         (let ((,gf (%defgeneric
1974                     ',function-name ',lambda-list ',method-combination ',generic-function-class 
1975                     ',(apply #'append options))))
1976           (%set-defgeneric-methods ,gf ,@methods)
1977           ,gf)))))
1978
1979
1980
1981(defun parse-defgeneric (function-name global-p lambda-list options-and-methods)
1982  (check-generic-function-lambda-list lambda-list)
1983  (let ((method-combination '(standard))
1984        (generic-function-class 'standard-generic-function)
1985        options declarations methods option-keywords method-class)
1986    (flet ((bad-option (o)
1987             (signal-program-error "Bad option: ~s to ~s." o 'defgeneric)))
1988      (dolist (o options-and-methods)
1989        (let ((keyword (car o))
1990              (defmethod (if global-p 'defmethod 'anonymous-method)))
1991          (if (eq keyword :method)
1992            (push `(,defmethod ,function-name ,@(%cdr o)) methods)
1993            (cond ((and (not (eq keyword 'declare))
1994                        (memq keyword (prog1 option-keywords (push keyword option-keywords))))             
1995                   (signal-program-error "Duplicate option: ~s to ~s" keyword 'defgeneric))
1996                  ((eq keyword :method-combination)
1997                   (unless (symbolp (cadr o))
1998                     (bad-option o))
1999                   (setq method-combination (cdr o)))
2000                  ((eq keyword :generic-function-class)
2001                   (unless (and (cdr o) (symbolp (cadr o)) (null (%cddr o)))
2002                     (bad-option o))
2003                   (setq generic-function-class (%cadr o)))
2004                  ((eq keyword 'declare)
2005                   (push (cadr o) declarations))
2006                  ((eq keyword :argument-precedence-order)
2007                   (dolist (arg (cdr o))
2008                     (unless (and (symbolp arg) (memq arg lambda-list))
2009                       (bad-option o)))
2010                   (push (list keyword (cdr o)) options))
2011                  ((eq keyword :method-class)
2012                   (push o options)
2013                   (when (or (cddr o) (not (symbolp (setq method-class (%cadr o)))))
2014                     (bad-option o)))
2015                  ((eq keyword :documentation)
2016                   (push o options)
2017                   (when (or (cddr o) (not (stringp (%cadr o))))
2018                     (bad-option o)))
2019                  (t (bad-option o)))))))
2020    (when method-class
2021      (dolist (m methods)
2022        (push `(:method-class ,method-class) (cddr m))))
2023    (when declarations
2024      (setq options `((:declarations ,declarations) ,@options)))
2025    (values method-combination generic-function-class options methods)))
2026
2027                 
2028(defmacro def-aux-init-functions (class &rest functions)
2029  `(set-aux-init-functions ',class (list ,@functions)))
2030
2031
2032
2033
2034
2035
2036;;; A powerful way of defining REPORT-CONDITION...
2037;;; Do they really expect that each condition type has a unique method on PRINT-OBJECT
2038;;; which tests *print-escape* ?  Scary if so ...
2039
2040(defmacro define-condition (name (&rest supers) &optional ((&rest slots)) &body options)
2041  "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
2042   Define NAME as a condition type. This new type inherits slots and its
2043   report function from the specified PARENT-TYPEs. A slot spec is a list of:
2044     (slot-name :reader <rname> :initarg <iname> {Option Value}*
2045
2046   The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
2047   and :TYPE and the overall options :DEFAULT-INITARGS and
2048   [type] :DOCUMENTATION are also allowed.
2049
2050   The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
2051   a string or a two-argument lambda or function name. If a function, the
2052   function is called with the condition and stream to report the condition.
2053   If a string, the string is printed.
2054
2055   Condition types are classes, but (as allowed by ANSI and not as described in
2056   CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
2057   SLOT-VALUE may not be used on condition objects."
2058  ; If we could tell what environment we're being expanded in, we'd
2059  ; probably want to check to ensure that all supers name conditions
2060  ; in that environment.
2061  (let ((classopts nil)
2062        (duplicate nil)
2063        (docp nil)
2064        (default-initargs-p nil)
2065        (reporter nil))
2066    (dolist (option options)
2067      (unless (and (consp option)
2068                   (consp (%cdr option)))
2069        (error "Invalid option ~s ." option))
2070      (ecase (%car option)
2071        (:default-initargs 
2072            (unless (plistp (cdr option)) 
2073              (signal-program-error "~S is not a plist." (%cdr option))) 
2074            (if default-initargs-p 
2075              (setq duplicate t) 
2076              (push (setq default-initargs-p option) classopts))) 
2077        (:documentation 
2078         (unless (null (%cddr option)) 
2079           (error "Invalid option ~s ." option)) 
2080         (if docp
2081           (setq duplicate t)
2082           (push (setq docp option) classopts)))
2083        (:report 
2084         (unless (null (%cddr option)) 
2085           (error "Invalid option ~s ." option)) 
2086         (if reporter
2087           (setq duplicate t)
2088           (progn
2089             (if (or (lambda-expression-p (setq reporter (%cadr option)))
2090                     (symbolp reporter))
2091               (setq reporter `(function ,reporter))
2092               (if (stringp reporter)
2093                 (setq reporter `(function (lambda (c s) (declare (ignore c)) (write-string ,reporter s))))
2094                 (error "~a expression is not a string, symbol, or lambda expression ." (%car option))))
2095             (setq reporter `((defmethod report-condition ((c ,name) s)
2096                                (funcall ,reporter c s))))))))
2097      (if duplicate (error "Duplicate option ~s ." option)))
2098    `(progn
2099       (defclass ,name ,(or supers '(condition)) ,slots ,@classopts)
2100       ,@reporter
2101       ',name)))
2102
2103(defmacro with-condition-restarts (&environment env condition restarts &body body)
2104  "Evaluates the BODY in a dynamic environment where the restarts in the list
2105   RESTARTS-FORM are associated with the condition returned by CONDITION-FORM.
2106   This allows FIND-RESTART, etc., to recognize restarts that are not related
2107   to the error currently being debugged. See also RESTART-CASE."
2108  (multiple-value-bind (body decls)
2109                       (parse-body body env)
2110    (let ((cond (gensym))
2111          (r (gensym)))
2112          `(let* ((*condition-restarts* *condition-restarts*))
2113             ,@decls
2114             (let ((,cond ,condition))
2115               (dolist (,r ,restarts) (push (cons ,r ,cond) *condition-restarts*))
2116               ,@body)))))
2117 
2118(defmacro setf-find-class (name arg1 &optional (arg2 () 2-p) (arg3 () 3-p))
2119  (cond (3-p ;might want to pass env (arg2) to find-class someday?
2120         `(set-find-class ,name (progn ,arg1 ,arg2 ,arg3)))
2121        (2-p
2122         `(set-find-class ,name (progn ,arg1 ,arg2)))
2123        (t `(set-find-class ,name ,arg1))))
2124
2125(defsetf find-class setf-find-class)
2126
2127(defmacro restoring-interrupt-level (var &body body)
2128  `(unwind-protect
2129    (progn ,@body)
2130    (restore-interrupt-level ,var)
2131    (%interrupt-poll)))
2132
2133(defmacro without-interrupts (&body body)
2134  "Evaluate its body in an environment in which process-interrupt
2135requests are deferred."
2136  `(let* ((*interrupt-level* -1))
2137    ,@body))
2138
2139(defmacro with-interrupts-enabled (&body body)
2140  "Evaluate its body in an environment in which process-interrupt
2141has immediate effect."
2142  `(let* ((*interrupt-level* 0))
2143    ,@body))
2144
2145;;; undoes the effect of one enclosing without-interrupts during execution of body.
2146(defmacro ignoring-without-interrupts (&body body)
2147  `(let* ((*interrupt-level* 0))
2148    ,@body))
2149
2150
2151
2152(defmacro error-ignoring-without-interrupts (format-string &rest format-args)
2153  `(ignoring-without-interrupts
2154    (error ,format-string ,@format-args)))
2155
2156
2157;init-list-default: if there is no init pair for <keyword>,
2158;    add a <keyword> <value> pair to init-list
2159(defmacro init-list-default (the-init-list &rest args)
2160  (let ((result)
2161       (init-list-sym (gensym)))
2162   (do ((args args (cddr args)))
2163       ((not args))
2164     (setq result 
2165           (cons `(if (eq '%novalue (getf ,init-list-sym ,(car args) 
2166                                          '%novalue))
2167                    (setq ,init-list-sym (cons ,(car args) 
2168                                               (cons ,(cadr args) 
2169                                                     ,init-list-sym))))
2170                 result)))                                                                               
2171   `(let ((,init-list-sym ,the-init-list))
2172      (progn ,@result)
2173      ,init-list-sym)
2174   ))
2175
2176; This can only be partially backward-compatible: even if only
2177; the "name" arg is supplied, the old function would create the
2178; package if it didn't exist.
2179; Should see how well this works & maybe flush the whole idea.
2180
2181(defmacro in-package (name)
2182  (let ((form nil))
2183    (when (quoted-form-p name)
2184      (warn "Unquoting argument ~S to ~S." name 'in-package )
2185      (setq name (cadr name)))   
2186    (setq form `(set-package ,(string name)))
2187    `(eval-when (:execute :load-toplevel :compile-toplevel)
2188      ,form)))
2189
2190(defmacro defpackage (name &rest options)
2191  "Defines a new package called PACKAGE. Each of OPTIONS should be one of the
2192   following:
2193    (NICKNAMES {package-name}*)
2194
2195    (SIZE <integer>)
2196    (SHADOW {symbol-name}*)
2197    (SHADOWING-IMPORT-FROM <package-name> {symbol-name}*)
2198    (USE {package-name}*)
2199    (IMPORT-FROM <package-name> {symbol-name}*)
2200    (INTERN {symbol-name}*)
2201    (EXPORT {symbol-name}*)
2202    (IMPLEMENT {package-name}*)
2203    (LOCK boolean)
2204    (DOCUMENTATION doc-string)
2205   All options except SIZE, LOCK, and :DOCUMENTATION can be used multiple
2206   times."
2207  (let* ((size nil)
2208         (all-names-size 0)
2209         (intern-export-size 0)
2210         (shadow-etc-size 0)
2211         (documentation nil)
2212         (all-names-hash (let ((all-options-alist nil))
2213                           (dolist (option options)
2214                             (let ((option-name (car option)))
2215                               (when (memq option-name
2216                                           '(:nicknames :shadow :shadowing-import-from
2217                                             :use :import-from :intern :export))
2218                                 (let ((option-size (length (cdr option)))
2219                                       (cell (assq option-name all-options-alist)))
2220                                   (declare (fixnum option-size))
2221                                   (if cell
2222                                     (incf (cdr cell) option-size)
2223                                     (push (cons option-name option-size) all-options-alist))
2224                                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2225                                     (incf shadow-etc-size option-size))
2226                                   (when (memq option-name '(:export :intern))
2227                                     (incf intern-export-size option-size))))))
2228                           (dolist (cell all-options-alist)
2229                             (let ((option-size (cdr cell)))
2230                               (when (> option-size all-names-size)
2231                                 (setq all-names-size option-size))))
2232                           (when (> all-names-size 0)
2233                             (make-hash-table :test 'equal :size all-names-size))))
2234         (intern-export-hash (when (> intern-export-size 0)
2235                               (make-hash-table :test 'equal :size intern-export-size)))
2236         (shadow-etc-hash (when (> shadow-etc-size 0)
2237                            (make-hash-table :test 'equal :size shadow-etc-size)))
2238         (external-size nil)
2239         (nicknames nil)
2240         (shadow nil)
2241         (shadowing-import-from-specs nil)
2242         (use :default)
2243         (import-from-specs nil)
2244         (intern nil)
2245         (export nil))
2246    (declare (fixnum all-names-size intern-export-size shadow-etc-size))
2247    (labels ((string-or-name (s) (string s))
2248             (duplicate-option (o)
2249               (signal-program-error "Duplicate ~S option in ~S ." o options))
2250             (duplicate-name (name option-name)
2251               (signal-program-error "Name ~s, used in ~s option, is already used in a conflicting option ." name option-name))
2252             (all-names (option-name tail already)
2253               (when (eq already :default) (setq already nil))
2254               (when all-names-hash
2255                 (clrhash all-names-hash))
2256               (dolist (name already)
2257                 (setf (gethash (string-or-name name) all-names-hash) t))
2258               (dolist (name tail already)
2259                 (setq name (string-or-name name))
2260                 (unless (gethash name all-names-hash)          ; Ok to repeat name in same option.
2261                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2262                     (if (gethash name shadow-etc-hash)
2263                       (duplicate-name name option-name))
2264                     (setf (gethash name shadow-etc-hash) t))
2265                   (when (memq option-name '(:export :intern))
2266                     (if (gethash name intern-export-hash)
2267                       (duplicate-name name option-name))
2268                     (setf (gethash name intern-export-hash) t))
2269                   (setf (gethash name all-names-hash) t)
2270                   (push name already)))))
2271      (dolist (option options)
2272        (let ((args (cdr option)))
2273          (ecase (%car option)
2274                 (:size 
2275                  (if size 
2276                    (duplicate-option :size) 
2277                    (setq size (car args))))             
2278                 (:external-size 
2279                  (if external-size 
2280                    (duplicate-option :external-size) 
2281                    (setq external-size (car args))))
2282                 (:nicknames (setq nicknames (all-names nil args nicknames)))
2283                 (:shadow (setq shadow (all-names :shadow args shadow)))
2284                 (:shadowing-import-from
2285                  (destructuring-bind (from &rest shadowing-imports) args
2286                    (push (cons (string-or-name from)
2287                                (all-names :shadowing-import-from shadowing-imports nil))
2288                          shadowing-import-from-specs)))
2289                 (:use (setq use (all-names nil args use)))
2290                 (:import-from
2291                  (destructuring-bind (from &rest imports) args
2292                    (push (cons (string-or-name from)
2293                                (all-names :import-from imports nil))
2294                          import-from-specs)))
2295                 (:intern (setq intern (all-names :intern args intern)))
2296                 (:export (setq export (all-names :export args export)))
2297                 (:documentation
2298                  (if documentation
2299                    (duplicate-option :documentation)
2300                    (setq documentation (cadr option)))))))
2301      `(eval-when (:execute :compile-toplevel :load-toplevel)
2302         (%define-package ',(string-or-name name)
2303          ',size 
2304          ',external-size 
2305          ',nicknames
2306          ',shadow
2307          ',shadowing-import-from-specs
2308          ',use
2309          ',import-from-specs
2310          ',intern
2311          ',export
2312          ',documentation)))))
2313
2314
2315
2316(defmacro with-package-iterator ((mname package-list first-type &rest other-types)
2317                                 &body body)
2318  "Within the lexical scope of the body forms, MNAME is defined via macrolet
2319   such that successive invocations of (MNAME) will return the symbols,
2320   one by one, from the packages in PACKAGE-LIST. SYMBOL-TYPES may be
2321   any of :INHERITED :EXTERNAL :INTERNAL."
2322  (setq mname (require-type mname 'symbol))
2323  (let ((state (make-symbol "WITH-PACKAGE-ITERATOR_STATE")))
2324    (declare (fixnum types))
2325    (dolist (type (push first-type other-types))
2326      (ecase type
2327        ((:external :internal :inherited))))
2328    `(let ((,state (%setup-pkg-iter-state ,package-list ',other-types)))
2329       (macrolet ((,mname () `(%pkg-iter-next ,',state)))
2330         ,@body))))
2331
2332; Does NOT evaluate the constructor, but DOES evaluate the destructor & initializer
2333(defmacro defresource (name &key constructor destructor initializer)
2334  `(defparameter ,name (make-resource #'(lambda () ,constructor)
2335                                      ,@(when destructor
2336                                          `(:destructor ,destructor))
2337                                      ,@(when initializer
2338                                          `(:initializer ,initializer)))))
2339
2340(defmacro using-resource ((var resource) &body body)
2341  (let ((resource-var (gensym)))
2342  `(let ((,resource-var ,resource)
2343         ,var)
2344     (unwind-protect
2345       (progn
2346         (setq ,var (allocate-resource ,resource-var))
2347         ,@body)
2348       (when ,var
2349         (free-resource ,resource-var ,var))))))
2350
2351;;; Bind per-thread specials which help with lock accounting.
2352(defmacro with-lock-context (&body body)
2353  #+lock-accounting
2354  `(let* ((*locks-held* *locks-held*)
2355          (*locks-pending* *locks-pending*)
2356          (*lock-conses* *lock-conses*))
2357    ,@body)
2358  #-lock-accounting
2359  `(progn ,@body))
2360
2361(defmacro with-lock-grabbed ((lock &optional
2362                                   (whostate "Lock"))
2363                             &body body)
2364  "Wait until a given lock can be obtained, then evaluate its body with
2365the lock held."
2366  (declare (ignore whostate))
2367    (let* ((locked (gensym))
2368           (l (gensym)))
2369      `  (with-lock-context
2370           (let ((,locked (make-lock-acquisition))
2371             (,l ,lock))
2372        (declare (dynamic-extent ,locked))
2373        (unwind-protect
2374             (progn
2375               (%lock-recursive-lock-object ,l ,locked )
2376               ,@body)
2377          (when (lock-acquisition.status ,locked) (%unlock-recursive-lock-object ,l)))))))
2378
2379(defmacro with-lock-grabbed-maybe ((lock &optional
2380                                         (whostate "Lock"))
2381                                   &body body)
2382  (declare (ignore whostate))
2383  (let* ((l (gensym)))
2384    `(with-lock-context
2385      (let* ((,l ,lock))
2386        (when (%try-recursive-lock-object ,l)
2387          (unwind-protect
2388               (progn ,@body)
2389            (%unlock-recursive-lock-object ,l)))))))
2390
2391(defmacro with-standard-abort-handling (abort-message &body body)
2392  (let ((stream (gensym)))
2393    `(restart-case
2394       (catch :abort
2395         (catch-cancel
2396           ,@body))
2397       (abort () ,@(when abort-message
2398                     `(:report (lambda (,stream)
2399                                 (write-string ,abort-message ,stream)))))
2400       (abort-break ()))))
2401       
2402
2403
2404
2405(defmacro %lexpr-count (l)
2406  `(%lisp-word-ref ,l 0))
2407
2408(defmacro %lexpr-ref (lexpr count i)
2409  `(%lisp-word-ref ,lexpr (%i- ,count ,i)))
2410
2411;;; args will be list if old style clos
2412(defmacro apply-with-method-context (magic function args)
2413  (let ((m (gensym))
2414        (f (gensym))
2415        (as (gensym)))
2416      `((lambda (,m ,f ,as)
2417          (if (listp ,as)
2418            (%apply-with-method-context ,m ,f ,as)
2419            (%apply-lexpr-with-method-context ,m ,f ,as))) ,magic ,function ,args)))
2420
2421(defmacro defcallback (name arglist &body body &environment env)
2422  "Proclaim name to be a special variable; sets its value to a MACPTR which,
2423when called by foreign code, calls a lisp function which expects foreign
2424arguments of the specified types and which returns a foreign value of the
2425specified result type. Any argument variables which correspond to foreign
2426arguments of type :ADDRESS are bound to stack-allocated MACPTRs.
2427
2428If name is already a callback function pointer, its value is not changed;
2429instead, it's arranged that an updated version of the lisp callback function
2430will be called. This feature allows for callback functions to be redefined
2431incrementally, just like Lisp functions are.
2432
2433defcallback returns the callback pointer, e.g., the value of name."
2434  (define-callback name arglist body env))
2435
2436(declare-arch-specific-macro %get-single-float-from-double-ptr)
2437
2438(declare-arch-specific-macro lfun-vector)
2439(declare-arch-specific-macro lfun-vector-lfun)
2440
2441(declare-arch-specific-macro symptr->symvector)
2442(declare-arch-specific-macro symvector->symptr)
2443
2444(declare-arch-specific-macro function-to-function-vector)
2445(declare-arch-specific-macro function-vector-to-function)
2446
2447(declare-arch-specific-macro with-ffcall-results)
2448
2449(defvar *trace-print-functions* nil)
2450(defun %trace-print-arg (stream arg val type)
2451  (format stream " ")
2452  (let ((fn (assoc type *trace-print-functions*)))
2453    (if fn
2454      (funcall (cdr fn) stream arg val)
2455      (progn
2456      (when arg
2457        (format stream "~A = " arg))
2458      (if (and type (not (eq type :void)))
2459          (format stream "[:~A] ~A~%" type val)
2460        (format stream ":VOID~%" val))))))
2461
2462(defun def-trace-print-function (type fn)
2463  (push (cons type fn) *trace-print-functions*))
2464
2465(defun define-callback (name args body env)
2466  (let* ((stack-word (gensym))
2467         (stack-ptr (gensym))
2468         (fp-args-ptr (gensym))
2469         (result-type-spec :void)
2470         (args args)
2471         (woi nil)
2472         (monitor nil)
2473         (need-struct-arg)
2474         (struct-return-arg-name)
2475         (error-return nil))
2476    (collect ((arg-names)
2477              (arg-specs))
2478      (let* ((spec (car (last args)))
2479             (rtype (ignore-errors (parse-foreign-type spec))))
2480        (setq need-struct-arg (typep rtype 'foreign-record-type))
2481        (if rtype
2482          (setq result-type-spec spec args (butlast args))))
2483      (loop
2484        (when (null args) (return))
2485        (if (eq (car args) :without-interrupts)
2486          (setq woi (cadr args) args (cddr args))
2487          (if (eq (car args) :monitor-exception-ports)
2488            (setq monitor (cadr args) args (cddr args))
2489           
2490            (if (eq (car args) :error-return)
2491              (setq error-return
2492                    (cadr args)                 
2493                    args (cddr args))
2494              (if need-struct-arg
2495                (setq struct-return-arg-name (pop args) need-struct-arg nil)
2496                (progn
2497                  (arg-specs (pop args))
2498                  (arg-names (pop args))))))))
2499      (multiple-value-bind (rlets lets dynamic-extent-names inits foreign-return-type fp-args-form error-return-offset)
2500          (funcall (ftd-callback-bindings-function *target-ftd*)
2501                   stack-ptr fp-args-ptr (arg-names) (arg-specs) result-type-spec struct-return-arg-name)
2502        (multiple-value-bind (body decls doc) (parse-body body env t)
2503          `(progn
2504            (declaim (special ,name))
2505            (define-callback-function
2506                (nfunction ,name
2507                 (lambda (,stack-word)
2508                   (declare (ignorable ,stack-word))
2509                   (block ,name
2510                     (with-macptrs ((,stack-ptr))
2511                       (%setf-macptr-to-object ,stack-ptr ,stack-word)
2512                       (with-macptrs (,@(when fp-args-form
2513                                              `((,fp-args-ptr ,fp-args-form))))
2514                         ,(defcallback-body stack-ptr
2515                                            fp-args-ptr
2516                                            lets
2517                                            rlets
2518                                            inits
2519                                            `(declare (dynamic-extent ,@dynamic-extent-names))
2520                                            decls
2521                                            body
2522                                            foreign-return-type
2523                                            struct-return-arg-name
2524                                            error-return
2525                                            error-return-offset
2526                                            ))))))
2527                ,doc
2528              ,woi
2529              ,monitor)))))))
2530
2531
2532(defun defcallback-body (&rest args)
2533  (declare (dynamic-extent args))
2534  (destructuring-bind (stack-ptr fp-args-ptr lets rlets inits dynamic-extent-decls other-decls body return-type struct-return-arg error-return error-delta) args
2535    (declare (ignorable dynamic-extent-decls))
2536    (let* ((result (gensym))
2537           (condition-name (if (atom error-return) 'error (car error-return)))
2538           (error-return-function (if (atom error-return) error-return (cadr error-return)))
2539           (body
2540            `(rlet ,rlets
2541              (let ,lets
2542                ,dynamic-extent-decls
2543                ,@other-decls
2544                ,@inits
2545                (let ((,result (progn ,@body)))
2546                  (declare (ignorable ,result)
2547                           (dynamic-extent ,result))
2548
2549                  ,(funcall (ftd-callback-return-value-function *target-ftd*)
2550                            stack-ptr
2551                            fp-args-ptr
2552                            result
2553                            return-type
2554                            struct-return-arg)
2555                  nil)))))
2556      (if error-return
2557        (let* ((cond (gensym))
2558               (block (gensym))
2559               (handler (gensym)))
2560          `(block ,block
2561            (let* ((,handler (lambda (,cond)
2562                                           (,error-return-function ,cond ,stack-ptr (%inc-ptr ,stack-ptr ,error-delta))
2563                                           (return-from ,block
2564                                             nil))))
2565              (declare (dynamic-extent ,handler))
2566            (handler-bind ((,condition-name ,handler))
2567              (values ,body)))))
2568        body))))
2569
2570
2571(defmacro errchk (form)
2572  (let* ((res (gensym)))
2573    `(let* ((,res ,form))
2574       (if (eql 0 ,res)
2575         0
2576         (signal-posix-error ,res)))))
2577
2578(defmacro define-toplevel-command (group-name name arglist &body body &environment env)
2579  (let* ((key (make-keyword name)))
2580    (multiple-value-bind (body decls doc) (parse-body body env)
2581      `(%define-toplevel-command ',group-name ,key ',name 
2582        (nfunction ,name (lambda ,arglist
2583                           ,@decls
2584                           (block ,name
2585                             ,@body)))
2586        ,doc
2587        ',(mapcar #'symbol-name arglist)))))
2588
2589(defmacro with-toplevel-commands (group-name &body body)
2590  `(let* ((*active-toplevel-commands* *active-toplevel-commands*))
2591    (progn
2592      (%use-toplevel-commands ',group-name)
2593      ,@body)))
2594
2595(defmacro assert (test-form &optional (places ()) string &rest args)
2596  "ASSERT Test-Form [(Place*) [String Arg*]]
2597  If the Test-Form is not true, then signal a correctable error.  If Places
2598  are specified, then new values are prompted for when the error is proceeded.
2599  String and Args are the format string and args to the error call."
2600  (let* ((TOP (gensym))
2601         (setf-places-p (not (null places))))
2602    `(tagbody
2603       ,TOP
2604       (unless ,test-form
2605         (%assertion-failure ,setf-places-p ',test-form ,string ,@args)
2606         ,@(if places
2607             `((write-line "Type expressions to set places to, or nothing to leave them alone."
2608                           *query-io*)
2609               ,@(mapcar #'(lambda (place &aux (new-val (gensym))
2610                                          (set-p (gensym)))
2611                             `(multiple-value-bind
2612                                (,new-val ,set-p)
2613                                (assertion-value-prompt ',place)
2614                                (when ,set-p (setf ,place (values-list ,new-val)))))
2615                         places)))
2616         (go ,TOP)))))
2617
2618
2619(defmacro check-type (place typespec &optional string)
2620  "CHECK-TYPE Place Typespec [String]
2621  Signal a restartable error of type TYPE-ERROR if the value of PLACE is
2622  not of the specified type. If an error is signalled and the restart is
2623  used to return, this can only return if the STORE-VALUE restart is
2624  invoked. In that case it will store into PLACE and start over."
2625  `(progn
2626     (setf ,place 
2627           (ensure-value-of-type 
2628            ,place 
2629            ',typespec 
2630            ',place 
2631            ,string))
2632     nil))
2633
2634
2635
2636(defmacro with-hash-table-iterator ((mname hash-table) &body body &environment env)
2637  "WITH-HASH-TABLE-ITERATOR ((function hash-table) &body body)
2638   provides a method of manually looping over the elements of a hash-table.
2639   FUNCTION is bound to a generator-macro that, within the scope of the
2640   invocation, returns one or three values. The first value tells whether
2641   any objects remain in the hash table. When the first value is non-NIL,
2642   the second and third values are the key and the value of the next object."
2643  (let* ((hash (gensym))
2644         (keys (gensym))
2645         (values (gensym))
2646         (count (gensym))
2647         (state (gensym)))
2648    `(let* ((,hash ,hash-table)
2649            (,count (hash-table-count ,hash))
2650            (,keys (make-array ,count))
2651            (,values (make-array ,count))
2652            (,state (vector ,hash 0 ,keys ,values (enumerate-hash-keys-and-values ,hash ,keys ,values))))
2653      (declare (dynamic-extent ,keys ,state)
2654               (fixnum ,count))
2655      (macrolet ((,mname () `(next-hash-table-iteration-1 ,',state)))
2656        ,@body))))
2657
2658
2659(eval-when (compile load eval)
2660(defmacro pprint-logical-block ((stream-symbol list
2661                                 &key (prefix "" prefixp)
2662                                      (per-line-prefix "" per-line-prefix-p)
2663                                      (suffix "" suffixp))
2664                                &body body)
2665  (cond ((eq stream-symbol nil) (setq stream-symbol '*standard-output*))
2666        ((eq stream-symbol T) (setq stream-symbol '*terminal-io*)))
2667  (when (not (symbolp stream-symbol))
2668    (warn "STREAM-SYMBOL arg ~S to PPRINT-LOGICAL-BLOCK is not a bindable symbol"
2669          stream-symbol)
2670    (setq stream-symbol '*standard-output*))
2671  (when (and prefixp per-line-prefix-p)
2672    (warn "prefix ~S and per-line-prefix ~S cannot both be specified ~
2673           in PPRINT-LOGICAL-BLOCK")
2674    (setq per-line-prefix nil))
2675  `(let ((*logical-block-p* t))
2676     (maybe-initiate-xp-printing
2677      #'(lambda (,stream-symbol)
2678          (let ((+l ,list)
2679                (+p (or (and ,prefixp
2680                             (require-type ,prefix 'string))
2681                        (and ,per-line-prefix-p
2682                             (require-type ,per-line-prefix 'string))))
2683                (+s (require-type ,suffix 'string)))
2684            (pprint-logical-block+
2685                (,stream-symbol +l +p +s ,per-line-prefix-p T nil)
2686              ,@ body nil)))
2687      (decode-stream-arg ,stream-symbol))))
2688
2689
2690;Assumes var and args must be variables.  Other arguments must be literals or variables.
2691
2692(defmacro pprint-logical-block+ ((var args prefix suffix per-line? circle-check? atsign?)
2693                                 &body body)
2694  "Group some output into a logical block. STREAM-SYMBOL should be either a
2695   stream, T (for *TERMINAL-IO*), or NIL (for *STANDARD-OUTPUT*). The printer
2696   control variable *PRINT-LEVEL* is automatically handled."
2697  (when (and circle-check? atsign?)
2698    (setq circle-check? 'not-first-p))
2699  `(let ((*current-level* (1+ *current-level*))
2700         (*current-length* -1)
2701         ;(*parents* *parents*)
2702         ,@(if (and circle-check? atsign?) `((not-first-p (plusp *current-length*)))))
2703     (unless (check-block-abbreviation ,var ,args ,circle-check?)
2704       (start-block ,var ,prefix ,per-line? ,suffix)
2705       (when
2706         (catch 'line-limit-abbreviation-exit
2707           (block logical-block
2708             (macrolet ((pprint-pop () `(pprint-pop+ ,',args ,',var))
2709                        (pprint-exit-if-list-exhausted ()
2710                          `(if (null ,',args) (return-from logical-block nil))))
2711               ,@ body))
2712           (end-block ,var ,suffix)
2713           nil)
2714         (end-block ,var ,suffix)
2715         (throw 'line-limit-abbreviation-exit T)))))
2716) ; eval-when
2717
2718(defmacro %old-class-local-shared-slotds (class &optional default)
2719  (if default                           ; so setf works
2720    `(%class-get ,class '%old-class-local-shared-slotds ,default)
2721    `(%class-get ,class '%old-class-local-shared-slotds)))
2722
2723(defmacro with-slot-values (slot-entries instance-form &body body)
2724; Simplified form of with-slots.  Expands into a let instead of a symbol-macrolet
2725; Thus, you can access the slot values, but you can't setq them.
2726  (let ((instance (gensym)) var slot-name bindings)
2727    (dolist (slot-entry slot-entries)
2728      (cond ((symbolp slot-entry)
2729             (setq var slot-entry slot-name slot-entry))
2730            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2731                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2732             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2733            (t (error "Malformed slot-entry: ~a to with-slot-values.~@
2734                       Should be a symbol or a list of two symbols."
2735                      slot-entry)))
2736      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2737    `(let ((,instance ,instance-form))
2738       (let ,(nreverse bindings)
2739         ,@body))))
2740
2741(defmacro with-slots (slot-entries instance-form &body body)
2742  "Establish a lexical environment for referring to the slots in the
2743instance named by the given slot-names as though they were variables.
2744Within such a context the value of the slot can be specified by using
2745its slot name, as if it were a lexically bound variable. Both setf and
2746setq can be used to set the value of the slot."
2747  (let ((instance (gensym)) var slot-name bindings)
2748    (dolist (slot-entry slot-entries)
2749      (cond ((symbolp slot-entry)
2750             (setq var slot-entry slot-name slot-entry))
2751            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2752                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2753             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2754            (t (error "Malformed slot-entry: ~a to with-slots.~@
2755                       Should be a symbol or a list of two symbols."
2756                      slot-entry)))
2757      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2758    `(let ((,instance ,instance-form))
2759       ,@(if bindings 
2760             (list `(declare (ignorable ,instance)))
2761             (list `(declare (ignore ,instance))))
2762       (symbol-macrolet ,(nreverse bindings)
2763         ,@body))))
2764
2765(defmacro with-accessors (slot-entries instance-form &body body)
2766  "Create a lexical environment in which the slots specified by slot-entry
2767are lexically available through their accessors as if they were variables.
2768The appropriate accessors are invoked to access the slots specified by
2769slot-entry. Both setf and setq can be used to set the value of the slot."
2770  (let ((instance (gensym)) var reader bindings)
2771    (dolist (slot-entry slot-entries)
2772      (cond ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2773                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2774             (setq var (car slot-entry) reader (cadr slot-entry)))
2775            (t (error "Malformed slot-entry: ~a to with-accessors.~@
2776                       Should be a list of two symbols."
2777                      slot-entry)))
2778      (push `(,var (,reader ,instance)) bindings))
2779    `(let ((,instance ,instance-form))
2780       ,@(if bindings 
2781             (list `(declare (ignorable ,instance)))
2782             (list `(declare (ignore ,instance))))
2783       (symbol-macrolet ,(nreverse bindings)
2784         ,@body))))
2785
2786; I wanted to call this ":method"
2787(defmacro reference-method (gf &rest qualifiers-and-specializers)
2788  (let ((qualifiers (butlast qualifiers-and-specializers))
2789        (specializers (car (last qualifiers-and-specializers))))
2790    (if (null specializers) (report-bad-arg qualifiers-and-specializers '(not null)))
2791    `(find-method #',gf ',qualifiers (mapcar #'find-specializer ',specializers))))
2792
2793(defmacro time (form)
2794  "Execute FORM and print timing information on *TRACE-OUTPUT*."
2795  `(report-time ',form #'(lambda () (progn ,form))))
2796
2797(defmacro with-error-reentry-detection (&body body)
2798  (let ((thunk (gensym)))
2799    `(let ((,thunk #'(lambda () ,@body)))
2800       (declare (dynamic-extent ,thunk))
2801       (funcall-with-error-reentry-detection ,thunk))))
2802
2803#+ppc-target
2804(defmacro scan-for-instr (mask opcode fn pc-index &optional (tries *trap-lookup-tries*))
2805  `(%scan-for-instr ,mask ,opcode ,fn ,pc-index ,tries))
2806
2807
2808(declare-arch-specific-macro codevec-header-p)
2809
2810#+ppc-target
2811(defmacro match-instr (instr mask bits-to-match)
2812  `(eql (logand ,instr ,mask) ,bits-to-match))
2813
2814(defmacro with-xp-stack-frames ((xp trap-function &optional stack-frame) &body body)
2815  (let ((thunk (gensym))
2816        (sf (or stack-frame (gensym))))
2817    `(let ((,thunk #'(lambda (&optional ,sf)
2818                       ,@(unless stack-frame `((declare (ignore ,sf))))
2819                       ,@body)))
2820       (declare (dynamic-extent ,thunk))
2821       (funcall-with-xp-stack-frames ,xp ,trap-function ,thunk))))
2822
2823(defmacro signal-eof-error (stream)
2824  `(error 'end-of-file :stream ,stream))
2825
2826(defmacro check-eof (valform stream eof-error-p eof-value)
2827  (let* ((val (gensym)))
2828    `(let ((,val ,valform))
2829      (if (eq ,val :eof)
2830        (if ,eof-error-p
2831          (signal-eof-error ,stream)
2832          ,eof-value)
2833        ,val))))
2834
2835(defmacro designated-input-stream (input-stream)
2836  `(if ,input-stream
2837    (if (eq t ,input-stream)
2838      *terminal-io*
2839      ,input-stream)
2840    *standard-input*))
2841
2842(defmacro pref (pointer accessor)
2843  "Reference an instance of a foreign type (or a component of a foreign
2844type) accessible via ptr.
2845
2846Expand into code which references the indicated scalar type or component,
2847or returns a pointer to a composite type."
2848  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2849    (destructuring-bind (type-name &rest accessors) (decompose-record-accessor accessor)
2850      (%foreign-access-form pointer (%foreign-type-or-record type-name) 0 accessors))))
2851
2852(defmacro paref (pointer type-name index)
2853  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2854    (%foreign-array-access-form  pointer (%foreign-type-or-record type-name) index)))
2855
2856(defmacro rref (pointer accessor &key (storage :pointer storage-p))
2857  (when storage-p
2858    (warn "Use of :storage option ignored: ~a" storage))
2859  `(pref ,pointer ,accessor))
2860
2861(defmacro rlet (spec &body body)
2862  "Execute body in an environment in which each var is bound to a MACPTR
2863encapsulating the address of a stack-allocated foreign memory block,
2864allocated and initialized from typespec and initforms as per make-record.
2865Return whatever value(s) body returns."
2866  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2867    `(%stack-block ,(rlet-sizes spec)
2868      ,@(rlet-inits spec)
2869      ,@body)))
2870
2871(defmacro rletz (spec &body body)
2872  "Execute body in an environment in which each var is bound to a MACPTR
2873encapuslating the address of a stack-allocated foreign memory block,
2874allocated and initialized from typespec and initforms as per make-record.
2875Return whatever value(s) body returns.
2876
2877Unlike rlet, record fields that aren't explicitly initialized are set
2878to binary 0."
2879  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2880    `(%stack-block ,(rlet-sizes spec t)
2881      ,@(rlet-inits spec)
2882      ,@body)))
2883
2884(defun rlet-sizes (inits &optional clear-p &aux result)
2885  (dolist (item inits (nreverse result))
2886    (push `(,(car item)
2887            ,(%foreign-type-or-record-size (cadr item) :bytes)
2888            ,@(if clear-p '(:clear t)))
2889          result)))
2890
2891(defun rlet-inits (inits &aux result)
2892  (dolist (item inits result)
2893    (let* ((name (car item))
2894           (record-name (cadr item))
2895           (inits (cddr item))
2896           (ftype (%foreign-type-or-record record-name))
2897           (ordinal (foreign-type-ordinal ftype))
2898           (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
2899                           ordinal
2900                           `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name))))))
2901      (when (eq *host-backend* *target-backend*)
2902        (setq result (nconc result `((%set-macptr-type ,name ,ordinal-form)))))
2903      (if (typep ftype 'foreign-record-type)
2904        (setq result
2905              (nconc result (%foreign-record-field-forms name ftype record-name inits)))
2906        (progn
2907          (when inits
2908            (if (and ftype (null (cdr inits)))
2909              (setq result
2910                    (nconc result
2911                           `((setf ,(%foreign-access-form name ftype 0 nil)
2912                              ,(car inits)))))
2913              (error "Unexpected or malformed initialization forms: ~s in field type: ~s"
2914                     inits record-name))))))))
2915
2916(defun %foreign-record-field-forms (ptr record-type record-name inits)
2917  (unless (evenp (length inits))
2918    (error "Unexpected or malformed initialization forms: ~s in field type: ~s"
2919                     inits record-name))
2920  (let* ((result ()))
2921    (do* ()
2922         ((null inits)
2923          `((progn
2924              ;(%assert-macptr-ftype ,ptr ,record-type)
2925              ,@(nreverse result))))
2926      (let* ((accessor (decompose-record-accessor (pop inits)))
2927             (valform (pop inits)))
2928        (push `(setf ,(%foreign-access-form ptr record-type 0  accessor) ,valform)
2929              result)))))
2930 
2931(defmacro get-field-offset (accessor)
2932  (destructuring-bind (type-name field-name) (decompose-record-accessor accessor)
2933    (let* ((record-type (require-type (%foreign-type-or-record type-name) 'foreign-record-type))
2934           (field (%find-foreign-record-type-field record-type field-name))
2935           (bit-offset (foreign-record-field-offset field)))
2936      `(values ,(floor bit-offset 8) ,(foreign-record-field-type field) ,bit-offset))))
2937
2938(defmacro record-length (recname)
2939  (%foreign-type-or-record-size recname :bytes))
2940
2941(defun make-record-form (record-name allocator &rest initforms)
2942  (let* ((ftype (%foreign-type-or-record record-name))
2943         (ordinal (foreign-type-ordinal ftype))
2944         (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
2945                         ordinal
2946                         `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name)))))
2947         (bits (ensure-foreign-type-bits ftype))
2948         (bytes (if bits
2949                  (ceiling bits 8)
2950                  (error "Unknown size for foreign type ~S."
2951                         (unparse-foreign-type ftype))))
2952         (p (gensym))
2953         (bzero (read-from-string "#_bzero")))   
2954    `(let* ((,p (,allocator ,bytes)))
2955      ,@(when (eq *host-backend* *target-backend*)
2956              `((%set-macptr-type ,p ,ordinal-form)))
2957      (,bzero ,p ,bytes)
2958      ,@(%foreign-record-field-forms p ftype record-name initforms)
2959      ,p)))
2960 
2961(defmacro make-record (record-name &rest initforms)
2962  "Expand into code which allocates and initalizes an instance of the type
2963denoted by typespec, on the foreign heap. The record is allocated using the
2964C function malloc, and the user of make-record must explicitly call the C
2965function free to deallocate the record, when it is no longer needed."
2966  (apply 'make-record-form record-name 'malloc initforms))
2967
2968(defmacro make-gcable-record (record-name &rest initforms)
2969  "Like MAKE-RECORD, only advises the GC that the foreign memory can
2970   be deallocated if the returned pointer becomes garbage."
2971  (apply 'make-record-form record-name '%new-gcable-ptr initforms))
2972
2973(defmacro copy-record (type source dest)
2974  (let* ((size (* (%foreign-type-or-record-size type :words) #+64-bit-target 1 #+32-bit-target 2))
2975         (src (gensym "SRC"))
2976         (dst (gensym "DST"))
2977         (accessor #+64-bit-target '%get-unsigned-long #+32-bit-target '%get-unsigned-word)
2978         (i (gensym "I"))
2979         (j (gensym "J")))
2980    `(with-macptrs ((,src ,source)
2981                    (,dst ,dest))
2982      (do* ((,i 0 (+ ,i #+64-bit-target 4 #+32-bit-target 2))
2983            (,j 0 (+ ,j 1)))
2984           ((= ,j ,size))
2985        (declare (fixnum ,i))
2986        (setf (,accessor ,dst ,i) (,accessor ,src ,i))))))
2987
2988(defmacro assert-pointer-type (pointer type)
2989  "Assert that the pointer points to an instance of the specified foreign type.
2990Return the pointer."
2991  (let* ((ptr (gensym)))
2992    `(let* ((,ptr ,pointer))
2993      (%set-macptr-type ,ptr (foreign-type-ordinal (load-time-value (parse-foreign-type ',type))))
2994      ,ptr)))
2995
2996   
2997
2998(defmacro with-terminal-input (&body body)
2999  "Execute body in an environment with exclusive read access to the terminal."
3000  (let* ((got-it (gensym)))
3001    `(let* ((,got-it (%request-terminal-input)))
3002      (unwind-protect
3003           (progn ,@body)
3004        (%restore-terminal-input ,got-it)))))
3005
3006
3007(defmacro with-process-whostate ((whostate) &body body)
3008  `(let* ((*whostate* ,whostate))
3009    ,@body))
3010
3011
3012
3013
3014
3015(defmacro with-read-lock ((lock) &body body)
3016  "Wait until a given lock is available for read-only access, then evaluate
3017its body with the lock held."
3018  (let* ((p (gensym)))
3019    `(with-lock-context
3020      (let* ((,p ,lock))
3021        (unwind-protect
3022             (progn
3023               (read-lock-rwlock ,p)
3024               ,@body)
3025          (unlock-rwlock ,p))))))
3026
3027
3028(defmacro with-write-lock ((lock) &body body)
3029  "Wait until the given lock is available for write access, then execute
3030its body with the lock held."
3031  (let* ((p (gensym)))
3032    `(with-lock-context
3033      (let* ((,p ,lock))
3034      (unwind-protect
3035           (progn
3036             (write-lock-rwlock ,p)
3037             ,@body)
3038        (unlock-rwlock ,p))))))
3039
3040
3041
3042(defmacro without-gcing (&body body)
3043  `(unwind-protect
3044    (progn
3045      (%lock-gc-lock)
3046      ,@body)
3047    (%unlock-gc-lock)))
3048
3049(defmacro with-deferred-gc (&body body)
3050  "Execute BODY without responding to the signal used to suspend
3051threads for GC.  BODY must be very careful not to do anything which
3052could cause an exception (note that attempting to allocate lisp memory
3053may cause an exception.)"
3054  `(let* ((*interrupt-level* -2))
3055    ,@body))
3056
3057(defmacro allowing-deferred-gc (&body body)
3058  "Within the extent of a surrounding WITH-DEFERRED-GC, allow GC."
3059  `(let* ((*interrupt-level* -1))
3060    (%check-deferred-gc)
3061    ,@body))
3062
3063(defmacro defer-gc ()
3064  `(setq *interrupt-level* -2))
3065
3066
3067(defmacro with-pointer-to-ivector ((ptr ivector) &body body)
3068  "Executes BODY with PTR bound to a pointer to the first byte of data
3069in IVECTOR.  The GC is disabled during execution of BODY; PTR has
3070has dynamic-extent (and the address it references may become invalid
3071after the BODY exits.)  IVECTOR should be a (SIMPLE-ARRAY (*)) whose
3072element-type is numeric."
3073  (let* ((v (gensym)))
3074    `(let* ((,v ,ivector))
3075       (unless (typep ,v 'ivector) (report-bad-arg ,v 'ivector))
3076       (without-gcing
3077         (with-macptrs ((,ptr))
3078           (%vect-data-to-macptr ,v ,ptr)
3079           ,@body)))))
3080     
3081
3082
3083(defmacro with-other-threads-suspended (&body body)
3084  `(unwind-protect
3085    (progn
3086      (%suspend-other-threads)
3087      ,@body)
3088    (%resume-other-threads)))
3089
3090(defmacro with-package-read-lock ((p) &body body)
3091  `(with-read-lock ((pkg.lock ,p)) ,@body))
3092
3093(defmacro with-package-write-lock ((p) &body body)
3094  `(with-write-lock ((pkg.lock ,p)) ,@body))
3095
3096(defmacro with-package-lock ((p) &body body)
3097  `(with-package-write-lock (,p) ,@body))
3098
3099;;; Lock %all-packages-lock%, for shared read access to %all-packages%
3100
3101(defmacro with-package-list-read-lock (&body body)
3102  `(with-read-lock (%all-packages-lock%) ,@body))
3103
3104;;; Lock %all-packages-lock%, to allow modification to %all-packages%
3105(defmacro with-package-list-write-lock (&body body)
3106  `(with-write-lock (%all-packages-lock%) ,@body))
3107
3108(defmacro atomic-incf-decf (place delta &environment env)
3109  (setq place (macroexpand place env))
3110  (if (consp place)
3111    (let* ((sym (car place))
3112           (struct-transform (or (environment-structref-info sym env)
3113                                 (gethash sym %structure-refs%))))
3114      (if struct-transform
3115        (setq place (defstruct-ref-transform struct-transform (cdr place))
3116              sym (car place)))
3117      (ecase sym
3118        (the `(the ,(cadr place) (atomic-incf-decf ,(caddr place) ,delta)))
3119        (car `(%atomic-incf-car ,(cadr place) ,delta))
3120        (cdr `(%atomic-incf-cdr ,(cadr place) ,delta))
3121        ((svref %svref) `(%atomic-incf-gvector ,@(cdr place) ,delta))))
3122    (if (and (symbolp place) (eq :special (variable-information place env)))
3123      (let* ((base (gensym))
3124             (offset (gensym)))
3125        `(multiple-value-bind (,base ,offset)
3126          (%symbol-binding-address ',place)
3127          (%atomic-incf-node ,delta ,base ,offset)))
3128      (error "~S is not a special variable"  place))))
3129   
3130(defmacro atomic-incf (place)
3131  `(atomic-incf-decf ,place 1))
3132
3133(defmacro atomic-decf (place)
3134  `(atomic-incf-decf ,place -1))
3135
3136; Some of these macros were stolen from CMUCL.  Sort of ...
3137
3138(defmacro iterate (name binds &body body)
3139  "Iterate Name ({(Var Initial-Value)}*) Declaration* Form*
3140  This is syntactic sugar for Labels.  It creates a local function Name with
3141  the specified Vars as its arguments and the Declarations and Forms as its
3142  body.  This function is then called with the Initial-Values, and the result
3143  of the call is return from the macro."
3144  (dolist (x binds)
3145    (unless (and (listp x)
3146                 (= (length x) 2))
3147      (error "Malformed iterate variable spec: ~S." x)))
3148
3149  `(labels ((,name ,(mapcar #'first binds) ,@body))
3150     (,name ,@(mapcar #'second binds))))
3151
3152;;;; The Collect macro:
3153
3154;;; Collect-Normal-Expander  --  Internal
3155;;;
3156;;;    This function does the real work of macroexpansion for normal collection
3157;;; macros.  N-Value is the name of the variable which holds the current
3158;;; value.  Fun is the function which does collection.  Forms is the list of
3159;;; forms whose values we are supposed to collect.
3160;;;
3161(eval-when (:compile-toplevel :load-toplevel :execute)
3162
3163
3164(defun collect-normal-expander (n-value fun forms)
3165  `(progn
3166     ,@(mapcar #'(lambda (form) `(setq ,n-value (,fun ,form ,n-value))) forms)
3167     ,n-value))
3168
3169
3170)
3171
3172(defmacro once-only (specs &body body)
3173  "Once-Only ({(Var Value-Expression)}*) Form*
3174  Create a Let* which evaluates each Value-Expression, binding a temporary
3175  variable to the result, and wrapping the Let* around the result of the
3176  evaluation of Body.  Within the body, each Var is bound to the corresponding
3177  temporary variable."
3178  (iterate frob
3179           ((specs specs)
3180            (body body))
3181    (if (null specs)
3182      `(progn ,@body)
3183      (let ((spec (first specs)))
3184        (when (/= (length spec) 2)
3185          (error "Malformed Once-Only binding spec: ~S." spec))
3186        (let ((name (first spec))
3187              (exp-temp (gensym)))
3188          `(let ((,exp-temp ,(second spec))
3189                 (,name (gensym)))
3190             `(let ((,,name ,,exp-temp))
3191                ,,(frob (rest specs) body))))))))
3192
3193(eval-when (:compile-toplevel :load-toplevel :execute)
3194(defun form-symbol (first &rest others)
3195  (intern (apply #'concatenate 'simple-base-string (string first) (mapcar #'string others))))
3196)
3197
3198
3199;;; Collect-List-Expander  --  Internal
3200;;;
3201;;;    This function deals with the list collection case.  N-Tail is the pointer
3202;;; to the current tail of the list, which is NIL if the list is empty.
3203;;;
3204(defun collect-list-expander (n-value n-tail forms)
3205  (let ((n-res (gensym)))
3206    `(progn
3207       ,@(mapcar #'(lambda (form)
3208                     `(let ((,n-res (cons ,form nil)))
3209                        (cond (,n-tail
3210                               (setf (cdr ,n-tail) ,n-res)
3211                               (setq ,n-tail ,n-res))
3212                              (t
3213                               (setq ,n-tail ,n-res  ,n-value ,n-res)))))
3214                 forms)
3215       ,n-value)))
3216
3217;;;
3218;;;    The ultimate collection macro...
3219;;;
3220
3221(defmacro collect (collections &body body)
3222  "Collect ({(Name [Initial-Value] [Function])}*) {Form}*
3223  Collect some values somehow.  Each of the collections specifies a bunch of
3224  things which collected during the evaluation of the body of the form.  The
3225  name of the collection is used to define a local macro, a la MACROLET.
3226  Within the body, this macro will evaluate each of its arguments and collect
3227  the result, returning the current value after the collection is done.  The
3228  body is evaluated as a PROGN; to get the final values when you are done, just
3229  call the collection macro with no arguments.
3230
3231  Initial-Value is the value that the collection starts out with, which
3232  defaults to NIL.  Function is the function which does the collection.  It is
3233  a function which will accept two arguments: the value to be collected and the
3234  current collection.  The result of the function is made the new value for the
3235  collection.  As a totally magical special-case, the Function may be Collect,
3236  which tells us to build a list in forward order; this is the default.  If an
3237  Initial-Value is supplied for Collect, the stuff will be rplacd'd onto the
3238  end.  Note that Function may be anything that can appear in the functional
3239  position, including macros and lambdas."
3240 
3241 
3242  (let ((macros ())
3243        (binds ()))
3244    (dolist (spec collections)
3245      (unless (<= 1 (length spec) 3)
3246        (error "Malformed collection specifier: ~S." spec))
3247      (let ((n-value (gensym))
3248            (name (first spec))
3249            (default (second spec))
3250            (kind (or (third spec) 'collect)))
3251       
3252        (push `(,n-value ,default) binds)
3253        (if (eq kind 'collect)
3254          (let ((n-tail (gensym)))
3255            (if default
3256              (push `(,n-tail (last ,n-value)) binds)
3257              (push n-tail binds))
3258            (push `(,name (&rest args)
3259                          (collect-list-expander ',n-value ',n-tail args))
3260                  macros))
3261          (push `(,name (&rest args)
3262                        (collect-normal-expander ',n-value ',kind args))
3263                macros))))
3264    `(macrolet ,macros (let* ,(nreverse binds) (declare (ignorable ,@binds)) ,@body))))
3265
3266
3267;;; DEFENUM -- Internal Interface.
3268;;;
3269(defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
3270                   &rest identifiers)
3271  (let ((results nil)
3272        (index 0)
3273        (start (eval start))
3274        (step (eval step)))
3275    (dolist (id identifiers)
3276      (multiple-value-bind
3277        (root docs)
3278        (if (consp id)
3279          (values (car id) (cdr id))
3280          (values id nil))
3281        (push `(defconstant ,(intern (concatenate 'simple-base-string
3282                                                  (string prefix)
3283                                                  (string root)
3284                                                  (string suffix)))
3285                 ,(+ start (* step index))
3286                 ,@docs)
3287              results))
3288      (incf index))
3289    `(eval-when (:compile-toplevel :load-toplevel :execute)
3290       ,@(nreverse results))))
3291
3292
3293;;; This does something like special binding, but the "bindings" established
3294;;; aren't thread-specific.
3295
3296(defmacro let-globally ((&rest vars) &body body &environment env)
3297  (multiple-value-bind (body decls) (parse-body body env)
3298    (let* ((initforms nil)
3299           (psetform nil)
3300           (specvars nil)
3301           (restoreform nil))
3302      (flet ((pair-name-value (p)
3303               (if (atom p)
3304                 (values (require-global-symbol p env) nil)
3305                 (if (and (consp (%cdr p)) (null (%cddr p)))
3306                   (values (require-global-symbol (%car p) env) (%cadr p))
3307                   (error "Invalid variable initialization form : ~s")))))
3308        (declare (inline pair-name-value))
3309        (dolist (v vars)
3310          (let* ((oldval (gensym))
3311                 (newval (gensym)))
3312            (multiple-value-bind (var valueform) (pair-name-value v)
3313              (push var specvars)
3314              (push var restoreform)
3315              (push oldval restoreform)
3316              (push `(,oldval (uvref (symptr->symvector ',var) #.target::symbol.vcell-cell)) initforms)
3317              (push `(,newval ,valueform) initforms)
3318              (push var psetform)
3319              (push newval psetform))))
3320        `(let ,(nreverse initforms)
3321           ,@decls
3322           (locally (declare (special ,@(nreverse specvars)))
3323             (unwind-protect
3324               (progn (psetq ,@(nreverse psetform)) ,@body)
3325               (psetq ,@(nreverse restoreform)))))))))
3326;;; From CLX.
3327
3328;;; The good news is that this uses an interlocked load/store sequence
3329;;; and is fairly efficient.
3330;;; The bad news is that it only handles a few types of "place" forms.
3331;;; The good news is that CLX only uses a few types of "place" forms.
3332
3333(defmacro conditional-store (place old-value new-value &environment env)
3334  (setq place (macroexpand place env))
3335  (if (atom place)
3336    ;; CLX uses special variables' value cells as place forms.
3337    (if (and (symbolp place)
3338             (eq :special (ccl::variable-information place env)))
3339      (let* ((base (gensym))
3340             (offset (gensym)))
3341        `(multiple-value-bind (,base ,offset)
3342          (ccl::%symbol-binding-address ',place)
3343          (ccl::%store-node-conditional ,offset ,base ,old-value ,new-value)))
3344      (error "~s is not a special variable ." place))
3345    (let* ((sym (car place))
3346           (struct-transform (or (ccl::environment-structref-info sym env)
3347                                 (gethash sym ccl::%structure-refs%))))
3348      (if struct-transform
3349        (setq place (ccl::defstruct-ref-transform struct-transform (cdr place))
3350              sym (car place)))
3351      (if (member  sym '(svref ccl::%svref ccl::struct-ref))
3352        (let* ((v (gensym)))
3353          `(let* ((,v ,(cadr place)))
3354            (ccl::store-gvector-conditional ,(caddr place)
3355             ,v ,old-value ,new-value)))
3356        (error "Don't know how to do conditional store to ~s" place)))))
3357
3358(defmacro step (form)
3359  "The form is evaluated with single stepping enabled. Function calls
3360outside the lexical scope of the form can be stepped into only if the
3361functions in question have been compiled with sufficient DEBUG policy
3362to be at least partially steppable."
3363  form)
3364
3365(defmacro target-arch-case (&rest clauses)
3366  `(case (backend-target-arch-name *target-backend*)
3367    ,@clauses))
3368
3369(defmacro target-os-case (&rest clauses)
3370  `(ecase (backend-target-os *target-backend*)
3371    ,@clauses))
3372
3373(defmacro target-word-size-case (&rest clauses)
3374  `(ecase (arch::target-nbits-in-word (backend-target-arch *target-backend*))
3375    ,@clauses))
3376
3377(defmacro %get-natural (&body body)
3378  "A free copy of the next OpenMCL release to anyone who remembers Flakey Foont"
3379  (target-word-size-case
3380   (32 `(%get-unsigned-long ,@body))
3381   (64 `(%%get-unsigned-longlong ,@body))))
3382
3383(defmacro %get-signed-natural (&body body)
3384  "And that's my final offer."
3385  (target-word-size-case
3386   (32 `(%get-signed-long ,@body))
3387   (64 `(%%get-signed-longlong ,@body))))
3388
3389(declare-arch-specific-macro %target-kernel-global)
3390
3391;;; This behaves like a function, but looks up the kernel global
3392;;; at compile time if possible. Probably should be done as a function
3393;;; and a compiler macro, but we can't define compiler macros yet,
3394;;; and I don't want to add it to "ccl:compiler;optimizers.lisp"
3395(declare-arch-specific-macro %get-kernel-global)
3396
3397(declare-arch-specific-macro %get-kernel-global-ptr)
3398
3399(declare-arch-specific-macro area-code)
3400
3401(declare-arch-specific-macro nth-immediate)
3402
3403(declare-arch-specific-macro set-nth-immediate)
3404
3405(defsetf nth-immediate set-nth-immediate)
3406
3407(defmacro do-consing-areas ((area) &body body)
3408  (let ((code (gensym)))
3409  `(do-gc-areas (,area)
3410     (let ((,code (%fixnum-ref ,area  (area-code))))
3411       (when (or (eql ,code area-readonly)
3412                 (eql ,code area-managed-static)
3413                 (eql ,code area-static)
3414                 (eql ,code area-dynamic))
3415         ,@body)))))
3416
3417(declare-arch-specific-macro area-succ)
3418
3419(defmacro with-ioblock-lock-grabbed ((lock)
3420                                       &body body)
3421  `(with-lock-grabbed (,lock)
3422    ,@body))
3423
3424(defmacro with-ioblock-lock-grabbed-maybe ((lock)
3425                                           &body body)
3426  `(with-lock-grabbed-maybe (,lock)
3427    ,@body))
3428
3429
3430(defmacro do-gc-areas ((area) &body body)
3431  (let ((initial-area (gensym)))
3432    `(let* ((,initial-area (%get-kernel-global 'all-areas))
3433            (,area ,initial-area))
3434       (declare (fixnum ,initial-area ,area))
3435       (loop
3436         (setq ,area (%fixnum-ref ,area (area-succ)))
3437         (when (eql ,area ,initial-area)
3438           (return))
3439         ,@body))))
3440
3441(defmacro with-ioblock-input-lock-grabbed ((ioblock) &body body)
3442  `(with-lock-grabbed ((ioblock-inbuf-lock ,ioblock))
3443    ,@body))
3444
3445(defmacro with-ioblock-output-lock-grabbed ((ioblock) &body body)
3446  `(with-lock-grabbed ((ioblock-outbuf-lock ,ioblock))
3447    ,@body))
3448 
3449
3450(defmacro with-stream-ioblock-input ((ioblock stream &key
3451                                             speedy)
3452                                  &body body)
3453  `(let ((,ioblock (stream-ioblock ,stream t)))
3454     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3455     (with-ioblock-input-locked (,ioblock) ,@body)))
3456
3457(defmacro with-stream-ioblock-output ((ioblock stream &key
3458                                             speedy)
3459                                  &body body)
3460  `(let ((,ioblock (stream-ioblock ,stream t)))
3461     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3462     (with-ioblock-output-locked (,ioblock) ,@body)))
3463
3464(defmacro with-stream-ioblock-output-maybe ((ioblock stream &key
3465                                                     speedy)
3466                                            &body body)
3467  `(let ((,ioblock (stream-ioblock ,stream t)))
3468    ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3469    (with-ioblock-output-locked-maybe (,ioblock) ,@body)))
3470
3471(defmacro with-ioblock-input-locked ((ioblock) &body body)
3472  (let* ((lock (gensym)))
3473    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3474                                  (ioblock-inbuf-lock ,ioblock))))
3475      (if ,lock
3476        (with-lock-grabbed (,lock)
3477          ,@body)
3478        (progn
3479          (check-ioblock-owner ,ioblock)
3480          ,@body)))))
3481
3482(defmacro with-ioblock-output-locked ((ioblock) &body body)
3483  (let* ((lock (gensym)))
3484    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3485                                  (ioblock-outbuf-lock ,ioblock))))
3486      (if ,lock
3487        (with-lock-grabbed (,lock)
3488          ,@body)
3489        (progn
3490          (check-ioblock-owner ,ioblock)
3491          ,@body)))))
3492
3493
3494
3495(defmacro with-ioblock-output-locked-maybe ((ioblock) &body body)
3496  (let* ((lock (gensym)))
3497    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3498                                  (ioblock-outbuf-lock ,ioblock))))
3499      (if ,lock
3500        (with-lock-grabbed-maybe (,lock)
3501          ,@body)
3502        (progn
3503          (check-ioblock-owner ,ioblock)
3504          ,@body)))))
3505
3506;;; Use this when it's possible that the fd might be in
3507;;; a non-blocking state.  Body must return a negative of
3508;;; the os error number on failure.
3509;;; The use of READ-FROM-STRING below is certainly ugly, but macros
3510;;; that expand into reader-macros don't generally trigger the reader-macro's
3511;;; side-effects.  (Besides, the reader-macro might return a different
3512;;; value when the macro function is expanded than it did when the macro
3513;;; function was defined; this can happen during cross-compilation.)
3514(defmacro with-eagain (fd direction &body body)
3515  (let* ((res (gensym))
3516         (eagain (symbol-value (read-from-string "#$EAGAIN"))))
3517   `(loop
3518      (let ((,res (progn ,@body)))
3519        (if (eql ,res (- ,eagain))
3520          (progn
3521            (setq ,res
3522                  (,(ecase direction
3523                           (:input 'process-input-would-block)
3524                           (:output 'process-output-would-block))
3525                    ,fd))
3526            (unless (eq ,res t) (return ,res)))
3527          (return ,res))))))
3528
3529(defmacro ignoring-eintr (&body body)
3530  (let* ((res (gensym))
3531         (eintr (symbol-value (read-from-string "#$EINTR"))))
3532    `(loop
3533      (let* ((,res ,@body))
3534        (unless (eql ,res (- ,eintr))
3535          (return ,res))))))
3536
3537(defmacro basic-stream-ioblock (s)
3538  `(or (basic-stream.state ,s)
3539    (stream-is-closed ,s)))
3540
3541(defsetf interrupt-level set-interrupt-level)
3542
3543(defmacro %swap-u16 (val)
3544  (let* ((arg (gensym)))
3545    `(let* ((,arg ,val))
3546      (declare (type (unsigned-byte 16) ,arg))
3547      (logand #xffff (the fixnum (logior (the fixnum (ash ,arg -8))
3548                                         (the fixnum (ash ,arg 8))))))))
3549
3550(defmacro %swap-u32 (val)
3551  (let* ((arg (gensym)))
3552    `(let ((,arg ,val))
3553      (declare (type (unsigned-byte 32) ,arg))
3554      (the (unsigned-byte 32) (logior (the (unsigned-byte 32)
3555                                        (ash (logand #xff ,arg) 24))
3556                                      (the (unsigned-byte 24)
3557                                        (logior
3558                                         (the (unsigned-byte 24) (ash (logand #xff00 ,arg) 8))
3559                                         (the (unsigned-byte 16)
3560                                           (logior
3561                                            (the (unsigned-byte 16) (ash (logand #xff0000 ,arg) -8))
3562                                            (the (unsigned-byte 8) (ash ,arg -24)))))))))))
3563   
3564
3565(defmacro multiple-value-bind (varlist values-form &body body &environment env)
3566  (multiple-value-bind (body decls)
3567                       (parse-body body env)
3568    (let ((ignore (make-symbol "IGNORE")))
3569      `(multiple-value-call #'(lambda (&optional ,@varlist &rest ,ignore)
3570                                (declare (ignore ,ignore))
3571                                ,@decls
3572                                ,@body)
3573                            ,values-form))))
3574
3575(defmacro multiple-value-setq (vars val)
3576  (if vars
3577    `(values (setf (values ,@(mapcar #'(lambda (s) (require-type s 'symbol)) vars))  ,val))
3578    `(prog1 ,val)))
3579
3580(defmacro nth-value (n form)
3581  "Evaluate FORM and return the Nth value (zero based). This involves no
3582  consing when N is a trivial constant integer."
3583  `(car (nthcdr ,n (multiple-value-list ,form))))
3584
3585
3586
3587(defmacro with-input-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3588  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3589stream-input-timeout set to TIMEOUT."
3590  (let* ((old-input-timeout (gensym))
3591         (stream (gensym)))
3592    `(let* ((,stream ,stream-form)
3593            (,stream-var ,stream)
3594            (,old-input-timeout (stream-input-timeout ,stream)))
3595      (unwind-protect
3596           (progn
3597             (setf (stream-input-timeout ,stream) ,timeout)
3598             ,@body)
3599        (setf (stream-input-timeout ,stream) ,old-input-timeout)))))
3600
3601(defmacro with-output-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3602  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3603stream-output-timeout set to TIMEOUT."
3604  (let* ((old-output-timeout (gensym))
3605         (stream (gensym)))
3606    `(let* ((,stream ,stream-form)
3607            (,stream-var ,stream)
3608            (,old-output-timeout (stream-output-timeout ,stream)))
3609      (unwind-protect
3610           (progn
3611             (setf (stream-output-timeout ,stream) ,timeout)
3612             ,@body)
3613        (setf (stream-output-timeout ,stream) ,old-output-timeout)))))
Note: See TracBrowser for help on using the repository browser.