source: trunk/source/level-1/l1-processes.lisp @ 15270

Last change on this file since 15270 was 15155, checked in by gb, 8 years ago

Keep process-whostate in a (CONS) cell in a slot in the PROCESS
object, not in a thread-local binding (so that we don't have to
suspend a process to print it.)

WITH-PROCESS-WHOSTATE needs to access this slot once and RPLACA it a
couple of times and needs to use UNWIND-PROTECT.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 26.0 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18
19;; L1-processes.lisp
20
21(cl:in-package "CCL")
22
23
24(let* ((all-processes ())
25       (shutdown-processes ())
26       (all-processes-lock (make-lock)))
27  (defun add-to-all-processes (p)
28    (with-lock-grabbed (all-processes-lock)
29      (pushnew p all-processes :test #'eq)
30      p))
31  (defun remove-from-all-processes (p)
32    (with-lock-grabbed (all-processes-lock)
33      (setq all-processes (delete p all-processes))
34      t))
35  (defun all-processes ()
36    "Obtain a fresh list of all known Lisp threads."
37    (with-lock-grabbed (all-processes-lock)
38      (copy-list all-processes)))
39  (defun shutdown-processes ()
40    (with-lock-grabbed (all-processes-lock)
41      (copy-list shutdown-processes)))
42  (defun %clear-shutdown-proceses ()
43    (setq shutdown-processes nil))
44  (defun add-to-shutdown-processes (p)
45    (with-lock-grabbed (all-processes-lock)
46      (pushnew p shutdown-processes :test #'eq))
47    t)
48  (defun pop-shutdown-processes ()
49    (with-lock-grabbed (all-processes-lock)
50      (pop shutdown-processes)))
51  (defun find-process (id)
52    (etypecase id
53      (process id)
54      (integer (with-lock-grabbed (all-processes-lock)
55                 (find id all-processes
56                       :key #'(lambda (p)
57                                (process-serial-number p)))))
58      (string (with-lock-grabbed (all-processes-lock)
59                (find id all-processes
60                      :key #'(lambda (p)
61                               (process-name p))
62                      :test #'equal))))))
63
64
65
66(defun not-in-current-process (p operation)
67  (if (eq p *current-process*)
68    (error "The current process (~s) can't perform the ~a operation on itself."
69           p operation)))
70
71(defun startup-shutdown-processes ()
72  (let* ((p))
73    (loop
74      (unless (setq p (pop-shutdown-processes)) (return))
75      (new-tcr-for-thread (process-thread p))
76      (%process-preset-internal p)
77      (process-enable p)
78      )))
79
80;;; Done with a queue-fixup so that it will be the last thing
81;;; that happens on startup.
82(queue-fixup
83 (pushnew 'startup-shutdown-processes *lisp-system-pointer-functions*))
84
85
86
87
88
89
90
91(defun wrap-initial-bindings (alist)
92  (mapcar #'(lambda (pair)
93              (destructuring-bind (symbol . valform) pair
94                (cons (require-type symbol 'symbol)
95                      (cond ((symbolp valform)
96                             (constantly (symbol-value valform)))
97                            ((typep valform 'function) valform)
98                            ((consp valform)
99                             (if (eq (car valform) 'quote)
100                               (constantly (cadr valform))
101                               #'(lambda () (apply (car valform) (cdr valform)))))
102                            (t
103                             (constantly valform))))))
104          alist))
105
106
107(defun valid-allocation-quantum-p (x)
108  (and (>= x *host-page-size*)
109       (<= x (default-allocation-quantum))
110       (= (logcount x) 1)))
111
112 
113(let* ((psn -1))
114  (defun %new-psn () (incf psn)))
115
116(defclass process ()
117    ((name :initform nil :initarg :name :accessor process-name)
118     (thread :initarg :thread :initform nil :accessor process-thread)
119     (initial-form :initform (cons nil nil) :reader process-initial-form)
120     (priority :initform 0 :initarg :priority :accessor process-priority)
121     (persistent :initform nil :initarg :persistent :reader process-persistent)
122     (splice :initform (cons nil nil) :accessor process-splice)
123     (initial-bindings :initform nil :initarg :initial-bindings
124                       :accessor process-initial-bindings)
125     (serial-number :initform (%new-psn) :accessor process-serial-number)
126     (creation-time :initform (get-tick-count) :reader process-creation-time)
127     (total-run-time :initform nil :accessor %process-total-run-time)
128     (ui-object :initform (application-ui-object *application*)
129                :accessor process-ui-object)
130     (termination-semaphore :initform nil
131                            :initarg :termination-semaphore
132                            :accessor process-termination-semaphore
133                            :type (or null semaphore))
134     (allocation-quantum :initform (default-allocation-quantum)
135                         :initarg :allocation-quantum
136                         :reader process-allocation-quantum
137                         :type (satisfies valid-allocation-quantum-p))
138     (plist :initform nil :accessor process-plist)
139     (dribble-stream :initform nil)
140     (dribble-saved-terminal-io :initform nil)
141     (result :initform (cons nil nil)
142             :reader process-result)
143     (whostate-cell :initform (list "Reset")
144                    :reader process-whostate-cell))
145  (:primary-p t))
146
147(defparameter *print-process-whostate* t "make it optional")
148
149(defmethod print-object ((p process) s)
150  (print-unreadable-object (p s :type t :identity t)
151    (format s "~a(~d)" (process-name p)
152            (process-serial-number p))
153    (when *print-process-whostate*
154      (format s " [~a]" (process-whostate p)))))
155
156(defvar *process-class* (find-class 'process))
157
158(defun processp (p)
159  (memq *process-class* (class-precedence-list (class-of p))))
160
161(set-type-predicate 'process 'processp)
162
163(defun make-process (name &key 
164                          thread
165                          persistent
166                          (priority 0)
167                          (stack-size *default-control-stack-size*)
168                          (vstack-size *default-value-stack-size*)
169                          (tstack-size *default-temp-stack-size*)
170                          (initial-bindings ())
171                          (use-standard-initial-bindings t)
172                          (class (find-class 'process))
173                          (initargs nil)
174                          (termination-semaphore ())
175                          (allocation-quantum (default-allocation-quantum)))
176  "Create and return a new process."
177  (let* ((p (apply #'make-instance
178             class
179             :name name
180             :priority priority
181             :persistent persistent
182             :initial-bindings (append (if use-standard-initial-bindings
183                                         (standard-initial-bindings))
184                                       (wrap-initial-bindings
185                                        initial-bindings))
186             :termination-semaphore (or termination-semaphore
187                                        (make-semaphore))
188             :allocation-quantum allocation-quantum
189             initargs)))
190    (with-slots ((lisp-thread thread)) p
191      (unless lisp-thread
192        (setq lisp-thread
193              (or thread
194                  (new-thread name stack-size  vstack-size  tstack-size)))))
195    (add-to-all-processes p)
196    (setf (car (process-splice p)) p)
197    p))
198
199
200(defstatic *initial-process*
201    (let* ((p (make-process
202               "Initial"
203               :thread *initial-lisp-thread*
204               :priority 0)))
205      p))
206
207
208(defvar *current-process* *initial-process*
209  "Bound in each process, to that process itself.")
210
211(defstatic *interactive-abort-process* *initial-process*)
212
213
214
215
216(defun process-tcr (p)
217  (lisp-thread.tcr (process-thread p)))
218
219
220
221(defun process-exhausted-p (p)
222  (let* ((thread (process-thread p)))
223    (or (null thread)
224        (thread-exhausted-p thread))))
225 
226;;; This should be way more concerned about being correct and thread-safe
227;;; than about being quick: it's generally only called while printing
228;;; or debugging, and there are all kinds of subtle race conditions
229;;; here.
230(defun process-whostate (p)
231  "Return a string which describes the status of a specified process."
232  (car (process-whostate-cell p)))
233
234(defun (setf process-whostate) (new p)
235  (setf (car (process-whostate-cell p)) new))
236
237
238
239(defun process-total-run-time (p)
240  (or (%process-total-run-time p)
241      (thread-total-run-time (process-thread p))))
242
243
244
245
246(defun initial-bindings (alist)
247  (let* ((symbols ())
248         (values ()))
249    (dolist (a alist (values (nreverse symbols) (nreverse values)))
250      (push (car a) symbols)
251      (push (funcall (cdr a)) values))))
252
253
254                           
255(defun symbol-value-in-process (sym process)
256  (if (eq process *current-process*)
257    (symbol-value sym)
258    (let* ((val
259            (without-interrupts
260             (with-lock-grabbed (*kernel-exception-lock*)
261               (with-lock-grabbed (*kernel-tcr-area-lock*)
262                 (let* ((tcr (process-tcr process)))
263                   (if tcr
264                     (symbol-value-in-tcr sym tcr)
265                     (%sym-global-value sym))))))))
266      (if (eq val (%unbound-marker))
267        ;; This might want to be a CELL-ERROR.
268        (error "~S is unbound in ~S." sym process)
269        val))))
270
271(defun (setf symbol-value-in-process) (value sym process)
272  (if (eq process *current-process*)
273    (setf (symbol-value sym) value)
274    (with-lock-grabbed (*kernel-exception-lock*)
275      (with-lock-grabbed (*kernel-tcr-area-lock*)
276        (let* ((tcr (process-tcr process)))
277          (if tcr
278            (setf (symbol-value-in-tcr sym tcr) value)
279            (%set-sym-global-value sym value)))))))
280
281
282(defmethod process-enable ((p process) &optional (wait (* 60 60 24) wait-p))
283  "Begin executing the initial function of a specified process."
284  (not-in-current-process p 'process-enable)
285  (when wait-p
286    (check-type wait (unsigned-byte 32)))
287  (unless (car (process-initial-form p))
288    (error "Process ~s has not been preset.  Use PROCESS-PRESET to preset the process." p))
289  (let* ((thread (process-thread p)))
290    (do* ((total-wait wait (+ total-wait wait)))
291         ((thread-enable thread (process-termination-semaphore p) (1- (integer-length (process-allocation-quantum p)))  wait)
292          (process-tcr-enable p (lisp-thread.tcr thread))
293          p)
294      (cerror "Keep trying."
295              "Unable to enable process ~s; have been trying for ~s seconds."
296              p total-wait))))
297
298(defmethod process-tcr-enable ((process process) tcr)
299  (when (and tcr (not (eql 0 tcr)))
300    #+(and windows-target x8632-target)
301    (let ((aux (%fixnum-ref tcr (- target::tcr.aux target::tcr-bias))))
302      (%signal-semaphore-ptr (%fixnum-ref-macptr aux target::tcr-aux.activate)))
303    #-(and windows-target x8632-target)
304    (%signal-semaphore-ptr (%fixnum-ref-macptr tcr target::tcr.activate))
305    ))
306
307
308
309(defun process-resume (p)
310  "Resume a specified process which had previously been suspended
311by process-suspend."
312  (setq p (require-type p 'process))
313  (let* ((tcr (process-tcr p)))
314    (and tcr (%resume-tcr tcr))))
315
316(defun process-suspend (p)
317  "Suspend a specified process."
318  (setq p (require-type p 'process))
319  (if (eq p *current-process*)
320    (error "Suspending the current process can't work.  ~&(If the documentation claims otherwise, it's incorrect.)")
321    (let* ((tcr (process-tcr p)))
322      (and tcr (%suspend-tcr tcr)))))
323
324(defun process-suspend-count (p)
325  "Return the number of currently-pending suspensions applicable to
326a given process."
327  (setq p (require-type p 'process))
328  (let* ((thread (process-thread p)))
329    (if thread
330      (lisp-thread-suspend-count thread))))
331
332(defun process-active-p (p)
333  (setq p (require-type p 'process))
334  (and (eql 0 (process-suspend-count p))
335       (not (process-exhausted-p p))))
336 
337;;; Used by process-run-function
338(defmethod process-preset ((p process) function &rest args)
339  "Set the initial function and arguments of a specified process."
340  (let* ((f (require-type function 'function))
341         (initial-form (process-initial-form p)))
342    (declare (type cons initial-form))
343    (not-in-current-process p 'process-preset)
344    ; Not quite right ...
345    (rplaca initial-form f)
346    (rplacd initial-form args)
347    (%process-preset-internal p)))
348
349(defmethod %process-preset-internal ((process process))
350   (let* ((initial-form (process-initial-form process))
351         (thread (process-thread process)))
352     (declare (type cons initial-form))
353     (thread-preset
354      thread
355      #'(lambda (process initial-form)
356          (let* ((*current-process* process))
357            (add-to-all-processes process)
358            (with-initial-bindings (process-initial-bindings process)
359              (with-process-whostate ("Active")
360                (run-process-initial-form process initial-form)))))
361      process
362      initial-form)
363     process))
364
365
366(defun run-process-initial-form (process initial-form)
367  (let* ((exited nil)
368         (kill (handler-case
369                   (restart-case
370                    (let ((values
371                           (multiple-value-list
372                            (apply (car initial-form)
373                                   (cdr (the list initial-form)))))
374                          (result (process-result process)))
375                      (setf (cdr result) values
376                            (car result) t)
377                      (setq exited t)
378                      nil)
379                    (abort-break () :report "Reset this thread")
380                    (abort () :report "Kill this thread" (setq exited t)))
381                 (process-reset (condition)
382                   (process-reset-kill condition)))))
383    ;; We either exited from the initial form normally, were told to
384    ;; exit prematurely, or are being reset and should enter the
385    ;; "awaiting preset" state.
386    (if (or kill exited) 
387      (unless (eq kill :toplevel)
388        (process-initial-form-exited process (or kill t)))
389      (progn
390        (thread-change-state (process-thread process) :run :reset)
391        (tcr-set-preset-state (process-tcr process))))
392    nil))
393
394;;; Separated from run-process-initial-form just so I can change it easily.
395(defun process-initial-form-exited (process kill)
396  (without-interrupts
397   (if (eq kill :shutdown)
398     (progn
399       (setf (car (process-whostate-cell process)) "Shutdown")
400       (add-to-shutdown-processes process)))
401   (let* ((semaphore (process-termination-semaphore process)))
402     (when semaphore (signal-semaphore semaphore)))
403   (maybe-finish-process-kill process kill)))
404
405(defun maybe-finish-process-kill (process kill)
406  (when (and kill (neq kill :shutdown))
407    (setf (process-whostate process) "Dead")
408    (remove-from-all-processes process)
409    (let ((thread (process-thread process)))
410      (unless (or (eq thread *current-lisp-thread*)
411                  (thread-exhausted-p thread))
412        (kill-lisp-thread thread))))
413  nil)
414
415
416 
417
418(defun require-global-symbol (s &optional env)
419  (let* ((s (require-type s 'symbol))
420         (bits (%symbol-bits s)))
421    (unless (or (logbitp $sym_vbit_global bits)
422                (let* ((defenv (if env (definition-environment env))))
423                  (if defenv
424                    (eq :global (%cdr (assq s (defenv.specials defenv)))))))
425      (error "~s not defined with ~s" s 'defstatic))
426    s))
427
428
429(defmethod print-object ((s lock) stream)
430  (print-unreadable-object (s stream :type t :identity t)
431    (let* ((val (uvref s target::lock._value-cell))
432           (name (uvref s target::lock.name-cell)))
433      (when name
434        (format stream "~s " name))
435      (if (typep val 'macptr)
436        (format stream "[ptr @ #x~x]"
437                (%ptr-to-int val))))))
438
439(defun lockp (l)
440  (eq target::subtag-lock (typecode l)))
441
442(set-type-predicate 'lock 'lockp)
443
444(defun recursive-lock-p (l)
445  (and (eq target::subtag-lock (typecode l))
446       (eq 'recursive-lock (%svref l target::lock.kind-cell))))
447
448(defun read-write-lock-p (l)
449  (and (eq target::subtag-lock (typecode l))
450       (eq 'read-write-lock (%svref l target::lock.kind-cell))))
451
452(setf (type-predicate 'recursive-lock) 'recursive-lock-p
453      (type-predicate 'read-write-lock) 'read-write-lock-p)
454
455
456(defun grab-lock (lock &optional flag)
457  "Wait until a given lock can be obtained, then obtain it."
458  (%lock-recursive-lock-object lock flag))
459
460(defun release-lock (lock)
461  "Relinquish ownership of a given lock."
462  (%unlock-recursive-lock-object lock))
463
464(defun try-lock (lock &optional flag)
465  "Obtain the given lock, but only if it is not necessary to wait for it."
466  (%try-recursive-lock-object lock flag))
467
468(defun lock-acquisition-status (thing)
469  (if (istruct-typep thing 'lock-acquisition)
470    (lock-acquisition.status thing)
471    (report-bad-arg thing 'lock-acquisition)))
472
473(defun clear-lock-acquisition-status (thing)
474  (if (istruct-typep thing 'lock-acquisition)
475    (setf (lock-acquisition.status thing) nil)
476    (report-bad-arg thing 'lock-acquisition)))
477
478(defmethod print-object ((l lock-acquisition) stream)
479  (print-unreadable-object (l stream :type t :identity t)
480    (format stream "[status = ~s]" (lock-acquisition-status l))))
481
482(defun semaphore-notification-status (thing)
483  (if (istruct-typep thing 'semaphore-notification)
484    (semaphore-notification.status thing)
485    (report-bad-arg thing 'semaphore-notification)))
486
487(defun clear-semaphore-notification-status (thing)
488  (if (istruct-typep thing 'semaphore-notification)
489    (setf (semaphore-notification.status thing) nil)
490    (report-bad-arg thing 'semaphore-notification)))
491
492(defmethod print-object ((l semaphore-notification) stream)
493  (print-unreadable-object (l stream :type t :identity t)
494    (format stream "[status = ~s]" (semaphore-notification-status l))))
495
496(defun process-wait (whostate function &rest args)
497  "Causes the current lisp process (thread) to wait for a given
498predicate to return true."
499  (declare (dynamic-extent args))
500  (or (apply function args)
501      (with-process-whostate (whostate)
502        (loop
503          (when (apply function args)
504            (return))
505          ;; Sleep for a tick
506          #-windows-target
507          (%nanosleep 0 *ns-per-tick*)
508          #+windows-target
509          (%windows-sleep 5)))))
510
511
512
513(defun process-wait-with-timeout (whostate time function &rest args)
514  "Cause the current thread to wait for a given predicate to return true,
515or for a timeout to expire."
516  (declare (dynamic-extent args))
517  (cond ((null time)  (apply #'process-wait whostate function args) t)
518        (t (let* ((win nil)
519                  (when (+ (get-tick-count) time))
520                  (f #'(lambda () (let ((val (apply function args)))
521                                    (if val
522                                      (setq win val)
523                                      (> (get-tick-count) when))))))
524             (declare (dynamic-extent f))
525             (process-wait whostate f)
526             win))))
527
528
529(defmethod process-interrupt ((process process) function &rest args)
530  "Arrange for the target process to invoke a specified function at
531some point in the near future, and then return to what it was doing."
532  (let* ((p (require-type process 'process)))
533    (if (eq p *current-process*)
534      (progn
535        (apply function args)
536        t)
537      (thread-interrupt
538       (process-thread p)
539       process
540       #'apply
541       function args))))
542
543(defmethod process-debug-condition ((p process) condition frame-pointer)
544  (declare (ignore condition frame-pointer)))
545
546
547
548
549;;; This one is in the Symbolics documentation
550(defun process-allow-schedule ()
551  "Used for cooperative multitasking; probably never necessary."
552  (process-yield *current-process*))
553
554
555;;; something unique that users won't get their hands on
556(defun process-reset-tag (process)
557  (process-splice process))
558
559(defun process-run-function (name-or-keywords function &rest args)
560  "Create a process, preset it, and enable it."
561  (if (listp name-or-keywords)
562    (%process-run-function name-or-keywords function args)
563    (let ((keywords (list :name name-or-keywords)))
564      (declare (dynamic-extent keywords))
565      (%process-run-function keywords function args))))
566
567(defun %process-run-function (keywords function args)
568  (destructuring-bind (&key (name "Anonymous")
569                            (priority  0)
570                            (stack-size *default-control-stack-size*)
571                            (vstack-size *default-value-stack-size*)
572                            (tstack-size *default-temp-stack-size*)
573                            (persistent nil)
574                            (initial-bindings ())
575                            (use-standard-initial-bindings t)
576                            (class (find-class 'process))
577                            (initargs nil)
578                            (termination-semaphore nil)
579                            (allocation-quantum (default-allocation-quantum)))
580                      keywords
581    (setq priority (require-type priority 'fixnum))
582    (let* ((process (make-process name
583                                  :priority priority
584                                  :stack-size stack-size
585                                  :vstack-size vstack-size
586                                  :tstack-size tstack-size
587                                  :persistent persistent
588                                  :use-standard-initial-bindings use-standard-initial-bindings
589                                  :initial-bindings initial-bindings
590                                  :class class
591                                  :initargs initargs
592                                  :termination-semaphore termination-semaphore
593                                  :allocation-quantum allocation-quantum)))
594      (process-preset process #'(lambda () (apply function args)))
595      (process-enable process)
596      process)))
597
598(defmethod process-reset ((process process) &optional kill)
599  "Cause a specified process to cleanly exit from any ongoing computation."
600  (setq process (require-type process 'process))
601  (unless (memq kill '(nil :kill :shutdown))
602    (setq kill (require-type kill '(member nil :kill :shutdown))))
603  (if (eq process *current-process*)
604    (%process-reset kill)
605    (if (process-exhausted-p process)
606      (maybe-finish-process-kill process kill)
607      (progn
608        (process-interrupt process '%process-reset kill)))))
609
610(defmethod process-yield ((p process))
611  #+windows-target (#_Sleep 0)
612  #-windows-target (#_sched_yield))
613
614
615(defun %process-reset (kill)
616  (signal 'process-reset :kill kill)
617  (maybe-finish-process-kill *current-process* kill))
618
619;;; By default, it's just fine with the current process
620;;; if the application/user wants to quit.
621(defmethod process-verify-quit ((process process))
622  t)
623
624(defmethod process-exit-application ((process process) thunk)
625  (when (eq process *initial-process*)
626    (with-standard-abort-handling "Exit Lisp"
627      (prepare-to-quit)
628      ;; We may have abruptly terminated a thread which owned the
629      ;; output lock on a stream we want to flush.  Don't block
630      ;; waiting on the lock if so.
631      (flet ((flush-stream (s)
632               (let* ((lock (ioblock-outbuf-lock (basic-stream-ioblock s)))
633                      (locked (make-lock-acquisition)))
634                 (declare (dynamic-extent locked))
635                 (when (or (null lock)
636                           (%try-recursive-lock-object lock locked))
637                   (unwind-protect
638                        (progn
639                          (fresh-line s)
640                          (finish-output s))
641                     (when (lock-acquisition.status locked)
642                       (release-lock lock)))))))
643        (flush-stream *stdout*)
644        (flush-stream *stderr*)))
645    (%set-toplevel thunk)
646    (toplevel)))
647
648
649
650(defmethod process-kill ((process process))
651  "Cause a specified process to cleanly exit from any ongoing
652computation, and then exit."
653  (and (process-interrupt process #'%process-reset :kill)
654       (setf (process-kill-issued process) t)))
655
656(defun process-abort (process &optional condition)
657  "Cause a specified process to process an abort condition, as if it
658had invoked abort."
659  (process-interrupt process
660                     #'(lambda ()
661                         (abort condition))))
662
663(defmethod process-reset-and-enable ((process process))
664  (not-in-current-process process 'process-reset-and-enable)
665  (process-reset process)
666  (process-enable process))
667
668(defmethod process-kill-issued ((process process))
669  (cdr (process-splice process)))
670
671(defmethod (setf process-kill-issued) (val (process process))
672  (setf (cdr (process-splice process)) val))
673
674(defun tcr->process (tcr)
675  (dolist (p (all-processes))
676    (when (eq tcr (process-tcr p))
677      (return p))))
678
679(defun current-process-allocation-quantum ()
680  (process-allocation-quantum *current-process*))
681
682(defun (setf current-process-allocation-quantum) (new)
683  (if (valid-allocation-quantum-p new)
684    (with-macptrs (tcrp)
685      (%setf-macptr-to-object tcrp (%current-tcr))
686      #+(and windows-target x8632-target)
687      (let ((aux (%get-ptr tcrp (- target::tcr.aux target::tcr-bias))))
688        (setf (%get-natural aux target::tcr-aux.log2-allocation-quantum)
689              (1- (integer-length new))))
690      #-(and windows-target x8632-target)
691      (setf (%get-natural tcrp target::tcr.log2-allocation-quantum)
692            (1- (integer-length new)))
693      (setf (slot-value *current-process* 'allocation-quantum) new)
694      new)
695    (report-bad-arg new '(satisfies valid-allocation-quantum-p))))
696
697
698(def-standard-initial-binding *backtrace-contexts* nil)
699
700(defmethod exit-interactive-process ((p process))
701  (unless (eq p *initial-process*)
702    (when (eq p *current-process*)
703      (process-kill p))))
704
705(defclass tty-listener (process)
706    ())
707
708(defmethod exit-interactive-process ((p tty-listener))
709  (when (eq p *current-process*)
710    (quit)))
711
712(defmethod process-stop-dribbling ((p process))
713  (with-slots (dribble-stream dribble-saved-terminal-io) p
714    (when dribble-stream
715      (close dribble-stream)
716      (setq dribble-stream nil))
717    (when dribble-saved-terminal-io
718      (setq *terminal-io* dribble-saved-terminal-io
719            dribble-saved-terminal-io nil))))
720
721(defmethod process-dribble ((p process) path)
722  (with-slots (dribble-stream dribble-saved-terminal-io) p
723    (process-stop-dribbling p)
724    (when path
725      (let* ((in (two-way-stream-input-stream *terminal-io*))
726             (out (two-way-stream-output-stream *terminal-io*))
727             (f (open path :direction :output :if-exists :append 
728                      :if-does-not-exist :create)))
729        (without-interrupts
730         (setq dribble-stream f
731               dribble-saved-terminal-io *terminal-io*
732               *terminal-io* (make-echoing-two-way-stream
733                              (make-echo-stream in f)
734                              (make-broadcast-stream out f)))))
735      path)))
736
737(defmethod join-process ((p process) &key default)
738  (wait-on-semaphore (process-termination-semaphore p) nil "join-process")
739  (let ((result (process-result p)))
740    (cond ((car result) (values-list (cdr result)))
741          (t default))))
742
743(defun call-in-process (f process)
744  (let* ((return-values nil)
745         (done (make-semaphore)))
746    (process-interrupt process
747                       #'(lambda ()
748                           (unwind-protect
749                                (progn
750                                  (setq return-values
751                                        (multiple-value-list (funcall f))))
752                             (signal-semaphore done))))
753    (wait-on-semaphore done)
754    (apply #'values return-values)))
755
756(defun call-in-initial-process (f)
757  (call-in-process f *initial-process*))
758
Note: See TracBrowser for help on using the repository browser.