source: trunk/source/lib/dumplisp.lisp @ 8932

Last change on this file since 8932 was 8932, checked in by gz, 11 years ago

Fix for bugs #263 and #238:

  • %unix-file-kind takes a native namestring, so don't try to nativize it.
  • file-namestring-from-parts on the other hand takes escaped strings, so don't try to re-escape them.
  • Add a comment in %path-std-quotes explaining the convention.
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 8.7 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17; Dumplisp.lisp
18
19(in-package "CCL")
20
21(defvar *save-exit-functions* nil 
22  "List of (0-arg)functions to call before saving memory image")
23
24(defvar *restore-lisp-functions* nil
25  "List of (0-arg)functions to call after restoring saved image")
26
27
28(declaim (special *lisp-system-pointer-functions*)) ; defined in l1-init.
29
30(defun kill-lisp-pointers ()
31  (setq * nil ** nil *** nil + nil ++ nil +++ nil - nil
32        / nil // nil /// nil
33         @ nil)
34  (clear-open-file-streams)
35  (setf (*%saved-method-var%*) nil)
36  (setq *%periodic-tasks%* nil)
37  (setq *event-dispatch-task* nil)
38  (setq *interactive-abort-process* nil)
39  )
40
41
42(defun save-application (filename
43                         &rest rest
44                         &key toplevel-function
45                         init-file
46                         error-handler application-class
47                         clear-clos-caches
48                         (purify t)
49                         impurify
50                         (mode #o644)
51                         prepend-kernel
52                         )
53  (declare (ignore toplevel-function error-handler application-class
54                   resources clear-clos-caches init-file impurify
55                   mode prepend-kernel))
56  (unless (probe-file (make-pathname :defaults nil
57                                     :directory (pathname-directory (translate-logical-pathname filename))))
58    (error "Directory containing ~s does not exist." filename))
59  (let* ((kind (%unix-file-kind (native-translated-namestring filename))))
60    (when (and kind (not (eq kind :file )))
61      (error "~S is not a regular file." filename)))
62  (let* ((ip *initial-process*)
63         (cp *current-process*))
64    (when (process-verify-quit ip)
65      (process-interrupt ip
66                         #'(lambda ()
67                             (process-exit-application
68                              *current-process*
69                              #'(lambda ()
70                                  (apply #'%save-application-internal
71                                         filename
72                                         :purify purify
73                                         rest)))))
74      (unless (eq cp ip)
75        (process-kill cp)))))
76
77(defun %save-application-internal (filename &key
78                                            toplevel-function  ;????
79                                            error-handler ; meaningless unless application-class or *application* not lisp-development..
80                                            application-class
81                                            (mode #o644)
82                                            (purify t)
83                                            (impurify nil)
84                                            (init-file nil init-file-p)
85                                            (clear-clos-caches t)
86                                            (prepend-kernel nil))
87  (when (and application-class (neq  (class-of *application*)
88                                     (if (symbolp application-class)
89                                       (find-class application-class)
90                                       application-class)))
91    (setq *application* (make-instance application-class)))
92  (when (not toplevel-function)
93    (setq toplevel-function 
94          #'(lambda ()
95              (toplevel-function *application*
96                                 (if init-file-p
97                                   init-file
98                                   (application-init-file *application*))))))
99  (when error-handler
100    (make-application-error-handler *application* error-handler))
101 
102  (if clear-clos-caches (clear-clos-caches))
103  (save-image (let ((fd (open-dumplisp-file filename
104                                            :mode mode
105                                            :prepend-kernel prepend-kernel)))
106                #'(lambda () (%save-application fd
107                                                (logior (if impurify 2 0)
108                                                        (if purify 1 0)))))
109              toplevel-function))
110
111(defun save-image (save-function toplevel-function)
112  (let ((toplevel #'(lambda () (#_exit -1))))
113      (%set-toplevel #'(lambda ()
114                         (setf (interrupt-level) -1)
115                         (%set-toplevel toplevel)       ; in case *save-exit-functions* error
116                         (dolist (f *save-exit-functions*)
117                           (funcall f))
118                         (kill-lisp-pointers)
119                         (%set-toplevel
120                          #'(lambda ()
121                              (%set-toplevel #'(lambda ()
122                                                 (setf (interrupt-level) 0)
123                                                 (funcall toplevel-function)))
124                              (restore-lisp-pointers)))   ; do startup stuff
125                         (funcall save-function)))
126      (toplevel)))
127
128;;; If file in-fd contains an embedded lisp image, return the file position
129;;; of the start of that image; otherwise, return the file's length.
130(defun skip-embedded-image (in-fd)
131  (let* ((len (fd-lseek in-fd 0 #$SEEK_END)))
132    (if (< len 0)
133      (%errno-disp len)
134      (%stack-block ((trailer 16))
135        (let* ((trailer-pos (fd-lseek in-fd -16 #$SEEK_CUR)))
136          (if (< trailer-pos 0)
137            len
138            (if (not (= 16 (the fixnum (fd-read in-fd trailer 16))))
139              len
140              (if (not (dotimes (i 12 t)
141                         (unless (eql (char-code (schar "OpenMCLImage" i))
142                                      (%get-unsigned-byte trailer i))
143                           (return nil))))
144                len
145                (let* ((header-pos (fd-lseek in-fd
146                                             (%get-signed-long
147                                              trailer
148                                              12)
149                                             #$SEEK_CUR)))
150                  (if (< header-pos 0)
151                    len
152                    header-pos))))))))))
153                 
154 
155(defun %prepend-file (out-fd in-fd len)
156  (declare (fixnum out-fd in-fd len))
157  (fd-lseek in-fd 0 #$SEEK_SET)
158  (let* ((bufsize (ash 1 15)))
159    (%stack-block ((buf bufsize))
160      (loop
161          (when (zerop len) (return))
162          (let* ((nread (fd-read in-fd buf (min len bufsize))))
163            (declare (fixnum nread))
164            (if (< nread 0)
165              (%errno-disp nread))
166            (let* ((nwritten (fd-write out-fd buf nread)))
167              (declare (fixnum nwritten))
168              (unless (= nwritten nread)
169                (error "I/O error writing to fd ~d" out-fd)))
170            (decf len nread))))))
171   
172(defun open-dumplisp-file (path &key (mode #o666) prepend-kernel)
173  (let* ((prepend-fd (if prepend-kernel (fd-open
174                                         (if (eq prepend-kernel t)
175                                           (car *command-line-argument-list*)
176                                           (native-translated-namestring
177                                            (pathname prepend-kernel)))
178                                         #$O_RDONLY)))
179         (prepend-len (if (and prepend-fd (>= prepend-fd 0))
180                        (skip-embedded-image prepend-fd)))
181         (filename (native-translated-namestring path)))
182    (when (probe-file filename)
183      (%delete-file filename))
184    (when prepend-fd
185      (setq mode (logior #o111 mode)))
186    (let* ((image-fd (fd-open filename (logior #$O_WRONLY #$O_CREAT) mode)))
187      (unless (>= image-fd 0) (signal-file-error image-fd filename))
188      (fd-chmod image-fd mode)
189      (when prepend-fd
190        (%prepend-file image-fd prepend-fd prepend-len))
191      image-fd)))
192
193
194(defun %save-application (fd &optional (flags 1))
195  (let* ((err (%%save-application flags fd)))
196    (unless (eql err 0)
197      (%err-disp err))))
198 
199
200(defun restore-lisp-pointers ()
201  (%revive-system-locks)
202  (refresh-external-entrypoints)
203  (restore-pascal-functions)
204  (dolist (f (reverse *lisp-system-pointer-functions*))
205    (funcall f))
206  (let ((restore-lisp-fns *restore-lisp-functions*)
207        (user-pointer-fns *lisp-user-pointer-functions*)
208        (lisp-startup-fns *lisp-startup-functions*))
209    (unwind-protect
210      (with-simple-restart (abort "Abort (possibly crucial) startup functions.")
211        (let ((call-with-restart
212               #'(lambda (f)
213                   (with-simple-restart 
214                     (continue "Skip (possibly crucial) startup function ~s."
215                               (if (symbolp f) f (function-name f)))
216                     (funcall f)))))
217          (dolist (f restore-lisp-fns) (funcall call-with-restart f))
218          (dolist (f (reverse user-pointer-fns)) (funcall call-with-restart f))
219          (dolist (f (reverse lisp-startup-fns)) (funcall call-with-restart f))))
220      (setf (interrupt-level) 0)))
221  nil)
222
223
224(defun restore-pascal-functions ()
225  (reset-callback-storage)
226  (when (simple-vector-p %pascal-functions%)
227    (dotimes (i (length %pascal-functions%))
228      (let ((pfe (%svref %pascal-functions% i)))
229        (when (vectorp pfe)
230          (let* ((name (pfe.sym pfe))
231                 (descriptor (pfe.routine-descriptor pfe)))
232            (%revive-macptr descriptor)
233            (%setf-macptr descriptor (make-callback-trampoline i (pfe.proc-info pfe)))
234            (when name
235              (set name descriptor))))))))
236
Note: See TracBrowser for help on using the repository browser.