source: trunk/source/level-1/l1-sockets.lisp @ 13636

Last change on this file since 13636 was 13382, checked in by rme, 10 years ago

On Linux, the EAI_xxx error codes (as returned by getaddrinfo or
getnameinfo) are negative.

Therefore, don't mess with the sign of the error code in socket-error
when nameserver-p is true, and don't mess with the sign at all in
%gai-strerror.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 54.6 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2001-2009 Clozure Associates
4;;;   This file is part of Clozure CL. 
5;;;
6;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with Clozure CL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17(in-package "CCL")
18
19
20
21;;; basic socket API
22(eval-when (:compile-toplevel :load-toplevel :execute)
23  (export '(MAKE-SOCKET
24            ACCEPT-CONNECTION
25            DOTTED-TO-IPADDR
26            IPADDR-TO-DOTTED
27            IPADDR-TO-HOSTNAME
28            LOOKUP-HOSTNAME
29            LOOKUP-PORT
30            ;;with-pending-connect
31            RECEIVE-FROM
32            SEND-TO
33            SHUTDOWN
34            ;;socket-control
35            SOCKET-OS-FD
36            REMOTE-HOST
37            REMOTE-PORT
38            REMOTE-FILENAME
39            LOCAL-HOST
40            LOCAL-PORT
41            LOCAL-FILENAME
42            SOCKET-ADDRESS-FAMILY
43            SOCKET-CONNECT
44            SOCKET-FORMAT
45            SOCKET-TYPE
46            SOCKET-ERROR
47            SOCKET-ERROR-CODE
48            SOCKET-ERROR-IDENTIFIER
49            SOCKET-ERROR-SITUATION
50            SOCKET-CREATION-ERROR
51            SOCKET-CREATION-ERROR-CODE
52            SOCKET-CREATION-ERROR-IDENTIFIER
53            SOCKET-CREATION-ERROR-SITUATION
54            WITH-OPEN-SOCKET))
55  #+windows-target
56  (defmacro check-winsock-error (form)
57    (let* ((val (gensym)))
58      `(let* ((,val ,form))
59        (if (< ,val 0)
60          (%get-winsock-error)
61          ,val))))
62  (defmacro check-socket-error (form)
63    #+windows-target `(check-winsock-error ,form)
64    #-windows-target `(int-errno-call ,form))
65  )
66
67
68#+windows-target
69(defun %get-winsock-error ()
70  (- (#_WSAGetLastError)))
71
72;;; The PPC is big-endian (uses network byte order), which makes
73;;; things like #_htonl and #_htonl no-ops.  These functions aren't
74;;; necessarily defined as functions in some header files (I'm sure
75;;; that that either complies with or violates some C standard), and
76;;; it doesn't seem to make much sense to fight that to do ff-calls
77;;; to a couple of identity functions.
78
79#+big-endian-target
80(progn
81  (defmacro HTONL (x) x)
82  (defmacro HTONS (x) x)
83  (defmacro NTOHL (x) x)
84  (defmacro NTOHS (x) x))
85
86#+little-endian-target
87(progn
88  (declaim (inline %bswap32 %bswap16))
89  (defun %bswap32 (x)
90    (declare (type (unsigned-byte 32) x))
91    (%swap-u32 x))
92  (defun %bswap16 (x)
93    (declare (type (unsigned-byte 16) x))
94    (%swap-u16 x))
95  (defmacro HTONL (x) `(%bswap32 ,x))
96  (defmacro HTONS (x) `(%bswap16 ,x))
97  (defmacro NTOHL (x) `(%bswap32 ,x))
98  (defmacro NTOHS (x) `(%bswap16 ,x)))
99
100(defparameter *default-socket-character-encoding*
101  nil)
102
103(defmethod default-character-encoding ((domain (eql :socket)))
104  *default-socket-character-encoding*)
105 
106
107;;; On some (hypothetical) little-endian platform, we might want to
108;;; define HTONL and HTONS to actually swap bytes around.
109
110(defpackage "OPENMCL-SOCKET"
111  (:use "CL")
112  (:import-from "CCL"
113                "MAKE-SOCKET"
114                "ACCEPT-CONNECTION"
115                "DOTTED-TO-IPADDR"
116                "IPADDR-TO-DOTTED"
117                "IPADDR-TO-HOSTNAME"
118                "LOOKUP-HOSTNAME"
119                "LOOKUP-PORT"
120                ;;with-pending-connect
121                "RECEIVE-FROM"
122                "SEND-TO"
123                "SHUTDOWN"
124                ;;socket-control
125                "SOCKET-OS-FD"
126                "REMOTE-HOST"
127                "REMOTE-PORT"
128                "REMOTE-FILENAME"
129                "LOCAL-HOST"
130                "LOCAL-PORT"
131                "LOCAL-FILENAME"
132                "SOCKET-ADDRESS-FAMILY"
133                "SOCKET-CONNECT"
134                "SOCKET-FORMAT"
135                "SOCKET-TYPE"
136                "SOCKET-ERROR"
137                "SOCKET-ERROR-CODE"
138                "SOCKET-ERROR-IDENTIFIER"
139                "SOCKET-ERROR-SITUATION"
140                "SOCKET-CREATION-ERROR"
141                "SOCKET-CREATION-ERROR-CODE"
142                "SOCKET-CREATION-ERROR-IDENTIFIER"
143                "SOCKET-CREATION-ERROR-SITUATION"
144                "WITH-OPEN-SOCKET")
145  (:export  "MAKE-SOCKET"
146            "ACCEPT-CONNECTION"
147            "DOTTED-TO-IPADDR"
148            "IPADDR-TO-DOTTED"
149            "IPADDR-TO-HOSTNAME"
150            "LOOKUP-HOSTNAME"
151            "LOOKUP-PORT"
152            ;;with-pending-connect
153            "RECEIVE-FROM"
154            "SEND-TO"
155            "SHUTDOWN"
156            ;;socket-control
157            "SOCKET-OS-FD"
158            "REMOTE-HOST"
159            "REMOTE-PORT"
160            "REMOTE-FILENAME"
161            "LOCAL-HOST"
162            "LOCAL-PORT"
163            "LOCAL-FILENAME"
164            "SOCKET-ADDRESS-FAMILY"
165            "SOCKET-CONNECT"
166            "SOCKET-FORMAT"
167            "SOCKET-TYPE"
168            "SOCKET-ERROR"
169            "SOCKET-ERROR-CODE"
170            "SOCKET-ERROR-IDENTIFIER"
171            "SOCKET-ERROR-SITUATION"
172            "SOCKET-CREATION-ERROR"
173            "SOCKET-CREATION-ERROR-CODE"
174            "SOCKET-CREATION-ERROR-IDENTIFIER"
175            "SOCKET-CREATION-ERROR-SITUATION"
176            "WITH-OPEN-SOCKET"))
177
178(define-condition socket-error (simple-stream-error)
179  ((code :initarg :code :reader socket-error-code)
180   (identifier :initform :unknown :initarg :identifier :reader socket-error-identifier)
181   (situation :initarg :situation :reader socket-error-situation)))
182
183(define-condition socket-creation-error (simple-error)
184  ((code :initarg :code :reader socket-creation-error-code)
185   (identifier :initform :unknown :initarg :identifier :reader socket-creation-error-identifier)
186   (situation :initarg :situation :reader socket-creation-error-situation)))
187
188(defparameter *gai-error-identifiers*
189  (list #$EAI_AGAIN :try-again
190        #$EAI_FAIL :no-recovery
191        #$EAI_NONAME :host-not-found))
192
193(defvar *socket-error-identifiers*
194  #-windows-target
195  (list #$EADDRINUSE :address-in-use
196        #$ECONNABORTED :connection-aborted
197        #$ENOBUFS :no-buffer-space
198        #$ENOMEM :no-buffer-space
199        #$ENFILE :no-buffer-space
200        #$ETIMEDOUT :connection-timed-out
201        #$ECONNREFUSED :connection-refused
202        #$ENETUNREACH :host-unreachable
203        #$EHOSTUNREACH :host-unreachable
204        #$EHOSTDOWN :host-down
205        #$ENETDOWN :network-down
206        #$EADDRNOTAVAIL :address-not-available
207        #$ENETRESET :network-reset
208        #$ECONNRESET :connection-reset
209        #$ESHUTDOWN :shutdown
210        #$EACCES :access-denied
211        #$EPERM :access-denied)
212  #+windows-target
213  (list #$WSAEADDRINUSE :address-in-use
214        #$WSAECONNABORTED :connection-aborted
215        #$WSAENOBUFS :no-buffer-space
216        #$ENOMEM :no-buffer-space
217        #$ENFILE :no-buffer-space
218        #$WSAETIMEDOUT :connection-timed-out
219        #$WSAECONNREFUSED :connection-refused
220        #$WSAENETUNREACH :host-unreachable
221        #$WSAEHOSTUNREACH :host-unreachable
222        #$WSAEHOSTDOWN :host-down
223        #$WSAENETDOWN :network-down
224        #$WSAEADDRNOTAVAIL :address-not-available
225        #$WSAENETRESET :network-reset
226        #$WSAECONNRESET :connection-reset
227        #$WSAESHUTDOWN :shutdown
228        #$EACCES :access-denied
229        #$EPERM :access-denied)
230  )
231
232
233(declaim (inline socket-call))
234(defun socket-call (stream where res)
235  (if (< res 0)
236    (socket-error stream where res)
237    res))
238
239#-windows-target
240(defun %gai-strerror (err)
241  (let ((p (#_gai_strerror err)))
242    (if (%null-ptr-p p)
243      (format nil "Unknown nameserver error ~d" err)
244      (%get-cstring p))))
245
246(defun socket-error (stream where errno &optional nameserver-p)
247  "Creates and signals (via error) one of two socket error
248conditions, based on the state of the arguments."
249  (unless nameserver-p
250    (setq errno (abs errno)))
251  (if stream
252    (error (make-condition 'socket-error
253                           :stream stream
254                           :code errno
255                           :identifier (getf *socket-error-identifiers* errno :unknown)
256                           :situation where
257                           :format-control "~a (error #~d) during ~a"
258                           :format-arguments (list
259                                              #+windows-target
260                                              (%windows-error-string errno)
261                                              #-windows-target
262                                              (%strerror errno)
263                                              errno where)))
264    (let ((identifiers (if nameserver-p
265                         *gai-error-identifiers*
266                         *socket-error-identifiers*)))
267      (error (make-condition 'socket-creation-error
268                             :code errno
269                             :identifier (getf identifiers errno :unknown)
270                             :situation where
271                             :format-control "~a (error #~d) during socket creation or nameserver operation in ~a"
272                             :format-arguments (list
273                                                #+windows-target
274                                                (%windows-error-string errno)
275                                                #-windows-target
276                                                (if nameserver-p
277                                                  (%gai-strerror errno)
278                                                  (%strerror errno))
279                                                errno where))))))
280
281;; If true, this will try to allow other cooperative processes to run
282;; while socket io is happening.  Since CCL threads are preemptively
283;; scheduled, this isn't particularly meaningful.
284(defvar *multiprocessing-socket-io* nil)
285
286(defclass socket ()
287  ())
288
289(defmacro with-open-socket ((var . args) &body body
290                            &aux (socket (make-symbol "socket"))
291                                 (done (make-symbol "done")))
292  "Execute body with var bound to the result of applying make-socket to
293make-socket-args. The socket gets closed on exit."
294  `(let (,socket ,done)
295     (unwind-protect
296         (multiple-value-prog1
297           (let ((,var (setq ,socket (make-socket ,@args))))
298             ,@body)
299           (setq ,done t))
300       (when ,socket (close ,socket :abort (not ,done))))))
301
302(defgeneric socket-address-family (socket)
303  (:documentation "Return :internet or :file, as appropriate."))
304
305(defclass ip-socket (socket)
306  ())
307
308(defmethod socket-address-family ((socket ip-socket)) :internet)
309
310(defclass file-socket (socket)
311  ())
312
313(defmethod socket-address-family ((socket file-socket)) :file)
314
315(defclass tcp-socket (ip-socket)
316  ())
317
318(defgeneric socket-type (socket)
319  (:documentation
320   "Return :stream for tcp-stream and listener-socket, and :datagram
321for udp-socket."))
322
323(defmethod socket-type ((socket tcp-socket)) :stream)
324
325(defclass stream-file-socket (file-socket)
326  ())
327
328(defmethod socket-type ((socket stream-file-socket)) :stream)
329
330
331;;; An active TCP socket is an honest-to-goodness stream.
332(defclass tcp-stream (tcp-socket)
333  ())
334
335(defclass fundamental-tcp-stream (tcp-stream
336                                  fd-stream
337                                  buffered-binary-io-stream-mixin
338                                  buffered-character-io-stream-mixin)
339    ())
340
341(make-built-in-class 'basic-tcp-stream
342                     'tcp-stream
343                     'basic-binary-io-stream
344                     'basic-character-io-stream)
345
346(defgeneric socket-connect (stream)
347 (:documentation
348   "Return :active for tcp-stream, :passive for listener-socket, and NIL
349for udp-socket"))
350
351(defmethod socket-connect ((stream tcp-stream)) :active)
352
353(defgeneric socket-format (stream)
354  (:documentation
355   "Return the socket format as specified by the :format argument to
356make-socket."))
357
358(defmethod socket-format ((stream tcp-stream))
359  (if (eq (stream-element-type stream) 'character)
360    :text
361    ;; Should distinguish between :binary and :bivalent, but hardly
362    ;; seems worth carrying around an extra slot just for that.
363    :bivalent))
364
365(defmethod socket-device ((stream tcp-stream))
366  (let ((ioblock (stream-ioblock stream nil)))
367    (and ioblock (ioblock-device ioblock))))
368
369(defmethod select-stream-class ((class tcp-stream) in-p out-p char-p)
370  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
371  ;; Yes, in general.  There is.
372  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
373  'fundamental-tcp-stream)
374
375(defmethod map-to-basic-stream-class-name ((name (eql 'tcp-stream)))
376  'basic-tcp-stream)
377
378(defmethod select-stream-class ((s (eql 'basic-tcp-stream)) in-p out-p char-p)
379  (declare (ignore char-p))
380  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
381  'basic-tcp-stream)
382
383;;; A FILE-SOCKET-STREAM is also honest. To goodness.
384(defclass file-socket-stream (stream-file-socket)
385  ())
386
387(defclass fundamental-file-socket-stream (file-socket-stream
388                                          fd-stream
389                                          buffered-binary-io-stream-mixin
390                                          buffered-character-io-stream-mixin)
391    ())
392
393(make-built-in-class 'basic-file-socket-stream
394                     'file-socket-stream
395                     'basic-binary-io-stream
396                     'basic-character-io-stream)
397
398
399(defmethod map-to-basic-stream-class-name ((name (eql 'file-socket-stream)))
400  'basic-file-socket-stream)
401
402(defmethod select-stream-class ((class file-socket-stream) in-p out-p char-p)
403  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
404  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
405  'fundamental-file-socket-stream)
406
407(defmethod select-stream-class ((s (eql 'basic-file-socket-stream)) in-p out-p char-p)
408  (declare (ignore char-p))
409  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
410  'basic-file-socket-stream)
411
412(defclass unconnected-socket (socket)
413  ((device :initarg :device :accessor socket-device)
414   (keys :initarg :keys :reader socket-keys)))
415
416(defmethod socket-format ((socket unconnected-socket))
417  (or (getf (socket-keys socket) :format) :text))
418
419(defgeneric close (socket &key abort)
420  (:documentation
421   "The close generic function can be applied to sockets. It releases the
422operating system resources associated with the socket."))
423
424(defmethod close ((socket unconnected-socket) &key abort)
425  (declare (ignore abort))
426  (when (socket-device socket)
427    (fd-close (socket-device socket))
428    (setf (socket-device socket) nil)
429    t))
430
431;; A passive tcp socket just generates connection streams
432(defclass listener-socket (tcp-socket unconnected-socket) ())
433
434(defmethod SOCKET-CONNECT ((stream listener-socket)) :passive)
435
436(defclass file-listener-socket (stream-file-socket unconnected-socket) ())
437
438(defmethod SOCKET-CONNECT ((stream file-listener-socket)) :passive)
439
440;;; A FILE-LISTENER-SOCKET should try to delete the filesystem
441;;; entity when closing.
442
443#-windows-target
444(defmethod close :before ((s file-listener-socket) &key abort)
445  (declare (ignore abort))
446  (let* ((path (local-socket-filename (socket-device s) s)))
447    (when path (%delete-file path))))
448
449
450;; A udp socket just sends and receives packets.
451(defclass udp-socket (ip-socket unconnected-socket) ())
452
453(defmethod socket-type ((stream udp-socket)) :datagram)
454(defmethod socket-connect ((stream udp-socket)) nil)
455
456(defgeneric socket-os-fd (socket)
457  (:documentation
458   "Return the native OS's representation of the socket, or NIL if the
459socket is closed. On Unix, this is the Unix 'file descriptor', a small
460non-negative integer. Note that it is rather dangerous to mess around
461with tcp-stream fd's, as there is all sorts of buffering and asynchronous
462I/O going on above the OS level. listener-socket and udp-socket fd's are
463safer to mess with directly as there is less magic going on."))
464
465;; Returns nil for closed stream...
466(defmethod socket-os-fd ((socket socket))
467  (socket-device socket))
468
469;; Returns nil for closed stream
470(defun local-socket-info (fd type socket)
471  (and fd
472       (rlet ((sockaddr :sockaddr_in)
473              (namelen :signed))
474             (setf (pref namelen :signed) (record-length :sockaddr_in))
475             (socket-call socket "getsockname" (c_getsockname fd sockaddr namelen))
476             (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
477               (ecase type
478                 (:host (ntohl (pref sockaddr
479                                     #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
480                                     #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr)))
481                 (:port (ntohs (pref sockaddr :sockaddr_in.sin_port))))))))
482
483#-windows-target
484(defun path-from-unix-address (addr)
485  (when (= #$AF_UNIX (pref addr :sockaddr_un.sun_family))
486    #+darwin-target
487    (%str-from-ptr (pref addr :sockaddr_un.sun_path)
488                   (- (pref addr :sockaddr_un.sun_len) 2))
489    #-darwin-target
490    (%get-cstring (pref addr :sockaddr_un.sun_path))))
491
492#-windows-target
493(defun local-socket-filename (fd socket)
494  (and fd
495       (rlet ((addr :sockaddr_un)
496              (namelen :signed))
497         (setf (pref namelen :signed) (record-length :sockaddr_un))
498         (socket-call socket "getsockname" (c_getsockname fd addr namelen))
499         (path-from-unix-address addr))))
500
501(defmacro with-if ((var expr) &body body)
502  `(let ((,var ,expr))
503     (if ,var
504         (progn
505           ,@body))))     
506
507(defun remote-socket-info (socket type)
508  (with-if (fd (socket-device socket))
509    (rlet ((sockaddr :sockaddr_in)
510           (namelen :signed))
511          (setf (pref namelen :signed) (record-length :sockaddr_in))
512          (let ((err (c_getpeername fd sockaddr namelen)))
513            (cond ((eql err (- #+windows-target #$WSAENOTCONN #-windows-target #$ENOTCONN)) nil)
514                  ((< err 0) (socket-error socket "getpeername" err))
515                  (t
516                   (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
517                     (ecase type
518                       (:host (ntohl (pref sockaddr
519                                           #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
520                                           #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr)))
521                       (:port (ntohs  (pref sockaddr :sockaddr_in.sin_port)))))))))))
522
523#-windows-target
524(defun remote-socket-filename (socket)
525  (with-if (fd (socket-device socket))
526    (rlet ((addr :sockaddr_un)
527           (namelen :signed))
528          (setf (pref namelen :signed) (record-length :sockaddr_un))
529          (let* ((err (c_getsockname fd addr namelen)))
530            (cond ((eql err (- #$ENOTCONN)) nil)
531                  ((< err 0) (socket-error socket "getpeername" err))
532                  (t (path-from-unix-address addr)))))))
533
534(defgeneric local-port (socket)
535  (:documentation "Return the local port number."))
536
537(defmethod local-port ((socket socket))
538  (local-socket-info (socket-device socket) :port socket))
539
540(defgeneric local-host (socket)
541  (:documentation
542   "Return 32-bit unsigned IP address of the local host."))
543
544(defmethod local-host ((socket socket))
545  (local-socket-info (socket-device socket) :host socket))
546
547#-windows-target
548(defmethod local-filename ((socket socket))
549  (local-socket-filename (socket-device socket) socket))
550
551(defgeneric remote-host (socket)
552  (:documentation
553   "Return the 32-bit unsigned IP address of the remote host, or NIL if
554the socket is not connected."))
555
556;; Returns NIL if socket is not connected
557(defmethod remote-host ((socket socket))
558  (remote-socket-info socket :host))
559
560(defgeneric remote-port (socket)
561  (:documentation
562   "Return the remote port number, or NIL if the socket is not connected."))
563
564(defmethod remote-port ((socket socket))
565  (remote-socket-info socket :port))
566
567#-windows-target
568(defmethod remote-filename ((socket socket))
569  (remote-socket-filename socket))
570 
571(defun set-socket-fd-blocking (fd block-flag)
572  #+windows-target
573  (rlet ((argp :u_long (if block-flag 0 1)))
574    (#_ioctlsocket fd #$FIONBIO argp))
575  #-windows-target
576  (if block-flag
577    (fd-clear-flag fd #$O_NONBLOCK)
578    (fd-set-flag fd #$O_NONBLOCK)))
579
580(defun get-socket-fd-blocking (fd)
581  "returns T iff socket is in blocking mode"
582  #+windows-target (declare (ignore fd))
583  #+windows-target t
584  #-windows-target
585  (not (logtest #$O_NONBLOCK (fd-get-flags fd))))
586
587(defun set-socket-options (fd-or-socket &key 
588                           keepalive
589                           reuse-address
590                           nodelay
591                           broadcast
592                           linger
593                           address-family
594                           local-port
595                           local-host
596                           local-filename
597                           type
598                           connect
599                           out-of-band-inline
600                           &allow-other-keys)
601  ;; see man socket(7) tcp(7) ip(7)
602  (multiple-value-bind (socket fd) (etypecase fd-or-socket
603                                     (socket (values fd-or-socket (socket-device fd-or-socket)))
604                                     (integer (values nil fd-or-socket)))
605   
606    (if (null address-family)
607        (setq address-family :internet))
608    (when keepalive
609      (int-setsockopt fd #$SOL_SOCKET #$SO_KEEPALIVE 1))
610    (when reuse-address
611      (int-setsockopt fd #$SOL_SOCKET #$SO_REUSEADDR 1))
612    (when broadcast
613      (int-setsockopt fd #$SOL_SOCKET #$SO_BROADCAST 1))
614    (when out-of-band-inline
615      (int-setsockopt fd #$SOL_SOCKET #$SO_OOBINLINE 1))
616    (when (eq address-family :internet)
617      (when (eq type :stream)
618        (rlet ((plinger :linger))
619          (setf (pref plinger :linger.l_onoff) (if linger 1 0)
620                (pref plinger :linger.l_linger) (or linger 0))
621          (socket-call socket "setsockopt"
622                       (c_setsockopt fd #$SOL_SOCKET #$SO_LINGER
623                                     plinger (record-length :linger)))))
624      (when nodelay
625        (int-setsockopt fd
626                        #+linux-target #$SOL_TCP
627                        #-linux-target #$IPPROTO_TCP
628                        #$TCP_NODELAY 1))
629      (when (or local-port local-host)
630        (let* ((proto (if (eq type :stream) "tcp" "udp"))
631               (port-n (if local-port (port-as-inet-port local-port proto) 0))
632               (host-n (if local-host (host-as-inet-host local-host) #$INADDR_ANY)))
633          ;; Darwin includes the SIN_ZERO field of the sockaddr_in when
634          ;; comparing the requested address to the addresses of configured
635          ;; interfaces (as if the zeros were somehow part of either address.)
636          ;; "rletz" zeros out the stack-allocated structure, so those zeros
637          ;; will be 0.
638          (rletz ((sockaddr :sockaddr_in))
639                 (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
640                       (pref sockaddr :sockaddr_in.sin_port) port-n
641                       (pref sockaddr
642                             #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
643                             #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr
644                             ) host-n)
645                 (socket-call socket "bind" (c_bind fd sockaddr (record-length :sockaddr_in)))))))
646    (when (and (eq address-family :file)
647               (eq connect :passive)
648               local-filename)
649      #+windows-target (error "can't create file socket on Windows")
650      #-windows-target (bind-unix-socket fd local-filename))))
651
652;; I hope the inline declaration makes the &rest/apply's go away...
653(declaim (inline make-ip-socket))
654(defun make-ip-socket (&rest keys &key type &allow-other-keys)
655  (declare (dynamic-extent keys))
656  (ecase type
657    ((nil :stream) (apply #'make-tcp-socket keys))
658    ((:datagram) (apply #'make-udp-socket keys))))
659
660(declaim (inline make-file-socket))
661(defun make-file-socket (&rest keys &key type &allow-other-keys)
662  (declare (dynamic-extent keys))
663  (ecase type
664    ((nil :stream) (apply #'make-stream-file-socket keys))
665    (:datagram (apply #'make-datagram-file-socket keys))))
666
667(defun make-socket (&rest keys
668                    &key address-family
669                    ;; List all keys here just for error checking...
670                    ;; &allow-other-keys
671                    type connect remote-host remote-port eol format
672                    keepalive reuse-address nodelay broadcast linger
673                    local-port local-host backlog class out-of-band-inline
674                    local-filename remote-filename sharing basic
675                    external-format (auto-close t)
676                    connect-timeout input-timeout output-timeout deadline
677                    fd)
678  "Create and return a new socket."
679  (declare (dynamic-extent keys))
680  (declare (ignore type connect remote-host remote-port eol format
681                   keepalive reuse-address nodelay broadcast linger
682                   local-port local-host backlog class out-of-band-inline
683                   local-filename remote-filename sharing basic external-format
684                   auto-close connect-timeout input-timeout output-timeout deadline fd))
685  (ecase address-family
686    ((:file) (apply #'make-file-socket keys))
687    ((nil :internet) (apply #'make-ip-socket keys))))
688
689
690
691(defun make-udp-socket (&rest keys &key (fd -1) &allow-other-keys)
692  (unwind-protect
693    (let (socket)
694      (when (< fd 0)
695        (setq fd (socket-call nil "socket"
696                              (c_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_UDP))))
697      (apply #'set-socket-options fd keys)
698      (setq socket (make-instance 'udp-socket
699                                  :device fd
700                                  :keys keys))
701      (setq fd -1)
702      socket)
703    (unless (< fd 0)
704      (fd-close fd))))
705
706(defun make-tcp-socket (&rest keys &key connect (fd -1) &allow-other-keys)
707  (unwind-protect
708       (let (socket)
709         (when (< fd 0)
710           (setq fd (socket-call nil "socket"
711                                 (c_socket #$AF_INET #$SOCK_STREAM #$IPPROTO_TCP))))
712         (apply #'set-socket-options fd keys)
713         (setq socket
714               (ecase connect
715                 ((nil :active) (apply #'make-tcp-stream-socket fd keys))
716                 ((:passive) (apply #'make-tcp-listener-socket fd keys))))
717         (setq fd -1)
718         socket)
719    (unless (< fd 0)
720      (fd-close fd))))
721
722(defun make-stream-file-socket (&rest keys &key connect (fd -1) &allow-other-keys)
723  (unwind-protect
724       (let (socket)
725         (when (< fd 0)
726           (setq fd (socket-call nil "socket" (c_socket #$PF_UNIX #$SOCK_STREAM 0))))
727         (apply #'set-socket-options fd keys)
728         (setq socket
729               (ecase connect
730                 ((nil :active) (apply #'make-file-stream-socket fd keys))
731                 ((:passive) (apply #'make-file-listener-socket fd keys))))
732         (setq fd -1)
733         socket)
734    (unless (< fd 0)
735      (fd-close fd))))
736
737(defun make-datagram-file-socket (&rest keys)
738  (declare (ignore keys))
739  (error "Datagram file sockets aren't implemented."))
740
741
742(defun %socket-connect (fd addr addrlen &optional timeout-in-milliseconds)
743  (let* ((err (c_connect fd addr addrlen timeout-in-milliseconds)))
744    (declare (fixnum err))
745    (unless (eql err 0) (fd-close fd) (socket-error nil "connect" err))))
746   
747(defun inet-connect (fd host-n port-n &optional timeout-in-milliseconds)
748  (rlet ((sockaddr :sockaddr_in))
749    (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
750          (pref sockaddr :sockaddr_in.sin_port) port-n
751          (pref sockaddr
752                #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
753                #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr
754                ) host-n)
755    (%socket-connect fd sockaddr (record-length :sockaddr_in) timeout-in-milliseconds)))
756
757#-windows-target
758(defun file-socket-connect (fd remote-filename)
759  (rletz ((sockaddr :sockaddr_un))
760    (init-unix-sockaddr sockaddr remote-filename)
761    (%socket-connect fd sockaddr (record-length :sockaddr_un))))
762
763#+windows-target
764(defun file-socket-connect (fd remote-filename)
765  (declare (ignore fd))
766  (error "Can't create file socket to ~s on Windows" remote-filename))
767 
768(defun make-tcp-stream-socket (fd &rest keys
769                                  &key remote-host
770                                  remote-port
771                                  connect-timeout
772                                  deadline
773                                  &allow-other-keys)
774  (let* ((timeout-in-milliseconds
775          (if deadline
776            (max (round (- deadline (get-internal-real-time))
777                        (/ internal-time-units-per-second 1000))
778                 0)
779            (if connect-timeout
780              (round (* connect-timeout 1000))))))
781    (inet-connect fd
782                  (host-as-inet-host remote-host)
783                  (port-as-inet-port remote-port "tcp")
784                  timeout-in-milliseconds)
785    (apply #'make-tcp-stream fd keys)))
786
787(defun make-file-stream-socket (fd &rest keys
788                                   &key remote-filename
789                                   &allow-other-keys)
790  (file-socket-connect fd remote-filename)
791  (apply #'make-file-socket-stream fd keys))
792
793
794(defun make-tcp-stream (fd
795                        &key (format :bivalent)
796                             external-format
797                             (class 'tcp-stream)
798                             sharing
799                             (basic t)
800                             (auto-close t)
801                             input-timeout
802                             output-timeout
803                             deadline
804                        &allow-other-keys)
805  (let* ((external-format (normalize-external-format :socket external-format)))
806    (let ((element-type (ecase format
807                          ((nil :text) 'character)
808                          ((:binary :bivalent) '(unsigned-byte 8)))))
809      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
810      ;; See if should specialize any of 'em.
811      (make-fd-stream fd
812                      :class class
813                      :direction :io
814                      :element-type element-type
815                      :sharing sharing
816                      :character-p (not (eq format :binary))
817                      :encoding (external-format-character-encoding external-format)
818                      :line-termination (external-format-line-termination external-format)
819                      :basic basic
820                      :auto-close auto-close
821                      :input-timeout input-timeout
822                      :output-timeout output-timeout
823                      :deadline deadline))))
824
825(defun make-file-socket-stream (fd
826                                &key (format :bivalent)
827                                external-format
828                                (class 'file-socket-stream)
829                                sharing
830                                basic
831                                (auto-close t)
832                                input-timeout
833                                output-timeout
834                                deadline
835                                &allow-other-keys)
836  (let* ((external-format (normalize-external-format :socket external-format)))
837 
838    (let ((element-type (ecase format
839                          ((nil :text) 'character)
840                          ((:binary :bivalent) '(unsigned-byte 8)))))
841      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
842      ;; See if should specialize any of 'em.
843      (make-fd-stream fd
844                      :class class
845                      :direction :io
846                      :element-type element-type
847                      :encoding (external-format-character-encoding external-format)
848                      :line-termination (external-format-line-termination external-format)
849                      :sharing sharing
850                      :character-p (not (eq format :binary))
851                      :basic basic
852                      :auto-close auto-close
853                      :input-timeout input-timeout
854                      :output-timeout output-timeout
855                      :deadline deadline))))
856
857(defun make-tcp-listener-socket (fd &rest keys &key backlog &allow-other-keys)
858  (socket-call nil "listen" (c_listen fd (or backlog 5)))
859  (make-instance 'listener-socket
860                 :device fd
861                 :keys keys))
862
863(defun make-file-listener-socket (fd &rest keys &key backlog &allow-other-keys)
864  (socket-call nil "listen" (c_listen fd (or backlog 5)))
865  (make-instance 'file-listener-socket
866                 :device fd
867                 :keys keys))
868
869(defun socket-accept (fd wait)
870  (flet ((_accept (fd async)
871           (let ((res (c_accept fd (%null-ptr) (%null-ptr))))
872             (declare (fixnum res))
873             ;; See the inscrutable note under ERROR HANDLING in
874             ;; man accept(2). This is my best guess at what they mean...
875             (if (and async (< res 0)
876                      #+windows-target
877                      (= res #$WSAEWOULDBLOCK)
878                      #-windows-target
879                      (or (eql res (- #$ENETDOWN))
880                          (eql res (- #+linux-target #$EPROTO
881                                      #-linux-target  #$EPROTOTYPE))
882                          (eql res (- #$ENOPROTOOPT))
883                          (eql res (- #$EHOSTDOWN))
884                          (eql res (- #+linux-target #$ENONET
885                                      #-linux-target #$ENETDOWN))
886                          (eql res (- #$EHOSTUNREACH))
887                          (eql res (- #$EOPNOTSUPP))
888                          (eql res (- #$ENETUNREACH))))
889               (- #$EAGAIN)
890               res))))
891    (cond (wait
892            (with-eagain fd :input
893              (_accept fd *multiprocessing-socket-io*)))
894          (*multiprocessing-socket-io*
895            (_accept fd t))
896          (t
897            (let ((was-blocking (get-socket-fd-blocking fd)))
898              (unwind-protect
899                  (progn
900                    (set-socket-fd-blocking fd nil)
901                    (_accept fd t))
902                (set-socket-fd-blocking fd was-blocking)))))))
903
904(defun accept-socket-connection (socket wait stream-create-function &optional stream-args)
905  (let ((listen-fd (socket-device socket))
906        (fd -1))
907    (unwind-protect
908      (let ((keys (append stream-args (socket-keys socket))))
909        (setq fd (socket-accept listen-fd wait))
910        (cond ((>= fd 0)
911               (prog1 (apply stream-create-function fd keys)
912                 (setq fd -1)))
913              ((eql fd (- #$EAGAIN)) nil)
914              (t (socket-error socket "accept" fd))))
915      (when (>= fd 0)
916        (fd-close fd)))))
917
918(defgeneric accept-connection (socket &key wait stream-args)
919  (:documentation
920  "Extract the first connection on the queue of pending connections,
921accept it (i.e. complete the connection startup protocol) and return a new
922tcp-stream or file-socket-stream representing the newly established
923connection.  The tcp stream inherits any properties of the listener socket
924that are relevant (e.g. :keepalive, :nodelay, etc.) Additional arguments
925may be specified using STREAM-ARGS. The original listener
926socket continues to be open listening for more connections, so you can call
927accept-connection on it again."))
928
929(defmethod accept-connection ((socket listener-socket) &key (wait t) stream-args)
930  (accept-socket-connection socket wait #'make-tcp-stream stream-args))
931
932(defmethod accept-connection ((socket file-listener-socket) &key (wait t) stream-args)
933  (accept-socket-connection socket wait #'make-file-socket-stream stream-args))
934
935(defun verify-socket-buffer (buf offset size)
936  (unless offset (setq offset 0))
937  (unless (<= (+ offset size) (length buf))
938    (report-bad-arg size `(integer 0 ,(- (length buf) offset))))
939  (multiple-value-bind (arr start) (array-data-and-offset buf)
940    (setq buf arr offset (+ offset start)))
941  ;; TODO: maybe should allow any raw vector
942  (let ((subtype (typecode buf)))
943    (unless #+ppc32-target (and (<= ppc32::min-8-bit-ivector-subtag subtype)
944                                (<= subtype ppc32::max-8-bit-ivector-subtag))
945            #+ppc64-target (= (the fixnum (logand subtype ppc64::fulltagmask))
946                              ppc64::ivector-class-8-bit)
947            #+x8632-target (and (<= x8632::min-8-bit-ivector-subtag subtype)
948                                (<= subtype x8632::max-8-bit-ivector-subtag))
949            #+x8664-target (and (>= subtype x8664::min-8-bit-ivector-subtag)
950                                (<= subtype x8664::max-8-bit-ivector-subtag))
951      (report-bad-arg buf `(or (array character)
952                               (array (unsigned-byte 8))
953                               (array (signed-byte 8))))))
954  (values buf offset))
955
956(defmethod send-to ((socket udp-socket) msg size
957                    &key remote-host remote-port offset)
958  "Send a UDP packet over a socket."
959  (let ((fd (socket-device socket)))
960    (multiple-value-setq (msg offset) (verify-socket-buffer msg offset size))
961    (unless remote-host
962      (setq remote-host (or (getf (socket-keys socket) :remote-host)
963                            (remote-socket-info socket :host))))
964    (unless remote-port
965      (setq remote-port (or (getf (socket-keys socket) :remote-port)
966                            (remote-socket-info socket :port))))
967    (rlet ((sockaddr :sockaddr_in))
968      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
969      (setf (pref sockaddr
970                  #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
971                  #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr)
972            (if remote-host (host-as-inet-host remote-host) #$INADDR_ANY))
973      (setf (pref sockaddr :sockaddr_in.sin_port)
974            (if remote-port (port-as-inet-port remote-port "udp") 0))
975      (%stack-block ((bufptr size))
976        (%copy-ivector-to-ptr msg offset bufptr 0 size)
977        (socket-call socket "sendto"
978          (with-eagain fd :output
979            (c_sendto fd bufptr size 0 sockaddr (record-length :sockaddr_in))))))))
980
981(defmethod receive-from ((socket udp-socket) size &key buffer extract offset)
982  "Read a UDP packet from a socket. If no packets are available, wait for
983a packet to arrive. Returns four values:
984  The buffer with the data
985  The number of bytes read
986  The 32-bit unsigned IP address of the sender of the data
987  The port number of the sender of the data."
988  (let ((fd (socket-device socket))
989        (vec-offset offset)
990        (vec buffer)
991        (ret-size -1))
992    (when vec
993      (multiple-value-setq (vec vec-offset)
994        (verify-socket-buffer vec vec-offset size)))
995    (rlet ((sockaddr :sockaddr_in)
996           (namelen :signed))
997      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
998      (setf (pref sockaddr
999                  #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
1000                  #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr)
1001            #$INADDR_ANY)
1002      (setf (pref sockaddr :sockaddr_in.sin_port) 0)
1003      (setf (pref namelen :signed) (record-length :sockaddr_in))
1004      (%stack-block ((bufptr size))
1005        (setq ret-size (socket-call socket "recvfrom"
1006                         (with-eagain fd :input
1007                           (c_recvfrom fd bufptr size 0 sockaddr namelen))))
1008        (unless vec
1009          (setq vec (make-array ret-size
1010                                :element-type
1011                                (ecase (socket-format socket)
1012                                  ((:text) 'base-char)
1013                                  ((:binary :bivalent) '(unsigned-byte 8))))
1014                vec-offset 0))
1015        (%copy-ptr-to-ivector bufptr 0 vec vec-offset ret-size))
1016      (values (cond ((null buffer)
1017                     vec)
1018                    ((or (not extract)
1019                         (and (eql 0 (or offset 0))
1020                              (eql ret-size (length buffer))))
1021                     buffer)
1022                    (t 
1023                     (subseq vec vec-offset (+ vec-offset ret-size))))
1024              ret-size
1025              (ntohl (pref sockaddr
1026                           #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
1027                           #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr))
1028              (ntohs (pref sockaddr :sockaddr_in.sin_port))))))
1029
1030(defgeneric shutdown (socket &key direction)
1031  (:documentation
1032   "Shut down part of a bidirectional connection. This is useful if e.g.
1033you need to read responses after sending an end-of-file signal."))
1034
1035(defmethod shutdown (socket &key direction)
1036  ;; TODO: should we ignore ENOTCONN error?  (at least make sure it
1037  ;; is a distinct, catchable error type).
1038  (let ((fd (socket-device socket)))
1039    (socket-call socket "shutdown"
1040      (c_shutdown fd (ecase direction
1041                       (:input 0)
1042                       (:output 1))))))
1043
1044;; Accepts port as specified by user, returns port number in network byte
1045;; order.  Protocol should be one of "tcp" or "udp".  Error if not known.
1046(defun port-as-inet-port (port proto)
1047  (or (etypecase port
1048        (fixnum (htons port))
1049        (string (_getservbyname port proto))
1050        (symbol (_getservbyname (string-downcase (symbol-name port)) proto)))
1051      (socket-error nil "getservbyname" (- #$ENOENT))))
1052
1053(defun lookup-port (port proto)
1054  "Find the port number for the specified port and protocol."
1055  (if (fixnump port)
1056    port
1057    (ntohs (port-as-inet-port port proto))))
1058
1059;; Accepts host as specified by user, returns host number in network byte
1060;; order.
1061(defun host-as-inet-host (host)
1062  (etypecase host
1063    (integer (htonl host))
1064    (string (or (and (every #'(lambda (c) (position c ".0123456789")) host)
1065                     (_inet_aton host))
1066                (multiple-value-bind (addr err) (c_gethostbyname host)
1067                  (or addr
1068                      (socket-error nil "gethostbyname" err t)))))))
1069
1070
1071(defun dotted-to-ipaddr (name &key (errorp t))
1072  "Convert a dotted-string representation of a host address to a 32-bit
1073unsigned IP address."
1074  (let ((addr (_inet_aton name)))
1075    (if addr (ntohl addr)
1076      (and errorp (error "Invalid dotted address ~s" name)))))
1077   
1078(defun lookup-hostname (host)
1079  "Convert a host spec in any of the acceptable formats into a 32-bit
1080unsigned IP address."
1081  (if (typep host 'integer)
1082    host
1083    (ntohl (host-as-inet-host host))))
1084
1085(defun ipaddr-to-dotted (addr &key values)
1086  "Convert a 32-bit unsigned IP address into octets."
1087  (let* ((a (ldb (byte 8 24) addr))
1088         (b (ldb (byte 8 16) addr))
1089         (c (ldb (byte 8  8) addr))
1090         (d (ldb (byte 8  0) addr)))
1091    (if values
1092      (values a b c d)
1093      (format nil "~d.~d.~d.~d" a b c d))))
1094
1095(defun ipaddr-to-hostname (ipaddr &key ignore-cache)
1096  "Convert a 32-bit unsigned IP address into a host name string."
1097  (declare (ignore ignore-cache))
1098  (multiple-value-bind (name err) (c_gethostbyaddr (htonl ipaddr))
1099    (or name (socket-error nil "gethostbyaddr" err t))))
1100 
1101
1102(defun int-getsockopt (socket level optname)
1103  (rlet ((valptr :signed)
1104         (vallen :signed))
1105    (setf (pref vallen :signed) 4)
1106    (let* ((err (c_getsockopt socket level optname valptr vallen)))
1107      (if (and (eql 0 err)
1108               (eql 4 (pref vallen :signed)))
1109        (pref valptr :signed)
1110        (socket-error socket "getsockopt" err)))))
1111
1112(defun timeval-setsockopt (socket level optname timeout)
1113    (multiple-value-bind (seconds micros)
1114        (microseconds timeout)
1115      (rlet ((valptr :timeval :tv_sec seconds :tv_usec micros))
1116        (socket-call socket "setsockopt"
1117          (c_setsockopt socket level optname valptr (record-length :timeval))))))
1118                   
1119(defun int-setsockopt (socket level optname optval)
1120  (rlet ((valptr :signed))
1121    (setf (pref valptr :signed) optval)
1122    (socket-call socket "setsockopt"
1123      (c_setsockopt socket level optname valptr (record-length :signed)))))
1124
1125
1126
1127           
1128(defun c_gethostbyaddr (addr-in-net-byte-order)
1129  (rletZ ((sin #>sockaddr_in))
1130    (setf (pref sin :sockaddr_in.sin_family) #$AF_INET
1131          (pref sin
1132                #+(or windows-target solaris-target) #>sockaddr_in.sin_addr.S_un.S_addr
1133                #-(or windows-target solaris-target) #>sockaddr_in.sin_addr.s_addr) addr-in-net-byte-order)
1134    #+darwin-target (setf (pref sin :sockaddr_in.sin_len) (record-length :sockaddr_in))
1135    (%stack-block ((namep #$NI_MAXHOST))
1136      (let* ((err (#_getnameinfo sin (record-length #>sockaddr_in) namep #$NI_MAXHOST (%null-ptr) 0 #$NI_NAMEREQD)))
1137        (if (eql 0 err)
1138          (%get-cstring namep)
1139          (values nil err))))))
1140               
1141(defun c_gethostbyname (name)
1142  (with-cstrs ((name (string name)))
1143    (rletZ ((hints #>addrinfo)
1144            (results :address))
1145      (setf (pref hints #>addrinfo.ai_family) #$AF_INET)
1146      (let* ((err (#_getaddrinfo name (%null-ptr) hints results)))
1147        (if (eql 0 err)
1148          (let* ((info (pref results :address))
1149                 (sin (pref info #>addrinfo.ai_addr)))
1150            (prog1
1151                #+(or windows-target solaris-target)
1152                (pref sin #>sockaddr_in.sin_addr.S_un.S_addr)
1153                #-(or windows-target solaris-target)
1154                (pref sin #>sockaddr_in.sin_addr.s_addr)
1155                (#_freeaddrinfo info)))
1156          (values nil err))))))
1157     
1158 
1159
1160 
1161
1162(defun _getservbyname (name proto)
1163  (with-cstrs ((name (string name))
1164               (proto (string proto)))
1165    (let* ((servent-ptr (%null-ptr)))
1166      (declare (dynamic-extent servent-ptr))
1167      (%setf-macptr servent-ptr (#_getservbyname name proto))
1168      (unless (%null-ptr-p servent-ptr)
1169        (pref servent-ptr :servent.s_port)))))
1170
1171(defun _inet_aton (string)
1172  (with-cstrs ((name string))
1173    #-windows-target
1174    (rlet ((addr :in_addr))
1175      (let* ((result #+freebsd-target (#___inet_aton name addr)
1176                     #-freebsd-target (#_inet_aton name addr)))
1177        (unless (eql result 0)
1178          (pref addr
1179                #-solaris-target :in_addr.s_addr
1180                #+solaris-target #>in_addr.S_un.S_addr
1181                ))))
1182    #+windows-target
1183    (rlet ((addr :sockaddr_in)
1184           (addrlenp :int (record-length :sockaddr_in)))
1185      (setf (pref addr :sockaddr_in.sin_family) #$AF_INET)
1186      (when (zerop (#_WSAStringToAddressA name #$AF_INET (%null-ptr)  addr addrlenp))
1187        (pref addr #>sockaddr_in.sin_addr.S_un.S_addr)))))
1188
1189(defun c_socket_1 (domain type protocol)
1190  #-windows-target (int-errno-call (#_socket domain type protocol))
1191  #+windows-target (let* ((handle (#_socket domain type protocol)))
1192                     (if (< handle 0)
1193                       (%get-winsock-error)
1194                       handle)))
1195
1196
1197
1198(defun c_socket (domain type protocol)
1199  (let* ((fd (c_socket_1 domain type protocol)))
1200    (when (or (eql fd (- #$EMFILE))
1201              (eql fd (- #$ENFILE)))
1202      (gc)
1203      (drain-termination-queue)
1204      (setq fd (c_socket_1 domain type protocol)))
1205    fd))
1206     
1207
1208#-windows-target
1209(defun init-unix-sockaddr (addr path)
1210  (macrolet ((sockaddr_un-path-len ()
1211               (/ (ensure-foreign-type-bits
1212                   (foreign-record-field-type 
1213                    (%find-foreign-record-type-field
1214                     (parse-foreign-type '(:struct :sockaddr_un)) :sun_path)))
1215                  8)))
1216    (let* ((name (native-translated-namestring path))
1217           (namelen (length name))
1218           (pathlen (sockaddr_un-path-len))
1219           (copylen (min (1- pathlen) namelen)))
1220      (setf (pref addr :sockaddr_un.sun_family) #$AF_UNIX)
1221      (let* ((sun-path (pref addr :sockaddr_un.sun_path)))
1222        (dotimes (i copylen)
1223          (setf (%get-unsigned-byte sun-path i)
1224                (let* ((code (char-code (schar name i))))
1225                  (if (> code 255)
1226                    (char-code #\Sub)
1227                    code))))))))
1228
1229#-windows-target
1230(defun bind-unix-socket (socketfd path)
1231  (rletz ((addr :sockaddr_un))
1232    (init-unix-sockaddr addr path)
1233    (socket-call
1234     nil
1235     "bind"
1236     (c_bind socketfd
1237             addr
1238             (+ 2
1239                (#_strlen
1240                 (pref addr :sockaddr_un.sun_path)))))))
1241     
1242
1243(defun c_bind (sockfd sockaddr addrlen)
1244  (check-socket-error (#_bind sockfd sockaddr addrlen)))
1245
1246
1247#+windows-target
1248(defun windows-connect-wait (sockfd timeout-in-milliseconds)
1249  (if (and timeout-in-milliseconds
1250           (< timeout-in-milliseconds 0))
1251    (setq timeout-in-milliseconds nil))
1252  (rlet ((writefds :fd_set)
1253         (exceptfds :fd_set)
1254         (tv :timeval :tv_sec 0 :tv_usec 0))
1255    (fd-zero writefds)
1256    (fd-zero exceptfds)
1257    (fd-set sockfd writefds)
1258    (fd-set sockfd exceptfds)
1259    (when timeout-in-milliseconds
1260      (multiple-value-bind (seconds milliseconds)
1261          (floor timeout-in-milliseconds 1000)
1262        (setf (pref tv :timeval.tv_sec) seconds
1263              (pref tv :timeval.tv_usec) (* 1000 milliseconds))))
1264    (> (#_select 1 (%null-ptr) writefds exceptfds (if timeout-in-milliseconds tv (%null-ptr))) 0)))
1265     
1266     
1267;;; If attempts to connnect are interrupted, we basically have to
1268;;; wait in #_select (or the equivalent).  There's a good rant
1269;;; about these issues in:
1270;;; <http://www.madore.org/~david/computers/connect-intr.html>
1271(defun c_connect (sockfd addr len &optional timeout-in-milliseconds)
1272  (let* ((was-blocking (get-socket-fd-blocking sockfd)))
1273    (unwind-protect
1274         (progn
1275           (set-socket-fd-blocking sockfd nil)
1276           (let* ((err (check-socket-error (#_connect sockfd addr len))))
1277             (cond ((or (eql err (- #+windows-target #$WSAEINPROGRESS
1278                                   
1279                                    #-windows-target #$EINPROGRESS))
1280                        #+windows-target (eql err (- #$WSAEWOULDBLOCK))
1281                        (eql err (- #$EINTR)))
1282                    (if
1283                      #+windows-target (windows-connect-wait sockfd timeout-in-milliseconds)
1284                      #-windows-target (process-output-wait sockfd timeout-in-milliseconds)
1285                      (- (int-getsockopt sockfd #$SOL_SOCKET #$SO_ERROR))
1286                      (- #+windows-target #$WSAETIMEDOUT #-windows-target #$ETIMEDOUT)))
1287                   (t err))))
1288      (set-socket-fd-blocking sockfd was-blocking))))
1289
1290(defun c_listen (sockfd backlog)
1291  (check-socket-error (#_listen sockfd backlog)))
1292
1293(defun c_accept (sockfd addrp addrlenp)
1294  (ignoring-eintr
1295   (check-socket-error (#_accept sockfd addrp addrlenp))))
1296
1297(defun c_getsockname (sockfd addrp addrlenp)
1298  (check-socket-error (#_getsockname sockfd addrp addrlenp)))
1299
1300(defun c_getpeername (sockfd addrp addrlenp)
1301  (check-socket-error (#_getpeername sockfd addrp addrlenp)))
1302
1303#-windows-target
1304(defun c_socketpair (domain type protocol socketsptr)
1305  (check-socket-error (#_socketpair domain type protocol socketsptr)))
1306
1307
1308(defun c_sendto (sockfd msgptr len flags addrp addrlen)
1309  (ignoring-eintr (check-socket-error (#_sendto sockfd msgptr len flags addrp addrlen))))
1310
1311(defun c_recvfrom (sockfd bufptr len flags addrp addrlenp)
1312  (ignoring-eintr (check-socket-error (#_recvfrom sockfd bufptr len flags addrp addrlenp))))
1313
1314(defun c_shutdown (sockfd how)
1315  (check-socket-error (#_shutdown sockfd how)))
1316
1317(defun c_setsockopt (sockfd level optname optvalp optlen)
1318  (check-socket-error (#_setsockopt sockfd level optname optvalp optlen)))
1319
1320(defun c_getsockopt (sockfd level optname optvalp optlenp)
1321  (check-socket-error (#_getsockopt sockfd level optname optvalp optlenp)))
1322
1323#-windows-target
1324(defun c_sendmsg (sockfd msghdrp flags)
1325  (check-socket-error (#_sendmsg sockfd msghdrp flags)))
1326
1327#-windows-target
1328(defun c_recvmsg (sockfd msghdrp flags)
1329  (check-socket-error   (#_recvmsg sockfd msghdrp flags)))
1330
1331;;; Return a list of currently configured interfaces, a la ifconfig.
1332(defstruct ip-interface
1333  name
1334  addr
1335  netmask
1336  flags
1337  address-family)
1338
1339(defun dump-buffer (p n)
1340  (dotimes (i n (progn (terpri) (terpri)))
1341    (unless (logtest i 15)
1342      (format t "~&~8,'0x: " (%ptr-to-int (%inc-ptr p i))))
1343    (format t " ~2,'0x" (%get-byte p i))))
1344
1345#-(or windows-target solaris-target)
1346(defun %get-ip-interfaces ()
1347  (rlet ((p :address (%null-ptr)))
1348    (if (zerop (#_getifaddrs p))
1349      (unwind-protect
1350           (do* ((q (%get-ptr p) (pref q :ifaddrs.ifa_next))
1351                 (res ()))
1352                ((%null-ptr-p q) (nreverse res))
1353             (let* ((addr (pref q :ifaddrs.ifa_addr)))
1354               (when (and (not (%null-ptr-p addr))
1355                          (eql (pref addr :sockaddr.sa_family) #$AF_INET))
1356                 (push (make-ip-interface
1357                        :name (%get-cstring (pref q :ifaddrs.ifa_name))
1358                        :addr (ntohl (pref addr :sockaddr_in.sin_addr.s_addr))
1359                        :netmask (ntohl
1360                                  (pref (pref q :ifaddrs.ifa_netmask)
1361                                       :sockaddr_in.sin_addr.s_addr))
1362                        :flags (pref q :ifaddrs.ifa_flags)
1363                        :address-family #$AF_INET)
1364                       res))))
1365        (#_freeifaddrs (pref p :address))))))
1366
1367#+solaris-target
1368(progn
1369  ;;; Interface translator has trouble with a lot of ioctl constants.
1370  (eval-when (:compile-toplevel :execute)
1371    (defconstant os::|SIOCGLIFNUM| #xc00c6982)
1372    (defconstant os::|SIOCGLIFCONF| #xc01069a5)
1373    (defconstant os::|SIOCGLIFADDR| #xc0786971)
1374    (defconstant os::|SIOCGLIFFLAGS| #xc0786975)
1375    (defconstant os::|SIOCGLIFNETMASK| #xc078697d)
1376    )
1377
1378(defun %get-ip-interfaces ()
1379  (let* ((sock (c_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_UDP))
1380         (res nil))
1381    (when (>= sock 0)
1382      (unwind-protect
1383           (let* ((flags (logior #$LIFC_NOXMIT #$LIFC_TEMPORARY #$LIFC_ALLZONES))
1384                  (ninterfaces (rlet ((lifnum :lifnum
1385                                        :lifn_flags flags
1386                                        :lifn_family #$AF_INET
1387                                        :lifn_count 0))
1388                                 (#_ioctl sock os::SIOCGLIFNUM :address lifnum)
1389                                 (pref lifnum :lifnum.lifn_count))))
1390             (declare (fixnum ninterfaces))
1391             (when (> ninterfaces 0)
1392               (let* ((bufsize (* ninterfaces (record-length :lifreq))))
1393                 (%stack-block ((buf bufsize :clear t))
1394                   (rlet ((lifc :lifconf
1395                            :lifc_family #$AF_INET
1396                            :lifc_flags flags
1397                            :lifc_len bufsize
1398                            :lifc_lifcu.lifcu_buf buf))
1399                     (when (>= (#_ioctl sock os::SIOCGLIFCONF :address lifc) 0)
1400                       (do* ((i 0 (1+ i))
1401                             (p (pref lifc :lifconf.lifc_lifcu.lifcu_buf)
1402                                (%inc-ptr p (record-length :lifreq))))
1403                            ((= i ninterfaces))
1404                         (let* ((name (%get-cstring (pref p :lifreq.lifr_name)))
1405                                (address-family (pref p :lifreq.lifr_lifru.lifru_addr.ss_family))
1406                                (if-flags nil)
1407                                (address nil)
1408                                (netmask nil))
1409                           (if (>= (#_ioctl sock os::SIOCGLIFFLAGS :address p)
1410                                   0)
1411                             (setq if-flags (pref p :lifreq.lifr_lifru.lifru_flags)))
1412                           (if (>= (#_ioctl sock os::SIOCGLIFADDR :address p)
1413                                   0)
1414                             (setq address (pref
1415                                            (pref p :lifreq.lifr_lifru.lifru_addr)
1416                                            #>sockaddr_in.sin_addr.S_un.S_addr)))
1417                           (if (>= (#_ioctl sock os::SIOCGLIFNETMASK :address p)
1418                                   0)
1419                             (setq netmask (pref
1420                                            (pref p :lifreq.lifr_lifru.lifru_subnet)
1421                                            #>sockaddr_in.sin_addr.S_un.S_addr)))
1422                             
1423                           (push (make-ip-interface
1424                                  :name name
1425                                  :addr (ntohl address)
1426                                  :netmask (ntohl netmask)
1427                                  :flags if-flags
1428                                  :address-family address-family)
1429                                 res)))))))))
1430        (fd-close sock)))
1431    res))
1432)
1433
1434
1435
1436
1437#+windows-target
1438(defun %get-ip-interfaces ()
1439  (let* ((socket (#_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_IP)))
1440    (unwind-protect
1441    (rlet ((realoutlen #>DWORD 0))
1442      (do* ((reservedlen (* 4 (record-length #>INTERFACE_INFO))
1443                         (* 2 reservedlen)))
1444           ()
1445        (%stack-block ((buf reservedlen))
1446          (unless (eql 0 (#_WSAIoctl
1447                          socket
1448                          #$SIO_GET_INTERFACE_LIST
1449                          (%null-ptr)
1450                          0
1451                          buf
1452                          reservedlen
1453                          realoutlen
1454                          (%null-ptr)
1455                          (%null-ptr)))
1456            (return))
1457          (let* ((noutbytes (pref realoutlen #>DWORD)))
1458            (when (< noutbytes reservedlen)
1459              (let* ((interfaces nil))
1460                (do* ((offset 0 (+ offset (record-length #>INTERFACE_INFO)))
1461                      (nameidx 0 (1+ nameidx)))
1462                     ((>= offset noutbytes))
1463                  (with-macptrs ((p (%inc-ptr buf offset)))
1464                    (push (make-ip-interface 
1465                           :name (format nil "ip~d" nameidx)
1466                           :addr (ntohl
1467                                  (pref (pref p #>INTERFACE_INFO.iiAddress)
1468                                        #>sockaddr_gen.AddressIn.sin_addr.S_un.S_addr))
1469                           :netmask (ntohl
1470                                     (pref (pref p #>INTERFACE_INFO.iiNetmask)
1471                                        #>sockaddr_gen.AddressIn.sin_addr.S_un.S_addr))
1472                           :flags (pref p #>INTERFACE_INFO.iiFlags)
1473                           :address-family #$AF_INET)
1474                          interfaces)))
1475                (return interfaces)))))))
1476      (#_closesocket socket))))
1477
1478     
1479
1480
1481(defloadvar *ip-interfaces* ())
1482
1483(defun ip-interfaces ()
1484  (or *ip-interfaces*
1485      (setq *ip-interfaces* (%get-ip-interfaces))))
1486
1487;;; This should presumably happen after a configuration change.
1488;;; How do we detect a configuration change ?
1489(defun %reset-ip-interfaces ()
1490  (setq *ip-interfaces* ()))
1491
1492;;; Return the first non-loopback interface that's up and whose address
1493;;; family is #$AF_INET.  If no such interface exists, return
1494;;; the loopback interface.
1495(defun primary-ip-interface ()
1496  (let* ((ifaces (ip-interfaces)))
1497    (or (find-if #'(lambda (i)
1498                     (and (eq #$AF_INET (ip-interface-address-family i))
1499                          (ip-interface-addr i)
1500                          (let* ((flags (ip-interface-flags i)))
1501                            (and (not (logtest #$IFF_LOOPBACK flags))
1502                                 (logtest #$IFF_UP flags)))))
1503                 ifaces)
1504        (car ifaces))))
1505
1506(defun primary-ip-interface-address ()
1507  (let* ((iface (primary-ip-interface)))
1508    (if iface
1509      (ip-interface-addr iface)
1510      (error "Can't determine primary IP interface"))))
1511         
1512         
1513(defmethod stream-io-error ((stream socket) errno where)
1514  (socket-error stream where errno))
Note: See TracBrowser for help on using the repository browser.