source: trunk/source/level-0/l0-hash.lisp @ 15606

Last change on this file since 15606 was 15606, checked in by gb, 7 years ago

This is a work-in-progress; there will need to be new binaries
and similar changes for other architectures.

compiler/nx2.lisp: do late constant-folding on comparisons. (This depends

on being able to use operators for T and NIL in the backend; since backends
don't necessarily support that, check first.)

compiler/optimizers.lisp: bind temporaries for 3-arg numeric comparisons.

compiler/vinsn.lisp: do dead-code elimination at the vinsn level. Because

of the way that "aligned labels" work on x86, introduce an :align vinsn
attribute. Add/change some utilities for finding next/previous vinsn, etc.

compiler/X86/x862.lisp: Handle operators for T/NIL. Peephole optimize

things like (if (let ...)) where the LET returns a constant value and
we need to discard some words from the stack.

compiler/X86/X8632/x8632-arch.lisp:
compiler/X86/X8664/x8664-arch.lisp: Bump image version

compiler/X86/X8632/x8632-vinsns.lisp:
compiler/X86/X8664/x8664-vinsns.lisp: EMIT-ALIGNED-LABEL has :align

attribute

level-0/l0-hash.lisp: Don't assume that GC maintains weak-deletions; do

assume that it maintains count/deleted-count, so lock-based code adjusts
those slots atomically.

level-0/l0-misc.lisp: We don't want to use futexes (at least not instead

of spinlocks.)

level-0/X86/x86-misc.lisp: %ATOMIC-INCF-NODE needs to pause while spinning.

(Note that a locked ADD may be faster on x86, but wouldn't return a
meaningful value and some callers expect it to.)

level-1/l1-clos-boot.lisp: no more DESTRUCTURE-STATE.
level-1/l1-files.lisp: indentation change
level-1/l1-utils.lisp: no more DESTRUCTURE-STATE.
level-1/linux-files.lisp: UNSETENV

lib/hash.lisp: no need to %NORMALIZE-HASH-TABLE-COUNT.
lib/macros.lisp: no more DESTRUCTURE-STATE.

library/lispequ.lisp: no more DESTRUCTURE-STATE.

lisp-kernel/gc-common.c: decrement count when removing weak key from

hash vector; increment deleted-count if not lock-free.

lisp-kernel/x86-constants32.h:
lisp-kernel/x86-constants64.h: bump current, max image versions

lisp-kernel/linuxx8632/Makefile:
lisp-kernel/linuxx8664/Makefile: don't define USE_FUTEX.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 91.1 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18(in-package "CCL")
19
20;;;;;;;;;;;;;
21;;
22;; See hash.lisp for documentation
23
24
25(eval-when (:compile-toplevel :execute)
26  (require "HASHENV" "ccl:xdump;hashenv")
27  (require :number-case-macro)
28  (assert (and (not (eql (%unbound-marker) (%slot-unbound-marker)))
29               (not (eql (%unbound-marker) (%illegal-marker)))
30               (not (eql (%slot-unbound-marker) (%illegal-marker)))))
31  (define-symbol-macro deleted-hash-key-marker (%slot-unbound-marker))
32  (define-symbol-macro deleted-hash-value-marker (%slot-unbound-marker))
33  (define-symbol-macro free-hash-marker (%unbound-marker))
34  (define-symbol-macro rehashing-value-marker (%illegal-marker))
35  (declaim (inline nhash.vector-size))
36  (declaim (inline mixup-hash-code))
37  (declaim (inline hash-table-p))
38  (declaim (inline %%eqhash))
39  (declaim (inline index->vector-index vector-index->index swap))
40  (declaim (inline %already-rehashed-p %set-already-rehashed-p))
41  (declaim (inline need-use-eql))
42  (declaim (inline %needs-rehashing-p))
43  (declaim (inline compute-hash-code))
44  (declaim (inline eq-hash-find eq-hash-find-for-put))
45  (declaim (inline read-lock-hash-table write-lock-hash-table  unlock-hash-table))
46  (declaim (inline %hash-symbol))
47  (declaim (inline hash-mod))
48  (declaim (inline set-hash-key-conditional set-hash-value-conditional))
49  (declaim (inline hash-lock-free-p lock-free-gethash)))
50
51#+eq-hash-monitor
52(progn
53(defparameter eq-hash-find-calls 0)
54(defparameter eq-hash-find-probes 0)
55(defparameter eq-hash-find-for-put-calls 0)
56(defparameter eq-hash-find-for-put-probes 0)
57)
58
59
60(defun %cons-hash-table (keytrans-function compare-function vector
61                         threshold rehash-ratio rehash-size find find-new owner &optional lock-free-p)
62  (%istruct
63   'HASH-TABLE                          ; type
64   keytrans-function                    ; nhash.keytransF
65   compare-function                     ; nhash.compareF
66   nil                                  ; nhash.rehash-bits
67   vector                               ; nhash.vector
68   (if lock-free-p $nhash.lock-free 0)  ; nhash.lock
69   owner                                ; nhash.owner
70   threshold                            ; nhash.grow-threshold
71   rehash-ratio                         ; nhash.rehash-ratio
72   rehash-size                          ; nhash.rehash-size
73   0                                    ; nhash.puthash-count
74   (if lock-free-p
75     (make-lock)
76     (unless owner (make-read-write-lock))) ; nhash.exclusion-lock
77   find                                 ; nhash.find
78   find-new                             ; nhash.find-new
79   nil                                  ; nhash.read-only
80   ))
81
82(defun nhash.vector-size (vector)
83  (nhash.vector.size vector))
84
85(defun hash-mod (hash entries vector)
86  (fast-mod-3 hash entries (nhash.vector.size-reciprocal vector)))
87
88;; For lock-free hash tables
89(defun set-hash-key-conditional (index vector old new)
90  (%set-hash-table-vector-key-conditional (%i+ target::misc-data-offset
91                                               (ash (the fixnum index) target::word-shift))
92                                          vector
93                                          old
94                                          new))
95
96(defun set-hash-value-conditional (index vector old new)
97  (store-gvector-conditional (%i+ index 1) vector old new))
98
99(defun hash-lock-free-p (hash)
100  (logtest $nhash.lock-free (the fixnum (nhash.lock hash))))
101 
102;;; Is KEY something which can be EQL to something it's not EQ to ?
103;;; (e.g., is it a number or macptr ?)
104;;; This can be more general than necessary but shouldn't be less so.
105(defun need-use-eql (key)
106  (let* ((typecode (typecode key)))
107    (declare (fixnum typecode))
108    (or (= typecode target::subtag-macptr)
109        (and (< typecode (- target::nbits-in-word target::fixnumshift))
110             (logbitp (the (integer 0 (#.(- target::nbits-in-word target::fixnumshift)))
111                        typecode)
112                      (logior (ash 1 target::subtag-bignum)
113                              #-64-bit-target
114                              (ash 1 target::subtag-single-float)
115                              (ash 1 target::subtag-double-float)
116                              (ash 1 target::subtag-ratio)
117                              (ash 1 target::subtag-complex)))))))
118
119;;; Don't rehash at all, unless some key is address-based (directly or
120;;; indirectly.)
121(defun %needs-rehashing-p (vector)
122  (let* ((flags (nhash.vector.flags vector)))
123    (declare (fixnum flags))
124    (if (logbitp $nhash_track_keys_bit flags)
125      ;; GC is tracking key movement
126      (logbitp $nhash_key_moved_bit flags)
127      ;; GC is not tracking key movement
128      (if (logbitp $nhash_component_address_bit flags)
129        (not (eql (the fixnum (%get-gc-count)) (the fixnum (nhash.vector.gc-count vector))))))))
130
131(defun %set-does-not-need-rehashing (vector)
132  (let* ((flags (nhash.vector.flags vector)))
133    (declare (fixnum flags))
134    (setf (nhash.vector.gc-count vector) (%get-gc-count))
135    (when (logbitp $nhash_track_keys_bit flags)
136      (setf (nhash.vector.flags vector)
137            (logand (lognot (ash 1 $nhash_key_moved_bit)) flags)))))
138
139
140;;; Tempting though it may be to remove this, a hash table loaded from
141;;; a fasl file likely needs to be rehashed, and the MAKE-LOAD-FORM
142;;; for hash tables needs to be able to call this or something similar.
143(defun %set-needs-rehashing (hash)
144  (let* ((vector (nhash.vector hash))
145         (flags (nhash.vector.flags vector)))
146    (declare (fixnum flags))
147    (setf (nhash.vector.gc-count vector) (the fixnum (1- (the fixnum (%get-gc-count)))))
148    (when (logbitp $nhash_track_keys_bit flags)
149      (setf (nhash.vector.flags vector) (logior (ash 1 $nhash_key_moved_bit) flags)))))
150
151;;;
152;;; This is a fairly straightforward translation of the "one-at-a-time"
153;;; hash function described at:
154;;; http://www.burtleburtle.net/bob/hash/doobs.html
155;;;
156(defun mixup-hash-code (fixnum)
157  (declare (fixnum fixnum)
158           (optimize (speed 3) (safety 0)))
159  (setq fixnum (logand fixnum target::most-positive-fixnum))
160  (do* ((hash 0))
161       ((zerop fixnum)
162        (setq hash (+ hash (the fixnum (ash hash 3)))
163              hash (logxor hash (the fixnum (ash hash -11))))
164        (the fixnum (+ hash (the fixnum (ash hash 15)))))
165    (declare (fixnum hash))
166    (setq hash (+ hash (the fixnum (logand fixnum #xff)))
167          fixnum (ash fixnum -8)
168          hash (+ hash (the fixnum (ash hash 10)))
169          hash (logxor hash (the fixnum (ash hash -6))))))
170         
171(defun rotate-hash-code (fixnum)
172  (declare (fixnum fixnum))
173  (let* ((low-3 (logand 7 fixnum))
174         (but-low-3 (%ilsr 3 fixnum))
175         (low-3*64K (%ilsl 13 low-3))
176         (low-3-in-high-3 (%ilsl (- 32 3 3) low-3)))
177    (declare (fixnum low-3 but-low-3 low-3*64K low-3-in-high-3))
178    (the fixnum (+ low-3-in-high-3
179                   (the fixnum (logxor low-3*64K but-low-3))))))
180
181
182
183
184(defconstant $nhash-track-keys-mask
185  #.(- (ash 1 $nhash_track_keys_bit)))
186
187(defconstant $nhash-clear-key-bits-mask #xfffff)
188
189
190(defun %hash-symbol (sym)
191  (if sym   
192    (let* ((vector (%symptr->symvector sym))
193           (cell (%svref vector target::symbol.plist-cell))
194           (consp (consp cell)))
195      (or (if consp (%car cell) cell)
196          (let* ((pname (%svref vector target::symbol.pname-cell))
197                 (hash (mixup-hash-code (%pname-hash pname (uvsize pname)))))
198            (declare (type simple-string pname) (fixnum hash))
199            (if consp
200              (setf (%car cell) hash)
201              (setf (%svref vector target::symbol.plist-cell) hash)))))
202    +nil-hash+))
203             
204;;; Hash on address, or at least on some persistent, immutable
205;;; attribute of the key.  If all keys are fixnums or immediates (or if
206;;; that attribute exists), rehashing won't ever be necessary.
207(defun %%eqhash (key)
208  (let* ((typecode (typecode key)))
209    (if (eq typecode target::tag-fixnum)
210      (values (mixup-hash-code key) nil)
211      (if (eq typecode target::subtag-instance)
212        (values (mixup-hash-code (instance.hash key)) nil)
213        (if (symbolp key)
214          (values (%hash-symbol key) nil)
215          (let ((hash (mixup-hash-code (strip-tag-to-fixnum key))))
216            (if (immediate-p-macro key)
217              (values hash nil)
218              (values hash :key ))))))))
219
220
221#+32-bit-target
222(defun swap (num)
223  (declare (fixnum num))
224  (the fixnum (+ (the fixnum (%ilsl 16 num))(the fixnum (%ilsr 13 num)))))
225
226#+64-bit-target
227(defun swap (num)
228  (declare (fixnum num))
229  (the fixnum (+ (the fixnum (%ilsl 32 num))(the fixnum (%ilsr 29 num)))))
230
231;;; teeny bit faster when nothing to do
232(defun %%eqlhash-internal (key)
233  (number-case key
234    (fixnum (mixup-hash-code key)) ; added this
235    (double-float (%dfloat-hash key))
236    (short-float (%sfloat-hash key))
237    (bignum (%bignum-hash key))
238    (ratio (logxor (swap (%%eqlhash-internal (numerator key)))
239                   (%%eqlhash-internal (denominator key))))
240    (complex
241     (logxor (swap (%%eqlhash-internal (realpart key)))
242             (%%eqlhash-internal (imagpart key))))
243    (t (cond ((macptrp key)
244              (%macptr-hash key))
245             (t key)))))
246
247               
248
249
250;;; new function
251
252(defun %%eqlhash (key)
253  ;; if key is a macptr, float, bignum, ratio, or complex, convert it
254  ;; to a fixnum
255  (if (hashed-by-identity key)
256    (%%eqhash key)
257    (let ((primary  (%%eqlhash-internal key)))
258      (if (eq primary key)
259        (%%eqhash key)
260        (mixup-hash-code (strip-tag-to-fixnum primary))))))
261
262
263(defun %%equalhash (key)
264  (let* ((id-p (hashed-by-identity key))
265         (hash (if (and key (not id-p)) (%%eqlhash-internal key)))
266         addressp)
267    (cond ((null key) (mixup-hash-code 17))
268          #+64-bit-target
269          ((and (typep key 'single-float)
270                (zerop (the single-float key)))
271           0)
272          ((immediate-p-macro key) (mixup-hash-code (strip-tag-to-fixnum key)))
273          ((and hash (neq hash key)) hash)  ; eql stuff
274          (t (typecase key
275                (simple-string (%string-hash 0 key (length key)))
276                (string
277                 (let ((length (length key)))
278                   (multiple-value-bind (data offset) (array-data-and-offset key)
279                     (%string-hash offset data length))))
280                (bit-vector (bit-vector-hash key))
281                (cons
282                 (let ((hash 0))
283                   (do* ((i 0 (1+ i))
284                         (done nil)
285                         (list key (unless done (cdr list))))
286                        ((or done (> i 11))) ; who figured 11?
287                     (declare (fixnum i))
288                     (multiple-value-bind (h1 a1) (%%equalhash
289                                                   (if (atom list)
290                                                     (progn
291                                                       (setq done t)
292                                                       list)
293                                                     (%car list)))
294                       (when a1 (setq addressp t))
295                       ; fix the case of lists of same stuff in different order
296                       ;(setq hash (%ilogxor (fixnum-rotate h1 i) hash))
297                       (setq hash (%i+ (rotate-hash-code hash) h1))
298                       ))
299                   (values (mixup-hash-code hash) addressp)))
300                (pathname (%%equalphash key))
301                (t (%%eqlhash key)))))))
302
303(defun %string-hash-folding-case (start string len)
304  (declare (index start len)
305           (optimize (speed 3) (safety 0)))
306  (let* ((copy (make-string len)))
307    (declare (dynamic-extent copy))
308    (dotimes (i len (values (%string-hash 0 copy len)))
309      (declare (index i))
310      (setf (schar copy i)
311            (char-upcase (schar string start))
312            start (1+ start)))))
313
314(defun %hash-pathname (key)
315  (let* ((logical (istruct-typep key 'logical-pathnames))
316         (case-sensitive *case-sensitive-filesystem*)
317         (hash 0))
318    (flet ((incorporate (component)
319             (setq hash (logand target::target-most-positive-fixnum
320                                (+ hash
321                                   (if case-sensitive
322                                     (%%equalhash component)
323                                     (%%equalphash component)))))))
324      (if logical
325        (progn
326          (setq hash (%%equalphash (%logical-pathname-host key)))
327          (incorporate (%logical-pathname-version key)))
328        (incorporate (%physical-pathname-device key)))
329      (dolist (element (%pathname-directory key))
330        (incorporate element))
331      (incorporate (%pathname-name key))
332      (incorporate (%pathname-type key))
333      (mixup-hash-code hash))))
334   
335
336         
337   
338
339(defun update-hash-flags (hash vector addressp)
340  (when addressp
341    (flet ((new-flags (flags addressp)
342             (declare (fixnum flags))
343             (if (eq :key addressp)
344               ;; hash code depended on key's address
345               (if (logbitp $nhash_component_address_bit flags)
346                 flags
347                 (logior $nhash-track-keys-mask
348                         (if (logbitp $nhash_track_keys_bit flags)
349                           flags
350                           (bitclr $nhash_key_moved_bit flags))))
351               ;; hash code depended on component address
352               (bitset $nhash_component_address_bit
353                       (logand (lognot $nhash-track-keys-mask) flags)))))
354      (declare (inline new-flags))
355      (if (hash-lock-free-p hash)
356        (loop
357          (let* ((flags (nhash.vector.flags vector))
358                 (new-flags (new-flags flags addressp)))
359            (when (or (eq flags new-flags)
360                      (store-gvector-conditional nhash.vector.flags vector flags new-flags))
361              (return))))
362        (setf (nhash.vector.flags vector)
363              (new-flags (nhash.vector.flags vector) addressp))))))
364
365(defun compute-hash-code (hash key update-hash-flags &optional
366                               (vector (nhash.vector hash))) ; vectorp))
367  (let ((keytransF (nhash.keytransF hash))
368        primary addressp)
369    (if (not (fixnump keytransF))
370      ;; not EQ or EQL hash table
371      (progn
372        (multiple-value-setq (primary addressp) (funcall keytransF key))
373        (let ((immediate-p (immediate-p-macro primary)))
374          (setq primary (strip-tag-to-fixnum primary))
375          (unless immediate-p
376            (setq primary (mixup-hash-code primary))
377            (setq addressp :key))))
378      ;; EQ or EQL hash table
379      (if (and (not (eql keytransF 0))
380               (need-use-eql key))
381        ;; EQL hash table
382        (setq primary (%%eqlhash-internal key))
383        ;; EQ hash table - or something eql doesn't do
384        (multiple-value-setq (primary addressp) (%%eqhash key))))
385    (when update-hash-flags
386      (when addressp
387        (update-hash-flags hash vector addressp)))
388    (let* ((entries (nhash.vector-size vector)))
389      (declare (fixnum entries))
390      (values primary
391              (hash-mod primary entries vector)
392              entries))))
393
394(defun %already-rehashed-p (primary rehash-bits)
395  (declare (optimize (speed 3)(safety 0)))
396  (declare (type (simple-array bit (*)) rehash-bits))
397  (eql 1 (sbit rehash-bits primary)))
398
399(defun %set-already-rehashed-p (primary rehash-bits)
400  (declare (optimize (speed 3)(safety 0)))
401  (declare (type (simple-array bit (*)) rehash-bits))
402  (setf (sbit rehash-bits primary) 1))
403
404
405(defun hash-table-p (hash)
406  (istruct-typep hash 'hash-table))
407
408
409
410(defparameter *shared-hash-table-default* t
411  "Be sure that you understand the implications of changing this
412before doing so.")
413
414(defparameter *lock-free-hash-table-default* :shared
415  "If NIL, hash tables default to using the standard algorithms, with locks for shared tables.
416   If :SHARED, shared hash tables default to using the \"lock-free\" algorithm,
417   which is faster for typical access but slower for rehashing or growing the table.
418   Otherwise, all hash tables default to the lock-free algorithm")
419
420(defun make-hash-table (&key (test 'eql)
421                             (size 60)
422                             (rehash-size 1.5)
423                             (rehash-threshold .85)
424                             (hash-function nil)
425                             (weak nil)
426                             (finalizeable nil)
427                             (address-based t)  ;; Ignored
428                             (lock-free *lock-free-hash-table-default*)
429                             (shared *shared-hash-table-default*))
430  "Create and return a new hash table. The keywords are as follows:
431     :TEST -- Indicates what kind of test to use.
432     :SIZE -- A hint as to how many elements will be put in this hash
433       table.
434     :REHASH-SIZE -- Indicates how to expand the table when it fills up.
435       If an integer, add space for that many elements. If a floating
436       point number (which must be greater than 1.0), multiply the size
437       by that amount.
438     :REHASH-THRESHOLD -- Indicates how dense the table can become before
439       forcing a rehash. Can be any positive number <=1, with density
440       approaching zero as the threshold approaches 0. Density 1 means an
441       average of one entry per bucket."
442  (declare (ignore address-based)) ;; TODO: could reinterpret as "warn if becomes address-based"
443  (unless (and test (or (functionp test) (symbolp test)))
444    (report-bad-arg test '(and (not null) (or symbol function))))
445  (unless (or (functionp hash-function) (symbolp hash-function))
446    (report-bad-arg hash-function '(or symbol function)))
447  (unless (and (realp rehash-threshold) (<= 0.0 rehash-threshold) (<= rehash-threshold 1.0))
448    (report-bad-arg rehash-threshold '(real 0 1)))
449  (unless (or (fixnump rehash-size) (and (realp rehash-size) (< 1.0 rehash-size)))
450    (report-bad-arg rehash-size '(or fixnum (real 1 *))))
451  (unless (fixnump size) (report-bad-arg size 'fixnum))
452  (setq rehash-threshold (/ 1.0 (max 0.01 rehash-threshold)))
453  (let* ((default-hash-function
454             (cond ((or (eq test 'eq) (eq test #'eq)) 
455                    (setq test 0))
456                   ((or (eq test 'eql) (eq test #'eql)) 
457                    (setq test -1))
458                   ((or (eq test 'equal) (eq test #'equal))
459                    (setq test #'equal) #'%%equalhash)
460                   ((or (eq test 'equalp) (eq test #'equalp))
461                    (setq test #'equalp) #'%%equalphash)
462                   (t (setq test (require-type test 'symbol))
463                      (or hash-function 
464                          (error "non-standard test specified without hash-function")))))
465         (find-function
466          (case test
467            (0 #'eq-hash-find)
468            (-1 #'eql-hash-find)
469            (t #'general-hash-find)))
470         (find-put-function
471          (case test
472            (0 #'eq-hash-find-for-put)
473            (-1 #'eql-hash-find-for-put)
474            (t #'general-hash-find-for-put))))
475    (setq hash-function
476          (if hash-function
477            (require-type hash-function 'symbol)
478            default-hash-function))
479    (when (and weak (neq weak :value) (neq test 0))
480      (error "Only EQ hash tables can be weak."))
481    (when (and finalizeable (not weak))
482      (error "Only weak hash tables can be finalizeable."))
483    (when (and (eq lock-free :shared) (not shared))
484      (setq lock-free nil))
485    (multiple-value-bind (grow-threshold total-size)
486        (compute-hash-size (1- size) 1 rehash-threshold)
487      (let* ((flags (+ (if weak (ash 1 $nhash_weak_bit) 0)
488                       (ecase weak
489                         ((t nil :key) 0)
490                         (:value (ash 1 $nhash_weak_value_bit)))
491                       (if finalizeable (ash 1 $nhash_finalizeable_bit) 0)
492                       (if lock-free (ash 1 $nhash_keys_frozen_bit) 0)))
493             (hash (%cons-hash-table 
494                    hash-function test
495                    (%cons-nhash-vector total-size flags)
496                    grow-threshold rehash-threshold rehash-size
497                    find-function find-put-function
498                    (unless shared *current-process*)
499                    lock-free)))
500        (setf (nhash.vector.hash (nhash.vector hash)) hash)
501        hash))))
502
503(defun compute-hash-size (size rehash-size rehash-ratio)
504  (let* ((new-size size))
505    (declare (fixnum size new-size))
506    (setq new-size (max 30 (if (fixnump rehash-size)
507                             (%i+ size rehash-size)
508                             (ceiling (* size rehash-size)))))
509    (if (<= new-size size)
510      (setq new-size (1+ size)))        ; God save you if you make this happen
511   
512    (let ((vector-size (%hash-size (max (+ new-size 2) (ceiling (* new-size rehash-ratio))))))
513      ; TODO: perhaps allow more entries, based on actual size:
514      ;  (values (min (floor vector-size rehash-ratio) (%i- vector-size 2)) vector-size))
515      (values new-size vector-size)
516      )))
517
518;;;  Suggested size is a fixnum: number of pairs.  Return a fixnum >=
519;;;  that size that is relatively prime to all secondary keys.
520(defun %hash-size (suggestion)
521  (declare (fixnum suggestion))
522  (declare (optimize (speed 3)(safety 0)))
523  (if (<= suggestion #.(aref secondary-keys 7))
524    (setq suggestion (+ 2 #.(aref secondary-keys 7)))
525     (setq suggestion (logior 1 suggestion)))
526  (loop
527    (dovector (key secondary-keys (return-from %hash-size suggestion))
528      (when (eql 0 (fast-mod suggestion key))
529        (return)))
530    (incf suggestion 2)))
531
532
533(defvar *continue-from-readonly-hashtable-lock-error* t)
534
535(defun signal-read-only-hash-table-error (hash)
536  (cond ((hash-lock-free-p hash)
537         ;; We don't really do anything different if this is set, so no problem
538         (cerror "Modify it anyway"
539                 "Attempt to modify readonly hash table ~s" hash))
540        (*continue-from-readonly-hashtable-lock-error*
541         (cerror "Make the hash-table writable. DANGEROUS! This could damage your lisp if another thread is acccessing this table. CONTINUE ONLY IF YOU KNOW WHAT YOU'RE DOING!"
542                 "Hash-table ~s is readonly" hash)
543         (assert-hash-table-writeable hash)
544         (write-lock-hash-table hash))
545        (t (error "Hash-table ~s is readonly" hash))))
546
547(defun read-lock-hash-table (hash)
548  (if (nhash.read-only hash)
549    :readonly
550    (let* ((lock (nhash.exclusion-lock hash)))
551      (if lock
552        (read-lock-rwlock lock)
553        (unless (eq (nhash.owner hash) *current-process*)
554          (error "Not owner of hash table ~s" hash))))))
555
556(defun write-lock-hash-table (hash)
557  (if (nhash.read-only hash)
558    (signal-read-only-hash-table-error hash)
559    (let* ((lock (nhash.exclusion-lock hash)))
560      (if lock
561        (write-lock-rwlock lock)
562        (unless (eq (nhash.owner hash) *current-process*)
563          (error "Not owner of hash table ~s" hash))))))
564
565
566(defun unlock-hash-table (hash was-readonly)
567  (unless was-readonly
568    (let* ((lock (nhash.exclusion-lock hash)))
569      (if lock
570        (unlock-rwlock lock)))))
571
572(defun index->vector-index (index)
573  (declare (fixnum index))
574  (the fixnum (+ $nhash.vector_overhead (the fixnum (+ index index)))))
575
576(defun vector-index->index (index)
577  (declare (fixnum index))
578  (the fixnum (ash (the fixnum (- index $nhash.vector_overhead)) -1)))
579
580(defun hash-table-count (hash)
581  "Return the number of entries in the given HASH-TABLE."
582  (setq hash (require-type hash 'hash-table))
583  (when (hash-lock-free-p hash)
584    ;; We don't try to maintain a running total, so just count.
585    (return-from hash-table-count (lock-free-count-entries hash)))
586  (the fixnum (nhash.vector.count (nhash.vector hash))))
587
588(defun hash-table-rehash-size (hash)
589  "Return the rehash-size HASH-TABLE was created with."
590  (nhash.rehash-size (require-type hash 'hash-table)))
591
592(defun hash-table-rehash-threshold (hash)
593  "Return the rehash-threshold HASH-TABLE was created with."
594  (/ 1.0 (nhash.rehash-ratio (require-type hash 'hash-table))))
595
596(defun hash-table-size (hash)
597  "Return a size that can be used with MAKE-HASH-TABLE to create a hash
598   table that can hold however many entries HASH-TABLE can hold without
599   having to be grown."
600  (let* ((hash (require-type hash 'hash-table))
601         (vector (nhash.vector hash)))
602    (values (floor (nhash.vector.size vector) (nhash.rehash-ratio hash)))))
603
604(defun hash-table-test (hash)
605  "Return the test HASH-TABLE was created with."
606  (let ((f (nhash.compareF (require-type hash 'hash-table))))
607    (if (fixnump f)
608      (if (eql 0 f) 'eq 'eql)
609      (let ((name (if (symbolp f) f (function-name f))))
610        (if (memq name '(equal equalp)) name f)))))
611
612;;; sometimes you'd rather have the function than the symbol.
613(defun hash-table-test-function (hash)
614  (let ((f (nhash.compareF (require-type hash 'hash-table))))
615    (if (fixnump f)
616      (if (eql 0 f) #'eq #'eql)
617      f)))
618
619;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
620;;
621;; nearly-lock-free hash tables
622;;
623;; A modification of the lock-free hash table algorithm described by Cliff Click Jr.  in
624;; http://blogs.azulsystems.com/cliff/2007/03/a_nonblocking_h.html.
625;;
626;; The modifications have to do with the fact that our goal is just to minimize the
627;; performance impact of thread-safety, by eliminating the need for locking on every
628;; read.  I don't bother with aspects of his algorithm that aren't relevant to that goal.
629;;
630;; The main difference from Click's algorithm is that I don't try to do rehashing
631;; concurrently.  Instead, rehashing grabs a lock, so that only one thread can be
632;; rehashing at any given time, and readers/writers will block waiting for the rehashing
633;; to finish.
634;;
635;; In our implementation the following are the possible states of a hash table entry:
636;;   (where "object" means any object other than the special markers):
637;;
638;; State      Key               Value
639;; FREE       free-hash-marker  free-hash-marker
640;; INSERTING  object            free-hash-marker
641;; DELETING0  deleted-marker    free-hash-marker  ;; abandoned insert
642;; IN-USE     object            object
643;; DELETING1  object            deleted-marker
644;; DELETING2  deleted-marker    object
645;; DELETED    deleted-marker    deleted-marker
646;; REHASHING  object            rehashing-value-marker
647;; REHASHING  free-hash-marker  rehashing-value-marker
648;; REHASHING  deleted-marker    rehashing-value-marker
649;;
650;; No other states are allowed - at no point in time can a hash table entry be in any
651;; other state.   In addition, the only transitions allowed on the key slot are
652;; free-hash-marker -> object/deleted-marker -> deleted-marker.  Once a key slot
653;; is claimed, it must never change to free or another key value (even after the hash
654;; vector has been discarded after rehashing, because some process might still be
655;; looking at it).
656;; In particular, rehashing in place is not an option.  All rehashing creates a new
657;; vector and copies into it.  This means it's kinda risky to use lock-free hash
658;; tables with address-based keys, because they will thrash in low-memory situations,
659;; but we don't disallow it because a particular use might not have this problem.
660;;
661;; The following operations may take place:
662;;
663;; * gethash: find matching key - if no match, return not found.  Else fetch value,
664;;   if value is rehashing-value-marker then maybe-rehash and try again;
665;;   if value is free-hash-marker or deleted-marker, return not found, else return found value.
666;; * puthash: find matching key or FREE slot.
667;;   ** If found key, fetch value.
668;;      if value is rehashing-value-marker then maybe-rehash and try again;
669;;      else store-conditional the value -> new value, if fails try again.
670;;   ** Else have FREE slot, store-key-conditional free-hash-marker -> key,
671;;      if that succeeds, check whether key moved (invalidating the hash), if so,
672;;         back out to DELETED0 and try again,
673;;      else store-conditional free-hash-marker -> new value,
674;;      if either store fails, maybe-rehash and try again.
675;; * remhash: find matching key - if no match, done.  Else fetch value,
676;;   if value is rehashing-value-marker then maybe-rehash and try again;
677;;   if value is free-hash-marker or deleted-marker, done.
678;;   else store-conditional the value -> deleted-marker, if fails try again.
679;;    if succeeds, clobber key with deleted-marker to allow it to get gc'd.
680;; * clrhash: grab the rehash lock, then set all slots to DELETED (transitioning through either
681;;    DELETING1 or DELETING2 state).
682;; * rehash: grab a lock, estimate number of entries, make a new vector.  loop over
683;; old vector, at each entry fetch the old value with atomic swap of
684;; rehashing-value-marker.  This prevents any further state changes involving the
685;; value.  It doesn't prevent state changes involving the key, but the only ones that
686;; can happen is FREE -> INSERTING, and DELETINGn -> DELETED, all of which are
687;; equivalent from the point of view of rehashing.  Anyway, if the old value was
688;; rehashing-value-marker then bug (because we have a lock).  If the old value is
689;; free-hash-marker or deleted-marker then do nothing, else get the entry key and
690;; rehash into the new vector -- if no more room, start over.  When done, store the
691;; new vector in the hash table and release lock.
692;;
693;; * gc: for weak tables, gc may convert IN-USE states to DELETED states.
694
695
696(defun lock-free-rehash (hash)
697  ;;(break "We think we need to rehash ~s" (nhash.vector hash))
698  (with-lock-context
699    (without-interrupts ;; not re-entrant
700      (let ((lock (nhash.exclusion-lock hash)))
701        (%lock-recursive-lock-object lock)
702        ;; TODO: might also want to rehash if deleted entries are a large percentage
703        ;; of all entries, more or less.
704        (when (or (%i<= (nhash.grow-threshold hash) 0) ;; no room
705                  (%needs-rehashing-p (nhash.vector hash))) ;; or keys moved
706          (%lock-free-rehash hash))
707        (%unlock-recursive-lock-object lock)))))
708
709
710;; TODO: This is silly.  We're implementing atomic swap using store-conditional,
711;; but internally store-conditional is probably implemented using some kind of
712;; an atomic swap!!
713(defun atomic-swap-gvector (index gvector value)
714  (loop
715    (let ((old-value (%svref gvector index)))
716      (when (store-gvector-conditional index gvector old-value value)
717        (return old-value)))))
718
719;; Interrupts are disabled and caller has the hash lock on the table, blocking other
720;; threads attempting a rehash.
721;; Other threads might be reading/writing/deleting individual entries, but they
722;; will block if they see a value = rehashing-value-marker.
723;; GC may run, updating the needs-rehashing flags and deleting weak entries in both
724;; old and new vectors.
725(defun %lock-free-rehash (hash)
726  (let* ((old-vector (nhash.vector hash))
727         (inherited-flags (logand $nhash_weak_flags_mask (nhash.vector.flags old-vector)))
728         (grow-threshold (nhash.grow-threshold hash))
729         count new-vector vector-size)
730    ;; Prevent puthash from adding new entries.
731    (setf (nhash.grow-threshold hash) 0)
732    (setq count (lock-free-count-entries hash))
733    (multiple-value-setq (grow-threshold vector-size)
734      (if (%i<= grow-threshold 0) ; if ran out of room, grow, else get just enough.
735        (compute-hash-size count (nhash.rehash-size hash) (nhash.rehash-ratio hash))
736        (compute-hash-size count 1 (nhash.rehash-ratio hash))))
737    (setq new-vector (%cons-nhash-vector vector-size inherited-flags))
738    (loop ;; with full-count = grow-threshold
739          for i from $nhash.vector_overhead below (uvsize old-vector) by 2
740          do (let* ((value (atomic-swap-gvector (%i+ i 1) old-vector rehashing-value-marker))
741                    (key (%svref old-vector i)))
742               (when (eq value rehashing-value-marker) (error "Who else is doing this?"))
743               (unless (or (eq value free-hash-marker)
744                           (eq value deleted-hash-value-marker)
745                           (eq key deleted-hash-key-marker))
746                 (let* ((new-index (%growhash-probe new-vector hash key))
747                        (new-vector-index (index->vector-index new-index)))
748                   (%set-hash-table-vector-key new-vector new-vector-index key)
749                   (setf (%svref new-vector (%i+ new-vector-index 1)) value)
750                   (decf grow-threshold)
751                   (when (%i<= grow-threshold 0)
752                     (error "Bug: undeleted entries?")
753                     #+obsolete ;; we no longer undelete entries
754                     ;; Too many entries got undeleted while we were rehashing (that's the
755                     ;; only way we could end up with more than COUNT entries, as adding
756                     ;; new entries is blocked).  Grow the output vector.
757                     (multiple-value-bind (bigger-threshold bigger-vector-size)
758                         (compute-hash-size full-count (nhash.rehash-size hash) (nhash.rehash-ratio hash))
759                       (assert (> bigger-vector-size vector-size))
760                       (let ((bigger-vector (%cons-nhash-vector bigger-vector-size 0)))
761                         (%copy-gvector-to-gvector new-vector
762                                                   $nhash.vector_overhead
763                                                   bigger-vector
764                                                   $nhash.vector_overhead
765                                                   (%i- (uvsize new-vector) $nhash.vector_overhead))
766                         (setf (nhash.vector.flags bigger-vector) (nhash.vector.flags new-vector))
767                         (%lock-free-rehash-in-place hash bigger-vector)
768                         (setq grow-threshold (- bigger-threshold full-count))
769                         (setq full-count bigger-threshold)
770                         (setq new-vector bigger-vector)
771                         (setq vector-size bigger-vector-size))))))))
772    (when (%needs-rehashing-p new-vector) ;; keys moved, but at least can use the same new-vector.
773      (%lock-free-rehash-in-place hash new-vector))
774    (setf (nhash.vector.hash new-vector) hash)
775    (setf (nhash.grow-threshold hash) grow-threshold)
776    ;; At this point, another thread might decrement the threshold while they're looking at the old
777    ;; vector. That's ok, just means it will be too small and we'll rehash sooner than planned,
778    ;; no big deal.
779    (setf (nhash.vector hash) new-vector)))
780
781;; This is called on a new vector that hasn't been installed yet, so no other thread is
782;; accessing it.  However, gc might be deleting stuff from it, which is why it tests
783;; key for deleted-hash-key-marker in addition to free-hash-marker value
784(defun %lock-free-rehash-in-place (hash vector)
785  (let* ((vector-index (- $nhash.vector_overhead 2))
786         (size (nhash.vector-size vector))
787         (rehash-bits (%make-rehash-bits hash size))
788         (index -1))
789    (declare (fixnum size index vector-index))
790    (%set-does-not-need-rehashing vector)
791    (loop
792      (when (>= (incf index) size) (return))
793      (setq vector-index (+ vector-index 2))
794      (unless (%already-rehashed-p index rehash-bits)
795        (let* ((key (%svref vector vector-index)))
796          (if (or (eq key free-hash-marker) (eq key deleted-hash-key-marker))
797            (unless (eq key free-hash-marker)
798              (setf (%svref vector vector-index) free-hash-marker
799                    (%svref vector (%i+ vector-index 1)) free-hash-marker))
800            (let* ((last-index index)
801                   (value (%svref vector (%i+ vector-index 1)))
802                   (first t))
803              (loop
804                (let ((found-index (%rehash-probe rehash-bits hash key vector)))
805                  (%set-already-rehashed-p found-index rehash-bits)
806                  (when (eq last-index found-index)
807                    (return))
808                  (let* ((found-vector-index (index->vector-index found-index))
809                         (newvalue (%svref vector (the fixnum (1+ found-vector-index))))
810                         (newkey (%svref vector found-vector-index)))
811                    (declare (fixnum found-vector-index))
812                    (when first         ; or (eq last-index index) ?
813                      (setq first nil)
814                      (setf (%svref vector (the fixnum (1+ vector-index))) free-hash-marker)
815                      (setf (%svref vector vector-index) free-hash-marker))
816                    (%set-hash-table-vector-key vector found-vector-index key)
817                    (setf (%svref vector (the fixnum (1+ found-vector-index))) value)
818                    (when (or (eq newkey deleted-hash-key-marker) (eq newkey free-hash-marker))
819                      (return))
820                    (when (eq key newkey)
821                      (cerror "Delete one of the entries." "Duplicate key: ~s in ~s ~s ~s ~s ~s"
822                              key hash value newvalue index found-index)                       
823                      (return))
824                    (setq key newkey
825                          value newvalue
826                          last-index found-index))))))))))
827  t )
828
829
830(defun lock-free-gethash (key hash default)
831  (declare (optimize (speed 3) (safety 0) (debug 0)))
832  (loop
833    (let* ((vector (nhash.vector hash))
834           (vector-index (funcall (the function (nhash.find hash)) hash key)))
835      (declare (fixnum vector-index))
836      ;; Need to punt if vector changed because no way to know whether nhash.find was
837      ;; using old or new vector.
838      (when (eq vector (nhash.vector hash))
839        (cond ((eql vector-index -1)
840               (unless (%needs-rehashing-p vector)
841                 (return-from lock-free-gethash (values default nil))))
842              (t (let ((value (%svref vector (%i+ vector-index 1))))
843                   (unless (eq value rehashing-value-marker)
844                     (if (or (eq value deleted-hash-value-marker)
845                             (eq value free-hash-marker))
846                       (return-from lock-free-gethash (values default nil))
847                       (return-from lock-free-gethash (values value t)))))))))
848    ;; We're here because the table needs rehashing or it was getting rehashed while we
849    ;; were searching. Take care of it and try again.
850    (lock-free-rehash hash)))
851
852(defun lock-free-remhash (key hash)
853  (declare (optimize (speed 3) (safety 0) (debug 0)))
854  (when (nhash.read-only hash)
855    (signal-read-only-hash-table-error hash)) ;; continuable
856  (loop
857    (let* ((vector (nhash.vector hash))
858           (vector-index (funcall (the function (nhash.find hash)) hash key)))
859      (declare (fixnum vector-index))
860      ;; Need to punt if vector changed because no way to know whether nhash.find was
861      ;; using old or new vector.
862      (when (eq vector (nhash.vector hash))
863        (cond ((eql vector-index -1)
864               (unless (%needs-rehashing-p vector)
865                 (return-from lock-free-remhash nil)))
866              (t (let ((old-value (%svref vector (%i+ vector-index 1))))
867                   (unless (eq old-value rehashing-value-marker)
868                     (when (or (eq old-value deleted-hash-value-marker) ;; deleted
869                               (eq old-value free-hash-marker)) ;; or about to be added
870                       (return-from lock-free-remhash nil))
871                     (when (set-hash-value-conditional vector-index vector old-value deleted-hash-value-marker)
872                       ;; Clear the key slot so can be gc'd.
873                       (setf (%svref vector vector-index) deleted-hash-key-marker)
874                       (return-from lock-free-remhash t)))))))
875      ;; We're here because the table needs rehashing or it was getting rehashed while we
876      ;; were searching.  Take care of it and try again.
877      (lock-free-rehash hash))))
878
879;; TODO: might be better (faster, safer) to just create a new all-free vector?
880(defun lock-free-clrhash (hash)
881  (when (nhash.read-only hash)
882    (signal-read-only-hash-table-error hash)) ;;continuable
883  (with-lock-context
884    (without-interrupts
885     (let ((lock (nhash.exclusion-lock hash)))
886       (%lock-recursive-lock-object lock) ;; disallow rehashing.
887       (loop
888         with vector = (nhash.vector hash)
889         for i fixnum from (%i+ $nhash.vector_overhead 1) below (uvsize vector) by 2
890         as val = (%svref vector i)
891         unless (or (eq val free-hash-marker) (eq val deleted-hash-value-marker))
892         do (setf (%svref vector (%i- i 1)) deleted-hash-key-marker
893                  (%svref vector i) deleted-hash-value-marker))
894       (%unlock-recursive-lock-object lock))))
895  hash)
896
897(defun lock-free-puthash (key hash value)
898  (declare (optimize (speed 3) (safety 0) (debug 0)))
899  (when (or (eq value rehashing-value-marker)
900            (eq value free-hash-marker)
901            (eq value deleted-hash-value-marker))
902    (error "Illegal value ~s for storing in a hash table" value))
903  (when (nhash.read-only hash)
904    (signal-read-only-hash-table-error hash)) ;;continuable
905  (loop
906    (let* ((vector (nhash.vector hash))
907           (address (strip-tag-to-fixnum key))
908           ;; This also makes sure the vector's track_keys bit is set if key is address based (in an eq table),
909           ;; and component_address bit is set if a key component is address based (in an equal[p] table).
910           (vector-index (funcall (nhash.find-new hash) hash key)))
911      ;; Need to punt if vector changed because no way to know whether nhash.find-new was
912      ;; using old or new vector.
913      (when (eq vector (nhash.vector hash))
914        (cond ((or (eql vector-index -1)
915                   (eq (%svref vector vector-index) free-hash-marker))
916               (unless (or (%needs-rehashing-p vector)
917                           (%i<= (nhash.grow-threshold hash) 0))
918                 ;; Note if the puthash fails, grow-threshold will end up too small. This
919                 ;; just means we might rehash sooner than absolutely necessary, no real
920                 ;; harm done (the most likely cause of failing is that somebody is
921                 ;; already rehashing anyway).  DON'T try to incf it back on failure --
922                 ;; that risks grow-threshold ending up too big (e.g. if somebody rehashes
923                 ;; before the incf), which _could_ be harmful.
924                 (atomic-decf (nhash.grow-threshold hash))
925                 (when (set-hash-key-conditional vector-index vector free-hash-marker key)
926                   ;; %needs-rehashing-p is not quite enough in the track_keys case, since gc cannot
927                   ;; track this key until it's actually added to the table.  Check now.
928                   (if (and (%ilogbitp $nhash_track_keys_bit (nhash.vector.flags vector))
929                            (not (eq address (strip-tag-to-fixnum key))))
930                     (setf (%svref vector vector-index) deleted-hash-key-marker)                       ;; Back out and try again.
931                     (when (set-hash-value-conditional vector-index vector free-hash-marker value)
932                       (return-from lock-free-puthash value))))))
933              (t (let ((old-value (%svref vector (%i+ vector-index 1))))
934                   (unless (or (eq old-value rehashing-value-marker)
935                               ;; In theory, could reuse the deleted slot since we know it had this key
936                               ;; initially, but that would complicate the state machine for very little gain.
937                               (eq old-value deleted-hash-value-marker))
938                     (when (set-hash-value-conditional vector-index vector old-value value)
939                       (return-from lock-free-puthash value))))))))
940    ;; We're here because the table needs rehashing or it was getting rehashed while we
941    ;; were searching, or no room for new entry, or somebody else claimed the key from
942    ;; under us (that last case doesn't need to retry, but it's unlikely enough that
943    ;; it's not worth checking for).  Take care of it and try again.
944    (lock-free-rehash hash)))
945
946(defun lock-free-count-entries (hash)
947  ;; Other threads could be adding/removing entries while we count, some of
948  ;; which will be included in the count (i.e. will be treated as if they
949  ;; happened after counting) and some won't (i.e. will be treated as if
950  ;; they happened before counting), but not necessarily in correlation
951  ;; with their temporal relationship.
952  (loop
953    with vector = (nhash.vector hash)
954    for i fixnum from $nhash.vector_overhead below (uvsize vector) by 2
955    count (let ((value (%svref vector (%i+ i 1))))
956            (when (eq value rehashing-value-marker)
957              ;; This table is being rehashed.  Wait for it to be
958              ;; done and try again.
959              (lock-free-rehash hash)
960              (return-from lock-free-count-entries (lock-free-count-entries hash)))
961            (and (neq value free-hash-marker)
962                 (neq value deleted-hash-value-marker)))))
963
964;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
965
966
967(defun gethash (key hash &optional default)
968  "Finds the entry in HASH-TABLE whose key is KEY and returns the associated
969   value and T as multiple values, or returns DEFAULT and NIL if there is no
970   such entry. Entries can be added using SETF."
971  (unless (typep hash 'hash-table)
972    (report-bad-arg hash 'hash-table))
973  (when (or (eq key free-hash-marker)
974            (eq key deleted-hash-key-marker))
975    (return-from gethash (values default nil)))
976  (when (hash-lock-free-p hash)
977    (return-from gethash (lock-free-gethash key hash default)))
978  (let* ((value nil)
979         (gc-locked nil)
980         (readonly nil)
981         (foundp nil))
982    (with-lock-context
983      (without-interrupts
984        (setq readonly (eq (read-lock-hash-table hash) :readonly))
985        (let* ((vector (nhash.vector hash)))
986          (if (and (eq key (nhash.vector.cache-key vector))
987                   ;; Check twice: the GC might nuke the cached key/value pair
988                   (progn (setq value (nhash.vector.cache-value vector))
989                          (eq key (nhash.vector.cache-key vector))))
990            (setq foundp t)
991            (loop
992              (let* ((vector-index (funcall (nhash.find hash) hash key)))
993                (declare (fixnum vector-index))
994                (cond ((setq foundp (not (eql vector-index -1)))
995                       ;; Referencing both key and value here - and referencing
996                       ;; value first - is an attempt to compensate for the
997                       ;; possibility that the GC deletes a weak-on-key pair.
998                       (setq value (%svref vector (%i+ vector-index 1)))
999                       (when (nhash.owner hash)
1000                         (setf (nhash.vector.cache-key vector)
1001                               (%svref vector vector-index)
1002                               (nhash.vector.cache-value vector)
1003                               value
1004                               (nhash.vector.cache-idx vector)
1005                               (vector-index->index (the fixnum vector-index))))
1006                       (return))
1007                      ((%needs-rehashing-p vector)
1008                       (%lock-gc-lock)
1009                       (setq gc-locked t)
1010                       (unless readonly
1011                         (let* ((lock (nhash.exclusion-lock hash)))
1012                           (when lock (%promote-rwlock lock))))
1013                       (when (%needs-rehashing-p vector)
1014                         (%rehash hash)))
1015                      (t (return)))))))
1016        (when gc-locked (%unlock-gc-lock))
1017        (unlock-hash-table hash readonly)))
1018    (if foundp
1019      (values value t)
1020      (values default nil))))
1021
1022(defun remhash (key hash)
1023  "Remove the entry in HASH-TABLE associated with KEY. Return T if there
1024   was such an entry, or NIL if not."
1025  (unless (typep hash 'hash-table)
1026    (setq hash (require-type hash 'hash-table)))
1027  (when (hash-lock-free-p hash)
1028    (return-from remhash (lock-free-remhash key hash)))
1029  (let* ((foundp nil))
1030    (with-lock-context
1031      (without-interrupts
1032       (write-lock-hash-table hash)
1033       (%lock-gc-lock)
1034       (let* ((vector (nhash.vector hash)))
1035         (when (%needs-rehashing-p vector)
1036           (%rehash hash))
1037         (if (eq key (nhash.vector.cache-key vector))
1038           (progn
1039             (setf (nhash.vector.cache-key vector) free-hash-marker
1040                   (nhash.vector.cache-value vector) nil)
1041             (let ((vidx (index->vector-index (nhash.vector.cache-idx vector))))
1042               (setf (%svref vector vidx) deleted-hash-key-marker)
1043               (setf (%svref vector (the fixnum (1+ vidx))) nil))
1044             (atomic-incf (the fixnum (nhash.vector.deleted-count vector)))
1045             (atomic-decf (the fixnum (nhash.vector.count vector)))
1046             (setq foundp t))
1047           (let* ((vector-index (funcall (nhash.find hash) hash key)))
1048             (declare (fixnum vector-index))
1049             (unless (eql vector-index -1)
1050               ;; always clear the cache cause I'm too lazy to call the
1051               ;; comparison function and don't want to keep a possibly
1052               ;; deleted key from being GC'd
1053               (setf (nhash.vector.cache-key vector) free-hash-marker
1054                     (nhash.vector.cache-value vector) nil)
1055               ;; Update the count
1056               (atomic-incf (the fixnum (nhash.vector.deleted-count vector)))
1057               (atomic-decf (the fixnum (nhash.vector.count vector)))
1058               ;; Delete the value from the table.
1059               (setf (%svref vector vector-index) deleted-hash-key-marker
1060                     (%svref vector (the fixnum (1+ vector-index))) nil)
1061               (setq foundp t)))))
1062       ;; Return T if we deleted something
1063       (%unlock-gc-lock)
1064       (unlock-hash-table hash nil)))
1065    foundp))
1066
1067;;; what if somebody is mapping, growing, rehashing?
1068(defun clrhash (hash)
1069  "This removes all the entries from HASH-TABLE and returns the hash table
1070   itself."
1071  (unless (typep hash 'hash-table)
1072    (report-bad-arg hash 'hash-table))
1073  (when (hash-lock-free-p hash)
1074    (return-from clrhash (lock-free-clrhash hash)))
1075  (with-lock-context
1076    (without-interrupts
1077     (write-lock-hash-table hash)
1078     (let* ((vector (nhash.vector hash))
1079            (size (nhash.vector-size vector))
1080            (count (+ size size))
1081            (index $nhash.vector_overhead))
1082       (declare (fixnum size count index))
1083       (dotimes (i count)
1084         (setf (%svref vector index) free-hash-marker)
1085         (incf index))
1086       (incf (the fixnum (nhash.grow-threshold hash))
1087             (the fixnum (+ (the fixnum (nhash.vector.count vector))
1088                            (the fixnum (nhash.vector.deleted-count vector)))))
1089       (setf (nhash.vector.count vector) 0
1090             (nhash.vector.cache-key vector) free-hash-marker
1091             (nhash.vector.cache-value vector) nil
1092             (nhash.vector.finalization-alist vector) nil
1093             (nhash.vector.free-alist vector) nil
1094             (nhash.vector.deleted-count vector) 0
1095             (nhash.vector.flags vector) (logand $nhash_weak_flags_mask
1096                                                 (nhash.vector.flags vector))))
1097     (unlock-hash-table hash nil)
1098     hash)))
1099
1100
1101(defun puthash (key hash default &optional (value default))
1102  (declare (optimize (speed 3) (space 0)))
1103  (unless (typep hash 'hash-table)
1104    (report-bad-arg hash 'hash-table))
1105  (when (or (eq key free-hash-marker)
1106            (eq key deleted-hash-key-marker))
1107    (error "Can't use ~s as a hash-table key" key))
1108  (when (hash-lock-free-p hash)
1109    (return-from puthash (lock-free-puthash key hash value)))
1110  (with-lock-context
1111    (without-interrupts
1112     (block protected
1113       (tagbody
1114          (write-lock-hash-table hash)
1115        AGAIN
1116          (%lock-gc-lock)
1117          (let ((vector (nhash.vector hash)))
1118            (when (%needs-rehashing-p vector)
1119              (%rehash hash))
1120            (when (eq key (nhash.vector.cache-key vector))
1121              (let* ((idx (nhash.vector.cache-idx vector)))
1122                (declare (fixnum idx))
1123                (setf (%svref vector (the fixnum (1+ (the fixnum (index->vector-index idx)))))
1124                      value)
1125                (setf (nhash.vector.cache-value vector) value)
1126                (return-from protected)))               
1127            (let* ((vector-index (funcall (nhash.find-new hash) hash key))
1128                   (old-value (%svref vector vector-index)))
1129              (declare (fixnum vector-index))
1130
1131              (cond ((eq old-value deleted-hash-key-marker)
1132                     (%set-hash-table-vector-key vector vector-index key)
1133                     (setf (%svref vector (the fixnum (1+ vector-index))) value)
1134                     (atomic-incf (nhash.vector.count vector))
1135                     ;; Adjust deleted-count
1136                     (atomic-decf (nhash.vector.deleted-count vector)))
1137                    ((eq old-value free-hash-marker)
1138                     (when (eql 0 (nhash.grow-threshold hash))
1139                       (%unlock-gc-lock)
1140                       (%grow-hash-table hash)
1141                       (go AGAIN))
1142                     (%set-hash-table-vector-key vector vector-index key)
1143                     (setf (%svref vector (the fixnum (1+ vector-index))) value)
1144                     (decf (the fixnum (nhash.grow-threshold hash)))
1145                     (atomic-incf (the fixnum (nhash.vector.count vector))))
1146                    (t
1147                     ;; Key was already there, update value.
1148                     (setf (%svref vector (the fixnum (1+ vector-index))) value)))
1149              (setf (nhash.vector.cache-idx vector) (vector-index->index vector-index)
1150                    (nhash.vector.cache-key vector) key
1151                    (nhash.vector.cache-value vector) value)))))
1152     (%unlock-gc-lock)
1153     (unlock-hash-table hash nil)))
1154  value)
1155
1156
1157(defun count-entries (hash)
1158  (if (hash-lock-free-p hash)
1159    (lock-free-count-entries hash)
1160    (let* ((vector (nhash.vector hash))
1161           (size (uvsize vector))
1162           (idx $nhash.vector_overhead)
1163           (count 0))
1164      (loop
1165        (when (neq (%svref vector idx) free-hash-marker)
1166          (incf count))
1167        (when (>= (setq idx (+ idx 2)) size)
1168          (return count))))))
1169
1170(defun grow-hash-table (hash)
1171  (unless (typep hash 'hash-table)
1172    (setq hash (require-type hash 'hash-table)))
1173  (%grow-hash-table hash))
1174
1175(defun %grow-hash-table-in-place-p (hash)
1176  ;; Arbitrarily: if the number of deleted entries is > half
1177  ;; the number of used entries, do an in-place rehash.
1178  (let* ((vec (nhash.vector hash)))
1179    (> (the fixnum (nhash.vector.deleted-count vec))
1180       (the fixnum (ash (the fixnum (nhash.vector.count vec)) -1)))))
1181           
1182
1183;;; Interrupts are disabled, and the caller has an exclusive
1184;;; lock on the hash table.
1185(defun %grow-hash-table (hash)
1186  (block grow-hash-table
1187    (let* ((old-vector (nhash.vector hash))
1188           (old-size (nhash.vector.count old-vector))
1189           (old-total-size (nhash.vector.size old-vector))
1190           (flags 0)
1191           (flags-sans-weak 0)
1192           (weak-flags nil))
1193      (declare (fixnum old-total-size flags flags-sans-weak))
1194      (when (%grow-hash-table-in-place-p hash)
1195        ;; There are enough deleted entries. Rehash to get rid of them
1196        (%rehash hash)
1197        (return-from grow-hash-table))
1198      (multiple-value-bind (size total-size)
1199                           (compute-hash-size 
1200                            old-size (nhash.rehash-size hash) (nhash.rehash-ratio hash))
1201        (unless (eql 0 (nhash.grow-threshold hash))       ; maybe it's done already - shouldnt happen               
1202          (return-from grow-hash-table ))
1203        (progn
1204          (unwind-protect
1205            (let ((gc-count (%get-gc-count))
1206                  vector)
1207              (setq flags (nhash.vector.flags old-vector)
1208                    flags-sans-weak (logand flags (logxor -1 $nhash_weak_flags_mask))
1209                    weak-flags (logand flags $nhash_weak_flags_mask))
1210              (setf (nhash.vector.flags old-vector) flags-sans-weak)      ; disable GC weak stuff
1211              (when (%grow-hash-table-in-place-p hash)
1212                (setf (nhash.vector.flags old-vector) flags)
1213                (setq weak-flags nil)
1214                (return-from grow-hash-table (%rehash hash)))
1215              (setq vector (%cons-nhash-vector total-size 0))
1216              (do* ((index 0 (1+ index))
1217                    (vector-index (index->vector-index 0) (+ vector-index 2)))
1218                   ((>= index old-total-size))
1219                (declare (fixnum index vector-index))
1220               
1221                 (let ((key (%svref old-vector vector-index)))
1222                   (unless (or (eq key free-hash-marker)
1223                               (eq key deleted-hash-key-marker))
1224                     (let* ((new-index (%growhash-probe vector hash key))
1225                            (new-vector-index (index->vector-index new-index)))
1226                       (setf (%svref vector new-vector-index) key)
1227                       (setf (%svref vector (the fixnum (1+ new-vector-index)))
1228                             (%svref old-vector (the fixnum (1+ vector-index))))))))
1229              (progn
1230               (setf (nhash.vector.finalization-alist vector)
1231                     (nhash.vector.finalization-alist old-vector)
1232                     (nhash.vector.free-alist vector)
1233                     (nhash.vector.free-alist old-vector)
1234                     (nhash.vector.count vector) old-size
1235                     (nhash.vector.flags vector)
1236                     (logior (the fixnum weak-flags)
1237                             (the fixnum (nhash.vector.flags vector))))
1238               (setf (nhash.rehash-bits hash) nil
1239                     (nhash.vector hash) vector
1240                     (nhash.vector.hash vector) hash
1241                     (nhash.vector.cache-key vector) free-hash-marker
1242                     (nhash.vector.cache-value vector) nil
1243                     (nhash.vector.gc-count vector) gc-count
1244                     (nhash.grow-threshold hash) (- size old-size))
1245               (setq weak-flags nil)       ; tell clean-up form we finished the loop
1246               ;; If the old vector's in some static heap, zero it
1247               ;; so that less garbage is retained.
1248               (%init-misc 0 old-vector)))
1249            (when weak-flags
1250              (setf (nhash.vector.flags old-vector)
1251                    (logior (the fixnum weak-flags)
1252                            (the fixnum (nhash.vector.flags old-vector)))))))))))
1253
1254
1255
1256(defun general-hash-find (hash key)
1257  (%hash-probe hash key nil))
1258
1259(defun general-hash-find-for-put (hash key)
1260  (%hash-probe hash key (if (hash-lock-free-p hash) :free :reuse)))
1261
1262;;; returns a single value:
1263;;;   index - the index in the vector for key (where it was or where
1264;;;           to insert if the current key at that index is deleted-hash-key-marker
1265;;;           or free-hash-marker)
1266
1267
1268
1269(defun %hash-probe (hash key for-put-p)
1270  (declare (optimize (speed 3) (space 0)))
1271  (multiple-value-bind (hash-code index entries)
1272                       (compute-hash-code hash key for-put-p)
1273    (locally (declare (fixnum hash-code index entries))
1274      (let* ((compareF (nhash.compareF hash))
1275             (vector (nhash.vector hash))
1276             (vector-index 0)
1277             table-key
1278             (first-deleted-index nil))
1279        (declare (fixnum vector-index))
1280        (macrolet ((return-it (form)
1281                     `(return-from %hash-probe ,form)))
1282          (macrolet ((test-it (predicate)
1283                       (unless (listp predicate) (setq predicate (list predicate)))
1284                       `(progn
1285                          (setq vector-index (index->vector-index index)
1286                                table-key (%svref vector vector-index))
1287                          (cond ((eq table-key free-hash-marker)
1288                                 (return-it (if for-put-p
1289                                              (or first-deleted-index
1290                                                  vector-index)
1291                                              -1)))
1292                                ((eq table-key deleted-hash-key-marker)
1293                                 (when (and (eq for-put-p :reuse)
1294                                            (null first-deleted-index))
1295                                   (setq first-deleted-index vector-index)))
1296                                ((,@predicate key table-key)
1297                                 (return-it vector-index))))))
1298            (macrolet ((do-it (predicate)
1299                         `(progn
1300                            (test-it ,predicate)
1301                            ; First probe failed. Iterate on secondary key
1302                            (let ((initial-index index)
1303                                  (secondary-hash (%svref secondary-keys (logand 7 hash-code)))
1304                                  (DEBUG-COUNT 0))
1305                              (declare (fixnum secondary-hash initial-index))
1306                              (loop
1307                                (INCF DEBUG-COUNT)
1308                                (incf index secondary-hash)
1309                                (when (>= index entries)
1310                                  (decf index entries))
1311                                (when (eql index initial-index)
1312                                  (return-it (if for-put-p
1313                                               (or first-deleted-index
1314                                                   #+NOT-SO-HELPFUL (error "Bug: no room in table")
1315                                                   (bug (format nil "No room in table after ~s tests, ~%initial ~s index ~s entries ~s for-put-p ~s"
1316                                                                DEBUG-COUNT initial-index index entries for-put-p))
1317                                                   )
1318                                               -1)))
1319                                (test-it ,predicate))))))
1320              (if (fixnump comparef)
1321                ;; EQ or EQL hash table
1322                (if (or (eql 0 comparef)
1323                        (immediate-p-macro key)
1324                        (not (need-use-eql key)))
1325                  ;; EQ hash table or EQL == EQ for KEY
1326                  (do-it eq)
1327                  (do-it eql))
1328                ;; general compare function
1329                (do-it (funcall comparef))))))))))
1330
1331(defun eq-hash-find (hash key)
1332  (declare (optimize (speed 3) (safety 0)))
1333  #+eq-hash-monitor (progn
1334                      (incf eq-hash-find-calls)
1335                      (incf eq-hash-find-probes))
1336  (let* ((vector (nhash.vector hash))
1337         (hash-code
1338          (let* ((typecode (typecode key)))
1339            (if (eq typecode target::tag-fixnum)
1340              (mixup-hash-code key)
1341              (if (eq typecode target::subtag-instance)
1342                (mixup-hash-code (instance.hash key))
1343                (if (symbolp key)
1344                  (%hash-symbol key)
1345                  (mixup-hash-code (strip-tag-to-fixnum key)))))))
1346         (entries (nhash.vector-size vector))
1347         (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1348         (table-key (%svref vector vector-index)))
1349    (declare (fixnum hash-code  entries vector-index))
1350    (if (eq table-key key)
1351      vector-index
1352      (if (eq table-key free-hash-marker)
1353        -1
1354        (let* ((secondary-hash (%svref secondary-keys-*-2
1355                                       (logand 7 hash-code)))
1356               (initial-index vector-index)             
1357               (count (+ entries entries))
1358               (length (+ count $nhash.vector_overhead)))
1359          (declare (fixnum secondary-hash initial-index count length))
1360          (loop
1361            #+eq-hash-monitor (incf eq-hash-find-probes)
1362            (incf vector-index secondary-hash)
1363            (when (>= vector-index length)
1364              (decf vector-index count))
1365            (setq table-key (%svref vector vector-index))
1366            (when (= vector-index initial-index)
1367              (return -1))
1368            (if (eq table-key key)
1369              (return vector-index)
1370              (when (eq table-key free-hash-marker)
1371                (return -1)))))))))
1372
1373;;; As above, but note whether the key is in some way address-based
1374;;; and update the hash-vector's flags word if so.
1375;;; This only needs to be done by PUTHASH, and it only really needs
1376;;; to be done if we're adding a new key.
1377(defun eq-hash-find-for-put (hash key)
1378  (declare (optimize (speed 3) (safety 0)))
1379  #+eq-hash-monitor (progn
1380                      (incf eq-hash-find-for-put-calls)
1381                      (incf eq-hash-find-for-put-probes))
1382  (let* ((vector (nhash.vector hash))
1383         (hash-code
1384          (let* ((typecode (typecode key)))
1385            (if (eq typecode target::tag-fixnum)
1386              (mixup-hash-code key)
1387              (if (eq typecode target::subtag-instance)
1388                (mixup-hash-code (instance.hash key))
1389                (if (symbolp key)
1390                  (%hash-symbol key)
1391                  (progn
1392                    (unless (immediate-p-macro key)
1393                      (update-hash-flags hash vector :key))
1394                    (mixup-hash-code (strip-tag-to-fixnum key))))))))
1395         (entries (nhash.vector-size vector))
1396         (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1397         (table-key (%svref vector vector-index))
1398         (reuse (not (hash-lock-free-p hash))))
1399    (declare (fixnum hash-code vector-index))
1400    (if (or (eq key table-key)
1401            (eq table-key free-hash-marker))
1402      vector-index
1403      (let* ((secondary-hash (%svref secondary-keys-*-2
1404                                     (logand 7 hash-code)))
1405             (initial-index vector-index)             
1406             (first-deleted-index (and reuse
1407                                       (eq table-key deleted-hash-key-marker)
1408                                       vector-index))
1409             (count (+ entries entries))
1410             (length (+ count $nhash.vector_overhead)))
1411        (declare (fixnum secondary-hash initial-index count length))
1412        (loop
1413          #+eq-hash-monitor (incf eq-hash-find-for-put-probes)
1414          (incf vector-index secondary-hash)
1415          (when (>= vector-index length)
1416            (decf vector-index count))
1417          (setq table-key (%svref vector vector-index))
1418          (when (= vector-index initial-index)
1419            (return (or first-deleted-index
1420                        (error "Bug: no room in table"))))
1421          (if (eq table-key key)
1422            (return vector-index)
1423            (if (eq table-key free-hash-marker)
1424              (return (or first-deleted-index vector-index))
1425              (if (and reuse
1426                       (null first-deleted-index)
1427                       (eq table-key deleted-hash-key-marker))
1428                (setq first-deleted-index vector-index)))))))))
1429
1430(defun eql-hash-find (hash key)
1431  (declare (optimize (speed 3) (safety 0)))
1432  (if (need-use-eql key)
1433    (let* ((vector (nhash.vector hash))
1434           (hash-code (%%eqlhash-internal key))
1435           (entries (nhash.vector-size vector))
1436           (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1437           (table-key (%svref vector vector-index)))
1438      (declare (fixnum hash-code entries vector-index))
1439      (if (eql key table-key)
1440        vector-index
1441        (if (eq table-key free-hash-marker)
1442          -1
1443          (let* ((secondary-hash (%svref secondary-keys-*-2
1444                                         (logand 7 hash-code)))
1445                 (initial-index vector-index)
1446                 (count (+ entries entries))
1447                 (length (+ count $nhash.vector_overhead)))
1448            (declare (fixnum secondary-hash initial-index count length))
1449            (loop
1450              (incf vector-index secondary-hash)
1451              (when (>= vector-index length)
1452                (decf vector-index count))
1453              (setq table-key (%svref vector vector-index))
1454              (when (= vector-index initial-index)
1455                (return -1))
1456              (if (eql table-key key)
1457                (return vector-index)
1458                (when (eq table-key free-hash-marker)
1459                  (return -1))))))))
1460    (eq-hash-find hash key)))
1461
1462(defun eql-hash-find-for-put (hash key)
1463  (declare (optimize (speed 3) (safety 0)))
1464  (if (need-use-eql key)
1465    (let* ((vector (nhash.vector hash))
1466           (hash-code (%%eqlhash-internal key))
1467           (entries (nhash.vector-size vector))
1468           (vector-index (index->vector-index (hash-mod hash-code entries vector)))
1469           (table-key (%svref vector vector-index))
1470           (reuse (not (hash-lock-free-p hash))))
1471      (declare (fixnum hash-code entries vector-index))
1472      (if (or (eql key table-key)
1473              (eq table-key free-hash-marker))
1474        vector-index
1475        (let* ((secondary-hash (%svref secondary-keys-*-2
1476                                       (logand 7 hash-code)))
1477               (initial-index vector-index)
1478               (first-deleted-index (and reuse
1479                                         (eq table-key deleted-hash-key-marker)
1480                                         vector-index))
1481               (count (+ entries entries))
1482               (length (+ count $nhash.vector_overhead)))
1483          (declare (fixnum secondary-hash initial-index count length))
1484          (loop
1485            (incf vector-index secondary-hash)
1486            (when (>= vector-index length)
1487              (decf vector-index count))
1488            (setq table-key (%svref vector vector-index))
1489            (when (= vector-index initial-index)
1490              (return (or first-deleted-index
1491                          (error "Bug: no room in table"))))
1492            (if (eql table-key key)
1493              (return vector-index)
1494              (if (eq table-key free-hash-marker)
1495                (return (or first-deleted-index vector-index))
1496                (if (and reuse
1497                         (null first-deleted-index)
1498                         (eq table-key deleted-hash-key-marker))
1499                  (setq first-deleted-index vector-index))))))))
1500    (eq-hash-find-for-put hash key)))
1501
1502(defun %make-rehash-bits (hash &optional (size (nhash.vector-size (nhash.vector hash))))
1503  (declare (fixnum size))
1504  (let ((rehash-bits (nhash.rehash-bits hash)))
1505    (unless (and rehash-bits
1506                 (>= (uvsize rehash-bits) size))
1507      (return-from %make-rehash-bits
1508        (setf (nhash.rehash-bits hash) (make-array size :element-type 'bit :initial-element 0))))
1509    (fill (the simple-bit-vector rehash-bits) 0)))
1510
1511;;; Rehash.  Caller should have exclusive access to the hash table
1512;;; and have disabled interrupts.
1513(defun %rehash (hash)
1514  (when (hash-lock-free-p hash)
1515    (error "How did we get here?"))
1516  (let* ((vector (nhash.vector hash))
1517         (flags (nhash.vector.flags vector))
1518         (vector-index (- $nhash.vector_overhead 2))
1519         (size (nhash.vector-size vector))
1520         (rehash-bits (%make-rehash-bits hash size))
1521         (index -1))
1522    (declare (fixnum size index vector-index))
1523    (setf (nhash.vector.flags vector)
1524          (logand flags $nhash-clear-key-bits-mask))
1525    (setf (nhash.vector.cache-key vector) free-hash-marker
1526          (nhash.vector.cache-value vector) nil)
1527    (%set-does-not-need-rehashing vector)
1528    (loop
1529      (when (>= (incf index) size) (return))
1530      (setq vector-index (+ vector-index 2))
1531      (unless (%already-rehashed-p index rehash-bits)
1532        (let* ((key (%svref vector vector-index))
1533               (deleted (eq key deleted-hash-key-marker)))
1534          (unless
1535            (when (or deleted (eq key free-hash-marker))
1536              (if deleted  ; one less deleted entry
1537                (progn
1538                  (atomic-decf  (nhash.vector.deleted-count vector))
1539                  (incf (nhash.grow-threshold hash))
1540                  ;; Change deleted to free
1541                  (setf (%svref vector vector-index) free-hash-marker)))
1542              t)
1543            (let* ((last-index index)
1544                   (value (%svref vector (the fixnum (1+ vector-index))))
1545                   (first t))
1546                (loop
1547                  (let ((vector (nhash.vector hash))
1548                        (found-index (%rehash-probe rehash-bits hash key)))
1549                    (%set-already-rehashed-p found-index rehash-bits)
1550                    (if (eq last-index found-index)
1551                      (return)
1552                      (let* ((found-vector-index (index->vector-index found-index))
1553                             (newkey (%svref vector found-vector-index))
1554                             (newvalue (%svref vector (the fixnum (1+ found-vector-index)))))
1555                        (declare (fixnum found-vector-index))
1556                        (when first ; or (eq last-index index) ?
1557                          (setq first nil)
1558                          (setf (%svref vector vector-index) free-hash-marker)
1559                          (setf (%svref vector (the fixnum (1+ vector-index))) free-hash-marker))
1560                        (%set-hash-table-vector-key vector found-vector-index key)
1561                        (setf (%svref vector (the fixnum (1+ found-vector-index))) value)                       
1562                        (when (or (eq newkey free-hash-marker)
1563                                  (setq deleted (eq newkey deleted-hash-key-marker)))
1564                          (when deleted
1565                            (atomic-decf (nhash.vector.deleted-count vector))
1566                            (incf (nhash.grow-threshold hash)))
1567                          (return))
1568                        (when (eq key newkey)
1569                          (cerror "Delete one of the entries." "Duplicate key: ~s in ~s ~s ~s ~s ~s"
1570                                  key hash value newvalue index found-index)                       
1571                          (atomic-decf (nhash.vector.count vector))
1572                          (incf (nhash.grow-threshold hash))
1573                          (return))
1574                        (setq key newkey
1575                              value newvalue
1576                              last-index found-index)))))))))))
1577    t )
1578
1579;;; Hash to an index that is not set in rehash-bits
1580 
1581(defun %rehash-probe (rehash-bits hash key &optional (vector (nhash.vector hash)))
1582  (declare (optimize (speed 3)(safety 0))) 
1583  (multiple-value-bind (hash-code index entries)(compute-hash-code hash key t vector)
1584    (declare (fixnum hash-code index entries))
1585    (when (null hash-code)(cerror "nuts" "Nuts"))
1586    (let* ((vector-index (index->vector-index index)))
1587      (if (or (not (%already-rehashed-p index rehash-bits))
1588              (eq key (%svref vector vector-index)))
1589        (return-from %rehash-probe index)
1590        (let ((second (%svref secondary-keys (%ilogand 7 hash-code))))
1591          (declare (fixnum second))
1592          (loop
1593            (setq index (+ index second))
1594            (when (>= index entries)
1595              (setq index (- index entries)))
1596            (when (or (not (%already-rehashed-p index rehash-bits))
1597                      (eq key (%svref vector (index->vector-index index))))
1598              (return-from %rehash-probe index))))))))
1599
1600;;; Returns one value: the index of the entry in the vector
1601;;; Since we're growing, we don't need to compare and can't find a key that's
1602;;; already there.
1603(defun %growhash-probe (vector hash key)
1604  (declare (optimize (speed 3)(safety 0)))
1605  (multiple-value-bind (hash-code index entries)(compute-hash-code hash key t vector)
1606    (declare (fixnum hash-code index entries))
1607    (let* ((vector-index (index->vector-index  index))
1608           (vector-key nil))
1609      (declare (fixnum vector-index))
1610      (if (or (eq free-hash-marker
1611                  (setq vector-key (%svref vector vector-index)))
1612              (eq deleted-hash-key-marker vector-key))
1613        (return-from %growhash-probe index)
1614        (let ((second (%svref secondary-keys (%ilogand 7 hash-code))))
1615          (declare (fixnum second))
1616          (loop
1617            (setq index (+ index second))
1618            (when (>= index entries)
1619              (setq index (- index entries)))
1620            (when (or (eq free-hash-marker
1621                          (setq vector-key (%svref vector (index->vector-index index))))
1622                      (eq deleted-hash-key-marker vector-key))
1623              (return-from %growhash-probe index))))))))
1624
1625;;;;;;;;;;;;;
1626;;
1627;; Mapping functions are in "ccl:lib;hash"
1628;;
1629
1630
1631
1632;;;;;;;;;;;;;
1633;;
1634;; Hashing functions
1635;; EQ & the EQ part of EQL are done in-line.
1636;;
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646;;; so whats so special about bit vectors as opposed to any other vectors of bytes
1647;;; For starters, it's guaranteed that they exist in the implementation; that may
1648;;; not be true of other immediate vector types.
1649(defun bit-vector-hash (bv)
1650  (declare (optimize (speed 3)(safety 0)))
1651  (let ((length (length bv)))
1652    (declare (fixnum length)) ;will this always be true? it's true of all vectors.
1653    (multiple-value-bind (data offset) (array-data-and-offset bv)
1654      (declare (type simple-bit-vector data) (fixnum offset))
1655      (let* ((hash 0)
1656             (limit (+ length offset))
1657             (nbytes (ash (the fixnum (+ length 7)) -3)))
1658        (declare (fixnum hash limit nbytes))
1659        (dotimes (i nbytes (mixup-hash-code hash))
1660          (let* ((w 0))
1661            (declare (fixnum w))
1662            (dotimes (j 8 (setq hash (+ (the fixnum (ash hash -3))  w)))
1663              (setq w (the fixnum
1664                        (logxor
1665                         (the fixnum
1666                           (ash (if (< offset limit) 
1667                                  (the fixnum (sbit data offset))
1668                                  0)
1669                                (the fixnum j)))
1670                         w)))
1671              (incf offset))))))))
1672
1673#|
1674(defun bit-vector-hash (bv)
1675  (declare (optimize (speed 3)(safety 0)))
1676  (let ((length (length bv)))
1677    (declare (fixnum length))
1678    (let* ((all (+ length 15))
1679           (nwds (ash all -4))
1680           (rem (logand all 15))
1681           (hash 0)
1682           (mask (ash (the fixnum (1- (the fixnum (expt 2 rem))))(the fixnum(- 16 rem)))))
1683      (declare (fixnum all nwds rem hash mask))
1684      (multiple-value-bind (data offset)
1685                           (array-data-and-offset bv)
1686        (declare (fixnum offset))
1687        (locally (declare (type (simple-array (unsigned-byte 16) (*)) data))
1688          (dotimes (i nwds)
1689            (setq hash (%i+ hash (aref data (the fixnum (+ i offset))))))
1690          (when (neq 0 mask)           
1691            (setq hash (%i+ hash (%ilogand mask (aref data (the fixnum (+ offset nwds)))))))
1692          (mixup-hash-code hash))))))
1693|#
1694
1695
1696;;; Same as %%equalhash, but different:
1697;;;  1) Real numbers are hashed as if they were double-floats.  The real components of complex numbers
1698;;;     are hashed as double-floats and XORed together.
1699;;;  2) Characters and strings are hashed in a case-insensitive manner.
1700;;;  3) Hash tables are hashed based on their size and type.
1701;;;  4) Structures and CL array types are hashed based on their content.
1702
1703
1704;;; check fixnum befor immediate-p. call %%eqlhash
1705
1706(defun %%equalphash (key)
1707  (cond ((or (fixnump key)(short-float-p key))
1708         (%dfloat-hash (float key 1.0d0))) 
1709        ((immediate-p-macro key)
1710         (mixup-hash-code (strip-tag-to-fixnum (if (characterp key)(char-upcase key) key))))
1711        ((bignump key)
1712         (if (<= most-negative-double-float key most-positive-double-float)
1713           (%dfloat-hash (float key 1.0d0))  ; with-stack-double-floats
1714           (%%eqlhash-internal key)))
1715        ((double-float-p key)
1716         (%dfloat-hash key))
1717        ((ratiop key)
1718         (%ilogxor (%%equalphash (numerator key)) (%%equalphash (denominator key))))
1719        ((complexp key)
1720         (%ilogxor (%%equalphash (realpart key)) (%%equalphash (imagpart key))))
1721        ((hash-table-p key)
1722         (equalphash-hash-table key))
1723        ((typep key 'simple-string)
1724         (%string-hash-folding-case 0 key (length key)))
1725        ((typep key 'string)
1726         (multiple-value-bind (data offset) (array-data-and-offset key)
1727           (%string-hash-folding-case offset data (length key))))
1728        ((pathnamep key)
1729         (%hash-pathname key))
1730        ((or (istructp key)
1731             (structurep key))  ; was (gvectorp key)
1732         (%%equalphash-structure 11 key))
1733        ((or (arrayp key)) ;(uvectorp key)) ;??
1734         (%%equalphash-array 11 key))
1735        ((consp key)
1736         (%%equalphash-aux 11 key))
1737        (t (%%eqlhash key))))
1738
1739
1740(defun equalphash-hash-table (hash-table)
1741  (let ((hash (%%equalhash "HASH-TABLE"))
1742        addressp)
1743    (declare (fixnum hash))
1744    (incf hash (the fixnum (%%eqhash (hash-table-count hash-table))))
1745    (multiple-value-bind (h ap) (%%eqhash (nhash.comparef hash-table))
1746      (declare (fixnum h))
1747      (incf hash h)
1748      (if ap (setq addressp t)))
1749    (multiple-value-bind (h ap) (%%eqhash (nhash.keytransF hash-table))
1750      (declare (fixnum h))
1751      (incf hash h)
1752      (if ap (setq addressp t)))
1753    (values hash addressp)))
1754
1755(defun %%equalphash-structure (limit key)
1756  (let* ((size (uvsize key))
1757         (hash (mixup-hash-code size))
1758         addressp)
1759    (declare (fixnum limit size hash))
1760    (dotimes (i size)
1761      (multiple-value-bind (h ap) (%%equalphash-aux limit (%svref key i))
1762        (declare (fixnum h))
1763        (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash)) h)))
1764        (if ap (setq addressp t)))
1765      (when (<= (decf limit) 0)
1766        (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash))
1767                                  (the fixnum (mixup-hash-code 11)))))
1768        (return)))
1769    (values hash addressp)))
1770
1771(defun %%equalphash-array (limit key)
1772  (multiple-value-bind (array offset) (array-data-and-offset key)
1773    (let* ((rank (array-rank key))
1774           (vectorp (eql rank 1))
1775           (size (if vectorp (length key) (array-total-size key)))
1776           (hash (mixup-hash-code rank))
1777           addressp)
1778      (declare (fixnum size hash limit rank))
1779      (if vectorp
1780        (setq hash
1781              (the fixnum
1782                   (+ (the fixnum (rotate-hash-code hash))
1783                      (the fixnum (mixup-hash-code size)))))
1784        (dotimes (i rank)
1785          (declare (fixnum i))
1786          (setq hash
1787                (the fixnum 
1788                     (+ (the fixnum (rotate-hash-code hash))
1789                        (the fixnum
1790                             (mixup-hash-code (array-dimension key i))))))))     
1791      (dotimes (i size)
1792        (declare (fixnum i))
1793        (multiple-value-bind (h ap) (%%equalphash-aux limit (uvref array offset))
1794          (declare (fixnum h))
1795          (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash)) h)))
1796          (if ap (setq addressp t)))
1797        (when (<= (decf limit) 0)
1798          (setq hash (the fixnum (+ (the fixnum (rotate-hash-code hash))
1799                                    (the fixnum (mixup-hash-code 11)))))
1800          (return))
1801        (incf offset))
1802      (values hash addressp))))
1803
1804(defun %%equalphash-aux (limit key)
1805  (if (<= limit 0) 
1806    (mixup-hash-code 11)
1807    (if (null key) (mixup-hash-code 17)
1808        (cond ((consp key)
1809               (let ((hash 0)
1810                     address-p)
1811                 (do ((l limit (1- l)))
1812                     ((eq l 0)(values hash address-p))
1813                   (multiple-value-bind (ahash ap)
1814                                        (%%equalphash-aux l (if (consp key)(car key) key))
1815                     (setq hash (mixup-hash-code (logxor ahash hash)))
1816                     (if ap (setq address-p t)))
1817                   (when (not (consp key))
1818                     (return (values hash address-p)))
1819                   (setq key (cdr key)))))
1820              ((typep key 'hash-table)
1821               (equalphash-hash-table key))
1822              ; what are the dudes called that contain bits? they are uvectors but not gvectors?
1823              ; ivectors.
1824              ((or (istructp key)
1825                   (structurep key))    ;was (gvectorp key)
1826               (%%equalphash-structure limit key))
1827              ((or (arrayp key))  ; (uvectorp key))
1828               (%%equalphash-array limit key))
1829              (t (%%equalphash key))))))
1830
1831(defun alist-hash-table (alist &rest hash-table-args)
1832  (declare (dynamic-extent hash-table-args))
1833  (if (typep alist 'hash-table)
1834    alist
1835    (let ((hash-table (apply #'make-hash-table hash-table-args)))
1836      (dolist (cons alist) (puthash (car cons) hash-table (cdr cons)))
1837      hash-table)))
1838
1839(defun %hash-table-equalp (x y)
1840  ;; X and Y are both hash tables
1841  (and (eq (hash-table-test x)
1842           (hash-table-test y))
1843       (eql (hash-table-count x)
1844            (hash-table-count y))
1845       (block nil
1846         (let* ((default (cons nil nil))
1847                (foo #'(lambda (k v)
1848                         (let ((y-value (gethash k y default)))
1849                           (unless (and (neq default y-value)
1850                                        (equalp v y-value))
1851                             (return nil))))))
1852           (declare (dynamic-extent foo default))
1853           (maphash foo x))
1854         t)))
1855
1856(defun sxhash (s-expr)
1857  "Computes a hash code for S-EXPR and returns it as an integer."
1858  (logand (sxhash-aux s-expr 7 17) target::target-most-positive-fixnum))
1859
1860(defun sxhash-aux (expr counter key)
1861  (declare (fixnum counter))
1862  (if (> counter 0)
1863    (typecase expr
1864      ((or string bit-vector number character)  (+ key (%%equalhash expr)))
1865      (logical-pathname
1866       (dotimes (i (uvsize expr) key)
1867         (declare (fixnum i))
1868         (setq key (+ key (sxhash-aux (%svref expr i) (1- counter) key)))))
1869      (pathname
1870       ;; Don't consider %PHYSICAL-PATHNAME-VERSION to be significant
1871       (dotimes (i (uvsize expr) key)
1872         (declare (fixnum i))
1873         (unless (= i %physical-pathname-version)
1874           (setq key (+ key (sxhash-aux (%svref expr i) (1- counter) key))))))
1875      (symbol (+ key (%%equalhash (symbol-name expr))))
1876      (cons (sxhash-aux
1877             (cdr expr)
1878             (the fixnum (1- counter))             
1879             (+ key (sxhash-aux (car expr) (the fixnum (1- counter)) key))))
1880      (t (+  key (%%equalhash (symbol-name (%type-of expr))))))
1881    key))
1882
1883
1884
1885#+(or ppc32-target x8632-target)
1886(defun immediate-p (thing)
1887  (let* ((tag (lisptag thing)))
1888    (declare (fixnum tag))
1889    (or (= tag target::tag-fixnum)
1890        (= tag target::tag-imm))))
1891
1892#+ppc64-target
1893(defun immediate-p (thing)
1894  (let* ((tag (lisptag thing)))
1895    (declare (fixnum tag))
1896    (or (= tag ppc64::tag-fixnum)
1897        (= (logand tag ppc64::lowtagmask) ppc64::lowtag-imm))))
1898
1899#+x8664-target
1900(defun immediate-p (thing)
1901  (let* ((tag (lisptag thing)))
1902    (declare (type (unsigned-byte 3) tag))
1903    (logbitp tag
1904             (logior (ash 1 x8664::tag-fixnum)
1905                     (ash 1 x8664::tag-imm-0)
1906                     (ash 1 x8664::tag-imm-1)))))
1907
1908
1909
1910(defun %cons-nhash-vector (size &optional (flags 0))
1911  (declare (fixnum size))
1912  (let* ((vector (%alloc-misc (+ (+ size size) $nhash.vector_overhead) target::subtag-hash-vector free-hash-marker)))
1913    (%init-nhash-vector vector flags)
1914    vector))
1915
1916(defun %init-nhash-vector (vector flags)
1917  (let ((size (vector-index->index (uvsize vector))))
1918    (declare (fixnum size))
1919    (setf (nhash.vector.link vector) 0
1920          (nhash.vector.flags vector) flags
1921          (nhash.vector.gc-count vector) (%get-gc-count)
1922          (nhash.vector.free-alist vector) nil
1923          (nhash.vector.finalization-alist vector) nil
1924          (nhash.vector.hash vector) nil
1925          (nhash.vector.deleted-count vector) 0
1926          (nhash.vector.count vector) 0
1927          (nhash.vector.cache-key vector) free-hash-marker
1928          (nhash.vector.cache-value vector) nil
1929          (nhash.vector.cache-idx vector) nil
1930          (nhash.vector.size vector) size
1931          (nhash.vector.size-reciprocal vector) (floor (ash 1 (- target::nbits-in-word target::fixnumshift)) size))))
1932
1933(defun assert-hash-table-readonly (hash)
1934  (unless (typep hash 'hash-table)
1935    (report-bad-arg hash 'hash-table))
1936  (or (nhash.read-only hash)
1937      (when (nhash.owner hash)
1938        (error "Hash~table ~s is thread-private and can't be made read-only for that reason" hash))
1939      (if (hash-lock-free-p hash)
1940        (setf (nhash.read-only hash) t)
1941        (with-lock-context
1942          (without-interrupts
1943           (write-lock-hash-table hash)
1944           (let* ((flags (nhash.vector.flags (nhash.vector hash))))
1945             (declare (fixnum flags))
1946             (when (or (logbitp $nhash_track_keys_bit flags)
1947                       (logbitp $nhash_component_address_bit flags))
1948               (format t "~&Hash-table ~s uses address-based hashing and can't yet be made read-only for that reason." hash)
1949               (unlock-hash-table hash nil)
1950               (return-from assert-hash-table-readonly nil))
1951             (setf (nhash.read-only hash) t)
1952             (unlock-hash-table hash nil)
1953             t))))))
1954
1955;; This is dangerous, if multiple threads are accessing a read-only
1956;; hash table. Use it responsibly.
1957(defun assert-hash-table-writeable (hash)
1958  (unless (typep hash 'hash-table)
1959    (report-bad-arg hash 'hash-table))
1960  (when (nhash.read-only hash)
1961    (setf (nhash.read-only hash) nil)
1962    t))
1963
1964(defun readonly-hash-table-p (hash)
1965  (unless (typep hash 'hash-table)
1966    (report-bad-arg hash 'hash-table))
1967  (nhash.read-only hash))
1968
1969(defun hash-table-owner (hash)
1970  (unless (typep hash 'hash-table)
1971    (report-bad-arg hash 'hash-table))
1972  (nhash.owner hash))
1973
1974(defun claim-hash-table (hash &optional steal)
1975  (unless (typep hash 'hash-table)
1976    (report-bad-arg hash 'hash-table))
1977  (let* ((owner (nhash.owner hash)))
1978    (if owner
1979      (or (eq owner *current-process*)
1980          (when steal
1981            (setf (nhash.owner hash) *current-process*)))
1982      (progn
1983        (unless (hash-lock-free-p hash)
1984          (write-lock-hash-table hash)
1985          (setf (nhash.exclusion-lock hash) nil))
1986        (setf (nhash.owner hash) *current-process*)
1987        t))))
1988
1989 
1990;; ** TODO: for lock-free hash tables, maybe we don't need to copy,
1991;; we could map over the actual hash table vector, because it's
1992;; always valid.
1993(defun lock-free-enumerate-hash-keys-and-values (hash keys values)
1994  (do* ((in (nhash.vector hash))
1995        (in-idx $nhash.vector_overhead (+ in-idx 2))
1996        (insize (uvsize in))
1997        (outsize (length (or keys values)))
1998        (out-idx 0))
1999       ((or (= in-idx insize)
2000            (= out-idx outsize))
2001        out-idx)
2002    (declare (fixnum in-idx insize out-idx outsize))
2003    (let* ((key (%svref in in-idx)))
2004      (unless (eq key free-hash-marker)
2005        (let ((val (%svref in (%i+ in-idx 1))))
2006          (when (eq val rehashing-value-marker)
2007            ;; This table is being rehashed.  Wait to finish and try again
2008            (lock-free-rehash hash)
2009            (return-from lock-free-enumerate-hash-keys-and-values
2010                         (lock-free-enumerate-hash-keys-and-values hash keys values)))
2011          (unless (or (eq key deleted-hash-key-marker)
2012                      (eq val deleted-hash-value-marker)
2013                      (eq val free-hash-marker))
2014            (when keys (setf (%svref keys out-idx) key))
2015            (when values (setf (%svref values out-idx) val))
2016            (incf out-idx)))))))
2017
2018(defun enumerate-hash-keys-and-values (hash keys values)
2019  (unless (typep hash 'hash-table)
2020    (report-bad-arg hash 'hash-table))
2021  (when (hash-lock-free-p hash)
2022    (return-from enumerate-hash-keys-and-values
2023                 (lock-free-enumerate-hash-keys-and-values hash keys values)))
2024  (with-lock-context
2025    (without-interrupts
2026     (let* ((readonly (eq (read-lock-hash-table hash) :readonly)))
2027       (do* ((in (nhash.vector hash))
2028             (in-idx $nhash.vector_overhead (+ in-idx 2))
2029             (insize (uvsize in))
2030             (outsize (length (or keys values)))
2031             (out-idx 0))
2032           ((or (= in-idx insize)
2033                (= out-idx outsize))
2034              (unlock-hash-table hash readonly)
2035              out-idx)
2036         (declare (fixnum in-idx insize out-idx outsize))
2037         (let* ((key (%svref in in-idx)))
2038           (unless (or (eq key free-hash-marker)
2039                       (eq key deleted-hash-key-marker))
2040             (when keys
2041               (setf (%svref keys out-idx) key))
2042             (when values
2043               (setf (%svref values out-idx) (%svref in (%i+ in-idx 1))))
2044             (incf out-idx))))))))
2045
2046(defun enumerate-hash-keys (hash out)
2047  (enumerate-hash-keys-and-values hash out nil))
Note: See TracBrowser for help on using the repository browser.