source: trunk/source/level-1/l1-processes.lisp @ 15018

Last change on this file since 15018 was 14995, checked in by gz, 8 years ago

accept an :initargs arg in make-mcl-listener-process

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 26.6 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18
19;; L1-processes.lisp
20
21(cl:in-package "CCL")
22
23
24(let* ((all-processes ())
25       (shutdown-processes ())
26       (all-processes-lock (make-lock)))
27  (defun add-to-all-processes (p)
28    (with-lock-grabbed (all-processes-lock)
29      (pushnew p all-processes :test #'eq)
30      p))
31  (defun remove-from-all-processes (p)
32    (with-lock-grabbed (all-processes-lock)
33      (setq all-processes (delete p all-processes))
34      t))
35  (defun all-processes ()
36    "Obtain a fresh list of all known Lisp threads."
37    (with-lock-grabbed (all-processes-lock)
38      (copy-list all-processes)))
39  (defun shutdown-processes ()
40    (with-lock-grabbed (all-processes-lock)
41      (copy-list shutdown-processes)))
42  (defun %clear-shutdown-proceses ()
43    (setq shutdown-processes nil))
44  (defun add-to-shutdown-processes (p)
45    (with-lock-grabbed (all-processes-lock)
46      (pushnew p shutdown-processes :test #'eq))
47    t)
48  (defun pop-shutdown-processes ()
49    (with-lock-grabbed (all-processes-lock)
50      (pop shutdown-processes)))
51  (defun find-process (id)
52    (etypecase id
53      (process id)
54      (integer (with-lock-grabbed (all-processes-lock)
55                 (find id all-processes
56                       :key #'(lambda (p)
57                                (process-serial-number p)))))
58      (string (with-lock-grabbed (all-processes-lock)
59                (find id all-processes
60                      :key #'(lambda (p)
61                               (process-name p))
62                      :test #'equal))))))
63
64
65
66(defun not-in-current-process (p operation)
67  (if (eq p *current-process*)
68    (error "The current process (~s) can't perform the ~a operation on itself."
69           p operation)))
70
71(defun startup-shutdown-processes ()
72  (let* ((p))
73    (loop
74      (unless (setq p (pop-shutdown-processes)) (return))
75      (new-tcr-for-thread (process-thread p))
76      (%process-preset-internal p)
77      (process-enable p)
78      )))
79
80;;; Done with a queue-fixup so that it will be the last thing
81;;; that happens on startup.
82(queue-fixup
83 (pushnew 'startup-shutdown-processes *lisp-system-pointer-functions*))
84
85
86
87
88
89
90
91(defun wrap-initial-bindings (alist)
92  (mapcar #'(lambda (pair)
93              (destructuring-bind (symbol . valform) pair
94                (cons (require-type symbol 'symbol)
95                      (cond ((symbolp valform)
96                             (constantly (symbol-value valform)))
97                            ((typep valform 'function) valform)
98                            ((consp valform)
99                             (if (eq (car valform) 'quote)
100                               (constantly (cadr valform))
101                               #'(lambda () (apply (car valform) (cdr valform)))))
102                            (t
103                             (constantly valform))))))
104          alist))
105
106
107(defun valid-allocation-quantum-p (x)
108  (and (>= x *host-page-size*)
109       (<= x (default-allocation-quantum))
110       (= (logcount x) 1)))
111
112 
113(let* ((psn -1))
114  (defun %new-psn () (incf psn)))
115
116(defclass process ()
117    ((name :initform nil :initarg :name :accessor process-name)
118     (thread :initarg :thread :initform nil :accessor process-thread)
119     (initial-form :initform (cons nil nil) :reader process-initial-form)
120     (priority :initform 0 :initarg :priority :accessor process-priority)
121     (persistent :initform nil :initarg :persistent :reader process-persistent)
122     (splice :initform (cons nil nil) :accessor process-splice)
123     (initial-bindings :initform nil :initarg :initial-bindings
124                       :accessor process-initial-bindings)
125     (serial-number :initform (%new-psn) :accessor process-serial-number)
126     (creation-time :initform (get-tick-count) :reader process-creation-time)
127     (total-run-time :initform nil :accessor %process-total-run-time)
128     (ui-object :initform (application-ui-object *application*)
129                :accessor process-ui-object)
130     (termination-semaphore :initform nil
131                            :initarg :termination-semaphore
132                            :accessor process-termination-semaphore
133                            :type (or null semaphore))
134     (allocation-quantum :initform (default-allocation-quantum)
135                         :initarg :allocation-quantum
136                         :reader process-allocation-quantum
137                         :type (satisfies valid-allocation-quantum-p))
138     (dribble-stream :initform nil)
139     (dribble-saved-terminal-io :initform nil)
140     (result :initform (cons nil nil)
141             :reader process-result))
142  (:primary-p t))
143
144(defparameter *print-process-whostate* t "make it optional")
145
146(defmethod print-object ((p process) s)
147  (print-unreadable-object (p s :type t :identity t)
148    (format s "~a(~d)" (process-name p)
149            (process-serial-number p))
150    (when *print-process-whostate*
151      (format s " [~a]" (process-whostate p)))))
152
153(defvar *process-class* (find-class 'process))
154
155(defun processp (p)
156  (memq *process-class* (class-precedence-list (class-of p))))
157
158(set-type-predicate 'process 'processp)
159
160(defun make-process (name &key 
161                          thread
162                          persistent
163                          (priority 0)
164                          (stack-size *default-control-stack-size*)
165                          (vstack-size *default-value-stack-size*)
166                          (tstack-size *default-temp-stack-size*)
167                          (initial-bindings ())
168                          (use-standard-initial-bindings t)
169                          (class (find-class 'process))
170                          (initargs nil)
171                          (termination-semaphore ())
172                          (allocation-quantum (default-allocation-quantum)))
173  "Create and return a new process."
174  (let* ((p (apply #'make-instance
175             class
176             :name name
177             :priority priority
178             :persistent persistent
179             :initial-bindings (append (if use-standard-initial-bindings
180                                         (standard-initial-bindings))
181                                       (wrap-initial-bindings
182                                        initial-bindings))
183             :termination-semaphore (or termination-semaphore
184                                        (make-semaphore))
185             :allocation-quantum allocation-quantum
186             initargs)))
187    (with-slots ((lisp-thread thread)) p
188      (unless lisp-thread
189        (setq lisp-thread
190              (or thread
191                  (new-thread name stack-size  vstack-size  tstack-size)))))
192    (add-to-all-processes p)
193    (setf (car (process-splice p)) p)
194    p))
195
196
197(defstatic *initial-process*
198    (let* ((p (make-process
199               "Initial"
200               :thread *initial-lisp-thread*
201               :priority 0)))
202      p))
203
204
205(defvar *current-process* *initial-process*
206  "Bound in each process, to that process itself.")
207
208(defstatic *interactive-abort-process* *initial-process*)
209
210
211
212
213(defun process-tcr (p)
214  (lisp-thread.tcr (process-thread p)))
215
216
217
218(defun process-exhausted-p (p)
219  (let* ((thread (process-thread p)))
220    (or (null thread)
221        (thread-exhausted-p thread))))
222 
223;;; This should be way more concerned about being correct and thread-safe
224;;; than about being quick: it's generally only called while printing
225;;; or debugging, and there are all kinds of subtle race conditions
226;;; here.
227(defun process-whostate (p)
228  "Return a string which describes the status of a specified process."
229    (let* ((ip *initial-process*))
230      (cond ((eq p *current-process*)
231             (if (%tcr-binding-location (%current-tcr) '*whostate*)
232               *whostate*
233               (if (eq p ip)
234                 "Active"
235                 "Reset")))
236            (t
237             (without-interrupts
238              (with-lock-grabbed (*kernel-exception-lock*)
239               (with-lock-grabbed (*kernel-tcr-area-lock*)
240                 (let* ((tcr (process-tcr p)))
241                   (if tcr
242                     (unwind-protect
243                          (let* ((loc nil))
244                            (%suspend-tcr tcr)
245                            (setq loc (%tcr-binding-location tcr '*whostate*))
246                            (if loc
247                              (%fixnum-ref loc)
248                              (if (eq p ip)
249                                "Active"
250                                "Reset")))
251                       (%resume-tcr tcr))
252                     "Exhausted")))))))))
253
254(defun (setf process-whostate) (new p)
255  (unless (process-exhausted-p p)
256    (setf (symbol-value-in-process '*whostate* p) new)))
257
258
259
260(defun process-total-run-time (p)
261  (or (%process-total-run-time p)
262      (thread-total-run-time (process-thread p))))
263
264
265
266
267(defun initial-bindings (alist)
268  (let* ((symbols ())
269         (values ()))
270    (dolist (a alist (values (nreverse symbols) (nreverse values)))
271      (push (car a) symbols)
272      (push (funcall (cdr a)) values))))
273
274
275                           
276(defun symbol-value-in-process (sym process)
277  (if (eq process *current-process*)
278    (symbol-value sym)
279    (let* ((val
280            (without-interrupts
281             (with-lock-grabbed (*kernel-exception-lock*)
282               (with-lock-grabbed (*kernel-tcr-area-lock*)
283                 (let* ((tcr (process-tcr process)))
284                   (if tcr
285                     (symbol-value-in-tcr sym tcr)
286                     (%sym-global-value sym))))))))
287      (if (eq val (%unbound-marker))
288        ;; This might want to be a CELL-ERROR.
289        (error "~S is unbound in ~S." sym process)
290        val))))
291
292(defun (setf symbol-value-in-process) (value sym process)
293  (if (eq process *current-process*)
294    (setf (symbol-value sym) value)
295    (with-lock-grabbed (*kernel-exception-lock*)
296      (with-lock-grabbed (*kernel-tcr-area-lock*)
297        (let* ((tcr (process-tcr process)))
298          (if tcr
299            (setf (symbol-value-in-tcr sym tcr) value)
300            (%set-sym-global-value sym value)))))))
301
302
303(defmethod process-enable ((p process) &optional (wait (* 60 60 24) wait-p))
304  "Begin executing the initial function of a specified process."
305  (not-in-current-process p 'process-enable)
306  (when wait-p
307    (check-type wait (unsigned-byte 32)))
308  (unless (car (process-initial-form p))
309    (error "Process ~s has not been preset.  Use PROCESS-PRESET to preset the process." p))
310  (let* ((thread (process-thread p)))
311    (do* ((total-wait wait (+ total-wait wait)))
312         ((thread-enable thread (process-termination-semaphore p) (1- (integer-length (process-allocation-quantum p)))  wait)
313          (process-tcr-enable p (lisp-thread.tcr thread))
314          p)
315      (cerror "Keep trying."
316              "Unable to enable process ~s; have been trying for ~s seconds."
317              p total-wait))))
318
319(defmethod process-tcr-enable ((process process) tcr)
320  (when (and tcr (not (eql 0 tcr)))
321    #+(and windows-target x8632-target)
322    (let ((aux (%fixnum-ref tcr (- target::tcr.aux target::tcr-bias))))
323      (%signal-semaphore-ptr (%fixnum-ref-macptr aux target::tcr-aux.activate)))
324    #-(and windows-target x8632-target)
325    (%signal-semaphore-ptr (%fixnum-ref-macptr tcr target::tcr.activate))
326    ))
327
328
329
330(defun process-resume (p)
331  "Resume a specified process which had previously been suspended
332by process-suspend."
333  (setq p (require-type p 'process))
334  (let* ((tcr (process-tcr p)))
335    (and tcr (%resume-tcr tcr))))
336
337(defun process-suspend (p)
338  "Suspend a specified process."
339  (setq p (require-type p 'process))
340  (if (eq p *current-process*)
341    (error "Suspending the current process can't work.  ~&(If the documentation claims otherwise, it's incorrect.)")
342    (let* ((tcr (process-tcr p)))
343      (and tcr (%suspend-tcr tcr)))))
344
345(defun process-suspend-count (p)
346  "Return the number of currently-pending suspensions applicable to
347a given process."
348  (setq p (require-type p 'process))
349  (let* ((thread (process-thread p)))
350    (if thread
351      (lisp-thread-suspend-count thread))))
352
353(defun process-active-p (p)
354  (setq p (require-type p 'process))
355  (and (eql 0 (process-suspend-count p))
356       (not (process-exhausted-p p))))
357 
358;;; Used by process-run-function
359(defmethod process-preset ((p process) function &rest args)
360  "Set the initial function and arguments of a specified process."
361  (let* ((f (require-type function 'function))
362         (initial-form (process-initial-form p)))
363    (declare (type cons initial-form))
364    (not-in-current-process p 'process-preset)
365    ; Not quite right ...
366    (rplaca initial-form f)
367    (rplacd initial-form args)
368    (%process-preset-internal p)))
369
370(defmethod %process-preset-internal ((process process))
371   (let* ((initial-form (process-initial-form process))
372         (thread (process-thread process)))
373     (declare (type cons initial-form))
374     (thread-preset
375      thread
376      #'(lambda (process initial-form)
377          (let* ((*current-process* process))
378            (add-to-all-processes process)
379            (with-initial-bindings (process-initial-bindings process)
380              (setq *whostate* "Active")
381              (run-process-initial-form process initial-form))))
382      process
383      initial-form)
384     process))
385
386
387(defun run-process-initial-form (process initial-form)
388  (let* ((exited nil)
389         (kill (handler-case
390                   (restart-case
391                    (let ((values
392                           (multiple-value-list
393                            (apply (car initial-form)
394                                   (cdr (the list initial-form)))))
395                          (result (process-result process)))
396                      (setf (cdr result) values
397                            (car result) t)
398                      (setq exited t)
399                      nil)
400                    (abort-break () :report "Reset this thread")
401                    (abort () :report "Kill this thread" (setq exited t)))
402                 (process-reset (condition)
403                   (process-reset-kill condition)))))
404    ;; We either exited from the initial form normally, were told to
405    ;; exit prematurely, or are being reset and should enter the
406    ;; "awaiting preset" state.
407    (if (or kill exited) 
408      (unless (eq kill :toplevel)
409        (process-initial-form-exited process (or kill t)))
410      (progn
411        (thread-change-state (process-thread process) :run :reset)
412        (tcr-set-preset-state (process-tcr process))))
413    nil))
414
415;;; Separated from run-process-initial-form just so I can change it easily.
416(defun process-initial-form-exited (process kill)
417  (without-interrupts
418   (if (eq kill :shutdown)
419     (progn
420       (setq *whostate* "Shutdown")
421       (add-to-shutdown-processes process)))
422   (let* ((semaphore (process-termination-semaphore process)))
423     (when semaphore (signal-semaphore semaphore)))
424   (maybe-finish-process-kill process kill)))
425
426(defun maybe-finish-process-kill (process kill)
427  (when (and kill (neq kill :shutdown))
428    (setf (process-whostate process) "Dead")
429    (remove-from-all-processes process)
430    (let ((thread (process-thread process)))
431      (unless (or (eq thread *current-lisp-thread*)
432                  (thread-exhausted-p thread))
433        (kill-lisp-thread thread))))
434  nil)
435
436
437 
438
439(defun require-global-symbol (s &optional env)
440  (let* ((s (require-type s 'symbol))
441         (bits (%symbol-bits s)))
442    (unless (or (logbitp $sym_vbit_global bits)
443                (let* ((defenv (if env (definition-environment env))))
444                  (if defenv
445                    (eq :global (%cdr (assq s (defenv.specials defenv)))))))
446      (error "~s not defined with ~s" s 'defstatic))
447    s))
448
449
450(defmethod print-object ((s lock) stream)
451  (print-unreadable-object (s stream :type t :identity t)
452    (let* ((val (uvref s target::lock._value-cell))
453           (name (uvref s target::lock.name-cell)))
454      (when name
455        (format stream "~s " name))
456      (if (typep val 'macptr)
457        (format stream "[ptr @ #x~x]"
458                (%ptr-to-int val))))))
459
460(defun lockp (l)
461  (eq target::subtag-lock (typecode l)))
462
463(set-type-predicate 'lock 'lockp)
464
465(defun recursive-lock-p (l)
466  (and (eq target::subtag-lock (typecode l))
467       (eq 'recursive-lock (%svref l target::lock.kind-cell))))
468
469(defun read-write-lock-p (l)
470  (and (eq target::subtag-lock (typecode l))
471       (eq 'read-write-lock (%svref l target::lock.kind-cell))))
472
473(setf (type-predicate 'recursive-lock) 'recursive-lock-p
474      (type-predicate 'read-write-lock) 'read-write-lock-p)
475
476
477(defun grab-lock (lock &optional flag)
478  "Wait until a given lock can be obtained, then obtain it."
479  (%lock-recursive-lock-object lock flag))
480
481(defun release-lock (lock)
482  "Relinquish ownership of a given lock."
483  (%unlock-recursive-lock-object lock))
484
485(defun try-lock (lock &optional flag)
486  "Obtain the given lock, but only if it is not necessary to wait for it."
487  (%try-recursive-lock-object lock flag))
488
489(defun lock-acquisition-status (thing)
490  (if (istruct-typep thing 'lock-acquisition)
491    (lock-acquisition.status thing)
492    (report-bad-arg thing 'lock-acquisition)))
493
494(defun clear-lock-acquisition-status (thing)
495  (if (istruct-typep thing 'lock-acquisition)
496    (setf (lock-acquisition.status thing) nil)
497    (report-bad-arg thing 'lock-acquisition)))
498
499(defmethod print-object ((l lock-acquisition) stream)
500  (print-unreadable-object (l stream :type t :identity t)
501    (format stream "[status = ~s]" (lock-acquisition-status l))))
502
503(defun semaphore-notification-status (thing)
504  (if (istruct-typep thing 'semaphore-notification)
505    (semaphore-notification.status thing)
506    (report-bad-arg thing 'semaphore-notification)))
507
508(defun clear-semaphore-notification-status (thing)
509  (if (istruct-typep thing 'semaphore-notification)
510    (setf (semaphore-notification.status thing) nil)
511    (report-bad-arg thing 'semaphore-notification)))
512
513(defmethod print-object ((l semaphore-notification) stream)
514  (print-unreadable-object (l stream :type t :identity t)
515    (format stream "[status = ~s]" (semaphore-notification-status l))))
516
517(defun process-wait (whostate function &rest args)
518  "Causes the current lisp process (thread) to wait for a given
519predicate to return true."
520  (declare (dynamic-extent args))
521  (or (apply function args)
522      (with-process-whostate (whostate)
523        (loop
524          (when (apply function args)
525            (return))
526          ;; Sleep for a tick
527          #-windows-target
528          (%nanosleep 0 *ns-per-tick*)
529          #+windows-target
530          (%windows-sleep 5)))))
531
532
533
534(defun process-wait-with-timeout (whostate time function &rest args)
535  "Cause the current thread to wait for a given predicate to return true,
536or for a timeout to expire."
537  (declare (dynamic-extent args))
538  (cond ((null time)  (apply #'process-wait whostate function args) t)
539        (t (let* ((win nil)
540                  (when (+ (get-tick-count) time))
541                  (f #'(lambda () (let ((val (apply function args)))
542                                    (if val
543                                      (setq win val)
544                                      (> (get-tick-count) when))))))
545             (declare (dynamic-extent f))
546             (process-wait whostate f)
547             win))))
548
549
550(defmethod process-interrupt ((process process) function &rest args)
551  "Arrange for the target process to invoke a specified function at
552some point in the near future, and then return to what it was doing."
553  (let* ((p (require-type process 'process)))
554    (if (eq p *current-process*)
555      (progn
556        (apply function args)
557        t)
558      (thread-interrupt
559       (process-thread p)
560       process
561       #'apply
562       function args))))
563
564(defmethod process-debug-condition ((p process) condition frame-pointer)
565  (declare (ignore condition frame-pointer)))
566
567
568
569
570;;; This one is in the Symbolics documentation
571(defun process-allow-schedule ()
572  "Used for cooperative multitasking; probably never necessary."
573  (process-yield *current-process*))
574
575
576;;; something unique that users won't get their hands on
577(defun process-reset-tag (process)
578  (process-splice process))
579
580(defun process-run-function (name-or-keywords function &rest args)
581  "Create a process, preset it, and enable it."
582  (if (listp name-or-keywords)
583    (%process-run-function name-or-keywords function args)
584    (let ((keywords (list :name name-or-keywords)))
585      (declare (dynamic-extent keywords))
586      (%process-run-function keywords function args))))
587
588(defun %process-run-function (keywords function args)
589  (destructuring-bind (&key (name "Anonymous")
590                            (priority  0)
591                            (stack-size *default-control-stack-size*)
592                            (vstack-size *default-value-stack-size*)
593                            (tstack-size *default-temp-stack-size*)
594                            (initial-bindings ())
595                            (persistent nil)
596                            (use-standard-initial-bindings t)
597                            (termination-semaphore nil)
598                            (allocation-quantum (default-allocation-quantum)))
599                      keywords
600    (setq priority (require-type priority 'fixnum))
601    (let* ((process (make-process name
602                                  :priority priority
603                                  :stack-size stack-size
604                                  :vstack-size vstack-size
605                                  :tstack-size tstack-size
606                                  :persistent persistent
607                                  :use-standard-initial-bindings use-standard-initial-bindings
608                                  :initial-bindings initial-bindings
609                                  :termination-semaphore termination-semaphore
610                                  :allocation-quantum allocation-quantum)))
611      (process-preset process #'(lambda () (apply function args)))
612      (process-enable process)
613      process)))
614
615(defmethod process-reset ((process process) &optional kill)
616  "Cause a specified process to cleanly exit from any ongoing computation."
617  (setq process (require-type process 'process))
618  (unless (memq kill '(nil :kill :shutdown))
619    (setq kill (require-type kill '(member nil :kill :shutdown))))
620  (if (eq process *current-process*)
621    (%process-reset kill)
622    (if (process-exhausted-p process)
623      (maybe-finish-process-kill process kill)
624      (progn
625        (process-interrupt process '%process-reset kill)))))
626
627(defmethod process-yield ((p process))
628  #+windows-target (#_Sleep 0)
629  #-windows-target (#_sched_yield))
630
631
632(defun %process-reset (kill)
633  (signal 'process-reset :kill kill)
634  (maybe-finish-process-kill *current-process* kill))
635
636;;; By default, it's just fine with the current process
637;;; if the application/user wants to quit.
638(defmethod process-verify-quit ((process process))
639  t)
640
641(defmethod process-exit-application ((process process) thunk)
642  (when (eq process *initial-process*)
643    (with-standard-abort-handling "Exit Lisp"
644      (prepare-to-quit)
645      ;; We may have abruptly terminated a thread which owned the
646      ;; output lock on a stream we want to flush.  Don't block
647      ;; waiting on the lock if so.
648      (flet ((flush-stream (s)
649               (let* ((lock (ioblock-outbuf-lock (basic-stream-ioblock s)))
650                      (locked (make-lock-acquisition)))
651                 (declare (dynamic-extent locked))
652                 (when (or (null lock)
653                           (%try-recursive-lock-object lock locked))
654                   (unwind-protect
655                        (progn
656                          (fresh-line s)
657                          (finish-output s))
658                     (when (lock-acquisition.status locked)
659                       (release-lock lock)))))))
660        (flush-stream *stdout*)
661        (flush-stream *stderr*)))
662    (%set-toplevel thunk)
663    (toplevel)))
664
665
666
667(defmethod process-kill ((process process))
668  "Cause a specified process to cleanly exit from any ongoing
669computation, and then exit."
670  (and (process-interrupt process #'%process-reset :kill)
671       (setf (process-kill-issued process) t)))
672
673(defun process-abort (process &optional condition)
674  "Cause a specified process to process an abort condition, as if it
675had invoked abort."
676  (process-interrupt process
677                     #'(lambda ()
678                         (abort condition))))
679
680(defmethod process-reset-and-enable ((process process))
681  (not-in-current-process process 'process-reset-and-enable)
682  (process-reset process)
683  (process-enable process))
684
685(defmethod process-kill-issued ((process process))
686  (cdr (process-splice process)))
687
688(defmethod (setf process-kill-issued) (val (process process))
689  (setf (cdr (process-splice process)) val))
690
691(defun tcr->process (tcr)
692  (dolist (p (all-processes))
693    (when (eq tcr (process-tcr p))
694      (return p))))
695
696(defun current-process-allocation-quantum ()
697  (process-allocation-quantum *current-process*))
698
699(defun (setf current-process-allocation-quantum) (new)
700  (if (valid-allocation-quantum-p new)
701    (with-macptrs (tcrp)
702      (%setf-macptr-to-object tcrp (%current-tcr))
703      #+(and windows-target x8632-target)
704      (let ((aux (%get-ptr tcrp (- target::tcr.aux target::tcr-bias))))
705        (setf (%get-natural aux target::tcr-aux.log2-allocation-quantum)
706              (1- (integer-length new))))
707      #-(and windows-target x8632-target)
708      (setf (%get-natural tcrp target::tcr.log2-allocation-quantum)
709            (1- (integer-length new)))
710      (setf (slot-value *current-process* 'allocation-quantum) new)
711      new)
712    (report-bad-arg new '(satisfies valid-allocation-quantum-p))))
713
714
715(def-standard-initial-binding *backtrace-contexts* nil)
716
717(defmethod exit-interactive-process ((p process))
718  (unless (eq p *initial-process*)
719    (when (eq p *current-process*)
720      (process-kill p))))
721
722(defclass tty-listener (process)
723    ())
724
725(defmethod exit-interactive-process ((p tty-listener))
726  (when (eq p *current-process*)
727    (quit)))
728
729(defmethod process-stop-dribbling ((p process))
730  (with-slots (dribble-stream dribble-saved-terminal-io) p
731    (when dribble-stream
732      (close dribble-stream)
733      (setq dribble-stream nil))
734    (when dribble-saved-terminal-io
735      (setq *terminal-io* dribble-saved-terminal-io
736            dribble-saved-terminal-io nil))))
737
738(defmethod process-dribble ((p process) path)
739  (with-slots (dribble-stream dribble-saved-terminal-io) p
740    (process-stop-dribbling p)
741    (when path
742      (let* ((in (two-way-stream-input-stream *terminal-io*))
743             (out (two-way-stream-output-stream *terminal-io*))
744             (f (open path :direction :output :if-exists :append 
745                      :if-does-not-exist :create)))
746        (without-interrupts
747         (setq dribble-stream f
748               dribble-saved-terminal-io *terminal-io*
749               *terminal-io* (make-echoing-two-way-stream
750                              (make-echo-stream in f)
751                              (make-broadcast-stream out f)))))
752      path)))
753
754(defmethod join-process ((p process) &key default)
755  (wait-on-semaphore (process-termination-semaphore p) nil "join-process")
756  (let ((result (process-result p)))
757    (cond ((car result) (values-list (cdr result)))
758          (t default))))
759
760(defun call-in-process (f process)
761  (let* ((return-values nil)
762         (done (make-semaphore)))
763    (process-interrupt process
764                       #'(lambda ()
765                           (unwind-protect
766                                (progn
767                                  (setq return-values
768                                        (multiple-value-list (funcall f))))
769                             (signal-semaphore done))))
770    (wait-on-semaphore done)
771    (apply #'values return-values)))
772
773(defun call-in-initial-process (f)
774  (call-in-process f *initial-process*))
775
Note: See TracBrowser for help on using the repository browser.