source: trunk/source/level-1/l1-error-system.lisp @ 8603

Last change on this file since 8603 was 8603, checked in by gb, 12 years ago

Stream I/O deadline changes, based on patch from Hans Hubner.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 51.8 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;;; This file contains the error/condition system.  Functions that
19;;; signal/handle errors are defined later.
20
21(in-package "CCL")
22
23;;;***********************************
24;;; Error System
25;;;***********************************
26
27(defclass condition () ())
28(defclass warning (condition) ())
29(defclass serious-condition (condition) ())
30(defclass error (serious-condition) ())
31
32(define-condition simple-condition (condition)
33  ((format-control :initarg :format-control
34                  :reader simple-condition-format-control)
35   (format-arguments :initarg :format-arguments
36                     :initform nil
37                     :reader simple-condition-format-arguments))
38  (:report (lambda (c stream)  ;; If this were a method, slot value might be faster someday.  Accessors always faster ?
39                               ;; And of course it's terribly important that this be as fast as humanly possible...
40            ;Use accessors because they're documented and users can specialize them.
41            (apply #'format stream (simple-condition-format-control c)
42                   (simple-condition-format-arguments c)))))
43
44
45(define-condition storage-condition (serious-condition) ())
46
47(define-condition thread-condition (serious-condition) ())
48
49(define-condition process-reset (thread-condition)
50  ((kill :initarg :kill :initform nil :reader process-reset-kill)))
51
52
53(define-condition print-not-readable (error)
54  ((object :initarg :object :reader print-not-readable-object)
55   (stream :initarg :stream :reader print-not-readable-stream))
56  (:report (lambda (c stream)
57             (let* ((*print-readably* nil))
58               (format stream "Attempt to print object ~S on stream ~S ."
59                       (print-not-readable-object c)
60                       (print-not-readable-stream c))))))
61
62(define-condition simple-warning (simple-condition warning))
63
64(define-condition compiler-warning (warning)
65  ((file-name :initarg :file-name :initform nil :accessor compiler-warning-file-name)
66   (stream-position :initform nil :accessor compiler-warning-stream-position)
67   (function-name :initarg :function-name :initform nil :accessor compiler-warning-function-name)
68   (warning-type :initarg :warning-type :reader compiler-warning-warning-type)
69   (args :initarg :args :reader compiler-warning-args)
70   (nrefs :initform 1 :accessor compiler-warning-nrefs))
71  (:report report-compiler-warning))
72
73(define-condition style-warning (compiler-warning))
74(define-condition undefined-function-reference (style-warning))
75(define-condition macro-used-before-definition (compiler-warning))
76(define-condition invalid-arguments (style-warning))
77(define-condition invalid-arguments-global (style-warning))
78
79(define-condition simple-error (simple-condition error))
80
81(define-condition simple-storage-condition (simple-condition storage-condition))
82(define-condition stack-overflow-condition (simple-storage-condition))
83
84(define-condition invalid-memory-access (storage-condition)
85  ((address :initarg :address)
86   (write-p :initform nil :initarg :write-p))
87  (:report (lambda (c s)
88             (with-slots (address write-p) c
89               (format s "Fault during ~a memory address #x~x" (if write-p "write to" "read of") address)))))
90 
91(define-condition type-error (error)
92  ((datum :initarg :datum)
93   (expected-type :initarg :expected-type :reader type-error-expected-type)
94   (format-control :initarg :format-control  :initform (%rsc-string  $xwrongtype) :reader type-error-format-control))
95  (:report (lambda (c s)
96             (format s (type-error-format-control c)
97                     (type-error-datum c) 
98                     (type-error-expected-type c)))))
99
100(define-condition bad-slot-type (type-error)
101  ((slot-definition :initform nil :initarg :slot-definition)
102   (instance :initform nil :initarg :instance))
103  (:report (lambda (c s)
104             (format s "The value ~s can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
105                     (type-error-datum c)
106                     (slot-definition-name (slot-value c 'slot-definition))
107                     (slot-value c 'instance)
108                     (type-error-expected-type c)))))
109
110(define-condition bad-slot-type-from-initform (bad-slot-type)
111  ()
112  (:report (lambda (c s)
113             (let* ((slotd (slot-value c 'slot-definition)))
114               (format s "The value ~s, derived from the initform ~s, can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
115                     (type-error-datum c)
116                     (slot-definition-initform slotd)
117                     (slot-definition-name slotd)
118                     (slot-value c 'instance)
119                     (type-error-expected-type c))))))
120
121(define-condition bad-slot-type-from-initarg (bad-slot-type)
122  ((initarg-name :initarg :initarg-name))
123  (:report (lambda (c s)
124             (let* ((slotd (slot-value c 'slot-definition)))
125               (format s "The value ~s, derived from the initarg ~s, can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
126                     (type-error-datum c)
127                     (slot-value c 'initarg-name)
128                     (slot-definition-name slotd)
129                     (slot-value c 'instance)
130                     (type-error-expected-type c))))))
131 
132
133(define-condition improper-list (type-error)
134  ((expected-type :initform '(satisfies proper-list-p) :reader type-error-expected-type)))
135
136(define-condition cant-construct-arglist (improper-list)
137  ())
138
139
140
141(let* ((magic-token '("Unbound")))
142  (defmethod type-error-datum ((c type-error))
143    (let* ((datum-slot (slot-value c 'datum)))
144      (if (eq magic-token datum-slot)
145        (%unbound-marker-8)
146        datum-slot)))
147
148; do we need this
149  (defun signal-type-error (datum expected &optional (format-string (%rsc-string  $xwrongtype)))
150    (let ((error #'error))
151      (funcall error (make-condition 'type-error
152                                     :format-control format-string
153                                     :datum (if (eq datum (%unbound-marker-8)) magic-token datum)
154                                     :expected-type (%type-error-type expected)))))
155)
156
157
158(define-condition sequence-index-type-error (type-error)
159  ((sequence :initarg :sequence))
160  (:report (lambda (c s)
161             (format s "~s is not a valid sequence index for ~s"
162                     (type-error-datum c)
163                     (slot-value c 'sequence)))))
164
165
166;;; This is admittedly sleazy; ANSI CL requires TYPE-ERRORs to be
167;;; signalled in cases where a type-specifier is not of an appropriate
168;;; subtype.  The sleazy part is whether it's right to overload TYPE-ERROR
169;;; like this.
170
171(define-condition invalid-subtype-error (type-error)
172  ()
173  (:report (lambda (c s)
174             (format s "The type specifier ~S is not determinably a subtype of the type ~S"
175                     (type-error-datum c)
176                     (type-error-expected-type c)))))
177
178(define-condition simple-type-error (simple-condition type-error))
179
180
181
182(define-condition program-error (error))
183(define-condition simple-program-error (simple-condition program-error)
184  ((context :initarg :context :reader simple-program-error-context :initform nil)))
185
186(defun signal-program-error (string &rest args)
187  (let* ((e #'error))
188    (funcall e
189             (make-condition 'simple-program-error
190                             :format-control (if (fixnump string) (%rsc-string string) string)
191                             :format-arguments args))))
192
193(define-condition simple-destructuring-error (simple-program-error))
194
195(define-condition wrong-number-of-arguments (program-error)
196  ((nargs :initform nil
197          :initarg :nargs :reader wrong-number-of-arguments-nargs)
198   (fn :initform nil :initarg :fn :reader wrong-number-of-arguments-fn))
199  (:report report-argument-mismatch))
200       
201(define-condition too-many-arguments (wrong-number-of-arguments))
202
203(define-condition too-few-arguments (wrong-number-of-arguments))
204
205(defun report-argument-mismatch (c s)
206  (let* ((nargs-provided (wrong-number-of-arguments-nargs c))
207         (fn (wrong-number-of-arguments-fn c))
208         (too-many (typep c 'too-many-arguments)))
209    (multiple-value-bind (min max scaled-nargs)
210        (min-max-actual-args fn nargs-provided)
211      (if (not min)
212        (progn
213          (format s "Function ~s called with too ~a arguments. "
214                  fn
215                  (if too-many
216                    "many"
217                    "few")))
218        (if too-many
219          (format s "Too many arguments in call to ~s:~&~d arguments provided, at most ~d accepted. " fn scaled-nargs max)
220          (format s "Too few arguments in call to ~s:~&~d arguments provided, at least ~d required. " fn  scaled-nargs min))))))
221
222
223
224(define-condition compile-time-program-error (simple-program-error)
225  nil ;((context :initarg :context :reader compile-time-program-error-context))
226  (:report
227   (lambda (c s)
228     (format s "While compiling ~a :~%~a" 
229             (simple-program-error-context c)
230             (apply #'format nil (simple-condition-format-control c) (simple-condition-format-arguments c))))))
231
232
233
234;;; Miscellaneous error during compilation (caused by macroexpansion, transforms, compile-time evaluation, etc.)
235;;; NOT program-errors.
236(define-condition compile-time-error (simple-error)
237  ((context :initarg :context :reader compile-time-error-context))
238  (:report
239   (lambda (c s)
240     (format s "While compiling ~a :~%~a" 
241             (compile-time-error-context c)
242             (format nil "~a" c)))))
243
244(define-condition control-error (error))
245
246(define-condition cant-throw-error (control-error)
247  ((tag :initarg :tag))
248  (:report (lambda (c s)
249             (format s "Can't throw to tag ~s" (slot-value c 'tag)))))
250
251(define-condition inactive-restart (control-error)
252  ((restart-name :initarg :restart-name))
253  (:report (lambda (c s)
254             (format s "Restart ~s is not active" (slot-value c 'restart-name)))))
255
256(define-condition lock-protocol-error (control-error)
257  ((lock :initarg :lock)))
258
259(define-condition not-lock-owner (lock-protocol-error)
260  ()
261  (:report (lambda (c s)
262             (format s "Current process ~s does not own lock ~s"
263                     *current-process* (slot-value c 'lock)))))
264
265(define-condition not-locked (lock-protocol-error)
266  ()
267  (:report (lambda (c s)
268             (format s "Lock ~s isn't locked." (slot-value c 'lock)))))
269
270(define-condition deadlock (lock-protocol-error)
271  ()
272  (:report (lambda (c s)
273             (format s "Requested operation on ~s would cause deadlock." (slot-value c 'lock)))))
274
275(define-condition package-error (error)
276  ((package :initarg :package :reader package-error-package)))
277(define-condition no-such-package (package-error)
278  ()
279  (:report (lambda (c s) (format s (%rsc-string $xnopkg) (package-error-package c)))))
280(define-condition unintern-conflict-error (package-error)
281  ((sym-to-unintern :initarg :sym)
282   (conflicting-syms :initarg :conflicts))
283  (:report (lambda (c s)
284             (format s (%rsc-string $xunintc) (slot-value c 'sym-to-unintern) (package-error-package c) (slot-value c 'conflicting-syms)))))
285
286(define-condition import-conflict-error (package-error)
287  ((imported-sym :initarg :imported-sym)
288   (conflicting-sym :initarg :conflicting-sym)
289   (conflict-external-p :initarg :conflict-external))
290  (:report (lambda (c s)
291             (format s (%rsc-string (if (slot-value c 'conflict-external-p) $ximprtcx $ximprtc))
292                     (slot-value c 'imported-sym)
293                     (package-error-package c)
294                     (slot-value c 'conflicting-sym)))))
295
296(define-condition use-package-conflict-error (package-error)
297  ((package-to-use :initarg :package-to-use)
298   (conflicts :initarg :conflicts)
299   (external-p :initarg :external-p))
300  (:report (lambda (c s)
301             (format s (%rsc-string (if (slot-value c 'external-p) $xusecX $xusec))
302                     (slot-value c 'package-to-use)
303                     (package-error-package c)
304                     (slot-value c 'conflicts)))))
305
306(define-condition export-conflict-error (package-error)
307  ((conflicts :initarg :conflicts))
308  (:report 
309   (lambda (c s)
310     (format s "Name conflict~p detected by ~A :" (length (slot-value c 'conflicts)) 'export)
311     (let* ((package (package-error-package c)))
312       (dolist (conflict (slot-value c 'conflicts))
313         (destructuring-bind (inherited-p sym-to-export using-package conflicting-sym) conflict
314           (format s "~&~A'ing ~S from ~S would cause a name conflict with ~&~
315                      the ~a symbol ~S in the package ~s, which uses ~S."
316                   'export 
317                   sym-to-export 
318                   package 
319                   (if inherited-p "inherited" "present")
320                   conflicting-sym
321                   using-package
322                   package)))))))
323
324(define-condition export-requires-import (package-error)
325  ((to-be-imported :initarg :to-be-imported))
326  (:report
327   (lambda (c s)
328     (let* ((p (package-error-package c)))
329       (format s "The following symbols need to be imported to ~S before they can be exported ~& from that package:~%~s:" p (slot-value c 'to-be-imported) p)))))
330
331
332(define-condition package-name-conflict-error (package-error simple-error) ())
333
334(define-condition package-is-used-by (package-error)
335  ((using-packages :initarg :using-packages))
336  (:report (lambda (c s)
337             (format s "~S is used by ~S" (package-error-package c)
338                     (slot-value c 'using-packages)))))
339
340(define-condition symbol-name-not-accessible (package-error)
341  ((symbol-name :initarg :symbol-name))
342  (:report (lambda (c s)
343             (format s "No aymbol named ~S is accessible in package ~s"
344                     (slot-value c 'symbol-name)
345                     (package-error-package c)))))
346
347(define-condition stream-error (error)
348  ((stream :initarg :stream :reader stream-error-stream)))
349
350(defun stream-error-context (condition)
351  (let* ((stream (stream-error-stream condition)))
352    (with-output-to-string (s)
353       (format s "on ~s" stream)
354       (let* ((pos (ignore-errors (stream-position stream))))
355         (when pos
356           (format s ", near position ~d" pos)))
357       (let* ((surrounding (stream-surrounding-characters stream)))
358         (when surrounding
359           (format s ", within ~s" surrounding))))))
360
361(define-condition parse-error (error) ())
362(define-condition parse-integer-not-integer-string (parse-error)
363  ((string :initarg :string))
364  (:report (lambda (c s)
365             (format s "Not an integer string: ~s" (slot-value c 'string)))))
366
367(define-condition reader-error (parse-error stream-error) ())
368(define-condition end-of-file (stream-error) ()
369  (:report (lambda (c s)
370             (format s "Unexpected end of file ~a" (stream-error-context c)))))
371
372(define-condition io-timeout (stream-error)
373  ())
374
375(define-condition input-timeout (io-timeout)
376  ()
377  (:report (lambda (c s)
378             (format s "Input timeout on ~s" (stream-error-stream c)))))
379(define-condition output-timeout (io-timeout)
380  ()
381  (:report (lambda (c s)
382             (format s "Output timeout on ~s" (stream-error-stream c)))))
383(define-condition communication-deadline-expired (io-timeout)
384  ()
385  (:report (lambda (c s)
386             (format s "Communication deadline timeout on ~s" (stream-error-stream c)))))
387 
388
389
390
391(define-condition impossible-number (reader-error)
392  ((token :initarg :token :reader impossible-number-token)
393   (condition :initarg :condition :reader impossible-number-condition))
394  (:report (lambda (c s)
395             (format s "Condition of type ~s raised ~&while trying to parse numeric token ~s ~&~s"
396                     (type-of (impossible-number-condition c))
397                     (impossible-number-token c)
398                     (stream-error-context c)))))
399
400
401   
402(define-condition simple-stream-error (stream-error simple-condition) () 
403  (:report (lambda (c s) 
404             (format s "~a : ~&~a" (stream-error-context c) 
405                     (apply #'format
406                            nil
407                            (simple-condition-format-control c)
408                            (simple-condition-format-arguments c))))))
409
410
411
412
413(define-condition file-error (error)
414  ((pathname :initarg :pathname :initform "<unspecified>" :reader file-error-pathname)
415   (error-type :initarg :error-type :initform "File error on file ~S"))
416  (:report (lambda (c s)
417              (format s (slot-value c 'error-type) 
418                     (file-error-pathname c)))))
419
420(define-condition simple-file-error (simple-condition file-error)
421  ()
422  (:report (lambda (c s)
423             (apply #'format s (slot-value c 'error-type) 
424                    (file-error-pathname c)
425                    (simple-condition-format-arguments c)))))
426
427
428(define-condition namestring-parse-error (error)
429  ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
430   (arguments :reader namestring-parse-error-arguments :initarg :arguments
431              :initform nil)
432   (namestring :reader namestring-parse-error-namestring :initarg :namestring)
433   (offset :reader namestring-parse-error-offset :initarg :offset))
434  (:report (lambda (condition stream) 
435  (format stream "Parse error in namestring: ~?~%  ~A~%  ~V@T^"
436          (namestring-parse-error-complaint condition)
437          (namestring-parse-error-arguments condition)
438          (namestring-parse-error-namestring condition)
439          (namestring-parse-error-offset condition)))))
440
441(define-condition cell-error (error)
442  ((name :initarg :name :reader cell-error-name)
443   (error-type :initarg :error-type :initform "Cell error" :reader cell-error-type))
444  (:report (lambda (c s) (format s "~A: ~S" (cell-error-type c) (cell-error-name c)))))
445
446(define-condition unbound-variable (cell-error)
447  ((error-type :initform "Unbound variable")))
448
449(define-condition undefined-function (cell-error)
450  ((error-type :initform "Undefined function")))
451(define-condition undefined-function-call (control-error undefined-function)
452  ((function-arguments :initarg :function-arguments :reader undefined-function-call-arguments))
453  (:report (lambda (c s) (format s "Undefined function ~S called with arguments ~:S ."
454                                 (cell-error-name c)
455                                 (undefined-function-call-arguments c)))))
456
457(define-condition call-special-operator-or-macro (undefined-function-call)
458  ()
459  (:report (lambda (c s) (format s "Special operator or global macro-function ~s can't be FUNCALLed or APPLYed" (cell-error-name c)))))
460
461 
462(define-condition unbound-slot (cell-error)
463  ((instance :initarg :instance :accessor unbound-slot-instance))
464  (:report (lambda (c s) (format s "Slot ~s is unbound in ~s"
465                                 (cell-error-name c)
466                                 (unbound-slot-instance c)))))
467 
468
469(define-condition arithmetic-error (error) 
470  ((operation :initform nil :initarg :operation :reader arithmetic-error-operation)
471   (operands :initform nil :initarg :operands :reader arithmetic-error-operands)
472   (status :initform nil :initarg :status :reader arithmetic-error-status))
473  (:report (lambda (c s)
474             (format s "~S detected" (type-of c))
475             (let* ((operands (arithmetic-error-operands c)))
476               (when operands
477                 (format s "~&performing ~A on ~:S"
478                         (arithmetic-error-operation c) 
479                         operands))))))
480
481(define-condition division-by-zero (arithmetic-error))
482 
483(define-condition floating-point-underflow (arithmetic-error))
484(define-condition floating-point-overflow (arithmetic-error))
485(define-condition floating-point-inexact (arithmetic-error))
486(define-condition floating-point-invalid-operation (arithmetic-error))
487
488(define-condition compiler-bug (simple-error)
489  ()
490  (:report (lambda (c stream)
491                  (format stream "Compiler bug or inconsistency:~%")
492                  (apply #'format stream (simple-condition-format-control c)
493                         (simple-condition-format-arguments c)))))
494                         
495(defun restartp (thing) 
496  (istruct-typep thing 'restart))
497(setf (type-predicate 'restart) 'restartp)
498
499(defmethod print-object ((restart restart) stream)
500  (let ((report (%restart-report restart)))
501    (cond ((or *print-escape* (null report))
502           (print-unreadable-object (restart stream :identity t)
503             (format stream "~S ~S"
504                     'restart (%restart-name restart))))
505          ((stringp report)
506           (write-string report stream))
507          (t
508           (funcall report stream)))))
509
510(defun %make-restart (name action report interactive test)
511  (%cons-restart name action report interactive test))
512
513(defun make-restart (vector name action-function &key report-function interactive-function test-function)
514  (unless vector (setq vector (%cons-restart nil nil nil nil nil)))
515  (setf (%restart-name vector) name
516        (%restart-action vector) (require-type action-function 'function)
517        (%restart-report vector) (if report-function (require-type report-function 'function))
518        (%restart-interactive vector) (if interactive-function (require-type interactive-function 'function))
519        (%restart-test vector) (if test-function (require-type test-function 'function)))
520  vector)
521
522(defun restart-name (restart)
523  "Return the name of the given restart object."
524  (%restart-name (require-type restart 'restart)))
525
526(defun applicable-restart-p (restart condition)
527  (let* ((pair (if condition (assq restart *condition-restarts*)))
528         (test (%restart-test restart)))
529    (and (or (null pair) (eq (%cdr pair) condition))
530         (or (null test) (funcall test condition)))))
531
532(defun compute-restarts (&optional condition &aux restarts)
533  "Return a list of all the currently active restarts ordered from most
534   recently established to less recently established. If CONDITION is
535   specified, then only restarts associated with CONDITION (or with no
536   condition) will be returned."
537  (dolist (cluster %restarts% (nreverse restarts))
538    (dolist (restart cluster)
539      (when (applicable-restart-p restart condition)
540        (push restart restarts)))))
541
542(defun find-restart (name &optional condition)
543  "Return the first active restart named NAME. If NAME names a
544   restart, the restart is returned if it is currently active. If no such
545   restart is found, NIL is returned. It is an error to supply NIL as a
546   name. If CONDITION is specified and not NIL, then only restarts
547   associated with that condition (or with no condition) will be
548   returned."
549  (dolist (cluster %restarts%)
550    (dolist (restart cluster)
551      (when (and (or (eq restart name) (eq (restart-name restart) name))
552                 (applicable-restart-p restart condition))
553        (return-from find-restart restart)))))
554
555(defun %active-restart (name)
556  (dolist (cluster %restarts%)
557    (dolist (restart cluster)
558      (let* ((rname (%restart-name restart))
559             (rtest (%restart-test restart)))
560        (when (and (or (eq restart name) (eq rname name))
561                   (or (null rtest) (funcall rtest nil)))
562          (return-from %active-restart (values restart cluster))))))
563  (error 'inactive-restart :restart-name name))
564
565(defun invoke-restart (restart &rest values)
566  "Calls the function associated with the given restart, passing any given
567   arguments. If the argument restart is not a restart or a currently active
568   non-nil restart name, then a CONTROL-ERROR is signalled."
569  (multiple-value-bind (restart tag) (%active-restart restart)
570    (let ((fn (%restart-action restart)))
571      (cond ((null fn)                  ; simple restart
572             (unless (null values) (%err-disp $xtminps))
573             (throw tag nil))
574            ((fixnump fn)               ; restart case
575             (throw tag (cons fn values)))
576            ((functionp fn)             ; restart bind
577             (apply fn values))         
578            (t                          ; with-simple-restart
579             (throw tag (values nil t)))))))
580
581(defun invoke-restart-no-return (restart)
582  (invoke-restart restart)
583  (error 'restart-failure :restart restart))
584
585(defun invoke-restart-interactively (restart)
586  "Calls the function associated with the given restart, prompting for any
587   necessary arguments. If the argument restart is not a restart or a
588   currently active non-NIL restart name, then a CONTROL-ERROR is signalled."
589  (let* ((restart (find-restart restart)))
590    (format *error-output* "~&Invoking restart: ~a~&" restart)
591    (let* ((argfn (%restart-interactive restart))
592           (values (when argfn (funcall argfn))))
593      (apply #'invoke-restart restart values))))
594
595
596
597(defun maybe-invoke-restart (restart value condition)
598  (let ((restart (find-restart restart condition)))
599    (when restart (invoke-restart restart value))))
600
601(defun use-value (value &optional condition)
602  "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
603   none exists."
604  (maybe-invoke-restart 'use-value value condition))
605
606(defun store-value (value &optional condition)
607  "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
608   none exists."
609  (maybe-invoke-restart 'store-value value condition))
610
611(defun condition-arg (thing args type)
612  (cond ((condition-p thing) (if args (%err-disp $xtminps) thing))
613        ((symbolp thing) (apply #'make-condition thing args))
614        (t (make-condition type :format-control thing :format-arguments args))))
615
616(defun make-condition (name &rest init-list)
617  "Make an instance of a condition object using the specified initargs."
618  (declare (dynamic-extent init-list))
619  (if (subtypep name 'condition)
620    (apply #'make-instance name init-list)
621    (error "~S is not a defined condition type name" name)))
622
623(defmethod print-object ((c condition) stream)
624  (if *print-escape* 
625    (call-next-method)
626    (report-condition c stream)))
627
628(defmethod report-condition ((c condition) stream)
629  (princ (cond ((typep c 'error) "Error ")
630               ((typep c 'warning) "Warning ")
631               (t "Condition "))
632         stream)
633  ;Here should dump all slots or something.  For now...
634  (let ((*print-escape* t))
635    (print-object c stream)))
636
637(defun signal-simple-condition (class-name format-string &rest args)
638  (let ((e #'error))  ; Never-tail-call.
639    (funcall e (make-condition class-name :format-control format-string :format-arguments args))))
640
641(defun signal-simple-program-error (format-string &rest args)
642  (apply #'signal-simple-condition 'simple-program-error format-string args))
643
644;;getting the function name for error functions.
645
646
647(defun %last-fn-on-stack (&optional (number 0) (s (%get-frame-ptr)))
648  (let* ((fn nil))
649    (let ((p s))
650      (dotimes (i number)
651        (declare (fixnum i))
652        (unless (setq p (parent-frame p nil))
653          (return)))
654      (do* ((i number (1+ i)))
655           ((null p))
656        (if (setq fn (cfp-lfun p))
657          (return (values fn i))
658          (setq p (parent-frame p nil)))))))
659 
660(defun %err-fn-name (lfun)
661  "given an lfun returns the name or the string \"Unknown\""
662  (if (lfunp lfun) (or (lfun-name lfun) lfun)
663     (or lfun "Unknown")))
664
665(defun %real-err-fn-name (error-pointer)
666  (multiple-value-bind (fn p) (%last-fn-on-stack 0 error-pointer)
667    (let ((name (%err-fn-name fn)))
668      (if (and (memq name '( call-check-regs)) p)
669        (%err-fn-name (%last-fn-on-stack (1+ p) error-pointer))
670        name))))
671
672
673;; Some simple restarts for simple error conditions.  Callable from the kernel.
674
675(defun find-unique-homonym (name &optional test)
676  (let ((pname (and name (symbolp name) (symbol-name name)))
677        (other-name nil))
678    (dolist (pkg (list-all-packages) other-name)
679      (let ((candidate (find-symbol pname pkg)))
680        (when (and candidate
681                   (not (eq candidate name))
682                   (or (null test) (funcall test candidate)))
683          (when (and other-name (neq other-name candidate))
684            (return nil)) ;; more than one, too complicated, give up
685          (setq other-name candidate))))))
686
687
688(def-kernel-restart $xvunbnd %default-unbound-variable-restarts (frame-ptr cell-name)
689  (unless *level-1-loaded*
690    (dbg cell-name))       ;  user should never see this.
691  (let ((condition (make-condition 'unbound-variable :name cell-name))
692        (other-variable (find-unique-homonym cell-name #'boundp)))
693    (flet ((new-value ()
694             (catch-cancel
695              (return-from new-value
696                           (list (read-from-string 
697                                  (get-string-from-user
698                                   (format nil "New value for ~s : " cell-name))))))
699             (continue condition))) ; force error again if cancelled, var still not set.
700      (restart-case (%error condition nil frame-ptr)
701        (continue ()
702                  :report (lambda (s) (format s "Retry getting the value of ~S." cell-name))
703                  (symbol-value cell-name))
704        (use-homonym ()
705                     :test (lambda (c) (and (or (null c) (eq c condition)) other-variable))
706                     :report (lambda (s) (format s "Use the value of ~s this time." other-variable))
707                     (symbol-value other-variable))
708        (use-value (value)
709                   :interactive new-value
710                   :report (lambda (s) (format s "Specify a value of ~S to use this time." cell-name))
711                   value)
712        (store-value (value)
713                     :interactive new-value
714                     :report (lambda (s) (format s "Specify a value of ~S to store and use." cell-name))
715                     (setf (symbol-value cell-name) value))))))
716
717(def-kernel-restart $xnopkg %default-no-package-restart (frame-ptr package-name)
718  (or (and *autoload-lisp-package*
719           (or (string-equal package-name "LISP") 
720               (string-equal package-name "USER"))
721           (progn
722             (require "LISP-PACKAGE")
723             (find-package package-name)))
724      (let* ((alias (or (%cdr (assoc package-name '(("LISP" . "COMMON-LISP")
725                                                    ("USER" . "CL-USER")) 
726                                     :test #'string-equal))
727                        (if (packagep *package*) (package-name *package*))))
728             (condition (make-condition 'no-such-package :package package-name)))
729        (flet ((try-again (p)
730                          (or (find-package p) (%kernel-restart $xnopkg p))))
731          (restart-case
732            (restart-case (%error condition nil frame-ptr)
733              (continue ()
734                        :report (lambda (s) (format s "Retry finding package with name ~S." package-name))
735                        (try-again package-name))
736              (use-value (value)
737                         :interactive (lambda () (block nil 
738                                                   (catch-cancel
739                                                    (return (list (get-string-from-user
740                                                                   "Find package named : "))))
741                                                   (continue condition)))
742                         :report (lambda (s) (format s "Find specified package instead of ~S ." package-name))
743                         (try-again value))
744              (make-nickname ()
745                             :report (lambda (s) (format s "Make ~S be a nickname for package ~S." package-name alias))
746                             (let ((p (try-again alias)))
747                               (push package-name (cdr (pkg.names p)))
748                               p)))
749            (require-lisp-package ()
750                                  :test (lambda (c)
751                                          (and (eq c condition)
752                                               (or (string-equal package-name "LISP") (string-equal package-name "USER"))))
753                                  :report (lambda (s) 
754                                            (format s "(require :lisp-package) and retry finding package ~s"
755                                                    package-name))
756                                  (require "LISP-PACKAGE")
757                                  (try-again package-name)))))))
758
759(def-kernel-restart $xunintc unintern-conflict-restarts (frame-ptr sym package conflicts)
760  (let ((condition (make-condition 'unintern-conflict-error :package package :sym sym :conflicts conflicts)))
761    (restart-case (%error condition nil frame-ptr)
762      (continue ()
763                :report (lambda (s) (format s "Try again to unintern ~s from ~s" sym package))
764                (unintern sym package))
765      (do-shadowing-import (ssym)
766                           :report (lambda (s) (format s "SHADOWING-IMPORT one of ~S in ~S." conflicts package))
767                           :interactive (lambda ()
768                                          (block nil
769                                            (catch-cancel
770                                             (return (select-item-from-list conflicts 
771                                                                            :window-title 
772                                                                            (format nil "Shadowing-import one of the following in ~s" package)
773                                                                            :table-print-function #'prin1)))
774                                            (continue condition)))
775                           (shadowing-import (list ssym) package)))))
776
777
778(def-kernel-restart $xusec blub (frame-ptr package-to-use using-package conflicts)
779  (resolve-use-package-conflict-error frame-ptr package-to-use using-package conflicts nil))
780
781(def-kernel-restart $xusecX blub (frame-ptr package-to-use using-package conflicts)
782  (resolve-use-package-conflict-error frame-ptr package-to-use using-package conflicts t))
783
784(defun resolve-use-package-conflict-error (frame-ptr package-to-use using-package conflicts external-p)
785  (let ((condition (make-condition 'use-package-conflict-error 
786                                   :package using-package
787                                   :package-to-use package-to-use
788                                   :conflicts conflicts
789                                   :external-p external-p)))
790    (flet ((external-test (&rest ignore) (declare (ignore ignore)) external-p)
791           (present-test (&rest ignore) (declare (ignore ignore)) (not external-p)))
792      (declare (dynamic-extent #'present-test #'external-test))
793      (restart-case (%error condition nil frame-ptr)
794        (continue ()
795                  :report (lambda (s) (format s "Try again to use ~s in ~s" package-to-use using-package)))
796        (resolve-by-shadowing-import (&rest shadowing-imports)
797                                     :test external-test
798                                     :interactive (lambda ()
799                                                    (mapcar #'(lambda (pair) 
800                                                                (block nil
801                                                                  (catch-cancel
802                                                                    (return (car (select-item-from-list pair
803                                                                                                        :window-title 
804                                                                                                        (format nil "Shadowing-import one of the following in ~s" using-package)
805                                                                                                        :table-print-function #'prin1))))
806                                                                  (continue condition)))
807                                                            conflicts))
808                                     :report (lambda (s) (format s "SHADOWING-IMPORT one of each pair of conflicting symbols."))
809                                     (shadowing-import shadowing-imports using-package))
810        (unintern-all ()
811                      :test present-test
812                      :report (lambda (s) (format s "UNINTERN all conflicting symbols from ~S" using-package))
813                      (dolist (c conflicts)
814                        (unintern (car c) using-package)))
815        (shadow-all ()
816                      :test present-test
817                      :report (lambda (s) (format s "SHADOW all conflicting symbols in ~S" using-package))
818                      (dolist (c conflicts)
819                        (shadow-1 using-package (car c))))
820        (resolve-by-unintern-or-shadow (&rest dispositions)
821                                       :test present-test
822                                       :interactive (lambda ()
823                                                      (mapcar #'(lambda (pair)
824                                                                  (let* ((present-sym (car pair)))
825                                                                    (block nil
826                                                                      (catch-cancel
827                                                                        (return (car (select-item-from-list (list 'shadow 'unintern) 
828                                                                                                            :window-title
829                                                                                                            (format nil "SHADOW ~S in, or UNINTERN ~S from ~S" 
830                                                                                                                    present-sym 
831                                                                                                                    present-sym
832                                                                                                                    using-package)
833                                                                                                            :table-print-function #'prin1)))
834                                                                        (continue condition)))))
835                                                              conflicts))
836                                       :report (lambda (s) (format s "SHADOW or UNINTERN the conflicting symbols in ~S." using-package))
837                                       (dolist (d dispositions)
838                                         (let* ((sym (car (pop conflicts))))
839                                           (if (eq d 'shadow)
840                                             (shadow-1 using-package sym)
841                                             (unintern sym using-package)))))))))
842
843
844(defun resolve-export-conflicts (conflicts package)
845  (let* ((first-inherited (caar conflicts))
846         (all-same (dolist (conflict (cdr conflicts) t)
847                     (unless (eq (car conflict) first-inherited) (return nil))))
848         (all-inherited (and all-same first-inherited))
849         (all-present (and all-same (not first-inherited)))
850         (condition (make-condition 'export-conflict-error
851                                    :conflicts conflicts
852                                    :package package)))
853    (flet ((check-again () 
854             (let* ((remaining-conflicts (check-export-conflicts (mapcar #'cadr conflicts) package)))
855               (if remaining-conflicts (resolve-export-conflicts remaining-conflicts package)))))
856      (restart-case (%error condition nil (%get-frame-ptr))
857        (resolve-all-by-shadowing-import-inherited 
858         ()
859         :test (lambda (&rest ignore) (declare (ignore ignore)) all-inherited)
860         :report (lambda (s) (format s "SHADOWING-IMPORT all conflicting inherited symbol(s) in using package(s)."))
861         (dolist (conflict conflicts (check-again))
862           (destructuring-bind (using-package inherited-sym) (cddr conflict)
863             (shadowing-import-1 using-package inherited-sym))))
864        (resolve-all-by-shadowing-import-exported 
865         ()
866         :test (lambda (&rest ignore) (declare (ignore ignore)) all-inherited)
867         :report (lambda (s) (format s "SHADOWING-IMPORT all conflicting symbol(s) to be exported in using package(s)."))
868         (dolist (conflict conflicts (check-again))
869           (destructuring-bind (exported-sym using-package ignore) (cdr conflict)
870             (declare (ignore ignore))
871             (shadowing-import-1 using-package exported-sym))))
872        (resolve-all-by-uninterning-present 
873         ()
874         :test (lambda (&rest ignore) (declare (ignore ignore)) all-present)
875         :report (lambda (s) (format s "UNINTERN all present conflicting symbol(s) in using package(s)."))
876         (dolist (conflict conflicts (check-again))
877           (destructuring-bind (using-package inherited-sym) (cddr conflict)
878             (unintern inherited-sym using-package))))
879        (resolve-all-by-shadowing-present 
880         ()
881         :test (lambda (&rest ignore) (declare (ignore ignore)) all-present)
882         :report (lambda (s) (format s "SHADOW all present conflicting symbol(s) in using package(s)."))
883         (dolist (conflict conflicts (check-again))
884           (destructuring-bind (using-package inherited-sym) (cddr conflict)
885             (shadow-1 using-package inherited-sym))))
886        (review-and-resolve 
887         (dispositions)
888         :report (lambda (s) (format s "Review each name conflict and resolve individually."))
889         :interactive (lambda ()
890                        (let* ((disp nil))
891                          (block b
892                            (catch-cancel
893                              (dolist (conflict conflicts (return-from b (list disp)))
894                                (destructuring-bind (inherited-p exported-sym using-package conflicting-sym) conflict
895                                  (let* ((syms (list exported-sym conflicting-sym)))
896                                    (if inherited-p
897                                      (push (list 'shadowing-import
898                                                  (select-item-from-list syms
899                                                                              :window-title 
900                                                                              (format nil "Shadowing-import one of the following in ~s" using-package)
901                                                                              :table-print-function #'prin1)
902                                                  using-package)
903                                            disp)
904                                      (let* ((selection (car (select-item-from-list syms
905                                                                                    :window-title 
906                                                                                    (format nil "Shadow ~S or unintern ~s in ~s"
907                                                                                            exported-sym 
908                                                                                            conflicting-sym using-package)
909                                                                                    :table-print-function #'prin1))))
910                                        (push (if (eq selection 'exported-sym)
911                                                (list 'shadow (list exported-sym) using-package)
912                                                (list 'unintern conflicting-sym using-package))
913                                              disp)))))))
914                            nil)))
915         (dolist (disp dispositions (check-again))
916           (apply (car disp) (cdr disp))))))))
917
918
919(def-kernel-restart $xwrongtype default-require-type-restarts (frame-ptr value typespec)
920  (setq typespec (%type-error-type typespec))
921  (let ((condition (make-condition 'type-error 
922                                   :datum value
923                                   :expected-type typespec)))
924    (restart-case (%error condition nil frame-ptr)
925      (use-value (newval)
926                 :report (lambda (s)
927                           (format s "Use a new value of type ~s instead of ~s." typespec value))
928                 :interactive (lambda ()
929                                (format *query-io* "~&New value of type ~S :" typespec)
930                                (list (read *query-io*)))
931                 (require-type newval typespec)))))
932
933(def-kernel-restart $xudfcall default-undefined-function-call-restarts (frame-ptr function-name args)
934  (unless *level-1-loaded*
935    (dbg function-name))   ; user should never see this
936  (let ((condition (make-condition 'undefined-function-call
937                                   :name function-name
938                                   :function-arguments args))
939        (other-function (find-unique-homonym function-name #'fboundp)))
940    (restart-case (%error condition nil frame-ptr)
941      (continue ()
942                :report (lambda (s) (format s "Retry applying ~S to ~S." function-name args))
943                (apply function-name args))
944      (use-homonym ()
945                   :test (lambda (c) (and (or (null c) (eq c condition)) other-function))
946                   :report (lambda (s) (format s "Apply ~s to ~S this time." other-function args))
947                   (apply other-function args))
948      (use-value (function)
949                 :interactive (lambda ()
950                                (format *query-io* "Function to apply instead of ~s :" function-name)
951                                (let ((f (read *query-io*)))
952                                  (unless (symbolp f) (setq f (eval f))) ; almost-the-right-thing (tm)
953                                  (list (coerce f 'function))))
954                 :report (lambda (s) (format s "Apply specified function to ~S this time." args))
955                 (apply function args))
956      (store-value (function)
957                   :interactive (lambda ()
958                                (format *query-io* "Function to apply as new definition of ~s :" function-name)
959                                (let ((f (read *query-io*)))
960                                  (unless (symbolp f) (setq f (eval f))) ; almost-the-right-thing (tm)
961                                  (list (coerce f 'function))))
962                   :report (lambda (s) (format s "Specify a function to use as the definition of ~S." function-name))
963                   (apply (setf (symbol-function function-name) function) args)))))
964
965
966
967
968; This has to be defined fairly early (assuming, of course, that it "has" to be defined at all ...
969
970(defun ensure-value-of-type (value typespec placename &optional typename)
971  (tagbody
972    again
973    (unless (typep value typespec)
974      (let ((condition (make-condition 'type-error 
975                                       :datum value
976                                       :expected-type typespec)))
977        (if typename
978            (setf (slot-value condition 'format-control)
979                  (format nil "value ~~S is not ~A (~~S)." typename)))
980        (restart-case (%error condition nil (%get-frame-ptr))
981          (store-value (newval)
982                       :report (lambda (s)
983                                 (format s "Assign a new value of type ~a to ~s" typespec placename))
984                       :interactive (lambda ()
985                                      (format *query-io* "~&New value for ~S :" placename)
986                                      (list (eval (read))))
987                       (setq value newval)
988                       (go again))))))
989  value)
990
991;;;The Error Function
992
993(defparameter *kernel-simple-error-classes*
994  (list (cons $xcalltoofew 'simple-destructuring-error)
995        (cons $xcalltoomany 'simple-destructuring-error)
996        (cons $xstkover 'stack-overflow-condition)
997        (cons $xmemfull 'simple-storage-condition)
998        (cons $xwrongtype 'type-error) ; this one needs 2 args
999        (cons $xdivzro 'division-by-zero)
1000        (cons $xflovfl 'floating-point-overflow)
1001        (cons $xfunbnd 'undefined-function)
1002        (cons $xbadkeys 'simple-program-error)
1003        (cons $xnotfun 'call-special-operator-or-macro)
1004        (cons $xaccessnth 'sequence-index-type-error)
1005        (cons $ximproperlist 'improper-list)
1006        (cons $xnospread 'cant-construct-arglist)
1007        ))
1008
1009
1010(defparameter *simple-error-types*
1011  (vector nil 'simple-program-error 'simple-file-error))
1012
1013(defconstant $pgm-err #x10000)
1014
1015
1016
1017
1018(defparameter %type-error-typespecs%
1019  #(array
1020    bignum
1021    fixnum
1022    character
1023    integer
1024    list
1025    number
1026    sequence
1027    simple-string
1028    simple-vector
1029    string
1030    symbol
1031    macptr
1032    real
1033    cons
1034    unsigned-byte
1035    (integer 2 36)
1036    float
1037    rational
1038    ratio
1039    short-float
1040    double-float
1041    complex
1042    vector
1043    simple-base-string
1044    function
1045    (unsigned-byte 16)
1046    (unsigned-byte 8)
1047    (unsigned-byte 32)
1048    (signed-byte 32)
1049    (signed-byte 16)
1050    (signed-byte 8)
1051    base-char
1052    bit
1053    (unsigned-byte 24)                  ; (integer 0 (array-total-size-limit))
1054    (unsigned-byte 64)
1055    (signed-byte 64)
1056    (unsigned-byte 56)
1057    (simple-array double-float (* *))
1058    (simple-array single-float (* *))
1059    (mod #x110000)
1060    (array * (* *))                     ;2d array
1061    (array * (* * *))                   ;3d array
1062    (array t)
1063    (array bit)
1064    (array (signed-byte 8))
1065    (array (unsigned-byte 8))
1066    (array (signed-byte 16))
1067    (array (unsigned-byte 16))
1068    (array (signed-byte 32))
1069    (array (unsigned-byte 32))
1070    (array (signed-byte 64))
1071    (array (unsigned-byte 64))
1072    (array fixnum)
1073    (array single-float)
1074    (array double-float)
1075    (array character)
1076    (array t (* *))
1077    (array bit (* *))
1078    (array (signed-byte 8) (* *))
1079    (array (unsigned-byte 8) (* *))
1080    (array (signed-byte 16) (* *))
1081    (array (unsigned-byte 16) (* *))
1082    (array (signed-byte 32) (* *))
1083    (array (unsigned-byte 32) (* *))
1084    (array (signed-byte 64) (* *))
1085    (array (unsigned-byte 64) (* *))
1086    (array fixnum (* *))
1087    (array single-float (* *))
1088    (array double-float (* *))
1089    (array character (* *))
1090    (simple-array t (* *))
1091    (simple-array bit (* *))
1092    (simple-array (signed-byte 8) (* *))
1093    (simple-array (unsigned-byte 8) (* *))
1094    (simple-array (signed-byte 16) (* *))
1095    (simple-array (unsigned-byte 16) (* *))
1096    (simple-array (signed-byte 32) (* *))
1097    (simple-array (unsigned-byte 32) (* *))
1098    (simple-array (signed-byte 64) (* *))
1099    (simple-array (unsigned-byte 64) (* *))
1100    (simple-array fixnum (* *))
1101    (simple-array character (* *))
1102    (array t (* * *))
1103    (array bit (* * *))
1104    (array (signed-byte 8) (* * *))
1105    (array (unsigned-byte 8) (* * *))
1106    (array (signed-byte 16) (* * *))
1107    (array (unsigned-byte 16) (* * *))
1108    (array (signed-byte 32) (* * *))
1109    (array (unsigned-byte 32) (* * *))
1110    (array (signed-byte 64) (* * *))
1111    (array (unsigned-byte 64) (* * *))
1112    (array fixnum (* * *))
1113    (array single-float (* * *))
1114    (array double-float (* * *))
1115    (array character (* * *))
1116    (simple-array t (* * *))
1117    (simple-array bit (* * *))
1118    (simple-array (signed-byte 8) (* * *))
1119    (simple-array (unsigned-byte 8) (* * *))
1120    (simple-array (signed-byte 16) (* * *))
1121    (simple-array (unsigned-byte 16) (* * *))
1122    (simple-array (signed-byte 32) (* * *))
1123    (simple-array (unsigned-byte 32) (* * *))
1124    (simple-array (signed-byte 64) (* * *))
1125    (simple-array (unsigned-byte 64) (* * *))
1126    (simple-array fixnum (* * *))
1127    (simple-array single-float (* * *))
1128    (simple-array double-float (* * *))
1129    (simple-array char (* * *))
1130   
1131    ))
1132
1133
1134(defun %type-error-type (type)
1135  (if (fixnump type) 
1136    (svref %type-error-typespecs% type)
1137    type))
1138
1139(defun %typespec-id (typespec)
1140  (flet ((type-equivalent (t1 t2) (ignore-errors (and (subtypep t1 t2) (subtypep t2 t1)))))
1141    (position typespec %type-error-typespecs% :test #'type-equivalent)))
1142
1143
1144(defmethod condition-p ((x t)) nil)
1145(defmethod condition-p ((x condition)) t)
1146
1147
1148
1149(let* ((globals ()))
1150
1151  (defun %check-error-globals ()
1152    (let ((vars ())
1153          (valfs ())
1154          (oldvals ()))
1155      (dolist (g globals (values vars valfs oldvals))
1156        (destructuring-bind (sym predicate newvalf) g
1157          (let* ((boundp (boundp sym))
1158                 (oldval (if boundp (symbol-value sym) (%unbound-marker-8))))
1159          (unless (and boundp (funcall predicate oldval))
1160            (push sym vars)
1161            (push oldval oldvals)
1162            (push newvalf valfs)))))))
1163
1164  (defun check-error-global (sym checkfn newvalfn)
1165    (setq sym (require-type sym 'symbol)
1166          checkfn (require-type checkfn 'function)
1167          newvalfn (require-type newvalfn 'function))
1168    (let ((found (assq sym globals)))
1169      (if found
1170        (setf (cadr found) checkfn (caddr found) newvalfn)
1171        (push (list sym checkfn newvalfn) globals))
1172      sym))
1173)
1174
1175(check-error-global '*package* #'packagep #'(lambda () (find-package "CL-USER")))
1176
1177
1178 
1179
Note: See TracBrowser for help on using the repository browser.