source: trunk/source/level-1/l1-readloop-lds.lisp @ 11124

Last change on this file since 11124 was 11124, checked in by gz, 11 years ago

Indentation tweaks

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 27.5 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17; l1-readloop-lds.lisp
18
19(in-package "CCL")
20
21
22
23(defun toplevel-loop ()
24  (loop
25    (if (eq (catch :toplevel 
26              (read-loop :break-level 0 )) $xstkover)
27      (format t "~&;[Stacks reset due to overflow.]")
28      (when (eq *current-process* *initial-process*)
29        (toplevel)))))
30
31
32(defvar *defined-toplevel-commands* ())
33(defvar *active-toplevel-commands* ())
34
35(defun %define-toplevel-command (group-name key name fn doc args)
36  (let* ((group (or (assoc group-name *defined-toplevel-commands*)
37                    (car (push (list group-name)
38                               *defined-toplevel-commands*))))
39         (pair (assoc key (cdr group) :test #'eq)))
40    (if pair
41      (rplacd pair (list* fn doc args))
42      (push (cons key (list* fn doc args)) (cdr group))))
43  name)
44
45(define-toplevel-command 
46    :global y (&optional p) "Yield control of terminal-input to process
47whose name or ID matches <p>, or to any process if <p> is null"
48    (%%yield-terminal-to (if p (find-process p))))      ;may be nil
49
50
51(define-toplevel-command
52    :global kill (p) "Kill process whose name or ID matches <p>"
53    (let* ((proc (find-process p)))
54      (if proc
55        (process-kill proc))))
56
57(define-toplevel-command 
58    :global proc (&optional p) "Show information about specified process <p>/all processes"
59    (flet ((show-process-info (proc)
60             (format t "~&~d : ~a ~a ~20t[~a] "
61                     (process-serial-number proc)
62                     (if (eq proc *current-process*)
63                       "->"
64                       "  ")
65                     (process-name proc)
66                     (process-whostate proc))
67             (let* ((suspend-count (process-suspend-count proc)))
68               (if (and suspend-count (not (eql 0 suspend-count)))
69                 (format t " (Suspended)")))
70             (let* ((terminal-input-shared-resource
71                     (if (typep *terminal-io* 'two-way-stream)
72                       (input-stream-shared-resource
73                        (two-way-stream-input-stream *terminal-io*)))))
74               (if (and terminal-input-shared-resource
75                        (%shared-resource-requestor-p
76                         terminal-input-shared-resource proc))
77                 (format t " (Requesting terminal input)")))
78             (fresh-line)))
79      (if p
80        (let* ((proc (find-process p)))
81          (if (null proc)
82            (format t "~&;; not found - ~s" p)
83            (show-process-info proc)))
84        (dolist (proc (all-processes) (values))
85          (show-process-info proc)))))
86
87(define-toplevel-command :global cd (dir) "Change to directory DIR" (setf (current-directory) dir) (toplevel-print (list (current-directory))))
88
89(define-toplevel-command :global pwd () "Print the pathame of the current directory" (toplevel-print (list (current-directory))))
90
91
92
93(defun list-restarts ()
94  (format *debug-io* "~&>   Type (:C <n>) to invoke one of the following restarts:")
95  (display-restarts))
96
97(define-toplevel-command :break pop () "exit current break loop" (abort-break))
98(define-toplevel-command :break a () "exit current break loop" (abort-break))
99(define-toplevel-command :break go () "continue" (continue))
100(define-toplevel-command :break q () "return to toplevel" (toplevel))
101(define-toplevel-command :break r () "list restarts" (list-restarts))
102
103(define-toplevel-command :break set (n frame value) "Set <n>th item of frame <frame> to <value>"
104  (let* ((frame-sp (nth-raw-frame frame *break-frame* nil)))
105    (if frame-sp
106        (toplevel-print (list (set-nth-value-in-frame frame-sp n nil value)))
107        (format *debug-io* "No frame with number ~D~%" frame))))
108
109(define-toplevel-command :break nframes ()
110  "print the number of stack frames accessible from this break loop"
111  (do* ((p *break-frame* (parent-frame p nil))
112        (i 0 (1+ i))
113        (last (last-frame-ptr)))
114      ((eql p last) (toplevel-print (list i)))))
115
116(define-toplevel-command :global ? () "help"
117  (format t "~&The following toplevel commands are available:")
118  (when *default-integer-command*
119    (format t "~& <n>  ~8Tthe same as (~s <n>)" (car *default-integer-command*)))
120  (dolist (g *active-toplevel-commands*)
121    (dolist (c (cdr g))
122      (let* ((command (car c))
123             (doc (caddr c))
124             (args (cdddr c)))
125        (if args
126          (format t "~& (~S~{ ~A~}) ~8T~A" command args doc)
127          (format t "~& ~S  ~8T~A" command doc)))))
128  (format t "~&Any other form is evaluated and its results are printed out."))
129
130
131(define-toplevel-command :break b (&key start count show-frame-contents) "backtrace"
132  (when *break-frame*
133      (print-call-history :detailed-p show-frame-contents
134                          :origin *break-frame*
135                          :count count
136                          :start-frame-number (or start 0))))
137
138(define-toplevel-command :break c (&optional n) "Choose restart <n>. If no <n>, continue"
139  (if n
140   (select-restart n)
141   (continue)))
142
143(define-toplevel-command :break f (n) "Show backtrace frame <n>"
144   (print-call-history :origin *break-frame*
145                       :start-frame-number n
146                       :count 1
147                       :detailed-p t))
148
149(define-toplevel-command :break return-from-frame (i &rest values) "Return VALUES from the I'th stack frame"
150  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
151    (if frame-sp
152      (apply #'return-from-frame frame-sp values))))
153
154(define-toplevel-command :break apply-in-frame (i function &rest args) "Applies FUNCTION to ARGS in the execution context of the Ith stack frame"
155  (let* ((frame-sp (nth-raw-frame  i *break-frame* nil)))
156    (if frame-sp
157      (apply-in-frame frame-sp function args))))
158                         
159                         
160
161(define-toplevel-command :break raw (n) "Show raw contents of backtrace frame <n>"
162   (print-call-history :origin *break-frame*
163                       :start-frame-number n
164                       :count 1
165                       :detailed-p :raw))
166
167(define-toplevel-command :break v (n frame-number) "Return value <n> in frame <frame-number>"
168  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
169    (if frame-sp
170      (toplevel-print (list (nth-value-in-frame frame-sp n nil))))))
171
172(define-toplevel-command :break arg (name frame-number) "Return value of argument named <name> in frame <frame-number>"
173  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
174    (when frame-sp
175      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
176        (when (and lfun pc)
177          (let* ((unavailable (cons nil nil)))
178            (declare (dynamic-extent unavailable))
179            (let* ((value (arg-value nil frame-sp lfun pc unavailable name)))
180              (if (eq value unavailable)
181                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
182                (toplevel-print (list value))))))))))
183
184(define-toplevel-command :break set-arg (name frame-number new) "Set value of argument named <name> in frame <frame-number> to value <new>."
185  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
186    (when frame-sp
187      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
188        (when (and lfun pc)
189          (or (set-arg-value nil frame-sp lfun pc name new)
190              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
191   
192
193(define-toplevel-command :break local (name frame-number) "Return value of local denoted by <name> in frame <frame-number> <name> can either be a symbol - in which case the most recent
194binding of that symbol is used - or an integer index into the frame's set of local bindings."
195  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
196    (when frame-sp
197      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
198        (when (and lfun pc)
199          (let* ((unavailable (cons nil nil)))
200            (declare (dynamic-extent unavailable))
201            (let* ((value (local-value nil frame-sp lfun pc unavailable name)))
202              (if (eq value unavailable)
203                (format *debug-io* "~&;; Can't determine value of ~s in frame ~s." name frame-number)
204                (toplevel-print (list value))))))))))
205
206(define-toplevel-command :break set-local (name frame-number new) "Set value of argument denoted <name> (see :LOCAL) in frame <frame-number> to value <new>."
207  (let* ((frame-sp (nth-raw-frame frame-number *break-frame* nil)))
208    (when frame-sp
209      (multiple-value-bind (lfun pc) (cfp-lfun frame-sp)
210        (when (and lfun pc)
211          (or (set-local-value nil frame-sp lfun pc name new)
212              (format *debug-io* "~&;; Can't change value of ~s in frame ~s." name frame-number)))))))
213
214
215(define-toplevel-command :break form (frame-number)
216   "Return a form which looks like the call which established the stack frame identified by <frame-number>.  This is only well-defined in certain cases: when the function is globally named and not a lexical closure and when it was compiled with *SAVE-LOCAL-SYMBOLS* in effect."
217   (let* ((form (dbg-form frame-number)))
218     (when form
219       (let* ((*print-level* *backtrace-print-level*)
220              (*print-length* *backtrace-print-length*))
221         (toplevel-print (list form))))))
222
223;;; Ordinarily, form follows function.
224(define-toplevel-command :break function (frame-number)
225  "Returns the function invoked in backtrace frame <frame-number>.  This may be useful for, e.g., disassembly"
226  (let* ((cfp (nth-raw-frame frame-number *break-frame* nil)))
227    (when (and cfp (not (catch-csp-p cfp nil)))
228      (let* ((function (cfp-lfun cfp)))
229        (when function
230          (toplevel-print (list function)))))))
231 
232
233
234         
235
236 
237
238(defun %use-toplevel-commands (group-name)
239  ;; Push the whole group
240  (pushnew (assoc group-name *defined-toplevel-commands*)
241           *active-toplevel-commands*
242           :key #'(lambda (x) (car x))))  ; #'car not defined yet ...
243
244(%use-toplevel-commands :global)
245
246(defparameter *toplevel-commands-dwim* t "If true, tries to interpret otherwise-erroneous toplevel
247expressions as commands")
248
249(defvar *default-integer-command* nil
250  "If non-nil, should be (keyword  min max)), causing integers between min and max to be
251  interpreted as (keyword integer)")
252
253(defun check-toplevel-command (form)
254  (when (and *default-integer-command*
255             (integerp form)
256             (<= (cadr *default-integer-command*) form (caddr *default-integer-command*)))
257    (setq form `(,(car *default-integer-command*) ,form)))
258  (let* ((cmd (if (consp form) (car form) form))
259         (args (if (consp form) (cdr form))))
260    (when (or (keywordp cmd)
261              (and *toplevel-commands-dwim*
262                   (non-nil-symbol-p cmd)
263                   (not (if (consp form) (fboundp cmd) (boundp cmd)))
264                   ;; Use find-symbol so don't make unneeded keywords.
265                   (setq cmd (find-symbol (symbol-name cmd) :keyword))))
266      (when (eq cmd :help) (setq cmd :?))
267      (dolist (g *active-toplevel-commands*)
268        (let* ((pair (assoc cmd (cdr g))))
269          (when pair 
270            (apply (cadr pair) args)
271            (return t)))))))
272
273(defparameter *quit-on-eof* nil)
274
275(defmethod stream-eof-transient-p (stream)
276  (let ((fd (stream-device stream :input)))
277    (and fd (eof-transient-p fd))))
278
279;;; This is the part common to toplevel loop and inner break loops.
280(defun read-loop (&key (input-stream *standard-input*)
281                       (output-stream *standard-output*)
282                       (break-level *break-level*)
283                       (prompt-function #'(lambda (stream)
284                                            (when (and *show-available-restarts* *break-condition*)
285                                              (list-restarts)
286                                              (setf *show-available-restarts* nil))
287                                            (print-listener-prompt stream t))))
288  (let* ((*break-level* break-level)
289         (*last-break-level* break-level)
290         *loading-file-source-file*
291         *in-read-loop*
292         *** ** * +++ ++ + /// // / -
293         (eof-value (cons nil nil))
294         (*show-available-restarts* (and *show-restarts-on-break* *break-condition*)))
295    (declare (dynamic-extent eof-value))
296    (loop
297      (restart-case
298       (catch :abort                    ;last resort...
299         (loop
300           (catch-cancel
301            (loop               
302              (setq *in-read-loop* nil
303                    *break-level* break-level)
304              (multiple-value-bind (form env print-result)
305                  (toplevel-read :input-stream input-stream
306                                 :output-stream output-stream
307                                 :prompt-function prompt-function
308                                 :eof-value eof-value)
309                (if (eq form eof-value)
310                  (if (and (not *batch-flag*)
311                           (not *quit-on-eof*)
312                           (stream-eof-transient-p input-stream))
313                    (progn
314                      (stream-clear-input input-stream)
315                      (abort-break))
316                    (exit-interactive-process *current-process*))
317                    (or (check-toplevel-command form)
318                        (let* ((values (toplevel-eval form env)))
319                          (if print-result (toplevel-print values))))))))
320           (format *terminal-io* "~&Cancelled")))
321       (abort () :report (lambda (stream)
322                           (if (eq break-level 0)
323                             (format stream "Return to toplevel.")
324                             (format stream "Return to break level ~D." break-level)))
325              #|                        ; Handled by interactive-abort
326                                        ; go up one more if abort occurred while awaiting/reading input               
327              (when (and *in-read-loop* (neq break-level 0))
328              (abort))
329              |#
330               )
331        (abort-break () 
332                     (unless (eq break-level 0)
333                       (abort))))
334       (clear-input input-stream)
335      (format output-stream "~%"))))
336
337;;; The first non-whitespace character available on INPUT-STREAM is a colon.
338;;; Try to interpret the line as a colon command (or possibly just a keyword.)
339(defun read-command-or-keyword (input-stream eof-value)
340  (let* ((line (read-line input-stream nil eof-value)))
341    (if (eq line eof-value)
342      eof-value
343      (let* ((in (make-string-input-stream line))
344             (keyword (read in nil eof-value)))
345        (if (eq keyword eof-value)
346          eof-value
347          (if (not (keywordp keyword))
348            keyword
349            (collect ((params))
350              (loop
351                (let* ((param (read in nil eof-value)))
352                  (if (eq param eof-value)
353                    (return
354                      (let* ((params (params)))
355                        (if params
356                          (cons keyword params)
357                          keyword)))
358                    (params (eval param))))))))))))
359
360;;; Read a form from the specified stream.
361(defun toplevel-read (&key (input-stream *standard-input*)
362                           (output-stream *standard-output*)
363                           (prompt-function #'print-listener-prompt)
364                           (eof-value *eof-value*))
365  (force-output output-stream)
366  (funcall prompt-function output-stream)
367  (read-toplevel-form input-stream eof-value))
368
369(defvar *always-eval-user-defvars* nil)
370
371(defun process-single-selection (form)
372  (if (and *always-eval-user-defvars*
373           (listp form) (eq (car form) 'defvar) (cddr form))
374    `(defparameter ,@(cdr form))
375    form))
376
377(defun toplevel-eval (form &optional env)
378  (destructuring-bind (vars . vals) (or env '(nil . nil))
379    (progv vars vals
380      (setq +++ ++ ++ + + - - form)
381      (unwind-protect
382           (let* ((package *package*)
383                  (values (multiple-value-list (cheap-eval-in-environment form nil))))
384             (unless (eq package *package*)
385               ;; If changing a local value (e.g. buffer-local), not useful to notify app
386               ;; without more info.  Perhaps should have a *source-context* that can send along?
387               (unless (member '*package* vars)
388                 (application-ui-operation *application* :note-current-package *package*)))
389             values)
390        (loop for var in vars as pval on vals
391              do (setf (car pval) (symbol-value var)))))))
392
393
394(defun toplevel-print (values &optional (out *standard-output*))
395  (setq /// // // / / values)
396  (unless (eq (car values) (%unbound-marker))
397    (setq *** ** ** * *  (%car values)))
398  (when values
399    (fresh-line out)
400    (dolist (val values) (write val :stream out) (terpri out))))
401
402(defparameter *listener-prompt-format* "~[?~:;~:*~d >~] ")
403
404 
405(defun print-listener-prompt (stream &optional (force t))
406  (unless *quiet-flag*
407    (when (or force (neq *break-level* *last-break-level*))
408      (let* ((*listener-indent* nil))
409        (fresh-line stream)
410        (format stream *listener-prompt-format* *break-level*))
411      (setq *last-break-level* *break-level*)))
412    (force-output stream))
413
414
415;;; Fairly crude default error-handlingbehavior, and a fairly crude mechanism
416;;; for customizing it.
417
418(defvar *app-error-handler-mode* :quit
419  "one of :quit, :quit-quietly, :listener might be useful.")
420
421(defmethod application-error ((a application) condition error-pointer)
422  (case *app-error-handler-mode*
423    (:listener   (break-loop-handle-error condition error-pointer))
424    (:quit-quietly (quit -1))
425    (:quit  (format t "~&Fatal error in ~s : ~a"
426                    (pathname-name (car *command-line-argument-list*))
427                    condition)
428                    (quit -1))))
429
430(defun make-application-error-handler (app mode)
431  (declare (ignore app))
432  (setq *app-error-handler-mode* mode))
433
434
435; You may want to do this anyway even if your application
436; does not otherwise wish to be a "lisp-development-system"
437(defmethod application-error ((a lisp-development-system) condition error-pointer)
438  (break-loop-handle-error condition error-pointer))
439
440(defun abnormal-application-exit ()
441  (ignore-errors
442    (print-call-history)
443    (force-output *debug-io*)
444    (quit -1))
445  (#__exit -1))
446
447(defun break-loop-handle-error (condition error-pointer)
448  (multiple-value-bind (bogus-globals newvals oldvals) (%check-error-globals)
449    (dolist (x bogus-globals)
450      (set x (funcall (pop newvals))))
451    (when (and *debugger-hook* *break-on-errors* (not *batch-flag*))
452      (let ((hook *debugger-hook*)
453            (*debugger-hook* nil))
454        (funcall hook condition hook)))
455    (%break-message "Error" condition error-pointer)
456    (let* ((s *error-output*))
457      (dolist (bogusness bogus-globals)
458        (let ((oldval (pop oldvals)))
459          (format s "~&;  NOTE: ~S was " bogusness)
460          (if (eq oldval (%unbound-marker-8))
461            (format s "unbound")
462            (format s "~s" oldval))
463          (format s ", was reset to ~s ." (symbol-value bogusness)))))
464    (if (and *break-on-errors* (not *batch-flag*))
465      (with-terminal-input
466          (break-loop condition error-pointer))
467      (if *batch-flag*
468        (abnormal-application-exit)
469        (abort)))))
470
471(defun break (&optional string &rest args)
472  "Print a message and invoke the debugger without allowing any possibility
473   of condition handling occurring."
474  (if *batch-flag*
475    (apply #'error string args)
476    (apply #'%break-in-frame (%get-frame-ptr) string args)))
477
478(defun %break-in-frame (fp &optional string &rest args)
479  (flet ((do-break-loop ()
480           (let ((c (if (typep string 'condition)
481                      string
482                      (make-condition 'simple-condition
483                                    :format-control (or string "")
484                                    :format-arguments args))))
485             (cbreak-loop "Break" "Return from BREAK." c fp))))
486    (cond ((%i> *interrupt-level* -1)
487           (do-break-loop))
488          (*break-loop-when-uninterruptable*
489           (format *error-output* "Break while interrupt-level less than zero; binding to 0 during break-loop.")
490           (let ((interrupt-level (interrupt-level)))
491             (unwind-protect
492                  (progn
493                    (setf (interrupt-level) 0)
494                    (do-break-loop))
495               (setf (interrupt-level) interrupt-level))))
496          (t (format *error-output* "Break while interrupt-level less than zero; ignored.")))))
497
498
499(defun invoke-debugger (condition &aux (fp (%get-frame-ptr)))
500  "Enter the debugger."
501  (let ((c (require-type condition 'condition)))
502    (when *debugger-hook*
503      (let ((hook *debugger-hook*)
504            (*debugger-hook* nil))
505        (funcall hook c hook)))
506    (%break-message "Debug" c fp)
507    (with-terminal-input
508        (break-loop c fp))))
509
510(defun %break-message (msg condition error-pointer &optional (prefixchar #\>))
511  (let ((*print-circle* *error-print-circle*)
512        ;(*print-prett*y nil)
513        (*print-array* nil)
514        (*print-escape* t)
515        (*print-gensym* t)
516        (*print-length* *error-print-length*)
517        (*print-level* *error-print-level*)
518        (*print-lines* nil)
519        (*print-miser-width* nil)
520        (*print-readably* nil)
521        (*print-right-margin* nil)
522        (*signal-printing-errors* nil)
523        (s (make-indenting-string-output-stream prefixchar nil)))
524    (format s "~A ~A: " prefixchar msg)
525    (setf (indenting-string-output-stream-indent s) (column s))
526    ;(format s "~A" condition) ; evil if circle
527    (report-condition condition s)
528    (if (not (and (typep condition 'simple-program-error)
529                  (simple-program-error-context condition)))
530      (format *error-output* "~&~A~%~A While executing: ~S"
531              (get-output-stream-string s) prefixchar (%real-err-fn-name error-pointer))
532      (format *error-output* "~&~A"
533              (get-output-stream-string s)))
534    (format *error-output* ", in process ~a(~d).~%" (process-name *current-process*) (process-serial-number *current-process*))
535  (force-output *error-output*)))
536                                        ; returns NIL
537
538(defun cbreak-loop (msg cont-string condition error-pointer)
539  (let* ((*print-readably* nil))
540    (%break-message msg condition error-pointer)
541    (with-terminal-input
542      (restart-case (break-loop condition error-pointer)
543                    (continue () :report (lambda (stream) (write-string cont-string stream))))
544      (fresh-line *error-output*)
545      nil)))
546
547(defun warn (condition-or-format-string &rest args)
548  "Warn about a situation by signalling a condition formed by DATUM and
549   ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
550   exists that causes WARN to immediately return NIL."
551  (when (typep condition-or-format-string 'condition)
552    (unless (typep condition-or-format-string 'warning)
553      (report-bad-arg condition-or-format-string 'warning))
554    (when args
555      (error 'type-error :datum args :expected-type 'null
556             :format-control "Extra arguments in ~s.")))
557  (let ((fp (%get-frame-ptr))
558        (c (require-type (condition-arg condition-or-format-string args 'simple-warning) 'warning)))
559    (when *break-on-warnings*
560      (cbreak-loop "Warning" "Signal the warning." c fp))
561    (restart-case (signal c)
562      (muffle-warning () :report "Skip the warning" (return-from warn nil)))
563    (%break-message (if (typep c 'compiler-warning) "Compiler warning" "Warning") c fp #\;)
564    ))
565
566(declaim (notinline select-backtrace))
567
568(defmacro new-backtrace-info (dialog youngest oldest tcr condition current fake db-link level)
569  (let* ((cond (gensym)))
570  `(let* ((,cond ,condition))
571    (vector ,dialog ,youngest ,oldest ,tcr (cons nil (compute-restarts ,cond)) (%catch-top ,tcr) ,cond ,current ,fake ,db-link ,level))))
572
573(defun select-backtrace ()
574  (declare (notinline select-backtrace))
575  ;(require 'new-backtrace)
576  (require :inspector)
577  (select-backtrace))
578
579(defvar *break-condition* nil "condition argument to innermost break-loop.")
580(defvar *break-frame* nil "frame-pointer arg to break-loop")
581(defvar *break-loop-when-uninterruptable* t)
582(defvar *show-restarts-on-break* #+ccl-0711 t #-ccl-0711 nil)
583(defvar *show-available-restarts* nil)
584
585(defvar *error-reentry-count* 0)
586
587(defun funcall-with-error-reentry-detection (thunk)
588  (let* ((count *error-reentry-count*)
589         (*error-reentry-count* (1+ count)))
590    (cond ((eql count 0) (funcall thunk))
591          ((eql count 1) (error "Error reporting error"))
592          (t (bug "Error reporting error")))))
593
594
595
596
597(defvar %last-continue% nil)
598(defun break-loop (condition frame-pointer)
599  "Never returns"
600  (let* ((%handlers% (last %handlers%)) ; firewall
601         (*break-frame* frame-pointer)
602         (*break-condition* condition)
603         (*compiling-file* nil)
604         (*backquote-stack* nil)
605         (continue (find-restart 'continue))
606         (*continuablep* (unless (eq %last-continue% continue) continue))
607         (%last-continue% continue)
608         (*standard-input* *debug-io*)
609         (*standard-output* *debug-io*)
610         (*signal-printing-errors* nil)
611         (*read-suppress* nil)
612         (*print-readably* nil))
613    (let* ((context (new-backtrace-info nil
614                                        frame-pointer
615                                        (if *backtrace-contexts*
616                                          (or (child-frame
617                                               (bt.youngest (car *backtrace-contexts*))
618                                               nil)
619                                              (last-frame-ptr))
620                                          (last-frame-ptr))
621                                        (%current-tcr)
622                                        condition
623                                        (%current-frame-ptr)
624                                        #+ppc-target *fake-stack-frames*
625                                        #+x86-target (%current-frame-ptr)
626                                        (db-link)
627                                        (1+ *break-level*)))
628           (*backtrace-contexts* (cons context *backtrace-contexts*)))
629      (with-toplevel-commands :break
630        (if *continuablep*
631          (let* ((*print-circle* *error-print-circle*)
632                 (*print-level* *error-print-level*)
633                 (*print-length* *error-print-length*)
634                                        ;(*print-pretty* nil)
635                 (*print-array* nil))
636            (format t "~&> Type :GO to continue, :POP to abort, :R for a list of available restarts.")
637            (format t "~&> If continued: ~A~%" continue))
638          (format t "~&> Type :POP to abort, :R for a list of available restarts.~%"))
639        (format t "~&> Type :? for other options.")
640        (terpri)
641        (force-output)
642
643        (clear-input *debug-io*)
644        (setq *error-reentry-count* 0)  ; succesfully reported error
645        (ignoring-without-interrupts
646         (unwind-protect
647              (progn
648                (application-ui-operation *application*
649                                          :enter-backtrace-context context)
650                (read-loop :break-level (1+ *break-level*)
651                           :input-stream *debug-io*
652                           :output-stream *debug-io*))
653           (application-ui-operation *application* :exit-backtrace-context
654                                     context)))))))
655
656
657
658(defun display-restarts (&optional (condition *break-condition*))
659  (loop
660    for restart in (compute-restarts condition)
661    for count upfrom 0
662    do (format *debug-io* "~&~D. ~A" count restart)
663    finally (fresh-line *debug-io*)))
664
665(defun select-restart (n &optional (condition *break-condition*))
666  (let* ((restarts (compute-restarts condition)))
667    (invoke-restart-interactively
668     (nth (require-type n `(integer 0 (,(length restarts)))) restarts))))
669
670
671
672
673; End of l1-readloop-lds.lisp
Note: See TracBrowser for help on using the repository browser.