source: trunk/source/lib/macros.lisp @ 12940

Last change on this file since 12940 was 12940, checked in by gz, 10 years ago

From working-0711 branch: more extensive compile-time checking involving methods/gfs: warn about incongruent lambda lists, duplicate gf defs, required keyword args (from defgeneric), and invalid keyword args in gf calls. Also fix to keep method source files in env function info so dup method warnings can cite the right file.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 152.9 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;;; Macros (and functions/constants used at macroexpand-time) ONLY.
18
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require "LEVEL-2")
23  (require "BACKQUOTE")
24  (require "DEFSTRUCT-MACROS"))
25
26;; Constants
27
28(defmacro defconstant (sym val &optional (doc () doc-p) &environment env)
29  "Define a global constant, saying that the value is constant and may be
30  compiled into code. If the variable already has a value, and this is not
31  EQL to the new value, the code is not portable (undefined behavior). The
32  third argument is an optional documentation string for the variable."
33  (setq sym (require-type sym 'symbol)
34        doc (if doc-p (require-type doc 'string)))
35  `(progn
36     (eval-when (:compile-toplevel)
37       (define-compile-time-constant ',sym ',val ,env))
38     (eval-when (:load-toplevel :execute)
39       (%defconstant ',sym ,val ,@(if doc-p (list doc))))))
40
41;; Lists
42
43(defmacro %car (x)
44  `(car (the list ,x)))
45
46(defmacro set-%car (x y)
47  `(setf (car (the cons ,x)) ,y))
48
49(defmacro %cdr (x)
50  `(cdr (the list ,x)))
51
52(defmacro set-%cdr (x y)
53  `(setf (cdr (the cons ,x)) ,y))
54
55(defmacro %caar (x)
56 `(%car (%car ,x)))
57
58(defmacro %cadr (x)
59 `(%car (%cdr ,x)))
60
61(defmacro %cdar (x)
62 `(%cdr (%car ,x)))
63
64(defmacro %cddr (x)
65 `(%cdr (%cdr ,x)))
66
67(defmacro %caaar (x)
68 `(%car (%car (%car ,x))))
69
70(defmacro %caadr (x)
71 `(%car (%car (%cdr ,x))))
72
73(defmacro %cadar (x)
74 `(%car (%cdr (%car ,x))))
75
76(defmacro %caddr (x)
77 `(%car (%cdr (%cdr ,x))))
78
79(defmacro %cdaar (x)
80 `(%cdr (%car (%car ,x))))
81
82(defmacro %cdadr (x)
83 `(%cdr (%car (%cdr ,x))))
84
85(defmacro %cddar (x)
86 `(%cdr (%cdr (%car ,x))))
87
88(defmacro %cdddr (x)
89 `(%cdr (%cdr (%cdr ,x))))
90
91(defmacro %rplaca (x y)
92  `(rplaca (the cons ,x) ,y))
93
94(defmacro %rplacd (x y)
95  `(rplacd (the cons ,x) ,y))
96
97; These are open-coded by the compiler to isolate platform
98; dependencies.
99
100(defmacro %unbound-marker-8 ()
101  `(%unbound-marker))
102
103(defmacro %slot-missing-marker ()
104  `(%illegal-marker))
105
106
107
108
109(defmacro %null-ptr () '(%int-to-ptr 0))
110
111;;;Assorted useful macro definitions
112
113(defmacro def-accessors (ref &rest names)
114  (define-accessors ref names))
115
116(defmacro def-accessor-macros (ref &rest names)
117  (define-accessors ref names t))
118
119(defun define-accessors (ref names &optional no-constants
120                             &aux (arg (gensym)) (index 0) progn types)
121  (when (listp ref)
122    (setq types ref
123          ref (pop names)))
124  (dolist (name names)
125    (when name
126      (unless (listp name) (setq name (list name)))
127      (dolist (sym name)
128        (when sym
129          (push `(defmacro ,sym (,arg) (list ',ref ,arg ,index)) progn)
130          (unless no-constants
131            (push `(defconstant ,sym ,index) progn)))))
132    (setq index (1+ index)))
133 `(progn
134    ,.(nreverse progn)
135    ,@(if types `((add-accessor-types ',types ',names)))
136    ,index))
137
138(defmacro specialv (var)
139  `(locally (declare (special ,var)) ,var))
140
141
142(defmacro prog1 (valform &rest otherforms)
143 (let ((val (gensym)))
144 `(let ((,val ,valform))
145   ,@otherforms
146   ,val)))
147
148(defmacro prog2 (first second &rest others)
149 `(progn ,first (prog1 ,second ,@others)))
150
151(defmacro prog (inits &body body &environment env)
152  (multiple-value-bind (forms decls) (parse-body body env nil)
153    `(block nil
154       (let ,inits
155         ,@decls
156         (tagbody ,@forms)))))
157
158(defmacro prog* (inits &body body &environment env)
159  (multiple-value-bind (forms decls) (parse-body body env nil)
160    `(block nil
161       (let* ,inits
162         ,@decls
163         (tagbody ,@forms)))))
164
165
166(defmacro %stack-block ((&rest specs) &body forms &aux vars lets)
167  (dolist (spec specs)
168    (destructuring-bind (var ptr &key clear) spec
169      (push var vars)
170      (push `(,var (%new-ptr ,ptr ,clear)) lets)))
171  `(let* ,(nreverse lets)
172     (declare (dynamic-extent ,@vars))
173     (declare (type macptr ,@vars))
174     (declare (unsettable ,@vars))
175     ,@forms))
176
177(defmacro %vstack-block (spec &body forms)
178  `(%stack-block (,spec) ,@forms))
179
180
181
182(eval-when (:compile-toplevel :load-toplevel :execute)
183(defun extract-type-decl-for-dolist-var (var decls env)
184  (if (null decls)
185    (values nil nil nil)
186    (let* ((declared-type-p nil))
187      (collect ((new-decls)
188                (declared-types))
189        (dolist (declform decls)
190          ;; (assert (eq (car declform) 'declare))
191          (dolist (decl (cdr declform))
192            (if (atom decl)
193              (new-decls decl)
194              (let* ((spec (car decl)))
195                (if (specifier-type-if-known spec env)
196                  (setq spec 'type
197                        decl `(type ,@decl)))
198                (if (eq spec 'type)
199                  (destructuring-bind (typespec &rest vars) (cdr decl)
200                    (cond ((member var vars :test #'eq)
201                           (setq declared-type-p t)
202                           (declared-types typespec)
203                           (new-decls `(type ,typespec ,@(remove var vars))))
204                          (t (new-decls decl))))
205                  (new-decls decl))))))
206        (if (not declared-type-p)
207          (values nil nil (new-decls))
208          (values t
209                  (let* ((declared-type (declared-types)))
210                    (if (cdr declared-type)
211                      `(and ,@declared-type)
212                      (car declared-type)))
213                  (new-decls)))))))
214)
215
216
217(defmacro dolist ((varsym list &optional ret) &body body &environment env)
218  (if (not (symbolp varsym)) (signal-program-error $XNotSym varsym))
219  (let* ((toplab (gensym))
220         (tstlab (gensym))
221         (lstsym (gensym)))
222    (multiple-value-bind (forms decls) (parse-body body env nil)
223      (multiple-value-bind (var-type-p vartype other-decls)
224          (extract-type-decl-for-dolist-var varsym decls env)
225        (if var-type-p
226          (setq forms `((locally (declare (type ,vartype ,varsym)) (tagbody ,@forms)))))
227        (if other-decls
228          (setq other-decls `((declare ,@other-decls))))
229        `(block nil
230          (let* ((,lstsym ,list) ,varsym)
231            ,@(if var-type-p `((declare (type (or null ,vartype) ,varsym))))
232            ,@other-decls
233            (tagbody
234               (go ,tstlab)
235               ,toplab
236               (setq ,lstsym (cdr (the list ,lstsym)))
237               ,@forms
238               ,tstlab
239               (setq ,varsym (car ,lstsym))
240               (if ,lstsym (go ,toplab)))
241            ,@(if ret `((progn  ,ret)))))))))
242
243
244(defmacro dovector ((varsym vector &optional ret) &body body &environment env)
245  (if (not (symbolp varsym))(signal-program-error $XNotSym varsym))
246  (let* ((toplab (gensym))
247         (tstlab (gensym))
248         (lengthsym (gensym))
249         (indexsym (gensym))
250         (vecsym (gensym)))
251    (multiple-value-bind (forms decls) (parse-body body env nil)
252     `(let* ((,vecsym ,vector)
253             (,lengthsym (length ,vecsym))
254             (,indexsym 0)
255             ,varsym)
256        ,@decls
257        ,@(let ((type (nx-form-type vector env)))
258            (unless (eq type t)
259              `((declare (type ,type ,vecsym)))))
260        (block nil
261          (tagbody
262            (go ,tstlab)
263            ,toplab
264            (setq ,varsym (locally (declare (optimize (speed 3) (safety 0)))
265                            (aref ,vecsym ,indexsym))
266                  ,indexsym (%i+ ,indexsym 1))
267            ,@forms
268            ,tstlab
269            (if (%i< ,indexsym ,lengthsym) (go ,toplab)))
270          ,@(if ret `((progn (setq ,varsym nil) ,ret))))))))
271
272(defmacro report-bad-arg (&rest args)
273  `(values (%badarg ,@args)))
274
275(defmacro %cons-restart (name action report interactive test)
276 `(%istruct 'restart ,name ,action ,report ,interactive ,test))
277
278(defmacro restart-bind (clauses &body body)
279  "Executes forms in a dynamic context where the given restart bindings are
280   in effect. Users probably want to use RESTART-CASE. When clauses contain
281   the same restart name, FIND-RESTART will find the first such clause."
282  (let* ((restarts (mapcar #'(lambda (clause) 
283                               (list (make-symbol (symbol-name (require-type (car clause) 'symbol)))
284                                     `(%cons-restart nil nil nil nil nil)))
285                           clauses))
286         (bindings (mapcar #'(lambda (clause name)
287                              `(make-restart ,(car name) ',(car clause)
288                                             ,@(cdr clause)))
289                           clauses restarts))
290        (cluster (gensym)))
291    `(let* (,@restarts)
292       (declare (dynamic-extent ,@(mapcar #'car restarts)))
293       (let* ((,cluster (list ,@bindings))
294              (%restarts% (cons ,cluster %restarts%)))
295         (declare (dynamic-extent ,cluster %restarts%))
296         (progn
297           ,@body)))))
298
299(defmacro handler-bind (clauses &body body)
300  "(HANDLER-BIND ( {(type handler)}* )  body)
301   Executes body in a dynamic context where the given handler bindings are
302   in effect. Each handler must take the condition being signalled as an
303   argument. The bindings are searched first to last in the event of a
304   signalled condition."
305  (let* ((fns)
306         (decls)         
307         (bindings (mapcan #'(lambda (clause)
308                               (destructuring-bind (condition handler) clause
309                                 (if (and (consp handler)(eq (car handler) 'function)
310                                          (consp (cadr handler))(eq (car (cadr handler)) 'lambda))
311                                   (let ((fn (gensym)))
312                                     (push `(,fn ,handler) fns)
313                                     (push `(declare (dynamic-extent ,fn)) decls)
314                                     `(',condition ,fn))
315                                   (list `',condition
316                                         `,handler))))
317                           clauses))
318        (cluster (gensym)))   
319    (if (null bindings)
320      `(progn ,@body)
321      `(let* (,@fns
322              (,cluster (list ,@bindings))
323              (%handlers% (cons ,cluster %handlers%)))
324         (declare (dynamic-extent ,cluster %handlers%))
325         ,@decls
326         ,@body))))
327
328(defmacro restart-case (&environment env form &rest clauses)
329  "(RESTART-CASE form
330   {(case-name arg-list {keyword value}* body)}*)
331   The form is evaluated in a dynamic context where the clauses have special
332   meanings as points to which control may be transferred (see INVOKE-RESTART).
333   When clauses contain the same case-name, FIND-RESTART will find the first
334   such clause. If Expression is a call to SIGNAL, ERROR, CERROR or WARN (or
335   macroexpands into such) then the signalled condition will be associated with
336   the new restarts."
337  (let ((cluster nil))
338    (when clauses (setq cluster (gensym) form (restart-case-form form env cluster)))
339    (flet ((restart-case-1 (name arglist &rest forms)
340             (let (interactive report test)
341               (loop
342                 (case (car forms)
343                   (:interactive (setq interactive (cadr forms)))
344                   (:report (setq report (cadr forms)))
345                   (:test (setq test (cadr forms)))
346                   (t (return nil)))
347                 (setq forms (cddr forms)))
348               (when (and report (not (stringp report)))
349                 (setq report `#',report))
350               (when interactive
351                 (setq interactive `#',interactive))
352               (when test
353                 (setq test `#',test))
354               (values (require-type name 'symbol) arglist report interactive test forms))))
355      (cond ((null clauses) form)
356            ((and (null (cdr clauses)) (null (cadr (car clauses))))
357             (let ((block (gensym)) 
358                   (restart-name (gensym)))
359               (multiple-value-bind (name arglist report interactive test body)
360                                    (apply #'restart-case-1 (car clauses))
361                 (declare (ignore arglist))
362                 `(block ,block
363                    (let* ((,restart-name (%cons-restart ',name () ,report ,interactive ,test))
364                           (,cluster (list ,restart-name)))
365                      (declare (dynamic-extent ,restart-name ,cluster))
366                      (catch ,cluster
367                        (let ((%restarts% (cons ,cluster %restarts%)))
368                          (declare (dynamic-extent %restarts%))
369                          (return-from ,block ,form))))
370                    ,@body))))
371            (t
372             (let ((block (gensym)) (val (gensym))
373                   (index -1) restarts restart-names restart-name cases)
374               (while clauses
375                 (setq index (1+ index))
376                 (multiple-value-bind (name arglist report interactive test body)
377                                      (apply #'restart-case-1 (pop clauses))
378                   (push (setq restart-name (make-symbol (symbol-name name))) restart-names)
379                   (push (list restart-name `(%cons-restart ',name ,index ,report ,interactive ,test))
380                         restarts)
381                   (when (null clauses) (setq index t))
382                   (push `(,index (apply #'(lambda ,arglist ,@body) ,val))
383                         cases)))
384               `(block ,block
385                  (let ((,val (let* (,@restarts
386                                     (,cluster (list ,@(reverse restart-names))))
387                                (declare (dynamic-extent ,@restart-names ,cluster))
388                                (catch ,cluster
389                                  (let ((%restarts% (cons ,cluster %restarts%)))
390                                    (declare (dynamic-extent %restarts%))
391                                    (return-from ,block ,form))))))
392                    (case (pop ,val)
393                      ,@(nreverse cases))))))))))
394
395
396; Anything this hairy should die a slow and painful death.
397; Unless, of course, I grossly misunderstand...
398(defun restart-case-form (form env clustername)
399  (let ((expansion (macroexpand form env))
400        (head nil))
401    (if (and (listp expansion)          ; already an ugly hack, made uglier by %error case ...
402             (memq (setq head (pop expansion)) '(signal error cerror warn %error)))
403      (let ((condform nil)
404            (signalform nil)
405            (cname (gensym)))
406        (case head
407          (cerror
408           (destructuring-bind 
409             (continue cond &rest args) expansion
410             (setq condform `(condition-arg ,cond (list ,@args) 'simple-error)
411                   signalform `(cerror ,continue ,cname))))
412          ((signal error warn)
413           (destructuring-bind
414             (cond &rest args) expansion
415             (setq condform `(condition-arg ,cond (list ,@args) ,(if (eq head 'warning)
416                                                                   ''simple-warning
417                                                                   (if (eq head 'error)
418                                                                     ''simple-error
419                                                                     ''simple-condition)))
420                   signalform `(,head ,cname))))
421          (t ;%error
422           (destructuring-bind (cond args fp) expansion
423             (setq condform `(condition-arg ,cond ,args 'simple-error)
424                   signalform `(%error ,cname nil ,fp)))))
425        `(let ((,cname ,condform))
426           (with-condition-restarts ,cname ,clustername
427             ,signalform)))
428      form)))
429     
430
431(defmacro handler-case (form &rest clauses)
432  "(HANDLER-CASE form
433   { (type ([var]) body) }* )
434   Execute FORM in a context with handlers established for the condition
435   types. A peculiar property allows type to be :NO-ERROR. If such a clause
436   occurs, and form returns normally, all its values are passed to this clause
437   as if by MULTIPLE-VALUE-CALL.  The :NO-ERROR clause accepts more than one
438   var specification."
439  (let* ((no-error-clause (assoc :no-error clauses)))
440    (if no-error-clause
441      (let* ((normal-return (gensym))
442             (error-return (gensym)))
443        `(block ,error-return
444          (multiple-value-call #'(lambda ,@(cdr no-error-clause))
445            (block ,normal-return
446              (return-from ,error-return
447                (handler-case (return-from ,normal-return ,form)
448                  ,@(remove no-error-clause clauses)))))))
449      (flet ((handler-case (type var &rest body)
450               (when (eq type :no-error)
451                 (signal-program-error "Duplicate :no-error clause. "))
452           (values type var body)))
453        (cond ((null clauses) form)
454          ((null (cdr clauses))
455           (let ((block   (gensym))
456                 (cluster (gensym)))
457             (multiple-value-bind (type var body)
458                                  (apply #'handler-case (car clauses))
459               (if var
460                 `(block ,block
461                    ((lambda ,var ,@body)
462                      (let* ((,cluster (list ',type)))
463                        (declare (dynamic-extent ,cluster))
464                        (catch ,cluster
465                          (let ((%handlers% (cons ,cluster %handlers%)))
466                            (declare (dynamic-extent %handlers%))
467                            (return-from ,block ,form))))))
468                 `(block ,block
469                    (let* ((,cluster (list ',type)))
470                      (declare (dynamic-extent ,cluster))
471                      (catch ,cluster
472                        (let ((%handlers% (cons ,cluster %handlers%)))
473                          (declare (dynamic-extent %handlers%))
474                          (return-from ,block ,form)))
475                      (locally ,@body)))))))
476          (t (let ((block (gensym)) (cluster (gensym)) (val (gensym))
477                   (index -1) handlers cases)
478               (while clauses
479                 (setq index (1+ index))
480                 (multiple-value-bind (type var body)
481                                      (apply #'handler-case (pop clauses))                   
482                   (push `',type handlers)
483                   (push index handlers)
484                   (when (null clauses) (setq index t))
485                   (push (if var
486                           `(,index ((lambda ,var ,@body) ,val))
487                           `(,index (locally ,@body))) cases)))
488               `(block ,block
489                  (let ((,val (let* ((,cluster (list ,@(nreverse handlers))))
490                                (declare (dynamic-extent ,cluster))
491                                (catch ,cluster
492                                  (let ((%handlers% (cons ,cluster %handlers%)))
493                                    (declare (dynamic-extent %handlers%))
494                                    (return-from ,block ,form))))))
495                    (case (pop ,val)
496                      ,@(nreverse cases)))))))))))
497
498(defmacro with-simple-restart ((restart-name format-string &rest format-args)
499                               &body body
500                               &aux (cluster (gensym)) (temp (make-symbol (symbol-name restart-name))))
501  "(WITH-SIMPLE-RESTART (restart-name format-string format-arguments)
502   body)
503   If restart-name is not invoked, then all values returned by forms are
504   returned. If control is transferred to this restart, it immediately
505   returns the values NIL and T."
506  (unless (and (stringp format-string)
507               (null format-args)
508               (not (%str-member #\~ (ensure-simple-string format-string))))
509    (let ((stream (gensym)))
510      (setq format-string `#'(lambda (,stream) (format ,stream ,format-string ,@format-args)))))
511  `(let* ((,temp (%cons-restart ',restart-name
512                                'simple-restart
513                                ,format-string
514                                nil
515                                nil))
516          (,cluster (list ,temp)))
517     (declare (dynamic-extent ,temp ,cluster))
518     (catch ,cluster
519       (let ((%restarts% (cons ,cluster %restarts%)))
520         (declare (dynamic-extent %restarts%))
521         ,@body))))
522
523;Like with-simple-restart but takes a pre-consed restart.  Not CL.
524(defmacro with-restart (restart &body body &aux (cluster (gensym)))
525  `(let* ((,cluster (list ,restart)))
526     (declare (dynamic-extent ,cluster))
527     (catch ,cluster
528       (let ((%restarts% (cons ,cluster %restarts%)))
529         (declare (dynamic-extent %restarts%))
530         ,@body))))
531
532(defmacro ignore-errors (&rest forms)
533  "Execute FORMS handling ERROR conditions, returning the result of the last
534  form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
535  `(handler-case (progn ,@forms)
536     (error (condition) (values nil condition))))
537
538(defmacro def-kernel-restart (&environment env errno name arglist &body body)
539  (multiple-value-bind (body decls)
540                       (parse-body body env)
541    `(let* ((fn (nfunction ,name (lambda ,arglist ,@decls (block ,name ,@body))))
542            (pair (assq ,errno ccl::*kernel-restarts*)))
543       (if pair
544         (rplacd pair fn)
545         (push (cons ,errno fn) ccl::*kernel-restarts*))
546       fn)))
547
548
549;;; Setf.
550
551;  If you change anything here, be sure to make the corresponding change
552;  in get-setf-method.
553(defmacro setf (&rest args &environment env)
554  "Takes pairs of arguments like SETQ. The first is a place and the second
555  is the value that is supposed to go into that place. Returns the last
556  value. The place argument may be any of the access forms for which SETF
557  knows a corresponding setting form."
558  (let ((temp (length args))
559        (accessor nil))
560    (cond ((eq temp 2)
561           (let* ((form (car args)) 
562                  (value (cadr args)))
563             ;This must match get-setf-method .
564             (cond ((atom form)
565                    (progn
566                      (unless (symbolp form)(signal-program-error $XNotSym form))
567                      `(setq ,form ,value)))
568                   ((eq (car form) 'the)
569                    (unless (eql (length form) 3)
570                      (error "Bad THE place form in (SETF ~S ~S)" form value))
571                    (destructuring-bind (type place) (cdr form)
572                      `(setf ,place (the ,type ,value))))
573                   (t
574                    (multiple-value-bind (ftype local-p)
575                        (function-information (setq accessor (car form)) ENV)
576                      (if local-p
577                        (if (eq ftype :function)
578                                        ;Local function, so don't use global setf definitions.
579                          (default-setf form value env)
580                          `(setf ,(macroexpand-1 form env) ,value))
581                        (cond
582                          ((setq temp (%setf-method accessor))
583                           (if (symbolp temp)
584                             `(,temp ,@(cdar args) ,value)
585                             (multiple-value-bind (dummies vals storevars setter #|getter|#)
586                                 (funcall temp form env)
587                               (do* ((d dummies (cdr d))
588                                     (v vals (cdr v))
589                                     (let-list nil))
590                                    ((null d)
591                                     (setq let-list (nreverse let-list))
592                                     `(let* ,let-list
593                                       (declare (ignorable ,@dummies))
594                                       (multiple-value-bind ,storevars ,value
595                                         #|,getter|#
596                                         ,setter)))
597                                 (push (list (car d) (car v)) let-list)))))
598                          ((and (type-and-refinfo-p (setq temp (or (environment-structref-info accessor env)
599                                                                   (and #-bccl (boundp '%structure-refs%)
600                                                                        (gethash accessor %structure-refs%)))))
601                                (not (refinfo-r/o (if (consp temp) (%cdr temp) temp))))
602                           (if (consp temp)
603                             ;; strip off type, but add in a require-type
604                             (let ((type (%car temp)))
605                               `(the ,type (setf ,(defstruct-ref-transform (%cdr temp) (%cdar args) env)
606                                            (require-type ,value ',type))))
607                             `(setf ,(defstruct-ref-transform temp (%cdar args) env)
608                               ,value)))
609                          (t
610                           (multiple-value-bind (res win)
611                               (macroexpand-1 form env)
612                             (if win
613                               `(setf ,res ,value)
614                               (default-setf form value env)))))))))))
615          ((oddp temp)
616           (signal-program-error "Odd number of args to SETF : ~s." args))
617          (t (do* ((a args (cddr a)) (l nil))
618                  ((null a) `(progn ,@(nreverse l)))
619               (push `(setf ,(car a) ,(cadr a)) l))))))
620
621
622(defun default-setf (setter value &optional env)
623  (let* ((reader (car setter))
624         (args (cdr setter))
625         (gensyms (mapcar #'(lambda (sym) (declare (ignore sym)) (gensym)) args))
626         types declares)
627    (flet ((form-type (form)
628             (nx-form-type form env)))
629      (declare (dynamic-extent #'form-type))
630      (setq types (mapcar #'form-type args)))
631    (dolist (sym gensyms)
632      (let ((sym-type (pop types)))
633        (unless (eq sym-type t)
634          (push `(type ,sym-type ,sym) declares))))
635    `(let ,(mapcar #'list gensyms args)
636       ,@(and declares (list `(declare ,@(nreverse declares))))
637       (funcall #'(setf ,reader) ,value ,@gensyms))))
638
639;; Establishing these setf-inverses is something that should
640;; happen at compile-time
641(defsetf elt set-elt)
642(defsetf car set-car)
643(defsetf %car set-%car)
644(defsetf first set-car)
645(defsetf cdr set-cdr)
646(defsetf %cdr set-%cdr)
647(defsetf rest set-cdr)
648(defsetf uvref uvset)
649(defsetf aref aset)
650(defsetf svref svset)
651(defsetf %svref %svset)
652(defsetf char set-char)
653(defsetf schar set-schar)
654(defsetf %scharcode %set-scharcode)
655(defsetf symbol-value set)
656(defsetf symbol-plist set-symbol-plist)
657(defsetf fill-pointer set-fill-pointer)
658
659; This sux; it calls the compiler twice (once to shove the macro in the
660; environment, once to dump it into the file.)
661(defmacro defmacro  (name arglist &body body &environment env)
662  (unless (symbolp name)(signal-program-error $XNotSym name))
663  (unless (listp arglist) (signal-program-error "~S is not a list." arglist))
664  (multiple-value-bind (lambda-form doc)
665                       (parse-macro-1 name arglist body env)
666    (let* ((normalized (normalize-lambda-list arglist t t))
667           (body-pos (position '&body normalized))
668           (argstring (let ((temp nil))
669                        (dolist (arg normalized)
670                          (if (eq arg '&aux)
671                            (return)
672                            (push arg temp)))
673                        (format nil "~:a" (nreverse temp)))))
674      (if (and body-pos (memq '&optional normalized)) (decf body-pos))
675      `(progn
676         (eval-when (:compile-toplevel)
677           (define-compile-time-macro ',name ',lambda-form ',env))
678         (eval-when (:load-toplevel :execute)
679           (%macro 
680            (nfunction ,name ,lambda-form)
681            '(,doc ,body-pos . ,argstring))
682           ',name)))))
683
684(defmacro define-symbol-macro (name expansion &environment env)
685  (unless (symbolp name)(signal-program-error $XNotSym name))
686  `(progn
687    (eval-when (:compile-toplevel)
688      (define-compile-time-symbol-macro ',name ',expansion ',env))
689    (eval-when (:load-toplevel :execute)
690      (%define-symbol-macro ',name ',expansion))))
691
692;; ---- allow inlining setf functions
693(defmacro defun (spec args &body body &environment env &aux global-name inline-spec)
694  "Define a function at top level."
695  (validate-function-name spec)
696  (setq args (require-type args 'list))
697  (setq body (require-type body 'list))
698  (multiple-value-bind (forms decls doc) (parse-body body env t)
699    (cond ((symbolp spec)
700           (setq global-name spec)
701           (setq inline-spec spec)
702           (setq body `(block ,spec ,@forms)))
703          ((setf-function-name-p spec)
704           (setq inline-spec spec)
705           (setq body `(block ,(cadr spec) ,@forms)))
706          (t (setq body `(progn ,@forms))))
707    (let* ((lambda-expression `(lambda ,args 
708                                ,@(if global-name
709                                    `((declare (global-function-name ,global-name))))
710                                ,@decls ,body))
711           (info (if (and inline-spec
712                          (or (null env)
713                              (definition-environment env t))
714                          (nx-declared-inline-p inline-spec env)
715                          (not (and (symbolp inline-spec)
716                                    (gethash inline-spec *NX1-ALPHATIZERS*))))
717                   (cons doc lambda-expression)
718                   doc)))
719      `(progn
720         (%defun (nfunction ,spec ,lambda-expression) ',info)
721         ',spec))))
722
723(defmacro %defvar-init (var initform doc)
724  `(unless (%defvar ',var ,doc)
725    (set ',var ,initform)))
726
727(defmacro defvar (&environment env var &optional (value () value-p) doc)
728  "Define a global variable at top level. Declare the variable
729  SPECIAL and, optionally, initialize it. If the variable already has a
730  value, the old value is not clobbered. The third argument is an optional
731  documentation string for the variable."
732  (if (and doc (not (stringp doc))) (report-bad-arg doc 'string))
733  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
734    (setq doc nil))
735 `(progn
736    (eval-when (:compile-toplevel)
737      (note-variable-info ',var ,value-p ,env))
738    ,(if value-p
739       `(%defvar-init ,var ,value ,doc)
740       `(%defvar ',var))
741    ',var))
742         
743(defmacro def-standard-initial-binding (name &optional (form name) (doc nil doc-p) &environment env)
744  `(progn
745    (eval-when (:compile-toplevel)
746      (note-variable-info ',name t ,env))   
747    (define-standard-initial-binding ',name #'(lambda () ,form))
748    ,@(when doc-p
749           `((set-documentation ',name 'variable ,doc)))
750    ',name))
751
752(defmacro defparameter (&environment env var value &optional doc)
753  "Define a parameter that is not normally changed by the program,
754  but that may be changed without causing an error. Declare the
755  variable special and sets its value to VAL, overwriting any
756  previous value. The third argument is an optional documentation
757  string for the parameter."
758  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
759  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
760    (setq doc nil))
761  `(progn
762     (eval-when (:compile-toplevel)
763       (note-variable-info ',var t ,env))
764     (%defparameter ',var ,value ,doc)))
765
766
767(defmacro defstatic (&environment env var value &optional doc)
768  "Syntax is like DEFPARAMETER.  Proclaims the symbol to be special,
769but also asserts that it will never be given a per-thread dynamic
770binding.  The value of the variable can be changed (via SETQ, etc.),
771but since all threads access the same static binding of the variable,
772such changes should be made with care."
773  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
774  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
775    (setq doc nil))
776  `(progn
777     (eval-when (:compile-toplevel)
778       (note-variable-info ',var :global ,env))
779     (%defglobal ',var ,value ,doc)))
780
781(defmacro defstaticvar (&environment env var value &optional doc)
782  "Syntax is like DEFVAR.  Proclaims the symbol to be special,
783but also asserts that it will never be given a per-thread dynamic
784binding.  The value of the variable can be changed (via SETQ, etc.),
785but since all threads access the same static binding of the variable,
786such changes should be made with care.  Like DEFVAR, the initial value
787form is not evaluated if the variable is already BOUNDP."
788  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
789  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
790    (setq doc nil))
791  `(progn
792     (eval-when (:compile-toplevel)
793       (note-variable-info ',var :global ,env))
794      (%symbol-bits ',var (logior (ash 1 $sym_vbit_global) (the fixnum (%symbol-bits ',var))))
795     (%defvar-init ,var ,value ,doc)))
796
797
798(defmacro defglobal (&rest args)
799  "Synonym for DEFSTATIC."
800  `(defstatic ,@args))
801
802
803(defmacro defloadvar (var value &optional doc)
804  `(progn
805     (defstaticvar ,var ,nil ,@(if doc `(,doc)))
806     (def-ccl-pointers ,var ()
807       (setq ,var ,value))
808     ',var))
809
810
811
812
813(defmacro qlfun (name args &body body)
814  `(nfunction ,name (lambda ,args ,@body)))
815
816(defmacro lfun-bits-known-function (f)
817  (let* ((temp (gensym)))
818    `(let* ((,temp (function-to-function-vector ,f)))
819      (%svref ,temp (the fixnum (1- (the fixnum (uvsize ,temp))))))))
820
821(defmacro lfunloop (for var in function &body loop-body)
822  "Loop over immediates in function"
823  (assert (and (or (equal (symbol-name for) "FOR") (equal (symbol-name for) "AS"))
824               (equal (symbol-name in) "IN")))
825  (let ((fn (gensym))
826        (lfv (gensym))
827        (i (gensym)))
828    `(loop with ,fn = ,function
829           with ,lfv = (function-to-function-vector ,fn)
830           for ,i from #+ppc-target 1 #+x86-target (%function-code-words ,fn) below (%i- (uvsize  ,lfv) 1)
831           as ,var = (%svref ,lfv ,i)
832           ,@loop-body)))
833
834(defmacro cond (&rest args &aux clause)
835  (when args
836     (setq clause (car args))
837     (if (cdr clause)         
838         `(if ,(car clause) (progn ,@(cdr clause)) (cond ,@(cdr args)))
839       (if (cdr args) `(or ,(car clause) (cond ,@(cdr args)))
840                      `(values ,(car clause))))))
841
842(defmacro and (&rest args)
843  "And Form*
844AND evaluates each form in sequence, from left to right.  If any form
845returns NIL, AND returns NIL; otherwise, AND returns the values(s) returned
846by the last form.  If there are no forms, AND returns T."
847  (if (null args) t
848    (if (null (cdr args)) (car args)
849      `(if ,(car args) (and ,@(cdr args))))))
850
851(defmacro or (&rest args)
852  "Or Form*
853OR evaluates each Form, in sequence, from left to right.
854If any Form but the last returns a non-NIL value, OR returns that
855single value (without evaluating any subsequent Forms.)  If OR evaluates
856the last Form, it returns all values returned by that Form.  If there
857are no Forms, OR returns NIL."
858  (if args
859    (if (cdr args)
860      (do* ((temp (gensym))
861            (handle (list nil))
862            (forms `(let ((,temp ,(pop args)))
863                     (if ,temp ,temp ,@handle))))
864           ((null (cdr args))
865            (%rplaca handle (%car args))
866            forms)
867        (%rplaca handle `(if (setq ,temp ,(%car args)) 
868                          ,temp 
869                          ,@(setq handle (list nil))))
870        (setq args (%cdr args)))
871      (%car args))))
872
873(defmacro case (key &body forms)
874  "CASE Keyform {({(Key*) | Key} Form*)}*
875  Evaluates the Forms in the first clause with a Key EQL to the value of
876  Keyform. If a singleton key is T then the clause is a default clause."
877   (let ((key-var (gensym)))
878     `(let ((,key-var ,key))
879        (declare (ignorable ,key-var))
880        (cond ,@(case-aux forms key-var nil nil)))))
881
882(defmacro ccase (keyplace &body forms)
883  "CCASE Keyform {({(Key*) | Key} Form*)}*
884  Evaluates the Forms in the first clause with a Key EQL to the value of
885  Keyform. If none of the keys matches then a correctable error is
886  signalled."
887  (let* ((key-var (gensym))
888         (tag (gensym)))
889    `(prog (,key-var)
890       ,tag
891       (setq ,key-var ,keyplace)
892       (return (cond ,@(case-aux forms key-var tag keyplace))))))
893
894(defmacro ecase (key &body forms)
895  "ECASE Keyform {({(Key*) | Key} Form*)}*
896  Evaluates the Forms in the first clause with a Key EQL to the value of
897  Keyform. If none of the keys matches then an error is signalled."
898  (let* ((key-var (gensym)))
899    `(let ((,key-var ,key))
900       (declare (ignorable ,key-var))
901       (cond ,@(case-aux forms key-var 'ecase nil)))))
902       
903(defun case-aux (clauses key-var e-c-p placename &optional (used-keys (list (list '%case-core))))
904  (if clauses
905    (let* ((key-list (caar clauses))
906           (stype (if e-c-p (if (eq e-c-p 'ecase) e-c-p 'ccase) 'case))
907           (test (cond ((and (not e-c-p)
908                             (or (eq key-list 't)
909                                 (eq key-list 'otherwise)))
910                        t)
911                       (key-list
912                        (cons 'or
913                              (case-key-testers key-var used-keys key-list stype)))))
914           (consequent-list (or (%cdar clauses) '(nil))))
915      (if (eq test t)
916        (progn
917          (when (%cdr clauses) (warn "~s or ~s clause in the middle of a ~s statement.  Subsequent clauses ignored."
918                                     't 'otherwise 'case))
919          (cons (cons t consequent-list) nil))
920        (cons (cons test consequent-list)
921              (case-aux (%cdr clauses) key-var e-c-p placename used-keys))))
922    (when e-c-p
923      (setq used-keys `(member ,@(mapcar #'car (cdr used-keys))))
924      (if (eq e-c-p 'ecase)
925        `((t (values (%err-disp #.$XWRONGTYPE ,key-var ',used-keys))))
926        `((t (setf ,placename (ensure-value-of-type ,key-var ',used-keys ',placename))
927           (go ,e-c-p)))))))
928
929
930;;; We don't want to descend list structure more than once (like this has
931;;; been doing for the last 18 years or so.)
932(defun case-key-testers (symbol used-keys atom-or-list statement-type &optional recursive)
933  (if (or recursive (atom atom-or-list))
934    (progn
935      (if (assoc atom-or-list used-keys)
936        (warn "Duplicate keyform ~s in ~s statement." atom-or-list statement-type)
937        (setq used-keys (nconc used-keys (list (cons atom-or-list t)))))
938      `((,(if (typep atom-or-list '(and number (not fixnum)))
939              'eql
940              'eq)
941         ,symbol ',atom-or-list)))
942    (nconc (case-key-testers symbol used-keys (car atom-or-list) statement-type t)
943           (when (cdr atom-or-list)
944             (case-key-testers symbol used-keys (%cdr atom-or-list) statement-type nil)))))
945
946
947; generate the COND body of a {C,E}TYPECASE form
948(defun typecase-aux (key-var clauses &optional e-c-p keyform)
949  (let* ((construct (if e-c-p (if (eq e-c-p 'etypecase) e-c-p 'ctypecase) 'typecase))
950         (types ())
951         (body ())
952         otherwise-seen-p)
953    (flet ((bad-clause (c) 
954             (signal-program-error "Invalid clause ~S in ~S form." c construct)))
955      (dolist (clause clauses)
956        (if (atom clause)
957            (bad-clause clause))
958        (if otherwise-seen-p
959            (signal-program-error "OTHERWISE must be final clause in ~S form." construct))
960        (destructuring-bind (typespec &body consequents) clause
961          (when (eq construct 'typecase)
962            (if (eq typespec 'otherwise)
963                (progn (setq typespec t)
964                       (setq otherwise-seen-p t))))
965          (unless
966              (dolist (already types nil)
967                (when (subtypep typespec already)
968                  (warn "Clause ~S ignored in ~S form - shadowed by ~S ." clause construct (assq already clauses))
969                  (return t)))
970            (push typespec types)
971            (setq typespec `(typep ,key-var ',typespec))
972            (push `(,typespec nil ,@consequents) body))))
973      (when e-c-p
974        (setq types `(or ,@(nreverse types)))
975        (if (eq construct 'etypecase)
976            (push `(t (values (%err-disp #.$XWRONGTYPE ,key-var ',types))) body)
977            (push `(t (setf ,keyform (ensure-value-of-type  ,key-var ',types ',keyform))
978                      (go ,e-c-p)) body))))
979    `(cond ,@(nreverse body))))
980
981(defmacro typecase (keyform &body clauses)
982  "TYPECASE Keyform {(Type Form*)}*
983  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
984  is true."
985  (let ((key-var (gensym)))
986    `(let ((,key-var ,keyform))
987       (declare (ignorable ,key-var))
988       ,(typecase-aux key-var clauses))))
989
990(defmacro etypecase (keyform &body clauses)
991  "ETYPECASE Keyform {(Type Form*)}*
992  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
993  is true. If no form is satisfied then an error is signalled."
994  (let ((key-var (gensym)))
995    `(let ((,key-var ,keyform))
996       (declare (ignorable ,key-var))
997       ,(typecase-aux key-var clauses 'etypecase))))
998
999(defmacro ctypecase (keyplace &body clauses)
1000  "CTYPECASE Key {(Type Form*)}*
1001  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
1002  is true. If no form is satisfied then a correctable error is signalled."
1003  (let ((key-var (gensym))
1004        (tag (gensym)))
1005    `(prog (,key-var)
1006       ,tag
1007       (setq ,key-var ,keyplace)
1008       (return ,(typecase-aux key-var clauses tag keyplace)))))
1009
1010(defmacro destructuring-bind (lambda-list expression &body body)
1011  "Bind the variables in LAMBDA-LIST to the contents of ARG-LIST."
1012  (multiple-value-bind (bindings decls)
1013      (%destructure-lambda-list  lambda-list expression nil nil)
1014    `(let* ,(nreverse bindings)
1015      ,@(when decls `((declare ,@decls)))
1016      ,@body)))
1017
1018(defmacro make-destructure-state (tail whole lambda)
1019  `(%istruct 'destructure-state ,tail ,whole ,lambda))
1020
1021
1022; This is supposedly ANSI CL.
1023(defmacro lambda (&whole lambda-expression (&rest paramlist) &body body)
1024  (declare (ignore paramlist body))
1025  (unless (lambda-expression-p lambda-expression)
1026    (warn "Invalid lambda expression: ~s" lambda-expression))
1027  `(function ,lambda-expression))
1028
1029; This isn't
1030(defmacro nlambda (name (&rest arglist) &body body)
1031  `(nfunction ,name (lambda ,arglist ,@body)))
1032
1033(defmacro when (test &body body)
1034  "If the first argument is true, the rest of the forms are
1035  evaluated as a PROGN."
1036 `(if ,test
1037   (progn ,@body)))
1038
1039(defmacro unless (test &body body)
1040  "If the first argument is not true, the rest of the forms are
1041  evaluated as a PROGN."
1042 `(if (not ,test)
1043   (progn ,@body)))
1044
1045(defmacro return (&optional (form nil form-p))
1046  `(return-from nil ,@(if form-p `(,form))))
1047
1048; since they use tagbody, while & until BOTH return NIL
1049(defmacro while (test &body body)
1050  (let ((testlab (gensym))
1051        (toplab (gensym)))
1052    `(tagbody
1053       (go ,testlab)
1054      ,toplab
1055      (progn ,@body)
1056      ,testlab
1057      (when ,test (go ,toplab)))))
1058
1059(defmacro until (test &body body)
1060  (let ((testlab (gensym))
1061        (toplab (gensym)))
1062    `(tagbody
1063       (go ,testlab)
1064      ,toplab
1065      (progn ,@body)
1066      ,testlab
1067      (if (not ,test)
1068        (go ,toplab)))))
1069
1070(defmacro psetq (&whole call &body pairs &environment env)
1071  "PSETQ {var value}*
1072   Set the variables to the values, like SETQ, except that assignments
1073   happen in parallel, i.e. no assignments take place until all the
1074   forms have been evaluated."
1075  (when pairs
1076   (if (evenp (length pairs))
1077     (do* ((l pairs (%cddr l))
1078           (sym (%car l) (%car l)))
1079          ((null l) (%pset pairs))
1080       (unless (symbolp sym) (report-bad-arg sym 'symbol))
1081       (when (nth-value 1 (macroexpand-1 sym env))
1082         (return `(psetf ,@pairs))))
1083     (signal-program-error "Uneven number of args in the call ~S" call))))
1084
1085; generates body for psetq.
1086; "pairs" is a proper list whose length is not odd.
1087(defun %pset (pairs)
1088 (when pairs
1089   (let (vars vals gensyms let-list var val sets)
1090      (loop
1091        (setq var (pop pairs)
1092              val (pop pairs))
1093        (if (null pairs) (return))
1094        (push var vars)
1095        (push val vals)
1096        (push (gensym) gensyms))
1097      (dolist (g gensyms)
1098        (push g sets)
1099        (push (pop vars) sets)
1100        (push (list g (pop vals)) let-list))
1101      (push val sets)
1102      (push var sets)
1103      `(progn
1104         (let ,let-list
1105           (setq ,@sets))
1106         nil))))
1107
1108
1109(eval-when (:compile-toplevel :load-toplevel :execute)
1110(defun do-loop (binder setter env var-init-steps end-test result body)
1111  (let ((toptag (gensym))
1112        (testtag (gensym)))
1113    (multiple-value-bind (forms decls) (parse-body body env nil)
1114      `(block nil
1115         (,binder ,(do-let-vars var-init-steps)
1116                  ,@decls
1117                  (tagbody ; crocks-r-us.
1118                    (go ,testtag)
1119                    ,toptag
1120                    (tagbody
1121                      ,@forms)
1122                    (,setter ,@(do-step-vars var-init-steps))
1123                    ,testtag
1124                    (unless ,end-test
1125                      (go ,toptag)))
1126                  ,@result)))))
1127)
1128
1129(defmacro do (&environment env var-init-steps (&optional end-test &rest result) &body body)
1130  "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1131  Iteration construct. Each Var is initialized in parallel to the value of the
1132  specified Init form. On subsequent iterations, the Vars are assigned the
1133  value of the Step form (if any) in parallel. The Test is evaluated before
1134  each evaluation of the body Forms. When the Test is true, the Exit-Forms
1135  are evaluated as a PROGN, with the result being the value of the DO. A block
1136  named NIL is established around the entire expansion, allowing RETURN to be
1137  used as an alternate exit mechanism."
1138  (do-loop 'let 'psetq env var-init-steps end-test result body))
1139
1140(defmacro do* (&environment env var-init-steps (&optional end-test &rest result) &body body)
1141  "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1142  Iteration construct. Each Var is initialized sequentially (like LET*) to the
1143  value of the specified Init form. On subsequent iterations, the Vars are
1144  sequentially assigned the value of the Step form (if any). The Test is
1145  evaluated before each evaluation of the body Forms. When the Test is true,
1146  the Exit-Forms are evaluated as a PROGN, with the result being the value
1147  of the DO. A block named NIL is established around the entire expansion,
1148  allowing RETURN to be used as an laternate exit mechanism."
1149  (do-loop 'let* 'setq env var-init-steps end-test result body))
1150
1151
1152(defun do-let-vars (var-init-steps)
1153  (if var-init-steps
1154      (cons (list (do-let-vars-var (car var-init-steps))
1155                  (do-let-vars-init (car var-init-steps)))
1156             (do-let-vars (cdr var-init-steps)))))
1157
1158(defun do-let-vars-var (var-init-step)
1159  (if (consp var-init-step)
1160       (car var-init-step)
1161       var-init-step))
1162
1163(defun do-let-vars-init (var-init-step)
1164   (if (consp var-init-step)
1165        (cadr var-init-step)
1166        nil))
1167
1168(defun do-step-vars (var-init-steps)
1169    (if var-init-steps
1170        (if (do-step-vars-step? (car var-init-steps))
1171             (append (list (do-let-vars-var (car var-init-steps))
1172                           (do-step-vars-step (car var-init-steps)))
1173                     (do-step-vars (cdr var-init-steps)))
1174             (do-step-vars (cdr var-init-steps)))))
1175
1176(defun do-step-vars-step? (var-init-step)
1177  (if (consp var-init-step)
1178       (cddr var-init-step)))
1179
1180(defun do-step-vars-step (var-init-step)
1181  (if (consp var-init-step)
1182       (caddr var-init-step)))
1183
1184
1185(defmacro dotimes ((i n &optional result) &body body &environment env)
1186  (multiple-value-bind (forms decls)
1187                       (parse-body body env)
1188    (if (not (symbolp i))(signal-program-error $Xnotsym i))
1189    (let* ((toptag (gensym))
1190           (limit (gensym)))
1191      `(block nil
1192        (let ((,limit ,n) (,i 0))
1193         ,@decls
1194         (declare (unsettable ,i))
1195           (if (int>0-p ,limit)
1196             (tagbody
1197               ,toptag
1198               ,@forms
1199               (locally
1200                (declare (settable ,i))
1201                (setq ,i (1+ ,i)))
1202               (unless (eql ,i ,limit) (go ,toptag))))
1203           ,result)))))
1204 
1205(defun do-syms-result (var resultform)
1206  (unless (eq var resultform)
1207    (if (and (consp resultform) (not (quoted-form-p resultform)))
1208      `(progn (setq ,var nil) ,resultform)
1209      resultform)))
1210
1211(defun expand-package-iteration-macro (iteration-function var pkg-spec resultform body env)
1212  (multiple-value-bind (body decls) (parse-body body env nil)
1213    (let* ((ftemp (gensym))
1214           (vtemp (gensym))
1215           (ptemp (gensym))
1216           (result (do-syms-result var resultform)))
1217      `(block nil
1218        (let* ((,var nil)
1219               (,ptemp ,pkg-spec))
1220          ,@decls
1221           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1222             (declare (dynamic-extent #',ftemp))
1223             (,iteration-function ,ptemp #',ftemp))
1224           ,@(when result `(,result)))))))
1225
1226(defmacro do-symbols ((var &optional pkg result) &body body &environment env)
1227  "DO-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECLARATION}* {TAG | FORM}*
1228   Executes the FORMs at least once for each symbol accessible in the given
1229   PACKAGE with VAR bound to the current symbol."
1230  (expand-package-iteration-macro 'iterate-over-accessable-symbols var pkg result body env))
1231
1232(defmacro do-present-symbols ((var &optional pkg result) &body body &environment env)
1233  (expand-package-iteration-macro 'iterate-over-present-symbols var pkg result body env))
1234
1235(defmacro do-external-symbols ((var &optional pkg result) &body body &environment env)
1236  "DO-EXTERNAL-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECL}* {TAG | FORM}*
1237   Executes the FORMs once for each external symbol in the given PACKAGE with
1238   VAR bound to the current symbol."
1239  (expand-package-iteration-macro 'iterate-over-external-symbols var pkg result body env))
1240
1241(defmacro do-all-symbols ((var &optional resultform)
1242                          &body body &environment env)
1243  "DO-ALL-SYMBOLS (VAR [RESULT-FORM]) {DECLARATION}* {TAG | FORM}*
1244   Executes the FORMs once for each symbol in every package with VAR bound
1245   to the current symbol."
1246  (multiple-value-bind (body decls) (parse-body body env nil)
1247    (let* ((ftemp (gensym))
1248           (vtemp (gensym))
1249           (result (do-syms-result var resultform)))
1250      `(block nil
1251        (let* ((,var nil))
1252         ,@decls
1253           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1254             (declare (dynamic-extent #',ftemp))
1255             (iterate-over-all-symbols #',ftemp))
1256           ,@(when result `(,result)))))))
1257
1258(defmacro multiple-value-list (form)
1259  `(multiple-value-call #'list ,form))
1260
1261
1262
1263
1264(defmacro %i> (x y)
1265  `(> (the fixnum ,x) (the fixnum ,y)))
1266
1267(defmacro %i< (x y)
1268  `(< (the fixnum ,x) (the fixnum ,y)))
1269
1270(defmacro %i<= (x y)
1271 `(not (%i> ,x ,y)))
1272
1273(defmacro %i>= (x y)
1274 `(not (%i< ,x ,y)))
1275
1276(defmacro bitset (bit number)
1277  `(logior (ash 1 ,bit) ,number))
1278
1279(defmacro bitclr (bit number)
1280  `(logand (lognot (ash 1 ,bit)) ,number))
1281
1282(defmacro bitopf ((op bit place) &environment env)
1283  (multiple-value-bind (vars vals stores store-form access-form)
1284                       (get-setf-method place env)
1285    (let* ((constant-bit-p (constantp bit))
1286           (bitvar (if constant-bit-p bit (gensym))))
1287      `(let ,(unless constant-bit-p `((,bitvar ,bit)))          ; compiler isn't smart enough
1288         (let* ,(mapcar #'list `(,@vars ,@stores) `(,@vals (,op ,bitvar ,access-form)))
1289           ,store-form)))))
1290
1291(defmacro bitsetf (bit place)
1292  `(bitopf (bitset ,bit ,place)))
1293
1294(defmacro bitclrf (bit place)
1295  `(bitopf (bitclr ,bit ,place)))
1296
1297(defmacro %svref (v i)
1298  (let* ((vtemp (make-symbol "VECTOR"))
1299           (itemp (make-symbol "INDEX")))
1300      `(let* ((,vtemp ,v)
1301              (,itemp ,i))
1302         (locally (declare (optimize (speed 3) (safety 0)))
1303           (svref ,vtemp ,itemp)))))
1304
1305(defmacro %svset (v i new)
1306  (let* ((vtemp (make-symbol "VECTOR"))
1307         (itemp (make-symbol "INDEX"))
1308         (ntemp (make-symbol "NEW")))
1309    `(let* ((,vtemp ,v)
1310            (,itemp ,i)
1311            (,ntemp ,new))
1312      (locally (declare (optimize (speed 3) (safety 0)))
1313        (setf (svref ,vtemp ,itemp) ,ntemp)))))
1314
1315
1316(defmacro %schar (v i)
1317  (let* ((vtemp (make-symbol "STRING"))
1318         (itemp (make-symbol "INDEX")))
1319    `(let* ((,vtemp ,v)
1320            (,itemp ,i))
1321       (locally (declare (optimize (speed 3) (safety 0)))
1322         (schar ,vtemp ,itemp)))))
1323
1324(defmacro %set-schar (v i new)
1325  (let* ((vtemp (make-symbol "STRING"))
1326         (itemp (make-symbol "INDEX"))
1327         (ntemp (make-symbol "NEW")))
1328      `(let* ((,vtemp ,v)
1329              (,itemp ,i)
1330              (,ntemp ,new))
1331         (locally (declare (optimize (speed 3) (safety 0)))
1332           (setf (schar ,vtemp ,itemp) ,ntemp)))))
1333
1334
1335
1336(defmacro %char-code (c) `(char-code (the character ,c)))
1337(defmacro %code-char (i) `(code-char (the (mod 256) ,i)))
1338
1339(defmacro %izerop (x) `(eq ,x 0))
1340(defmacro %iminusp (x) `(< (the fixnum ,x) 0))
1341(defmacro %i+ (&rest (&optional (n0 0) &rest others))
1342  (if others
1343    `(the fixnum (+ (the fixnum ,n0) (%i+ ,@others)))
1344    `(the fixnum ,n0)))
1345(defmacro %i- (x y &rest others) 
1346  (if (not others)
1347    `(the fixnum (- (the fixnum ,x) (the fixnum ,y)))
1348    `(the fixnum (- (the fixnum ,x) (the fixnum (%i+ ,y ,@others))))))
1349
1350
1351(defmacro %i* (x y) `(the fixnum (* (the fixnum ,x) (the fixnum ,y))))
1352
1353(defmacro %ilogbitp (b i)
1354  (target-word-size-case
1355   (32
1356    `(logbitp (the (integer 0 29) ,b) (the fixnum ,i)))
1357   (64
1358    `(logbitp (the (integer 0 60) ,b) (the fixnum ,i)))))
1359
1360;;; Seq-Dispatch does an efficient type-dispatch on the given Sequence.
1361
1362(defmacro seq-dispatch (sequence list-form array-form)
1363  `(if (sequence-type ,sequence)
1364       ,list-form
1365       ,array-form))
1366
1367
1368(defsetf %get-byte %set-byte)
1369(defsetf %get-unsigned-byte %set-unsigned-byte)
1370(defsetf %get-signed-byte %set-byte)
1371(defsetf %get-word %set-word)
1372(defsetf %get-signed-word %set-word)
1373(defsetf %get-unsigned-word %set-unsigned-word)
1374(defsetf %get-long %set-long)
1375(defsetf %get-signed-long %set-long)
1376(defsetf %get-unsigned-long %set-unsigned-long)
1377(defsetf %get-full-long %set-long)
1378(defsetf %get-point %set-long)
1379(defsetf %get-ptr %set-ptr)
1380(defsetf %get-double-float %set-double-float)
1381(defsetf %get-single-float %set-single-float)
1382(defsetf %get-bit %set-bit)
1383(defsetf %get-unsigned-long-long %set-unsigned-long-long)
1384(defsetf %%get-unsigned-longlong %%set-unsigned-longlong)
1385(defsetf %get-signed-long-long %set-signed-long-long)
1386(defsetf %%get-signed-longlong %%set-signed-longlong)
1387(defsetf %get-bitfield %set-bitfield)
1388
1389(defmacro %ilognot (int) `(%i- -1 ,int))
1390
1391(defmacro %ilogior2 (x y) 
1392  `(logior (the fixnum ,x) (the fixnum ,y)))
1393
1394(defmacro %ilogior (body &rest args)
1395   (while args
1396     (setq body (list '%ilogior2 body (pop args))))
1397   body)
1398
1399(defmacro %ilogand2 (x y)
1400  `(logand (the fixnum ,x) (the fixnum ,y)))
1401
1402(defmacro %ilogand (body &body args)
1403   (while args
1404     (setq body (list '%ilogand2 body (pop args))))
1405   body)
1406
1407(defmacro %ilogxor2 (x y)
1408  `(logxor (the fixnum ,x) (the fixnum ,y)))
1409
1410(defmacro %ilogxor (body &body args)
1411   (while args
1412     (setq body (list '%ilogxor2 body (pop args))))
1413   body)
1414
1415(defmacro with-macptrs (varlist &rest body &environment env)
1416  (multiple-value-bind (body other-decls) (parse-body body env)
1417    (collect ((temp-bindings)
1418              (temp-decls)
1419              (bindings)
1420              (our-decls)
1421              (inits))
1422      (dolist (var varlist)
1423        (let* ((temp (gensym)))
1424          (temp-decls temp)
1425        (if (consp var)
1426          (progn
1427            (our-decls (car var))
1428            (temp-bindings `(,temp (%null-ptr)))
1429            (bindings `(,(car var) ,temp))
1430            (if (cdr var)
1431              (inits `(%setf-macptr ,temp ,@(cdr var)))))
1432          (progn
1433            (our-decls var)
1434            (temp-bindings  `(,temp  (%null-ptr)))
1435            (bindings `(,var ,temp))))))
1436  `(let* ,(temp-bindings)
1437    (declare (dynamic-extent ,@(temp-decls)))
1438    (declare (type macptr ,@(temp-decls)))
1439    ,@(inits)
1440    (let* ,(bindings)
1441      (declare (type macptr ,@(our-decls)))
1442      ,@other-decls
1443      ,@body)))))
1444
1445
1446(defmacro with-loading-file (filename &rest body)
1447   `(let ((*loading-files* (cons ,filename (locally (declare (special *loading-files*))
1448                                                    *loading-files*))))
1449      (declare (special *loading-files*))
1450      ,@body))
1451
1452(defmacro with-input-from-string ((var string &key index start end) &body forms &environment env)
1453  "Create an input string stream, provide an opportunity to perform
1454operations on the stream (returning zero or more values), and then close
1455the string stream.
1456
1457STRING is evaluated first, and VAR is bound to a character input string
1458stream that supplies characters from the subsequence of the resulting
1459string bounded by start and end. BODY is executed as an implicit progn."
1460  (multiple-value-bind (forms decls) (parse-body forms env nil)
1461    `(let ((,var
1462            ,(cond ((null end)
1463                    `(make-string-input-stream ,string ,(or start 0)))
1464                   ((symbolp end)
1465                    `(if ,end
1466                      (make-string-input-stream ,string ,(or start 0) ,end)
1467                      (make-string-input-stream ,string ,(or start 0))))
1468                   (t
1469                    `(make-string-input-stream ,string ,(or start 0) ,end)))))
1470      ,@decls
1471      (unwind-protect
1472           (multiple-value-prog1
1473               (progn ,@forms)
1474             ,@(if index `((setf ,index (string-input-stream-index ,var)))))
1475        (close ,var)))))
1476
1477(defmacro with-output-to-string ((var &optional string &key (element-type 'base-char element-type-p))
1478                                 &body body 
1479                                 &environment env)
1480  "Create a character output stream, perform a series of operations that
1481may send results to this stream, and then close the stream.  BODY is
1482executed as an implicit progn with VAR bound to an output string stream.
1483All output to that string stream is saved in a string."
1484  (let ((string-var (gensym "string")))
1485    (multiple-value-bind (forms decls) (parse-body body env nil)
1486      `(let* ((,string-var ,string)
1487              (,var (if ,string-var
1488                      ,@(if element-type-p
1489                            `((progn
1490                                ,element-type
1491                                (%make-string-output-stream ,string-var)))
1492                            `((%make-string-output-stream ,string-var)))
1493                      ,@(if element-type-p
1494                            `((make-string-output-stream :element-type ,element-type))
1495                            `((make-string-output-stream))))))
1496         ,@decls
1497         (unwind-protect
1498              (progn
1499                ,@forms
1500                ,@(if string () `((get-output-stream-string ,var))))
1501           (close ,var))))))
1502
1503(defmacro with-output-to-truncating-string-stream ((var len) &body body
1504                                                   &environment env)
1505  (multiple-value-bind (forms decls) (parse-body body env nil)
1506    `(let* ((,var (make-truncating-string-stream ,len)))
1507      ,@decls
1508      (unwind-protect
1509           (progn
1510             ,@forms
1511             (values (get-output-stream-string ,var)
1512                     (slot-value ,var 'truncated)))
1513        (close ,var)))))
1514
1515(defmacro with-open-file ((var filename . args) &body body &aux (stream (gensym))(done (gensym)))
1516  "Use open to create a file stream to file named by filename. Filename is
1517the name of the file to be opened. Options are used as keyword arguments
1518to open."
1519  `(let (,stream ,done)
1520     (unwind-protect
1521       (multiple-value-prog1
1522         (let ((,var (setq ,stream (open ,filename ,@args))))
1523           ,@body)
1524         (setq ,done t))
1525       (when ,stream (close ,stream :abort (null ,done))))))
1526
1527(defmacro with-compilation-unit ((&key override) &body body)
1528  "WITH-COMPILATION-UNIT ({Key Value}*) Form*
1529  This form affects compilations that take place within its dynamic extent. It
1530  is intended to be wrapped around the compilation of all files in the same
1531  system. These keywords are defined:
1532    :OVERRIDE Boolean-Form
1533        One of the effects of this form is to delay undefined warnings
1534        until the end of the form, instead of giving them at the end of each
1535        compilation. If OVERRIDE is NIL (the default), then the outermost
1536        WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
1537        OVERRIDE true causes that form to grab any enclosed warnings, even if
1538        it is enclosed by another WITH-COMPILATION-UNIT."
1539  `(flet ((with-compilation-unit-body ()
1540            ,@body))
1541     (declare (dynamic-extent #'with-compilation-unit-body))
1542     (call-with-compilation-unit #'with-compilation-unit-body :override ,override)))
1543
1544; Yow! Another Done Fun.
1545(defmacro with-standard-io-syntax (&body body &environment env)
1546  "Bind the reader and printer control variables to values that enable READ
1547   to reliably read the results of PRINT. These values are:
1548       *PACKAGE*                        the COMMON-LISP-USER package
1549       *PRINT-ARRAY*                    T
1550       *PRINT-BASE*                     10
1551       *PRINT-CASE*                     :UPCASE
1552       *PRINT-CIRCLE*                   NIL
1553       *PRINT-ESCAPE*                   T
1554       *PRINT-GENSYM*                   T
1555       *PRINT-LENGTH*                   NIL
1556       *PRINT-LEVEL*                    NIL
1557       *PRINT-LINES*                    NIL
1558       *PRINT-MISER-WIDTH*              NIL
1559       *PRINT-PRETTY*                   NIL
1560       *PRINT-RADIX*                    NIL
1561       *PRINT-READABLY*                 T
1562       *PRINT-RIGHT-MARGIN*             NIL
1563       *READ-BASE*                      10
1564       *READ-DEFAULT-FLOAT-FORMAT*      SINGLE-FLOAT
1565       *READ-EVAL*                      T
1566       *READ-SUPPRESS*                  NIL
1567       *READTABLE*                      the standard readtable"
1568  (multiple-value-bind (decls body) (parse-body body env)
1569    `(let ((*package* (pkg-arg "COMMON-LISP-USER"))
1570           (*print-array* t)
1571           (*print-base* 10.)
1572           (*print-case* :upcase)
1573           (*print-circle* nil)
1574           (*print-escape* t)
1575           (*print-gensym* t)
1576           (*print-length* nil)
1577           (*print-level* nil)
1578           (*print-lines* nil) ; This doesn't exist as of 5/15/90 - does now
1579           (*print-miser-width* nil)
1580           (*print-pprint-dispatch* nil)
1581           (*print-pretty* nil)
1582           (*print-radix* nil)
1583           (*print-readably* t)
1584           (*print-right-margin* nil)
1585           (*read-base* 10.)
1586           (*read-default-float-format* 'single-float)
1587           (*read-eval* t) ; Also MIA as of 5/15/90
1588           (*read-suppress* nil)
1589           (*readtable* %standard-readtable%)
1590           ; ccl extensions (see l1-io.lisp)
1591           (*print-abbreviate-quote* t)
1592           (*print-structure* t)
1593           (*print-simple-vector* nil)
1594           (*print-simple-bit-vector* nil)
1595           (*print-string-length* nil))
1596       ,@decls
1597       ,@body)))
1598
1599(defmacro with-self-bound-io-control-vars (&body body)
1600  `(let (
1601         (*print-array* *print-array*)
1602         (*print-base* *print-base*)
1603         (*print-case* *print-case*)
1604         (*print-circle* *print-circle*)
1605         (*print-escape* *print-escape*)
1606         (*print-gensym* *print-gensym*)
1607         (*print-length* *print-length*)
1608         (*print-level* *print-level*)
1609         (*print-lines* *print-lines*)
1610         (*print-miser-width* *print-miser-width*)
1611         (*print-pprint-dispatch* *print-pprint-dispatch*)
1612         (*print-pretty* *print-pretty*)
1613         (*print-radix* *print-radix*)
1614         (*print-readably* *print-readably*)
1615         (*print-right-margin* *print-right-margin*)
1616         (*read-base* *read-base*)
1617         (*read-default-float-format* *read-default-float-format*)
1618         (*read-eval* *read-eval*)
1619         (*read-suppress* *read-suppress*)
1620         (*readtable* *readtable*))
1621     ,@body))
1622
1623(defmacro print-unreadable-object (&environment env (object stream &key type identity) &body forms)
1624  "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
1625  with object-type prefix and object-identity suffix, and executing the
1626  code in BODY to provide possible further output."
1627  (multiple-value-bind (body decls) (parse-body forms env)
1628    (if body
1629      (let ((thunk (gensym)))
1630        `(let ((,thunk #'(lambda () ,@decls ,@body)))
1631           (declare (dynamic-extent ,thunk))
1632          (%print-unreadable-object ,object ,stream ,type ,identity ,thunk)))
1633      `(%print-unreadable-object ,object ,stream ,type ,identity nil))))
1634;; Pointers and Handles
1635
1636;;Add function to lisp system pointer functions, and run it if it's not already
1637;; there.
1638(defmacro def-ccl-pointers (name arglist &body body &aux (old (gensym)))
1639  `(flet ((,name ,arglist ,@body))
1640     (let ((,old (member ',name *lisp-system-pointer-functions* :key #'function-name)))
1641       (if ,old
1642         (rplaca ,old #',name)
1643         (progn
1644           (push #',name *lisp-system-pointer-functions*)
1645           (,name))))))
1646
1647(defmacro def-load-pointers (name arglist &body body &aux (old (gensym)))
1648  `(flet ((,name ,arglist ,@body))
1649     (let ((,old (member ',name *lisp-user-pointer-functions* :key #'function-name)))
1650       (if ,old
1651         (rplaca ,old #',name)
1652         (progn
1653           (push #',name *lisp-user-pointer-functions*)
1654           (,name))))))
1655
1656;Queue up some code to run after ccl all loaded up, or, if ccl is already
1657;loaded up, just run it right now.
1658(defmacro queue-fixup (&rest body &aux (fn (gensym)))
1659  `(let ((,fn #'(lambda () ,@body)))
1660     (if (eq %lisp-system-fixups% T)
1661       (funcall ,fn)
1662       (push (cons ,fn (or *loading-toplevel-location* *loading-file-source-file*)) %lisp-system-fixups%))))
1663
1664(defmacro %incf-ptr (p &optional (by 1))
1665  (if (symbolp p)  ;once-only
1666    `(%setf-macptr (the macptr ,p) (%inc-ptr ,p ,by))
1667    (let ((var (gensym)))
1668      `(let ((,var ,p)) (%setf-macptr (the macptr ,var) (%inc-ptr ,var ,by))))))
1669
1670(defmacro with-string-from-cstring ((s ptr) &body body)
1671  (let* ((len (gensym))
1672         (p (gensym)))
1673    `(let* ((,p ,ptr)
1674            (,len (%cstrlen ,p))
1675            (,s (make-string ,len)))
1676      (declare (fixnum ,len))
1677      (%copy-ptr-to-ivector ,p 0 ,s 0 ,len)
1678      (locally
1679          ,@body))))
1680
1681
1682(defmacro with-cstr ((sym str &optional start end) &rest body &environment env)
1683  (multiple-value-bind (body decls) (parse-body body env nil)
1684    (if (and (base-string-p str) (null start) (null end))
1685      (let ((strlen (%i+ (length str) 1)))
1686        `(%stack-block ((,sym ,strlen))
1687           ,@decls
1688           (%cstr-pointer ,str ,sym)
1689           ,@body))
1690      (let ((strname (gensym))
1691            (start-name (gensym))
1692            (end-name (gensym)))
1693        `(let ((,strname ,str)
1694               ,@(if (or start end)
1695                   `((,start-name ,(or start 0))
1696                     (,end-name ,(or end `(length ,strname))))))
1697           (%vstack-block (,sym
1698                           (the fixnum
1699                             (1+
1700                              (the fixnum
1701                                ,(if (or start end)
1702                                     `(byte-length
1703                                       ,strname ,start-name ,end-name)
1704                                     `(length ,strname))))))
1705             ,@decls
1706             ,(if (or start end)
1707                `(%cstr-segment-pointer ,strname ,sym ,start-name ,end-name)
1708                `(%cstr-pointer ,strname ,sym))
1709             ,@body))))))
1710
1711(defmacro with-utf-8-cstr ((sym str) &body body)
1712  (let* ((data (gensym))
1713         (offset (gensym))
1714         (string (gensym))
1715         (len (gensym))
1716         (noctets (gensym))
1717         (end (gensym)))
1718    `(let* ((,string ,str)
1719            (,len (length ,string)))
1720      (multiple-value-bind (,data ,offset) (array-data-and-offset ,string)
1721        (let* ((,end (+ ,offset ,len))
1722               (,noctets (utf-8-octets-in-string ,data ,offset ,end)))
1723          (%stack-block ((,sym (1+ ,noctets)))
1724            (utf-8-memory-encode ,data ,sym 0 ,offset ,end)
1725            (setf (%get-unsigned-byte ,sym ,noctets) 0)
1726            ,@body))))))
1727
1728
1729
1730(defmacro with-native-utf-16-cstr ((sym str) &body body)
1731  (let* ((data (gensym))
1732         (offset (gensym))
1733         (string (gensym))
1734         (len (gensym))
1735         (noctets (gensym))
1736         (end (gensym)))
1737    `(let* ((,string ,str)
1738            (,len (length ,string)))
1739      (multiple-value-bind (,data ,offset) (array-data-and-offset ,string)
1740        (let* ((,end (+ ,offset ,len))
1741               (,noctets (utf-16-octets-in-string ,data ,offset ,end)))
1742          (%stack-block ((,sym (1+ ,noctets)))
1743            (native-utf-16-memory-encode ,data ,sym 0 ,offset ,end)
1744            (setf (%get-unsigned-word ,sym ,noctets) 0)
1745            ,@body))))))
1746
1747(defmacro with-pointers (speclist &body body)
1748   (with-specs-aux 'with-pointer speclist body))
1749
1750
1751
1752(defmacro with-cstrs (speclist &body body)
1753   (with-specs-aux 'with-cstr speclist body))
1754
1755(defmacro with-utf-8-cstrs (speclist &body body)
1756   (with-specs-aux 'with-utf-8-cstr speclist body))
1757
1758(defmacro with-native-utf-16-cstrs (speclist &body body)
1759  (with-specs-aux 'with-native-utf-16-cstr speclist body))
1760
1761(defmacro with-encoded-cstr ((encoding-name (sym string &optional start end))
1762                             &rest body &environment env)
1763  (let* ((encoding (gensym))
1764         (str (gensym)))
1765      (multiple-value-bind (body decls) (parse-body body env nil)
1766        `(let* ((,str ,string)
1767                (,encoding (get-character-encoding ,encoding-name)))
1768          (%stack-block ((,sym (cstring-encoded-length-in-bytes ,encoding ,str ,start ,end) :clear t))
1769            ,@decls
1770            (encode-string-to-memory ,encoding ,sym 0 ,str ,start ,end)
1771            ,@body)))))
1772
1773(defmacro with-encoded-cstrs (encoding-name bindings &body body)
1774  (with-specs-aux 'with-encoded-cstr (mapcar #'(lambda (b)
1775                                                 `(,encoding-name ,b))
1776                                             bindings) body))
1777
1778(defmacro with-filename-cstrs (&rest rest)
1779  (case (target-os-name)
1780    (:darwin `(with-utf-8-cstrs ,@rest))
1781    (:windows `(with-native-utf-16-cstrs ,@rest))
1782    (t `(with-encoded-cstrs (pathname-encoding-name) ,@rest))))
1783
1784
1785(defun with-specs-aux (name spec-list original-body)
1786  (multiple-value-bind (body decls) (parse-body original-body nil)
1787    (when decls (signal-program-error "declarations not allowed in ~s" original-body))
1788    (setq body (cons 'progn body))
1789    (dolist (spec (reverse spec-list))
1790      (setq body (list name spec body)))
1791    body))
1792
1793
1794(defmacro type-predicate (type)
1795  `(get-type-predicate ,type))
1796
1797(defsetf type-predicate set-type-predicate)
1798
1799(defun adjust-defmethod-lambda-list (ll)
1800  ;; If the lambda list contains &key, ensure that it also contains
1801  ;; &allow-other-keys
1802  (if (or (not (memq '&key ll))
1803          (memq '&allow-other-keys ll))
1804    ll
1805    (if (memq '&aux ll)
1806      (let* ((ll (copy-list ll))
1807             (aux (memq '&aux ll)))
1808        (setf (car aux) '&allow-other-keys
1809              (cdr aux) (cons '&aux (cdr aux)))
1810        ll)
1811      (append ll '(&allow-other-keys)))))
1812
1813(defmacro defmethod (name &rest args &environment env)
1814  (multiple-value-bind (function-form specializers-form qualifiers lambda-list documentation specializers)
1815      (parse-defmethod name args env)
1816    `(progn
1817       (eval-when (:compile-toplevel)
1818         (record-function-info ',(maybe-setf-function-name name)
1819                               ',(multiple-value-bind (bits keyvect) (encode-lambda-list lambda-list t)
1820                                   (%cons-def-info 'defmethod bits keyvect nil specializers qualifiers))
1821                               ,env))
1822       (compiler-let ((*nx-method-warning-name* '(,name ,@qualifiers ,specializers)))
1823         (ensure-method ',name ,specializers-form
1824                        :function ,function-form
1825                        :qualifiers ',qualifiers
1826                        :lambda-list ',lambda-list
1827                        ,@(if documentation `(:documentation ,documentation)))))))
1828
1829
1830(defun seperate-defmethod-decls (decls)
1831  (let (outer inner)
1832    (dolist (decl decls)
1833      (if (neq (car decl) 'declare)
1834        (push decl outer)
1835        (let (outer-list inner-list)
1836          (dolist (d (cdr decl))
1837            (if (and (listp d) (eq (car d) 'dynamic-extent))
1838              (let (in out)
1839                (dolist (fspec (cdr d))
1840                  (if (and (listp fspec)
1841                           (eq (car fspec) 'function)
1842                           (listp (cdr fspec))
1843                           (null (cddr fspec))
1844                           (memq (cadr fspec) '(call-next-method next-method-p)))
1845                    (push fspec in)
1846                    (push fspec out)))
1847                (when out
1848                  (push `(dynamic-extent ,@(nreverse out)) outer-list))
1849                (when in
1850                  (push `(dynamic-extent ,@(nreverse in)) inner-list)))
1851              (push d outer-list)))
1852          (when outer-list
1853            (push `(declare ,@(nreverse outer-list)) outer))
1854          (when inner-list
1855            (push `(declare ,@(nreverse inner-list)) inner)))))
1856    (values (nreverse outer) (nreverse inner))))
1857                   
1858
1859(defvar *warn-about-unreferenced-required-args-in-methods* #+ccl-0711 nil #-ccl-0711 T)
1860
1861(defun parse-defmethod (name args env)
1862  (validate-function-name name)
1863  (let (qualifiers lambda-list parameters specializers specializers-form refs types temp)
1864    (until (listp (car args))
1865      (push (pop args) qualifiers))
1866    (setq lambda-list (pop args))
1867    (while (and lambda-list (not (memq (car lambda-list) lambda-list-keywords)))
1868      (let ((p (pop lambda-list)))
1869        (cond ((consp p)
1870               (unless (and (consp (%cdr p)) (null (%cddr p)))
1871                 (signal-program-error "Illegal arg ~S" p))
1872               (push (%car p) parameters)
1873               (push (%car p) refs)
1874               (setq p (%cadr p))
1875               (cond ((and (consp p) (eq (%car p) 'eql)
1876                           (consp (%cdr p)) (null (%cddr p)))
1877                      (push `(list 'eql ,(%cadr p)) specializers-form)
1878                      (push p specializers))
1879                     ((or (setq temp (non-nil-symbol-p p))
1880                          (specializer-p p))
1881                      (push `',p specializers-form)
1882                      (push p specializers)
1883                      (unless (or (eq p t) (not temp))
1884                        ;Should be `(guaranteed-type ...).
1885                        (push `(type ,p ,(%car parameters)) types)))
1886                     (t (signal-program-error "Illegal arg ~S" p))))
1887              (t
1888               (push p parameters)
1889               (unless *warn-about-unreferenced-required-args-in-methods*
1890                 (push p refs))
1891               (push t specializers-form)
1892               (push t specializers)))))
1893    (setq lambda-list (nreconc parameters lambda-list))
1894    (multiple-value-bind (body decls doc) (parse-body args env t)
1895      (multiple-value-bind (outer-decls inner-decls) 
1896                           (seperate-defmethod-decls decls)
1897        (let* ((methvar (make-symbol "NEXT-METHOD-CONTEXT"))
1898               (cnm-args (gensym))
1899               (lambda-form `(lambda ,(list* '&method methvar lambda-list)
1900                               (declare ;,@types
1901                                (ignorable ,@refs))
1902                               ,@outer-decls
1903                               (block ,(if (consp name) (cadr name) name)
1904                                 (flet ((call-next-method (&rest ,cnm-args)
1905                                          (declare (dynamic-extent ,cnm-args))
1906                                          (if ,cnm-args
1907                                            (apply #'%call-next-method-with-args ,methvar ,cnm-args)
1908                                            (%call-next-method ,methvar)))
1909                                        (next-method-p () (%next-method-p ,methvar)))
1910                                   (declare (inline call-next-method next-method-p))
1911                                   ,@inner-decls
1912                                   ,@body)))))
1913          (values
1914           (if name `(nfunction ,name ,lambda-form) `(function ,lambda-form))
1915           `(list ,@(nreverse specializers-form))
1916           (nreverse qualifiers)
1917           lambda-list
1918           doc
1919           (nreverse specializers)))))))
1920
1921(defmacro anonymous-method (name &rest args &environment env)
1922  (multiple-value-bind (function-form specializers-form qualifiers method-class documentation)
1923                       (parse-defmethod name args env)
1924   
1925    `(%anonymous-method
1926      ,function-form
1927      ,specializers-form
1928      ',qualifiers
1929      ,@(if (or method-class documentation) `(',method-class))
1930      ,@(if documentation `(,documentation)))))
1931
1932
1933
1934(defmacro defclass (class-name superclasses slots &rest class-options &environment env)
1935  (flet ((duplicate-options (where) (signal-program-error "Duplicate options in ~S" where))
1936         (illegal-option (option) (signal-program-error "Illegal option ~s" option))
1937         (make-initfunction (form)
1938           (cond ((or (eq form 't)
1939                      (equal form ''t))
1940                  '(function true))
1941                 ((or (eq form 'nil)
1942                      (equal form ''nil))
1943                  '(function false))
1944                 (t
1945                  `(function (lambda () ,form))))))
1946    (setq class-name (require-type class-name '(and symbol (not null))))
1947    (setq superclasses (mapcar #'(lambda (s) (require-type s 'symbol)) superclasses))
1948    (let* ((options-seen ())
1949           (signatures ())
1950           (slot-names ())
1951           (slot-initargs ()))
1952      (flet ((canonicalize-defclass-option (option)
1953               (let* ((option-name (car option)))
1954                 (if (member option-name options-seen :test #'eq)
1955                   (duplicate-options class-options)
1956                   (push option-name options-seen))
1957                 (case option-name
1958                   (:default-initargs
1959                       (let ((canonical ())
1960                             (initargs-seen ()))
1961                         (let (key val (tail (cdr option)))
1962                           (loop (when (null tail) (return nil))
1963                              (setq key (pop tail)
1964                                    val (pop tail))
1965                              (when (memq key initargs-seen)
1966                                (SIGNAL-PROGRAM-error "Duplicate initialization argument name ~S in :DEFAULT-INITARGS of DEFCLASS ~S" key class-name))
1967                              (push key initargs-seen)
1968                              (push ``(,',key ,',val  ,,(make-initfunction val)) canonical))
1969                           `(':direct-default-initargs (list ,@(nreverse canonical))))))
1970                   (:metaclass
1971                    (unless (and (cadr option)
1972                                 (typep (cadr option) 'symbol))
1973                      (illegal-option option))
1974                    `(:metaclass  ',(cadr option)))
1975                   (:documentation
1976                    `(:documentation ',(cadr option)))
1977                   (t
1978                     (list `',option-name `',(cdr option))))))
1979             (canonicalize-slot-spec (slot)
1980               (if (null slot) (signal-program-error "Illegal slot NIL"))
1981               (if (not (listp slot)) (setq slot (list slot)))
1982               (let* ((slot-name (require-type (car slot) 'symbol))
1983                      (initargs nil)
1984                      (other-options ())
1985                      (initform nil)
1986                      (initform-p nil)
1987                      (initfunction nil)
1988                      (type nil)
1989                      (type-p nil)
1990                      (allocation nil)
1991                      (allocation-p nil)
1992                      (documentation nil)
1993                      (documentation-p nil)
1994                      (readers nil)
1995                      (writers nil)
1996                      (reader-info (%cons-def-info 'defmethod (dpb 1 $lfbits-numreq 0) nil nil (list class-name)))
1997                      (writer-info (%cons-def-info 'defmethod (dpb 2 $lfbits-numreq 0) nil nil (list t class-name))))
1998                 (when (memq slot-name slot-names)
1999                   (signal-program-error "Multiple slots named ~S in DEFCLASS ~S" slot-name class-name))
2000                 (push slot-name slot-names)
2001                 (do ((options (cdr slot) (cddr options))
2002                      name)
2003                     ((null options))
2004                   (when (null (cdr options)) (signal-program-error "Illegal slot spec ~S" slot))
2005                   (case (car options)
2006                     (:reader
2007                      (setq name (cadr options))
2008                      (unless (memq name readers)
2009                        (push (cons name reader-info) signatures)
2010                        (push name readers)))
2011                     (:writer                     
2012                      (setq name (cadr options))
2013                      (unless (member name writers :test 'equal)
2014                        (push (cons name writer-info) signatures)
2015                        (push name writers)))
2016                     (:accessor
2017                      (setq name (cadr options))
2018                      (unless (memq name readers)
2019                        (push (cons name reader-info) signatures)
2020                        (push name readers))
2021                      (let ((setf-name `(setf ,name)))
2022                        (unless (member setf-name writers :test 'equal)
2023                          (push (cons (setf-function-name name) writer-info) signatures)
2024                          (push setf-name writers))))
2025                     (:initarg
2026                      (let* ((initarg (require-type (cadr options) 'symbol))
2027                             (other (position initarg slot-initargs :test #'memq)))
2028                        (when other
2029                          (warn "Initarg ~s occurs in both ~s and ~s slots"
2030                                initarg (nth (1+ other) slot-names) slot-name))
2031                        (push initarg initargs)))
2032                     (:type
2033                      (if type-p
2034                        (duplicate-options slot)
2035                        (setq type-p t))
2036                      (setq type (cadr options))
2037                      ;; complain about illegal typespecs and continue
2038                      (handler-case (specifier-type type env)
2039                        (program-error ()
2040                          (warn "Invalid type ~s in ~s slot definition ~s" type class-name slot))))
2041                     (:initform
2042                      (if initform-p
2043                        (duplicate-options slot)
2044                        (setq initform-p t))
2045                      (let ((option (cadr options)))
2046                        (setq initform `',option
2047                              initfunction
2048                              (if (constantp option)
2049                                `(constantly ,option)
2050                                `#'(lambda () ,option)))))
2051                     (:allocation
2052                      (if allocation-p
2053                        (duplicate-options slot)
2054                        (setq allocation-p t))
2055                      (setq allocation (cadr options)))
2056                     (:documentation
2057                      (if documentation-p
2058                        (duplicate-options slot)
2059                        (setq documentation-p t))
2060                      (setq documentation (cadr options)))
2061                     (t
2062                      (let* ((pair (or (assq (car options) other-options)
2063                                       (car (push (list (car options)) other-options)))))
2064                        (push (cadr options) (cdr pair))))))
2065                 (push initargs slot-initargs)
2066                 `(list :name ',slot-name
2067                   ,@(when allocation `(:allocation ',allocation))
2068                   ,@(when initform-p `(:initform ,initform
2069                                        :initfunction ,initfunction))
2070                   ,@(when initargs `(:initargs ',initargs))
2071                   ,@(when readers `(:readers ',readers))
2072                   ,@(when writers `(:writers ',writers))
2073                   ,@(when type-p `(:type ',type))
2074                   ,@(when documentation-p `(:documentation ,documentation))
2075                   ,@(mapcan #'(lambda (opt)
2076                                 `(',(car opt) ',(if (null (cddr opt))
2077                                                     (cadr opt)
2078                                                     (cdr opt)))) other-options)))))
2079        (let* ((direct-superclasses superclasses)
2080               (direct-slot-specs (mapcar #'canonicalize-slot-spec slots))
2081               (other-options (apply #'append (mapcar #'canonicalize-defclass-option class-options )))
2082               (keyvect (class-keyvect class-name other-options)))
2083          (when (vectorp keyvect)
2084            (let ((illegal (loop for arg in other-options by #'cddr
2085                              as key = (if (quoted-form-p arg) (%cadr arg) arg)
2086                              unless (or (eq key :metaclass) (find key keyvect)) collect key)))
2087              (when illegal
2088                (signal-program-error "Class option~p~{ ~s~} is not one of ~s"
2089                                      (length illegal) illegal keyvect))))
2090          `(progn
2091             (when (memq ',class-name *nx-known-declarations*)
2092               (check-declaration-redefinition ',class-name 'defclass))
2093            (eval-when (:compile-toplevel)
2094              (%compile-time-defclass ',class-name ,env)
2095              (progn
2096                ,@(mapcar #'(lambda (sig) `(record-function-info ',(car sig) ',(cdr sig) ,env))
2097                          signatures)))
2098              (ensure-class-for-defclass ',class-name
2099                            :direct-superclasses ',direct-superclasses
2100                            :direct-slots ,`(list ,@direct-slot-specs)
2101                            ,@other-options)))))))
2102
2103(defmacro define-method-combination (name &rest rest &environment env)
2104  (setq name (require-type name 'symbol))
2105  (cond ((or (null rest) (and (car rest) (symbolp (car rest))))
2106         `(short-form-define-method-combination ',name ',rest))
2107        ((listp (car rest))
2108         (destructuring-bind (lambda-list method-group-specifiers . forms) rest
2109           (long-form-define-method-combination 
2110            name lambda-list method-group-specifiers forms env)))
2111        (t (%badarg (car rest) '(or (and null symbol) list)))))
2112
2113(defmacro defgeneric (function-name lambda-list &rest options-and-methods &environment env)
2114  (fboundp function-name)             ; type-check
2115  (multiple-value-bind (method-combination generic-function-class options methods)
2116      (parse-defgeneric function-name t lambda-list options-and-methods)
2117    (let ((gf (gensym)))
2118      `(progn
2119         (eval-when (:compile-toplevel)
2120           (record-function-info ',(maybe-setf-function-name function-name)
2121                                 ',(multiple-value-bind (bits keyvect) (encode-lambda-list lambda-list t)
2122                                     (%cons-def-info 'defgeneric bits keyvect))
2123                                 ,env))
2124         (let ((,gf (%defgeneric
2125                     ',function-name ',lambda-list ',method-combination ',generic-function-class 
2126                     ',(apply #'append options))))
2127           (%set-defgeneric-methods ,gf ,@methods)
2128           ,gf)))))
2129
2130
2131
2132(defun parse-defgeneric (function-name global-p lambda-list options-and-methods)
2133  (check-generic-function-lambda-list lambda-list)
2134  (let ((method-combination '(standard))
2135        (generic-function-class 'standard-generic-function)
2136        options declarations methods option-keywords method-class)
2137    (flet ((bad-option (o)
2138             (signal-program-error "Bad option: ~s to ~s." o 'defgeneric)))
2139      (dolist (o options-and-methods)
2140        (let ((keyword (car o))
2141              (defmethod (if global-p 'defmethod 'anonymous-method)))
2142          (if (eq keyword :method)
2143            (let ((defn `(,defmethod ,function-name ,@(%cdr o))))
2144              (note-source-transformation o defn)
2145              (push defn methods))
2146            (cond ((and (not (eq keyword 'declare))
2147                        (memq keyword (prog1 option-keywords (push keyword option-keywords))))             
2148                   (signal-program-error "Duplicate option: ~s to ~s" keyword 'defgeneric))
2149                  ((eq keyword :method-combination)
2150                   (unless (symbolp (cadr o))
2151                     (bad-option o))
2152                   (setq method-combination (cdr o)))
2153                  ((eq keyword :generic-function-class)
2154                   (unless (and (cdr o) (symbolp (cadr o)) (null (%cddr o)))
2155                     (bad-option o))
2156                   (setq generic-function-class (%cadr o)))
2157                  ((eq keyword 'declare)
2158                   (push (cadr o) declarations))
2159                  ((eq keyword :argument-precedence-order)
2160                   (dolist (arg (cdr o))
2161                     (unless (and (symbolp arg) (memq arg lambda-list))
2162                       (bad-option o)))
2163                   (push (list keyword (cdr o)) options))
2164                  ((eq keyword :method-class)
2165                   (push o options)
2166                   (when (or (cddr o) (not (symbolp (setq method-class (%cadr o)))))
2167                     (bad-option o)))
2168                  ((eq keyword :documentation)
2169                   (push o options)
2170                   (when (or (cddr o) (not (stringp (%cadr o))))
2171                     (bad-option o)))
2172                  (t (bad-option o)))))))
2173    (when method-class
2174      (dolist (m methods)
2175        (push `(:method-class ,method-class) (cddr m))))
2176    (when declarations
2177      (setq options `((:declarations ,declarations) ,@options)))
2178    (values method-combination generic-function-class options methods)))
2179
2180                 
2181(defmacro def-aux-init-functions (class &rest functions)
2182  `(set-aux-init-functions ',class (list ,@functions)))
2183
2184
2185
2186
2187
2188
2189;;; A powerful way of defining REPORT-CONDITION...
2190;;; Do they really expect that each condition type has a unique method on PRINT-OBJECT
2191;;; which tests *print-escape* ?  Scary if so ...
2192
2193(defmacro define-condition (name (&rest supers) (&rest slots) &body options)
2194  "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
2195   Define NAME as a condition type. This new type inherits slots and its
2196   report function from the specified PARENT-TYPEs. A slot spec is a list of:
2197     (slot-name :reader <rname> :initarg <iname> {Option Value}*
2198
2199   The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
2200   and :TYPE and the overall options :DEFAULT-INITARGS and
2201   [type] :DOCUMENTATION are also allowed.
2202
2203   The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
2204   a string or a two-argument lambda or function name. If a function, the
2205   function is called with the condition and stream to report the condition.
2206   If a string, the string is printed.
2207
2208   Condition types are classes, but (as allowed by ANSI and not as described in
2209   CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
2210   SLOT-VALUE may not be used on condition objects."
2211  ; If we could tell what environment we're being expanded in, we'd
2212  ; probably want to check to ensure that all supers name conditions
2213  ; in that environment.
2214  (let ((classopts nil)
2215        (duplicate nil)
2216        (docp nil)
2217        (default-initargs-p nil)
2218        (reporter nil))
2219    (dolist (option options)
2220      (unless (and (consp option)
2221                   (consp (%cdr option)))
2222        (signal-program-error "Invalid option ~s ." option))
2223      (ecase (%car option)
2224        (:default-initargs 
2225            (unless (plistp (cdr option)) 
2226              (signal-program-error "~S is not a plist." (%cdr option))) 
2227            (if default-initargs-p 
2228              (setq duplicate t) 
2229              (push (setq default-initargs-p option) classopts))) 
2230        (:documentation 
2231         (unless (null (%cddr option)) 
2232           (signal-program-error "Invalid option ~s ." option)) 
2233         (if docp
2234           (setq duplicate t)
2235           (push (setq docp option) classopts)))
2236        (:report 
2237         (unless (null (%cddr option)) 
2238           (signal-program-error "Invalid option ~s ." option)) 
2239         (if reporter
2240           (setq duplicate t)
2241           (progn
2242             (if (or (lambda-expression-p (setq reporter (%cadr option)))
2243                     (symbolp reporter))
2244               (setq reporter `(function ,reporter))
2245               (if (stringp reporter)
2246                 (setq reporter `(function (lambda (c s) (declare (ignore c)) (write-string ,reporter s))))
2247                 (signal-program-error "~a expression is not a string, symbol, or lambda expression ." (%car option))))
2248             (setq reporter `((defmethod report-condition ((c ,name) s)
2249                                (funcall ,reporter c s))))))))
2250      (if duplicate (signal-program-error "Duplicate option ~s ." option)))
2251    `(progn
2252       (defclass ,name ,(or supers '(condition)) ,slots ,@classopts)
2253       ,@reporter
2254       ',name)))
2255
2256(defmacro with-condition-restarts (&environment env condition restarts &body body)
2257  "Evaluates the BODY in a dynamic environment where the restarts in the list
2258   RESTARTS-FORM are associated with the condition returned by CONDITION-FORM.
2259   This allows FIND-RESTART, etc., to recognize restarts that are not related
2260   to the error currently being debugged. See also RESTART-CASE."
2261  (multiple-value-bind (body decls)
2262                       (parse-body body env)
2263    (let ((cond (gensym))
2264          (r (gensym)))
2265          `(let* ((*condition-restarts* *condition-restarts*))
2266             ,@decls
2267             (let ((,cond ,condition))
2268               (dolist (,r ,restarts) (push (cons ,r ,cond) *condition-restarts*))
2269               ,@body)))))
2270 
2271(defmacro setf-find-class (name arg1 &optional (arg2 () 2-p) (arg3 () 3-p))
2272  (cond (3-p ;might want to pass env (arg2) to find-class someday?
2273         `(set-find-class ,name (progn ,arg1 ,arg2 ,arg3)))
2274        (2-p
2275         `(set-find-class ,name (progn ,arg1 ,arg2)))
2276        (t `(set-find-class ,name ,arg1))))
2277
2278(defsetf find-class setf-find-class)
2279
2280(defmacro restoring-interrupt-level (var &body body)
2281  `(unwind-protect
2282    (progn ,@body)
2283    (restore-interrupt-level ,var)
2284    (%interrupt-poll)))
2285
2286(defmacro without-interrupts (&body body)
2287  "Evaluate its body in an environment in which process-interrupt
2288requests are deferred."
2289  `(let* ((*interrupt-level* -1))
2290    ,@body))
2291
2292(defmacro with-interrupts-enabled (&body body)
2293  "Evaluate its body in an environment in which process-interrupt
2294has immediate effect."
2295  `(let* ((*interrupt-level* 0))
2296    ,@body))
2297
2298;;; undoes the effect of one enclosing without-interrupts during execution of body.
2299(defmacro ignoring-without-interrupts (&body body)
2300  `(let* ((*interrupt-level* 0))
2301    ,@body))
2302
2303
2304
2305(defmacro error-ignoring-without-interrupts (format-string &rest format-args)
2306  `(ignoring-without-interrupts
2307    (error ,format-string ,@format-args)))
2308
2309
2310;init-list-default: if there is no init pair for <keyword>,
2311;    add a <keyword> <value> pair to init-list
2312(defmacro init-list-default (the-init-list &rest args)
2313  (let ((result)
2314       (init-list-sym (gensym)))
2315   (do ((args args (cddr args)))
2316       ((not args))
2317     (setq result 
2318           (cons `(if (eq '%novalue (getf ,init-list-sym ,(car args) 
2319                                          '%novalue))
2320                    (setq ,init-list-sym (cons ,(car args) 
2321                                               (cons ,(cadr args) 
2322                                                     ,init-list-sym))))
2323                 result)))                                                                               
2324   `(let ((,init-list-sym ,the-init-list))
2325      (progn ,@result)
2326      ,init-list-sym)
2327   ))
2328
2329; This can only be partially backward-compatible: even if only
2330; the "name" arg is supplied, the old function would create the
2331; package if it didn't exist.
2332; Should see how well this works & maybe flush the whole idea.
2333
2334(defmacro in-package (name)
2335  (let ((form nil))
2336    (when (quoted-form-p name)
2337      (warn "Unquoting argument ~S to ~S." name 'in-package )
2338      (setq name (cadr name)))   
2339    (setq form `(set-package ,(string name)))
2340    `(eval-when (:execute :load-toplevel :compile-toplevel)
2341      ,form)))
2342
2343(defmacro defpackage (name &rest options)
2344  "Defines a new package called PACKAGE. Each of OPTIONS should be one of the
2345   following:
2346    (NICKNAMES {package-name}*)
2347
2348    (SIZE <integer>)
2349    (SHADOW {symbol-name}*)
2350    (SHADOWING-IMPORT-FROM <package-name> {symbol-name}*)
2351    (USE {package-name}*)
2352    (IMPORT-FROM <package-name> {symbol-name}*)
2353    (INTERN {symbol-name}*)
2354    (EXPORT {symbol-name}*)
2355    (IMPLEMENT {package-name}*)
2356    (LOCK boolean)
2357    (DOCUMENTATION doc-string)
2358   All options except SIZE, LOCK, and :DOCUMENTATION can be used multiple
2359   times."
2360  (let* ((size nil)
2361         (all-names-size 0)
2362         (intern-export-size 0)
2363         (shadow-etc-size 0)
2364         (documentation nil)
2365         (all-names-hash (let ((all-options-alist nil))
2366                           (dolist (option options)
2367                             (let ((option-name (car option)))
2368                               (when (memq option-name
2369                                           '(:nicknames :shadow :shadowing-import-from
2370                                             :use :import-from :intern :export))
2371                                 (let ((option-size (length (cdr option)))
2372                                       (cell (assq option-name all-options-alist)))
2373                                   (declare (fixnum option-size))
2374                                   (if cell
2375                                     (incf (cdr cell) option-size)
2376                                     (push (cons option-name option-size) all-options-alist))
2377                                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2378                                     (incf shadow-etc-size option-size))
2379                                   (when (memq option-name '(:export :intern))
2380                                     (incf intern-export-size option-size))))))
2381                           (dolist (cell all-options-alist)
2382                             (let ((option-size (cdr cell)))
2383                               (when (> option-size all-names-size)
2384                                 (setq all-names-size option-size))))
2385                           (when (> all-names-size 0)
2386                             (make-hash-table :test 'equal :size all-names-size))))
2387         (intern-export-hash (when (> intern-export-size 0)
2388                               (make-hash-table :test 'equal :size intern-export-size)))
2389         (shadow-etc-hash (when (> shadow-etc-size 0)
2390                            (make-hash-table :test 'equal :size shadow-etc-size)))
2391         (external-size nil)
2392         (nicknames nil)
2393         (shadow nil)
2394         (shadowing-import-from-specs nil)
2395         (use :default)
2396         (import-from-specs nil)
2397         (intern nil)
2398         (export nil))
2399    (declare (fixnum all-names-size intern-export-size shadow-etc-size))
2400    (labels ((string-or-name (s) (string s))
2401             (duplicate-option (o)
2402               (signal-program-error "Duplicate ~S option in ~S ." o options))
2403             (duplicate-name (name option-name)
2404               (signal-program-error "Name ~s, used in ~s option, is already used in a conflicting option ." name option-name))
2405             (all-names (option-name tail already)
2406               (when (eq already :default) (setq already nil))
2407               (when all-names-hash
2408                 (clrhash all-names-hash))
2409               (dolist (name already)
2410                 (setf (gethash (string-or-name name) all-names-hash) t))
2411               (dolist (name tail already)
2412                 (setq name (string-or-name name))
2413                 (unless (gethash name all-names-hash)          ; Ok to repeat name in same option.
2414                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2415                     (if (gethash name shadow-etc-hash)
2416                       (duplicate-name name option-name))
2417                     (setf (gethash name shadow-etc-hash) t))
2418                   (when (memq option-name '(:export :intern))
2419                     (if (gethash name intern-export-hash)
2420                       (duplicate-name name option-name))
2421                     (setf (gethash name intern-export-hash) t))
2422                   (setf (gethash name all-names-hash) t)
2423                   (push name already)))))
2424      (dolist (option options)
2425        (let ((args (cdr option)))
2426          (ecase (%car option)
2427                 (:size 
2428                  (if size 
2429                    (duplicate-option :size) 
2430                    (setq size (car args))))             
2431                 (:external-size 
2432                  (if external-size 
2433                    (duplicate-option :external-size) 
2434                    (setq external-size (car args))))
2435                 (:nicknames (setq nicknames (all-names nil args nicknames)))
2436                 (:shadow (setq shadow (all-names :shadow args shadow)))
2437                 (:shadowing-import-from
2438                  (destructuring-bind (from &rest shadowing-imports) args
2439                    (push (cons (string-or-name from)
2440                                (all-names :shadowing-import-from shadowing-imports nil))
2441                          shadowing-import-from-specs)))
2442                 (:use (setq use (all-names nil args use)))
2443                 (:import-from
2444                  (destructuring-bind (from &rest imports) args
2445                    (push (cons (string-or-name from)
2446                                (all-names :import-from imports nil))
2447                          import-from-specs)))
2448                 (:intern (setq intern (all-names :intern args intern)))
2449                 (:export (setq export (all-names :export args export)))
2450                 (:documentation
2451                  (if documentation
2452                    (duplicate-option :documentation)
2453                    (setq documentation (cadr option)))))))
2454      `(eval-when (:execute :compile-toplevel :load-toplevel)
2455         (%define-package ',(string-or-name name)
2456          ',size 
2457          ',external-size 
2458          ',nicknames
2459          ',shadow
2460          ',shadowing-import-from-specs
2461          ',use
2462          ',import-from-specs
2463          ',intern
2464          ',export
2465          ',documentation)))))
2466
2467
2468
2469(defmacro with-package-iterator ((mname package-list first-type &rest other-types)
2470                                 &body body)
2471  "Within the lexical scope of the body forms, MNAME is defined via macrolet
2472   such that successive invocations of (MNAME) will return the symbols,
2473   one by one, from the packages in PACKAGE-LIST. SYMBOL-TYPES may be
2474   any of :INHERITED :EXTERNAL :INTERNAL."
2475  (setq mname (require-type mname 'symbol))
2476  (let ((state (make-symbol "WITH-PACKAGE-ITERATOR_STATE")))
2477    (dolist (type (push first-type other-types))
2478      (ecase type
2479        ((:external :internal :inherited))))
2480    `(let ((,state (%setup-pkg-iter-state ,package-list ',other-types)))
2481       (macrolet ((,mname () `(%pkg-iter-next ,',state)))
2482         ,@body))))
2483
2484; Does NOT evaluate the constructor, but DOES evaluate the destructor & initializer
2485(defmacro defresource (name &key constructor destructor initializer)
2486  `(defparameter ,name (make-resource #'(lambda () ,constructor)
2487                                      ,@(when destructor
2488                                          `(:destructor ,destructor))
2489                                      ,@(when initializer
2490                                          `(:initializer ,initializer)))))
2491
2492(defmacro using-resource ((var resource) &body body)
2493  (let ((resource-var (gensym)))
2494  `(let ((,resource-var ,resource)
2495         ,var)
2496     (unwind-protect
2497       (progn
2498         (setq ,var (allocate-resource ,resource-var))
2499         ,@body)
2500       (when ,var
2501         (free-resource ,resource-var ,var))))))
2502
2503;;; Bind per-thread specials which help with lock accounting.
2504(defmacro with-lock-context (&body body)
2505  `(progn ,@body))
2506
2507(defmacro with-lock-grabbed ((lock &optional
2508                                   (whostate "Lock"))
2509                             &body body)
2510  "Wait until a given lock can be obtained, then evaluate its body with
2511the lock held."
2512  (declare (ignore whostate))
2513    (let* ((locked (gensym))
2514           (l (gensym)))
2515      `  (with-lock-context
2516           (let ((,locked (make-lock-acquisition))
2517             (,l ,lock))
2518        (declare (dynamic-extent ,locked))
2519        (unwind-protect
2520             (progn
2521               (%lock-recursive-lock-object ,l ,locked )
2522               ,@body)
2523          (when (lock-acquisition.status ,locked) (%unlock-recursive-lock-object ,l)))))))
2524
2525(defmacro with-lock-grabbed-maybe ((lock &optional
2526                                         (whostate "Lock"))
2527                                   &body body)
2528  (declare (ignore whostate))
2529  (let* ((l (gensym)))
2530    `(with-lock-context
2531      (let* ((,l ,lock))
2532        (when (%try-recursive-lock-object ,l)
2533          (unwind-protect
2534               (progn ,@body)
2535            (%unlock-recursive-lock-object ,l)))))))
2536
2537(defmacro with-standard-abort-handling (abort-message &body body)
2538  (let ((stream (gensym)))
2539    `(restart-case
2540       (catch :abort
2541         (catch-cancel
2542           ,@body))
2543       (abort () ,@(when abort-message
2544                     `(:report (lambda (,stream)
2545                                 (write-string ,abort-message ,stream)))))
2546       (abort-break ()))))
2547       
2548
2549
2550
2551(defmacro %lexpr-count (l)
2552  `(%lisp-word-ref ,l 0))
2553
2554(defmacro %lexpr-ref (lexpr count i)
2555  `(%lisp-word-ref ,lexpr (%i- ,count ,i)))
2556
2557;;; args will be list if old style clos
2558(defmacro apply-with-method-context (magic function args)
2559  (let ((m (gensym))
2560        (f (gensym))
2561        (as (gensym)))
2562      `((lambda (,m ,f ,as)
2563          (if (listp ,as)
2564            (%apply-with-method-context ,m ,f ,as)
2565            (%apply-lexpr-with-method-context ,m ,f ,as))) ,magic ,function ,args)))
2566
2567(defmacro defcallback (name arglist &body body &environment env)
2568  "Proclaim name to be a special variable; sets its value to a MACPTR which,
2569when called by foreign code, calls a lisp function which expects foreign
2570arguments of the specified types and which returns a foreign value of the
2571specified result type. Any argument variables which correspond to foreign
2572arguments of type :ADDRESS are bound to stack-allocated MACPTRs.
2573
2574If name is already a callback function pointer, its value is not changed;
2575instead, it's arranged that an updated version of the lisp callback function
2576will be called. This feature allows for callback functions to be redefined
2577incrementally, just like Lisp functions are.
2578
2579defcallback returns the callback pointer, e.g., the value of name."
2580  (define-callback name arglist body env))
2581
2582(declare-arch-specific-macro %get-single-float-from-double-ptr)
2583
2584(declare-arch-specific-macro lfun-vector)
2585(declare-arch-specific-macro lfun-vector-lfun)
2586
2587(declare-arch-specific-macro symptr->symvector)
2588(declare-arch-specific-macro symvector->symptr)
2589
2590(declare-arch-specific-macro function-to-function-vector)
2591(declare-arch-specific-macro function-vector-to-function)
2592
2593(declare-arch-specific-macro with-ffcall-results)
2594
2595(defvar *trace-print-functions* nil)
2596(defun %trace-print-arg (stream arg val type)
2597  (format stream " ")
2598  (let ((fn (assoc type *trace-print-functions*)))
2599    (if fn
2600      (funcall (cdr fn) stream arg val)
2601      (progn
2602      (when arg
2603        (format stream "~A = " arg))
2604      (if (and type (not (eq type :void)))
2605          (format stream "[:~A] ~A~%" type val)
2606        (format stream ":VOID~%" val))))))
2607
2608(defun def-trace-print-function (type fn)
2609  (push (cons type fn) *trace-print-functions*))
2610
2611(defun define-callback (name args body env)
2612  (let* ((stack-word (gensym))
2613         (stack-ptr (gensym))
2614         (fp-args-ptr (gensym))
2615         (result-type-spec :void)
2616         (args args)
2617         (discard-stack-args nil)       ;only meaningful on win32
2618         (discard-hidden-arg nil)       ;only meaningful on x8632
2619         (info nil)
2620         (woi nil)
2621         (need-struct-arg)
2622         (struct-return-arg-name)
2623         (error-return nil))
2624    (collect ((arg-names)
2625              (arg-specs))
2626      (let* ((spec (car (last args)))
2627             (rtype (ignore-errors (parse-foreign-type spec))))
2628        (setq need-struct-arg (typep rtype 'foreign-record-type))
2629        (when need-struct-arg
2630          (setq discard-hidden-arg
2631                (funcall (ftd-ff-call-struct-return-by-implicit-arg-function
2632                          *target-ftd*) rtype)))
2633        (if rtype
2634          (setq result-type-spec spec args (butlast args))))
2635      (loop
2636        (when (null args) (return))
2637        (if (eq (car args) :without-interrupts)
2638          (setq woi (cadr args) args (cddr args))
2639          (if (eq (car args) :discard-stack-args)
2640            (setq discard-stack-args (eq (backend-target-os *target-backend*) :win32) args (cdr args))
2641            (if (eq (car args) :error-return)
2642              (setq error-return
2643                    (cadr args)                 
2644                    args (cddr args))
2645              (if need-struct-arg
2646                (setq struct-return-arg-name (pop args) need-struct-arg nil)
2647                (progn
2648                  (arg-specs (pop args))
2649                  (arg-names (pop args))))))))
2650      (multiple-value-bind (rlets lets dynamic-extent-names inits foreign-return-type fp-args-form error-return-offset num-arg-bytes)
2651          (funcall (ftd-callback-bindings-function *target-ftd*)
2652                   stack-ptr fp-args-ptr (arg-names) (arg-specs) result-type-spec struct-return-arg-name)
2653        ;; x8632 hair
2654        (when discard-hidden-arg
2655          (if discard-stack-args
2656            ;; We already have to discard some number of args, so just
2657            ;; discard the extra hidden arg while we're at it.
2658            (incf num-arg-bytes 4)
2659            ;; Otherwise, indicate that we'll need to discard the
2660            ;; hidden arg.
2661            (setq info (ash 1 23))))
2662        (when discard-stack-args
2663          (setq info 0)
2664          ;; put number of words to discard in high-order byte
2665          (setf (ldb (byte 8 24) info)
2666                (ash num-arg-bytes (- target::word-shift))))
2667        (multiple-value-bind (body decls doc) (parse-body body env t)
2668          `(progn
2669            (declaim (special ,name))
2670            (define-callback-function
2671                (nfunction ,name
2672                 (lambda (,stack-word)
2673                   (declare (ignorable ,stack-word))
2674                   (block ,name
2675                     (with-macptrs ((,stack-ptr))
2676                       (%setf-macptr-to-object ,stack-ptr ,stack-word)
2677                       (with-macptrs (,@(when fp-args-form
2678                                              `((,fp-args-ptr ,fp-args-form))))
2679                         ,(defcallback-body stack-ptr
2680                                            fp-args-ptr
2681                                            lets
2682                                            rlets
2683                                            inits
2684                                            `(declare (dynamic-extent ,@dynamic-extent-names))
2685                                            decls
2686                                            body
2687                                            foreign-return-type
2688                                            struct-return-arg-name
2689                                            error-return
2690                                            error-return-offset
2691                                            ))))))
2692                ,doc
2693              ,woi
2694              ,info)))))))
2695
2696
2697(defun defcallback-body (&rest args)
2698  (declare (dynamic-extent args))
2699  (destructuring-bind (stack-ptr fp-args-ptr lets rlets inits dynamic-extent-decls other-decls body return-type struct-return-arg error-return error-delta) args
2700    (declare (ignorable dynamic-extent-decls))
2701    (let* ((condition-name (if (atom error-return) 'error (car error-return)))
2702           (error-return-function (if (atom error-return) error-return (cadr error-return)))
2703           (result (if struct-return-arg (gensym)))
2704           (body
2705            `(rlet ,rlets
2706              (let ,lets
2707                ,dynamic-extent-decls
2708                ,@other-decls
2709                ,@inits
2710                ,(if result
2711                     `(let* ((,result ,@body))
2712                       (declare (dynamic-extent ,result)
2713                                (ignorable ,result))
2714                       ,(funcall (ftd-callback-return-value-function *target-ftd*)
2715                              stack-ptr
2716                              fp-args-ptr
2717                              result
2718                              return-type
2719                              struct-return-arg))
2720                     (if (eq return-type *void-foreign-type*)
2721                       `(progn ,@body)
2722                       (funcall (ftd-callback-return-value-function *target-ftd*)
2723                                stack-ptr
2724                                fp-args-ptr
2725                                `(progn ,@body)
2726                                return-type
2727                                struct-return-arg)))
2728                nil))))
2729      (if error-return
2730        (let* ((cond (gensym))
2731               (block (gensym))
2732               (handler (gensym)))
2733          `(block ,block
2734            (let* ((,handler (lambda (,cond)
2735                               (,error-return-function ,cond ,stack-ptr (%inc-ptr ,stack-ptr ,error-delta))
2736                               (return-from ,block
2737                                 nil))))
2738              (declare (dynamic-extent ,handler))
2739              (handler-bind ((,condition-name ,handler))
2740                (values ,body)))))
2741        body))))
2742
2743
2744(defmacro define-toplevel-command (group-name name arglist &body body &environment env)
2745  (let* ((key (make-keyword name)))
2746    (multiple-value-bind (body decls doc) (parse-body body env)
2747      `(%define-toplevel-command ',group-name ,key ',name 
2748        (nfunction ,name (lambda ,arglist
2749                           ,@decls
2750                           (block ,name
2751                             ,@body)))
2752        ,doc
2753        ',(mapcar #'symbol-name arglist)))))
2754
2755(defmacro with-toplevel-commands (group-name &body body)
2756  `(let* ((*active-toplevel-commands* *active-toplevel-commands*))
2757    (progn
2758      (%use-toplevel-commands ',group-name)
2759      ,@body)))
2760
2761(defmacro assert (test-form &optional (places ()) string &rest args)
2762  "ASSERT Test-Form [(Place*) [String Arg*]]
2763  If the Test-Form is not true, then signal a correctable error.  If Places
2764  are specified, then new values are prompted for when the error is proceeded.
2765  String and Args are the format string and args to the error call."
2766  (let* ((TOP (gensym))
2767         (setf-places-p (not (null places))))
2768    `(without-compiling-code-coverage
2769      (tagbody
2770       ,TOP
2771       (unless ,test-form
2772         (%assertion-failure ,setf-places-p ',test-form ,string ,@args)
2773         ,@(if places
2774             `((write-line "Type expressions to set places to, or nothing to leave them alone."
2775                           *query-io*)
2776               ,@(mapcar #'(lambda (place &aux (new-val (gensym))
2777                                          (set-p (gensym)))
2778                             `(multiple-value-bind
2779                                (,new-val ,set-p)
2780                                (assertion-value-prompt ',place)
2781                                (when ,set-p (setf ,place (values-list ,new-val)))))
2782                         places)))
2783         (go ,TOP))))))
2784
2785
2786(defmacro check-type (place typespec &optional string)
2787  "CHECK-TYPE Place Typespec [String]
2788  Signal a restartable error of type TYPE-ERROR if the value of PLACE is
2789  not of the specified type. If an error is signalled and the restart is
2790  used to return, this can only return if the STORE-VALUE restart is
2791  invoked. In that case it will store into PLACE and start over."
2792  (let* ((val (gensym)))
2793    `(without-compiling-code-coverage
2794      (do* ((,val ,place ,place))
2795          ((typep ,val ',typespec))
2796       (setf ,place (%check-type ,val ',typespec ',place ,string))))))
2797
2798
2799
2800
2801(defmacro with-hash-table-iterator ((mname hash-table) &body body)
2802  "WITH-HASH-TABLE-ITERATOR ((function hash-table) &body body)
2803   provides a method of manually looping over the elements of a hash-table.
2804   FUNCTION is bound to a generator-macro that, within the scope of the
2805   invocation, returns one or three values. The first value tells whether
2806   any objects remain in the hash table. When the first value is non-NIL,
2807   the second and third values are the key and the value of the next object."
2808  (let* ((hash (gensym))
2809         (keys (gensym))
2810         (values (gensym))
2811         (count (gensym))
2812         (state (gensym)))
2813    `(let* ((,hash ,hash-table)
2814            (,count (hash-table-count ,hash))
2815            (,keys (make-array ,count))
2816            (,values (make-array ,count))
2817            (,state (vector ,hash 0 ,keys ,values (enumerate-hash-keys-and-values ,hash ,keys ,values))))
2818      (declare (dynamic-extent ,keys ,state)
2819               (fixnum ,count))
2820      (macrolet ((,mname () `(next-hash-table-iteration-1 ,',state)))
2821        ,@body))))
2822
2823
2824(eval-when (compile load eval)
2825(defmacro pprint-logical-block ((stream-symbol list
2826                                 &key (prefix "" prefixp)
2827                                      (per-line-prefix "" per-line-prefix-p)
2828                                      (suffix "" suffixp))
2829                                &body body)
2830  (cond ((eq stream-symbol nil) (setq stream-symbol '*standard-output*))
2831        ((eq stream-symbol T) (setq stream-symbol '*terminal-io*)))
2832  (when (not (symbolp stream-symbol))
2833    (warn "STREAM-SYMBOL arg ~S to PPRINT-LOGICAL-BLOCK is not a bindable symbol"
2834          stream-symbol)
2835    (setq stream-symbol '*standard-output*))
2836  (when (and prefixp per-line-prefix-p)
2837    (warn "prefix ~S and per-line-prefix ~S cannot both be specified ~
2838           in PPRINT-LOGICAL-BLOCK" prefix per-line-prefix)
2839    (setq per-line-prefix nil))
2840  `(let ((*logical-block-p* t))
2841     (maybe-initiate-xp-printing
2842      #'(lambda (,stream-symbol)
2843          (let ((+l ,list)
2844                (+p (or (and ,prefixp
2845                             (require-type ,prefix 'string))
2846                        (and ,per-line-prefix-p
2847                             (require-type ,per-line-prefix 'string))))
2848                (+s (require-type ,suffix 'string)))
2849            (pprint-logical-block+
2850                (,stream-symbol +l +p +s ,per-line-prefix-p T nil)
2851              ,@ body nil)))
2852      (decode-stream-arg ,stream-symbol))))
2853
2854
2855;Assumes var and args must be variables.  Other arguments must be literals or variables.
2856
2857(defmacro pprint-logical-block+ ((var args prefix suffix per-line? circle-check? atsign?)
2858                                 &body body)
2859  "Group some output into a logical block. STREAM-SYMBOL should be either a
2860   stream, T (for *TERMINAL-IO*), or NIL (for *STANDARD-OUTPUT*). The printer
2861   control variable *PRINT-LEVEL* is automatically handled."
2862  (when (and circle-check? atsign?)
2863    (setq circle-check? 'not-first-p))
2864  `(let ((*current-level* (1+ *current-level*))
2865         (*current-length* -1)
2866         ;(*parents* *parents*)
2867         ,@(if (and circle-check? atsign?) `((not-first-p (plusp *current-length*)))))
2868     (unless (check-block-abbreviation ,var ,args ,circle-check?)
2869       (start-block ,var ,prefix ,per-line? ,suffix)
2870       (when
2871         (catch 'line-limit-abbreviation-exit
2872           (block logical-block
2873             (macrolet ((pprint-pop () `(pprint-pop+ ,',args ,',var))
2874                        (pprint-exit-if-list-exhausted ()
2875                          `(if (null ,',args) (return-from logical-block nil))))
2876               ,@ body))
2877           (end-block ,var ,suffix)
2878           nil)
2879         (end-block ,var ,suffix)
2880         (throw 'line-limit-abbreviation-exit T)))))
2881) ; eval-when
2882
2883(defmacro %old-class-local-shared-slotds (class &optional default)
2884  (if default                           ; so setf works
2885    `(%class-get ,class '%old-class-local-shared-slotds ,default)
2886    `(%class-get ,class '%old-class-local-shared-slotds)))
2887
2888(defmacro with-slot-values (slot-entries instance-form &body body)
2889; Simplified form of with-slots.  Expands into a let instead of a symbol-macrolet
2890; Thus, you can access the slot values, but you can't setq them.
2891  (let ((instance (gensym)) var slot-name bindings)
2892    (dolist (slot-entry slot-entries)
2893      (cond ((symbolp slot-entry)
2894             (setq var slot-entry slot-name slot-entry))
2895            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2896                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2897             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2898            (t (signal-program-error "Malformed slot-entry: ~a to with-slot-values.~@
2899                                      Should be a symbol or a list of two symbols."
2900                                     slot-entry)))
2901      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2902    `(let ((,instance ,instance-form))
2903       (let ,(nreverse bindings)
2904         ,@body))))
2905
2906(defmacro with-slots (slot-entries instance-form &body body)
2907  "Establish a lexical environment for referring to the slots in the
2908instance named by the given slot-names as though they were variables.
2909Within such a context the value of the slot can be specified by using
2910its slot name, as if it were a lexically bound variable. Both setf and
2911setq can be used to set the value of the slot."
2912  (let ((instance (gensym)) var slot-name bindings)
2913    (dolist (slot-entry slot-entries)
2914      (cond ((symbolp slot-entry)
2915             (setq var slot-entry slot-name slot-entry))
2916            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2917                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2918             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2919            (t (signal-program-error "Malformed slot-entry: ~a to with-slots.~@
2920                                      Should be a symbol or a list of two symbols."
2921                                     slot-entry)))
2922      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2923    `(let ((,instance ,instance-form))
2924       ,@(if bindings 
2925             (list `(declare (ignorable ,instance)))
2926             (list `(declare (ignore ,instance))))
2927       (symbol-macrolet ,(nreverse bindings)
2928         ,@body))))
2929
2930(defmacro with-accessors (slot-entries instance-form &body body)
2931  "Create a lexical environment in which the slots specified by slot-entry
2932are lexically available through their accessors as if they were variables.
2933The appropriate accessors are invoked to access the slots specified by
2934slot-entry. Both setf and setq can be used to set the value of the slot."
2935  (let ((instance (gensym)) var reader bindings)
2936    (dolist (slot-entry slot-entries)
2937      (cond ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2938                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2939             (setq var (car slot-entry) reader (cadr slot-entry)))
2940            (t (signal-program-error "Malformed slot-entry: ~a to with-accessors.~@
2941                                     Should be a list of two symbols."
2942                                     slot-entry)))
2943      (push `(,var (,reader ,instance)) bindings))
2944    `(let ((,instance ,instance-form))
2945       ,@(if bindings 
2946             (list `(declare (ignorable ,instance)))
2947             (list `(declare (ignore ,instance))))
2948       (symbol-macrolet ,(nreverse bindings)
2949         ,@body))))
2950
2951; I wanted to call this ":method"
2952(defmacro reference-method (gf &rest qualifiers-and-specializers)
2953  (let ((qualifiers (butlast qualifiers-and-specializers))
2954        (specializers (car (last qualifiers-and-specializers))))
2955    (if (null specializers) (report-bad-arg qualifiers-and-specializers '(not null)))
2956    `(find-method #',gf ',qualifiers (mapcar #'find-specializer ',specializers))))
2957
2958(defmacro time (form)
2959  "Execute FORM and print timing information on *TRACE-OUTPUT*."
2960  `(report-time ',form #'(lambda () (progn ,form))))
2961
2962(defmacro with-error-reentry-detection (&body body)
2963  (let ((thunk (gensym)))
2964    `(let ((,thunk #'(lambda () ,@body)))
2965       (declare (dynamic-extent ,thunk))
2966       (funcall-with-error-reentry-detection ,thunk))))
2967
2968(defmacro without-duplicate-definition-warnings (&body body)
2969  `(compiler-let ((*compiler-warn-on-duplicate-definitions* nil))
2970     ,@body))
2971
2972
2973#+ppc-target
2974(defmacro scan-for-instr (mask opcode fn pc-index &optional (tries *trap-lookup-tries*))
2975  `(%scan-for-instr ,mask ,opcode ,fn ,pc-index ,tries))
2976
2977
2978(declare-arch-specific-macro codevec-header-p)
2979
2980#+ppc-target
2981(defmacro match-instr (instr mask bits-to-match)
2982  `(eql (logand ,instr ,mask) ,bits-to-match))
2983
2984(defmacro with-xp-stack-frames ((xp trap-function &optional stack-frame) &body body)
2985  (let ((thunk (gensym))
2986        (sf (or stack-frame (gensym))))
2987    `(let ((,thunk #'(lambda (&optional ,sf)
2988                       ,@(unless stack-frame `((declare (ignore ,sf))))
2989                       ,@body)))
2990       (declare (dynamic-extent ,thunk))
2991       (funcall-with-xp-stack-frames ,xp ,trap-function ,thunk))))
2992
2993(defmacro signal-eof-error (stream)
2994  `(error 'end-of-file :stream ,stream))
2995
2996(defmacro check-eof (valform stream eof-error-p eof-value)
2997  (let* ((val (gensym)))
2998    `(let ((,val ,valform))
2999      (if (eq ,val :eof)
3000        (if ,eof-error-p
3001          (signal-eof-error ,stream)
3002          ,eof-value)
3003        ,val))))
3004
3005(defmacro designated-input-stream (input-stream)
3006  `(if ,input-stream
3007    (if (eq t ,input-stream)
3008      *terminal-io*
3009      ,input-stream)
3010    *standard-input*))
3011
3012(defmacro pref (pointer accessor)
3013  "Reference an instance of a foreign type (or a component of a foreign
3014type) accessible via ptr.
3015
3016Expand into code which references the indicated scalar type or component,
3017or returns a pointer to a composite type."
3018  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
3019    (destructuring-bind (type-name &rest accessors) (decompose-record-accessor accessor)
3020      (%foreign-access-form pointer (%foreign-type-or-record type-name) 0 accessors))))
3021
3022(defmacro paref (pointer type-name index)
3023  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
3024    (%foreign-array-access-form  pointer (%foreign-type-or-record type-name) index)))
3025
3026(defmacro rref (pointer accessor &key (storage :pointer storage-p))
3027  (when storage-p
3028    (warn "Use of :storage option ignored: ~a" storage))
3029  `(pref ,pointer ,accessor))
3030
3031(defmacro rlet (spec &body body)
3032  "Execute body in an environment in which each var is bound to a MACPTR
3033encapsulating the address of a stack-allocated foreign memory block,
3034allocated and initialized from typespec and initforms as per make-record.
3035Return whatever value(s) body returns."
3036  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
3037    `(%stack-block ,(rlet-sizes spec)
3038      ,@(rlet-inits spec)
3039      ,@body)))
3040
3041(defmacro rletz (spec &body body)
3042  "Execute body in an environment in which each var is bound to a MACPTR
3043encapuslating the address of a stack-allocated foreign memory block,
3044allocated and initialized from typespec and initforms as per make-record.
3045Return whatever value(s) body returns.
3046
3047Unlike rlet, record fields that aren't explicitly initialized are set
3048to binary 0."
3049  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
3050    `(%stack-block ,(rlet-sizes spec t)
3051      ,@(rlet-inits spec)
3052      ,@body)))
3053
3054(defun rlet-sizes (inits &optional clear-p &aux result)
3055  (dolist (item inits (nreverse result))
3056    (push `(,(car item)
3057            ,(%foreign-type-or-record-size (cadr item) :bytes)
3058            ,@(if clear-p '(:clear t)))
3059          result)))
3060
3061(defun rlet-inits (inits &aux result)
3062  (dolist (item inits result)
3063    (let* ((name (car item))
3064           (record-name (cadr item))
3065           (inits (cddr item))
3066           (ftype (%foreign-type-or-record record-name))
3067           (ordinal (foreign-type-ordinal ftype))
3068           (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
3069                           ordinal
3070                           `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name))))))
3071      (when (eq *host-backend* *target-backend*)
3072        (setq result (nconc result `((%set-macptr-type ,name ,ordinal-form)))))
3073      (if (typep ftype 'foreign-record-type)
3074        (setq result
3075              (nconc result (%foreign-record-field-forms name ftype record-name inits)))
3076        (progn
3077          (when inits
3078            (if (and ftype (null (cdr inits)))
3079              (setq result
3080                    (nconc result
3081                           `((setf ,(%foreign-access-form name ftype 0 nil)
3082                              ,(car inits)))))
3083              (signal-program-error "Unexpected or malformed initialization forms: ~s in field type: ~s"
3084                                    inits record-name))))))))
3085
3086(defun %foreign-record-field-forms (ptr record-type record-name inits)
3087  (unless (evenp (length inits))
3088    (signal-program-error "Unexpected or malformed initialization forms: ~s in field type: ~s"
3089                          inits record-name))
3090  (let* ((result ()))
3091    (do* ()
3092         ((null inits)
3093          `((progn
3094              ;(%assert-macptr-ftype ,ptr ,record-type)
3095              ,@(nreverse result))))
3096      (let* ((accessor (decompose-record-accessor (pop inits)))
3097             (valform (pop inits)))
3098        (push `(setf ,(%foreign-access-form ptr record-type 0  accessor) ,valform)
3099              result)))))
3100 
3101(defmacro get-field-offset (accessor)
3102  (destructuring-bind (type-name field-name) (decompose-record-accessor accessor)
3103    (let* ((record-type (require-type (%foreign-type-or-record type-name) 'foreign-record-type))
3104           (field (%find-foreign-record-type-field record-type field-name))
3105           (bit-offset (foreign-record-field-offset field)))
3106      `(values ,(floor bit-offset 8) ,(foreign-record-field-type field) ,bit-offset))))
3107
3108(defmacro record-length (recname)
3109  (%foreign-type-or-record-size recname :bytes))
3110
3111(defun make-record-form (record-name allocator &rest initforms)
3112  (let* ((ftype (%foreign-type-or-record record-name))
3113         (ordinal (foreign-type-ordinal ftype))
3114         (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
3115                         ordinal
3116                         `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name)))))
3117         (bits (ensure-foreign-type-bits ftype))
3118         (bytes (if bits
3119                  (ceiling bits 8)
3120                  (signal-program-error "Unknown size for foreign type ~S."
3121                                        (unparse-foreign-type ftype))))
3122         (p (gensym))
3123         (memset (read-from-string "#_memset")))   
3124    `(let* ((,p (,allocator ,bytes)))
3125      ,@(when (eq *host-backend* *target-backend*)
3126              `((%set-macptr-type ,p ,ordinal-form)))
3127      (,memset ,p 0 ,bytes)
3128      ,@(%foreign-record-field-forms p ftype record-name initforms)
3129      ,p)))
3130 
3131(defmacro make-record (record-name &rest initforms)
3132  "Expand into code which allocates and initalizes an instance of the type
3133denoted by typespec, on the foreign heap. The record is allocated using the
3134C function malloc, and the user of make-record must explicitly call the C
3135function free to deallocate the record, when it is no longer needed."
3136  (apply 'make-record-form record-name 'malloc initforms))
3137
3138(defmacro make-gcable-record (record-name &rest initforms)
3139  "Like MAKE-RECORD, only advises the GC that the foreign memory can
3140   be deallocated if the returned pointer becomes garbage."
3141  (apply 'make-record-form record-name '%new-gcable-ptr initforms))
3142
3143(defmacro copy-record (type source dest)
3144  (let* ((size (* (%foreign-type-or-record-size type :words) #+64-bit-target 1 #+32-bit-target 2))
3145         (src (gensym "SRC"))
3146         (dst (gensym "DST"))
3147         (accessor #+64-bit-target '%get-unsigned-long #+32-bit-target '%get-unsigned-word)
3148         (i (gensym "I"))
3149         (j (gensym "J")))
3150    `(with-macptrs ((,src ,source)
3151                    (,dst ,dest))
3152      (do* ((,i 0 (+ ,i #+64-bit-target 4 #+32-bit-target 2))
3153            (,j 0 (+ ,j 1)))
3154           ((= ,j ,size))
3155        (declare (fixnum ,i))
3156        (setf (,accessor ,dst ,i) (,accessor ,src ,i))))))
3157
3158(defmacro assert-pointer-type (pointer type)
3159  "Assert that the pointer points to an instance of the specified foreign type.
3160Return the pointer."
3161  (let* ((ptr (gensym)))
3162    `(let* ((,ptr ,pointer))
3163      (%set-macptr-type ,ptr (foreign-type-ordinal (load-time-value (parse-foreign-type ',type))))
3164      ,ptr)))
3165
3166   
3167
3168(defmacro with-terminal-input (&body body)
3169  "Execute body in an environment with exclusive read access to the terminal."
3170  (let* ((got-it (gensym)))
3171    `(let* ((,got-it (%request-terminal-input)))
3172      (unwind-protect
3173           (progn ,@body)
3174        (%restore-terminal-input ,got-it)))))
3175
3176
3177(defmacro with-process-whostate ((whostate) &body body)
3178  `(let* ((*whostate* ,whostate))
3179    ,@body))
3180
3181
3182
3183
3184
3185(defmacro with-read-lock ((lock) &body body)
3186  "Wait until a given lock is available for read-only access, then evaluate
3187its body with the lock held."
3188  (let* ((p (gensym)))
3189    `(with-lock-context
3190      (let* ((,p ,lock))
3191        (unwind-protect
3192             (progn
3193               (read-lock-rwlock ,p)
3194               ,@body)
3195          (unlock-rwlock ,p))))))
3196
3197
3198(defmacro with-write-lock ((lock) &body body)
3199  "Wait until the given lock is available for write access, then execute
3200its body with the lock held."
3201  (let* ((p (gensym)))
3202    `(with-lock-context
3203      (let* ((,p ,lock))
3204      (unwind-protect
3205           (progn
3206             (write-lock-rwlock ,p)
3207             ,@body)
3208        (unlock-rwlock ,p))))))
3209
3210
3211
3212(defmacro without-gcing (&body body)
3213  `(unwind-protect
3214    (progn
3215      (%lock-gc-lock)
3216      ,@body)
3217    (%unlock-gc-lock)))
3218
3219(defmacro with-deferred-gc (&body body)
3220  "Execute BODY without responding to the signal used to suspend
3221threads for GC.  BODY must be very careful not to do anything which
3222could cause an exception (note that attempting to allocate lisp memory
3223may cause an exception.)"
3224  `(let* ((*interrupt-level* -2))
3225    ,@body))
3226
3227(defmacro allowing-deferred-gc (&body body)
3228  "Within the extent of a surrounding WITH-DEFERRED-GC, allow GC."
3229  `(let* ((*interrupt-level* -1))
3230    (%check-deferred-gc)
3231    ,@body))
3232
3233(defmacro defer-gc ()
3234  `(setq *interrupt-level* -2))
3235
3236
3237(defmacro with-pointer-to-ivector ((ptr ivector) &body body)
3238  "Executes BODY with PTR bound to a pointer to the first byte of data
3239in IVECTOR.  The GC is disabled during execution of BODY; PTR has
3240has dynamic-extent (and the address it references may become invalid
3241after the BODY exits.)  IVECTOR should be a (SIMPLE-ARRAY (*)) whose
3242element-type is numeric."
3243  (let* ((v (gensym)))
3244    `(let* ((,v ,ivector))
3245       (unless (typep ,v 'ivector) (report-bad-arg ,v 'ivector))
3246       (without-gcing
3247         (with-macptrs ((,ptr))
3248           (%vect-data-to-macptr ,v ,ptr)
3249           ,@body)))))
3250     
3251
3252
3253(defmacro with-other-threads-suspended (&body body)
3254  `(unwind-protect
3255    (progn
3256      (%suspend-other-threads)
3257      ,@body)
3258    (%resume-other-threads)))
3259
3260(defmacro with-package-read-lock ((p) &body body)
3261  `(with-read-lock ((pkg.lock ,p)) ,@body))
3262
3263(defmacro with-package-write-lock ((p) &body body)
3264  `(with-write-lock ((pkg.lock ,p)) ,@body))
3265
3266(defmacro with-package-lock ((p) &body body)
3267  `(with-package-write-lock (,p) ,@body))
3268
3269;;; Lock %all-packages-lock%, for shared read access to %all-packages%
3270
3271(defmacro with-package-list-read-lock (&body body)
3272  `(with-read-lock (%all-packages-lock%) ,@body))
3273
3274;;; Lock %all-packages-lock%, to allow modification to %all-packages%
3275(defmacro with-package-list-write-lock (&body body)
3276  `(with-write-lock (%all-packages-lock%) ,@body))
3277
3278(defmacro atomic-incf-decf (place delta &environment env)
3279  (setq place (macroexpand place env))
3280  (if (consp place)
3281    (let* ((sym (car place))
3282           (struct-transform (or (environment-structref-info sym env)
3283                                 (gethash sym %structure-refs%))))
3284      (if struct-transform
3285        (setq place (defstruct-ref-transform struct-transform (cdr place) env)
3286              sym (car place)))
3287      (ecase sym
3288        (the `(the ,(cadr place) (atomic-incf-decf ,(caddr place) ,delta)))
3289         ;; Needed so can handle %svref (which macroexpands into a LET*)
3290         ((let let*) (multiple-value-bind (body decls) (parse-body (cddr place) env t)
3291                       (unless (eql (length body) 1)
3292                         (error "~S is not a valid atomic-incf/decf place" place))
3293                       `(,sym ,(cadr place) ,@decls (atomic-incf-decf ,@body ,delta))))
3294         ;; Ditto
3295         (locally (multiple-value-bind (body decls) (parse-body (cdr place) env t)
3296                    (unless (eql (length body) 1)
3297                      (error "~S is not a valid atomic-incf/decf place" place))
3298                    `(,sym ,@decls (atomic-incf-decf ,@body ,delta))))
3299        (car `(%atomic-incf-car ,(cadr place) ,delta))
3300        (cdr `(%atomic-incf-cdr ,(cadr place) ,delta))
3301        (svref `(%atomic-incf-gvector ,@(cdr place) ,delta))))
3302    (if (and (symbolp place) (eq :special (variable-information place env)))
3303      (let* ((base (gensym))
3304             (offset (gensym)))
3305        `(multiple-value-bind (,base ,offset)
3306          (%symbol-binding-address ',place)
3307          (%atomic-incf-node ,delta ,base ,offset)))
3308      (signal-program-error "~S is not a special variable"  place))))
3309   
3310(defmacro atomic-incf (place)
3311  `(atomic-incf-decf ,place 1))
3312
3313(defmacro atomic-decf (place)
3314  `(atomic-incf-decf ,place -1))
3315
3316; Some of these macros were stolen from CMUCL.  Sort of ...
3317
3318(defmacro iterate (name binds &body body)
3319  "Iterate Name ({(Var Initial-Value)}*) Declaration* Form*
3320  This is syntactic sugar for Labels.  It creates a local function Name with
3321  the specified Vars as its arguments and the Declarations and Forms as its
3322  body.  This function is then called with the Initial-Values, and the result
3323  of the call is return from the macro."
3324  (dolist (x binds)
3325    (unless (and (listp x)
3326                 (= (length x) 2))
3327      (signal-program-error "Malformed iterate variable spec: ~S." x)))
3328
3329  `(labels ((,name ,(mapcar #'first binds) ,@body))
3330     (,name ,@(mapcar #'second binds))))
3331
3332;;;; The Collect macro:
3333
3334;;; Collect-Normal-Expander  --  Internal
3335;;;
3336;;;    This function does the real work of macroexpansion for normal collection
3337;;; macros.  N-Value is the name of the variable which holds the current
3338;;; value.  Fun is the function which does collection.  Forms is the list of
3339;;; forms whose values we are supposed to collect.
3340;;;
3341(eval-when (:compile-toplevel :load-toplevel :execute)
3342
3343
3344(defun collect-normal-expander (n-value fun forms)
3345  `(progn
3346     ,@(mapcar #'(lambda (form) `(setq ,n-value (,fun ,form ,n-value))) forms)
3347     ,n-value))
3348
3349
3350)
3351
3352(defmacro once-only (specs &body body)
3353  "Once-Only ({(Var Value-Expression)}*) Form*
3354  Create a Let* which evaluates each Value-Expression, binding a temporary
3355  variable to the result, and wrapping the Let* around the result of the
3356  evaluation of Body.  Within the body, each Var is bound to the corresponding
3357  temporary variable."
3358  (iterate frob
3359           ((specs specs)
3360            (body body))
3361    (if (null specs)
3362      `(progn ,@body)
3363      (let ((spec (first specs)))
3364        (when (/= (length spec) 2)
3365          (signal-program-error "Malformed ~s binding spec: ~S." 'once-only spec))
3366        (let ((name (first spec))
3367              (exp-temp (gensym)))
3368          `(let ((,exp-temp ,(second spec))
3369                 (,name (gensym)))
3370             `(let ((,,name ,,exp-temp))
3371                ,,(frob (rest specs) body))))))))
3372
3373(eval-when (:compile-toplevel :load-toplevel :execute)
3374(defun form-symbol (first &rest others)
3375  (intern (apply #'concatenate 'simple-base-string (string first) (mapcar #'string others))))
3376)
3377
3378
3379;;; Collect-List-Expander  --  Internal
3380;;;
3381;;;    This function deals with the list collection case.  N-Tail is the pointer
3382;;; to the current tail of the list, which is NIL if the list is empty.
3383;;;
3384(defun collect-list-expander (n-value n-tail forms)
3385  (let ((n-res (gensym)))
3386    `(progn
3387       ,@(mapcar #'(lambda (form)
3388                     `(let ((,n-res (cons ,form nil)))
3389                        (cond (,n-tail
3390                               (setf (cdr ,n-tail) ,n-res)
3391                               (setq ,n-tail ,n-res))
3392                              (t
3393                               (setq ,n-tail ,n-res  ,n-value ,n-res)))))
3394                 forms)
3395       ,n-value)))
3396
3397;;;
3398;;;    The ultimate collection macro...
3399;;;
3400
3401(defmacro collect (collections &body body)
3402  "Collect ({(Name [Initial-Value] [Function])}*) {Form}*
3403  Collect some values somehow.  Each of the collections specifies a bunch of
3404  things which collected during the evaluation of the body of the form.  The
3405  name of the collection is used to define a local macro, a la MACROLET.
3406  Within the body, this macro will evaluate each of its arguments and collect
3407  the result, returning the current value after the collection is done.  The
3408  body is evaluated as a PROGN; to get the final values when you are done, just
3409  call the collection macro with no arguments.
3410
3411  Initial-Value is the value that the collection starts out with, which
3412  defaults to NIL.  Function is the function which does the collection.  It is
3413  a function which will accept two arguments: the value to be collected and the
3414  current collection.  The result of the function is made the new value for the
3415  collection.  As a totally magical special-case, the Function may be Collect,
3416  which tells us to build a list in forward order; this is the default.  If an
3417  Initial-Value is supplied for Collect, the stuff will be rplacd'd onto the
3418  end.  Note that Function may be anything that can appear in the functional
3419  position, including macros and lambdas."
3420 
3421 
3422  (let ((macros ())
3423        (binds ()))
3424    (dolist (spec collections)
3425      (unless (<= 1 (length spec) 3)
3426        (signal-program-error "Malformed collection specifier: ~S." spec))
3427      (let ((n-value (gensym))
3428            (name (first spec))
3429            (default (second spec))
3430            (kind (or (third spec) 'collect)))
3431       
3432        (push `(,n-value ,default) binds)
3433        (if (eq kind 'collect)
3434          (let ((n-tail (gensym)))
3435            (if default
3436              (push `(,n-tail (last ,n-value)) binds)
3437              (push n-tail binds))
3438            (push `(,name (&rest args)
3439                          (collect-list-expander ',n-value ',n-tail args))
3440                  macros))
3441          (push `(,name (&rest args)
3442                        (collect-normal-expander ',n-value ',kind args))
3443                macros))))
3444    `(macrolet ,macros (let* ,(nreverse binds) (declare (ignorable ,@binds)) ,@body))))
3445
3446
3447;;; DEFENUM -- Internal Interface.
3448;;;
3449(defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
3450                   &rest identifiers)
3451  (let ((results nil)
3452        (index 0)
3453        (start (eval start))
3454        (step (eval step)))
3455    (dolist (id identifiers)
3456      (multiple-value-bind
3457        (root docs)
3458        (if (consp id)
3459          (values (car id) (cdr id))
3460          (values id nil))
3461        (push `(defconstant ,(intern (concatenate 'simple-base-string
3462                                                  (string prefix)
3463                                                  (string root)
3464                                                  (string suffix)))
3465                 ,(+ start (* step index))
3466                 ,@docs)
3467              results))
3468      (incf index))
3469    `(eval-when (:compile-toplevel :load-toplevel :execute)
3470       ,@(nreverse results))))
3471
3472
3473;;; This does something like special binding, but the "bindings" established
3474;;; aren't thread-specific.
3475
3476(defmacro let-globally ((&rest vars) &body body &environment env)
3477  (multiple-value-bind (body decls) (parse-body body env)
3478    (let* ((initforms nil)
3479           (psetform nil)
3480           (specvars nil)
3481           (restoreform nil))
3482      (flet ((pair-name-value (p)
3483               (if (atom p)
3484                 (values (require-global-symbol p env) nil)
3485                 (if (and (consp (%cdr p)) (null (%cddr p)))
3486                   (values (require-global-symbol (%car p) env) (%cadr p))
3487                   (signal-program-error "Invalid variable initialization form : ~s")))))
3488        (declare (inline pair-name-value))
3489        (dolist (v vars)
3490          (let* ((oldval (gensym))
3491                 (newval (gensym)))
3492            (multiple-value-bind (var valueform) (pair-name-value v)
3493              (push var specvars)
3494              (push var restoreform)
3495              (push oldval restoreform)
3496              (push `(,oldval (uvref (symptr->symvector ',var) #.target::symbol.vcell-cell)) initforms)
3497              (push `(,newval ,valueform) initforms)
3498              (push var psetform)
3499              (push newval psetform))))
3500        `(let ,(nreverse initforms)
3501           ,@decls
3502           (locally (declare (special ,@(nreverse specvars)))
3503             (unwind-protect
3504               (progn (psetq ,@(nreverse psetform)) ,@body)
3505               (psetq ,@(nreverse restoreform)))))))))
3506;;; From CLX.
3507
3508;;; The good news is that this uses an interlocked load/store sequence
3509;;; and is fairly efficient.
3510;;; The bad news is that it only handles a few types of "place" forms.
3511;;; The good news is that CLX only uses a few types of "place" forms.
3512
3513(defmacro conditional-store (place old-value new-value &environment env)
3514  (setq place (macroexpand place env))
3515  (if (atom place)
3516    ;; CLX uses special variables' value cells as place forms.
3517    (if (and (symbolp place)
3518             (eq :special (ccl::variable-information place env)))
3519      (let* ((base (gensym))
3520             (offset (gensym)))
3521        `(multiple-value-bind (,base ,offset)
3522          (ccl::%symbol-binding-address ',place)
3523          (ccl::%store-node-conditional ,offset ,base ,old-value ,new-value)))
3524      (signal-program-error "~s is not a special variable ." place))
3525    (let* ((sym (car place))
3526           (struct-transform (or (ccl::environment-structref-info sym env)
3527                                 (gethash sym ccl::%structure-refs%))))
3528      (if struct-transform
3529        (setq place (defstruct-ref-transform struct-transform (cdr place) env)
3530              sym (car place)))
3531      (if (member  sym '(svref ccl::%svref ccl::struct-ref))
3532        (let* ((v (gensym)))
3533          `(let* ((,v ,(cadr place)))
3534            (ccl::store-gvector-conditional ,(caddr place)
3535             ,v ,old-value ,new-value)))
3536        (signal-program-error "Don't know how to do conditional store to ~s" place)))))
3537
3538(defmacro step (form)
3539  "The form is evaluated with single stepping enabled. Function calls
3540outside the lexical scope of the form can be stepped into only if the
3541functions in question have been compiled with sufficient DEBUG policy
3542to be at least partially steppable."
3543  form)
3544
3545(defmacro target-arch-case (&rest clauses)
3546  `(case (backend-target-arch-name *target-backend*)
3547    ,@clauses))
3548
3549(defmacro target-os-case (&rest clauses)
3550  `(ecase (backend-target-os *target-backend*)
3551    ,@clauses))
3552
3553(defmacro target-word-size-case (&rest clauses)
3554  `(ecase (arch::target-nbits-in-word (backend-target-arch *target-backend*))
3555    ,@clauses))
3556
3557(defmacro %get-natural (&body body)
3558  "A free copy of the next OpenMCL release to anyone who remembers Flakey Foont"
3559  (target-word-size-case
3560   (32 `(%get-unsigned-long ,@body))
3561   (64 `(%%get-unsigned-longlong ,@body))))
3562
3563(defmacro %get-signed-natural (&body body)
3564  "And that's my final offer."
3565  (target-word-size-case
3566   (32 `(%get-signed-long ,@body))
3567   (64 `(%%get-signed-longlong ,@body))))
3568
3569(declare-arch-specific-macro %target-kernel-global)
3570
3571;;; This behaves like a function, but looks up the kernel global
3572;;; at compile time if possible. Probably should be done as a function
3573;;; and a compiler macro, but we can't define compiler macros yet,
3574;;; and I don't want to add it to "ccl:compiler;optimizers.lisp"
3575(declare-arch-specific-macro %get-kernel-global)
3576
3577(declare-arch-specific-macro %get-kernel-global-ptr)
3578
3579(declare-arch-specific-macro area-code)
3580
3581(declare-arch-specific-macro nth-immediate)
3582
3583(declare-arch-specific-macro set-nth-immediate)
3584
3585(defsetf nth-immediate set-nth-immediate)
3586
3587(defmacro do-consing-areas ((area) &body body)
3588  (let ((code (gensym)))
3589  `(do-gc-areas (,area)
3590     (let ((,code (%fixnum-ref ,area  (area-code))))
3591       (when (or (eql ,code area-readonly)
3592                 (eql ,code area-watched)
3593                 (eql ,code area-managed-static)
3594                 (eql ,code area-static)
3595                 (eql ,code area-dynamic))
3596         ,@body)))))
3597
3598(declare-arch-specific-macro area-succ)
3599
3600
3601(defmacro do-gc-areas ((area) &body body)
3602  (let ((initial-area (gensym)))
3603    `(let* ((,initial-area (%get-kernel-global 'all-areas))
3604            (,area ,initial-area))
3605       (declare (fixnum ,initial-area ,area))
3606       (loop
3607         (setq ,area (%fixnum-ref ,area (area-succ)))
3608         (when (eql ,area ,initial-area)
3609           (return))
3610         ,@body))))
3611
3612(defmacro with-ioblock-input-lock-grabbed ((ioblock) &body body)
3613  (let* ((i (gensym)))
3614    `(let* ((,i ,ioblock))
3615      (with-lock-grabbed ((ioblock-inbuf-lock ,i))
3616        (cond ((ioblock-device ,i)
3617               ,@body)
3618              (t (stream-is-closed (ioblock-stream ,i))))))))
3619
3620(defmacro with-ioblock-output-lock-grabbed ((ioblock) &body body)
3621  (let* ((i (gensym)))
3622    `(let* ((,i ,ioblock))
3623      (with-lock-grabbed ((ioblock-outbuf-lock ,i))
3624        (cond ((ioblock-device ,i)
3625               ,@body)
3626              (t (stream-is-closed (ioblock-stream ,i))))))))
3627 
3628
3629(defmacro with-stream-ioblock-input ((ioblock stream &key
3630                                             speedy)
3631                                  &body body)
3632  `(let ((,ioblock (stream-ioblock ,stream t)))
3633     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3634     (with-ioblock-input-locked (,ioblock) ,@body)))
3635
3636(defmacro with-stream-ioblock-output ((ioblock stream &key
3637                                             speedy)
3638                                  &body body)
3639  `(let ((,ioblock (stream-ioblock ,stream t)))
3640     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3641     (with-ioblock-output-locked (,ioblock) ,@body)))
3642
3643(defmacro with-stream-ioblock-output-maybe ((ioblock stream &key
3644                                                     speedy)
3645                                            &body body)
3646  `(let ((,ioblock (stream-ioblock ,stream t)))
3647    ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3648    (with-ioblock-output-locked-maybe (,ioblock) ,@body)))
3649
3650(defmacro with-ioblock-input-locked ((ioblock) &body body)
3651  (let* ((lock (gensym)))
3652    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3653                                  (ioblock-inbuf-lock ,ioblock))))
3654      (if ,lock
3655        (with-lock-grabbed (,lock)
3656          (cond ((ioblock-device ,ioblock)
3657                 ,@body)
3658                (t (stream-is-closed (ioblock-stream ,ioblock)))))
3659        (progn
3660          (check-ioblock-owner ,ioblock)
3661          ,@body)))))
3662
3663(defmacro with-ioblock-output-locked ((ioblock) &body body)
3664  (let* ((lock (gensym)))
3665    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3666                                  (ioblock-outbuf-lock ,ioblock))))
3667      (if ,lock
3668        (with-lock-grabbed (,lock)
3669          (cond ((ioblock-device ,ioblock)
3670                 ,@body)
3671                (t (stream-is-closed (ioblock-stream ,ioblock)))))
3672        (progn
3673          (check-ioblock-owner ,ioblock)
3674          ,@body)))))
3675
3676
3677
3678(defmacro with-ioblock-output-locked-maybe ((ioblock) &body body)
3679  (let* ((lock (gensym)))
3680    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3681                     (ioblock-outbuf-lock ,ioblock))))
3682      (if ,lock
3683        (with-lock-grabbed (,lock)
3684          (cond ((ioblock-device ,ioblock)
3685                 ,@body)
3686                (t (stream-is-closed (ioblock-stream ,ioblock)))))
3687        (progn
3688          (check-ioblock-owner ,ioblock)
3689          ,@body)))))
3690
3691;;; Use this when it's possible that the fd might be in
3692;;; a non-blocking state.  Body must return a negative of
3693;;; the os error number on failure.
3694;;; The use of READ-FROM-STRING below is certainly ugly, but macros
3695;;; that expand into reader-macros don't generally trigger the reader-macro's
3696;;; side-effects.  (Besides, the reader-macro might return a different
3697;;; value when the macro function is expanded than it did when the macro
3698;;; function was defined; this can happen during cross-compilation.)
3699(defmacro with-eagain (fd direction &body body)
3700  (let* ((res (gensym))
3701         (eagain (symbol-value (read-from-string "#$EAGAIN"))))
3702   `(loop
3703      (let ((,res (progn ,@body)))
3704        (if (eql ,res (- ,eagain))
3705          (progn
3706            (setq ,res
3707                  (,(ecase direction
3708                           (:input 'process-input-would-block)
3709                           (:output 'process-output-would-block))
3710                    ,fd))
3711            (unless (eq ,res t) (return ,res)))
3712          (return ,res))))))
3713
3714(defmacro ignoring-eintr (&body body)
3715  (let* ((res (gensym))
3716         (eintr (symbol-value (read-from-string "#$EINTR"))))
3717    `(loop
3718       (let* ((,res (progn ,@body)))
3719         (unless (eql ,res (- ,eintr))
3720           (return ,res))))))
3721
3722(defmacro ff-call-ignoring-eintr (&body body)
3723  (let* ((res (gensym))
3724         (eintr (symbol-value (read-from-string "#$EINTR"))))
3725    `(loop
3726       (let* ((,res (progn ,@body)))
3727         (declare (fixnum ,res))
3728         (when (< ,res 0)
3729           (setq ,res (%get-errno)))
3730         (unless (eql ,res (- ,eintr))
3731           (return ,res))))))
3732
3733(defmacro basic-stream-ioblock (s)
3734  `(or (basic-stream.state ,s)
3735    (stream-is-closed ,s)))
3736
3737(defsetf interrupt-level set-interrupt-level)
3738
3739(defmacro %swap-u16 (val)
3740  (let* ((arg (gensym)))
3741    `(let* ((,arg ,val))
3742      (declare (type (unsigned-byte 16) ,arg))
3743      (logand #xffff (the fixnum (logior (the fixnum (ash ,arg -8))
3744                                         (the fixnum (ash ,arg 8))))))))
3745
3746(defmacro %swap-u32 (val)
3747  (let* ((arg (gensym)))
3748    `(let ((,arg ,val))
3749      (declare (type (unsigned-byte 32) ,arg))
3750      (the (unsigned-byte 32) (logior (the (unsigned-byte 32)
3751                                        (ash (logand #xff ,arg) 24))
3752                                      (the (unsigned-byte 24)
3753                                        (logior
3754                                         (the (unsigned-byte 24) (ash (logand #xff00 ,arg) 8))
3755                                         (the (unsigned-byte 16)
3756                                           (logior
3757                                            (the (unsigned-byte 16) (ash (logand #xff0000 ,arg) -8))
3758                                            (the (unsigned-byte 8) (ash ,arg -24)))))))))))
3759   
3760
3761(defmacro multiple-value-bind (varlist values-form &body body &environment env)
3762  (multiple-value-bind (body decls)
3763                       (parse-body body env)
3764    (let ((ignore (make-symbol "IGNORE")))
3765      `(multiple-value-call #'(lambda (&optional ,@varlist &rest ,ignore)
3766                                (declare (ignore ,ignore))
3767                                ,@decls
3768                                ,@body)
3769                            ,values-form))))
3770
3771(defmacro multiple-value-setq (vars val)
3772  (if vars
3773    `(values (setf (values ,@(mapcar #'(lambda (s) (require-type s 'symbol)) vars))  ,val))
3774    `(prog1 ,val)))
3775
3776(defmacro nth-value (n form)
3777  "Evaluate FORM and return the Nth value (zero based). This involves no
3778  consing when N is a trivial constant integer."
3779  `(car (nthcdr ,n (multiple-value-list ,form))))
3780
3781
3782
3783(defmacro with-input-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3784  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3785stream-input-timeout set to TIMEOUT."
3786  (let* ((old-input-timeout (gensym))
3787         (stream (gensym)))
3788    `(let* ((,stream ,stream-form)
3789            (,stream-var ,stream)
3790            (,old-input-timeout (stream-input-timeout ,stream)))
3791      (unwind-protect
3792           (progn
3793             (setf (stream-input-timeout ,stream) ,timeout)
3794             ,@body)
3795        (setf (stream-input-timeout ,stream) ,old-input-timeout)))))
3796
3797(defmacro with-output-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3798  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3799stream-output-timeout set to TIMEOUT."
3800  (let* ((old-output-timeout (gensym))
3801         (stream (gensym)))
3802    `(let* ((,stream ,stream-form)
3803            (,stream-var ,stream)
3804            (,old-output-timeout (stream-output-timeout ,stream)))
3805      (unwind-protect
3806           (progn
3807             (setf (stream-output-timeout ,stream) ,timeout)
3808             ,@body)
3809        (setf (stream-output-timeout ,stream) ,old-output-timeout)))))
3810
3811;;; FORM returns a signed integer.  If it's non-negative, return that
3812;;; value, otherwise, return the (negative) errnor value returned by
3813;;; %GET-ERRNO
3814(defmacro int-errno-call (form)
3815  (let* ((value (gensym)))
3816    `(let* ((,value ,form))
3817      (if (< ,value 0)
3818        (%get-errno)
3819        ,value))))
3820
3821(defmacro int-errno-ffcall (entry &rest args)
3822  `(int-errno-call (ff-call ,entry ,@args)))
Note: See TracBrowser for help on using the repository browser.