source: trunk/source/compiler/nx-basic.lisp @ 11154

Last change on this file since 11154 was 11154, checked in by gz, 12 years ago

Merge compiler policy init source of trunk and working-0711 branches, conditionalized with #+/- ccl-0711 so there are no actual changes in behavior

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 25.2 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
44
45(let ((policy (%istruct 'compiler-policy
46               #'(lambda (env)
47                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
48                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
49               #'(lambda (env)
50                   #+ccl-0711 nil
51                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
52               #'(lambda (env)
53                   (let* ((safety (safety-optimize-quantity env)))
54                     (and (< safety 3)
55                          (>= (speed-optimize-quantity env)
56                              safety)))) ; trust-declarations
57               #'(lambda (env)
58                   #+ccl-0711 (> (speed-optimize-quantity env)
59                                 (space-optimize-quantity env))
60                   #-ccl-0711 (>= (speed-optimize-quantity env)
61                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
62               #'(lambda (env)
63                   (and (eq (speed-optimize-quantity env) 3) 
64                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
65               #'(lambda (env)
66                   (let* ((safety (safety-optimize-quantity env)))
67                     (or (eq safety 3)
68                         (> safety (speed-optimize-quantity env)))))          ;the-typechecks
69               #'(lambda (env)
70                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
71               #'(lambda (env)
72                   (and (neq (compilation-speed-optimize-quantity env) 3)
73                        (neq (safety-optimize-quantity env) 3)
74                        #+ccl-0711 (neq (speed-optimize-quantity env) 0)
75                        (neq (debug-optimize-quantity env) 3))) ; allow-transforms
76               #'(lambda (var env)       ; force-boundp-checks
77                   (declare (ignore var))
78                   (eq (safety-optimize-quantity env) 3))
79               #'(lambda (var val env)       ; allow-constant-substitution
80                   (declare (ignore var val env))
81                   t)
82               nil           ; extensions
83               )))
84  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
85                                   (inhibit-register-allocation nil ira-p)
86                                   (trust-declarations nil td-p)
87                                   (open-code-inline nil oci-p)
88                                   (inhibit-safety-checking nil ischeck-p)
89                                   (inline-self-calls nil iscall-p)
90                                   (allow-transforms nil at-p)
91                                   (force-boundp-checks nil fb-p)
92                                   (allow-constant-substitution nil acs-p)
93                                   (the-typechecks nil tt-p))
94    (let ((p (copy-uvector policy)))
95      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
96      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
97      (if td-p (setf (policy.trust-declarations p) trust-declarations))
98      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
99      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
100      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
101      (if at-p (setf (policy.allow-transforms p) allow-transforms))
102      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
103      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
104      (if tt-p (setf (policy.the-typechecks p) the-typechecks))
105      p))
106  (defun %default-compiler-policy () policy))
107
108(%include "ccl:compiler;lambda-list.lisp")
109
110
111
112;Syntactic Environment Access.
113
114(defun declaration-information (decl-name &optional env)
115  (if (and env (not (istruct-typep env 'lexical-environment)))
116    (report-bad-arg env 'lexical-environment))
117; *** This needs to deal with things defined with DEFINE-DECLARATION ***
118  (case decl-name
119    (optimize
120     (list 
121      (list 'speed (speed-optimize-quantity env))
122      (list 'safety (safety-optimize-quantity env))
123      (list 'compilation-speed (compilation-speed-optimize-quantity env))
124      (list 'space (space-optimize-quantity env))
125      (list 'debug (debug-optimize-quantity env))))
126    (declaration
127     *nx-known-declarations*)))
128
129(defun function-information (name &optional env &aux decls)
130  (let ((name (ensure-valid-function-name name)))
131    (if (and env (not (istruct-typep env 'lexical-environment)))
132      (report-bad-arg env 'lexical-environment))
133    (if (special-operator-p name)
134      (values :special-form nil nil)
135      (flet ((process-new-fdecls (fdecls)
136                                 (dolist (fdecl fdecls)
137                                   (when (eq (car fdecl) name)
138                                     (let ((decl-type (cadr fdecl)))
139                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
140                                                  (not (assq decl-type decls)))
141                                         (push (cdr fdecl) decls)))))))
142        (declare (dynamic-extent #'process-new-fdecls))
143        (do* ((root t)
144              (contour env (when root (lexenv.parent-env contour))))
145             ((null contour)
146              (if (macro-function name)
147                (values :macro nil nil)
148                (if (fboundp name)
149                  (values :function 
150                          nil 
151                          (if (assq 'inline decls)
152                            decls
153                            (if (proclaimed-inline-p name)
154                              (push '(inline . inline) decls)
155                                (if (proclaimed-notinline-p name)
156                                  (push '(inline . notinline) decls)))))
157                  (values nil nil decls))))
158          (if (istruct-typep contour 'definition-environment)
159            (if (assq name (defenv.functions contour))
160              (return (values :macro nil nil))
161              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
162            (progn
163              (process-new-fdecls (lexenv.fdecls contour))
164              (let ((found (assq name (lexenv.functions contour))))
165                (when found
166                  (return
167                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
168                     (values :macro t nil)
169                     (values :function t decls))))))))))))
170
171(defun variable-information (var &optional env)
172  (setq var (require-type var 'symbol))
173  (if (and env (not (istruct-typep env 'lexical-environment)))
174    (report-bad-arg env 'lexical-environment))
175  (let* ((vartype nil)
176         (boundp nil)
177         (envtype nil)
178         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
179         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
180    (loop
181      (cond ((null env)
182             (if (constant-symbol-p var)
183               (setq vartype :constant decls nil)
184               (if (proclaimed-special-p var)
185                 (setq vartype :special)
186                 (let* ((not-a-symbol-macro (cons nil nil)))
187                   (declare (dynamic-extent not-a-symbol-macro))
188                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
189                               not-a-symbol-macro)
190                     (setq vartype :symbol-macro)))))
191             (return))
192            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
193             (cond ((assq var (defenv.constants env))
194                    (setq vartype :constant)
195                    (return))
196                   ((assq var (defenv.symbol-macros env))
197                    (setq vartype :symbol-macro)
198                    (return))
199                   ((assq var (defenv.specials env))
200                    (setq vartype :special)
201                    (return))))
202            (t
203             (dolist (vdecl (lexenv.vdecls env))
204               (when (eq (car vdecl) var)
205                 (let ((decltype (cadr vdecl)))
206                   (unless (assq decltype decls)
207                     (case decltype
208                       (special (setq vartype :special))
209                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
210             (let ((vars (lexenv.variables env)))
211               (unless (atom vars)
212                 (dolist (v vars)
213                   (when (eq (var-name v) var)
214                     (setq boundp t)
215                     (if (and (consp (var-ea v))
216                              (eq :symbol-macro (car (var-ea v))))
217                       (setq vartype :symbol-macro)
218                       (unless vartype (setq vartype
219                                             (let* ((bits (var-bits v)))
220                                               (if (and (typep bits 'integer)
221                                                        (logbitp $vbitspecial bits))
222                                                 :special
223                                                 :lexical)))))
224                     (return)))
225                 (when vartype (return))))))
226      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
227    (values vartype boundp decls)))
228
229(defun nx-target-type (typespec)
230  ;; Could do a lot more here
231  (if (or (eq *host-backend* *target-backend*)
232          (not (eq typespec 'fixnum)))
233    typespec
234    (target-word-size-case
235     (32 '(signed-byte 30))
236     (64 '(signed-byte 61)))))
237
238; Type declarations affect all references.
239(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
240  (loop
241    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
242    (dolist (decl (lexenv.vdecls env))
243      (if (and (eq (car decl) sym)
244               (eq (cadr decl) 'type))
245               (return-from nx-declared-type (nx-target-type (cddr decl)))))
246    (let ((vars (lexenv.variables env)))
247      (when (and (consp vars) 
248                 (dolist (var vars) 
249                   (when (eq (var-name var) sym) 
250                     (return t))))
251        (return-from nx-declared-type t)))
252    (setq env (lexenv.parent-env env)))
253  (let ((decl (or (assq sym *nx-compile-time-types*)
254                     (assq sym *nx-proclaimed-types*))))
255    (if decl (%cdr decl) t)))
256
257(defmacro define-declaration (decl-name lambda-list &body body &environment env)
258  (multiple-value-bind (body decls)
259                       (parse-body body env)
260    (let ((fn `(nfunction (define-declaration ,decl-name)
261                          (lambda ,lambda-list
262                            ,@decls
263                            (block ,decl-name
264                              ,@body)))))
265      `(progn
266         (proclaim '(declaration ,decl-name))
267         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
268
269(defun check-environment-args (variable symbol-macro function macro)
270  (flet ((check-all-pairs (pairlist argname)
271          (dolist (pair pairlist)
272            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
273              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
274                                           argname
275                                           pair
276                                           'name
277                                           'definition
278                                           pairlist))))
279         (check-all-symbols (symlist argname pairs pairsname)
280          (dolist (v symlist)
281            (unless (symbolp v) 
282              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
283            (when (assq v pairs) 
284              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
285    (check-all-pairs symbol-macro :symbol-macro)
286    (check-all-pairs macro :macro)
287    (check-all-symbols variable :variable symbol-macro :symbol-macro)
288    (check-all-symbols function :function macro :macro)))
289
290
291;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
292(defun process-declarations (env decls symbol-macros)
293  (let ((vdecls nil)
294        (fdecls nil)
295        (mdecls nil))
296    (flet ((add-type-decl (spec)
297            (destructuring-bind (typespec &rest vars) spec
298              (dolist (var vars)
299                (when (non-nil-symbol-p var)
300                  (push (list* var 
301                               'type
302                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
303                                 (if already
304                                   (let ((oldtype (%cdr already)))
305                                     (if oldtype
306                                       (if (subtypep oldtype typespec)
307                                         oldtype
308                                         (if (subtypep typespec oldtype)
309                                           typespec))))
310                                   typespec)))
311                        vdecls))))))
312      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
313      (dolist (decl decls)
314        (when (eq (car decl) 'special)
315          (dolist (spec (%cdr decl))
316            (when (non-nil-symbol-p spec)
317              (if (assq spec symbol-macros)
318                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
319              (push (list* spec 'special t) vdecls)))))
320      (dolist (decl decls)
321        (let ((decltype (car decl)))
322          (case decltype
323              ((inline notinline)
324               (dolist (spec (%cdr decl))
325               (let ((fname nil))
326                 (if (non-nil-symbol-p spec)
327                   (setq fname spec)
328                   (if (and (consp spec) (eq (%car spec) 'setf))
329                     (setq fname (setf-function-name (cadr spec)))))
330                 (if fname
331                   (push (list* fname decltype t) fdecls)))))
332              (optimize
333               (dolist (spec (%cdr decl))
334                 (let ((val 3)
335                       (quantity spec))
336                   (if (consp spec)
337                     (setq quantity (car spec) val (cadr spec)))
338                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
339                   (push (cons quantity val) mdecls)))))
340              (dynamic-extent
341               (dolist (spec (%cdr decl))
342               (if (non-nil-symbol-p spec)
343                 (push (list* spec decltype t) vdecls)
344                 (if (and (consp spec) (eq (%car spec) 'function))
345                   (let ((fname (cadr spec)))
346                     (if (not (non-nil-symbol-p fname))
347                       (setq fname 
348                             (if (and (consp fname) (eq (%car fname) 'setf))
349                               (setf-function-name (cadr fname)))))
350                     (if fname (push (list* fname decltype t) fdecls)))))))
351              (type (add-type-decl (cdr decl)))
352              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
353                       (dolist (name fnames)
354                         (let ((fname name))
355                           (if (not (non-nil-symbol-p fname))
356                             (setq fname 
357                                   (if (and (consp fname) (eq (%car fname) 'setf))
358                                     (setf-function-name (cadr fname)))))
359                           (if fname (push (list* fname decltype typespec) fdecls))))))
360              (special)
361              (t
362               (if (memq decltype *cl-types*)
363                 (add-type-decl decl)
364                 (let ((handler (getf *declaration-handlers* decltype)))
365                   (when handler
366                     (multiple-value-bind (type info) (funcall handler decl)
367                       (ecase type
368                         (:variable
369                          (dolist (v info) (push (apply #'list* v) vdecls)))
370                         (:function
371                          (dolist (f info) (push (apply #'list* f) fdecls)))
372                         (:declare  ;; N.B. CLtL/2 semantics
373                          (push info mdecls)))))))))))
374      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
375            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
376            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
377
378 
379(defun cons-var (name &optional (bits 0))
380  (%istruct 'var name bits nil nil nil nil nil))
381
382
383(defun augment-environment (env &key variable symbol-macro function macro declare)
384  (if (and env (not (istruct-typep env 'lexical-environment)))
385    (report-bad-arg env 'lexical-environment))
386  (check-environment-args variable symbol-macro function macro)
387  (let* ((vars (mapcar #'cons-var variable))
388         (symbol-macros (mapcar #'(lambda (s)
389                                    (let* ((sym (car s)))
390                                      (unless (and (symbolp sym)
391                                                   (not (constantp sym env))
392                                                   (not (eq (variable-information sym env) :special)))
393                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
394                                      (let ((v (cons-var (car s)))) 
395                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
396                                        v)))
397                                symbol-macro))
398         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
399         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
400         (new-env (new-lexical-environment env)))
401    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
402          (lexenv.functions new-env) (nconc functions macros))
403    (process-declarations new-env declare symbol-macro)
404    new-env))
405
406(defun enclose (lambda-expression &optional env)
407  (if (and env (not (istruct-typep env 'lexical-environment)))
408    (report-bad-arg env 'lexical-environment))
409  (unless (lambda-expression-p lambda-expression)
410    (error "Invalid lambda-expression ~S." lambda-expression))
411  (%make-function nil lambda-expression env))
412
413#|| Might be nicer to do %declaim
414(defmacro declaim (&rest decl-specs &environment env)
415  `(progn
416     (eval-when (:load-toplevel :execute)
417       (proclaim ',@decl-specs))
418     (eval-when (:compile-toplevel)
419       (%declaim ',@decl-specs ,env))))
420||#
421
422(defmacro declaim (&environment env &rest decl-specs)
423  "DECLAIM Declaration*
424  Do a declaration or declarations for the global environment."
425  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
426  `(progn
427     (eval-when (:compile-toplevel)
428       (compile-time-proclamation ',decl-specs ,env))
429     (eval-when (:load-toplevel :execute)
430       ,@body))))
431
432;;; If warnings have more than a single entry on their
433;;; args slot, don't merge them.
434(defun merge-compiler-warnings (old-warnings)
435  (let ((warnings nil))
436    (dolist (w old-warnings)
437      (let* ((w-args (compiler-warning-args w)))
438        (if
439          (or (cdr w-args)
440              (dolist (w1 warnings t) 
441                (let ((w1-args (compiler-warning-args w1)))
442                  (when (and (eq (compiler-warning-warning-type w)
443                                 (compiler-warning-warning-type w1))
444                             w1-args
445                             (null (cdr w1-args))
446                             (eq (%car w-args)
447                                 (%car w1-args)))
448                    (incf (compiler-warning-nrefs w1))
449                    (return)))))
450          (push w warnings))))
451    warnings))
452
453;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
454;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
455
456(defun nx-declared-inline-p (sym env)
457  (setq sym (maybe-setf-function-name sym))
458  (loop
459    (when (listp env)
460      (return (and (symbolp sym)
461                   (proclaimed-inline-p sym))))
462    (dolist (decl (lexenv.fdecls env))
463      (when (and (eq (car decl) sym)
464                 (eq (cadr decl) 'inline))
465        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
466    (setq env (lexenv.parent-env env))))
467
468(defun report-compile-time-argument-mismatch (condition stream)
469  (destructuring-bind (callee reason args spread-p)
470      (compiler-warning-args condition)
471    (format stream "In the ~a ~s with arguments ~:s,~%  "
472            (if spread-p "application of" "call to")
473            callee
474            args)
475    (case (car reason)
476      (:toomany
477       (destructuring-bind (provided max)
478           (cdr reason)
479         (format stream "~d argument~p were provided, but at most ~d ~a accepted~&  by " provided provided max (if (eql max 1) "is" "are"))))
480      (:toofew
481       (destructuring-bind (provided min)
482           (cdr reason)
483         (format stream "~d argument~p were provided, but at least ~d ~a required~&  by " provided provided min (if (eql min 1) "is" "are") )))
484      (:odd-keywords
485       (let* ((tail (cadr reason)))
486         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
487      (:unknown-keyword
488       (destructuring-bind (badguy goodguys)
489           (cdr reason)
490         (format stream "the keyword argument ~s is not one of ~s, which are recognized~&  by " badguy goodguys))))
491    (format stream
492            (ecase (compiler-warning-warning-type condition)       
493              (:global-mismatch "the current global definition of ~s")
494              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
495              (:lexical-mismatch "the lexically visible definition of ~s"))
496            callee)))
497
498(defparameter *compiler-warning-formats*
499  '((:special . "Undeclared free variable ~S")
500    (:unused . "Unused lexical variable ~S")
501    (:ignore . "Variable ~S not ignored.")
502    (:undefined-function . "Undefined function ~S")
503    (:unknown-declaration . "Unknown declaration ~S")
504    (:unknown-type-declaration . "Unknown type ~S")
505    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
506    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
507    (:unsettable . "Shouldn't assign to variable ~S")
508    (:global-mismatch . report-compile-time-argument-mismatch)
509    (:environment-mismatch . report-compile-time-argument-mismatch)
510    (:lexical-mismatch . report-compile-time-argument-mismatch)   
511    (:type . "Type declarations violated in ~S")
512    (:type-conflict . "Conflicting type declarations for ~S")
513    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
514    (:lambda . "Suspicious lambda-list: ~s")
515    (:result-ignored . "Function result ignored in call to ~s")
516    (:duplicate-definition . report-compile-time-duplicate-definition)
517    (:program-error . "~a")))
518
519(defun report-compile-time-duplicate-definition (condition stream)
520  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
521    (format stream
522            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
523            name from to
524            (and old-file new-file)
525            (neq old-file new-file)
526            old-file)))
527
528(defun report-compiler-warning (condition stream)
529  (let* ((warning-type (compiler-warning-warning-type condition))
530         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
531         (name (reverse (compiler-warning-function-name condition))))
532    (format stream "In ")
533    (print-nested-name name stream)
534    (when (every #'null name)
535      (let ((position (compiler-warning-stream-position condition)))
536        (when position (format stream " at position ~s" position))))
537    (format stream ": ")
538    (if (typep format-string 'string)
539      (apply #'format stream format-string (compiler-warning-args condition))
540      (funcall format-string condition stream))
541    ;(format stream ".")
542    (let ((nrefs (compiler-warning-nrefs condition)))
543      (when (and nrefs (neq nrefs 1))
544        (format stream " (~D references)" nrefs)))))
545
546(defun environment-structref-info (name env)
547  (let ((defenv (definition-environment env)))
548    (when defenv
549      (cdr (assq name (defenv.structrefs defenv))))))
550
551; end
Note: See TracBrowser for help on using the repository browser.