source: trunk/source/level-1/sysutils.lisp @ 14760

Last change on this file since 14760 was 14760, checked in by gb, 9 years ago

Move REQUIRE-STRUCTURE-TYPE to level-0.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 31.2 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18
19;; sysutils.lisp - things which have outgrown l1-utils
20
21(in-package "CCL")
22
23(eval-when (:execute :compile-toplevel)
24  (require 'level-2)
25  (require 'optimizers)
26  (require 'backquote)
27  (require 'defstruct-macros)
28  )
29
30;;; things might be clearer if this stuff were in l1-typesys?
31;;; Translation from type keywords to specific predicates.
32(eval-when (:execute :compile-toplevel)
33
34(defconstant type-pred-pairs
35  '((array . arrayp)
36    (atom . atom)
37    (base-string . base-string-p)
38    (bignum . bignump)
39    (bit . bitp)
40    (bit-vector . bit-vector-p)
41    (character . characterp)
42    (compiled-function . compiled-function-p)
43    (complex . complexp)
44    (cons . consp)
45    (double-float . double-float-p)
46    (fixnum . fixnump) ;not cl
47    (float . floatp)
48    (function . functionp)
49    (hash-table . hash-table-p)
50    (integer . integerp)
51    (real . realp)
52    (keyword . keywordp)
53    (list . listp)
54    (long-float . double-float-p)
55    (nil . false)
56    (null . null)
57    (number . numberp)
58    (package . packagep)
59    (pathname . pathnamep)
60    (logical-pathname . logical-pathname-p)
61    (random-state . random-state-p)
62    (ratio . ratiop)
63    (rational . rationalp)
64    (readtable . readtablep)
65    (sequence . sequencep)
66    (short-float . short-float-p)
67    (signed-byte . integerp)
68    (simple-array . simple-array-p)
69    (simple-base-string . simple-base-string-p)
70    (simple-bit-vector . simple-bit-vector-p)
71    (simple-string . simple-string-p)
72    (simple-vector . simple-vector-p)
73    (single-float . short-float-p)
74    (stream . streamp)
75    (string . stringp)
76    (base-char . base-char-p)
77    (extended-char . extended-char-p)
78    (structure-object . structurep)
79    (symbol . symbolp)
80    (t . true)
81    (unsigned-byte . unsigned-byte-p)
82    (vector . vectorp)
83    ))
84
85(defmacro init-type-predicates ()
86  `(dolist (pair ',type-pred-pairs)
87     (setf (type-predicate (car pair)) (cdr pair))
88     (let ((ctype (info-type-builtin (car pair))))       
89       (if (typep ctype 'numeric-ctype)
90         (setf (numeric-ctype-predicate ctype) (cdr pair))))))
91
92)
93
94(init-type-predicates)
95
96(defun unsigned-byte-8-p (n)
97  (and (fixnump n)
98       (locally (declare (fixnum n))
99         (and 
100          (>= n 0)
101          (< n #x100)))))
102
103(defun signed-byte-8-p (n)
104  (and (fixnump n)
105       (locally (declare (fixnum n))
106         (and 
107          (>= n -128)
108          (<= n 127)))))
109
110(defun unsigned-byte-16-p (n)
111  (and (fixnump n)
112       (locally (declare (fixnum n))
113         (and 
114          (>= n 0)
115          (< n #x10000)))))
116
117(defun signed-byte-16-p (n)
118  (and (fixnump n)
119       (locally (declare (fixnum n))
120         (and 
121          (>= n -32768)
122          (<= n 32767)))))
123
124(defun unsigned-byte-32-p (n)
125  (and (integerp n)
126       (>= n 0)
127       (<= n #xffffffff)))
128
129(defun signed-byte-32-p (n)
130  (and (integerp n)
131       (>= n  -2147483648)
132       (<= n 2147483647)))
133
134(eval-when (:load-toplevel :execute)
135  (let ((more-pairs
136         '(((unsigned-byte 8) . unsigned-byte-8-p)
137           ((signed-byte 8) . signed-byte-8-p)
138           ((unsigned-byte 16) . unsigned-byte-16-p)
139           ((signed-byte 16) . signed-byte-16-p)
140           ((unsigned-byte 32) . unsigned-byte-32-p)
141           ((signed-byte 32) . signed-byte-32-p))))         
142    (dolist (pair more-pairs)
143      (let ((ctype (info-type-builtin (car pair))))       
144        (if (typep ctype 'numeric-ctype) (setf (numeric-ctype-predicate ctype) (cdr pair))))))
145  )
146
147
148(defun specifier-type-known (type) 
149  (let ((ctype (specifier-type type)))
150    (if (typep ctype 'unknown-ctype)
151      (error "Unknown type specifier ~s." type)
152      (if (and (typep ctype 'numeric-ctype) ; complexp??
153               (eq 'integer (numeric-ctype-class ctype))
154               (not (numeric-ctype-predicate ctype)))
155        (setf (numeric-ctype-predicate ctype)(make-numeric-ctype-predicate ctype))))
156    ctype))
157
158
159(defun find-builtin-cell (type  &optional (create t))
160  (let ((cell (gethash type %builtin-type-cells%)))
161    (or cell
162        (when create
163          (setf (gethash type %builtin-type-cells%)
164                (cons type (or (info-type-builtin type)(specifier-type-known type))))))))
165
166
167; for now only called for builtin types or car = unsigned-byte, signed-byte, mod or integer
168
169(defun builtin-typep (form cell)
170  (unless (listp cell)
171    (setq cell (require-type cell 'list)))
172  (locally (declare (type list cell))
173    (let ((ctype (cdr cell))
174          (name (car cell)))
175      (when (not ctype)
176        (setq ctype (or (info-type-builtin name)(specifier-type-known name)))
177        (when ctype (setf (gethash (car cell) %builtin-type-cells%) cell))
178        (rplacd cell ctype))
179      (if ctype 
180        (if (and (typep ctype 'numeric-ctype)
181                 (numeric-ctype-predicate ctype))
182          ; doing this inline is a winner - at least if true
183          (funcall (numeric-ctype-predicate ctype) form)
184          (%%typep form ctype))
185        (typep form name)))))
186
187#|
188(defvar %find-classes% (make-hash-table :test 'eq))
189
190(defun find-class-cell (name create?)
191  (let ((cell (gethash name %find-classes%)))
192    (or cell
193        (and create?
194             (setf (gethash name %find-classes%) (cons name nil))))))
195|#
196
197;(setq *type-system-initialized* t)
198
199
200;; Type-of, typep, and a bunch of other predicates.
201
202;;; Data type predicates.
203
204;;; things might be clearer if this stuff were in l1-typesys?
205;;; Translation from type keywords to specific predicates.
206
207
208
209
210;necessary since standard-char-p, by definition, errors if not passed a char.
211(setf (type-predicate 'standard-char)
212      #'(lambda (form) (and (characterp form) (standard-char-p form))))
213
214(defun type-of (form)
215  "Return the type of OBJECT."
216  (case form
217    ((t) 'boolean)
218    ((0 1) 'bit)
219    (t
220     (typecase form
221       (standard-char 'standard-char)
222       (keyword 'keyword)
223       ;; Partition integers so that the negative cases
224       ;; are SIGNED-BYTE and the positive are UNSIGNED-BYTE
225       (fixnum
226        (if (< (the fixnum form) 0)
227          'fixnum
228          '(integer 0 #.target::target-most-positive-fixnum)))
229       (bignum
230        (if (< form 0)
231          'bignum
232          '(integer  #.(1+ target::target-most-positive-fixnum))))
233       ((or array complex) (type-specifier (ctype-of form)))
234       (single-float 'single-float)
235       (double-float 'double-float)
236       (t
237        (if (eql (typecode form) target::subtag-istruct)
238          (istruct-type-name form)
239          (let* ((class (class-of form)))
240            (or (%class-proper-name class)
241                class))))))))
242
243;;; Create the list-style description of an array.
244
245;made more specific by fry. slisp used  (mod 2) , etc.
246;Oh.
247; As much fun as this has been, I think it'd be really neat if
248; it returned a type specifier.
249
250(defun describe-array (array)
251  (if (arrayp array)
252    (type-specifier
253     (specifier-type
254      `(,(if (simple-array-p array) 'simple-array 'array) 
255        ,(array-element-type array) 
256        ,(array-dimensions array))))
257    (report-bad-arg array 'array)))
258 
259
260;;;; TYPEP and auxiliary functions.
261
262
263
264(defun type-specifier-p (form &aux sym)
265  (cond ((symbolp form)
266         (or (type-predicate form)
267             (structure-class-p form)
268             (%deftype-expander form)
269             (find-class form nil)
270             ))
271        ((consp form)
272         (setq sym (%car form))
273         (or (type-specifier-p sym)
274             (memq sym '(member satisfies mod))
275             (and (memq sym '(and or not))
276                  (dolist (spec (%cdr form) t)
277                    (unless (type-specifier-p spec) (return nil))))))
278        (t (typep form 'class))))
279
280(defun built-in-type-p (type)
281  (if (symbolp type)
282    (or (type-predicate type)
283        (let ((class (find-class type nil)))
284          (and class (typep class 'built-in-class))))
285    (and (consp type)
286         (or (and (memq (%car type) '(and or not))
287                  (every #'built-in-type-p (%cdr type)))
288             (memq (%car type) '(array simple-array vector simple-vector
289                                 string simple-string bit-vector simple-bit-vector 
290                                 complex integer mod signed-byte unsigned-byte
291                                 rational float short-float single-float
292                                 double-float long-float real member))))))
293
294(defun typep (object type &optional env)
295  "Is OBJECT of type TYPE?"
296  (let* ((pred (if (symbolp type) (type-predicate type))))
297    (if pred
298      (funcall pred object)
299      (values (%typep object (if env (specifier-type type env) type))))))
300
301
302
303;;; This is like check-type, except it returns the value rather than setf'ing
304;;; anything, and so can be done entirely out-of-line.
305(defun require-type (arg type)
306  (multiple-value-bind (win sure)
307      (ctypep  arg (specifier-type type))
308    (if (or win (not sure))
309      arg
310      (%kernel-restart $xwrongtype arg type))))
311
312
313
314;;; Might want to use an inverted mapping instead of (satisfies ccl::obscurely-named)
315(defun %require-type (arg predsym)
316  (if (funcall predsym arg)
317    arg
318    (%kernel-restart $xwrongtype arg (type-for-predicate predsym))))
319
320(defun %require-type-builtin (arg type-cell) 
321  (if (builtin-typep arg type-cell)
322    arg
323    (%kernel-restart $xwrongtype arg (car type-cell))))
324
325
326
327;;; In lieu of an inverted mapping, at least try to find cases involving
328;;; builtin numeric types and predicates associated with them.
329(defun type-for-predicate (pred)
330  (or (block find
331        (maphash #'(lambda (type ctype) (when (and (typep ctype 'numeric-ctype)
332                                                   (eq (numeric-ctype-predicate ctype)
333                                                       pred))
334                                          (return-from find type)))
335                 *builtin-type-info*))
336      `(satisfies ,pred)))
337
338
339
340; Subtypep.
341
342(defun subtypep (type1 type2 &optional env)
343  "Return two values indicating the relationship between type1 and type2.
344  If values are T and T, type1 definitely is a subtype of type2.
345  If values are NIL and T, type1 definitely is not a subtype of type2.
346  If values are NIL and NIL, it couldn't be determined."
347  (csubtypep (specifier-type type1 env) (specifier-type type2 env)))
348
349(defun types-disjoint-p (type1 type2 &optional env)
350  ;; Return true if types are guaranteed to be disjoint, nil if not disjoint or unknown.
351  (let ((ctype1 (if (typep type1 'ctype) type1 (specifier-type type1 env)))
352        (ctype2 (if (typep type2 'ctype) type2 (specifier-type type2 env))))
353    (eq *empty-type* (type-intersection ctype1 ctype2))))
354
355
356
357(defun preload-all-functions ()
358  nil)
359
360
361 ; used by arglist
362(defun temp-cons (a b)
363  (cons a b))
364
365
366
367
368(defun copy-into-float (src dest)
369  (%copy-double-float src dest))
370
371(queue-fixup
372 (defun fmakunbound (name)
373   "Make NAME have no global function definition."
374   (let* ((fname (validate-function-name name)))
375     (remhash fname %structure-refs%)
376     (%unfhave fname))
377   name))
378
379(defun frozen-definition-p (name)
380  (if (symbolp name)
381    (%ilogbitp $sym_fbit_frozen (%symbol-bits name))))
382
383(defun redefine-kernel-function (name)
384  (when (and *warn-if-redefine-kernel*
385             (frozen-definition-p name)
386             (or (lfunp (fboundp name))
387                 (and (not (consp name)) (macro-function name)))
388             (or (and (consp name) (neq (car name) 'setf))
389                 (let ((pkg (symbol-package (if (consp name) (cadr name) name))))
390                   (or (eq *common-lisp-package* pkg) (eq *ccl-package* pkg)))))
391    (cerror "Replace the definition of ~S."
392            "The function ~S is predefined in Clozure CL." name)
393    (unless (consp name)
394      (proclaim-inline nil name))))
395
396(defun fset (name function)
397  (setq function (require-type function 'function))
398  (when (symbolp name)
399    (when (special-operator-p name)
400      (error "Can not redefine a special-form: ~S ." name))
401    (when (macro-function name)
402      (cerror "Redefine the macro ~S as a function"
403              "The macro ~S is being redefined as a function." name)))
404; This lets us redefine %FHAVE.  Big fun.
405  (let ((fhave #'%fhave))
406    (redefine-kernel-function name)
407    (fmakunbound name)
408    (funcall fhave name function)
409    function))
410
411(defsetf symbol-function fset-symbol)
412(defsetf fdefinition fset)
413
414(defun (setf macro-function) (macro-fun name &optional env)
415  (declare (ignore env))
416  (unless (typep macro-fun 'function)
417    (report-bad-arg macro-fun 'function))
418  (if (special-operator-p name)
419    (error "Can not redefine a special-form: ~S ." name))
420  (when (and (fboundp name) (not (macro-function name)))
421    (warn "The function ~S is being redefined as a macro." name))
422  (redefine-kernel-function name)
423  (fmakunbound name)
424  (%macro-have name macro-fun)
425  macro-fun)
426
427(defun set-macro-function (name def)
428  (setf (macro-function name) def))
429
430
431
432
433;;; Arrays and vectors, including make-array.
434
435
436
437
438
439
440
441(defun char (string index)
442  "Given a string and a non-negative integer index less than the length of
443  the string, returns the character object representing the character at
444  that position in the string."
445  (if (typep string 'simple-string)
446    (schar (the simple-string string) index)
447    (if (stringp string)
448      (multiple-value-bind (data offset) (array-data-and-offset string)
449        (schar (the simple-string data) (+ index offset)))
450      (report-bad-arg string 'string))))
451
452(defun set-char (string index new-el)
453  (if (typep string 'simple-string)
454    (setf (schar string index) new-el)
455    (if (stringp string)
456      (multiple-value-bind (data offset) (array-data-and-offset string)
457        (setf (schar (the simple-string data) (+ index offset)) new-el))
458      (report-bad-arg string 'string))))
459
460(defun equalp (x y)
461  "Just like EQUAL, but more liberal in several respects.
462  Numbers may be of different types, as long as the values are identical
463  after coercion.  Characters may differ in alphabetic case.  Vectors and
464  arrays must have identical dimensions and EQUALP elements, but may differ
465  in their type restriction.
466  If one of x or y is a pathname and one is a string with the name of the
467  pathname then this will return T."
468  (cond ((eql x y) t)
469        ((characterp x) (and (characterp y) (eq (char-upcase x) (char-upcase y))))
470        ((numberp x) (and (numberp y) (= x y)))
471        ((consp x)
472         (and (consp y)
473              (equalp (car x) (car y))
474              (equalp (cdr x) (cdr y))))       
475        ((pathnamep x) (equal x y))
476        ((vectorp x)
477         (and (vectorp y)
478              (let ((length (length x)))
479                (when (eq length (length y))
480                  (dotimes (i length t)
481                    (declare (fixnum i))
482                    (let ((x-el (aref x i))
483                          (y-el (aref y i)))
484                      (unless (or (eq x-el y-el) (equalp x-el y-el))
485                        (return nil))))))))
486        ((arrayp x)
487         (and (arrayp y)
488              (let ((rank (array-rank x)) x-el y-el)
489                (and (eq (array-rank y) rank)
490                     (if (%izerop rank) (equalp (aref x) (aref y))
491                         (and
492                          (dotimes (i rank t)
493                            (declare (fixnum i))
494                            (unless (eq (array-dimension x i)
495                                        (array-dimension y i))
496                              (return nil)))
497                          (multiple-value-bind (x0 i) (array-data-and-offset x)
498                            (multiple-value-bind (y0 j) (array-data-and-offset y)
499                              (dotimes (count (array-total-size x) t)
500                                (declare (fixnum count))
501                                (setq x-el (uvref x0 i) y-el (uvref y0 j))
502                                (unless (or (eq x-el y-el) (equalp x-el y-el))
503                                  (return nil))
504                                (setq i (%i+ i 1) j (%i+ j 1)))))))))))
505        ((and (structurep x) (structurep y))
506         (let ((size (uvsize x)))
507           (and (eq size (uvsize y))
508                (dotimes (i size t)
509                  (declare (fixnum i))
510                  (unless (equalp (uvref x i) (uvref y i))
511                    (return nil))))))
512        ((and (hash-table-p x) (hash-table-p y))
513         (%hash-table-equalp x y))
514        ((and (random-state-p x) (random-state-p y))
515         (%random-state-equalp x y))
516        (t nil)))
517
518
519; The compiler (or some transforms) might want to do something more interesting
520; with these, but they have to exist as functions anyhow.
521
522
523
524(defun complement (function)
525  "Return a new function that returns T whenever FUNCTION returns NIL and
526   NIL whenever FUNCTION returns non-NIL."
527  (let ((f (coerce-to-function function))) ; keep poor compiler from consing value cell
528  #'(lambda (&rest args)
529      (declare (dynamic-extent args)) ; not tail-recursive anyway
530      (not (apply f args)))))
531
532; Special variables are evil, but I can't think of a better way to do this.
533
534(defparameter *outstanding-deferred-warnings* nil)
535
536(defun call-with-compilation-unit (thunk &key override)
537  (let* ((*outstanding-deferred-warnings* (%defer-warnings override)))
538    (multiple-value-prog1 (funcall thunk)
539      (report-deferred-warnings))))
540
541(defun %defer-warnings (override &aux (parent *outstanding-deferred-warnings*))
542  (when parent
543    (ensure-merged-deferred-warnings parent))
544  (%istruct 'deferred-warnings
545            (unless override parent)
546            nil
547            (make-hash-table :test #'eq)
548            nil))
549
550(defun ensure-merged-deferred-warnings (parent &aux (last (deferred-warnings.last-file parent)))
551  (when last
552    (setf (deferred-warnings.last-file parent) nil)
553    (let* ((child (car last)) ;; last = (deferred-warnings . file)
554           (warnings (deferred-warnings.warnings child))
555           (defs (deferred-warnings.defs child))
556           (parent-defs (deferred-warnings.defs parent))
557           (parent-warnings (deferred-warnings.warnings parent)))
558      (maphash (lambda (key val) (setf (gethash key parent-defs) val)) defs)
559      (setf (deferred-warnings.warnings parent) (append warnings parent-warnings))))
560  parent)
561
562
563;; Should be a generic function but compiler-warning class not defined yet.
564(defun verify-deferred-warning (w)
565  (etypecase w
566    (undefined-type-reference (verify-deferred-type-warning w))
567    (undefined-function-reference (verify-deferred-function-warning w))
568    (undefined-keyword-reference (verify-deferred-keyword-warning w))
569    (compiler-warning nil)))
570
571(defun verify-deferred-type-warning (w)
572  (let* ((args (compiler-warning-args w))
573         (typespec (car args))
574         (defs (deferred-warnings.defs *outstanding-deferred-warnings*)))
575    (handler-bind ((parse-unknown-type
576                    (lambda (c)
577                      (let* ((type (parse-unknown-type-specifier c))
578                             (spec (if (consp type) (car type) type))
579                             (cell (and (symbolp spec) (gethash spec defs))))
580                        (unless (and cell (def-info.deftype (cdr cell)))
581                          (when (and args (neq type typespec))
582                            (setf (car args) type))
583                          (return-from verify-deferred-type-warning w))
584                        ;; Else got defined.  TODO: Should check syntax, but don't have enuff info.
585                        ;; TODO: should note if got defined as a deftype (rather than class or struct) and
586                        ;; warn about forward reference, akin to the macro warning?  Might be missing out on
587                        ;; some intended optimizations.
588                        )))
589                   (program-error ;; got defined, but turns out it's being used wrong
590                    (lambda (c)
591                      (let ((w2 (make-condition 'invalid-type-warning
592                                  :function-name (compiler-warning-function-name w)
593                                  :source-note (compiler-warning-source-note w)
594                                  :warning-type :invalid-type
595                                  :args (list typespec c))))
596                        (return-from verify-deferred-type-warning w2)))))
597      (values-specifier-type typespec)
598      nil)))
599
600
601(defun deferred-function-def (name)
602  (let* ((defs (deferred-warnings.defs *outstanding-deferred-warnings*))
603         (def (or (let ((cell (gethash name defs)))
604                    (and cell (def-info.function-p (cdr cell)) cell))
605                 (let* ((global (fboundp name)))
606                   (and (typep global 'function) global)))))
607    def))
608
609(defun check-deferred-call-args (w def wargs)
610  (destructuring-bind (arglist spread-p) wargs
611    (multiple-value-bind (deftype reason) (nx1-check-call-args def arglist spread-p)
612      (when (and (eq deftype :deferred-mismatch)
613                 (eq (car reason) :unknown-gf-keywords)
614                 (consp def)
615                 (not (logbitp $lfbits-gfn-bit (def-info.lfbits (cdr def)))))
616        ;; If didn't have a defgeneric, check against global defn
617        (let* ((global-def (fboundp (car def)))
618               (bad-keys (cadr reason)))
619          (when (typep global-def 'generic-function)
620            (setq bad-keys
621                  (multiple-value-bind (bits keyvect) (innermost-lfun-bits-keyvect global-def)
622                    (when (and bits
623                               (logbitp  $lfbits-keys-bit bits)
624                               (not (logbitp $lfbits-aok-bit bits)))
625                      (loop for key in bad-keys
626                        unless (or (find key keyvect)
627                                   (nx1-valid-gf-keyword-p global-def key))
628                        collect key)))))
629          (if bad-keys
630            (setq reason (list* :unknown-gf-keys bad-keys (cddr reason)))
631            (setq deftype nil))))
632      (when deftype
633        (when (eq deftype :deferred-mismatch)
634          (setq deftype (if (consp def) :environment-mismatch :global-mismatch)))
635        (make-condition
636         'invalid-arguments
637         :function-name (compiler-warning-function-name w)
638         :source-note (compiler-warning-source-note w)
639         :warning-type deftype
640         :args (list (car (compiler-warning-args w)) reason arglist spread-p))))))
641
642(defun verify-deferred-function-warning (w)
643  (let* ((args (compiler-warning-args w))
644         (wfname (car args))
645         (def (deferred-function-def wfname)))
646    (cond ((null def) w)
647          ((or (typep def 'function)
648               (and (consp def)
649                    (def-info.lfbits (cdr def))))
650           ;; Check args in call to forward-referenced function.
651           (when (cdr args)
652             (check-deferred-call-args w def (cdr args))))
653          ((def-info.macro-p (cdr def))
654           (let* ((w2 (make-condition
655                       'macro-used-before-definition
656                       :function-name (compiler-warning-function-name w)
657                       :source-note (compiler-warning-source-note w)
658                       :warning-type :macro-used-before-definition
659                       :args (list (car args)))))
660             w2)))))
661
662(defun verify-deferred-keyword-warning (w)
663  (let* ((args (compiler-warning-args w))
664         (wfname (car args))
665         (def (deferred-function-def wfname)))
666    (when def
667      (check-deferred-call-args w def (cddr args)))))
668
669
670(defun report-deferred-warnings (&optional (file nil))
671  (let* ((current (ensure-merged-deferred-warnings *outstanding-deferred-warnings*))
672         (parent (deferred-warnings.parent current))
673         (warnings (deferred-warnings.warnings current))
674         (any nil)
675         (harsh nil))
676    (if parent
677      (progn
678        (setf (deferred-warnings.last-file parent) (cons current file))
679        (unless file ;; don't defer merge for non-file units.
680          (ensure-merged-deferred-warnings parent))
681        (setq parent t))
682      (let* ((file nil)
683             (init t))
684        (dolist (w warnings)
685          (when (setq w (verify-deferred-warning w))
686            (multiple-value-setq (harsh any file) (signal-compiler-warning w init file harsh any))
687            (setq init nil)))))
688    (values any harsh parent)))
689
690(defun print-nested-name (name-list stream)
691  (if (null name-list)
692    (princ "a toplevel form" stream)
693    (progn
694      (if (car name-list)
695        (prin1 (%car name-list) stream)
696        (princ "an anonymous lambda form" stream))
697      (when (%cdr name-list)
698        (princ " inside " stream)
699        (print-nested-name (%cdr name-list) stream)))))
700
701(defparameter *suppress-compiler-warnings* nil)
702
703(defun signal-compiler-warning (w init-p last-w-file harsh-p any-p &optional eval-p)
704  (let ((muffled *suppress-compiler-warnings*)
705        (w-file (compiler-warning-file-name w))
706        (s *error-output*))
707    (unless muffled 
708      (restart-case (signal w)
709        (muffle-warning () (setq muffled t))))
710    (unless muffled
711      (setq any-p t)
712      (unless (typep w 'style-warning)
713        (unless (eq harsh-p :very)
714          (setq harsh-p t)
715          (when (and (typep w 'compiler-warning)
716                     (eq (compiler-warning-warning-type w) :program-error)
717                     (typep (car (compiler-warning-args w)) 'error))
718            (setq harsh-p :very))))
719      (when (or init-p (not (equalp w-file last-w-file)))
720        (format s "~&;~A warnings " (if (null eval-p) "Compiler" "Interpreter"))
721        (if w-file (format s "for ~S :" w-file) (princ ":" s)))
722      (let* ((indenting-stream (make-indenting-string-output-stream #\; 4)))
723        (format indenting-stream "~%~a" w)
724        (format s "~a" (get-output-stream-string indenting-stream))))
725    (values harsh-p any-p w-file)))
726
727;;;; Assorted mumble-P type predicates.
728;;;; No functions have been in the kernel for the last year or so.
729;;;; (Just thought you'd like to know.)
730
731(defun sequencep (form)
732  "Not CL. SLISP Returns T if form is a sequence, NIL otherwise."
733   (or (listp form) (vectorp form)))
734
735;;; The following are not defined at user level, but are necessary for
736;;; internal use by TYPEP.
737
738(defun bitp (form)
739  "Not CL. SLISP"
740  (or (eq form 0) (eq form 1)))
741
742(defun unsigned-byte-p (form)
743  (and (integerp form) (not (< form 0))))
744
745;This is false for internal structures.
746;;; ---- look at defenv.structures, not defenv.structrefs
747
748(defun structure-class-p (form &optional env)
749  (and (symbolp form)
750       (let ((sd (or (and env
751                          (let ((defenv (definition-environment env)))
752                            (and defenv
753                                 (%cdr (assq form (defenv.structures defenv))))))
754                     (gethash form %defstructs%))))
755         (and sd
756              (null (sd-type sd))
757              sd))))
758
759
760
761
762
763(defun type-keyword-code (type-keyword &optional target)
764  ;; Don't really care about speed, but turn off typechecking for bootstrapping reasons
765  (declare (optimize (speed 3) (safety 0)))
766  (let* ((backend (if target (find-backend target) *target-backend*))
767         (alist (arch::target-uvector-subtags (backend-target-arch backend)))
768         (entry (assq type-keyword alist)))
769    (if entry
770      (let* ((code (cdr entry)))
771        (or code (error "Vector type ~s invalid," type-keyword)))
772      (error "Unknown type-keyword ~s. " type-keyword))))
773
774
775(defstruct id-map
776  (vector (make-array 1 :initial-element nil))
777  (free 0)
778  (lock (make-lock)))
779
780;;; Caller owns the lock on the id-map.
781(defun id-map-grow (id-map)
782  (without-interrupts
783   (let* ((old-vector (id-map-vector id-map))
784          (old-size (length old-vector))
785          (new-size (+ old-size old-size))
786          (new-vector (make-array new-size)))
787     (declare (fixnum old-size new-size))
788     (dotimes (i old-size)
789       (setf (svref new-vector i) (svref old-vector i)))
790     (let* ((limit (1- new-size)))
791       (declare (fixnum limit))
792       (do* ((i old-size (1+ i)))
793            ((= i limit) (setf (svref new-vector i) nil))
794         (declare (fixnum i))
795         (setf (svref new-vector i) (the fixnum (1+ i)))))
796     (setf (id-map-vector id-map) new-vector
797           (id-map-free id-map) old-size))))
798
799;;; Map an object to a small fixnum ID in id-map.
800;;; Object can't be NIL or a fixnum itself.
801(defun assign-id-map-id (id-map object)
802  (if (or (null object) (typep object 'fixnum))
803    (setq object (require-type object '(not (or null fixnum)))))
804  (with-lock-grabbed ((id-map-lock id-map))
805    (let* ((free (or (id-map-free id-map) (id-map-grow id-map)))
806           (vector (id-map-vector id-map))
807           (newfree (svref vector free)))
808      (setf (id-map-free id-map) newfree
809            (svref vector free) object)
810      free)))
811     
812;;; Referemce the object with id ID in ID-MAP.  Leave the object in
813;;; the map.
814(defun id-map-object (id-map id)
815  (let* ((object (with-lock-grabbed ((id-map-lock id-map))
816                   (svref (id-map-vector id-map) id))))
817    (if (or (null object) (typep object 'fixnum))
818      (error "invalid index ~d for ~s" id id-map)
819      object)))
820
821;;; Referemce the object with id ID in ID-MAP.  Remove the object from
822;;; the map.
823(defun id-map-free-object (id-map id)
824  (with-lock-grabbed ((id-map-lock id-map))
825    (let* ((vector (id-map-vector id-map))
826           (object (svref vector id)))
827      (if (or (null object) (typep object 'fixnum))
828        (error "invalid index ~d for ~s" id id-map))
829      (setf (svref vector id) (id-map-free id-map)
830            (id-map-free id-map) id)
831      object)))
832
833(defun id-map-modify-object (id-map id old-value new-value)
834  (with-lock-grabbed ((id-map-lock id-map))
835    (let* ((vector (id-map-vector id-map))
836           (object (svref vector id)))
837      (if (or (null object) (typep object 'fixnum))
838        (error "invalid index ~d for ~s" id id-map))
839      (if (eq object old-value)
840        (setf (svref vector id) new-value)))))
841
842
843   
844
845(setq *type-system-initialized* t)
846
847;;; Try to map from a CTYPE describing some array/stream
848;;; element-type to a target-specific typecode, catching
849;;; cases that CTYPE-SUBTYPE missed.
850
851(defun harder-ctype-subtype (ctype)
852  (cond ((csubtypep ctype (load-time-value (specifier-type 'bit)))
853         target::subtag-bit-vector)
854        ((csubtypep ctype (load-time-value (specifier-type '(unsigned-byte 8))))
855         target::subtag-u8-vector)
856        ((csubtypep ctype (load-time-value (specifier-type '(unsigned-byte 16))))
857         target::subtag-u16-vector)
858        ((csubtypep ctype (load-time-value (specifier-type '(unsigned-byte 32))))
859         target::subtag-u32-vector)
860        #+64-bit-target
861        ((csubtypep ctype (load-time-value (specifier-type '(unsigned-byte 64))))
862         target::subtag-u64-vector)
863        ((csubtypep ctype (load-time-value (specifier-type '(signed-byte 8))))
864         target::subtag-s8-vector)
865        ((csubtypep ctype (load-time-value (specifier-type '(signed-byte 16))))
866         target::subtag-s16-vector)
867        #+32-bit-target
868        ((csubtypep ctype (load-time-value (specifier-type `(integer ,target::target-most-negative-fixnum ,target::target-most-positive-fixnum))))
869         target::subtag-fixnum-vector)
870        ((csubtypep ctype (load-time-value (specifier-type '(signed-byte 32))))
871         target::subtag-s32-vector)
872        #+64-bit-target
873        ((csubtypep ctype (load-time-value (specifier-type `(integer ,target::target-most-negative-fixnum ,target::target-most-positive-fixnum))))
874         target::subtag-fixnum-vector)
875        #+64-bit-target
876        ((csubtypep ctype (load-time-value (specifier-type '(signed-byte 64))))
877         target::subtag-s64-vector)
878        (t target::subtag-simple-vector)))
879
880
881#+count-gf-calls
882(progn
883;;; Call-counting for generic functions.  We overload the
884;;; (previously unused
885(defmethod generic-function-call-count ((gf generic-function))
886  (gf.hash gf))
887
888
889(defun (setf generic-function-call-count) (count gf)
890  (setf (gf.hash gf) (require-type count 'fixnum)))
891
892(defun clear-all-generic-function-call-counts ()
893  (dolist (gf (population.data %all-gfs%))
894    (setf (gf.hash gf) 0)))
895);#+count-gf-calls
896
897
Note: See TracBrowser for help on using the repository browser.