source: trunk/source/level-0/l0-numbers.lisp @ 14681

Last change on this file since 14681 was 14681, checked in by rme, 9 years ago

In /-2, be more careful with division involving a complex operand.

The code was adapted from CMUCL. Fixes ticket:674.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 77.9 KB
Line 
1;;; -*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;;
19;;; level-0;l0-numbers.lisp
20
21(in-package "CCL")
22
23(eval-when (:compile-toplevel :execute)
24  (require "ARCH")
25  (require "LISPEQU")
26  (require "NUMBER-MACROS")
27  (require "NUMBER-CASE-MACRO")
28
29
30
31  (defvar *dfloat-dops* '((* . %double-float*-2!)(/ . %double-float/-2!)
32                          (+ . %double-float+-2!)(- . %double-float--2!)))
33 
34  (defvar *sfloat-dops* '((* . %short-float*-2!)(/ . %short-float/-2!)
35                          (+ . %short-float+-2!)(- . %short-float--2!)))
36
37  (defmacro dfloat-rat (op x y &optional (destructive-op (cdr (assq op *dfloat-dops*))))
38    (if destructive-op
39        (let ((f2 (gensym)))
40          `(let ((,f2 (%double-float ,y (%make-dfloat))))
41            (,destructive-op ,x ,f2 ,f2)))         
42        `(,op (the double-float ,x) (the double-float (%double-float ,y)))))
43
44  (defmacro rat-dfloat (op x y &optional (destructive-op (cdr (assq op *dfloat-dops*))))
45    (if destructive-op
46        (let ((f1 (gensym)))
47          `(let ((,f1 (%double-float ,x (%make-dfloat)))) 
48            (,destructive-op ,f1 ,y ,f1)))
49        `(,op (the double-float (%double-float ,x)) (the double-float ,y))))
50
51  (defmacro sfloat-rat (op x y &optional (destructive-op (cdr (assq op *sfloat-dops*))))
52    (let* ((use-destructive-op
53            (target-word-size-case
54             (32 destructive-op)
55             (64 nil))))
56      (if use-destructive-op
57        (let ((f2 (gensym)))
58          `(let ((,f2 (%short-float ,y (%make-sfloat)))) 
59            (,destructive-op ,x ,f2 ,f2)))
60        `(,op (the short-float ,x) (the short-float (%short-float ,y))))))
61
62  (defmacro rat-sfloat (op x y &optional (destructive-op (cdr (assq op *sfloat-dops*))))
63    (let* ((use-destructive-op
64            (target-word-size-case
65             (32 destructive-op)
66             (64 nil))))
67      (if use-destructive-op
68        (let ((f1 (gensym)))
69          `(let ((,f1 (%short-float ,x (%make-sfloat)))) 
70            (,destructive-op ,f1 ,y ,f1)))
71        `(,op (the short-float (%short-float ,x)) (the short-float ,y)))))
72
73
74 
75
76
77  (declaim (inline  %make-complex %make-ratio))
78  (declaim (inline canonical-complex))
79  (declaim (inline build-ratio))
80  (declaim (inline maybe-truncate)))
81
82
83
84(defun %make-complex (realpart imagpart)
85  (gvector :complex realpart imagpart))
86
87(defun %make-ratio (numerator denominator)
88  (gvector :ratio numerator denominator))
89 
90
91
92; this is no longer used
93(defun %integer-signum (num)
94  (if (fixnump num)
95    (%fixnum-signum num)
96    ; there is no such thing as bignum zero we hope
97    (if (bignum-minusp num) -1 1)))
98
99
100; Destructive primitives.
101(macrolet ((defdestructive-df-op (non-destructive-name destructive-name op)
102             `(progn
103                (defun ,non-destructive-name (x y)
104                  (,destructive-name x y (%make-dfloat)))
105                (defun ,destructive-name (x y result)
106                  (declare (double-float x y result))
107                  (%setf-double-float result (the double-float (,op x y)))))))
108  (defdestructive-df-op %double-float+-2 %double-float+-2! +)
109  (defdestructive-df-op %double-float--2 %double-float--2! -)
110  (defdestructive-df-op %double-float*-2 %double-float*-2! *)
111  (defdestructive-df-op %double-float/-2 %double-float/-2! /))
112
113#-64-bit-target
114(macrolet ((defdestructive-sf-op (non-destructive-name destructive-name op)
115             `(progn
116                (defun ,non-destructive-name (x y)
117                  (,destructive-name x y (%make-sfloat)))
118                (defun ,destructive-name (x y result)
119                  (declare (short-float x y result))
120                  (%setf-short-float result (the short-float (,op x y)))))))
121  (defdestructive-sf-op %short-float+-2 %short-float+-2! +)
122  (defdestructive-sf-op %short-float--2 %short-float--2! -)
123  (defdestructive-sf-op %short-float*-2 %short-float*-2! *)
124  (defdestructive-sf-op %short-float/-2 %short-float/-2! /))
125
126
127(defun %negate (x)
128  (number-case x
129    (fixnum  (- (the fixnum x)))
130    (double-float  (%double-float-negate! x (%make-dfloat)))
131    (short-float
132     #+32-bit-target (%short-float-negate! x (%make-sfloat))
133     #+64-bit-target (%short-float-negate x))
134    (bignum (negate-bignum x))
135    (ratio (%make-ratio (%negate (%numerator x)) (%denominator x)))
136    (complex (%make-complex (%negate (%realpart X))(%negate (%imagpart X))) )))
137
138(defun %double-float-zerop (n)
139  (zerop (the double-float n)))
140
141(defun %short-float-zerop (n)
142  (zerop (the single-float n)))
143
144(defun zerop (number)
145  "Is this number zero?"
146  (number-case number
147    (integer (eq number 0))
148    (short-float (%short-float-zerop number))
149    (double-float (%double-float-zerop number))
150    (ratio nil)
151    (complex
152     (number-case (%realpart number)
153       (short-float (and (%short-float-zerop (%realpart number))
154                         (%short-float-zerop (%imagpart number))))
155       (double-float (and (%double-float-zerop (%realpart number))
156                          (%double-float-zerop (%imagpart number))))
157       (t (and (eql 0 (%realpart number))(eql 0 (%imagpart number))))))))
158
159(defun %short-float-plusp (x)
160  (> (the single-float x) 0.0f0))
161
162(defun %double-float-plusp (x)
163  (> (the double-float x) 0.0d0))
164
165(defun plusp (number)
166  "Is this real number strictly positive?"
167  (number-case number
168    (fixnum (%i> number 0))
169    (bignum (bignum-plusp number))
170    (short-float (%short-float-plusp number))
171    (double-float (%double-float-plusp number))
172    (ratio (plusp (%numerator number)))))
173
174
175(defun minusp (number)
176  "Is this real number strictly negative?"
177  (number-case number
178    (fixnum (%i< number 0))
179    (bignum (bignum-minusp number))
180    (short-float (%short-float-minusp number))
181    (double-float (%double-float-minusp number))
182    (ratio (minusp (%numerator number)))))
183
184
185(defun oddp (n)
186  "Is this integer odd?"
187  (case (typecode n)
188    (#.target::tag-fixnum (logbitp 0 (the fixnum n)))
189    (#.target::subtag-bignum (%bignum-oddp n))
190    (t (report-bad-arg n 'integer))))
191
192(defun evenp (n)
193  "Is this integer even?"
194  (case (typecode n)
195    (#.target::tag-fixnum (not (logbitp 0 (the fixnum n))))
196    (#.target::subtag-bignum (not (%bignum-oddp n)))
197    (t (report-bad-arg n 'integer))))
198
199;; expansion slightly changed
200(defun =-2 (x y)
201  (number-case x
202    (fixnum (number-case y
203              (fixnum (eq x y))
204              (double-float (eq 0 (fixnum-dfloat-compare x y)))
205              (short-float (eq 0 (fixnum-sfloat-compare x y)))
206              ((bignum ratio) nil)
207              (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
208    (double-float (number-case y ; x
209                    (double-float (= (the double-float x)(the double-float y))) ;x
210                    (short-float (with-stack-double-floats ((dy y))
211                                   (= (the double-float x) (the double-float dy))))
212                    (fixnum (eq 0 (fixnum-dfloat-compare  y x)))
213                    (bignum (eq 0 (bignum-dfloat-compare y x)))
214                    (ratio (= (rational x) y))
215                    (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
216    (short-float (number-case y
217                   (short-float (= (the short-float x) (the short-float y)))
218                   (double-float (with-stack-double-floats ((dx x))
219                                   (= (the double-float dx) (the double-float y))))
220                   (fixnum (eq 0 (fixnum-sfloat-compare y x)))
221                   (bignum (eq 0 (bignum-sfloat-compare y x)))
222                   (ratio (= (rational x) y))
223                   (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
224    (bignum (number-case y 
225              (bignum (eq 0 (bignum-compare x y)))
226              ((fixnum ratio) nil)
227              (double-float (eq 0 (bignum-dfloat-compare x y)))
228              (short-float (eq 0 (bignum-sfloat-compare x y)))
229              (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
230    (ratio (number-case y
231             (integer nil)
232             (ratio
233              (and (eql (%numerator x) (%numerator y))
234                   (eql (%denominator x) (%denominator y))))
235             (float (= x (rational y)))
236             (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
237    (complex (number-case y
238               (complex (and (= (%realpart x) (%realpart y))
239                             (= (%imagpart x) (%imagpart y))))
240               ((float rational)
241                (and (zerop (%imagpart x)) (= (%realpart x) y)))))))
242
243(defun /=-2 (x y)
244  (declare (notinline =-2))
245  (not (= x y)))
246
247
248; true iff (< x y) is false.
249(defun >=-2 (x y)
250  (declare (notinline <-2))
251  (not (< x y)))
252
253
254
255(defun <=-2 (x y)
256  (declare (notinline >-2))
257  (not (> x y)))
258
259(defun <-2 (x y)
260  (number-case x
261    (fixnum (number-case y
262              (fixnum (< (the fixnum x) (the fixnum y)))
263              (double-float (eq -1 (fixnum-dfloat-compare x y)))
264              (short-float (eq -1 (fixnum-sfloat-compare x y)))
265              (bignum (bignum-plusp y))
266              (ratio (< x (ceiling (%numerator y)(%denominator y))))))
267    (double-float (number-case y ; x
268                    (double-float (< (the double-float x)(the double-float y))) ;x
269                    (short-float (with-stack-double-floats ((dy y))
270                                   (< (the double-float x) (the double-float dy))))
271                    (fixnum (eq 1 (fixnum-dfloat-compare  y x)))
272                    (bignum (eq 1 (bignum-dfloat-compare y x)))
273                    (ratio (< (rational x) y))))
274    (short-float (number-case y
275                    (short-float (< (the short-float x) (the short-float y)))
276                    (double-float (with-stack-double-floats ((dx x))
277                                    (< (the double-float dx) (the double-float y))))
278                    (fixnum (eq 1 (fixnum-sfloat-compare y x)))
279                    (bignum (eq 1 (bignum-sfloat-compare y x)))
280                    (ratio (< (rational x) y))))
281    (bignum (number-case y 
282              (bignum (EQ -1 (bignum-compare x y)))
283              (fixnum (not (bignum-plusp x)))
284              (ratio (< x (ceiling (%numerator y)(%denominator y))))
285              (double-float (eq -1 (bignum-dfloat-compare x y)))
286              (short-float (eq -1 (bignum-sfloat-compare x y)))))
287    (ratio (number-case y
288             (integer (< (floor (%numerator x)(%denominator x)) y))
289             (ratio
290              (< (* (%numerator (the ratio x))
291                    (%denominator (the ratio y)))
292                 (* (%numerator (the ratio y))
293                    (%denominator (the ratio x)))))
294             (float (< x (rational y)))))))
295
296
297
298(defun >-2 (x y)
299  ;(declare (optimize (speed 3)(safety 0)))
300  (number-case x
301    (fixnum (number-case y
302              (fixnum (> (the fixnum x) (the fixnum y)))
303              (bignum (not (bignum-plusp y)))
304              (double-float (eq 1 (fixnum-dfloat-compare x y)))
305              (short-float (eq 1 (fixnum-sfloat-compare x y)))
306              ;; or (> (* x denom) num) ?
307              (ratio (> x (floor (%numerator y) (%denominator y))))))
308    (double-float (number-case y
309                    (double-float (> (the double-float x) (the double-float y)))
310                    (short-float (with-stack-double-floats ((dy y))
311                                   (> (the double-float x) (the double-float dy))))
312                    (fixnum (eq -1 (fixnum-dfloat-compare  y x)))
313                    (bignum (eq -1 (bignum-dfloat-compare y x)))
314                    (ratio (> (rational x) y))))
315    (short-float (number-case y
316                    (short-float (> (the short-float x) (the short-float y)))
317                    (double-float (with-stack-double-floats ((dx x))
318                                   (> (the double-float dx) (the double-float y))))
319                    (fixnum (eq -1 (fixnum-sfloat-compare  y x)))
320                    (bignum (eq -1 (bignum-sfloat-compare y x)))
321                    (ratio (> (rational x) y))))
322    (bignum (number-case y
323              (fixnum (bignum-plusp x))
324              (bignum (eq 1 (bignum-compare x y)))
325              ;; or (> (* x demon) num)
326              (ratio (> x (floor (%numerator y) (%denominator y))))
327              (double-float (eq 1 (bignum-dfloat-compare x y)))
328              (short-float (eq 1 (bignum-sfloat-compare x y)))))
329    (ratio (number-case y
330             ;; or (> num (* y denom))
331             (integer (> (ceiling (%numerator x) (%denominator x)) y))
332             (ratio
333              (> (* (%numerator (the ratio x))
334                    (%denominator (the ratio y)))
335                 (* (%numerator (the ratio y))
336                    (%denominator (the ratio x)))))
337             (float (> x (rational y)))))))
338
339
340; t if any bits set after exp (unbiased)
341(defun hi-lo-fraction-p (hi lo exp)
342  (declare (fixnum hi lo exp))
343  (if (> exp 24)
344    (not (eql 0 (%ilogand lo (%ilsr (- exp 25) #xfffffff))))
345    (or (not (zerop lo))(not (eql 0 (%ilogand hi (%ilsr exp #x1ffffff)))))))
346
347
348
349(defun negate-hi-lo (hi lo)
350  (setq hi (%ilogxor hi #x3ffffff))
351  (if (eq 0 lo)   
352    (setq hi (+ hi 1))
353    (setq lo (+ (%ilogxor lo #xfffffff) 1)))
354  (values hi lo))
355
356
357
358(defun fixnum-dfloat-compare (int dfloat)
359  (declare (double-float dfloat) (fixnum int))
360  (if (and (eq int 0)(= dfloat 0.0d0))
361    0
362    (with-stack-double-floats ((d1 int))
363      (locally (declare (double-float d1))
364        (if (eq int (%truncate-double-float->fixnum d1))
365          (cond ((< d1 dfloat) -1)
366                ((= d1 dfloat) 0)
367                (t 1))
368          ;; Whatever we do here should have the effect
369          ;; of comparing the integer to the result of calling
370          ;; RATIONAL on the float.  We could probably
371          ;; skip the call to RATIONAL in more cases,
372          ;; but at least check the obvious ones here
373          ;; (e.g. different signs)
374          (multiple-value-bind (mantissa exponent sign)
375              (integer-decode-double-float dfloat)
376            (declare (type (integer -1 1) sign)
377                     (fixnum exponent))
378            (cond ((zerop int)
379                   (- sign))
380                  ((and (< int 0) (eql sign 1)) -1)
381                  ((and (> int 0) (eql sign -1)) 1)
382                  (t
383                   ;; See RATIONAL.  Can probably avoid this if
384                   ;; magnitudes are clearly dissimilar.
385                   (if (= sign -1) (setq mantissa (- mantissa)))
386                   (let* ((rat (if (< exponent 0)
387                                 (/ mantissa (ash 1 (the fixnum (- exponent))))
388                                 (ash mantissa exponent))))
389                     (if (< int rat)
390                       -1
391                       (if (eq int rat)
392                         0
393                         1)))))))))))
394
395
396
397(defun fixnum-sfloat-compare (int sfloat)
398  (declare (short-float sfloat) (fixnum int))
399  (if (and (eq int 0)(= sfloat 0.0s0))
400    0
401    (#+32-bit-target target::with-stack-short-floats #+32-bit-target ((s1 int))
402     #-32-bit-target let* #-32-bit-target ((s1 (%int-to-sfloat int)))
403                     (locally
404                         (declare (short-float s1))
405                       (if (eq (%truncate-short-float->fixnum s1) int)
406                         (cond ((< s1 sfloat) -1)
407                               ((= s1 sfloat) 0)
408                               (t 1))
409                         ;; Whatever we do here should have the effect
410                         ;; of comparing the integer to the result of calling
411                         ;; RATIONAL on the float.  We could probably
412                         ;; skip the call to RATIONAL in more cases,
413                         ;; but at least check the obvious ones here
414                         ;; (e.g. different signs)
415                         (multiple-value-bind (mantissa exponent sign)
416                             (integer-decode-short-float sfloat)
417                           (declare (type (integer -1 1) sign)
418                                    (fixnum exponent))
419                           (cond ((zerop int)
420                                  (- sign))
421                                 ((and (< int 0) (eql sign 1)) -1)
422                                 ((and (> int 0) (eql sign -1)) 1)
423                                 (t
424                                  ;; See RATIONAL.  Can probably avoid this if
425                                  ;; magnitudes are clearly dissimilar.
426                                  (if (= sign -1) (setq mantissa (- mantissa)))
427                                  (let* ((rat (if (< exponent 0)
428                                                (/ mantissa (ash 1 (the fixnum (- exponent))))
429                                                (ash mantissa exponent))))
430                                    (if (< int rat)
431                                      -1
432                                      (if (eq int rat)
433                                        0
434                                        1)))))))))))
435
436
437       
438;;; lotta stuff to avoid making a rational from a float
439;;; returns -1 less, 0 equal, 1 greater
440(defun bignum-dfloat-compare (int float)
441  (cond 
442   ((and (eq int 0)(= float 0.0d0)) 0)
443   (t
444    (let* ((fminus  (%double-float-minusp float))
445           (iminus (minusp int))
446           (gt (if iminus -1 1)))
447      (declare (fixnum gt))
448      (if (neq fminus iminus)
449        gt  ; if different signs, done
450        (let ((intlen (integer-length int)) 
451              (exp (- (the fixnum (%double-float-exp float)) 1022)))
452          (declare (fixnum intlen exp))
453          (cond 
454           ((and (not fminus) (< intlen exp)) -1)
455           ((> intlen exp)  gt)   ; if different exp, done
456           ((and fminus (or (< (1+ intlen) exp)
457                            (and (= (1+ intlen) exp)
458                                 (neq (one-bignum-factor-of-two int) intlen))))
459            ;(print 'zow)
460            (the fixnum (- gt)))  ; ; integer-length is strange for neg powers of 2           
461           (t (multiple-value-bind (hi lo)(fixnum-decode-float float)
462                (declare (fixnum hi lo)) 
463                (when fminus (multiple-value-setq (hi lo)(negate-hi-lo hi lo)))
464                (let* ((sz 26)  ; exp > 28 always
465                       (pos (- exp 25))
466                       (big-bits (%ldb-fixnum-from-bignum int sz pos)))
467                  (declare (fixnum pos big-bits sz))
468                  ;(print (list big-bits hi sz pos))
469                  (cond 
470                   ((< big-bits hi) -1)
471                   ((> big-bits hi) 1)
472                   (t (let* ((sz (min (- exp 25) 28))
473                             (pos (- exp 25 sz)) ; ?
474                             (ilo (if (< exp 53) (ash lo (- exp 53)) lo))                                   
475                             (big-bits (%ldb-fixnum-from-bignum int sz pos)))
476                        (declare (fixnum pos sz ilo big-bits))
477                        ;(PRINT (list big-bits ilo))
478                        (cond
479                         ((< big-bits ilo) -1)
480                         ((> big-bits ilo) 1)
481                         ((eq exp 53) 0)
482                         ((< exp 53)
483                          (if (not (hi-lo-fraction-p hi lo exp)) 0 -1)) ; -1 if pos
484                         (t (if (%i< (one-bignum-factor-of-two int) (- exp 53)) 1 0)))))))
485                )))))))))
486
487
488
489;;; I don't know if it's worth doing a more "real" version of this.
490(defun bignum-sfloat-compare (int float)
491  (with-stack-double-floats ((df float))
492    (bignum-dfloat-compare int df)))
493
494;;;; Canonicalization utilities:
495
496;;; CANONICAL-COMPLEX  --  Internal
497;;;
498;;;    If imagpart is 0, return realpart, otherwise make a complex.  This is
499;;; used when we know that realpart and imagpart are the same type, but
500;;; rational canonicalization might still need to be done.
501;;;
502
503(defun canonical-complex (realpart imagpart)
504  (if (eql imagpart 0)
505    realpart
506    (%make-complex realpart imagpart)))
507
508
509
510
511(defun +-2 (x y)     
512  (number-case x
513    (fixnum (number-case y
514              (fixnum (+ (the fixnum x) (the fixnum y)))
515              (double-float (rat-dfloat + x y))
516              (short-float (rat-sfloat + x y))
517              (bignum (add-bignum-and-fixnum y x))
518              (complex (complex (+ x (%realpart y))
519                                (%imagpart y)))
520              (ratio (let* ((dy (%denominator y)) 
521                            (n (+ (* x dy) (%numerator y))))
522                       (%make-ratio n dy)))))
523    (double-float (number-case y
524                    (double-float (+ (the double-float x) (the double-float y)))
525                    (short-float (with-stack-double-floats ((dy y))
526                                   (+ (the double-float x) (the double-float dy))))
527                    (rational (dfloat-rat + x y))
528                    (complex (complex (+ x (%realpart y)) 
529                                      (%imagpart y)))))
530    (short-float (number-case y                               
531                   (short-float (+ (the short-float x) (the short-float y)))
532                   (double-float (with-stack-double-floats ((dx x))
533                                   (+ (the double-float dx) (the double-float y))))
534                   (rational (sfloat-rat + x y))
535                   (complex (complex (+ x (%realpart y))
536                                     (%imagpart y)))))
537    (bignum (number-case y
538              (bignum (add-bignums x y))
539              (fixnum (add-bignum-and-fixnum x y))
540              (double-float (rat-dfloat + x y))
541              (short-float (rat-sfloat + x y))
542              (complex (complex (+ x (realpart y)) 
543                                (%imagpart y)))
544              (ratio
545               (let* ((dy (%denominator y))
546                      (n (+ (* x dy) (%numerator y))))
547                 (%make-ratio n dy)))))
548    (complex (number-case y
549               (complex (canonical-complex (+ (%realpart x) (%realpart y))
550                                           (+ (%imagpart x) (%imagpart y))))
551               ((rational float) (complex (+ (%realpart x) y) (%imagpart x)))))
552    (ratio (number-case y
553             (ratio
554              (let* ((nx (%numerator x))
555                     (dx (%denominator x))
556                     (ny (%numerator y))
557                     (dy (%denominator y))
558                     (g1 (gcd dx dy)))
559                (if (eql g1 1)
560                  (%make-ratio (+ (* nx dy) (* dx ny)) (* dx dy))
561                  (let* ((t1 (+ (* nx (truncate dy g1)) (* (truncate dx g1) ny)))
562                         (g2 (gcd t1 g1))
563                         (t2 (truncate dx g1)))
564                    (cond ((eql t1 0) 0)
565                          ((eql g2 1) (%make-ratio t1 (* t2 dy)))
566                          (t
567                           (let* ((nn (truncate t1 g2))
568                                  (t3 (truncate dy g2))
569                                  (nd (if (eql t2 1) t3 (* t2 t3))))
570                             (if (eql nd 1) nn (%make-ratio nn nd)))))))))
571             (integer
572              (let* ((dx (%denominator x)) (n (+ (%numerator x) (* y dx))))
573                (%make-ratio n dx)))
574             (double-float (rat-dfloat + x y))
575             (short-float (rat-sfloat + x y))
576             (complex (complex (+ x (%realpart y)) 
577                               (%imagpart y)))))))
578
579(defun --2 (x y)     
580  (number-case x
581    (fixnum (number-case y
582              (fixnum (- (the fixnum x) (the fixnum y)))
583              (double-float (rat-dfloat - x y))
584              (short-float (rat-sfloat - x y))
585              (bignum 
586               (with-small-bignum-buffers ((bx x))
587                        (subtract-bignum bx y)))
588              (complex (complex (- x (%realpart y))
589                                (- (%imagpart y))))
590              (ratio (let* ((dy (%denominator y)) 
591                            (n (- (* x dy) (%numerator y))))
592                       (%make-ratio n dy)))))
593    (double-float (number-case y
594                    (double-float (- (the double-float x) (the double-float y)))
595                    (short-float (with-stack-double-floats ((dy y))
596                                   (- (the double-float x) (the double-float dy))))
597                    (rational (dfloat-rat - x y))
598                    (complex (complex (- x (%realpart y)) 
599                                      (- (%imagpart y))))))
600    (short-float (number-case y                               
601                   (short-float (- (the short-float x) (the short-float y)))
602                   (double-float (with-stack-double-floats ((dx x))
603                                   (- (the double-float dx) (the double-float y))))
604                   (rational (sfloat-rat - x y))
605                   (complex (complex (- x (%realpart y))
606                                     (- (%imagpart y))))))
607    (bignum (number-case y
608              (bignum (subtract-bignum x y))
609              (fixnum (if (eql y target::target-most-negative-fixnum)
610                        (with-small-bignum-buffers ((by y))
611                          (subtract-bignum x by))
612                        (add-bignum-and-fixnum x (- y))))
613              (double-float (rat-dfloat - x y))
614              (short-float (rat-sfloat - x y))
615              (complex (complex (- x (realpart y)) 
616                                (- (%imagpart y))))
617              (ratio
618               (let* ((dy (%denominator y))
619                      (n (- (* x dy) (%numerator y))))
620                 (%make-ratio n dy)))))
621    (complex (number-case y
622               (complex (canonical-complex (- (%realpart x) (%realpart y))
623                                           (- (%imagpart x) (%imagpart y))))
624               ((rational float) (complex (- (%realpart x) y) (%imagpart x)))))
625    (ratio (number-case y
626             (ratio
627              (let* ((nx (%numerator x))
628                     (dx (%denominator x))
629                     (ny (%numerator y))
630                     (dy (%denominator y))
631                     (g1 (gcd dx dy)))
632                (if (eql g1 1)
633                  (%make-ratio (- (* nx dy) (* dx ny)) (* dx dy))
634                  (let* ((t1 (- (* nx (truncate dy g1)) (* (truncate dx g1) ny)))
635                         (g2 (gcd t1 g1))
636                         (t2 (truncate dx g1)))
637                    (cond ((eql t1 0) 0)
638                          ((eql g2 1) (%make-ratio t1 (* t2 dy)))
639                          (t
640                           (let* ((nn (truncate t1 g2))
641                                  (t3 (truncate dy g2))
642                                  (nd (if (eql t2 1) t3 (* t2 t3))))
643                             (if (eql nd 1) nn (%make-ratio nn nd)))))))))
644             (integer
645              (let* ((dx (%denominator x)) (n (- (%numerator x) (* y dx))))
646                (%make-ratio n dx)))
647             (double-float (rat-dfloat - x y))
648             (short-float (rat-sfloat - x y))
649             (complex (complex (- x (%realpart y)) 
650                               (- (%imagpart y))))))))
651
652
653;;; BUILD-RATIO  --  Internal
654;;;
655;;;    Given a numerator and denominator with the GCD already divided out, make
656;;; a canonical rational.  We make the denominator positive, and check whether
657;;; it is 1.
658;;;
659
660(defun build-ratio (num den)
661  (if (minusp den) (setq num (- num) den (- den)))
662  (case den
663    (0 (divide-by-zero-error 'build-ratio num den))
664    (1 num)
665    (t (%make-ratio num den))))
666
667
668
669
670;;; MAYBE-TRUNCATE  --  Internal
671;;;
672;;;    Truncate X and Y, but bum the case where Y is 1.
673;;;
674
675
676(defun maybe-truncate (x y)
677  (if (eql y 1)
678    x
679    (truncate x y)))
680
681(defun *-2 (x y)
682  ;(declare (optimize (speed 3)(safety 0)))
683  (flet ((integer*ratio (x y)
684           (if (eql x 0) 0
685               (let* ((ny (%numerator y))
686                      (dy (%denominator y))
687                      (gcd (gcd x dy)))
688                 (if (eql gcd 1)
689                     (%make-ratio (* x ny) dy)
690                     (let ((nn (* (truncate x gcd) ny))
691                           (nd (truncate dy gcd)))
692                       (if (eql nd 1)
693                           nn
694                           (%make-ratio nn nd)))))))
695         (complex*real (x y)
696           (canonical-complex (* (%realpart x) y) (* (%imagpart x) y))))
697    (number-case x
698      (double-float (number-case y
699                      (double-float (* (the double-float x)(the double-float y)))
700                      (short-float (with-stack-double-floats ((dy y))
701                                     (* (the double-float x) (the double-float dy))))
702                      (rational (dfloat-rat * x y))
703                      (complex (complex*real y x))))
704      (short-float (number-case y
705                      (double-float (with-stack-double-floats ((dx x))
706                                     (* (the double-float dx) (the double-float y))))
707                      (short-float (* (the short-float x) (the short-float y)))
708                      (rational (sfloat-rat * x y))
709                      (complex (complex*real y x))))
710      (bignum (number-case y
711                (fixnum (multiply-bignum-and-fixnum x y))
712                (bignum (multiply-bignums x y))
713                (double-float (dfloat-rat * y x))
714                (short-float (sfloat-rat * y x))
715                (ratio (integer*ratio x y))
716                (complex (complex*real y x))))
717      (fixnum (number-case y
718                (bignum (multiply-bignum-and-fixnum y x))
719                (fixnum (multiply-fixnums (the fixnum x) (the fixnum y)))
720                (short-float (sfloat-rat * y x))
721                (double-float (dfloat-rat * y x))
722                (ratio (integer*ratio x y))
723                (complex (complex*real y x))))
724      (complex (number-case y
725                 (complex (let* ((rx (%realpart x))
726                                 (ix (%imagpart x))
727                                 (ry (%realpart y))
728                                 (iy (%imagpart y)))
729                            (canonical-complex (- (* rx ry) (* ix iy)) (+ (* rx iy) (* ix ry)))))
730                 (real (complex*real x y))))
731      (ratio (number-case y
732               (ratio (let* ((nx (%numerator x))
733                             (dx (%denominator x))
734                             (ny (%numerator y))
735                             (dy (%denominator y))
736                             (g1 (gcd nx dy))
737                             (g2 (gcd dx ny)))
738                        (build-ratio (* (maybe-truncate nx g1)
739                                        (maybe-truncate ny g2))
740                                     (* (maybe-truncate dx g2)
741                                        (maybe-truncate dy g1)))))
742               (integer (integer*ratio y x))
743               (double-float (rat-dfloat * x y))
744               (short-float (rat-sfloat * x y))
745               (complex (complex*real y x)))))))
746
747
748
749(defun integer*integer (x y &optional res)
750  (declare (ignore res))
751  (number-case x     
752      (fixnum (number-case y
753                (fixnum (* (the fixnum x) (the fixnum y)))
754                (t (multiply-bignum-and-fixnum y x))))
755      (bignum (number-case y
756                (fixnum (multiply-bignum-and-fixnum x y))
757                (t (multiply-bignums x y))))))
758
759
760
761 
762
763;;; INTEGER-/-INTEGER  --  Internal
764;;;
765;;;    Divide two integers, producing a canonical rational.  If a fixnum, we
766;;; see if they divide evenly before trying the GCD.  In the bignum case, we
767;;; don't bother, since bignum division is expensive, and the test is not very
768;;; likely to suceed.
769;;;
770(defun integer-/-integer (x y)
771  (if (and (typep x 'fixnum) (typep y 'fixnum))
772    (multiple-value-bind (quo rem) (%fixnum-truncate x y)
773      (if (eql 0 rem)
774        quo
775        (let ((gcd (gcd x y)))
776          (declare (fixnum gcd))
777          (if (eql gcd 1)
778            (build-ratio x y)
779            (build-ratio (%fixnum-truncate x gcd) (%fixnum-truncate y gcd))))))
780      (let ((gcd (gcd x y)))
781        (if (eql gcd 1)
782          (build-ratio x y)
783          (build-ratio (truncate x gcd) (truncate y gcd))))))
784
785
786
787(defun /-2 (x y)
788  (macrolet ((real-complex-/ (x y)
789               (let ((ry (gensym))
790                     (iy (gensym))
791                     (r (gensym))
792                     (dn (gensym)))
793                 `(let* ((,ry (%realpart ,y))
794                         (,iy (%imagpart ,y)))
795                    (if (> (abs ,ry) (abs ,iy))
796                      (let* ((,r (/ ,iy ,ry))
797                             (,dn (* ,ry (+ 1 (* ,r ,r)))))
798                        (canonical-complex (/ ,x ,dn)
799                                           (/ (- (* ,x ,r)) ,dn)))
800                      (let* ((,r (/ ,ry ,iy))
801                             (,dn (* ,iy (+ 1 (* ,r ,r)))))
802                        (canonical-complex (/ (* ,x ,r) ,dn)
803                                           (/ (- ,x) ,dn))))))))
804    (number-case x
805      (double-float (number-case y
806                      (double-float (/ (the double-float x) (the double-float y)))
807                      (short-float (with-stack-double-floats ((dy y))
808                                     (/ (the double-float x)
809                                        (the double-float dy))))
810                      (rational (dfloat-rat / x y))
811                      (complex (real-complex-/ x y))))
812      (short-float (number-case y
813                     (short-float (/ (the short-float x) (the short-float y)))
814                     (double-float (with-stack-double-floats ((dx x))
815                                     (/ (the double-float dx)
816                                        (the double-float y))))
817                     (rational (sfloat-rat / x y))
818                     (complex (real-complex-/ x y))))
819      (integer (number-case y
820                 (double-float (rat-dfloat / x y))
821                 (short-float (rat-sfloat / x y))
822                 (integer (integer-/-integer x y))
823                 (complex (real-complex-/ x y))
824                 (ratio
825                  (if (eql 0 x)
826                    0
827                    (let* ((ny (%numerator y)) 
828                           (dy (%denominator y)) 
829                           (gcd (gcd x ny)))
830                      (build-ratio (* (maybe-truncate x gcd) dy)
831                                   (maybe-truncate ny gcd)))))))
832      (complex (number-case y
833                 (complex (let* ((rx (%realpart x))
834                                 (ix (%imagpart x))
835                                 (ry (%realpart y))
836                                 (iy (%imagpart y)))
837                            (if (> (abs ry) (abs iy))
838                              (let* ((r (/ iy ry))
839                                     (dn (+ ry (* r iy))))
840                                (canonical-complex (/ (+ rx (* ix r)) dn)
841                                                   (/ (- ix (* rx r)) dn)))
842                              (let* ((r (/ ry iy))
843                                     (dn (+ iy (* r ry))))
844                                (canonical-complex (/ (+ (* rx r) ix) dn)
845                                                   (/ (- (* ix r) rx) dn))))))
846                 ((rational float)
847                  (canonical-complex (/ (%realpart x) y) (/ (%imagpart x) y)))))
848      (ratio (number-case y
849               (double-float (rat-dfloat / x y))
850               (short-float (rat-sfloat / x y))
851               (integer
852                (when (eql y 0)
853                  (divide-by-zero-error '/ x y))
854                (let* ((nx (%numerator x)) (gcd (gcd nx y)))
855                  (build-ratio (maybe-truncate nx gcd)
856                               (* (maybe-truncate y gcd) (%denominator x)))))
857               (complex (real-complex-/ x y))
858               (ratio
859                (let* ((nx (%numerator x))
860                       (dx (%denominator x))
861                       (ny (%numerator y))
862                       (dy (%denominator y))
863                       (g1 (gcd nx ny))
864                       (g2 (gcd dx dy)))
865                  (build-ratio (* (maybe-truncate nx g1)
866                                  (maybe-truncate dy g2))
867                               (* (maybe-truncate dx g2)
868                                  (maybe-truncate ny g1))))))))))
869
870
871
872(defun divide-by-zero-error (operation &rest operands)
873  (error (make-condition 'division-by-zero
874           :operation operation
875           :operands operands)))
876
877
878(defun 1+ (number)
879  "Returns NUMBER + 1."
880  (+-2 number 1))
881
882(defun 1- (number)
883  "Returns NUMBER - 1."
884  (--2 number 1))
885
886
887
888
889(defun conjugate (number)
890  "Return the complex conjugate of NUMBER. For non-complex numbers, this is
891  an identity."
892  (number-case number
893    (complex (complex (%realpart number) (- (%imagpart number))))
894    (number number)))
895
896(defun numerator (rational)
897  "Return the numerator of NUMBER, which must be rational."
898  (number-case rational
899    (ratio (%numerator rational))
900    (integer rational)))
901
902(defun denominator (rational)
903  "Return the denominator of NUMBER, which must be rational."
904  (number-case rational
905    (ratio (%denominator rational))
906    (integer 1)))
907
908
909
910(defun abs (number)
911  "Return the absolute value of the number."
912  (number-case number
913   (fixnum
914    (locally (declare (fixnum number))
915      (if (minusp number) (- number) number)))
916   (double-float
917    (%double-float-abs number))
918   (short-float
919    (%short-float-abs number))
920   (bignum
921    (if (bignum-minusp number)(negate-bignum number) number))
922   (ratio
923    (if (minusp number) (- number) number))   
924   (complex
925    (let ((rx (%realpart number))
926          (ix (%imagpart number)))
927      (number-case rx
928        (rational
929         (sqrt (+ (* rx rx) (* ix ix))))
930        (short-float
931         (%short-float (%double-float-hypot (%double-float rx)
932                                            (%double-float ix))))
933        (double-float
934         (%double-float-hypot rx ix)))))))
935
936
937
938(defun phase (number)
939  "Return the angle part of the polar representation of a complex number.
940  For complex numbers, this is (atan (imagpart number) (realpart number)).
941  For non-complex positive numbers, this is 0. For non-complex negative
942  numbers this is PI."
943  (number-case number
944    (rational
945     (if (minusp number)
946       (%short-float pi)
947       0.0f0))
948    (double-float
949     (if (minusp number)
950       (%double-float pi)
951       0.0d0))
952    (complex
953     (atan (%imagpart number) (%realpart number)))
954    (short-float
955     (if (minusp number)
956       (%short-float pi)
957       0.0s0))))
958
959
960
961; from Lib;numbers.lisp, sort of
962(defun float (number &optional other)
963  "Converts any REAL to a float. If OTHER is not provided, it returns a
964  SINGLE-FLOAT if NUMBER is not already a FLOAT. If OTHER is provided, the
965  result is the same float format as OTHER."
966  (if (null other)
967    (if (typep number 'float)
968      number
969      (%short-float number))
970    (if (typep other 'double-float)
971      (%double-float number)
972      (if (typep other 'short-float)
973        (%short-float number)
974        (float number (require-type other 'float))))))
975
976
977
978
979
980;;; If the numbers do not divide exactly and the result of (/ number divisor)
981;;; would be negative then decrement the quotient and augment the remainder by
982;;; the divisor.
983;;;
984(defun floor (number &optional divisor)
985  "Return the greatest integer not greater than number, or number/divisor.
986  The second returned value is (mod number divisor)."
987  (if (null divisor)(setq divisor 1))
988  (multiple-value-bind (tru rem) (truncate number divisor)
989    (if (and (not (zerop rem))
990             (if (minusp divisor)
991               (plusp number)
992               (minusp number)))
993      (if (called-for-mv-p)
994        (values (1- tru) (+ rem divisor))
995        (1- tru))
996      (values tru rem))))
997
998
999
1000(defun %fixnum-floor (number divisor)
1001  (declare (fixnum number divisor))
1002  (if (eq divisor 1)
1003    (values number 0)
1004    (multiple-value-bind (tru rem) (truncate number divisor)
1005      (if (eq rem 0)
1006        (values tru 0)
1007        (locally (declare (fixnum tru rem))
1008          (if (and ;(not (zerop rem))
1009                   (if (minusp divisor)
1010                     (plusp number)
1011                     (minusp number)))
1012            (values (the fixnum (1- tru)) (the fixnum (+ rem divisor)))
1013            (values tru rem)))))))
1014
1015
1016
1017;;; If the numbers do not divide exactly and the result of (/ number divisor)
1018;;; would be positive then increment the quotient and decrement the remainder by
1019;;; the divisor.
1020;;;
1021(defun ceiling (number &optional divisor)
1022  "Return the smallest integer not less than number, or number/divisor.
1023  The second returned value is the remainder."
1024  (if (null divisor)(setq divisor 1))
1025  (multiple-value-bind (tru rem) (truncate number divisor)
1026    (if (and (not (zerop rem))
1027             (if (minusp divisor)
1028               (minusp number)
1029               (plusp number)))
1030      (if (called-for-mv-p)
1031        (values (+ tru 1) (- rem divisor))
1032        (+ tru 1))
1033      (values tru rem))))
1034
1035
1036
1037(defun %fixnum-ceiling (number  divisor)
1038  "Returns the smallest integer not less than number, or number/divisor.
1039  The second returned value is the remainder."
1040  (declare (fixnum number divisor))
1041  (multiple-value-bind (tru rem) (%fixnum-truncate number divisor)
1042    (if (eq 0 rem)
1043      (values tru 0)
1044      (locally (declare (fixnum tru rem))
1045        (if (and ;(not (zerop rem))
1046             (if (minusp divisor)
1047               (minusp number)
1048               (plusp number)))
1049          (values (the fixnum (+ tru 1))(the fixnum  (- rem divisor)))
1050          (values tru rem))))))
1051
1052
1053
1054(defun integer-decode-denorm-short-float (mantissa sign)
1055  (declare (fixnum mantissa sign))
1056  (do* ((bias 0 (1+ bias))
1057        (sig mantissa (ash sig 1)))
1058       ((logbitp 23 sig)
1059        (values sig
1060                (- (- IEEE-single-float-bias)
1061                   IEEE-single-float-digits
1062                   bias)
1063                sign))))
1064
1065
1066(defun integer-decode-short-float (sfloat)
1067  (multiple-value-bind (mantissa exp sign)(fixnum-decode-short-float sfloat)
1068    (let* ((biased (- exp IEEE-single-float-bias IEEE-single-float-digits)))
1069      (setq sign (if (eql 0 sign) 1 -1))
1070      (if (eq exp 255)
1071        (error "Can't decode NAN/Inf: ~s" sfloat))
1072      (if (eql 0 exp)
1073        (if (eql 0 mantissa)
1074          (values 0 biased sign)
1075          (integer-decode-denorm-short-float (ash mantissa 1) sign))
1076        (values (logior #x800000 mantissa) biased sign)))))
1077
1078
1079
1080
1081;;; INTEGER-DECODE-FLOAT  --  Public
1082;;;
1083;;;    Dispatch to the correct type-specific i-d-f function.
1084;;;
1085(defun integer-decode-float (x)
1086  "Returns three values:
1087   1) an integer representation of the significand.
1088   2) the exponent for the power of 2 that the significand must be multiplied
1089      by to get the actual value.  This differs from the DECODE-FLOAT exponent
1090      by FLOAT-DIGITS, since the significand has been scaled to have all its
1091      digits before the radix point.
1092   3) -1 or 1 (i.e. the sign of the argument.)"
1093  (number-case x
1094    (short-float
1095     (integer-decode-short-float x))
1096    (double-float
1097     (integer-decode-double-float x))))
1098
1099
1100;;; %UNARY-TRUNCATE  --  Interface
1101;;;
1102;;;    This function is called when we are doing a truncate without any funky
1103;;; divisor, i.e. converting a float or ratio to an integer.  Note that we do
1104;;; *not* return the second value of truncate, so it must be computed by the
1105;;; caller if needed.
1106;;;
1107;;;    In the float case, we pick off small arguments so that compiler can use
1108;;; special-case operations.  We use an exclusive test, since (due to round-off
1109;;; error), (float most-positive-fixnum) may be greater than
1110;;; most-positive-fixnum.
1111;;;
1112(defun %unary-truncate (number)
1113  (number-case number
1114    (integer number)
1115    (ratio (truncate-no-rem (%numerator number) (%denominator number)))
1116    (double-float
1117     (if (and (< (the double-float number) 
1118                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 0.0d0))
1119              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 0.0d0)
1120                 (the double-float number)))
1121       (%truncate-double-float->fixnum number)
1122       (%truncate-double-float number)))
1123    (short-float
1124     (if (and (< (the short-float number) 
1125                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 0.0s0))
1126              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 0.0s0)
1127                 (the short-float number)))
1128       (%truncate-short-float->fixnum number)
1129       (%truncate-short-float number)))))
1130
1131
1132
1133; cmucl:compiler:float-tran.lisp
1134(defun xform-truncate (x)
1135  (let ((res (%unary-truncate x)))
1136    (values res (- x res))))
1137
1138
1139
1140(defun truncate (number &optional divisor)
1141  "Returns number (or number/divisor) as an integer, rounded toward 0.
1142  The second returned value is the remainder."
1143  (if (null divisor)(setq divisor 1))
1144  (when (not (called-for-mv-p))
1145    (return-from truncate (truncate-no-rem number divisor)))
1146  (macrolet 
1147      ((truncate-rat-dfloat (number divisor)
1148         `(with-stack-double-floats ((fnum ,number)
1149                                     (f2))
1150           (let ((res (%unary-truncate (%double-float/-2! fnum ,divisor f2))))
1151             (values res 
1152                     (%double-float--2 fnum (%double-float*-2! (%double-float res f2) ,divisor f2))))))
1153       (truncate-rat-sfloat (number divisor)
1154         #+32-bit-target
1155         `(target::with-stack-short-floats ((fnum ,number)
1156                                            (f2))
1157           (let ((res (%unary-truncate (%short-float/-2! fnum ,divisor f2))))
1158             (values res 
1159                     (%short-float--2 fnum (%short-float*-2! (%short-float res f2) ,divisor f2)))))
1160         #+64-bit-target
1161         `(let* ((temp (%short-float ,number))
1162                 (res (%unary-truncate (/ (the short-float temp)
1163                                          (the short-float ,divisor)))))
1164           (values res
1165            (- (the short-float temp)
1166             (the short-float (* (the short-float (%short-float res))
1167                                 (the short-float ,divisor)))))))
1168       )
1169    (number-case number
1170      (fixnum
1171       (number-case divisor
1172         (fixnum (if (eq divisor 1) (values number 0) (%fixnum-truncate number divisor)))
1173         (bignum (if (eq number target::target-most-negative-fixnum)
1174                   (with-small-bignum-buffers ((bn number))
1175                     (bignum-truncate bn divisor))
1176                   (values 0 number)))
1177         (double-float (truncate-rat-dfloat number divisor))
1178         (short-float (truncate-rat-sfloat number divisor))
1179         (ratio (let ((q (truncate (* number (%denominator divisor)) ; this was wrong
1180                                   (%numerator divisor))))
1181                  (values q (- number (* q divisor)))))))
1182      (bignum (number-case divisor
1183                (fixnum (if (eq divisor 1)
1184                          (values number 0)
1185                          (if (eq divisor target::target-most-negative-fixnum);; << aargh
1186                            (with-small-bignum-buffers ((bd divisor))
1187                              (bignum-truncate number bd))
1188                            (bignum-truncate-by-fixnum number divisor))))
1189                (bignum (bignum-truncate number divisor))
1190                (double-float  (truncate-rat-dfloat number divisor))
1191                (short-float (truncate-rat-sfloat number divisor))
1192                (ratio (let ((q (truncate (* number (%denominator divisor)) ; so was this
1193                                          (%numerator divisor))))
1194                         (values q (- number (* q divisor)))))))
1195      (short-float (if (eql divisor 1)
1196                     (let* ((res (%unary-truncate number)))
1197                       (values res (- number res)))
1198                     (number-case divisor
1199                       (short-float
1200                        #+32-bit-target
1201                        (target::with-stack-short-floats ((f2))
1202                          (let ((res (%unary-truncate (%short-float/-2! number divisor f2))))
1203                            (values res 
1204                                    (%short-float--2
1205                                     number 
1206                                     (%short-float*-2! (%short-float res f2) divisor f2)))))
1207                        #+64-bit-target
1208                        (let ((res (%unary-truncate
1209                                    (/ (the short-float number)
1210                                       (the short-float divisor)))))
1211                          (values res
1212                                  (- (the short-float number)
1213                                     (* (the short-float (%short-float res))
1214                                        (the short-float divisor))))))
1215                       ((fixnum bignum ratio)
1216                        #+32-bit-target
1217                        (target::with-stack-short-floats ((fdiv divisor)
1218                                                          (f2))
1219                          (let ((res (%unary-truncate (%short-float/-2! number fdiv f2))))
1220                            (values res 
1221                                    (%short-float--2 
1222                                     number 
1223                                     (%short-float*-2! (%short-float res f2) fdiv f2)))))
1224                        #+64-bit-target
1225                        (let* ((fdiv (%short-float divisor))
1226                               (res (%unary-truncate
1227                                     (/ (the short-float number)
1228                                        (the short-float fdiv)))))
1229                          (values res (- number (* res fdiv))))
1230                                     
1231                        )
1232                       (double-float
1233                        (with-stack-double-floats ((fnum number)
1234                                                   (f2))
1235                          (let* ((res (%unary-truncate (%double-float/-2! fnum divisor f2))))
1236                            (values res
1237                                    (%double-float--2
1238                                     fnum
1239                                     (%double-float*-2! (%double-float res f2) divisor f2)))))))))
1240      (double-float (if (eql divisor 1)
1241                      (let ((res (%unary-truncate number)))
1242                        (values res (- number res)))
1243                      (number-case divisor
1244                        ((fixnum bignum ratio short-float)
1245                         (with-stack-double-floats ((fdiv divisor)
1246                                                    (f2))
1247                           (let ((res (%unary-truncate (%double-float/-2! number fdiv f2))))
1248                             (values res 
1249                                     (%double-float--2 
1250                                      number 
1251                                      (%double-float*-2! (%double-float res f2) fdiv f2))))))                       
1252                        (double-float
1253                         (with-stack-double-floats ((f2))
1254                           (let ((res (%unary-truncate (%double-float/-2! number divisor f2))))
1255                             (values res 
1256                                     (%double-float--2
1257                                      number 
1258                                      (%double-float*-2! (%double-float res f2) divisor f2)))))))))
1259      (ratio (number-case divisor
1260               (double-float (truncate-rat-dfloat number divisor))
1261               (short-float (truncate-rat-sfloat number divisor))
1262               (rational
1263                (let ((q (truncate (%numerator number)
1264                                   (* (%denominator number) divisor))))
1265                  (values q (- number (* q divisor))))))))))
1266
1267(defun truncate-no-rem (number  divisor)
1268  "Returns number (or number/divisor) as an integer, rounded toward 0."
1269  (macrolet 
1270    ((truncate-rat-dfloat (number divisor)
1271       `(with-stack-double-floats ((fnum ,number)
1272                                      (f2))
1273         (%unary-truncate (%double-float/-2! fnum ,divisor f2))))
1274     (truncate-rat-sfloat (number divisor)
1275       #+32-bit-target
1276       `(target::with-stack-short-floats ((fnum ,number)
1277                                      (f2))
1278         (%unary-truncate (%short-float/-2! fnum ,divisor f2)))
1279       #+64-bit-target
1280       `(let ((fnum (%short-float ,number)))
1281         (%unary-truncate (/ (the short-float fnum)
1282                           (the short-float ,divisor))))))
1283    (number-case number
1284    (fixnum
1285     (if (eql number target::target-most-negative-fixnum)
1286       (if (zerop divisor)
1287         (error 'division-by-zero :operation 'truncate :operands (list number divisor))
1288         (with-small-bignum-buffers ((bn number))
1289           (let* ((result (truncate-no-rem bn divisor)))
1290             (if (eq result bn)
1291               number
1292               result))))
1293       (number-case divisor
1294         (fixnum (if (eq divisor 1) number (values (%fixnum-truncate number divisor))))
1295         (bignum 0)
1296         (double-float (truncate-rat-dfloat number divisor))
1297         (short-float (truncate-rat-sfloat number divisor))
1298         (ratio (let ((q (truncate (* number (%denominator divisor))
1299                                   (%numerator divisor))))
1300                  q)))))
1301     (bignum (number-case divisor
1302               (fixnum (if (eq divisor 1) number
1303                         (if (eq divisor target::target-most-negative-fixnum)
1304                           (with-small-bignum-buffers ((bd divisor))
1305                             (bignum-truncate number bd :no-rem))
1306                           (bignum-truncate-by-fixnum number divisor))))
1307               (bignum (bignum-truncate number divisor :no-rem))
1308               (double-float  (truncate-rat-dfloat number divisor))
1309               (short-float (truncate-rat-sfloat number divisor))
1310               (ratio (let ((q (truncate (* number (%denominator divisor))
1311                                         (%numerator divisor))))
1312                        Q))))
1313     (double-float (if (eql divisor 1)
1314                     (let ((res (%unary-truncate number)))
1315                       RES)
1316                     (number-case divisor
1317                       ((fixnum bignum ratio)
1318                        (with-stack-double-floats ((fdiv divisor)
1319                                                   (f2))
1320                          (let ((res (%unary-truncate (%double-float/-2! number fdiv f2))))
1321                            RES)))
1322                       (short-float
1323                        (with-stack-double-floats ((ddiv divisor)
1324                                                   (f2))
1325                          (%unary-truncate (%double-float/-2! number ddiv f2))))
1326                       (double-float
1327                        (with-stack-double-floats ((f2))
1328                          (%unary-truncate (%double-float/-2! number divisor f2)))))))
1329     (short-float (if (eql divisor 1)
1330                    (let ((res (%unary-truncate number)))
1331                      RES)
1332                    (number-case divisor
1333                      ((fixnum bignum ratio)
1334                       #+32-bit-target
1335                       (target::with-stack-short-floats ((fdiv divisor)
1336                                                 (f2))
1337                         (let ((res (%unary-truncate (%short-float/-2! number fdiv f2))))
1338                           RES))
1339                       #+64-bit-target
1340                       (%unary-truncate (/ (the short-float number)
1341                                           (the short-float (%short-float divisor)))))
1342                      (short-float
1343                       #+32-bit-target
1344                       (target::with-stack-short-floats ((ddiv divisor)
1345                                                      (f2))
1346                         (%unary-truncate (%short-float/-2! number ddiv f2)))
1347                       #+64-bit-target
1348                       (%unary-truncate (/ (the short-float number)
1349                                           (the short-float (%short-float divisor)))))
1350                      (double-float
1351                       (with-stack-double-floats ((n2 number)
1352                                                      (f2))
1353                         (%unary-truncate (%double-float/-2! n2 divisor f2)))))))
1354    (ratio (number-case divisor
1355                  (double-float (truncate-rat-dfloat number divisor))
1356                  (short-float (truncate-rat-sfloat number divisor))
1357                  (rational
1358                   (let ((q (truncate (%numerator number)
1359                                      (* (%denominator number) divisor))))
1360                     Q)))))))
1361
1362
1363;;; %UNARY-ROUND  --  Interface
1364;;;
1365;;;    Similar to %UNARY-TRUNCATE, but rounds to the nearest integer.  If we
1366;;; can't use the round primitive, then we do our own round-to-nearest on the
1367;;; result of i-d-f.  [Note that this rounding will really only happen with
1368;;; double floats, since the whole single-float fraction will fit in a fixnum,
1369;;; so all single-floats larger than most-positive-fixnum can be precisely
1370;;; represented by an integer.]
1371;;;
1372;;; returns both values today
1373
1374(defun %unary-round (number)
1375  (number-case number
1376    (integer (values number 0))
1377    (ratio (let ((q (round (%numerator number) (%denominator number))))             
1378             (values q (- number q))))
1379    (double-float
1380     (if (and (< (the double-float number) 
1381                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 1.0d0))
1382              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 1.0d0)
1383                 (the double-float number)))
1384       (let ((round (%unary-round-to-fixnum number)))
1385         (values round (- number round)))
1386       (multiple-value-bind (trunc rem) (truncate number)         
1387         (if (not (%double-float-minusp number))
1388           (if (or (> rem 0.5d0)(and (= rem 0.5d0) (oddp trunc)))
1389             (values (+ trunc 1) (- rem 1.0d0))
1390             (values trunc rem))
1391           (if (or (> rem -0.5d0)(and (evenp trunc)(= rem -0.5d0)))
1392             (values trunc rem)
1393             (values (1- trunc) (+ 1.0d0 rem)))))))
1394    (short-float
1395     (if (and (< (the short-float number) 
1396                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 1.0s0))
1397              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 1.0s0)
1398                 (the double-float number)))
1399       (let ((round (%unary-round-to-fixnum number)))
1400         (values round (- number round)))
1401       (multiple-value-bind (trunc rem) (truncate number)         
1402         (if (not (%short-float-minusp number))
1403           (if (or (> rem 0.5s0)(and (= rem 0.5s0) (oddp trunc)))
1404             (values (+ trunc 1) (- rem 1.0s0))
1405             (values trunc rem))
1406           (if (or (> rem -0.5s0)(and (evenp trunc)(= rem -0.5s0)))
1407             (values trunc rem)
1408             (values (1- trunc) (+ 1.0s0 rem)))))))))
1409
1410(defun %unary-round-to-fixnum (number)
1411  (number-case number
1412    (double-float
1413     (%round-nearest-double-float->fixnum number))
1414    (short-float
1415     (%round-nearest-short-float->fixnum number))))
1416
1417                         
1418                               
1419         
1420; cmucl:compiler:float-tran.lisp
1421#|
1422(defun xform-round (x)
1423  (let ((res (%unary-round x)))
1424    (values res (- x res))))
1425|#
1426
1427#|
1428(defun round (number &optional divisor)
1429  "Rounds number (or number/divisor) to nearest integer.
1430  The second returned value is the remainder."
1431  (if (null divisor)(setq divisor 1))
1432  (if (eql divisor 1)
1433    (xform-round number)
1434    (multiple-value-bind (tru rem) (truncate number divisor)
1435      (let ((thresh (if (integerp divisor) (ash (abs divisor) -1)(/ (abs divisor) 2)))) ; does this need to be a ratio?
1436        (cond ((or (> rem thresh)
1437                   (and (= rem thresh) (oddp tru)))
1438               (if (minusp divisor)
1439                 (values (- tru 1) (+ rem divisor))
1440                 (values (+ tru 1) (- rem divisor))))
1441              ((let ((-thresh (- thresh)))
1442                 (or (< rem -thresh)
1443                     (and (= rem -thresh) (oddp tru))))
1444               (if (minusp divisor)
1445                 (values (+ tru 1) (- rem divisor))
1446                 (values (- tru 1) (+ rem divisor))))
1447              (t (values tru rem)))))))
1448|#
1449
1450
1451(defun %fixnum-round (number divisor)
1452  (declare (fixnum number divisor))
1453  (multiple-value-bind (quo rem)(truncate number divisor) ; should => %fixnum-truncate
1454    (if (= 0 rem)
1455      (values quo rem)
1456      (locally (declare (fixnum quo rem))
1457        (let* ((minusp-num (minusp number))
1458               (minusp-div (minusp divisor))
1459               (2rem (* rem (if (neq minusp-num minusp-div) -2 2))))
1460          ;(declare (fixnum 2rem)) ; no way jose 
1461          ;(truncate (1- most-positive-fixnum) most-positive-fixnum)
1462          ; 2rem has same sign as divisor
1463          (cond (minusp-div             
1464                 (if (or (< 2rem divisor)
1465                         (and (= 2rem divisor)(logbitp 0 quo)))
1466                   (if minusp-num
1467                     (values (the fixnum (+ quo 1))(the fixnum (- rem divisor)))
1468                     (values (the fixnum (- quo 1))(the fixnum (+ rem divisor))))
1469                   (values quo rem)))
1470                (t (if (or (> 2rem divisor)
1471                           (and (= 2rem divisor)(logbitp 0 quo)))
1472                     (if minusp-num
1473                       (values (the fixnum (- quo 1))(the fixnum (+ rem divisor)))
1474                       (values (the fixnum (+ quo 1))(the fixnum (- rem divisor))))
1475                     (values quo rem)))))))))
1476#|
1477; + + => + +
1478; + - => - +
1479; - + => - -
1480; - - => + -
1481(defun %fixnum-round (number divisor)
1482  (declare (fixnum number divisor))
1483  "Rounds number (or number/divisor) to nearest integer.
1484  The second returned value is the remainder."
1485  (if (eq divisor 1)
1486    (values number 0)
1487    (multiple-value-bind (tru rem) (truncate number divisor)
1488      (if (= 0 rem)
1489        (values tru rem)
1490        (locally (declare (fixnum tru rem))
1491          (let* ((minusp-num (minusp number))
1492                 (minusp-div (minusp divisor))
1493                 (half-div (ash (if minusp-div (- divisor) divisor) -1))
1494                 (abs-rem (if minusp-num (- rem) rem)))           
1495            (declare (fixnum half-div abs-rem)) ; true of abs-rem?
1496            (if (or (> abs-rem half-div)
1497                    (and
1498                     (not (logbitp 0 divisor))
1499                     (logbitp 0 tru) ; oddp
1500                     (= abs-rem half-div)))
1501              (if (eq minusp-num minusp-div)
1502                (values (the fixnum (+ tru 1))(the fixnum (- rem divisor)))
1503                (values (the fixnum (- tru 1))(the fixnum (+ rem divisor))))
1504              (values tru rem))))))))
1505|#
1506
1507
1508
1509;; makes 1 piece of garbage instead of average of 2
1510(defun round (number &optional divisor)
1511  "Rounds number (or number/divisor) to nearest integer.
1512  The second returned value is the remainder."
1513  (if (null divisor)(setq divisor 1))
1514  (if (eql divisor 1)
1515    (%unary-round number)
1516    (multiple-value-bind (tru rem) (truncate number divisor)
1517      (if (= 0 rem)
1518        (values tru rem)
1519        (let* ((mv-p (called-for-mv-p))
1520               (minusp-num (minusp number))
1521               (minusp-div (minusp divisor))
1522               (2rem (* rem (if (neq minusp-num minusp-div) -2 2))))
1523          ; 2rem has same sign as divisor
1524          (cond (minusp-div             
1525                 (if (or (< 2rem divisor)
1526                         (and (= 2rem divisor)(oddp tru)))
1527                   (if mv-p
1528                     (if minusp-num
1529                       (values (+ tru 1)(- rem divisor))
1530                       (values (- tru 1)(+ rem divisor)))
1531                     (if minusp-num (+ tru 1)(- tru 1)))
1532                   (values tru rem)))
1533                (t (if (or (> 2rem divisor)
1534                           (and (= 2rem divisor)(oddp tru)))
1535                     (if mv-p
1536                       (if minusp-num
1537                         (values (- tru 1)(+ rem divisor))
1538                         (values (+ tru 1)(- rem divisor)))
1539                       (if minusp-num (- tru 1)(+ tru 1)))
1540                     (values tru rem)))))))))
1541
1542
1543;; #-PPC IN L1-NUMBERS.LISP (or implement %%numdiv)
1544;; Anyone caught implementing %%numdiv will be summarily executed.
1545(defun rem (number divisor)
1546  "Returns second result of TRUNCATE."
1547  (number-case number
1548    (fixnum
1549     (number-case divisor
1550       (fixnum (nth-value 1 (%fixnum-truncate number divisor)))
1551       (bignum number)
1552       (t (nth-value 1 (truncate number divisor)))))
1553    (bignum
1554     (number-case divisor
1555       (fixnum
1556        (if (eq divisor target::target-most-negative-fixnum)
1557          (nth-value 1 (truncate number divisor))
1558          (bignum-truncate-by-fixnum-no-quo number divisor)))
1559       (bignum
1560        (bignum-rem number divisor))
1561       (t (nth-value 1 (truncate number divisor)))))
1562    (t (nth-value 1 (truncate number divisor)))))
1563
1564;; #-PPC IN L1-NUMBERS.LISP (or implement %%numdiv)
1565;; See above.
1566(defun mod (number divisor)
1567  "Returns second result of FLOOR."
1568  (let ((rem (rem number divisor)))
1569    (if (and (not (zerop rem))
1570             (if (minusp divisor)
1571                 (plusp number)
1572                 (minusp number)))
1573        (+ rem divisor)
1574        rem)))
1575
1576(defun cis (theta)
1577  "Return cos(Theta) + i sin(Theta), i.e. exp(i Theta)."
1578  (if (complexp theta)
1579    (error "Argument to CIS is complex: ~S" theta)
1580    (complex (cos theta) (sin theta))))
1581
1582
1583(defun complex (realpart &optional (imagpart 0))
1584  "Return a complex number with the specified real and imaginary components."
1585  (number-case realpart
1586    (short-float
1587      (number-case imagpart
1588         (short-float (canonical-complex realpart imagpart))
1589         (double-float (canonical-complex (%double-float realpart) imagpart))
1590         (rational (canonical-complex realpart (%short-float imagpart)))))
1591    (double-float 
1592     (number-case imagpart
1593       (double-float (canonical-complex
1594                      (the double-float realpart)
1595                      (the double-float imagpart)))
1596       (short-float (canonical-complex realpart (%double-float imagpart)))
1597       (rational (canonical-complex
1598                              (the double-float realpart)
1599                              (the double-float (%double-float imagpart))))))
1600    (rational (number-case imagpart
1601                (double-float (canonical-complex
1602                               (the double-float (%double-float realpart))
1603                               (the double-float imagpart)))
1604                (short-float (canonical-complex (%short-float realpart) imagpart))
1605                (rational (canonical-complex realpart imagpart)))))) 
1606
1607;; #-PPC IN L1-NUMBERS.LISP
1608(defun realpart (number)
1609  "Extract the real part of a number."
1610  (number-case number
1611    (complex (%realpart number))
1612    (number number)))
1613
1614;; #-PPC IN L1-NUMBERS.LISP
1615(defun imagpart (number)
1616  "Extract the imaginary part of a number."
1617  (number-case number
1618    (complex (%imagpart number))
1619    (float (* 0 number))
1620    (rational 0)))
1621
1622(defun logand-2 (x y) 
1623  (number-case x
1624    (fixnum (number-case y
1625              (fixnum
1626               (%ilogand (the fixnum x)(the fixnum y)))
1627              (bignum (fix-big-logand x y))))
1628    (bignum (number-case y
1629              (fixnum (fix-big-logand y x))
1630              (bignum (bignum-logical-and x y))))))
1631
1632(defun logior-2 (x y)
1633  (number-case x
1634    (fixnum (number-case y
1635              (fixnum (%ilogior2 x y))
1636              (bignum
1637               (if (zerop x)
1638                 y
1639                 (with-small-bignum-buffers ((bx x))
1640                   (bignum-logical-ior bx y))))))
1641    (bignum (number-case y
1642              (fixnum (if (zerop y)
1643                        x
1644                        (with-small-bignum-buffers ((by y))
1645                          (bignum-logical-ior x by))))
1646              (bignum (bignum-logical-ior x y))))))
1647
1648(defun logxor-2 (x y)
1649  (number-case x
1650    (fixnum (number-case y
1651              (fixnum (%ilogxor2 x y))
1652              (bignum
1653               (with-small-bignum-buffers ((bx x))
1654                 (bignum-logical-xor bx y)))))
1655    (bignum (number-case y
1656              (fixnum (with-small-bignum-buffers ((by y))
1657                        (bignum-logical-xor x by)))
1658              (bignum (bignum-logical-xor x y))))))
1659
1660               
1661
1662; see cmucl:compiler:srctran.lisp for transforms
1663
1664(defun lognand (integer1 integer2)
1665  "Complement the logical AND of INTEGER1 and INTEGER2."
1666  (lognot (logand integer1 integer2)))
1667
1668(defun lognor (integer1 integer2)
1669  "Complement the logical AND of INTEGER1 and INTEGER2."
1670  (lognot (logior integer1 integer2)))
1671
1672(defun logandc1 (x y)
1673  "Return the logical AND of (LOGNOT integer1) and integer2."
1674  (number-case x
1675    (fixnum (number-case y               
1676              (fixnum (%ilogand (%ilognot x) y))
1677              (bignum  (fix-big-logandc1 x y))))    ; (%ilogand-fix-big (%ilognot x) y))))
1678    (bignum (number-case y
1679              (fixnum  (fix-big-logandc2 y x))      ; (%ilogandc2-fix-big y x))
1680              (bignum (bignum-logandc2 y x))))))    ;(bignum-logical-and (bignum-logical-not x)  y))))))
1681
1682
1683#| ; its in numbers
1684(defun logandc2 (integer1 integer2)
1685  "Returns the logical AND of integer1 and (LOGNOT integer2)."
1686  (logand integer1 (lognot integer2)))
1687|#
1688
1689(defun logorc1 (integer1 integer2)
1690  "Return the logical OR of (LOGNOT integer1) and integer2."
1691  (logior (lognot integer1) integer2))
1692
1693#|
1694(defun logorc2 (integer1 integer2)
1695  "Returns the logical OR of integer1 and (LOGNOT integer2)."
1696  (logior integer1 (lognot integer2)))
1697|#
1698
1699(defun logtest (integer1 integer2)
1700  "Predicate which returns T if logand of integer1 and integer2 is not zero."
1701 ; (not (zerop (logand integer1 integer2)))
1702  (number-case integer1
1703    (fixnum (number-case integer2
1704              (fixnum (not (= 0 (%ilogand integer1 integer2))))
1705              (bignum (logtest-fix-big integer1 integer2))))
1706    (bignum (number-case integer2
1707              (fixnum (logtest-fix-big integer2 integer1))
1708              (bignum (bignum-logtest integer1 integer2)))))) 
1709
1710
1711
1712(defun lognot (number)
1713  "Return the bit-wise logical not of integer."
1714  (number-case number
1715    (fixnum (%ilognot number))
1716    (bignum (bignum-logical-not number))))
1717
1718(defun logcount (integer)
1719  "Count the number of 1 bits if INTEGER is positive, and the number of 0 bits
1720  if INTEGER is negative."
1721  (number-case integer
1722    (fixnum
1723     (%ilogcount (if (minusp (the fixnum integer))
1724                   (%ilognot integer)
1725                   integer)))
1726    (bignum
1727     (bignum-logcount integer))))
1728
1729
1730
1731(defun ash (integer count)
1732  "Shifts integer left by count places preserving sign. - count shifts right."
1733  (etypecase integer
1734    (fixnum
1735     (etypecase count
1736       (fixnum
1737        (if (eql integer 0)
1738          0
1739          (if (eql count 0)
1740            integer
1741            (let ((length (integer-length (the fixnum integer))))
1742              (declare (fixnum length count))
1743              (cond ((and (plusp count)
1744                          (> (+ length count)
1745                             (- (1- target::nbits-in-word) target::fixnumshift)))
1746                     (with-small-bignum-buffers ((bi integer))
1747                       (bignum-ashift-left bi count)))
1748                    ((and (minusp count) (< count (- (1- target::nbits-in-word))))
1749                     (if (minusp integer) -1 0))
1750                    (t (%iash (the fixnum integer) count)))))))
1751       (bignum
1752        (if (minusp count)
1753          (if (minusp integer) -1 0)         
1754          (error "Count ~s too large for ASH" count)))))
1755    (bignum
1756     (etypecase count
1757       (fixnum
1758        (if (eql count 0) 
1759          integer
1760          (if (plusp count)
1761            (bignum-ashift-left integer count)
1762            (bignum-ashift-right integer (- count)))))
1763       (bignum
1764        (if (minusp count)
1765          (if (minusp integer) -1 0)
1766          (error "Count ~s too large for ASH" count)))))))
1767
1768(defun integer-length (integer)
1769  "Return the number of significant bits in the absolute value of integer."
1770  (number-case integer
1771    (fixnum
1772     (%fixnum-intlen (the fixnum integer)))
1773    (bignum
1774     (bignum-integer-length integer))))
1775
1776
1777; not CL, used below
1778(defun byte-mask (size)
1779  (1- (ash 1 (the fixnum size))))
1780
1781(defun byte-position (bytespec)
1782  "Return the position part of the byte specifier bytespec."
1783  (if (> bytespec 0)
1784    (- (integer-length bytespec) (logcount bytespec))
1785    (- bytespec)))
1786
1787
1788; CMU CL returns T.
1789(defun upgraded-complex-part-type (type)
1790  "Return the element type of the most specialized COMPLEX number type that
1791   can hold parts of type SPEC."
1792  (declare (ignore type))
1793  'real)
1794
1795;;; This is the MRG31k3p random number generator described in
1796;;; P. L'Ecuyer and R. Touzin, "Fast Combined Multiple Recursive
1797;;; Generators with Multipliers of the form a = +/- 2^d +/- 2^e",
1798;;; Proceedings of the 2000 Winter Simulation Conference, Dec. 2000,
1799;;; 683--689.
1800;;;
1801;;; A link to the paper is available on L'Ecuyer's web site:
1802;;; http://www.iro.umontreal.ca/~lecuyer/papers.html.
1803;;;
1804;;; This generator has a period of about 2^185.  It produces values in
1805;;; in the half-open interval [0, 2^31 - 1).
1806;;;
1807;;; It uses 6 words of state.
1808
1809(defconstant mrg31k3p-m1 #.(- (expt 2 31) 1))
1810(defconstant mrg31k3p-m2 #.(- (expt 2 31) 21069))
1811(defconstant mrg31k3p-limit #.(1- (expt 2 31))
1812             "Exclusive upper bound on values returned by %mrg31k3p.")
1813
1814
1815;;; This is a portable version of the MRG31k3p generator.  It's not
1816;;; too bad in a 64-bit CCL, but the generator pretty much has to be
1817;;; in LAP for 32-bit ports.
1818#-(or x8632-target ppc32-target x8664-target ppc64-target arm-target)
1819(defun %mrg31k3p (state)
1820  (let* ((v (random.mrg31k3p-state state)))
1821    (declare (type (simple-array (unsigned-byte 32) (*)) v)
1822             (optimize speed))
1823    (let ((y1 (+ (+ (ash (logand (aref v 1) #x1ff) 22)
1824                    (ash (aref v 1) -9))
1825                 (+ (ash (logand (aref v 2) #xffffff) 7)
1826                    (ash (aref v 2) -24)))))
1827      (declare (type (unsigned-byte 32) y1))
1828      (if (>= y1 mrg31k3p-m1) (decf y1 mrg31k3p-m1))
1829      (incf y1 (aref v 2))
1830      (if (>= y1 mrg31k3p-m1) (decf y1 mrg31k3p-m1))
1831      (setf (aref v 2) (aref v 1)
1832            (aref v 1) (aref v 0)
1833            (aref v 0) y1))
1834    (let ((y1 (+ (ash (logand (aref v 3) #xffff) 15)
1835                 (* 21069 (ash (aref v 3) -16))))
1836          (y2 (+ (ash (logand (aref v 5) #xffff) 15)
1837                 (* 21069 (ash (aref v 5) -16)))))
1838      (declare (type (unsigned-byte 32) y1 y2))
1839      (if (>= y1 mrg31k3p-m2) (decf y1 mrg31k3p-m2))
1840      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1841      (incf y2 (aref v 5))
1842      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1843      (incf y2 y1)
1844      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1845      (setf (aref v 5) (aref v 4)
1846            (aref v 4) (aref v 3)
1847            (aref v 3) y2))
1848    (let* ((x10 (aref v 0))
1849           (x20 (aref v 3)))
1850      (if (<= x10 x20)
1851        (+ (- x10 x20) mrg31k3p-m1)
1852        (- x10 x20)))))
1853
1854(eval-when (:compile-toplevel :execute)
1855  (declaim (inline %16-random-bits)))
1856
1857(defun %16-random-bits (state)
1858  (logand #xffff (the fixnum (%mrg31k3p state))))
1859
1860#+64-bit-target
1861(defun %big-fixnum-random (number state)
1862  (declare (fixnum number)
1863           (ftype (function (random-state) fixnum) %mrg31k3p))
1864  (let ((low (ldb (byte 30 0) (%mrg31k3p state)))
1865        (high (ldb (byte 30 0) (%mrg31k3p state))))
1866    (declare (fixnum low high))
1867    (fast-mod (logior low (the fixnum (ash high 30)))
1868              number)))
1869
1870;;; When using a dead simple random number generator, it's reasonable
1871;;; to take 16 bits of the output and discard the rest.  With a more
1872;;; expensive generator, however, it may be worthwhile to do more bit
1873;;; fiddling here here so that we can use all of the random bits
1874;;; produced by %mrg31k2p.
1875#+32-bit-target
1876(defun %bignum-random (number state)
1877  (let* ((bits (+ (integer-length number) 8))
1878         (half-words (ash (the fixnum (+ bits 15)) -4))
1879         (long-words (ash (+ half-words 1) -1))
1880         (dividend (%alloc-misc long-words target::subtag-bignum))
1881         (16-bit-dividend dividend)
1882         (index 1))
1883    (declare (fixnum long-words index bits)
1884             (dynamic-extent dividend)
1885             (type (simple-array (unsigned-byte 16) (*)) 16-bit-dividend) ;lie
1886             (optimize (speed 3) (safety 0)))
1887    (loop
1888       ;; This had better inline due to the lie above, or it will error
1889       #+big-endian-target
1890       (setf (aref 16-bit-dividend index) (%16-random-bits state))
1891       #+little-endian-target
1892       (setf (aref 16-bit-dividend (the fixnum (1- index)))
1893             (%16-random-bits state))
1894       (decf half-words)
1895       (when (<= half-words 0) (return))
1896       #+big-endian-target
1897       (setf (aref 16-bit-dividend (the fixnum (1- index)))
1898             (%16-random-bits state))
1899       #+little-endian-target
1900       (setf (aref 16-bit-dividend index) (%16-random-bits state))
1901       (decf half-words)
1902       (when (<= half-words 0) (return))
1903       (incf index 2))
1904    ;; The bignum code expects normalized bignums
1905    (let* ((result (mod dividend number)))
1906      (if (eq dividend result)
1907        (copy-uvector result)
1908        result))))
1909
1910(defun %float-random (number state)
1911  (let ((ratio (gvector :ratio (random target::target-most-positive-fixnum state) target::target-most-positive-fixnum)))
1912    (declare (dynamic-extent ratio))
1913    (* number ratio)))
1914
1915(defun random (number &optional (state *random-state*))
1916  (if (not (typep state 'random-state)) (report-bad-arg state 'random-state))
1917  (cond
1918    ((and (fixnump number) (> (the fixnum number) 0))
1919     #+32-bit-target
1920     (fast-mod (%mrg31k3p state) number)
1921     #+64-bit-target
1922     (if (< number mrg31k3p-limit)
1923       (fast-mod (%mrg31k3p state) number)
1924       (%big-fixnum-random number state)))
1925    ((and (typep number 'double-float) (> (the double-float number) 0.0))
1926     (%float-random number state))
1927    ((and (typep number 'short-float) (> (the short-float number) 0.0s0))
1928     (%float-random number state))
1929    ((and (bignump number) (> number 0))
1930     (%bignum-random number state))
1931    (t (report-bad-arg number '(or (integer (0)) (float (0.0)))))))
1932
1933(eval-when (:compile-toplevel :execute)
1934  (defmacro bignum-abs (nexp)
1935    (let ((n (gensym)))
1936      `(let ((,n ,nexp))
1937         (if  (bignum-minusp ,n) (negate-bignum ,n) ,n))))
1938 
1939  (defmacro fixnum-abs (nexp)
1940    (let ((n (gensym)))
1941      `(let ((,n ,nexp))
1942         (if (minusp (the fixnum ,n))
1943           (if (eq ,n target::target-most-negative-fixnum)
1944             (- ,n)
1945             (the fixnum (- (the fixnum ,n))))
1946           ,n))))
1947  )
1948 
1949
1950;;; TWO-ARG-GCD  --  Internal
1951;;;
1952;;;    Do the GCD of two integer arguments.  With fixnum arguments, we use the
1953;;; binary GCD algorithm from Knuth's seminumerical algorithms (slightly
1954;;; structurified), otherwise we call BIGNUM-GCD.  We pick off the special case
1955;;; of 0 before the dispatch so that the bignum code doesn't have to worry
1956;;; about "small bignum" zeros.
1957;;;
1958(defun gcd-2 (n1 n2)
1959  ;(declare (optimize (speed 3)(safety 0)))
1960  (cond 
1961   ((eql n1 0) (%integer-abs n2))
1962   ((eql n2 0) (%integer-abs n1))
1963   (t (number-case n1
1964        (fixnum 
1965         (number-case n2
1966          (fixnum
1967           (if (eql n1 target::target-most-negative-fixnum)
1968             (if (eql n2 target::target-most-negative-fixnum)
1969               (- target::target-most-negative-fixnum)
1970               (bignum-fixnum-gcd (- target::target-most-negative-fixnum) (abs n2)))
1971             (if (eql n2 target::target-most-negative-fixnum)
1972               (bignum-fixnum-gcd (- target::target-most-negative-fixnum) (abs n1))
1973               (locally
1974                   (declare (optimize (speed 3) (safety 0))
1975                            (fixnum n1 n2))
1976                 (if (minusp n1)(setq n1 (the fixnum (- n1))))
1977                 (if (minusp n2)(setq n2 (the fixnum (- n2))))
1978               (%fixnum-gcd n1 n2)))))
1979           (bignum (if (eql n1 target::target-most-negative-fixnum)
1980                     (%bignum-bignum-gcd n2 (- target::target-most-negative-fixnum))
1981                     (bignum-fixnum-gcd (bignum-abs n2)(fixnum-abs n1))))))
1982        (bignum
1983         (number-case n2
1984           (fixnum
1985            (if (eql n2 target::target-most-negative-fixnum)
1986              (%bignum-bignum-gcd (bignum-abs n1)(fixnum-abs n2))
1987              (bignum-fixnum-gcd (bignum-abs n1)(fixnum-abs n2))))
1988           (bignum (%bignum-bignum-gcd n1 n2))))))))
1989
1990#|
1991(defun fixnum-gcd (n1 n2)
1992  (declare (optimize (speed 3) (safety 0))
1993           (fixnum n1 n2))                   
1994  (do* ((k 0 (%i+ 1 k))
1995        (n1 n1 (%iasr 1 n1))
1996        (n2 n2 (%iasr 1 n2)))
1997       ((oddp (logior n1 n2))
1998        (do ((temp (if (oddp n1) (the fixnum (- n2)) (%iasr 1 n1))
1999                   (%iasr 1 temp)))
2000            (nil)
2001          (declare (fixnum temp))
2002          (when (oddp temp)
2003            (if (plusp temp)
2004              (setq n1 temp)
2005              (setq n2 (- temp)))
2006            (setq temp (the fixnum (- n1 n2)))
2007            (when (zerop temp)
2008              (let ((res (%ilsl k n1)))
2009                (return res))))))
2010    (declare (fixnum n1 n2 k))))
2011|#
2012
2013
2014
2015(defun %quo-1 (n)
2016  (/ 1 n))
2017
2018;; Compute (sqrt (+ (* x x) (* y y))), but
2019;; try to be a little more careful about it.
2020;; Both x and y must be double-floats.
2021(defun %double-float-hypot (x y)
2022  (with-stack-double-floats ((a) (b) (c))
2023    (%%double-float-abs! x a)
2024    (%%double-float-abs! y b)
2025    (when (> a b)
2026      (psetq a b b a))
2027    (if (= b 0d0)
2028      0d0
2029      (progn
2030        (%double-float/-2! a b c)
2031        (* b (fsqrt (+ 1d0 (* c c))))))))
2032                                       
Note: See TracBrowser for help on using the repository browser.