source: trunk/source/level-1/l1-error-system.lisp @ 14851

Last change on this file since 14851 was 14851, checked in by rme, 8 years ago

In shadowed-typecase-clause condition: add an omitted quote
to the construct slot initform.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 59.3 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18
19;;; This file contains the error/condition system.  Functions that
20;;; signal/handle errors are defined later.
21
22(in-package "CCL")
23
24;;;***********************************
25;;; Error System
26;;;***********************************
27
28(defclass condition () ())
29(defclass warning (condition) ())
30(defclass serious-condition (condition) ())
31(defclass error (serious-condition) ())
32
33(define-condition simple-condition (condition)
34  ((format-control :initarg :format-control
35                  :reader simple-condition-format-control)
36   (format-arguments :initarg :format-arguments
37                     :initform nil
38                     :reader simple-condition-format-arguments))
39  (:report (lambda (c stream)  ;; If this were a method, slot value might be faster someday.  Accessors always faster ?
40                               ;; And of course it's terribly important that this be as fast as humanly possible...
41            ;Use accessors because they're documented and users can specialize them.
42            (apply #'format stream (simple-condition-format-control c)
43                   (simple-condition-format-arguments c)))))
44
45
46(define-condition storage-condition (serious-condition) ())
47
48(define-condition thread-condition (serious-condition) ())
49
50(define-condition process-reset (thread-condition)
51  ((kill :initarg :kill :initform nil :reader process-reset-kill)))
52
53
54(define-condition print-not-readable (error)
55  ((object :initarg :object :reader print-not-readable-object)
56   (stream :initarg :stream :reader print-not-readable-stream))
57  (:report (lambda (c stream)
58             (let* ((*print-readably* nil))
59               (format stream "Attempt to print object ~S on stream ~S ."
60                       (print-not-readable-object c)
61                       (print-not-readable-stream c))))))
62
63(define-condition simple-warning (simple-condition warning) ())
64
65(define-condition compiler-warning (warning)
66  ((function-name :initarg :function-name :initform nil :accessor compiler-warning-function-name)
67   (source-note :initarg :source-note :initform nil :accessor compiler-warning-source-note)
68   (warning-type :initarg :warning-type :reader compiler-warning-warning-type)
69   (args :initarg :args :reader compiler-warning-args)
70   (nrefs :initform () :accessor compiler-warning-nrefs))
71  (:report report-compiler-warning))
72
73;; Backward compatibility
74(defmethod compiler-warning-file-name ((w compiler-warning))
75  (source-note-filename (compiler-warning-source-note w)))
76
77(define-condition style-warning (compiler-warning)
78  ((warning-type :initform :unsure)
79   (args :initform nil)))
80(define-condition undefined-reference (style-warning) ())
81(define-condition undefined-type-reference (undefined-reference) ())
82(define-condition undefined-function-reference (undefined-reference) ())
83(define-condition macro-used-before-definition (compiler-warning) ())
84(define-condition invalid-type-warning (style-warning) ())
85(define-condition invalid-arguments (style-warning) ())
86(define-condition invalid-arguments-global (style-warning) ())
87(define-condition undefined-keyword-reference (undefined-reference invalid-arguments) ())
88(define-condition shadowed-typecase-clause (style-warning)
89  ((construct :initarg :construct :initform 'typecase)
90   (clause :initarg :clause)
91   (by :initarg :by))
92  (:report (lambda (c s)
93             (with-slots (construct clause by) c
94               (format s "Clause ~S ignored in ~S form - shadowed by ~S ."
95                       clause construct by)))))
96
97(define-condition simple-error (simple-condition error) ())
98
99(define-condition simple-storage-condition (simple-condition storage-condition) ())
100(define-condition stack-overflow-condition (simple-storage-condition) ())
101
102(define-condition invalid-memory-access (storage-condition)
103  ((address :initarg :address)
104   (write-p :initform nil :initarg :write-p))
105  (:report (lambda (c s)
106             (with-slots (address write-p) c
107               (format s "Fault during ~a memory address #x~x" (if write-p "write to" "read of") address)))))
108
109(define-condition invalid-memory-operation (storage-condition)
110  ()
111  (:report (lambda (c s)
112             (declare (ignore c))
113             (format s "Invalid memory operation."))))
114
115(define-condition write-to-watched-object (storage-condition)
116  ((object :initform nil :initarg :object
117           :reader write-to-watched-object-object)
118   (offset :initarg :offset
119           :reader write-to-watched-object-offset)
120   (instruction :initarg :instruction
121                :reader write-to-watched-object-instruction))
122  (:report report-write-to-watched-object))
123
124(defun report-write-to-watched-object (c s)
125  (with-slots (object offset instruction) c
126    (cond
127      ((uvectorp object)
128       (let* ((count (uvsize object))
129              (nbytes (if (ivectorp object)
130                        (subtag-bytes (typecode object) count)
131                        (* count target::node-size)))
132              (bytes-per-element (/ nbytes count))
133              (offset (- offset target::misc-data-offset))
134              (index (/ offset bytes-per-element)))
135         (format s "Write to watched uvector ~s at " object)
136         (if (fixnump index)
137           (format s "index ~s" index)
138           (format s "an apparently unaligned byte offset ~s" offset))))
139      ((consp object)
140       (format s "Write to ~a watched cons cell ~s"
141               (cond
142                 ((= offset target::cons.cdr) "the CDR of")
143                 ((= offset target::cons.car) "the CAR of")
144                 (t
145                  (format nil "an apparently unaligned byte offset (~s) into"
146                          offset)))
147               object))
148      (t
149       (format s "Write to a strange object ~s at byte offset ~s"
150               object offset)))
151    (when instruction
152      (format s "~&Faulting instruction: ~s" instruction))))
153
154(define-condition allocation-disabled (storage-condition)
155  ()
156  (:report (lambda (c s) (declare (ignore c)) (format s "Attempt to heap-allocate a lisp object when heap allocation is disabled."))))
157 
158
159(define-condition type-error (error)
160  ((datum :initarg :datum)
161   (expected-type :initarg :expected-type :reader type-error-expected-type)
162   (format-control :initarg :format-control  :initform (%rsc-string  $xwrongtype) :reader type-error-format-control))
163  (:report (lambda (c s)
164             (format s (type-error-format-control c)
165                     (type-error-datum c) 
166                     (type-error-expected-type c)))))
167
168(define-condition bad-slot-type (type-error)
169  ((slot-definition :initform nil :initarg :slot-definition)
170   (instance :initform nil :initarg :instance))
171  (:report (lambda (c s)
172             (format s "The value ~s can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
173                     (type-error-datum c)
174                     (slot-definition-name (slot-value c 'slot-definition))
175                     (slot-value c 'instance)
176                     (type-error-expected-type c)))))
177
178(define-condition bad-slot-type-from-initform (bad-slot-type)
179  ()
180  (:report (lambda (c s)
181             (let* ((slotd (slot-value c 'slot-definition)))
182               (format s "The value ~s, derived from the initform ~s, can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
183                     (type-error-datum c)
184                     (slot-definition-initform slotd)
185                     (slot-definition-name slotd)
186                     (slot-value c 'instance)
187                     (type-error-expected-type c))))))
188
189(define-condition bad-slot-type-from-initarg (bad-slot-type)
190  ((initarg-name :initarg :initarg-name))
191  (:report (lambda (c s)
192             (let* ((slotd (slot-value c 'slot-definition)))
193               (format s "The value ~s, derived from the initarg ~s, can not be used to set the value of the slot ~s in ~s, because it is not of type ~s. "
194                     (type-error-datum c)
195                     (slot-value c 'initarg-name)
196                     (slot-definition-name slotd)
197                     (slot-value c 'instance)
198                     (type-error-expected-type c))))))
199 
200
201(define-condition improper-list (type-error)
202  ((expected-type :initform '(satisfies proper-list-p) :reader type-error-expected-type)))
203
204(define-condition cant-construct-arglist (improper-list)
205  ())
206
207
208(let* ((magic-token '("Unbound")))
209  (defmethod type-error-datum ((c type-error))
210    (let* ((datum-slot (slot-value c 'datum)))
211      (if (eq magic-token datum-slot)
212        (%unbound-marker-8)
213        datum-slot)))
214
215; do we need this
216  (defun signal-type-error (datum expected &optional (format-string (%rsc-string  $xwrongtype)))
217    (let ((error #'error))
218      (funcall error (make-condition 'type-error
219                                     :format-control format-string
220                                     :datum (if (eq datum (%unbound-marker-8)) magic-token datum)
221                                     :expected-type (%type-error-type expected)))))
222)
223
224
225(define-condition sequence-index-type-error (type-error)
226  ((sequence :initarg :sequence))
227  (:report (lambda (c s)
228             (format s "~s is not a valid sequence index for ~s"
229                     (type-error-datum c)
230                     (slot-value c 'sequence)))))
231
232
233;;; This is admittedly sleazy; ANSI CL requires TYPE-ERRORs to be
234;;; signalled in cases where a type-specifier is not of an appropriate
235;;; subtype.  The sleazy part is whether it's right to overload TYPE-ERROR
236;;; like this.
237
238(define-condition invalid-subtype-error (type-error)
239  ()
240  (:report (lambda (c s)
241             (format s "The type specifier ~S is not determinably a subtype of the type ~S"
242                     (type-error-datum c)
243                     (type-error-expected-type c)))))
244
245(define-condition simple-type-error (simple-condition type-error) ())
246
247(define-condition array-element-type-error (simple-type-error)
248  ((array :initarg :array :reader array-element-type-error-array))
249  (:report (lambda (c s)
250             (format s (simple-condition-format-control c)
251                     (type-error-datum c)
252                     (array-element-type-error-array c)))))
253                 
254
255
256
257
258(define-condition program-error (error) ())
259(define-condition simple-program-error (simple-condition program-error)
260  ((context :initarg :context :reader simple-program-error-context :initform nil)))
261
262(define-condition invalid-type-specifier (program-error)
263  ((typespec :initarg :typespec :reader invalid-type-specifier-typespec))
264  (:report (lambda (c s)
265             (with-slots (typespec) c
266               (format s "Invalid type specifier: ~s ." typespec)))))
267
268(defun signal-program-error (string &rest args)
269  (let* ((e #'error))
270    (funcall e
271             (make-condition 'simple-program-error
272                             :format-control (if (fixnump string) (%rsc-string string) string)
273                             :format-arguments args))))
274
275(define-condition simple-destructuring-error (simple-program-error) ())
276
277(define-condition wrong-number-of-arguments (program-error)
278  ((nargs :initform nil
279          :initarg :nargs :reader wrong-number-of-arguments-nargs)
280   (fn :initform nil :initarg :fn :reader wrong-number-of-arguments-fn))
281  (:report report-argument-mismatch))
282       
283(define-condition too-many-arguments (wrong-number-of-arguments) ())
284
285(define-condition too-few-arguments (wrong-number-of-arguments) ())
286
287(defun report-argument-mismatch (c s)
288  (let* ((nargs-provided (wrong-number-of-arguments-nargs c))
289         (fn (wrong-number-of-arguments-fn c))
290         (too-many (typep c 'too-many-arguments)))
291    (multiple-value-bind (min max scaled-nargs)
292        (min-max-actual-args fn nargs-provided)
293      (if (not min)
294        (progn
295          (format s "Function ~s called with too ~a arguments. "
296                  fn
297                  (if too-many
298                    "many"
299                    "few")))
300        (if too-many
301          (format s "Too many arguments in call to ~s:~&~d argument~:p provided, at most ~d accepted. " fn scaled-nargs max)
302          (format s "Too few arguments in call to ~s:~&~d argument~:p provided, at least ~d required. " fn  scaled-nargs min))))))
303
304
305
306(define-condition compile-time-program-error (simple-program-error)
307  nil ;((context :initarg :context :reader compile-time-program-error-context))
308  (:report
309   (lambda (c s)
310     (format s "While compiling ~a :~%~a" 
311             (simple-program-error-context c)
312             (apply #'format nil (simple-condition-format-control c) (simple-condition-format-arguments c))))))
313
314
315
316;;; Miscellaneous error during compilation (caused by macroexpansion, transforms, compile-time evaluation, etc.)
317;;; NOT program-errors.
318(define-condition compile-time-error (simple-error)
319  ((context :initarg :context :reader compile-time-error-context))
320  (:report
321   (lambda (c s)
322     (format s "While compiling ~a :~%~a" 
323             (compile-time-error-context c)
324             (format nil "~a" c)))))
325
326(define-condition control-error (error) ())
327
328(define-condition cant-throw-error (control-error)
329  ((tag :initarg :tag))
330  (:report (lambda (c s)
331             (format s "Can't throw to tag ~s" (slot-value c 'tag)))))
332
333(define-condition inactive-restart (control-error)
334  ((restart-name :initarg :restart-name))
335  (:report (lambda (c s)
336             (format s "Restart ~s is not active" (slot-value c 'restart-name)))))
337
338(define-condition lock-protocol-error (control-error)
339  ((lock :initarg :lock)))
340
341(define-condition not-lock-owner (lock-protocol-error)
342  ()
343  (:report (lambda (c s)
344             (format s "Current process ~s does not own lock ~s"
345                     *current-process* (slot-value c 'lock)))))
346
347(define-condition not-locked (lock-protocol-error)
348  ()
349  (:report (lambda (c s)
350             (format s "Lock ~s isn't locked." (slot-value c 'lock)))))
351
352(define-condition deadlock (lock-protocol-error)
353  ()
354  (:report (lambda (c s)
355             (format s "Requested operation on ~s would cause deadlock." (slot-value c 'lock)))))
356
357(define-condition package-error (error)
358  ((package :initarg :package :reader package-error-package)))
359(define-condition no-such-package (package-error)
360  ()
361  (:report (lambda (c s) (format s (%rsc-string $xnopkg) (package-error-package c)))))
362(define-condition unintern-conflict-error (package-error)
363  ((sym-to-unintern :initarg :sym)
364   (conflicting-syms :initarg :conflicts))
365  (:report (lambda (c s)
366             (format s (%rsc-string $xunintc) (slot-value c 'sym-to-unintern) (package-error-package c) (slot-value c 'conflicting-syms)))))
367
368(define-condition import-conflict-error (package-error)
369  ((imported-sym :initarg :imported-sym)
370   (conflicting-sym :initarg :conflicting-sym)
371   (conflict-external-p :initarg :conflict-external))
372  (:report (lambda (c s)
373             (format s (%rsc-string (if (slot-value c 'conflict-external-p) $ximprtcx $ximprtc))
374                     (slot-value c 'imported-sym)
375                     (package-error-package c)
376                     (slot-value c 'conflicting-sym)))))
377
378(define-condition use-package-conflict-error (package-error)
379  ((package-to-use :initarg :package-to-use)
380   (conflicts :initarg :conflicts)
381   (external-p :initarg :external-p))
382  (:report (lambda (c s)
383             (format s (%rsc-string (if (slot-value c 'external-p) $xusecX $xusec))
384                     (slot-value c 'package-to-use)
385                     (package-error-package c)
386                     (slot-value c 'conflicts)))))
387
388(define-condition export-conflict-error (package-error)
389  ((conflicts :initarg :conflicts))
390  (:report 
391   (lambda (c s)
392     (format s "Name conflict~p detected by ~A :" (length (slot-value c 'conflicts)) 'export)
393     (let* ((package (package-error-package c)))
394       (dolist (conflict (slot-value c 'conflicts))
395         (destructuring-bind (inherited-p sym-to-export using-package conflicting-sym) conflict
396           (format s "~&~A'ing ~S from ~S would cause a name conflict with ~&~
397                      the ~a symbol ~S in the package ~s, which uses ~S."
398                   'export 
399                   sym-to-export 
400                   package 
401                   (if inherited-p "inherited" "present")
402                   conflicting-sym
403                   using-package
404                   package)))))))
405
406(define-condition export-requires-import (package-error)
407  ((to-be-imported :initarg :to-be-imported))
408  (:report
409   (lambda (c s)
410     (let* ((p (package-error-package c)))
411       (format s "The following symbols need to be imported to ~S before they can be exported ~& from that package:~%~s:" p (slot-value c 'to-be-imported))))))
412
413
414(define-condition package-name-conflict-error (package-error simple-error) ())
415
416(define-condition package-is-used-by (package-error)
417  ((using-packages :initarg :using-packages))
418  (:report (lambda (c s)
419             (format s "~S is used by ~S" (package-error-package c)
420                     (slot-value c 'using-packages)))))
421
422(define-condition symbol-name-not-accessible (package-error)
423  ((symbol-name :initarg :symbol-name))
424  (:report (lambda (c s)
425             (format s "No aymbol named ~S is accessible in package ~s"
426                     (slot-value c 'symbol-name)
427                     (package-error-package c)))))
428
429(define-condition stream-error (error)
430  ((stream :initarg :stream :reader stream-error-stream)))
431
432(defun stream-error-context (condition)
433  (let* ((stream (stream-error-stream condition)))
434    (with-output-to-string (s)
435       (format s "on ~s" stream)
436       (let* ((pos (ignore-errors (stream-position stream))))
437         (when pos
438           (format s ", near position ~d" pos)))
439       (let* ((surrounding (stream-surrounding-characters stream)))
440         (when surrounding
441           (format s ", within ~s" surrounding))))))
442
443(define-condition parse-error (error) ())
444(define-condition parse-integer-not-integer-string (parse-error)
445  ((string :initarg :string))
446  (:report (lambda (c s)
447             (format s "Not an integer string: ~s" (slot-value c 'string)))))
448
449(define-condition reader-error (parse-error stream-error) ())
450(define-condition end-of-file (stream-error) ()
451  (:report (lambda (c s)
452             (format s "Unexpected end of file ~a" (stream-error-context c)))))
453
454(define-condition io-timeout (stream-error)
455  ())
456
457(define-condition input-timeout (io-timeout)
458  ()
459  (:report (lambda (c s)
460             (format s "Input timeout on ~s" (stream-error-stream c)))))
461(define-condition output-timeout (io-timeout)
462  ()
463  (:report (lambda (c s)
464             (format s "Output timeout on ~s" (stream-error-stream c)))))
465(define-condition communication-deadline-expired (io-timeout)
466  ()
467  (:report (lambda (c s)
468             (format s "Communication deadline timeout on ~s" (stream-error-stream c)))))
469 
470
471
472
473(define-condition impossible-number (reader-error)
474  ((token :initarg :token :reader impossible-number-token)
475   (condition :initarg :condition :reader impossible-number-condition))
476  (:report (lambda (c s)
477             (format s "Condition of type ~s raised ~&while trying to parse numeric token ~s ~&~s"
478                     (type-of (impossible-number-condition c))
479                     (impossible-number-token c)
480                     (stream-error-context c)))))
481
482
483   
484(define-condition simple-stream-error (stream-error simple-condition) () 
485  (:report (lambda (c s) 
486             (format s "~a : ~&~a" (stream-error-context c) 
487                     (apply #'format
488                            nil
489                            (simple-condition-format-control c)
490                            (simple-condition-format-arguments c))))))
491
492
493
494
495(define-condition file-error (error)
496  ((pathname :initarg :pathname :initform "<unspecified>" :reader file-error-pathname)
497   (error-type :initarg :error-type :initform "File error on file ~S"))
498  (:report (lambda (c s)
499              (format s (slot-value c 'error-type) 
500                     (file-error-pathname c)))))
501
502(define-condition simple-file-error (simple-condition file-error)
503  ()
504  (:report (lambda (c s)
505             (apply #'format s (slot-value c 'error-type) 
506                    (file-error-pathname c)
507                    (simple-condition-format-arguments c)))))
508
509
510(define-condition namestring-parse-error (error)
511  ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
512   (arguments :reader namestring-parse-error-arguments :initarg :arguments
513              :initform nil)
514   (namestring :reader namestring-parse-error-namestring :initarg :namestring)
515   (offset :reader namestring-parse-error-offset :initarg :offset))
516  (:report (lambda (condition stream) 
517  (format stream "Parse error in namestring: ~?~%  ~A~%  ~V@T^"
518          (namestring-parse-error-complaint condition)
519          (namestring-parse-error-arguments condition)
520          (namestring-parse-error-namestring condition)
521          (namestring-parse-error-offset condition)))))
522
523(define-condition cell-error (error)
524  ((name :initarg :name :reader cell-error-name)
525   (error-type :initarg :error-type :initform "Cell error" :reader cell-error-type))
526  (:report (lambda (c s) (format s "~A: ~S" (cell-error-type c) (cell-error-name c)))))
527
528(define-condition unbound-variable (cell-error)
529  ((error-type :initform "Unbound variable")))
530
531(define-condition undefined-function (cell-error)
532  ((error-type :initform "Undefined function")))
533(define-condition undefined-function-call (control-error undefined-function)
534  ((function-arguments :initarg :function-arguments :reader undefined-function-call-arguments))
535  (:report (lambda (c s) (format s "Undefined function ~S called with arguments ~:S ."
536                                 (cell-error-name c)
537                                 (undefined-function-call-arguments c)))))
538
539(define-condition call-special-operator-or-macro (undefined-function-call)
540  ()
541  (:report (lambda (c s) (format s "Special operator or global macro-function ~s can't be FUNCALLed or APPLYed" (cell-error-name c)))))
542
543 
544(define-condition unbound-slot (cell-error)
545  ((instance :initarg :instance :accessor unbound-slot-instance))
546  (:report (lambda (c s) (format s "Slot ~s is unbound in ~s"
547                                 (cell-error-name c)
548                                 (unbound-slot-instance c)))))
549 
550
551(define-condition arithmetic-error (error) 
552  ((operation :initform nil :initarg :operation :reader arithmetic-error-operation)
553   (operands :initform nil :initarg :operands :reader arithmetic-error-operands)
554   (status :initform nil :initarg :status :reader arithmetic-error-status))
555  (:report (lambda (c s)
556             (format s "~S detected" (type-of c))
557             (let* ((operands (arithmetic-error-operands c)))
558               (when operands
559                 (format s "~&performing ~A on ~:S"
560                         (arithmetic-error-operation c) 
561                         operands))))))
562
563(define-condition division-by-zero (arithmetic-error) ())
564 
565(define-condition floating-point-underflow (arithmetic-error) ())
566(define-condition floating-point-overflow (arithmetic-error) ())
567(define-condition floating-point-inexact (arithmetic-error) ())
568(define-condition floating-point-invalid-operation (arithmetic-error) ())
569
570(define-condition compiler-bug (simple-error)
571  ()
572  (:report (lambda (c stream)
573                  (format stream "Compiler bug or inconsistency:~%")
574                  (apply #'format stream (simple-condition-format-control c)
575                         (simple-condition-format-arguments c)))))
576
577(define-condition external-process-creation-failure (serious-condition)
578  ((proc :initarg :proc))
579  (:report (lambda (c stream)
580             (with-slots (proc) c
581               (let* ((code (external-process-%exit-code proc)))
582                 (format stream "Fork failed in ~s: ~a. " proc (if (eql code -1) "random lisp error" (%strerror code))))))))
583   
584                         
585(defun restartp (thing) 
586  (istruct-typep thing 'restart))
587(setf (type-predicate 'restart) 'restartp)
588
589(defmethod print-object ((restart restart) stream)
590  (let ((report (%restart-report restart)))
591    (cond ((or *print-escape* (null report))
592           (print-unreadable-object (restart stream :identity t)
593             (format stream "~S ~S"
594                     'restart (%restart-name restart))))
595          ((stringp report)
596           (write-string report stream))
597          (t
598           (funcall report stream)))))
599
600(defun %make-restart (name action report interactive test)
601  (%cons-restart name action report interactive test))
602
603(defun make-restart (vector name action-function &key report-function interactive-function test-function)
604  (unless vector (setq vector (%cons-restart nil nil nil nil nil)))
605  (setf (%restart-name vector) name
606        (%restart-action vector) (require-type action-function 'function)
607        (%restart-report vector) (if report-function (require-type report-function 'function))
608        (%restart-interactive vector) (if interactive-function (require-type interactive-function 'function))
609        (%restart-test vector) (if test-function (require-type test-function 'function)))
610  vector)
611
612(defun restart-name (restart)
613  "Return the name of the given restart object."
614  (%restart-name (require-type restart 'restart)))
615
616(defun applicable-restart-p (restart condition)
617  (let* ((pair (if condition (assq restart *condition-restarts*)))
618         (test (%restart-test restart)))
619    (and (or (null pair) (eq (%cdr pair) condition))
620         (or (null test) (funcall test condition)))))
621
622(defun compute-restarts (&optional condition &aux restarts)
623  "Return a list of all the currently active restarts ordered from most
624   recently established to less recently established. If CONDITION is
625   specified, then only restarts associated with CONDITION (or with no
626   condition) will be returned."
627  (dolist (cluster %restarts% (nreverse restarts))
628    (dolist (restart cluster)
629      (when (applicable-restart-p restart condition)
630        (push restart restarts)))))
631
632(defun find-restart (name &optional condition)
633  "Return the first active restart named NAME. If NAME names a
634   restart, the restart is returned if it is currently active. If no such
635   restart is found, NIL is returned. It is an error to supply NIL as a
636   name. If CONDITION is specified and not NIL, then only restarts
637   associated with that condition (or with no condition) will be
638   returned."
639  (dolist (cluster %restarts%)
640    (dolist (restart cluster)
641      (when (and (or (eq restart name) (eq (restart-name restart) name))
642                 (applicable-restart-p restart condition))
643        (return-from find-restart restart)))))
644
645(defun %active-restart (name)
646  (dolist (cluster %restarts%)
647    (dolist (restart cluster)
648      (when (or (eq restart name)
649                (let* ((rname (%restart-name restart))
650                       (rtest (%restart-test restart)))
651                  (and (eq rname name)
652                       (or (null rtest) (funcall rtest nil)))))
653                (return-from %active-restart (values restart cluster)))))
654  (error 'inactive-restart :restart-name name))
655
656(defun invoke-restart (restart &rest values)
657  "Calls the function associated with the given restart, passing any given
658   arguments. If the argument restart is not a restart or a currently active
659   non-nil restart name, then a CONTROL-ERROR is signalled."
660  (multiple-value-bind (restart tag) (%active-restart restart)
661    (let ((fn (%restart-action restart)))
662      (cond ((null fn)                  ; simple restart
663             (unless (null values) (%err-disp $xtminps))
664             (throw tag nil))
665            ((fixnump fn)               ; restart case
666             (throw tag (cons fn values)))
667            ((functionp fn)             ; restart bind
668             (apply fn values))         
669            (t                          ; with-simple-restart
670             (throw tag (values nil t)))))))
671
672(defun invoke-restart-no-return (restart)
673  (invoke-restart restart)
674  (error 'restart-failure :restart restart))
675
676(defun invoke-restart-interactively (restart)
677  "Calls the function associated with the given restart, prompting for any
678   necessary arguments. If the argument restart is not a restart or a
679   currently active non-NIL restart name, then a CONTROL-ERROR is signalled."
680  (let* ((restart (find-restart restart)))
681    (format *error-output* "~&Invoking restart: ~a~&" restart)
682    (let* ((argfn (%restart-interactive restart))
683           (values (when argfn (funcall argfn))))
684      (apply #'invoke-restart restart values))))
685
686
687
688(defun maybe-invoke-restart (restart value condition)
689  (let ((restart (find-restart restart condition)))
690    (when restart (invoke-restart restart value))))
691
692(defun use-value (value &optional condition)
693  "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
694   none exists."
695  (maybe-invoke-restart 'use-value value condition))
696
697(defun store-value (value &optional condition)
698  "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
699   none exists."
700  (maybe-invoke-restart 'store-value value condition))
701
702(defun condition-arg (thing args type)
703  (cond ((condition-p thing) (if args (%err-disp $xtminps) thing))
704        ((symbolp thing) (apply #'make-condition thing args))
705        (t (make-condition type :format-control thing :format-arguments args))))
706
707(defun make-condition (name &rest init-list)
708  "Make an instance of a condition object using the specified initargs."
709  (declare (dynamic-extent init-list))
710  (if (subtypep name 'condition)
711    (apply #'make-instance name init-list)
712    (let ((class (if (classp name)
713                   name
714                   (find-class name)))) ;; elicit an error if no such class
715      (unless (class-finalized-p class)
716        (finalize-inheritance class)) ;; elicit an error if forward refs.
717      (error "~S is not a condition class" class))))
718
719(defmethod print-object ((c condition) stream)
720  (if *print-escape* 
721    (call-next-method)
722    (report-condition c stream)))
723
724(defmethod report-condition ((c condition) stream)
725  (princ (cond ((typep c 'error) "Error ")
726               ((typep c 'warning) "Warning ")
727               (t "Condition "))
728         stream)
729  ;Here should dump all slots or something.  For now...
730  (let ((*print-escape* t))
731    (print-object c stream)))
732
733(defun signal-simple-condition (class-name format-string &rest args)
734  (let ((e #'error))  ; Never-tail-call.
735    (funcall e (make-condition class-name :format-control format-string :format-arguments args))))
736
737(defun signal-simple-program-error (format-string &rest args)
738  (apply #'signal-simple-condition 'simple-program-error format-string args))
739
740;;getting the function name for error functions.
741
742
743(defun %last-fn-on-stack (&optional (number 0) (s (%get-frame-ptr)))
744  (let* ((fn nil))
745    (let ((p s))
746      (dotimes (i number)
747        (declare (fixnum i))
748        (unless (setq p (parent-frame p nil))
749          (return)))
750      (do* ((i number (1+ i)))
751           ((null p))
752        (if (setq fn (cfp-lfun p))
753          (return (values fn i))
754          (setq p (parent-frame p nil)))))))
755 
756(defun %err-fn-name (lfun)
757  "given an lfun returns the name or the string \"Unknown\""
758  (if (lfunp lfun) (or (lfun-name lfun) lfun)
759     (or lfun "Unknown")))
760
761(defun %real-err-fn-name (error-pointer)
762  (multiple-value-bind (fn p) (%last-fn-on-stack 0 error-pointer)
763    (let ((name (%err-fn-name fn)))
764      (if (and (memq name '( call-check-regs)) p)
765        (%err-fn-name (%last-fn-on-stack (1+ p) error-pointer))
766        name))))
767
768
769;; Some simple restarts for simple error conditions.  Callable from the kernel.
770
771(defun find-unique-homonyms (name &optional (test (constantly t)))
772  (delete-duplicates
773   (loop
774     with symbol = (if (consp name) (second name) name)
775     with pname = (symbol-name symbol)
776     for package in (list-all-packages)
777     for other-package-symbol = (find-symbol pname package)
778     for canditate = (and other-package-symbol
779                          (neq other-package-symbol symbol)
780                          (if (consp name)
781                            (list (first name) other-package-symbol)
782                            other-package-symbol))
783     when (and canditate
784               (funcall test canditate))
785       collect canditate)
786   :test #'equal))
787
788(def-kernel-restart $xvunbnd %default-unbound-variable-restarts (frame-ptr cell-name)
789  (unless *level-1-loaded*
790    (dbg cell-name))       ;  user should never see this.
791  (let ((condition (make-condition 'unbound-variable :name cell-name))
792        (other-variables (find-unique-homonyms cell-name (lambda (name)
793                                                           (and (not (keywordp name))
794                                                                (boundp name))))))
795    (flet ((new-value ()
796             (catch-cancel
797              (return-from new-value
798                           (list (read-from-string 
799                                  (get-string-from-user
800                                   (format nil "New value for ~s : " cell-name))))))
801             (continue condition))) ; force error again if cancelled, var still not set.
802      (restart-case (%error condition nil frame-ptr)
803        (continue ()
804                  :report (lambda (s) (format s "Retry getting the value of ~S." cell-name))
805                  (symbol-value cell-name))
806        (use-homonym (homonym)
807                     :test (lambda (c) (and (or (null c) (eq c condition)) other-variables))
808                     :report (lambda (s)
809                               (if (= 1 (length other-variables))
810                                 (format s "Use the value of ~s this time." (first other-variables))
811                                 (format s "Use one of the homonyms ~{~S or ~} this time." other-variables)))
812                     :interactive (lambda ()
813                                    (if (= 1 (length other-variables))
814                                      other-variables
815                                      (select-item-from-list other-variables :window-title "Select homonym to use")))
816                     (symbol-value homonym))
817        (use-value (value)
818                   :interactive new-value
819                   :report (lambda (s) (format s "Specify a value of ~S to use this time." cell-name))
820                   value)
821        (store-value (value)
822                     :interactive new-value
823                     :report (lambda (s) (format s "Specify a value of ~S to store and use." cell-name))
824                     (setf (symbol-value cell-name) value))))))
825
826(def-kernel-restart $xnopkg %default-no-package-restart (frame-ptr package-name)
827  (or (and *autoload-lisp-package*
828           (or (string-equal package-name "LISP") 
829               (string-equal package-name "USER"))
830           (progn
831             (require "LISP-PACKAGE")
832             (find-package package-name)))
833      (let* ((alias (or (%cdr (assoc package-name '(("LISP" . "COMMON-LISP")
834                                                    ("USER" . "CL-USER")) 
835                                     :test #'string-equal))
836                        (if (packagep *package*) (package-name *package*))))
837             (condition (make-condition 'no-such-package :package package-name)))
838        (flet ((try-again (p)
839                          (or (find-package p) (%kernel-restart $xnopkg p))))
840          (restart-case
841            (restart-case (%error condition nil frame-ptr)
842              (continue ()
843                        :report (lambda (s) (format s "Retry finding package with name ~S." package-name))
844                        (try-again package-name))
845              (use-value (value)
846                         :interactive (lambda () (block nil 
847                                                   (catch-cancel
848                                                    (return (list (get-string-from-user
849                                                                   "Find package named : "))))
850                                                   (continue condition)))
851                         :report (lambda (s) (format s "Find specified package instead of ~S ." package-name))
852                         (try-again value))
853              (make-nickname ()
854                             :report (lambda (s) (format s "Make ~S be a nickname for package ~S." package-name alias))
855                             (let ((p (try-again alias)))
856                               (push package-name (cdr (pkg.names p)))
857                               p)))
858            (require-lisp-package ()
859                                  :test (lambda (c)
860                                          (and (eq c condition)
861                                               (or (string-equal package-name "LISP") (string-equal package-name "USER"))))
862                                  :report (lambda (s) 
863                                            (format s "(require :lisp-package) and retry finding package ~s"
864                                                    package-name))
865                                  (require "LISP-PACKAGE")
866                                  (try-again package-name)))))))
867
868(def-kernel-restart $xunintc unintern-conflict-restarts (frame-ptr sym package conflicts)
869  (let ((condition (make-condition 'unintern-conflict-error :package package :sym sym :conflicts conflicts)))
870    (restart-case (%error condition nil frame-ptr)
871      (continue ()
872                :report (lambda (s) (format s "Try again to unintern ~s from ~s" sym package))
873                (unintern sym package))
874      (do-shadowing-import (ssym)
875                           :report (lambda (s) (format s "SHADOWING-IMPORT one of ~S in ~S." conflicts package))
876                           :interactive (lambda ()
877                                          (block nil
878                                            (catch-cancel
879                                             (return (select-item-from-list conflicts 
880                                                                            :window-title 
881                                                                            (format nil "Shadowing-import one of the following in ~s" package)
882                                                                            :table-print-function #'prin1)))
883                                            (continue condition)))
884                           (shadowing-import (list ssym) package)))))
885
886
887(def-kernel-restart $xusec blub (frame-ptr package-to-use using-package conflicts)
888  (resolve-use-package-conflict-error frame-ptr package-to-use using-package conflicts nil))
889
890(def-kernel-restart $xusecX blub (frame-ptr package-to-use using-package conflicts)
891  (resolve-use-package-conflict-error frame-ptr package-to-use using-package conflicts t))
892
893(defun resolve-use-package-conflict-error (frame-ptr package-to-use using-package conflicts external-p)
894  (let ((condition (make-condition 'use-package-conflict-error 
895                                   :package using-package
896                                   :package-to-use package-to-use
897                                   :conflicts conflicts
898                                   :external-p external-p)))
899    (flet ((external-test (&rest ignore) (declare (ignore ignore)) external-p)
900           (present-test (&rest ignore) (declare (ignore ignore)) (not external-p)))
901      (declare (dynamic-extent #'present-test #'external-test))
902      (restart-case (%error condition nil frame-ptr)
903        (continue ()
904                  :report (lambda (s) (format s "Try again to use ~s in ~s" package-to-use using-package)))
905        (resolve-by-shadowing-import (&rest shadowing-imports)
906                                     :test external-test
907                                     :interactive (lambda ()
908                                                    (mapcar #'(lambda (pair) 
909                                                                (block nil
910                                                                  (catch-cancel
911                                                                    (return (car (select-item-from-list pair
912                                                                                                        :window-title 
913                                                                                                        (format nil "Shadowing-import one of the following in ~s" using-package)
914                                                                                                        :table-print-function #'prin1))))
915                                                                  (continue condition)))
916                                                            conflicts))
917                                     :report (lambda (s) (format s "SHADOWING-IMPORT one of each pair of conflicting symbols."))
918                                     (shadowing-import shadowing-imports using-package))
919        (unintern-all ()
920                      :test present-test
921                      :report (lambda (s) (format s "UNINTERN all conflicting symbols from ~S" using-package))
922                      (dolist (c conflicts)
923                        (unintern (car c) using-package)))
924        (shadow-all ()
925                      :test present-test
926                      :report (lambda (s) (format s "SHADOW all conflicting symbols in ~S" using-package))
927                      (dolist (c conflicts)
928                        (shadow-1 using-package (car c))))
929        (resolve-by-unintern-or-shadow (&rest dispositions)
930                                       :test present-test
931                                       :interactive (lambda ()
932                                                      (mapcar #'(lambda (pair)
933                                                                  (let* ((present-sym (car pair)))
934                                                                    (block nil
935                                                                      (catch-cancel
936                                                                        (return (car (select-item-from-list (list 'shadow 'unintern) 
937                                                                                                            :window-title
938                                                                                                            (format nil "SHADOW ~S in, or UNINTERN ~S from ~S" 
939                                                                                                                    present-sym 
940                                                                                                                    present-sym
941                                                                                                                    using-package)
942                                                                                                            :table-print-function #'prin1)))
943                                                                        (continue condition)))))
944                                                              conflicts))
945                                       :report (lambda (s) (format s "SHADOW or UNINTERN the conflicting symbols in ~S." using-package))
946                                       (dolist (d dispositions)
947                                         (let* ((sym (car (pop conflicts))))
948                                           (if (eq d 'shadow)
949                                             (shadow-1 using-package sym)
950                                             (unintern sym using-package)))))))))
951
952
953(defun resolve-export-conflicts (conflicts package)
954  (let* ((first-inherited (caar conflicts))
955         (all-same (dolist (conflict (cdr conflicts) t)
956                     (unless (eq (car conflict) first-inherited) (return nil))))
957         (all-inherited (and all-same first-inherited))
958         (all-present (and all-same (not first-inherited)))
959         (condition (make-condition 'export-conflict-error
960                                    :conflicts conflicts
961                                    :package package)))
962    (flet ((check-again () 
963             (let* ((remaining-conflicts (check-export-conflicts (mapcar #'cadr conflicts) package)))
964               (if remaining-conflicts (resolve-export-conflicts remaining-conflicts package)))))
965      (restart-case (%error condition nil (%get-frame-ptr))
966        (resolve-all-by-shadowing-import-inherited 
967         ()
968         :test (lambda (&rest ignore) (declare (ignore ignore)) all-inherited)
969         :report (lambda (s) (format s "SHADOWING-IMPORT all conflicting inherited symbol(s) in using package(s)."))
970         (dolist (conflict conflicts (check-again))
971           (destructuring-bind (using-package inherited-sym) (cddr conflict)
972             (shadowing-import-1 using-package inherited-sym))))
973        (resolve-all-by-shadowing-import-exported 
974         ()
975         :test (lambda (&rest ignore) (declare (ignore ignore)) all-inherited)
976         :report (lambda (s) (format s "SHADOWING-IMPORT all conflicting symbol(s) to be exported in using package(s)."))
977         (dolist (conflict conflicts (check-again))
978           (destructuring-bind (exported-sym using-package ignore) (cdr conflict)
979             (declare (ignore ignore))
980             (shadowing-import-1 using-package exported-sym))))
981        (resolve-all-by-uninterning-present 
982         ()
983         :test (lambda (&rest ignore) (declare (ignore ignore)) all-present)
984         :report (lambda (s) (format s "UNINTERN all present conflicting symbol(s) in using package(s)."))
985         (dolist (conflict conflicts (check-again))
986           (destructuring-bind (using-package inherited-sym) (cddr conflict)
987             (unintern inherited-sym using-package))))
988        (resolve-all-by-shadowing-present 
989         ()
990         :test (lambda (&rest ignore) (declare (ignore ignore)) all-present)
991         :report (lambda (s) (format s "SHADOW all present conflicting symbol(s) in using package(s)."))
992         (dolist (conflict conflicts (check-again))
993           (destructuring-bind (using-package inherited-sym) (cddr conflict)
994             (shadow-1 using-package inherited-sym))))
995        (review-and-resolve 
996         (dispositions)
997         :report (lambda (s) (format s "Review each name conflict and resolve individually."))
998         :interactive (lambda ()
999                        (let* ((disp nil))
1000                          (block b
1001                            (catch-cancel
1002                              (dolist (conflict conflicts (return-from b (list disp)))
1003                                (destructuring-bind (inherited-p exported-sym using-package conflicting-sym) conflict
1004                                  (let* ((syms (list exported-sym conflicting-sym)))
1005                                    (if inherited-p
1006                                      (push (list 'shadowing-import
1007                                                  (select-item-from-list syms
1008                                                                              :window-title 
1009                                                                              (format nil "Shadowing-import one of the following in ~s" using-package)
1010                                                                              :table-print-function #'prin1)
1011                                                  using-package)
1012                                            disp)
1013                                      (let* ((selection (car (select-item-from-list syms
1014                                                                                    :window-title 
1015                                                                                    (format nil "Shadow ~S or unintern ~s in ~s"
1016                                                                                            exported-sym 
1017                                                                                            conflicting-sym using-package)
1018                                                                                    :table-print-function #'prin1))))
1019                                        (push (if (eq selection 'exported-sym)
1020                                                (list 'shadow (list exported-sym) using-package)
1021                                                (list 'unintern conflicting-sym using-package))
1022                                              disp)))))))
1023                            nil)))
1024         (dolist (disp dispositions (check-again))
1025           (apply (car disp) (cdr disp))))))))
1026
1027
1028(def-kernel-restart $xwrongtype default-require-type-restarts (frame-ptr value typespec)
1029  (setq typespec (%type-error-type typespec))
1030  (let ((condition (make-condition 'type-error 
1031                                   :datum value
1032                                   :expected-type typespec)))
1033    (restart-case (%error condition nil frame-ptr)
1034      (use-value (newval)
1035                 :report (lambda (s)
1036                           (format s "Use a new value of type ~s instead of ~s." typespec value))
1037                 :interactive (lambda ()
1038                                (format *query-io* "~&New value of type ~S :" typespec)
1039                                (list (read *query-io*)))
1040                 (require-type newval typespec)))))
1041
1042(def-kernel-restart $xudfcall default-undefined-function-call-restarts (frame-ptr function-name args)
1043  (unless *level-1-loaded*
1044    (dbg function-name))   ; user should never see this
1045  (let ((condition (make-condition 'undefined-function-call
1046                                   :name function-name
1047                                   :function-arguments args))
1048        (other-functions (find-unique-homonyms function-name #'fboundp)))
1049    (restart-case (%error condition nil frame-ptr)
1050      (continue ()
1051                :report (lambda (s) (format s "Retry applying ~S to ~S." function-name args))
1052                (apply function-name args))
1053      (use-homonym (function-name)
1054                   :test (lambda (c) (and (or (null c) (eq c condition)) other-functions))
1055                   :report (lambda (s)
1056                             (if (= 1 (length other-functions))
1057                               (format s "Apply ~s to ~S this time." (first other-functions) args)
1058                               (format s "Apply one of ~{~S or ~} to ~S this time."
1059                                       other-functions args)))
1060                   :interactive (lambda ()
1061                                  (if (= 1 (length other-functions))
1062                                    other-functions
1063                                    (select-item-from-list other-functions :window-title "Select homonym to use")))
1064                   (apply (fdefinition function-name) args))
1065      (use-value (function)
1066                 :interactive (lambda ()
1067                                (format *query-io* "Function to apply instead of ~s :" function-name)
1068                                (let ((f (read *query-io*)))
1069                                  (unless (symbolp f) (setq f (eval f))) ; almost-the-right-thing (tm)
1070                                  (list (coerce f 'function))))
1071                 :report (lambda (s) (format s "Apply specified function to ~S this time." args))
1072                 (apply function args))
1073      (store-value (function)
1074                   :interactive (lambda ()
1075                                (format *query-io* "Function to apply as new definition of ~s :" function-name)
1076                                (let ((f (read *query-io*)))
1077                                  (unless (symbolp f) (setq f (eval f))) ; almost-the-right-thing (tm)
1078                                  (list (coerce f 'function))))
1079                   :report (lambda (s) (format s "Specify a function to use as the definition of ~S." function-name))
1080                   (apply (setf (symbol-function function-name) function) args)))))
1081
1082
1083
1084(defun %check-type (value typespec placename typename)
1085  (let ((condition (make-condition 'type-error 
1086                                   :datum value
1087                                   :expected-type typespec)))
1088    (if typename
1089      (setf (slot-value condition 'format-control)
1090            (format nil "value ~~S is not ~A (~~S)." typename)))
1091    (restart-case (%error condition nil (%get-frame-ptr))
1092                  (store-value (newval)
1093                               :report (lambda (s)
1094                                         (format s "Assign a new value of type ~a to ~s" typespec placename))
1095                               :interactive (lambda ()
1096                                              (format *query-io* "~&New value for ~S :" placename)
1097                                              (list (eval (read))))
1098                               newval))))
1099
1100
1101; This has to be defined fairly early (assuming, of course, that it "has" to be defined at all ...
1102
1103(defun ensure-value-of-type (value typespec placename &optional typename)
1104  (tagbody
1105    again
1106    (unless (typep value typespec)
1107      (let ((condition (make-condition 'type-error 
1108                                       :datum value
1109                                       :expected-type typespec)))
1110        (if typename
1111            (setf (slot-value condition 'format-control)
1112                  (format nil "value ~~S is not ~A (~~S)." typename)))
1113        (restart-case (%error condition nil (%get-frame-ptr))
1114          (store-value (newval)
1115                       :report (lambda (s)
1116                                 (format s "Assign a new value of type ~a to ~s" typespec placename))
1117                       :interactive (lambda ()
1118                                      (format *query-io* "~&New value for ~S :" placename)
1119                                      (list (eval (read))))
1120                       (setq value newval)
1121                       (go again))))))
1122  value)
1123
1124;;;The Error Function
1125
1126(defparameter *kernel-simple-error-classes*
1127  (list (cons $xcalltoofew 'simple-destructuring-error)
1128        (cons $xcalltoomany 'simple-destructuring-error)
1129        (cons $xstkover 'stack-overflow-condition)
1130        (cons $xmemfull 'simple-storage-condition)
1131        (cons $xwrongtype 'type-error) ; this one needs 2 args
1132        (cons $xdivzro 'division-by-zero)
1133        (cons $xflovfl 'floating-point-overflow)
1134        (cons $xfunbnd 'undefined-function)
1135        (cons $xbadkeys 'simple-program-error)
1136        (cons $xcallnomatch 'simple-program-error)
1137        (cons $xnotfun 'call-special-operator-or-macro)
1138        (cons $xaccessnth 'sequence-index-type-error)
1139        (cons $ximproperlist 'improper-list)
1140        (cons $xnospread 'cant-construct-arglist)
1141        (cons $xnotelt 'array-element-type-error)
1142        ))
1143
1144
1145(defparameter *simple-error-types*
1146  (vector nil 'simple-program-error 'simple-file-error))
1147
1148(defconstant $pgm-err #x10000)
1149
1150
1151
1152
1153(defparameter %type-error-typespecs%
1154  #(array
1155    bignum
1156    fixnum
1157    character
1158    integer
1159    list
1160    number
1161    sequence
1162    simple-string
1163    simple-vector
1164    string
1165    symbol
1166    macptr
1167    real
1168    cons
1169    unsigned-byte
1170    (integer 2 36)
1171    float
1172    rational
1173    ratio
1174    short-float
1175    double-float
1176    complex
1177    vector
1178    simple-base-string
1179    function
1180    (unsigned-byte 16)
1181    (unsigned-byte 8)
1182    (unsigned-byte 32)
1183    (signed-byte 32)
1184    (signed-byte 16)
1185    (signed-byte 8)
1186    base-char
1187    bit
1188    (unsigned-byte 24)                  ; (integer 0 (array-total-size-limit))
1189    (unsigned-byte 64)
1190    (signed-byte 64)
1191    (unsigned-byte 56)
1192    (simple-array double-float (* *))
1193    (simple-array single-float (* *))
1194    (mod #x110000)
1195    (array * (* *))                     ;2d array
1196    (array * (* * *))                   ;3d array
1197    (array t)
1198    (array bit)
1199    (array (signed-byte 8))
1200    (array (unsigned-byte 8))
1201    (array (signed-byte 16))
1202    (array (unsigned-byte 16))
1203    (array (signed-byte 32))
1204    (array (unsigned-byte 32))
1205    (array (signed-byte 64))
1206    (array (unsigned-byte 64))
1207    (array fixnum)
1208    (array single-float)
1209    (array double-float)
1210    (array character)
1211    (array t (* *))
1212    (array bit (* *))
1213    (array (signed-byte 8) (* *))
1214    (array (unsigned-byte 8) (* *))
1215    (array (signed-byte 16) (* *))
1216    (array (unsigned-byte 16) (* *))
1217    (array (signed-byte 32) (* *))
1218    (array (unsigned-byte 32) (* *))
1219    (array (signed-byte 64) (* *))
1220    (array (unsigned-byte 64) (* *))
1221    (array fixnum (* *))
1222    (array single-float (* *))
1223    (array double-float (* *))
1224    (array character (* *))
1225    (simple-array t (* *))
1226    (simple-array bit (* *))
1227    (simple-array (signed-byte 8) (* *))
1228    (simple-array (unsigned-byte 8) (* *))
1229    (simple-array (signed-byte 16) (* *))
1230    (simple-array (unsigned-byte 16) (* *))
1231    (simple-array (signed-byte 32) (* *))
1232    (simple-array (unsigned-byte 32) (* *))
1233    (simple-array (signed-byte 64) (* *))
1234    (simple-array (unsigned-byte 64) (* *))
1235    (simple-array fixnum (* *))
1236    (simple-array character (* *))
1237    (array t (* * *))
1238    (array bit (* * *))
1239    (array (signed-byte 8) (* * *))
1240    (array (unsigned-byte 8) (* * *))
1241    (array (signed-byte 16) (* * *))
1242    (array (unsigned-byte 16) (* * *))
1243    (array (signed-byte 32) (* * *))
1244    (array (unsigned-byte 32) (* * *))
1245    (array (signed-byte 64) (* * *))
1246    (array (unsigned-byte 64) (* * *))
1247    (array fixnum (* * *))
1248    (array single-float (* * *))
1249    (array double-float (* * *))
1250    (array character (* * *))
1251    (simple-array t (* * *))
1252    (simple-array bit (* * *))
1253    (simple-array (signed-byte 8) (* * *))
1254    (simple-array (unsigned-byte 8) (* * *))
1255    (simple-array (signed-byte 16) (* * *))
1256    (simple-array (unsigned-byte 16) (* * *))
1257    (simple-array (signed-byte 32) (* * *))
1258    (simple-array (unsigned-byte 32) (* * *))
1259    (simple-array (signed-byte 64) (* * *))
1260    (simple-array (unsigned-byte 64) (* * *))
1261    (simple-array fixnum (* * *))
1262    (simple-array single-float (* * *))
1263    (simple-array double-float (* * *))
1264    (simple-array character (* * *))
1265
1266    (vector t)
1267    bit-vector
1268    (vector (signed-byte 8))
1269    (vector (unsigned-byte 8))
1270    (vector (signed-byte 16))
1271    (vector (unsigned-byte 16))
1272    (vector (signed-byte 32))
1273    (vector (unsigned-byte 32))
1274    (vector (signed-byte 64))
1275    (vector (unsigned-byte 64))
1276    (vector fixnum)
1277    (vector single-float)
1278    (vector double-float)
1279
1280    ))
1281
1282
1283(defun %type-error-type (type)
1284  (if (fixnump type) 
1285    (svref %type-error-typespecs% type)
1286    type))
1287
1288(defun %typespec-id (typespec)
1289  (flet ((type-equivalent (t1 t2) (ignore-errors (and (subtypep t1 t2) (subtypep t2 t1)))))
1290    (position typespec %type-error-typespecs% :test #'type-equivalent)))
1291
1292
1293(defmethod condition-p ((x t)) nil)
1294(defmethod condition-p ((x condition)) t)
1295
1296
1297
1298(let* ((globals ()))
1299
1300  (defun %check-error-globals ()
1301    (let ((vars ())
1302          (valfs ())
1303          (oldvals ()))
1304      (dolist (g globals (values vars valfs oldvals))
1305        (destructuring-bind (sym predicate newvalf) g
1306          (let* ((boundp (boundp sym))
1307                 (oldval (if boundp (symbol-value sym) (%unbound-marker-8))))
1308          (unless (and boundp (funcall predicate oldval))
1309            (push sym vars)
1310            (push oldval oldvals)
1311            (push newvalf valfs)))))))
1312
1313  (defun check-error-global (sym checkfn newvalfn)
1314    (setq sym (require-type sym 'symbol)
1315          checkfn (require-type checkfn 'function)
1316          newvalfn (require-type newvalfn 'function))
1317    (let ((found (assq sym globals)))
1318      (if found
1319        (setf (cadr found) checkfn (caddr found) newvalfn)
1320        (push (list sym checkfn newvalfn) globals))
1321      sym))
1322)
1323
1324(check-error-global '*package* #'packagep #'(lambda () (find-package "CL-USER")))
1325
1326
1327(flet ((io-stream-p (x) (and (streamp x) (eq (stream-direction x) :io)))
1328       (input-stream-p (x) (and (streamp x) (input-stream-p x)))
1329       (output-stream-p (x) (and (streamp x) (output-stream-p x)))
1330       (default-terminal-io () (make-echoing-two-way-stream *stdin* *stdout*))
1331       (terminal-io () *terminal-io*)
1332       (standard-output () *standard-output*))
1333
1334  ;; Note that order matters.  These need to come out of %check-error-globals with
1335  ;; *terminal-io* first and *trace-output* last
1336  (check-error-global '*terminal-io* #'io-stream-p #'default-terminal-io)
1337  (check-error-global '*query-io* #'io-stream-p #'terminal-io)
1338  (check-error-global '*debug-io* #'io-stream-p #'terminal-io)
1339  (check-error-global '*standard-input* #'input-stream-p #'terminal-io)
1340  (check-error-global '*standard-output* #'output-stream-p #'terminal-io)
1341  (check-error-global '*error-output* #'output-stream-p #'standard-output)
1342  (check-error-global '*trace-output* #'output-stream-p #'standard-output))
1343
Note: See TracBrowser for help on using the repository browser.