source: trunk/source/level-0/l0-numbers.lisp @ 13532

Last change on this file since 13532 was 13532, checked in by gb, 10 years ago

Don't try to special-case (TRUNCATE MOST-NEGATIVE-FIXNUM some-other-fixnum);
the cases that requires special treatment are when some-other-fixnum is -1 (or
0), and they're already handled in %FIXNUM-TRUNCATE now.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 78.4 KB
Line 
1;;; -*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;;
19;;; level-0;l0-numbers.lisp
20
21(in-package "CCL")
22
23(eval-when (:compile-toplevel :execute)
24  (require "ARCH")
25  (require "LISPEQU")
26  (require "NUMBER-MACROS")
27  (require "NUMBER-CASE-MACRO")
28
29
30
31  (defvar *dfloat-dops* '((* . %double-float*-2!)(/ . %double-float/-2!)
32                          (+ . %double-float+-2!)(- . %double-float--2!)))
33 
34  (defvar *sfloat-dops* '((* . %short-float*-2!)(/ . %short-float/-2!)
35                          (+ . %short-float+-2!)(- . %short-float--2!)))
36
37  (defmacro dfloat-rat (op x y &optional (destructive-op (cdr (assq op *dfloat-dops*))))
38    (if destructive-op
39        (let ((f2 (gensym)))
40          `(let ((,f2 (%double-float ,y (%make-dfloat))))
41            (,destructive-op ,x ,f2 ,f2)))         
42        `(,op (the double-float ,x) (the double-float (%double-float ,y)))))
43
44  (defmacro rat-dfloat (op x y &optional (destructive-op (cdr (assq op *dfloat-dops*))))
45    (if destructive-op
46        (let ((f1 (gensym)))
47          `(let ((,f1 (%double-float ,x (%make-dfloat)))) 
48            (,destructive-op ,f1 ,y ,f1)))
49        `(,op (the double-float (%double-float ,x)) (the double-float ,y))))
50
51  (defmacro sfloat-rat (op x y &optional (destructive-op (cdr (assq op *sfloat-dops*))))
52    (let* ((use-destructive-op
53            (target-word-size-case
54             (32 destructive-op)
55             (64 nil))))
56      (if use-destructive-op
57        (let ((f2 (gensym)))
58          `(let ((,f2 (%short-float ,y (%make-sfloat)))) 
59            (,destructive-op ,x ,f2 ,f2)))
60        `(,op (the short-float ,x) (the short-float (%short-float ,y))))))
61
62  (defmacro rat-sfloat (op x y &optional (destructive-op (cdr (assq op *sfloat-dops*))))
63    (let* ((use-destructive-op
64            (target-word-size-case
65             (32 destructive-op)
66             (64 nil))))
67      (if use-destructive-op
68        (let ((f1 (gensym)))
69          `(let ((,f1 (%short-float ,x (%make-sfloat)))) 
70            (,destructive-op ,f1 ,y ,f1)))
71        `(,op (the short-float (%short-float ,x)) (the short-float ,y)))))
72
73
74 
75
76
77  (declaim (inline  %make-complex %make-ratio))
78  (declaim (inline canonical-complex))
79  (declaim (inline build-ratio))
80  (declaim (inline maybe-truncate)))
81
82
83
84(defun %make-complex (realpart imagpart)
85  (gvector :complex realpart imagpart))
86
87(defun %make-ratio (numerator denominator)
88  (gvector :ratio numerator denominator))
89 
90
91
92; this is no longer used
93(defun %integer-signum (num)
94  (if (fixnump num)
95    (%fixnum-signum num)
96    ; there is no such thing as bignum zero we hope
97    (if (bignum-minusp num) -1 1)))
98
99
100; Destructive primitives.
101(macrolet ((defdestructive-df-op (non-destructive-name destructive-name op)
102             `(progn
103                (defun ,non-destructive-name (x y)
104                  (,destructive-name x y (%make-dfloat)))
105                (defun ,destructive-name (x y result)
106                  (declare (double-float x y result))
107                  (%setf-double-float result (the double-float (,op x y)))))))
108  (defdestructive-df-op %double-float+-2 %double-float+-2! +)
109  (defdestructive-df-op %double-float--2 %double-float--2! -)
110  (defdestructive-df-op %double-float*-2 %double-float*-2! *)
111  (defdestructive-df-op %double-float/-2 %double-float/-2! /))
112
113#-64-bit-target
114(macrolet ((defdestructive-sf-op (non-destructive-name destructive-name op)
115             `(progn
116                (defun ,non-destructive-name (x y)
117                  (,destructive-name x y (%make-sfloat)))
118                (defun ,destructive-name (x y result)
119                  (declare (short-float x y result))
120                  (%setf-short-float result (the short-float (,op x y)))))))
121  (defdestructive-sf-op %short-float+-2 %short-float+-2! +)
122  (defdestructive-sf-op %short-float--2 %short-float--2! -)
123  (defdestructive-sf-op %short-float*-2 %short-float*-2! *)
124  (defdestructive-sf-op %short-float/-2 %short-float/-2! /))
125
126
127(defun %negate (x)
128  (number-case x
129    (fixnum  (- (the fixnum x)))
130    (double-float  (%double-float-negate! x (%make-dfloat)))
131    (short-float
132     #+32-bit-target (%short-float-negate! x (%make-sfloat))
133     #+64-bit-target (%short-float-negate x))
134    (bignum (negate-bignum x))
135    (ratio (%make-ratio (%negate (%numerator x)) (%denominator x)))
136    (complex (%make-complex (%negate (%realpart X))(%negate (%imagpart X))) )))
137
138(defun %double-float-zerop (n)
139  (zerop (the double-float n)))
140
141(defun %short-float-zerop (n)
142  (zerop (the single-float n)))
143
144(defun zerop (number)
145  "Is this number zero?"
146  (number-case number
147    (integer (eq number 0))
148    (short-float (%short-float-zerop number))
149    (double-float (%double-float-zerop number))
150    (ratio nil)
151    (complex
152     (number-case (%realpart number)
153       (short-float (and (%short-float-zerop (%realpart number))
154                         (%short-float-zerop (%imagpart number))))
155       (double-float (and (%double-float-zerop (%realpart number))
156                          (%double-float-zerop (%imagpart number))))
157       (t (and (eql 0 (%realpart number))(eql 0 (%imagpart number))))))))
158
159(defun %short-float-plusp (x)
160  (> (the single-float x) 0.0f0))
161
162(defun %double-float-plusp (x)
163  (> (the double-float x) 0.0d0))
164
165(defun plusp (number)
166  "Is this real number strictly positive?"
167  (number-case number
168    (fixnum (%i> number 0))
169    (bignum (bignum-plusp number))
170    (short-float (%short-float-plusp number))
171    (double-float (%double-float-plusp number))
172    (ratio (plusp (%numerator number)))))
173
174
175(defun minusp (number)
176  "Is this real number strictly negative?"
177  (number-case number
178    (fixnum (%i< number 0))
179    (bignum (bignum-minusp number))
180    (short-float (%short-float-minusp number))
181    (double-float (%double-float-minusp number))
182    (ratio (minusp (%numerator number)))))
183
184
185(defun oddp (n)
186  "Is this integer odd?"
187  (case (typecode n)
188    (#.target::tag-fixnum (logbitp 0 (the fixnum n)))
189    (#.target::subtag-bignum (%bignum-oddp n))
190    (t (report-bad-arg n 'integer))))
191
192(defun evenp (n)
193  "Is this integer even?"
194  (case (typecode n)
195    (#.target::tag-fixnum (not (logbitp 0 (the fixnum n))))
196    (#.target::subtag-bignum (not (%bignum-oddp n)))
197    (t (report-bad-arg n 'integer))))
198
199;; expansion slightly changed
200(defun =-2 (x y)
201  (number-case x
202    (fixnum (number-case y
203              (fixnum (eq x y))
204              (double-float (eq 0 (fixnum-dfloat-compare x y)))
205              (short-float (eq 0 (fixnum-sfloat-compare x y)))
206              ((bignum ratio) nil)
207              (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
208    (double-float (number-case y ; x
209                    (double-float (= (the double-float x)(the double-float y))) ;x
210                    (short-float (with-stack-double-floats ((dy y))
211                                   (= (the double-float x) (the double-float dy))))
212                    (fixnum (eq 0 (fixnum-dfloat-compare  y x)))
213                    (bignum (eq 0 (bignum-dfloat-compare y x)))
214                    (ratio (= (rational x) y))
215                    (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
216    (short-float (number-case y
217                   (short-float (= (the short-float x) (the short-float y)))
218                   (double-float (with-stack-double-floats ((dx x))
219                                   (= (the double-float dx) (the double-float y))))
220                   (fixnum (eq 0 (fixnum-sfloat-compare y x)))
221                   (bignum (eq 0 (bignum-sfloat-compare y x)))
222                   (ratio (= (rational x) y))
223                   (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
224    (bignum (number-case y 
225              (bignum (eq 0 (bignum-compare x y)))
226              ((fixnum ratio) nil)
227              (double-float (eq 0 (bignum-dfloat-compare x y)))
228              (short-float (eq 0 (bignum-sfloat-compare x y)))
229              (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
230    (ratio (number-case y
231             (integer nil)
232             (ratio
233              (and (eql (%numerator x) (%numerator y))
234                   (eql (%denominator x) (%denominator y))))
235             (float (= x (rational y)))
236             (complex (and (zerop (%imagpart y)) (= x (%realpart y))))))
237    (complex (number-case y
238               (complex (and (= (%realpart x) (%realpart y))
239                             (= (%imagpart x) (%imagpart y))))
240               ((float rational)
241                (and (zerop (%imagpart x)) (= (%realpart x) y)))))))
242
243(defun /=-2 (x y)
244  (declare (notinline =-2))
245  (not (= x y)))
246
247
248; true iff (< x y) is false.
249(defun >=-2 (x y)
250  (declare (notinline <-2))
251  (not (< x y)))
252
253
254
255(defun <=-2 (x y)
256  (declare (notinline >-2))
257  (not (> x y)))
258
259(defun <-2 (x y)
260  (number-case x
261    (fixnum (number-case y
262              (fixnum (< (the fixnum x) (the fixnum y)))
263              (double-float (eq -1 (fixnum-dfloat-compare x y)))
264              (short-float (eq -1 (fixnum-sfloat-compare x y)))
265              (bignum (bignum-plusp y))
266              (ratio (< x (ceiling (%numerator y)(%denominator y))))))
267    (double-float (number-case y ; x
268                    (double-float (< (the double-float x)(the double-float y))) ;x
269                    (short-float (with-stack-double-floats ((dy y))
270                                   (< (the double-float x) (the double-float dy))))
271                    (fixnum (eq 1 (fixnum-dfloat-compare  y x)))
272                    (bignum (eq 1 (bignum-dfloat-compare y x)))
273                    (ratio (< (rational x) y))))
274    (short-float (number-case y
275                    (short-float (< (the short-float x) (the short-float y)))
276                    (double-float (with-stack-double-floats ((dx x))
277                                    (< (the double-float dx) (the double-float y))))
278                    (fixnum (eq 1 (fixnum-sfloat-compare y x)))
279                    (bignum (eq 1 (bignum-sfloat-compare y x)))
280                    (ratio (< (rational x) y))))
281    (bignum (number-case y 
282              (bignum (EQ -1 (bignum-compare x y)))
283              (fixnum (not (bignum-plusp x)))
284              (ratio (< x (ceiling (%numerator y)(%denominator y))))
285              (double-float (eq -1 (bignum-dfloat-compare x y)))
286              (short-float (eq -1 (bignum-sfloat-compare x y)))))
287    (ratio (number-case y
288             (integer (< (floor (%numerator x)(%denominator x)) y))
289             (ratio
290              (< (* (%numerator (the ratio x))
291                    (%denominator (the ratio y)))
292                 (* (%numerator (the ratio y))
293                    (%denominator (the ratio x)))))
294             (float (< x (rational y)))))))
295
296
297
298(defun >-2 (x y)
299  ;(declare (optimize (speed 3)(safety 0)))
300  (number-case x
301    (fixnum (number-case y
302              (fixnum (> (the fixnum x) (the fixnum y)))
303              (bignum (not (bignum-plusp y)))
304              (double-float (eq 1 (fixnum-dfloat-compare x y)))
305              (short-float (eq 1 (fixnum-sfloat-compare x y)))
306              ;; or (> (* x denom) num) ?
307              (ratio (> x (floor (%numerator y) (%denominator y))))))
308    (double-float (number-case y
309                    (double-float (> (the double-float x) (the double-float y)))
310                    (short-float (with-stack-double-floats ((dy y))
311                                   (> (the double-float x) (the double-float dy))))
312                    (fixnum (eq -1 (fixnum-dfloat-compare  y x)))
313                    (bignum (eq -1 (bignum-dfloat-compare y x)))
314                    (ratio (> (rational x) y))))
315    (short-float (number-case y
316                    (short-float (> (the short-float x) (the short-float y)))
317                    (double-float (with-stack-double-floats ((dx x))
318                                   (> (the double-float dx) (the double-float y))))
319                    (fixnum (eq -1 (fixnum-sfloat-compare  y x)))
320                    (bignum (eq -1 (bignum-sfloat-compare y x)))
321                    (ratio (> (rational x) y))))
322    (bignum (number-case y
323              (fixnum (bignum-plusp x))
324              (bignum (eq 1 (bignum-compare x y)))
325              ;; or (> (* x demon) num)
326              (ratio (> x (floor (%numerator y) (%denominator y))))
327              (double-float (eq 1 (bignum-dfloat-compare x y)))
328              (short-float (eq 1 (bignum-sfloat-compare x y)))))
329    (ratio (number-case y
330             ;; or (> num (* y denom))
331             (integer (> (ceiling (%numerator x) (%denominator x)) y))
332             (ratio
333              (> (* (%numerator (the ratio x))
334                    (%denominator (the ratio y)))
335                 (* (%numerator (the ratio y))
336                    (%denominator (the ratio x)))))
337             (float (> x (rational y)))))))
338
339
340; t if any bits set after exp (unbiased)
341(defun hi-lo-fraction-p (hi lo exp)
342  (declare (fixnum hi lo exp))
343  (if (> exp 24)
344    (not (eql 0 (%ilogand lo (%ilsr (- exp 25) #xfffffff))))
345    (or (not (zerop lo))(not (eql 0 (%ilogand hi (%ilsr exp #x1ffffff)))))))
346
347
348
349(defun negate-hi-lo (hi lo)
350  (setq hi (%ilogxor hi #x3ffffff))
351  (if (eq 0 lo)   
352    (setq hi (+ hi 1))
353    (setq lo (+ (%ilogxor lo #xfffffff) 1)))
354  (values hi lo))
355
356
357
358(defun fixnum-dfloat-compare (int dfloat)
359  (declare (double-float dfloat) (fixnum int))
360  (if (and (eq int 0)(= dfloat 0.0d0))
361    0
362    (with-stack-double-floats ((d1 int))
363      (locally (declare (double-float d1))
364        (if (eq int (%truncate-double-float->fixnum d1))
365          (cond ((< d1 dfloat) -1)
366                ((= d1 dfloat) 0)
367                (t 1))
368          ;; Whatever we do here should have the effect
369          ;; of comparing the integer to the result of calling
370          ;; RATIONAL on the float.  We could probably
371          ;; skip the call to RATIONAL in more cases,
372          ;; but at least check the obvious ones here
373          ;; (e.g. different signs)
374          (multiple-value-bind (mantissa exponent sign)
375              (integer-decode-double-float dfloat)
376            (declare (type (integer -1 1) sign)
377                     (fixnum exponent))
378            (cond ((zerop int)
379                   (- sign))
380                  ((and (< int 0) (eql sign 1)) -1)
381                  ((and (> int 0) (eql sign -1)) 1)
382                  (t
383                   ;; See RATIONAL.  Can probably avoid this if
384                   ;; magnitudes are clearly dissimilar.
385                   (if (= sign -1) (setq mantissa (- mantissa)))
386                   (let* ((rat (if (< exponent 0)
387                                 (/ mantissa (ash 1 (the fixnum (- exponent))))
388                                 (ash mantissa exponent))))
389                     (if (< int rat)
390                       -1
391                       (if (eq int rat)
392                         0
393                         1)))))))))))
394
395
396
397(defun fixnum-sfloat-compare (int sfloat)
398  (declare (short-float sfloat) (fixnum int))
399  (if (and (eq int 0)(= sfloat 0.0s0))
400    0
401    (#+32-bit-target target::with-stack-short-floats #+32-bit-target ((s1 int))
402     #-32-bit-target let* #-32-bit-target ((s1 (%int-to-sfloat int)))
403                     (locally
404                         (declare (short-float s1))
405                       (if (eq (%truncate-short-float->fixnum s1) int)
406                         (cond ((< s1 sfloat) -1)
407                               ((= s1 sfloat) 0)
408                               (t 1))
409                         ;; Whatever we do here should have the effect
410                         ;; of comparing the integer to the result of calling
411                         ;; RATIONAL on the float.  We could probably
412                         ;; skip the call to RATIONAL in more cases,
413                         ;; but at least check the obvious ones here
414                         ;; (e.g. different signs)
415                         (multiple-value-bind (mantissa exponent sign)
416                             (integer-decode-short-float sfloat)
417                           (declare (type (integer -1 1) sign)
418                                    (fixnum exponent))
419                           (cond ((zerop int)
420                                  (- sign))
421                                 ((and (< int 0) (eql sign 1)) -1)
422                                 ((and (> int 0) (eql sign -1)) 1)
423                                 (t
424                                  ;; See RATIONAL.  Can probably avoid this if
425                                  ;; magnitudes are clearly dissimilar.
426                                  (if (= sign -1) (setq mantissa (- mantissa)))
427                                  (let* ((rat (if (< exponent 0)
428                                                (/ mantissa (ash 1 (the fixnum (- exponent))))
429                                                (ash mantissa exponent))))
430                                    (if (< int rat)
431                                      -1
432                                      (if (eq int rat)
433                                        0
434                                        1)))))))))))
435
436
437       
438;;; lotta stuff to avoid making a rational from a float
439;;; returns -1 less, 0 equal, 1 greater
440(defun bignum-dfloat-compare (int float)
441  (cond 
442   ((and (eq int 0)(= float 0.0d0)) 0)
443   (t
444    (let* ((fminus  (%double-float-minusp float))
445           (iminus (minusp int))
446           (gt (if iminus -1 1)))
447      (declare (fixnum gt))
448      (if (neq fminus iminus)
449        gt  ; if different signs, done
450        (let ((intlen (integer-length int)) 
451              (exp (- (the fixnum (%double-float-exp float)) 1022)))
452          (declare (fixnum intlen exp))
453          (cond 
454           ((and (not fminus) (< intlen exp)) -1)
455           ((> intlen exp)  gt)   ; if different exp, done
456           ((and fminus (or (< (1+ intlen) exp)
457                            (and (= (1+ intlen) exp)
458                                 (neq (one-bignum-factor-of-two int) intlen))))
459            ;(print 'zow)
460            (the fixnum (- gt)))  ; ; integer-length is strange for neg powers of 2           
461           (t (multiple-value-bind (hi lo)(fixnum-decode-float float)
462                (declare (fixnum hi lo)) 
463                (when fminus (multiple-value-setq (hi lo)(negate-hi-lo hi lo)))
464                (let* ((sz 26)  ; exp > 28 always
465                       (pos (- exp 25))
466                       (big-bits (%ldb-fixnum-from-bignum int sz pos)))
467                  (declare (fixnum pos big-bits sz))
468                  ;(print (list big-bits hi sz pos))
469                  (cond 
470                   ((< big-bits hi) -1)
471                   ((> big-bits hi) 1)
472                   (t (let* ((sz (min (- exp 25) 28))
473                             (pos (- exp 25 sz)) ; ?
474                             (ilo (if (< exp 53) (ash lo (- exp 53)) lo))                                   
475                             (big-bits (%ldb-fixnum-from-bignum int sz pos)))
476                        (declare (fixnum pos sz ilo big-bits))
477                        ;(PRINT (list big-bits ilo))
478                        (cond
479                         ((< big-bits ilo) -1)
480                         ((> big-bits ilo) 1)
481                         ((eq exp 53) 0)
482                         ((< exp 53)
483                          (if (not (hi-lo-fraction-p hi lo exp)) 0 -1)) ; -1 if pos
484                         (t (if (%i< (one-bignum-factor-of-two int) (- exp 53)) 1 0)))))))
485                )))))))))
486
487
488
489;;; I don't know if it's worth doing a more "real" version of this.
490(defun bignum-sfloat-compare (int float)
491  (with-stack-double-floats ((df float))
492    (bignum-dfloat-compare int df)))
493
494;;;; Canonicalization utilities:
495
496;;; CANONICAL-COMPLEX  --  Internal
497;;;
498;;;    If imagpart is 0, return realpart, otherwise make a complex.  This is
499;;; used when we know that realpart and imagpart are the same type, but
500;;; rational canonicalization might still need to be done.
501;;;
502
503(defun canonical-complex (realpart imagpart)
504  (if (eql imagpart 0)
505    realpart
506    (%make-complex realpart imagpart)))
507
508
509
510
511(defun +-2 (x y)     
512  (number-case x
513    (fixnum (number-case y
514              (fixnum (+ (the fixnum x) (the fixnum y)))
515              (double-float (rat-dfloat + x y))
516              (short-float (rat-sfloat + x y))
517              (bignum (add-bignum-and-fixnum y x))
518              (complex (complex (+ x (%realpart y))
519                                (%imagpart y)))
520              (ratio (let* ((dy (%denominator y)) 
521                            (n (+ (* x dy) (%numerator y))))
522                       (%make-ratio n dy)))))
523    (double-float (number-case y
524                    (double-float (+ (the double-float x) (the double-float y)))
525                    (short-float (with-stack-double-floats ((dy y))
526                                   (+ (the double-float x) (the double-float dy))))
527                    (rational (dfloat-rat + x y))
528                    (complex (complex (+ x (%realpart y)) 
529                                      (%imagpart y)))))
530    (short-float (number-case y                               
531                   (short-float (+ (the short-float x) (the short-float y)))
532                   (double-float (with-stack-double-floats ((dx x))
533                                   (+ (the double-float dx) (the double-float y))))
534                   (rational (sfloat-rat + x y))
535                   (complex (complex (+ x (%realpart y))
536                                     (%imagpart y)))))
537    (bignum (number-case y
538              (bignum (add-bignums x y))
539              (fixnum (add-bignum-and-fixnum x y))
540              (double-float (rat-dfloat + x y))
541              (short-float (rat-sfloat + x y))
542              (complex (complex (+ x (realpart y)) 
543                                (%imagpart y)))
544              (ratio
545               (let* ((dy (%denominator y))
546                      (n (+ (* x dy) (%numerator y))))
547                 (%make-ratio n dy)))))
548    (complex (number-case y
549               (complex (canonical-complex (+ (%realpart x) (%realpart y))
550                                           (+ (%imagpart x) (%imagpart y))))
551               ((rational float) (complex (+ (%realpart x) y) (%imagpart x)))))
552    (ratio (number-case y
553             (ratio
554              (let* ((nx (%numerator x))
555                     (dx (%denominator x))
556                     (ny (%numerator y))
557                     (dy (%denominator y))
558                     (g1 (gcd dx dy)))
559                (if (eql g1 1)
560                  (%make-ratio (+ (* nx dy) (* dx ny)) (* dx dy))
561                  (let* ((t1 (+ (* nx (truncate dy g1)) (* (truncate dx g1) ny)))
562                         (g2 (gcd t1 g1))
563                         (t2 (truncate dx g1)))
564                    (cond ((eql t1 0) 0)
565                          ((eql g2 1) (%make-ratio t1 (* t2 dy)))
566                          (t
567                           (let* ((nn (truncate t1 g2))
568                                  (t3 (truncate dy g2))
569                                  (nd (if (eql t2 1) t3 (* t2 t3))))
570                             (if (eql nd 1) nn (%make-ratio nn nd)))))))))
571             (integer
572              (let* ((dx (%denominator x)) (n (+ (%numerator x) (* y dx))))
573                (%make-ratio n dx)))
574             (double-float (rat-dfloat + x y))
575             (short-float (rat-sfloat + x y))
576             (complex (complex (+ x (%realpart y)) 
577                               (%imagpart y)))))))
578
579(defun --2 (x y)     
580  (number-case x
581    (fixnum (number-case y
582              (fixnum (- (the fixnum x) (the fixnum y)))
583              (double-float (rat-dfloat - x y))
584              (short-float (rat-sfloat - x y))
585              (bignum 
586               (with-small-bignum-buffers ((bx x))
587                        (subtract-bignum bx y)))
588              (complex (complex (- x (%realpart y))
589                                (- (%imagpart y))))
590              (ratio (let* ((dy (%denominator y)) 
591                            (n (- (* x dy) (%numerator y))))
592                       (%make-ratio n dy)))))
593    (double-float (number-case y
594                    (double-float (- (the double-float x) (the double-float y)))
595                    (short-float (with-stack-double-floats ((dy y))
596                                   (- (the double-float x) (the double-float dy))))
597                    (rational (dfloat-rat - x y))
598                    (complex (complex (- x (%realpart y)) 
599                                      (- (%imagpart y))))))
600    (short-float (number-case y                               
601                   (short-float (- (the short-float x) (the short-float y)))
602                   (double-float (with-stack-double-floats ((dx x))
603                                   (- (the double-float dx) (the double-float y))))
604                   (rational (sfloat-rat - x y))
605                   (complex (complex (- x (%realpart y))
606                                     (- (%imagpart y))))))
607    (bignum (number-case y
608              (bignum (subtract-bignum x y))
609              (fixnum (if (eql y target::target-most-negative-fixnum)
610                        (with-small-bignum-buffers ((by y))
611                          (subtract-bignum x by))
612                        (add-bignum-and-fixnum x (- y))))
613              (double-float (rat-dfloat - x y))
614              (short-float (rat-sfloat - x y))
615              (complex (complex (- x (realpart y)) 
616                                (- (%imagpart y))))
617              (ratio
618               (let* ((dy (%denominator y))
619                      (n (- (* x dy) (%numerator y))))
620                 (%make-ratio n dy)))))
621    (complex (number-case y
622               (complex (canonical-complex (- (%realpart x) (%realpart y))
623                                           (- (%imagpart x) (%imagpart y))))
624               ((rational float) (complex (- (%realpart x) y) (%imagpart x)))))
625    (ratio (number-case y
626             (ratio
627              (let* ((nx (%numerator x))
628                     (dx (%denominator x))
629                     (ny (%numerator y))
630                     (dy (%denominator y))
631                     (g1 (gcd dx dy)))
632                (if (eql g1 1)
633                  (%make-ratio (- (* nx dy) (* dx ny)) (* dx dy))
634                  (let* ((t1 (- (* nx (truncate dy g1)) (* (truncate dx g1) ny)))
635                         (g2 (gcd t1 g1))
636                         (t2 (truncate dx g1)))
637                    (cond ((eql t1 0) 0)
638                          ((eql g2 1) (%make-ratio t1 (* t2 dy)))
639                          (t
640                           (let* ((nn (truncate t1 g2))
641                                  (t3 (truncate dy g2))
642                                  (nd (if (eql t2 1) t3 (* t2 t3))))
643                             (if (eql nd 1) nn (%make-ratio nn nd)))))))))
644             (integer
645              (let* ((dx (%denominator x)) (n (- (%numerator x) (* y dx))))
646                (%make-ratio n dx)))
647             (double-float (rat-dfloat - x y))
648             (short-float (rat-sfloat - x y))
649             (complex (complex (- x (%realpart y)) 
650                               (- (%imagpart y))))))))
651
652
653;;; BUILD-RATIO  --  Internal
654;;;
655;;;    Given a numerator and denominator with the GCD already divided out, make
656;;; a canonical rational.  We make the denominator positive, and check whether
657;;; it is 1.
658;;;
659
660(defun build-ratio (num den)
661  (if (minusp den) (setq num (- num) den (- den)))
662  (case den
663    (0 (divide-by-zero-error 'build-ratio num den))
664    (1 num)
665    (t (%make-ratio num den))))
666
667
668
669
670;;; MAYBE-TRUNCATE  --  Internal
671;;;
672;;;    Truncate X and Y, but bum the case where Y is 1.
673;;;
674
675
676(defun maybe-truncate (x y)
677  (if (eql y 1)
678    x
679    (truncate x y)))
680
681(defun *-2 (x y)
682  ;(declare (optimize (speed 3)(safety 0)))
683  (flet ((integer*ratio (x y)
684           (if (eql x 0) 0
685               (let* ((ny (%numerator y))
686                      (dy (%denominator y))
687                      (gcd (gcd x dy)))
688                 (if (eql gcd 1)
689                     (%make-ratio (* x ny) dy)
690                     (let ((nn (* (truncate x gcd) ny))
691                           (nd (truncate dy gcd)))
692                       (if (eql nd 1)
693                           nn
694                           (%make-ratio nn nd)))))))
695         (complex*real (x y)
696           (canonical-complex (* (%realpart x) y) (* (%imagpart x) y))))
697    (number-case x
698      (double-float (number-case y
699                      (double-float (* (the double-float x)(the double-float y)))
700                      (short-float (with-stack-double-floats ((dy y))
701                                     (* (the double-float x) (the double-float dy))))
702                      (rational (dfloat-rat * x y))
703                      (complex (complex*real y x))))
704      (short-float (number-case y
705                      (double-float (with-stack-double-floats ((dx x))
706                                     (* (the double-float dx) (the double-float y))))
707                      (short-float (* (the short-float x) (the short-float y)))
708                      (rational (sfloat-rat * x y))
709                      (complex (complex*real y x))))
710      (bignum (number-case y
711                (fixnum (multiply-bignum-and-fixnum x y))
712                (bignum (multiply-bignums x y))
713                (double-float (dfloat-rat * y x))
714                (short-float (sfloat-rat * y x))
715                (ratio (integer*ratio x y))
716                (complex (complex*real y x))))
717      (fixnum (number-case y
718                (bignum (multiply-bignum-and-fixnum y x))
719                (fixnum (multiply-fixnums (the fixnum x) (the fixnum y)))
720                (short-float (sfloat-rat * y x))
721                (double-float (dfloat-rat * y x))
722                (ratio (integer*ratio x y))
723                (complex (complex*real y x))))
724      (complex (number-case y
725                 (complex (let* ((rx (%realpart x))
726                                 (ix (%imagpart x))
727                                 (ry (%realpart y))
728                                 (iy (%imagpart y)))
729                            (canonical-complex (- (* rx ry) (* ix iy)) (+ (* rx iy) (* ix ry)))))
730                 (real (complex*real x y))))
731      (ratio (number-case y
732               (ratio (let* ((nx (%numerator x))
733                             (dx (%denominator x))
734                             (ny (%numerator y))
735                             (dy (%denominator y))
736                             (g1 (gcd nx dy))
737                             (g2 (gcd dx ny)))
738                        (build-ratio (* (maybe-truncate nx g1)
739                                        (maybe-truncate ny g2))
740                                     (* (maybe-truncate dx g2)
741                                        (maybe-truncate dy g1)))))
742               (integer (integer*ratio y x))
743               (double-float (rat-dfloat * x y))
744               (short-float (rat-sfloat * x y))
745               (complex (complex*real y x)))))))
746
747
748
749(defun integer*integer (x y &optional res)
750  (declare (ignore res))
751  (number-case x     
752      (fixnum (number-case y
753                (fixnum (* (the fixnum x) (the fixnum y)))
754                (t (multiply-bignum-and-fixnum y x))))
755      (bignum (number-case y
756                (fixnum (multiply-bignum-and-fixnum x y))
757                (t (multiply-bignums x y))))))
758
759
760
761 
762
763;;; INTEGER-/-INTEGER  --  Internal
764;;;
765;;;    Divide two integers, producing a canonical rational.  If a fixnum, we
766;;; see if they divide evenly before trying the GCD.  In the bignum case, we
767;;; don't bother, since bignum division is expensive, and the test is not very
768;;; likely to suceed.
769;;;
770(defun integer-/-integer (x y)
771  (if (and (typep x 'fixnum) (typep y 'fixnum))
772    (multiple-value-bind (quo rem) (%fixnum-truncate x y)
773      (if (eql 0 rem)
774        quo
775        (let ((gcd (gcd x y)))
776          (declare (fixnum gcd))
777          (if (eql gcd 1)
778            (build-ratio x y)
779            (build-ratio (%fixnum-truncate x gcd) (%fixnum-truncate y gcd))))))
780      (let ((gcd (gcd x y)))
781        (if (eql gcd 1)
782          (build-ratio x y)
783          (build-ratio (truncate x gcd) (truncate y gcd))))))
784
785
786
787(defun /-2 (x y)
788  (number-case x
789    (double-float (number-case y
790                    (double-float (/ (the double-float x) (the double-float y)))
791                    (short-float (with-stack-double-floats ((dy y))
792                                   (/ (the double-float x) (the double-float dy))))
793                    (rational (dfloat-rat / x y))
794                    (complex (let* ((ry (%realpart y))
795                                    (iy (%imagpart y))
796                                    (dn (+ (* ry ry) (* iy iy))))
797                               (canonical-complex (/ (* x ry) dn) (/ (- (* x iy)) dn))))))
798    (short-float (number-case y
799                   (short-float (/ (the short-float x) (the short-float y)))
800                   (double-float (with-stack-double-floats ((dx x))
801                                   (/ (the double-float dx) (the double-float y))))
802                   (rational (sfloat-rat / x y))
803                   (complex (let* ((ry (%realpart y))
804                                    (iy (%imagpart y))
805                                    (dn (+ (* ry ry) (* iy iy))))
806                               (canonical-complex (/ (* x ry) dn) (/ (- (* x iy)) dn))))))                   
807    (integer (number-case y
808               (double-float (rat-dfloat / x y))
809               (short-float (rat-sfloat / x y))
810               (integer (integer-/-integer x y))
811               (complex (let* ((ry (%realpart y))
812                               (iy (%imagpart y))
813                               (dn (+ (* ry ry) (* iy iy))))
814                          (canonical-complex (/ (* x ry) dn) (/ (- (* x iy)) dn))))
815               (ratio
816                (if (eql 0 x)
817                  0
818                  (let* ((ny (%numerator y)) 
819                         (dy (%denominator y)) 
820                         (gcd (gcd x ny)))
821                    (build-ratio (* (maybe-truncate x gcd) dy)
822                                 (maybe-truncate ny gcd)))))))
823    (complex (number-case y
824               (complex (let* ((rx (%realpart x))
825                               (ix (%imagpart x))
826                               (ry (%realpart y))
827                               (iy (%imagpart y))
828                               (dn (+ (* ry ry) (* iy iy))))
829                          (canonical-complex (/ (+ (* rx ry) (* ix iy)) dn)
830                                             (/ (- (* ix ry) (* rx iy)) dn))))
831               ((rational float)
832                (canonical-complex (/ (%realpart x) y) (/ (%imagpart x) y)))))
833    (ratio (number-case y
834             (double-float (rat-dfloat / x y))
835             (short-float (rat-sfloat / x y))
836             (integer
837              (when (eql y 0)
838                (divide-by-zero-error '/ x y))
839              (let* ((nx (%numerator x)) (gcd (gcd nx y)))
840                (build-ratio (maybe-truncate nx gcd)
841                             (* (maybe-truncate y gcd) (%denominator x)))))
842             (complex (let* ((ry (%realpart y))
843                             (iy (%imagpart y))
844                             (dn (+ (* ry ry) (* iy iy))))
845                        (canonical-complex (/ (* x ry) dn) (/ (- (* x iy)) dn))))
846             (ratio
847              (let* ((nx (%numerator x))
848                     (dx (%denominator x))
849                     (ny (%numerator y))
850                     (dy (%denominator y))
851                     (g1 (gcd nx ny))
852                     (g2 (gcd dx dy)))
853                (build-ratio (* (maybe-truncate nx g1) (maybe-truncate dy g2))
854                             (* (maybe-truncate dx g2) (maybe-truncate ny g1)))))))))
855
856
857
858(defun divide-by-zero-error (operation &rest operands)
859  (error (make-condition 'division-by-zero
860           :operation operation
861           :operands operands)))
862
863
864(defun 1+ (number)
865  "Returns NUMBER + 1."
866  (+-2 number 1))
867
868(defun 1- (number)
869  "Returns NUMBER - 1."
870  (--2 number 1))
871
872
873
874
875(defun conjugate (number)
876  "Return the complex conjugate of NUMBER. For non-complex numbers, this is
877  an identity."
878  (number-case number
879    (complex (complex (%realpart number) (- (%imagpart number))))
880    (number number)))
881
882(defun numerator (rational)
883  "Return the numerator of NUMBER, which must be rational."
884  (number-case rational
885    (ratio (%numerator rational))
886    (integer rational)))
887
888(defun denominator (rational)
889  "Return the denominator of NUMBER, which must be rational."
890  (number-case rational
891    (ratio (%denominator rational))
892    (integer 1)))
893
894
895
896(defun abs (number)
897  "Return the absolute value of the number."
898  (number-case number
899   (fixnum
900    (locally (declare (fixnum number))
901      (if (minusp number) (- number) number)))
902   (double-float
903    (%double-float-abs number))
904   (short-float
905    (%short-float-abs number))
906   (bignum
907    (if (bignum-minusp number)(negate-bignum number) number))
908   (ratio
909    (if (minusp number) (- number) number))   
910   (complex
911    (let ((rx (%realpart number))
912          (ix (%imagpart number)))
913      (number-case rx
914        (rational
915         (sqrt (+ (* rx rx) (* ix ix))))
916        (short-float
917         (%short-float (%hypot (%double-float rx)
918                               (%double-float ix))))
919        (double-float
920         (%hypot rx ix)))))))
921
922
923
924(defun phase (number)
925  "Return the angle part of the polar representation of a complex number.
926  For complex numbers, this is (atan (imagpart number) (realpart number)).
927  For non-complex positive numbers, this is 0. For non-complex negative
928  numbers this is PI."
929  (number-case number
930    (rational
931     (if (minusp number)
932       (%short-float pi)
933       0.0f0))
934    (double-float
935     (if (minusp number)
936       (%double-float pi)
937       0.0d0))
938    (complex
939     (atan (%imagpart number) (%realpart number)))
940    (short-float
941     (if (minusp number)
942       (%short-float pi)
943       0.0s0))))
944
945
946
947; from Lib;numbers.lisp, sort of
948(defun float (number &optional other)
949  "Converts any REAL to a float. If OTHER is not provided, it returns a
950  SINGLE-FLOAT if NUMBER is not already a FLOAT. If OTHER is provided, the
951  result is the same float format as OTHER."
952  (if (null other)
953    (if (typep number 'float)
954      number
955      (%short-float number))
956    (if (typep other 'double-float)
957      (%double-float number)
958      (if (typep other 'short-float)
959        (%short-float number)
960        (float number (require-type other 'float))))))
961
962
963
964
965
966;;; If the numbers do not divide exactly and the result of (/ number divisor)
967;;; would be negative then decrement the quotient and augment the remainder by
968;;; the divisor.
969;;;
970(defun floor (number &optional divisor)
971  "Return the greatest integer not greater than number, or number/divisor.
972  The second returned value is (mod number divisor)."
973  (if (null divisor)(setq divisor 1))
974  (multiple-value-bind (tru rem) (truncate number divisor)
975    (if (and (not (zerop rem))
976             (if (minusp divisor)
977               (plusp number)
978               (minusp number)))
979      (if (called-for-mv-p)
980        (values (1- tru) (+ rem divisor))
981        (1- tru))
982      (values tru rem))))
983
984
985
986(defun %fixnum-floor (number divisor)
987  (declare (fixnum number divisor))
988  (if (eq divisor 1)
989    (values number 0)
990    (multiple-value-bind (tru rem) (truncate number divisor)
991      (if (eq rem 0)
992        (values tru 0)
993        (locally (declare (fixnum tru rem))
994          (if (and ;(not (zerop rem))
995                   (if (minusp divisor)
996                     (plusp number)
997                     (minusp number)))
998            (values (the fixnum (1- tru)) (the fixnum (+ rem divisor)))
999            (values tru rem)))))))
1000
1001
1002
1003;;; If the numbers do not divide exactly and the result of (/ number divisor)
1004;;; would be positive then increment the quotient and decrement the remainder by
1005;;; the divisor.
1006;;;
1007(defun ceiling (number &optional divisor)
1008  "Return the smallest integer not less than number, or number/divisor.
1009  The second returned value is the remainder."
1010  (if (null divisor)(setq divisor 1))
1011  (multiple-value-bind (tru rem) (truncate number divisor)
1012    (if (and (not (zerop rem))
1013             (if (minusp divisor)
1014               (minusp number)
1015               (plusp number)))
1016      (if (called-for-mv-p)
1017        (values (+ tru 1) (- rem divisor))
1018        (+ tru 1))
1019      (values tru rem))))
1020
1021
1022
1023(defun %fixnum-ceiling (number  divisor)
1024  "Returns the smallest integer not less than number, or number/divisor.
1025  The second returned value is the remainder."
1026  (declare (fixnum number divisor))
1027  (multiple-value-bind (tru rem) (%fixnum-truncate number divisor)
1028    (if (eq 0 rem)
1029      (values tru 0)
1030      (locally (declare (fixnum tru rem))
1031        (if (and ;(not (zerop rem))
1032             (if (minusp divisor)
1033               (minusp number)
1034               (plusp number)))
1035          (values (the fixnum (+ tru 1))(the fixnum  (- rem divisor)))
1036          (values tru rem))))))
1037
1038
1039
1040(defun integer-decode-denorm-short-float (mantissa sign)
1041  (declare (fixnum mantissa sign))
1042  (do* ((bias 0 (1+ bias))
1043        (sig mantissa (ash sig 1)))
1044       ((logbitp 23 sig)
1045        (values sig
1046                (- (- IEEE-single-float-bias)
1047                   IEEE-single-float-digits
1048                   bias)
1049                sign))))
1050
1051
1052(defun integer-decode-short-float (sfloat)
1053  (multiple-value-bind (mantissa exp sign)(fixnum-decode-short-float sfloat)
1054    (let* ((biased (- exp IEEE-single-float-bias IEEE-single-float-digits)))
1055      (setq sign (if (eql 0 sign) 1 -1))
1056      (if (eq exp 255)
1057        (error "Can't decode NAN/Inf: ~s" sfloat))
1058      (if (eql 0 exp)
1059        (if (eql 0 mantissa)
1060          (values 0 biased sign)
1061          (integer-decode-denorm-short-float (ash mantissa 1) sign))
1062        (values (logior #x800000 mantissa) biased sign)))))
1063
1064
1065
1066
1067;;; INTEGER-DECODE-FLOAT  --  Public
1068;;;
1069;;;    Dispatch to the correct type-specific i-d-f function.
1070;;;
1071(defun integer-decode-float (x)
1072  "Returns three values:
1073   1) an integer representation of the significand.
1074   2) the exponent for the power of 2 that the significand must be multiplied
1075      by to get the actual value.  This differs from the DECODE-FLOAT exponent
1076      by FLOAT-DIGITS, since the significand has been scaled to have all its
1077      digits before the radix point.
1078   3) -1 or 1 (i.e. the sign of the argument.)"
1079  (number-case x
1080    (short-float
1081     (integer-decode-short-float x))
1082    (double-float
1083     (integer-decode-double-float x))))
1084
1085
1086;;; %UNARY-TRUNCATE  --  Interface
1087;;;
1088;;;    This function is called when we are doing a truncate without any funky
1089;;; divisor, i.e. converting a float or ratio to an integer.  Note that we do
1090;;; *not* return the second value of truncate, so it must be computed by the
1091;;; caller if needed.
1092;;;
1093;;;    In the float case, we pick off small arguments so that compiler can use
1094;;; special-case operations.  We use an exclusive test, since (due to round-off
1095;;; error), (float most-positive-fixnum) may be greater than
1096;;; most-positive-fixnum.
1097;;;
1098(defun %unary-truncate (number)
1099  (number-case number
1100    (integer number)
1101    (ratio (truncate-no-rem (%numerator number) (%denominator number)))
1102    (double-float
1103     (if (and (< (the double-float number) 
1104                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 0.0d0))
1105              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 0.0d0)
1106                 (the double-float number)))
1107       (%truncate-double-float->fixnum number)
1108       (%truncate-double-float number)))
1109    (short-float
1110     (if (and (< (the short-float number) 
1111                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 0.0s0))
1112              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 0.0s0)
1113                 (the short-float number)))
1114       (%truncate-short-float->fixnum number)
1115       (%truncate-short-float number)))))
1116
1117
1118
1119; cmucl:compiler:float-tran.lisp
1120(defun xform-truncate (x)
1121  (let ((res (%unary-truncate x)))
1122    (values res (- x res))))
1123
1124
1125
1126(defun truncate (number &optional divisor)
1127  "Returns number (or number/divisor) as an integer, rounded toward 0.
1128  The second returned value is the remainder."
1129  (if (null divisor)(setq divisor 1))
1130  (when (not (called-for-mv-p))
1131    (return-from truncate (truncate-no-rem number divisor)))
1132  (macrolet 
1133      ((truncate-rat-dfloat (number divisor)
1134         `(with-stack-double-floats ((fnum ,number)
1135                                     (f2))
1136           (let ((res (%unary-truncate (%double-float/-2! fnum ,divisor f2))))
1137             (values res 
1138                     (%double-float--2 fnum (%double-float*-2! (%double-float res f2) ,divisor f2))))))
1139       (truncate-rat-sfloat (number divisor)
1140         #+32-bit-target
1141         `(target::with-stack-short-floats ((fnum ,number)
1142                                            (f2))
1143           (let ((res (%unary-truncate (%short-float/-2! fnum ,divisor f2))))
1144             (values res 
1145                     (%short-float--2 fnum (%short-float*-2! (%short-float res f2) ,divisor f2)))))
1146         #+64-bit-target
1147         `(let* ((temp (%short-float ,number))
1148                 (res (%unary-truncate (/ (the short-float temp)
1149                                          (the short-float ,divisor)))))
1150           (values res
1151            (- (the short-float temp)
1152             (the short-float (* (the short-float (%short-float res))
1153                                 (the short-float ,divisor)))))))
1154       )
1155    (number-case number
1156      (fixnum
1157       (number-case divisor
1158         (fixnum (if (eq divisor 1) (values number 0) (%fixnum-truncate number divisor)))
1159         (bignum (values 0 number))
1160         (double-float (truncate-rat-dfloat number divisor))
1161         (short-float (truncate-rat-sfloat number divisor))
1162         (ratio (let ((q (truncate (* number (%denominator divisor)) ; this was wrong
1163                                   (%numerator divisor))))
1164                  (values q (- number (* q divisor)))))))
1165      (bignum (number-case divisor
1166                (fixnum (if (eq divisor 1) (values number 0)
1167                          (if (eq divisor target::target-most-negative-fixnum);; << aargh
1168                            (with-small-bignum-buffers ((bd divisor))
1169                              (bignum-truncate number bd))
1170                            (bignum-truncate-by-fixnum number divisor))))
1171                (bignum (bignum-truncate number divisor))
1172                (double-float  (truncate-rat-dfloat number divisor))
1173                (short-float (truncate-rat-sfloat number divisor))
1174                (ratio (let ((q (truncate (* number (%denominator divisor)) ; so was this
1175                                          (%numerator divisor))))
1176                         (values q (- number (* q divisor)))))))
1177      (short-float (if (eql divisor 1)
1178                     (let* ((res (%unary-truncate number)))
1179                       (values res (- number res)))
1180                     (number-case divisor
1181                       (short-float
1182                        #+32-bit-target
1183                        (target::with-stack-short-floats ((f2))
1184                          (let ((res (%unary-truncate (%short-float/-2! number divisor f2))))
1185                            (values res 
1186                                    (%short-float--2
1187                                     number 
1188                                     (%short-float*-2! (%short-float res f2) divisor f2)))))
1189                        #+64-bit-target
1190                        (let ((res (%unary-truncate
1191                                    (/ (the short-float number)
1192                                       (the short-float divisor)))))
1193                          (values res
1194                                  (- (the short-float number)
1195                                     (* (the short-float (%short-float res))
1196                                        (the short-float divisor))))))
1197                       ((fixnum bignum ratio)
1198                        #+32-bit-target
1199                        (target::with-stack-short-floats ((fdiv divisor)
1200                                                          (f2))
1201                          (let ((res (%unary-truncate (%short-float/-2! number fdiv f2))))
1202                            (values res 
1203                                    (%short-float--2 
1204                                     number 
1205                                     (%short-float*-2! (%short-float res f2) fdiv f2)))))
1206                        #+64-bit-target
1207                        (let* ((fdiv (%short-float divisor))
1208                               (res (%unary-truncate
1209                                     (/ (the short-float number)
1210                                        (the short-float fdiv)))))
1211                          (values res (- number (* res fdiv))))
1212                                     
1213                        )
1214                       (double-float
1215                        (with-stack-double-floats ((fnum number)
1216                                                   (f2))
1217                          (let* ((res (%unary-truncate (%double-float/-2! fnum divisor f2))))
1218                            (values res
1219                                    (%double-float--2
1220                                     fnum
1221                                     (%double-float*-2! (%double-float res f2) divisor f2)))))))))
1222      (double-float (if (eql divisor 1)
1223                      (let ((res (%unary-truncate number)))
1224                        (values res (- number res)))
1225                      (number-case divisor
1226                        ((fixnum bignum ratio short-float)
1227                         (with-stack-double-floats ((fdiv divisor)
1228                                                    (f2))
1229                           (let ((res (%unary-truncate (%double-float/-2! number fdiv f2))))
1230                             (values res 
1231                                     (%double-float--2 
1232                                      number 
1233                                      (%double-float*-2! (%double-float res f2) fdiv f2))))))                       
1234                        (double-float
1235                         (with-stack-double-floats ((f2))
1236                           (let ((res (%unary-truncate (%double-float/-2! number divisor f2))))
1237                             (values res 
1238                                     (%double-float--2
1239                                      number 
1240                                      (%double-float*-2! (%double-float res f2) divisor f2)))))))))
1241      (ratio (number-case divisor
1242               (double-float (truncate-rat-dfloat number divisor))
1243               (short-float (truncate-rat-sfloat number divisor))
1244               (rational
1245                (let ((q (truncate (%numerator number)
1246                                   (* (%denominator number) divisor))))
1247                  (values q (- number (* q divisor))))))))))
1248
1249(defun truncate-no-rem (number  divisor)
1250  "Returns number (or number/divisor) as an integer, rounded toward 0."
1251  (macrolet 
1252    ((truncate-rat-dfloat (number divisor)
1253       `(with-stack-double-floats ((fnum ,number)
1254                                      (f2))
1255         (%unary-truncate (%double-float/-2! fnum ,divisor f2))))
1256     (truncate-rat-sfloat (number divisor)
1257       #+32-bit-target
1258       `(target::with-stack-short-floats ((fnum ,number)
1259                                      (f2))
1260         (%unary-truncate (%short-float/-2! fnum ,divisor f2)))
1261       #+64-bit-target
1262       `(let ((fnum (%short-float ,number)))
1263         (%unary-truncate (/ (the short-float fnum)
1264                           (the short-float ,divisor))))))
1265    (number-case number
1266    (fixnum
1267     (if (eql number target::target-most-negative-fixnum)
1268       (if (zerop divisor)
1269         (error 'division-by-zero :operation 'truncate :operands (list number divisor))
1270         (with-small-bignum-buffers ((bn number))
1271           (let* ((result (truncate-no-rem bn divisor)))
1272             (if (eq result bn)
1273               number
1274               result))))
1275       (number-case divisor
1276         (fixnum (if (eq divisor 1) number (values (%fixnum-truncate number divisor))))
1277         (bignum 0)
1278         (double-float (truncate-rat-dfloat number divisor))
1279         (short-float (truncate-rat-sfloat number divisor))
1280         (ratio (let ((q (truncate (* number (%denominator divisor))
1281                                   (%numerator divisor))))
1282                  q)))))
1283     (bignum (number-case divisor
1284               (fixnum (if (eq divisor 1) number
1285                         (if (eq divisor target::target-most-negative-fixnum)
1286                           (with-small-bignum-buffers ((bd divisor))
1287                             (bignum-truncate number bd :no-rem))
1288                           (bignum-truncate-by-fixnum number divisor))))
1289               (bignum (bignum-truncate number divisor :no-rem))
1290               (double-float  (truncate-rat-dfloat number divisor))
1291               (short-float (truncate-rat-sfloat number divisor))
1292               (ratio (let ((q (truncate (* number (%denominator divisor))
1293                                         (%numerator divisor))))
1294                        Q))))
1295     (double-float (if (eql divisor 1)
1296                     (let ((res (%unary-truncate number)))
1297                       RES)
1298                     (number-case divisor
1299                       ((fixnum bignum ratio)
1300                        (with-stack-double-floats ((fdiv divisor)
1301                                                   (f2))
1302                          (let ((res (%unary-truncate (%double-float/-2! number fdiv f2))))
1303                            RES)))
1304                       (short-float
1305                        (with-stack-double-floats ((ddiv divisor)
1306                                                   (f2))
1307                          (%unary-truncate (%double-float/-2! number ddiv f2))))
1308                       (double-float
1309                        (with-stack-double-floats ((f2))
1310                          (%unary-truncate (%double-float/-2! number divisor f2)))))))
1311     (short-float (if (eql divisor 1)
1312                    (let ((res (%unary-truncate number)))
1313                      RES)
1314                    (number-case divisor
1315                      ((fixnum bignum ratio)
1316                       #+32-bit-target
1317                       (target::with-stack-short-floats ((fdiv divisor)
1318                                                 (f2))
1319                         (let ((res (%unary-truncate (%short-float/-2! number fdiv f2))))
1320                           RES))
1321                       #+64-bit-target
1322                       (%unary-truncate (/ (the short-float number)
1323                                           (the short-float (%short-float divisor)))))
1324                      (short-float
1325                       #+32-bit-target
1326                       (target::with-stack-short-floats ((ddiv divisor)
1327                                                      (f2))
1328                         (%unary-truncate (%short-float/-2! number ddiv f2)))
1329                       #+64-bit-target
1330                       (%unary-truncate (/ (the short-float number)
1331                                           (the short-float (%short-float divisor)))))
1332                      (double-float
1333                       (with-stack-double-floats ((n2 number)
1334                                                      (f2))
1335                         (%unary-truncate (%double-float/-2! n2 divisor f2)))))))
1336    (ratio (number-case divisor
1337                  (double-float (truncate-rat-dfloat number divisor))
1338                  (short-float (truncate-rat-sfloat number divisor))
1339                  (rational
1340                   (let ((q (truncate (%numerator number)
1341                                      (* (%denominator number) divisor))))
1342                     Q)))))))
1343
1344
1345;;; %UNARY-ROUND  --  Interface
1346;;;
1347;;;    Similar to %UNARY-TRUNCATE, but rounds to the nearest integer.  If we
1348;;; can't use the round primitive, then we do our own round-to-nearest on the
1349;;; result of i-d-f.  [Note that this rounding will really only happen with
1350;;; double floats, since the whole single-float fraction will fit in a fixnum,
1351;;; so all single-floats larger than most-positive-fixnum can be precisely
1352;;; represented by an integer.]
1353;;;
1354;;; returns both values today
1355
1356(defun %unary-round (number)
1357  (number-case number
1358    (integer (values number 0))
1359    (ratio (let ((q (round (%numerator number) (%denominator number))))             
1360             (values q (- number q))))
1361    (double-float
1362     (if (and (< (the double-float number) 
1363                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 1.0d0))
1364              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 1.0d0)
1365                 (the double-float number)))
1366       (let ((round (%unary-round-to-fixnum number)))
1367         (values round (- number round)))
1368       (multiple-value-bind (trunc rem) (truncate number)         
1369         (if (not (%double-float-minusp number))
1370           (if (or (> rem 0.5d0)(and (= rem 0.5d0) (oddp trunc)))
1371             (values (+ trunc 1) (- rem 1.0d0))
1372             (values trunc rem))
1373           (if (or (> rem -0.5d0)(and (evenp trunc)(= rem -0.5d0)))
1374             (values trunc rem)
1375             (values (1- trunc) (+ 1.0d0 rem)))))))
1376    (short-float
1377     (if (and (< (the short-float number) 
1378                 (float (1- (ash 1 (- (1- target::nbits-in-word) target::fixnumshift))) 1.0s0))
1379              (< (float (ash -1 (- (1- target::nbits-in-word) target::fixnumshift)) 1.0s0)
1380                 (the double-float number)))
1381       (let ((round (%unary-round-to-fixnum number)))
1382         (values round (- number round)))
1383       (multiple-value-bind (trunc rem) (truncate number)         
1384         (if (not (%short-float-minusp number))
1385           (if (or (> rem 0.5s0)(and (= rem 0.5s0) (oddp trunc)))
1386             (values (+ trunc 1) (- rem 1.0s0))
1387             (values trunc rem))
1388           (if (or (> rem -0.5s0)(and (evenp trunc)(= rem -0.5s0)))
1389             (values trunc rem)
1390             (values (1- trunc) (+ 1.0s0 rem)))))))))
1391
1392(defun %unary-round-to-fixnum (number)
1393  (number-case number
1394    (double-float
1395     (%round-nearest-double-float->fixnum number))
1396    (short-float
1397     (%round-nearest-short-float->fixnum number))))
1398
1399                         
1400                               
1401         
1402; cmucl:compiler:float-tran.lisp
1403#|
1404(defun xform-round (x)
1405  (let ((res (%unary-round x)))
1406    (values res (- x res))))
1407|#
1408
1409#|
1410(defun round (number &optional divisor)
1411  "Rounds number (or number/divisor) to nearest integer.
1412  The second returned value is the remainder."
1413  (if (null divisor)(setq divisor 1))
1414  (if (eql divisor 1)
1415    (xform-round number)
1416    (multiple-value-bind (tru rem) (truncate number divisor)
1417      (let ((thresh (if (integerp divisor) (ash (abs divisor) -1)(/ (abs divisor) 2)))) ; does this need to be a ratio?
1418        (cond ((or (> rem thresh)
1419                   (and (= rem thresh) (oddp tru)))
1420               (if (minusp divisor)
1421                 (values (- tru 1) (+ rem divisor))
1422                 (values (+ tru 1) (- rem divisor))))
1423              ((let ((-thresh (- thresh)))
1424                 (or (< rem -thresh)
1425                     (and (= rem -thresh) (oddp tru))))
1426               (if (minusp divisor)
1427                 (values (+ tru 1) (- rem divisor))
1428                 (values (- tru 1) (+ rem divisor))))
1429              (t (values tru rem)))))))
1430|#
1431
1432
1433(defun %fixnum-round (number divisor)
1434  (declare (fixnum number divisor))
1435  (multiple-value-bind (quo rem)(truncate number divisor) ; should => %fixnum-truncate
1436    (if (= 0 rem)
1437      (values quo rem)
1438      (locally (declare (fixnum quo rem))
1439        (let* ((minusp-num (minusp number))
1440               (minusp-div (minusp divisor))
1441               (2rem (* rem (if (neq minusp-num minusp-div) -2 2))))
1442          ;(declare (fixnum 2rem)) ; no way jose 
1443          ;(truncate (1- most-positive-fixnum) most-positive-fixnum)
1444          ; 2rem has same sign as divisor
1445          (cond (minusp-div             
1446                 (if (or (< 2rem divisor)
1447                         (and (= 2rem divisor)(logbitp 0 quo)))
1448                   (if minusp-num
1449                     (values (the fixnum (+ quo 1))(the fixnum (- rem divisor)))
1450                     (values (the fixnum (- quo 1))(the fixnum (+ rem divisor))))
1451                   (values quo rem)))
1452                (t (if (or (> 2rem divisor)
1453                           (and (= 2rem divisor)(logbitp 0 quo)))
1454                     (if minusp-num
1455                       (values (the fixnum (- quo 1))(the fixnum (+ rem divisor)))
1456                       (values (the fixnum (+ quo 1))(the fixnum (- rem divisor))))
1457                     (values quo rem)))))))))
1458#|
1459; + + => + +
1460; + - => - +
1461; - + => - -
1462; - - => + -
1463(defun %fixnum-round (number divisor)
1464  (declare (fixnum number divisor))
1465  "Rounds number (or number/divisor) to nearest integer.
1466  The second returned value is the remainder."
1467  (if (eq divisor 1)
1468    (values number 0)
1469    (multiple-value-bind (tru rem) (truncate number divisor)
1470      (if (= 0 rem)
1471        (values tru rem)
1472        (locally (declare (fixnum tru rem))
1473          (let* ((minusp-num (minusp number))
1474                 (minusp-div (minusp divisor))
1475                 (half-div (ash (if minusp-div (- divisor) divisor) -1))
1476                 (abs-rem (if minusp-num (- rem) rem)))           
1477            (declare (fixnum half-div abs-rem)) ; true of abs-rem?
1478            (if (or (> abs-rem half-div)
1479                    (and
1480                     (not (logbitp 0 divisor))
1481                     (logbitp 0 tru) ; oddp
1482                     (= abs-rem half-div)))
1483              (if (eq minusp-num minusp-div)
1484                (values (the fixnum (+ tru 1))(the fixnum (- rem divisor)))
1485                (values (the fixnum (- tru 1))(the fixnum (+ rem divisor))))
1486              (values tru rem))))))))
1487|#
1488
1489
1490
1491;; makes 1 piece of garbage instead of average of 2
1492(defun round (number &optional divisor)
1493  "Rounds number (or number/divisor) to nearest integer.
1494  The second returned value is the remainder."
1495  (if (null divisor)(setq divisor 1))
1496  (if (eql divisor 1)
1497    (%unary-round number)
1498    (multiple-value-bind (tru rem) (truncate number divisor)
1499      (if (= 0 rem)
1500        (values tru rem)
1501        (let* ((mv-p (called-for-mv-p))
1502               (minusp-num (minusp number))
1503               (minusp-div (minusp divisor))
1504               (2rem (* rem (if (neq minusp-num minusp-div) -2 2))))
1505          ; 2rem has same sign as divisor
1506          (cond (minusp-div             
1507                 (if (or (< 2rem divisor)
1508                         (and (= 2rem divisor)(oddp tru)))
1509                   (if mv-p
1510                     (if minusp-num
1511                       (values (+ tru 1)(- rem divisor))
1512                       (values (- tru 1)(+ rem divisor)))
1513                     (if minusp-num (+ tru 1)(- tru 1)))
1514                   (values tru rem)))
1515                (t (if (or (> 2rem divisor)
1516                           (and (= 2rem divisor)(oddp tru)))
1517                     (if mv-p
1518                       (if minusp-num
1519                         (values (- tru 1)(+ rem divisor))
1520                         (values (+ tru 1)(- rem divisor)))
1521                       (if minusp-num (- tru 1)(+ tru 1)))
1522                     (values tru rem)))))))))
1523
1524
1525;; #-PPC IN L1-NUMBERS.LISP (or implement %%numdiv)
1526;; Anyone caught implementing %%numdiv will be summarily executed.
1527(defun rem (number divisor)
1528  "Returns second result of TRUNCATE."
1529  (number-case number
1530    (fixnum
1531     (number-case divisor
1532       (fixnum (nth-value 1 (%fixnum-truncate number divisor)))
1533       (bignum number)
1534       (t (nth-value 1 (truncate number divisor)))))
1535    (bignum
1536     (number-case divisor
1537       (fixnum
1538        (if (eq divisor target::target-most-negative-fixnum)
1539          (nth-value 1 (truncate number divisor))
1540          (bignum-truncate-by-fixnum-no-quo number divisor)))
1541       (bignum
1542        (bignum-rem number divisor))
1543       (t (nth-value 1 (truncate number divisor)))))
1544    (t (nth-value 1 (truncate number divisor)))))
1545
1546;; #-PPC IN L1-NUMBERS.LISP (or implement %%numdiv)
1547;; See above.
1548(defun mod (number divisor)
1549  "Returns second result of FLOOR."
1550  (let ((rem (rem number divisor)))
1551    (if (and (not (zerop rem))
1552             (if (minusp divisor)
1553                 (plusp number)
1554                 (minusp number)))
1555        (+ rem divisor)
1556        rem)))
1557
1558(defun cis (theta)
1559  "Return cos(Theta) + i sin(Theta), i.e. exp(i Theta)."
1560  (if (complexp theta)
1561    (error "Argument to CIS is complex: ~S" theta)
1562    (complex (cos theta) (sin theta))))
1563
1564
1565(defun complex (realpart &optional (imagpart 0))
1566  "Return a complex number with the specified real and imaginary components."
1567  (number-case realpart
1568    (short-float
1569      (number-case imagpart
1570         (short-float (canonical-complex realpart imagpart))
1571         (double-float (canonical-complex (%double-float realpart) imagpart))
1572         (rational (canonical-complex realpart (%short-float imagpart)))))
1573    (double-float 
1574     (number-case imagpart
1575       (double-float (canonical-complex
1576                      (the double-float realpart)
1577                      (the double-float imagpart)))
1578       (short-float (canonical-complex realpart (%double-float imagpart)))
1579       (rational (canonical-complex
1580                              (the double-float realpart)
1581                              (the double-float (%double-float imagpart))))))
1582    (rational (number-case imagpart
1583                (double-float (canonical-complex
1584                               (the double-float (%double-float realpart))
1585                               (the double-float imagpart)))
1586                (short-float (canonical-complex (%short-float realpart) imagpart))
1587                (rational (canonical-complex realpart imagpart)))))) 
1588
1589;; #-PPC IN L1-NUMBERS.LISP
1590(defun realpart (number)
1591  "Extract the real part of a number."
1592  (number-case number
1593    (complex (%realpart number))
1594    (number number)))
1595
1596;; #-PPC IN L1-NUMBERS.LISP
1597(defun imagpart (number)
1598  "Extract the imaginary part of a number."
1599  (number-case number
1600    (complex (%imagpart number))
1601    (float (* 0 number))
1602    (rational 0)))
1603
1604(defun logand-2 (x y) 
1605  (number-case x
1606    (fixnum (number-case y
1607              (fixnum
1608               (%ilogand (the fixnum x)(the fixnum y)))
1609              (bignum (fix-big-logand x y))))
1610    (bignum (number-case y
1611              (fixnum (fix-big-logand y x))
1612              (bignum (bignum-logical-and x y))))))
1613
1614(defun logior-2 (x y)
1615  (number-case x
1616    (fixnum (number-case y
1617              (fixnum (%ilogior2 x y))
1618              (bignum
1619               (if (zerop x)
1620                 y
1621                 (with-small-bignum-buffers ((bx x))
1622                   (bignum-logical-ior bx y))))))
1623    (bignum (number-case y
1624              (fixnum (if (zerop y)
1625                        x
1626                        (with-small-bignum-buffers ((by y))
1627                          (bignum-logical-ior x by))))
1628              (bignum (bignum-logical-ior x y))))))
1629
1630(defun logxor-2 (x y)
1631  (number-case x
1632    (fixnum (number-case y
1633              (fixnum (%ilogxor2 x y))
1634              (bignum
1635               (with-small-bignum-buffers ((bx x))
1636                 (bignum-logical-xor bx y)))))
1637    (bignum (number-case y
1638              (fixnum (with-small-bignum-buffers ((by y))
1639                        (bignum-logical-xor x by)))
1640              (bignum (bignum-logical-xor x y))))))
1641
1642               
1643
1644; see cmucl:compiler:srctran.lisp for transforms
1645
1646(defun lognand (integer1 integer2)
1647  "Complement the logical AND of INTEGER1 and INTEGER2."
1648  (lognot (logand integer1 integer2)))
1649
1650(defun lognor (integer1 integer2)
1651  "Complement the logical AND of INTEGER1 and INTEGER2."
1652  (lognot (logior integer1 integer2)))
1653
1654(defun logandc1 (x y)
1655  "Return the logical AND of (LOGNOT integer1) and integer2."
1656  (number-case x
1657    (fixnum (number-case y               
1658              (fixnum (%ilogand (%ilognot x) y))
1659              (bignum  (fix-big-logandc1 x y))))    ; (%ilogand-fix-big (%ilognot x) y))))
1660    (bignum (number-case y
1661              (fixnum  (fix-big-logandc2 y x))      ; (%ilogandc2-fix-big y x))
1662              (bignum (bignum-logandc2 y x))))))    ;(bignum-logical-and (bignum-logical-not x)  y))))))
1663
1664
1665#| ; its in numbers
1666(defun logandc2 (integer1 integer2)
1667  "Returns the logical AND of integer1 and (LOGNOT integer2)."
1668  (logand integer1 (lognot integer2)))
1669|#
1670
1671(defun logorc1 (integer1 integer2)
1672  "Return the logical OR of (LOGNOT integer1) and integer2."
1673  (logior (lognot integer1) integer2))
1674
1675#|
1676(defun logorc2 (integer1 integer2)
1677  "Returns the logical OR of integer1 and (LOGNOT integer2)."
1678  (logior integer1 (lognot integer2)))
1679|#
1680
1681(defun logtest (integer1 integer2)
1682  "Predicate which returns T if logand of integer1 and integer2 is not zero."
1683 ; (not (zerop (logand integer1 integer2)))
1684  (number-case integer1
1685    (fixnum (number-case integer2
1686              (fixnum (not (= 0 (%ilogand integer1 integer2))))
1687              (bignum (logtest-fix-big integer1 integer2))))
1688    (bignum (number-case integer2
1689              (fixnum (logtest-fix-big integer2 integer1))
1690              (bignum (bignum-logtest integer1 integer2)))))) 
1691
1692
1693
1694(defun lognot (number)
1695  "Return the bit-wise logical not of integer."
1696  (number-case number
1697    (fixnum (%ilognot number))
1698    (bignum (bignum-logical-not number))))
1699
1700(defun logcount (integer)
1701  "Count the number of 1 bits if INTEGER is positive, and the number of 0 bits
1702  if INTEGER is negative."
1703  (number-case integer
1704    (fixnum
1705     (%ilogcount (if (minusp (the fixnum integer))
1706                   (%ilognot integer)
1707                   integer)))
1708    (bignum
1709     (bignum-logcount integer))))
1710
1711
1712
1713(defun ash (integer count)
1714  "Shifts integer left by count places preserving sign. - count shifts right."
1715  (etypecase integer
1716    (fixnum
1717     (etypecase count
1718       (fixnum
1719        (if (eql integer 0)
1720          0
1721          (if (eql count 0)
1722            integer
1723            (let ((length (integer-length (the fixnum integer))))
1724              (declare (fixnum length count))
1725              (cond ((and (plusp count)
1726                          (> (+ length count)
1727                             (- (1- target::nbits-in-word) target::fixnumshift)))
1728                     (with-small-bignum-buffers ((bi integer))
1729                       (bignum-ashift-left bi count)))
1730                    ((and (minusp count) (< count (- (1- target::nbits-in-word))))
1731                     (if (minusp integer) -1 0))
1732                    (t (%iash (the fixnum integer) count)))))))
1733       (bignum
1734        (if (minusp count)
1735          (if (minusp integer) -1 0)         
1736          (error "Count ~s too large for ASH" count)))))
1737    (bignum
1738     (etypecase count
1739       (fixnum
1740        (if (eql count 0) 
1741          integer
1742          (if (plusp count)
1743            (bignum-ashift-left integer count)
1744            (bignum-ashift-right integer (- count)))))
1745       (bignum
1746        (if (minusp count)
1747          (if (minusp integer) -1 0)
1748          (error "Count ~s too large for ASH" count)))))))
1749
1750(defun integer-length (integer)
1751  "Return the number of significant bits in the absolute value of integer."
1752  (number-case integer
1753    (fixnum
1754     (%fixnum-intlen (the fixnum integer)))
1755    (bignum
1756     (bignum-integer-length integer))))
1757
1758
1759; not CL, used below
1760(defun byte-mask (size)
1761  (1- (ash 1 (the fixnum size))))
1762
1763(defun byte-position (bytespec)
1764  "Return the position part of the byte specifier bytespec."
1765  (if (> bytespec 0)
1766    (- (integer-length bytespec) (logcount bytespec))
1767    (- bytespec)))
1768
1769
1770; CMU CL returns T.
1771(defun upgraded-complex-part-type (type)
1772  "Return the element type of the most specialized COMPLEX number type that
1773   can hold parts of type SPEC."
1774  (declare (ignore type))
1775  'real)
1776
1777;;; This is the MRG31k3p random number generator described in
1778;;; P. L'Ecuyer and R. Touzin, "Fast Combined Multiple Recursive
1779;;; Generators with Multipliers of the form a = +/- 2^d +/- 2^e",
1780;;; Proceedings of the 2000 Winter Simulation Conference, Dec. 2000,
1781;;; 683--689.
1782;;;
1783;;; A link to the paper is available on L'Ecuyer's web site:
1784;;; http://www.iro.umontreal.ca/~lecuyer/papers.html.
1785;;;
1786;;; This generator has a period of about 2^185.  It produces values in
1787;;; in the half-open interval [0, 2^31 - 1).
1788;;;
1789;;; It uses 6 words of state.
1790
1791(defconstant mrg31k3p-m1 #.(- (expt 2 31) 1))
1792(defconstant mrg31k3p-m2 #.(- (expt 2 31) 21069))
1793(defconstant mrg31k3p-limit #.(1- (expt 2 31))
1794             "Exclusive upper bound on values returned by %mrg31k3p.")
1795
1796
1797;;; This is a portable version of the MRG31k3p generator.  It's not
1798;;; too bad in a 64-bit CCL, but the generator pretty much has to be
1799;;; in LAP for 32-bit ports.
1800#-(or x8632-target ppc32-target x8664-target ppc64-target)
1801(defun %mrg31k3p (state)
1802  (let* ((v (random.mrg31k3p-state state)))
1803    (declare (type (simple-array (unsigned-byte 32) (*)) v)
1804             (optimize speed))
1805    (let ((y1 (+ (+ (ash (logand (aref v 1) #x1ff) 22)
1806                    (ash (aref v 1) -9))
1807                 (+ (ash (logand (aref v 2) #xffffff) 7)
1808                    (ash (aref v 2) -24)))))
1809      (declare (type (unsigned-byte 32) y1))
1810      (if (>= y1 mrg31k3p-m1) (decf y1 mrg31k3p-m1))
1811      (incf y1 (aref v 2))
1812      (if (>= y1 mrg31k3p-m1) (decf y1 mrg31k3p-m1))
1813      (setf (aref v 2) (aref v 1)
1814            (aref v 1) (aref v 0)
1815            (aref v 0) y1))
1816    (let ((y1 (+ (ash (logand (aref v 3) #xffff) 15)
1817                 (* 21069 (ash (aref v 3) -16))))
1818          (y2 (+ (ash (logand (aref v 5) #xffff) 15)
1819                 (* 21069 (ash (aref v 5) -16)))))
1820      (declare (type (unsigned-byte 32) y1 y2))
1821      (if (>= y1 mrg31k3p-m2) (decf y1 mrg31k3p-m2))
1822      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1823      (incf y2 (aref v 5))
1824      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1825      (incf y2 y1)
1826      (if (>= y2 mrg31k3p-m2) (decf y2 mrg31k3p-m2))
1827      (setf (aref v 5) (aref v 4)
1828            (aref v 4) (aref v 3)
1829            (aref v 3) y2))
1830    (let* ((x10 (aref v 0))
1831           (x20 (aref v 3)))
1832      (if (<= x10 x20)
1833        (+ (- x10 x20) mrg31k3p-m1)
1834        (- x10 x20)))))
1835
1836(eval-when (:compile-toplevel :execute)
1837  (declaim (inline %16-random-bits)))
1838
1839(defun %16-random-bits (state)
1840  (logand #xffff (the fixnum (%mrg31k3p state))))
1841
1842#+64-bit-target
1843(defun %big-fixnum-random (number state)
1844  (declare (fixnum number)
1845           (ftype (function (random-state) fixnum) %mrg31k3p))
1846  (let ((low (ldb (byte 30 0) (%mrg31k3p state)))
1847        (high (ldb (byte 30 0) (%mrg31k3p state))))
1848    (declare (fixnum low high))
1849    (fast-mod (logior low (the fixnum (ash high 30)))
1850              number)))
1851
1852;;; When using a dead simple random number generator, it's reasonable
1853;;; to take 16 bits of the output and discard the rest.  With a more
1854;;; expensive generator, however, it may be worthwhile to do more bit
1855;;; fiddling here here so that we can use all of the random bits
1856;;; produced by %mrg31k2p.
1857#+32-bit-target
1858(defun %bignum-random (number state)
1859  (let* ((bits (+ (integer-length number) 8))
1860         (half-words (ash (the fixnum (+ bits 15)) -4))
1861         (long-words (ash (+ half-words 1) -1))
1862         (dividend (%alloc-misc long-words target::subtag-bignum))
1863         (16-bit-dividend dividend)
1864         (index 1))
1865    (declare (fixnum long-words index bits)
1866             (dynamic-extent dividend)
1867             (type (simple-array (unsigned-byte 16) (*)) 16-bit-dividend) ;lie
1868             (optimize (speed 3) (safety 0)))
1869    (loop
1870       ;; This had better inline due to the lie above, or it will error
1871       #+big-endian-target
1872       (setf (aref 16-bit-dividend index) (%16-random-bits state))
1873       #+little-endian-target
1874       (setf (aref 16-bit-dividend (the fixnum (1- index)))
1875             (%16-random-bits state))
1876       (decf half-words)
1877       (when (<= half-words 0) (return))
1878       #+big-endian-target
1879       (setf (aref 16-bit-dividend (the fixnum (1- index)))
1880             (%16-random-bits state))
1881       #+little-endian-target
1882       (setf (aref 16-bit-dividend index) (%16-random-bits state))
1883       (decf half-words)
1884       (when (<= half-words 0) (return))
1885       (incf index 2))
1886    ;; The bignum code expects normalized bignums
1887    (let* ((result (mod dividend number)))
1888      (if (eq dividend result)
1889        (copy-uvector result)
1890        result))))
1891
1892(defun %float-random (number state)
1893  (let ((ratio (gvector :ratio (random target::target-most-positive-fixnum state) target::target-most-positive-fixnum)))
1894    (declare (dynamic-extent ratio))
1895    (* number ratio)))
1896
1897(defun random (number &optional (state *random-state*))
1898  (if (not (typep state 'random-state)) (report-bad-arg state 'random-state))
1899  (cond
1900    ((and (fixnump number) (> (the fixnum number) 0))
1901     #+32-bit-target
1902     (fast-mod (%mrg31k3p state) number)
1903     #+64-bit-target
1904     (if (< number mrg31k3p-limit)
1905       (fast-mod (%mrg31k3p state) number)
1906       (%big-fixnum-random number state)))
1907    ((and (typep number 'double-float) (> (the double-float number) 0.0))
1908     (%float-random number state))
1909    ((and (typep number 'short-float) (> (the short-float number) 0.0s0))
1910     (%float-random number state))
1911    ((and (bignump number) (> number 0))
1912     (%bignum-random number state))
1913    (t (report-bad-arg number '(or (integer (0)) (float (0.0)))))))
1914
1915(eval-when (:compile-toplevel :execute)
1916  (defmacro bignum-abs (nexp)
1917    (let ((n (gensym)))
1918      `(let ((,n ,nexp))
1919         (if  (bignum-minusp ,n) (negate-bignum ,n) ,n))))
1920 
1921  (defmacro fixnum-abs (nexp)
1922    (let ((n (gensym)))
1923      `(let ((,n ,nexp))
1924         (if (minusp (the fixnum ,n))
1925           (if (eq ,n target::target-most-negative-fixnum)
1926             (- ,n)
1927             (the fixnum (- (the fixnum ,n))))
1928           ,n))))
1929  )
1930 
1931
1932;;; TWO-ARG-GCD  --  Internal
1933;;;
1934;;;    Do the GCD of two integer arguments.  With fixnum arguments, we use the
1935;;; binary GCD algorithm from Knuth's seminumerical algorithms (slightly
1936;;; structurified), otherwise we call BIGNUM-GCD.  We pick off the special case
1937;;; of 0 before the dispatch so that the bignum code doesn't have to worry
1938;;; about "small bignum" zeros.
1939;;;
1940(defun gcd-2 (n1 n2)
1941  ;(declare (optimize (speed 3)(safety 0)))
1942  (cond 
1943   ((eql n1 0) (%integer-abs n2))
1944   ((eql n2 0) (%integer-abs n1))
1945   (t (number-case n1
1946        (fixnum 
1947         (number-case n2
1948          (fixnum
1949           (if (eql n1 target::target-most-negative-fixnum)
1950             (if (eql n2 target::target-most-negative-fixnum)
1951               (- target::target-most-negative-fixnum)
1952               (bignum-fixnum-gcd (- target::target-most-negative-fixnum) (abs n2)))
1953             (if (eql n2 target::target-most-negative-fixnum)
1954               (bignum-fixnum-gcd (- target::target-most-negative-fixnum) (abs n1))
1955               (locally
1956                   (declare (optimize (speed 3) (safety 0))
1957                            (fixnum n1 n2))
1958                 (if (minusp n1)(setq n1 (the fixnum (- n1))))
1959                 (if (minusp n2)(setq n2 (the fixnum (- n2))))
1960               (%fixnum-gcd n1 n2)))))
1961           (bignum (if (eql n1 target::target-most-negative-fixnum)
1962                     (%bignum-bignum-gcd n2 (- target::target-most-negative-fixnum))
1963                     (bignum-fixnum-gcd (bignum-abs n2)(fixnum-abs n1))))))
1964        (bignum
1965         (number-case n2
1966           (fixnum
1967            (if (eql n2 target::target-most-negative-fixnum)
1968              (%bignum-bignum-gcd (bignum-abs n1)(fixnum-abs n2))
1969              (bignum-fixnum-gcd (bignum-abs n1)(fixnum-abs n2))))
1970           (bignum (%bignum-bignum-gcd n1 n2))))))))
1971
1972#|
1973(defun fixnum-gcd (n1 n2)
1974  (declare (optimize (speed 3) (safety 0))
1975           (fixnum n1 n2))                   
1976  (do* ((k 0 (%i+ 1 k))
1977        (n1 n1 (%iasr 1 n1))
1978        (n2 n2 (%iasr 1 n2)))
1979       ((oddp (logior n1 n2))
1980        (do ((temp (if (oddp n1) (the fixnum (- n2)) (%iasr 1 n1))
1981                   (%iasr 1 temp)))
1982            (nil)
1983          (declare (fixnum temp))
1984          (when (oddp temp)
1985            (if (plusp temp)
1986              (setq n1 temp)
1987              (setq n2 (- temp)))
1988            (setq temp (the fixnum (- n1 n2)))
1989            (when (zerop temp)
1990              (let ((res (%ilsl k n1)))
1991                (return res))))))
1992    (declare (fixnum n1 n2 k))))
1993|#
1994
1995
1996
1997(defun %quo-1 (n)
1998  (/ 1 n))
1999
2000; x & y must both be double floats
2001(defun %hypot (x y)
2002  (with-stack-double-floats ((x**2) (y**2))
2003    (let ((res**2 x**2))
2004      (%double-float*-2! x x x**2)
2005      (%double-float*-2! y y y**2)
2006      (%double-float+-2! x**2 y**2 res**2)
2007      (fsqrt res**2))))
2008
2009
Note: See TracBrowser for help on using the repository browser.