source: trunk/source/compiler/nx-basic.lisp @ 12940

Last change on this file since 12940 was 12940, checked in by gz, 10 years ago

From working-0711 branch: more extensive compile-time checking involving methods/gfs: warn about incongruent lambda lists, duplicate gf defs, required keyword args (from defgeneric), and invalid keyword args in gf calls. Also fix to keep method source files in env function info so dup method warnings can cite the right file.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 32.7 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx-current-code-note*)
44
45;; The problem with undefind type warnings is that there is no in-language way to shut
46;; them up even when the reference is intentional.  (In case of undefined functions,
47;; you can declare FTYPE and that will turn off any warnings without interfering with
48;; the function being defined later).  For now just provide this as an out.
49(defvar *compiler-warn-on-undefined-type-references* #+ccl-0711 t #-ccl-0711 t)
50
51
52
53;; In lieu of a slot in acode.  Don't reference this variable elsewhere because I'm
54;; hoping to make it go away.
55(defparameter *nx-acode-note-map* nil)
56
57(defun acode-note (acode &aux (hash *nx-acode-note-map*))
58  (and hash (gethash acode hash)))
59
60(defun (setf acode-note) (note acode)
61  (when note
62    (assert *nx-acode-note-map*)
63    ;; Only record if have a unique key
64    (unless (or (atom acode)
65                (nx-null acode)
66                (nx-t acode))
67      (setf (gethash acode *nx-acode-note-map*) note))))
68
69
70(defstruct (code-note (:constructor %make-code-note))
71  ;; Code coverage state.  This MUST be the first slot - see nx2-code-coverage.
72  code-coverage
73  ;; The source note of this form, or NIL if random code form (no file info,
74  ;; generated by macros or other source transform)
75  source-note
76  ;; the note that was being compiled when this note was emitted.
77  parent-note
78  #+debug-code-notes ;; The actual source form - useful for debugging, otherwise unused.
79  form)
80
81(defun make-code-note (&key form source-note parent-note)
82  (declare (ignorable form))
83  (let ((note (%make-code-note
84               :source-note source-note
85               :parent-note parent-note)))
86    #+debug-code-notes
87    (when form
88      ;; Unfortunately, recording the macroexpanded form is problematic, since they
89      ;; can have references to non-dumpable forms, see e.g. loop.
90      (setf (code-note-form note)
91            (with-output-to-string (s) (let ((*print-circle* t)) (prin1 form s)))))
92    note))
93
94(defmethod print-object ((note code-note) stream)
95  (print-unreadable-object (note stream :type t :identity t)
96    (format stream "[~s]" (code-note-code-coverage note))
97    (let ((sn (code-note-source-note note)))
98      (if sn
99        (progn
100          (format stream " for ")
101          (print-source-note sn stream))
102        #+debug-code-notes
103        (when (code-note-form note)
104          (format stream " form ~a"
105                  (string-sans-most-whitespace (code-note-form note))))))))
106
107(defun nx-ensure-code-note (form &optional parent-note)
108  (let* ((parent-note (or parent-note *nx-current-code-note*))
109         (source-note (nx-source-note form)))
110    (unless (and source-note
111                 ;; Look out for a case like a lambda macro that turns (lambda ...)
112                 ;; into (FUNCTION (lambda ...)) which then has (lambda ...)
113                 ;; as a child.  Create a fresh note for the child, to avoid ambiguity.
114                 ;; Another case is forms wrapping THE around themselves.
115                 (neq source-note (code-note-source-note parent-note))
116                 ;; Don't use source notes from a different toplevel form, which could
117                 ;; happen due to inlining etc.  The result then is that the source note
118                 ;; appears in multiple places, and shows partial coverage (from the
119                 ;; other reference) in code that's never executed.
120                 (loop for p = parent-note then (code-note-parent-note p)
121                       when (null p) return t
122                       when (code-note-source-note p)
123                       return (eq (loop for n = source-note then s
124                                        as s = (source-note-source n)
125                                        unless (source-note-p s) return n)
126                                  (loop for n = (code-note-source-note p) then s
127                                        as s = (source-note-source n)
128                                        unless (source-note-p s) return n))))
129      (setq source-note nil))
130    (make-code-note :form form :source-note source-note :parent-note parent-note)))
131
132(defun nx-note-source-transformation (original new &aux (source-notes *nx-source-note-map*) sn)
133  (when (and source-notes
134             (setq sn (gethash original source-notes))
135             (not (gethash new source-notes)))
136    (setf (gethash new source-notes) sn)))
137
138
139(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
140
141(let ((policy (%istruct 'compiler-policy
142               #'(lambda (env)
143                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
144                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
145               #'(lambda (env)
146                   (declare (ignorable env))
147                   #+ccl-0711 nil
148                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
149               #'(lambda (env)
150                   (let* ((safety (safety-optimize-quantity env)))
151                     (and (< safety 3)
152                          (>= (speed-optimize-quantity env)
153                              safety)))) ; trust-declarations
154               #'(lambda (env)
155                   #+ccl-0711 (> (speed-optimize-quantity env)
156                                 (space-optimize-quantity env))
157                   #-ccl-0711 (>= (speed-optimize-quantity env)
158                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
159               #'(lambda (env)
160                   (and (eq (speed-optimize-quantity env) 3) 
161                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
162               #'(lambda (env)
163                   (let* ((safety (safety-optimize-quantity env)))
164                     (or (eq safety 3)
165                         (> safety (speed-optimize-quantity env)))))          ;declarations-typecheck
166               #'(lambda (env)
167                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
168               #'(lambda (env)
169                   (and (neq (compilation-speed-optimize-quantity env) 3)
170                        (or (neq (speed-optimize-quantity env) 0)
171                            (and (neq (safety-optimize-quantity env) 3)
172                                 (neq (debug-optimize-quantity env) 3))))) ; allow-transforms
173               #'(lambda (var env)       ; force-boundp-checks
174                   (declare (ignore var))
175                   (eq (safety-optimize-quantity env) 3))
176               #'(lambda (var val env)       ; allow-constant-substitution
177                   (declare (ignore var val env))
178                   t)
179               nil           ; extensions
180               )))
181  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
182                                   (inhibit-register-allocation nil ira-p)
183                                   (trust-declarations nil td-p)
184                                   (open-code-inline nil oci-p)
185                                   (inhibit-safety-checking nil ischeck-p)
186                                   (inline-self-calls nil iscall-p)
187                                   (allow-transforms nil at-p)
188                                   (force-boundp-checks nil fb-p)
189                                   (allow-constant-substitution nil acs-p)
190                                   (declarations-typecheck nil dt-p))
191    (let ((p (copy-uvector policy)))
192      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
193      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
194      (if td-p (setf (policy.trust-declarations p) trust-declarations))
195      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
196      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
197      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
198      (if at-p (setf (policy.allow-transforms p) allow-transforms))
199      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
200      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
201      (if dt-p (setf (policy.declarations-typecheck p) declarations-typecheck))
202      p))
203  (defun %default-compiler-policy () policy))
204
205(%include "ccl:compiler;lambda-list.lisp")
206
207;Syntactic Environment Access.
208
209(defun declaration-information (decl-name &optional env)
210  (if (and env (not (istruct-typep env 'lexical-environment)))
211    (report-bad-arg env 'lexical-environment))
212; *** This needs to deal with things defined with DEFINE-DECLARATION ***
213  (case decl-name
214    (optimize
215     (list 
216      (list 'speed (speed-optimize-quantity env))
217      (list 'safety (safety-optimize-quantity env))
218      (list 'compilation-speed (compilation-speed-optimize-quantity env))
219      (list 'space (space-optimize-quantity env))
220      (list 'debug (debug-optimize-quantity env))))
221    (declaration
222     *nx-known-declarations*)))
223
224(defun function-information (name &optional env &aux decls)
225  (let ((name (ensure-valid-function-name name)))
226    (if (and env (not (istruct-typep env 'lexical-environment)))
227      (report-bad-arg env 'lexical-environment))
228    (if (special-operator-p name)
229      (values :special-form nil nil)
230      (flet ((process-new-fdecls (fdecls)
231                                 (dolist (fdecl fdecls)
232                                   (when (eq (car fdecl) name)
233                                     (let ((decl-type (cadr fdecl)))
234                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
235                                                  (not (assq decl-type decls)))
236                                         (push (cdr fdecl) decls)))))))
237        (declare (dynamic-extent #'process-new-fdecls))
238        (do* ((root t)
239              (contour env (when root (lexenv.parent-env contour))))
240             ((null contour)
241              (if (macro-function name)
242                (values :macro nil nil)
243                (if (fboundp name)
244                  (values :function 
245                          nil 
246                          (if (assq 'inline decls)
247                            decls
248                            (if (proclaimed-inline-p name)
249                              (push '(inline . inline) decls)
250                                (if (proclaimed-notinline-p name)
251                                  (push '(inline . notinline) decls)))))
252                  (values nil nil decls))))
253          (if (istruct-typep contour 'definition-environment)
254            (if (assq name (defenv.functions contour))
255              (return (values :macro nil nil))
256              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
257            (progn
258              (process-new-fdecls (lexenv.fdecls contour))
259              (let ((found (assq name (lexenv.functions contour))))
260                (when found
261                  (return
262                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
263                     (values :macro t nil)
264                     (values :function t decls))))))))))))
265
266(defun variable-information (var &optional env)
267  (setq var (require-type var 'symbol))
268  (if (and env (not (istruct-typep env 'lexical-environment)))
269    (report-bad-arg env 'lexical-environment))
270  (let* ((vartype nil)
271         (boundp nil)
272         (envtype nil)
273         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
274         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
275    (loop
276      (cond ((null env)
277             (if (constant-symbol-p var)
278               (setq vartype :constant decls nil)
279               (if (proclaimed-special-p var)
280                 (setq vartype :special)
281                 (let* ((not-a-symbol-macro (cons nil nil)))
282                   (declare (dynamic-extent not-a-symbol-macro))
283                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
284                               not-a-symbol-macro)
285                     (setq vartype :symbol-macro)))))
286             (return))
287            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
288             (cond ((assq var (defenv.constants env))
289                    (setq vartype :constant)
290                    (return))
291                   ((assq var (defenv.symbol-macros env))
292                    (setq vartype :symbol-macro)
293                    (return))
294                   ((assq var (defenv.specials env))
295                    (setq vartype :special)
296                    (return))))
297            (t
298             (dolist (vdecl (lexenv.vdecls env))
299               (when (eq (car vdecl) var)
300                 (let ((decltype (cadr vdecl)))
301                   (unless (assq decltype decls)
302                     (case decltype
303                       (special (setq vartype :special))
304                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
305             (let ((vars (lexenv.variables env)))
306               (unless (atom vars)
307                 (dolist (v vars)
308                   (when (eq (var-name v) var)
309                     (setq boundp t)
310                     (if (and (consp (var-ea v))
311                              (eq :symbol-macro (car (var-ea v))))
312                       (setq vartype :symbol-macro)
313                       (unless vartype (setq vartype
314                                             (let* ((bits (var-bits v)))
315                                               (if (and (typep bits 'integer)
316                                                        (logbitp $vbitspecial bits))
317                                                 :special
318                                                 :lexical)))))
319                     (return)))
320                 (when vartype (return))))))
321      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
322    (values vartype boundp decls)))
323
324(defun nx-target-type (typespec)
325  ;; Could do a lot more here
326  (if (or (eq *host-backend* *target-backend*)
327          (not (eq typespec 'fixnum)))
328    typespec
329    (target-word-size-case
330     (32 '(signed-byte 30))
331     (64 '(signed-byte 61)))))
332
333; Type declarations affect all references.
334(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
335  (loop
336    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
337    (dolist (decl (lexenv.vdecls env))
338      (if (and (eq (car decl) sym)
339               (eq (cadr decl) 'type))
340               (return-from nx-declared-type (nx-target-type (cddr decl)))))
341    (let ((vars (lexenv.variables env)))
342      (when (and (consp vars) 
343                 (dolist (var vars) 
344                   (when (eq (var-name var) sym) 
345                     (return t))))
346        (return-from nx-declared-type t)))
347    (setq env (lexenv.parent-env env)))
348  (let ((decl (or (assq sym *nx-compile-time-types*)
349                     (assq sym *nx-proclaimed-types*))))
350    (if decl (%cdr decl) t)))
351
352(defun nx-declared-result-type (sym &optional (env *nx-lexical-environment*))
353  (when (symbolp (setq sym (maybe-setf-function-name sym)))
354    (let* ((ftype (find-ftype-decl sym env))
355           (ctype (if (typep ftype 'ctype) ftype (specifier-type-if-known ftype env))))
356      (unless (or (null ctype)
357                  (not (function-ctype-p ctype))
358                  (eq *wild-type* (function-ctype-returns ctype)))
359        (let ((result-type (type-specifier (single-value-type (function-ctype-returns ctype)))))
360          (and (neq result-type 't) result-type))))))
361
362(defmacro define-declaration (decl-name lambda-list &body body &environment env)
363  (multiple-value-bind (body decls)
364                       (parse-body body env)
365    (let ((fn `(nfunction (define-declaration ,decl-name)
366                          (lambda ,lambda-list
367                            ,@decls
368                            (block ,decl-name
369                              ,@body)))))
370      `(progn
371         (proclaim '(declaration ,decl-name))
372         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
373
374(defun check-environment-args (variable symbol-macro function macro)
375  (flet ((check-all-pairs (pairlist argname)
376          (dolist (pair pairlist)
377            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
378              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
379                                           argname
380                                           pair
381                                           'name
382                                           'definition
383                                           pairlist))))
384         (check-all-symbols (symlist argname pairs pairsname)
385          (dolist (v symlist)
386            (unless (symbolp v) 
387              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
388            (when (assq v pairs) 
389              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
390    (check-all-pairs symbol-macro :symbol-macro)
391    (check-all-pairs macro :macro)
392    (check-all-symbols variable :variable symbol-macro :symbol-macro)
393    (check-all-symbols function :function macro :macro)))
394
395
396;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
397(defun process-declarations (env decls symbol-macros)
398  (let ((vdecls nil)
399        (fdecls nil)
400        (mdecls nil))
401    (flet ((add-type-decl (spec)
402            (destructuring-bind (typespec &rest vars) spec
403              (dolist (var vars)
404                (when (non-nil-symbol-p var)
405                  (push (list* var 
406                               'type
407                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
408                                 (if already
409                                   (let ((oldtype (%cdr already)))
410                                     (if oldtype
411                                       (if (subtypep oldtype typespec)
412                                         oldtype
413                                         (if (subtypep typespec oldtype)
414                                           typespec))))
415                                   typespec)))
416                        vdecls))))))
417      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
418      (dolist (decl decls)
419        (when (eq (car decl) 'special)
420          (dolist (spec (%cdr decl))
421            (when (non-nil-symbol-p spec)
422              (if (assq spec symbol-macros)
423                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
424              (push (list* spec 'special t) vdecls)))))
425      (dolist (decl decls)
426        (let ((decltype (car decl)))
427          (case decltype
428              ((inline notinline)
429               (dolist (spec (%cdr decl))
430               (let ((fname nil))
431                 (if (non-nil-symbol-p spec)
432                   (setq fname spec)
433                   (if (setf-function-name-p spec)
434                     (setq fname (setf-function-name (cadr spec)))))
435                 (if fname
436                   (push (list* fname decltype t) fdecls)))))
437              (optimize
438               (dolist (spec (%cdr decl))
439                 (let ((val 3)
440                       (quantity spec))
441                   (if (consp spec)
442                     (setq quantity (car spec) val (cadr spec)))
443                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
444                   (push (cons quantity val) mdecls)))))
445              (dynamic-extent
446               (dolist (spec (%cdr decl))
447               (if (non-nil-symbol-p spec)
448                 (push (list* spec decltype t) vdecls)
449                 (if (and (consp spec) (eq (%car spec) 'function))
450                   (let ((fname (cadr spec)))
451                     (if (not (non-nil-symbol-p fname))
452                       (setq fname 
453                             (if (setf-function-name-p fname)
454                               (setf-function-name (cadr fname)))))
455                     (if fname (push (list* fname decltype t) fdecls)))))))
456              (type (add-type-decl (cdr decl)))
457              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
458                       (dolist (name fnames)
459                         (let ((fname name))
460                           (if (not (non-nil-symbol-p fname))
461                             (setq fname 
462                                   (if (setf-function-name-p fname)
463                                     (setf-function-name (cadr fname)))))
464                           (if fname (push (list* fname decltype typespec) fdecls))))))
465              (special)
466              (t
467               (if (memq decltype *cl-types*)
468                 (add-type-decl decl)
469                 (let ((handler (getf *declaration-handlers* decltype)))
470                   (when handler
471                     (multiple-value-bind (type info) (funcall handler decl)
472                       (ecase type
473                         (:variable
474                          (dolist (v info) (push (apply #'list* v) vdecls)))
475                         (:function
476                          (dolist (f info) (push (apply #'list* f) fdecls)))
477                         (:declare  ;; N.B. CLtL/2 semantics
478                          (push info mdecls)))))))))))
479      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
480            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
481            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
482
483 
484(defun cons-var (name &optional (bits 0))
485  (%istruct 'var name bits nil nil nil nil nil nil))
486
487
488(defun augment-environment (env &key variable symbol-macro function macro declare)
489  (if (and env (not (istruct-typep env 'lexical-environment)))
490    (report-bad-arg env 'lexical-environment))
491  (check-environment-args variable symbol-macro function macro)
492  (let* ((vars (mapcar #'cons-var variable))
493         (symbol-macros (mapcar #'(lambda (s)
494                                    (let* ((sym (car s)))
495                                      (unless (and (symbolp sym)
496                                                   (not (constantp sym env))
497                                                   (not (eq (variable-information sym env) :special)))
498                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
499                                      (let ((v (cons-var (car s)))) 
500                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
501                                        v)))
502                                symbol-macro))
503         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
504         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
505         (new-env (new-lexical-environment env)))
506    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
507          (lexenv.functions new-env) (nconc functions macros))
508    (process-declarations new-env declare symbol-macro)
509    new-env))
510
511(defun enclose (lambda-expression &optional env)
512  (if (and env (not (istruct-typep env 'lexical-environment)))
513    (report-bad-arg env 'lexical-environment))
514  (unless (lambda-expression-p lambda-expression)
515    (error "Invalid lambda-expression ~S." lambda-expression))
516  (%make-function nil lambda-expression env))
517
518#|| Might be nicer to do %declaim
519(defmacro declaim (&rest decl-specs &environment env)
520  `(progn
521     (eval-when (:load-toplevel :execute)
522       (proclaim ',@decl-specs))
523     (eval-when (:compile-toplevel)
524       (%declaim ',@decl-specs ,env))))
525||#
526
527(defmacro declaim (&environment env &rest decl-specs)
528  "DECLAIM Declaration*
529  Do a declaration or declarations for the global environment."
530  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
531  `(progn
532     (eval-when (:compile-toplevel)
533       (compile-time-proclamation ',decl-specs ,env))
534     (eval-when (:load-toplevel :execute)
535       ,@body))))
536
537
538;; Should be true if compiler warnings UI doesn't use source locations, false if it does.
539(defvar *merge-compiler-warnings* t "If false, don't merge compiler warnings with different source locations")
540
541;;; If warnings have more than a single entry on their
542;;; args slot, don't merge them.
543(defun merge-compiler-warnings (old-warnings)
544  (let ((warnings nil))
545    (dolist (w old-warnings)
546      (let* ((w-args (compiler-warning-args w)))
547        (if
548          (or (cdr w-args)
549              ;; See if W can be merged into an existing warning
550              (dolist (w1 warnings t) 
551                (let ((w1-args (compiler-warning-args w1)))
552                  (when (and (eq (compiler-warning-warning-type w)
553                                 (compiler-warning-warning-type w1))
554                             w1-args
555                             (null (cdr w1-args))
556                             (eq (%car w-args)
557                                 (%car w1-args))
558                             (or *merge-compiler-warnings*
559                                 (eq (compiler-warning-source-note w)
560                                     (compiler-warning-source-note w1))))
561                    (let ((nrefs (compiler-warning-nrefs w1)))
562                      (setf (compiler-warning-nrefs w1)
563                            (cons (compiler-warning-source-note w)
564                                  (or nrefs
565                                      (list (compiler-warning-source-note w1)))))
566                      (return nil))))))
567          (push w warnings))))
568    warnings))
569
570;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
571;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
572
573(defun nx-declared-inline-p (sym env)
574  (setq sym (maybe-setf-function-name sym))
575  (loop
576    (when (listp env)
577      (return (and (symbolp sym)
578                   (proclaimed-inline-p sym))))
579    (dolist (decl (lexenv.fdecls env))
580      (when (and (eq (car decl) sym)
581                 (eq (cadr decl) 'inline))
582        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
583    (setq env (lexenv.parent-env env))))
584
585(defun report-compile-time-argument-mismatch (condition stream &aux (type (compiler-warning-warning-type condition)))
586  (destructuring-bind (callee reason args spread-p)
587      (compiler-warning-args condition)
588    (format stream "In the ~a ~s with arguments ~:s,~%  "
589            (if spread-p "application of" "call to")
590            callee
591            args)
592    (ecase (car reason)
593      (:toomany
594       (destructuring-bind (provided max)
595           (cdr reason)
596         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at most ~d ~:*~[are~;is~:;are~] accepted~&  by " provided max)))
597      (:toofew
598       (destructuring-bind (provided min)
599           (cdr reason)
600         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at least ~d ~:*~[are~;is~:;are~] required~&  by " provided min)))
601      (:odd-keywords
602       (let* ((tail (cadr reason)))
603         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
604      (:unknown-keyword
605       (destructuring-bind (badguy goodguys)
606           (cdr reason)
607         (format stream "the keyword argument~:[ ~s is~;s~{ ~s~^~#[~; and~:;,~]~} are~] not one of ~:s, which are recognized by "
608                 (consp badguy) badguy goodguys)))
609      (:unknown-gf-keywords
610         (let ((badguys (cadr reason)))
611           (when (and (consp badguys) (null (%cdr badguys))) (setq badguys (car badguys)))
612           (format stream "the keyword argument~:[ ~s is~;s~{ ~s~^~#[~; and~:;,~]~} are~] not recognized by "
613
614                   (consp badguys) badguys))))
615    (format stream
616            (ecase type
617              (:ftype-mismatch "the FTYPE declaration of ~s")
618              (:global-mismatch "the current global definition of ~s")
619              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
620              (:lexical-mismatch "the lexically visible definition of ~s")
621              ;; This can happen when compiling without compilation unit:
622              (:deferred-mismatch "~s"))
623            callee)))
624
625(defparameter *compiler-warning-formats*
626  '((:special . "Undeclared free variable ~S")
627    (:unused . "Unused lexical variable ~S")
628    (:ignore . "Variable ~S not ignored.")
629    (:undefined-function . "Undefined function ~S") ;; (deferred)
630    (:undefined-type . "Undefined type ~S")         ;; (deferred)
631    (:unknown-type-in-declaration . "Unknown or invalid type ~S, declaration ignored")
632    (:bad-declaration . "Unknown or invalid declaration ~S")
633    (:invalid-type . report-invalid-type-compiler-warning)
634    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
635    (:unknown-declaration-function . "~s declaration for unknown function ~s")
636    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
637    (:unsettable . "Shouldn't assign to variable ~S")
638    (:global-mismatch . report-compile-time-argument-mismatch)
639    (:environment-mismatch . report-compile-time-argument-mismatch)
640    (:lexical-mismatch . report-compile-time-argument-mismatch)   
641    (:ftype-mismatch . report-compile-time-argument-mismatch)
642    (:deferred-mismatch . report-compile-time-argument-mismatch)
643    (:type . "Type declarations violated in ~S")
644    (:type-conflict . "Conflicting type declarations for ~S")
645    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
646    (:lambda . "Suspicious lambda-list: ~s")
647    (:incongruent-gf-lambda-list . "Lambda list of generic function ~s is incongruent with previously defined methods")
648    (:incongruent-method-lambda-list . "Lambda list of ~s is incongruent with previous definition of ~s")
649    (:gf-keys-not-accepted . "~s does not accept keywords ~s required by the generic functions")
650    (:result-ignored . "Function result ignored in call to ~s")
651    (:duplicate-definition . report-compile-time-duplicate-definition)
652    (:format-error . "~:{~@?~%~}")
653    (:program-error . "~a")
654    (:unsure . "Nonspecific warning")))
655
656(defun report-invalid-type-compiler-warning (condition stream)
657  (destructuring-bind (type &optional why) (compiler-warning-args condition)
658    (when (typep why 'invalid-type-specifier)
659      (setq type (invalid-type-specifier-typespec why) why nil))
660    (format stream "Invalid type specifier ~S~@[: ~A~]" type why)))
661
662(defun report-compile-time-duplicate-definition (condition stream)
663  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
664    (format stream
665            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
666            (maybe-setf-name name) from to
667            (and old-file new-file)
668            (neq old-file new-file)
669            old-file)))
670
671(defun adjust-compiler-warning-args (warning-type args)
672  (case warning-type
673    ((:undefined-function :result-ignored) (mapcar #'maybe-setf-name args))
674    (t args)))
675
676
677(defun report-compiler-warning (condition stream &key short)
678  (let* ((warning-type (compiler-warning-warning-type condition))
679         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
680         (warning-args (compiler-warning-args condition)))
681    (unless short
682      (let ((name (reverse (compiler-warning-function-name condition))))
683        (format stream "In ")
684        (print-nested-name name stream)
685        (when (every #'null name)
686          (let ((position (source-note-start-pos (compiler-warning-source-note condition))))
687            (when position (format stream " at position ~s" position))))
688        (format stream ": ")))
689    (if (typep format-string 'string)
690      (apply #'format stream format-string (adjust-compiler-warning-args warning-type warning-args))
691      (if (null format-string)
692        (format stream "~A: ~S" warning-type warning-args)
693        (funcall format-string condition stream)))
694    ;(format stream ".")
695    (let ((nrefs (compiler-warning-nrefs condition)))
696      (when nrefs
697        (format stream " (~D references)" (length nrefs))))))
698
699(defun environment-structref-info (name env)
700  (let ((defenv (definition-environment env)))
701    (when defenv
702      (cdr (assq name (defenv.structrefs defenv))))))
703
704; end
Note: See TracBrowser for help on using the repository browser.