source: trunk/source/level-1/l1-readloop-lds.lisp @ 13124

Last change on this file since 13124 was 13124, checked in by gz, 10 years ago

Recording source text in read-loop (useful for disassembly). It's now possible have a source note with null filename, fix a couple places to account for that.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 30.0 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18; l1-readloop-lds.lisp
19
20(in-package "CCL")
21
22
23
24(defun toplevel-loop ()
25  (loop
26    (if (eq (catch :toplevel 
27              (read-loop :break-level 0 )) $xstkover)
28      (format t "~&;[Stacks reset due to overflow.]")
29      (when (eq *current-process* *initial-process*)
30        (toplevel)))))
31
32
33(defvar *defined-toplevel-commands* ())
34(defvar *active-toplevel-commands* ())
35
36(defun %define-toplevel-command (group-name key name fn doc args)
37  (let* ((group (or (assoc group-name *defined-toplevel-commands*)
38                    (car (push (list group-name)
39                               *defined-toplevel-commands*))))
40         (pair (assoc key (cdr group) :test #'eq)))
41    (if pair
42      (rplacd pair (list* fn doc args))
43      (push (cons key (list* fn doc args)) (cdr group))))
44  name)
45
46(define-toplevel-command 
47    :global y (&optional p) "Yield control of terminal-input to process
48whose name or ID matches <p>, or to any process if <p> is null"
49    (%%yield-terminal-to (if p (find-process p))))      ;may be nil
50
51
52(define-toplevel-command
53    :global kill (p) "Kill process whose name or ID matches <p>"
54    (let* ((proc (find-process p)))
55      (if proc
56        (process-kill proc))))
57
58(define-toplevel-command 
59    :global proc (&optional p) "Show information about specified process <p>/all processes"
60    (flet ((show-process-info (proc)
61             (format t "~&~d : ~a ~a ~20t[~a] "
62                     (process-serial-number proc)
63                     (if (eq proc *current-process*)
64                       "->"
65                       "  ")
66                     (process-name proc)
67                     (process-whostate proc))
68             (let* ((suspend-count (process-suspend-count proc)))
69               (if (and suspend-count (not (eql 0 suspend-count)))
70                 (format t " (Suspended)")))
71             (let* ((terminal-input-shared-resource
72                     (if (typep *terminal-io* 'two-way-stream)
73                       (input-stream-shared-resource
74                        (two-way-stream-input-stream *terminal-io*)))))
75               (if (and terminal-input-shared-resource
76                        (%shared-resource-requestor-p
77                         terminal-input-shared-resource proc))
78                 (format t " (Requesting terminal input)")))
79             (fresh-line)))
80      (if p
81        (let* ((proc (find-process p)))
82          (if (null proc)
83            (format t "~&;; not found - ~s" p)
84            (show-process-info proc)))
85        (dolist (proc (all-processes) (values))
86          (show-process-info proc)))))
87
88(define-toplevel-command :global cd (dir) "Change to directory DIR" (setf (current-directory) dir) (toplevel-print (list (current-directory))))
89
90(define-toplevel-command :global pwd () "Print the pathame of the current directory" (toplevel-print (list (current-directory))))
91
92
93
94(defun list-restarts ()
95  (format *debug-io* "~&>   Type (:C <n>) to invoke one of the following restarts:")
96  (display-restarts))
97
98(define-toplevel-command :break pop () "exit current break loop" (abort-break))
99(define-toplevel-command :break a () "exit current break loop" (abort-break))
100(define-toplevel-command :break go () "continue" (continue))
101(define-toplevel-command :break q () "return to toplevel" (toplevel))
102(define-toplevel-command :break r () "list restarts" (list-restarts))
103
104(define-toplevel-command :break set (n frame value) "Set <n>th item of frame <frame> to <value>"
105  (let* ((frame-sp (nth-raw-frame frame *break-frame* nil)))
106    (if frame-sp
107        (toplevel-print (list (set-nth-value-in-frame frame-sp n nil value)))
108        (format *debug-io* "No frame with number ~D~%" frame))))
109
110(define-toplevel-command :break nframes ()
111  "print the number of stack frames accessible from this break loop"
112  (do* ((p *break-frame* (parent-frame p nil))
113        (i 0 (1+ i))
114        (last (last-frame-ptr)))
115      ((eql p last) (toplevel-print (list i)))))
116
117(define-toplevel-command :global ? () "help"
118  (format t "~&The following toplevel commands are available:")
119  (when *default-integer-command*
120    (format t "~& <n>  ~8Tthe same as (~s <n>)" (car *default-integer-command*)))
121  (dolist (g *active-toplevel-commands*)
122    (dolist (c (cdr g))
123      (let* ((command (car c))
124             (doc (caddr c))
125             (args (cdddr c)))
126        (if args
127          (format t "~& (~S~{ ~A~}) ~8T~A" command args doc)
128          (format t "~& ~S  ~8T~A" command doc)))))
129  (format t "~&Any other form is evaluated and its results are printed out."))
130
131
132(define-toplevel-command :break b (&key start count show-frame-contents) "backtrace"
133  (when *break-frame*
134      (print-call-history :detailed-p show-frame-contents
135                          :origin *break-frame*
136                          :count count
137                          :start-frame-number (or start 0))))
138
139(define-toplevel-command :break c (&optional n) "Choose restart <n>. If no <n>, continue"
140  (if n
141   (select-restart n)
142   (continue)))
143
144(define-toplevel-command :break f (n) "Show backtrace frame <n>"
145   (print-call-history :origin *break-frame*
146                       :start-frame-number n
147                       :count 1
148                       :detailed-p t))
149
150(define-toplevel-command :break return-from-frame (i &rest values) "Return VALUES from the I'th stack frame"
151  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
152    (if frame-sp
153      (apply #'return-from-frame frame-sp values))))
154
155(define-toplevel-command :break apply-in-frame (i function &rest args) "Applies FUNCTION to ARGS in the execution context of the Ith stack frame"
156  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
157    (if frame-sp
158      (apply-in-frame frame-sp function args))))
159                         
160                         
161
162(define-toplevel-command :break raw (n) "Show raw contents of backtrace frame <n>"
163   (print-call-history :origin *break-frame*
164                       :start-frame-number n
165                       :count 1
166                       :detailed-p :raw))
167
168(define-toplevel-command :break v (n frame-number) "Return value <n> in frame <frame-number>"
169  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
170    (if frame-sp
171      (toplevel-print (list (nth-value-in-frame frame-sp n nil))))))
172
173(define-toplevel-command :break arg (name frame-number) "Return value of argument named <name> in frame <frame-number>"
174  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
175    (when frame-sp
176      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
177        (when (and lfun pc)
178          (let* ((unavailable (cons nil nil)))
179            (declare (dynamic-extent unavailable))
180            (let* ((value (arg-value nil frame-sp lfun pc unavailable name)))
181              (if (eq value unavailable)
182                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
183                (toplevel-print (list value))))))))))
184
185(define-toplevel-command :break set-arg (name frame-number new) "Set value of argument named <name> in frame <frame-number> to value <new>."
186  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
187    (when frame-sp
188      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
189        (when (and lfun pc)
190          (or (set-arg-value nil frame-sp lfun pc name new)
191              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
192   
193
194(define-toplevel-command :break local (name frame-number) "Return value of local denoted by <name> in frame <frame-number> <name> can either be a symbol - in which case the most recent
195binding of that symbol is used - or an integer index into the frame's set of local bindings."
196  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
197    (when frame-sp
198      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
199        (when (and lfun pc)
200          (let* ((unavailable (cons nil nil)))
201            (declare (dynamic-extent unavailable))
202            (let* ((value (local-value nil frame-sp lfun pc unavailable name)))
203              (if (eq value unavailable)
204                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
205                (toplevel-print (list value))))))))))
206
207(define-toplevel-command :break set-local (name frame-number new) "Set value of argument denoted <name> (see :LOCAL) in frame <frame-number> to value <new>."
208  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
209    (when frame-sp
210      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
211        (when (and lfun pc)
212          (or (set-local-value nil frame-sp lfun pc name new)
213              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
214
215
216(define-toplevel-command :break form (frame-number)
217   "Return a form which looks like the call which established the stack frame identified by <frame-number>.  This is only well-defined in certain cases: when the function is globally named and not a lexical closure and when it was compiled with *SAVE-LOCAL-SYMBOLS* in effect."
218   (let* ((form (dbg-form frame-number)))
219     (when form
220       (let* ((*print-level* *backtrace-print-level*)
221              (*print-length* *backtrace-print-length*))
222         (toplevel-print (list form))))))
223
224;;; Ordinarily, form follows function.
225(define-toplevel-command :break function (frame-number)
226  "Returns the function invoked in backtrace frame <frame-number>.  This may be useful for, e.g., disassembly"
227  (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
228    (when (and cfp (not (catch-csp-p cfp nil)))
229      (let* ((function (cfp-lfun cfp)))
230        (when function
231          (toplevel-print (list function)))))))
232 
233
234
235         
236
237 
238
239(defun %use-toplevel-commands (group-name)
240  ;; Push the whole group
241  (pushnew (assoc group-name *defined-toplevel-commands*)
242           *active-toplevel-commands*
243           :key #'(lambda (x) (car x))))  ; #'car not defined yet ...
244
245(%use-toplevel-commands :global)
246
247(defparameter *toplevel-commands-dwim* t
248 "If true, tries to interpret otherwise-erroneous toplevel expressions as commands.
249In addition, will suppress standard error handling for expressions that look like
250commands but aren't")
251
252(defvar *default-integer-command* nil
253  "If non-nil, should be (keyword  min max)), causing integers between min and max to be
254  interpreted as (keyword integer)")
255
256(defun check-toplevel-command (form)
257  (when (and *default-integer-command*
258             (integerp form)
259             (<= (cadr *default-integer-command*) form (caddr *default-integer-command*)))
260    (setq form `(,(car *default-integer-command*) ,form)))
261  (let* ((cmd (if (consp form) (car form) form))
262         (args (if (consp form) (cdr form))))
263    (when (or (keywordp cmd)
264              (and *toplevel-commands-dwim*
265                   (non-nil-symbol-p cmd)
266                   (not (if (consp form)
267                          (fboundp cmd)
268                          (or (boundp cmd)
269                              (nth-value 1 (gethash cmd *symbol-macros*)))))
270                   ;; Use find-symbol so don't make unneeded keywords.
271                   (setq cmd (find-symbol (symbol-name cmd) :keyword))))
272      (when (eq cmd :help) (setq cmd :?))
273      (flet ((run (cmd form)
274               (or (dolist (g *active-toplevel-commands*)
275                     (let* ((pair (assoc cmd (cdr g))))
276                       (when pair 
277                         (apply (cadr pair) args)
278                         (return t))))
279                   ;; Try to detect user mistyping a command
280                   (when (and *toplevel-commands-dwim*
281                              (if (consp form)
282                                (and (keywordp (%car form)) (not (fboundp (%car form))))
283                                (keywordp form)))
284                     (error "Unknown command ~s" cmd)))))
285        (declare (dynamic-extent #'run))
286        (if *toplevel-commands-dwim*
287          (block nil
288            (handler-bind ((error (lambda (c)
289                                    (format t "~&~a" c)
290                                    (return t))))
291              (run cmd form)))
292          (run cmd form))))))
293
294(defparameter *quit-on-eof* nil)
295
296(defparameter *consecutive-eof-limit* 2 "max number of consecutive EOFs at a given break level, before we give up and abruptly exit.")
297
298(defmethod stream-eof-transient-p (stream)
299  (let ((fd (stream-device stream :input)))
300    (and fd (eof-transient-p fd))))
301
302;;; This is the part common to toplevel loop and inner break loops.
303(defun read-loop (&key (input-stream *standard-input*)
304                       (output-stream *standard-output*)
305                       (break-level *break-level*)
306                       (prompt-function #'(lambda (stream)
307                                            (when (and *show-available-restarts* *break-condition*)
308                                              (list-restarts)
309                                              (setf *show-available-restarts* nil))
310                                            (print-listener-prompt stream t))))
311  (let* ((*break-level* break-level)
312         (*last-break-level* break-level)
313         (*loading-file-source-file* nil)
314         (*loading-toplevel-location* nil)
315         *in-read-loop*
316         *** ** * +++ ++ + /// // / -
317         (eof-value (cons nil nil))
318         (eof-count 0)
319         (*show-available-restarts* (and *show-restarts-on-break* *break-condition*))
320         (*nx-source-note-map* (make-hash-table :test #'eq :shared nil)))
321    (declare (dynamic-extent eof-value))
322    (loop
323      (restart-case
324       (catch :abort                    ;last resort...
325         (loop
326           (catch-cancel
327            (loop               
328              (setq *in-read-loop* nil
329                    *break-level* break-level)
330              (clrhash *nx-source-note-map*)
331              (multiple-value-bind (form env print-result)
332                  (toplevel-read :input-stream input-stream
333                                 :output-stream output-stream
334                                 :prompt-function prompt-function
335                                 :eof-value eof-value
336                                 :map *nx-source-note-map*)
337                (if (eq form eof-value)
338                  (progn
339                    (when (> (incf eof-count) *consecutive-eof-limit*)
340                      (#_ _exit 0))
341                    (if (and (not *batch-flag*)
342                             (not *quit-on-eof*)
343                             (stream-eof-transient-p input-stream))
344                      (progn
345                        (stream-clear-input input-stream)
346                        (abort-break))
347                      (exit-interactive-process *current-process*)))
348                  (progn
349                    (setq eof-count 0)
350                    (or (check-toplevel-command form)
351                        (let* ((values (toplevel-eval form env)))
352                          (if print-result (toplevel-print values)))))))))
353           (format *terminal-io* "~&Cancelled")))
354       (abort () :report (lambda (stream)
355                           (if (eq break-level 0)
356                             (format stream "Return to toplevel.")
357                             (format stream "Return to break level ~D." break-level)))
358              #|                        ; Handled by interactive-abort
359                                        ; go up one more if abort occurred while awaiting/reading input               
360              (when (and *in-read-loop* (neq break-level 0))
361              (abort))
362              |#
363               )
364        (abort-break () 
365                     (unless (eq break-level 0)
366                       (abort))))
367       (clear-input input-stream)
368      (format output-stream "~%"))))
369
370;;; The first non-whitespace character available on INPUT-STREAM is a colon.
371;;; Try to interpret the line as a colon command (or possibly just a keyword.)
372(defun read-command-or-keyword (input-stream eof-value)
373  (let* ((line (read-line input-stream nil eof-value)))
374    (if (eq line eof-value)
375      eof-value
376      (let* ((in (make-string-input-stream line))
377             (keyword (read in nil eof-value)))
378        (if (eq keyword eof-value)
379          eof-value
380          (if (not (keywordp keyword))
381            keyword
382            (collect ((params))
383              (loop
384                (let* ((param (read in nil eof-value)))
385                  (if (eq param eof-value)
386                    (return
387                      (let* ((params (params)))
388                        (if params
389                          (cons keyword params)
390                          keyword)))
391                    (params (eval param))))))))))))
392
393;;; Read a form from the specified stream.
394(defun toplevel-read (&key (input-stream *standard-input*)
395                           (output-stream *standard-output*)
396                           (prompt-function #'print-listener-prompt)
397                           (eof-value *eof-value*)
398                           (map nil))
399  (force-output output-stream)
400  (funcall prompt-function output-stream)
401  (read-toplevel-form input-stream :eof-value eof-value :map map))
402
403(defvar *always-eval-user-defvars* nil)
404
405(defun process-single-selection (form)
406  (if (and *always-eval-user-defvars*
407           (listp form) (eq (car form) 'defvar) (cddr form))
408    `(defparameter ,@(cdr form))
409    form))
410
411(defun toplevel-eval (form &optional env)
412  (destructuring-bind (vars . vals) (or env '(nil . nil))
413    (progv vars vals
414      (setq +++ ++ ++ + + - - form)
415      (unwind-protect
416           (let* ((package *package*)
417                  (values (multiple-value-list (cheap-eval-in-environment form nil))))
418             (unless (eq package *package*)
419               ;; If changing a local value (e.g. buffer-local), not useful to notify app
420               ;; without more info.  Perhaps should have a *source-context* that can send along?
421               (unless (member '*package* vars)
422                 (application-ui-operation *application* :note-current-package *package*)))
423             values)
424        (loop for var in vars as pval on vals
425              do (setf (car pval) (symbol-value var)))))))
426
427
428(defun toplevel-print (values &optional (out *standard-output*))
429  (setq /// // // / / values)
430  (unless (eq (car values) (%unbound-marker))
431    (setq *** ** ** * *  (%car values)))
432  (when values
433    (fresh-line out)
434    (dolist (val values) (write val :stream out) (terpri out))))
435
436(defparameter *listener-prompt-format* "~[?~:;~:*~d >~] ")
437
438 
439(defun print-listener-prompt (stream &optional (force t))
440  (unless *quiet-flag*
441    (when (or force (neq *break-level* *last-break-level*))
442      (let* ((*listener-indent* nil))
443        (fresh-line stream)
444        (format stream *listener-prompt-format* *break-level*))
445      (setq *last-break-level* *break-level*)))
446    (force-output stream))
447
448
449;;; Fairly crude default error-handlingbehavior, and a fairly crude mechanism
450;;; for customizing it.
451
452(defvar *app-error-handler-mode* :quit
453  "one of :quit, :quit-quietly, :listener might be useful.")
454
455(defmethod application-error ((a application) condition error-pointer)
456  (case *app-error-handler-mode*
457    (:listener   (break-loop-handle-error condition error-pointer))
458    (:quit-quietly (quit -1))
459    (:quit  (format t "~&Fatal error in ~s : ~a"
460                    (pathname-name (car *command-line-argument-list*))
461                    condition)
462                    (quit -1))))
463
464(defun make-application-error-handler (app mode)
465  (declare (ignore app))
466  (setq *app-error-handler-mode* mode))
467
468
469; You may want to do this anyway even if your application
470; does not otherwise wish to be a "lisp-development-system"
471(defmethod application-error ((a lisp-development-system) condition error-pointer)
472  (break-loop-handle-error condition error-pointer))
473
474(defun abnormal-application-exit ()
475  (ignore-errors
476    (print-call-history)
477    (force-output *debug-io*)
478    (quit -1))
479  (#__exit -1))
480
481(defvar *top-error-frame* nil)
482
483(defun break-loop-handle-error (condition *top-error-frame*)
484  (multiple-value-bind (bogus-globals newvals oldvals) (%check-error-globals)
485    (dolist (x bogus-globals)
486      (set x (funcall (pop newvals))))
487    (when (and *debugger-hook* *break-on-errors* (not *batch-flag*))
488      (let ((hook *debugger-hook*)
489            (*debugger-hook* nil))
490        (funcall hook condition hook)))
491    (%break-message "Error" condition)
492    (let* ((s *error-output*))
493      (dolist (bogusness bogus-globals)
494        (let ((oldval (pop oldvals)))
495          (format s "~&;  NOTE: ~S was " bogusness)
496          (if (eq oldval (%unbound-marker-8))
497            (format s "unbound")
498            (format s "~s" oldval))
499          (format s ", was reset to ~s ." (symbol-value bogusness)))))
500    (if (and *break-on-errors* (not *batch-flag*))
501      (break-loop condition)
502      (if *batch-flag*
503        (abnormal-application-exit)
504        (abort)))))
505
506(defun break (&optional string &rest args)
507  "Print a message and invoke the debugger without allowing any possibility
508   of condition handling occurring."
509  (if *batch-flag*
510    (apply #'error (or string "BREAK invoked in batch mode") args)
511    (apply #'%break-in-frame (%get-frame-ptr) string args)))
512
513(defun %break-in-frame (fp &optional string &rest args)
514  (flet ((do-break-loop ()
515           (let ((c (if (typep string 'condition)
516                      string
517                      (make-condition 'simple-condition
518                                    :format-control (or string "")
519                                    :format-arguments args))))
520             (cbreak-loop "Break" "Return from BREAK." c fp))))
521    (cond ((%i> *interrupt-level* -1)
522           (do-break-loop))
523          (*break-loop-when-uninterruptable*
524           (format *error-output* "Break while interrupt-level less than zero; binding to 0 during break-loop.")
525           (let ((interrupt-level (interrupt-level)))
526             (unwind-protect
527                  (progn
528                    (setf (interrupt-level) 0)
529                    (do-break-loop))
530               (setf (interrupt-level) interrupt-level))))
531          (t (format *error-output* "Break while interrupt-level less than zero; ignored.")))))
532
533
534(defun invoke-debugger (condition &aux (*top-error-frame* (%get-frame-ptr)))
535  "Enter the debugger."
536  (let ((c (require-type condition 'condition)))
537    (when *debugger-hook*
538      (let ((hook *debugger-hook*)
539            (*debugger-hook* nil))
540        (funcall hook c hook)))
541    (%break-message "Debug" c)
542    (break-loop c)))
543
544(defun %break-message (msg condition &optional (error-pointer *top-error-frame*) (prefixchar #\>))
545  (let ((*print-circle* *error-print-circle*)
546        ;(*print-prett*y nil)
547        (*print-array* nil)
548        (*print-escape* t)
549        (*print-gensym* t)
550        (*print-length* *error-print-length*)
551        (*print-level* *error-print-level*)
552        (*print-lines* nil)
553        (*print-miser-width* nil)
554        (*print-readably* nil)
555        (*print-right-margin* nil)
556        (*signal-printing-errors* nil)
557        (s (make-indenting-string-output-stream prefixchar nil)))
558    (format s "~A ~A: " prefixchar msg)
559    (setf (indenting-string-output-stream-indent s) (column s))
560    ;(format s "~A" condition) ; evil if circle
561    (report-condition condition s)
562    (if (not (and (typep condition 'simple-program-error)
563                  (simple-program-error-context condition)))
564      (format *error-output* "~&~A~%~A While executing: ~S"
565              (get-output-stream-string s) prefixchar (%real-err-fn-name error-pointer))
566      (format *error-output* "~&~A"
567              (get-output-stream-string s)))
568    (format *error-output* ", in process ~a(~d).~%" (process-name *current-process*) (process-serial-number *current-process*))
569  (force-output *error-output*)))
570                                        ; returns NIL
571
572(defvar *break-hook* nil)
573
574(defun cbreak-loop (msg cont-string condition *top-error-frame*)
575  (let* ((*print-readably* nil)
576         (hook *break-hook*))
577    (restart-case (progn
578                    (when hook
579                      (let ((*break-hook* nil))
580                        (funcall hook condition hook))
581                      (setq hook nil))
582                    (%break-message msg condition)
583                    (when (and (eq (type-of condition) 'simple-condition)
584                               (equal (simple-condition-format-control condition) ""))
585                      (setq condition (make-condition 'simple-condition
586                                        :format-control "~a"
587                                        :format-arguments (list msg))))
588                    (break-loop condition))
589      (continue () :report (lambda (stream) (write-string cont-string stream))))
590    (unless hook
591      (fresh-line *error-output*))
592    nil))
593
594(defun warn (condition-or-format-string &rest args)
595  "Warn about a situation by signalling a condition formed by DATUM and
596   ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
597   exists that causes WARN to immediately return NIL."
598  (when (typep condition-or-format-string 'condition)
599    (unless (typep condition-or-format-string 'warning)
600      (report-bad-arg condition-or-format-string 'warning))
601    (when args
602      (error 'type-error :datum args :expected-type 'null
603             :format-control "Extra arguments in ~s.")))
604  (let ((fp (%get-frame-ptr))
605        (c (require-type (condition-arg condition-or-format-string args 'simple-warning) 'warning)))
606    (when *break-on-warnings*
607      (cbreak-loop "Warning" "Signal the warning." c fp))
608    (restart-case (signal c)
609      (muffle-warning () :report "Skip the warning" (return-from warn nil)))
610    (%break-message (if (typep c 'compiler-warning) "Compiler warning" "Warning") c fp #\;)
611    ))
612
613(declaim (notinline select-backtrace))
614
615(defmacro new-backtrace-info (dialog youngest oldest tcr condition current fake db-link level)
616  (let* ((cond (gensym)))
617  `(let* ((,cond ,condition))
618    (vector ,dialog ,youngest ,oldest ,tcr (cons nil (compute-restarts ,cond)) (%catch-top ,tcr) ,cond ,current ,fake ,db-link ,level))))
619
620(defun select-backtrace ()
621  (declare (notinline select-backtrace))
622  ;(require 'new-backtrace)
623  (require :inspector)
624  (select-backtrace))
625
626(defvar *break-condition* nil "condition argument to innermost break-loop.")
627(defvar *break-frame* nil "frame-pointer arg to break-loop")
628(defvar *break-loop-when-uninterruptable* t)
629(defvar *show-restarts-on-break* #+ccl-0711 t #-ccl-0711 nil)
630(defvar *show-available-restarts* nil)
631
632(defvar *error-reentry-count* 0)
633
634(defun funcall-with-error-reentry-detection (thunk)
635  (let* ((count *error-reentry-count*)
636         (*error-reentry-count* (1+ count)))
637    (cond ((eql count 0) (funcall thunk))
638          ((eql count 1) (error "Error reporting error"))
639          (t (bug "Error reporting error")))))
640
641
642
643
644(defvar %last-continue% nil)
645(defun break-loop (condition &optional (frame-pointer *top-error-frame*))
646  "Never returns"
647  (let* ((%handlers% (last %handlers%)) ; firewall
648         (*break-frame* frame-pointer)
649         (*break-condition* condition)
650         (*compiling-file* nil)
651         (*backquote-stack* nil)
652         (continue (find-restart 'continue))
653         (*continuablep* (unless (eq %last-continue% continue) continue))
654         (%last-continue% continue)
655         (*standard-input* *debug-io*)
656         (*standard-output* *debug-io*)
657         (*signal-printing-errors* nil)
658         (*read-suppress* nil)
659         (*print-readably* nil)
660         (*default-integer-command* `(:c 0 ,(1- (length (compute-restarts condition)))))
661         (context (new-backtrace-info nil
662                                      frame-pointer
663                                      (if *backtrace-contexts*
664                                        (or (child-frame
665                                             (bt.youngest (car *backtrace-contexts*))
666                                             nil)
667                                            (last-frame-ptr))
668                                        (last-frame-ptr))
669                                      (%current-tcr)
670                                      condition
671                                      (%current-frame-ptr)
672                                      #+ppc-target *fake-stack-frames*
673                                      #+x86-target (%current-frame-ptr)
674                                      (db-link)
675                                      (1+ *break-level*)))
676         (*backtrace-contexts* (cons context *backtrace-contexts*)))
677    (with-terminal-input
678      (with-toplevel-commands :break
679        (if *continuablep*
680          (let* ((*print-circle* *error-print-circle*)
681                 (*print-level* *error-print-level*)
682                 (*print-length* *error-print-length*)
683                                        ;(*print-pretty* nil)
684                 (*print-array* nil))
685            (format t (or (application-ui-operation *application* :break-options-string t)
686                          "~&> Type :GO to continue, :POP to abort, :R for a list of available restarts."))
687            (format t "~&> If continued: ~A~%" continue))
688          (format t (or (application-ui-operation *application* :break-options-string nil)
689                        "~&> Type :POP to abort, :R for a list of available restarts.~%")))
690        (format t "~&> Type :? for other options.")
691        (terpri)
692        (force-output)
693
694        (clear-input *debug-io*)
695        (setq *error-reentry-count* 0)  ; succesfully reported error
696        (ignoring-without-interrupts
697          (unwind-protect
698               (progn
699                 (application-ui-operation *application*
700                                           :enter-backtrace-context context)
701                 (read-loop :break-level (1+ *break-level*)
702                            :input-stream *debug-io*
703                            :output-stream *debug-io*))
704            (application-ui-operation *application* :exit-backtrace-context
705                                      context)))))))
706
707
708
709(defun display-restarts (&optional (condition *break-condition*))
710  (loop
711    for restart in (compute-restarts condition)
712    for count upfrom 0
713    do (format *debug-io* "~&~D. ~A" count restart)
714    finally (fresh-line *debug-io*)))
715
716(defun select-restart (n &optional (condition *break-condition*))
717  (let* ((restarts (compute-restarts condition)))
718    (invoke-restart-interactively
719     (nth (require-type n `(integer 0 (,(length restarts)))) restarts))))
720
721
722
723
724; End of l1-readloop-lds.lisp
Note: See TracBrowser for help on using the repository browser.