source: trunk/source/level-1/l1-sockets.lisp @ 12165

Last change on this file since 12165 was 12165, checked in by rme, 10 years ago

SET-SOCKET-OPTIONS: linger makes sense only for TCP sockets. (ticket:519)

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 54.4 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2001 Clozure Associates
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17(in-package "CCL")
18
19
20
21;;; basic socket API
22(eval-when (:compile-toplevel :load-toplevel :execute)
23  (export '(MAKE-SOCKET
24            ACCEPT-CONNECTION
25            DOTTED-TO-IPADDR
26            IPADDR-TO-DOTTED
27            IPADDR-TO-HOSTNAME
28            LOOKUP-HOSTNAME
29            LOOKUP-PORT
30            ;;with-pending-connect
31            RECEIVE-FROM
32            SEND-TO
33            SHUTDOWN
34            ;;socket-control
35            SOCKET-OS-FD
36            REMOTE-HOST
37            REMOTE-PORT
38            REMOTE-FILENAME
39            LOCAL-HOST
40            LOCAL-PORT
41            LOCAL-FILENAME
42            SOCKET-ADDRESS-FAMILY
43            SOCKET-CONNECT
44            SOCKET-FORMAT
45            SOCKET-TYPE
46            SOCKET-ERROR
47            SOCKET-ERROR-CODE
48            SOCKET-ERROR-IDENTIFIER
49            SOCKET-ERROR-SITUATION
50            WITH-OPEN-SOCKET))
51  #+windows-target
52  (defmacro check-winsock-error (form)
53    (let* ((val (gensym)))
54      `(let* ((,val ,form))
55        (if (< ,val 0)
56          (%get-winsock-error)
57          ,val))))
58  (defmacro check-socket-error (form)
59    #+windows-target `(check-winsock-error ,form)
60    #-windows-target `(int-errno-call ,form))
61  )
62
63
64#+windows-target
65(defun %get-winsock-error ()
66  (- (#_WSAGetLastError)))
67
68;;; The PPC is big-endian (uses network byte order), which makes
69;;; things like #_htonl and #_htonl no-ops.  These functions aren't
70;;; necessarily defined as functions in some header files (I'm sure
71;;; that that either complies with or violates some C standard), and
72;;; it doesn't seem to make much sense to fight that to do ff-calls
73;;; to a couple of identity functions.
74
75#+big-endian-target
76(progn
77  (defmacro HTONL (x) x)
78  (defmacro HTONS (x) x)
79  (defmacro NTOHL (x) x)
80  (defmacro NTOHS (x) x))
81
82#+little-endian-target
83(progn
84  (declaim (inline %bswap32 %bswap16))
85  (defun %bswap32 (x)
86    (declare (type (unsigned-byte 32) x))
87    (%swap-u32 x))
88  (defun %bswap16 (x)
89    (declare (type (unsigned-byte 16) x))
90    (%swap-u16 x))
91  (defmacro HTONL (x) `(%bswap32 ,x))
92  (defmacro HTONS (x) `(%bswap16 ,x))
93  (defmacro NTOHL (x) `(%bswap32 ,x))
94  (defmacro NTOHS (x) `(%bswap16 ,x)))
95
96(defparameter *default-socket-character-encoding*
97  nil)
98
99(defmethod default-character-encoding ((domain (eql :socket)))
100  *default-socket-character-encoding*)
101 
102
103;;; On some (hypothetical) little-endian platform, we might want to
104;;; define HTONL and HTONS to actually swap bytes around.
105
106(defpackage "OPENMCL-SOCKET"
107  (:use "CL")
108  (:import-from "CCL"
109                "MAKE-SOCKET"
110                "ACCEPT-CONNECTION"
111                "DOTTED-TO-IPADDR"
112                "IPADDR-TO-DOTTED"
113                "IPADDR-TO-HOSTNAME"
114                "LOOKUP-HOSTNAME"
115                "LOOKUP-PORT"
116                ;;with-pending-connect
117                "RECEIVE-FROM"
118                "SEND-TO"
119                "SHUTDOWN"
120                ;;socket-control
121                "SOCKET-OS-FD"
122                "REMOTE-HOST"
123                "REMOTE-PORT"
124                "REMOTE-FILENAME"
125                "LOCAL-HOST"
126                "LOCAL-PORT"
127                "LOCAL-FILENAME"
128                "SOCKET-ADDRESS-FAMILY"
129                "SOCKET-CONNECT"
130                "SOCKET-FORMAT"
131                "SOCKET-TYPE"
132                "SOCKET-ERROR"
133                "SOCKET-ERROR-CODE"
134                "SOCKET-ERROR-IDENTIFIER"
135                "SOCKET-ERROR-SITUATION"
136                "WITH-OPEN-SOCKET")
137  (:export  "MAKE-SOCKET"
138            "ACCEPT-CONNECTION"
139            "DOTTED-TO-IPADDR"
140            "IPADDR-TO-DOTTED"
141            "IPADDR-TO-HOSTNAME"
142            "LOOKUP-HOSTNAME"
143            "LOOKUP-PORT"
144            ;;with-pending-connect
145            "RECEIVE-FROM"
146            "SEND-TO"
147            "SHUTDOWN"
148            ;;socket-control
149            "SOCKET-OS-FD"
150            "REMOTE-HOST"
151            "REMOTE-PORT"
152            "REMOTE-FILENAME"
153            "LOCAL-HOST"
154            "LOCAL-PORT"
155            "LOCAL-FILENAME"
156            "SOCKET-ADDRESS-FAMILY"
157            "SOCKET-CONNECT"
158            "SOCKET-FORMAT"
159            "SOCKET-TYPE"
160            "SOCKET-ERROR"
161            "SOCKET-ERROR-CODE"
162            "SOCKET-ERROR-IDENTIFIER"
163            "SOCKET-ERROR-SITUATION"
164            "WITH-OPEN-SOCKET"))
165
166
167
168(define-condition socket-error (simple-stream-error)
169  ((code :initarg :code :reader socket-error-code)
170   (identifier :initform :unknown :initarg :identifier :reader socket-error-identifier)
171   (Situation :initarg :situation :reader socket-error-situation)))
172
173(define-condition socket-creation-error (simple-error)
174  ((code :initarg :code :reader socket-creation-error-code)
175   (identifier :initform :unknown :initarg :identifier :reader socket-creation-error-identifier)
176   (situation :initarg :situation :reader socket-creation-error-situation)))
177
178(defvar *socket-error-identifiers*
179  #-windows-target
180  (list #$EADDRINUSE :address-in-use
181        #$ECONNABORTED :connection-aborted
182        #$ENOBUFS :no-buffer-space
183        #$ENOMEM :no-buffer-space
184        #$ENFILE :no-buffer-space
185        #$ETIMEDOUT :connection-timed-out
186        #$ECONNREFUSED :connection-refused
187        #$ENETUNREACH :host-unreachable
188        #$EHOSTUNREACH :host-unreachable
189        #$EHOSTDOWN :host-down
190        #$ENETDOWN :network-down
191        #$EADDRNOTAVAIL :address-not-available
192        #$ENETRESET :network-reset
193        #$ECONNRESET :connection-reset
194        #$ESHUTDOWN :shutdown
195        #$EACCES :access-denied
196        #$EPERM :access-denied)
197  #+windows-target
198  (list #$WSAEADDRINUSE :address-in-use
199        #$WSAECONNABORTED :connection-aborted
200        #$WSAENOBUFS :no-buffer-space
201        #$ENOMEM :no-buffer-space
202        #$ENFILE :no-buffer-space
203        #$WSAETIMEDOUT :connection-timed-out
204        #$WSAECONNREFUSED :connection-refused
205        #$WSAENETUNREACH :host-unreachable
206        #$WSAEHOSTUNREACH :host-unreachable
207        #$WSAEHOSTDOWN :host-down
208        #$WSAENETDOWN :network-down
209        #$WSAEADDRNOTAVAIL :address-not-available
210        #$WSAENETRESET :network-reset
211        #$WSAECONNRESET :connection-reset
212        #$WSAESHUTDOWN :shutdown
213        #$EACCES :access-denied
214        #$EPERM :access-denied)
215  )
216
217
218(declaim (inline socket-call))
219(defun socket-call (stream where res)
220  (if (< res 0)
221    (socket-error stream where res)
222    res))
223
224#-windows-target
225(defun %gai-strerror (errno)
226  (let* ((err (abs errno))
227         (p (#_gai_strerror err)))
228    (if (%null-ptr-p p)
229      (format nil "Unknown nameserver error ~d" err)
230      (%get-cstring p))))
231   
232
233
234(defun socket-error (stream where errno &optional nameserver-p)
235  "Creates and signals (via error) one of two socket error
236conditions, based on the state of the arguments."
237  #+windows-target (declare (ignore nameserver-p))
238  (when (< errno 0)
239    (setq errno (- errno)))
240  (if stream
241    (error (make-condition 'socket-error
242                           :stream stream
243                           :code errno
244                           :identifier (getf *socket-error-identifiers* errno :unknown)
245                           :situation where
246                           ;; TODO: this is a constant arg, there is a way to put this
247                           ;; in the class definition, just need to remember how...
248                           :format-control "~a (error #~d) during ~a"
249                           :format-arguments (list
250                                              #+windows-target
251                                              (%windows-error-string errno)
252                                              #-windows-target
253                                              (if nameserver-p
254                                                (%gai-strerror errno)
255                                                (%strerror errno))
256                                              errno where)))
257    (error (make-condition 'socket-creation-error
258                           :code errno
259                           :identifier (getf *socket-error-identifiers* errno :unknown)
260                           :situation where
261                           ;; TODO: this is a constant arg, there is a way to put this
262                           ;; in the class definition, just need to remember how...
263                           :format-control "~a (error #~d) during socket creation or nameserver operation in ~a"
264                           :format-arguments (list
265                                              #+windows-target
266                                              (%windows-error-string errno)
267                                              #-windows-target
268                                              (if nameserver-p
269                                                (%gai-strerror errno)
270                                                (%strerror errno))
271                                              errno where)))))
272   
273
274
275;; If true, this will try to allow other cooperative processes to run
276;; while socket io is happening.  Since CCL threads are preemptively
277;; scheduled, this isn't particularly meaningful.
278(defvar *multiprocessing-socket-io* nil)
279
280(defclass socket ()
281  ())
282
283(defmacro with-open-socket ((var . args) &body body
284                            &aux (socket (make-symbol "socket"))
285                                 (done (make-symbol "done")))
286  "Execute body with var bound to the result of applying make-socket to
287make-socket-args. The socket gets closed on exit."
288  `(let (,socket ,done)
289     (unwind-protect
290         (multiple-value-prog1
291           (let ((,var (setq ,socket (make-socket ,@args))))
292             ,@body)
293           (setq ,done t))
294       (when ,socket (close ,socket :abort (not ,done))))))
295
296(defgeneric socket-address-family (socket)
297  (:documentation "Return :internet or :file, as appropriate."))
298
299(defclass ip-socket (socket)
300  ())
301
302(defmethod socket-address-family ((socket ip-socket)) :internet)
303
304(defclass file-socket (socket)
305  ())
306
307(defmethod socket-address-family ((socket file-socket)) :file)
308
309(defclass tcp-socket (ip-socket)
310  ())
311
312(defgeneric socket-type (socket)
313  (:documentation
314   "Return :stream for tcp-stream and listener-socket, and :datagram
315for udp-socket."))
316
317(defmethod socket-type ((socket tcp-socket)) :stream)
318
319(defclass stream-file-socket (file-socket)
320  ())
321
322(defmethod socket-type ((socket stream-file-socket)) :stream)
323
324
325;;; An active TCP socket is an honest-to-goodness stream.
326(defclass tcp-stream (tcp-socket)
327  ())
328
329(defclass fundamental-tcp-stream (tcp-stream
330                                  fd-stream
331                                  buffered-binary-io-stream-mixin
332                                  buffered-character-io-stream-mixin)
333    ())
334
335(make-built-in-class 'basic-tcp-stream
336                     'tcp-stream
337                     'basic-binary-io-stream
338                     'basic-character-io-stream)
339
340(defgeneric socket-connect (stream)
341 (:documentation
342   "Return :active for tcp-stream, :passive for listener-socket, and NIL
343for udp-socket"))
344
345(defmethod socket-connect ((stream tcp-stream)) :active)
346
347(defgeneric socket-format (stream)
348  (:documentation
349   "Return the socket format as specified by the :format argument to
350make-socket."))
351
352(defmethod socket-format ((stream tcp-stream))
353  (if (eq (stream-element-type stream) 'character)
354    :text
355    ;; Should distinguish between :binary and :bivalent, but hardly
356    ;; seems worth carrying around an extra slot just for that.
357    :bivalent))
358
359(defmethod socket-device ((stream tcp-stream))
360  (let ((ioblock (stream-ioblock stream nil)))
361    (and ioblock (ioblock-device ioblock))))
362
363(defmethod select-stream-class ((class tcp-stream) in-p out-p char-p)
364  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
365  ;; Yes, in general.  There is.
366  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
367  'fundamental-tcp-stream)
368
369(defmethod map-to-basic-stream-class-name ((name (eql 'tcp-stream)))
370  'basic-tcp-stream)
371
372(defmethod select-stream-class ((s (eql 'basic-tcp-stream)) in-p out-p char-p)
373  (declare (ignore char-p))
374  (assert (and in-p out-p) () "Non-bidirectional tcp stream?")
375  'basic-tcp-stream)
376
377;;; A FILE-SOCKET-STREAM is also honest. To goodness.
378(defclass file-socket-stream (stream-file-socket)
379  ())
380
381(defclass fundamental-file-socket-stream (file-socket-stream
382                                          fd-stream
383                                          buffered-binary-io-stream-mixin
384                                          buffered-character-io-stream-mixin)
385    ())
386
387(make-built-in-class 'basic-file-socket-stream
388                     'file-socket-stream
389                     'basic-binary-io-stream
390                     'basic-character-io-stream)
391
392
393(defmethod map-to-basic-stream-class-name ((name (eql 'file-socket-stream)))
394  'basic-file-socket-stream)
395
396(defmethod select-stream-class ((class file-socket-stream) in-p out-p char-p)
397  (declare (ignore char-p)) ; TODO: is there any real reason to care about this?
398  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
399  'fundamental-file-socket-stream)
400
401(defmethod select-stream-class ((s (eql 'basic-file-socket-stream)) in-p out-p char-p)
402  (declare (ignore char-p))
403  (assert (and in-p out-p) () "Non-bidirectional file-socket stream?")
404  'basic-file-socket-stream)
405
406(defclass unconnected-socket (socket)
407  ((device :initarg :device :accessor socket-device)
408   (keys :initarg :keys :reader socket-keys)))
409
410(defmethod socket-format ((socket unconnected-socket))
411  (or (getf (socket-keys socket) :format) :text))
412
413(defgeneric close (socket &key abort)
414  (:documentation
415   "The close generic function can be applied to sockets. It releases the
416operating system resources associated with the socket."))
417
418(defmethod close ((socket unconnected-socket) &key abort)
419  (declare (ignore abort))
420  (when (socket-device socket)
421    (fd-close (socket-device socket))
422    (setf (socket-device socket) nil)
423    t))
424
425;; A passive tcp socket just generates connection streams
426(defclass listener-socket (tcp-socket unconnected-socket) ())
427
428(defmethod SOCKET-CONNECT ((stream listener-socket)) :passive)
429
430(defclass file-listener-socket (stream-file-socket unconnected-socket) ())
431
432(defmethod SOCKET-CONNECT ((stream file-listener-socket)) :passive)
433
434;;; A FILE-LISTENER-SOCKET should try to delete the filesystem
435;;; entity when closing.
436
437#-windows-target
438(defmethod close :before ((s file-listener-socket) &key abort)
439  (declare (ignore abort))
440  (let* ((path (local-socket-filename (socket-device s) s)))
441    (when path (%delete-file path))))
442
443
444;; A udp socket just sends and receives packets.
445(defclass udp-socket (ip-socket unconnected-socket) ())
446
447(defmethod socket-type ((stream udp-socket)) :datagram)
448(defmethod socket-connect ((stream udp-socket)) nil)
449
450(defgeneric socket-os-fd (socket)
451  (:documentation
452   "Return the native OS's representation of the socket, or NIL if the
453socket is closed. On Unix, this is the Unix 'file descriptor', a small
454non-negative integer. Note that it is rather dangerous to mess around
455with tcp-stream fd's, as there is all sorts of buffering and asynchronous
456I/O going on above the OS level. listener-socket and udp-socket fd's are
457safer to mess with directly as there is less magic going on."))
458
459;; Returns nil for closed stream...
460(defmethod socket-os-fd ((socket socket))
461  (socket-device socket))
462
463;; Returns nil for closed stream
464(defun local-socket-info (fd type socket)
465  (and fd
466       (rlet ((sockaddr :sockaddr_in)
467              (namelen :signed))
468             (setf (pref namelen :signed) (record-length :sockaddr_in))
469             (socket-call socket "getsockname" (c_getsockname fd sockaddr namelen))
470             (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
471               (ecase type
472                 (:host (ntohl (pref sockaddr
473                                     #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
474                                     #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr)))
475                 (:port (ntohs (pref sockaddr :sockaddr_in.sin_port))))))))
476
477#-windows-target
478(defun path-from-unix-address (addr)
479  (when (= #$AF_UNIX (pref addr :sockaddr_un.sun_family))
480    #+darwin-target
481    (%str-from-ptr (pref addr :sockaddr_un.sun_path)
482                   (- (pref addr :sockaddr_un.sun_len) 2))
483    #-darwin-target
484    (%get-cstring (pref addr :sockaddr_un.sun_path))))
485
486#-windows-target
487(defun local-socket-filename (fd socket)
488  (and fd
489       (rlet ((addr :sockaddr_un)
490              (namelen :signed))
491         (setf (pref namelen :signed) (record-length :sockaddr_un))
492         (socket-call socket "getsockname" (c_getsockname fd addr namelen))
493         (path-from-unix-address addr))))
494
495(defmacro with-if ((var expr) &body body)
496  `(let ((,var ,expr))
497     (if ,var
498         (progn
499           ,@body))))     
500
501(defun remote-socket-info (socket type)
502  (with-if (fd (socket-device socket))
503    (rlet ((sockaddr :sockaddr_in)
504           (namelen :signed))
505          (setf (pref namelen :signed) (record-length :sockaddr_in))
506          (let ((err (c_getpeername fd sockaddr namelen)))
507            (cond ((eql err (- #+windows-target #$WSAENOTCONN #-windows-target #$ENOTCONN)) nil)
508                  ((< err 0) (socket-error socket "getpeername" err))
509                  (t
510                   (when (= #$AF_INET (pref sockaddr :sockaddr_in.sin_family))
511                     (ecase type
512                       (:host (ntohl (pref sockaddr
513                                           #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
514                                           #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr)))
515                       (:port (ntohs  (pref sockaddr :sockaddr_in.sin_port)))))))))))
516
517#-windows-target
518(defun remote-socket-filename (socket)
519  (with-if (fd (socket-device socket))
520    (rlet ((addr :sockaddr_un)
521           (namelen :signed))
522          (setf (pref namelen :signed) (record-length :sockaddr_un))
523          (let* ((err (c_getsockname fd addr namelen)))
524            (cond ((eql err (- #$ENOTCONN)) nil)
525                  ((< err 0) (socket-error socket "getpeername" err))
526                  (t (path-from-unix-address addr)))))))
527
528(defgeneric local-port (socket)
529  (:documentation "Return the local port number."))
530
531(defmethod local-port ((socket socket))
532  (local-socket-info (socket-device socket) :port socket))
533
534(defgeneric local-host (socket)
535  (:documentation
536   "Return 32-bit unsigned IP address of the local host."))
537
538(defmethod local-host ((socket socket))
539  (local-socket-info (socket-device socket) :host socket))
540
541#-windows-target
542(defmethod local-filename ((socket socket))
543  (local-socket-filename (socket-device socket) socket))
544
545(defgeneric remote-host (socket)
546  (:documentation
547   "Return the 32-bit unsigned IP address of the remote host, or NIL if
548the socket is not connected."))
549
550;; Returns NIL if socket is not connected
551(defmethod remote-host ((socket socket))
552  (remote-socket-info socket :host))
553
554(defgeneric remote-port (socket)
555  (:documentation
556   "Return the remote port number, or NIL if the socket is not connected."))
557
558(defmethod remote-port ((socket socket))
559  (remote-socket-info socket :port))
560
561#-windows-target
562(defmethod remote-filename ((socket socket))
563  (remote-socket-filename socket))
564 
565(defun set-socket-fd-blocking (fd block-flag)
566  #+windows-target
567  (rlet ((argp :u_long (if block-flag 0 1)))
568    (#_ioctlsocket fd #$FIONBIO argp))
569  #-windows-target
570  (if block-flag
571    (fd-clear-flag fd #$O_NONBLOCK)
572    (fd-set-flag fd #$O_NONBLOCK)))
573
574(defun get-socket-fd-blocking (fd)
575  "returns T iff socket is in blocking mode"
576  #+windows-target (declare (ignore fd))
577  #+windows-target t
578  #-windows-target
579  (not (logtest #$O_NONBLOCK (fd-get-flags fd))))
580
581(defun set-socket-options (fd-or-socket &key 
582                           keepalive
583                           reuse-address
584                           nodelay
585                           broadcast
586                           linger
587                           address-family
588                           local-port
589                           local-host
590                           local-filename
591                           type
592                           connect
593                           out-of-band-inline
594                           &allow-other-keys)
595  ;; see man socket(7) tcp(7) ip(7)
596  (multiple-value-bind (socket fd) (etypecase fd-or-socket
597                                     (socket (values fd-or-socket (socket-device fd-or-socket)))
598                                     (integer (values nil fd-or-socket)))
599   
600    (if (null address-family)
601        (setq address-family :internet))
602    (when keepalive
603      (int-setsockopt fd #$SOL_SOCKET #$SO_KEEPALIVE 1))
604    (when reuse-address
605      (int-setsockopt fd #$SOL_SOCKET #$SO_REUSEADDR 1))
606    (when broadcast
607      (int-setsockopt fd #$SOL_SOCKET #$SO_BROADCAST 1))
608    (when out-of-band-inline
609      (int-setsockopt fd #$SOL_SOCKET #$SO_OOBINLINE 1))
610    (when (eq address-family :internet)
611      (when (eq type :stream)
612        (rlet ((plinger :linger))
613          (setf (pref plinger :linger.l_onoff) (if linger 1 0)
614                (pref plinger :linger.l_linger) (or linger 0))
615          (socket-call socket "setsockopt"
616                       (c_setsockopt fd #$SOL_SOCKET #$SO_LINGER
617                                     plinger (record-length :linger)))))
618      (when nodelay
619        (int-setsockopt fd
620                        #+linux-target #$SOL_TCP
621                        #-linux-target #$IPPROTO_TCP
622                        #$TCP_NODELAY 1))
623      (when (or local-port local-host)
624        (let* ((proto (if (eq type :stream) "tcp" "udp"))
625               (port-n (if local-port (port-as-inet-port local-port proto) 0))
626               (host-n (if local-host (host-as-inet-host local-host) #$INADDR_ANY)))
627          ;; Darwin includes the SIN_ZERO field of the sockaddr_in when
628          ;; comparing the requested address to the addresses of configured
629          ;; interfaces (as if the zeros were somehow part of either address.)
630          ;; "rletz" zeros out the stack-allocated structure, so those zeros
631          ;; will be 0.
632          (rletz ((sockaddr :sockaddr_in))
633                 (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
634                       (pref sockaddr :sockaddr_in.sin_port) port-n
635                       (pref sockaddr
636                             #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
637                             #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr
638                             ) host-n)
639                 (socket-call socket "bind" (c_bind fd sockaddr (record-length :sockaddr_in)))))))
640    (when (and (eq address-family :file)
641               (eq connect :passive)
642               local-filename)
643      #+windows-target (error "can't create file socket on Windows")
644      #-windows-target (bind-unix-socket fd local-filename))))
645
646;; I hope the inline declaration makes the &rest/apply's go away...
647(declaim (inline make-ip-socket))
648(defun make-ip-socket (&rest keys &key type &allow-other-keys)
649  (declare (dynamic-extent keys))
650  (ecase type
651    ((nil :stream) (apply #'make-tcp-socket keys))
652    ((:datagram) (apply #'make-udp-socket keys))))
653
654(declaim (inline make-file-socket))
655(defun make-file-socket (&rest keys &key type &allow-other-keys)
656  (declare (dynamic-extent keys))
657  (ecase type
658    ((nil :stream) (apply #'make-stream-file-socket keys))
659    (:datagram (apply #'make-datagram-file-socket keys))))
660
661(defun make-socket (&rest keys
662                    &key address-family
663                    ;; List all keys here just for error checking...
664                    ;; &allow-other-keys
665                    type connect remote-host remote-port eol format
666                    keepalive reuse-address nodelay broadcast linger
667                    local-port local-host backlog class out-of-band-inline
668                    local-filename remote-filename sharing basic
669                    external-format (auto-close t)
670                    connect-timeout input-timeout output-timeout deadline
671                    fd)
672  "Create and return a new socket."
673  (declare (dynamic-extent keys))
674  (declare (ignore type connect remote-host remote-port eol format
675                   keepalive reuse-address nodelay broadcast linger
676                   local-port local-host backlog class out-of-band-inline
677                   local-filename remote-filename sharing basic external-format
678                   auto-close connect-timeout input-timeout output-timeout deadline fd))
679  (ecase address-family
680    ((:file) (apply #'make-file-socket keys))
681    ((nil :internet) (apply #'make-ip-socket keys))))
682
683
684
685(defun make-udp-socket (&rest keys &key (fd -1) &allow-other-keys)
686  (unwind-protect
687    (let (socket)
688      (when (< fd 0)
689        (setq fd (socket-call nil "socket"
690                              (c_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_UDP))))
691      (apply #'set-socket-options fd keys)
692      (setq socket (make-instance 'udp-socket
693                                  :device fd
694                                  :keys keys))
695      (setq fd -1)
696      socket)
697    (unless (< fd 0)
698      (fd-close fd))))
699
700(defun make-tcp-socket (&rest keys &key connect (fd -1) &allow-other-keys)
701  (unwind-protect
702       (let (socket)
703         (when (< fd 0)
704           (setq fd (socket-call nil "socket"
705                                 (c_socket #$AF_INET #$SOCK_STREAM #$IPPROTO_TCP))))
706         (apply #'set-socket-options fd keys)
707         (setq socket
708               (ecase connect
709                 ((nil :active) (apply #'make-tcp-stream-socket fd keys))
710                 ((:passive) (apply #'make-tcp-listener-socket fd keys))))
711         (setq fd -1)
712         socket)
713    (unless (< fd 0)
714      (fd-close fd))))
715
716(defun make-stream-file-socket (&rest keys &key connect (fd -1) &allow-other-keys)
717  (unwind-protect
718       (let (socket)
719         (when (< fd 0)
720           (setq fd (socket-call nil "socket" (c_socket #$PF_UNIX #$SOCK_STREAM 0))))
721         (apply #'set-socket-options fd keys)
722         (setq socket
723               (ecase connect
724                 ((nil :active) (apply #'make-file-stream-socket fd keys))
725                 ((:passive) (apply #'make-file-listener-socket fd keys))))
726         (setq fd -1)
727         socket)
728    (unless (< fd 0)
729      (fd-close fd))))
730
731(defun make-datagram-file-socket (&rest keys)
732  (declare (ignore keys))
733  (error "Datagram file sockets aren't implemented."))
734
735
736(defun %socket-connect (fd addr addrlen &optional timeout-in-milliseconds)
737  (let* ((err (c_connect fd addr addrlen timeout-in-milliseconds)))
738    (declare (fixnum err))
739    (unless (eql err 0) (fd-close fd) (socket-error nil "connect" err))))
740   
741(defun inet-connect (fd host-n port-n &optional timeout-in-milliseconds)
742  (rlet ((sockaddr :sockaddr_in))
743    (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET
744          (pref sockaddr :sockaddr_in.sin_port) port-n
745          (pref sockaddr
746                #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
747                #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr
748                ) host-n)
749    (%socket-connect fd sockaddr (record-length :sockaddr_in) timeout-in-milliseconds)))
750
751#-windows-target
752(defun file-socket-connect (fd remote-filename)
753  (rletz ((sockaddr :sockaddr_un))
754    (init-unix-sockaddr sockaddr remote-filename)
755    (%socket-connect fd sockaddr (record-length :sockaddr_un))))
756
757#+windows-target
758(defun file-socket-connect (fd remote-filename)
759  (declare (ignore fd))
760  (error "Can't create file socket to ~s on Windows" remote-filename))
761 
762(defun make-tcp-stream-socket (fd &rest keys
763                                  &key remote-host
764                                  remote-port
765                                  connect-timeout
766                                  deadline
767                                  &allow-other-keys)
768  (let* ((timeout-in-milliseconds
769          (if deadline
770            (max (round (- deadline (get-internal-real-time))
771                        (/ internal-time-units-per-second 1000))
772                 0)
773            (if connect-timeout
774              (round (* connect-timeout 1000))))))
775    (inet-connect fd
776                  (host-as-inet-host remote-host)
777                  (port-as-inet-port remote-port "tcp")
778                  timeout-in-milliseconds)
779    (apply #'make-tcp-stream fd keys)))
780
781(defun make-file-stream-socket (fd &rest keys
782                                   &key remote-filename
783                                   &allow-other-keys)
784  (file-socket-connect fd remote-filename)
785  (apply #'make-file-socket-stream fd keys))
786
787
788(defun make-tcp-stream (fd
789                        &key (format :bivalent)
790                             external-format
791                             (class 'tcp-stream)
792                             sharing
793                             (basic t)
794                             (auto-close t)
795                             input-timeout
796                             output-timeout
797                             deadline
798                        &allow-other-keys)
799  (let* ((external-format (normalize-external-format :socket external-format)))
800    (let ((element-type (ecase format
801                          ((nil :text) 'character)
802                          ((:binary :bivalent) '(unsigned-byte 8)))))
803      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
804      ;; See if should specialize any of 'em.
805      (make-fd-stream fd
806                      :class class
807                      :direction :io
808                      :element-type element-type
809                      :sharing sharing
810                      :character-p (not (eq format :binary))
811                      :encoding (external-format-character-encoding external-format)
812                      :line-termination (external-format-line-termination external-format)
813                      :basic basic
814                      :auto-close auto-close
815                      :input-timeout input-timeout
816                      :output-timeout output-timeout
817                      :deadline deadline))))
818
819(defun make-file-socket-stream (fd
820                                &key (format :bivalent)
821                                external-format
822                                (class 'file-socket-stream)
823                                sharing
824                                basic
825                                (auto-close t)
826                                input-timeout
827                                output-timeout
828                                deadline
829                                &allow-other-keys)
830  (let* ((external-format (normalize-external-format :socket external-format)))
831 
832    (let ((element-type (ecase format
833                          ((nil :text) 'character)
834                          ((:binary :bivalent) '(unsigned-byte 8)))))
835      ;; TODO: check out fd-stream-advance, -listen, -eofp, -force-output, -close
836      ;; See if should specialize any of 'em.
837      (make-fd-stream fd
838                      :class class
839                      :direction :io
840                      :element-type element-type
841                      :encoding (external-format-character-encoding external-format)
842                      :line-termination (external-format-line-termination external-format)
843                      :sharing sharing
844                      :character-p (not (eq format :binary))
845                      :basic basic
846                      :auto-close auto-close
847                      :input-timeout input-timeout
848                      :output-timeout output-timeout
849                      :deadline deadline))))
850
851(defun make-tcp-listener-socket (fd &rest keys &key backlog &allow-other-keys)
852  (socket-call nil "listen" (c_listen fd (or backlog 5)))
853  (make-instance 'listener-socket
854                 :device fd
855                 :keys keys))
856
857(defun make-file-listener-socket (fd &rest keys &key backlog &allow-other-keys)
858  (socket-call nil "listen" (c_listen fd (or backlog 5)))
859  (make-instance 'file-listener-socket
860                 :device fd
861                 :keys keys))
862
863(defun socket-accept (fd wait)
864  (flet ((_accept (fd async)
865           (let ((res (c_accept fd (%null-ptr) (%null-ptr))))
866             (declare (fixnum res))
867             ;; See the inscrutable note under ERROR HANDLING in
868             ;; man accept(2). This is my best guess at what they mean...
869             (if (and async (< res 0)
870                      #+windows-target
871                      (= res #$WSAEWOULDBLOCK)
872                      #-windows-target
873                      (or (eql res (- #$ENETDOWN))
874                          (eql res (- #+linux-target #$EPROTO
875                                      #-linux-target  #$EPROTOTYPE))
876                          (eql res (- #$ENOPROTOOPT))
877                          (eql res (- #$EHOSTDOWN))
878                          (eql res (- #+linux-target #$ENONET
879                                      #-linux-target #$ENETDOWN))
880                          (eql res (- #$EHOSTUNREACH))
881                          (eql res (- #$EOPNOTSUPP))
882                          (eql res (- #$ENETUNREACH))))
883               (- #$EAGAIN)
884               res))))
885    (cond (wait
886            (with-eagain fd :input
887              (_accept fd *multiprocessing-socket-io*)))
888          (*multiprocessing-socket-io*
889            (_accept fd t))
890          (t
891            (let ((was-blocking (get-socket-fd-blocking fd)))
892              (unwind-protect
893                  (progn
894                    (set-socket-fd-blocking fd nil)
895                    (_accept fd t))
896                (set-socket-fd-blocking fd was-blocking)))))))
897
898(defun accept-socket-connection (socket wait stream-create-function)
899  (let ((listen-fd (socket-device socket))
900        (fd -1))
901    (unwind-protect
902      (progn
903        (setq fd (socket-accept listen-fd wait))
904        (cond ((>= fd 0)
905               (prog1 (apply stream-create-function fd (socket-keys socket))
906                 (setq fd -1)))
907              ((eql fd (- #$EAGAIN)) nil)
908              (t (socket-error socket "accept" fd))))
909      (when (>= fd 0)
910        (fd-close fd)))))
911
912(defgeneric accept-connection (socket &key wait)
913  (:documentation
914  "Extract the first connection on the queue of pending connections,
915accept it (i.e. complete the connection startup protocol) and return a new
916tcp-stream or file-socket-stream representing the newly established
917connection.  The tcp stream inherits any properties of the listener socket
918that are relevant (e.g. :keepalive, :nodelay, etc.) The original listener
919socket continues to be open listening for more connections, so you can call
920accept-connection on it again."))
921
922(defmethod accept-connection ((socket listener-socket) &key (wait t))
923  (accept-socket-connection socket wait #'make-tcp-stream))
924
925(defmethod accept-connection ((socket file-listener-socket) &key (wait t))
926  (accept-socket-connection socket wait #'make-file-socket-stream))
927
928(defun verify-socket-buffer (buf offset size)
929  (unless offset (setq offset 0))
930  (unless (<= (+ offset size) (length buf))
931    (report-bad-arg size `(integer 0 ,(- (length buf) offset))))
932  (multiple-value-bind (arr start) (array-data-and-offset buf)
933    (setq buf arr offset (+ offset start)))
934  ;; TODO: maybe should allow any raw vector
935  (let ((subtype (typecode buf)))
936    (unless #+ppc32-target (and (<= ppc32::min-8-bit-ivector-subtag subtype)
937                                (<= subtype ppc32::max-8-bit-ivector-subtag))
938            #+ppc64-target (= (the fixnum (logand subtype ppc64::fulltagmask))
939                              ppc64::ivector-class-8-bit)
940            #+x8632-target (and (<= x8632::min-8-bit-ivector-subtag subtype)
941                                (<= subtype x8632::max-8-bit-ivector-subtag))
942            #+x8664-target (and (>= subtype x8664::min-8-bit-ivector-subtag)
943                                (<= subtype x8664::max-8-bit-ivector-subtag))
944      (report-bad-arg buf `(or (array character)
945                               (array (unsigned-byte 8))
946                               (array (signed-byte 8))))))
947  (values buf offset))
948
949(defmethod send-to ((socket udp-socket) msg size
950                    &key remote-host remote-port offset)
951  "Send a UDP packet over a socket."
952  (let ((fd (socket-device socket)))
953    (multiple-value-setq (msg offset) (verify-socket-buffer msg offset size))
954    (unless remote-host
955      (setq remote-host (or (getf (socket-keys socket) :remote-host)
956                            (remote-socket-info socket :host))))
957    (unless remote-port
958      (setq remote-port (or (getf (socket-keys socket) :remote-port)
959                            (remote-socket-info socket :port))))
960    (rlet ((sockaddr :sockaddr_in))
961      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
962      (setf (pref sockaddr
963                  #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
964                  #+(or solaris-target windows-target)  #>sockaddr_in.sin_addr.S_un.S_addr)
965            (if remote-host (host-as-inet-host remote-host) #$INADDR_ANY))
966      (setf (pref sockaddr :sockaddr_in.sin_port)
967            (if remote-port (port-as-inet-port remote-port "udp") 0))
968      (%stack-block ((bufptr size))
969        (%copy-ivector-to-ptr msg offset bufptr 0 size)
970        (socket-call socket "sendto"
971          (with-eagain fd :output
972            (c_sendto fd bufptr size 0 sockaddr (record-length :sockaddr_in))))))))
973
974(defmethod receive-from ((socket udp-socket) size &key buffer extract offset)
975  "Read a UDP packet from a socket. If no packets are available, wait for
976a packet to arrive. Returns four values:
977  The buffer with the data
978  The number of bytes read
979  The 32-bit unsigned IP address of the sender of the data
980  The port number of the sender of the data."
981  (let ((fd (socket-device socket))
982        (vec-offset offset)
983        (vec buffer)
984        (ret-size -1))
985    (when vec
986      (multiple-value-setq (vec vec-offset)
987        (verify-socket-buffer vec vec-offset size)))
988    (rlet ((sockaddr :sockaddr_in)
989           (namelen :signed))
990      (setf (pref sockaddr :sockaddr_in.sin_family) #$AF_INET)
991      (setf (pref sockaddr
992                  #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
993                  #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr)
994            #$INADDR_ANY)
995      (setf (pref sockaddr :sockaddr_in.sin_port) 0)
996      (setf (pref namelen :signed) (record-length :sockaddr_in))
997      (%stack-block ((bufptr size))
998        (setq ret-size (socket-call socket "recvfrom"
999                         (with-eagain fd :input
1000                           (c_recvfrom fd bufptr size 0 sockaddr namelen))))
1001        (unless vec
1002          (setq vec (make-array ret-size
1003                                :element-type
1004                                (ecase (socket-format socket)
1005                                  ((:text) 'base-char)
1006                                  ((:binary :bivalent) '(unsigned-byte 8))))
1007                vec-offset 0))
1008        (%copy-ptr-to-ivector bufptr 0 vec vec-offset ret-size))
1009      (values (cond ((null buffer)
1010                     vec)
1011                    ((or (not extract)
1012                         (and (eql 0 (or offset 0))
1013                              (eql ret-size (length buffer))))
1014                     buffer)
1015                    (t 
1016                     (subseq vec vec-offset (+ vec-offset ret-size))))
1017              ret-size
1018              (ntohl (pref sockaddr
1019                           #-(or solaris-target windows-target) :sockaddr_in.sin_addr.s_addr
1020                           #+(or solaris-target windows-target) #>sockaddr_in.sin_addr.S_un.S_addr))
1021              (ntohs (pref sockaddr :sockaddr_in.sin_port))))))
1022
1023(defgeneric shutdown (socket &key direction)
1024  (:documentation
1025   "Shut down part of a bidirectional connection. This is useful if e.g.
1026you need to read responses after sending an end-of-file signal."))
1027
1028(defmethod shutdown (socket &key direction)
1029  ;; TODO: should we ignore ENOTCONN error?  (at least make sure it
1030  ;; is a distinct, catchable error type).
1031  (let ((fd (socket-device socket)))
1032    (socket-call socket "shutdown"
1033      (c_shutdown fd (ecase direction
1034                       (:input 0)
1035                       (:output 1))))))
1036
1037;; Accepts port as specified by user, returns port number in network byte
1038;; order.  Protocol should be one of "tcp" or "udp".  Error if not known.
1039(defun port-as-inet-port (port proto)
1040  (or (etypecase port
1041        (fixnum (htons port))
1042        (string (_getservbyname port proto))
1043        (symbol (_getservbyname (string-downcase (symbol-name port)) proto)))
1044      (socket-error nil "getservbyname" (- #$ENOENT))))
1045
1046(defun lookup-port (port proto)
1047  "Find the port number for the specified port and protocol."
1048  (if (fixnump port)
1049    port
1050    (ntohs (port-as-inet-port port proto))))
1051
1052;; Accepts host as specified by user, returns host number in network byte
1053;; order.
1054(defun host-as-inet-host (host)
1055  (etypecase host
1056    (integer (htonl host))
1057    (string (or (and (every #'(lambda (c) (position c ".0123456789")) host)
1058                     (_inet_aton host))
1059                (multiple-value-bind (addr err) (c_gethostbyname host)
1060                  (or addr
1061                      (socket-error nil "gethostbyname" err t)))))))
1062
1063
1064(defun dotted-to-ipaddr (name &key (errorp t))
1065  "Convert a dotted-string representation of a host address to a 32-bit
1066unsigned IP address."
1067  (let ((addr (_inet_aton name)))
1068    (if addr (ntohl addr)
1069      (and errorp (error "Invalid dotted address ~s" name)))))
1070   
1071(defun lookup-hostname (host)
1072  "Convert a host spec in any of the acceptable formats into a 32-bit
1073unsigned IP address."
1074  (if (typep host 'integer)
1075    host
1076    (ntohl (host-as-inet-host host))))
1077
1078(defun ipaddr-to-dotted (addr &key values)
1079  "Convert a 32-bit unsigned IP address into octets."
1080  (let* ((a (ldb (byte 8 24) addr))
1081         (b (ldb (byte 8 16) addr))
1082         (c (ldb (byte 8  8) addr))
1083         (d (ldb (byte 8  0) addr)))
1084    (if values
1085      (values a b c d)
1086      (format nil "~d.~d.~d.~d" a b c d))))
1087
1088(defun ipaddr-to-hostname (ipaddr &key ignore-cache)
1089  "Convert a 32-bit unsigned IP address into a host name string."
1090  (declare (ignore ignore-cache))
1091  (multiple-value-bind (name err) (c_gethostbyaddr (htonl ipaddr))
1092    (or name (socket-error nil "gethostbyaddr" err t))))
1093 
1094
1095(defun int-getsockopt (socket level optname)
1096  (rlet ((valptr :signed)
1097         (vallen :signed))
1098    (setf (pref vallen :signed) 4)
1099    (let* ((err (c_getsockopt socket level optname valptr vallen)))
1100      (if (and (eql 0 err)
1101               (eql 4 (pref vallen :signed)))
1102        (pref valptr :signed)
1103        (socket-error socket "getsockopt" err)))))
1104
1105(defun timeval-setsockopt (socket level optname timeout)
1106    (multiple-value-bind (seconds micros)
1107        (microseconds timeout)
1108      (rlet ((valptr :timeval :tv_sec seconds :tv_usec micros))
1109        (socket-call socket "setsockopt"
1110          (c_setsockopt socket level optname valptr (record-length :timeval))))))
1111                   
1112(defun int-setsockopt (socket level optname optval)
1113  (rlet ((valptr :signed))
1114    (setf (pref valptr :signed) optval)
1115    (socket-call socket "setsockopt"
1116      (c_setsockopt socket level optname valptr (record-length :signed)))))
1117
1118
1119
1120           
1121(defun c_gethostbyaddr (addr-in-net-byte-order)
1122  (rletZ ((sin #>sockaddr_in))
1123    (setf (pref sin :sockaddr_in.sin_family) #$AF_INET
1124          (pref sin
1125                #+(or windows-target solaris-target) #>sockaddr_in.sin_addr.S_un.S_addr
1126                #-(or windows-target solaris-target) #>sockaddr_in.sin_addr.s_addr) addr-in-net-byte-order)
1127    #+darwin-target (setf (pref sin :sockaddr_in.sin_len) (record-length :sockaddr_in))
1128    (%stack-block ((namep #$NI_MAXHOST))
1129      (let* ((err (#_getnameinfo sin (record-length #>sockaddr_in) namep #$NI_MAXHOST (%null-ptr) 0 #$NI_NAMEREQD)))
1130        (if (eql 0 err)
1131          (%get-cstring namep)
1132          (values nil err))))))
1133               
1134(defun c_gethostbyname (name)
1135  (with-cstrs ((name (string name)))
1136    (rletZ ((hints #>addrinfo)
1137            (results :address))
1138      (setf (pref hints #>addrinfo.ai_family) #$AF_INET)
1139      (let* ((err (#_getaddrinfo name (%null-ptr) hints results)))
1140        (if (eql 0 err)
1141          (let* ((info (pref results :address))
1142                 (sin (pref info #>addrinfo.ai_addr)))
1143            (prog1
1144                #+(or windows-target solaris-target)
1145                (pref sin #>sockaddr_in.sin_addr.S_un.S_addr)
1146                #-(or windows-target solaris-target)
1147                (pref sin #>sockaddr_in.sin_addr.s_addr)
1148                (#_freeaddrinfo info)))
1149          (values nil err))))))
1150     
1151 
1152
1153 
1154
1155(defun _getservbyname (name proto)
1156  (with-cstrs ((name (string name))
1157               (proto (string proto)))
1158    (let* ((servent-ptr (%null-ptr)))
1159      (declare (dynamic-extent servent-ptr))
1160      (%setf-macptr servent-ptr (#_getservbyname name proto))
1161      (unless (%null-ptr-p servent-ptr)
1162        (pref servent-ptr :servent.s_port)))))
1163
1164(defun _inet_aton (string)
1165  (with-cstrs ((name string))
1166    #-windows-target
1167    (rlet ((addr :in_addr))
1168      (let* ((result #+freebsd-target (#___inet_aton name addr)
1169                     #-freebsd-target (#_inet_aton name addr)))
1170        (unless (eql result 0)
1171          (pref addr
1172                #-solaris-target :in_addr.s_addr
1173                #+solaris-target #>in_addr.S_un.S_addr
1174                ))))
1175    #+windows-target
1176    (rlet ((addr :sockaddr_in)
1177           (addrlenp :int (record-length :sockaddr_in)))
1178      (setf (pref addr :sockaddr_in.sin_family) #$AF_INET)
1179      (when (zerop (#_WSAStringToAddressA name #$AF_INET (%null-ptr)  addr addrlenp))
1180        (pref addr #>sockaddr_in.sin_addr.S_un.S_addr)))))
1181
1182(defun c_socket_1 (domain type protocol)
1183  #-windows-target (int-errno-call (#_socket domain type protocol))
1184  #+windows-target (let* ((handle (#_socket domain type protocol)))
1185                     (if (< handle 0)
1186                       (%get-winsock-error)
1187                       handle)))
1188
1189
1190
1191(defun c_socket (domain type protocol)
1192  (let* ((fd (c_socket_1 domain type protocol)))
1193    (when (or (eql fd (- #$EMFILE))
1194              (eql fd (- #$ENFILE)))
1195      (gc)
1196      (drain-termination-queue)
1197      (setq fd (c_socket_1 domain type protocol)))
1198    fd))
1199     
1200
1201#-windows-target
1202(defun init-unix-sockaddr (addr path)
1203  (macrolet ((sockaddr_un-path-len ()
1204               (/ (ensure-foreign-type-bits
1205                   (foreign-record-field-type 
1206                    (%find-foreign-record-type-field
1207                     (parse-foreign-type '(:struct :sockaddr_un)) :sun_path)))
1208                  8)))
1209    (let* ((name (native-translated-namestring path))
1210           (namelen (length name))
1211           (pathlen (sockaddr_un-path-len))
1212           (copylen (min (1- pathlen) namelen)))
1213      (setf (pref addr :sockaddr_un.sun_family) #$AF_UNIX)
1214      (let* ((sun-path (pref addr :sockaddr_un.sun_path)))
1215        (dotimes (i copylen)
1216          (setf (%get-unsigned-byte sun-path i)
1217                (let* ((code (char-code (schar name i))))
1218                  (if (> code 255)
1219                    (char-code #\Sub)
1220                    code))))))))
1221
1222#-windows-target
1223(defun bind-unix-socket (socketfd path)
1224  (rletz ((addr :sockaddr_un))
1225    (init-unix-sockaddr addr path)
1226    (socket-call
1227     nil
1228     "bind"
1229     (c_bind socketfd
1230             addr
1231             (+ 2
1232                (#_strlen
1233                 (pref addr :sockaddr_un.sun_path)))))))
1234     
1235
1236(defun c_bind (sockfd sockaddr addrlen)
1237  (check-socket-error (#_bind sockfd sockaddr addrlen)))
1238
1239
1240#+windows-target
1241(defun windows-connect-wait (sockfd timeout-in-milliseconds)
1242  (if (and timeout-in-milliseconds
1243           (< timeout-in-milliseconds 0))
1244    (setq timeout-in-milliseconds nil))
1245  (rlet ((writefds :fd_set)
1246         (exceptfds :fd_set)
1247         (tv :timeval :tv_sec 0 :tv_usec 0))
1248    (fd-zero writefds)
1249    (fd-zero exceptfds)
1250    (fd-set sockfd writefds)
1251    (fd-set sockfd exceptfds)
1252    (when timeout-in-milliseconds
1253      (multiple-value-bind (seconds milliseconds)
1254          (floor timeout-in-milliseconds 1000)
1255        (setf (pref tv :timeval.tv_sec) seconds
1256              (pref tv :timeval.tv_usec) (* 1000 milliseconds))))
1257    (> (#_select 1 (%null-ptr) writefds exceptfds (if timeout-in-milliseconds tv (%null-ptr))) 0)))
1258     
1259     
1260;;; If attempts to connnect are interrupted, we basically have to
1261;;; wait in #_select (or the equivalent).  There's a good rant
1262;;; about these issues in:
1263;;; <http://www.madore.org/~david/computers/connect-intr.html>
1264(defun c_connect (sockfd addr len &optional timeout-in-milliseconds)
1265  (let* ((was-blocking (get-socket-fd-blocking sockfd)))
1266    (unwind-protect
1267         (progn
1268           (set-socket-fd-blocking sockfd nil)
1269           (let* ((err (check-socket-error (#_connect sockfd addr len))))
1270             (cond ((or (eql err (- #+windows-target #$WSAEINPROGRESS
1271                                   
1272                                    #-windows-target #$EINPROGRESS))
1273                        #+windows-target (eql err (- #$WSAEWOULDBLOCK))
1274                        (eql err (- #$EINTR)))
1275                    (if
1276                      #+windows-target (windows-connect-wait sockfd timeout-in-milliseconds)
1277                      #-windows-target (process-output-wait sockfd timeout-in-milliseconds)
1278                      (- (int-getsockopt sockfd #$SOL_SOCKET #$SO_ERROR))
1279                      (- #+windows-target #$WSAETIMEDOUT #-windows-target #$ETIMEDOUT)))
1280                   (t err))))
1281      (set-socket-fd-blocking sockfd was-blocking))))
1282
1283(defun c_listen (sockfd backlog)
1284  (check-socket-error (#_listen sockfd backlog)))
1285
1286(defun c_accept (sockfd addrp addrlenp)
1287  (ignoring-eintr
1288   (check-socket-error (#_accept sockfd addrp addrlenp))))
1289
1290(defun c_getsockname (sockfd addrp addrlenp)
1291  (check-socket-error (#_getsockname sockfd addrp addrlenp)))
1292
1293(defun c_getpeername (sockfd addrp addrlenp)
1294  (check-socket-error (#_getpeername sockfd addrp addrlenp)))
1295
1296#-windows-target
1297(defun c_socketpair (domain type protocol socketsptr)
1298  (check-socket-error (#_socketpair domain type protocol socketsptr)))
1299
1300
1301(defun c_sendto (sockfd msgptr len flags addrp addrlen)
1302  (ignoring-eintr (check-socket-error (#_sendto sockfd msgptr len flags addrp addrlen))))
1303
1304(defun c_recvfrom (sockfd bufptr len flags addrp addrlenp)
1305  (ignoring-eintr (check-socket-error (#_recvfrom sockfd bufptr len flags addrp addrlenp))))
1306
1307(defun c_shutdown (sockfd how)
1308  (check-socket-error (#_shutdown sockfd how)))
1309
1310(defun c_setsockopt (sockfd level optname optvalp optlen)
1311  (check-socket-error (#_setsockopt sockfd level optname optvalp optlen)))
1312
1313(defun c_getsockopt (sockfd level optname optvalp optlenp)
1314  (check-socket-error (#_getsockopt sockfd level optname optvalp optlenp)))
1315
1316#-windows-target
1317(defun c_sendmsg (sockfd msghdrp flags)
1318  (check-socket-error (#_sendmsg sockfd msghdrp flags)))
1319
1320#-windows-target
1321(defun c_recvmsg (sockfd msghdrp flags)
1322  (check-socket-error   (#_recvmsg sockfd msghdrp flags)))
1323
1324;;; Return a list of currently configured interfaces, a la ifconfig.
1325(defstruct ip-interface
1326  name
1327  addr
1328  netmask
1329  flags
1330  address-family)
1331
1332(defun dump-buffer (p n)
1333  (dotimes (i n (progn (terpri) (terpri)))
1334    (unless (logtest i 15)
1335      (format t "~&~8,'0x: " (%ptr-to-int (%inc-ptr p i))))
1336    (format t " ~2,'0x" (%get-byte p i))))
1337
1338#-(or windows-target solaris-target)
1339(defun %get-ip-interfaces ()
1340  (rlet ((p :address (%null-ptr)))
1341    (if (zerop (#_getifaddrs p))
1342      (unwind-protect
1343           (do* ((q (%get-ptr p) (pref q :ifaddrs.ifa_next))
1344                 (res ()))
1345                ((%null-ptr-p q) (nreverse res))
1346             (let* ((addr (pref q :ifaddrs.ifa_addr)))
1347               (when (and (not (%null-ptr-p addr))
1348                          (eql (pref addr :sockaddr.sa_family) #$AF_INET))
1349                 (push (make-ip-interface
1350                        :name (%get-cstring (pref q :ifaddrs.ifa_name))
1351                        :addr (ntohl (pref addr :sockaddr_in.sin_addr.s_addr))
1352                        :netmask (ntohl
1353                                  (pref (pref q :ifaddrs.ifa_netmask)
1354                                       :sockaddr_in.sin_addr.s_addr))
1355                        :flags (pref q :ifaddrs.ifa_flags)
1356                        :address-family #$AF_INET)
1357                       res))))
1358        (#_freeifaddrs (pref p :address))))))
1359
1360#+solaris-target
1361(progn
1362  ;;; Interface translator has trouble with a lot of ioctl constants.
1363  (eval-when (:compile-toplevel :execute)
1364    (defconstant os::|SIOCGLIFNUM| #xc00c6982)
1365    (defconstant os::|SIOCGLIFCONF| #xc01069a5)
1366    (defconstant os::|SIOCGLIFADDR| #xc0786971)
1367    (defconstant os::|SIOCGLIFFLAGS| #xc0786975)
1368    (defconstant os::|SIOCGLIFNETMASK| #xc078697d)
1369    )
1370
1371(defun %get-ip-interfaces ()
1372  (let* ((sock (c_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_UDP))
1373         (res nil))
1374    (when (>= sock 0)
1375      (unwind-protect
1376           (let* ((flags (logior #$LIFC_NOXMIT #$LIFC_TEMPORARY #$LIFC_ALLZONES))
1377                  (ninterfaces (rlet ((lifnum :lifnum
1378                                        :lifn_flags flags
1379                                        :lifn_family #$AF_INET
1380                                        :lifn_count 0))
1381                                 (#_ioctl sock os::SIOCGLIFNUM :address lifnum)
1382                                 (pref lifnum :lifnum.lifn_count))))
1383             (declare (fixnum ninterfaces))
1384             (when (> ninterfaces 0)
1385               (let* ((bufsize (* ninterfaces (record-length :lifreq))))
1386                 (%stack-block ((buf bufsize :clear t))
1387                   (rlet ((lifc :lifconf
1388                            :lifc_family #$AF_INET
1389                            :lifc_flags flags
1390                            :lifc_len bufsize
1391                            :lifc_lifcu.lifcu_buf buf))
1392                     (when (>= (#_ioctl sock os::SIOCGLIFCONF :address lifc) 0)
1393                       (do* ((i 0 (1+ i))
1394                             (p (pref lifc :lifconf.lifc_lifcu.lifcu_buf)
1395                                (%inc-ptr p (record-length :lifreq))))
1396                            ((= i ninterfaces))
1397                         (let* ((name (%get-cstring (pref p :lifreq.lifr_name)))
1398                                (address-family (pref p :lifreq.lifr_lifru.lifru_addr.ss_family))
1399                                (if-flags nil)
1400                                (address nil)
1401                                (netmask nil))
1402                           (if (>= (#_ioctl sock os::SIOCGLIFFLAGS :address p)
1403                                   0)
1404                             (setq if-flags (pref p :lifreq.lifr_lifru.lifru_flags)))
1405                           (if (>= (#_ioctl sock os::SIOCGLIFADDR :address p)
1406                                   0)
1407                             (setq address (pref
1408                                            (pref p :lifreq.lifr_lifru.lifru_addr)
1409                                            #>sockaddr_in.sin_addr.S_un.S_addr)))
1410                           (if (>= (#_ioctl sock os::SIOCGLIFNETMASK :address p)
1411                                   0)
1412                             (setq netmask (pref
1413                                            (pref p :lifreq.lifr_lifru.lifru_subnet)
1414                                            #>sockaddr_in.sin_addr.S_un.S_addr)))
1415                             
1416                           (push (make-ip-interface
1417                                  :name name
1418                                  :addr (ntohl address)
1419                                  :netmask (ntohl netmask)
1420                                  :flags if-flags
1421                                  :address-family address-family)
1422                                 res)))))))))
1423        (fd-close sock)))
1424    res))
1425)
1426
1427
1428
1429
1430#+windows-target
1431(defun %get-ip-interfaces ()
1432  (let* ((handle (#_socket #$AF_INET #$SOCK_DGRAM #$IPPROTO_IP)))
1433    (unwind-protect
1434    (rlet ((realoutlen #>DWORD 0))
1435      (do* ((reservedlen (* 4 (record-length #>INTERFACE_INFO))
1436                         (* 2 reservedlen)))
1437           ()
1438        (%stack-block ((buf reservedlen))
1439          (unless (eql 0 (#_WSAIoctl
1440                          handle
1441                          #$SIO_GET_INTERFACE_LIST
1442                          (%null-ptr)
1443                          0
1444                          buf
1445                          reservedlen
1446                          realoutlen
1447                          (%null-ptr)
1448                          (%null-ptr)))
1449            (return))
1450          (let* ((noutbytes (pref realoutlen #>DWORD)))
1451            (when (< noutbytes reservedlen)
1452              (let* ((interfaces nil))
1453                (do* ((offset 0 (+ offset (record-length #>INTERFACE_INFO)))
1454                      (nameidx 0 (1+ nameidx)))
1455                     ((>= offset noutbytes))
1456                  (with-macptrs ((p (%inc-ptr buf offset)))
1457                    (push (make-ip-interface 
1458                           :name (format nil "ip~d" nameidx)
1459                           :addr (ntohl
1460                                  (pref (pref p #>INTERFACE_INFO.iiAddress)
1461                                        #>sockaddr_gen.AddressIn.sin_addr.S_un.S_addr))
1462                           :netmask (ntohl
1463                                     (pref (pref p #>INTERFACE_INFO.iiNetmask)
1464                                        #>sockaddr_gen.AddressIn.sin_addr.S_un.S_addr))
1465                           :flags (pref p #>INTERFACE_INFO.iiFlags)
1466                           :address-family #$AF_INET)
1467                          interfaces)))
1468                (return interfaces)))))))
1469      (#_CloseHandle (%int-to-ptr handle)))))
1470
1471     
1472
1473
1474(defloadvar *ip-interfaces* ())
1475
1476(defun ip-interfaces ()
1477  (or *ip-interfaces*
1478      (setq *ip-interfaces* (%get-ip-interfaces))))
1479
1480;;; This should presumably happen after a configuration change.
1481;;; How do we detect a configuration change ?
1482(defun %reset-ip-interfaces ()
1483  (setq *ip-interfaces* ()))
1484
1485;;; Return the first non-loopback interface that's up and whose address
1486;;; family is #$AF_INET.  If no such interface exists, return
1487;;; the loopback interface.
1488(defun primary-ip-interface ()
1489  (let* ((ifaces (ip-interfaces)))
1490    (or (find-if #'(lambda (i)
1491                     (and (eq #$AF_INET (ip-interface-address-family i))
1492                          (ip-interface-addr i)
1493                          (let* ((flags (ip-interface-flags i)))
1494                            (and (not (logtest #$IFF_LOOPBACK flags))
1495                                 (logtest #$IFF_UP flags)))))
1496                 ifaces)
1497        (car ifaces))))
1498
1499(defun primary-ip-interface-address ()
1500  (let* ((iface (primary-ip-interface)))
1501    (if iface
1502      (ip-interface-addr iface)
1503      (error "Can't determine primary IP interface"))))
1504         
1505         
1506(defmethod stream-io-error ((stream socket) errno where)
1507  (socket-error stream where errno))
Note: See TracBrowser for help on using the repository browser.