source: trunk/source/compiler/optimizers.lisp @ 13231

Last change on this file since 13231 was 13231, checked in by gb, 10 years ago

If APPLY's last arg is a quoted list, transform it into FUNCALL
(quoting list elements if necessary.)

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 95.5 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL.
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence.
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18; Optimizers.lisp - compiler optimizers
19
20(in-package "CCL")
21
22(eval-when (eval compile)
23  (require'backquote)
24  (require'lispequ)
25  (require "ARCH"))
26
27(declaim (special *nx-can-constant-fold* *nx-synonyms*))
28
29(defvar *dont-find-class-optimize* nil) ; t means dont
30
31#|
32;;; can-constant-fold had a bug in the way it called #'proclaim-inline
33|#
34
35;;; There seems to be some confusion about what #'proclaim-inline does.
36;;; The value of the alist entry in *nx-proclaimed-inline* indicates
37;;; whether or not the compiler is allowed to use any special knowledge
38;;; about the symbol in question.  That's a necessary but not sufficient
39;;; condition to enable inline expansion; that's governed by declarations
40;;; in the compile-time environment.
41;;; If someone observed a symptom whereby calling CAN-CONSTANT-FOLD
42;;; caused unintended inline-expansion, the bug's elsewhere ...
43;;; The bug is that nx-declared-inline-p calls proclaimed-inline-p
44;;;  which looks at what proclaim-inline sets.  Presumably, that
45;;;  means that someone fixed it because it showed evidence of
46;;;  being broken.
47;;; The two concepts (the compiler should/should not make assumptions about
48;;;  the signature of known functions, the compiler should/should not arrange
49;;;  to keep the lambda expression around) need to be sorted out.
50
51(defun can-constant-fold (names &aux handler inlines)
52  (dolist (name names)
53    (if (atom name)
54      (setq handler nil)
55      (setq handler (cdr name) name (car name)))
56    (when (and handler (not (eq handler 'fold-constant-subforms)))
57      (warn "Unknown constant-fold handler : ~s" handler)
58      (setq handler nil))
59    (let* ((bits (%symbol-bits name)))
60      (declare (fixnum bits))
61      (%symbol-bits name (logior
62                          (if handler (logior (ash 1 $sym_fbit_fold_subforms) (ash 1 $sym_fbit_constant_fold))
63                              (ash 1 $sym_fbit_constant_fold))
64                          bits)))
65     (push name inlines))
66  '(apply #'proclaim-inline t inlines)
67)
68
69;;; There's a bit somewhere.  This is very partial.  Should be a bit
70;;; somewhere, there are too many of these to keep on a list.
71(can-constant-fold '(specfier-type %ilsl %ilsr 1- 1+ eql eq
72                     byte make-point - / (+ . fold-constant-subforms) (* . fold-constant-subforms) ash character
73                     char-code code-char lsh
74                     (logior . fold-constant-subforms) (logand . fold-constant-subforms)
75                     (logxor . fold-constant-subforms) logcount logorc2 listp consp expt
76                     logorc1 logtest lognand logeqv lognor lognot logandc2 logandc1
77                     numerator denominator ldb-test byte-position byte-size isqrt gcd
78                     floor mod truncate rem round boole max min ldb dpb mask-field deposit-field
79                     length aref svref char schar bit sbit getf identity list-length
80                     car cdr cadr cddr nth nthcdr last load-byte deposit-byte byte-mask
81                     member search count position assoc rassoc integer-length
82                         float not null char-int expt abs
83                     = /= < <= > >=))
84
85(defun %binop-cassoc (call)
86  (unless (and (cddr call) (null (cdr (%cddr call))))
87    (return-from %binop-cassoc call))
88  (let ((func (%car call))
89        (arg1 (%cadr call))
90        (arg2 (%caddr call))
91        (val))
92    (cond ((and (fixnump arg1) (fixnump arg2))
93           (funcall func arg1 arg2))
94          ((or (fixnump arg1) (fixnump arg2))
95           (if (fixnump arg2) (psetq arg1 arg2 arg2 arg1))
96           (if (and (consp arg2)
97                    (eq (%car arg2) func)
98                    (cddr arg2)
99                    (null (cdr (%cddr arg2)))
100                    (or (fixnump (setq val (%cadr arg2)))
101                        (fixnump (setq val (%caddr arg2)))))
102             (list func
103                   (funcall func arg1 val)
104                   (if (eq val (%cadr arg2)) (%caddr arg2) (%cadr arg2)))
105             call))
106          (t call))))
107
108(defun fixnumify (args op &aux (len (length args)))
109  (if (eq len 2)
110    (cons op args)
111    (list op (%car args) (fixnumify (%cdr args) op))))
112
113(defun generic-to-fixnum-n (call env op &aux (args (%cdr call)) targs)
114  (block nil
115    (if (and (%i> (length args) 1)
116             (and (nx-trust-declarations env)
117                  (or (neq op '%i+) (subtypep *nx-form-type* 'fixnum))))
118      (if (dolist (arg args t)
119            (if (nx-form-typep arg 'fixnum env)
120              (push arg targs)
121              (return)))
122        (return
123         (fixnumify (nreverse targs) op))))
124    call))
125
126;;; True if arg is an alternating list of keywords and args, only
127;;; recognizes keywords in keyword package.  Historical note: this
128;;; used to try to ensure that the keyword appeared at most once.  Why
129;;; ? (Even before destructuring, pl-search/getf would have dtrt.)
130;;; Side effects: it's not the right thing to simply pick the value
131;;; associated with the first occurrence of a keyword if the value
132;;; associated with subsequent occurrence could have a side-effect.
133;;; (We -can- ignore a duplicate key if the associated value is
134;;; side-effect free.)
135(defun constant-keywords-p (keys)
136  (when (plistp keys)
137    (do* ((seen ())
138          (keys keys (cddr keys)))
139         ((null keys) t)
140      (let* ((key (car keys)))
141        (if (or (not (keywordp key))
142                (and (memq key seen)
143                     (not (constantp (cadr keys)))))
144          (return))
145        (push key seen)))))
146
147
148(defun remove-explicit-test-keyword-from-test-testnot-key (item list keys default alist testonly)
149  (if (null keys)
150    `(,default ,item ,list)
151     (if (constant-keywords-p keys)
152        (destructuring-bind (&key (test nil test-p)
153                                  (test-not nil test-not-p)
154                                  (key nil key-p))
155                            keys
156          (declare (ignore test-not))
157          (if (and test-p
158                   (not test-not-p)
159                   (or (not key-p)
160                       (and (consp key)
161                            (consp (%cdr key))
162                            (null (%cddr key))
163                            (or (eq (%car key) 'function)
164                                (eq (%car key) 'quote))
165                            (eq (%cadr key) 'identity)))
166                   (consp test)
167                   (consp (%cdr test))
168                   (null (%cddr test))
169                   (or (eq (%car test) 'function)
170                       (eq (%car test) 'quote)))
171            (let* ((testname (%cadr test))
172                   (reduced (cdr (assoc testname alist))))
173              (if reduced
174                `(,reduced ,item ,list)
175                `(,testonly ,item ,list ,test))))))))
176
177
178(defun eql-iff-eq-p (thing env)
179  (if (nx-form-constant-p thing env)
180    (setq thing (nx-form-constant-value thing env))
181    (return-from eql-iff-eq-p
182      (or (nx-form-typep thing  'symbol env)
183          (nx-form-typep thing 'character env)
184          (nx-form-typep thing
185                         '(or fixnum
186                           #+64-bit-target single-float
187                           symbol character
188                           (and (not number) (not macptr))) env))))
189  (or (fixnump thing) #+64-bit-target (typep thing 'single-float)
190      (symbolp thing) (characterp thing)
191      (and (not (numberp thing)) (not (macptrp thing)))))
192
193(defun equal-iff-eql-p (thing env)
194  (if (nx-form-constant-p thing env)
195    (setq thing (nx-form-constant-value thing env))
196    (return-from equal-iff-eql-p
197      (nx-form-typep thing
198                     '(and (not cons) (not string) (not bit-vector) (not pathname)) env)))
199  (not (typep thing '(or cons string bit-vector pathname))))
200
201
202(defun fold-constant-subforms (call env)
203    (let* ((constants nil)
204           (forms nil))
205      (declare (list constants forms))
206      (dolist (form (cdr call))
207        (setq form (nx-transform form env))
208        (if (numberp form)
209          (setq constants (%temp-cons form constants))
210          (setq forms (%temp-cons form forms))))
211      (if constants
212        (let* ((op (car call))
213               (constant (if (cdr constants) (handler-case (apply op constants)
214                                               (error (c) (declare (ignore c))
215                                                      (return-from fold-constant-subforms (values call t))))
216                             (car constants))))
217          (values (if forms (cons op (cons constant (reverse forms))) constant) t))
218        (values call nil))))
219
220;;; inline some, etc. in some cases
221;;; in all cases, add dynamic-extent declarations
222(defun some-xx-transform (call env)
223  (destructuring-bind (func predicate sequence &rest args) call
224    (multiple-value-bind (func-constant end-value loop-test)
225                         (case func
226                           (some (values $some nil 'when))
227                           (notany (values $notany t 'when))
228                           (every (values $every t 'unless))
229                           (notevery (values $notevery nil 'unless)))
230      (if args
231        (let ((func-sym (gensym))
232              (seq-sym (gensym))
233              (list-sym (gensym)))
234          `(let ((,func-sym ,predicate)
235                 (,seq-sym ,sequence)
236                 (,list-sym (list ,@args)))
237             (declare (dynamic-extent ,func-sym ,list-sym ,seq-sym))
238             (some-xx-multi ,func-constant ,end-value ,func-sym ,seq-sym ,list-sym)))
239        (let ((loop-function (nx-form-sequence-iterator sequence env)))
240          ;; inline if we know the type of the sequence and if
241          ;; the predicate is a lambda expression
242          ;; otherwise, it blows up the code for not much gain
243          (if (and loop-function
244                   (function-form-p predicate)
245                   (lambda-expression-p (second predicate)))
246            (let ((elt-var (gensym)))
247              (case func
248                (some
249                 `(,loop-function (,elt-var ,sequence ,end-value)
250                                  (let ((result (funcall ,predicate ,elt-var)))
251                                    (when result (return result)))))
252                ((every notevery notany)
253                 `(,loop-function (,elt-var ,sequence ,end-value)
254                                  (,loop-test (funcall ,predicate ,elt-var)
255                                              (return ,(not end-value)))))))
256            (let ((func-sym (gensym))
257                  (seq-sym (gensym)))
258              `(let ((,func-sym ,predicate)
259                     (,seq-sym ,sequence))
260                 (declare (dynamic-extent ,func-sym ,seq-sym))
261                 (some-xx-one ,func-constant ,end-value ,func-sym ,seq-sym)))))))))
262
263
264;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
265;;;
266;;; The new (roughly alphabetical) order.
267;;;
268;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
269
270;;; Compiler macros on functions can assume that their arguments have
271;;; already been transformed.
272
273
274(defun transform-real-n-ary-comparision (whole binary-name)
275  (destructuring-bind (n0 &optional (n1 0 n1-p) &rest more) (cdr whole)
276    (if more
277      (if (cdr more)
278        whole
279        (let* ((n2 (car more))
280               (n (gensym)))
281          `(let* ((,n ,n0))
282            (if (,binary-name ,n (setq ,n ,n1))
283              (,binary-name ,n ,n2)))))
284      (if (not n1-p)
285        `(require-type ,n0 'real)
286        `(,binary-name ,n0 ,n1)))))
287
288
289
290(define-compiler-macro < (&whole whole &rest ignore)
291  (declare (ignore ignore))
292  (transform-real-n-ary-comparision whole '<-2))
293
294(define-compiler-macro > (&whole whole &rest ignore)
295  (declare (ignore ignore))
296  (transform-real-n-ary-comparision whole '>-2))
297
298(define-compiler-macro <= (&whole whole &rest ignore)
299  (declare (ignore ignore))
300  (transform-real-n-ary-comparision whole '<=-2))
301
302(define-compiler-macro >= (&whole whole &rest ignore)
303  (declare (ignore ignore))
304  (transform-real-n-ary-comparision whole '>=-2))
305
306
307(define-compiler-macro 1- (x)
308  `(- ,x 1))
309
310(define-compiler-macro 1+ (x)
311  `(+ ,x 1))
312
313(define-compiler-macro append  (&whole call
314                                       &optional arg0
315                                       &rest
316                                       (&whole tail
317                                               &optional (junk nil arg1-p)
318                                               &rest more))
319  ;(append (list x y z) A) -> (list* x y z A)
320  (if (and arg1-p
321           (null more)
322           (consp arg0)
323           (eq (%car arg0) 'list))
324    (cons 'list* (append (%cdr arg0) tail))
325    (if (and arg1-p (null more))
326      `(append-2 ,arg0 ,junk)
327      call)))
328
329
330(define-compiler-macro apply  (&whole call fn arg0 &rest args)
331  ;; Special-case (apply #'make-instance 'name ...)
332  ;; Might be good to make this a little more general, e.g., there
333  ;; may be other things that can be strength-reduced even if we can't
334  ;; get rid of the APPLY.
335  (if (and (consp fn)
336           (or (eq (car fn) 'quote)
337               (eq (car fn) 'function))
338           (consp (cdr fn))
339           (null (cddr fn))
340           (eq (cadr fn) 'make-instance)
341           (consp arg0)
342           (eq (car arg0) 'quote)
343           (consp (cdr arg0))
344           (symbolp (cadr arg0)))
345    (let* ((name (cadr arg0))
346           (class-cell (gensym)))
347      `(let* ((,class-cell (load-time-value (find-class-cell ',name t))))
348        (apply (class-cell-instantiate ,class-cell) ,class-cell ,@args)))
349    (let ((original-fn fn))
350      (if (and arg0
351               (null args)
352               (consp fn)
353               (eq (%car fn) 'function)
354               (null (cdr (%cdr fn)))
355               (consp (setq fn (%cadr fn)))
356               (eq (%car fn) 'lambda))
357        (destructuring-bind (lambda-list &body body) (%cdr fn)
358          `(destructuring-bind ,lambda-list ,arg0 ,@body))
359        (let ((last (%car (last (push arg0 args)))))
360          (if (and (consp last) (memq (%car last) '(cons list* list)))
361            (cons (if (eq (%car last) 'list) 'funcall 'apply)
362                  (cons
363                   original-fn
364                   (nreconc (cdr (reverse args)) (%cdr last))))
365            (if (and (consp last)
366                     (eq (car last) 'quote)
367                     (proper-list-p (cadr last)))
368              (flet ((quotify (arg)
369                       (if (self-evaluating-p arg)
370                         arg
371                         (list 'quote arg))))
372                (cons 'funcall (cons original-fn
373                                     (nreconc (cdr (reverse args)) (mapcar #'quotify (%cadr last))))))
374              call)))))))
375
376
377
378
379(define-compiler-macro assoc (&whole call item list &rest keys)
380  (or (remove-explicit-test-keyword-from-test-testnot-key item list keys 'asseql '((eq . assq) (eql . asseql) (equal . assequal)) 'assoc-test)
381      call))
382
383(define-compiler-macro assequal (&whole call &environment env item list)
384  (if (or (equal-iff-eql-p item env)
385          (and (quoted-form-p list)
386               (proper-list-p (%cadr list))
387               (every (lambda (x) (equal-iff-eql-p (car x) env)) (%cadr list))))
388    `(asseql ,item ,list)
389    call))
390
391(define-compiler-macro asseql (&whole call &environment env item list)
392  (if (or (eql-iff-eq-p item env)
393          (and (quoted-form-p list)
394               (proper-list-p (%cadr list))
395               (every (lambda (x) (eql-iff-eq-p (car x) env)) (%cadr list))))
396    `(assq ,item ,list)
397    call))
398
399(define-compiler-macro assq (item list)
400  (let* ((itemx (gensym))
401         (listx (gensym))
402         (pair (gensym)))
403    `(let* ((,itemx ,item)
404            (,listx ,list))
405      (dolist (,pair ,listx)
406        (when (and ,pair (eq (car ,pair) ,itemx)) (return ,pair))))))
407
408(define-compiler-macro caar (form)
409  `(car (car ,form)))
410
411(define-compiler-macro cadr (form)
412  `(car (cdr ,form)))
413
414(define-compiler-macro cdar (form)
415  `(cdr (car ,form)))
416
417(define-compiler-macro cddr (form)
418  `(cdr (cdr ,form)))
419
420(define-compiler-macro caaar (form)
421  `(car (caar ,form)))
422
423(define-compiler-macro caadr (form)
424  `(car (cadr ,form)))
425
426(define-compiler-macro cadar (form)
427  `(car (cdar ,form)))
428
429(define-compiler-macro caddr (form)
430  `(car (cddr ,form)))
431
432(define-compiler-macro cdaar (form)
433  `(cdr (caar ,form)))
434
435(define-compiler-macro cdadr (form)
436  `(cdr (cadr ,form)))
437
438(define-compiler-macro cddar (form)
439  `(cdr (cdar ,form)))
440
441(define-compiler-macro cdddr (form)
442  `(cdr (cddr ,form)))
443
444(define-compiler-macro caaaar (form)
445  `(car (caaar ,form)))
446
447(define-compiler-macro caaadr (form)
448  `(car (caadr ,form)))
449
450(define-compiler-macro caadar (form)
451  `(car (cadar ,form)))
452
453(define-compiler-macro caaddr (form)
454  `(car (caddr ,form)))
455
456(define-compiler-macro cadaar (form)
457  `(car (cdaar ,form)))
458
459(define-compiler-macro cadadr (form)
460  `(car (cdadr ,form)))
461
462(define-compiler-macro caddar (form)
463  `(car (cddar ,form)))
464
465(define-compiler-macro cadddr (form)
466  `(car (cdddr ,form)))
467
468(define-compiler-macro cdaaar (form)
469  `(cdr (caaar ,form)))
470
471(define-compiler-macro cdaadr (form)
472  `(cdr (caadr ,form)))
473
474(define-compiler-macro cdadar (form)
475  `(cdr (cadar ,form)))
476
477(define-compiler-macro cdaddr (form)
478  `(cdr (caddr ,form)))
479
480(define-compiler-macro cddaar (form)
481  `(cdr (cdaar ,form)))
482
483(define-compiler-macro cddadr (form)
484  `(cdr (cdadr ,form)))
485
486(define-compiler-macro cdddar (form)
487  `(cdr (cddar ,form)))
488
489(define-compiler-macro cddddr (form)
490  `(cdr (cdddr ,form)))
491
492
493
494
495(define-compiler-macro cons (&whole call x y &aux dcall ddcall)
496   (if (consp (setq dcall y))
497     (cond
498      ((or (eq (%car dcall) 'list) (eq (%car dcall) 'list*))
499       ;(CONS A (LIST[*] . args)) -> (LIST[*] A . args)
500       (list* (%car dcall) x (%cdr dcall)))
501      ((or (neq (%car dcall) 'cons) (null (cddr dcall)) (cdddr dcall))
502       call)
503      ((null (setq ddcall (%caddr dcall)))
504       ;(CONS A (CONS B NIL)) -> (LIST A B)
505       `(list ,x ,(%cadr dcall)))
506      ((and (consp ddcall)
507            (eq (%car ddcall) 'cons)
508            (eq (list-length ddcall) 3))
509       ;(CONS A (CONS B (CONS C D))) -> (LIST* A B C D)
510       (list* 'list* x (%cadr dcall) (%cdr ddcall)))
511      (t call))
512     call))
513
514(define-compiler-macro dotimes (&whole call (i n &optional result)
515                                       &body body
516                                       &environment env)
517  (multiple-value-bind (body decls) (parse-body body env)
518    (if (nx-form-typep (setq n (nx-transform n env)) 'fixnum env)
519        (let* ((limit (gensym))
520               (upper (if (nx-form-constant-p n env) (nx-form-constant-value n env) most-positive-fixnum))
521               (top (gensym))
522               (test (gensym)))
523          `(let* ((,limit ,n) (,i 0))
524             ,@decls
525             (declare (fixnum ,limit)
526                      (type (integer 0 ,(if (<= upper 0) 0 upper)) ,i)
527                      (unsettable ,i))
528             (block nil
529               (tagbody
530                 (go ,test)
531                 ,top
532                 ,@body
533                 (locally
534                   (declare (settable ,i))
535                   (setq ,i (1+ ,i)))
536                 ,test
537                 (when (< ,i ,limit) (go ,top)))
538               ,result)))
539        call)))
540
541(define-compiler-macro dpb (&whole call value byte integer)
542  (cond ((and (integerp byte) (> byte 0))
543         (if (integerp value)
544           `(logior ,(dpb value byte 0) (logand ,(lognot byte) ,integer))
545           `(deposit-field (ash ,value ,(byte-position byte)) ,byte ,integer)))
546        ((and (consp byte)
547              (eq (%car byte) 'byte)
548              (eq (list-length (%cdr byte)) 2))
549         `(deposit-byte ,value ,(%cadr byte) ,(%caddr byte) ,integer))
550        (t call)))
551
552(define-compiler-macro eql (&whole call &environment env v1 v2)
553  (if (or (eql-iff-eq-p v1 env) (eql-iff-eq-p v2 env))
554    `(eq ,v1 ,v2)
555    call))
556
557(define-compiler-macro every (&whole call &environment env &rest ignore)
558  (declare (ignore ignore))
559  (some-xx-transform call env))
560
561
562(define-compiler-macro identity (form) form)
563
564(define-compiler-macro if (&whole call test true &optional false &environment env)
565  (let ((test-val (nx-transform test env)))
566    (if (nx-form-constant-p test-val env)
567      (if (nx-form-constant-value test-val env)
568        true
569        false)
570      call)))
571
572(define-compiler-macro %ilsr (&whole call shift value)
573  (if (eql shift 0)
574    value
575    (if (eql value 0)
576      `(progn ,shift 0)
577      call)))
578
579(defun string-designator-p (object)
580  (typecase object
581    (character t)
582    (symbol t)
583    (string t)))
584
585(define-compiler-macro ldb (&whole call &environment env byte integer)
586   (cond ((and (integerp byte) (> byte 0))
587          (let ((size (byte-size byte))
588                (position (byte-position byte)))
589            (cond ((nx-form-typep integer 'fixnum env)
590                   `(logand ,(byte-mask size)
591                     (the fixnum (ash ,integer ,(- position)))))
592                  (t `(load-byte ,size ,position ,integer)))))
593         ((and (consp byte)
594               (eq (%car byte) 'byte)
595               (eq (list-length (%cdr byte)) 2))
596          (let ((size (%cadr byte))
597                (position (%caddr byte)))
598            (if (and (nx-form-typep integer 'fixnum env) (fixnump position))
599              ;; I'm not sure this is worth doing
600              `(logand (byte-mask ,size) (the fixnum (ash ,integer ,(- position))))
601              ;; this IS worth doing
602              `(load-byte ,size ,position ,integer))))
603         (t call)))
604
605(define-compiler-macro length (&whole call &environment env seq)
606  (if (nx-form-typep seq '(simple-array * (*)) env)
607    `(uvsize ,seq)
608    call))
609
610(define-compiler-macro let (&whole call (&optional (first nil first-p) &rest rest) &body body)
611  (if first-p
612    (if rest
613      call
614      `(let* (,first) ,@body))
615    `(locally ,@body)))
616
617(define-compiler-macro let* (&whole call (&rest bindings) &body body)
618  (if bindings
619    call
620    `(locally ,@body)))
621
622(define-compiler-macro list* (&whole call &rest rest  &aux (n (list-length rest)) last)
623  (cond ((%izerop n) nil)
624        ((null (setq last (%car (last call))))
625         (cons 'list (nreverse (cdr (reverse (cdr call))))))
626        ((and (consp last) (memq (%car last) '(list* list cons)))
627         (cons (if (eq (%car last) 'cons) 'list* (%car last))
628                                 (nreconc (cdr (reverse (cdr call))) (%cdr last))))
629        ((eq n 1) (list 'values last))
630        ((eq n 2) (cons 'cons (%cdr call)))
631        (t call)))
632
633
634
635;;;(CONS X NIL) is same size as (LIST X) and faster.
636(define-compiler-macro list  (&whole call &optional (first nil first-p) &rest more)
637  (if more
638    call
639    (if first-p
640      `(cons ,first nil))))
641
642
643(define-compiler-macro locally (&whole call &body body &environment env)
644  (multiple-value-bind (body decls) (parse-body body env nil)
645    (if decls
646      call
647      `(progn ,@body))))
648
649(defun target-element-type-type-keyword (typespec &optional env)
650  (let ((ctype (specifier-type-if-known `(array ,typespec) env)))
651    (when ctype
652      (funcall (arch::target-array-type-name-from-ctype-function
653                (backend-target-arch *target-backend*))
654               ctype))))
655
656(defun infer-array-type (dims element-type element-type-p displaced-to-p fill-pointer-p adjustable-p env)
657  (let* ((ctype (make-array-ctype :complexp (or displaced-to-p fill-pointer-p adjustable-p))))
658    (if (nx-form-constant-p dims env)
659      (let* ((dims (nx-form-constant-value dims env)))
660        (if (listp dims)
661          (progn
662            (unless (every #'fixnump dims)
663              (warn "Funky-looking array dimensions ~s in MAKE-ARRAY call" dims))
664            (setf (array-ctype-dimensions ctype) dims))
665          (progn
666            (unless (typep dims 'fixnum)
667              (warn "Funky-looking array dimensions ~s in MAKE-ARRAY call" dims))
668            (setf (array-ctype-dimensions ctype) (list dims)))))
669      (if (atom dims)
670        (if (nx-form-typep dims 'fixnum env)
671          (setf (array-ctype-dimensions ctype)
672                (if (typep (setq dims (nx-transform dims env)) 'fixnum)
673                  (list dims)
674                  (list '*)))
675          (setf (array-ctype-dimensions ctype) '*))
676        (if (eq (car dims) 'list)
677          (setf (array-ctype-dimensions ctype)
678                (mapcar #'(lambda (d)
679                            (if (typep (setq d (nx-transform d env)) 'fixnum)
680                              d
681                              '*))
682                        (cdr dims)))
683          ;; Wimp out
684          (setf (array-ctype-dimensions ctype)
685                '*))))
686    (let* ((typespec (if element-type-p
687                       (if (nx-form-constant-p element-type env)
688                         (nx-form-constant-value element-type env)
689                         '*)
690                       t))
691           (element-type (specifier-type-if-known typespec env :whine t)))
692      (setf (array-ctype-element-type ctype) (or element-type *wild-type*))
693      (specialize-array-type ctype))
694    (type-specifier ctype)))
695
696
697
698(define-compiler-macro make-array (&whole call &environment env dims &rest keys)
699  (if (constant-keywords-p keys)
700    (destructuring-bind (&key (element-type t element-type-p)
701                              (displaced-to () displaced-to-p)
702                              (displaced-index-offset () displaced-index-offset-p)
703                              (adjustable () adjustable-p)
704                              (fill-pointer () fill-pointer-p)
705                              (initial-element () initial-element-p)
706                              (initial-contents () initial-contents-p))
707        keys
708      (declare (ignorable element-type element-type-p
709                          displaced-to displaced-to-p
710                          displaced-index-offset displaced-index-offset-p
711                          adjustable adjustable-p
712                          fill-pointer fill-pointer-p
713                          initial-element initial-element-p
714                          initial-contents initial-contents-p))
715      (let* ((element-type-keyword nil)
716             (expansion
717              (cond ((and initial-element-p initial-contents-p)
718                     (signal-program-error  "Incompatible arguments :INITIAL-ELEMENT and :INITIAL-CONTENTS in ~s" call)
719                     call)
720                    (displaced-to-p
721                     (if (or initial-element-p initial-contents-p element-type-p)
722                       (comp-make-array-1 dims keys)
723                       (comp-make-displaced-array dims keys)))
724                    ((or displaced-index-offset-p
725                         (not (nx-form-constant-p element-type env))
726                         (null (setq element-type-keyword
727                                     (target-element-type-type-keyword
728                                      (nx-form-constant-value element-type env) env))))
729                     (comp-make-array-1 dims keys))
730                    ((and (typep element-type-keyword 'keyword)
731                          (nx-form-typep dims 'fixnum env)
732                          (null (or adjustable fill-pointer initial-contents
733                                    initial-contents-p)))
734                     (if
735                       (or (null initial-element-p)
736                           (cond ((eql element-type-keyword :double-float-vector)
737                                  (eql initial-element 0.0d0))
738                                 ((eql element-type-keyword :single-float-vector)
739                                  (eql initial-element 0.0s0))
740                                 ((eql element-type :simple-string)
741                                  (eql initial-element #\Null))
742                                 (t (eql initial-element 0))))
743                       `(allocate-typed-vector ,element-type-keyword ,dims)
744                       `(allocate-typed-vector ,element-type-keyword ,dims ,initial-element)))
745                    (t                        ;Should do more here
746                     (comp-make-uarray dims keys (type-keyword-code element-type-keyword)))))
747             (type (if (nx-trust-declarations env)
748                     (infer-array-type dims element-type element-type-p displaced-to-p fill-pointer-p adjustable-p env)
749                     t)))
750        `(the ,type ,expansion)))
751
752        call))
753
754(defun comp-make-displaced-array (dims keys)
755  (let* ((call-list (make-list 4 :initial-element nil))
756         (dims-var (make-symbol "DIMS"))
757         (let-list (comp-nuke-keys keys
758                                   '((:displaced-to 0)
759                                     (:fill-pointer 1)
760                                     (:adjustable 2)
761                                     (:displaced-index-offset 3))
762                                   call-list
763                                   `((,dims-var ,dims)))))
764
765    `(let ,let-list
766       (%make-displaced-array ,dims-var ,@call-list t))))
767
768(defun comp-make-uarray (dims keys subtype)
769  (if (null keys)
770    `(%make-simple-array ,subtype ,dims)
771    (let* ((call-list (make-list 6))
772           (dims-var (make-symbol "DIMS"))
773           (let-list (comp-nuke-keys keys
774                                     '((:adjustable 0)
775                                       (:fill-pointer 1)
776                                       (:initial-element 2 3)
777                                       (:initial-contents 4 5))
778                                     call-list
779                                     `((,dims-var ,dims)))))
780      `(let ,let-list
781        (make-uarray-1 ,subtype ,dims-var ,@call-list nil nil)))))
782
783(defun comp-make-array-1 (dims keys)
784  (let* ((call-list (make-list 10 :initial-element nil))
785         (dims-var (make-symbol "DIMS"))
786         (let-list (comp-nuke-keys keys
787                                   '((:element-type 0 1)
788                                     (:displaced-to 2)
789                                     (:displaced-index-offset 3)
790                                     (:adjustable 4)
791                                     (:fill-pointer 5)
792                                     (:initial-element 6 7)
793                                     (:initial-contents 8 9))
794                                   call-list
795                                   `((,dims-var ,dims)))))
796    `(let ,let-list
797       (make-array-1 ,dims-var ,@call-list nil))))
798
799(defun comp-nuke-keys (keys key-list call-list &optional required-bindings)
800  ; side effects call list, returns a let-list
801  (let* ((let-list (reverse required-bindings))
802         (seen nil))
803    (do ((lst keys (cddr lst)))
804        ((null lst) nil)
805      (let* ((key (car lst))
806             (val (cadr lst))
807             (ass (assq key key-list))
808             (vpos (cadr ass))
809             (ppos (caddr ass)))
810        (when ass
811          (unless (memq vpos seen)
812            (push vpos seen)
813            (when (not (constantp val))
814              (let ((gen (gensym)))
815                (setq let-list (cons (list gen val) let-list)) ; reverse him
816                (setq val gen)))
817            (rplaca (nthcdr vpos call-list) val)
818            (if ppos (rplaca (nthcdr ppos call-list) t))))))
819    (nreverse let-list)))
820
821(define-compiler-macro make-instance (&whole call class &rest initargs)
822  (if (and (listp class)
823           (eq (car class) 'quote)
824           (symbolp (cadr class))
825           (null (cddr class)))
826    (let* ((cell (gensym)))
827      `(let* ((,cell (load-time-value (find-class-cell ,class t))))
828        (funcall (class-cell-instantiate ,cell) ,cell ,@initargs)))
829    call))
830
831
832
833
834
835
836
837(define-compiler-macro mapc  (&whole call fn lst &rest more)
838  (if more
839    call
840    (let* ((temp-var (gensym))
841           (elt-var (gensym))
842           (fn-var (gensym)))
843       `(let* ((,fn-var ,fn)
844               (,temp-var ,lst))
845          (dolist (,elt-var ,temp-var ,temp-var)
846            (funcall ,fn-var ,elt-var))
847          ))))
848
849(define-compiler-macro mapcar (&whole call fn lst &rest more)
850  (if more
851    call
852    (let* ((temp-var (gensym))
853           (result-var (gensym))
854           (elt-var (gensym))
855           (fn-var (gensym)))
856      `(let* ((,temp-var (cons nil nil))
857              (,result-var ,temp-var)
858              (,fn-var ,fn))
859         (declare (dynamic-extent ,temp-var)
860                  (type cons ,temp-var ,result-var))
861         (dolist (,elt-var ,lst (cdr ,result-var))
862           (setq ,temp-var (setf (cdr ,temp-var) (list (funcall ,fn-var ,elt-var)))))))))
863
864(define-compiler-macro member (&whole call item list &rest keys)
865  (or (remove-explicit-test-keyword-from-test-testnot-key item list keys 'memeql '((eq . memq) (eql . memeql) (equal . memequal)) 'member-test)
866      call))
867
868(define-compiler-macro memequal (&whole call &environment env item list)
869  (if (or (equal-iff-eql-p item env)
870          (and (quoted-form-p list)
871               (proper-list-p (%cadr list))
872               (every (lambda (elt) (equal-iff-eql-p elt env)) (%cadr list))))
873    `(memeql ,item ,list)
874    call))
875
876(define-compiler-macro memeql (&whole call &environment env item list)
877  (if (or (eql-iff-eq-p item env)
878          (and (quoted-form-p list)
879               (proper-list-p (%cadr list))
880               (every (lambda (elt) (eql-iff-eq-p elt env)) (%cadr list))))
881    `(memq ,item ,list)
882    call))
883
884(define-compiler-macro memq (item list)
885  ;;(memq x '(y)) => (if (eq x 'y) '(y))
886  ;;Would it be worth making a two elt list into an OR?  Maybe if
887  ;;optimizing for speed...
888   (if (and (or (quoted-form-p list)
889                (null list))
890            (null (cdr (%cadr list))))
891     (if list `(if (eq ,item ',(%caadr list)) ,list))
892     (let* ((x (gensym))
893            (tail (gensym)))
894       `(do* ((,x ,item)
895              (,tail ,list (cdr (the list ,tail))))
896         ((null ,tail))
897         (if (eq (car ,tail) ,x) (return ,tail))))))
898
899(define-compiler-macro minusp (x)
900  `(< ,x 0))
901
902(define-compiler-macro notany (&whole call &environment env &rest ignore)
903  (declare (ignore ignore))
904  (some-xx-transform call env))
905
906(define-compiler-macro notevery (&whole call &environment env &rest ignore)
907  (declare (ignore ignore))
908  (some-xx-transform call env))
909
910(define-compiler-macro nth  (count list)
911   (if (and (fixnump count)
912            (%i>= count 0)
913            (%i< count 3))
914     `(,(svref '#(car cadr caddr) count) ,list)
915     `(car (nthcdr ,count ,list))))
916
917(define-compiler-macro nthcdr (count list)
918  (if (and (fixnump count)
919           (%i>= count 0)
920           (%i< count 4))
921     (if (%izerop count)
922       `(require-type ,list 'list)
923       `(,(svref '#(cdr cddr cdddr) (%i- count 1)) ,list))
924    (let* ((i (gensym))
925           (n (gensym))                 ; evaluation order
926           (tail (gensym)))
927      `(let* ((,n (require-type ,count 'unsigned-byte))
928              (,tail (require-type ,list 'list)))
929        (dotimes (,i ,n ,tail)
930          (unless (setq ,tail (cdr ,tail))
931            (return nil)))))))
932
933(define-compiler-macro plusp (x)
934  `(> ,x 0))
935
936(define-compiler-macro progn (&whole call &optional (first nil first-p) &rest rest)
937  (if first-p
938    (if rest call first)))
939
940;;; This isn't quite right... The idea is that (car (require-type foo
941;;; 'list)) ;can become just (<typechecking-car> foo) [regardless of
942;;; optimize settings], ;but I don't think this can be done just with
943;;; optimizers... For now, at least try to get it to become (%car
944;;; (<typecheck> foo)).
945(define-compiler-macro require-type (&whole call &environment env arg type &aux ctype)
946  (cond ((and (or (eq type t)
947                  (and (nx-form-constant-p type env)
948                       (setq type (nx-form-constant-value type env))))
949              (setq ctype (specifier-type-if-known type env :whine t)))
950         (cond ((nx-form-typep arg type env) arg)
951               ((and (nx-trust-declarations env) ;; if don't trust declarations, don't bother.
952                     (cond ((eq type 'simple-vector)
953                            `(the simple-vector (require-simple-vector ,arg)))
954                           ((eq type 'simple-string)
955                            `(the simple-string (require-simple-string ,arg)))
956                           ((eq type 'integer)
957                            `(the integer (require-integer ,arg)))
958                           ((eq type 'fixnum)
959                            `(the fixnum (require-fixnum ,arg)))
960                           ((eq type 'real)
961                            `(the real (require-real ,arg)))
962                           ((eq type 'list)
963                            `(the list (require-list ,arg)))
964                           ((eq type 'character)
965                            `(the character (require-character ,arg)))
966                           ((eq type 'number)
967                            `(the number (require-number ,arg)))
968                           ((eq type 'symbol)
969                            `(the symbol (require-symbol ,arg)))
970                           ((type= ctype
971                                   (specifier-type '(signed-byte 8)))
972                            `(the (signed-byte 8) (require-s8 ,arg)))
973                           ((type= ctype
974                                   (specifier-type '(unsigned-byte 8)))
975                            `(the (unsigned-byte 8) (require-u8 ,arg)))
976                           ((type= ctype
977                                   (specifier-type '(signed-byte 16)))
978                            `(the (signed-byte 16) (require-s16 ,arg)))
979                           ((type= ctype
980                                   (specifier-type '(unsigned-byte 16)))
981                            `(the (unsigned-byte 16) (require-u16 ,arg)))
982                           ((type= ctype
983                                   (specifier-type '(signed-byte 32)))
984                            `(the (signed-byte 32) (require-s32 ,arg)))
985                           ((type= ctype
986                                   (specifier-type '(unsigned-byte 32)))
987                            `(the (unsigned-byte 32) (require-u32 ,arg)))
988                           ((type= ctype
989                                   (specifier-type '(signed-byte 64)))
990                            `(the (signed-byte 64) (require-s64 ,arg)))
991                           ((type= ctype
992                                   (specifier-type '(unsigned-byte 64)))
993                            `(the (unsigned-byte 64) (require-u64 ,arg)))
994                           #+nil
995                           ((and (symbolp type)
996                                 (let ((simpler (type-predicate type)))
997                                   (if simpler `(the ,type (%require-type ,arg ',simpler))))))
998                           #+nil
999                           ((and (symbolp type)(find-class type nil env))
1000                            `(%require-type-class-cell ,arg (load-time-value (find-class-cell ',type t))))
1001                           (t (let* ((val (gensym)))
1002                                `(the ,type
1003                                   (let* ((,val ,arg))
1004                                     (if (typep ,val ',type)
1005                                       ,val
1006                                       (%kernel-restart $xwrongtype ,val ',type)))))))))
1007               (t (let* ((val (gensym)))
1008                    `(let* ((,val ,arg))
1009                       (if (typep ,val ',type)
1010                         ,val
1011                         (%kernel-restart $xwrongtype ,val ',type)))))))
1012        (t call)))
1013
1014(define-compiler-macro proclaim (&whole call decl)
1015   (if (and (quoted-form-p decl)
1016            (eq (car (setq decl (%cadr decl))) 'special))
1017       (do ((vars (%cdr decl) (%cdr vars)) (decls ()))
1018           ((null vars)
1019            (cons 'progn (nreverse decls)))
1020         (unless (and (car vars)
1021                      (neq (%car vars) t)
1022                      (symbolp (%car vars)))
1023            (return call))
1024         (push (list '%proclaim-special (list 'quote (%car vars))) decls))
1025       call))
1026
1027
1028(define-compiler-macro some (&whole call &environment env &rest ignore)
1029  (declare (ignore ignore))
1030  (some-xx-transform call env))
1031
1032(define-compiler-macro struct-ref (&whole call &environment env struct offset)
1033   (if (nx-inhibit-safety-checking env)
1034    `(%svref ,struct ,offset)
1035    call))
1036
1037;;; expand find-if and find-if-not
1038
1039(define-compiler-macro find-if (test sequence &rest keys)
1040  `(find ,test ,sequence
1041        :test #'funcall
1042        ,@keys))
1043
1044(define-compiler-macro find-if-not (test sequence &rest keys)
1045  `(find ,test ,sequence
1046        :test-not #'funcall
1047        ,@keys))
1048
1049;;; inline some cases, and use a positional function in others
1050
1051(define-compiler-macro find (&whole call &environment env
1052                                    item sequence &rest keys)
1053  (if (constant-keywords-p keys)
1054    (destructuring-bind (&key from-end test test-not (start 0) end key) keys
1055      (if (and (eql start 0)
1056               (null end)
1057               (null from-end)
1058               (not (and test test-not)))
1059        (let ((find-test (or test test-not '#'eql))
1060              (loop-test (if test-not 'unless 'when))
1061              (loop-function (nx-form-sequence-iterator sequence env)))
1062          (if loop-function
1063            (let ((item-var (unless (or (nx-form-constant-p item env)
1064                                        (and (equal find-test '#'funcall)
1065                                             (function-form-p item)))
1066                              (gensym)))
1067                  (elt-var (gensym)))
1068              `(let (,@(when item-var `((,item-var ,item))))
1069                 (,loop-function (,elt-var ,sequence)
1070                                 (,loop-test (funcall ,find-test ,(or item-var item)
1071                                                      (funcall ,(or key '#'identity) ,elt-var))
1072                                             (return ,elt-var)))))
1073            (let ((find-function (if test-not 'find-positional-test-not-key 'find-positional-test-key))
1074                  (item-var (gensym))
1075                  (sequence-var (gensym))
1076                  (test-var (gensym))
1077                  (key-var (gensym)))
1078              `(let ((,item-var ,item)
1079                     (,sequence-var ,sequence)
1080                     (,test-var ,(or test test-not))
1081                     (,key-var ,key))
1082                 (declare (dynamic-extent ,item-var ,sequence-var ,test-var ,key-var))
1083                 (,find-function ,item-var ,sequence-var ,test-var ,key-var)))))
1084        call))
1085      call))
1086
1087;;; expand position-if and position-if-not
1088
1089(define-compiler-macro position-if (test sequence &rest keys)
1090  `(position ,test ,sequence
1091             :test #'funcall
1092             ,@keys))
1093
1094(define-compiler-macro position-if-not (test sequence &rest keys)
1095  `(position ,test ,sequence
1096             :test-not #'funcall
1097             ,@keys))
1098
1099;;; inline some cases, and use positional functions for others
1100
1101(define-compiler-macro position (&whole call &environment env
1102                                        item sequence &rest keys)
1103  (if (constant-keywords-p keys)
1104    (destructuring-bind (&key from-end test test-not (start 0) end key) keys
1105      (if (and (eql start 0)
1106               (null end)
1107               (null from-end)
1108               (not (and test test-not)))
1109        (let ((position-test (or test test-not '#'eql))
1110              (loop-test (if test-not 'unless 'when)))
1111          (cond ((nx-form-typep sequence 'list env)
1112                 (let ((item-var (unless (or (nx-form-constant-p item env)
1113                                             (and (equal position-test '#'funcall)
1114                                                  (function-form-p item)))
1115                                   (gensym)))
1116                       (elt-var (gensym))
1117                       (position-var (gensym)))
1118                   `(let (,@(when item-var `((,item-var ,item)))
1119                          (,position-var 0))
1120                      (dolist (,elt-var ,sequence)
1121                        (,loop-test (funcall ,position-test ,(or item-var item)
1122                                             (funcall ,(or key '#'identity) ,elt-var))
1123                                    (return ,position-var))
1124                        (incf ,position-var)))))
1125                ((nx-form-typep sequence 'vector env)
1126                 (let ((item-var (unless (or (nx-form-constant-p item env)
1127                                             (and (equal position-test '#'funcall)
1128                                                  (function-form-p item)))
1129                                   (gensym)))
1130                       (sequence-var (gensym))
1131                       (position-var (gensym)))
1132                   `(let (,@(when item-var `((,item-var ,item)))
1133                          (,sequence-var ,sequence))
1134                      ,@(let ((type (nx-form-type sequence env)))
1135                          (unless (eq type t)
1136                            `((declare (type ,type ,sequence-var)))))
1137                      (dotimes (,position-var (length ,sequence-var))
1138                        (,loop-test (funcall ,position-test ,(or item-var item)
1139                                             (funcall ,(or key '#'identity)
1140                                                      (locally (declare (optimize (speed 3) (safety 0)))
1141                                                        (aref ,sequence ,position-var))))
1142                                    (return ,position-var))))))
1143                (t
1144                 (let ((position-function (if test-not
1145                                            'position-positional-test-not-key
1146                                            'position-positional-test-key))
1147                       (item-var (gensym))
1148                       (sequence-var (gensym))
1149                       (test-var (gensym))
1150                       (key-var (gensym)))
1151                   `(let ((,item-var ,item)
1152                          (,sequence-var ,sequence)
1153                          (,test-var ,(or test test-not))
1154                          (,key-var ,key))
1155                      (declare (dynamic-extent ,sequence-var ,test-var ,key-var))
1156                      (,position-function ,item-var ,sequence-var ,test-var ,key-var))))))
1157        call))
1158    call))
1159
1160;;; inline some cases of remove-if and remove-if-not
1161
1162(define-compiler-macro remove-if (&whole call &environment env &rest ignore)
1163  (declare (ignore ignore))
1164  (remove-if-transform call env))
1165
1166(define-compiler-macro remove-if-not (&whole call &environment env &rest ignore)
1167  (declare (ignore ignore))
1168  (remove-if-transform call env))
1169
1170(defun remove-if-transform (call env)
1171  (destructuring-bind (function test sequence &rest keys) call
1172    (if (constant-keywords-p keys)
1173      (destructuring-bind (&key from-end (start 0) end count (key '#'identity)) keys
1174        (if (and (eql start 0)
1175                 (null end)
1176                 (null from-end)
1177                 (null count)
1178                 (nx-form-typep sequence 'list env))
1179          ;; only do the list case, since it's hard to collect vector results
1180          (let ((temp-var (gensym))
1181                (result-var (gensym))
1182                (elt-var (gensym))
1183                (loop-test (ecase function (remove-if 'unless) (remove-if-not 'when))))
1184            `(the list
1185               (let* ((,temp-var (cons nil nil))
1186                      (,result-var ,temp-var))
1187                 (declare (dynamic-extent ,temp-var))
1188                 (dolist (,elt-var ,sequence (%cdr ,result-var))
1189                   (,loop-test (funcall ,test (funcall ,key ,elt-var))
1190                               (setq ,temp-var
1191                                     (%cdr
1192                                      (%rplacd ,temp-var (list ,elt-var)))))))))
1193          call))
1194      call)))
1195
1196
1197
1198(define-compiler-macro struct-set (&whole call &environment env struct offset new)
1199  (if (nx-inhibit-safety-checking env)
1200    `(%svset ,struct ,offset ,new)
1201    call))
1202
1203(define-compiler-macro zerop (arg &environment env)
1204  (let* ((z (if (nx-form-typep arg 'float env)
1205              (coerce 0 (nx-form-type arg env))
1206              0)))
1207    `(= ,arg ,z)))
1208
1209
1210(define-compiler-macro = (&whole w n0 &optional (n1 nil n1p) &rest more)
1211  (if (not n1p)
1212    `(require-type ,n0 'number)
1213    (if more
1214      w
1215      `(=-2 ,n0 ,n1))))
1216
1217(define-compiler-macro /= (&whole w n0 &optional (n1 nil n1p) &rest more)
1218  (if (not n1p)
1219    `(require-type ,n0 'number)
1220    (if more
1221      w
1222      `(/=-2 ,n0 ,n1))))
1223
1224(define-compiler-macro + (&optional (n0 nil n0p) (n1 nil n1p) &rest more)
1225  (if more
1226    `(+ (+-2 ,n0 ,n1) ,@more)
1227    (if n1p
1228      `(+-2 ,n0 ,n1)
1229      (if n0p
1230        `(require-type ,n0 'number)
1231        0))))
1232
1233(define-compiler-macro - (n0 &optional (n1 nil n1p) &rest more)
1234  (if more
1235    `(- (--2 ,n0 ,n1) ,@more)
1236    (if n1p
1237      `(--2 ,n0 ,n1)
1238      `(%negate ,n0))))
1239
1240(define-compiler-macro * (&optional (n0 nil n0p) (n1 nil n1p) &rest more)
1241  (if more
1242    `(*-2 ,n0 (* ,n1 ,@more))
1243    (if n1p
1244      `(*-2 ,n0 ,n1)
1245      (if n0p
1246        `(require-type ,n0 'number)
1247        1))))
1248
1249(define-compiler-macro / (&whole w n0 &optional (n1 nil n1p) &rest more)
1250  (if more
1251    w
1252    (if n1p
1253      `(/-2 ,n0 ,n1)
1254      `(%quo-1 ,n0))))
1255
1256;;; beware of limits - truncate of most-negative-fixnum & -1 ain't a
1257;;; fixnum - too bad
1258(define-compiler-macro truncate (&whole w &environment env n0 &optional (n1 nil n1p))
1259  (let ((*nx-form-type* t))
1260    (if (nx-form-typep n0 'fixnum env)
1261      (if (not n1p)
1262        n0
1263        (if (nx-form-typep n1 'fixnum env)
1264          `(%fixnum-truncate ,n0 ,n1)
1265          w))
1266      w)))
1267
1268(define-compiler-macro floor (&whole w &environment env n0 &optional (n1 nil n1p))
1269  (let ((*nx-form-type* t))
1270    (if (nx-form-typep n0 'fixnum env)
1271      (if (not n1p)
1272        n0
1273        (if (nx-form-typep n1 'fixnum env)
1274          `(%fixnum-floor ,n0 ,n1)
1275          w))
1276      w)))
1277
1278(define-compiler-macro round (&whole w &environment env n0 &optional (n1 nil n1p))
1279  (let ((*nx-form-type* t)) ; it doesn't matter what the result type is declared to be
1280    (if (nx-form-typep n0 'fixnum env)
1281      (if (not n1p)
1282        n0
1283        (if (nx-form-typep n1 'fixnum env)
1284          `(%fixnum-round ,n0 ,n1)
1285          w))
1286      w)))
1287
1288(define-compiler-macro ceiling (&whole w &environment env n0 &optional (n1 nil n1p))
1289  (let ((*nx-form-type* t))
1290    (if (nx-form-typep n0 'fixnum env)
1291      (if (not n1p)
1292        n0
1293        (if (nx-form-typep n1 'fixnum env)
1294          `(%fixnum-ceiling ,n0 ,n1)
1295          w))
1296      w)))
1297
1298(define-compiler-macro oddp (&whole w &environment env n0)
1299  (if (nx-form-typep n0 'fixnum env)
1300    `(logbitp 0 (the fixnum ,n0))
1301    w))
1302
1303(define-compiler-macro evenp (&whole w &environment env n0)
1304  (if (nx-form-typep n0 'fixnum env)
1305    `(not (logbitp 0 (the fixnum ,n0)))
1306    w))
1307
1308
1309(define-compiler-macro logandc2 (n0 n1)
1310  (let ((n1var (gensym))
1311        (n0var (gensym)))
1312    `(let ((,n0var ,n0)
1313           (,n1var ,n1))
1314       (logandc1 ,n1var ,n0var))))
1315
1316(define-compiler-macro logorc2 (n0 n1)
1317  (let ((n1var (gensym))
1318        (n0var (gensym)))
1319    `(let ((,n0var ,n0)
1320           (,n1var ,n1))
1321       (logorc1 ,n1var ,n0var))))
1322
1323(define-compiler-macro lognand (n0 n1)
1324  `(lognot (logand ,n0 ,n1)))
1325
1326(define-compiler-macro lognor (n0 n1)
1327  `(lognot (logior ,n0 ,n1)))
1328
1329
1330(defun transform-logop (whole identity binop &optional (transform-complement t))
1331  (destructuring-bind (op &optional (n0 nil n0p) (n1 nil n1p) &rest more) whole
1332    (if (and n1p (eql n0 identity))
1333      `(,op ,n1 ,@more)
1334      (if (and transform-complement n1p (eql n0 (lognot identity)))
1335        `(progn
1336           (,op ,n1 ,@more)
1337           ,(lognot identity))
1338        (if more
1339          (if (cdr more)
1340            whole
1341            `(,binop ,n0 (,binop ,n1 ,(car more))))
1342          (if n1p
1343            `(,binop ,n0 ,n1)
1344            (if n0p
1345              `(require-type ,n0 'integer)
1346              identity)))))))
1347
1348(define-compiler-macro logand (&whole w &rest all)
1349  (declare (ignore all))
1350  (transform-logop w -1 'logand-2))
1351
1352(define-compiler-macro logior (&whole w &rest all)
1353  (declare (ignore all))
1354  (transform-logop w 0 'logior-2))
1355
1356(define-compiler-macro logxor (&whole w &rest all)
1357  (declare (ignore all))
1358  (transform-logop w 0 'logxor-2 nil))
1359
1360(define-compiler-macro lognot (&whole w &environment env n1)
1361  (if (nx-form-typep n1 'fixnum env)
1362    `(%ilognot ,n1)
1363    w))
1364
1365(define-compiler-macro logtest (&whole w &environment env n1 n2)
1366  (if (and (nx-form-typep n1 'fixnum env)
1367           (nx-form-typep n2 'fixnum env))
1368    `(not (eql 0 (logand ,n1 ,n2)))
1369    w))
1370
1371
1372(defmacro defsynonym (from to)
1373  ;Should maybe check for circularities.
1374  `(progn
1375     (setf (compiler-macro-function ',from) nil)
1376     (let ((pair (assq ',from *nx-synonyms*)))
1377       (if pair (rplacd pair ',to)
1378           (push (cons ',from ',to)
1379                 *nx-synonyms*))
1380       ',to)))
1381
1382(defsynonym first car)
1383(defsynonym second cadr)
1384(defsynonym third caddr)
1385(defsynonym fourth cadddr)
1386(defsynonym rest cdr)
1387
1388
1389(defsynonym functionp lfunp)
1390(defsynonym null not)
1391(defsynonym char-int char-code)
1392
1393;;; Improvemets file by Bob Cassels
1394;;; Just what are "Improvemets", anyway ?
1395
1396;;; Optimize some CL sequence functions, mostly by inlining them in
1397;;; simple cases when the type of the sequence is known.  In some
1398;;; cases, dynamic-extent declarations are automatically inserted.
1399;;; For some sequence functions, if the type of the sequence is known
1400;;; at compile time, the function is inlined.  If the type isn't known
1401;;; but the call is "simple", a call to a faster (positional-arg)
1402;;; function is substituted.
1403
1404
1405(defun nx-form-sequence-iterator (sequence-form env)
1406  (cond ((nx-form-typep sequence-form 'vector env) 'dovector)
1407        ((nx-form-typep sequence-form 'list env) 'dolist)))
1408
1409(defun function-form-p (form)
1410   ;; c.f. quoted-form-p
1411   (and (consp form)
1412        (eq (%car form) 'function)
1413        (consp (%cdr form))
1414        (null (%cdr (%cdr form)))))
1415
1416
1417;; Return a form that checks to see if THING is if type CTYPE, or
1418;; NIL if we can't do that for some reason.
1419(defun optimize-ctypep (thing ctype)
1420  (when (eq *target-backend* *host-backend*)
1421    (typecase ctype
1422      (numeric-ctype
1423       (cond ((eq :real (numeric-ctype-complexp ctype))
1424              (let* ((low (numeric-ctype-low ctype))
1425                     (high (numeric-ctype-high ctype))
1426                     (class (numeric-ctype-class ctype))
1427                     (format (numeric-ctype-format ctype))
1428                     (type (if (eq class 'float)
1429                             (or format class)
1430                             (or class 'real))))
1431                (cond ((and low (eql low high) (or (not (eq class 'float))
1432                                                   format))
1433                       `(eql ,thing ,low))
1434                      ((and (eq type 'float)
1435                            (or low high)
1436                            (or (null low)
1437                                (typep low 'single-float)
1438                                (not (null (ignore-errors
1439                                             (coerce (if (atom low)
1440                                                       low
1441                                                       (car low))
1442                                                     'single-float)))))
1443                            (or (null high)
1444                                (typep high 'single-float)
1445                                (not (null (ignore-errors
1446                                             (coerce (if (atom high)
1447                                                       high
1448                                                       (car high))
1449                                                     'single-float))))))
1450                       (let* ((temp (gensym)))
1451                         (flet ((bounded-float (type low high)
1452                                  `(,type
1453                                    ,(if low
1454                                         (if (listp low)
1455                                           (list (coerce (car low) type))
1456                                           (coerce low type))
1457                                         '*)
1458                                    ,(if high
1459                                         (if (listp high)
1460                                           (list (coerce (car high) type))
1461                                           (coerce high type))
1462                                         '*))))
1463                         `(let* ((,temp ,thing))
1464                           (or (typep ,temp ',(bounded-float 'single-float low high))
1465                            (typep ,temp ',(bounded-float 'double-float low high)))))))
1466                      (t
1467                       (let* ((temp (gensym)))
1468                         (if (and (typep low 'fixnum) (typep high 'fixnum)
1469                                  (eq class 'integer))
1470                           (setq type 'fixnum))
1471                         (if (or low high)
1472                           `(let* ((,temp ,thing))
1473                             (and (typep ,temp ',type)
1474                              ,@(if low `((,(if (consp low) '> '>=) (the ,type ,temp) ,(if (consp low) (car low) low))))
1475                              ,@(if high `((,(if (consp high) '< '<=) (the ,type ,temp) ,(if (consp high) (car high) high))))))
1476                           `(typep ,thing ',type)))))))
1477             (t `(numeric-%%typep ,thing ,ctype))))
1478      (array-ctype
1479       (or
1480        (let* ((typecode (array-ctype-typecode ctype))
1481               (dims (array-ctype-dimensions ctype)))
1482          (cond ((and typecode (consp dims) (null (cdr dims)))
1483                 (case (array-ctype-complexp ctype)
1484                   ((nil)
1485                    (if (eq (car dims) '*)
1486                      `(eql (typecode ,thing) ,typecode)
1487                      (let* ((temp (gensym)))
1488                        `(let* ((,temp ,thing))
1489                          (and (eql (typecode ,temp) ,typecode)
1490                           (eq (uvsize ,temp) ,(car dims)))))))
1491                   ((* :maybe)
1492                    (let* ((temp (gensym))
1493                           (tempcode (gensym)))
1494                      `(let* ((,temp ,thing)
1495                              (,tempcode (typecode ,temp)))
1496                        (or (and (eql ,tempcode ,typecode)
1497                             ,@(unless (eq (car dims) '*)
1498                                       `((eq (uvsize ,temp) ,(car dims)))))
1499                         (and (eql ,tempcode target::subtag-vectorH)
1500                          (eql (ldb target::arrayH.flags-cell-subtag-byte (the fixnum (%svref ,temp target::arrayH.flags-cell))) ,typecode)
1501                          ,@(unless (eq (car dims) '*)
1502                                    `((eq (%svref ,temp target::vectorH.logsize-cell) ,(car dims)))))))))))))
1503        `(values (array-%%typep ,thing ,ctype)))))))
1504
1505
1506(defun optimize-typep (thing type env)
1507  ;; returns a new form, or nil if it can't optimize
1508  (let ((ctype (specifier-type-if-known type env :whine t)))
1509    (when ctype
1510      (let* ((type (type-specifier ctype))
1511             (predicate (if (typep type 'symbol) (type-predicate type))))
1512        (if (and predicate (symbolp predicate))
1513          `(,predicate ,thing)
1514          (let* ((pair (assq type *istruct-cells*))
1515                 (class (and pair (%wrapper-class (istruct-cell-info pair)))))
1516            (if (and class (not (%class-direct-subclasses class)))
1517              `(istruct-typep ,thing ',type)             
1518              (or (optimize-ctypep thing ctype)
1519                  (cond ((symbolp type)
1520                         (cond ((%deftype-expander type)
1521                                ;; recurse here, rather than returning the
1522                                ;; partially-expanded form mostly since it doesn't
1523                                ;; seem to further optimize the result otherwise
1524                                (let ((expanded-type (type-expand type)))
1525                                  (or (optimize-typep thing expanded-type env)
1526                                      ;; at least do the first expansion
1527                                      `(typep ,thing ',expanded-type))))
1528                               ((structure-class-p type env)
1529                                `(structure-typep ,thing ',(find-class-cell type t)))
1530                               ((find-class type nil env)
1531                                ;; If we know for sure that the class
1532                                ;; is one whose instances are all
1533                                ;; STANDARD-INSTANCEs (not funcallable,
1534                                ;; not foreign), we can use
1535                                ;; STD-INSTANCE-CLASS-CELL-TYPEP, which
1536                                ;; can be a little faster then the more
1537                                ;; general CLASS-CELL-TYPEP.  We can
1538                                ;; only be sure of that if the class
1539                                ;; exists (as a non-COMPILE-TIME-CLASS)
1540                                (let* ((class (find-class type nil nil))
1541                                       (fname 
1542                                        (if (and class
1543                                                 (subtypep class 'standard-object)
1544                                                 (not (subtypep class 'foreign-standard-object))
1545                                                 (not (subtypep class 'funcallable-standard-object)))
1546                                          'std-instance-class-cell-typep
1547                                          'class-cell-typep)))
1548                                  `(,fname ,thing (load-time-value (find-class-cell ',type t)))))
1549                               ((info-type-builtin type) ; bootstrap troubles here?
1550                                `(builtin-typep ,thing (load-time-value (find-builtin-cell ',type))))
1551                               (t nil)))
1552                        ((consp type)
1553                         (cond
1554                           ((info-type-builtin type) ; byte types
1555                            `(builtin-typep ,thing (load-time-value (find-builtin-cell ',type))))
1556                           (t
1557                            (case (%car type)
1558                              (satisfies `(funcall ',(cadr type) ,thing))
1559                              (eql `(eql ,thing ',(cadr type)))
1560                              (member `(not (null (member ,thing ',(%cdr type)))))
1561                              (not `(not (typep ,thing ',(cadr type))))
1562                              ((or and)
1563                               (let ((thing-sym (gensym)))
1564                                 `(let ((,thing-sym ,thing))
1565                                   (,(%car type)
1566                                    ,@(mapcar #'(lambda (type-spec)
1567                                                  (or (optimize-typep thing-sym type-spec env)
1568                                                      `(typep ,thing-sym ',type-spec)))
1569                                              (%cdr type))))))
1570                              ((signed-byte unsigned-byte integer mod) ; more byte types
1571                               `(builtin-typep ,thing (load-time-value (find-builtin-cell ',type))))
1572                              (t nil)))))
1573                        (t nil))))))))))
1574
1575(define-compiler-macro typep  (&whole call &environment env thing type &optional e)
1576  (if (nx-form-constant-p type env)
1577    (let ((type-val (nx-form-constant-value type env)))
1578      (if (eq type-val t)
1579        `(progn ,thing t)
1580        (if (and (nx-form-constant-p thing env)
1581                 (specifier-type-if-known type-val env))
1582          (typep (nx-form-constant-value thing env) type-val env)
1583          (or (and (null e) (optimize-typep thing type-val env))
1584              call))))
1585    call))
1586
1587(define-compiler-macro structure-typep (&whole w thing type)
1588  (if (not (quoted-form-p type))
1589    (progn
1590      (warn "Non-quoted structure-type in ~s" w)
1591      w)
1592    (let* ((type (nx-unquote type)))
1593      (if (symbolp type)
1594        `(structure-typep ,thing ',(find-class-cell type t))
1595        w))))
1596
1597(define-compiler-macro true (&rest args)
1598  `(progn
1599    ,@args
1600    t))
1601
1602
1603(define-compiler-macro false (&rest args)
1604  `(progn
1605    ,@args
1606    nil))
1607
1608(define-compiler-macro find-class (&whole call type &optional (errorp t) env)
1609  (if (and (quoted-form-p type)(not *dont-find-class-optimize*)(not env))
1610      `(class-cell-find-class (load-time-value (find-class-cell ,type t)) ,errorp)
1611    call))
1612
1613
1614(define-compiler-macro gcd (&whole call &optional (n0 nil n0-p) (n1 nil n1-p) &rest rest)
1615  (if rest
1616    call
1617    (if n1-p
1618      `(gcd-2 ,n0 ,n1)
1619      (if n0-p
1620        `(%integer-abs ,n0)
1621        0))))
1622
1623(define-compiler-macro lcm (&whole call &optional (n0 nil n0-p) (n1 nil n1-p) &rest rest)
1624  (if rest
1625    call
1626    (if n1-p
1627      `(lcm-2 ,n0 ,n1)
1628      (if n0-p
1629        `(%integer-abs ,n0)
1630        1))))
1631
1632(define-compiler-macro max (&whole call &environment env n0 &optional (n1 nil n1-p) &rest rest)
1633  (if rest
1634    call
1635    (if n1-p
1636      (if (and (nx-form-typep n0 'fixnum env)(nx-form-typep n1 'fixnum env))
1637        `(imax-2 ,n0 ,n1)
1638        `(max-2 ,n0 ,n1))
1639      `(require-type ,n0 'real))))
1640
1641(define-compiler-macro max-2 (n0 n1)
1642  (let* ((g0 (gensym))
1643         (g1 (gensym)))
1644   `(let* ((,g0 ,n0)
1645           (,g1 ,n1))
1646      (if (> ,g0 ,g1) ,g0 ,g1))))
1647
1648(define-compiler-macro imax-2 (n0 n1)
1649  (let* ((g0 (gensym))
1650         (g1 (gensym)))
1651   `(let* ((,g0 ,n0)
1652           (,g1 ,n1))
1653      (if (%i> ,g0 ,g1) ,g0 ,g1))))
1654
1655
1656
1657
1658(define-compiler-macro min (&whole call &environment env n0 &optional (n1 nil n1-p) &rest rest)
1659  (if rest
1660    call
1661    (if n1-p
1662      (if (and (nx-form-typep n0 'fixnum env)(nx-form-typep n1 'fixnum env))
1663        `(imin-2 ,n0 ,n1)
1664        `(min-2 ,n0 ,n1))
1665      `(require-type ,n0 'real))))
1666
1667(define-compiler-macro min-2 (n0 n1)
1668  (let* ((g0 (gensym))
1669         (g1 (gensym)))
1670   `(let* ((,g0 ,n0)
1671           (,g1 ,n1))
1672      (if (< ,g0 ,g1) ,g0 ,g1))))
1673
1674(define-compiler-macro imin-2 (n0 n1)
1675  (let* ((g0 (gensym))
1676         (g1 (gensym)))
1677   `(let* ((,g0 ,n0)
1678           (,g1 ,n1))
1679      (if (%i< ,g0 ,g1) ,g0 ,g1))))
1680
1681
1682(defun eq-test-p (test)
1683  (or (equal test ''eq) (equal test '#'eq)))
1684
1685(defun eql-test-p (test)
1686  (or (equal test ''eql) (equal test '#'eql)))
1687
1688(define-compiler-macro adjoin (&whole whole elt list &rest keys)
1689  (if (constant-keywords-p keys)
1690    (destructuring-bind (&key (test ''eql) test-not key) keys
1691      (or (and (null test-not)
1692               (null key)
1693               (cond ((eq-test-p test)
1694                      `(adjoin-eq ,elt ,list))
1695                     ((eql-test-p test)
1696                      `(adjoin-eql ,elt ,list))
1697                     (t nil)))
1698          whole))
1699    whole))
1700
1701(define-compiler-macro union (&whole whole list1 list2 &rest keys)
1702  (if (constant-keywords-p keys)
1703    (destructuring-bind (&key (test ''eql) test-not key) keys
1704      (or (and (null test-not)
1705               (null key)
1706               (cond ((eq-test-p test)
1707                      `(union-eq ,list1 ,list2))
1708                     ((eql-test-p test)
1709                      `(union-eql ,list1 ,list2))
1710                     (t nil)))
1711          whole))
1712    whole))
1713
1714(define-compiler-macro slot-value (&whole whole &environment env
1715                                          instance slot-name-form)
1716  (declare (ignore env))
1717  (let* ((name (and (quoted-form-p slot-name-form)
1718                    (typep (cadr slot-name-form) 'symbol)
1719                    (cadr slot-name-form))))
1720    (if name
1721      `(slot-id-value ,instance (load-time-value (ensure-slot-id ',name)))
1722      whole)))
1723
1724
1725(define-compiler-macro set-slot-value (&whole whole &environment env
1726                                          instance slot-name-form value-form)
1727  (declare (ignore env))
1728  (let* ((name (and (quoted-form-p slot-name-form)
1729                    (typep (cadr slot-name-form) 'symbol)
1730                    (cadr slot-name-form))))
1731    (if name
1732      `(set-slot-id-value
1733        ,instance
1734        (load-time-value (ensure-slot-id ',name))
1735        ,value-form)
1736      whole)))
1737
1738
1739(define-compiler-macro slot-boundp (&whole whole instance slot-name-form)
1740  (let* ((name (and (quoted-form-p slot-name-form)
1741                    (typep (cadr slot-name-form) 'symbol)
1742                    (cadr slot-name-form))))
1743    (if name
1744      `(slot-id-boundp ,instance (load-time-value (ensure-slot-id ',name)))
1745      whole)))
1746
1747(defsynonym %get-unsigned-byte %get-byte)
1748(defsynonym %get-unsigned-word %get-word)
1749(defsynonym %get-signed-long %get-long)
1750
1751
1752
1753
1754(define-compiler-macro arrayp (arg)
1755  `(>= (the fixnum (typecode ,arg))
1756    ,(nx-lookup-target-uvector-subtag :array-header)))
1757
1758(define-compiler-macro vectorp (arg)
1759  `(>= (the fixnum (typecode ,arg))
1760    ,(nx-lookup-target-uvector-subtag :vector-header)))
1761
1762
1763
1764(define-compiler-macro fixnump (arg)
1765  (let* ((fixnum-tag
1766          (arch::target-fixnum-tag (backend-target-arch *target-backend*))))
1767    `(eql (lisptag ,arg) ,fixnum-tag)))
1768
1769
1770
1771(define-compiler-macro double-float-p (n)
1772  (let* ((tag (arch::target-double-float-tag (backend-target-arch *target-backend*))))
1773    `(eql (typecode ,n) ,tag)))
1774
1775
1776(define-compiler-macro short-float-p (n)
1777  (let* ((arch (backend-target-arch *target-backend*))
1778         (tag (arch::target-single-float-tag arch))
1779         (op (if (arch::target-single-float-tag-is-subtag arch)
1780               'typecode
1781               'fulltag)))
1782    `(eql (,op ,n) ,tag)))
1783
1784
1785(define-compiler-macro floatp (n)
1786  (let* ((typecode (make-symbol "TYPECODE"))
1787         (arch (backend-target-arch *target-backend*))
1788         (single (arch::target-single-float-tag arch))
1789         (double (arch::target-double-float-tag arch)))
1790    `(let* ((,typecode (typecode ,n)))
1791       (declare (fixnum ,typecode))
1792       (or (= ,typecode ,single)
1793           (= ,typecode ,double)))))
1794
1795(define-compiler-macro functionp (n)
1796  (let* ((arch (backend-target-arch *target-backend*))
1797         (tag (arch::target-function-tag arch))
1798         (op (if (arch::target-function-tag-is-subtag arch)
1799               'typecode
1800               'fulltag)))
1801    `(eql (,op  ,n) ,tag)))
1802
1803(define-compiler-macro symbolp (s)
1804  (let* ((arch (backend-target-arch *target-backend*))
1805         (symtag (arch::target-symbol-tag arch))
1806         (op (if (arch::target-symbol-tag-is-subtag arch)
1807               'typecode
1808               'fulltag))
1809         (niltag (arch::target-null-tag arch)))
1810    (if (eql niltag symtag)
1811      `(eql (,op ,s) ,symtag)
1812      (let* ((sym (gensym)))
1813        `(let* ((,sym ,s))
1814          (if ,sym (eql (,op ,sym) ,symtag) t))))))
1815
1816;;; If NIL isn't tagged as a symbol, assume that LISPTAG only looks
1817;;; at bits that NIL shares with a cons.
1818(define-compiler-macro listp (n)
1819  (let* ((arch (backend-target-arch *target-backend*))
1820         (cons-tag (arch::target-cons-tag arch))
1821         (nil-tag  (arch::target-null-tag arch))
1822         (symbol-tag (arch::target-symbol-tag arch)))
1823    (if (= nil-tag symbol-tag)
1824      (let* ((nvar (gensym)))
1825        `(let* ((,nvar ,n))
1826          (if ,nvar (consp ,nvar) t)))
1827      `(eql (lisptag ,n) ,cons-tag))))
1828
1829(define-compiler-macro consp (&whole call n)
1830  (let* ((arch (backend-target-arch *target-backend*))
1831         (cons-tag (arch::target-cons-tag arch))
1832         (nil-tag (arch::target-null-tag arch)))
1833    (if (= nil-tag cons-tag)
1834      call
1835      `(eql (fulltag ,n) ,cons-tag))))
1836
1837(define-compiler-macro bignump (n)
1838  `(eql (typecode ,n) ,(nx-lookup-target-uvector-subtag :bignum)))
1839
1840(define-compiler-macro ratiop (n)
1841  `(eql (typecode ,n) ,(nx-lookup-target-uvector-subtag :ratio)))
1842
1843(define-compiler-macro complexp (n)
1844  `(eql (typecode ,n) ,(nx-lookup-target-uvector-subtag :complex)))
1845
1846(define-compiler-macro macptrp (n)
1847  `(eql (typecode ,n) ,(nx-lookup-target-uvector-subtag :macptr)))
1848
1849(define-compiler-macro basic-stream-p (n)
1850  `(eql (typecode ,n) ,(nx-lookup-target-uvector-subtag :basic-stream)))
1851
1852(define-compiler-macro aref (&whole call a &rest subscripts &environment env)
1853  (let* ((ctype (if (nx-form-typep a 'array env)
1854                  (specifier-type (nx-form-type a env) env)))
1855         (ectype (typecase ctype
1856                   (array-ctype (array-ctype-specialized-element-type ctype))
1857                   (union-ctype (when (every #'array-ctype-p (union-ctype-types ctype))
1858                                  (%type-union
1859                                   (mapcar (lambda (ct) (array-ctype-specialized-element-type ct))
1860                                           (union-ctype-types ctype)))))))
1861         (etype (and ectype (type-specifier ectype)))
1862         (useful (unless (or (eq etype *) (eq etype t))
1863                   etype)))
1864    (if (= 2 (length subscripts))
1865      (setq call `(%aref2 ,a ,@subscripts))
1866      (if (= 3 (length subscripts))
1867        (setq call `(%aref3 ,a ,@subscripts))))
1868    (if useful
1869      `(the ,useful ,call)
1870      call)))
1871
1872
1873(define-compiler-macro aset (&whole call a &rest subs&val)
1874  (if (= 3 (length subs&val))
1875    `(%aset2 ,a ,@subs&val)
1876    (if (= 4 (length subs&val))
1877      `(%aset3 ,a ,@subs&val)
1878      call)))
1879
1880
1881(define-compiler-macro make-sequence (&whole call typespec len &rest keys &key initial-element)
1882  (declare (ignore typespec len keys initial-element))
1883  call)
1884
1885(define-compiler-macro make-string (&whole call &environment env size &rest keys)
1886  (if (constant-keywords-p keys)
1887    (destructuring-bind (&key (element-type () element-type-p)
1888                              (initial-element () initial-element-p))
1889                        keys
1890      (if (and element-type-p
1891               (nx-form-constant-p element-type env))
1892        (let* ((element-type (nx-form-constant-value element-type env)))
1893          (if (subtypep element-type 'base-char)
1894            `(allocate-typed-vector :simple-string ,size ,@(if initial-element-p `(,initial-element)))
1895            call))
1896        (if (not element-type-p)
1897          `(allocate-typed-vector :simple-string ,size ,@(if initial-element-p `(,initial-element)))
1898          call)))
1899    call))
1900
1901(define-compiler-macro make-string-output-stream (&whole whole &rest keys)
1902  (if (null keys)
1903    '(make-simple-string-output-stream)
1904    whole))
1905
1906
1907(define-compiler-macro write-string (&environment env &whole call
1908                                                  string &optional (stream nil) &rest keys)
1909  (if (nx-form-typep string 'simple-string env)
1910    (if keys
1911      `((lambda (string stream &key (start 0) end)
1912          (write-simple-string string stream start end))
1913        ,string ,stream ,@keys)
1914      `(write-simple-string ,string ,stream 0 nil))
1915    call))
1916
1917(define-compiler-macro format (&environment env &whole call stream string &rest args)
1918  (if (stringp string)
1919    (cond ((and (string-equal string "~a") args (null (cdr args)))
1920           (destructuring-bind (object) args
1921             (cond ((null stream)
1922                    `(princ-to-string ,object))
1923                   ((or (eq stream t) (nx-form-typep stream 'stream env))
1924                    `(progn (princ ,object ,(and (neq stream t) stream)) nil))
1925                   (t `(let ((stream ,stream)
1926                             (object ,object))
1927                         (if (or (null stream) (stringp stream))
1928                           (format-to-string stream ,string object)
1929                           (progn (princ object (and (neq stream t) stream)) nil)))))))
1930          ((and (string-equal string "~s") args (null (cdr args)))
1931           (destructuring-bind (object) args
1932             (cond ((null stream)
1933                    `(prin1-to-string ,object))
1934                   ((or (eq stream t) (nx-form-typep stream 'stream env))
1935                    `(progn (prin1 ,object ,(and (neq stream t) stream)) nil))
1936                   (t `(let ((stream ,stream)
1937                             (object ,object))
1938                         (if (or (null stream) (stringp stream))
1939                           (format-to-string stream ,string object)
1940                           (progn (prin1 object (and (neq stream t) stream)) nil)))))))
1941          ((and (null (position #\~ string)) (null args))
1942           (cond ((null stream)
1943                  string)
1944                 ((or (eq stream t) (nx-form-typep stream 'stream env))
1945                  `(progn (write-string ,string ,(and (neq stream t) stream)) nil))
1946                 (t `(let ((stream ,stream))
1947                       (if (or (null stream) (stringp stream))
1948                         (format-to-string stream ,string)
1949                         (progn (write-string ,string (and (neq stream t) stream)) nil))))))
1950          ((let ((new (format-string-sans~newlines string)))
1951             (and (neq new string) (setq string new)))
1952           `(format ,stream ,string ,@args))
1953          ((optimize-format-call stream string args env))
1954          (t call))
1955    call))
1956
1957(defun format-string-sans~newlines (string)
1958  (loop as pos = 0 then (position #\Newline string :start pos) while pos
1959        as ch = (and (> pos 0) (schar string (1- pos)))
1960        do (cond ((not (or (eq ch #\~)
1961                           (and (or (eq ch #\:) (eq ch #\@))
1962                                (> pos 1) (eq (schar string (- pos 2)) #\~))))
1963                  (incf pos))
1964                 ((eq ch #\:)
1965                  (decf pos 2)
1966                  (setq string (%str-cat (subseq string 0 pos) (subseq string (+ pos 3)))))
1967                 ((eq ch #\@)
1968                  (setq string (%str-cat (subseq string 0 (- pos 2))
1969                                         "~%"
1970                                         (subseq string (or
1971                                                         (position-if-not #'whitespacep string
1972                                                                          :start (1+ pos))
1973                                                         (1+ pos))))))
1974                  ((eq ch #\~)
1975                  (decf pos)
1976                  (setq string (%str-cat (subseq string 0 pos)
1977                                         (subseq string (or (position-if-not #'whitespacep string
1978                                                                         :start (1+ pos))
1979                                                            (1+ pos))))))))
1980  string)
1981
1982(defun count-known-format-args (string start end)
1983  (declare (fixnum end))
1984  (loop with count = 0
1985        do (setq start (position #\~ string :start start :end end))
1986        when (null start)
1987          do (return count)
1988        unless (< (incf start) end)
1989          do (return nil)
1990        do (let ((ch (aref string start)))
1991             (cond ((memq ch '(#\a #\A #\s #\S)) (incf count))
1992                   ((memq ch '(#\~ #\% #\&)))
1993                   (t (return nil)))
1994             (incf start))))
1995
1996(defun optimize-format-call (stream string args env)
1997  (let* ((start (or (search "~/" string)
1998                    (return-from optimize-format-call nil)))
1999         (ipos (+ start 2))
2000         (epos (or (position #\/ string :start ipos)
2001                   (return-from optimize-format-call nil)))
2002         (nargs (or (count-known-format-args string 0 start)
2003                    (return-from optimize-format-call nil))))
2004    (when (and
2005           ;; Must be able to split args
2006           (< nargs (length args))
2007           ;; Don't deal with packages
2008           (not (position #\: string :start ipos :end epos)))
2009      (let* ((func (intern (string-upcase (subseq string ipos epos)) :cl-user))
2010             (prev (and (< 0 start) (subseq string 0 start)))
2011             (prev-args (subseq args 0 nargs))
2012             (rest (and (< (1+ epos) (length string)) (subseq string (1+ epos))))
2013             (rest-args (nthcdr nargs args))
2014             (obj (pop rest-args))
2015             (stream-var (gensym))
2016             (body `(,@(and prev `((format ,stream-var ,prev ,@prev-args)))
2017                       (,func ,stream-var ,obj nil nil)
2018                       ,(if rest `(format ,stream-var ,rest ,@rest-args) `nil))))
2019        (cond ((null stream)
2020               `(with-output-to-string (,stream-var)
2021                  (declare (type stream ,stream-var))
2022                  ,@body))
2023              ((or (eq stream t) (nx-form-typep stream 'stream env))
2024               `(let ((,stream-var ,(if (eq stream t) '*standard-output* stream)))
2025                  (declare (type stream ,stream-var))
2026                  ,@body))
2027              (t
2028               `(let ((,stream-var ,stream))
2029                  (if (or (null ,stream-var) (stringp ,stream-var))
2030                    (format-to-string ,stream-var ,string ,@args)
2031                    (let ((,stream-var
2032                           (if (eq ,stream-var t) *standard-output* ,stream-var)))
2033                      ;; For the purposes of body, it's ok to assume stream-var
2034                      ;; is a stream. method dispatch will signal any errors
2035                      ;; at runtime if it's not true...
2036                      (declare (type stream ,stream-var))
2037                      ,@body)))))))))
2038
2039
2040(define-compiler-macro sbit (&whole call v &optional sub0 &rest others)
2041  (if (and sub0 (null others))
2042    `(aref (the simple-bit-vector ,v) ,sub0)
2043    call))
2044
2045(define-compiler-macro %sbitset (&whole call v sub0 &optional (newval nil newval-p) &rest newval-was-really-sub1)
2046  (if (and newval-p (not newval-was-really-sub1) )
2047    `(setf (aref (the simple-bit-vector ,v) ,sub0) ,newval)
2048    call))
2049
2050(define-compiler-macro simple-base-string-p (thing)
2051  `(= (the fixnum (typecode ,thing)) ,(nx-lookup-target-uvector-subtag :simple-string)))
2052
2053(define-compiler-macro simple-string-p (thing)
2054  `(simple-base-string-p ,thing))
2055
2056(define-compiler-macro stringp (thing)
2057  `(base-string-p  ,thing))
2058
2059(define-compiler-macro base-string-p (thing)
2060  (let* ((gthing (gensym))
2061         (gtype (gensym)))
2062    `(let* ((,gthing ,thing)
2063            (,gtype (typecode ,gthing)))
2064      (declare (type (unsigned-byte 8) ,gtype))
2065      (if (= ,gtype ,(nx-lookup-target-uvector-subtag :vector-header))
2066        (= (the (unsigned-byte 8)
2067             (ldb target::arrayH.flags-cell-subtag-byte (the fixnum (%svref ,gthing target::arrayH.flags-cell))))
2068           ,(nx-lookup-target-uvector-subtag :simple-string))
2069        (= ,gtype ,(nx-lookup-target-uvector-subtag :simple-string))))))
2070
2071
2072
2073(defsetf %misc-ref %misc-set)
2074
2075(define-compiler-macro lockp (lock)
2076  (let* ((tag (nx-lookup-target-uvector-subtag :lock)))
2077    `(eq ,tag (typecode ,lock))))
2078
2079(define-compiler-macro structurep (s)
2080  (let* ((tag (nx-lookup-target-uvector-subtag :struct)))
2081    `(eq ,tag (typecode ,s))))
2082 
2083
2084(define-compiler-macro integerp (thing)
2085  (let* ((typecode (gensym))
2086         (fixnum-tag (arch::target-fixnum-tag (backend-target-arch *target-backend*)))
2087         (bignum-tag (nx-lookup-target-uvector-subtag :bignum)))
2088    `(let* ((,typecode (typecode ,thing)))
2089      (declare (fixnum ,typecode))
2090      (if (= ,typecode ,fixnum-tag)
2091        t
2092        (= ,typecode ,bignum-tag)))))
2093
2094(define-compiler-macro realp (&whole call x)
2095  (if (not (eq *host-backend* *target-backend*))
2096    call
2097    (let* ((typecode (gensym)))
2098      `(let* ((,typecode (typecode ,x)))
2099        (declare (type (unsigned-byte 8) ,typecode))
2100        #+(or ppc32-target x8632-target)
2101        (or (= ,typecode target::tag-fixnum)
2102         (and (>= ,typecode target::min-numeric-subtag)
2103          (<= ,typecode target::max-real-subtag)))
2104        #+ppc64-target
2105        (if (<= ,typecode ppc64::subtag-double-float)
2106          (logbitp (the (integer 0 #.ppc64::subtag-double-float) ,typecode)
2107                   (logior (ash 1 ppc64::tag-fixnum)
2108                           (ash 1 ppc64::subtag-single-float)
2109                           (ash 1 ppc64::subtag-double-float)
2110                           (ash 1 ppc64::subtag-bignum)
2111                           (ash 1 ppc64::subtag-ratio))))
2112        #+x8664-target
2113        (if (<= ,typecode x8664::subtag-double-float)
2114          (logbitp (the (integer 0 #.x8664::subtag-double-float) ,typecode)
2115                   (logior (ash 1 x8664::tag-fixnum)
2116                           (ash 1 x8664::subtag-bignum)
2117                           (ash 1 x8664::tag-single-float)
2118                           (ash 1 x8664::subtag-double-float)
2119                           (ash 1 x8664::subtag-ratio))))))))
2120
2121(define-compiler-macro %composite-pointer-ref (size pointer offset)
2122  (if (constantp size)
2123    `(%inc-ptr ,pointer ,offset)
2124    `(progn
2125      ,size
2126      (%inc-ptr ,pointer ,offset))))
2127
2128
2129(define-compiler-macro char= (&whole call ch &optional (other nil other-p) &rest others)
2130  (if (null others)
2131    (if other-p
2132      `(eq (char-code ,ch) (char-code ,other))
2133      `(progn (char-code ,ch) t))
2134    (if (null (cdr others))
2135      (let* ((third (car others))
2136             (code (gensym))
2137             (code2 (gensym))
2138             (code3 (gensym)))
2139        `(let* ((,code (char-code ,ch))
2140                (,code2 (char-code ,other))
2141                (,code3 (char-code ,third)))
2142          (and (eq ,code ,code2)
2143           (eq ,code2 ,code3))))
2144      call)))
2145
2146(define-compiler-macro char-equal (&whole call ch &optional (other nil other-p) &rest others)
2147  (if (null others)
2148    (if other-p
2149      `(eq (%char-code-upcase (char-code ,ch)) (%char-code-upcase (char-code ,other)))
2150      `(progn (char-code ,ch) t))
2151    (if (null (cdr others))
2152      (let* ((third (car others))
2153             (code (gensym))
2154             (code2 (gensym))
2155             (code3 (gensym)))
2156        `(let* ((,code (%char-code-upcase (char-code ,ch)))
2157                (,code2 (%char-code-upcase (char-code ,other)))
2158                (,code3 (%char-code-upcase (char-code ,third))))
2159          (and (eq ,code ,code2)
2160           (eq ,code ,code3))))
2161      call)))
2162
2163(define-compiler-macro char/= (&whole call ch &optional (other nil other-p) &rest others)
2164  (if (null others)
2165    (if other-p
2166      `(not (eq (char-code ,ch) (char-code ,other)))
2167      `(progn (char-code ,ch) t))
2168    call))
2169
2170
2171(define-compiler-macro char< (&whole call ch &optional (other nil other-p) &rest others)
2172  (if (null others)
2173    (if other-p
2174      `(< (the fixnum (char-code ,ch)) (the fixnum (char-code ,other)))
2175      `(progn (char-code ,ch) t))
2176    (if (null (cdr others))
2177      (let* ((third (car others))
2178             (code (gensym))
2179             (code2 (gensym))
2180             (code3 (gensym)))
2181        ;; We have to evaluate all forms for side-effects.
2182        ;; Hopefully, there won't be any
2183        `(let* ((,code (char-code ,ch))
2184                (,code2 (char-code ,other))
2185                (,code3 (char-code ,third)))
2186          (declare (fixnum ,code ,code2 ,code3))
2187          (and (< ,code ,code2)
2188           (< ,code2 ,code3))))
2189      call)))
2190
2191(define-compiler-macro char<= (&whole call ch &optional (other nil other-p) &rest others)
2192  (if (null others)
2193    (if other-p
2194      `(<= (the fixnum (char-code ,ch)) (the fixnum (char-code ,other)))
2195      `(progn (char-code ,ch) t))
2196    (if (null (cdr others))
2197      (let* ((third (car others))
2198             (code (gensym))
2199             (code2 (gensym))
2200             (code3 (gensym)))
2201        `(let* ((,code (char-code ,ch))
2202                (,code2 (char-code ,other))
2203                (,code3 (char-code ,third)))
2204          (declare (fixnum ,code ,code2 ,code3))
2205          (and (<= ,code ,code2)
2206           (<= ,code2 ,code3))))
2207      call)))
2208
2209(define-compiler-macro char> (&whole call ch &optional (other nil other-p) &rest others)
2210  (if (null others)
2211    (if other-p
2212      `(> (the fixnum (char-code ,ch)) (the fixnum (char-code ,other)))
2213      `(progn (char-code ,ch) t))
2214    (if (null (cdr others))
2215      (let* ((third (car others))
2216             (code (gensym))
2217             (code2 (gensym))
2218             (code3 (gensym)))
2219        `(let* ((,code (char-code ,ch))
2220                (,code2 (char-code ,other))
2221                (,code3 (char-code ,third)))
2222          (declare (fixnum ,code ,code2 ,code3))
2223          (and (> ,code ,code2)
2224           (> ,code2 ,code3))))
2225      call)))
2226
2227(define-compiler-macro char>= (&whole call ch &optional (other nil other-p) &rest others)
2228  (if (null others)
2229    (if other-p
2230      `(>= (the fixnum (char-code ,ch)) (the fixnum (char-code ,other)))
2231      `(progn (char-code ,ch) t))
2232    (if (null (cdr others))
2233      (let* ((third (car others))
2234             (code (gensym))
2235             (code2 (gensym))
2236             (code3 (gensym)))
2237        `(let* ((,code (char-code ,ch))
2238                (,code2 (char-code ,other))
2239                (,code3 (char-code ,third)))
2240          (declare (fixnum ,code ,code2 ,code3))
2241          (and (>= ,code ,code2)
2242           (>= ,code2 ,code3))))
2243      call)))
2244
2245(define-compiler-macro float (&whole call number &optional (other 0.0f0 other-p) &environment env)
2246
2247  (cond ((and (typep other 'single-float)
2248              (nx-form-typep number 'double-float env))
2249         `(the single-float (%double-to-single ,number)))
2250        ((and (typep other 'double-float)
2251              (nx-form-typep number 'single-float env))
2252         `(the double-float (%single-to-double ,number)))
2253        ((and other-p (typep other 'single-float))
2254         `(the single-float (%short-float ,number)))
2255        ((typep other 'double-float)
2256         `(the double-float (%double-float ,number)))
2257        ((null other-p)
2258         (let* ((temp (gensym)))
2259           `(let* ((,temp ,number))
2260             (if (typep ,temp 'double-float)
2261               ,temp
2262               (the single-float (%short-float ,temp))))))
2263        (t call)))
2264
2265(define-compiler-macro coerce (&whole call &environment env thing type)
2266  (cond ((nx-form-constant-p type env)
2267         (setq type (nx-form-constant-value type env))
2268         (let ((ctype (specifier-type-if-known type env :whine t)))
2269           (if ctype
2270             (if (csubtypep ctype (specifier-type 'single-float))
2271                 `(float ,thing 0.0f0)
2272                 (if (csubtypep ctype (specifier-type 'double-float))
2273                     `(float ,thing 0.0d0)
2274                     (let ((simple nil)
2275                           (extra nil))
2276                       (if (and (typep ctype 'array-ctype)
2277                                (equal (array-ctype-dimensions ctype) '(*)))
2278                           (if (eq (array-ctype-specialized-element-type ctype)
2279                                   (specifier-type 'character))
2280                               (setq simple '%coerce-to-string)
2281                               (if (and (eq *host-backend* *target-backend*)
2282                                        (array-ctype-typecode ctype))
2283                                   (setq simple '%coerce-to-vector
2284                                         extra (list (array-ctype-typecode ctype)))))
2285                           (if (eq ctype (specifier-type 'list))
2286                               (setq simple '%coerce-to-list)))
2287                       (if simple
2288                           (let* ((temp (gensym)))
2289                             `(let* ((,temp ,thing))
2290                                (if (typep ,temp ',(type-specifier ctype))
2291                                    ,temp
2292                                    (,simple ,temp ,@extra))))
2293                           call))))
2294             call)))
2295        (t call)))
2296
2297(define-compiler-macro equal (&whole call x y &environment env)
2298  (if (or (equal-iff-eql-p x env)
2299          (equal-iff-eql-p y env))
2300    `(eql ,x ,y)
2301    call))
2302
2303(define-compiler-macro instance-slots (instance &environment env)
2304  (if (and (nx-form-constant-p instance env)
2305           (eql (typecode (nx-form-constant-value instance env)) (nx-lookup-target-uvector-subtag :instance)))
2306    `(instance.slots ,instance)
2307    (let* ((itemp (gensym))
2308           (typecode (gensym)))
2309      `(let* ((,itemp ,instance)
2310              (,typecode (typecode ,itemp)))
2311        (declare (type (unsigned-byte 8) ,typecode))
2312        (if (eql ,typecode ,(nx-lookup-target-uvector-subtag :instance))
2313          (instance.slots ,itemp)
2314          (%non-standard-instance-slots ,itemp ,typecode))))))
2315
2316(define-compiler-macro instance-class-wrapper (instance)
2317  (let* ((itemp (gensym)))
2318    `(let* ((,itemp ,instance))
2319      (if (eql (the (unsigned-byte 8) (typecode ,itemp))
2320               ,(nx-lookup-target-uvector-subtag :instance))
2321        (instance.class-wrapper ,itemp)
2322        (non-standard-instance-class-wrapper ,itemp)))))
2323
2324;; Instance must be a standard-instance.
2325(define-compiler-macro %class-of-instance (instance)
2326  `(%wrapper-class (instance.class-wrapper ,instance)))
2327
2328(define-compiler-macro standard-object-p (thing)
2329  (let* ((temp (gensym))
2330         (typecode (gensym)))
2331    `(let* ((,temp ,thing)
2332            (,typecode (typecode ,temp)))
2333      (declare (type (unsigned-byte 8) ,typecode))
2334      (if (= ,typecode ,(nx-lookup-target-uvector-subtag :instance))
2335        (instance.class-wrapper ,temp)
2336        (if (= ,typecode ,(nx-lookup-target-uvector-subtag :macptr))
2337          (foreign-instance-class-wrapper ,temp))))))
2338
2339(define-compiler-macro %class-ordinal (class &optional error)
2340  (let* ((temp (gensym)))
2341    `(let* ((,temp ,class))
2342      (if (eql (the (unsigned-byte 8) (typecode ,temp))
2343               ,(nx-lookup-target-uvector-subtag :instance))
2344        (instance.hash ,temp)
2345        (funcall '%class-ordinal ,temp ,error)))))
2346
2347(define-compiler-macro native-class-p (class)
2348  (let* ((temp (gensym)))
2349    `(let* ((,temp ,class))
2350      (if (eql (the (unsigned-byte 8) (typecode ,temp))
2351               ,(nx-lookup-target-uvector-subtag :instance))
2352        (< (the fixnum (instance.hash ,temp)) max-class-ordinal)))))
2353 
2354
2355
2356(define-compiler-macro unsigned-byte-p (x)
2357  (if (typep (nx-unquote x) 'unsigned-byte)
2358    t
2359    (let* ((val (gensym)))
2360      `(let* ((,val ,x))
2361        (and (integerp ,val) (not (< ,val 0)))))))
2362
2363(define-compiler-macro subtypep (&whole w t1 t2 &optional rtenv)
2364  (if (and (consp t1)
2365           (consp (cdr t1))
2366           (null (cddr t1))
2367           (eq (car t1) 'type-of))
2368    ;; People really write code like this.  I've seen it.
2369    `(typep ,(cadr t1) ,t2 ,@(and rtenv `(,rtenv)))
2370    (if (and (null rtenv) (quoted-form-p t2))
2371      `(cell-csubtypep-2 ,t1 (load-time-value (register-type-cell ,t2)))
2372      w)))
2373
2374
2375(define-compiler-macro string-equal (s1 s2 &rest keys)
2376  (if (null keys)
2377    `(%fixed-string-equal ,s1 ,s2)
2378    (let* ((s1-arg (gensym))
2379           (s2-arg (gensym)))
2380      `(funcall
2381        (lambda (,s1-arg ,s2-arg &key start1 end1 start2 end2)
2382          (%bounded-string-equal ,s1-arg ,s2-arg start1 end1 start2 end2))
2383        ,s1 ,s2 ,@keys))))
2384
2385;;; Try to use "package-references" to speed up package lookup when
2386;;; a package name is used as a constant argument to some functions.
2387
2388(defun package-ref-form (arg env)
2389  (when (and arg (nx-form-constant-p arg env)
2390             (typep (setq arg (nx-form-constant-value arg env))
2391                    '(or symbol string)))
2392    `(load-time-value (register-package-ref ,(string arg)))))
2393
2394
2395
2396(define-compiler-macro intern (&whole w string &optional package &environment env)
2397  (let* ((ref (package-ref-form package env)))
2398    (if (or ref
2399            (setq ref (and (consp package)
2400                           (eq (car package) 'find-package)
2401                           (consp (cdr package))
2402                           (null (cddr package))
2403                           (package-ref-form (cadr package) env))))
2404      `(%pkg-ref-intern ,string ,ref)
2405      w)))
2406
2407(define-compiler-macro find-symbol (&whole w string &optional package &environment env)
2408  (let* ((ref (package-ref-form package env)))
2409    (if (or ref
2410            (setq ref (and (consp package)
2411                           (eq (car package) 'find-package)
2412                           (consp (cdr package))
2413                           (null (cddr package))
2414                           (package-ref-form (cadr package) env))))
2415      `(%pkg-ref-find-symbol ,string ,ref)
2416      w)))
2417
2418(define-compiler-macro find-package (&whole w package &environment env)
2419  (let* ((ref (package-ref-form package env)))
2420    (if ref
2421      `(package-ref.pkg ,ref)
2422      w)))
2423
2424(define-compiler-macro pkg-arg (&whole w package &optional allow-deleted &environment env)
2425  (let* ((ref (unless allow-deleted (package-ref-form package env))))
2426    (if ref
2427      (let* ((r (gensym)))
2428        `(let* ((,r ,ref))
2429          (or (package-ref.pkg ,ref)
2430           (%kernel-restart $xnopkg (package-ref.pkg ,r)))))
2431      w)))
2432
2433
2434;;; In practice, things that're STREAMP are almost always
2435;;; BASIC-STREAMs or FUNDAMENTAL-STREAMs, but STREAMP is a generic
2436;;; function.
2437(define-compiler-macro streamp (arg)
2438  (let* ((s (gensym)))
2439    `(let* ((,s ,arg))
2440      (or (typep ,s 'basic-stream)
2441       (typep ,s 'fundamental-stream)
2442       ;; Don't recurse
2443       (funcall 'streamp ,s)))))
2444
2445
2446(define-compiler-macro %char-code-case-fold (&whole w code vector &environment env)
2447  (if (nx-open-code-in-line env)
2448    (let* ((c (gensym))
2449           (table (gensym)))
2450      `(let* ((,c ,code)
2451              (,table ,vector))
2452        (declare (type (mod #x110000) ,c)
2453                 (type (simple-array (signed-byte 16) (*)) ,table))
2454        (if (< ,c (length ,table))
2455          (the fixnum (+ ,c (the (signed-byte 16)
2456                              (locally (declare (optimize (speed 3) (safety 0)))
2457                                (aref ,table ,c)))))
2458          ,c)))
2459    w))
2460       
2461(define-compiler-macro %char-code-upcase (code)
2462  (if (typep code '(mod #x110000))
2463    (%char-code-upcase code)
2464    `(%char-code-case-fold ,code *lower-to-upper*)))
2465
2466(define-compiler-macro %char-code-downcase (code)
2467  (if (typep code '(mod #x110000))
2468    (%char-code-downcase code)
2469    `(%char-code-case-fold ,code *upper-to-lower*)))
2470
2471(define-compiler-macro char-upcase (char)
2472  `(code-char (the valid-char-code (%char-code-upcase (char-code ,char)))))
2473
2474(define-compiler-macro char-downcase (char)
2475  `(code-char (the valid-char-code (%char-code-downcase (char-code ,char)))))
2476
2477
2478(define-compiler-macro register-istruct-cell (&whole w arg &environment env)
2479  (if (and (nx-form-constant-p arg env)
2480           (setq arg (nx-form-constant-value arg env))
2481           (symbolp arg))
2482    `',(register-istruct-cell arg)
2483    w))
2484
2485(define-compiler-macro get-character-encoding (&whole w name)
2486  (or (if (typep name 'keyword) (lookup-character-encoding name))
2487      w))
2488
2489(define-compiler-macro read-char (&optional stream (eof-error-p t) eof-value recursive-p)
2490  `(read-char-internal ,stream ,eof-error-p (values ,eof-value ,recursive-p)))
2491
2492
2493(provide "OPTIMIZERS")
Note: See TracBrowser for help on using the repository browser.