source: trunk/source/compiler/nx-basic.lisp @ 12512

Last change on this file since 12512 was 12512, checked in by gz, 10 years ago

bug#573: return a single value type from nx-declared-result-type

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 32.0 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx-current-code-note*)
44
45;; The problem with undefind type warnings is that there is no in-language way to shut
46;; them up even when the reference is intentional.  (In case of undefined functions,
47;; you can declare FTYPE and that will turn off any warnings without interfering with
48;; the function being defined later).  For now just provide this as an out.
49(defvar *compiler-warn-on-undefined-type-references* #+ccl-0711 t #-ccl-0711 t)
50
51
52
53;; In lieu of a slot in acode.  Don't reference this variable elsewhere because I'm
54;; hoping to make it go away.
55(defparameter *nx-acode-note-map* nil)
56
57(defun acode-note (acode &aux (hash *nx-acode-note-map*))
58  (and hash (gethash acode hash)))
59
60(defun (setf acode-note) (note acode)
61  (when note
62    (assert *nx-acode-note-map*)
63    ;; Only record if have a unique key
64    (unless (or (atom acode)
65                (nx-null acode)
66                (nx-t acode))
67      (setf (gethash acode *nx-acode-note-map*) note))))
68
69
70(defstruct (code-note (:constructor %make-code-note))
71  ;; Code coverage state.  This MUST be the first slot - see nx2-code-coverage.
72  code-coverage
73  ;; The source note of this form, or NIL if random code form (no file info,
74  ;; generated by macros or other source transform)
75  source-note
76  ;; the note that was being compiled when this note was emitted.
77  parent-note
78  #+debug-code-notes ;; The actual source form - useful for debugging, otherwise unused.
79  form)
80
81(defun make-code-note (&key form source-note parent-note)
82  (declare (ignorable form))
83  (let ((note (%make-code-note
84               :source-note source-note
85               :parent-note parent-note)))
86    #+debug-code-notes
87    (when form
88      ;; Unfortunately, recording the macroexpanded form is problematic, since they
89      ;; can have references to non-dumpable forms, see e.g. loop.
90      (setf (code-note-form note)
91            (with-output-to-string (s) (let ((*print-circle* t)) (prin1 form s)))))
92    note))
93
94(defmethod print-object ((note code-note) stream)
95  (print-unreadable-object (note stream :type t :identity t)
96    (format stream "[~s]" (code-note-code-coverage note))
97    (let ((sn (code-note-source-note note)))
98      (if sn
99        (progn
100          (format stream " for ")
101          (print-source-note sn stream))
102        #+debug-code-notes
103        (when (code-note-form note)
104          (format stream " form ~a"
105                  (string-sans-most-whitespace (code-note-form note))))))))
106
107(defun nx-ensure-code-note (form &optional parent-note)
108  (let* ((parent-note (or parent-note *nx-current-code-note*))
109         (source-note (nx-source-note form)))
110    (unless (and source-note
111                 ;; Look out for a case like a lambda macro that turns (lambda ...)
112                 ;; into (FUNCTION (lambda ...)) which then has (lambda ...)
113                 ;; as a child.  Create a fresh note for the child, to avoid ambiguity.
114                 ;; Another case is forms wrapping THE around themselves.
115                 (neq source-note (code-note-source-note parent-note))
116                 ;; Don't use source notes from a different toplevel form, which could
117                 ;; happen due to inlining etc.  The result then is that the source note
118                 ;; appears in multiple places, and shows partial coverage (from the
119                 ;; other reference) in code that's never executed.
120                 (loop for p = parent-note then (code-note-parent-note p)
121                       when (null p) return t
122                       when (code-note-source-note p)
123                       return (eq (loop for n = source-note then s
124                                        as s = (source-note-source n)
125                                        unless (source-note-p s) return n)
126                                  (loop for n = (code-note-source-note p) then s
127                                        as s = (source-note-source n)
128                                        unless (source-note-p s) return n))))
129      (setq source-note nil))
130    (make-code-note :form form :source-note source-note :parent-note parent-note)))
131
132(defun nx-note-source-transformation (original new &aux (source-notes *nx-source-note-map*) sn)
133  (when (and source-notes
134             (setq sn (gethash original source-notes))
135             (not (gethash new source-notes)))
136    (setf (gethash new source-notes) sn)))
137
138
139(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
140
141(let ((policy (%istruct 'compiler-policy
142               #'(lambda (env)
143                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
144                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
145               #'(lambda (env)
146                   (declare (ignorable env))
147                   #+ccl-0711 nil
148                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
149               #'(lambda (env)
150                   (let* ((safety (safety-optimize-quantity env)))
151                     (and (< safety 3)
152                          (>= (speed-optimize-quantity env)
153                              safety)))) ; trust-declarations
154               #'(lambda (env)
155                   #+ccl-0711 (> (speed-optimize-quantity env)
156                                 (space-optimize-quantity env))
157                   #-ccl-0711 (>= (speed-optimize-quantity env)
158                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
159               #'(lambda (env)
160                   (and (eq (speed-optimize-quantity env) 3) 
161                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
162               #'(lambda (env)
163                   (let* ((safety (safety-optimize-quantity env)))
164                     (or (eq safety 3)
165                         (> safety (speed-optimize-quantity env)))))          ;declarations-typecheck
166               #'(lambda (env)
167                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
168               #'(lambda (env)
169                   (and (neq (compilation-speed-optimize-quantity env) 3)
170                        (or (neq (speed-optimize-quantity env) 0)
171                            (and (neq (safety-optimize-quantity env) 3)
172                                 (neq (debug-optimize-quantity env) 3))))) ; allow-transforms
173               #'(lambda (var env)       ; force-boundp-checks
174                   (declare (ignore var))
175                   (eq (safety-optimize-quantity env) 3))
176               #'(lambda (var val env)       ; allow-constant-substitution
177                   (declare (ignore var val env))
178                   t)
179               nil           ; extensions
180               )))
181  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
182                                   (inhibit-register-allocation nil ira-p)
183                                   (trust-declarations nil td-p)
184                                   (open-code-inline nil oci-p)
185                                   (inhibit-safety-checking nil ischeck-p)
186                                   (inline-self-calls nil iscall-p)
187                                   (allow-transforms nil at-p)
188                                   (force-boundp-checks nil fb-p)
189                                   (allow-constant-substitution nil acs-p)
190                                   (declarations-typecheck nil dt-p))
191    (let ((p (copy-uvector policy)))
192      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
193      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
194      (if td-p (setf (policy.trust-declarations p) trust-declarations))
195      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
196      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
197      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
198      (if at-p (setf (policy.allow-transforms p) allow-transforms))
199      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
200      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
201      (if dt-p (setf (policy.declarations-typecheck p) declarations-typecheck))
202      p))
203  (defun %default-compiler-policy () policy))
204
205(%include "ccl:compiler;lambda-list.lisp")
206
207#-BOOTSTRAPPED (unless (fboundp 'types-disjoint-p)
208                 (fset 'types-disjoint-p (lambda (t1 t2 &optional env) t1 t2 env nil)))
209
210;Syntactic Environment Access.
211
212(defun declaration-information (decl-name &optional env)
213  (if (and env (not (istruct-typep env 'lexical-environment)))
214    (report-bad-arg env 'lexical-environment))
215; *** This needs to deal with things defined with DEFINE-DECLARATION ***
216  (case decl-name
217    (optimize
218     (list 
219      (list 'speed (speed-optimize-quantity env))
220      (list 'safety (safety-optimize-quantity env))
221      (list 'compilation-speed (compilation-speed-optimize-quantity env))
222      (list 'space (space-optimize-quantity env))
223      (list 'debug (debug-optimize-quantity env))))
224    (declaration
225     *nx-known-declarations*)))
226
227(defun function-information (name &optional env &aux decls)
228  (let ((name (ensure-valid-function-name name)))
229    (if (and env (not (istruct-typep env 'lexical-environment)))
230      (report-bad-arg env 'lexical-environment))
231    (if (special-operator-p name)
232      (values :special-form nil nil)
233      (flet ((process-new-fdecls (fdecls)
234                                 (dolist (fdecl fdecls)
235                                   (when (eq (car fdecl) name)
236                                     (let ((decl-type (cadr fdecl)))
237                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
238                                                  (not (assq decl-type decls)))
239                                         (push (cdr fdecl) decls)))))))
240        (declare (dynamic-extent #'process-new-fdecls))
241        (do* ((root t)
242              (contour env (when root (lexenv.parent-env contour))))
243             ((null contour)
244              (if (macro-function name)
245                (values :macro nil nil)
246                (if (fboundp name)
247                  (values :function 
248                          nil 
249                          (if (assq 'inline decls)
250                            decls
251                            (if (proclaimed-inline-p name)
252                              (push '(inline . inline) decls)
253                                (if (proclaimed-notinline-p name)
254                                  (push '(inline . notinline) decls)))))
255                  (values nil nil decls))))
256          (if (istruct-typep contour 'definition-environment)
257            (if (assq name (defenv.functions contour))
258              (return (values :macro nil nil))
259              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
260            (progn
261              (process-new-fdecls (lexenv.fdecls contour))
262              (let ((found (assq name (lexenv.functions contour))))
263                (when found
264                  (return
265                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
266                     (values :macro t nil)
267                     (values :function t decls))))))))))))
268
269(defun variable-information (var &optional env)
270  (setq var (require-type var 'symbol))
271  (if (and env (not (istruct-typep env 'lexical-environment)))
272    (report-bad-arg env 'lexical-environment))
273  (let* ((vartype nil)
274         (boundp nil)
275         (envtype nil)
276         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
277         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
278    (loop
279      (cond ((null env)
280             (if (constant-symbol-p var)
281               (setq vartype :constant decls nil)
282               (if (proclaimed-special-p var)
283                 (setq vartype :special)
284                 (let* ((not-a-symbol-macro (cons nil nil)))
285                   (declare (dynamic-extent not-a-symbol-macro))
286                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
287                               not-a-symbol-macro)
288                     (setq vartype :symbol-macro)))))
289             (return))
290            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
291             (cond ((assq var (defenv.constants env))
292                    (setq vartype :constant)
293                    (return))
294                   ((assq var (defenv.symbol-macros env))
295                    (setq vartype :symbol-macro)
296                    (return))
297                   ((assq var (defenv.specials env))
298                    (setq vartype :special)
299                    (return))))
300            (t
301             (dolist (vdecl (lexenv.vdecls env))
302               (when (eq (car vdecl) var)
303                 (let ((decltype (cadr vdecl)))
304                   (unless (assq decltype decls)
305                     (case decltype
306                       (special (setq vartype :special))
307                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
308             (let ((vars (lexenv.variables env)))
309               (unless (atom vars)
310                 (dolist (v vars)
311                   (when (eq (var-name v) var)
312                     (setq boundp t)
313                     (if (and (consp (var-ea v))
314                              (eq :symbol-macro (car (var-ea v))))
315                       (setq vartype :symbol-macro)
316                       (unless vartype (setq vartype
317                                             (let* ((bits (var-bits v)))
318                                               (if (and (typep bits 'integer)
319                                                        (logbitp $vbitspecial bits))
320                                                 :special
321                                                 :lexical)))))
322                     (return)))
323                 (when vartype (return))))))
324      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
325    (values vartype boundp decls)))
326
327(defun nx-target-type (typespec)
328  ;; Could do a lot more here
329  (if (or (eq *host-backend* *target-backend*)
330          (not (eq typespec 'fixnum)))
331    typespec
332    (target-word-size-case
333     (32 '(signed-byte 30))
334     (64 '(signed-byte 61)))))
335
336; Type declarations affect all references.
337(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
338  (loop
339    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
340    (dolist (decl (lexenv.vdecls env))
341      (if (and (eq (car decl) sym)
342               (eq (cadr decl) 'type))
343               (return-from nx-declared-type (nx-target-type (cddr decl)))))
344    (let ((vars (lexenv.variables env)))
345      (when (and (consp vars) 
346                 (dolist (var vars) 
347                   (when (eq (var-name var) sym) 
348                     (return t))))
349        (return-from nx-declared-type t)))
350    (setq env (lexenv.parent-env env)))
351  (let ((decl (or (assq sym *nx-compile-time-types*)
352                     (assq sym *nx-proclaimed-types*))))
353    (if decl (%cdr decl) t)))
354
355(defun nx-declared-result-type (sym &optional (env *nx-lexical-environment*))
356  (when (symbolp (setq sym (maybe-setf-function-name sym)))
357    (let* ((ftype (find-ftype-decl sym env))
358           (ctype (if (typep ftype 'ctype) ftype (specifier-type-if-known ftype env))))
359      (unless (or (null ctype)
360                  (not (function-ctype-p ctype))
361                  (eq *wild-type* (function-ctype-returns ctype)))
362        (let ((result-type (type-specifier (single-value-type (function-ctype-returns ctype)))))
363          (and (neq result-type 't) result-type))))))
364
365(defmacro define-declaration (decl-name lambda-list &body body &environment env)
366  (multiple-value-bind (body decls)
367                       (parse-body body env)
368    (let ((fn `(nfunction (define-declaration ,decl-name)
369                          (lambda ,lambda-list
370                            ,@decls
371                            (block ,decl-name
372                              ,@body)))))
373      `(progn
374         (proclaim '(declaration ,decl-name))
375         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
376
377(defun check-environment-args (variable symbol-macro function macro)
378  (flet ((check-all-pairs (pairlist argname)
379          (dolist (pair pairlist)
380            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
381              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
382                                           argname
383                                           pair
384                                           'name
385                                           'definition
386                                           pairlist))))
387         (check-all-symbols (symlist argname pairs pairsname)
388          (dolist (v symlist)
389            (unless (symbolp v) 
390              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
391            (when (assq v pairs) 
392              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
393    (check-all-pairs symbol-macro :symbol-macro)
394    (check-all-pairs macro :macro)
395    (check-all-symbols variable :variable symbol-macro :symbol-macro)
396    (check-all-symbols function :function macro :macro)))
397
398
399;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
400(defun process-declarations (env decls symbol-macros)
401  (let ((vdecls nil)
402        (fdecls nil)
403        (mdecls nil))
404    (flet ((add-type-decl (spec)
405            (destructuring-bind (typespec &rest vars) spec
406              (dolist (var vars)
407                (when (non-nil-symbol-p var)
408                  (push (list* var 
409                               'type
410                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
411                                 (if already
412                                   (let ((oldtype (%cdr already)))
413                                     (if oldtype
414                                       (if (subtypep oldtype typespec)
415                                         oldtype
416                                         (if (subtypep typespec oldtype)
417                                           typespec))))
418                                   typespec)))
419                        vdecls))))))
420      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
421      (dolist (decl decls)
422        (when (eq (car decl) 'special)
423          (dolist (spec (%cdr decl))
424            (when (non-nil-symbol-p spec)
425              (if (assq spec symbol-macros)
426                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
427              (push (list* spec 'special t) vdecls)))))
428      (dolist (decl decls)
429        (let ((decltype (car decl)))
430          (case decltype
431              ((inline notinline)
432               (dolist (spec (%cdr decl))
433               (let ((fname nil))
434                 (if (non-nil-symbol-p spec)
435                   (setq fname spec)
436                   (if (setf-function-name-p spec)
437                     (setq fname (setf-function-name (cadr spec)))))
438                 (if fname
439                   (push (list* fname decltype t) fdecls)))))
440              (optimize
441               (dolist (spec (%cdr decl))
442                 (let ((val 3)
443                       (quantity spec))
444                   (if (consp spec)
445                     (setq quantity (car spec) val (cadr spec)))
446                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
447                   (push (cons quantity val) mdecls)))))
448              (dynamic-extent
449               (dolist (spec (%cdr decl))
450               (if (non-nil-symbol-p spec)
451                 (push (list* spec decltype t) vdecls)
452                 (if (and (consp spec) (eq (%car spec) 'function))
453                   (let ((fname (cadr spec)))
454                     (if (not (non-nil-symbol-p fname))
455                       (setq fname 
456                             (if (setf-function-name-p fname)
457                               (setf-function-name (cadr fname)))))
458                     (if fname (push (list* fname decltype t) fdecls)))))))
459              (type (add-type-decl (cdr decl)))
460              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
461                       (dolist (name fnames)
462                         (let ((fname name))
463                           (if (not (non-nil-symbol-p fname))
464                             (setq fname 
465                                   (if (setf-function-name-p fname)
466                                     (setf-function-name (cadr fname)))))
467                           (if fname (push (list* fname decltype typespec) fdecls))))))
468              (special)
469              (t
470               (if (memq decltype *cl-types*)
471                 (add-type-decl decl)
472                 (let ((handler (getf *declaration-handlers* decltype)))
473                   (when handler
474                     (multiple-value-bind (type info) (funcall handler decl)
475                       (ecase type
476                         (:variable
477                          (dolist (v info) (push (apply #'list* v) vdecls)))
478                         (:function
479                          (dolist (f info) (push (apply #'list* f) fdecls)))
480                         (:declare  ;; N.B. CLtL/2 semantics
481                          (push info mdecls)))))))))))
482      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
483            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
484            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
485
486 
487(defun cons-var (name &optional (bits 0))
488  (%istruct 'var name bits nil nil nil nil nil))
489
490
491(defun augment-environment (env &key variable symbol-macro function macro declare)
492  (if (and env (not (istruct-typep env 'lexical-environment)))
493    (report-bad-arg env 'lexical-environment))
494  (check-environment-args variable symbol-macro function macro)
495  (let* ((vars (mapcar #'cons-var variable))
496         (symbol-macros (mapcar #'(lambda (s)
497                                    (let* ((sym (car s)))
498                                      (unless (and (symbolp sym)
499                                                   (not (constantp sym env))
500                                                   (not (eq (variable-information sym env) :special)))
501                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
502                                      (let ((v (cons-var (car s)))) 
503                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
504                                        v)))
505                                symbol-macro))
506         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
507         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
508         (new-env (new-lexical-environment env)))
509    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
510          (lexenv.functions new-env) (nconc functions macros))
511    (process-declarations new-env declare symbol-macro)
512    new-env))
513
514(defun enclose (lambda-expression &optional env)
515  (if (and env (not (istruct-typep env 'lexical-environment)))
516    (report-bad-arg env 'lexical-environment))
517  (unless (lambda-expression-p lambda-expression)
518    (error "Invalid lambda-expression ~S." lambda-expression))
519  (%make-function nil lambda-expression env))
520
521#|| Might be nicer to do %declaim
522(defmacro declaim (&rest decl-specs &environment env)
523  `(progn
524     (eval-when (:load-toplevel :execute)
525       (proclaim ',@decl-specs))
526     (eval-when (:compile-toplevel)
527       (%declaim ',@decl-specs ,env))))
528||#
529
530(defmacro declaim (&environment env &rest decl-specs)
531  "DECLAIM Declaration*
532  Do a declaration or declarations for the global environment."
533  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
534  `(progn
535     (eval-when (:compile-toplevel)
536       (compile-time-proclamation ',decl-specs ,env))
537     (eval-when (:load-toplevel :execute)
538       ,@body))))
539
540
541;; Should be true if compiler warnings UI doesn't use source locations, false if it does.
542(defvar *merge-compiler-warnings* t "If false, don't merge compiler warnings with different source locations")
543
544;;; If warnings have more than a single entry on their
545;;; args slot, don't merge them.
546(defun merge-compiler-warnings (old-warnings)
547  (let ((warnings nil))
548    (dolist (w old-warnings)
549      (let* ((w-args (compiler-warning-args w)))
550        (if
551          (or (cdr w-args)
552              ;; See if W can be merged into an existing warning
553              (dolist (w1 warnings t) 
554                (let ((w1-args (compiler-warning-args w1)))
555                  (when (and (eq (compiler-warning-warning-type w)
556                                 (compiler-warning-warning-type w1))
557                             w1-args
558                             (null (cdr w1-args))
559                             (eq (%car w-args)
560                                 (%car w1-args))
561                             (or *merge-compiler-warnings*
562                                 (eq (compiler-warning-source-note w)
563                                     (compiler-warning-source-note w1))))
564                    (let ((nrefs (compiler-warning-nrefs w1)))
565                      (setf (compiler-warning-nrefs w1)
566                            (cons (compiler-warning-source-note w)
567                                  (or nrefs
568                                      (list (compiler-warning-source-note w1)))))
569                      (return nil))))))
570          (push w warnings))))
571    warnings))
572
573;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
574;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
575
576(defun nx-declared-inline-p (sym env)
577  (setq sym (maybe-setf-function-name sym))
578  (loop
579    (when (listp env)
580      (return (and (symbolp sym)
581                   (proclaimed-inline-p sym))))
582    (dolist (decl (lexenv.fdecls env))
583      (when (and (eq (car decl) sym)
584                 (eq (cadr decl) 'inline))
585        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
586    (setq env (lexenv.parent-env env))))
587
588(defun report-compile-time-argument-mismatch (condition stream)
589  (destructuring-bind (callee reason args spread-p)
590      (compiler-warning-args condition)
591    (format stream "In the ~a ~s with arguments ~:s,~%  "
592            (if spread-p "application of" "call to")
593            callee
594            args)
595    (case (car reason)
596      (:toomany
597       (destructuring-bind (provided max)
598           (cdr reason)
599         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at most ~d ~:*~[are~;is~:;are~] accepted~&  by " provided max)))
600      (:toofew
601       (destructuring-bind (provided min)
602           (cdr reason)
603         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at least ~d ~:*~[are~;is~:;are~] required~&  by " provided min)))
604      (:odd-keywords
605       (let* ((tail (cadr reason)))
606         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
607      (:unknown-keyword
608       (destructuring-bind (badguy goodguys)
609           (cdr reason)
610         (format stream "the keyword argument~:[ ~s is~;s~{ ~s~^~#[~; and~:;,~]~} are~] not one of ~s, which are recognized~&  by "
611                 (consp badguy) badguy goodguys))))
612    (format stream
613            (ecase (compiler-warning-warning-type condition)       
614              (:ftype-mismatch "the FTYPE declaration of ~s")
615              (:global-mismatch "the current global definition of ~s")
616              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
617              (:lexical-mismatch "the lexically visible definition of ~s"))
618            callee)))
619
620(defparameter *compiler-warning-formats*
621  '((:special . "Undeclared free variable ~S")
622    (:unused . "Unused lexical variable ~S")
623    (:ignore . "Variable ~S not ignored.")
624    (:undefined-function . "Undefined function ~S") ;; (not reported if defined later)
625    (:undefined-type . "Undefined type ~S")         ;; (not reported if defined later)
626    (:unknown-type-in-declaration . "Unknown or invalid type ~S, declaration ignored")
627    (:bad-declaration . "Unknown or invalid declaration ~S")
628    (:invalid-type . report-invalid-type-compiler-warning)
629    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
630    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
631    (:unsettable . "Shouldn't assign to variable ~S")
632    (:global-mismatch . report-compile-time-argument-mismatch)
633    (:environment-mismatch . report-compile-time-argument-mismatch)
634    (:lexical-mismatch . report-compile-time-argument-mismatch)   
635    (:ftype-mismatch . report-compile-time-argument-mismatch)
636    (:type . "Type declarations violated in ~S")
637    (:type-conflict . "Conflicting type declarations for ~S")
638    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
639    (:lambda . "Suspicious lambda-list: ~s")
640    (:result-ignored . "Function result ignored in call to ~s")
641    (:duplicate-definition . report-compile-time-duplicate-definition)
642    (:format-error . "~:{~@?~%~}")
643    (:program-error . "~a")
644    (:unsure . "Nonspecific warning")))
645
646(defun report-invalid-type-compiler-warning (condition stream)
647  (destructuring-bind (type &optional why) (compiler-warning-args condition)
648    (when (typep why 'invalid-type-specifier)
649      (setq type (invalid-type-specifier-typespec why) why nil))
650    (format stream "Invalid type specifier ~S~@[: ~A~]" type why)))
651
652(defun report-compile-time-duplicate-definition (condition stream)
653  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
654    (format stream
655            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
656            (maybe-setf-name name) from to
657            (and old-file new-file)
658            (neq old-file new-file)
659            old-file)))
660
661(defun adjust-compiler-warning-args (warning-type args)
662  (case warning-type
663    ((:undefined-function :result-ignored) (mapcar #'maybe-setf-name args))
664    (t args)))
665
666
667(defun report-compiler-warning (condition stream &key short)
668  (let* ((warning-type (compiler-warning-warning-type condition))
669         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
670         (warning-args (compiler-warning-args condition)))
671    (unless short
672      (let ((name (reverse (compiler-warning-function-name condition))))
673        (format stream "In ")
674        (print-nested-name name stream)
675        (when (every #'null name)
676          (let ((position (source-note-start-pos (compiler-warning-source-note condition))))
677            (when position (format stream " at position ~s" position))))
678        (format stream ": ")))
679    (if (typep format-string 'string)
680      (apply #'format stream format-string (adjust-compiler-warning-args warning-type warning-args))
681      (if (null format-string)
682        (format stream "~A: ~S" warning-type warning-args)
683        (funcall format-string condition stream)))
684    ;(format stream ".")
685    (let ((nrefs (compiler-warning-nrefs condition)))
686      (when nrefs
687        (format stream " (~D references)" (length nrefs))))))
688
689(defun environment-structref-info (name env)
690  (let ((defenv (definition-environment env)))
691    (when defenv
692      (cdr (assq name (defenv.structrefs defenv))))))
693
694; end
Note: See TracBrowser for help on using the repository browser.