source: trunk/source/level-1/l1-processes.lisp @ 11744

Last change on this file since 11744 was 11744, checked in by gb, 11 years ago

Mostly experimental changes: try to make some operations on PROCESSes
generic. Work-in-progress.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 25.2 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; L1-processes.lisp
19
20(cl:in-package "CCL")
21
22
23(let* ((all-processes ())
24       (shutdown-processes ())
25       (all-processes-lock (make-lock)))
26  (defun add-to-all-processes (p)
27    (with-lock-grabbed (all-processes-lock)
28      (pushnew p all-processes :test #'eq)
29      p))
30  (defun remove-from-all-processes (p)
31    (with-lock-grabbed (all-processes-lock)
32      (setq all-processes (delete p all-processes))
33      t))
34  (defun all-processes ()
35    "Obtain a fresh list of all known Lisp threads."
36    (with-lock-grabbed (all-processes-lock)
37      (copy-list all-processes)))
38  (defun shutdown-processes ()
39    (with-lock-grabbed (all-processes-lock)
40      (copy-list shutdown-processes)))
41  (defun %clear-shutdown-proceses ()
42    (setq shutdown-processes nil))
43  (defun add-to-shutdown-processes (p)
44    (with-lock-grabbed (all-processes-lock)
45      (pushnew p shutdown-processes :test #'eq))
46    t)
47  (defun pop-shutdown-processes ()
48    (with-lock-grabbed (all-processes-lock)
49      (pop shutdown-processes)))
50  (defun find-process (id)
51    (etypecase id
52      (process id)
53      (integer (with-lock-grabbed (all-processes-lock)
54                 (find id all-processes
55                       :key #'(lambda (p)
56                                (process-serial-number p)))))
57      (string (with-lock-grabbed (all-processes-lock)
58                (find id all-processes
59                      :key #'(lambda (p)
60                               (process-name p))
61                      :test #'equal))))))
62
63
64
65(defun not-in-current-process (p operation)
66  (if (eq p *current-process*)
67    (error "The current process (~s) can't perform the ~a operation on itself."
68           p operation)))
69
70(defun startup-shutdown-processes ()
71  (let* ((p))
72    (loop
73      (unless (setq p (pop-shutdown-processes)) (return))
74      (new-tcr-for-thread (process-thread p))
75      (%process-preset-internal p)
76      (process-enable p)
77      )))
78
79;;; Done with a queue-fixup so that it will be the last thing
80;;; that happens on startup.
81(queue-fixup
82 (pushnew 'startup-shutdown-processes *lisp-system-pointer-functions*))
83
84
85
86
87
88
89
90(defun wrap-initial-bindings (alist)
91  (mapcar #'(lambda (pair)
92              (destructuring-bind (symbol . valform) pair
93                (cons (require-type symbol 'symbol)
94                      (cond ((symbolp valform)
95                             (constantly (symbol-value valform)))
96                            ((typep valform 'function) valform)
97                            ((consp valform)
98                             (if (eq (car valform) 'quote)
99                               (constantly (cadr valform))
100                               #'(lambda () (apply (car valform) (cdr valform)))))
101                            (t
102                             (constantly valform))))))
103          alist))
104
105
106(defun valid-allocation-quantum-p (x)
107  (and (>= x *host-page-size*)
108       (<= x (default-allocation-quantum))
109       (= (logcount x) 1)))
110
111 
112(let* ((psn -1))
113  (defun %new-psn () (incf psn)))
114
115(defclass process ()
116    ((name :initform nil :initarg :name :accessor process-name)
117     (thread :initarg :thread :accessor process-thread)
118     (initial-form :initform (cons nil nil) :reader process-initial-form)
119     (priority :initform 0 :initarg :priority :accessor process-priority)
120     (persistent :initform nil :initarg :persistent :reader process-persistent)
121     (splice :initform (cons nil nil) :accessor process-splice)
122     (initial-bindings :initform nil :initarg :initial-bindings
123                       :accessor process-initial-bindings)
124     (serial-number :initform (%new-psn) :accessor process-serial-number)
125     (creation-time :initform (get-tick-count) :reader process-creation-time)
126     (total-run-time :initform nil :accessor %process-total-run-time)
127     (ui-object :initform (application-ui-object *application*)
128                :accessor process-ui-object)
129     (termination-semaphore :initform nil
130                            :initarg :termination-semaphore
131                            :accessor process-termination-semaphore
132                            :type (or null semaphore))
133     (allocation-quantum :initform (default-allocation-quantum)
134                         :initarg :allocation-quantum
135                         :reader process-allocation-quantum
136                         :type (satisfies valid-allocation-quantum-p))
137     (dribble-stream :initform nil)
138     (dribble-saved-terminal-io :initform nil)
139     (result :initform (cons nil nil)
140             :reader process-result))
141  (:primary-p t))
142
143(defparameter *print-process-whostate* t "make it optional")
144
145(defmethod print-object ((p process) s)
146  (print-unreadable-object (p s :type t :identity t)
147    (format s "~a(~d)" (process-name p)
148            (process-serial-number p))
149    (when *print-process-whostate*
150      (format s " [~a]" (process-whostate p)))))
151
152(defvar *process-class* (find-class 'process))
153
154(defun processp (p)
155  (memq *process-class* (class-precedence-list (class-of p))))
156
157(set-type-predicate 'process 'processp)
158
159(defun make-process (name &key 
160                          thread
161                          persistent
162                          (priority 0)
163                          (stack-size *default-control-stack-size*)
164                          (vstack-size *default-value-stack-size*)
165                          (tstack-size *default-temp-stack-size*)
166                          (initial-bindings ())
167                          (use-standard-initial-bindings t)
168                          (class (find-class 'process))
169                          (termination-semaphore ())
170                          (allocation-quantum (default-allocation-quantum)))
171  "Create and return a new process."
172  (let* ((p (make-instance
173             class
174             :name name
175             :thread (or thread
176                         (new-thread name stack-size  vstack-size  tstack-size))
177             :priority priority
178             :persistent persistent
179             :initial-bindings (append (if use-standard-initial-bindings
180                                         (standard-initial-bindings))
181                                       (wrap-initial-bindings
182                                        initial-bindings))
183             :termination-semaphore (or termination-semaphore
184                                        (make-semaphore))
185             :allocation-quantum allocation-quantum)))
186    (add-to-all-processes p)
187    (setf (car (process-splice p)) p)
188    p))
189
190
191(defstatic *initial-process*
192    (let* ((p (make-process
193               "Initial"
194               :thread *initial-lisp-thread*
195               :priority 0)))
196      p))
197
198
199(defvar *current-process* *initial-process*
200  "Bound in each process, to that process itself.")
201
202(defstatic *interactive-abort-process* *initial-process*)
203
204
205
206
207(defun process-tcr (p)
208  (lisp-thread.tcr (process-thread p)))
209
210
211
212(defun process-exhausted-p (p)
213  (let* ((thread (process-thread p)))
214    (or (null thread)
215        (thread-exhausted-p thread))))
216 
217;;; This should be way more concerned about being correct and thread-safe
218;;; than about being quick: it's generally only called while printing
219;;; or debugging, and there are all kinds of subtle race conditions
220;;; here.
221(defun process-whostate (p)
222  "Return a string which describes the status of a specified process."
223    (let* ((ip *initial-process*))
224      (cond ((eq p *current-process*)
225             (if (%tcr-binding-location (%current-tcr) '*whostate*)
226               *whostate*
227               (if (eq p ip)
228                 "Active"
229                 "Reset")))
230            (t
231             (without-interrupts
232              (with-lock-grabbed (*kernel-exception-lock*)
233               (with-lock-grabbed (*kernel-tcr-area-lock*)
234                 (let* ((tcr (process-tcr p)))
235                   (if tcr
236                     (unwind-protect
237                          (let* ((loc nil))
238                            (%suspend-tcr tcr)
239                            (setq loc (%tcr-binding-location tcr '*whostate*))
240                            (if loc
241                              (%fixnum-ref loc)
242                              (if (eq p ip)
243                                "Active"
244                                "Reset")))
245                       (%resume-tcr tcr))
246                     "Exhausted")))))))))
247
248(defun (setf process-whostate) (new p)
249  (unless (process-exhausted-p p)
250    (setf (symbol-value-in-process '*whostate* p) new)))
251
252
253
254(defun process-total-run-time (p)
255  (or (%process-total-run-time p)
256      (thread-total-run-time (process-thread p))))
257
258
259
260
261(defun initial-bindings (alist)
262  (let* ((symbols ())
263         (values ()))
264    (dolist (a alist (values (nreverse symbols) (nreverse values)))
265      (push (car a) symbols)
266      (push (funcall (cdr a)) values))))
267
268
269                           
270(defun symbol-value-in-process (sym process)
271  (if (eq process *current-process*)
272    (symbol-value sym)
273    (let* ((val
274            (without-interrupts
275             (with-lock-grabbed (*kernel-exception-lock*)
276               (with-lock-grabbed (*kernel-tcr-area-lock*)
277                 (let* ((tcr (process-tcr process)))
278                   (if tcr
279                     (symbol-value-in-tcr sym tcr)
280                     (%sym-global-value sym))))))))
281      (if (eq val (%unbound-marker))
282        ;; This might want to be a CELL-ERROR.
283        (error "~S is unbound in ~S." sym process)
284        val))))
285
286(defun (setf symbol-value-in-process) (value sym process)
287  (if (eq process *current-process*)
288    (setf (symbol-value sym) value)
289    (with-lock-grabbed (*kernel-exception-lock*)
290      (with-lock-grabbed (*kernel-tcr-area-lock*)
291        (let* ((tcr (process-tcr process)))
292          (if tcr
293            (setf (symbol-value-in-tcr sym tcr) value)
294            (%set-sym-global-value sym value)))))))
295
296
297(defmethod process-enable ((p process) &optional (wait (* 60 60 24) wait-p))
298  "Begin executing the initial function of a specified process."
299  (not-in-current-process p 'process-enable)
300  (when wait-p
301    (check-type wait (unsigned-byte 32)))
302  (unless (car (process-initial-form p))
303    (error "Process ~s has not been preset.  Use PROCESS-PRESET to preset the process." p))
304  (let* ((thread (process-thread p)))
305    (do* ((total-wait wait (+ total-wait wait)))
306         ((thread-enable thread (process-termination-semaphore p) (1- (integer-length (process-allocation-quantum p)))  wait)
307          (process-tcr-enable p (lisp-thread.tcr thread))
308          p)
309      (cerror "Keep trying."
310              "Unable to enable process ~s; have been trying for ~s seconds."
311              p total-wait))))
312
313(defmethod process-tcr-enable ((process process) tcr)
314  (when (and tcr (not (eql 0 tcr)))
315    (%signal-semaphore-ptr (%fixnum-ref-macptr tcr target::tcr.activate))
316    ))
317
318(defmethod (setf process-termination-semaphore) :after (new (p process))
319  (with-macptrs (tcrp)
320    (%setf-macptr-to-object tcrp (process-tcr p))
321    (unless (%null-ptr-p tcrp)
322      (setf (%get-ptr tcrp target::tcr.termination-semaphore)
323            (if new
324              (semaphore-value new)
325              (%null-ptr))))
326    new))
327
328(defun process-resume (p)
329  "Resume a specified process which had previously been suspended
330by process-suspend."
331  (setq p (require-type p 'process))
332  (let* ((tcr (process-tcr p)))
333    (and tcr (%resume-tcr tcr))))
334
335(defun process-suspend (p)
336  "Suspend a specified process."
337  (setq p (require-type p 'process))
338  (if (eq p *current-process*)
339    (error "Suspending the current process can't work.  ~&(If the documentation claims otherwise, it's incorrect.)")
340    (let* ((tcr (process-tcr p)))
341      (and tcr (%suspend-tcr tcr)))))
342
343(defun process-suspend-count (p)
344  "Return the number of currently-pending suspensions applicable to
345a given process."
346  (setq p (require-type p 'process))
347  (let* ((thread (process-thread p)))
348    (if thread
349      (lisp-thread-suspend-count thread))))
350
351(defun process-active-p (p)
352  (setq p (require-type p 'process))
353  (and (eql 0 (process-suspend-count p))
354       (not (process-exhausted-p p))))
355 
356;;; Used by process-run-function
357(defmethod process-preset ((p process) function &rest args)
358  "Set the initial function and arguments of a specified process."
359  (let* ((f (require-type function 'function))
360         (initial-form (process-initial-form p)))
361    (declare (type cons initial-form))
362    (not-in-current-process p 'process-preset)
363    ; Not quite right ...
364    (rplaca initial-form f)
365    (rplacd initial-form args)
366    (%process-preset-internal p)))
367
368(defmethod %process-preset-internal ((process process))
369   (let* ((initial-form (process-initial-form process))
370         (thread (process-thread process)))
371     (declare (type cons initial-form))
372     (thread-preset
373      thread
374      #'(lambda (process initial-form)
375          (let* ((*current-process* process))
376            (add-to-all-processes process)
377            (multiple-value-bind (syms values)
378                (initial-bindings (process-initial-bindings process))
379              (progv syms values
380                (setq *whostate* "Active")
381                (run-process-initial-form process initial-form)))))
382      process
383      initial-form)
384     process))
385
386
387(defun run-process-initial-form (process initial-form)
388  (let* ((exited nil)
389         (kill (handler-case
390                   (restart-case
391                    (let ((values
392                           (multiple-value-list
393                            (apply (car initial-form)
394                                   (cdr (the list initial-form)))))
395                          (result (process-result process)))
396                      (setf (cdr result) values
397                            (car result) t)
398                      (setq exited t)
399                      nil)
400                    (abort-break () :report "Reset this thread")
401                    (abort () :report "Kill this thread" (setq exited t)))
402                 (process-reset (condition)
403                   (process-reset-kill condition)))))
404    ;; We either exited from the initial form normally, were told to
405    ;; exit prematurely, or are being reset and should enter the
406    ;; "awaiting preset" state.
407    (if (or kill exited) 
408      (unless (eq kill :toplevel)
409        (process-initial-form-exited process (or kill t)))
410      (progn
411        (thread-change-state (process-thread process) :run :reset)
412        (tcr-set-preset-state (process-tcr process))))
413    nil))
414
415;;; Separated from run-process-initial-form just so I can change it easily.
416(defun process-initial-form-exited (process kill)
417  ;; Enter the *initial-process* and have it finish us up
418  (without-interrupts
419   (if (eq kill :shutdown)
420     (progn
421       (setq *whostate* "Shutdown")
422       (add-to-shutdown-processes process)))
423   (maybe-finish-process-kill process kill)))
424
425(defun maybe-finish-process-kill (process kill)
426  (when (and kill (neq kill :shutdown))
427    (setf (process-whostate process) "Dead")
428    (remove-from-all-processes process)
429    (let ((thread (process-thread process)))
430      (unless (or (eq thread *current-lisp-thread*)
431                  (thread-exhausted-p thread))
432        (kill-lisp-thread thread))))
433  nil)
434
435
436 
437
438(defun require-global-symbol (s &optional env)
439  (let* ((s (require-type s 'symbol))
440         (bits (%symbol-bits s)))
441    (unless (or (logbitp $sym_vbit_global bits)
442                (let* ((defenv (if env (definition-environment env))))
443                  (if defenv
444                    (eq :global (%cdr (assq s (defenv.specials defenv)))))))
445      (error "~s not defined with ~s" s 'defstatic))
446    s))
447
448
449(defmethod print-object ((s lock) stream)
450  (print-unreadable-object (s stream :type t :identity t)
451    (let* ((val (uvref s target::lock._value-cell))
452           (name (uvref s target::lock.name-cell)))
453      (when name
454        (format stream "~s " name))
455      (if (typep val 'macptr)
456        (format stream "[ptr @ #x~x]"
457                (%ptr-to-int val))))))
458
459(defun lockp (l)
460  (eq target::subtag-lock (typecode l)))
461
462(set-type-predicate 'lock 'lockp)
463
464(defun recursive-lock-p (l)
465  (and (eq target::subtag-lock (typecode l))
466       (eq 'recursive-lock (%svref l target::lock.kind-cell))))
467
468(defun read-write-lock-p (l)
469  (and (eq target::subtag-lock (typecode l))
470       (eq 'read-write-lock (%svref l target::lock.kind-cell))))
471
472(setf (type-predicate 'recursive-lock) 'recursive-lock-p
473      (type-predicate 'read-write-lock) 'read-write-lock-p)
474
475
476(defun grab-lock (lock &optional flag)
477  "Wait until a given lock can be obtained, then obtain it."
478  (%lock-recursive-lock-object lock flag))
479
480(defun release-lock (lock)
481  "Relinquish ownership of a given lock."
482  (%unlock-recursive-lock-object lock))
483
484(defun try-lock (lock &optional flag)
485  "Obtain the given lock, but only if it is not necessary to wait for it."
486  (%try-recursive-lock-object lock flag))
487
488(defun lock-acquisition-status (thing)
489  (if (istruct-typep thing 'lock-acquisition)
490    (lock-acquisition.status thing)
491    (report-bad-arg thing 'lock-acquisition)))
492
493(defun clear-lock-acquisition-status (thing)
494  (if (istruct-typep thing 'lock-acquisition)
495    (setf (lock-acquisition.status thing) nil)
496    (report-bad-arg thing 'lock-acquisition)))
497
498(defmethod print-object ((l lock-acquisition) stream)
499  (print-unreadable-object (l stream :type t :identity t)
500    (format stream "[status = ~s]" (lock-acquisition-status l))))
501
502(defun semaphore-notification-status (thing)
503  (if (istruct-typep thing 'semaphore-notification)
504    (semaphore-notification.status thing)
505    (report-bad-arg thing 'semaphore-notification)))
506
507(defun clear-semaphore-notification-status (thing)
508  (if (istruct-typep thing 'semaphore-notification)
509    (setf (semaphore-notification.status thing) nil)
510    (report-bad-arg thing 'semaphore-notification)))
511
512(defmethod print-object ((l semaphore-notification) stream)
513  (print-unreadable-object (l stream :type t :identity t)
514    (format stream "[status = ~s]" (semaphore-notification-status l))))
515
516(defun process-wait (whostate function &rest args)
517  "Causes the current lisp process (thread) to wait for a given
518predicate to return true."
519  (declare (dynamic-extent args))
520  (or (apply function args)
521      (with-process-whostate (whostate)
522        (loop
523          (when (apply function args)
524            (return))
525          ;; Sleep for a tick
526          #-windows-target
527          (%nanosleep 0 *ns-per-tick*)
528          #+windows-target
529          (%windows-sleep 5)))))
530
531
532
533(defun process-wait-with-timeout (whostate time function &rest args)
534  "Cause the current thread to wait for a given predicate to return true,
535or for a timeout to expire."
536  (declare (dynamic-extent args))
537  (cond ((null time)  (apply #'process-wait whostate function args) t)
538        (t (let* ((win nil)
539                  (when (+ (get-tick-count) time))
540                  (f #'(lambda () (let ((val (apply function args)))
541                                    (if val
542                                      (setq win val)
543                                      (> (get-tick-count) when))))))
544             (declare (dynamic-extent f))
545             (process-wait whostate f)
546             win))))
547
548
549(defmethod process-interrupt ((process process) function &rest args)
550  "Arrange for the target process to invoke a specified function at
551some point in the near future, and then return to what it was doing."
552  (let* ((p (require-type process 'process)))
553    (if (eq p *current-process*)
554      (progn
555        (apply function args)
556        t)
557      (thread-interrupt
558       (process-thread p)
559       process
560       #'apply
561       function args))))
562
563(defmethod process-debug-condition ((p process) condition frame-pointer)
564  (declare (ignore condition frame-pointer)))
565
566
567
568
569;;; This one is in the Symbolics documentation
570(defun process-allow-schedule ()
571  "Used for cooperative multitasking; probably never necessary."
572  (process-yield *current-process*))
573
574
575;;; something unique that users won't get their hands on
576(defun process-reset-tag (process)
577  (process-splice process))
578
579(defun process-run-function (name-or-keywords function &rest args)
580  "Create a process, preset it, and enable it."
581  (if (listp name-or-keywords)
582    (%process-run-function name-or-keywords function args)
583    (let ((keywords (list :name name-or-keywords)))
584      (declare (dynamic-extent keywords))
585      (%process-run-function keywords function args))))
586
587(defun %process-run-function (keywords function args)
588  (destructuring-bind (&key (name "Anonymous")
589                            (priority  0)
590                            (stack-size *default-control-stack-size*)
591                            (vstack-size *default-value-stack-size*)
592                            (tstack-size *default-temp-stack-size*)
593                            (initial-bindings ())
594                            (persistent nil)
595                            (use-standard-initial-bindings t)
596                            (termination-semaphore nil)
597                            (allocation-quantum (default-allocation-quantum)))
598                      keywords
599    (setq priority (require-type priority 'fixnum))
600    (let* ((process (make-process name
601                                  :priority priority
602                                  :stack-size stack-size
603                                  :vstack-size vstack-size
604                                  :tstack-size tstack-size
605                                  :persistent persistent
606                                  :use-standard-initial-bindings use-standard-initial-bindings
607                                  :initial-bindings initial-bindings
608                                  :termination-semaphore termination-semaphore
609                                  :allocation-quantum allocation-quantum)))
610      (process-preset process #'(lambda () (apply function args)))
611      (process-enable process)
612      process)))
613
614(defmethod process-reset ((process process) &optional kill)
615  "Cause a specified process to cleanly exit from any ongoing computation."
616  (setq process (require-type process 'process))
617  (unless (memq kill '(nil :kill :shutdown))
618    (setq kill (require-type kill '(member nil :kill :shutdown))))
619  (if (eq process *current-process*)
620    (%process-reset kill)
621    (if (process-exhausted-p process)
622      (maybe-finish-process-kill process kill)
623      (progn
624        (process-interrupt process '%process-reset kill)))))
625
626(defmethod process-yield ((p process))
627  #+windows-target (#_Sleep 0)
628  #-windows-target (#_sched_yield))
629
630
631(defun %process-reset (kill)
632  (signal 'process-reset :kill kill)
633  (maybe-finish-process-kill *current-process* kill))
634
635;;; By default, it's just fine with the current process
636;;; if the application/user wants to quit.
637(defmethod process-verify-quit ((process process))
638  t)
639
640(defmethod process-exit-application ((process process) thunk)
641  (when (eq process *initial-process*)
642    (prepare-to-quit)
643    (%set-toplevel thunk)
644    (fresh-line *stdout*)
645    (finish-output *stdout*)
646    (toplevel)))
647
648
649
650(defmethod process-kill ((process process))
651  "Cause a specified process to cleanly exit from any ongoing
652computation, and then exit."
653  (and (process-interrupt process #'%process-reset :kill)
654       (setf (process-kill-issued process) t)))
655
656(defun process-abort (process &optional condition)
657  "Cause a specified process to process an abort condition, as if it
658had invoked abort."
659  (process-interrupt process
660                     #'(lambda ()
661                         (abort condition))))
662
663(defmethod process-reset-and-enable ((process process))
664  (not-in-current-process process 'process-reset-and-enable)
665  (process-reset process)
666  (process-enable process))
667
668(defmethod process-kill-issued ((process process))
669  (cdr (process-splice process)))
670
671(defmethod (setf process-kill-issued) (val (process process))
672  (setf (cdr (process-splice process)) val))
673
674(defun tcr->process (tcr)
675  (dolist (p (all-processes))
676    (when (eq tcr (process-tcr p))
677      (return p))))
678
679(defun current-process-allocation-quantum ()
680  (process-allocation-quantum *current-process*))
681
682(defun (setf current-process-allocation-quantum) (new)
683  (if (valid-allocation-quantum-p new)
684    (with-macptrs (tcrp)
685      (%setf-macptr-to-object tcrp (%current-tcr))
686      (setf (slot-value *current-process* 'allocation-quantum) new
687            (%get-natural tcrp target::tcr.log2-allocation-quantum)
688            (1- (integer-length new)))
689      new)
690    (report-bad-arg new '(satisfies valid-allocation-quantum-p))))
691
692
693(def-standard-initial-binding *backtrace-contexts* nil)
694
695(defmethod exit-interactive-process ((p process))
696  (unless (eq p *initial-process*)
697    (when (eq p *current-process*)
698      (process-kill p))))
699
700(defclass tty-listener (process)
701    ())
702
703(defmethod exit-interactive-process ((p tty-listener))
704  (when (eq p *current-process*)
705    (quit)))
706
707(defmethod process-stop-dribbling ((p process))
708  (with-slots (dribble-stream dribble-saved-terminal-io) p
709    (when dribble-stream
710      (close dribble-stream)
711      (setq dribble-stream nil))
712    (when dribble-saved-terminal-io
713      (setq *terminal-io* dribble-saved-terminal-io
714            dribble-saved-terminal-io nil))))
715
716(defmethod process-dribble ((p process) path)
717  (with-slots (dribble-stream dribble-saved-terminal-io) p
718    (process-stop-dribbling p)
719    (when path
720      (let* ((in (two-way-stream-input-stream *terminal-io*))
721             (out (two-way-stream-output-stream *terminal-io*))
722             (f (open path :direction :output :if-exists :append 
723                      :if-does-not-exist :create)))
724        (without-interrupts
725         (setq dribble-stream f
726               dribble-saved-terminal-io *terminal-io*
727               *terminal-io* (make-echoing-two-way-stream
728                              (make-echo-stream in f)
729                              (make-broadcast-stream out f)))))
730      path)))
731
732(defmethod join-process ((p process) &key default)
733  (wait-on-semaphore (process-termination-semaphore p) nil "join-process")
734  (let ((result (process-result p)))
735    (cond ((car result) (values-list (cdr result)))
736          (t default))))
737
738
Note: See TracBrowser for help on using the repository browser.