source: trunk/source/lib/backtrace.lisp @ 12193

Last change on this file since 12193 was 12193, checked in by gz, 10 years ago

merge r12190 into trunk

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 30.9 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;;; backtrace.lisp
18;;; low-level support for stack-backtrace printing
19
20(in-package "CCL")
21
22#+ppc-target (require "PPC-BACKTRACE")
23#+x86-target (require "X86-BACKTRACE")
24
25
26(defparameter *backtrace-show-internal-frames* nil)
27(defparameter *backtrace-print-level* 2)
28(defparameter *backtrace-print-length* 5)
29
30(defparameter *backtrace-format* #+ccl-0711 :direct #-ccl-0711 :traditional
31  "If :TRADITIONAL, shows calls to non-toplevel functions using FUNCALL, and shows frame address values.
32   If :DIRECT, uses a more streamlined format.")
33
34(defun context-for-suspended-tcr (tcr)
35  (let ((frame-ptr (%tcr-frame-ptr tcr)))
36    (new-backtrace-info nil
37                        frame-ptr ;; youngest - not used
38                        frame-ptr ;; oldest - not used
39                        tcr
40                        nil       ;; condition - not used
41                        frame-ptr ;; current
42                        #+ppc-target *fake-stack-frames*
43                        #+x86-target frame-ptr
44                        (%fixnum-ref tcr target::tcr.db-link)
45                        0         ;; break level - not used
46                        )))
47 
48
49(defun backtrace-as-list (&key
50                          context
51                          process
52                          origin
53                          (count target::target-most-positive-fixnum)
54                          (start-frame-number 0)
55                          (print-level *backtrace-print-level*)
56                          (print-length *backtrace-print-length*)
57                          (show-internal-frames *backtrace-show-internal-frames*))
58  "Returns a list representing the backtrace.
59Each element in the list is a list that describes the call in one stack frame:
60   (function arg1 arg2 ...)
61The arguments are represented by strings, the function is a symbol or a function
62object."
63  (when (null count) (setq count target::target-most-positive-fixnum))
64  (when (and context process (neq (bt.tcr context) (process-tcr process)))
65    (error "Context ~s doesn't correspond to the process ~s" context process))
66  (let* ((tcr (cond (context (bt.tcr context))
67                    (process (process-tcr process))
68                    (t (%current-tcr))))
69         (*backtrace-print-level* print-level)
70         (*backtrace-print-length* print-length)
71         (*backtrace-show-internal-frames* show-internal-frames)
72         (*backtrace-format* :list))
73    (if (eq tcr (%current-tcr))
74      (%backtrace-as-list-internal context (or origin (%get-frame-ptr)) count start-frame-number)
75      (unwind-protect
76           (progn
77             (%suspend-tcr tcr)
78             (unless context
79               (setq context (context-for-suspended-tcr tcr)))
80             (%backtrace-as-list-internal context (or origin (bt.current context)) count start-frame-number))
81        (%resume-tcr tcr)))))
82
83
84;;; This PRINTS the call history on *DEBUG-IO*.  It's more dangerous
85;;; (because of stack consing) to actually return it.
86                               
87(defun print-call-history (&key context
88                                process
89                                origin
90                                (detailed-p t)
91                                (count target::target-most-positive-fixnum)
92                                (start-frame-number 0)
93                                (stream *debug-io*)
94                                (print-level *backtrace-print-level*)
95                                (print-length *backtrace-print-length*)
96                                (show-internal-frames *backtrace-show-internal-frames*)
97                                (format *backtrace-format*))
98  (when (null count) (setq count target::target-most-positive-fixnum))
99  (when (and context process (neq (bt.tcr context) (process-tcr process)))
100    (error "Context ~s doesn't correspond to the process ~s" context process))
101  (let* ((tcr (cond (context (bt.tcr context))
102                    (process (process-tcr process))
103                    (t (%current-tcr))))
104         (*backtrace-print-level* print-level)
105         (*backtrace-print-length* print-length)
106         (*backtrace-show-internal-frames* show-internal-frames)
107         (*backtrace-format* format))
108    (if (eq tcr (%current-tcr))
109      (%print-call-history-internal context (or origin (%get-frame-ptr)) detailed-p count start-frame-number stream)
110      (unwind-protect
111           (progn
112             (%suspend-tcr tcr)
113             (unless context
114               (setq context (context-for-suspended-tcr tcr)))
115             (%print-call-history-internal context (or origin (bt.current context)) detailed-p count start-frame-number stream))
116        (%resume-tcr tcr)))
117    (values)))
118
119(defun map-call-frames (fn &key context
120                           (origin (%get-frame-ptr))
121                           (start-frame-number 0)
122                           (include-internal nil))
123  (let* ((tcr (if context (bt.tcr context) (%current-tcr))))
124    (if (eq tcr (%current-tcr))
125      (%map-call-frames-internal fn context origin include-internal start-frame-number)
126      (unwind-protect
127           (progn
128             (%suspend-tcr tcr)
129             (%map-call-frames-internal fn context origin include-internal start-frame-number))
130        (%resume-tcr tcr))))
131  nil)
132
133(defun %show-stack-frame (p context lfun pc)
134  (handler-case
135      (multiple-value-bind (count vsp parent-vsp) (count-values-in-frame p context)
136        (declare (fixnum count))
137        (dotimes (i count)
138          (multiple-value-bind (var type name) 
139                               (nth-value-in-frame p i context lfun pc vsp parent-vsp)
140            (format t "~&  ~D " i)
141            (when name (format t "~s" name))
142            (let* ((*print-length* *backtrace-print-length*)
143                   (*print-level* *backtrace-print-level*))
144              (format t ": ~s" var))
145            (when type (format t " (~S)" type)))))
146    (error () (format t "#<error printing frame>")))
147  (terpri)
148  (terpri))
149
150(defun %show-args-and-locals (p context lfun pc)
151  (handler-case
152      (let* ((unavailable (cons nil nil)))
153        (multiple-value-bind (args locals) (arguments-and-locals context p lfun pc unavailable)
154          (case *backtrace-format*
155            (:direct
156               (format t "~&     Arguments: ~:s" (arglist-from-map lfun)))
157            (t (format t "~&  ~s" (arglist-from-map lfun))))
158          (let* ((*print-length* *backtrace-print-length*)
159                 (*print-level* *backtrace-print-level*))
160            (flet ((show-pair (pair prefix)
161                     (destructuring-bind (name . val) pair
162                       (format t "~&~a~s: " prefix name)
163                       (if (eq val unavailable)
164                         (format t "#<Unavailable>")
165                         (format t "~s" val)))))
166              (case *backtrace-format*
167                (:direct
168                   (when args
169                     (dolist (arg args)
170                       (show-pair arg "       ")))
171                   (when locals
172                     ;; This shows all bindings (including specials), but help on debugger
173                     ;; commands refers to "locals", so say both words...
174                     (format t "~&     Local bindings:")
175                     (dolist (loc locals)
176                       (show-pair loc "       "))))
177                (t
178                   (dolist (arg args)
179                     (show-pair arg "   "))
180                   (terpri)
181                   (terpri)
182                   (dolist (loc locals)
183                     (show-pair loc "  "))))))))
184    (error () (format t "#<error printing args and locals>")))
185  (terpri)
186  (terpri))
187
188
189(defun backtrace-call-arguments (context cfp lfun pc)
190  (nconc (let* ((name (function-name lfun)))
191           (if (function-is-current-definition? lfun)
192             (list name)
193             (case *backtrace-format*
194               (:direct
195                  (list (format nil "~s" (or name lfun))))
196               (:list
197                  (list 'funcall (format nil "~s" (or name lfun))))
198               (t (list 'funcall `(function ,(concatenate 'string "#<" (%lfun-name-string lfun) ">")))))))
199         (backtrace-supplied-args context cfp lfun pc)))
200
201(defun backtrace-supplied-args (context frame lfun pc)
202  (if (and pc (<= pc target::arg-check-trap-pc-limit))
203    (arg-check-call-arguments frame lfun)
204    (multiple-value-bind (params valid) (arglist-from-map lfun)
205      (if (not valid)
206        '("???")
207        (let ((args (arguments-and-locals context frame lfun pc)) ;overkill, but will do.
208              (state :required)
209              (strings ()))
210          (flet ((collect (arg)
211                   (let* ((*print-length* *backtrace-print-length*)
212                          (*print-level* *backtrace-print-level*))
213                     (push (format nil "~s" arg) strings))))
214            (dolist (param params)
215              (if (or (member param lambda-list-keywords) (eq param '&lexpr))
216                (setq state param)
217                (let* ((pair (pop args))
218                       (value (cdr pair)))
219                  (case state
220                    (&lexpr
221                       (with-list-from-lexpr (rest value)
222                         (dolist (r rest) (collect r)))
223                       (return))
224                    (&rest
225                       (dolist (r value) (collect r))
226                       (return))
227                    (&key (collect param)))
228                  (if (eq value (%unbound-marker))
229                    (push "?" strings)
230                    (collect value))))))
231          (nreverse strings))))))
232
233;;; Return a list of "interesting" frame addresses in context, most
234;;; recent first.
235(defun %stack-frames-in-context (context &optional (include-internal *backtrace-show-internal-frames*))
236  (collect ((frames))
237    (do* ((p (bt.youngest context) (parent-frame p context))
238          (q (bt.oldest context)))
239         ((eql p q) (frames))
240      (when (or (not (catch-csp-p p context)) include-internal)
241        (when (or (cfp-lfun p) include-internal)
242          (frames p))))))
243   
244(defun %map-call-frames-internal (fn context origin include-internal skip-initial)
245  (let ((*standard-output* *debug-io*)
246        (*print-circle* nil)
247        (p origin)
248        (q (last-frame-ptr context)))
249    (dotimes (i skip-initial)
250      (setq p (parent-frame p context))
251      (when (or (null p) (eq p q) (%stack< q p context))
252        (return (setq p nil))))
253    (do* ((p p (parent-frame p context)))
254         ((or (null p) (eq p q) (%stack< q p context)) nil)
255      (when (or include-internal
256                (and (not (catch-csp-p p context)) (cfp-lfun p)))
257        (funcall fn p)))))
258
259(defun %backtrace-as-list-internal (context origin count skip-initial)
260  (unless (eq (last-frame-ptr context origin) (last-frame-ptr context))
261    (error "Origin ~s is not in the stack of ~s" origin context))
262  (let ((*print-catch-errors* t)
263        (p origin)
264        (q (last-frame-ptr context)))
265    (dotimes (i skip-initial)
266      (setq p (parent-frame p context))
267      (when (or (null p) (eq p q) (%stack< q p context))
268        (return (setq p nil))))
269    (do* ((frame-number (or skip-initial 0) (1+ frame-number))
270          (i 0 (1+ i))
271          (p p (parent-frame p context))
272          (r '()))
273        ((or (null p) (eq p q) (%stack< q p context)
274             (>= i count))
275         (nreverse r))
276      (declare (fixnum frame-number i))
277      (when (or (not (catch-csp-p p context))
278                *backtrace-show-internal-frames*)
279        (multiple-value-bind (lfun pc) (cfp-lfun p)
280          (when (or lfun *backtrace-show-internal-frames*)
281            (push
282             (if lfun
283               (backtrace-call-arguments context p lfun pc)
284               "?????")
285             r)))))))
286
287 
288(defun %print-call-history-internal (context origin detailed-p
289                                             &optional (count target::target-most-positive-fixnum)
290                                                       (skip-initial 0)
291                                                       (stream *debug-io*))
292  (unless (eq (last-frame-ptr context origin) (last-frame-ptr context))
293    (error "Origin ~s is not in the stack of ~s" origin context))
294  (let ((*standard-output* stream)
295        (*print-circle* nil)
296        (*print-catch-errors* t)
297        (p origin)
298        (q (last-frame-ptr context)))
299    (dotimes (i skip-initial)
300      (setq p (parent-frame p context))
301      (when (or (null p) (eq p q) (%stack< q p context))
302        (return (setq p nil))))
303    (do* ((frame-number (or skip-initial 0) (1+ frame-number))
304          (i 0 (1+ i))
305          (p p (parent-frame p context)))
306         ((or (null p) (eq p q) (%stack< q p context)
307              (>= i count))
308          (values))
309      (declare (fixnum frame-number i))
310      (when (or (not (catch-csp-p p context))
311                *backtrace-show-internal-frames*)
312        (multiple-value-bind (lfun pc) (cfp-lfun p)
313          (when (or lfun *backtrace-show-internal-frames*)
314            (unless (and (typep detailed-p 'fixnum)
315                         (not (= (the fixnum detailed-p) frame-number)))
316              (%show-stack-frame-label frame-number p context lfun pc detailed-p)
317              (when detailed-p
318                (if (eq detailed-p :raw)
319                  (%show-stack-frame p context lfun pc)
320                  (%show-args-and-locals p context lfun pc))))))))))
321
322(defun %show-stack-frame-label (frame-number p context lfun pc detailed-p)
323  (case *backtrace-format*
324    (:direct
325       (let ((call (backtrace-call-arguments context p lfun pc)))
326         (format t "~&~3D: ~a ~a~@d~:[~; [Exception]~]"
327                 frame-number
328                 (if lfun
329                   (if detailed-p (car call) call)
330                   "<non-function frame>")
331                 "at pc "
332                 pc
333                 (exception-frame-p p))))
334    (t (format t "~&~c(~x) : ~D ~a ~d"
335                      (if (exception-frame-p p)  #\* #\space)
336                      (index->address p) frame-number
337                      (if lfun (backtrace-call-arguments context p lfun pc))
338                      pc))))
339
340
341(defun %access-lisp-data (vstack-index)
342  (%fixnum-ref vstack-index))
343
344(defun %store-lisp-data (vstack-index value)
345  (setf (%fixnum-ref vstack-index) value))
346
347(defun closed-over-value (data)
348  (if (closed-over-value-p data)
349    (uvref data 0)
350    data))
351
352(defun set-closed-over-value (value-cell value)
353  (setf (uvref value-cell 0) value))
354
355
356
357;;; Act as if VSTACK-INDEX points at some lisp data & return that data.
358(defun access-lisp-data (vstack-index)
359  (closed-over-value (%access-lisp-data vstack-index)))
360
361(defun find-local-name (cellno lfun pc)
362  (let* ((n cellno))
363    (when lfun
364      (multiple-value-bind (mask where) (registers-used-by lfun pc)
365        (if (and where (< (1- where) n (+ where (logcount mask))))
366          (let ((j *saved-register-count*))
367            (decf n where)
368            (loop (loop (if (logbitp (decf j) mask) (return)))
369                  (if (< (decf n) 0) (return)))
370            (values (format nil "saved ~a" (aref *saved-register-names* j))
371                    nil))
372          (multiple-value-bind (nreq nopt restp nkeys junk optinitp junk ncells nclosed)
373                               (if lfun (function-args lfun))
374            (declare (ignore junk optinitp))
375            (if nkeys (setq nkeys (+ nkeys nkeys)))
376            (values
377             (if (and ncells (< n ncells))
378               (if (< n nclosed)
379                 :inherited
380                 (if (< (setq n (- n nclosed)) nreq)
381                   "required"
382                   (if (< (setq n (- n nreq)) nopt)
383                     "optional"
384                     (progn
385                       (setq n (- n nopt))
386                       (progn
387                         (if (and nkeys (< n nkeys))
388                           (if (not (logbitp 0 n)) ; a keyword
389                             "keyword"
390                             "key-supplied-p")
391                           (progn
392                             (if nkeys (setq n (- n nkeys)))
393                             (if (and restp (zerop n))
394                               "rest"
395                               "opt-supplied-p")))))))))
396             (match-local-name cellno (function-symbol-map lfun) pc))))))))
397
398(defun map-entry-value (context cfp lfun pc idx unavailable)
399  (declare (fixnum pc idx))
400  (let* ((info (function-symbol-map lfun)))
401    (if (null info)
402      unavailable
403      (let* ((addrs (cdr info))
404             (i (* 3 idx))
405             (addr (svref addrs i))
406             (startpc (svref addrs (the fixnum (+ i 1))))
407             (endpc (svref addrs (the fixnum (+ i 2)))))
408        (declare (fixnum i addr startpc endpc))
409        (if (or (< pc startpc)
410                (>= pc endpc))
411          unavailable
412          (let* ((value (if (= #o77 (ldb (byte 6 0) addr))
413                          (raw-frame-ref cfp context (ash addr (- (+ target::word-shift 6)))
414                                         unavailable)
415                          (find-register-argument-value context cfp addr unavailable))))
416            (if (typep value 'value-cell)
417              (uvref value 0)
418              value)))))))
419
420;;; Returns non-nil on success (not newval)
421(defun set-map-entry-value (context cfp lfun pc idx newval)
422  (declare (fixnum pc idx))
423  (let* ((unavailable (cons nil nil))
424         (value (map-entry-value context cfp lfun pc idx unavailable)))
425    (if (eq value unavailable)
426      nil
427      (if (typep value 'value-cell)
428        (progn (setf (uvref value 0) newval) t)
429
430        (let* ((addrs (cdr (function-symbol-map lfun)))
431               (addr (svref addrs (the fixnum (* 3 idx)))))
432          (declare (fixnum  addr))
433          (if (= #o77 (ldb (byte 6 0) addr))
434            (raw-frame-set cfp context (ash addr (- (+ target::word-shift 6))) newval)
435            (set-register-argument-value context cfp addr newval))
436          t)))))
437
438         
439(defun argument-value (context cfp lfun pc name &optional (quote t))
440  (declare (fixnum pc))
441  (let* ((info (function-symbol-map lfun))
442         (unavailable (%unbound-marker)))
443    (if (null info)
444      unavailable
445      (let* ((names (car info))
446             (addrs (cdr info)))
447        (do* ((nname (1- (length names)) (1- nname))
448              (naddr (- (length addrs) 3) (- naddr 3)))
449             ((or (< nname 0) (< naddr 0)) unavailable)
450          (declare (fixnum nname naddr))
451          (when (eq (svref names nname) name)
452            (let* ((value
453                    (let* ((addr (svref addrs naddr))
454                           (startpc (svref addrs (the fixnum (1+ naddr))))
455                           (endpc (svref addrs (the fixnum (+ naddr 2)))))
456                      (declare (fixnum addr startpc endpc))
457                      (if (or (< pc startpc)
458                              (>= pc endpc))
459                        unavailable
460                        (if (= #o77 (ldb (byte 6 0) addr))
461                          (raw-frame-ref cfp context (ash addr (- (+ target::word-shift 6)))
462                                         unavailable)
463                          (find-register-argument-value context cfp addr unavailable))))))
464              (if (typep value 'value-cell)
465                (setq value (uvref value 0)))
466              (if (or (not quote) (self-evaluating-p value))
467                (return value)
468                (return (list 'quote value))))))))))
469
470
471
472(defun raw-frame-ref (cfp context index bad)
473  (%raw-frame-ref cfp context index bad))
474
475(defun raw-frame-set (cfp context index new)
476  (%raw-frame-set cfp context index new))
477 
478(defun find-register-argument-value (context cfp regval bad)
479  (%find-register-argument-value context cfp regval bad))
480
481(defun set-register-argument-value (context cfp regval newval)
482  (%set-register-argument-value context cfp regval newval))
483
484   
485
486(defun dbg-form (frame-number)
487  (when *break-frame*
488    (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
489      (if (and cfp (not (catch-csp-p cfp nil)))
490        (multiple-value-bind (function pc)
491            (cfp-lfun cfp)
492          (if (and function
493                   (function-is-current-definition? function))
494            (block %cfp-form
495              (collect ((form))
496                (multiple-value-bind (nreq nopt restp keys allow-other-keys
497                                           optinit lexprp ncells nclosed)
498                    (function-args function)
499                  (declare (ignore ncells))
500                  (unless (or lexprp restp (> 0 nclosed) (> 0 nopt) keys allow-other-keys
501                              optinit)
502                    (let* ((name (function-name function)))
503                      (multiple-value-bind (arglist win)
504                          (arglist-from-map function)
505                      (when (and win name (symbolp name))
506                        (form name)
507                        (dotimes (i nreq)
508                          (let* ((val (argument-value nil cfp function pc (pop arglist))))
509                            (if (closed-over-value-p val)
510                              (setq val (%svref val target::value-cell.value-cell)))
511                            (if (eq val (%unbound-marker))
512                              (return-from %cfp-form nil))
513                            (form val))))))))
514                (form)))))))))
515
516(defun function-args (lfun)
517  "Returns 9 values, as follows:
518     req = number of required arguments
519     opt = number of optional arguments
520     restp = t if rest arg
521     keys = number of keyword arguments or NIL if &key not mentioned
522     allow-other-keys = t if &allow-other-keys present
523     optinit = t if any optional arg has non-nil default value or supplied-p
524               variable
525     lexprp = t if function is a lexpr, in which case all other values are
526              undefined.
527     ncells = number of stack frame cells used by all arguments.
528     nclosed = number of inherited values (now counted distinctly from required)
529     All numeric values (but ncells) are mod 64."
530  (let* ((bits (lfun-bits lfun))
531         (req (ldb $lfbits-numreq bits))
532         (opt (ldb $lfbits-numopt bits))
533         (restp (logbitp $lfbits-rest-bit bits))
534         (keyvect (lfun-keyvect lfun))
535         (keys (and keyvect (length keyvect)))
536         (allow-other-keys (logbitp $lfbits-aok-bit bits))
537         (optinit (logbitp $lfbits-optinit-bit bits))
538         (lexprp (logbitp $lfbits-restv-bit bits))
539         (nclosed (ldb $lfbits-numinh bits)))
540    (values req opt restp keys allow-other-keys optinit lexprp
541            (unless (or lexprp)
542              (+ req opt (if restp 1 0) (if keys (+ keys keys) 0)
543                 (if optinit opt 0) nclosed))
544            nclosed)))
545
546;;; If we can tell reliably, return the function's minimum number of
547;;; non-inherited arguments, the maximum number of such arguments (or NIL),
548;;; and the actual number of such arguments.  We "can't tell" if either
549;;; of the arguments to this function are null, and we can't tell reliably
550;;; if any of the lfbits fields are full.
551(defun min-max-actual-args (fn nargs)
552  (let* ((lfbits (if (and fn nargs)
553                   (lfun-bits fn)
554                   -1))
555         (raw-req (ldb $lfbits-numreq lfbits))
556         (raw-opt (ldb $lfbits-numopt lfbits))
557         (raw-inh (ldb $lfbits-numinh lfbits)))
558    (declare (fixnum raw-req raw-opt raw-inh))
559    (if (or (eql raw-req (1- (ash 1 (byte-size $lfbits-numreq))))
560            (eql raw-opt (1- (ash 1 (byte-size $lfbits-numopt))))
561            (eql raw-inh (1- (ash 1 (byte-size $lfbits-numinh)))))
562      (values nil nil nil)
563      (values raw-req
564              (unless (or (lfun-keyvect fn)
565                          (logbitp $lfbits-rest-bit lfbits)
566                          (logbitp $lfbits-restv-bit lfbits))
567                (+ raw-req raw-opt))
568              (- nargs raw-inh)))))
569
570
571
572(defun closed-over-value-p (value)
573  (eql target::subtag-value-cell (typecode value)))
574
575
576(defun variables-in-scope (lfun pc)
577  ;; Return a list of all symbol names "in scope" in the function lfun
578  ;; at relative program counter PC, using the function's symbol map.
579  ;; The list will be ordered so that least-recent bindings appear first.
580  ;; Return a list of the matching symbol map entries as a second value
581  (when pc
582    (locally (declare (fixnum pc))
583      (let* ((map (function-symbol-map lfun))
584             (names (car map))
585             (info (cdr map)))
586        (when map
587          (let* ((vars ())
588                 (indices ()))
589            (dotimes (i (length names) (values vars indices))
590              (let* ((start-pc (aref info (1+ (* 3 i))))
591                     (end-pc (aref info (+ 2 (* 3 i)))))
592                (declare (fixnum start-pc end-pc))
593                (when (and (>= pc start-pc)
594                           (< pc end-pc))
595                  (push i indices)
596                  (push (svref names i) vars))))))))))
597
598
599(defun arg-value (context cfp lfun pc unavailable name)
600  (multiple-value-bind (vars map-indices) (variables-in-scope lfun pc)
601    (multiple-value-bind (valid req opt rest keys)
602        (arg-names-from-map lfun pc)
603      (if valid
604        (let* ((nargs (+ (length req) (length opt) (if rest 1 0) (length keys)))
605               (pos (position name vars)))
606          (if (and pos (< pos nargs))
607            (map-entry-value context cfp lfun pc (nth pos map-indices) unavailable)
608            unavailable))
609        unavailable))))
610
611(defun local-value (context cfp lfun pc unavailable name)
612  (multiple-value-bind (vars map-indices) (variables-in-scope lfun pc)
613    (multiple-value-bind (valid req opt rest keys)
614        (arg-names-from-map lfun pc)
615      (if valid
616        (let* ((nargs (+ (length req) (length opt) (if rest 1 0) (length keys)))
617               (names (nthcdr nargs vars))
618               (indices (nthcdr nargs map-indices))
619               (pos (if (typep name 'unsigned-byte)
620                      name
621                      (position name names :from-end t))))
622          (if pos
623            (map-entry-value context cfp lfun pc (nth pos indices) unavailable)
624            unavailable))
625        unavailable))))
626
627(defun set-arg-value (context cfp lfun pc name new)
628  (multiple-value-bind (vars map-indices) (variables-in-scope lfun pc)
629    (multiple-value-bind (valid req opt rest keys)
630        (arg-names-from-map lfun pc)
631      (if valid
632        (let* ((nargs (+ (length req) (length opt) (if rest 1 0) (length keys)))
633               (pos (position name vars)))
634          (when (and pos (< pos nargs))
635            (set-map-entry-value context cfp lfun pc (nth pos map-indices) new)))))))
636
637(defun set-local-value (context cfp lfun pc name new)
638  (multiple-value-bind (vars map-indices) (variables-in-scope lfun pc)
639    (multiple-value-bind (valid req opt rest keys)
640        (arg-names-from-map lfun pc)
641      (if valid
642        (let* ((nargs (+ (length req) (length opt) (if rest 1 0) (length keys)))
643               (names (nthcdr nargs vars))
644               (indices (nthcdr nargs map-indices))
645               (pos (if (typep name 'unsigned-byte)
646                      name
647                      (position name names :from-end t))))
648          (if (and pos (< pos nargs))
649            (set-map-entry-value context cfp lfun pc (nth pos indices) new)))))))
650
651
652(defun arguments-and-locals (context cfp lfun pc &optional unavailable)
653  (multiple-value-bind (vars map-indices) (variables-in-scope lfun pc)
654    (collect ((args)
655              (inherited-indices)
656              (inherited-vars)
657              (locals))
658      (multiple-value-bind (valid req opt rest keys)
659          (arg-names-from-map lfun pc)
660        (when valid
661          (let* ((numinh (ldb $lfbits-numinh (lfun-bits lfun))))
662            (dotimes (i numinh)
663              (inherited-indices (pop map-indices))
664              (inherited-vars (pop vars))))
665          (let* ((nargs (+ (length req) (length opt) (if rest 1 0) (length keys)))
666                 (nlocals (- (length vars) nargs))
667                 (local-vars (append (nthcdr nargs vars) (inherited-vars)))
668                 (local-indices (append (nthcdr nargs map-indices) (inherited-indices)))
669                 (arg-vars (if (<= nlocals 0) vars (nbutlast vars nlocals)))
670                 (arg-indices (if (<= nlocals 0) map-indices (nbutlast map-indices nlocals))))
671            (flet ((get-arg-value (name)
672                     (let* ((pos (position name arg-vars :test #'eq)))
673                       (when pos
674                         (args (cons name (map-entry-value context cfp lfun pc (nth pos arg-indices) unavailable))))))
675                   (get-local-value (name)
676                     (when name
677                       (locals (cons name (map-entry-value context cfp lfun pc (pop local-indices) unavailable))))))
678              (dolist (name req)
679                (get-arg-value name))
680              (dolist (name opt)
681                (get-arg-value name))
682              (when rest
683                (get-arg-value rest))
684              (dolist (name keys)
685                (get-arg-value name))
686              (dolist (name local-vars)
687                (get-local-value name)))))
688        (values (args) (locals))))))
689                   
690           
691
692(defun safe-cell-value (val)
693  val)
694
695(defun closure-closed-over-values (closure)
696  (when (typep closure 'compiled-lexical-closure)
697    (let* ((inner (closure-function closure))
698           (nclosed (nth-value 8 (function-args inner)))
699           (names (car (function-symbol-map inner))))
700      (when nclosed
701        (collect ((cells))
702          (do* ((i (1- (length names)) (1- i))
703                (k 0 (1+ k))
704                (idx 2 (1+ idx)))
705               ((= k nclosed) (reverse (cells)))
706            (let* ((name (svref names i))
707                   (imm (nth-immediate closure idx)))
708              (cells (list name (if (closed-over-value-p imm)
709                                  (closed-over-value imm)
710                                  imm))))))))))
711
712     
713;;; Find the oldest binding frame that binds the same symbol as
714;;; FRAME in context.  If found, return the saved value of that
715;;; binding, else the value of the symbol in the context's thread.
716(defun oldest-binding-frame-value (context frame)
717  (let* ((oldest nil)
718         (binding-index (%fixnum-ref frame (ash 1 target::fixnum-shift))))
719    (do* ((db (db-link context) (%fixnum-ref db 0)))
720         ((eq frame db)
721          (if oldest
722            (%fixnum-ref oldest (ash 2 target::fixnum-shift))
723            (let* ((symbol (binding-index-symbol binding-index)))
724              (if context
725                (symbol-value-in-tcr symbol (bt.tcr context))
726                (%sym-value symbol)))))
727      (if (eq (%fixnum-ref db (ash 1 target::fixnum-shift)) binding-index)
728        (setq oldest db)))))
729
730(defun (setf oldest-binding-frame-value) (new context frame)
731  (let* ((oldest nil)
732         (binding-index (%fixnum-ref frame (ash 1 target::fixnum-shift))))
733    (do* ((db (db-link context) (%fixnum-ref db 0)))
734         ((eq frame db)
735          (if oldest
736            (setf (%fixnum-ref oldest (ash 2 target::fixnum-shift)) new)
737            (let* ((symbol (binding-index-symbol binding-index)))
738              (if context
739                (setf (symbol-value-in-tcr symbol (bt.tcr context)) new)
740                (%set-sym-value symbol new)))))
741      (if (eq (%fixnum-ref db (ash 1 target::fixnum-shift)) binding-index)
742        (setq oldest db)))))
743   
744
745
746;;; End of backtrace.lisp
Note: See TracBrowser for help on using the repository browser.