source: trunk/source/level-1/l1-readloop-lds.lisp @ 13066

Last change on this file since 13066 was 13066, checked in by rme, 10 years ago

Change "OpenMCL" to "Clozure CL" in comments and docstrings.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 29.8 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of Clozure CL. 
5;;;
6;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with Clozure CL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17; l1-readloop-lds.lisp
18
19(in-package "CCL")
20
21
22
23(defun toplevel-loop ()
24  (loop
25    (if (eq (catch :toplevel 
26              (read-loop :break-level 0 )) $xstkover)
27      (format t "~&;[Stacks reset due to overflow.]")
28      (when (eq *current-process* *initial-process*)
29        (toplevel)))))
30
31
32(defvar *defined-toplevel-commands* ())
33(defvar *active-toplevel-commands* ())
34
35(defun %define-toplevel-command (group-name key name fn doc args)
36  (let* ((group (or (assoc group-name *defined-toplevel-commands*)
37                    (car (push (list group-name)
38                               *defined-toplevel-commands*))))
39         (pair (assoc key (cdr group) :test #'eq)))
40    (if pair
41      (rplacd pair (list* fn doc args))
42      (push (cons key (list* fn doc args)) (cdr group))))
43  name)
44
45(define-toplevel-command 
46    :global y (&optional p) "Yield control of terminal-input to process
47whose name or ID matches <p>, or to any process if <p> is null"
48    (%%yield-terminal-to (if p (find-process p))))      ;may be nil
49
50
51(define-toplevel-command
52    :global kill (p) "Kill process whose name or ID matches <p>"
53    (let* ((proc (find-process p)))
54      (if proc
55        (process-kill proc))))
56
57(define-toplevel-command 
58    :global proc (&optional p) "Show information about specified process <p>/all processes"
59    (flet ((show-process-info (proc)
60             (format t "~&~d : ~a ~a ~20t[~a] "
61                     (process-serial-number proc)
62                     (if (eq proc *current-process*)
63                       "->"
64                       "  ")
65                     (process-name proc)
66                     (process-whostate proc))
67             (let* ((suspend-count (process-suspend-count proc)))
68               (if (and suspend-count (not (eql 0 suspend-count)))
69                 (format t " (Suspended)")))
70             (let* ((terminal-input-shared-resource
71                     (if (typep *terminal-io* 'two-way-stream)
72                       (input-stream-shared-resource
73                        (two-way-stream-input-stream *terminal-io*)))))
74               (if (and terminal-input-shared-resource
75                        (%shared-resource-requestor-p
76                         terminal-input-shared-resource proc))
77                 (format t " (Requesting terminal input)")))
78             (fresh-line)))
79      (if p
80        (let* ((proc (find-process p)))
81          (if (null proc)
82            (format t "~&;; not found - ~s" p)
83            (show-process-info proc)))
84        (dolist (proc (all-processes) (values))
85          (show-process-info proc)))))
86
87(define-toplevel-command :global cd (dir) "Change to directory DIR" (setf (current-directory) dir) (toplevel-print (list (current-directory))))
88
89(define-toplevel-command :global pwd () "Print the pathame of the current directory" (toplevel-print (list (current-directory))))
90
91
92
93(defun list-restarts ()
94  (format *debug-io* "~&>   Type (:C <n>) to invoke one of the following restarts:")
95  (display-restarts))
96
97(define-toplevel-command :break pop () "exit current break loop" (abort-break))
98(define-toplevel-command :break a () "exit current break loop" (abort-break))
99(define-toplevel-command :break go () "continue" (continue))
100(define-toplevel-command :break q () "return to toplevel" (toplevel))
101(define-toplevel-command :break r () "list restarts" (list-restarts))
102
103(define-toplevel-command :break set (n frame value) "Set <n>th item of frame <frame> to <value>"
104  (let* ((frame-sp (nth-raw-frame frame *break-frame* nil)))
105    (if frame-sp
106        (toplevel-print (list (set-nth-value-in-frame frame-sp n nil value)))
107        (format *debug-io* "No frame with number ~D~%" frame))))
108
109(define-toplevel-command :break nframes ()
110  "print the number of stack frames accessible from this break loop"
111  (do* ((p *break-frame* (parent-frame p nil))
112        (i 0 (1+ i))
113        (last (last-frame-ptr)))
114      ((eql p last) (toplevel-print (list i)))))
115
116(define-toplevel-command :global ? () "help"
117  (format t "~&The following toplevel commands are available:")
118  (when *default-integer-command*
119    (format t "~& <n>  ~8Tthe same as (~s <n>)" (car *default-integer-command*)))
120  (dolist (g *active-toplevel-commands*)
121    (dolist (c (cdr g))
122      (let* ((command (car c))
123             (doc (caddr c))
124             (args (cdddr c)))
125        (if args
126          (format t "~& (~S~{ ~A~}) ~8T~A" command args doc)
127          (format t "~& ~S  ~8T~A" command doc)))))
128  (format t "~&Any other form is evaluated and its results are printed out."))
129
130
131(define-toplevel-command :break b (&key start count show-frame-contents) "backtrace"
132  (when *break-frame*
133      (print-call-history :detailed-p show-frame-contents
134                          :origin *break-frame*
135                          :count count
136                          :start-frame-number (or start 0))))
137
138(define-toplevel-command :break c (&optional n) "Choose restart <n>. If no <n>, continue"
139  (if n
140   (select-restart n)
141   (continue)))
142
143(define-toplevel-command :break f (n) "Show backtrace frame <n>"
144   (print-call-history :origin *break-frame*
145                       :start-frame-number n
146                       :count 1
147                       :detailed-p t))
148
149(define-toplevel-command :break return-from-frame (i &rest values) "Return VALUES from the I'th stack frame"
150  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
151    (if frame-sp
152      (apply #'return-from-frame frame-sp values))))
153
154(define-toplevel-command :break apply-in-frame (i function &rest args) "Applies FUNCTION to ARGS in the execution context of the Ith stack frame"
155  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
156    (if frame-sp
157      (apply-in-frame frame-sp function args))))
158                         
159                         
160
161(define-toplevel-command :break raw (n) "Show raw contents of backtrace frame <n>"
162   (print-call-history :origin *break-frame*
163                       :start-frame-number n
164                       :count 1
165                       :detailed-p :raw))
166
167(define-toplevel-command :break v (n frame-number) "Return value <n> in frame <frame-number>"
168  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
169    (if frame-sp
170      (toplevel-print (list (nth-value-in-frame frame-sp n nil))))))
171
172(define-toplevel-command :break arg (name frame-number) "Return value of argument named <name> in frame <frame-number>"
173  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
174    (when frame-sp
175      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
176        (when (and lfun pc)
177          (let* ((unavailable (cons nil nil)))
178            (declare (dynamic-extent unavailable))
179            (let* ((value (arg-value nil frame-sp lfun pc unavailable name)))
180              (if (eq value unavailable)
181                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
182                (toplevel-print (list value))))))))))
183
184(define-toplevel-command :break set-arg (name frame-number new) "Set value of argument named <name> in frame <frame-number> to value <new>."
185  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
186    (when frame-sp
187      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
188        (when (and lfun pc)
189          (or (set-arg-value nil frame-sp lfun pc name new)
190              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
191   
192
193(define-toplevel-command :break local (name frame-number) "Return value of local denoted by <name> in frame <frame-number> <name> can either be a symbol - in which case the most recent
194binding of that symbol is used - or an integer index into the frame's set of local bindings."
195  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
196    (when frame-sp
197      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
198        (when (and lfun pc)
199          (let* ((unavailable (cons nil nil)))
200            (declare (dynamic-extent unavailable))
201            (let* ((value (local-value nil frame-sp lfun pc unavailable name)))
202              (if (eq value unavailable)
203                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
204                (toplevel-print (list value))))))))))
205
206(define-toplevel-command :break set-local (name frame-number new) "Set value of argument denoted <name> (see :LOCAL) in frame <frame-number> to value <new>."
207  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
208    (when frame-sp
209      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
210        (when (and lfun pc)
211          (or (set-local-value nil frame-sp lfun pc name new)
212              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
213
214
215(define-toplevel-command :break form (frame-number)
216   "Return a form which looks like the call which established the stack frame identified by <frame-number>.  This is only well-defined in certain cases: when the function is globally named and not a lexical closure and when it was compiled with *SAVE-LOCAL-SYMBOLS* in effect."
217   (let* ((form (dbg-form frame-number)))
218     (when form
219       (let* ((*print-level* *backtrace-print-level*)
220              (*print-length* *backtrace-print-length*))
221         (toplevel-print (list form))))))
222
223;;; Ordinarily, form follows function.
224(define-toplevel-command :break function (frame-number)
225  "Returns the function invoked in backtrace frame <frame-number>.  This may be useful for, e.g., disassembly"
226  (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
227    (when (and cfp (not (catch-csp-p cfp nil)))
228      (let* ((function (cfp-lfun cfp)))
229        (when function
230          (toplevel-print (list function)))))))
231 
232
233
234         
235
236 
237
238(defun %use-toplevel-commands (group-name)
239  ;; Push the whole group
240  (pushnew (assoc group-name *defined-toplevel-commands*)
241           *active-toplevel-commands*
242           :key #'(lambda (x) (car x))))  ; #'car not defined yet ...
243
244(%use-toplevel-commands :global)
245
246(defparameter *toplevel-commands-dwim* t
247 "If true, tries to interpret otherwise-erroneous toplevel expressions as commands.
248In addition, will suppress standard error handling for expressions that look like
249commands but aren't")
250
251(defvar *default-integer-command* nil
252  "If non-nil, should be (keyword  min max)), causing integers between min and max to be
253  interpreted as (keyword integer)")
254
255(defun check-toplevel-command (form)
256  (when (and *default-integer-command*
257             (integerp form)
258             (<= (cadr *default-integer-command*) form (caddr *default-integer-command*)))
259    (setq form `(,(car *default-integer-command*) ,form)))
260  (let* ((cmd (if (consp form) (car form) form))
261         (args (if (consp form) (cdr form))))
262    (when (or (keywordp cmd)
263              (and *toplevel-commands-dwim*
264                   (non-nil-symbol-p cmd)
265                   (not (if (consp form)
266                          (fboundp cmd)
267                          (or (boundp cmd)
268                              (nth-value 1 (gethash cmd *symbol-macros*)))))
269                   ;; Use find-symbol so don't make unneeded keywords.
270                   (setq cmd (find-symbol (symbol-name cmd) :keyword))))
271      (when (eq cmd :help) (setq cmd :?))
272      (flet ((run (cmd form)
273               (or (dolist (g *active-toplevel-commands*)
274                     (let* ((pair (assoc cmd (cdr g))))
275                       (when pair 
276                         (apply (cadr pair) args)
277                         (return t))))
278                   ;; Try to detect user mistyping a command
279                   (when (and *toplevel-commands-dwim*
280                              (if (consp form)
281                                (and (keywordp (%car form)) (not (fboundp (%car form))))
282                                (keywordp form)))
283                     (error "Unknown command ~s" cmd)))))
284        (declare (dynamic-extent #'run))
285        (if *toplevel-commands-dwim*
286          (block nil
287            (handler-bind ((error (lambda (c)
288                                    (format t "~&~a" c)
289                                    (return t))))
290              (run cmd form)))
291          (run cmd form))))))
292
293(defparameter *quit-on-eof* nil)
294
295(defparameter *consecutive-eof-limit* 2 "max number of consecutive EOFs at a given break level, before we give up and abruptly exit.")
296
297(defmethod stream-eof-transient-p (stream)
298  (let ((fd (stream-device stream :input)))
299    (and fd (eof-transient-p fd))))
300
301;;; This is the part common to toplevel loop and inner break loops.
302(defun read-loop (&key (input-stream *standard-input*)
303                       (output-stream *standard-output*)
304                       (break-level *break-level*)
305                       (prompt-function #'(lambda (stream)
306                                            (when (and *show-available-restarts* *break-condition*)
307                                              (list-restarts)
308                                              (setf *show-available-restarts* nil))
309                                            (print-listener-prompt stream t))))
310  (let* ((*break-level* break-level)
311         (*last-break-level* break-level)
312         (*loading-file-source-file* nil)
313         (*loading-toplevel-location* nil)
314         *in-read-loop*
315         *** ** * +++ ++ + /// // / -
316         (eof-value (cons nil nil))
317         (eof-count 0)
318         (*show-available-restarts* (and *show-restarts-on-break* *break-condition*)))
319    (declare (dynamic-extent eof-value))
320    (loop
321      (restart-case
322       (catch :abort                    ;last resort...
323         (loop
324           (catch-cancel
325            (loop               
326              (setq *in-read-loop* nil
327                    *break-level* break-level)
328              (multiple-value-bind (form env print-result)
329                  (toplevel-read :input-stream input-stream
330                                 :output-stream output-stream
331                                 :prompt-function prompt-function
332                                 :eof-value eof-value)
333                (if (eq form eof-value)
334                  (progn
335                    (when (> (incf eof-count) *consecutive-eof-limit*)
336                      (#_ _exit 0))
337                    (if (and (not *batch-flag*)
338                             (not *quit-on-eof*)
339                             (stream-eof-transient-p input-stream))
340                      (progn
341                        (stream-clear-input input-stream)
342                        (abort-break))
343                      (exit-interactive-process *current-process*)))
344                  (progn
345                    (setq eof-count 0)
346                    (or (check-toplevel-command form)
347                        (let* ((values (toplevel-eval form env)))
348                          (if print-result (toplevel-print values)))))))))
349           (format *terminal-io* "~&Cancelled")))
350       (abort () :report (lambda (stream)
351                           (if (eq break-level 0)
352                             (format stream "Return to toplevel.")
353                             (format stream "Return to break level ~D." break-level)))
354              #|                        ; Handled by interactive-abort
355                                        ; go up one more if abort occurred while awaiting/reading input               
356              (when (and *in-read-loop* (neq break-level 0))
357              (abort))
358              |#
359               )
360        (abort-break () 
361                     (unless (eq break-level 0)
362                       (abort))))
363       (clear-input input-stream)
364      (format output-stream "~%"))))
365
366;;; The first non-whitespace character available on INPUT-STREAM is a colon.
367;;; Try to interpret the line as a colon command (or possibly just a keyword.)
368(defun read-command-or-keyword (input-stream eof-value)
369  (let* ((line (read-line input-stream nil eof-value)))
370    (if (eq line eof-value)
371      eof-value
372      (let* ((in (make-string-input-stream line))
373             (keyword (read in nil eof-value)))
374        (if (eq keyword eof-value)
375          eof-value
376          (if (not (keywordp keyword))
377            keyword
378            (collect ((params))
379              (loop
380                (let* ((param (read in nil eof-value)))
381                  (if (eq param eof-value)
382                    (return
383                      (let* ((params (params)))
384                        (if params
385                          (cons keyword params)
386                          keyword)))
387                    (params (eval param))))))))))))
388
389;;; Read a form from the specified stream.
390(defun toplevel-read (&key (input-stream *standard-input*)
391                           (output-stream *standard-output*)
392                           (prompt-function #'print-listener-prompt)
393                           (eof-value *eof-value*))
394  (force-output output-stream)
395  (funcall prompt-function output-stream)
396  (read-toplevel-form input-stream :eof-value eof-value))
397
398(defvar *always-eval-user-defvars* nil)
399
400(defun process-single-selection (form)
401  (if (and *always-eval-user-defvars*
402           (listp form) (eq (car form) 'defvar) (cddr form))
403    `(defparameter ,@(cdr form))
404    form))
405
406(defun toplevel-eval (form &optional env)
407  (destructuring-bind (vars . vals) (or env '(nil . nil))
408    (progv vars vals
409      (setq +++ ++ ++ + + - - form)
410      (unwind-protect
411           (let* ((package *package*)
412                  (values (multiple-value-list (cheap-eval-in-environment form nil))))
413             (unless (eq package *package*)
414               ;; If changing a local value (e.g. buffer-local), not useful to notify app
415               ;; without more info.  Perhaps should have a *source-context* that can send along?
416               (unless (member '*package* vars)
417                 (application-ui-operation *application* :note-current-package *package*)))
418             values)
419        (loop for var in vars as pval on vals
420              do (setf (car pval) (symbol-value var)))))))
421
422
423(defun toplevel-print (values &optional (out *standard-output*))
424  (setq /// // // / / values)
425  (unless (eq (car values) (%unbound-marker))
426    (setq *** ** ** * *  (%car values)))
427  (when values
428    (fresh-line out)
429    (dolist (val values) (write val :stream out) (terpri out))))
430
431(defparameter *listener-prompt-format* "~[?~:;~:*~d >~] ")
432
433 
434(defun print-listener-prompt (stream &optional (force t))
435  (unless *quiet-flag*
436    (when (or force (neq *break-level* *last-break-level*))
437      (let* ((*listener-indent* nil))
438        (fresh-line stream)
439        (format stream *listener-prompt-format* *break-level*))
440      (setq *last-break-level* *break-level*)))
441    (force-output stream))
442
443
444;;; Fairly crude default error-handlingbehavior, and a fairly crude mechanism
445;;; for customizing it.
446
447(defvar *app-error-handler-mode* :quit
448  "one of :quit, :quit-quietly, :listener might be useful.")
449
450(defmethod application-error ((a application) condition error-pointer)
451  (case *app-error-handler-mode*
452    (:listener   (break-loop-handle-error condition error-pointer))
453    (:quit-quietly (quit -1))
454    (:quit  (format t "~&Fatal error in ~s : ~a"
455                    (pathname-name (car *command-line-argument-list*))
456                    condition)
457                    (quit -1))))
458
459(defun make-application-error-handler (app mode)
460  (declare (ignore app))
461  (setq *app-error-handler-mode* mode))
462
463
464; You may want to do this anyway even if your application
465; does not otherwise wish to be a "lisp-development-system"
466(defmethod application-error ((a lisp-development-system) condition error-pointer)
467  (break-loop-handle-error condition error-pointer))
468
469(defun abnormal-application-exit ()
470  (ignore-errors
471    (print-call-history)
472    (force-output *debug-io*)
473    (quit -1))
474  (#__exit -1))
475
476(defvar *top-error-frame* nil)
477
478(defun break-loop-handle-error (condition *top-error-frame*)
479  (multiple-value-bind (bogus-globals newvals oldvals) (%check-error-globals)
480    (dolist (x bogus-globals)
481      (set x (funcall (pop newvals))))
482    (when (and *debugger-hook* *break-on-errors* (not *batch-flag*))
483      (let ((hook *debugger-hook*)
484            (*debugger-hook* nil))
485        (funcall hook condition hook)))
486    (%break-message "Error" condition)
487    (let* ((s *error-output*))
488      (dolist (bogusness bogus-globals)
489        (let ((oldval (pop oldvals)))
490          (format s "~&;  NOTE: ~S was " bogusness)
491          (if (eq oldval (%unbound-marker-8))
492            (format s "unbound")
493            (format s "~s" oldval))
494          (format s ", was reset to ~s ." (symbol-value bogusness)))))
495    (if (and *break-on-errors* (not *batch-flag*))
496      (break-loop condition)
497      (if *batch-flag*
498        (abnormal-application-exit)
499        (abort)))))
500
501(defun break (&optional string &rest args)
502  "Print a message and invoke the debugger without allowing any possibility
503   of condition handling occurring."
504  (if *batch-flag*
505    (apply #'error (or string "BREAK invoked in batch mode") args)
506    (apply #'%break-in-frame (%get-frame-ptr) string args)))
507
508(defun %break-in-frame (fp &optional string &rest args)
509  (flet ((do-break-loop ()
510           (let ((c (if (typep string 'condition)
511                      string
512                      (make-condition 'simple-condition
513                                    :format-control (or string "")
514                                    :format-arguments args))))
515             (cbreak-loop "Break" "Return from BREAK." c fp))))
516    (cond ((%i> *interrupt-level* -1)
517           (do-break-loop))
518          (*break-loop-when-uninterruptable*
519           (format *error-output* "Break while interrupt-level less than zero; binding to 0 during break-loop.")
520           (let ((interrupt-level (interrupt-level)))
521             (unwind-protect
522                  (progn
523                    (setf (interrupt-level) 0)
524                    (do-break-loop))
525               (setf (interrupt-level) interrupt-level))))
526          (t (format *error-output* "Break while interrupt-level less than zero; ignored.")))))
527
528
529(defun invoke-debugger (condition &aux (*top-error-frame* (%get-frame-ptr)))
530  "Enter the debugger."
531  (let ((c (require-type condition 'condition)))
532    (when *debugger-hook*
533      (let ((hook *debugger-hook*)
534            (*debugger-hook* nil))
535        (funcall hook c hook)))
536    (%break-message "Debug" c)
537    (break-loop c)))
538
539(defun %break-message (msg condition &optional (error-pointer *top-error-frame*) (prefixchar #\>))
540  (let ((*print-circle* *error-print-circle*)
541        ;(*print-prett*y nil)
542        (*print-array* nil)
543        (*print-escape* t)
544        (*print-gensym* t)
545        (*print-length* *error-print-length*)
546        (*print-level* *error-print-level*)
547        (*print-lines* nil)
548        (*print-miser-width* nil)
549        (*print-readably* nil)
550        (*print-right-margin* nil)
551        (*signal-printing-errors* nil)
552        (s (make-indenting-string-output-stream prefixchar nil)))
553    (format s "~A ~A: " prefixchar msg)
554    (setf (indenting-string-output-stream-indent s) (column s))
555    ;(format s "~A" condition) ; evil if circle
556    (report-condition condition s)
557    (if (not (and (typep condition 'simple-program-error)
558                  (simple-program-error-context condition)))
559      (format *error-output* "~&~A~%~A While executing: ~S"
560              (get-output-stream-string s) prefixchar (%real-err-fn-name error-pointer))
561      (format *error-output* "~&~A"
562              (get-output-stream-string s)))
563    (format *error-output* ", in process ~a(~d).~%" (process-name *current-process*) (process-serial-number *current-process*))
564  (force-output *error-output*)))
565                                        ; returns NIL
566
567(defvar *break-hook* nil)
568
569(defun cbreak-loop (msg cont-string condition *top-error-frame*)
570  (let* ((*print-readably* nil)
571         (hook *break-hook*))
572    (restart-case (progn
573                    (when hook
574                      (let ((*break-hook* nil))
575                        (funcall hook condition hook))
576                      (setq hook nil))
577                    (%break-message msg condition)
578                    (when (and (eq (type-of condition) 'simple-condition)
579                               (equal (simple-condition-format-control condition) ""))
580                      (setq condition (make-condition 'simple-condition
581                                        :format-control "~a"
582                                        :format-arguments (list msg))))
583                    (break-loop condition))
584      (continue () :report (lambda (stream) (write-string cont-string stream))))
585    (unless hook
586      (fresh-line *error-output*))
587    nil))
588
589(defun warn (condition-or-format-string &rest args)
590  "Warn about a situation by signalling a condition formed by DATUM and
591   ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
592   exists that causes WARN to immediately return NIL."
593  (when (typep condition-or-format-string 'condition)
594    (unless (typep condition-or-format-string 'warning)
595      (report-bad-arg condition-or-format-string 'warning))
596    (when args
597      (error 'type-error :datum args :expected-type 'null
598             :format-control "Extra arguments in ~s.")))
599  (let ((fp (%get-frame-ptr))
600        (c (require-type (condition-arg condition-or-format-string args 'simple-warning) 'warning)))
601    (when *break-on-warnings*
602      (cbreak-loop "Warning" "Signal the warning." c fp))
603    (restart-case (signal c)
604      (muffle-warning () :report "Skip the warning" (return-from warn nil)))
605    (%break-message (if (typep c 'compiler-warning) "Compiler warning" "Warning") c fp #\;)
606    ))
607
608(declaim (notinline select-backtrace))
609
610(defmacro new-backtrace-info (dialog youngest oldest tcr condition current fake db-link level)
611  (let* ((cond (gensym)))
612  `(let* ((,cond ,condition))
613    (vector ,dialog ,youngest ,oldest ,tcr (cons nil (compute-restarts ,cond)) (%catch-top ,tcr) ,cond ,current ,fake ,db-link ,level))))
614
615(defun select-backtrace ()
616  (declare (notinline select-backtrace))
617  ;(require 'new-backtrace)
618  (require :inspector)
619  (select-backtrace))
620
621(defvar *break-condition* nil "condition argument to innermost break-loop.")
622(defvar *break-frame* nil "frame-pointer arg to break-loop")
623(defvar *break-loop-when-uninterruptable* t)
624(defvar *show-restarts-on-break* #+ccl-0711 t #-ccl-0711 nil)
625(defvar *show-available-restarts* nil)
626
627(defvar *error-reentry-count* 0)
628
629(defun funcall-with-error-reentry-detection (thunk)
630  (let* ((count *error-reentry-count*)
631         (*error-reentry-count* (1+ count)))
632    (cond ((eql count 0) (funcall thunk))
633          ((eql count 1) (error "Error reporting error"))
634          (t (bug "Error reporting error")))))
635
636
637
638
639(defvar %last-continue% nil)
640(defun break-loop (condition &optional (frame-pointer *top-error-frame*))
641  "Never returns"
642  (let* ((%handlers% (last %handlers%)) ; firewall
643         (*break-frame* frame-pointer)
644         (*break-condition* condition)
645         (*compiling-file* nil)
646         (*backquote-stack* nil)
647         (continue (find-restart 'continue))
648         (*continuablep* (unless (eq %last-continue% continue) continue))
649         (%last-continue% continue)
650         (*standard-input* *debug-io*)
651         (*standard-output* *debug-io*)
652         (*signal-printing-errors* nil)
653         (*read-suppress* nil)
654         (*print-readably* nil)
655         (*default-integer-command* `(:c 0 ,(1- (length (compute-restarts condition)))))
656         (context (new-backtrace-info nil
657                                      frame-pointer
658                                      (if *backtrace-contexts*
659                                        (or (child-frame
660                                             (bt.youngest (car *backtrace-contexts*))
661                                             nil)
662                                            (last-frame-ptr))
663                                        (last-frame-ptr))
664                                      (%current-tcr)
665                                      condition
666                                      (%current-frame-ptr)
667                                      #+ppc-target *fake-stack-frames*
668                                      #+x86-target (%current-frame-ptr)
669                                      (db-link)
670                                      (1+ *break-level*)))
671         (*backtrace-contexts* (cons context *backtrace-contexts*)))
672    (with-terminal-input
673      (with-toplevel-commands :break
674        (if *continuablep*
675          (let* ((*print-circle* *error-print-circle*)
676                 (*print-level* *error-print-level*)
677                 (*print-length* *error-print-length*)
678                                        ;(*print-pretty* nil)
679                 (*print-array* nil))
680            (format t (or (application-ui-operation *application* :break-options-string t)
681                          "~&> Type :GO to continue, :POP to abort, :R for a list of available restarts."))
682            (format t "~&> If continued: ~A~%" continue))
683          (format t (or (application-ui-operation *application* :break-options-string nil)
684                        "~&> Type :POP to abort, :R for a list of available restarts.~%")))
685        (format t "~&> Type :? for other options.")
686        (terpri)
687        (force-output)
688
689        (clear-input *debug-io*)
690        (setq *error-reentry-count* 0)  ; succesfully reported error
691        (ignoring-without-interrupts
692          (unwind-protect
693               (progn
694                 (application-ui-operation *application*
695                                           :enter-backtrace-context context)
696                 (read-loop :break-level (1+ *break-level*)
697                            :input-stream *debug-io*
698                            :output-stream *debug-io*))
699            (application-ui-operation *application* :exit-backtrace-context
700                                      context)))))))
701
702
703
704(defun display-restarts (&optional (condition *break-condition*))
705  (loop
706    for restart in (compute-restarts condition)
707    for count upfrom 0
708    do (format *debug-io* "~&~D. ~A" count restart)
709    finally (fresh-line *debug-io*)))
710
711(defun select-restart (n &optional (condition *break-condition*))
712  (let* ((restarts (compute-restarts condition)))
713    (invoke-restart-interactively
714     (nth (require-type n `(integer 0 (,(length restarts)))) restarts))))
715
716
717
718
719; End of l1-readloop-lds.lisp
Note: See TracBrowser for help on using the repository browser.