source: trunk/source/lib/format.lisp @ 16639

Last change on this file since 16639 was 16639, checked in by rme, 5 years ago

Replace scale-exponent with accurate-scaled-exponent, borrowed from
CMUCL.

Closes ticket:536 and ticket:1186.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 109.5 KB
Line 
1;;; -*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;; Functions to implement FORMAT.
19;;;
20
21(in-package "CCL")
22
23;;; Special variables local to FORMAT
24;;; why do these have top-level bindings ????? - seems wrong or at least unnecessary
25
26(defvar *format-control-string* ""
27  "The current FORMAT control string")
28
29(defvar *format-index* 0
30  "The current index into *format-control-string*")
31
32(defvar *format-length* 0
33  "The length of the current FORMAT control string")
34
35(defvar *format-arguments* ()
36  "Arguments to the current call of FORMAT")
37
38(defvar *format-original-arguments* ()
39  "Saved arglist from top-level FORMAT call for ~* and ~@*")
40
41(defvar *format-arguments-variance* nil
42  "Non-NIL only during compile-time scanning of a format string, in which case it is the
43number of additional elements at the front of *format-arguments* that may be already used
44up at runtime.  I.e. the actual *format-arguments* may be anything between *format-arguments*
45and (nthcdr *format-arguments-variance* *format-arguments*)")
46
47(def-standard-initial-binding *format-stream-stack* nil "A stack of string streams for collecting FORMAT output")
48
49(defvar *format-pprint* nil
50  "Has a pprint format directive (~W ~I ~_ ~:T) or logical-block directive been seen?")
51
52(defvar *format-justification-semi* nil
53  "Has a ~<...~:;...~> been seen?")
54
55(defvar *format-colon-rest* nil
56  )
57
58;;; prevent circle checking rest args. Really EVIL when dynamic-extent
59(def-standard-initial-binding *format-top-level* nil)
60
61
62;;; ERRORS
63
64;;; Since errors may occur while an indirect control string is being
65;;; processed, i.e. by ~? or ~{~:}, some sort of backtrace is necessary
66;;; in order to indicate the location in the control string where the
67;;; error was detected.  To this end, errors detected by format are
68;;; signalled by throwing a list of the form ((control-string args))
69;;; to the tag FORMAT-ERROR.  This throw will be caught at each level
70;;; of indirection, and the list of error messages re-thrown with an
71;;; additional message indicating that indirection was present CONSed
72;;; onto it.  Ultimately, the last throw will be caught by the top level
73;;; FORMAT function, which will then signal an error to the Slisp error
74;;; system in such a way that all the errror messages will be displayed
75;;; in reverse order.
76
77(defun format-error (complaint &rest args)
78  (throw 'format-error
79         (list (list "~1{~:}~%~S~%~V@T^" complaint args
80                    *format-control-string* (1+ *format-index*)))))
81
82
83;;; MACROS
84
85;;; This macro establishes the correct environment for processing
86;;; an indirect control string.  CONTROL-STRING is the string to
87;;; process, and FORMS are the forms to do the processing.  They
88;;; invariably will involve a call to SUB-FORMAT.  CONTROL-STRING
89;;; is guaranteed to be evaluated exactly once.
90(eval-when (compile eval #-bccl load)
91
92; does this need to exist?????
93#|| ; put it out of its misery
94(defmacro format-with-control-string (control-string &rest forms)
95  `(let ((string (if (simple-string-p ,control-string)
96                     ,control-string
97                     (coerce ,control-string 'simple-base-string))))
98        (declare (simple-string string))
99        (let ((error (catch 'format-error
100                            (let ((*format-control-string* string)
101                                  (*format-length* (length string))
102                                  (*format-index* 0))
103                                 ,@forms
104                                 nil))))
105         
106             (when error
107                   (throw 'format-error
108                          (cons (list "While processing indirect control string~%~S~%~V@T^"
109                                      *format-control-string*
110                                      (1+ *format-index*))
111                                error))))))
112||#
113(defmacro format-indirect-error (error)
114  `(throw 'format-error
115         (cons (list "While processing indirect control string~%~S~%~V@T^"
116                     *format-control-string*
117                     (1+ *format-index*))
118               ,error)))
119
120
121(defmacro get-a-format-string-stream ()
122  '(or (pop *format-stream-stack*) (make-string-output-stream :element-type 'base-char))) ; ??
123
124;;; This macro rebinds collects output to the standard output stream
125;;; in a string.  For efficiency, we avoid consing a new stream on
126;;; every call.  A stack of string streams is maintained in order to
127;;; guarantee re-entrancy.
128
129(defmacro with-format-string-output (stream-sym &rest forms)
130  `(let ((,stream-sym nil))
131     (unwind-protect
132       (progn
133         (setq ,stream-sym (get-a-format-string-stream))
134         ,@forms
135         (prog1
136           (get-output-stream-string ,stream-sym)
137           (push ,stream-sym *format-stream-stack*)))
138       (when ,stream-sym (file-position ,stream-sym 0)))))
139
140;;; This macro decomposes the argument list returned by PARSE-FORMAT-OPERATION.
141;;; PARMVAR is the list of parameters.  PARMDEFS is a list of lists of the form
142;;; (<var> <default>).  The FORMS are evaluated in an environment where each
143;;; <var> is bound to either the value of the parameter supplied in the
144;;; parameter list, or to its <default> value if the parameter was omitted or
145;;; explicitly defaulted.
146
147(defmacro with-format-parameters (parmvar parmdefs &body  body &environment env)
148  (do ((parmdefs parmdefs (cdr parmdefs))
149       (bindings () (cons `(,(caar parmdefs) (or (if ,parmvar (pop ,parmvar))
150                                                 ,(cadar parmdefs)))
151                          bindings)))
152      ((null parmdefs)
153       (multiple-value-bind (forms decls) (parse-body body env)
154         `(let ,(nreverse bindings)
155            ,@decls
156            (when ,parmvar
157              (format-error "Too many parameters"))
158            ,@forms)))))
159
160
161
162;;; Returns the index of the first occurrence of the specified character
163;;; between indices START (inclusive) and END (exclusive) in the control
164;;; string.
165
166
167(defmacro format-find-char (char start end)
168  `(%str-member  ,char *format-control-string*
169                   ,start ,end))
170
171
172) ;end of eval-when for macros
173
174;;; CONTROL STRING PARSING
175
176;;; The current control string is kept in *format-control-string*.
177;;; The variable *format-index* is the position of the last character
178;;; processed, indexing from zero.  The variable *format-length* is the
179;;; length of the control string, which is one greater than the maximum
180;;; value of *format-index*. 
181
182
183;;; Gets the next character from the current control string.  It is an
184;;; error if there is none.  Leave *format-index* pointing to the
185;;; character returned.
186
187(defun format-nextchar ()
188  (let ((index (%i+ 1 *format-index*)))   
189    (if (%i< (setq *format-index* index) *format-length*)
190      (schar *format-control-string* index)
191      (format-error "Syntax error"))))
192
193
194
195;;; Returns the current character, i.e. the one pointed to by *format-index*.
196
197(defmacro format-peek ()
198  `(schar *format-control-string* *format-index*))
199
200
201
202
203;;; Attempts to parse a parameter, starting at the current index.
204;;; Returns the value of the parameter, or NIL if none is found.
205;;; On exit, *format-index* points to the first character which is
206;;; not a part of the recognized parameter.
207
208(defun format-get-parameter (ch)
209  (case ch
210    (#\# (format-nextchar)
211     (let ((n (or *format-arguments-variance* 0))
212           (len (length *format-arguments*)))
213       (declare (fixnum n len))
214       (if (eql n 0)
215         len
216         `(the (integer ,(- len n) ,len) (length *format-arguments*)))))
217    ((#\V #\v)
218     (prog1 (pop-format-arg) (format-nextchar)))
219    (#\' (prog1 (format-nextchar) (format-nextchar)))
220    (t (cond ((or (eq ch #\-) (eq ch #\+) (digit-char-p ch))
221              (let ((neg-parm (eq ch #\-)))
222                (unless (setq ch (digit-char-p ch))
223                  (unless (setq ch (digit-char-p (format-nextchar)))
224                    (format-error "Illegal parameter")))
225                (do ((number ch (+ ch (* number 10))))
226                    ((not (setq ch (digit-char-p (format-nextchar))))
227                     (if neg-parm (- number) number)))))
228             (t nil)))))
229
230(defun format-skip-parameter (ch) ; only caller is parse-format-operation
231  "Might someday want to add proper format error checking for negative
232      parameters"
233  (let ()
234    (case ch
235      ((#\V #\v #\#)
236       (format-nextchar))
237      (#\' (format-nextchar) (format-nextchar))
238      (#\,)
239      (t (when (or (eq ch #\-) (eq ch #\+)) (format-nextchar))
240         (while (digit-char-p (format-nextchar)))))))
241
242(defun format-no-semi (char &optional colon atsign)
243  (when *format-justification-semi*
244    (format-error "~~~:[~;:~]~:[~;@~]~c illegal in this context" colon atsign char))
245  (setq *format-pprint* t))
246
247;;; Parses a format directive, including flags and parameters.  On entry,
248;;; *format-index* should point to the "~" preceding the command.  On
249;;; exit, *format-index* points to the command character itself.
250;;; Returns the list of parameters, the ":" flag, the "@" flag, and the
251;;; command character as multiple values.  Explicitly defaulted parameters
252;;; appear in the list of parameters as NIL.  Omitted parameters are simply
253;;; not included in the list at all.
254
255(defun parse-format-operation (&optional get-params) ; only caller is format-find-command
256  (let ((ch (format-nextchar)) parms colon atsign)
257    (when (or (digit-char-p ch)
258              ;(%str-member ch ",#Vv'"))
259              (memq ch '(#\- #\, #\# #\V #\v #\')))     
260      (cond (get-params
261             (setq parms (list (format-get-parameter ch)))
262             (until (neq (setq ch (format-peek)) #\,)
263               (setq ch (format-nextchar))
264               (push (format-get-parameter ch) parms)))
265            (t (setq parms t)  ; tell caller there were some so we get correct error msgs
266               (format-skip-parameter ch)
267               (until (neq (setq ch (format-peek)) #\,)
268                 (setq ch (format-nextchar))
269                 (format-skip-parameter ch)))))
270    ; allow either order
271    (case ch
272      (#\: (setq colon t ch (format-nextchar))
273           (when (eq ch #\@)
274             (setq atsign t ch (format-nextchar))))
275      (#\@ (setq atsign t ch (format-nextchar))
276           (when (eq ch #\:)
277             (setq colon t ch (format-nextchar)))))
278    (values (if (consp parms) (nreverse parms) parms)
279            colon
280            atsign
281            ch)))
282
283
284;;; Starting at the current value of *format-index*, finds the first
285;;; occurrence of one of the specified directives. Embedded constructs,
286;;; i.e. those inside ~(~), ~[~], ~{~}, or ~<~>, are ignored.  And error is
287;;; signalled if no satisfactory command is found.  Otherwise, the
288;;; following are returned as multiple values:
289;;;
290;;;     The value of *format-index* at the start of the search
291;;;     The index of the "~" character preceding the command
292;;;     The parameter list of the command
293;;;     The ":" flag
294;;;     The "@" flag
295;;;     The command character
296;;;
297;;; Implementation note:  The present implementation is not particulary
298;;; careful with storage allocation.  It would be a good idea to have
299;;; a separate function for skipping embedded constructs which did not
300;;; bother to cons parameter lists and then throw them away. This issue has been addressed. (akh)
301;;;
302;;; We go to some trouble here to use POSITION for most of the searching.
303;;; God only knows why!!!!
304
305;; and interesting note - the only caller who wants parameters is format-get-segments for
306;; ~< .... ~n:; ...~>
307(defun format-find-command (command-list &optional get-params evil-commands)
308  (let* ((start *format-index*)
309         (length *format-length*)
310         tilde)
311    (loop
312      (setq tilde (format-find-char #\~ *format-index* length))
313      (if (not tilde) (format-error "Expecting one of ~S" command-list))
314      (setq *format-index* tilde)
315      (multiple-value-bind (parms colon atsign command)
316                           (parse-format-operation get-params)
317        (when (memq command command-list)
318          (return (values start tilde parms colon atsign command)))
319        (when (and evil-commands
320                   (or (memq command  '(#\w #\_ #\i #\W #\I))
321                       (and colon (memq command '(#\t #\T)))))
322          (format-error "Illegal in this context"))
323        (case command
324          (#\{ (format-nextchar) (format-find-command '(#\})))
325          (#\( (format-nextchar) (format-find-command '(#\))))
326          (#\[ (format-nextchar) (format-find-command '(#\])))
327          (#\< (format-nextchar) 
328               (multiple-value-bind (prev tilde parms colon atsign cmd)
329                   (format-find-command '(#\>))
330                 (declare (ignore prev tilde parms atsign cmd))
331                 (if (and evil-commands colon)
332                     (format-error "Logical-block directive not allowed inside justification directive"))))
333          ((#\} #\> #\) #\])
334           (format-error "No matching bracket")))))))
335
336(defun format-find-command-no-params (command-list &key (colon t) (atsign t))
337  (multiple-value-bind (prev tilde parms colon-flag atsign-flag command)
338                       (format-find-command command-list)
339    (with-format-parameters parms ()
340      (format-no-flags (and (not colon) colon-flag) (and (not atsign) atsign-flag)))
341    (values prev tilde command colon-flag atsign-flag)))
342
343;;; This is the FORMAT top-level function.
344
345(defun format (stream control-string &rest format-arguments)
346  (declare (dynamic-extent format-arguments))
347  (if (null stream)
348    (with-output-to-string (s)
349                           (apply #'format s control-string format-arguments))
350    (if (stringp stream)
351      (with-output-to-string (s stream)
352                             (apply #'format s control-string format-arguments))
353      (let ((*format-top-level* t))
354        (when (xp-structure-p stream)(setq stream (xp-stream-stream stream))) ; for xp tests only! They call format on a structure
355        (setq stream (if (eq stream t)
356                       *standard-output*
357                       (require-type stream 'stream)))     
358        (if (functionp control-string)
359          (apply control-string stream format-arguments)
360          (let* ((control-string (ensure-simple-string control-string))
361                 (*format-control-string* control-string)
362                 (*format-pprint* nil)
363                 (*format-justification-semi* nil))
364            (declare (type simple-string control-string))
365            (cond
366              ;; Try to avoid pprint overhead in this case.
367              ((not (position #\~ control-string))
368               (write-string control-string stream))
369              ((and (or *print-pretty* *print-circle*)
370                    (not (typep stream 'xp-stream)))
371               (maybe-initiate-xp-printing
372                #'(lambda (s o)
373                    (do-sub-format-1 s o))
374                stream format-arguments))
375              (t 
376               (let ((*format-original-arguments* format-arguments)
377                     (*format-arguments* format-arguments)
378                     (*format-colon-rest* 'error)) ; what should this be??
379                 (do-sub-format stream))))))
380        nil))))
381
382(defun format-to-string (string control-string &rest format-arguments)
383  (declare (dynamic-extent format-arguments))
384  (if string
385    (with-output-to-string (stream string)
386      (apply #'format stream control-string format-arguments))
387    (with-output-to-string (stream)
388      (apply #'format stream control-string format-arguments))))
389
390(defun do-sub-format (stream)
391  (let (errorp)
392    (setq errorp
393          (catch 'format-error
394            (catch 'format-escape 
395              (sub-format stream 0 (length *format-control-string*)))
396            nil))   
397    (when errorp
398      (error "~%~:{~@?~%~}" (nreverse errorp)))))
399
400
401
402;;; This function does the real work of format.  The segment of the control
403;;; string between indiced START (inclusive) and END (exclusive) is processed
404;;; as follows: Text not part of a directive is output without further
405;;; processing.  Directives are parsed along with their parameters and flags,
406;;; and the appropriate handlers invoked with the arguments COLON, ATSIGN, and
407;;; PARMS.
408;;;
409
410;;; POP-FORMAT-ARG also defined in l1-format
411
412; in l1-format
413(def-standard-initial-binding *logical-block-xp* nil)
414
415(without-duplicate-definition-warnings
416 (defun pop-format-arg (&aux (args *format-arguments*) (xp *logical-block-xp*) (av *format-arguments-variance*))
417   (when (and (null args) (null xp))
418     (format-error "Missing argument"))
419   (when xp
420     (if (null av)
421       (when (pprint-pop-check+ args xp)    ; gets us level and length stuff in logical block
422         (throw 'logical-block nil))
423       ;; Could record that might exit here, but nobody cares.
424       #+no (note-format-scan-option *logical-block-options*)))
425   (if (or (null av) (eql av 0))
426     (progn
427       (setq *format-arguments* (cdr args))
428       (%car args))
429     (let ((types (loop for x in args as i from 0 below av
430                    collect (nx-form-type x))))
431       (when (eql av (length args))
432         (setq *format-arguments-variance* (1- av)))
433       (setq *format-arguments* (cdr args))
434       `(the (or ,@types) (car *format-arguments*))))))
435
436; SUB-FORMAT is now defined in L1-format.lisp
437; DEFFORMAT is also defined there.
438
439;;;;;;;;;;;;;;;;;;;;;;;;;;
440;;; pretty-printing stuff
441;;;
442
443(defformat #\W format-write (stream colon atsign)
444  (format-no-semi #\W)
445  (let ((arg (pop-format-arg)))
446    (cond (atsign
447       (let ((*print-level* nil)
448             (*print-length* nil))
449         (if colon
450           (let ((*print-pretty* t))
451             (write-1 arg stream))
452           (write-1 arg stream))))
453      (t (if colon
454           (let ((*print-pretty* t))
455             (write-1 arg stream))
456           (write-1 arg stream))))))
457
458(defformat #\I format-indent (stream colon atsign &rest parms)
459  (declare (dynamic-extent parms))
460  (declare (ignore atsign))
461  (format-no-semi #\I)
462  (with-format-parameters parms ((n 0))
463    (pprint-indent (if colon :current :block) n stream)))
464
465(defformat #\_ format-conditional-newline (stream colon atsign)
466  (format-no-semi #\_)
467  (let ((option
468         (cond (atsign
469                (cond (colon  :mandatory)
470                      (t :miser)))
471               (colon :fill)
472               (t :linear))))
473    (pprint-newline option stream)))
474
475;;; Tabulation  ~T
476
477(defformat #\T format-tab (stream colon atsign &rest parms)
478  (declare (dynamic-extent parms))
479  (when colon
480    (format-no-semi #\T t))
481  (with-format-parameters parms ((colnum 1) (colinc 1))
482    (cond ((or (typep stream 'xp-stream) (xp-structure-p stream))
483           (let ((kind (if colon
484                           (if atsign :section-relative :section)
485                           (if atsign :line-relative :line))))
486             (cond ((xp-structure-p stream)
487                    (pprint-tab+ kind colnum colinc stream))
488                   ((typep stream 'xp-stream)
489                    (pprint-tab+ kind colnum colinc
490                                 (slot-value stream 'xp-structure))))))
491          ((not colon)
492           (pprint-tab-not-pretty stream colnum colinc atsign)))))
493
494(defun pprint-tab-not-pretty (stream colnum colinc &optional atsign)
495  (let* ((position (column stream))
496         (count (if atsign
497                  (if position
498                    (if (zerop colinc)
499                      colnum (+ colnum (mod (- (+ position colnum)) colinc)))
500                    colnum)
501                  (if position
502                    (if (<= colnum position)
503                      (if (zerop colinc)
504                        0 (- colinc (mod (- position colnum) colinc)))
505                      (- colnum position))
506                    2))))
507    (while (> count 0)
508      (write-string "                                                                                "
509                           stream :start 
510                           0 :end (min count 80))
511      (setq count (- count 80)))))
512
513
514;;; ~/ call function
515(defformat #\/ format-call-function (stream colon atsign &rest parms)
516  (let* ((string *format-control-string*)
517         (ipos (1+ *format-index*))
518         (epos (format-find-char #\/ ipos *format-length*)))   
519    ; the spec is DUMB here - it requires that : and :: be treated the same
520    (when (not epos) (format-error "Unmatched ~~/"))
521    (let ((cpos (format-find-char #\: ipos epos))
522          package)
523      (cond (cpos 
524             (setq package (or (find-package (string-upcase (%substr string ipos cpos)))
525                               (format-error "Unknown package")))
526             (when (eql #\: (schar string (%i+ 1 cpos)))
527               (setq cpos (%i+ cpos 1)))
528             (setq ipos (%i+ cpos 1)))
529            (t (setq package (find-package "CL-USER"))))
530      (let ((thing (intern (string-upcase (%substr string ipos epos)) package)))
531        (setq *format-index* epos) ; or 1+ epos?
532        (apply thing stream (pop-format-arg) colon atsign parms)))))
533
534;;; Conditional case conversion  ~( ... ~)
535
536#| coral's old version
537(defformat #\( format-capitalization (stream colon atsign)
538  (format-nextchar)
539  (multiple-value-bind (prev tilde) (format-find-command-no-params '(#\)))
540   (let* (finished
541          (string (with-format-string-output stream
542                    (setq finished (catch 'format-escape (sub-format stream prev tilde) t)))))
543     (write-string
544         (cond ((and atsign colon)
545                (nstring-upcase string))
546               (colon
547                (nstring-capitalize string))
548               (atsign
549                (let ((strlen (length string)))
550                     ;; Capitalize the first word only
551                     (nstring-downcase string)
552                     (do ((i 0 (1+ i)))
553                         ((or (<= strlen i) (alpha-char-p (char string i)))
554                          (setf (char string i) (char-upcase (char string i)))
555                          string))))
556               (t (nstring-downcase string)))
557         stream :start
558         0 :end (length string))
559     (unless finished (throw 'format-escape nil)))))
560
561|#
562
563(defformat #\( format-capitalization (stream colon atsign)
564  (format-nextchar)
565  (multiple-value-bind (prev tilde) (format-find-command-no-params '(#\)))
566    (let (catchp)
567      (cond ((typep stream 'xp-stream)
568             (let ((xp (slot-value stream 'xp-structure)))
569               (push-char-mode xp (cond ((and colon atsign) :UP)
570                                         (colon :CAP1)
571                                         (atsign :CAP0)
572                                         (T :DOWN)))
573               (setq catchp
574                     (catch 'format-escape
575                       (sub-format stream prev tilde)
576                       nil))
577               (pop-char-mode xp)))
578            (t
579             (let* ((string (with-format-string-output stream                     
580                              (setq catchp (catch 'format-escape
581                                             (sub-format stream prev tilde)
582                                             nil)))))
583               (write-string
584                (cond ((and atsign colon)
585                       (nstring-upcase string))
586                      (colon
587                       (nstring-capitalize string))
588                      (atsign
589                       ;; Capitalize the first word only
590                       (nstring-downcase string)
591                       (dotimes (i (length string) string)
592                         (let ((ch (char string i)))
593                           (when (alpha-char-p ch)
594                             (setf (char string i) (char-upcase ch))
595                             (return string)))))
596                      (t (nstring-downcase string)))         
597                stream :start 
598                0 :end (length string)))))
599      (when catchp
600        (throw 'format-escape catchp))
601      )))
602
603;;; Up and Out (Escape)  ~^
604
605(defformat #\^ format-escape (stream colon atsign &optional p1 p2 p3)
606  (declare (ignore stream))
607  (when atsign
608    (format-error "FORMAT command ~~~:[~;:~]@^ is undefined" colon))
609  (when (cond (p3 (etypecase p2
610                    (real
611                     (<= p1 p2 p3))
612                    (character
613                     (char< p1 p2 p3))))
614              (p2 (equal p1 p2))
615              (p1 (eql p1 0))
616              (t (null (if colon *format-colon-rest* *format-arguments*))))
617    (throw 'format-escape (if colon 'format-colon-escape t))))
618
619;;; Conditional expression  ~[ ... ]
620
621
622;;; ~[  - Maybe these guys should deal with ~^ too - i.e. catch format-escape etc.
623;;; but I cant think of a case where just throwing to the { catcher fails
624
625(defun format-untagged-condition (stream)
626  (let ((test (pop-format-arg)))
627    (unless (integerp test)
628      (format-error "Argument to ~~[ must be integer - ~S" test))
629    (do ((count 0 (1+ count)))
630        ((= count test)
631         (multiple-value-bind (prev tilde cmd colon atsign)
632                              (format-find-command-no-params '(#\; #\]) :atsign nil)
633           (declare (ignore colon atsign))
634           (sub-format stream prev tilde)
635           (unless (eq cmd #\])
636             (format-find-command '(#\])))))
637      (multiple-value-bind (prev tilde cmd colon atsign)
638                           (format-find-command-no-params '(#\; #\]) :atsign nil)
639        (declare (ignore prev tilde atsign))
640        (when (eq cmd #\]) (return))
641        (format-nextchar)
642        (when colon
643          (multiple-value-bind (prev tilde cmd colon atsign)
644                               (format-find-command-no-params '(#\; #\]))
645            (declare (ignore colon atsign))
646            (sub-format stream prev tilde)
647            (unless (eq cmd #\])
648              (format-find-command-no-params '(#\]))))
649          (return))))))
650
651
652;;; ~@[
653
654(defun format-funny-condition (stream)
655  (multiple-value-bind (prev tilde) (format-find-command-no-params '(#\]))
656    (if *format-arguments*
657      (if (car *format-arguments*)
658        (sub-format stream prev tilde)
659        (pop *format-arguments*))
660      (format-error "Missing argument"))))
661
662
663;;; ~:[
664
665(defun format-boolean-condition (stream)
666  (multiple-value-bind (prev tilde command) (format-find-command-no-params '(#\; #\]))
667    (when (eq command #\])
668      (format-error "Two clauses separated by ~~; are required for ~~:["))
669    (format-nextchar)
670    (if (pop-format-arg)
671      (multiple-value-bind (prev tilde)
672          (format-find-command-no-params '(#\]) :colon nil :atsign nil)
673        (sub-format stream prev tilde))
674      (progn
675        (sub-format stream prev tilde)
676        (format-find-command-no-params '(#\]))))))
677
678
679(defformat #\[ format-condition (stream colon atsign &optional p)
680  (when p (push p *format-arguments*))
681  (format-nextchar)
682  (cond (colon
683         (when atsign
684           (format-error  "~~:@[ undefined"))
685         (format-boolean-condition stream))
686        (atsign
687         (format-funny-condition stream))
688        (t (format-untagged-condition stream))))
689
690
691;;; Iteration  ~{ ... ~}
692
693(defformat #\{ format-iteration (stream colon atsign &rest parms)
694  (declare (dynamic-extent parms))
695  (with-format-parameters parms ((max-iter -1))
696    (format-nextchar)
697    (multiple-value-bind (prev tilde end-cmd end-colon end-atsign)
698                         (format-find-command-no-params '(#\}) :atsign nil)
699      (declare (ignore end-cmd end-atsign))
700      (if (= prev tilde)
701        ;; Use an argument as the control string if ~{~} is empty
702        (let ((string (pop-format-arg)))
703          (cond ((stringp string)
704                 (when (not (simple-string-p string)) ; fix here too
705                   (setq string (coerce string 'simple-string))))
706                ((not (functionp string))
707                 (format-error "Control string is not a string or function")))         
708          (let ((error 
709                 (catch 'format-error
710                   (cond
711                    ((stringp string)
712                     (let* ((length (length (the simple-string string)))
713                            (*format-control-string* string)
714                            (*format-length* length)
715                            (*format-index* 0))
716                       (format-do-iteration stream 0 length
717                                            max-iter colon atsign end-colon)))
718                    (t ;(functionp string)
719                     (format-do-iteration stream string nil 
720                                          max-iter colon atsign end-colon)))
721                   nil)))
722            (when error (format-indirect-error error))))
723        (format-do-iteration stream prev tilde 
724                             max-iter colon atsign end-colon)))))
725
726
727;;; The two catch tags FORMAT-ESCAPE and FORMAT-COLON-ESCAPE are needed here
728;;; to correctly implement ~^ and ~:^.  The former aborts only the current
729;;; iteration, but the latter aborts the entire iteration process.
730;;; ~{ arg is a list  ~:{ arg is list of sublists, ~@{  arg is spread ~:@{ spread lists
731;;; We have nuked two catch tags. Instead throw two different values:
732;;; T if ~^ and 'format-colon-escape if ~:^
733
734(defun format-do-iteration (stream start end max-iter colon atsign at-least-once-p)
735  (flet ((do-iteration-1 (stream start end colon at-least-once-p)
736           (let (catchp)
737             (do* ((count 0 (1+ count)))
738                  ((or (= count max-iter)
739                       (and (null *format-arguments*)
740                            (if (= count 0) (not at-least-once-p) t))))
741               (setq catchp
742                     (catch 'format-escape
743                       (if colon
744                         (let* ((args (unless (and at-least-once-p (null *format-arguments*))
745                                        (pop-format-arg)))
746                                (*format-top-level* nil)
747                                (*format-colon-rest* *format-arguments*)
748                                (*format-arguments* args)
749                                (*format-original-arguments* args))
750                           (unless (listp *format-arguments*)
751                             (report-bad-arg *format-arguments* 'list))
752                           (if (functionp start)
753                             (apply start stream args)
754                             (sub-format stream start end)))
755                         (let ((*format-original-arguments* *format-arguments*))
756                           (if (functionp start)
757                             (setq *format-arguments* (apply start stream *format-arguments*))
758                             (sub-format stream start end))))
759                       nil))
760               (when (or (eq catchp 'format-colon-escape)
761                         (and catchp (null colon)))
762                 (return-from do-iteration-1  nil))))))
763      (if atsign
764        (do-iteration-1 stream start end colon at-least-once-p)       
765        ; no atsign - munch on first arg
766        (let* ((*format-arguments* (pop-format-arg))
767               (*format-top-level* nil)
768               (*format-original-arguments* *format-arguments*))
769          (unless (listp *format-arguments*)
770            (report-bad-arg *format-arguments* 'list))
771          (do-iteration-1 stream start end colon at-least-once-p)))))
772 
773
774;;; Justification  ~< ... ~>
775
776;;; Parses a list of clauses delimited by ~; and terminated by ~>.
777;;; Recursively invoke SUB-FORMAT to process them, and return a list
778;;; of the results, the length of this list, and the total number of
779;;; characters in the strings composing the list.
780
781
782(defun format-get-trailing-segments ()
783  (format-nextchar)
784  (multiple-value-bind (prev tilde parms colon atsign cmd)
785                       (format-find-command '(#\; #\>) nil T)
786    (with-format-parameters parms ()
787      (when colon
788        (format-error "~~:; allowed only after first segment in ~~<"))
789      (format-no-flags nil atsign))
790    (let ((str (catch 'format-escape
791                 (with-format-string-output stream
792                   (sub-format stream prev tilde)))))     
793      (if (stringp str)
794        (if (eq cmd #\;)
795          (multiple-value-bind
796            (segments numsegs numchars)
797            (format-get-trailing-segments)
798            (values (cons str segments)
799                    (1+ numsegs)
800                    (+ numchars
801                       (length str))))
802          (values (list str)
803                  1
804                  (length str)))
805        (progn
806          (unless (eq cmd #\>) (format-find-command '(#\>) nil T))
807          (values () 0 0))))))
808
809
810;;; Gets the first segment, which is treated specially.  Call
811;;; FORMAT-GET-TRAILING-SEGMENTS to get the rest.
812
813(defun format-get-segments ()
814  (let (ignore)
815    (declare (ignore-if-unused ignore)) ; why??
816    (multiple-value-bind (prev tilde parms colon atsign cmd)
817                         (format-find-command '(#\; #\>) nil T) ; skipping
818      (when atsign
819        (format-error "Atsign flag not allowed"))
820      ;(setq *format-arguments* blech)
821      (let ((first-seg (catch 'format-escape
822                         (with-format-string-output stream
823                           (sub-format stream prev tilde)))))
824        (if (stringp first-seg)
825          (if (eq cmd #\;)
826            (progn
827              (when parms
828                (setq *format-index* tilde)
829                ; now get the parameters if any - do this way cause of the V thingies
830                ; maybe only necessary in the : case
831                (multiple-value-setq (ignore ignore parms)
832                                     (format-find-command '(#\; #\>) t T)))             
833              (multiple-value-bind
834                (segments numsegs numchars)
835                (format-get-trailing-segments)
836                (if colon
837                  (values first-seg parms segments numsegs numchars)
838                  (values nil nil (cons first-seg segments)
839                          (1+ numsegs)
840                          (+ (length first-seg) numchars)))))
841            (values nil nil (list first-seg) 1 (length first-seg)))
842          (progn
843            (unless (eq cmd #\>) (format-find-command '(#\>) nil T))
844            (values nil nil () 0 0)))))))
845
846
847#|
848;;; Given the total number of SPACES needed for padding, and the number
849;;; of padding segments needed (PADDINGS), returns a list of such segments.
850;;; We try to allocate the spaces equally to each segment.  When this is
851;;; not possible, we allocate the left-over spaces randomly, to improve the
852;;; appearance of many successive lines of justified text.
853;;;
854;;; Query:  Is this right?  Perhaps consistency might be better for the kind
855;;; of applications ~<~> is used for.
856
857(defun make-pad-segs (spaces paddings)
858  (do* ((extra-space () (and (plusp extra-spaces)
859                             (< (random (float 1)) (/ segs extra-spaces))))
860        (result () (cons (if extra-space (1+ min-space) min-space) result))
861        (min-space (truncate spaces paddings))
862        (extra-spaces (- spaces (* paddings min-space))
863                      (if extra-space (1- extra-spaces) extra-spaces))
864        (segs paddings (1- segs)))
865       ((zerop segs) result)))
866|#
867(defun make-pad-segs (spaces segments)
868  (multiple-value-bind (min-space extra-spaces) (truncate spaces segments)
869    (declare (fixnum min-space extra-spaces))
870    (let* ((result (make-list segments :initial-element min-space))
871           (res result))
872      (setq min-space (1+ min-space))
873      (dotimes (i extra-spaces)
874        (rplaca res min-space)
875        (setq res (%cdr res)))
876      result)))
877
878;;; Determine the actual width to be used for a field requiring WIDTH
879;;; characters according to the following rule:  If WIDTH is less than or
880;;; equal to MINCOL, use WIDTH as the actual width.  Otherwise, round up
881;;; to MINCOL + k * COLINC for the smallest possible positive integer k.
882
883(defun format-round-columns (width mincol colinc)
884  (if (< width mincol)
885    (+ width (* colinc (ceiling (- mincol width) colinc)))
886    width))
887
888(defun format-justification-round-columns (width mincol colinc)
889  (if (< width mincol)
890    mincol
891    (+ mincol (* colinc (ceiling (- width mincol) colinc)))))
892
893(defformat #\< format-justification (stream colon atsign &rest parms)
894  (declare (dynamic-extent parms))
895  (multiple-value-bind (start tilde ecmd ecolon eatsign)
896                       (format-find-command-no-params '(#\>)) ; bumps format-index
897    (declare (ignore tilde ecmd))
898    (cond
899     (ecolon
900      (format-logical-block stream colon atsign eatsign start *format-index* parms))
901     (t (setq *format-index* start)
902        (with-format-parameters parms ((mincol 0) (colinc 1) (minpad 0) (padchar #\space))
903          (unless (integerp mincol)
904            (format-error "Mincol must be an integer - ~S" mincol))
905          (unless (and (integerp colinc) (plusp colinc))
906            (format-error "Colinc must be a positive integer - ~S" colinc))
907          (unless (integerp minpad)
908            (format-error "Minpad must be an integer - ~S" minpad))
909          (unless (characterp padchar)
910            (if (typep padchar `(integer 0 #.char-code-limit))
911              (setq padchar (code-char padchar))
912              (format-error "Padchar must be a character or integer from 0 to ~a - ~S"
913                            char-code-limit padchar)))
914          (format-nextchar)
915          (multiple-value-bind (special-arg special-parms segments numsegs numchars)
916                               (format-get-segments)
917            (when (= numsegs 1) (setq minpad 0))
918            (when segments
919              (let* ((padsegs (+ (if (or colon (= numsegs 1)) 1 0)
920                                 (1- numsegs)
921                                 (if atsign 1 0)))
922                     (width (format-justification-round-columns (+ numchars (* minpad padsegs))
923                                                  mincol colinc))
924                     (spaces (if (and atsign (not colon) (= numsegs 1)) ;dirty but works
925                                 (list 0 (- width numchars))
926                                 (append (if (or colon (= numsegs 1)) () '(0))
927                                         (make-pad-segs (- width numchars) padsegs)
928                                         (if atsign () '(0))))))
929                (when special-arg
930                  (if *format-pprint*
931                      (format-error "Justification illegal in this context"))
932                  (setq *format-justification-semi* t)
933                  (with-format-parameters special-parms ((spare 0)
934                                                         (linel (stream-line-length stream)))
935                     
936                    (let ((pos (column stream)))
937                      (when (> (+ pos width spare) linel)
938                        (stream-write-entire-string stream special-arg)))))
939                (do ((segs segments (cdr segs))
940                     (spcs spaces (cdr spcs)))
941                    ((null segs) (dotimes (i (car spcs)) (write-char padchar stream)))
942                  (dotimes (i (car spcs)) (write-char padchar stream))
943                  (stream-write-entire-string stream (car segs)))))))))))
944
945
946(defun format-logical-block (stream colon atsign end-atsign start end &rest parms)
947  (declare (ignore parms))
948  (flet ((format-check-simple (str)
949           (when (and str (or (%str-member #\~ str) (%str-member #\newline str)))
950             (format-error "Suffix and prefix must be simple")))
951         (first-block-p (start)
952           (let* ((*format-index* 0))
953             (loop
954               (parse-format-operation)
955               (when (eq (format-peek) #\<)
956                 (cond ((eq *format-index* start)
957                        (return t))
958                       (t (return nil))))))))
959    (format-no-semi #\<)
960    (let ((format-string *format-control-string*)
961          (prefix (if colon "(" ""))
962          (suffix (if colon ")" ""))
963          body-string start1 tilde ignore colon1 atsign1 per-line-p)
964      (declare (ignore-if-unused ignore colon1))
965      (setq *format-index* start)
966      (multiple-value-setq (start1 tilde ignore colon1 atsign1)
967        (format-find-command  '(#\; #\>)))
968      (setq body-string (%substr format-string (1+ start) tilde))
969      (when (not (eql *format-index* end)) ; > 1 segment
970        (setq prefix body-string)
971        (if atsign1 (setq per-line-p t))
972        (multiple-value-setq (start1 tilde)
973          (format-find-command '(#\; #\>)))
974        (setq body-string (%substr format-string (1+ start1) tilde))
975        (when (neq *format-index* end)
976          (multiple-value-setq (start1 tilde)(format-find-command  '(#\; #\>)))
977          (setq suffix (%substr format-string (1+ start1) tilde))
978          (when (neq *format-index* end)
979            (format-error "Too many chunks"))))
980      (when end-atsign (setq body-string (format-fill-transform body-string)))
981      (format-check-simple prefix)
982      (format-check-simple suffix)
983      (unless *format-arguments*
984        (setq *format-index* start)
985        (format-error "Missing argument"))
986      (let ((args (if (not atsign)
987                    ; This piece of garbage is needed to avoid double length counting from (formatter ...) things
988                    ; but also to allow (flet . t) not to barf.
989                    ; Was formerly simply  (if *format-arguments* (pop-format-arg))
990                    ; Actually wanna not count the arg iff the ~< is at the top level
991                    ; in a format string i.e. "is this the first ~< in THIS string?"                   
992                    (when *format-arguments*
993                      (if  (and (listp *format-arguments*)
994                                (first-block-p start))
995                        (pop *format-arguments*)  ; dont count
996                        (pop-format-arg))) ; unless not listp or not first
997                    (prog1 *format-arguments*
998                      (setq *format-arguments* nil))))
999            (*format-control-string* body-string)
1000            (*format-top-level* (and atsign *format-top-level*)))
1001        (let ((*logical-block-p* t)
1002              (xp-struct (cond ((xp-structure-p stream) stream)
1003                               ((typep stream 'xp-stream)
1004                                (slot-value stream 'xp-structure)))))
1005          ; lets avoid unnecessary closures
1006          (cond (xp-struct (logical-block-sub xp-struct args  prefix suffix per-line-p atsign))
1007                (t (maybe-initiate-xp-printing
1008                    #'(lambda (s o)
1009                        (logical-block-sub s o  prefix suffix per-line-p atsign))
1010                    stream args))))))))
1011
1012
1013   
1014; flet?
1015(defun logical-block-sub (stream args  prefix suffix per-line-p atsign)
1016  ;(push (list args body-string) barf)
1017  (let ((circle-chk (not (or *format-top-level* (and atsign (eq *current-length* -1)))))) ; i.e. ~<~@<
1018    (let ((*current-level* (1+ *current-level*)) ; these are for pprint
1019          (*current-length* -1))
1020      (declare (special *current-level* *current-length*))
1021      (unless (check-block-abbreviation stream args circle-chk) ;(neq args *format-original-arguments*)) ;??
1022        (start-block stream prefix per-line-p suffix)
1023        (let ((*logical-block-xp* stream)    ; for pop-format-arg
1024              (my-stream (if (xp-structure-p stream) (get-xp-stream stream) stream)))
1025          (catch 'logical-block
1026            (do-sub-format-1 my-stream args)))
1027        (end-block stream suffix)))))
1028
1029; bash in fill conditional newline after white space (except blanks after ~<newline>)
1030; I think this is silly!
1031(defun format-fill-transform (string)
1032  (let ((pos 0)(end (length (the string string)))(result "") ch)
1033    (while (%i< pos end)
1034      (let ((wsp-pos (min (or (%str-member #\space string pos) end)
1035                          (or (%str-member #\tab string pos) end)))
1036            (yes nil))
1037        (when (%i< wsp-pos end)
1038          (when (not (and (%i> wsp-pos 1)
1039                          (eq (schar string (%i- wsp-pos 1)) #\newline)
1040                          (or (eq (setq ch (schar string (%i- wsp-pos 2))) #\~)
1041                              (and (%i> wsp-pos 2)
1042                                   (memq ch '(#\: #\@))
1043                                   (eq (schar string (%i- wsp-pos 3)) #\~)))))
1044            (setq yes t))
1045          (loop 
1046            (while (%i< wsp-pos end)
1047              (setq ch (schar string wsp-pos))
1048              (when (Not (%str-member ch wsp)) (return))
1049              (setq wsp-pos (%i+ 1 wsp-pos)))
1050            (return)))
1051        (setq result (%str-cat result (%substr string pos  wsp-pos) (if yes "~:_" "")))
1052      (setq pos wsp-pos)))
1053    result))
1054
1055
1056;;;;some functions needed for dealing with floats
1057
1058;;;; Floating Point printing
1059;;;
1060;;;  Written by Bill Maddox
1061;;;
1062;;;
1063;;;
1064;;; FLONUM-TO-STRING (and its subsidiary function FLOAT-STRING) does most of
1065;;; the work for all printing of floating point numbers in the printer and in
1066;;; FORMAT.  It converts a floating point number to a string in a free or
1067;;; fixed format with no exponent.  The interpretation of the arguments is as
1068;;; follows:
1069;;;
1070;;;     X        - The floating point number to convert, which must not be
1071;;;                negative.
1072;;;     WIDTH    - The preferred field width, used to determine the number
1073;;;                of fraction digits to produce if the FDIGITS parameter
1074;;;                is unspecified or NIL.  If the non-fraction digits and the
1075;;;                decimal point alone exceed this width, no fraction digits
1076;;;                will be produced unless a non-NIL value of FDIGITS has been
1077;;;                specified.  Field overflow is not considerd an error at this
1078;;;                level.
1079;;;     FDIGITS  - The number of fractional digits to produce. Insignificant
1080;;;                trailing zeroes may be introduced as needed.  May be
1081;;;                unspecified or NIL, in which case as many digits as possible
1082;;;                are generated, subject to the constraint that there are no
1083;;;                trailing zeroes.
1084;;;     SCALE    - If this parameter is specified or non-NIL, then the number
1085;;;                printed is (* x (expt 10 scale)).  This scaling is exact,
1086;;;                and cannot lose precision.
1087;;;     FMIN     - This parameter, if specified or non-NIL, is the minimum
1088;;;                number of fraction digits which will be produced, regardless
1089;;;                of the value of WIDTH or FDIGITS.  This feature is used by
1090;;;                the ~E format directive to prevent complete loss of
1091;;;                significance in the printed value due to a bogus choice of
1092;;;                scale factor.
1093;;;
1094;;; Most of the optional arguments are for the benefit for FORMAT and are not
1095;;; used by the printer.
1096;;;
1097;;; Returns:
1098;;; (VALUES DIGIT-STRING DIGIT-LENGTH LEADING-POINT TRAILING-POINT DECPNT)
1099;;; where the results have the following interpretation:
1100;;;
1101;;;     DIGIT-STRING    - The decimal representation of X, with decimal point.
1102;;;     DIGIT-LENGTH    - The length of the string DIGIT-STRING.
1103;;;     LEADING-POINT   - True if the first character of DIGIT-STRING is the
1104;;;                       decimal point.
1105;;;     TRAILING-POINT  - True if the last character of DIGIT-STRING is the
1106;;;                       decimal point.
1107;;;     POINT-POS       - The position of the digit preceding the decimal
1108;;;                       point.  Zero indicates point before first digit.
1109;;;     NZEROS          - number of zeros after point
1110;;;
1111;;; WARNING: For efficiency, there is a single string object *digit-string*
1112;;; which is modified destructively and returned as the value of
1113;;; FLONUM-TO-STRING.  Thus the returned value is not valid across multiple
1114;;; calls.
1115;;;
1116;;; NOTE:  FLONUM-TO-STRING goes to a lot of trouble to guarantee accuracy.
1117;;; Specifically, the decimal number printed is the closest possible
1118;;; approximation to the true value of the binary number to be printed from
1119;;; among all decimal representations  with the same number of digits.  In
1120;;; free-format output, i.e. with the number of digits unconstrained, it is
1121;;; guaranteed that all the information is preserved, so that a properly-
1122;;; rounding reader can reconstruct the original binary number, bit-for-bit,
1123;;; from its printed decimal representation. Furthermore, only as many digits
1124;;; as necessary to satisfy this condition will be printed.
1125;;;
1126;;;
1127;;; FLOAT-STRING actually generates the digits for positive numbers.  The
1128;;; algorithm is essentially that of algorithm Dragon4 in "How to Print
1129;;; Floating-Point Numbers Accurately" by Steele and White.  The current
1130;;; (draft) version of this paper may be found in [CMUC]<steele>tradix.press.
1131;;; DO NOT EVEN THINK OF ATTEMPTING TO UNDERSTAND THIS CODE WITHOUT READING
1132;;; THE PAPER!
1133
1134
1135
1136
1137(defun flonum-to-string (n &optional width fdigits scale)
1138  (let ((*print-radix* nil))
1139    (cond ((zerop n)(values "" 0 0))
1140          ((and (not (or width fdigits scale))
1141                (double-float-p n)
1142                ; cheat for the only (?) number that fails to be aesthetically pleasing
1143                (= n 1e23))
1144           (values "1" 24 23))
1145          (t (let ((string (make-array 12 :element-type 'base-char
1146                                       :fill-pointer 0 :adjustable t)))
1147               (multiple-value-bind (sig exp)(integer-decode-float n)
1148                 (float-string string sig exp (integer-length sig) width fdigits scale)))))))
1149
1150;;; if width given and fdigits nil then if exponent is >= 0 returns at
1151;;; most width-1 digits if exponent is < 0 returns (- width (- exp) 1)
1152;;; digits if fdigits given width is ignored, returns fdigits after
1153;;; (implied) point The Steele/White algorithm can produce a leading
1154;;; zero for 1e23 which lies exactly between two double floats -
1155;;; rounding picks the float whose rational is
1156;;; 99999999999999991611392. This guy wants to print as
1157;;; 9.999999999999999E+22. The untweaked algorithm generates a leading
1158;;; zero in this case.  (actually wants to print as 1e23!)  If we
1159;;; choose s such that r < s - m/2, and r = s/10 - m/2 (which it does
1160;;; in this case) then r * 10 < s => first digit is zero and
1161;;; (remainder (* r 10) s) is r * 10 = new-r, 10 * m = new-m new-r = s
1162;;; - new-m/2 so high will be false and she won't round up we do r *
1163;;; (expt 2 (- e (- scale))) and s * (expt 5 (- scale)) i.e. both less
1164;;; by (expt 2 (- scale))
1165
1166(defun float-string (string f e p &optional width fdigits scale)
1167  (macrolet ((nth-digit (n) `(%code-char (%i+ ,n (%char-code #\0)))))   
1168    (let ((r f)(s 1)(m- 1)(m+ 1)(k 0) cutoff roundup (mm nil))
1169      (when (= f (if (eql p 53) #.(ash 1 52) (ash 1 (1- p))))
1170        (setq mm t))
1171      (when (or (null scale)(zerop scale))
1172        ; approximate k
1173        (let ((fudge 0))
1174          (setq fudge (truncate (*  (%i+ e p) .301)))
1175          (when (neq fudge 0)
1176            (setq k fudge)
1177            (setq scale (- k)))))
1178      (when (and scale (not (eql scale 0)))     
1179        (if (minusp scale)
1180          (setq s (* s (5-to-e  (- scale))))
1181          (let ((scale-factor (5-to-e scale)))
1182            (setq r (* r scale-factor))
1183            (setq m+ scale-factor)
1184            (when mm (setq m- scale-factor)))))
1185      (let ((shift (- e (if scale (- scale) 0))))
1186        (declare (fixnum shift))
1187        ;(print (list e scale shift))
1188        (cond ((> shift 0)
1189               (setq r (ash f shift))
1190               (setq m+ (ash m+ shift))
1191               (when mm (setq m- (ash m- shift))))
1192              ((< shift 0)
1193               (setq s (ash s (- shift))))))
1194      (when mm
1195        (setq m+ (+ m+ m+))
1196        (setq r (+ r r))
1197        (setq s (+ s s)))   
1198      (let ((ceil (ceiling s 10))(fudge 1))
1199        (while (< r ceil)
1200          (setq k (1- k))
1201          (setq r (* r 10))
1202          (setq fudge (* fudge 10)))
1203        (when (> fudge 1)
1204          (setq m+ (* m+ fudge))
1205          (when mm (setq m- (* m- fudge)))))   
1206      (let ((2r (+ r r)))
1207        (loop
1208          (let ((2rm+ (+ 2r m+)))         
1209            (while
1210              (if (not roundup)  ; guarantee no leading zero
1211                (> 2rm+ (+ s s))
1212                (>=  2rm+ (+ s s)))
1213              (setq s (* s 10))
1214              (setq k (1+ k))))
1215          (when (not (or fdigits width))(return))
1216          (cond 
1217           (fdigits (setq cutoff (- fdigits)))
1218           (width
1219            (setq cutoff
1220                  (if (< k 0) (- 1 width)(1+ (- k width))))
1221            ;(if (and fmin (> cutoff (- fmin))) (setq cutoff (- fmin)))
1222            ))
1223          (let ((a (if cutoff (- cutoff k) 0))
1224                (y s))
1225            (DECLARE (FIXNUM A))
1226            (if (>= a 0)
1227              (when (> a 0)(setq y (* y (10-to-e a))))
1228              (setq y (ceiling y (10-to-e (the fixnum (- a))))))
1229            (when mm (setq m- (max y m-)))
1230            (setq m+ (max y m+))
1231            (when (= m+ y) (setq roundup t)))
1232          (when (if (not roundup)   ; tweak as above
1233                  (<= (+ 2r m+)(+ s s))
1234                  (< (+ 2r m+)(+ s s)))
1235            (return))))
1236      (let* ((h k)
1237             (half-m+ (* m+ 5))  ; 10 * m+/2
1238             (half-m- (if mm (* m- 5)))
1239             u high low 
1240             )
1241        ;(print (list r s m+ roundup))
1242        (unless (and fdigits (>= (- k) fdigits))
1243          (loop
1244            (setq k (1- k))
1245            (multiple-value-setq (u r) (truncate (* r 10) s))         
1246            (setq low (< r (if mm half-m- half-m+)))
1247            (setq high 
1248                  (if (not roundup)
1249                    (> r (- s half-m+))
1250                    (>= r (- s half-m+))))                   
1251            (if (or low high)
1252              (return)
1253              (progn
1254                (vector-push-extend (nth-digit u) string)))
1255            (when mm (setq half-m- (* half-m- 10) ))
1256            (setq half-m+ (* half-m+ 10)))
1257          ;(print (list r s  high low h k))
1258          (vector-push-extend
1259           (nth-digit (cond
1260                       ((and low (not high)) u) 
1261                       ((and high (not low))(+ u 1))
1262                       
1263                       (t ;(and high low)
1264                        (if (<= (+ r r) s) u (1+ u)))))
1265           string))
1266        ; second value is exponent, third is exponent - # digits generated
1267        (values string h k)))))
1268
1269
1270(defparameter integer-powers-of-10 (make-array (+ 12 (floor 324 12))))
1271
1272; e better be positive
1273(defun 10-to-e (e)
1274  (declare (fixnum e)(optimize (speed 3)(safety 0)))
1275  (if (> e 335)
1276    (* (10-to-e 334) (10-to-e (%i- e 334)))
1277    (if (< e 12)
1278      (svref integer-powers-of-10 e)
1279      (multiple-value-bind (q r) (truncate e 12)
1280        (declare (fixnum q r))       
1281        (if (eql r 0)
1282          (svref integer-powers-of-10 (%i+ q 11))
1283          (* (svref integer-powers-of-10 r)
1284             (svref integer-powers-of-10 (%i+ q 11))))))))
1285
1286
1287(let ((array integer-powers-of-10))
1288  (dotimes (i 12)
1289    (setf (svref array i)  (expt 10 i)))
1290  (dotimes (i (floor 324 12))
1291    (setf (svref array (+ i 12)) (expt 10 (* 12 (1+ i))))))
1292#|
1293(defun 10-to-e (e)
1294  (ash (5-to-e e) e))
1295|#
1296     
1297;;; Given a non-negative floating point number, SCALE-EXPONENT returns a
1298;;; new floating point number Z in the range (0.1, 1.0] and and exponent
1299;;; E such that Z * 10^E is (approximately) equal to the original number.
1300;;; There may be some loss of precision due the floating point representation.
1301;;; JUST do the EXPONENT since thats all we use
1302
1303(defconstant single-float-min-e
1304  (nth-value 1 (decode-float least-positive-single-float)))
1305(defconstant double-float-min-e
1306  (nth-value 1 (decode-float least-positive-double-float)))
1307
1308;;; Adapted from CMUCL.
1309
1310;; This is a modified version of the scale computation from Burger and
1311;; Dybvig's paper "Printing floating-point quickly and accurately."
1312;; We only want the exponent, so most things not needed for the
1313;; computation of the exponent have been removed.  We also implemented
1314;; the floating-point log approximation given in Burger and Dybvig.
1315;; This is very noticeably faster for large and small numbers.  It is
1316;; slower for intermediate sized numbers.
1317(defun accurate-scale-exponent (v)
1318  (declare (type float v))
1319  (if (zerop v)
1320      1
1321      (let ((float-radix 2)             ; b
1322            (float-digits (float-digits v)) ; p
1323            (min-e
1324             (etypecase v
1325               (single-float single-float-min-e)
1326               (double-float double-float-min-e))))
1327        (multiple-value-bind (f e)
1328            (integer-decode-float v)
1329          (let ( ;; FIXME: these even tests assume normal IEEE rounding
1330                ;; mode.  I wonder if we should cater for non-normal?
1331                (high-ok (evenp f)))
1332            ;; We only want the exponent here.
1333            (labels ((flog (x)
1334                       (declare (type (float (0.0)) x))
1335                       (let ((xd (etypecase x
1336                                   (single-float
1337                                    (float x 1d0))
1338                                   (double-float
1339                                    x))))
1340                         (ceiling (- (the (double-float -400d0 400d0)
1341                                          (log xd 10d0))
1342                                     1d-10))))
1343                     (fixup (r s m+ k)
1344                       (if (if high-ok
1345                               (>= (+ r m+) s)
1346                               (> (+ r m+) s))
1347                           (+ k 1)
1348                           k))
1349                     (scale (r s m+)
1350                       (let* ((est (flog v))
1351                              (scale (the integer (10-to-e (abs est)))))
1352                         (if (>= est 0)
1353                             (fixup r (* s scale) m+ est)
1354                             (fixup (* r scale) s (* m+ scale) est)))))
1355              (let (r s m+)
1356                (if (>= e 0)
1357                    (let* ((be (expt float-radix e))
1358                           (be1 (* be float-radix)))
1359                      (if (/= f (expt float-radix (1- float-digits)))
1360                          (setf r (* f be 2)
1361                                s 2
1362                                m+ be)
1363                          (setf r (* f be1 2)
1364                                s (* float-radix 2)
1365                                m+ be1)))
1366                    (if (or (= e min-e) 
1367                            (/= f (expt float-radix (1- float-digits))))
1368                        (setf r (* f 2)
1369                              s (* (expt float-radix (- e)) 2)
1370                              m+ 1)
1371                        (setf r (* f float-radix 2)
1372                              s (* (expt float-radix (- 1 e)) 2)
1373                              m+ float-radix)))
1374                (scale r s m+))))))))
1375
1376;;; Page  ~|
1377
1378(defformat #\| format-page (stream colon atsign &rest parms)
1379  (declare (dynamic-extent parms))
1380  (format-no-flags colon atsign)
1381  (with-format-parameters parms ((repeat-count 1))
1382    (declare (fixnum repeat-count))
1383    (dotimes (i repeat-count) (write-char #\page stream))))
1384
1385
1386(defun format-eat-whitespace ()
1387  (do* ((i *format-index* (1+ i))
1388        (s *format-control-string*)
1389        (n *format-length*))
1390       ((or (= i n)
1391            (not (whitespacep (schar s i))))
1392        (setq *format-index* (1- i)))))
1393
1394(defun format-newline (stream colon atsign parms)
1395  (with-format-parameters parms ()
1396    (cond (colon
1397           (when atsign
1398             (format-error "~:@<newline> is undefined")))
1399          (atsign (terpri stream) (format-eat-whitespace))
1400          (t (format-eat-whitespace)))))
1401 
1402(defformat  #\newline format-newline (stream colon atsign &rest parms)
1403  (declare (dynamic-extent parms))
1404  (format-newline stream colon atsign parms))
1405
1406(defformat #\return format-newline (stream colon atsign &rest parms)
1407  (declare (dynamic-extent parms))
1408  (format-newline stream colon atsign parms))
1409
1410;;; Indirection  ~?
1411
1412(defformat #\? format-indirection (stream colon atsign)
1413  (format-no-flags colon nil)
1414  (let ((string (pop-format-arg)))
1415    (unless (or (stringp string)(functionp string))
1416      (format-error "Indirected control string is not a string or function"))
1417    (when (and (stringp string) (not (simple-string-p string)))
1418      (setq string (coerce string 'simple-string)))
1419    (catch 'format-escape
1420      (let ((error 
1421             (catch 'format-error
1422               (cond 
1423                ((stringp string)
1424                 (let* ((length (length (the simple-string string)))
1425                        (*format-control-string* string)
1426                        (*format-length* length)
1427                        (*format-index* 0))
1428                    (if atsign
1429                      (sub-format stream 0 length)
1430                      (let ((args (pop-format-arg)))
1431                        (let ((*format-top-level* nil)
1432                              (*format-arguments* args)
1433                              (*format-original-arguments* args))
1434                          (sub-format stream 0 length))))))
1435                (T ;(functionp string)
1436                 (if (not atsign)
1437                   (apply string stream (pop-format-arg))
1438                   ; account for the args it eats
1439                   (setq *format-arguments* (apply string stream *format-arguments*)))))
1440               nil)))
1441        (when error (format-indirect-error error))))))
1442
1443
1444
1445
1446;;; Ascii  ~A
1447
1448(defformat #\A format-princ (stream colon atsign &rest parms)
1449  (declare (dynamic-extent parms))
1450  (let ((arg (pop-format-arg)))
1451    (if (null parms)
1452      (princ (or arg (if colon "()" nil)) stream)
1453      (with-format-parameters parms ((mincol 0) (colinc 1) (minpad 0) (padchar #\space))
1454        (format-write-field
1455         stream
1456         (if (or arg (not colon))
1457           (princ-to-string arg)
1458           "()")
1459         mincol colinc minpad padchar atsign)))))
1460
1461
1462
1463;;; S-expression  ~S
1464           
1465(defformat #\S format-prin1 (stream colon atsign &rest parms)
1466  (declare (dynamic-extent parms))
1467  (let ((arg (pop-format-arg)))
1468    (if (null parms)
1469      (if (or arg (not colon)) (prin1 arg stream) (princ "()" stream))
1470      (with-format-parameters parms ((mincol 0) (colinc 1) (minpad 0) (padchar #\space))
1471        (format-write-field
1472         stream
1473         (if (or arg (not colon))
1474           (prin1-to-string arg)
1475           "()")
1476         mincol colinc minpad padchar atsign)))))
1477
1478
1479
1480;;; Character  ~C
1481
1482(defformat #\C format-print-character (stream colon atsign)
1483  (let* ((char (character (pop-format-arg)))
1484         (code (char-code char))
1485         (name (char-name char)))
1486    (cond ((and atsign (not colon))
1487           (prin1 char stream))
1488          (colon
1489           (if (or (eql char #\space)
1490                   (not (graphic-char-p char)))
1491             (princ name stream)
1492             (write-char char stream)))
1493          ((not (or atsign colon))
1494           (write-char char stream))
1495          ((and (< code 32) atsign)
1496           (setq char (code-char (logxor code 64)))
1497           (if (or colon (%str-member char "@CGHIJKLM[\\]^_"))
1498               (princ name stream)
1499               (progn
1500                 (write-char #\^ stream)
1501                 (write-char char stream)))
1502           (princ " (" stream)
1503           (princ "Control " stream)
1504           (write-char char stream)
1505           (write-char #\) stream))
1506          (name (princ name stream))
1507          (t (write-char char stream)))))
1508
1509
1510;;; NUMERIC PRINTING
1511
1512
1513
1514;;; Output a string in a field at MINCOL wide, padding with PADCHAR.
1515;;; Pads on the left if PADLEFT is true, else on the right.  If the
1516;;; length of the string plus the minimum permissible padding, MINPAD,
1517;;; is greater than MINCOL, the actual field size is rounded up to
1518;;; MINCOL + k * COLINC for the smallest possible positive integer k.
1519
1520(defun format-write-field (stream string mincol colinc minpad padchar padleft)
1521  (unless (or (null mincol)
1522              (integerp mincol))
1523    (format-error "Mincol must be an integer - ~S" mincol))
1524  (unless (and (integerp colinc) (plusp colinc))
1525    (format-error "Colinc must be a positive integer - ~S" colinc))
1526  (unless (integerp minpad)
1527    (format-error "Minpad must be an integer - ~S" minpad))
1528  (unless (characterp padchar)
1529    (if (typep padchar `(integer 0 #.char-code-limit))
1530      (setq padchar (code-char padchar))
1531      (format-error "Padchar must be a character or integer from 0 to ~a - ~S"
1532                    char-code-limit padchar)))
1533  (let* ((strlen (length (the string string)))
1534         (strwid (+ strlen minpad))
1535         (width (if mincol
1536                  (format-round-columns strwid mincol colinc)
1537                  strwid)))
1538    (if padleft
1539      (dotimes (i (the fixnum (- width strlen))) (write-char padchar stream)))
1540    (write-string string stream :start  0 :end strlen)
1541    (unless padleft
1542      (dotimes (i (the fixnum (- width strlen))) (write-char padchar stream)))))
1543
1544
1545;;; This functions does most of the work for the numeric printing
1546;;; directives.  The parameters are interpreted as defined for ~D.
1547
1548(defun format-print-number (stream number radix print-commas-p print-sign-p parms)
1549  (declare (dynamic-extent parms))
1550  (declare (type t number) (type fixnum radix))
1551  #+wrong
1552  (when (> (length parms) 2) (setq print-commas-p t)) ; print commas if char or interval provided
1553  (if (not (integerp number))
1554      (let ((*print-base* radix)
1555            (*print-escape* nil)
1556            (*print-radix* nil))
1557        (declare (special *print-base* *print-radix*))
1558        (princ number stream))
1559    (with-format-parameters parms
1560          ((mincol 0) (padchar #\space) (commachar #\,) (commainterval 3))
1561      ; look out for ",0D" - should be ",'0D"
1562      (unless (characterp padchar)
1563        (error "Use '~A instead of ~A for padchar in format directive" padchar padchar))
1564       (setq print-sign-p 
1565             (cond ((and print-sign-p (>= number 0)) #\+)
1566                   ((< number 0) #\-)))
1567       (setq number (abs number))
1568       (block HAIRY
1569         (block SIMPLE
1570           (if (and (not print-commas-p) (eql 0 mincol))
1571             (return-from SIMPLE))
1572           (let ((lg 0)
1573                 (commas 0))
1574             (declare (type fixnum lg commas))
1575             (do ((n (abs number) (floor n radix)))
1576                 ((%i< n radix))
1577               (declare (type integer n))
1578               (setq lg (%i+ lg 1))) ; lg is 1- significant digits             
1579             (setq commas (if print-commas-p
1580                              (floor lg commainterval)
1581                              0))
1582             (when print-sign-p
1583               (setq lg (1+ lg)))
1584             (when (and (eq commas 0)
1585                        (%i<= mincol lg))
1586               (return-from SIMPLE))
1587             ;; Cons-o-rama no more !
1588             (let* ((s (make-string-output-stream)))
1589               (when  (neq padchar #\space)
1590                 (dotimes (i (- mincol (+ lg commas) 1))
1591                   (write-char padchar s)))
1592               (when print-sign-p (write-char print-sign-p s))
1593               (%pr-integer  number radix s)                           
1594               (dotimes (i (the fixnum commas)) (write-char commachar s))
1595               (let ((text (get-output-stream-string s)))
1596                 (declare (type string text))
1597                 ;; -1234567,, => -1,234,567
1598                 (when (%i> commas 0)
1599                   (do* ((dest (%i- (length text) 1))
1600                         (source (%i- dest commas)))
1601                        ((= source dest))
1602                     (declare (type fixnum dest source))
1603                     (dotimes (i (the fixnum commainterval))
1604                       (setf (char text dest) (char text source)
1605                             dest (1- dest) 
1606                             source (1- source)))
1607                     (setf (char text dest) commachar
1608                           dest (1- dest))))
1609                 (format-write-field stream text mincol 1 0 padchar t)
1610                 (return-from HAIRY)))))
1611         ;; SIMPLE case         
1612         (when print-sign-p (write-char print-sign-p stream))
1613         (%pr-integer number radix stream))))
1614  nil)
1615
1616;;; Print a cardinal number in English
1617
1618(eval-when (:compile-toplevel :execute)
1619(defmacro cardinal-ones ()
1620  "Table of cardinal ones-place digits in English"
1621        '#(nil "one" "two" "three" "four" "five" "six" "seven" "eight" "nine"))
1622(defmacro cardinal-tens ()
1623  "Table of cardinal tens-place digits in English"
1624        '#(nil nil "twenty" "thirty" "forty"
1625           "fifty" "sixty" "seventy" "eighty" "ninety"))
1626(defmacro cardinal-teens ()
1627        '#("ten" "eleven" "twelve" "thirteen" "fourteen"  ;;; RAD
1628           "fifteen" "sixteen" "seventeen" "eighteen" "nineteen"))
1629)
1630
1631
1632(defun format-print-small-cardinal (stream n)
1633  (multiple-value-bind (hundreds rem) (truncate n 100)
1634    (when (plusp hundreds)
1635      (write-string (svref (cardinal-ones) hundreds) stream)
1636      (write-string " hundred" stream)
1637      (when (plusp rem) (write-char #\space stream)))    ; ; ; RAD
1638    (when (plusp rem)
1639      (multiple-value-bind (tens ones) (truncate rem 10)
1640        (cond ((< 1 tens)
1641               (write-string (svref (cardinal-tens) tens) stream)
1642               (when (plusp ones)
1643                 (write-char #\- stream)
1644                 (write-string (svref (cardinal-ones) ones) stream)))
1645              ((= tens 1)
1646               (write-string (svref (cardinal-teens) ones) stream))
1647              ((plusp ones)
1648               (write-string (svref (cardinal-ones) ones) stream)))))))
1649
1650(eval-when (:compile-toplevel :execute)
1651  (defmacro cardinal-periods ()
1652    "Table of cardinal 'teens' digits in English"
1653    '#("" " thousand" " million" " billion" " trillion" " quadrillion"
1654       " quintillion" " sextillion" " septillion" " octillion" " nonillion" 
1655       " decillion"))
1656)
1657
1658
1659(defun format-print-cardinal (stream n)
1660  (cond ((minusp n)
1661         (stream-write-entire-string stream "negative ")
1662         (format-print-cardinal-aux stream (- n) 0 n))
1663        ((zerop n)
1664         (stream-write-entire-string stream "zero"))
1665        (t (format-print-cardinal-aux stream n 0 n))))
1666
1667(defun format-print-cardinal-aux (stream n period err)
1668  (multiple-value-bind (beyond here) (truncate n 1000)
1669    (unless (<= period 10)
1670      (format-error "Number too large to print in English: ~:D" err))
1671    (unless (zerop beyond)
1672      (format-print-cardinal-aux stream beyond (1+ period) err))
1673    (unless (zerop here)
1674      (unless (zerop beyond) (write-char #\space stream))
1675      (format-print-small-cardinal stream here)
1676      (stream-write-entire-string stream (svref (cardinal-periods) period)))))
1677
1678
1679;;; Print an ordinal number in English
1680
1681
1682(eval-when (:compile-toplevel :execute)
1683(defmacro ordinal-ones ()
1684  "Table of ordinal ones-place digits in English"
1685  '#(nil "first" "second" "third" "fourth"
1686         "fifth" "sixth" "seventh" "eighth" "ninth"))
1687(defmacro ordinal-tens ()
1688  "Table of ordinal tens-place digits in English"
1689  '#(nil "tenth" "twentieth" "thirtieth" "fortieth"
1690         "fiftieth" "sixtieth" "seventieth" "eightieth" "ninetieth"))
1691)
1692
1693(defun format-print-ordinal (stream n)
1694  (when (minusp n)
1695    (stream-write-entire-string stream "negative "))
1696  (let ((number (abs n)))
1697    (multiple-value-bind (top bot) (truncate number 100)
1698      (unless (zerop top) (format-print-cardinal stream (- number bot)))
1699      (when (and (plusp top) (plusp bot)) (write-char #\space stream))
1700      (multiple-value-bind (tens ones) (truncate bot 10)
1701        (cond ((= bot 12) (stream-write-entire-string stream "twelfth"))
1702              ((= tens 1)
1703               (stream-write-entire-string stream (svref (cardinal-teens) ones));;;RAD
1704               (stream-write-entire-string stream "th"))
1705              ((and (zerop tens) (plusp ones))
1706               (stream-write-entire-string stream (svref (ordinal-ones) ones)))
1707              ((and (zerop ones)(plusp tens))
1708               (stream-write-entire-string stream (svref (ordinal-tens) tens)))
1709              ((plusp bot)
1710               (stream-write-entire-string stream (svref (cardinal-tens) tens))
1711               (write-char #\- stream)
1712               (stream-write-entire-string stream (svref (ordinal-ones) ones)))
1713              ((plusp number) (write-string "th" stream :start  0 :end 2))
1714              (t (stream-write-entire-string stream "zeroth")))))))
1715
1716
1717;;; Print Roman numerals
1718
1719(defun format-print-old-roman (stream n)
1720  (unless (< 0 n 5000)
1721          (format-error "Number out of range for old Roman numerals: ~:D" n))
1722  (do ((char-list '(#\D #\C #\L #\X #\V #\I) (cdr char-list))
1723       (val-list '(500 100 50 10 5 1) (cdr val-list))
1724       (cur-char #\M (car char-list))
1725       (cur-val 1000 (car val-list))
1726       (start n (do ((i start (progn (write-char cur-char stream) (- i cur-val))))
1727                    ((< i cur-val) i))))
1728      ((zerop start))))
1729
1730
1731(defun format-print-roman (stream n)
1732  (unless (< 0 n 4000)
1733          (format-error "Number out of range for Roman numerals: ~:D" n))
1734  (do ((char-list '(#\D #\C #\L #\X #\V #\I) (cdr char-list))
1735       (val-list '(500 100 50 10 5 1) (cdr val-list))
1736       (sub-chars '(#\C #\X #\X #\I #\I) (cdr sub-chars))
1737       (sub-val '(100 10 10 1 1 0) (cdr sub-val))
1738       (cur-char #\M (car char-list))
1739       (cur-val 1000 (car val-list))
1740       (cur-sub-char #\C (car sub-chars))
1741       (cur-sub-val 100 (car sub-val))
1742       (start n (do ((i start (progn (write-char cur-char stream) (- i cur-val))))
1743                    ((< i cur-val)
1744                     (cond ((<= (- cur-val cur-sub-val) i)
1745                            (write-char cur-sub-char stream)
1746                            (write-char cur-char stream)
1747                            (- i (- cur-val cur-sub-val)))
1748                           (t i))))))
1749      ((zerop start))))
1750
1751
1752;;; Decimal  ~D
1753
1754(defformat #\D format-print-decimal (stream colon atsign &rest parms)
1755  (declare (dynamic-extent parms))
1756  (format-print-number stream (pop-format-arg) 10 colon atsign parms))
1757
1758
1759;;; Binary  ~B
1760
1761(defformat #\B format-print-binary (stream colon atsign &rest parms)
1762  (declare (dynamic-extent parms))
1763  (format-print-number stream (pop-format-arg) 2 colon atsign parms))
1764
1765
1766;;; Octal  ~O
1767
1768(defformat #\O format-print-octal (stream colon atsign &rest parms)
1769  (declare (dynamic-extent parms))
1770  (format-print-number stream (pop-format-arg) 8 colon atsign parms))
1771
1772
1773;;; Hexadecimal  ~X
1774
1775(defformat #\X format-print-hexadecimal (stream colon atsign &rest parms)
1776  (declare (dynamic-extent parms))
1777  (format-print-number stream (pop-format-arg) 16 colon atsign parms))
1778
1779
1780;;; Radix  ~R
1781
1782(defformat #\R format-print-radix (stream colon atsign &rest parms)
1783  (declare (dynamic-extent parms))
1784  (let ((number (pop-format-arg))
1785        (parm (if parms (pop parms) nil)))
1786    (if parm
1787        (format-print-number stream number parm colon atsign parms)
1788        (if atsign
1789            (if colon
1790                (format-print-old-roman stream number)
1791                (format-print-roman stream number))
1792            (if colon
1793                (format-print-ordinal stream number)
1794                (format-print-cardinal stream number))))))
1795
1796;;; FLOATING-POINT NUMBERS
1797
1798
1799;;; Fixed-format floating point  ~F
1800
1801(defformat #\F format-fixed (stream colon atsign &rest parms)
1802  (declare (dynamic-extent parms))
1803  (when colon
1804    (format-error "Colon flag not allowed"))
1805  (with-format-parameters parms ((w nil) (d nil) (k nil) (ovf nil) (pad #\space))
1806    ;;Note that the scale factor k defaults to nil.  This is interpreted as
1807    ;;zero by flonum-to-string, but more efficiently.
1808    (let ((number (pop-format-arg))(*print-escape* nil))
1809      (if (floatp number)
1810        (format-fixed-aux stream number w d k ovf pad atsign)
1811        (if (rationalp number)
1812          (format-fixed-aux stream (coerce number 'float) w d k ovf pad atsign)
1813          (let ((*print-base* 10))
1814            (format-write-field stream (princ-to-string number) w 1 0 #\space t)))))))
1815
1816; do something ad hoc if d > w - happens if (format nil "~15g" (- 2.3 .1))
1817; called with w = 11 d = 16 - dont do it after all.
1818
1819(defun format-fixed-aux (stream number w d k ovf pad atsign)
1820  (and w (<= w 0) (setq w nil))  ; if width is unreasonable, ignore it.
1821  (if (not (or w d))
1822    (print-float-free-form number stream)
1823    (let ((spaceleft w)
1824          (abs-number (abs number))
1825          strlen zsuppress flonum-to-string-width)
1826      (when (and w (or atsign (minusp number)))
1827        (decf spaceleft))
1828      (when (and d w (<= w (+ 1 d (if atsign 1 0))))
1829        (setq zsuppress t))
1830      (when (and d (minusp d))
1831          (format-error "Illegal value for d"))
1832      (setq flonum-to-string-width
1833            (and w
1834                 (if (and (< abs-number 1) (not zsuppress))
1835                   (1- spaceleft)   ; room for leading 0
1836                   spaceleft)))
1837      (when (and w (not (plusp flonum-to-string-width)))
1838        (if ovf 
1839          (progn
1840            (dotimes (i w) (write-char ovf stream))
1841            (return-from format-fixed-aux))
1842          (setq spaceleft nil w nil flonum-to-string-width nil)))
1843      (multiple-value-bind (str before-pt after-pt)
1844                           (flonum-to-string abs-number
1845                                             flonum-to-string-width
1846                                             d k)
1847        (setq strlen (length str))
1848        (cond (w (decf spaceleft (+ (max before-pt 0) 1))
1849                 (when (and (< before-pt 1) (not zsuppress))
1850                   (decf spaceleft))
1851                 (if d
1852                   (decf spaceleft d)
1853                   (setq d (max (min spaceleft (- after-pt))
1854                                (if (> spaceleft 0) 1 0))
1855                         spaceleft (- spaceleft d))))
1856              ((null d) (setq d (max (- after-pt) 1))))
1857        (cond ((and w (< spaceleft 0) ovf)
1858               ;;field width overflow
1859               (dotimes (i w) (declare (fixnum i)) (write-char ovf stream)))
1860              (t (when w (dotimes (i spaceleft) (declare (fixnum i)) (write-char pad stream)))
1861                 (if (minusp (float-sign number)) ; 5/25
1862                   (write-char #\- stream)
1863                   (if atsign (write-char #\+ stream)))
1864                 (cond
1865                  ((> before-pt 0)
1866                   (cond ((> strlen before-pt)
1867                          (write-string str stream :start  0 :end before-pt)
1868                          (write-char #\. stream)
1869                          (write-string str stream :start  before-pt :end strlen)
1870                          (dotimes (i (- d (- strlen before-pt)))
1871                            (write-char #\0 stream)))
1872                         (t ; 0's after
1873                          (stream-write-entire-string stream str)
1874                          (dotimes (i (-  before-pt strlen))
1875                            (write-char #\0 stream))
1876                          (write-char #\. stream)
1877                          (dotimes (i d)
1878                            (write-char #\0 stream)))))
1879                  (t (unless zsuppress (write-char #\0 stream))
1880                     (write-char #\. stream)
1881                     (dotimes (i (- before-pt)) 
1882                       (write-char #\0 stream))
1883                     (stream-write-entire-string stream str)
1884                     (dotimes (i (+ d after-pt)) 
1885                      (write-char #\0 stream))))))))))
1886#|
1887; (format t "~7,3,-2f" 8.88)
1888; (format t "~10,5,2f" 8.88)
1889; (format t "~10,5,-2f" 8.88)
1890; (format t "~10,5,2f" 0.0)
1891; (format t "~10,5,2f" 9.999999999)
1892; (format t "~7,,,-2e" 8.88) s.b. .009e+3 ??
1893; (format t "~10,,2f" 8.88)
1894; (format t "~10,,-2f" 8.88)
1895; (format t "~10,,2f" 0.0)
1896; (format t "~10,,2f" 0.123454)
1897; (format t "~10,,2f" 9.9999999)
1898 (defun foo (x)
1899    (format nil "~6,2f|~6,2,1,'*f|~6,2,,'?f|~6f|~,2f|~F"
1900     x x x x x x))
1901
1902|#
1903
1904                 
1905
1906;;; Exponential-format floating point  ~E
1907
1908
1909(defformat #\E format-exponential (stream colon atsign &rest parms)
1910  (declare (dynamic-extent parms))
1911  (when colon
1912    (format-error "Colon flag not allowed"))
1913  (with-format-parameters parms ((w nil) (d nil) (e nil) (k 1) (ovf nil) (pad #\space) (marker nil))
1914    (let ((number (pop-format-arg)))
1915      (if (floatp number)
1916        (format-exp-aux stream number w d e k ovf pad marker atsign)
1917        (if (rationalp number)
1918          (format-exp-aux stream (coerce number 'float) w d e k ovf pad marker atsign)
1919          (let ((*print-base* 10))
1920            (format-write-field stream (princ-to-string number) w 1 0 #\space t)))))))
1921#|
1922(defun format-exponent-marker (number)
1923  (if (typep number *read-default-float-format*)
1924      #\E
1925      (cond ((double-floatp) #\D)
1926            ((short-floatp number) #\S)
1927            ((single-floatp number) #\F)
1928            ((long-floatp) #\L))))
1929|#
1930(eval-when (eval compile #-bccl load)
1931  (defmacro format-exponent-marker (number)
1932    `(float-exponent-char ,number))
1933)
1934
1935;;;Here we prevent the scale factor from shifting all significance out of
1936;;;a number to the right.  We allow insignificant zeroes to be shifted in
1937;;;to the left right, athough it is an error to specify k and d such that this
1938;;;occurs.  Perhaps we should detect both these condtions and flag them as
1939;;;errors.  As for now, we let the user get away with it, and merely guarantee
1940;;;that at least one significant digit will appear.
1941;;; THE ABOVE COMMENT no longer applies
1942
1943(defun format-exp-aux (stream number w d e k ovf pad marker atsign &optional string exp)
1944  (when (not k) (setq k 1))
1945  (if (not (or w d e marker (neq k 1)))
1946    (print-a-float number stream t)
1947    (prog () 
1948      (when d
1949        (when (or (minusp d)
1950                  (and (plusp k)(>= k (+ d 2)))
1951                  (and (minusp k)(< k (- d))))
1952          (format-error "incompatible values for k and d")))
1953      (when (not exp) (setq exp (accurate-scale-exponent (abs number))))
1954      AGAIN
1955      (let* ((expt (- exp k))
1956             (estr (let ((*print-base* 10))
1957                     (princ-to-string (abs expt))))
1958             (elen (max (length estr) (or e 0)))
1959             (spaceleft (if w (- w 2 elen) nil))
1960             (fwidth) scale)
1961        (when (and w (or atsign (minusp (float-sign number)))) ; 5/25
1962          (setq spaceleft (1- spaceleft)))
1963        (if w
1964          (progn 
1965          (setq fwidth (if d 
1966                         (if (> k 0)(+ d 2)(+ d k 1))
1967                         (if (> k 0) spaceleft (+ spaceleft k))))
1968          (when (minusp exp) ; i don't claim to understand this
1969            (setq fwidth (- fwidth exp))
1970            (when (< k 0) (setq fwidth (1- fwidth)))))         
1971          (when (and d  (not (zerop number))) ; d and no w
1972            (setq scale (- 2  k exp))))  ; 2 used to be 1  - 5/31
1973        (when (or (and w e ovf (> elen e))(and w fwidth (not (plusp fwidth))))
1974          ;;exponent overflow
1975          (dotimes (i w) (declare (fixnum i)) (write-char ovf stream))
1976          (if (plusp fwidth)
1977            (return-from format-exp-aux nil)
1978            (setq fwidth nil)))
1979        (when (not string)
1980          (multiple-value-bind (new-string before-pt) (flonum-to-string number fwidth 
1981                                                                        (if (not fwidth) d)
1982                                                                        (if (not fwidth) scale))
1983            (setq string new-string)
1984            (when scale (setq before-pt (- (+ 1 before-pt) k scale))) ; sign right?           
1985            (when (neq exp before-pt)
1986              ;(print (list 'agn exp before-pt))
1987              ;(setq string new-string)
1988              (setq exp before-pt)
1989              (go again))))
1990          (let ((strlen (length string)))
1991            (when w
1992              (if d 
1993                (setq spaceleft (- spaceleft (+ d 2)))
1994                (if (< k 1)
1995                  (setq spaceleft (- spaceleft (+ 2 (- k)(max strlen 1))))
1996                  (setq spaceleft (- spaceleft (+ 1 k (max 1 (- strlen k))))))))
1997            (when (and w (< spaceleft 0))
1998              (if (and ovf (or (plusp k)(< spaceleft -1)))           
1999                (progn (dotimes (i w) (declare (fixnum i)) (write-char ovf stream))
2000                       (return-from format-exp-aux nil))))
2001            (when w
2002              (dotimes (i  spaceleft)
2003                (declare (fixnum i))
2004                (write-char pad stream)))
2005            (if (minusp (float-sign number)) ; 5/25
2006              (write-char #\- stream)
2007              (if atsign (write-char #\+ stream)))
2008            (cond 
2009             ((< k 1)
2010              (when (not (minusp spaceleft))(write-char #\0 stream))
2011              (write-char #\. stream)
2012              (dotimes (i (- k))
2013                (write-char #\0 stream))
2014              (if (and (eq strlen 0)(not d))
2015                (write-char #\0 stream)
2016                (stream-write-entire-string stream string))
2017              (if d
2018                (dotimes (i (- (+ d k) strlen))
2019                  (write-char #\0 stream))))
2020             (t 
2021              (write-string string stream :start 0 :end (min k strlen))
2022              (dotimes (i (- k strlen))
2023                (write-char #\0 stream))                   
2024              (write-char #\. stream)
2025              (when (> strlen k)
2026                (write-string string stream :start k :end strlen))
2027              (if (not d) 
2028                (when (<= strlen k)(write-char #\0 stream))
2029                (dotimes (i (1+ (- d k (max 0 (- strlen k)))))
2030                  (write-char #\0 stream)))))
2031            (write-char (if marker
2032                          marker
2033                          (format-exponent-marker number))
2034                        stream)
2035            (write-char (if (minusp expt) #\- #\+) stream)
2036            (when e 
2037              ;;zero-fill before exponent if necessary
2038              (dotimes (i (- e (length estr)))
2039                (declare (fixnum i))
2040                (write-char #\0 stream)))
2041            (stream-write-entire-string stream estr))))))
2042#|
2043; (format t "~7,3,,-2e" 8.88) s.b. .009e+3
2044; (format t "~10,5,,2e" 8.888888888) ; "88.8889E-1"
2045; (format t "~10,5,,-2e" 8.88)   "0.00888E+3"
2046; (format t "~10,5,,-2e" .00123445) ; "0.00123E+0"
2047; (format t "~10,5,,-3e" .00123445) ; "0.00012E+1"
2048; (format t "~10,,,-2e" .123445)
2049; (format t "~10,5,,2e" .0012349999e-4)
2050; (format t "~10,5,,2e" 9.9999999)
2051; (format t "~10,5,,2e" 0.0)
2052; (format t "~10,5,,0e" 40000000.0)
2053; (format t "~10,5,,2e" 9.9999999)
2054; (format t "~7,,,-2e" 8.88) s.b. .009e+3 ??
2055; (format t "~10,,,2e" 8.888888)
2056; (format t "~10,,,-2e" 8.88)
2057; (format t "~10,,,-2e" 0.0)
2058; (format t "~10,,,2e" 0.0)
2059; (format t "~10,,,2e" 9.9999999)
2060; (format t "~10,,,2e" 9.9999999e100)
2061; (format t "~10,5,3,2,'xe" 10e100)
2062; (format t "~9,3,2,-2e" 1100.0)
2063(defun foo (x)
2064  (format nil
2065          "~9,2,1,,'*e|~10,3,2,2,'?,,'$e|~9,3,2,-2,'%@e|~9,2e"
2066          x x x x))
2067|#
2068
2069
2070;;; General Floating Point -  ~G
2071
2072(defformat #\G format-general-float (stream colon atsign &rest parms)
2073  (declare (dynamic-extent parms))
2074  (when colon
2075    (format-error "Colon flag not allowed"))
2076  (with-format-parameters parms ((w nil) (d nil) (e nil) (k nil) (ovf nil) (pad #\space) (marker nil))
2077    (let ((number (pop-format-arg)))
2078      ;;The Excelsior edition does not say what to do if
2079      ;;the argument is not a float.  Here, we adopt the
2080      ;;conventions used by ~F and ~E.
2081      (if (floatp number)
2082        (format-general-aux stream number w d e k ovf pad marker atsign)
2083        (if (rationalp number)
2084          (format-general-aux stream (coerce number 'float) w d e k ovf pad marker atsign)
2085          (let ((*print-base* 10))
2086            (format-write-field stream (princ-to-string number) w 1 0 #\space t)))))))
2087
2088#|
2089; completely broken
2090(defun foo (x)
2091  (format nil
2092          "~9,2,1,,'*g|~10,3,2,2,'?,,'$g|~9,3,2,-2,'%@g|~9,2g"
2093          x x x x))
2094|#
2095
2096
2097(defun format-general-aux (stream number w d e k ovf pad marker atsign)
2098  (multiple-value-bind (str n #|after-pt|#)(flonum-to-string number)
2099    ;;Default d if omitted.  The procedure is taken directly
2100    ;;from the definition given in the manual, and is not
2101    ;;very efficient, since we generate the digits twice.
2102    ;;Future maintainers are encouraged to improve on this.
2103    (let* ((d2 (or d (max (length str) (min n 7))))
2104           (ee (if e (+ e 2) 4))
2105           (ww (if w (- w ee) nil))
2106           (dd (- d2 n)))
2107      (cond ((<= 0 dd d2)
2108             ; this causes us to print 1.0 as 1. - seems weird
2109             (format-fixed-aux stream number ww dd nil ovf pad atsign)
2110             (dotimes (i ee) (declare (fixnum i)) (write-char #\space stream)))
2111            (t (format-exp-aux stream number w d e (or k 1) ovf pad marker atsign nil n))))))
2112
2113
2114;;; Dollars floating-point format  ~$
2115
2116(defformat #\$ format-dollars (stream colon atsign &rest parms)
2117  (declare (dynamic-extent parms))
2118  (with-format-parameters parms ((d 2) (n 1) (w 0) (pad #\space))
2119    (let* ((number (float (pop-format-arg)))
2120           (signstr (if (minusp (float-sign number)) "-" (if atsign "+" "")))
2121           (spaceleft)
2122           strlen)
2123      (multiple-value-bind (str before-pt after-pt) (flonum-to-string number nil d)
2124        (setq strlen (length str))
2125        (setq spaceleft (- w (+ (length signstr) (max before-pt n) 1 d)))
2126        (when colon (stream-write-entire-string stream signstr))
2127        (dotimes (i spaceleft) (write-char pad stream))
2128        (unless colon (stream-write-entire-string stream signstr))
2129        (cond
2130         ((> before-pt 0)
2131          (dotimes (i (- n before-pt))
2132            (write-char #\0 stream))
2133          (cond ((> strlen before-pt)
2134                 (write-string str stream :start 0 :end before-pt)
2135                 (write-char #\. stream)
2136                 (write-string str stream :start before-pt :end strlen)
2137                 (dotimes (i (- d (- strlen before-pt)))
2138                   (write-char #\0 stream)))
2139                (t ; 0's after
2140                 (stream-write-entire-string stream str)
2141                 (dotimes (i (-  before-pt strlen))
2142                   (write-char #\0 stream))
2143                 (write-char #\. stream)
2144                 (dotimes (i d)
2145                   (write-char #\0 stream)))))
2146         (t (dotimes (i n)
2147              (write-char #\0 stream))
2148            (write-char #\. stream)
2149            (dotimes (i (- before-pt))
2150              (write-char #\0 stream))
2151            (stream-write-entire-string stream str)
2152            (dotimes (i (+ d after-pt))
2153              (write-char #\0 stream))))))))
2154
2155(defun y-or-n-p (&optional format-string &rest arguments &aux response)
2156  "Y-OR-N-P prints the message, if any, and reads characters from
2157   *QUERY-IO* until the user enters y or Y as an affirmative, or either
2158   n or N as a negative answer. It asks again if you enter any other
2159   characters."
2160  (declare (dynamic-extent arguments))
2161  (with-terminal-input
2162      (clear-input *query-io*)
2163      (loop
2164        (when format-string
2165          (fresh-line *query-io*)
2166          (apply 'format *query-io* format-string arguments))
2167        (princ " (y or n)  " *query-io*)
2168        (setq response (read-char *query-io*))
2169        ;; Consume input up to trailing newline
2170        (when (peek-char #\NewLine *query-io* nil)
2171          ;; And consume the #\newline
2172          (read-char *query-io*))
2173        (clear-input *query-io*)
2174        (if (char-equal response #\y) (return t))
2175        (if (char-equal response #\n) (return nil))
2176        (format *query-io* "Please answer y or n."))))
2177
2178(defun yes-or-no-p (&optional format-string &rest arguments &aux response)
2179  "YES-OR-NO-P is similar to Y-OR-N-P, except that it clears the
2180   input buffer, beeps, and uses READ-LINE to get the strings
2181   YES or NO."
2182  (declare (dynamic-extent arguments))
2183  (with-terminal-input
2184      (loop
2185        (when format-string
2186          (fresh-line *query-io*)
2187          (apply 'format *query-io* format-string arguments))
2188        (princ " (yes or no)  " *query-io*)
2189        (format *query-io* "~A" #\Bell)
2190        (setq response (read-line *query-io*))
2191        (clear-input *query-io*)
2192        (when response
2193          (setq response (string-trim wsp response))
2194          (if (string-equal response "yes") (return t))
2195          (if (string-equal response "no") (return nil))
2196          (format *query-io* "Please answer yes or no.")))))
2197
2198
2199;; Compile-time format-scanning support.
2200;;
2201;; All this assumes it's called from the compiler, but it has to be kept in sync with code
2202;; here more than with the code in the compiler, so keep it in here.
2203
2204(defun note-format-scan-option (cell)
2205  (when cell
2206    (if (null (cdr cell))
2207      (setf (car cell) *format-arguments* (cdr cell) *format-arguments-variance*)
2208      (let* ((new-args *format-arguments*)
2209             (new-var *format-arguments-variance*)
2210             (new-max (length new-args))
2211             (old-args (car cell))
2212             (old-var (cdr cell))
2213             (old-max (length old-args))
2214             (min (min (- new-max new-var) (- old-max old-var))))
2215        (if (>= new-max old-max)
2216          (setf (car cell) new-args (cdr cell) (- new-max min))
2217          (setf (cdr cell) (- old-max min))))))
2218  cell)
2219
2220(defmacro with-format-scan-options ((var) &body body)
2221  (let ((cell (gensym)))
2222    ;; CELL is used to record range of arg variations that should be deferred til the end
2223    ;; of BODY because they represent possible non-local exits.
2224    `(let* ((,cell (cons nil nil))
2225            (,var ,cell))
2226       (declare (dynamic-extent ,cell))
2227       (prog1
2228           (progn
2229             ,@body)
2230         (setq *format-arguments* (car ,cell)
2231               *format-arguments-variance* (cdr ,cell))))))
2232
2233(defvar *format-escape-options* nil)
2234
2235(defun nx1-check-format-call (control-string format-arguments &optional (env *nx-lexical-environment*))
2236  "Format-arguments are expressions that will evaluate to the actual arguments.
2237  Pre-scan process the format string, nx1-whine if find errors"
2238  (let* ((*nx-lexical-environment* env)
2239         (*format-top-level* t)
2240         (*logical-block-xp* nil)
2241         (*format-pprint* nil)
2242         (*format-justification-semi* nil))
2243    (let ((error (catch 'format-error
2244                   (format-scan control-string format-arguments 0)
2245                   nil)))
2246      (when error
2247        (setf (cadar error) (concatenate 'string (cadar error) " in format string:"))
2248        (nx1-whine :format-error (nreverse error))
2249        t))))
2250
2251(defun format-scan (string args var)
2252  (let ((*format-original-arguments* args)
2253        (*format-arguments* args)
2254        (*format-arguments-variance* var)
2255        (*format-colon-rest* 'error)
2256        (*format-control-string* (ensure-simple-string string)))
2257    (with-format-scan-options (*format-escape-options*)
2258      (catch 'format-escape
2259        (sub-format-scan 0 (length *format-control-string*))
2260        (note-format-scan-option *format-escape-options*)))
2261    (when (> (length *format-arguments*) *format-arguments-variance*)
2262      (format-error "Too many format arguments"))))
2263
2264(defun sub-format-scan (i end)
2265  (let ((*format-index* i)
2266        (*format-length* end)
2267        (string *format-control-string*))
2268    (loop while (setq *format-index* (position #\~ string :start *format-index* :end end)) do
2269      (multiple-value-bind (params colon atsign char) (parse-format-operation t)
2270        (setq char (char-upcase char))
2271        (let ((code (%char-code char)))
2272          (unless (and (< -1 code (length *format-char-table*))
2273                       (svref *format-char-table* code))
2274            (format-error "Unknown directive ~c" char)))
2275        (format-scan-directive char colon atsign params)
2276        (incf *format-index*)))))
2277
2278(defun nx-could-be-type (form type &optional transformed &aux (env *nx-lexical-environment*))
2279  (unless transformed (setq form (nx-transform form env)))
2280  (if (nx-form-constant-p form env)
2281    (typep (nx-form-constant-value form env) type env)
2282    (not (types-disjoint-p (nx-form-type form env) type env))))
2283
2284(defun format-require-type (form type &optional description)
2285  (unless (nx-could-be-type form type)
2286    (format-error "~a must be of type ~s" (or description form) type)))
2287
2288
2289(defun format-scan-directive (char colon atsign parms)
2290  (ecase char
2291    ((#\% #\& #\~ #\|)
2292     (with-format-parameters parms ((repeat-count 1))
2293       (format-no-flags colon atsign)
2294       (format-require-type repeat-count '(integer 0))))
2295    ((#\newline #\return)
2296     (with-format-parameters parms ()
2297       (when (and atsign colon) (format-error "~:@<newline> is undefined"))
2298       (unless colon
2299         (format-eat-whitespace))))
2300    ((#\P)
2301     (with-format-parameters parms ()
2302       (when colon
2303         (loop with end = *format-arguments*
2304            for list on *format-original-arguments*
2305            when (eq (cdr list) end) return (setq *format-arguments* list)
2306            finally (if (> (or *format-arguments-variance* 0) 0)
2307                        (decf *format-arguments-variance*)
2308                        (format-error "No previous argument"))))
2309       (pop-format-arg)))
2310    ((#\A #\S)
2311     (with-format-parameters parms ((mincol 0) (colinc 1) (minpad 0) (padchar #\space))
2312       (format-require-type mincol 'integer "mincol (first parameter)")
2313       (format-require-type colinc '(integer 1) "colinc (second parameter)")
2314       (format-require-type minpad 'integer "minpad (third parameter)")
2315       (format-require-type padchar '(or (integer 0 #.char-code-limit) character) "padchar (fourth parameter)"))
2316     (pop-format-arg))
2317    ((#\I)
2318     (with-format-parameters parms ((n 0))
2319       (format-no-flags nil atsign)
2320       (format-no-semi char)
2321       (format-require-type n 'real)))
2322    ((#\_)
2323     (with-format-parameters parms ()
2324       (format-no-semi char)))
2325    ((#\T)
2326     (with-format-parameters parms ((colnum 1) (colinc 1))
2327       (when colon
2328         (format-no-semi char t))
2329       (format-require-type colnum 'integer "colnum (first parameter)")
2330       (format-require-type colinc 'integer "colinc (second parameter)")))
2331    ((#\W)
2332     (with-format-parameters parms ()
2333       (format-no-semi #\W))
2334     (pop-format-arg))
2335    ((#\C)
2336     (with-format-parameters parms ())
2337     (format-require-type (pop-format-arg) '(or character fixnum (string 1))))
2338    ((#\D #\B #\O #\X #\R)
2339     (when (eql char #\R)
2340       (let ((radix (pop parms)))
2341         (when radix
2342           (format-require-type radix '(integer 2 36)))))
2343     (with-format-parameters parms ((mincol 0) (padchar #\space) (commachar #\,) (commainterval 3))
2344       (format-require-type mincol 'integer "mincol (first parameter)")
2345       (format-require-type padchar 'character "padchar (second parameter)")
2346       (format-require-type commachar 'character "comma char (third parameter)")
2347       (format-require-type commainterval 'integer "comma interval (fourth parameter)"))
2348     (pop-format-arg))
2349    ((#\F)
2350     (format-no-flags colon nil)
2351     (with-format-parameters parms ((w nil) (d nil) (k nil) (ovf nil) (pad #\space))
2352       (format-require-type w '(or null (integer 0)) "w (first parameter)")
2353       (format-require-type d '(or null (integer 0)) "d (second parameter)")
2354       (format-require-type k '(or null integer) "k (third parameter)")
2355       (format-require-type ovf '(or null character) "overflowchar (fourth parameter)")
2356       (format-require-type pad '(or null character) "padchar (fifth parameter)"))
2357     (pop-format-arg))
2358    ((#\E #\G)
2359     (format-no-flags colon nil)
2360     (with-format-parameters parms ((w nil) (d nil) (e nil) (k 1) (ovf nil) (pad #\space) (marker nil))
2361       (format-require-type w '(or null (integer 0)) "w (first parameter)")
2362       (format-require-type d '(or null (integer 0)) "d (second parameter)")
2363       (format-require-type e '(or null (integer 0)) "e (third parameter)")
2364       (format-require-type k '(or null integer) "k (fourth parameter)")
2365       (format-require-type ovf '(or null character) "overflowchar (fifth parameter)")
2366       (format-require-type pad '(or null character) "padchar (sixth parameter)")
2367       (format-require-type marker '(or null character) "exponentchar (seventh parameter)"))
2368     (pop-format-arg))
2369    ((#\$)
2370     (with-format-parameters parms ((d 2) (n 1) (w 0) (pad #\space))
2371       (format-require-type d '(or null (integer 0)) "d (first parameter)")
2372       (format-require-type n '(or null (integer 0)) "n (second parameter)")
2373       (format-require-type w '(or null (integer 0)) "w (third parameter)")
2374       (format-require-type pad '(or null character) "pad (fourth parameter)"))
2375     (format-require-type (pop-format-arg) 'real))
2376    ((#\*)
2377     (with-format-parameters parms ((count nil))
2378       (when count
2379         (format-require-type count 'integer "count parameter"))
2380       (if (typep (setq count (nx-transform count)) '(or null integer))
2381         (format-scan-goto colon atsign count)
2382         ;; Else can't tell how much going back or forth, could be anywhere.
2383         (setq *format-arguments* *format-original-arguments*
2384               *format-arguments-variance* (length *format-arguments*)))))
2385    ((#\?)
2386     (with-format-parameters parms ()
2387       (format-no-flags colon nil))
2388     (let ((string (pop-format-arg)))
2389       (format-require-type string '(or string function))
2390       (if atsign
2391         (setq *format-arguments-variance* (length *format-arguments*))
2392         (let ((arg (pop-format-arg)))
2393           (format-require-type arg 'list)))))
2394    ((#\/)
2395     (let* ((string *format-control-string*)
2396            (ipos (1+ *format-index*))
2397            (epos (format-find-char #\/ ipos *format-length*)))
2398       (when (not epos) (format-error "Unmatched ~~/"))
2399       (let* ((cpos (format-find-char #\: ipos epos))
2400              (name (if cpos
2401                      (prog1
2402                          (string-upcase (%substr string ipos cpos))
2403                        (when (eql #\: (schar string (%i+ 1 cpos)))
2404                          (setq cpos (%i+ cpos 1)))
2405                        (setq ipos (%i+ cpos 1)))
2406                      "CL-USER"))
2407              (package (find-package name))
2408              (sym (and package (find-symbol (string-upcase (%substr string ipos epos)) package)))
2409              (arg (pop-format-arg)))
2410         (setq *format-index* epos) ; or 1+ epos?
2411         ;; TODO: should we complain if the symbol doesn't exit?  Perhaps it will be defined
2412         ;; later, and to detect that would need to intern it.  What if the package doesn't exist?
2413         ;; Would need to extend :undefined-function warnings to handle previously-undefined package.
2414         (when sym
2415           (when (nx1-check-typed-call sym (list* '*standard-output* arg colon atsign parms))
2416             ;; Whined, just get out now.
2417             (throw 'format-error nil))))))
2418    ((#\[)
2419     (when (and colon atsign) (format-error  "~~:@[ undefined"))
2420     (format-nextchar)
2421     (cond (colon
2422            (format-scan-boolean-condition parms))
2423           (atsign
2424            (format-scan-funny-condition parms))
2425           (t (format-scan-untagged-condition parms))))
2426    ((#\()
2427     (with-format-parameters parms ()
2428       (format-nextchar)
2429       (multiple-value-bind (prev tilde parms colon atsign) (format-find-command '(#\)))
2430         (with-format-parameters parms () (format-no-flags colon atsign))
2431         (sub-format-scan prev tilde))))
2432    ((#\^)
2433     (format-no-flags nil atsign)
2434     (with-format-parameters parms ((p1 nil) (p2 nil) (p3 nil))
2435       (let ((val (nx-transform (cond (p3
2436                                       (if (every (lambda (p) (nx-could-be-type p 'real)) parms)
2437                                         ;; If the params could also be chars, don't know enough to constant fold
2438                                         ;; anyway, so this test will do.
2439                                         `(< ,p1 ,p2 ,p3)
2440                                         (if (every (lambda (p) (nx-could-be-type p 'character)) parms)
2441                                           `(char< ,p1 ,p2 ,p3)
2442                                           ;; At least one can't be real, at least one can't be char.
2443                                           (format-error "Wrong type of parameters for three-way comparison"))))
2444                                      (p2 `(equal ,p1 ,p2))
2445                                      (p1 `(eq ,p1 0))
2446                                      (t (null (if colon *format-colon-rest* *format-arguments*)))))))
2447         (when val
2448           (note-format-scan-option *format-escape-options*)
2449           (unless (nx-could-be-type val 'null t)
2450             (throw 'format-escape t))))))
2451    ((#\{)
2452     (with-format-parameters parms ((max-iter -1))
2453       (format-require-type max-iter 'integer "max-iter parameter")
2454       (format-nextchar)
2455       (multiple-value-bind (prev tilde end-parms end-colon end-atsign) (format-find-command '(#\}))
2456         (declare (ignore end-colon))
2457         (with-format-parameters end-parms () (format-no-flags nil end-atsign))
2458         (when (= prev tilde)
2459           ;; Use an argument as the control string if ~{~} is empty
2460           (let ((string (pop-format-arg)))
2461             (unless (nx-could-be-type string '(or string function))
2462               (format-error "Control string is not a string or function"))))
2463         ;; Could try to actually scan the iteration if string is a compile-time string,
2464         ;; by that seems unlikely.
2465         (if atsign
2466           (setq *format-arguments-variance* (length *format-arguments*))
2467           (format-require-type (pop-format-arg) 'list)))))
2468    ((#\<)
2469     (multiple-value-bind (start tilde eparms ecolon eatsign) (format-find-command '(#\>))
2470       (declare (ignore tilde eparms eatsign))
2471       (setq *format-index* start)
2472       (if ecolon
2473         (format-logical-block-scan colon atsign parms)
2474         (format-justification-scan colon atsign parms))))
2475    ))
2476
2477(defun format-justification-scan (colon atsign parms)
2478  (declare (ignore colon atsign))
2479  (with-format-parameters parms ((mincol 0) (colinc 1) (minpad 0) (padchar #\space))
2480    (format-require-type mincol 'integer "mincol (first parameter)")
2481    (format-require-type colinc '(integer 1) "colinc (second parameter)")
2482    (format-require-type minpad 'integer "minpad (third parameter)")
2483    (format-require-type padchar `(or character (integer 0 #.char-code-limit)) "padchar (fourth parameter)"))
2484  (let ((first-parms nil) (first-colon nil) (count 0))
2485    (with-format-scan-options (*format-escape-options*)
2486      (loop
2487         (format-nextchar)
2488         (multiple-value-bind (prev tilde parms colon atsign cmd)
2489             (format-find-command '(#\; #\>) nil T)
2490           (if (and (eql count 0) (eql cmd #\;) colon)
2491             (progn
2492               (format-no-flags nil atsign)
2493               (setq first-colon t)
2494               (setq *format-index* tilde)
2495               (setq first-parms (nth-value 2 (format-find-command '(#\; #\>) t T))))
2496             (with-format-parameters parms ()
2497               (format-no-flags colon atsign)))
2498           (when (catch 'format-escape
2499                   (sub-format-scan prev tilde)
2500                   nil)
2501             (unless (eq cmd #\>) (format-find-command '(#\>) nil t))
2502             (return))
2503           (incf count)
2504           (when (eq cmd #\>)
2505             (return))))
2506      (note-format-scan-option *format-escape-options*))
2507    (when first-colon
2508      (when *format-pprint*
2509        (format-error "Justification illegal in this context"))
2510      (setq *format-justification-semi* t)
2511      (with-format-parameters first-parms ((spare 0) (linel 0))
2512        (format-require-type spare 'integer "spare (first parameter)")
2513        (format-require-type linel 'integer "line length (second parameter)")))))
2514     
2515
2516
2517(defun format-logical-block-scan (colon atsign params)
2518  (declare (ignore colon))
2519  (with-format-parameters params ()
2520    (format-no-semi #\<))
2521    ;; First section can be termined by ~@;
2522  (let ((format-string *format-control-string*)
2523        (prefix "")
2524        (suffix "")
2525        (body-string nil))
2526    (multiple-value-bind (start1 tilde parms1 colon1 atsign1 cmd) (format-find-command  '(#\; #\>))
2527      (setq body-string (%substr format-string (1+ start1) tilde))
2528      (with-format-parameters parms1 ())
2529      (when (eq cmd #\;)
2530        (format-no-flags colon1 nil)
2531        (setq prefix body-string)
2532        (multiple-value-setq (start1 tilde parms1 colon1 atsign1 cmd) (format-find-command '(#\; #\>)))
2533        (with-format-parameters parms1 ())
2534        (setq body-string (%substr format-string (1+ start1) tilde))
2535        (when (eq cmd #\;)
2536          (format-no-flags colon1 atsign1)
2537          (multiple-value-setq (start1 tilde parms1 colon1 atsign1 cmd) (format-find-command  '(#\; #\>)))
2538          (with-format-parameters parms1 ())
2539          (setq suffix (%substr format-string (1+ start1) tilde))
2540          (when (eq cmd #\;)
2541            (format-error "Too many sections")))))
2542    (flet ((format-check-simple (str where)
2543             (when (and str (or (%str-member #\~ str) (%str-member #\newline str)))
2544               (format-error "~A must be simple" where))))
2545      (format-check-simple prefix "Prefix")
2546      (format-check-simple suffix "Suffix"))
2547    (if atsign
2548      (let ((*logical-block-p* t))
2549        (format-scan body-string *format-arguments* *format-arguments-variance*)
2550        (setq *format-arguments* nil *format-arguments-variance* 0))
2551      ;; If no atsign, we just use up an arg.  Don't bother trying to scan it, unlikely to be a constant.
2552      (when *format-arguments*
2553        (pop-format-arg)))))
2554
2555
2556(defun format-scan-untagged-condition (parms)
2557  (with-format-parameters parms ((index nil))
2558    (unless index (setq index (pop-format-arg)))
2559    (format-require-type index 'integer)
2560    (with-format-scan-options (cond-options)
2561      (loop with default = nil do
2562           (multiple-value-bind (prev tilde parms colon atsign cmd)
2563               (format-find-command '(#\; #\]))
2564             (when (and default (eq cmd #\;))
2565               (format-error "~:; must be the last clause"))
2566             (with-format-parameters parms ()
2567               (format-no-flags (if (eq cmd #\]) colon) atsign)
2568               (when colon (setq default t)))
2569             (format-scan-optional-clause prev tilde cond-options)
2570             (when (eq cmd #\])
2571               (unless default    ;; Could just skip the whole thing
2572                 (note-format-scan-option cond-options))
2573               (return))
2574             (format-nextchar))))))
2575
2576(defun format-scan-funny-condition (parms)
2577  (with-format-parameters parms ())
2578  (multiple-value-bind (prev tilde parms colon atsign) (format-find-command '(#\]))
2579    (with-format-parameters parms ()
2580      (format-no-flags colon atsign))
2581    (when (null *format-arguments*) (pop-format-arg)) ;; invoke std error
2582    (with-format-scan-options (cond-options)
2583      (let ((arg (nx-transform (car *format-arguments*))))
2584        (when (nx-could-be-type arg 'null t)
2585          (let ((*format-arguments* *format-arguments*)
2586                (*format-arguments-variance* *format-arguments-variance*))
2587            (when (eql *format-arguments-variance* (length *format-arguments*))
2588              (decf *format-arguments-variance*))
2589            (pop *format-arguments*)
2590            (note-format-scan-option cond-options)))
2591        (when arg
2592          (format-scan-optional-clause prev tilde cond-options))))))
2593
2594
2595(defun format-scan-boolean-condition (parms)
2596  (with-format-parameters parms ())
2597  (multiple-value-bind (prev tilde parms colon atsign cmd) (format-find-command '(#\; #\]))
2598    (when (eq cmd #\])
2599      (format-error "Two clauses separated by ~~; are required for ~~:["))
2600    (with-format-parameters parms () (format-no-flags colon atsign))
2601    (format-nextchar)
2602    (with-format-scan-options (cond-options)
2603      (let ((arg (nx-transform (pop-format-arg))))
2604        (when (nx-could-be-type arg 'null t)
2605          (format-scan-optional-clause prev tilde cond-options))
2606        (multiple-value-bind (prev tilde parms colon atsign) (format-find-command '(#\]))
2607          (with-format-parameters parms () (format-no-flags colon atsign))
2608          (when arg
2609            (format-scan-optional-clause prev tilde cond-options)))))))
2610
2611
2612(defun format-scan-optional-clause (start end cond-option)
2613  (let ((*format-arguments* *format-arguments*)
2614        (*format-arguments-variance* *format-arguments-variance*))
2615    ;; Let the branch points collect in outer *format-escape-options*, but don't
2616    ;; throw there because need to consider the other clauses.
2617    (catch 'format-escape
2618      (sub-format-scan start end)
2619      (note-format-scan-option cond-option)
2620      nil)))
2621
2622(defun format-scan-goto (colon atsign count)
2623  (if atsign 
2624    (let* ((orig *format-original-arguments*)
2625           (orig-pos (- (length orig) (length *format-arguments*)))
2626           (new-pos (or count 0)))
2627      (format-no-flags colon nil)
2628      ;; After backing up, we may not use up all the arguments we backed over,
2629      ;; so even though real variance here is 0, increase variance so we don't
2630      ;; complain.
2631      (setq *format-arguments-variance* (max 0 (- orig-pos new-pos)))
2632      (setq *format-arguments* (nthcdr-no-overflow new-pos orig)))
2633    (progn
2634      (when (null count)(setq count 1))
2635      (when colon (setq count (- count)))
2636      (cond ((> count 0)
2637             (when (> count (length *format-arguments*))
2638               (format-error "Target position for ~~* out of bounds"))
2639             (setq *format-arguments* (nthcdr count *format-arguments*))
2640             (when *format-arguments-variance*
2641               (setq *format-arguments-variance*
2642                     (min *format-arguments-variance* (length *format-arguments*)))))
2643            ((< count 0)
2644             (let* ((orig *format-original-arguments*)
2645                    (orig-pos (- (length orig) (length *format-arguments*)))
2646                    (pos (+ orig-pos count))
2647                    (max-pos (+ pos (or *format-arguments-variance* 0))))
2648               (when (< max-pos 0)
2649                 (format-error "Target position for ~~* out of bounds"))
2650               ;; After backing up, we may not use up all the arguments we backed over.
2651               ;; Increase the variance allowed to cover those arguments, so we don't
2652               ;; complain about not using them.  E.g. (format t "~a ~a ~2:*~a" 1 2) should
2653               ;; be ok, (format t "~a ~a ~2:*" 1 2) should warn.
2654               (setq max-pos (1- (- max-pos count)))
2655               (if (< pos 0)
2656                 (setq *format-arguments* orig
2657                       *format-arguments-variance* max-pos)
2658                 (setq *format-arguments* (nthcdr pos orig)
2659                       *format-arguments-variance* (- max-pos pos)))))))))
Note: See TracBrowser for help on using the repository browser.