source: trunk/source/compiler/nx-basic.lisp @ 11755

Last change on this file since 11755 was 11755, checked in by gb, 11 years ago

Catch at least a few cases where the compiler might reference an
internal SETF package function name and print (SETF FOO) rather
than the SETF package symbol.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 29.0 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx-current-code-note*)
44
45;; In lieu of a slot in acode.  Don't reference this variable elsewhere because I'm
46;; hoping to make it go away.
47(defparameter *nx-acode-note-map* nil)
48
49(defun acode-note (acode &aux (hash *nx-acode-note-map*))
50  (and hash (gethash acode hash)))
51
52(defun (setf acode-note) (note acode)
53  (when note
54    (assert *nx-acode-note-map*)
55    (setf (gethash acode *nx-acode-note-map*) note)))
56
57
58(defun nx-source-note (form &aux (source-notes *nx-source-note-map*))
59  (when source-notes
60    (when (or (consp form) (vectorp form) (pathnamep form))
61      (let ((note (gethash form source-notes)))
62        (unless (listp note) note)))))
63
64(defstruct (code-note (:constructor %make-code-note))
65  ;; Code coverage state.  This MUST be the first slot - see nx2-code-coverage.
66  code-coverage
67  ;; The actual source form - useful for debugging, otherwise unused.
68  #+debug-code-notes form
69  ;; The source note of this form, or NIL if random code form (no file info,
70  ;; generated by macros or other source transform)
71  source-note
72  ;; the note that was being compiled when this note was emitted.
73  parent-note)
74
75(defun make-code-note (&key form source-note parent-note)
76  (declare (ignorable form))
77  (let ((note (%make-code-note
78               :source-note source-note
79               :parent-note parent-note)))
80    #+debug-code-notes
81    (when form
82      ;; Unfortunately, recording the macroexpanded form is problematic, since they
83      ;; can have references to non-dumpable forms, see e.g. loop.
84      (setf (code-note-form note)
85            (with-output-to-string (s) (let ((*print-circle* t)) (prin1 form s)))))
86    note))
87
88(defun nx-ensure-code-note (form &optional parent-note)
89  (let* ((parent-note (or parent-note *nx-current-code-note*))
90         (source-note (nx-source-note form)))
91    (unless (and source-note
92                 ;; Look out for a case like a lambda macro that turns (lambda ...)
93                 ;; into (FUNCTION (lambda ...)) which then has (lambda ...)
94                 ;; as a child.  Create a fresh note for the child, to avoid ambiguity.
95                 ;; Another case is forms wrapping THE around themselves.
96                 (neq source-note (code-note-source-note parent-note))
97                 ;; Don't use source notes from a different toplevel form, which could
98                 ;; happen due to inlining etc.  The result then is that the source note
99                 ;; appears in multiple places, and shows partial coverage (from the
100                 ;; other reference) in code that's never executed.
101                 (loop for p = parent-note then (code-note-parent-note p)
102                       when (null p) return t
103                       when (code-note-source-note p)
104                       return (eq (loop for n = source-note then s
105                                        as s = (source-note-source n)
106                                        unless (source-note-p s) return n)
107                                  (loop for n = (code-note-source-note p) then s
108                                        as s = (source-note-source n)
109                                        unless (source-note-p s) return n))))
110      (setq source-note nil))
111    (make-code-note :form form :source-note source-note :parent-note parent-note)))
112
113(defun nx-note-source-transformation (original new &aux (source-notes *nx-source-note-map*) sn)
114  (when (and source-notes
115             (setq sn (gethash original source-notes))
116             (not (gethash new source-notes)))
117    (setf (gethash new source-notes) sn)))
118
119
120
121(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
122
123(let ((policy (%istruct 'compiler-policy
124               #'(lambda (env)
125                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
126                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
127               #'(lambda (env)
128                   (declare (ignorable env))
129                   #+ccl-0711 nil
130                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
131               #'(lambda (env)
132                   (let* ((safety (safety-optimize-quantity env)))
133                     (and (< safety 3)
134                          (>= (speed-optimize-quantity env)
135                              safety)))) ; trust-declarations
136               #'(lambda (env)
137                   #+ccl-0711 (> (speed-optimize-quantity env)
138                                 (space-optimize-quantity env))
139                   #-ccl-0711 (>= (speed-optimize-quantity env)
140                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
141               #'(lambda (env)
142                   (and (eq (speed-optimize-quantity env) 3) 
143                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
144               #'(lambda (env)
145                   (let* ((safety (safety-optimize-quantity env)))
146                     (or (eq safety 3)
147                         (> safety (speed-optimize-quantity env)))))          ;the-typechecks
148               #'(lambda (env)
149                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
150               #'(lambda (env)
151                   (and (neq (compilation-speed-optimize-quantity env) 3)
152                        (neq (safety-optimize-quantity env) 3)
153                        #+ccl-0711 (neq (speed-optimize-quantity env) 0)
154                        (neq (debug-optimize-quantity env) 3))) ; allow-transforms
155               #'(lambda (var env)       ; force-boundp-checks
156                   (declare (ignore var))
157                   (eq (safety-optimize-quantity env) 3))
158               #'(lambda (var val env)       ; allow-constant-substitution
159                   (declare (ignore var val env))
160                   t)
161               nil           ; extensions
162               )))
163  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
164                                   (inhibit-register-allocation nil ira-p)
165                                   (trust-declarations nil td-p)
166                                   (open-code-inline nil oci-p)
167                                   (inhibit-safety-checking nil ischeck-p)
168                                   (inline-self-calls nil iscall-p)
169                                   (allow-transforms nil at-p)
170                                   (force-boundp-checks nil fb-p)
171                                   (allow-constant-substitution nil acs-p)
172                                   (the-typechecks nil tt-p))
173    (let ((p (copy-uvector policy)))
174      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
175      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
176      (if td-p (setf (policy.trust-declarations p) trust-declarations))
177      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
178      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
179      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
180      (if at-p (setf (policy.allow-transforms p) allow-transforms))
181      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
182      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
183      (if tt-p (setf (policy.the-typechecks p) the-typechecks))
184      p))
185  (defun %default-compiler-policy () policy))
186
187(%include "ccl:compiler;lambda-list.lisp")
188
189
190
191;Syntactic Environment Access.
192
193(defun declaration-information (decl-name &optional env)
194  (if (and env (not (istruct-typep env 'lexical-environment)))
195    (report-bad-arg env 'lexical-environment))
196; *** This needs to deal with things defined with DEFINE-DECLARATION ***
197  (case decl-name
198    (optimize
199     (list 
200      (list 'speed (speed-optimize-quantity env))
201      (list 'safety (safety-optimize-quantity env))
202      (list 'compilation-speed (compilation-speed-optimize-quantity env))
203      (list 'space (space-optimize-quantity env))
204      (list 'debug (debug-optimize-quantity env))))
205    (declaration
206     *nx-known-declarations*)))
207
208(defun function-information (name &optional env &aux decls)
209  (let ((name (ensure-valid-function-name name)))
210    (if (and env (not (istruct-typep env 'lexical-environment)))
211      (report-bad-arg env 'lexical-environment))
212    (if (special-operator-p name)
213      (values :special-form nil nil)
214      (flet ((process-new-fdecls (fdecls)
215                                 (dolist (fdecl fdecls)
216                                   (when (eq (car fdecl) name)
217                                     (let ((decl-type (cadr fdecl)))
218                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
219                                                  (not (assq decl-type decls)))
220                                         (push (cdr fdecl) decls)))))))
221        (declare (dynamic-extent #'process-new-fdecls))
222        (do* ((root t)
223              (contour env (when root (lexenv.parent-env contour))))
224             ((null contour)
225              (if (macro-function name)
226                (values :macro nil nil)
227                (if (fboundp name)
228                  (values :function 
229                          nil 
230                          (if (assq 'inline decls)
231                            decls
232                            (if (proclaimed-inline-p name)
233                              (push '(inline . inline) decls)
234                                (if (proclaimed-notinline-p name)
235                                  (push '(inline . notinline) decls)))))
236                  (values nil nil decls))))
237          (if (istruct-typep contour 'definition-environment)
238            (if (assq name (defenv.functions contour))
239              (return (values :macro nil nil))
240              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
241            (progn
242              (process-new-fdecls (lexenv.fdecls contour))
243              (let ((found (assq name (lexenv.functions contour))))
244                (when found
245                  (return
246                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
247                     (values :macro t nil)
248                     (values :function t decls))))))))))))
249
250(defun variable-information (var &optional env)
251  (setq var (require-type var 'symbol))
252  (if (and env (not (istruct-typep env 'lexical-environment)))
253    (report-bad-arg env 'lexical-environment))
254  (let* ((vartype nil)
255         (boundp nil)
256         (envtype nil)
257         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
258         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
259    (loop
260      (cond ((null env)
261             (if (constant-symbol-p var)
262               (setq vartype :constant decls nil)
263               (if (proclaimed-special-p var)
264                 (setq vartype :special)
265                 (let* ((not-a-symbol-macro (cons nil nil)))
266                   (declare (dynamic-extent not-a-symbol-macro))
267                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
268                               not-a-symbol-macro)
269                     (setq vartype :symbol-macro)))))
270             (return))
271            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
272             (cond ((assq var (defenv.constants env))
273                    (setq vartype :constant)
274                    (return))
275                   ((assq var (defenv.symbol-macros env))
276                    (setq vartype :symbol-macro)
277                    (return))
278                   ((assq var (defenv.specials env))
279                    (setq vartype :special)
280                    (return))))
281            (t
282             (dolist (vdecl (lexenv.vdecls env))
283               (when (eq (car vdecl) var)
284                 (let ((decltype (cadr vdecl)))
285                   (unless (assq decltype decls)
286                     (case decltype
287                       (special (setq vartype :special))
288                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
289             (let ((vars (lexenv.variables env)))
290               (unless (atom vars)
291                 (dolist (v vars)
292                   (when (eq (var-name v) var)
293                     (setq boundp t)
294                     (if (and (consp (var-ea v))
295                              (eq :symbol-macro (car (var-ea v))))
296                       (setq vartype :symbol-macro)
297                       (unless vartype (setq vartype
298                                             (let* ((bits (var-bits v)))
299                                               (if (and (typep bits 'integer)
300                                                        (logbitp $vbitspecial bits))
301                                                 :special
302                                                 :lexical)))))
303                     (return)))
304                 (when vartype (return))))))
305      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
306    (values vartype boundp decls)))
307
308(defun nx-target-type (typespec)
309  ;; Could do a lot more here
310  (if (or (eq *host-backend* *target-backend*)
311          (not (eq typespec 'fixnum)))
312    typespec
313    (target-word-size-case
314     (32 '(signed-byte 30))
315     (64 '(signed-byte 61)))))
316
317; Type declarations affect all references.
318(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
319  (loop
320    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
321    (dolist (decl (lexenv.vdecls env))
322      (if (and (eq (car decl) sym)
323               (eq (cadr decl) 'type))
324               (return-from nx-declared-type (nx-target-type (cddr decl)))))
325    (let ((vars (lexenv.variables env)))
326      (when (and (consp vars) 
327                 (dolist (var vars) 
328                   (when (eq (var-name var) sym) 
329                     (return t))))
330        (return-from nx-declared-type t)))
331    (setq env (lexenv.parent-env env)))
332  (let ((decl (or (assq sym *nx-compile-time-types*)
333                     (assq sym *nx-proclaimed-types*))))
334    (if decl (%cdr decl) t)))
335
336(defmacro define-declaration (decl-name lambda-list &body body &environment env)
337  (multiple-value-bind (body decls)
338                       (parse-body body env)
339    (let ((fn `(nfunction (define-declaration ,decl-name)
340                          (lambda ,lambda-list
341                            ,@decls
342                            (block ,decl-name
343                              ,@body)))))
344      `(progn
345         (proclaim '(declaration ,decl-name))
346         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
347
348(defun check-environment-args (variable symbol-macro function macro)
349  (flet ((check-all-pairs (pairlist argname)
350          (dolist (pair pairlist)
351            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
352              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
353                                           argname
354                                           pair
355                                           'name
356                                           'definition
357                                           pairlist))))
358         (check-all-symbols (symlist argname pairs pairsname)
359          (dolist (v symlist)
360            (unless (symbolp v) 
361              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
362            (when (assq v pairs) 
363              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
364    (check-all-pairs symbol-macro :symbol-macro)
365    (check-all-pairs macro :macro)
366    (check-all-symbols variable :variable symbol-macro :symbol-macro)
367    (check-all-symbols function :function macro :macro)))
368
369
370;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
371(defun process-declarations (env decls symbol-macros)
372  (let ((vdecls nil)
373        (fdecls nil)
374        (mdecls nil))
375    (flet ((add-type-decl (spec)
376            (destructuring-bind (typespec &rest vars) spec
377              (dolist (var vars)
378                (when (non-nil-symbol-p var)
379                  (push (list* var 
380                               'type
381                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
382                                 (if already
383                                   (let ((oldtype (%cdr already)))
384                                     (if oldtype
385                                       (if (subtypep oldtype typespec)
386                                         oldtype
387                                         (if (subtypep typespec oldtype)
388                                           typespec))))
389                                   typespec)))
390                        vdecls))))))
391      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
392      (dolist (decl decls)
393        (when (eq (car decl) 'special)
394          (dolist (spec (%cdr decl))
395            (when (non-nil-symbol-p spec)
396              (if (assq spec symbol-macros)
397                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
398              (push (list* spec 'special t) vdecls)))))
399      (dolist (decl decls)
400        (let ((decltype (car decl)))
401          (case decltype
402              ((inline notinline)
403               (dolist (spec (%cdr decl))
404               (let ((fname nil))
405                 (if (non-nil-symbol-p spec)
406                   (setq fname spec)
407                   (if (and (consp spec) (eq (%car spec) 'setf))
408                     (setq fname (setf-function-name (cadr spec)))))
409                 (if fname
410                   (push (list* fname decltype t) fdecls)))))
411              (optimize
412               (dolist (spec (%cdr decl))
413                 (let ((val 3)
414                       (quantity spec))
415                   (if (consp spec)
416                     (setq quantity (car spec) val (cadr spec)))
417                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
418                   (push (cons quantity val) mdecls)))))
419              (dynamic-extent
420               (dolist (spec (%cdr decl))
421               (if (non-nil-symbol-p spec)
422                 (push (list* spec decltype t) vdecls)
423                 (if (and (consp spec) (eq (%car spec) 'function))
424                   (let ((fname (cadr spec)))
425                     (if (not (non-nil-symbol-p fname))
426                       (setq fname 
427                             (if (and (consp fname) (eq (%car fname) 'setf))
428                               (setf-function-name (cadr fname)))))
429                     (if fname (push (list* fname decltype t) fdecls)))))))
430              (type (add-type-decl (cdr decl)))
431              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
432                       (dolist (name fnames)
433                         (let ((fname name))
434                           (if (not (non-nil-symbol-p fname))
435                             (setq fname 
436                                   (if (and (consp fname) (eq (%car fname) 'setf))
437                                     (setf-function-name (cadr fname)))))
438                           (if fname (push (list* fname decltype typespec) fdecls))))))
439              (special)
440              (t
441               (if (memq decltype *cl-types*)
442                 (add-type-decl decl)
443                 (let ((handler (getf *declaration-handlers* decltype)))
444                   (when handler
445                     (multiple-value-bind (type info) (funcall handler decl)
446                       (ecase type
447                         (:variable
448                          (dolist (v info) (push (apply #'list* v) vdecls)))
449                         (:function
450                          (dolist (f info) (push (apply #'list* f) fdecls)))
451                         (:declare  ;; N.B. CLtL/2 semantics
452                          (push info mdecls)))))))))))
453      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
454            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
455            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
456
457 
458(defun cons-var (name &optional (bits 0))
459  (%istruct 'var name bits nil nil nil nil nil))
460
461
462(defun augment-environment (env &key variable symbol-macro function macro declare)
463  (if (and env (not (istruct-typep env 'lexical-environment)))
464    (report-bad-arg env 'lexical-environment))
465  (check-environment-args variable symbol-macro function macro)
466  (let* ((vars (mapcar #'cons-var variable))
467         (symbol-macros (mapcar #'(lambda (s)
468                                    (let* ((sym (car s)))
469                                      (unless (and (symbolp sym)
470                                                   (not (constantp sym env))
471                                                   (not (eq (variable-information sym env) :special)))
472                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
473                                      (let ((v (cons-var (car s)))) 
474                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
475                                        v)))
476                                symbol-macro))
477         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
478         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
479         (new-env (new-lexical-environment env)))
480    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
481          (lexenv.functions new-env) (nconc functions macros))
482    (process-declarations new-env declare symbol-macro)
483    new-env))
484
485(defun enclose (lambda-expression &optional env)
486  (if (and env (not (istruct-typep env 'lexical-environment)))
487    (report-bad-arg env 'lexical-environment))
488  (unless (lambda-expression-p lambda-expression)
489    (error "Invalid lambda-expression ~S." lambda-expression))
490  (%make-function nil lambda-expression env))
491
492#|| Might be nicer to do %declaim
493(defmacro declaim (&rest decl-specs &environment env)
494  `(progn
495     (eval-when (:load-toplevel :execute)
496       (proclaim ',@decl-specs))
497     (eval-when (:compile-toplevel)
498       (%declaim ',@decl-specs ,env))))
499||#
500
501(defmacro declaim (&environment env &rest decl-specs)
502  "DECLAIM Declaration*
503  Do a declaration or declarations for the global environment."
504  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
505  `(progn
506     (eval-when (:compile-toplevel)
507       (compile-time-proclamation ',decl-specs ,env))
508     (eval-when (:load-toplevel :execute)
509       ,@body))))
510
511;;; If warnings have more than a single entry on their
512;;; args slot, don't merge them.
513(defun merge-compiler-warnings (old-warnings)
514  (let ((warnings nil))
515    (dolist (w old-warnings)
516      (let* ((w-args (compiler-warning-args w)))
517        (if
518          (or (cdr w-args)
519              (dolist (w1 warnings t) 
520                (let ((w1-args (compiler-warning-args w1)))
521                  (when (and (eq (compiler-warning-warning-type w)
522                                 (compiler-warning-warning-type w1))
523                             w1-args
524                             (null (cdr w1-args))
525                             (eq (%car w-args)
526                                 (%car w1-args)))
527                    (incf (compiler-warning-nrefs w1))
528                    (return)))))
529          (push w warnings))))
530    warnings))
531
532;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
533;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
534
535(defun nx-declared-inline-p (sym env)
536  (setq sym (maybe-setf-function-name sym))
537  (loop
538    (when (listp env)
539      (return (and (symbolp sym)
540                   (proclaimed-inline-p sym))))
541    (dolist (decl (lexenv.fdecls env))
542      (when (and (eq (car decl) sym)
543                 (eq (cadr decl) 'inline))
544        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
545    (setq env (lexenv.parent-env env))))
546
547(defun report-compile-time-argument-mismatch (condition stream)
548  (destructuring-bind (callee reason args spread-p)
549      (compiler-warning-args condition)
550    (format stream "In the ~a ~s with arguments ~:s,~%  "
551            (if spread-p "application of" "call to")
552            callee
553            args)
554    (case (car reason)
555      (:toomany
556       (destructuring-bind (provided max)
557           (cdr reason)
558         (format stream "~d argument~p were provided, but at most ~d ~a accepted~&  by " provided provided max (if (eql max 1) "is" "are"))))
559      (:toofew
560       (destructuring-bind (provided min)
561           (cdr reason)
562         (format stream "~d argument~p were provided, but at least ~d ~a required~&  by " provided provided min (if (eql min 1) "is" "are") )))
563      (:odd-keywords
564       (let* ((tail (cadr reason)))
565         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
566      (:unknown-keyword
567       (destructuring-bind (badguy goodguys)
568           (cdr reason)
569         (format stream "the keyword argument ~s is not one of ~s, which are recognized~&  by " badguy goodguys))))
570    (format stream
571            (ecase (compiler-warning-warning-type condition)       
572              (:global-mismatch "the current global definition of ~s")
573              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
574              (:lexical-mismatch "the lexically visible definition of ~s"))
575            callee)))
576
577(defparameter *compiler-warning-formats*
578  '((:special . "Undeclared free variable ~S")
579    (:unused . "Unused lexical variable ~S")
580    (:ignore . "Variable ~S not ignored.")
581    (:undefined-function . "Undefined function ~S")
582    (:unknown-declaration . "Unknown declaration ~S")
583    (:unknown-type-declaration . "Unknown type ~S")
584    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
585    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
586    (:unsettable . "Shouldn't assign to variable ~S")
587    (:global-mismatch . report-compile-time-argument-mismatch)
588    (:environment-mismatch . report-compile-time-argument-mismatch)
589    (:lexical-mismatch . report-compile-time-argument-mismatch)   
590    (:type . "Type declarations violated in ~S")
591    (:type-conflict . "Conflicting type declarations for ~S")
592    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
593    (:lambda . "Suspicious lambda-list: ~s")
594    (:result-ignored . "Function result ignored in call to ~s")
595    (:duplicate-definition . report-compile-time-duplicate-definition)
596    (:program-error . "~a")
597    (:unsure . "Nonspecific warning")))
598
599(defun report-compile-time-duplicate-definition (condition stream)
600  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
601    (format stream
602            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
603            (maybe-setf-name name) from to
604            (and old-file new-file)
605            (neq old-file new-file)
606            old-file)))
607
608(defun adjust-compiler-warning-args (warning-type args)
609  (case warning-type
610    ((:undefined-function :result-ignored) (mapcar #'maybe-setf-name args))
611    (t args)))
612
613
614(defun report-compiler-warning (condition stream)
615  (let* ((warning-type (compiler-warning-warning-type condition))
616         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
617         (name (reverse (compiler-warning-function-name condition))))
618    (format stream "In ")
619    (print-nested-name name stream)
620    (when (every #'null name)
621      (let ((position (compiler-warning-stream-position condition)))
622        (when position (format stream " at position ~s" position))))
623    (format stream ": ")
624    (if (typep format-string 'string)
625      (apply #'format stream format-string (adjust-compiler-warning-args warning-type (compiler-warning-args condition)))
626      (funcall format-string condition stream))
627    ;(format stream ".")
628    (let ((nrefs (compiler-warning-nrefs condition)))
629      (when (and nrefs (neq nrefs 1))
630        (format stream " (~D references)" nrefs)))))
631
632(defun environment-structref-info (name env)
633  (let ((defenv (definition-environment env)))
634    (when defenv
635      (cdr (assq name (defenv.structrefs defenv))))))
636
637; end
Note: See TracBrowser for help on using the repository browser.