source: trunk/source/compiler/nx-basic.lisp @ 11088

Last change on this file since 11088 was 11088, checked in by gz, 12 years ago

Trivial tweaks, mostly indentation and comments, to simplify merging with working-0711 branch

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 24.9 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
44
45(let ((policy (%istruct 'compiler-policy
46               #'(lambda (env)
47                   (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
48               #'(lambda (env)
49                   (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
50               #'(lambda (env)
51                   (let* ((safety (safety-optimize-quantity env)))
52                     (and (< safety 3)
53                          (>= (speed-optimize-quantity env)
54                              safety)))) ; trust-declarations
55               #'(lambda (env)
56                   (>= (speed-optimize-quantity env)
57                       (+ (space-optimize-quantity env) 2)))    ; open-code-inline
58               #'(lambda (env)
59                   (and (eq (speed-optimize-quantity env) 3) 
60                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
61               #'(lambda (env)
62                   (let* ((safety (safety-optimize-quantity env)))
63                     (or (eq safety 3)
64                         (> safety (speed-optimize-quantity env)))))          ;the-typechecks
65               #'(lambda (env)
66                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
67               #'(lambda (env)
68                   (and (neq (compilation-speed-optimize-quantity env) 3)
69                        (neq (safety-optimize-quantity env) 3)
70                        (neq (debug-optimize-quantity env) 3)))   ; allow-transforms
71               #'(lambda (var env)       ; force-boundp-checks
72                   (declare (ignore var))
73                   (eq (safety-optimize-quantity env) 3))
74               #'(lambda (var val env)       ; allow-constant-substitution
75                   (declare (ignore var val env))
76                   t)
77               nil           ; extensions
78               )))
79  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
80                                   (inhibit-register-allocation nil ira-p)
81                                   (trust-declarations nil td-p)
82                                   (open-code-inline nil oci-p)
83                                   (inhibit-safety-checking nil ischeck-p)
84                                   (inline-self-calls nil iscall-p)
85                                   (allow-transforms nil at-p)
86                                   (force-boundp-checks nil fb-p)
87                                   (allow-constant-substitution nil acs-p)
88                                   (the-typechecks nil tt-p))
89    (let ((p (copy-uvector policy)))
90      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
91      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
92      (if td-p (setf (policy.trust-declarations p) trust-declarations))
93      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
94      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
95      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
96      (if at-p (setf (policy.allow-transforms p) allow-transforms))
97      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
98      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
99      (if tt-p (setf (policy.the-typechecks p) the-typechecks))
100      p))
101  (defun %default-compiler-policy () policy))
102
103(%include "ccl:compiler;lambda-list.lisp")
104
105
106
107;Syntactic Environment Access.
108
109(defun declaration-information (decl-name &optional env)
110  (if (and env (not (istruct-typep env 'lexical-environment)))
111    (report-bad-arg env 'lexical-environment))
112; *** This needs to deal with things defined with DEFINE-DECLARATION ***
113  (case decl-name
114    (optimize
115     (list 
116      (list 'speed (speed-optimize-quantity env))
117      (list 'safety (safety-optimize-quantity env))
118      (list 'compilation-speed (compilation-speed-optimize-quantity env))
119      (list 'space (space-optimize-quantity env))
120      (list 'debug (debug-optimize-quantity env))))
121    (declaration
122     *nx-known-declarations*)))
123
124(defun function-information (name &optional env &aux decls)
125  (let ((name (ensure-valid-function-name name)))
126    (if (and env (not (istruct-typep env 'lexical-environment)))
127      (report-bad-arg env 'lexical-environment))
128    (if (special-operator-p name)
129      (values :special-form nil nil)
130      (flet ((process-new-fdecls (fdecls)
131                                 (dolist (fdecl fdecls)
132                                   (when (eq (car fdecl) name)
133                                     (let ((decl-type (cadr fdecl)))
134                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
135                                                  (not (assq decl-type decls)))
136                                         (push (cdr fdecl) decls)))))))
137        (declare (dynamic-extent #'process-new-fdecls))
138        (do* ((root t)
139              (contour env (when root (lexenv.parent-env contour))))
140             ((null contour)
141              (if (macro-function name)
142                (values :macro nil nil)
143                (if (fboundp name)
144                  (values :function 
145                          nil 
146                          (if (assq 'inline decls)
147                            decls
148                            (if (proclaimed-inline-p name)
149                              (push '(inline . inline) decls)
150                                (if (proclaimed-notinline-p name)
151                                  (push '(inline . notinline) decls)))))
152                  (values nil nil decls))))
153          (if (istruct-typep contour 'definition-environment)
154            (if (assq name (defenv.functions contour))
155              (return (values :macro nil nil))
156              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
157            (progn
158              (process-new-fdecls (lexenv.fdecls contour))
159              (let ((found (assq name (lexenv.functions contour))))
160                (when found
161                  (return
162                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
163                     (values :macro t nil)
164                     (values :function t decls))))))))))))
165
166(defun variable-information (var &optional env)
167  (setq var (require-type var 'symbol))
168  (if (and env (not (istruct-typep env 'lexical-environment)))
169    (report-bad-arg env 'lexical-environment))
170  (let* ((vartype nil)
171         (boundp nil)
172         (envtype nil)
173         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
174         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
175    (loop
176      (cond ((null env)
177             (if (constant-symbol-p var)
178               (setq vartype :constant decls nil)
179               (if (proclaimed-special-p var)
180                 (setq vartype :special)
181                 (let* ((not-a-symbol-macro (cons nil nil)))
182                   (declare (dynamic-extent not-a-symbol-macro))
183                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
184                               not-a-symbol-macro)
185                     (setq vartype :symbol-macro)))))
186             (return))
187            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
188             (cond ((assq var (defenv.constants env))
189                    (setq vartype :constant)
190                    (return))
191                   ((assq var (defenv.symbol-macros env))
192                    (setq vartype :symbol-macro)
193                    (return))
194                   ((assq var (defenv.specials env))
195                    (setq vartype :special)
196                    (return))))
197            (t
198             (dolist (vdecl (lexenv.vdecls env))
199               (when (eq (car vdecl) var)
200                 (let ((decltype (cadr vdecl)))
201                   (unless (assq decltype decls)
202                     (case decltype
203                       (special (setq vartype :special))
204                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
205             (let ((vars (lexenv.variables env)))
206               (unless (atom vars)
207                 (dolist (v vars)
208                   (when (eq (var-name v) var)
209                     (setq boundp t)
210                     (if (and (consp (var-ea v))
211                              (eq :symbol-macro (car (var-ea v))))
212                       (setq vartype :symbol-macro)
213                       (unless vartype (setq vartype
214                                             (let* ((bits (var-bits v)))
215                                               (if (and (typep bits 'integer)
216                                                        (logbitp $vbitspecial bits))
217                                                 :special
218                                                 :lexical)))))
219                     (return)))
220                 (when vartype (return))))))
221      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
222    (values vartype boundp decls)))
223
224(defun nx-target-type (typespec)
225  ;; Could do a lot more here
226  (if (or (eq *host-backend* *target-backend*)
227          (not (eq typespec 'fixnum)))
228    typespec
229    (target-word-size-case
230     (32 '(signed-byte 30))
231     (64 '(signed-byte 61)))))
232
233; Type declarations affect all references.
234(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
235  (loop
236    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
237    (dolist (decl (lexenv.vdecls env))
238      (if (and (eq (car decl) sym)
239               (eq (cadr decl) 'type))
240               (return-from nx-declared-type (nx-target-type (cddr decl)))))
241    (let ((vars (lexenv.variables env)))
242      (when (and (consp vars) 
243                 (dolist (var vars) 
244                   (when (eq (var-name var) sym) 
245                     (return t))))
246        (return-from nx-declared-type t)))
247    (setq env (lexenv.parent-env env)))
248  (let ((decl (or (assq sym *nx-compile-time-types*)
249                     (assq sym *nx-proclaimed-types*))))
250    (if decl (%cdr decl) t)))
251
252(defmacro define-declaration (decl-name lambda-list &body body &environment env)
253  (multiple-value-bind (body decls)
254                       (parse-body body env)
255    (let ((fn `(nfunction (define-declaration ,decl-name)
256                          (lambda ,lambda-list
257                            ,@decls
258                            (block ,decl-name
259                              ,@body)))))
260      `(progn
261         (proclaim '(declaration ,decl-name))
262         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
263
264(defun check-environment-args (variable symbol-macro function macro)
265  (flet ((check-all-pairs (pairlist argname)
266          (dolist (pair pairlist)
267            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
268              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
269                                           argname
270                                           pair
271                                           'name
272                                           'definition
273                                           pairlist))))
274         (check-all-symbols (symlist argname pairs pairsname)
275          (dolist (v symlist)
276            (unless (symbolp v) 
277              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
278            (when (assq v pairs) 
279              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
280    (check-all-pairs symbol-macro :symbol-macro)
281    (check-all-pairs macro :macro)
282    (check-all-symbols variable :variable symbol-macro :symbol-macro)
283    (check-all-symbols function :function macro :macro)))
284
285
286;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
287(defun process-declarations (env decls symbol-macros)
288  (let ((vdecls nil)
289        (fdecls nil)
290        (mdecls nil))
291    (flet ((add-type-decl (spec)
292            (destructuring-bind (typespec &rest vars) spec
293              (dolist (var vars)
294                (when (non-nil-symbol-p var)
295                  (push (list* var 
296                               'type
297                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
298                                 (if already
299                                   (let ((oldtype (%cdr already)))
300                                     (if oldtype
301                                       (if (subtypep oldtype typespec)
302                                         oldtype
303                                         (if (subtypep typespec oldtype)
304                                           typespec))))
305                                   typespec)))
306                        vdecls))))))
307      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
308      (dolist (decl decls)
309        (when (eq (car decl) 'special)
310          (dolist (spec (%cdr decl))
311            (when (non-nil-symbol-p spec)
312              (if (assq spec symbol-macros)
313                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
314              (push (list* spec 'special t) vdecls)))))
315      (dolist (decl decls)
316        (let ((decltype (car decl)))
317          (case decltype
318              ((inline notinline)
319               (dolist (spec (%cdr decl))
320               (let ((fname nil))
321                 (if (non-nil-symbol-p spec)
322                   (setq fname spec)
323                   (if (and (consp spec) (eq (%car spec) 'setf))
324                     (setq fname (setf-function-name (cadr spec)))))
325                 (if fname
326                   (push (list* fname decltype t) fdecls)))))
327              (optimize
328               (dolist (spec (%cdr decl))
329                 (let ((val 3)
330                       (quantity spec))
331                   (if (consp spec)
332                     (setq quantity (car spec) val (cadr spec)))
333                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
334                   (push (cons quantity val) mdecls)))))
335              (dynamic-extent
336               (dolist (spec (%cdr decl))
337               (if (non-nil-symbol-p spec)
338                 (push (list* spec decltype t) vdecls)
339                 (if (and (consp spec) (eq (%car spec) 'function))
340                   (let ((fname (cadr spec)))
341                     (if (not (non-nil-symbol-p fname))
342                       (setq fname 
343                             (if (and (consp fname) (eq (%car fname) 'setf))
344                               (setf-function-name (cadr fname)))))
345                     (if fname (push (list* fname decltype t) fdecls)))))))
346              (type (add-type-decl (cdr decl)))
347              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
348                       (dolist (name fnames)
349                         (let ((fname name))
350                           (if (not (non-nil-symbol-p fname))
351                             (setq fname 
352                                   (if (and (consp fname) (eq (%car fname) 'setf))
353                                     (setf-function-name (cadr fname)))))
354                           (if fname (push (list* fname decltype typespec) fdecls))))))
355              (special)
356              (t
357               (if (memq decltype *cl-types*)
358                 (add-type-decl decl)
359                 (let ((handler (getf *declaration-handlers* decltype)))
360                   (when handler
361                     (multiple-value-bind (type info) (funcall handler decl)
362                       (ecase type
363                         (:variable
364                          (dolist (v info) (push (apply #'list* v) vdecls)))
365                         (:function
366                          (dolist (f info) (push (apply #'list* f) fdecls)))
367                         (:declare  ;; N.B. CLtL/2 semantics
368                          (push info mdecls)))))))))))
369      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
370            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
371            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
372
373 
374(defun cons-var (name &optional (bits 0))
375  (%istruct 'var name bits nil nil nil nil nil))
376
377
378(defun augment-environment (env &key variable symbol-macro function macro declare)
379  (if (and env (not (istruct-typep env 'lexical-environment)))
380    (report-bad-arg env 'lexical-environment))
381  (check-environment-args variable symbol-macro function macro)
382  (let* ((vars (mapcar #'cons-var variable))
383         (symbol-macros (mapcar #'(lambda (s)
384                                    (let* ((sym (car s)))
385                                      (unless (and (symbolp sym)
386                                                   (not (constantp sym env))
387                                                   (not (eq (variable-information sym env) :special)))
388                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
389                                      (let ((v (cons-var (car s)))) 
390                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
391                                        v)))
392                                symbol-macro))
393         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
394         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
395         (new-env (new-lexical-environment env)))
396    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
397          (lexenv.functions new-env) (nconc functions macros))
398    (process-declarations new-env declare symbol-macro)
399    new-env))
400
401(defun enclose (lambda-expression &optional env)
402  (if (and env (not (istruct-typep env 'lexical-environment)))
403    (report-bad-arg env 'lexical-environment))
404  (unless (lambda-expression-p lambda-expression)
405    (error "Invalid lambda-expression ~S." lambda-expression))
406  (%make-function nil lambda-expression env))
407
408#|| Might be nicer to do %declaim
409(defmacro declaim (&rest decl-specs &environment env)
410  `(progn
411     (eval-when (:load-toplevel :execute)
412       (proclaim ',@decl-specs))
413     (eval-when (:compile-toplevel)
414       (%declaim ',@decl-specs ,env))))
415||#
416
417(defmacro declaim (&environment env &rest decl-specs)
418  "DECLAIM Declaration*
419  Do a declaration or declarations for the global environment."
420  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
421  `(progn
422     (eval-when (:compile-toplevel)
423       (compile-time-proclamation ',decl-specs ,env))
424     (eval-when (:load-toplevel :execute)
425       ,@body))))
426
427;;; If warnings have more than a single entry on their
428;;; args slot, don't merge them.
429(defun merge-compiler-warnings (old-warnings)
430  (let ((warnings nil))
431    (dolist (w old-warnings)
432      (let* ((w-args (compiler-warning-args w)))
433        (if
434          (or (cdr w-args)
435              (dolist (w1 warnings t) 
436                (let ((w1-args (compiler-warning-args w1)))
437                  (when (and (eq (compiler-warning-warning-type w)
438                                 (compiler-warning-warning-type w1))
439                             w1-args
440                             (null (cdr w1-args))
441                             (eq (%car w-args)
442                                 (%car w1-args)))
443                    (incf (compiler-warning-nrefs w1))
444                    (return)))))
445          (push w warnings))))
446    warnings))
447
448;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
449;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
450
451(defun nx-declared-inline-p (sym env)
452  (setq sym (maybe-setf-function-name sym))
453  (loop
454    (when (listp env)
455      (return (and (symbolp sym)
456                   (proclaimed-inline-p sym))))
457    (dolist (decl (lexenv.fdecls env))
458      (when (and (eq (car decl) sym)
459                 (eq (cadr decl) 'inline))
460        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
461    (setq env (lexenv.parent-env env))))
462
463(defun report-compile-time-argument-mismatch (condition stream)
464  (destructuring-bind (callee reason args spread-p)
465      (compiler-warning-args condition)
466    (format stream "In the ~a ~s with arguments ~:s,~%  "
467            (if spread-p "application of" "call to")
468            callee
469            args)
470    (case (car reason)
471      (:toomany
472       (destructuring-bind (provided max)
473           (cdr reason)
474         (format stream "~d argument~p were provided, but at most ~d ~a accepted~&  by " provided provided max (if (eql max 1) "is" "are"))))
475      (:toofew
476       (destructuring-bind (provided min)
477           (cdr reason)
478         (format stream "~d argument~p were provided, but at least ~d ~a required~&  by " provided provided min (if (eql min 1) "is" "are") )))
479      (:odd-keywords
480       (let* ((tail (cadr reason)))
481         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
482      (:unknown-keyword
483       (destructuring-bind (badguy goodguys)
484           (cdr reason)
485         (format stream "the keyword argument ~s is not one of ~s, which are recognized~&  by " badguy goodguys))))
486    (format stream
487            (ecase (compiler-warning-warning-type condition)       
488              (:global-mismatch "the current global definition of ~s")
489              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
490              (:lexical-mismatch "the lexically visible definition of ~s"))
491            callee)))
492
493(defparameter *compiler-warning-formats*
494  '((:special . "Undeclared free variable ~S")
495    (:unused . "Unused lexical variable ~S")
496    (:ignore . "Variable ~S not ignored.")
497    (:undefined-function . "Undefined function ~S")
498    (:unknown-declaration . "Unknown declaration ~S")
499    (:unknown-type-declaration . "Unknown type ~S")
500    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
501    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
502    (:unsettable . "Shouldn't assign to variable ~S")
503    (:global-mismatch . report-compile-time-argument-mismatch)
504    (:environment-mismatch . report-compile-time-argument-mismatch)
505    (:lexical-mismatch . report-compile-time-argument-mismatch)   
506    (:type . "Type declarations violated in ~S")
507    (:type-conflict . "Conflicting type declarations for ~S")
508    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
509    (:lambda . "Suspicious lambda-list: ~s")
510    (:result-ignored . "Function result ignored in call to ~s")
511    (:duplicate-definition . report-compile-time-duplicate-definition)
512    (:program-error . "~a")))
513
514(defun report-compile-time-duplicate-definition (condition stream)
515  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
516    (format stream
517            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
518            name from to
519            (and old-file new-file)
520            (neq old-file new-file)
521            old-file)))
522
523(defun report-compiler-warning (condition stream)
524  (let* ((warning-type (compiler-warning-warning-type condition))
525         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
526         (name (reverse (compiler-warning-function-name condition))))
527    (format stream "In ")
528    (print-nested-name name stream)
529    (when (every #'null name)
530      (let ((position (compiler-warning-stream-position condition)))
531        (when position (format stream " at position ~s" position))))
532    (format stream ": ")
533    (if (typep format-string 'string)
534      (apply #'format stream format-string (compiler-warning-args condition))
535      (funcall format-string condition stream))
536    ;(format stream ".")
537    (let ((nrefs (compiler-warning-nrefs condition)))
538      (when (and nrefs (neq nrefs 1))
539        (format stream " (~D references)" nrefs)))))
540
541(defun environment-structref-info (name env)
542  (let ((defenv (definition-environment env)))
543    (when defenv
544      (cdr (assq name (defenv.structrefs defenv))))))
545
546; end
Note: See TracBrowser for help on using the repository browser.