source: trunk/source/cocoa-ide/hemlock/src/lispmode.lisp @ 15906

Last change on this file since 15906 was 15906, checked in by gz, 8 years ago

Introduced a new convention: symbols exported from the HEMLOCK package are there for the IDE to use. Added a new hemlock file, display.lisp, which defines a set of such functions, mostly code that used to be in the IDE but had no actual Cocoa dependencies - we now have hemlock:update-current-package, hemlock:paren-matching-bounds, hemlock:selection-for-click, hemlock:move-point-for-click, and hemlock:compute-syntax-coloring.

New fn hemlock-ext:lookup-color maps a color description to a Cocoa color object. The current implementation is rudimentary, I'm hoping someone can make
it more real.

Extended hemlock:compute-syntax-coloring to add coloring for symbols. This fixes ticket:125.
To change how symbol colors get decided, you're most likely to want to modify some of:

hemlock::compute-symbol-category
hemlock::defining-symbol-p
hemlock::*lisp-code-colors*

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 87.5 KB
Line 
1;;; -*- Log: hemlock.log; Package: Hemlock -*-
2;;;
3;;; **********************************************************************
4;;; This code was written as part of the CMU Common Lisp project at
5;;; Carnegie Mellon University, and has been placed in the public domain.
6;;;
7#+CMU (ext:file-comment
8  "$Header$")
9;;;
10;;; **********************************************************************
11;;;
12;;; Hemlock LISP Mode commands
13;;;
14;;; Written by Ivan Vazquez and Bill Maddox.
15;;;
16
17(in-package :hemlock)
18
19;; (declaim (optimize (speed 2))); turn off byte compilation.
20
21
22;;;; Variables and lisp-info structure.
23
24;;; These routines are used to define, for standard LISP mode, the start and end
25;;; of a block to parse.  If these need to be changed for a minor mode that sits
26;;; on top of LISP mode, simply do a DEFHVAR with the minor mode and give the
27;;; name of the function to use instead of START-OF-PARSE-BLOCK and
28;;; END-OF-PARSE-BLOCK.
29;;;
30
31(defhvar "Parse Start Function"
32  "Take a mark and move it to the top of a block for paren parsing."
33  :value 'start-of-parse-block)
34
35(defhvar "Parse End Function"
36  "Take a mark and move it to the bottom of a block for paren parsing."
37  :value 'end-of-parse-block)
38
39           
40;;; LISP-INFO is the structure used to store the data about the line in its
41;;; Plist.
42;;;
43;;;     -> BEGINS-QUOTED, ENDING-QUOTED are both slots that tell whether or not
44;;;        a line's begining and/or ending are quoted, and if so, how.
45;;;
46;;;     -> RANGES-TO-IGNORE is a list of cons cells, each having the form
47;;;        ( [begining-charpos] [end-charpos] ) each of these cells indicating
48;;;        a range where :lisp-syntax attributes are ignored.  End is exclusive.
49;;;
50;;;     -> NET-OPEN-PARENS, NET-CLOSE-PARENS integers that are the number of
51;;;        unmatched opening and closing parens that there are on a line.
52;;;
53;;;     -> SIGNATURE-SLOT ...
54;;;
55
56(defstruct (lisp-info (:constructor make-lisp-info ()))
57  (begins-quoted nil)           ; nil or quote char attribute or comment nesting depth
58  (ending-quoted nil)           ; nil or quote char attribute or comment nesting depth
59  (ranges-to-ignore nil)
60  (net-open-parens 0 :type fixnum)
61  (net-close-parens 0 :type fixnum)
62  (signature-slot))
63
64
65
66;;;; Macros.
67
68;;; The following Macros exist to make it easy to acces the Syntax primitives
69;;; without uglifying the code.  They were originally written by Maddox.
70;;;
71
72(defmacro scan-char (mark attribute values)
73  `(find-attribute ,mark ',attribute ,(attr-predicate values)))
74
75(defmacro rev-scan-char (mark attribute values)
76  `(reverse-find-attribute ,mark ',attribute ,(attr-predicate values)))
77
78(defmacro test-char (char attribute values)
79  `(let ((x (character-attribute ',attribute ,char)))
80     ,(attr-predicate-aux values)))
81
82(eval-when (:compile-toplevel :execute :load-toplevel)
83(defun attr-predicate (values)
84  (cond ((eq values 't)
85         '#'plusp)
86        ((eq values 'nil)
87         '#'zerop)
88        (t `#'(lambda (x) ,(attr-predicate-aux values)))))
89
90(defun attr-predicate-aux (values)
91  (cond ((eq values t)
92         '(plusp x))
93        ((eq values nil)
94         '(zerop x))
95        ((symbolp values)
96         `(eq x ',values))
97        ((and (listp values) (member (car values) '(and or not)))
98         (cons (car values) (mapcar #'attr-predicate-aux (cdr values))))
99        (t (error "Illegal form in attribute pattern - ~S" values))))
100
101); Eval-When
102
103;;;
104;;; FIND-LISP-CHAR
105
106(defmacro find-lisp-char (mark)
107  "Move MARK to next :LISP-SYNTAX character, if one isn't found, return NIL."
108  `(find-attribute ,mark :lisp-syntax
109                   #'(lambda (x)
110                       (member x '(:open-paren :close-paren :newline :comment :prefix-dispatch
111                                               :char-quote :symbol-quote :string-quote)))))
112;;;
113;;; PUSH-RANGE
114
115(defmacro push-range (new-range info-struct)
116  "Insert NEW-RANGE into the LISP-INFO-RANGES-TO-IGNORE slot of the INFO-STRUCT."
117  `(when ,new-range
118     (setf (lisp-info-ranges-to-ignore ,info-struct) 
119           (cons ,new-range (lisp-info-ranges-to-ignore ,info-struct)))))
120;;;
121;;; SCAN-DIRECTION
122
123(defmacro scan-direction (mark forwardp &rest forms)
124  "Expand to a form that scans either backward or forward according to Forwardp."
125  (if forwardp
126      `(scan-char ,mark ,@forms)
127      `(rev-scan-char ,mark ,@forms)))
128;;;
129;;; DIRECTION-CHAR
130
131(defmacro direction-char (mark forwardp)
132  "Expand to a form that returns either the previous or next character according
133  to Forwardp."
134  (if forwardp
135      `(next-character ,mark)
136      `(previous-character ,mark)))
137
138;;;
139;;; NEIGHBOR-MARK
140
141(defmacro neighbor-mark (mark forwardp)
142  "Expand to a form that moves MARK either backward or forward one character,
143  depending on FORWARDP."
144  (if forwardp
145      `(mark-after ,mark)
146      `(mark-before ,mark)))
147
148;;;
149;;; NEIGHBOR-LINE
150
151(defmacro neighbor-line (line forwardp)
152  "Expand to return the next or previous line, according to Forwardp."
153  (if forwardp
154      `(line-next ,line)
155      `(line-previous ,line)))
156
157
158;;;; Parsing functions.
159
160;;; PRE-COMMAND-PARSE-CHECK -- Public.
161;;;
162(defun pre-command-parse-check (mark &optional (fer-sure-parse nil))
163  "Parse the area before the command is actually executed."
164  (with-mark ((top mark)
165              (bottom mark))
166    (funcall (value parse-start-function) top)
167    (funcall (value parse-end-function) bottom)
168    (parse-over-block (mark-line top) (mark-line bottom) fer-sure-parse)))
169
170;;; PARSE-OVER-BLOCK
171;;;
172(defun parse-over-block (start-line end-line &optional (fer-sure-parse nil))
173  "Parse over an area indicated from END-LINE to START-LINE."
174  (let ((test-line start-line)
175        prev-line-info)
176   
177    (with-mark ((mark (mark test-line 0)))
178     
179      ; Set the pre-begining and post-ending lines to delimit the range
180      ; of action any command will take.  This means set the lisp-info of the
181      ; lines immediately before and after the block to Nil.
182     
183      (when (line-previous start-line)
184        (setf (getf (line-plist (line-previous start-line)) 'lisp-info) nil))
185      (when (line-next end-line)
186        (setf (getf (line-plist (line-next end-line)) 'lisp-info) nil))
187     
188      (loop
189       (let ((line-info (getf (line-plist test-line) 'lisp-info)))
190         
191         ;;    Reparse the line when any of the following are true:
192         ;;
193         ;;      FER-SURE-PARSE is T
194         ;;
195         ;;      LINE-INFO or PREV-LINE-INFO are Nil.
196         ;;
197         ;;      If the line begins quoted and the previous one wasn't
198         ;;      ended quoted.
199         ;;
200         ;;      The Line's signature slot is invalid (the line has changed).
201         ;;
202         
203         (when (or fer-sure-parse     
204                   (not line-info)
205                   (not (eq (lisp-info-begins-quoted line-info)
206                            (let ((prev (and prev-line-info (lisp-info-ending-quoted prev-line-info))))
207                              (and (not (eq prev :char-quote)) prev))))
208                   (not (eql (line-signature test-line)
209                             (lisp-info-signature-slot line-info))))
210
211           (move-to-position mark 0 test-line)
212           
213           (unless line-info
214             (setf line-info (make-lisp-info))
215             (setf (getf (line-plist test-line) 'lisp-info) line-info))
216           
217           (parse-lisp-line-info mark line-info prev-line-info))
218         
219         (when (eq end-line test-line)
220           (return nil))
221         
222         (setq prev-line-info line-info)
223         
224         (setq test-line (line-next test-line)))))))
225
226
227;;;; Parse block finders.
228
229
230(defun start-of-parse-block (mark)
231  (buffer-start mark))
232
233(defun end-of-parse-block (mark)
234  (buffer-end mark))
235
236;;;
237;;; START-OF-SEARCH-LINE
238
239(defun start-of-search-line (line)
240  "Set LINE to the begining line of the block of text to parse."
241  (with-mark ((mark (mark line 0)))
242    (funcall (value 'Parse-Start-Function) mark)
243    (setq line (mark-line mark))))
244
245;;;
246;;; END-OF-SEACH-LINE
247
248(defun end-of-search-line (line)
249  "Set LINE to the ending line of the block of text to parse."
250  (with-mark ((mark (mark line 0)))
251    (funcall (value 'Parse-End-Function) mark)
252    (setq line (mark-line mark))))
253
254
255;;;; PARSE-LISP-LINE-INFO.
256
257;;; PARSE-LISP-LINE-INFO -- Internal.
258;;;
259;;; This parses through the line doing the following things:
260;;;
261;;;      Counting/Setting the NET-OPEN-PARENS & NET-CLOSE-PARENS.
262;;;
263;;;      Making all areas of the line that should be invalid (comments,
264;;;      char-quotes, and the inside of strings) and such be in
265;;;      RANGES-TO-IGNORE.
266;;;
267;;;      Set BEGINS-QUOTED and ENDING-QUOTED
268;;;
269(defun parse-lisp-line-info (mark line-info prev-line-info)
270  "Parse line and set line information like NET-OPEN-PARENS, NET-CLOSE-PARENS,
271   RANGES-TO-INGORE, and ENDING-QUOTED."
272  (let ((net-open-parens 0)
273        (net-close-parens 0))
274    (declare (fixnum net-open-parens net-close-parens))
275
276    ;; Re-set the slots necessary
277
278    (setf (lisp-info-ranges-to-ignore line-info) nil)
279
280    (setf (lisp-info-ending-quoted line-info) nil)
281
282    ;; The only way the current line begins quoted is when there
283    ;; is a previous line and it's ending was quoted.
284   
285    (setf (lisp-info-begins-quoted line-info)
286          (and prev-line-info 
287               (let ((prev (lisp-info-ending-quoted prev-line-info)))
288                 (and (not (eq prev :char-quote)) prev))))
289
290    (assert (eq (hi::mark-buffer mark) (current-buffer)))
291
292    (when (lisp-info-begins-quoted line-info)
293      (deal-with-quote (lisp-info-begins-quoted line-info) mark line-info))
294
295    (unless (lisp-info-ending-quoted line-info)
296      (loop 
297
298        (unless (find-lisp-char mark)
299          (error "Expected at least a newline!"))
300        (case (character-attribute :lisp-syntax (next-character mark))
301         
302          (:open-paren
303           (setq net-open-parens (1+ net-open-parens))
304           (mark-after mark))
305         
306          (:close-paren
307           (if (zerop net-open-parens)
308               (setq net-close-parens (1+ net-close-parens))
309               (setq net-open-parens (1- net-open-parens)))
310           (mark-after mark))
311         
312          (:newline
313           (setf (lisp-info-ending-quoted line-info) nil)
314           (return t))
315         
316          (:comment
317           (push-range (cons (mark-charpos mark) (line-length (mark-line mark)))
318                       line-info)
319           (setf (lisp-info-ending-quoted line-info) nil)
320           (return t))
321         
322          (:char-quote
323           (mark-after mark)
324           (let* ((charpos (mark-charpos mark))
325                  (nextpos (1+ charpos))
326                  (linelen (line-length (mark-line mark))))
327             (when (< linelen nextpos)
328               (setf (lisp-info-ending-quoted line-info) :char-quote)
329               (return t))
330             (push-range (cons charpos nextpos) line-info)
331             (mark-after mark)))
332
333          (:prefix-dispatch
334           (mark-after mark)
335           (when (test-char (next-character mark) :lisp-syntax :symbol-quote)
336             (mark-after mark)
337             (unless (deal-with-quote 1 mark line-info (- (mark-charpos mark) 2))
338               (return t))))
339
340          (:symbol-quote
341           (mark-after mark)
342           (unless (deal-with-quote :symbol-quote mark line-info)
343             (return t)))
344
345          (:string-quote
346           (mark-after mark)
347           (unless (deal-with-quote :string-quote mark line-info)
348             (return t)))
349
350          (t (ERROR "character attribute of: ~s is ~s, at ~s"
351                    (next-character mark)
352                    (character-attribute :lisp-syntax (next-character mark))
353                    mark)))))
354    (setf (lisp-info-net-open-parens line-info) net-open-parens)
355    (setf (lisp-info-net-close-parens line-info) net-close-parens)
356    (setf (lisp-info-signature-slot line-info) 
357          (line-signature (mark-line mark)))))
358
359
360
361;;;; String/symbol quote utilities.
362
363;;; VALID-QUOTE-P
364;;;
365(defmacro valid-quote-p (quote mark forwardp)
366  "Return T if the string-quote indicated by MARK is valid."
367  `(and (eq (character-attribute :lisp-syntax (direction-char ,mark ,forwardp)) ,quote)
368        (not (char-quoted-at-mark-p ,mark ,forwardp))))
369
370(defun char-quoted-at-mark-p (mark forwardp)
371  (unless forwardp
372    (unless (mark-before mark)
373      (return-from char-quoted-at-mark-p nil)))
374  (loop for count upfrom 0
375    do (unless (test-char (previous-character mark) :lisp-syntax :char-quote)
376         (character-offset mark count) ;; go back to where started
377         (unless forwardp
378           (mark-after mark))
379         (return (oddp count)))
380    do (mark-before mark)))
381
382;;;
383;;; FIND-VALID-QUOTE
384
385(defmacro find-valid-quote (quote mark &key forwardp (cease-at-eol nil))
386  "Expand to a form that will leave MARK before a valid string-quote character,
387  in either a forward or backward direction, according to FORWARDP.  If
388  CEASE-AT-EOL is T then it will return nil if encountering the EOL before a
389  valid string-quote."
390  (let ((e-mark (gensym))
391        (pred (gensym)))
392    `(with-mark ((,e-mark ,mark))
393       (let ((,pred ,(if cease-at-eol
394                       `#'(lambda (x) (or (eq x :newline) (eq x ,quote)))
395                       `#'(lambda (x) (eq x ,quote)))))
396
397         (loop
398           (unless (,(if forwardp 'find-attribute 'reverse-find-attribute)
399                    ,e-mark :lisp-syntax ,pred)
400             (return nil))
401
402        ,@(if cease-at-eol
403              `((when (test-char (direction-char ,e-mark ,forwardp) :lisp-syntax
404                                 :newline)
405                  (return nil))))
406       
407        (when (valid-quote-p ,quote ,e-mark ,forwardp)
408          (move-mark ,mark ,e-mark)
409          (return t))
410       
411        (neighbor-mark ,e-mark ,forwardp))))))
412
413;;; DEAL-WITH-QUOTE
414;;;
415;;; Called when a quoted area is begun (i.e. parse hits a #\" or #\|).  It checks for a
416;;; matching quote on the line that MARK points to, and puts the appropriate
417;;; area in the RANGES-TO-IGNORE slot and leaves MARK pointing after this area.
418;;; The "appropriate area" is from MARK to the end of the line or the matching
419;;; string-quote, whichever comes first.
420;;;
421
422(defun deal-with-quote (quote mark info-struct &optional (start (mark-charpos mark)))
423  "Alter the current line's info struct as necessary as due to encountering a
424  string or symbol quote character."
425  (if (fixnump quote) ;; nesting multi-line comments
426    (loop
427      (unless (and (scan-char mark :lisp-syntax (or :newline :symbol-quote))
428                   (test-char (next-character mark) :lisp-syntax :symbol-quote))
429        (line-end mark)
430        (push-range (cons start (mark-charpos mark)) info-struct)
431        (setf (lisp-info-ending-quoted info-struct) quote)
432        (return nil))
433      (if (prog1 (test-char (previous-character mark) :lisp-syntax :prefix-dispatch) (mark-after mark))
434        (incf quote)
435        (when (test-char (next-character mark) :lisp-syntax :prefix-dispatch)
436          (mark-after mark)
437          (decf quote)
438          (when (<= quote 0)
439            (push-range (cons start (mark-charpos mark)) info-struct)
440            (setf (lisp-info-ending-quoted info-struct) nil)
441            (return mark)))))
442    (cond ((find-valid-quote quote mark :forwardp t :cease-at-eol t)
443           ;; If matching quote is on this line then mark the area between the
444           ;; first quote (MARK) and the matching quote as invalid by pushing
445           ;; its begining and ending into the IGNORE-RANGE.
446           (push-range (cons start (mark-charpos mark)) info-struct)
447           (mark-after mark))
448          ;; If the EOL has been hit before the matching quote then mark the
449          ;; area from MARK to the EOL as invalid.
450          (t
451           (line-end mark)
452           (push-range (cons start (mark-charpos mark)) info-struct)
453           ;; The Ending is marked as still being quoted.
454           (setf (lisp-info-ending-quoted info-struct) quote)
455           nil))))
456
457;;;; Character validity checking:
458
459;;; Find-Ignore-Region  --  Internal
460;;;
461;;;    If the character in the specified direction from Mark is in an ignore
462;;; region, then return the region and the line that the region is in as
463;;; values.  If there is no ignore region, then return NIL and the Mark-Line.
464;;; If the line is not parsed, or there is no character (because of being at
465;;; the buffer beginning or end), then return both values NIL.
466;;;
467(defun find-ignore-region (mark forwardp)
468  (flet ((scan (line pos)
469           (declare (fixnum pos))
470           (let ((info (getf (line-plist line) 'lisp-info)))
471             (if info
472                 (dolist (range (lisp-info-ranges-to-ignore info)
473                                ;; if mark is at end of line, should check ending-quoted so can quote the newline...
474                                (values nil line))
475                   (let ((start (car range))
476                         (end (cdr range)))
477                     (declare (fixnum start end))
478                     (when (and (>= pos start) (< pos end))
479                       (return (values range line)))))
480                 (values nil nil)))))
481    (let ((pos (mark-charpos mark))
482          (line (mark-line mark)))
483      (declare (fixnum pos))
484      (cond (forwardp (scan line pos))
485            ((> pos 0) (scan line (1- pos)))
486            (t
487             (let ((prev (line-previous line)))
488               (if prev
489                   (scan prev (line-length prev))
490                   (values nil nil))))))))
491
492
493;;; Valid-Spot  --  Public
494;;;
495(defun valid-spot (mark forwardp)
496  "Return true if the character pointed to by Mark is not in a quoted context,
497  false otherwise.  If Forwardp is true, we use the next character, otherwise
498  we use the previous."
499  (if (and (not forwardp)
500           (null (previous-character mark)))
501    t                         ;beginning of buffer always a valid spot
502    (multiple-value-bind (region line)
503        (find-ignore-region mark forwardp)
504      (and line (not region)))))
505
506;;; Scan-Direction-Valid  --  Internal
507;;;
508;;;    Like scan-direction, but only stop on valid characters.
509;;;
510(defmacro scan-direction-valid (mark forwardp &rest forms)
511  (let ((n-mark (gensym))
512        (n-line (gensym))
513        (n-region (gensym))
514        (n-won (gensym)))
515    `(let ((,n-mark ,mark) (,n-won nil))
516       (loop
517         (multiple-value-bind (,n-region ,n-line)
518                              (find-ignore-region ,n-mark ,forwardp)
519           (unless ,n-line (return nil))
520           (if ,n-region
521               (move-to-position ,n-mark
522                                 ,(if forwardp
523                                      `(cdr ,n-region) 
524                                      `(car ,n-region))
525                                 ,n-line)
526               (when ,n-won (return t)))
527           ;;
528           ;; Peculiar condition when a quoting character terminates a line.
529           ;; The ignore region is off the end of the line causing %FORM-OFFSET
530           ;; to infinitely loop.
531           (when (> (mark-charpos ,n-mark) (line-length ,n-line))
532             #+gz (break "This shouldn't happen any more")
533             (line-offset ,n-mark 1 0))
534           (unless (scan-direction ,n-mark ,forwardp ,@forms)
535             (return nil))
536           (setq ,n-won t))))))
537
538
539;;;; List offseting.
540
541;;; %LIST-OFFSET allows for BACKWARD-LIST and FORWARD-LIST to be built
542;;; with the same existing structure, with the altering of one variable.
543;;; This one variable being FORWARDP.
544;;;
545(defmacro %list-offset (actual-mark forwardp &key (extra-parens 0) )
546  "Expand to code that will go forward one list either backward or forward,
547   according to the FORWARDP flag."
548  (let ((mark (gensym)))
549    `(with-mark ((,mark ,actual-mark))
550       (if (valid-spot ,mark ,forwardp)
551         (let ((paren-count ,extra-parens))
552           (declare (fixnum paren-count))
553           (loop
554             (unless (scan-direction-valid ,mark ,forwardp :lisp-syntax
555                                           (or :close-paren :open-paren :newline))
556               (return nil))
557             (let ((ch (direction-char ,mark ,forwardp)))
558               (unless ch (return nil))
559               (case (character-attribute :lisp-syntax ch)
560                 (:close-paren
561                  (decf paren-count)
562                  ,(when forwardp
563                     ;; When going forward, an unmatching close-paren means the
564                     ;; end of list.
565                     `(when (<= paren-count 0)
566                        (neighbor-mark ,mark ,forwardp)
567                        (move-mark ,actual-mark ,mark)
568                        (return t))))
569                 (:open-paren
570                  (incf paren-count)
571                  ,(unless forwardp             ; Same as above only end of list
572                     `(when (>= paren-count 0)  ; is opening parens.
573                        (neighbor-mark ,mark ,forwardp)
574                        (move-mark ,actual-mark ,mark)
575                          (return t))))
576                   
577                   (:newline 
578                    ;; When a #\Newline is hit, then the matching paren must lie
579                    ;; on some other line so drop down into the multiple line
580                    ;; balancing function: QUEST-FOR-BALANCING-PAREN If no paren
581                    ;; seen yet, keep going.
582                    (cond ((zerop paren-count))
583                          ((quest-for-balancing-paren ,mark paren-count ,forwardp)
584                           (move-mark ,actual-mark ,mark)
585                           (return t))
586                          (t
587                           (return nil))))))
588             (neighbor-mark ,mark ,forwardp)))
589         ;; We're inside a comment or a string.  Try anyway.
590         (when ,(if forwardp
591                  `(%forward-list-at-mark ,mark ,extra-parens t)
592                  `(%backward-list-at-mark ,mark ,extra-parens t))
593           (move-mark ,actual-mark ,mark))))))
594
595;;;
596;;; QUEST-FOR-BALANCING-PAREN
597
598(defmacro quest-for-balancing-paren (mark paren-count forwardp)
599  "Expand to a form that finds the the balancing paren for however many opens or
600  closes are registered by Paren-Count."
601  `(let* ((line (mark-line ,mark)))
602     (loop
603       (setq line (neighbor-line line ,forwardp))
604       (unless line (return nil))
605       (let ((line-info (getf (line-plist line) 'lisp-info))
606             (unbal-paren ,paren-count))
607         (unless line-info (return nil))
608         
609         ,(if forwardp
610              `(decf ,paren-count (lisp-info-net-close-parens line-info))
611              `(incf ,paren-count (lisp-info-net-open-parens line-info)))
612         
613         (when ,(if forwardp
614                    `(<= ,paren-count 0)
615                    `(>= ,paren-count 0))
616           ,(if forwardp
617                `(line-start ,mark line)
618                `(line-end ,mark line))
619           (return (goto-correct-paren-char ,mark unbal-paren ,forwardp)))
620
621         ,(if forwardp
622              `(incf ,paren-count (lisp-info-net-open-parens line-info))
623              `(decf ,paren-count (lisp-info-net-close-parens line-info)))))))
624                   
625
626;;;
627;;; GOTO-CORRECT-PAREN-CHAR
628
629(defmacro goto-correct-paren-char (mark paren-count forwardp)
630  "Expand to a form that will leave MARK on the correct balancing paren matching
631   however many are indicated by COUNT." 
632  `(with-mark ((m ,mark))
633     (let ((count ,paren-count))
634       (loop
635         (scan-direction m ,forwardp :lisp-syntax 
636                         (or :close-paren :open-paren :newline))
637         (when (valid-spot m ,forwardp)
638           (ecase (character-attribute :lisp-syntax (direction-char m ,forwardp))
639             (:close-paren 
640              (decf count)
641              ,(when forwardp
642                 `(when (zerop count)
643                    (neighbor-mark m ,forwardp)
644                    (move-mark ,mark m)
645                    (return t))))
646             
647             (:open-paren 
648              (incf count)
649              ,(unless forwardp
650                 `(when (zerop count)
651                    (neighbor-mark m ,forwardp)
652                    (move-mark ,mark m)
653                    (return t))))))
654         (neighbor-mark m ,forwardp)))))
655
656
657(defun list-offset (mark offset)
658  (if (plusp offset)
659      (dotimes (i offset t)
660        (unless (%list-offset mark t) (return nil)))
661      (dotimes (i (- offset) t)
662        (unless (%list-offset mark nil) (return nil)))))
663
664(defun forward-up-list (mark)
665  "Moves mark just past the closing paren of the immediately containing list."
666  (%list-offset mark t :extra-parens 1))
667
668(defun backward-up-list (mark)
669  "Moves mark just before the opening paren of the immediately containing list."
670  (%list-offset mark nil :extra-parens -1))
671
672
673
674;;;; Top level form location hacks (open parens beginning lines).
675
676;;; NEIGHBOR-TOP-LEVEL is used only in TOP-LEVEL-OFFSET.
677;;;
678(eval-when (:compile-toplevel :execute)
679(defmacro neighbor-top-level (line forwardp)
680  `(loop
681     (when (test-char (line-character ,line 0) :lisp-syntax :open-paren)
682       (return t))
683     (setf ,line ,(if forwardp `(line-next ,line) `(line-previous ,line)))
684     (unless ,line (return nil))))
685) ;eval-when
686
687(defun top-level-offset (mark offset)
688  "Go forward or backward offset number of top level forms.  Mark is
689   returned if offset forms exists, otherwise nil."
690  (declare (fixnum offset))
691  (let* ((line (mark-line mark))
692         (at-start (test-char (line-character line 0) :lisp-syntax :open-paren)))
693    (cond ((zerop offset) mark)
694          ((plusp offset)
695           (do ((offset (if at-start offset (1- offset))
696                        (1- offset)))
697               (nil)
698             (declare (fixnum offset))
699             (unless (neighbor-top-level line t) (return nil))
700             (when (zerop offset) (return (line-start mark line)))
701             (unless (setf line (line-next line)) (return nil))))
702          (t
703           (do ((offset (if (and at-start (start-line-p mark))
704                            offset
705                            (1+ offset))
706                        (1+ offset)))
707                (nil)
708             (declare (fixnum offset))
709             (unless (neighbor-top-level line nil) (return nil))
710             (when (zerop offset) (return (line-start mark line)))
711             (unless (setf line (line-previous line)) (return nil)))))))
712
713
714(defun mark-top-level-form (mark1 mark2)
715  "Moves mark1 and mark2 to the beginning and end of the current or next defun.
716   Mark1 one is used as a reference.  The marks may be altered even if
717   unsuccessful.  if successful, return mark2, else nil."
718  (let ((winp (cond ((inside-defun-p mark1)
719                     (cond ((not (top-level-offset mark1 -1)) nil)
720                           ((not (form-offset (move-mark mark2 mark1) 1)) nil)
721                           (t mark2)))
722                    ((start-defun-p mark1)
723                     (form-offset (move-mark mark2 mark1) 1))
724                    ((and (top-level-offset (move-mark mark2 mark1) -1)
725                          (start-defun-p mark2)
726                          (form-offset mark2 1)
727                          (same-line-p mark1 mark2))
728                     (form-offset (move-mark mark1 mark2) -1)
729                     mark2)
730                    ((top-level-offset mark1 1)
731                     (form-offset (move-mark mark2 mark1) 1)))))
732    (when winp
733      (when (blank-after-p mark2) (line-offset mark2 1 0))
734      mark2)))
735
736(defun inside-defun-p (mark)
737  "T if the current point is (supposedly) in a top level form."
738  (with-mark ((m mark))
739    (when (top-level-offset m -1)
740      (form-offset m 1)
741      (mark> m mark))))
742
743(defun start-defun-p (mark)
744  "Returns t if mark is sitting before an :open-paren at the beginning of a
745   line."
746  (and (start-line-p mark)
747       (test-char (next-character mark) :lisp-syntax :open-paren)))
748
749;;;; Form offseting.
750
751;; Heuristic versions, for navigating inside comments, doesn't make use of line info
752
753(defun unparsed-form-offset (mark forwardp)
754  ;; TODO: if called in "invalid" spot, arrange to stay within bounds of current invalid region.
755  ;; For now, just stop at #||# boundaries, as first approximation.
756  (if forwardp
757    (forward-form mark t)
758    (backward-form mark t)))
759
760(defun forward-form (mark &optional in-comment-p)
761  ;; If in-comment-p is true, tries not to go past a |#.
762  (with-mark ((m mark))
763    (when (and (scan-char m :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
764                                             :symbol-quote :string-quote :char-quote
765                                             :comment :constituent))
766               (%forward-form-at-mark m in-comment-p))
767      (move-mark mark m))))
768
769(defun backward-form (mark &optional in-comment-p)
770  ;; If in-comment-p is true, tries not to go past a #|.
771  (with-mark ((m mark))
772    (when (%backward-form-at-mark m in-comment-p)
773      (loop while (test-char (previous-character m) :lisp-syntax (or :prefix :prefix-dispatch)) do (mark-before m))
774      (move-mark mark m))))
775
776(defun %forward-form-at-mark (mark in-comment-p)
777  ;; Warning: moves mark even if returns nil (hence the % in name).
778  (case (character-attribute :lisp-syntax (next-character mark))
779    (:open-paren
780     (mark-after mark)
781     (%forward-list-at-mark mark 1))
782    (:close-paren
783     nil)
784    (:char-quote
785     (%forward-symbol-at-mark mark in-comment-p))
786    (:symbol-quote
787     (mark-after mark)
788     (unless (and in-comment-p (test-char (next-character mark) :lisp-syntax :prefix-dispatch))
789       (mark-before mark)
790       (%forward-symbol-at-mark mark in-comment-p)))
791    (:prefix-dispatch
792     (mark-after mark)
793     (case (character-attribute :lisp-syntax (next-character mark))
794       (:symbol-quote
795        (mark-after mark)
796        (%forward-nesting-comment-at-mark mark 1))
797       (:prefix
798        (mark-after mark)
799        (%forward-form-at-mark mark in-comment-p))
800       (t
801        (mark-before mark)
802        (%forward-symbol-at-mark mark in-comment-p))))
803    (:string-quote
804     (%forward-string-at-mark mark))
805    (:constituent
806     (%forward-symbol-at-mark mark in-comment-p))
807    (:comment
808     (%forward-comments-at-mark mark))
809    (t
810     (mark-after mark)
811     (%forward-form-at-mark mark in-comment-p))))
812
813(defun %backward-form-at-mark (mark in-comment-p)
814  ;; Warning: moves mark even if returns nil (hence the % in name).
815  (let* ((char (previous-character mark))
816         (attrib (character-attribute :lisp-syntax char)))
817    (when char
818      (mark-before mark)
819      (when (char-quoted-at-mark-p mark t)
820        (setq attrib :constituent))
821      (case attrib
822        (:open-paren
823         nil)
824        (:close-paren
825         (%backward-list-at-mark mark 1))
826        (:char-quote  ;;; can only happen if starting right after an unquoted char-quote
827         (%backward-symbol-at-mark mark in-comment-p))
828        (:symbol-quote
829         (unless (and in-comment-p (test-char (previous-character mark) :lisp-syntax :prefix-dispatch))
830           (mark-after mark)
831           (%backward-symbol-at-mark mark in-comment-p)))
832        (:prefix-dispatch
833         (if (test-char (previous-character mark) :lisp-syntax :symbol-quote)
834           (progn
835             (mark-before mark)
836             (%backward-nesting-comment-at-mark mark 1))
837           (progn
838             (mark-after mark)
839             (%backward-symbol-at-mark mark in-comment-p))))
840        (:string-quote
841         (mark-after mark)
842         (%backward-string-at-mark mark))
843        (:constituent
844         (mark-after mark)
845         (%backward-symbol-at-mark mark in-comment-p))
846        (:prefix
847         (loop while (test-char (previous-character mark) :lisp-syntax :prefix) do (mark-before mark))
848         mark)
849        (:comment
850         (loop while (test-char (previous-character mark) :lisp-syntax :comment) do (mark-before mark))
851         mark)
852        ;; TODO: it would be nice to skip over ;; comments if starting outside one, i.e. if encounter a newline
853        ;; before a form starts.
854        (t (%backward-form-at-mark mark in-comment-p))))))
855
856(defun %forward-symbol-at-mark (mark in-comment-p)
857  ;; Warning: moves mark even if returns nil (hence the % in name).
858  (loop
859    (unless (scan-char mark :lisp-syntax (not (or :constituent :prefix-dispatch)))
860      (return (buffer-end mark)))
861    (case (character-attribute :lisp-syntax (next-character mark))
862      (:symbol-quote
863       (mark-after mark)
864       (when (and in-comment-p (test-char (next-character mark) :lisp-syntax :prefix-dispatch))
865         (return (mark-before mark)))
866       (unless (loop
867                 (unless (scan-char mark :lisp-syntax (or :char-quote :symbol-quote))
868                   (return nil))
869                 (when (test-char (next-character mark) :lisp-syntax :symbol-quote)
870                   (return t))
871                 (unless (character-offset mark 2)
872                   (return nil)))
873         (return nil))
874       (mark-after mark))
875      (:char-quote
876       (unless (character-offset mark 2)
877         (return nil)))
878      (t (return mark)))))
879
880(defun %backward-symbol-at-mark (mark in-comment-p)
881  (loop
882    (unless (rev-scan-char mark :lisp-syntax (not (or :constituent :prefix-dispatch :char-quote)))
883      (buffer-start mark)
884      (return mark))
885    (mark-before mark)
886    (if (char-quoted-at-mark-p mark t)
887      (mark-before mark)
888      (let* ((char (next-character mark)))
889        (case (character-attribute :lisp-syntax char)
890          (:symbol-quote
891           (when (and in-comment-p (test-char (previous-character mark) :lisp-syntax :prefix-dispatch))
892             (return (mark-after mark)))
893           (unless (loop
894                     (unless (rev-scan-char mark :lisp-syntax :symbol-quote)
895                       (return nil))
896                     (mark-before mark)
897                     (unless (char-quoted-at-mark-p mark t)
898                       (return t))
899                     (mark-before mark))
900             (return nil)))
901          (t (mark-after mark)
902             (return mark)))))))
903
904(defun %forward-nesting-comment-at-mark (mark nesting)
905  ;; Warning: moves mark even if returns nil (hence the % in name).
906  (loop
907    (unless (scan-char mark :lisp-syntax :symbol-quote)
908      (return nil))
909    (let ((prev (previous-character mark)))
910      (mark-after mark)
911      (cond ((test-char prev :lisp-syntax :prefix-dispatch)
912             (incf nesting))
913            ((test-char (next-character mark) :lisp-syntax :prefix-dispatch)
914             (mark-after mark)
915             (when (<= (decf nesting) 0)
916               (return mark)))))))
917
918(defun %backward-nesting-comment-at-mark (mark nesting)
919  ;; Warning: moves mark even if returns nil (hence the % in name).
920  (loop
921    (unless (rev-scan-char mark :lisp-syntax :symbol-quote)
922      (return nil))
923    (let ((next (next-character mark)))
924      (mark-before mark)
925      (cond ((test-char next :lisp-syntax :prefix-dispatch)
926             (incf nesting))
927            ((test-char (previous-character mark) :lisp-syntax :prefix-dispatch)
928             (mark-before mark)
929             (when (<= (decf nesting) 0)
930               (return mark)))))))
931
932
933(defun %scan-to-form (m forwardp)
934  (if forwardp
935    ;; Stop at :prefix-dispatch if it is not followed by :prefix. If it's followed by :prefix,
936    ;; assume it has the semantics of :prefix and skip it.
937    (loop while (scan-direction-valid m t :lisp-syntax
938                                      (or :open-paren :close-paren
939                                          :char-quote :string-quote :symbol-quote
940                                          :prefix-dispatch :constituent))
941      do (unless (and (test-char (next-character m) :lisp-syntax :prefix-dispatch)
942                      (mark-after m))
943           (return t))
944      do (unless (test-char (next-character m) :lisp-syntax :prefix)
945           (mark-before m)
946           (return t)))
947    (scan-direction-valid m nil :lisp-syntax
948                          (or :open-paren :close-paren
949                              :char-quote :string-quote :symbol-quote
950                              :prefix-dispatch :constituent))))
951
952;; %FORM-OFFSET
953
954(defmacro %form-offset (mark forwardp)
955  `(if (valid-spot ,mark ,forwardp)
956     (with-mark ((m ,mark))
957       (when (%scan-to-form m ,forwardp)
958         (ecase (character-attribute :lisp-syntax (direction-char m ,forwardp))
959           (:open-paren
960            (when ,(if forwardp `(list-offset m 1) `(mark-before m))
961              ,(unless forwardp
962                 '(scan-direction m nil :lisp-syntax (not (or :prefix-dispatch :prefix))))
963              (move-mark ,mark m)
964              t))
965           (:close-paren
966            (when ,(if forwardp `(mark-after m) `(list-offset m -1))
967              ,(unless forwardp
968                 '(scan-direction m nil :lisp-syntax (not (or :prefix-dispatch :prefix))))
969              (move-mark ,mark m)
970              t))
971           ((:constituent :char-quote :symbol-quote :prefix-dispatch)
972            ,(if forwardp
973               `(scan-direction-valid m t :lisp-syntax
974                                      (not (or :constituent :char-quote :symbol-quote :prefix-dispatch)))
975               `(scan-direction-valid m nil :lisp-syntax
976                                      (not (or :constituent :char-quote :symbol-quote :prefix-dispatch
977                                               :prefix))))
978            (move-mark ,mark m)
979            t)
980           (:string-quote
981            (neighbor-mark m ,forwardp)
982            (when (scan-direction-valid m ,forwardp :lisp-syntax
983                                        :string-quote)
984              (neighbor-mark m ,forwardp)
985              (move-mark ,mark m)
986              t)))))
987     ;; Inside a comment or a string.  Switch to heuristic method.
988     (unparsed-form-offset ,mark ,forwardp)))
989
990(defun %forward-list-at-mark (mark nesting &optional in-comment-p)
991  ;; Warning: moves mark even if returns nil (hence the % in name).
992  (loop
993    (unless (scan-char mark :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
994                                             :symbol-quote :string-quote :char-quote :comment))
995      (return nil))
996    (case (character-attribute :lisp-syntax (next-character mark))
997      (:open-paren
998       (mark-after mark)
999       (incf nesting))
1000      (:close-paren
1001       (mark-after mark)
1002       (when (<= (decf nesting) 0)
1003         (return (and (eql nesting 0) mark))))
1004      (t
1005       (unless (%forward-form-at-mark mark in-comment-p)
1006         (return nil))))))
1007
1008(defun %backward-list-at-mark (mark nesting &optional in-comment-p)
1009  ;; Warning: moves mark even if returns nil (hence the % in name).
1010  (loop
1011    (unless (rev-scan-char mark :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
1012                                                 :symbol-quote :string-quote :comment))
1013      (return nil))
1014    (mark-before mark)
1015    (if (char-quoted-at-mark-p mark t)
1016      (mark-before mark)
1017      (case (character-attribute :lisp-syntax (next-character mark))
1018        (:close-paren
1019         (incf nesting))
1020        (:open-paren
1021         (when (<= (decf nesting) 0)
1022           (return mark)))
1023        (t
1024         (mark-after mark)
1025         (unless (%backward-form-at-mark mark in-comment-p)
1026           (return nil)))))))
1027
1028(defun %forward-string-at-mark (mark)
1029  ;; Warning: moves mark even if returns nil (hence the % in name).
1030  (mark-after mark)
1031  (loop
1032    (unless (scan-char mark :lisp-syntax (or :char-quote :string-quote))
1033      (return nil))
1034    (unless (test-char (next-character mark) :lisp-syntax :char-quote)
1035      (return (mark-after mark)))
1036    (character-offset mark 2)))
1037
1038
1039(defun %backward-string-at-mark (mark)
1040  ;; Warning: moves mark even if returns nil (hence the % in name).
1041  (mark-before mark)
1042  (loop
1043    (unless (rev-scan-char mark :lisp-syntax :string-quote)
1044      (return nil))
1045    (mark-before mark)
1046    (unless (char-quoted-at-mark-p mark t)
1047      (return mark))
1048    (mark-before mark)))
1049
1050(defun %forward-comments-at-mark (mark)
1051  ;; Warning: moves mark even if returns nil (hence the % in name).
1052  (with-mark ((m mark))
1053    (loop
1054      (line-end m)
1055      (mark-after m)
1056      (move-mark mark m)
1057      (unless (and (scan-char m :lisp-syntax (not :space))
1058                   (test-char (next-character m) :lisp-syntax :comment))
1059        (return mark)))))
1060
1061(defun form-offset (mark offset)
1062  "Move mark offset number of forms, after if positive, before if negative.
1063   Mark is always moved.  If there weren't enough forms, returns nil instead of
1064   mark."
1065  (if (plusp offset)
1066      (dotimes (i offset t)
1067        (unless (%form-offset mark t) (return nil)))
1068      (dotimes (i (- offset) t)
1069        (unless (%form-offset mark nil) (return nil)))))
1070
1071;; Return region for the "current form" at mark.
1072;; TODO: See also mark-nearest-form, should merge them
1073(defun form-region-at-mark (mark)
1074  (with-mark ((bwd-start mark)
1075              (bwd-end mark)
1076              (fwd-start mark)
1077              (fwd-end mark))
1078    (let* ((fwd (and (or (and (char-quoted-at-mark-p mark t)       ;; back-up so get whole character
1079                              (mark-before fwd-end))
1080                         (test-char (next-character mark) :lisp-syntax
1081                                    (or :open-paren :string-quote
1082                                        :char-quote :symbol-quote :constituent :prefix-dispatch
1083                                        :prefix)))
1084                     (form-offset fwd-end 1)
1085                     (form-offset (move-mark fwd-start fwd-end) -1)
1086                     (mark<= fwd-start mark)))
1087           (bwd (and (or (char-quoted-at-mark-p mark nil)
1088                         (test-char (previous-character mark) :lisp-syntax
1089                                    (or :close-paren :string-quote
1090                                        :char-quote :symbol-quote :constituent :prefix-dispatch)))
1091                     ;; Special case - if at an open paren, always select forward because that's
1092                     ;; the matching paren that's highlighted.
1093                     (not (and fwd (test-char (next-character mark) :lisp-syntax :open-paren)))
1094                     ;; Also prefer string over anything but close paren.
1095                     (not (and fwd (test-char (next-character mark) :lisp-syntax :string-quote)
1096                               (not (test-char (previous-character mark) :lisp-syntax :close-paren))))
1097                     (form-offset bwd-start -1)
1098                     (form-offset (move-mark bwd-end bwd-start) 1)
1099                     (mark<= mark bwd-end))))
1100      (if bwd
1101        (when (or (not fwd) ;; back is only option
1102                  (and (mark= bwd-start fwd-start) (mark= bwd-end fwd-end)) ;; or they're the same
1103                  (and (mark= bwd-start fwd-end)  ;; or had to skip prefix chars to get to forward
1104                       (test-char (next-character fwd-start) :lisp-syntax (or :prefix :prefix-dispatch))))
1105          (region bwd-start bwd-end))
1106        (if fwd
1107          (region fwd-start fwd-end))))))
1108
1109;; Return region for the current word at mark, or nil if there isn't one.
1110(defun word-region-at-mark (mark)
1111  (with-mark ((fwd mark)
1112              (bwd mark))
1113    (or (find-attribute  fwd :word-delimiter)
1114        (buffer-end fwd))
1115    (or (reverse-find-attribute bwd :word-delimiter)
1116        (buffer-start bwd))
1117    (unless (mark= bwd fwd)
1118      ;; Special-case for keywords (and gensyms)
1119      (when (eq (previous-character bwd) #\:)
1120        (mark-before bwd)
1121        (when (test-char (previous-character bwd) :lisp-syntax :constituent)
1122          (mark-after bwd))) ;; oops, never mind
1123      ;; Special-case for stuff like  #_foo.
1124      (when (test-char (previous-character bwd) :lisp-syntax :prefix-dispatch)
1125        ;; let :prefix-dispatch take on the attribute of the following char, which is a word constituent
1126        (mark-before bwd))
1127      (region bwd fwd))))
1128
1129;;;; Table of special forms with special indenting requirements.
1130
1131(defhvar "Indent Defanything"
1132  "This is the number of special arguments implicitly assumed to be supplied
1133   in calls to functions whose names begin with \"DEF\".  If set to NIL, this
1134   feature is disabled."
1135  :value 2)
1136
1137(defhvar "Indent With-anything"
1138  "This is the number of special arguments implicitly assumed to be supplied
1139   in calls to functions whose names begin with \"WITH-\". If set to NIL, this
1140   feature is disabled."
1141  :value 1)
1142
1143(defvar *special-forms* (make-hash-table :test #'equal))
1144
1145(defun defindent (fname args)
1146  "Define Fname to have Args special arguments.  If args is null then remove
1147   any special arguments information."
1148  (check-type fname string)
1149  (let ((fname (string-upcase fname)))
1150    (cond ((null args) (remhash fname *special-forms*))
1151          (t
1152           (check-type args integer)
1153           (setf (gethash fname *special-forms*) args)))))
1154
1155
1156;;; Hemlock forms.
1157;;;
1158(defindent "defhvar" 1)
1159(defindent "hlet" 1)
1160(defindent "defcommand" 2)
1161(defindent "defattribute" 1)
1162(defindent "command-case" 1)
1163(defindent "do-strings" 1)
1164(defindent "save-for-undo" 1)
1165(defindent "do-alpha-chars" 1)
1166(defindent "do-headers-buffers" 1)
1167(defindent "do-headers-lines" 1)
1168(defindent "frob" 1) ;cover silly FLET and MACROLET names for Rob and Bill.
1169(defindent "modifying-buffer" 1)
1170
1171;;; Common Lisp forms.
1172;;;
1173(defindent "block" 1)
1174(defindent "return-from" 1)
1175(defindent "case" 1)
1176(defindent "catch" 1)
1177(defindent "ccase" 1)                     
1178(defindent "compiler-let" 1)
1179(defindent "ctypecase" 1)
1180(defindent "defconstant" 1)
1181(defindent "define-compiler-macro" 2)
1182(defindent "define-setf-method" 2)
1183(defindent "destructuring-bind" 2)
1184(defindent "defmacro" 2)
1185(defindent "defpackage" 1)
1186(defindent "defparameter" 1)
1187(defindent "defstruct" 1)
1188(defindent "deftype" 2)
1189(defindent "defun" 2)
1190(defindent "defvar" 1)
1191(defindent "do" 2)
1192(defindent "do*" 2)
1193(defindent "do-all-symbols" 1)
1194(defindent "do-external-symbols" 1)
1195(defindent "do-symbols" 1)
1196(defindent "dolist" 1)
1197(defindent "dotimes" 1)
1198(defindent "ecase" 1)
1199(defindent "etypecase" 1)
1200(defindent "eval-when" 1)
1201(defindent "flet" 1)
1202(defindent "if" 1)
1203(defindent "labels" 1)
1204(defindent "lambda" 1)
1205(defindent "let" 1)
1206(defindent "let*" 1)
1207(defindent "locally" 0)
1208(defindent "loop" 0)
1209(defindent "macrolet" 1)
1210(defindent "multiple-value-bind" 2)
1211(defindent "multiple-value-call" 1)
1212(defindent "multiple-value-prog1" 1)
1213(defindent "multiple-value-setq" 1)
1214(defindent "prog" 1)
1215(defindent "prog*" 1)
1216(defindent "prog1" 0)
1217(defindent "prog2" 0)
1218(defindent "progv" 2)
1219(defindent "progn" 0)
1220(defindent "typecase" 1)
1221(defindent "unless" 1)
1222(defindent "unwind-protect" 1)
1223(defindent "when" 1)
1224
1225;; CCL extensions
1226(defindent "iterate" 2)
1227(defindent "rlet" 1)
1228(defindent "rletz" 1)
1229(defindent "let-globally" 1)
1230
1231;;; Error/condition system forms.
1232;;;
1233(defindent "define-condition" 2)
1234(defindent "handler-bind" 1)
1235(defindent "handler-case" 1)
1236(defindent "restart-bind" 1)
1237(defindent "restart-case" 1)
1238;;; These are for RESTART-CASE branch formatting.
1239(defindent "store-value" 1)
1240(defindent "use-value" 1)
1241(defindent "muffle-warning" 1)
1242(defindent "abort" 1)
1243(defindent "continue" 1)
1244;;; This is for DEFGENERIC method formatting
1245(defindent "method" 1)
1246
1247;;; Common library extensions
1248(defindent "if-let" 1)
1249(defindent "if-let*" 1)
1250(defindent "when-let" 1)
1251(defindent "when-let*" 1)
1252
1253#|
1254;;; Debug-internals forms.
1255;;;
1256(defindent "do-debug-function-blocks" 1)
1257(defindent "di:do-debug-function-blocks" 1)
1258(defindent "do-debug-function-variables" 1)
1259(defindent "di:do-debug-function-variables" 1)
1260(defindent "do-debug-block-locations" 1)
1261(defindent "di:do-debug-block-locations" 1)
1262;;;
1263;;; Debug-internals conditions
1264;;; (define these to make uses of HANDLER-CASE indent branches correctly.)
1265;;;
1266(defindent "debug-condition" 1)
1267(defindent "di:debug-condition" 1)
1268(defindent "no-debug-info" 1)
1269(defindent "di:no-debug-info" 1)
1270(defindent "no-debug-function-returns" 1)
1271(defindent "di:no-debug-function-returns" 1)
1272(defindent "no-debug-blocks" 1)
1273(defindent "di:no-debug-blocks" 1)
1274(defindent "lambda-list-unavailable" 1)
1275(defindent "di:lambda-list-unavailable" 1)
1276(defindent "no-debug-variables" 1)
1277(defindent "di:no-debug-variables" 1)
1278(defindent "invalid-value" 1)
1279(defindent "di:invalid-value" 1)
1280(defindent "ambiguous-variable-name" 1)
1281(defindent "di:ambiguous-variable-name" 1)
1282(defindent "debug-error" 1)
1283(defindent "di:debug-error" 1)
1284(defindent "unhandled-condition" 1)
1285(defindent "di:unhandled-condition" 1)
1286(defindent "unknown-code-location" 1)
1287(defindent "di:unknown-code-location" 1)
1288(defindent "unknown-debug-variable" 1)
1289(defindent "di:unknown-debug-variable" 1)
1290(defindent "invalid-control-stack-pointer" 1)
1291(defindent "di:invalid-control-stack-pointer" 1)
1292(defindent "frame-function-mismatch" 1)
1293(defindent "di:frame-function-mismatch" 1)
1294|#
1295
1296;;; CLOS forms.
1297;;;
1298(defindent "with-accessors" 2)
1299(defindent "defclass" 2)
1300(defindent "print-unreadable-object" 1)
1301(defindent "defmethod" 2)
1302(defindent "make-instance" 1)
1303
1304;;; System forms.
1305;;;
1306
1307;;; Multiprocessing forms.
1308(defindent "process-wait" 1)
1309(defindent "process-run-function" 1)
1310
1311
1312;;;; Indentation.
1313
1314;;; LISP-INDENTATION -- Internal Interface.
1315
1316(defun strip-package-prefix (string)
1317  (let* ((p (position #\: string :from-end t)))
1318    (if p
1319      (subseq string (1+ p))
1320      string)))
1321;;;
1322(defun lisp-indentation (mark)
1323  "Compute number of spaces which mark should be indented according to
1324   local context and lisp grinding conventions.  This assumes mark is at the
1325   beginning of the line to be indented."
1326  (with-mark ((m mark)
1327              (temp mark))
1328    ;; See if we are in a quoted context.
1329    (unless (valid-spot m nil)
1330      (return-from lisp-indentation (lisp-generic-indentation m)))
1331    ;; Look for the paren that opens the containing form.
1332    (unless (backward-up-list m)
1333      (return-from lisp-indentation 0))
1334    ;; Move after the paren, save the start, and find the form name.
1335    (mark-after m)
1336    (with-mark ((start m))
1337      (unless (and (scan-char m :lisp-syntax
1338                              (not (or :space :prefix :prefix-dispatch :char-quote)))
1339                   (test-char (next-character m) :lisp-syntax :constituent))
1340        (return-from lisp-indentation (mark-column start)))
1341      (with-mark ((fstart m))
1342        (scan-char m :lisp-syntax (not :constituent))
1343        (let* ((fname (nstring-upcase
1344                       (strip-package-prefix (region-to-string (region fstart m)))))
1345               (special-args (or (gethash fname *special-forms*)
1346                                 (and (> (length fname) 2)
1347                                      (string= fname "DEF" :end1 3)
1348                                      (value indent-defanything))
1349                                 (and (> (length fname) 4)
1350                                      (string= fname "WITH-" :end1 5)
1351                                      (value indent-with-anything)))))
1352          (declare (simple-string fname))
1353          ;; Now that we have the form name, did it have special syntax?
1354          (cond (special-args
1355                 (with-mark ((spec m))
1356                   (cond ((and (form-offset spec special-args)
1357                               (mark<= spec mark))
1358                          (1+ (mark-column start)))
1359                         ((skip-valid-space m)
1360                          (mark-column m))
1361                         (t
1362                          (+ (mark-column start) 3)))))
1363                ;; See if the user seems to have altered the editor's
1364                ;; indentation, and if so, try to adhere to it.  This usually
1365                ;; happens when you type in a quoted list constant that line
1366                ;; wraps.  You want all the items on successive lines to fall
1367                ;; under the first character after the opening paren, not as if
1368                ;; you are calling a function.
1369                ((and (form-offset temp -1)
1370                      (or (blank-before-p temp) (not (same-line-p temp fstart)))
1371                      (not (same-line-p temp mark)))
1372                 (unless (blank-before-p temp)
1373                   (line-start temp)
1374                   (find-attribute temp :space #'zerop))
1375                 (mark-column temp))
1376                ;; Appears to be a normal form.  Is the first arg on the same
1377                ;; line as the form name?
1378                ((skip-valid-space m)
1379                 (or (lisp-indentation-check-for-local-def
1380                      mark temp fstart start t)
1381                     (mark-column m)))
1382                ;; Okay, fall under the first character after the opening paren.
1383                (t
1384                 (or (lisp-indentation-check-for-local-def
1385                      mark temp fstart start nil)
1386                     (mark-column start)))))))))
1387
1388(defhvar "Lisp Indentation Local Definers"
1389  "Forms with syntax like LABELS, MACROLET, etc."
1390  :value '("LABELS" "MACROLET" "FLET"))
1391
1392;;; LISP-INDENTATION-CHECK-FOR-LOCAL-DEF -- Internal.
1393;;;
1394;;; This is a temporary hack to see how it performs.  When we are indenting
1395;;; what appears to be a function call, let's look for FLET or MACROLET to see
1396;;; if we really are indenting a local definition.  If we are, return the
1397;;; indentation for a DEFUN; otherwise, nil
1398;;;
1399;;; Mark is the argument to LISP-INDENTATION.  Start is just inside the paren
1400;;; of what looks like a function call.  If we are in an FLET, arg-list
1401;;; indicates whether the local function's arg-list has been entered, that is,
1402;;; whether we need to normally indent for a DEFUN body or indent specially for
1403;;; the arg-list.
1404;;;
1405(defun lisp-indentation-check-for-local-def (mark temp1 temp2 start arg-list)
1406  ;; We know this succeeds from LISP-INDENTATION.
1407  (backward-up-list (move-mark temp1 mark)) ;Paren for local definition.
1408  (cond ((and (backward-up-list temp1)      ;Paren opening the list of defs
1409              (form-offset (move-mark temp2 temp1) -1)
1410              (mark-before temp2)
1411              (backward-up-list temp1)      ;Paren for FLET or MACROLET.
1412              (mark= temp1 temp2))          ;Must be in first arg form.
1413         ;; See if the containing form is named FLET or MACROLET.
1414         (mark-after temp1)
1415         (unless (and (scan-char temp1 :lisp-syntax
1416                                 (not (or :space :prefix :prefix-dispatch :char-quote)))
1417                      (test-char (next-character temp1) :lisp-syntax
1418                                 :constituent))
1419           (return-from lisp-indentation-check-for-local-def nil))
1420         (move-mark temp2 temp1)
1421         (scan-char temp2 :lisp-syntax (not :constituent))
1422         (let ((fname (nstring-upcase (region-to-string (region temp1 temp2)))))
1423           (cond ((not (member fname (value lisp-indentation-local-definers)
1424                               :test #'string=))
1425                  nil)
1426                 (arg-list
1427                  (1+ (mark-column start)))
1428                 (t
1429                  (+ (mark-column start) 3)))))))
1430
1431;;; LISP-GENERIC-INDENTATION -- Internal.
1432;;;
1433;;; LISP-INDENTATION calls this when mark is in a invalid spot, or quoted
1434;;; context.  If we are inside a string, we return the column one greater
1435;;; than the opening double quote.  Otherwise, we just use the indentation
1436;;; of the first preceding non-blank line.
1437;;;
1438(defun lisp-generic-indentation (mark)
1439  (with-mark ((m mark))
1440    (form-offset m -1)
1441    (cond ((eq (character-attribute :lisp-syntax (next-character m))
1442               :string-quote)
1443           (1+ (mark-column m)))
1444          (t
1445           (let* ((line (mark-line mark))
1446                  (prev (do ((line (line-previous line) (line-previous line)))
1447                            ((not (and line (blank-line-p line))) line))))
1448             (cond (prev
1449                    (line-start mark prev)
1450                    (find-attribute mark :space #'zerop)
1451                    (mark-column mark))
1452                   (t 0)))))))
1453
1454;;; Skip-Valid-Space  --  Internal
1455;;;
1456;;;    Skip over any space on the line Mark is on, stopping at the first valid
1457;;; non-space character.  If there is none on the line, return nil.
1458;;;
1459(defun skip-valid-space (mark)
1460  (loop
1461    (scan-char mark :lisp-syntax (not :space))
1462    (let ((val (character-attribute :lisp-syntax
1463                                    (next-character mark))))
1464      (cond ((eq val :newline) (return nil))
1465            ((valid-spot mark t) (return mark))))
1466    (mark-after mark)))
1467
1468;; (declaim (optimize (speed 0))); byte compile again
1469
1470
1471;;;; Indentation commands and hook functions.
1472
1473(defcommand "Defindent" (p)
1474  "Define the Lisp indentation for the current function.
1475  The indentation is a non-negative integer which is the number
1476  of special arguments for the form.  Examples: 2 for Do, 1 for Dolist.
1477  If a prefix argument is supplied, then delete the indentation information."
1478  "Do a defindent, man!"
1479  (with-mark ((m (current-point)))
1480    (pre-command-parse-check m)
1481    (unless (backward-up-list m) (editor-error))
1482    (mark-after m)
1483    (with-mark ((n m))
1484      (scan-char n :lisp-syntax (not :constituent))
1485      (let ((s (region-to-string (region m n))))
1486        (declare (simple-string s))
1487        (when (zerop (length s)) (editor-error))
1488        (if p
1489            (defindent s nil)
1490            (let ((i (prompt-for-integer
1491                      :prompt (format nil "Indentation for ~A: " s)
1492                      :help "Number of special arguments.")))
1493              (when (minusp i)
1494                (editor-error "Indentation must be non-negative."))
1495              (defindent s i))))))
1496  (indent-command nil))
1497
1498(defcommand "Indent Form" (p)
1499  "Indent Lisp code in the next form, unless point is to the right of
1500   a closing parenthesis, in which case the previous form will be
1501   indented."
1502  "Indent Lisp code in the next form."
1503  (declare (ignore p))
1504  (let ((point (current-point))
1505        (offset 1))
1506    (pre-command-parse-check point)
1507    (when (eql (previous-character point) #\))
1508      (setq offset -1))
1509    (with-mark ((m point))
1510      (unless (form-offset m offset) (editor-error))
1511      (when (minusp offset)
1512        (rotatef point m))
1513      (lisp-indent-region (region point m) "Indent Form"))))
1514
1515;;; LISP-INDENT-REGION -- Internal.
1516;;;
1517;;; This indents a region of Lisp code without doing excessive redundant
1518;;; computation.  We parse the entire region once, then scan through doing
1519;;; indentation on each line.  We forcibly reparse each line that we indent so
1520;;; that the list operations done to determine indentation of subsequent lines
1521;;; will work.  This is done undoably with save1, save2, buf-region, and
1522;;; undo-region.
1523;;;
1524(defun lisp-indent-region (region &optional (undo-text "Lisp region indenting"))
1525  (let* ((start (region-start region))
1526         (end (region-end region))
1527         (buffer (hi::line-%buffer (mark-line start))))
1528    (with-mark ((m1 start)
1529                (m2 end))
1530      (funcall (value parse-start-function) m1)
1531      (funcall (value parse-end-function) m2)
1532      (parse-over-block (mark-line m1) (mark-line m2)))
1533    (hi::check-buffer-modification buffer start)
1534    (hi::check-buffer-modification buffer end)
1535    (let* ((first-line (mark-line start))
1536              (last-line (mark-line end))
1537              (prev (line-previous first-line))
1538              (prev-line-info
1539               (and prev (getf (line-plist prev) 'lisp-info)))
1540              (save1 (line-start (copy-mark start :right-inserting)))
1541              (save2 (line-end (copy-mark end :left-inserting)))
1542              (buf-region (region save1 save2))
1543              (undo-region (copy-region buf-region)))
1544         (with-mark ((bol start :left-inserting))
1545           (do ((line first-line (line-next line)))
1546               (nil)
1547             (line-start bol line)
1548             (ensure-lisp-indentation bol)
1549             (let ((line-info (getf (line-plist line) 'lisp-info)))
1550               (parse-lisp-line-info bol line-info prev-line-info)
1551               (setq prev-line-info line-info))
1552             (when (eq line last-line) (return nil))))
1553         (make-region-undo :twiddle undo-text buf-region undo-region))))
1554
1555;;; INDENT-FOR-LISP -- Internal.
1556;;;
1557;;; This is the value of "Indent Function" for "Lisp" mode.
1558;;;
1559(defun indent-for-lisp (mark)
1560  (line-start mark)
1561  (pre-command-parse-check mark)
1562  (ensure-lisp-indentation mark))
1563
1564(defun count-leading-whitespace (mark)
1565  (with-mark ((m mark))
1566    (line-start m)
1567    (do* ((p 0)
1568          (q 0 (1+ q))
1569          (tab-width (value spaces-per-tab)))
1570         ()
1571      (case (next-character m)
1572        (#\space (incf p))
1573        (#\tab (setq p (* tab-width (ceiling (1+ p) tab-width))))
1574        (t (return (values p q))))
1575      (character-offset m 1))))
1576
1577;;; Don't do anything if M's line is already correctly indented.
1578(defun ensure-lisp-indentation (m)
1579  (let* ((col (lisp-indentation m)))
1580    (multiple-value-bind (curcol curpos) (count-leading-whitespace m)
1581      (cond ((= curcol col) (setf (mark-charpos m) curpos))
1582            (t
1583             (delete-horizontal-space m)
1584             (indent-to-column m col))))))
1585
1586
1587
1588
1589;;;; Most "Lisp" mode commands.
1590
1591(defcommand "Beginning of Defun" (p)
1592  "Move the point to the beginning of a top-level form, collapsing the selection.
1593  with an argument, skips the previous p top-level forms."
1594  "Move the point to the beginning of a top-level form, collapsing the selection."
1595  (let ((point (current-point-collapsing-selection))
1596        (count (or p 1)))
1597    (pre-command-parse-check point)
1598    (if (minusp count)
1599        (end-of-defun-command (- count))
1600        (unless (top-level-offset point (- count))
1601          (editor-error)))))
1602
1603(defcommand "Select to Beginning of Defun" (p)
1604  "Move the point to the beginning of a top-level form, extending the selection.
1605  with an argument, skips the previous p top-level forms."
1606  "Move the point to the beginning of a top-level form, extending the selection."
1607  (let ((point (current-point-for-selection-start))
1608        (count (or p 1)))
1609    (pre-command-parse-check point)
1610    (if (minusp count)
1611        (end-of-defun-command (- count))
1612        (unless (top-level-offset point (- count))
1613          (editor-error)))))
1614
1615;;; "End of Defun", with a positive p (the normal case), does something weird.
1616;;; Get a mark at the beginning of the defun, and then offset it forward one
1617;;; less top level form than we want.  This sets us up to use FORM-OFFSET which
1618;;; allows us to leave the point immediately after the defun.  If we used
1619;;; TOP-LEVEL-OFFSET one less than p on the mark at the end of the current
1620;;; defun, point would be left at the beginning of the p+1'st form instead of
1621;;; at the end of the p'th form.
1622;;;
1623(defcommand "End of Defun" (p)
1624  "Move the point to the end of a top-level form, collapsing the selection.
1625   With an argument, skips the next p top-level forms."
1626  "Move the point to the end of a top-level form, collapsing the selection."
1627  (let ((point (current-point-collapsing-selection))
1628        (count (or p 1)))
1629    (pre-command-parse-check point)
1630    (if (minusp count)
1631        (beginning-of-defun-command (- count))
1632        (with-mark ((m point)
1633                    (dummy point))
1634          (cond ((not (mark-top-level-form m dummy))
1635                 (editor-error "No current or next top level form."))
1636                (t 
1637                 (unless (top-level-offset m (1- count))
1638                   (editor-error "Not enough top level forms."))
1639                 ;; We might be one unparsed for away.
1640                 (pre-command-parse-check m)
1641                 (unless (form-offset m 1)
1642                   (editor-error "Not enough top level forms."))
1643                 (when (blank-after-p m) (line-offset m 1 0))
1644                 (move-mark point m)))))))
1645
1646(defcommand "Select to End of Defun" (p)
1647  "Move the point to the end of a top-level form, extending the selection.
1648   With an argument, skips the next p top-level forms."
1649  "Move the point to the end of a top-level form, extending the selection."
1650  (let ((point (current-point-for-selection-end))
1651        (count (or p 1)))
1652    (pre-command-parse-check point)
1653    (if (minusp count)
1654        (beginning-of-defun-command (- count))
1655        (with-mark ((m point)
1656                    (dummy point))
1657          (cond ((not (mark-top-level-form m dummy))
1658                 (editor-error "No current or next top level form."))
1659                (t 
1660                 (unless (top-level-offset m (1- count))
1661                   (editor-error "Not enough top level forms."))
1662                 ;; We might be one unparsed for away.
1663                 (pre-command-parse-check m)
1664                 (unless (form-offset m 1)
1665                   (editor-error "Not enough top level forms."))
1666                 (when (blank-after-p m) (line-offset m 1 0))
1667                 (move-mark point m)))))))
1668
1669(defcommand "Forward List" (p)
1670  "Skip over the next Lisp list, collapsing the selection.
1671  With argument, skips the next p lists."
1672  "Skip over the next Lisp list, collapsing the selection."
1673  (or (collapse-if-selection :direction :forward)
1674      (let ((point (current-point-collapsing-selection))
1675            (count (or p 1)))
1676        (pre-command-parse-check point)
1677        (unless (list-offset point count) (editor-error "No next list.")))))
1678
1679(defcommand "Select Forward List" (p)
1680  "Skip over the next Lisp list, extending the selection.
1681  With argument, skips the next p lists."
1682  "Skip over the next Lisp list, extending the selection."
1683  (let ((point (current-point-for-selection-end))
1684        (count (or p 1)))
1685    (pre-command-parse-check point)
1686    (unless (list-offset point count) (editor-error "No next list."))))
1687
1688(defcommand "Backward List" (p)
1689  "Skip over the previous Lisp list, collapsing the selection.
1690  With argument, skips the previous p lists."
1691  "Skip over the previous Lisp list, collapsing the selection."
1692  (or (collapse-if-selection :direction :backward)
1693   (let ((point (current-point-collapsing-selection))
1694        (count (- (or p 1))))
1695    (pre-command-parse-check point)
1696    (unless (list-offset point count) (editor-error "No previous list.")))))
1697
1698(defcommand "Select Backward List" (p)
1699  "Skip over the previous Lisp list, extending the selection.
1700  With argument, skips the previous p lists."
1701  "Skip over the previous Lisp list, extending the selection."
1702  (let ((point (current-point-for-selection-start))
1703        (count (- (or p 1))))
1704    (pre-command-parse-check point)
1705    (unless (list-offset point count) (editor-error "No previous list."))))
1706
1707(defcommand "Forward Form" (p)
1708    "Skip over the next Form, collapsing the selection.
1709  With argument, skips the next p Forms."
1710    "Skip over the next Form, collapsing the selection."
1711  (or (collapse-if-selection :direction :forward)
1712      (let ((point (current-point-collapsing-selection))
1713            (count (or p 1)))
1714        (pre-command-parse-check point)
1715        (unless (form-offset point count) (editor-error "No next form.")))))
1716
1717(defcommand "Select Forward Form" (p)
1718  "Skip over the next Form, extending the selection.
1719  With argument, skips the next p Forms."
1720  "Skip over the next Form, extending the selection."
1721  (let ((point (current-point-for-selection-end))
1722        (count (or p 1)))
1723    (pre-command-parse-check point)
1724    (unless (form-offset point count) (editor-error "No next form."))))
1725
1726(defcommand "Backward Form" (p)
1727    "Skip over the previous Form, collapsing the selection.
1728  With argument, skips the previous p Forms."
1729    "Skip over the previous Form, collaspsing the selection."
1730  (or (collapse-if-selection :direction :backward)
1731      (let ((point (current-point-collapsing-selection))
1732            (count (- (or p 1))))
1733        (pre-command-parse-check point)
1734        (unless (form-offset point count) (editor-error "No previous form.")))))
1735
1736(defcommand "Select Backward Form" (p)
1737  "Skip over the previous Form, extending the selection.
1738  With argument, skips the previous p Forms."
1739  "Skip over the previous Form, extending the selection."
1740  (let ((point (current-point-for-selection-start))
1741        (count (- (or p 1))))
1742    (pre-command-parse-check point)
1743    (unless (form-offset point count) (editor-error "No previous form."))))
1744
1745(defcommand "Mark Form" (p)
1746  "Set the mark at the end of the next Form.
1747   With a positive argument, set the mark after the following p
1748   Forms. With a negative argument, set the mark before
1749   the preceding -p Forms."
1750  "Set the mark at the end of the next Form."
1751  (with-mark ((m (current-point)))
1752    (pre-command-parse-check m)
1753    (let ((count (or p 1))
1754          (mark (push-new-buffer-mark m t)))
1755      (if (form-offset m count)
1756          (move-mark mark m)
1757          (editor-error "No next form.")))))
1758
1759(defcommand "Mark Defun" (p)
1760  "Puts the region around the next or containing top-level form.
1761   The point is left before the form and the mark is placed immediately
1762   after it."
1763  "Puts the region around the next or containing top-level form."
1764  (declare (ignore p))
1765  (let ((point (current-point)))
1766    (pre-command-parse-check point)
1767    (with-mark ((start point)
1768                (end point))
1769      (cond ((not (mark-top-level-form start end))
1770             (editor-error "No current or next top level form."))
1771            (t
1772             (move-mark point start)
1773             (move-mark (push-new-buffer-mark point t) end))))))
1774
1775(defcommand "Forward Kill Form" (p)
1776  "Kill the next Form.
1777   With a positive argument, kills the next p Forms.
1778   Kills backward with a negative argument."
1779  "Kill the next Form."
1780  (with-mark ((m1 (current-point))
1781              (m2 (current-point)))
1782    (pre-command-parse-check m1)
1783    (let ((count (or p 1)))
1784      (unless (form-offset m1 count) (editor-error "No ~a form." (if (minusp count) "previous" "next")))
1785      (if (minusp count)
1786          (kill-region (region m1 m2) :kill-backward)
1787          (kill-region (region m2 m1) :kill-forward)))))
1788
1789(defcommand "Backward Kill Form" (p)
1790  "Kill the previous Form.
1791  With a positive argument, kills the previous p Forms.
1792  Kills forward with a negative argument."
1793  "Kill the previous Form."
1794  (forward-kill-form-command (- (or p 1))))
1795
1796(defcommand "Extract Form" (p)
1797  "Replace the current containing list with the next form.  The entire affected
1798   area is pushed onto the kill ring.  If an argument is supplied, that many
1799   upward levels of list nesting is replaced by the next form."
1800  "Replace the current containing list with the next form.  The entire affected
1801   area is pushed onto the kill ring.  If an argument is supplied, that many
1802   upward levels of list nesting is replaced by the next form."
1803  (let ((point (current-point)))
1804    (pre-command-parse-check point)
1805    (with-mark ((form-start point :right-inserting)
1806                (form-end point))
1807      (unless (form-offset form-end 1) (editor-error "No next form."))
1808      (form-offset (move-mark form-start form-end) -1)
1809      (with-mark ((containing-start form-start :left-inserting)
1810                  (containing-end form-end :left-inserting))
1811        (dotimes (i (or p 1))
1812          (unless (and (forward-up-list containing-end)
1813                       (backward-up-list containing-start))
1814            (editor-error "No containing list.")))
1815        (let ((r (copy-region (region form-start form-end))))
1816          (ring-push (delete-and-save-region
1817                      (region containing-start containing-end))
1818                     *kill-ring*)
1819          (ninsert-region point r)
1820          (move-mark point form-start))))))
1821
1822(defcommand "Extract List" (p)
1823  "Extract the current list.
1824  The current list replaces the surrounding list.  The entire affected
1825  area is pushed on the kill-ring.  With prefix argument, remove that
1826  many surrounding lists."
1827  "Replace the P containing lists with the current one."
1828  (let ((point (current-point)))
1829    (pre-command-parse-check point)
1830    (with-mark ((lstart point :right-inserting)
1831                (lend point))
1832      (if (eq (character-attribute :lisp-syntax (next-character lstart))
1833              :open-paren)
1834          (mark-after lend)
1835          (unless (backward-up-list lstart) (editor-error "No containing list.")))
1836      (unless (forward-up-list lend) (editor-error "No containing list."))
1837      (with-mark ((rstart lstart)
1838                  (rend lend))
1839        (dotimes (i (or p 1))
1840          (unless (and (forward-up-list rend) (backward-up-list rstart))
1841            (editor-error)))
1842        (let ((r (copy-region (region lstart lend))))
1843          (ring-push (delete-and-save-region (region rstart rend))
1844                     *kill-ring*)
1845          (ninsert-region point r)
1846          (move-mark point lstart))))))
1847
1848(defcommand "Transpose Forms" (p)
1849  "Transpose Forms immediately preceding and following the point.
1850  With a zero argument, tranposes the Forms at the point and the mark.
1851  With a positive argument, transposes the Form preceding the point
1852  with the p-th one following it.  With a negative argument, transposes the
1853  Form following the point with the p-th one preceding it."
1854  "Transpose Forms immediately preceding and following the point."
1855  (let ((point (current-point))
1856        (count (or p 1)))
1857    (pre-command-parse-check point)
1858    (if (zerop count)
1859        (let ((mark (current-mark)))
1860          (with-mark ((s1 mark :left-inserting)
1861                      (s2 point :left-inserting))
1862            (scan-char s1 :whitespace nil)
1863            (scan-char s2 :whitespace nil)
1864            (with-mark ((e1 s1 :right-inserting)
1865                        (e2 s2 :right-inserting))
1866              (unless (form-offset e1 1) (editor-error "No next form."))
1867              (unless (form-offset e2 1) (editor-error "No next form."))
1868              (ninsert-region s1 (delete-and-save-region (region s2 e2)))
1869              (ninsert-region s2 (delete-and-save-region (region s1 e1))))))
1870        (let ((fcount (if (plusp count) count 1))
1871              (bcount (if (plusp count) 1 count)))
1872          (with-mark ((s1 point :left-inserting)
1873                      (e2 point :right-inserting))
1874            (dotimes (i bcount)
1875              (unless (form-offset s1 -1) (editor-error "No previous form.")))
1876            (dotimes (i fcount)
1877              (unless (form-offset e2 1) (editor-error "No next form.")))
1878            (with-mark ((e1 s1 :right-inserting)
1879                        (s2 e2 :left-inserting))
1880              (unless (form-offset e1 1) (editor-error))
1881              (unless (form-offset s2 -1) (editor-error))
1882              (ninsert-region s1 (delete-and-save-region (region s2 e2)))
1883              (ninsert-region s2 (delete-and-save-region (region s1 e1)))
1884              (move-mark point s2)))))))
1885
1886
1887(defcommand "Insert ()" (count)
1888  "Insert a pair of parentheses ().  With positive argument, puts
1889   parentheses around the next COUNT Forms, or previous COUNT forms, if
1890   COUNT is negative.  The point is positioned after the open parenthesis."
1891  "Insert a pair of parentheses ()."
1892  ;; TODO Form navigation is broken, so this is broken too -- it is
1893  ;; possible to put parens around more forms than there are in current
1894  ;; expression.  It works by moving past as many forms as there is, and
1895  ;; then each delimiting paren also counts as a form.
1896  (let ((point (current-point)))
1897    (pre-command-parse-check point)
1898    (cond (count
1899           (when (minusp count)
1900             (form-offset point count)
1901             (setq count (- count)))
1902           (insert-character point #\()
1903           (with-mark ((m point))
1904             (unless (form-offset m count)
1905               (editor-error "Could not find that many forms."))
1906             (insert-character m #\))))
1907          ;; The simple case with no prefix argument
1908          (t
1909           (insert-character point #\()
1910           (insert-character point #\))
1911           (mark-before point)))))
1912
1913
1914(defcommand "Move Over )" (p)
1915  "Move past the next close parenthesis, and start a new line.  Any
1916   indentation preceding the preceding the parenthesis is deleted, and the
1917   new line is indented.  If there is only whitespace preceding the close
1918   paren, the paren is moved to the end of the previous line. With prefix
1919   argument, this command moves past next closing paren and inserts space."
1920  "Move past the next close parenthesis, and start a new line."
1921  ;; TODO This is still not complete, because SCAN-CHAR finds the next
1922  ;; close-paren, but we need to find the next paren that closes current
1923  ;; expression.  This will have to be updated when form navigation is
1924  ;; fixed.
1925  (let ((point (current-point)))
1926    (pre-command-parse-check point)
1927    (with-mark ((m point :right-inserting))
1928      (cond ((scan-char m :lisp-syntax :close-paren)
1929             (cond ((same-line-p point m)
1930                    (delete-horizontal-space m))
1931                   (t
1932                    (move-mark point m)
1933                    (reverse-find-attribute point :whitespace #'zerop)
1934                    (delete-region (region point m))))
1935             (cond ((not p)
1936                    ;; Move to the previous line if current is empty
1937                    (when (zerop (mark-charpos m))
1938                      (delete-characters m -1))
1939                    (mark-after m)
1940                    (move-mark point m)
1941                    (indent-new-line-command 1))
1942                   (t
1943                    (mark-after m)
1944                    (move-mark point m)
1945                    (insert-character m #\space))))
1946            (t 
1947             (editor-error "Could not find closing paren."))))))
1948
1949
1950(defcommand "Forward Up List" (p)
1951    "Move forward past a one containing )."
1952    "Move forward past a one containing )."
1953  (or (collapse-if-selection :direction :forward)
1954      (let ((point (current-point-collapsing-selection))
1955            (count (or p 1)))
1956        (pre-command-parse-check point)
1957        (if (minusp count)
1958            (backward-up-list-command (- count))
1959            (with-mark ((m point))
1960              (dotimes (i count (move-mark point m))
1961                (unless (forward-up-list m) (editor-error "No containing list."))))))))
1962
1963(defcommand "Backward Up List" (p)
1964    "Move backward past a one containing (."
1965    "Move backward past a one containing (."
1966  (or (collapse-if-selection :direction :backward)
1967      (let ((point (current-point-collapsing-selection))
1968            (count (or p 1)))
1969        (pre-command-parse-check point)
1970        (if (minusp count)
1971            (forward-up-list-command (- count))
1972            (with-mark ((m point))
1973              (dotimes (i count (move-mark point m))
1974                (unless (backward-up-list m) (editor-error "No containing list."))))))))
1975
1976
1977(defcommand "Down List" (p)
1978  "Move down a level in list structure.  With positive argument, moves down
1979   p levels.  With negative argument, moves down backward, but only one
1980   level."
1981  "Move down a level in list structure."
1982  (let ((point (current-point-collapsing-selection))
1983        (count (or p 1)))
1984    (pre-command-parse-check point)
1985    (with-mark ((m point))
1986      (cond ((plusp count)
1987             (loop repeat count
1988                   do (unless (and (scan-char m :lisp-syntax :open-paren)
1989                                   (mark-after m))
1990                        (editor-error "No embedded list."))))
1991            (t
1992             (unless (and (rev-scan-char m :lisp-syntax :close-paren)
1993                          (mark-before m))
1994               (editor-error "No embedded list."))))
1995      (move-mark point m))))
1996
1997
1998
1999;;;; Filling Lisp comments, strings, and indented text.
2000
2001(defhvar "Fill Lisp Comment Paragraph Confirm"
2002  "This determines whether \"Fill Lisp Comment Paragraph\" will prompt for
2003   confirmation to fill contiguous lines with the same initial whitespace when
2004   it is invoked outside of a comment or string."
2005  :value t)
2006
2007(defcommand "Fill Lisp Comment Paragraph" (p)
2008  "This fills a flushleft or indented Lisp comment.
2009   This also fills Lisp string literals using the proper indentation as a
2010   filling prefix.  When invoked outside of a comment or string, this tries
2011   to fill all contiguous lines beginning with the same initial, non-empty
2012   blankspace.  When filling a comment, the current line is used to determine a
2013   fill prefix by taking all the initial whitespace on the line, the semicolons,
2014   and any whitespace following the semicolons."
2015  "Fills a flushleft or indented Lisp comment."
2016  (declare (ignore p))
2017  (let ((point (current-point)))
2018    (pre-command-parse-check point)
2019    (with-mark ((start point)
2020                (end point)
2021                (m point))
2022      (let ((commentp (fill-lisp-comment-paragraph-prefix start end)))
2023        (cond (commentp
2024               (fill-lisp-comment-or-indented-text start end))
2025              ((and (not (valid-spot m nil))
2026                    (form-offset m -1)
2027                    (eq (character-attribute :lisp-syntax (next-character m))
2028                        :string-quote))
2029               (fill-lisp-string m))
2030              ((or (not (value fill-lisp-comment-paragraph-confirm))
2031                   (prompt-for-y-or-n
2032                    :prompt '("Not in a comment or string.  Fill contiguous ~
2033                               lines with the same initial whitespace? ")))
2034               (fill-lisp-comment-or-indented-text start end)))))))
2035
2036;;; FILL-LISP-STRING -- Internal.
2037;;;
2038;;; This fills the Lisp string containing mark as if it had been entered using
2039;;; Hemlock's Lisp string indentation, "Indent Function" for "Lisp" mode.  This
2040;;; assumes the area around mark has already been PRE-COMMAND-PARSE-CHECK'ed,
2041;;; and it ensures the string ends before doing any filling.  This function
2042;;; is undo'able.
2043;;;
2044(defun fill-lisp-string (mark)
2045  (with-mark ((end mark))
2046    (unless (form-offset end 1)
2047      (editor-error "Attempted to fill Lisp string, but it doesn't end?"))
2048    (let* ((mark (copy-mark mark :left-inserting))
2049           (end (copy-mark end :left-inserting))
2050           (string-region (region mark end))
2051           (undo-region (copy-region string-region))
2052           (hack (make-empty-region)))
2053      ;; Generate prefix.
2054      (indent-to-column (region-end hack) (1+ (mark-column mark)))
2055      ;; Skip opening double quote and fill string starting on its own line.
2056      (mark-after mark)
2057      (insert-character mark #\newline)
2058      (line-start mark)
2059      (setf (mark-kind mark) :right-inserting)
2060      (fill-region string-region (region-to-string hack))
2061      ;; Clean up inserted prefix on first line, delete inserted newline, and
2062      ;; move before the double quote for undo.
2063      (with-mark ((text mark :left-inserting))
2064        (find-attribute text :whitespace #'zerop)
2065        (delete-region (region mark text)))
2066      (delete-characters mark -1)
2067      (mark-before mark)
2068      ;; Save undo.
2069      (make-region-undo :twiddle "Fill Lisp Comment Paragraph"
2070                        string-region undo-region))))
2071
2072;;; FILL-LISP-COMMENT-OR-INDENTED-TEXT -- Internal.
2073;;;
2074;;; This fills all contiguous lines around start and end containing fill prefix
2075;;; designated by the region between start and end.  These marks can only be
2076;;; equal when there is no comment and no initial whitespace.  This is a bad
2077;;; situation since this function in that situation would fill the entire
2078;;; buffer into one paragraph.  This function is undo'able.
2079;;;
2080(defun fill-lisp-comment-or-indented-text (start end)
2081  (when (mark= start end)
2082    (editor-error "This command only fills Lisp comments, strings, or ~
2083                   indented text, but this line is flushleft."))
2084  ;;
2085  ;; Find comment block.
2086  (let* ((prefix (region-to-string (region start end)))
2087         (length (length prefix)))
2088    (declare (simple-string prefix))
2089    (flet ((frob (mark direction)
2090             (loop
2091               (let* ((line (line-string (mark-line mark)))
2092                      (line-len (length line)))
2093                 (declare (simple-string line))
2094                 (unless (string= line prefix :end1 (min line-len length))
2095                   (when (= direction -1)
2096                     (unless (same-line-p mark end) (line-offset mark 1 0)))
2097                   (return)))
2098               (unless (line-offset mark direction 0)
2099                 (when (= direction 1) (line-end mark))
2100                 (return)))))
2101      (frob start -1)
2102      (frob end 1))
2103    ;;
2104    ;; Do it undoable.
2105    (let* ((start1 (copy-mark start :right-inserting))
2106           (end2 (copy-mark end :left-inserting))
2107           (region (region start1 end2))
2108           (undo-region (copy-region region)))
2109      (fill-region region prefix)
2110      (make-region-undo :twiddle "Fill Lisp Comment Paragraph"
2111                        region undo-region))))
2112
2113;;; FILL-LISP-COMMENT-PARAGRAPH-PREFIX -- Internal.
2114;;;
2115;;; This sets start and end around the prefix to be used for filling.  We
2116;;; assume we are dealing with a comment.  If there is no ";", then we try to
2117;;; find some initial whitespace.  If there is a ";", we make sure the line is
2118;;; blank before it to eliminate ";"'s in the middle of a line of text.
2119;;; Finally, if we really have a comment instead of some indented text, we skip
2120;;; the ";"'s and any immediately following whitespace.  We allow initial
2121;;; whitespace, so we can fill strings with the same command.
2122;;;
2123(defun fill-lisp-comment-paragraph-prefix (start end)
2124  (line-start start)
2125  (let ((commentp t)) ; Assumes there's a comment.
2126    (unless (to-line-comment (line-start end) ";")
2127      (find-attribute end :whitespace #'zerop)
2128      #|(when (start-line-p end)
2129        (editor-error "No comment on line, and no initial whitespace."))|#
2130      (setf commentp nil))
2131    (when commentp
2132      (unless (blank-before-p end)
2133        (find-attribute (line-start end) :whitespace #'zerop)
2134        #|(when (start-line-p end)
2135          (editor-error "Semicolon preceded by unindented text."))|#
2136        (setf commentp nil)))
2137    (when commentp
2138      (find-attribute end :lisp-syntax #'(lambda (x) (not (eq x :comment))))
2139      (find-attribute end :whitespace #'zerop))
2140    commentp))
2141
2142
2143
2144;;;; "Lisp" mode.
2145
2146(defcommand "LISP Mode" (p)
2147  "Put current buffer in LISP mode." 
2148  "Put current buffer in LISP mode." 
2149  (declare (ignore p))
2150  (setf (buffer-major-mode (current-buffer)) "LISP"))
2151
2152
2153(defmode "Lisp" :major-p t :setup-function 'setup-lisp-mode)
2154
2155
2156(defun buffer-first-in-package-form (buffer)
2157  "Returns the package name referenced in the first apparent IN-PACKAGE
2158   form in buffer, or NIL if it can't find an IN-PACKAGE."
2159  (let* ((pattern (new-search-pattern :string-insensitive :forward "in-package" nil))
2160         (mark (copy-mark (buffer-start-mark buffer))))
2161    (with-mark ((start mark)
2162                (end mark))
2163      (loop
2164        (unless (find-pattern mark pattern)
2165          (return))
2166        (pre-command-parse-check mark)
2167        (when (valid-spot mark t)
2168          (move-mark end mark)
2169          (when (form-offset end 1)
2170            (move-mark start end)
2171            (when (backward-up-list start)
2172              (when (scan-char start :lisp-syntax :constituent)
2173                (let* ((s (nstring-upcase (region-to-string (region start end))))
2174                       (*package* (find-package "CL-USER")))
2175                  (unless (eq (ignore-errors (values (read-from-string s)))
2176                              'in-package)
2177                    (return)))
2178                (unless (form-offset end 1) (return))
2179                (move-mark start end)
2180                (form-offset start -1)
2181                (let* ((pkgname (ignore-errors (values (read-from-string (region-to-string (region start end)))))))
2182                  (return
2183                    (if pkgname
2184                      (values (ignore-errors (string pkgname))))))))))))))
2185
2186(defparameter *previous-in-package-search-pattern*
2187    (new-search-pattern :string-insensitive :backward "in-package" nil))
2188
2189(defun package-at-mark (start-mark &optional return-mark)
2190  (let* ((pattern *previous-in-package-search-pattern*)
2191         (mark (copy-mark start-mark :temporary)))
2192    (with-mark ((start mark)
2193                (end mark)
2194                (list-end mark))
2195      (loop for i from 0 do
2196        (tagbody ; I'm not proud of this
2197         (unless (find-pattern mark pattern)
2198           (return))
2199         (pre-command-parse-check mark)
2200         (when (valid-spot mark t)
2201           (move-mark end mark)
2202           (when (form-offset end 1)
2203             (move-mark start end)
2204             (when (backward-up-list start)
2205               (move-mark list-end start)
2206               (unless (and (list-offset list-end 1)
2207                            (mark<= list-end start-mark))
2208                 (go again))
2209               (when (scan-char start :lisp-syntax :constituent)
2210                 (unless (or (mark= mark start)
2211                             (let* ((s (nstring-upcase (region-to-string (region start end))))
2212                                    (*package* (find-package "CL-USER")))
2213                               (eq (ignore-errors (values (read-from-string s)))
2214                                   'in-package)))
2215                   (go again))
2216                 (unless (form-offset end 1) (go again))
2217                 (move-mark start end)
2218                 (unless (form-offset start -1) (go again))
2219                 (return
2220                  (if (eql (next-character start) #\")
2221                    (progn
2222                      (character-offset start 1)
2223                      (character-offset end -1)
2224                      (when return-mark (move-mark return-mark list-end))
2225                      (region-to-string (region start end)))
2226                     (let* ((pkgname (ignore-errors (read-from-string (region-to-string (region start end))))))
2227                       (when (and pkgname (setq pkgname (ignore-errors (string pkgname))))
2228                         (when return-mark (move-mark return-mark list-end))
2229                         pkgname))))))))
2230         again)))))
2231
2232(defun ensure-buffer-package (buffer)
2233  (or (variable-value 'current-package :buffer buffer)
2234      (setf (variable-value 'current-package :buffer buffer)
2235            (buffer-first-in-package-form buffer))))
2236
2237(defun buffer-package (buffer)
2238  (when (hemlock-bound-p 'current-package :buffer buffer)
2239    (let ((package-name (variable-value 'current-package :buffer buffer)))
2240      (find-package package-name))))
2241
2242(defun setup-lisp-mode (buffer)
2243  (unless (hemlock-bound-p 'current-package :buffer buffer)
2244    (defhvar "Current Package"
2245      "The package used for evaluation of Lisp in this buffer."
2246      :buffer buffer
2247      :value nil
2248      :hooks (list 'package-name-change-hook)))
2249  (unless (hemlock-bound-p 'default-package :buffer buffer)
2250    (defhvar "Default Package"
2251      "The package to use if the current package doesn't exist or isn't set."
2252      :buffer buffer
2253      :value (package-name *package*))))
2254
2255
2256
2257
2258
2259;;;; Some mode variables to coordinate with other stuff.
2260
2261(defhvar "Auto Fill Space Indent"
2262  "When non-nil, uses \"Indent New Comment Line\" to break lines instead of
2263   \"New Line\"."
2264  :mode "Lisp" :value t)
2265
2266(defhvar "Comment Start"
2267  "String that indicates the start of a comment."
2268  :mode "Lisp" :value ";")
2269
2270(defhvar "Comment Begin"
2271  "String that is inserted to begin a comment."
2272  :mode "Lisp" :value "; ")
2273
2274(defhvar "Indent Function"
2275  "Indentation function which is invoked by \"Indent\" command.
2276   It must take one argument that is the prefix argument."
2277  :value 'indent-for-lisp
2278  :mode "Lisp")
2279
2280(defun string-to-arglist (string buffer &optional quiet-if-unknown)
2281  (multiple-value-bind (name error)
2282      (let* ((*package* (or
2283                         (find-package
2284                          (variable-value 'current-package :buffer buffer))
2285                         *package*)))
2286        (ignore-errors (values (read-from-string string))))
2287    (unless error
2288      (when (typep name 'symbol)
2289        (multiple-value-bind (arglist win)
2290            (ccl::arglist-string name)
2291          (if (or win (not quiet-if-unknown))
2292            (format nil "~S : ~A" name (if win (or arglist "()") "(unknown)"))))))))
2293
2294(defcommand "Current Function Arglist" (p)
2295  "Show arglist of function whose name precedes point."
2296  "Show arglist of function whose name precedes point."
2297  (declare (ignore p))
2298  (let ((point (current-point)))
2299    (pre-command-parse-check point)
2300    (with-mark ((mark1 point)
2301                (mark2 point))
2302      (when (backward-up-list mark1)
2303        (when (form-offset (move-mark mark2 (mark-after mark1)) 1)
2304          (let* ((fun-name (region-to-string (region mark1 mark2)))
2305                 (arglist-string (string-to-arglist fun-name (current-buffer))))
2306            (when arglist-string
2307              (message "~a" arglist-string))))))))
2308
2309(defcommand "Arglist On Space" (p)
2310  "Insert a space, then show the current function's arglist."
2311  "Insert a space, then show the current function's arglist."
2312  (declare (ignore p))
2313  (let ((point (current-point-for-insertion)))
2314    (insert-character point #\Space)
2315    (pre-command-parse-check point)
2316    (with-mark ((m point))
2317      (when (backward-up-list m)
2318        (when (and (scan-char m :lisp-syntax :open-paren)
2319                   (mark-after m))
2320          (with-mark ((n m))
2321          (forward-form n)
2322            (let* ((fun-name (region-to-string (region m n)))
2323                   (arglist-string (string-to-arglist fun-name (current-buffer) t)))
2324              (when arglist-string
2325                      (message "~a" arglist-string)))))))))
2326
2327(hi:defcommand "Show Callers" (p)
2328  "Display a scrolling list of the callers of the symbol at point.
2329  Double-click a row to go to the caller's definition."
2330  (declare (ignore p))
2331  (with-mark ((mark1 (current-point))
2332              (mark2 (current-point)))
2333    (let* ((*package* (or (find-package (package-at-mark mark1)) *package*)))
2334      (mark-symbol mark1 mark2)
2335      (with-input-from-region (s (region mark1 mark2))
2336        (let* ((symbol (read s)))
2337          (hemlock-ext:open-sequence-dialog
2338           :title (format nil "Callers of ~a" symbol)
2339           :sequence (ccl::callers symbol)
2340           :action #'edit-definition))))))
2341
2342#||
2343(defcommand "Set Package Name" (p)
2344  (variable-value 'current-package :buffer buffer)
2345||#               
2346
2347(defcommand "Insert Sharp Comment" (p)
2348  "Inserts #| |# around the selection and puts point between them."
2349  (declare (ignore p))
2350  (multiple-value-bind (start end) (buffer-selection-range (current-buffer))
2351    (let ((point (current-point)))
2352      (cond ((= start end)
2353             (insert-string point "#|")
2354             (insert-character point #\newline)
2355             (insert-character point #\newline)
2356             (insert-string point "|#")
2357             (character-offset point -3))
2358            (t
2359             (with-mark ((start-mark point :left-inserting)
2360                         (end-mark point :left-inserting))
2361               (move-to-absolute-position start-mark start)
2362               (move-to-absolute-position end-mark end)
2363               (insert-string start-mark "#|
2364")
2365               (insert-string end-mark "
2366|#")))))))
Note: See TracBrowser for help on using the repository browser.