source: trunk/source/level-1/l1-readloop-lds.lisp @ 8791

Last change on this file since 8791 was 8791, checked in by gz, 12 years ago

Propagate changeset:8682 to trunk

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 26.2 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17; l1-readloop-lds.lisp
18
19(in-package "CCL")
20
21
22
23(defun toplevel-loop ()
24  (loop
25    (if (eq (catch :toplevel 
26              (read-loop :break-level 0 )) $xstkover)
27      (format t "~&;[Stacks reset due to overflow.]")
28      (when (eq *current-process* *initial-process*)
29        (toplevel)))))
30
31
32(defvar *defined-toplevel-commands* ())
33(defvar *active-toplevel-commands* ())
34
35(defun %define-toplevel-command (group-name key name fn doc args)
36  (let* ((group (or (assoc group-name *defined-toplevel-commands*)
37                    (car (push (list group-name)
38                               *defined-toplevel-commands*))))
39         (pair (assoc key (cdr group) :test #'eq)))
40    (if pair
41      (rplacd pair (list* fn doc args))
42      (push (cons key (list* fn doc args)) (cdr group))))
43  name)
44
45(define-toplevel-command 
46    :global y (&optional p) "Yield control of terminal-input to process
47whose name or ID matches <p>, or to any process if <p> is null"
48    (%%yield-terminal-to (if p (find-process p))))      ;may be nil
49
50
51(define-toplevel-command
52    :global kill (p) "Kill process whose name or ID matches <p>"
53    (let* ((proc (find-process p)))
54      (if proc
55        (process-kill proc))))
56
57(define-toplevel-command 
58    :global proc (&optional p) "Show information about specified process <p>/all processes"
59    (flet ((show-process-info (proc)
60             (format t "~&~d : ~a ~a ~20t[~a] "
61                     (process-serial-number proc)
62                     (if (eq proc *current-process*)
63                       "->"
64                       "  ")
65                     (process-name proc)
66                     (process-whostate proc))
67             (let* ((suspend-count (process-suspend-count proc)))
68               (if (and suspend-count (not (eql 0 suspend-count)))
69                 (format t " (Suspended)")))
70             (let* ((terminal-input-shared-resource
71                     (if (typep *terminal-io* 'two-way-stream)
72                       (input-stream-shared-resource
73                        (two-way-stream-input-stream *terminal-io*)))))
74               (if (and terminal-input-shared-resource
75                        (%shared-resource-requestor-p
76                         terminal-input-shared-resource proc))
77                 (format t " (Requesting terminal input)")))
78             (fresh-line)))
79      (if p
80        (let* ((proc (find-process p)))
81          (if (null proc)
82            (format t "~&;; not found - ~s" p)
83            (show-process-info proc)))
84        (dolist (proc (all-processes) (values))
85          (show-process-info proc)))))
86
87(define-toplevel-command :global cd (dir) "Change to directory DIR" (setf (current-directory) dir) (toplevel-print (list (current-directory))))
88
89(define-toplevel-command :global pwd () "Print the pathame of the current directory" (toplevel-print (list (current-directory))))
90
91
92
93(define-toplevel-command :break pop () "exit current break loop" (abort-break))
94(define-toplevel-command :break a () "exit current break loop" (abort-break))
95(define-toplevel-command :break go () "continue" (continue))
96(define-toplevel-command :break q () "return to toplevel" (toplevel))
97(define-toplevel-command :break r () "list restarts"
98  (format t "~&   (:C <n>) can be used to invoke one of the following restarts in this break loop:")
99  (let* ((r (apply #'vector (compute-restarts *break-condition*))))
100    (dotimes (i (length r) (terpri))
101      (format *debug-io* "~&~d. ~a" i (svref r i)))))
102
103;;; From Marco Baringer 2003/03/18
104
105(define-toplevel-command :break set (n frame value) "Set <n>th item of frame <frame> to <value>"
106  (let* ((frame-sp (nth-raw-frame frame *break-frame* nil)))
107    (if frame-sp
108        (toplevel-print (list (set-nth-value-in-frame frame-sp n nil value)))
109        (format *debug-io* "No frame with number ~D~%" frame))))
110
111(define-toplevel-command :break nframes ()
112                         "print the number of stack frames accessible from this break loop"
113                         (do* ((p *break-frame* (parent-frame p nil))
114                               (i 0 (1+ i))
115                               (last (last-frame-ptr)))
116                              ((eql p last) (toplevel-print (list i)))))
117
118(define-toplevel-command :global ? () "help"
119  (dolist (g *active-toplevel-commands*)
120    (dolist (c (cdr g))
121      (let* ((command (car c))
122             (doc (caddr c))
123             (args (cdddr c)))
124        (if args
125          (format t "~& (~S~{ ~A~}) ~8T~A" command args doc)
126          (format t "~& ~S  ~8T~A" command doc))))))
127
128
129(define-toplevel-command :break b (&key start count show-frame-contents) "backtrace"
130  (when *break-frame*
131      (print-call-history :detailed-p show-frame-contents
132                          :origin *break-frame*
133                          :count count
134                          :start-frame-number (or start 0))))
135
136(define-toplevel-command :break c (&optional n) "Choose restart <n>. If no <n>, continue"
137  (if n
138   (select-restart n)
139   (continue)))
140
141(define-toplevel-command :break f (n) "Show backtrace frame <n>"
142   (print-call-history :origin *break-frame*
143                       :start-frame-number n
144                       :count 1
145                       :detailed-p t))
146
147(define-toplevel-command :break return-from-frame (i &rest values) "Return VALUES from the I'th stack frame"
148  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
149    (if frame-sp
150      (apply #'return-from-frame frame-sp values))))
151
152(define-toplevel-command :break apply-in-frame (i function &rest args) "Applies FUNCTION to ARGS in the execution context of the Ith stack frame"
153  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
154    (if frame-sp
155      (apply-in-frame frame-sp function args))))
156                         
157                         
158
159(define-toplevel-command :break raw (n) "Show raw contents of backtrace frame <n>"
160   (print-call-history :origin *break-frame*
161                       :start-frame-number n
162                       :count 1
163                       :detailed-p :raw))
164
165(define-toplevel-command :break v (n frame-number) "Return value <n> in frame <frame-number>"
166  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
167    (if frame-sp
168      (toplevel-print (list (nth-value-in-frame frame-sp n nil))))))
169
170(define-toplevel-command :break arg (name frame-number) "Return value of argument named <name> in frame <frame-number>"
171  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
172    (when frame-sp
173      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
174        (when (and lfun pc)
175          (let* ((unavailable (cons nil nil)))
176            (declare (dynamic-extent unavailable))
177            (let* ((value (arg-value nil frame-sp lfun pc unavailable name)))
178              (if (eq value unavailable)
179                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
180                (toplevel-print (list value))))))))))
181
182(define-toplevel-command :break set-arg (name frame-number new) "Set value of argument named <name> in frame <frame-number> to value <new>."
183  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
184    (when frame-sp
185      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
186        (when (and lfun pc)
187          (or (set-arg-value nil frame-sp lfun pc name new)
188              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
189   
190
191(define-toplevel-command :break local (name frame-number) "Return value of local denoted by <name> in frame <frame-number> <name> can either be a symbol - in which case the most recent
192binding of that symbol is used - or an integer index into the frame's set of local bindings."
193  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
194    (when frame-sp
195      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
196        (when (and lfun pc)
197          (let* ((unavailable (cons nil nil)))
198            (declare (dynamic-extent unavailable))
199            (let* ((value (local-value nil frame-sp lfun pc unavailable name)))
200              (if (eq value unavailable)
201                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
202                (toplevel-print (list value))))))))))
203
204(define-toplevel-command :break set-local (name frame-number new) "Set value of argument denoted <name> (see :LOCAL) in frame <frame-number> to value <new>."
205  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
206    (when frame-sp
207      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
208        (when (and lfun pc)
209          (or (set-local-value nil frame-sp lfun pc name new)
210              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
211
212
213(define-toplevel-command :break form (frame-number)
214   "Return a form which looks like the call which established the stack frame identified by <frame-number>.  This is only well-defined in certain cases: when the function is globally named and not a lexical closure and when it was compiled with *SAVE-LOCAL-SYMBOLS* in effect."
215   (let* ((form (dbg-form frame-number)))
216     (when form
217       (let* ((*print-level* *backtrace-print-level*)
218              (*print-length* *backtrace-print-length*))
219         (toplevel-print (list form))))))
220
221;;; Ordinarily, form follows function.
222(define-toplevel-command :break function (frame-number)
223  "Returns the function invoked in backtrace frame <frame-number>.  This may be useful for, e.g., disassembly"
224  (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
225    (when (and cfp (not (catch-csp-p cfp nil)))
226      (let* ((function (cfp-lfun cfp)))
227        (when function
228          (toplevel-print (list function)))))))
229 
230
231
232         
233
234 
235
236(defun %use-toplevel-commands (group-name)
237  ;; Push the whole group
238  (pushnew (assoc group-name *defined-toplevel-commands*)
239           *active-toplevel-commands*
240           :key #'(lambda (x) (car x))))  ; #'car not defined yet ...
241
242(%use-toplevel-commands :global)
243
244(defun check-toplevel-command (form)
245  (let* ((cmd (if (consp form) (car form) form))
246         (args (if (consp form) (cdr form))))
247    (if (keywordp cmd)
248      (dolist (g *active-toplevel-commands*)
249        (when
250            (let* ((pair (assoc cmd (cdr g))))
251              (if pair 
252                (progn (apply (cadr pair) args)
253                       t)))
254          (return t))))))
255
256(defparameter *quit-on-eof* nil)
257
258(defmethod stream-eof-transient-p (stream)
259  (let ((fd (stream-device stream :input)))
260    (and fd (eof-transient-p fd))))
261
262;;; This is the part common to toplevel loop and inner break loops.
263(defun read-loop (&key (input-stream *standard-input*)
264                       (output-stream *standard-output*)
265                       (break-level *break-level*)
266                       (prompt-function #'(lambda (stream) (print-listener-prompt stream t))))
267  (let* ((*break-level* break-level)
268         (*last-break-level* break-level)
269         *loading-file-source-file*
270         *in-read-loop*
271         *** ** * +++ ++ + /// // / -
272         (eof-value (cons nil nil)))
273    (declare (dynamic-extent eof-value))
274    (loop
275      (restart-case
276       (catch :abort                    ;last resort...
277         (loop
278           (catch-cancel
279            (loop               
280              (setq *in-read-loop* nil
281                    *break-level* break-level)
282              (multiple-value-bind (form env print-result)
283                  (toplevel-read :input-stream input-stream
284                                 :output-stream output-stream
285                                 :prompt-function prompt-function
286                                 :eof-value eof-value)
287                (if (eq form eof-value)
288                  (if (and (not *batch-flag*)
289                           (not *quit-on-eof*)
290                           (stream-eof-transient-p input-stream))
291                    (progn
292                      (stream-clear-input input-stream)
293                      (abort-break))
294                    (exit-interactive-process *current-process*))
295                    (or (check-toplevel-command form)
296                        (let* ((values (toplevel-eval form env)))
297                          (if print-result (toplevel-print values))))))))
298           (format *terminal-io* "~&Cancelled")))
299       (abort () :report (lambda (stream)
300                           (if (eq break-level 0)
301                             (format stream "Return to toplevel.")
302                             (format stream "Return to break level ~D." break-level)))
303              #|                        ; Handled by interactive-abort
304                                        ; go up one more if abort occurred while awaiting/reading input               
305              (when (and *in-read-loop* (neq break-level 0))
306              (abort))
307              |#
308               )
309        (abort-break () 
310                     (unless (eq break-level 0)
311                       (abort))))
312       (clear-input input-stream)
313      (format output-stream "~%"))))
314
315;;; The first non-whitespace character available on INPUT-STREAM is a colon.
316;;; Try to interpret the line as a colon command (or possibly just a keyword.)
317(defun read-command-or-keyword (input-stream eof-value)
318  (let* ((line (read-line input-stream nil eof-value)))
319    (if (eq line eof-value)
320      eof-value
321      (let* ((in (make-string-input-stream line))
322             (keyword (read in nil eof-value)))
323        (if (eq keyword eof-value)
324          eof-value
325          (if (not (keywordp keyword))
326            keyword
327            (collect ((params))
328              (loop
329                (let* ((param (read in nil eof-value)))
330                  (if (eq param eof-value)
331                    (return
332                      (let* ((params (params)))
333                        (if params
334                          (cons keyword params)
335                          keyword)))
336                    (params (eval param))))))))))))
337
338;;; Read a form from the specified stream.
339(defun toplevel-read (&key (input-stream *standard-input*)
340                           (output-stream *standard-output*)
341                           (prompt-function #'print-listener-prompt)
342                           (eof-value *eof-value*))
343  (force-output output-stream)
344  (funcall prompt-function output-stream)
345  (read-toplevel-form input-stream eof-value))
346
347(defvar *always-eval-user-defvars* nil)
348
349(defun process-single-selection (form)
350  (if (and *always-eval-user-defvars*
351           (listp form) (eq (car form) 'defvar) (cddr form))
352    `(defparameter ,@(cdr form))
353    form))
354
355(defun toplevel-eval (form &optional env)
356  (destructuring-bind (vars . vals) (or env '(nil . nil))
357    (progv vars vals
358      (setq +++ ++ ++ + + - - form)
359      (unwind-protect
360          (let* ((package *package*)
361                 (values (multiple-value-list (cheap-eval-in-environment form nil))))
362            (unless (eq package *package*)
363              ;; If changing a local value (e.g. buffer-local), not useful to notify app
364              ;; without more info.  Perhaps should have a *source-context* that can send along?
365              (unless (member '*package* vars)
366                (application-ui-operation *application* :note-current-package *package*)))
367            values)
368        (loop for var in vars as pval on vals
369          do (setf (car pval) (symbol-value var)))))))
370
371
372(defun toplevel-print (values &optional (out *standard-output*))
373  (setq /// // // / / values)
374  (unless (eq (car values) (%unbound-marker))
375    (setq *** ** ** * *  (%car values)))
376  (when values
377    (fresh-line out)
378    (dolist (val values) (write val :stream out) (terpri out))))
379
380(defparameter *listener-prompt-format* "~[?~:;~:*~d >~] ")
381
382 
383(defun print-listener-prompt (stream &optional (force t))
384  (unless *quiet-flag*
385    (when (or force (neq *break-level* *last-break-level*))
386      (let* ((*listener-indent* nil))
387        (fresh-line stream)
388        (format stream *listener-prompt-format* *break-level*))
389      (setq *last-break-level* *break-level*)))
390    (force-output stream))
391
392
393;;; Fairly crude default error-handlingbehavior, and a fairly crude mechanism
394;;; for customizing it.
395
396(defvar *app-error-handler-mode* :quit
397  "one of :quit, :quit-quietly, :listener might be useful.")
398
399(defmethod application-error ((a application) condition error-pointer)
400  (case *app-error-handler-mode*
401    (:listener   (break-loop-handle-error condition error-pointer))
402    (:quit-quietly (quit -1))
403    (:quit  (format t "~&Fatal error in ~s : ~a"
404                    (pathname-name (car *command-line-argument-list*))
405                    condition)
406                    (quit -1))))
407
408(defun make-application-error-handler (app mode)
409  (declare (ignore app))
410  (setq *app-error-handler-mode* mode))
411
412
413; You may want to do this anyway even if your application
414; does not otherwise wish to be a "lisp-development-system"
415(defmethod application-error ((a lisp-development-system) condition error-pointer)
416  (break-loop-handle-error condition error-pointer))
417
418(defun abnormal-application-exit ()
419  (ignore-errors
420    (print-call-history)
421    (force-output *debug-io*)
422    (quit -1))
423  (#__exit -1))
424
425(defun break-loop-handle-error (condition error-pointer)
426  (multiple-value-bind (bogus-globals newvals oldvals) (%check-error-globals)
427    (dolist (x bogus-globals)
428      (set x (funcall (pop newvals))))
429    (when (and *debugger-hook* *break-on-errors* (not *batch-flag*))
430      (let ((hook *debugger-hook*)
431            (*debugger-hook* nil))
432        (funcall hook condition hook)))
433    (%break-message "Error" condition error-pointer)
434    (let* ((s *error-output*))
435      (dolist (bogusness bogus-globals)
436        (let ((oldval (pop oldvals)))
437          (format s "~&;  NOTE: ~S was " bogusness)
438          (if (eq oldval (%unbound-marker-8))
439            (format s "unbound")
440            (format s "~s" oldval))
441          (format s ", was reset to ~s ." (symbol-value bogusness)))))
442    (if (and *break-on-errors* (not *batch-flag*))
443      (with-terminal-input
444          (break-loop condition error-pointer))
445      (if *batch-flag*
446        (abnormal-application-exit)
447        (abort)))))
448
449(defun break (&optional string &rest args)
450  "Print a message and invoke the debugger without allowing any possibility
451   of condition handling occurring."
452  (if *batch-flag*
453    (apply #'error string args)
454    (apply #'%break-in-frame (%get-frame-ptr) string args)))
455
456(defun %break-in-frame (fp &optional string &rest args)
457  (flet ((do-break-loop ()
458           (let ((c (if (typep string 'condition)
459                      string
460                      (make-condition 'simple-condition
461                                    :format-control (or string "")
462                                    :format-arguments args))))
463             (cbreak-loop "Break" "Return from BREAK." c fp))))
464    (cond ((%i> *interrupt-level* -1)
465           (do-break-loop))
466          (*break-loop-when-uninterruptable*
467           (format *error-output* "Break while interrupt-level less than zero; binding to 0 during break-loop.")
468           (let ((interrupt-level (interrupt-level)))
469             (unwind-protect
470                  (progn
471                    (setf (interrupt-level) 0)
472                    (do-break-loop))
473               (setf (interrupt-level) interrupt-level))))
474          (t (format *error-output* "Break while interrupt-level less than zero; ignored.")))))
475
476
477(defun invoke-debugger (condition &aux (fp (%get-frame-ptr)))
478  "Enter the debugger."
479  (let ((c (require-type condition 'condition)))
480    (when *debugger-hook*
481      (let ((hook *debugger-hook*)
482            (*debugger-hook* nil))
483        (funcall hook c hook)))
484    (%break-message "Debug" c fp)
485    (with-terminal-input
486        (break-loop c fp))))
487
488(defun %break-message (msg condition error-pointer &optional (prefixchar #\>))
489  (let ((*print-circle* *error-print-circle*)
490        ;(*print-prett*y nil)
491        (*print-array* nil)
492        (*print-escape* t)
493        (*print-gensym* t)
494        (*print-length* *error-print-length*)
495        (*print-level* *error-print-level*)
496        (*print-lines* nil)
497        (*print-miser-width* nil)
498        (*print-readably* nil)
499        (*print-right-margin* nil)
500        (*signal-printing-errors* nil)
501        (s (make-indenting-string-output-stream prefixchar nil)))
502    (format s "~A ~A: " prefixchar msg)
503    (setf (indenting-string-output-stream-indent s) (column s))
504    ;(format s "~A" condition) ; evil if circle
505    (report-condition condition s)
506    (if (not (and (typep condition 'simple-program-error)
507                  (simple-program-error-context condition)))
508      (format *error-output* "~&~A~%~A While executing: ~S"
509              (get-output-stream-string s) prefixchar (%real-err-fn-name error-pointer))
510      (format *error-output* "~&~A"
511              (get-output-stream-string s)))
512    (format *error-output* ", in process ~a(~d).~%" (process-name *current-process*) (process-serial-number *current-process*))
513  (force-output *error-output*)))
514                                        ; returns NIL
515
516(defun cbreak-loop (msg cont-string condition error-pointer)
517  (let* ((*print-readably* nil))
518    (%break-message msg condition error-pointer)
519    (with-terminal-input
520      (restart-case (break-loop condition error-pointer)
521                    (continue () :report (lambda (stream) (write-string cont-string stream))))
522      (fresh-line *error-output*)
523      nil)))
524
525(defun warn (condition-or-format-string &rest args)
526  "Warn about a situation by signalling a condition formed by DATUM and
527   ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
528   exists that causes WARN to immediately return NIL."
529  (when (typep condition-or-format-string 'condition)
530    (unless (typep condition-or-format-string 'warning)
531      (report-bad-arg condition-or-format-string 'warning))
532    (when args
533      (error 'type-error :datum args :expected-type 'null
534             :format-control "Extra arguments in ~s.")))
535  (let ((fp (%get-frame-ptr))
536        (c (require-type (condition-arg condition-or-format-string args 'simple-warning) 'warning)))
537    (when *break-on-warnings*
538      (cbreak-loop "Warning" "Signal the warning." c fp))
539    (restart-case (signal c)
540      (muffle-warning () :report "Skip the warning" (return-from warn nil)))
541    (%break-message (if (typep c 'compiler-warning) "Compiler warning" "Warning") c fp #\;)
542    ))
543
544(declaim (notinline select-backtrace))
545
546(defmacro new-backtrace-info (dialog youngest oldest tcr condition current fake db-link level)
547  (let* ((cond (gensym)))
548  `(let* ((,cond ,condition))
549    (vector ,dialog ,youngest ,oldest ,tcr (cons nil (compute-restarts ,cond)) (%catch-top ,tcr) ,cond ,current ,fake ,db-link ,level))))
550
551(defun select-backtrace ()
552  (declare (notinline select-backtrace))
553  ;(require 'new-backtrace)
554  (require :inspector)
555  (select-backtrace))
556
557(defvar *break-condition* nil "condition argument to innermost break-loop.")
558(defvar *break-frame* nil "frame-pointer arg to break-loop")
559(defvar *break-loop-when-uninterruptable* t)
560
561(defvar *error-reentry-count* 0)
562
563(defun funcall-with-error-reentry-detection (thunk)
564  (let* ((count *error-reentry-count*)
565         (*error-reentry-count* (1+ count)))
566    (cond ((eql count 0) (funcall thunk))
567          ((eql count 1) (error "Error reporting error"))
568          (t (bug "Error reporting error")))))
569
570
571
572
573(defvar %last-continue% nil)
574(defun break-loop (condition frame-pointer)
575  "Never returns"
576  (let* ((%handlers% (last %handlers%)) ; firewall
577         (*break-frame* frame-pointer)
578         (*break-condition* condition)
579         (*compiling-file* nil)
580         (*backquote-stack* nil)
581         (continue (find-restart 'continue))
582         (*continuablep* (unless (eq %last-continue% continue) continue))
583         (%last-continue% continue)
584         (*standard-input* *debug-io*)
585         (*standard-output* *debug-io*)
586         (*signal-printing-errors* nil)
587         (*read-suppress* nil)
588         (*print-readably* nil))
589    (let* ((context (new-backtrace-info nil
590                                        frame-pointer
591                                        (if *backtrace-contexts*
592                                          (or (child-frame
593                                               (bt.youngest (car *backtrace-contexts*))
594                                               nil)
595                                              (last-frame-ptr))
596                                          (last-frame-ptr))
597                                        (%current-tcr)
598                                        condition
599                                        (%current-frame-ptr)
600                                        #+ppc-target *fake-stack-frames*
601                                        #+x86-target (%current-frame-ptr)
602                                        (db-link)
603                                        (1+ *break-level*)))
604           (*backtrace-contexts* (cons context *backtrace-contexts*)))
605      (with-toplevel-commands :break
606        (if *continuablep*
607          (let* ((*print-circle* *error-print-circle*)
608                 (*print-level* *error-print-level*)
609                 (*print-length* *error-print-length*)
610                                        ;(*print-pretty* nil)
611                 (*print-array* nil))
612            (format t "~&> Type :GO to continue, :POP to abort, :R for a list of available restarts.")
613            (format t "~&> If continued: ~A~%" continue))
614          (format t "~&> Type :POP to abort, :R for a list of available restarts.~%"))
615        (format t "~&> Type :? for other options.")
616        (terpri)
617        (force-output)
618
619        (clear-input *debug-io*)
620        (setq *error-reentry-count* 0)  ; succesfully reported error
621        (ignoring-without-interrupts
622         (unwind-protect
623              (progn
624                (application-ui-operation *application*
625                                          :enter-backtrace-context context)
626                  (read-loop :break-level (1+ *break-level*)
627                             :input-stream *debug-io*
628                             :output-stream *debug-io*))
629           (application-ui-operation *application* :exit-backtrace-context
630                                     context)))))))
631
632
633
634(defun display-restarts (&optional (condition *break-condition*))
635  (let ((i 0))
636    (format t "~&[Pretend that these are buttons.]")
637    (dolist (r (compute-restarts condition) i)
638      (format t "~&~a : ~A" i r)
639      (setq i (%i+ i 1)))
640    (fresh-line nil)))
641
642(defun select-restart (n &optional (condition *break-condition*))
643  (let* ((restarts (compute-restarts condition)))
644    (invoke-restart-interactively
645     (nth (require-type n `(integer 0 (,(length restarts)))) restarts))))
646
647
648
649
650; End of l1-readloop-lds.lisp
Note: See TracBrowser for help on using the repository browser.