source: trunk/source/compiler/nx-basic.lisp @ 12254

Last change on this file since 12254 was 12254, checked in by gz, 10 years ago

From r12020: require speed 0 to turn off transforms

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 30.2 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx-current-code-note*)
44
45;; The problem with undefind type warnings is that there is no in-language way to shut
46;; them up even when the reference is intentional.  (In case of undefined functions,
47;; you can declare FTYPE and that will turn off any warnings without interfering with
48;; the function being defined later).  For now just provide this as an out.
49(defvar *compiler-warn-on-undefined-type-references* #+ccl-0711 t #-ccl-0711 t)
50
51
52
53;; In lieu of a slot in acode.  Don't reference this variable elsewhere because I'm
54;; hoping to make it go away.
55(defparameter *nx-acode-note-map* nil)
56
57(defun acode-note (acode &aux (hash *nx-acode-note-map*))
58  (and hash (gethash acode hash)))
59
60(defun (setf acode-note) (note acode)
61  (when note
62    (assert *nx-acode-note-map*)
63    (setf (gethash acode *nx-acode-note-map*) note)))
64
65
66(defstruct (code-note (:constructor %make-code-note))
67  ;; Code coverage state.  This MUST be the first slot - see nx2-code-coverage.
68  code-coverage
69  ;; The actual source form - useful for debugging, otherwise unused.
70  #+debug-code-notes form
71  ;; The source note of this form, or NIL if random code form (no file info,
72  ;; generated by macros or other source transform)
73  source-note
74  ;; the note that was being compiled when this note was emitted.
75  parent-note)
76
77(defun make-code-note (&key form source-note parent-note)
78  (declare (ignorable form))
79  (let ((note (%make-code-note
80               :source-note source-note
81               :parent-note parent-note)))
82    #+debug-code-notes
83    (when form
84      ;; Unfortunately, recording the macroexpanded form is problematic, since they
85      ;; can have references to non-dumpable forms, see e.g. loop.
86      (setf (code-note-form note)
87            (with-output-to-string (s) (let ((*print-circle* t)) (prin1 form s)))))
88    note))
89
90(defun nx-ensure-code-note (form &optional parent-note)
91  (let* ((parent-note (or parent-note *nx-current-code-note*))
92         (source-note (nx-source-note form)))
93    (unless (and source-note
94                 ;; Look out for a case like a lambda macro that turns (lambda ...)
95                 ;; into (FUNCTION (lambda ...)) which then has (lambda ...)
96                 ;; as a child.  Create a fresh note for the child, to avoid ambiguity.
97                 ;; Another case is forms wrapping THE around themselves.
98                 (neq source-note (code-note-source-note parent-note))
99                 ;; Don't use source notes from a different toplevel form, which could
100                 ;; happen due to inlining etc.  The result then is that the source note
101                 ;; appears in multiple places, and shows partial coverage (from the
102                 ;; other reference) in code that's never executed.
103                 (loop for p = parent-note then (code-note-parent-note p)
104                       when (null p) return t
105                       when (code-note-source-note p)
106                       return (eq (loop for n = source-note then s
107                                        as s = (source-note-source n)
108                                        unless (source-note-p s) return n)
109                                  (loop for n = (code-note-source-note p) then s
110                                        as s = (source-note-source n)
111                                        unless (source-note-p s) return n))))
112      (setq source-note nil))
113    (make-code-note :form form :source-note source-note :parent-note parent-note)))
114
115(defun nx-note-source-transformation (original new &aux (source-notes *nx-source-note-map*) sn)
116  (when (and source-notes
117             (setq sn (gethash original source-notes))
118             (not (gethash new source-notes)))
119    (setf (gethash new source-notes) sn)))
120
121
122(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
123
124(let ((policy (%istruct 'compiler-policy
125               #'(lambda (env)
126                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
127                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
128               #'(lambda (env)
129                   (declare (ignorable env))
130                   #+ccl-0711 nil
131                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
132               #'(lambda (env)
133                   (let* ((safety (safety-optimize-quantity env)))
134                     (and (< safety 3)
135                          (>= (speed-optimize-quantity env)
136                              safety)))) ; trust-declarations
137               #'(lambda (env)
138                   #+ccl-0711 (> (speed-optimize-quantity env)
139                                 (space-optimize-quantity env))
140                   #-ccl-0711 (>= (speed-optimize-quantity env)
141                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
142               #'(lambda (env)
143                   (and (eq (speed-optimize-quantity env) 3) 
144                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
145               #'(lambda (env)
146                   (let* ((safety (safety-optimize-quantity env)))
147                     (or (eq safety 3)
148                         (> safety (speed-optimize-quantity env)))))          ;declarations-typecheck
149               #'(lambda (env)
150                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
151               #'(lambda (env)
152                   (and (neq (compilation-speed-optimize-quantity env) 3)
153                        (or (neq (speed-optimize-quantity env) 0)
154                            (and (neq (safety-optimize-quantity env) 3)
155                                 (neq (debug-optimize-quantity env) 3))))) ; allow-transforms
156               #'(lambda (var env)       ; force-boundp-checks
157                   (declare (ignore var))
158                   (eq (safety-optimize-quantity env) 3))
159               #'(lambda (var val env)       ; allow-constant-substitution
160                   (declare (ignore var val env))
161                   t)
162               nil           ; extensions
163               )))
164  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
165                                   (inhibit-register-allocation nil ira-p)
166                                   (trust-declarations nil td-p)
167                                   (open-code-inline nil oci-p)
168                                   (inhibit-safety-checking nil ischeck-p)
169                                   (inline-self-calls nil iscall-p)
170                                   (allow-transforms nil at-p)
171                                   (force-boundp-checks nil fb-p)
172                                   (allow-constant-substitution nil acs-p)
173                                   (declarations-typecheck nil dt-p))
174    (let ((p (copy-uvector policy)))
175      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
176      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
177      (if td-p (setf (policy.trust-declarations p) trust-declarations))
178      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
179      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
180      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
181      (if at-p (setf (policy.allow-transforms p) allow-transforms))
182      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
183      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
184      (if dt-p (setf (policy.declarations-typecheck p) declarations-typecheck))
185      p))
186  (defun %default-compiler-policy () policy))
187
188(%include "ccl:compiler;lambda-list.lisp")
189
190
191
192;Syntactic Environment Access.
193
194(defun declaration-information (decl-name &optional env)
195  (if (and env (not (istruct-typep env 'lexical-environment)))
196    (report-bad-arg env 'lexical-environment))
197; *** This needs to deal with things defined with DEFINE-DECLARATION ***
198  (case decl-name
199    (optimize
200     (list 
201      (list 'speed (speed-optimize-quantity env))
202      (list 'safety (safety-optimize-quantity env))
203      (list 'compilation-speed (compilation-speed-optimize-quantity env))
204      (list 'space (space-optimize-quantity env))
205      (list 'debug (debug-optimize-quantity env))))
206    (declaration
207     *nx-known-declarations*)))
208
209(defun function-information (name &optional env &aux decls)
210  (let ((name (ensure-valid-function-name name)))
211    (if (and env (not (istruct-typep env 'lexical-environment)))
212      (report-bad-arg env 'lexical-environment))
213    (if (special-operator-p name)
214      (values :special-form nil nil)
215      (flet ((process-new-fdecls (fdecls)
216                                 (dolist (fdecl fdecls)
217                                   (when (eq (car fdecl) name)
218                                     (let ((decl-type (cadr fdecl)))
219                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
220                                                  (not (assq decl-type decls)))
221                                         (push (cdr fdecl) decls)))))))
222        (declare (dynamic-extent #'process-new-fdecls))
223        (do* ((root t)
224              (contour env (when root (lexenv.parent-env contour))))
225             ((null contour)
226              (if (macro-function name)
227                (values :macro nil nil)
228                (if (fboundp name)
229                  (values :function 
230                          nil 
231                          (if (assq 'inline decls)
232                            decls
233                            (if (proclaimed-inline-p name)
234                              (push '(inline . inline) decls)
235                                (if (proclaimed-notinline-p name)
236                                  (push '(inline . notinline) decls)))))
237                  (values nil nil decls))))
238          (if (istruct-typep contour 'definition-environment)
239            (if (assq name (defenv.functions contour))
240              (return (values :macro nil nil))
241              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
242            (progn
243              (process-new-fdecls (lexenv.fdecls contour))
244              (let ((found (assq name (lexenv.functions contour))))
245                (when found
246                  (return
247                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
248                     (values :macro t nil)
249                     (values :function t decls))))))))))))
250
251(defun variable-information (var &optional env)
252  (setq var (require-type var 'symbol))
253  (if (and env (not (istruct-typep env 'lexical-environment)))
254    (report-bad-arg env 'lexical-environment))
255  (let* ((vartype nil)
256         (boundp nil)
257         (envtype nil)
258         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
259         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
260    (loop
261      (cond ((null env)
262             (if (constant-symbol-p var)
263               (setq vartype :constant decls nil)
264               (if (proclaimed-special-p var)
265                 (setq vartype :special)
266                 (let* ((not-a-symbol-macro (cons nil nil)))
267                   (declare (dynamic-extent not-a-symbol-macro))
268                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
269                               not-a-symbol-macro)
270                     (setq vartype :symbol-macro)))))
271             (return))
272            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
273             (cond ((assq var (defenv.constants env))
274                    (setq vartype :constant)
275                    (return))
276                   ((assq var (defenv.symbol-macros env))
277                    (setq vartype :symbol-macro)
278                    (return))
279                   ((assq var (defenv.specials env))
280                    (setq vartype :special)
281                    (return))))
282            (t
283             (dolist (vdecl (lexenv.vdecls env))
284               (when (eq (car vdecl) var)
285                 (let ((decltype (cadr vdecl)))
286                   (unless (assq decltype decls)
287                     (case decltype
288                       (special (setq vartype :special))
289                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
290             (let ((vars (lexenv.variables env)))
291               (unless (atom vars)
292                 (dolist (v vars)
293                   (when (eq (var-name v) var)
294                     (setq boundp t)
295                     (if (and (consp (var-ea v))
296                              (eq :symbol-macro (car (var-ea v))))
297                       (setq vartype :symbol-macro)
298                       (unless vartype (setq vartype
299                                             (let* ((bits (var-bits v)))
300                                               (if (and (typep bits 'integer)
301                                                        (logbitp $vbitspecial bits))
302                                                 :special
303                                                 :lexical)))))
304                     (return)))
305                 (when vartype (return))))))
306      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
307    (values vartype boundp decls)))
308
309(defun nx-target-type (typespec)
310  ;; Could do a lot more here
311  (if (or (eq *host-backend* *target-backend*)
312          (not (eq typespec 'fixnum)))
313    typespec
314    (target-word-size-case
315     (32 '(signed-byte 30))
316     (64 '(signed-byte 61)))))
317
318; Type declarations affect all references.
319(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
320  (loop
321    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
322    (dolist (decl (lexenv.vdecls env))
323      (if (and (eq (car decl) sym)
324               (eq (cadr decl) 'type))
325               (return-from nx-declared-type (nx-target-type (cddr decl)))))
326    (let ((vars (lexenv.variables env)))
327      (when (and (consp vars) 
328                 (dolist (var vars) 
329                   (when (eq (var-name var) sym) 
330                     (return t))))
331        (return-from nx-declared-type t)))
332    (setq env (lexenv.parent-env env)))
333  (let ((decl (or (assq sym *nx-compile-time-types*)
334                     (assq sym *nx-proclaimed-types*))))
335    (if decl (%cdr decl) t)))
336
337(defmacro define-declaration (decl-name lambda-list &body body &environment env)
338  (multiple-value-bind (body decls)
339                       (parse-body body env)
340    (let ((fn `(nfunction (define-declaration ,decl-name)
341                          (lambda ,lambda-list
342                            ,@decls
343                            (block ,decl-name
344                              ,@body)))))
345      `(progn
346         (proclaim '(declaration ,decl-name))
347         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
348
349(defun check-environment-args (variable symbol-macro function macro)
350  (flet ((check-all-pairs (pairlist argname)
351          (dolist (pair pairlist)
352            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
353              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
354                                           argname
355                                           pair
356                                           'name
357                                           'definition
358                                           pairlist))))
359         (check-all-symbols (symlist argname pairs pairsname)
360          (dolist (v symlist)
361            (unless (symbolp v) 
362              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
363            (when (assq v pairs) 
364              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
365    (check-all-pairs symbol-macro :symbol-macro)
366    (check-all-pairs macro :macro)
367    (check-all-symbols variable :variable symbol-macro :symbol-macro)
368    (check-all-symbols function :function macro :macro)))
369
370
371;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
372(defun process-declarations (env decls symbol-macros)
373  (let ((vdecls nil)
374        (fdecls nil)
375        (mdecls nil))
376    (flet ((add-type-decl (spec)
377            (destructuring-bind (typespec &rest vars) spec
378              (dolist (var vars)
379                (when (non-nil-symbol-p var)
380                  (push (list* var 
381                               'type
382                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
383                                 (if already
384                                   (let ((oldtype (%cdr already)))
385                                     (if oldtype
386                                       (if (subtypep oldtype typespec)
387                                         oldtype
388                                         (if (subtypep typespec oldtype)
389                                           typespec))))
390                                   typespec)))
391                        vdecls))))))
392      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
393      (dolist (decl decls)
394        (when (eq (car decl) 'special)
395          (dolist (spec (%cdr decl))
396            (when (non-nil-symbol-p spec)
397              (if (assq spec symbol-macros)
398                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
399              (push (list* spec 'special t) vdecls)))))
400      (dolist (decl decls)
401        (let ((decltype (car decl)))
402          (case decltype
403              ((inline notinline)
404               (dolist (spec (%cdr decl))
405               (let ((fname nil))
406                 (if (non-nil-symbol-p spec)
407                   (setq fname spec)
408                   (if (and (consp spec) (eq (%car spec) 'setf))
409                     (setq fname (setf-function-name (cadr spec)))))
410                 (if fname
411                   (push (list* fname decltype t) fdecls)))))
412              (optimize
413               (dolist (spec (%cdr decl))
414                 (let ((val 3)
415                       (quantity spec))
416                   (if (consp spec)
417                     (setq quantity (car spec) val (cadr spec)))
418                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
419                   (push (cons quantity val) mdecls)))))
420              (dynamic-extent
421               (dolist (spec (%cdr decl))
422               (if (non-nil-symbol-p spec)
423                 (push (list* spec decltype t) vdecls)
424                 (if (and (consp spec) (eq (%car spec) 'function))
425                   (let ((fname (cadr spec)))
426                     (if (not (non-nil-symbol-p fname))
427                       (setq fname 
428                             (if (and (consp fname) (eq (%car fname) 'setf))
429                               (setf-function-name (cadr fname)))))
430                     (if fname (push (list* fname decltype t) fdecls)))))))
431              (type (add-type-decl (cdr decl)))
432              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
433                       (dolist (name fnames)
434                         (let ((fname name))
435                           (if (not (non-nil-symbol-p fname))
436                             (setq fname 
437                                   (if (and (consp fname) (eq (%car fname) 'setf))
438                                     (setf-function-name (cadr fname)))))
439                           (if fname (push (list* fname decltype typespec) fdecls))))))
440              (special)
441              (t
442               (if (memq decltype *cl-types*)
443                 (add-type-decl decl)
444                 (let ((handler (getf *declaration-handlers* decltype)))
445                   (when handler
446                     (multiple-value-bind (type info) (funcall handler decl)
447                       (ecase type
448                         (:variable
449                          (dolist (v info) (push (apply #'list* v) vdecls)))
450                         (:function
451                          (dolist (f info) (push (apply #'list* f) fdecls)))
452                         (:declare  ;; N.B. CLtL/2 semantics
453                          (push info mdecls)))))))))))
454      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
455            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
456            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
457
458 
459(defun cons-var (name &optional (bits 0))
460  (%istruct 'var name bits nil nil nil nil nil))
461
462
463(defun augment-environment (env &key variable symbol-macro function macro declare)
464  (if (and env (not (istruct-typep env 'lexical-environment)))
465    (report-bad-arg env 'lexical-environment))
466  (check-environment-args variable symbol-macro function macro)
467  (let* ((vars (mapcar #'cons-var variable))
468         (symbol-macros (mapcar #'(lambda (s)
469                                    (let* ((sym (car s)))
470                                      (unless (and (symbolp sym)
471                                                   (not (constantp sym env))
472                                                   (not (eq (variable-information sym env) :special)))
473                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
474                                      (let ((v (cons-var (car s)))) 
475                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
476                                        v)))
477                                symbol-macro))
478         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
479         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
480         (new-env (new-lexical-environment env)))
481    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
482          (lexenv.functions new-env) (nconc functions macros))
483    (process-declarations new-env declare symbol-macro)
484    new-env))
485
486(defun enclose (lambda-expression &optional env)
487  (if (and env (not (istruct-typep env 'lexical-environment)))
488    (report-bad-arg env 'lexical-environment))
489  (unless (lambda-expression-p lambda-expression)
490    (error "Invalid lambda-expression ~S." lambda-expression))
491  (%make-function nil lambda-expression env))
492
493#|| Might be nicer to do %declaim
494(defmacro declaim (&rest decl-specs &environment env)
495  `(progn
496     (eval-when (:load-toplevel :execute)
497       (proclaim ',@decl-specs))
498     (eval-when (:compile-toplevel)
499       (%declaim ',@decl-specs ,env))))
500||#
501
502(defmacro declaim (&environment env &rest decl-specs)
503  "DECLAIM Declaration*
504  Do a declaration or declarations for the global environment."
505  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
506  `(progn
507     (eval-when (:compile-toplevel)
508       (compile-time-proclamation ',decl-specs ,env))
509     (eval-when (:load-toplevel :execute)
510       ,@body))))
511
512;;; If warnings have more than a single entry on their
513;;; args slot, don't merge them.
514(defun merge-compiler-warnings (old-warnings)
515  (let ((warnings nil))
516    (dolist (w old-warnings)
517      (let* ((w-args (compiler-warning-args w)))
518        (if
519          (or (cdr w-args)
520              (dolist (w1 warnings t) 
521                (let ((w1-args (compiler-warning-args w1)))
522                  (when (and (eq (compiler-warning-warning-type w)
523                                 (compiler-warning-warning-type w1))
524                             w1-args
525                             (null (cdr w1-args))
526                             (eq (%car w-args)
527                                 (%car w1-args)))
528                    (let ((nrefs (compiler-warning-nrefs w1)))
529                      #-BOOTSTRAPPED (when (eql nrefs 1) (setq nrefs nil))
530                      (setf (compiler-warning-nrefs w1)
531                            (cons (compiler-warning-source-note w)
532                                  (or nrefs
533                                      (list (compiler-warning-source-note w1))))))
534                    (return)))))
535          (push w warnings))))
536    warnings))
537
538;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
539;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
540
541(defun nx-declared-inline-p (sym env)
542  (setq sym (maybe-setf-function-name sym))
543  (loop
544    (when (listp env)
545      (return (and (symbolp sym)
546                   (proclaimed-inline-p sym))))
547    (dolist (decl (lexenv.fdecls env))
548      (when (and (eq (car decl) sym)
549                 (eq (cadr decl) 'inline))
550        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
551    (setq env (lexenv.parent-env env))))
552
553(defun report-compile-time-argument-mismatch (condition stream)
554  (destructuring-bind (callee reason args spread-p)
555      (compiler-warning-args condition)
556    (format stream "In the ~a ~s with arguments ~:s,~%  "
557            (if spread-p "application of" "call to")
558            callee
559            args)
560    (case (car reason)
561      (:toomany
562       (destructuring-bind (provided max)
563           (cdr reason)
564         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at most ~d ~:*~[are~;is~:;are~] accepted~&  by " provided max)))
565      (:toofew
566       (destructuring-bind (provided min)
567           (cdr reason)
568         (format stream "~d argument~:p ~:*~[were~;was~:;were~] provided, but at least ~d ~:*~[are~;is~:;are~] required~&  by " provided min)))
569      (:odd-keywords
570       (let* ((tail (cadr reason)))
571         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
572      (:unknown-keyword
573       (destructuring-bind (badguy goodguys)
574           (cdr reason)
575         (format stream "the keyword argument ~s is not one of ~s, which are recognized~&  by " badguy goodguys))))
576    (format stream
577            (ecase (compiler-warning-warning-type condition)       
578              (:global-mismatch "the current global definition of ~s")
579              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
580              (:lexical-mismatch "the lexically visible definition of ~s"))
581            callee)))
582
583(defparameter *compiler-warning-formats*
584  '((:special . "Undeclared free variable ~S")
585    (:unused . "Unused lexical variable ~S")
586    (:ignore . "Variable ~S not ignored.")
587    (:undefined-function . "Undefined function ~S") ;; (not reported if defined later)
588    (:undefined-type . "Undefined type ~S")         ;; (not reported if defined later)
589    (:unknown-type-in-declaration . "Unknown or invalid type ~S, declaration ignored")
590    (:bad-declaration . "Unknown or invalid declaration ~S")
591    (:invalid-type . report-invalid-type-compiler-warning)
592    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
593    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
594    (:unsettable . "Shouldn't assign to variable ~S")
595    (:global-mismatch . report-compile-time-argument-mismatch)
596    (:environment-mismatch . report-compile-time-argument-mismatch)
597    (:lexical-mismatch . report-compile-time-argument-mismatch)   
598    (:type . "Type declarations violated in ~S")
599    (:type-conflict . "Conflicting type declarations for ~S")
600    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
601    (:lambda . "Suspicious lambda-list: ~s")
602    (:result-ignored . "Function result ignored in call to ~s")
603    (:duplicate-definition . report-compile-time-duplicate-definition)
604    (:format-error . "~:{~@?~%~}")
605    (:program-error . "~a")
606    (:unsure . "Nonspecific warning")))
607
608(defun report-invalid-type-compiler-warning (condition stream)
609  (destructuring-bind (type &optional why) (compiler-warning-args condition)
610    (when (typep why 'invalid-type-specifier)
611      (setq type (invalid-type-specifier-typespec why) why nil))
612    (format stream "Invalid type specifier ~S~@[: ~A~]" type why)))
613
614(defun report-compile-time-duplicate-definition (condition stream)
615  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
616    (format stream
617            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
618            (maybe-setf-name name) from to
619            (and old-file new-file)
620            (neq old-file new-file)
621            old-file)))
622
623(defun adjust-compiler-warning-args (warning-type args)
624  (case warning-type
625    ((:undefined-function :result-ignored) (mapcar #'maybe-setf-name args))
626    (t args)))
627
628
629(defun report-compiler-warning (condition stream)
630  (let* ((warning-type (compiler-warning-warning-type condition))
631         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
632         (name (reverse (compiler-warning-function-name condition))))
633    (format stream "In ")
634    (print-nested-name name stream)
635    (when (every #'null name)
636      (let ((position (compiler-warning-stream-position condition)))
637        (when position (format stream " at position ~s" position))))
638    (format stream ": ")
639    (if (typep format-string 'string)
640      (apply #'format stream format-string (adjust-compiler-warning-args warning-type (compiler-warning-args condition)))
641      (if (null format-string)
642        (format stream "~A: ~S" warning-type (compiler-warning-args condition))
643        (funcall format-string condition stream)))
644    ;(format stream ".")
645    (let ((nrefs (compiler-warning-nrefs condition)))
646      #-BOOTSTRAPPED (when (eql nrefs 1) (setq nrefs nil))
647      (when nrefs
648        (format stream " (~D references)" (length nrefs))))))
649
650(defun environment-structref-info (name env)
651  (let ((defenv (definition-environment env)))
652    (when defenv
653      (cdr (assq name (defenv.structrefs defenv))))))
654
655; end
Note: See TracBrowser for help on using the repository browser.