source: trunk/source/cocoa-ide/hemlock/src/lispmode.lisp @ 13186

Last change on this file since 13186 was 13186, checked in by gz, 11 years ago

A bunch of Hemlock Lisp mode changes:

  • Add parsing support for |symbol quoting| and #| nested comments |#. This fixes bug 421.
  • Change comment syntax coloring color from light gray to brown. Use it to color #| |# blocks as well as ;;; comments. Do NOT use it to color escaped symbol constituents.
  • Add support for moving over lisp forms without pre-parsing info, for use when pre-parsing info is not available. Use this to allow navigation (i.e. c-m-f et. al.) inside strings and comment (seems like there would have been a ticket for this but I didn't find one).
  • Make meta-. work inside comments
  • Extend double-click selection to work inside comments/strings, ditto for Enter. This fixes bug 503 and bug 509.
  • Fix a couple bugs in pre-parsing of lines with escape at end. This was the underlying cause of bug 444, so this fixes bug 444.
  • Make triple-click select symbols vs. words for double-click. This addresses bug 496.
  • parse-over-block: fix the constant reparsing of the first line.
  • set-temporary-character-attributes: do not force reparsing, as this is called a lot.
  • fix macroexpand commands to act in-lisp context
  • Init hemlock syntax attributes from ccl::%standard-readtable%
  • Replace Editor Compile Defun and Editor Evaluate Defun with Editor Execute Defun, and replace Editor Compile Region and Editor Evaluate Region with Editor Execute Expression.
  • Make the form selected by double-clicking be the same as the form used for execution and macroexpansion commands, and make it be more general. This fixes bug 577 and bug 65 and bug 188.
  • some other changes that I no longer remember because I had this checked out for way too long...
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 83.5 KB
Line 
1;;; -*- Log: hemlock.log; Package: Hemlock -*-
2;;;
3;;; **********************************************************************
4;;; This code was written as part of the CMU Common Lisp project at
5;;; Carnegie Mellon University, and has been placed in the public domain.
6;;;
7#+CMU (ext:file-comment
8  "$Header$")
9;;;
10;;; **********************************************************************
11;;;
12;;; Hemlock LISP Mode commands
13;;;
14;;; Written by Ivan Vazquez and Bill Maddox.
15;;;
16
17(in-package :hemlock)
18
19;; (declaim (optimize (speed 2))); turn off byte compilation.
20
21
22;;;; Variables and lisp-info structure.
23
24;;; These routines are used to define, for standard LISP mode, the start and end
25;;; of a block to parse.  If these need to be changed for a minor mode that sits
26;;; on top of LISP mode, simply do a DEFHVAR with the minor mode and give the
27;;; name of the function to use instead of START-OF-PARSE-BLOCK and
28;;; END-OF-PARSE-BLOCK.
29;;;
30
31(defhvar "Parse Start Function"
32  "Take a mark and move it to the top of a block for paren parsing."
33  :value 'start-of-parse-block)
34
35(defhvar "Parse End Function"
36  "Take a mark and move it to the bottom of a block for paren parsing."
37  :value 'end-of-parse-block)
38
39           
40;;; LISP-INFO is the structure used to store the data about the line in its
41;;; Plist.
42;;;
43;;;     -> BEGINS-QUOTED, ENDING-QUOTED are both slots that tell whether or not
44;;;        a line's begining and/or ending are quoted, and if so, how.
45;;;
46;;;     -> RANGES-TO-IGNORE is a list of cons cells, each having the form
47;;;        ( [begining-charpos] [end-charpos] ) each of these cells indicating
48;;;        a range where :lisp-syntax attributes are ignored.  End is exclusive.
49;;;
50;;;     -> NET-OPEN-PARENS, NET-CLOSE-PARENS integers that are the number of
51;;;        unmatched opening and closing parens that there are on a line.
52;;;
53;;;     -> SIGNATURE-SLOT ...
54;;;
55
56(defstruct (lisp-info (:constructor make-lisp-info ()))
57  (begins-quoted nil)           ; nil or quote char attribute or comment nesting depth
58  (ending-quoted nil)           ; nil or quote char attribute or comment nesting depth
59  (ranges-to-ignore nil)
60  (net-open-parens 0 :type fixnum)
61  (net-close-parens 0 :type fixnum)
62  (signature-slot))
63
64
65
66;;;; Macros.
67
68;;; The following Macros exist to make it easy to acces the Syntax primitives
69;;; without uglifying the code.  They were originally written by Maddox.
70;;;
71
72(defmacro scan-char (mark attribute values)
73  `(find-attribute ,mark ',attribute ,(attr-predicate values)))
74
75(defmacro rev-scan-char (mark attribute values)
76  `(reverse-find-attribute ,mark ',attribute ,(attr-predicate values)))
77
78(defmacro test-char (char attribute values)
79  `(let ((x (character-attribute ',attribute ,char)))
80     ,(attr-predicate-aux values)))
81
82(eval-when (:compile-toplevel :execute :load-toplevel)
83(defun attr-predicate (values)
84  (cond ((eq values 't)
85         '#'plusp)
86        ((eq values 'nil)
87         '#'zerop)
88        (t `#'(lambda (x) ,(attr-predicate-aux values)))))
89
90(defun attr-predicate-aux (values)
91  (cond ((eq values t)
92         '(plusp x))
93        ((eq values nil)
94         '(zerop x))
95        ((symbolp values)
96         `(eq x ',values))
97        ((and (listp values) (member (car values) '(and or not)))
98         (cons (car values) (mapcar #'attr-predicate-aux (cdr values))))
99        (t (error "Illegal form in attribute pattern - ~S" values))))
100
101); Eval-When
102
103;;;
104;;; FIND-LISP-CHAR
105
106(defmacro find-lisp-char (mark)
107  "Move MARK to next :LISP-SYNTAX character, if one isn't found, return NIL."
108  `(find-attribute ,mark :lisp-syntax
109                   #'(lambda (x)
110                       (member x '(:open-paren :close-paren :newline :comment :prefix-dispatch
111                                               :char-quote :symbol-quote :string-quote)))))
112;;;
113;;; PUSH-RANGE
114
115(defmacro push-range (new-range info-struct)
116  "Insert NEW-RANGE into the LISP-INFO-RANGES-TO-IGNORE slot of the INFO-STRUCT."
117  `(when ,new-range
118     (setf (lisp-info-ranges-to-ignore ,info-struct) 
119           (cons ,new-range (lisp-info-ranges-to-ignore ,info-struct)))))
120;;;
121;;; SCAN-DIRECTION
122
123(defmacro scan-direction (mark forwardp &rest forms)
124  "Expand to a form that scans either backward or forward according to Forwardp."
125  (if forwardp
126      `(scan-char ,mark ,@forms)
127      `(rev-scan-char ,mark ,@forms)))
128;;;
129;;; DIRECTION-CHAR
130
131(defmacro direction-char (mark forwardp)
132  "Expand to a form that returns either the previous or next character according
133  to Forwardp."
134  (if forwardp
135      `(next-character ,mark)
136      `(previous-character ,mark)))
137
138;;;
139;;; NEIGHBOR-MARK
140
141(defmacro neighbor-mark (mark forwardp)
142  "Expand to a form that moves MARK either backward or forward one character,
143  depending on FORWARDP."
144  (if forwardp
145      `(mark-after ,mark)
146      `(mark-before ,mark)))
147
148;;;
149;;; NEIGHBOR-LINE
150
151(defmacro neighbor-line (line forwardp)
152  "Expand to return the next or previous line, according to Forwardp."
153  (if forwardp
154      `(line-next ,line)
155      `(line-previous ,line)))
156
157
158;;;; Parsing functions.
159
160;;; PRE-COMMAND-PARSE-CHECK -- Public.
161;;;
162(defun pre-command-parse-check (mark &optional (fer-sure-parse nil))
163  "Parse the area before the command is actually executed."
164  (with-mark ((top mark)
165              (bottom mark))
166    (funcall (value parse-start-function) top)
167    (funcall (value parse-end-function) bottom)
168    (parse-over-block (mark-line top) (mark-line bottom) fer-sure-parse)))
169
170;;; PARSE-OVER-BLOCK
171;;;
172(defun parse-over-block (start-line end-line &optional (fer-sure-parse nil))
173  "Parse over an area indicated from END-LINE to START-LINE."
174  (let ((test-line start-line)
175        prev-line-info)
176   
177    (with-mark ((mark (mark test-line 0)))
178     
179      ; Set the pre-begining and post-ending lines to delimit the range
180      ; of action any command will take.  This means set the lisp-info of the
181      ; lines immediately before and after the block to Nil.
182     
183      (when (line-previous start-line)
184        (setf (getf (line-plist (line-previous start-line)) 'lisp-info) nil))
185      (when (line-next end-line)
186        (setf (getf (line-plist (line-next end-line)) 'lisp-info) nil))
187     
188      (loop
189       (let ((line-info (getf (line-plist test-line) 'lisp-info)))
190         
191         ;;    Reparse the line when any of the following are true:
192         ;;
193         ;;      FER-SURE-PARSE is T
194         ;;
195         ;;      LINE-INFO or PREV-LINE-INFO are Nil.
196         ;;
197         ;;      If the line begins quoted and the previous one wasn't
198         ;;      ended quoted.
199         ;;
200         ;;      The Line's signature slot is invalid (the line has changed).
201         ;;
202         
203         (when (or fer-sure-parse     
204                   (not line-info)
205                   (not (eq (lisp-info-begins-quoted line-info)
206                            (let ((prev (and prev-line-info (lisp-info-ending-quoted prev-line-info))))
207                              (and (not (eq prev :char-quote)) prev))))
208                   (not (eql (line-signature test-line)
209                             (lisp-info-signature-slot line-info))))
210
211           (move-to-position mark 0 test-line)
212           
213           (unless line-info
214             (setf line-info (make-lisp-info))
215             (setf (getf (line-plist test-line) 'lisp-info) line-info))
216           
217           (parse-lisp-line-info mark line-info prev-line-info))
218         
219         (when (eq end-line test-line)
220           (return nil))
221         
222         (setq prev-line-info line-info)
223         
224         (setq test-line (line-next test-line)))))))
225
226
227;;;; Parse block finders.
228
229
230(defun start-of-parse-block (mark)
231  (buffer-start mark))
232
233(defun end-of-parse-block (mark)
234  (buffer-end mark))
235
236;;;
237;;; START-OF-SEARCH-LINE
238
239(defun start-of-search-line (line)
240  "Set LINE to the begining line of the block of text to parse."
241  (with-mark ((mark (mark line 0)))
242    (funcall (value 'Parse-Start-Function) mark)
243    (setq line (mark-line mark))))
244
245;;;
246;;; END-OF-SEACH-LINE
247
248(defun end-of-search-line (line)
249  "Set LINE to the ending line of the block of text to parse."
250  (with-mark ((mark (mark line 0)))
251    (funcall (value 'Parse-End-Function) mark)
252    (setq line (mark-line mark))))
253
254
255;;;; PARSE-LISP-LINE-INFO.
256
257;;; PARSE-LISP-LINE-INFO -- Internal.
258;;;
259;;; This parses through the line doing the following things:
260;;;
261;;;      Counting/Setting the NET-OPEN-PARENS & NET-CLOSE-PARENS.
262;;;
263;;;      Making all areas of the line that should be invalid (comments,
264;;;      char-quotes, and the inside of strings) and such be in
265;;;      RANGES-TO-IGNORE.
266;;;
267;;;      Set BEGINS-QUOTED and ENDING-QUOTED
268;;;
269(defun parse-lisp-line-info (mark line-info prev-line-info)
270  "Parse line and set line information like NET-OPEN-PARENS, NET-CLOSE-PARENS,
271   RANGES-TO-INGORE, and ENDING-QUOTED."
272  (let ((net-open-parens 0)
273        (net-close-parens 0))
274    (declare (fixnum net-open-parens net-close-parens))
275
276    ;; Re-set the slots necessary
277
278    (setf (lisp-info-ranges-to-ignore line-info) nil)
279
280    (setf (lisp-info-ending-quoted line-info) nil)
281
282    ;; The only way the current line begins quoted is when there
283    ;; is a previous line and it's ending was quoted.
284   
285    (setf (lisp-info-begins-quoted line-info)
286          (and prev-line-info 
287               (let ((prev (lisp-info-ending-quoted prev-line-info)))
288                 (and (not (eq prev :char-quote)) prev))))
289
290    (assert (eq (hi::mark-buffer mark) (current-buffer)))
291
292    (when (lisp-info-begins-quoted line-info)
293      (deal-with-quote (lisp-info-begins-quoted line-info) mark line-info))
294
295    (unless (lisp-info-ending-quoted line-info)
296      (loop 
297
298        (unless (find-lisp-char mark)
299          (error "Expected at least a newline!"))
300        (case (character-attribute :lisp-syntax (next-character mark))
301         
302          (:open-paren
303           (setq net-open-parens (1+ net-open-parens))
304           (mark-after mark))
305         
306          (:close-paren
307           (if (zerop net-open-parens)
308               (setq net-close-parens (1+ net-close-parens))
309               (setq net-open-parens (1- net-open-parens)))
310           (mark-after mark))
311         
312          (:newline
313           (setf (lisp-info-ending-quoted line-info) nil)
314           (return t))
315         
316          (:comment
317           (push-range (cons (mark-charpos mark) (line-length (mark-line mark)))
318                       line-info)
319           (setf (lisp-info-ending-quoted line-info) nil)
320           (return t))
321         
322          (:char-quote
323           (mark-after mark)
324           (let* ((charpos (mark-charpos mark))
325                  (nextpos (1+ charpos))
326                  (linelen (line-length (mark-line mark))))
327             (when (< linelen nextpos)
328               (setf (lisp-info-ending-quoted line-info) :char-quote)
329               (return t))
330             (push-range (cons charpos nextpos) line-info)
331             (mark-after mark)))
332
333          (:prefix-dispatch
334           (mark-after mark)
335           (when (test-char (next-character mark) :lisp-syntax :symbol-quote)
336             (mark-after mark)
337             (unless (deal-with-quote 1 mark line-info (- (mark-charpos mark) 2))
338               (return t))))
339
340          (:symbol-quote
341           (mark-after mark)
342           (unless (deal-with-quote :symbol-quote mark line-info)
343             (return t)))
344
345          (:string-quote
346           (mark-after mark)
347           (unless (deal-with-quote :string-quote mark line-info)
348             (return t)))
349
350          (t (ERROR "character attribute of: ~s is ~s, at ~s"
351                    (next-character mark)
352                    (character-attribute :lisp-syntax (next-character mark))
353                    mark)))))
354    (setf (lisp-info-net-open-parens line-info) net-open-parens)
355    (setf (lisp-info-net-close-parens line-info) net-close-parens)
356    (setf (lisp-info-signature-slot line-info) 
357          (line-signature (mark-line mark)))))
358
359
360
361;;;; String/symbol quote utilities.
362
363;;; VALID-QUOTE-P
364;;;
365(defmacro valid-quote-p (quote mark forwardp)
366  "Return T if the string-quote indicated by MARK is valid."
367  `(and (eq (character-attribute :lisp-syntax (direction-char ,mark ,forwardp)) ,quote)
368        (not (char-quoted-at-mark-p ,mark ,forwardp))))
369
370(defun char-quoted-at-mark-p (mark forwardp)
371  (unless forwardp
372    (unless (mark-before mark)
373      (return-from char-quoted-at-mark-p nil)))
374  (loop for count upfrom 0
375    do (unless (test-char (previous-character mark) :lisp-syntax :char-quote)
376         (character-offset mark count) ;; go back to where started
377         (unless forwardp
378           (mark-after mark))
379         (return (oddp count)))
380    do (mark-before mark)))
381
382;;;
383;;; FIND-VALID-QUOTE
384
385(defmacro find-valid-quote (quote mark &key forwardp (cease-at-eol nil))
386  "Expand to a form that will leave MARK before a valid string-quote character,
387  in either a forward or backward direction, according to FORWARDP.  If
388  CEASE-AT-EOL is T then it will return nil if encountering the EOL before a
389  valid string-quote."
390  (let ((e-mark (gensym))
391        (pred (gensym)))
392    `(with-mark ((,e-mark ,mark))
393       (let ((,pred ,(if cease-at-eol
394                       `#'(lambda (x) (or (eq x :newline) (eq x ,quote)))
395                       `#'(lambda (x) (eq x ,quote)))))
396
397         (loop
398           (unless (,(if forwardp 'find-attribute 'reverse-find-attribute)
399                    ,e-mark :lisp-syntax ,pred)
400             (return nil))
401
402        ,@(if cease-at-eol
403              `((when (test-char (direction-char ,e-mark ,forwardp) :lisp-syntax
404                                 :newline)
405                  (return nil))))
406       
407        (when (valid-quote-p ,quote ,e-mark ,forwardp)
408          (move-mark ,mark ,e-mark)
409          (return t))
410       
411        (neighbor-mark ,e-mark ,forwardp))))))
412
413;;; DEAL-WITH-QUOTE
414;;;
415;;; Called when a quoted area is begun (i.e. parse hits a #\" or #\|).  It checks for a
416;;; matching quote on the line that MARK points to, and puts the appropriate
417;;; area in the RANGES-TO-IGNORE slot and leaves MARK pointing after this area.
418;;; The "appropriate area" is from MARK to the end of the line or the matching
419;;; string-quote, whichever comes first.
420;;;
421
422(defun deal-with-quote (quote mark info-struct &optional (start (mark-charpos mark)))
423  "Alter the current line's info struct as necessary as due to encountering a
424  string or symbol quote character."
425  (if (fixnump quote) ;; nesting multi-line comments
426    (loop
427      (unless (and (scan-char mark :lisp-syntax (or :newline :symbol-quote))
428                   (test-char (next-character mark) :lisp-syntax :symbol-quote))
429        (line-end mark)
430        (push-range (cons start (mark-charpos mark)) info-struct)
431        (setf (lisp-info-ending-quoted info-struct) quote)
432        (return nil))
433      (if (prog1 (test-char (previous-character mark) :lisp-syntax :prefix-dispatch) (mark-after mark))
434        (incf quote)
435        (when (test-char (next-character mark) :lisp-syntax :prefix-dispatch)
436          (mark-after mark)
437          (decf quote)
438          (when (<= quote 0)
439            (push-range (cons start (mark-charpos mark)) info-struct)
440            (setf (lisp-info-ending-quoted info-struct) nil)
441            (return mark)))))
442    (cond ((find-valid-quote quote mark :forwardp t :cease-at-eol t)
443           ;; If matching quote is on this line then mark the area between the
444           ;; first quote (MARK) and the matching quote as invalid by pushing
445           ;; its begining and ending into the IGNORE-RANGE.
446           (push-range (cons start (mark-charpos mark)) info-struct)
447           (mark-after mark))
448          ;; If the EOL has been hit before the matching quote then mark the
449          ;; area from MARK to the EOL as invalid.
450          (t
451           (line-end mark)
452           (push-range (cons start (mark-charpos mark)) info-struct)
453           ;; The Ending is marked as still being quoted.
454           (setf (lisp-info-ending-quoted info-struct) quote)
455           nil))))
456
457;;;; Character validity checking:
458
459;;; Find-Ignore-Region  --  Internal
460;;;
461;;;    If the character in the specified direction from Mark is in an ignore
462;;; region, then return the region and the line that the region is in as
463;;; values.  If there is no ignore region, then return NIL and the Mark-Line.
464;;; If the line is not parsed, or there is no character (because of being at
465;;; the buffer beginning or end), then return both values NIL.
466;;;
467(defun find-ignore-region (mark forwardp)
468  (flet ((scan (line pos)
469           (declare (fixnum pos))
470           (let ((info (getf (line-plist line) 'lisp-info)))
471             (if info
472                 (dolist (range (lisp-info-ranges-to-ignore info)
473                                (values nil line))
474                   (let ((start (car range))
475                         (end (cdr range)))
476                     (declare (fixnum start end))
477                     (when (and (>= pos start) (< pos end))
478                       (return (values range line)))))
479                 (values nil nil)))))
480    (let ((pos (mark-charpos mark))
481          (line (mark-line mark)))
482      (declare (fixnum pos))
483      (cond (forwardp (scan line pos))
484            ((> pos 0) (scan line (1- pos)))
485            (t
486             (let ((prev (line-previous line)))
487               (if prev
488                   (scan prev (line-length prev))
489                   (values nil nil))))))))
490
491
492;;; Valid-Spot  --  Public
493;;;
494(defun valid-spot (mark forwardp)
495  "Return true if the character pointed to by Mark is not in a quoted context,
496  false otherwise.  If Forwardp is true, we use the next character, otherwise
497  we use the previous."
498  (if (and (not forwardp)
499           (null (previous-character mark)))
500    t                         ;beginning of buffer always a valid spot
501    (multiple-value-bind (region line)
502        (find-ignore-region mark forwardp)
503      (and line (not region)))))
504
505;;; Scan-Direction-Valid  --  Internal
506;;;
507;;;    Like scan-direction, but only stop on valid characters.
508;;;
509(defmacro scan-direction-valid (mark forwardp &rest forms)
510  (let ((n-mark (gensym))
511        (n-line (gensym))
512        (n-region (gensym))
513        (n-won (gensym)))
514    `(let ((,n-mark ,mark) (,n-won nil))
515       (loop
516         (multiple-value-bind (,n-region ,n-line)
517                              (find-ignore-region ,n-mark ,forwardp)
518           (unless ,n-line (return nil))
519           (if ,n-region
520               (move-to-position ,n-mark
521                                 ,(if forwardp
522                                      `(cdr ,n-region) 
523                                      `(car ,n-region))
524                                 ,n-line)
525               (when ,n-won (return t)))
526           ;;
527           ;; Peculiar condition when a quoting character terminates a line.
528           ;; The ignore region is off the end of the line causing %FORM-OFFSET
529           ;; to infinitely loop.
530           (when (> (mark-charpos ,n-mark) (line-length ,n-line))
531             #+gz (break "This shouldn't happen any more")
532             (line-offset ,n-mark 1 0))
533           (unless (scan-direction ,n-mark ,forwardp ,@forms)
534             (return nil))
535           (setq ,n-won t))))))
536
537
538;;;; List offseting.
539
540;;; %LIST-OFFSET allows for BACKWARD-LIST and FORWARD-LIST to be built
541;;; with the same existing structure, with the altering of one variable.
542;;; This one variable being FORWARDP.
543;;;
544(defmacro %list-offset (actual-mark forwardp &key (extra-parens 0) )
545  "Expand to code that will go forward one list either backward or forward,
546   according to the FORWARDP flag."
547  (let ((mark (gensym)))
548    `(with-mark ((,mark ,actual-mark))
549       (if (valid-spot ,mark ,forwardp)
550         (let ((paren-count ,extra-parens))
551           (declare (fixnum paren-count))
552           (loop
553             (unless (scan-direction-valid ,mark ,forwardp :lisp-syntax
554                                           (or :close-paren :open-paren :newline))
555               (return nil))
556             (let ((ch (direction-char ,mark ,forwardp)))
557               (case (character-attribute :lisp-syntax ch)
558                 (:close-paren
559                  (decf paren-count)
560                  ,(when forwardp
561                     ;; When going forward, an unmatching close-paren means the
562                     ;; end of list.
563                     `(when (<= paren-count 0)
564                        (neighbor-mark ,mark ,forwardp)
565                        (move-mark ,actual-mark ,mark)
566                        (return t))))
567                 (:open-paren
568                  (incf paren-count)
569                  ,(unless forwardp             ; Same as above only end of list
570                     `(when (>= paren-count 0)  ; is opening parens.
571                        (neighbor-mark ,mark ,forwardp)
572                        (move-mark ,actual-mark ,mark)
573                          (return t))))
574                   
575                   (:newline 
576                    ;; When a #\Newline is hit, then the matching paren must lie
577                    ;; on some other line so drop down into the multiple line
578                    ;; balancing function: QUEST-FOR-BALANCING-PAREN If no paren
579                    ;; seen yet, keep going.
580                    (cond ((zerop paren-count))
581                          ((quest-for-balancing-paren ,mark paren-count ,forwardp)
582                           (move-mark ,actual-mark ,mark)
583                           (return t))
584                          (t
585                           (return nil))))))
586             (neighbor-mark ,mark ,forwardp)))
587         ;; We're inside a comment or a string.  Try anyway.
588         (when ,(if forwardp
589                  `(%forward-list-at-mark ,mark ,extra-parens t)
590                  `(%backward-list-at-mark ,mark ,extra-parens t))
591           (move-mark ,actual-mark ,mark))))))
592
593;;;
594;;; QUEST-FOR-BALANCING-PAREN
595
596(defmacro quest-for-balancing-paren (mark paren-count forwardp)
597  "Expand to a form that finds the the balancing paren for however many opens or
598  closes are registered by Paren-Count."
599  `(let* ((line (mark-line ,mark)))
600     (loop
601       (setq line (neighbor-line line ,forwardp))
602       (unless line (return nil))
603       (let ((line-info (getf (line-plist line) 'lisp-info))
604             (unbal-paren ,paren-count))
605         (unless line-info (return nil))
606         
607         ,(if forwardp
608              `(decf ,paren-count (lisp-info-net-close-parens line-info))
609              `(incf ,paren-count (lisp-info-net-open-parens line-info)))
610         
611         (when ,(if forwardp
612                    `(<= ,paren-count 0)
613                    `(>= ,paren-count 0))
614           ,(if forwardp
615                `(line-start ,mark line)
616                `(line-end ,mark line))
617           (return (goto-correct-paren-char ,mark unbal-paren ,forwardp)))
618
619         ,(if forwardp
620              `(incf ,paren-count (lisp-info-net-open-parens line-info))
621              `(decf ,paren-count (lisp-info-net-close-parens line-info)))))))
622                   
623
624;;;
625;;; GOTO-CORRECT-PAREN-CHAR
626
627(defmacro goto-correct-paren-char (mark paren-count forwardp)
628  "Expand to a form that will leave MARK on the correct balancing paren matching
629   however many are indicated by COUNT." 
630  `(with-mark ((m ,mark))
631     (let ((count ,paren-count))
632       (loop
633         (scan-direction m ,forwardp :lisp-syntax 
634                         (or :close-paren :open-paren :newline))
635         (when (valid-spot m ,forwardp)
636           (ecase (character-attribute :lisp-syntax (direction-char m ,forwardp))
637             (:close-paren 
638              (decf count)
639              ,(when forwardp
640                 `(when (zerop count)
641                    (neighbor-mark m ,forwardp)
642                    (move-mark ,mark m)
643                    (return t))))
644             
645             (:open-paren 
646              (incf count)
647              ,(unless forwardp
648                 `(when (zerop count)
649                    (neighbor-mark m ,forwardp)
650                    (move-mark ,mark m)
651                    (return t))))))
652         (neighbor-mark m ,forwardp)))))
653
654
655(defun list-offset (mark offset)
656  (if (plusp offset)
657      (dotimes (i offset t)
658        (unless (%list-offset mark t) (return nil)))
659      (dotimes (i (- offset) t)
660        (unless (%list-offset mark nil) (return nil)))))
661
662(defun forward-up-list (mark)
663  "Moves mark just past the closing paren of the immediately containing list."
664  (%list-offset mark t :extra-parens 1))
665
666(defun backward-up-list (mark)
667  "Moves mark just before the opening paren of the immediately containing list."
668  (%list-offset mark nil :extra-parens -1))
669
670
671
672;;;; Top level form location hacks (open parens beginning lines).
673
674;;; NEIGHBOR-TOP-LEVEL is used only in TOP-LEVEL-OFFSET.
675;;;
676(eval-when (:compile-toplevel :execute)
677(defmacro neighbor-top-level (line forwardp)
678  `(loop
679     (when (test-char (line-character ,line 0) :lisp-syntax :open-paren)
680       (return t))
681     (setf ,line ,(if forwardp `(line-next ,line) `(line-previous ,line)))
682     (unless ,line (return nil))))
683) ;eval-when
684
685(defun top-level-offset (mark offset)
686  "Go forward or backward offset number of top level forms.  Mark is
687   returned if offset forms exists, otherwise nil."
688  (declare (fixnum offset))
689  (let* ((line (mark-line mark))
690         (at-start (test-char (line-character line 0) :lisp-syntax :open-paren)))
691    (cond ((zerop offset) mark)
692          ((plusp offset)
693           (do ((offset (if at-start offset (1- offset))
694                        (1- offset)))
695               (nil)
696             (declare (fixnum offset))
697             (unless (neighbor-top-level line t) (return nil))
698             (when (zerop offset) (return (line-start mark line)))
699             (unless (setf line (line-next line)) (return nil))))
700          (t
701           (do ((offset (if (and at-start (start-line-p mark))
702                            offset
703                            (1+ offset))
704                        (1+ offset)))
705                (nil)
706             (declare (fixnum offset))
707             (unless (neighbor-top-level line nil) (return nil))
708             (when (zerop offset) (return (line-start mark line)))
709             (unless (setf line (line-previous line)) (return nil)))))))
710
711
712(defun mark-top-level-form (mark1 mark2)
713  "Moves mark1 and mark2 to the beginning and end of the current or next defun.
714   Mark1 one is used as a reference.  The marks may be altered even if
715   unsuccessful.  if successful, return mark2, else nil."
716  (let ((winp (cond ((inside-defun-p mark1)
717                     (cond ((not (top-level-offset mark1 -1)) nil)
718                           ((not (form-offset (move-mark mark2 mark1) 1)) nil)
719                           (t mark2)))
720                    ((start-defun-p mark1)
721                     (form-offset (move-mark mark2 mark1) 1))
722                    ((and (top-level-offset (move-mark mark2 mark1) -1)
723                          (start-defun-p mark2)
724                          (form-offset mark2 1)
725                          (same-line-p mark1 mark2))
726                     (form-offset (move-mark mark1 mark2) -1)
727                     mark2)
728                    ((top-level-offset mark1 1)
729                     (form-offset (move-mark mark2 mark1) 1)))))
730    (when winp
731      (when (blank-after-p mark2) (line-offset mark2 1 0))
732      mark2)))
733
734(defun inside-defun-p (mark)
735  "T if the current point is (supposedly) in a top level form."
736  (with-mark ((m mark))
737    (when (top-level-offset m -1)
738      (form-offset m 1)
739      (mark> m mark))))
740
741(defun start-defun-p (mark)
742  "Returns t if mark is sitting before an :open-paren at the beginning of a
743   line."
744  (and (start-line-p mark)
745       (test-char (next-character mark) :lisp-syntax :open-paren)))
746
747;;;; Form offseting.
748
749;; Heuristic versions, for navigating inside comments, doesn't make use of line info
750
751(defun unparsed-form-offset (mark forwardp)
752  ;; TODO: if called in "invalid" spot, arrange to stay within bounds of current invalid region.
753  ;; For now, just stop at #||# boundaries, as first approximation.
754  (if forwardp
755    (forward-form mark t)
756    (backward-form mark t)))
757
758(defun forward-form (mark &optional in-comment-p)
759  ;; If in-comment-p is true, tries not to go past a |#.
760  (with-mark ((m mark))
761    (when (and (scan-char m :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
762                                             :symbol-quote :string-quote :char-quote
763                                             :comment :constituent))
764               (%forward-form-at-mark m in-comment-p))
765      (move-mark mark m))))
766
767(defun backward-form (mark &optional in-comment-p)
768  ;; If in-comment-p is true, tries not to go past a #|.
769  (with-mark ((m mark))
770    (when (%backward-form-at-mark m in-comment-p)
771      (loop while (test-char (previous-character m) :lisp-syntax :prefix) do (mark-before m))
772      (move-mark mark m))))
773
774(defun %forward-form-at-mark (mark in-comment-p)
775  ;; Warning: moves mark even if returns nil (hence the % in name).
776  (case (character-attribute :lisp-syntax (next-character mark))
777    (:open-paren
778     (mark-after mark)
779     (%forward-list-at-mark mark 1))
780    (:close-paren
781     nil)
782    (:char-quote
783     (%forward-symbol-at-mark mark in-comment-p))
784    (:symbol-quote
785     (mark-after mark)
786     (unless (and in-comment-p (test-char (next-character mark) :lisp-syntax :prefix-dispatch))
787       (mark-before mark)
788       (%forward-symbol-at-mark mark in-comment-p)))
789    (:prefix-dispatch
790     (mark-after mark)
791     (if (test-char (next-character mark) :lisp-syntax :symbol-quote)
792       (progn
793         (mark-after mark)
794         (%forward-nesting-comment-at-mark mark 1))
795       (progn
796         (mark-before mark)
797         (%forward-symbol-at-mark mark in-comment-p))))
798    (:string-quote
799     (%forward-string-at-mark mark))
800    (:constituent
801     (%forward-symbol-at-mark mark in-comment-p))
802    (:comment
803     (%forward-comments-at-mark mark))
804    (t
805     (mark-after mark)
806     (%forward-form-at-mark mark in-comment-p))))
807
808(defun %backward-form-at-mark (mark in-comment-p)
809  ;; Warning: moves mark even if returns nil (hence the % in name).
810  (let* ((char (previous-character mark))
811         (attrib (character-attribute :lisp-syntax char)))
812    (when char
813      (mark-before mark)
814      (when (char-quoted-at-mark-p mark t)
815        (setq attrib :constituent))
816      (case attrib
817        (:open-paren
818         nil)
819        (:close-paren
820         (%backward-list-at-mark mark 1))
821        (:char-quote  ;;; can only happen if starting right after an unquoted char-quote
822         (%backward-symbol-at-mark mark in-comment-p))
823        (:symbol-quote
824         (unless (and in-comment-p (test-char (previous-character mark) :lisp-syntax :prefix-dispatch))
825           (mark-after mark)
826           (%backward-symbol-at-mark mark in-comment-p)))
827        (:prefix-dispatch
828         (if (test-char (previous-character mark) :lisp-syntax :symbol-quote)
829           (progn
830             (mark-before mark)
831             (%backward-nesting-comment-at-mark mark 1))
832           (progn
833             (mark-after mark)
834             (%backward-symbol-at-mark mark in-comment-p))))
835        (:string-quote
836         (mark-after mark)
837         (%backward-string-at-mark mark))
838        (:constituent
839         (mark-after mark)
840         (%backward-symbol-at-mark mark in-comment-p))
841        (:prefix
842         (loop while (test-char (previous-character mark) :lisp-syntax :prefix) do (mark-before mark))
843         mark)
844        (:comment
845         (loop while (test-char (previous-character mark) :lisp-syntax :comment) do (mark-before mark))
846         mark)
847        ;; TODO: it would be nice to skip over ;; comments if starting outside one, i.e. if encounter a newline
848        ;; before a form starts.
849        (t (%backward-form-at-mark mark in-comment-p))))))
850
851(defun %forward-symbol-at-mark (mark in-comment-p)
852  ;; Warning: moves mark even if returns nil (hence the % in name).
853  (loop
854    (unless (scan-char mark :lisp-syntax (not (or :constituent :prefix-dispatch)))
855      (return (buffer-end mark)))
856    (case (character-attribute :lisp-syntax (next-character mark))
857      (:symbol-quote
858       (mark-after mark)
859       (when (and in-comment-p (test-char (next-character mark) :lisp-syntax :prefix-dispatch))
860         (return (mark-before mark)))
861       (unless (loop
862                 (unless (scan-char mark :lisp-syntax (or :char-quote :symbol-quote))
863                   (return nil))
864                 (when (test-char (next-character mark) :lisp-syntax :symbol-quote)
865                   (return t))
866                 (character-offset mark 2))
867         (return nil))
868       (mark-after mark))
869      (:char-quote
870       (character-offset mark 2))
871      (t (return mark)))))
872
873(defun %backward-symbol-at-mark (mark in-comment-p)
874  (loop
875    (unless (rev-scan-char mark :lisp-syntax (not (or :constituent :prefix-dispatch :char-quote)))
876      (buffer-start mark)
877      (return mark))
878    (mark-before mark)
879    (if (char-quoted-at-mark-p mark t)
880      (mark-before mark)
881      (let* ((char (next-character mark)))
882        (case (character-attribute :lisp-syntax char)
883          (:symbol-quote
884           (when (and in-comment-p (test-char (previous-character mark) :lisp-syntax :prefix-dispatch))
885             (return (mark-after mark)))
886           (unless (loop
887                     (unless (rev-scan-char mark :lisp-syntax :symbol-quote)
888                       (return nil))
889                     (mark-before mark)
890                     (unless (char-quoted-at-mark-p mark t)
891                       (return t))
892                     (mark-before mark))
893             (return nil)))
894          (t (mark-after mark)
895             (return mark)))))))
896
897(defun %forward-nesting-comment-at-mark (mark nesting)
898  ;; Warning: moves mark even if returns nil (hence the % in name).
899  (loop
900    (unless (scan-char mark :lisp-syntax :symbol-quote)
901      (return nil))
902    (let ((prev (previous-character mark)))
903      (mark-after mark)
904      (cond ((test-char prev :lisp-syntax :prefix-dispatch)
905             (incf nesting))
906            ((test-char (next-character mark) :lisp-syntax :prefix-dispatch)
907             (mark-after mark)
908             (when (<= (decf nesting) 0)
909               (return mark)))))))
910
911(defun %backward-nesting-comment-at-mark (mark nesting)
912  ;; Warning: moves mark even if returns nil (hence the % in name).
913  (loop
914    (unless (rev-scan-char mark :lisp-syntax :symbol-quote)
915      (return nil))
916    (let ((next (next-character mark)))
917      (mark-before mark)
918      (cond ((test-char next :lisp-syntax :prefix-dispatch)
919             (incf nesting))
920            ((test-char (previous-character mark) :lisp-syntax :prefix-dispatch)
921             (mark-before mark)
922             (when (<= (decf nesting) 0)
923               (return mark)))))))
924
925
926;; %FORM-OFFSET
927
928(defmacro %form-offset (mark forwardp)
929  `(if (valid-spot ,mark ,forwardp)
930     (with-mark ((m ,mark))
931       (when (scan-direction-valid m ,forwardp :lisp-syntax
932                                   (or :open-paren :close-paren
933                                       :char-quote :string-quote :symbol-quote
934                                       :prefix-dispatch :constituent))
935         (ecase (character-attribute :lisp-syntax (direction-char m ,forwardp))
936           (:open-paren
937            (when ,(if forwardp `(list-offset m 1) `(mark-before m))
938              ,(unless forwardp
939                 '(scan-direction m nil :lisp-syntax (not :prefix)))
940              (move-mark ,mark m)
941              t))
942           (:close-paren
943            (when ,(if forwardp `(mark-after m) `(list-offset m -1))
944              ,(unless forwardp
945                 '(scan-direction m nil :lisp-syntax (not :prefix)))
946              (move-mark ,mark m)
947              t))
948           ((:constituent :char-quote :symbol-quote :prefix-dispatch)
949            ,(if forwardp
950               `(scan-direction-valid m t :lisp-syntax
951                                      (not (or :constituent :char-quote :symbol-quote :prefix-dispatch)))
952               `(scan-direction-valid m nil :lisp-syntax
953                                      (not (or :constituent :char-quote :symbol-quote :prefix-dispatch
954                                               :prefix))))
955            (move-mark ,mark m)
956            t)
957           (:string-quote
958            (neighbor-mark m ,forwardp)
959            (when (scan-direction-valid m ,forwardp :lisp-syntax
960                                        :string-quote)
961              (neighbor-mark m ,forwardp)
962              (move-mark ,mark m)
963              t)))))
964     ;; Inside a comment or a string.  Switch to heuristic method.
965     (unparsed-form-offset ,mark ,forwardp)))
966
967(defun %forward-list-at-mark (mark nesting &optional in-comment-p)
968  ;; Warning: moves mark even if returns nil (hence the % in name).
969  (loop
970    (unless (scan-char mark :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
971                                             :symbol-quote :string-quote :char-quote :comment))
972      (return nil))
973    (case (character-attribute :lisp-syntax (next-character mark))
974      (:open-paren
975       (mark-after mark)
976       (incf nesting))
977      (:close-paren
978       (mark-after mark)
979       (when (<= (decf nesting) 0)
980         (return (and (eql nesting 0) mark))))
981      (t
982       (unless (%forward-form-at-mark mark in-comment-p)
983         (return nil))))))
984
985(defun %backward-list-at-mark (mark nesting &optional in-comment-p)
986  ;; Warning: moves mark even if returns nil (hence the % in name).
987  (loop
988    (unless (rev-scan-char mark :lisp-syntax (or :open-paren :close-paren :prefix-dispatch
989                                                 :symbol-quote :string-quote :comment))
990      (return nil))
991    (mark-before mark)
992    (if (char-quoted-at-mark-p mark t)
993      (mark-before mark)
994      (case (character-attribute :lisp-syntax (next-character mark))
995        (:close-paren
996         (incf nesting))
997        (:open-paren
998         (when (<= (decf nesting) 0)
999           (return mark)))
1000        (t
1001         (mark-after mark)
1002         (unless (%backward-form-at-mark mark in-comment-p)
1003           (return nil)))))))
1004
1005(defun %forward-string-at-mark (mark)
1006  ;; Warning: moves mark even if returns nil (hence the % in name).
1007  (mark-after mark)
1008  (loop
1009    (unless (scan-char mark :lisp-syntax (or :char-quote :string-quote))
1010      (return nil))
1011    (unless (test-char (next-character mark) :lisp-syntax :char-quote)
1012      (return (mark-after mark)))
1013    (character-offset mark 2)))
1014
1015
1016(defun %backward-string-at-mark (mark)
1017  ;; Warning: moves mark even if returns nil (hence the % in name).
1018  (mark-before mark)
1019  (loop
1020    (unless (rev-scan-char mark :lisp-syntax :string-quote)
1021      (return nil))
1022    (mark-before mark)
1023    (unless (char-quoted-at-mark-p mark t)
1024      (return mark))
1025    (mark-before mark)))
1026
1027(defun %forward-comments-at-mark (mark)
1028  ;; Warning: moves mark even if returns nil (hence the % in name).
1029  (with-mark ((m mark))
1030    (loop
1031      (line-end m)
1032      (mark-after m)
1033      (move-mark mark m)
1034      (unless (and (scan-char m :lisp-syntax (not :space))
1035                   (test-char (next-character m) :lisp-syntax :comment))
1036        (return mark)))))
1037
1038(defun form-offset (mark offset)
1039  "Move mark offset number of forms, after if positive, before if negative.
1040   Mark is always moved.  If there weren't enough forms, returns nil instead of
1041   mark."
1042  (if (plusp offset)
1043      (dotimes (i offset t)
1044        (unless (%form-offset mark t) (return nil)))
1045      (dotimes (i (- offset) t)
1046        (unless (%form-offset mark nil) (return nil)))))
1047
1048;; Return region for the "current form" at mark.
1049;; TODO: See also mark-nearest-form, should merge them
1050(defun form-region-at-mark (mark)
1051  (with-mark ((bwd-start mark)
1052              (bwd-end mark)
1053              (fwd-start mark)
1054              (fwd-end mark))
1055    (let* ((fwd (and (or (and (char-quoted-at-mark-p mark t)       ;; back-up so get whole character
1056                              (mark-before fwd-end))
1057                         (test-char (next-character mark) :lisp-syntax
1058                                    (or :open-paren :string-quote
1059                                        :char-quote :symbol-quote :constituent :prefix-dispatch
1060                                        :prefix)))
1061                     (form-offset fwd-end 1)
1062                     (form-offset (move-mark fwd-start fwd-end) -1)
1063                     (mark<= fwd-start mark)))
1064           (bwd (and (or (char-quoted-at-mark-p mark nil)
1065                         (test-char (previous-character mark) :lisp-syntax
1066                                    (or :close-paren :string-quote
1067                                        :char-quote :symbol-quote :constituent :prefix-dispatch)))
1068                     ;; Special case - if at an open paren, always select forward because that's
1069                     ;; the matching paren that's highlighted.
1070                     (not (and fwd (test-char (next-character mark) :lisp-syntax :open-paren)))
1071                     ;; Also prefer string over anything but close paren.
1072                     (not (and fwd (test-char (next-character mark) :lisp-syntax :string-quote)
1073                               (not (test-char (previous-character mark) :lisp-syntax :close-paren))))
1074                     (form-offset bwd-start -1)
1075                     (form-offset (move-mark bwd-end bwd-start) 1)
1076                     (mark<= mark bwd-end))))
1077      (if bwd
1078        (when (or (not fwd) ;; back is only option
1079                  (and (mark= bwd-start fwd-start) (mark= bwd-end fwd-end)) ;; or they're the same
1080                  (and (mark= bwd-start fwd-end)  ;; or had to skip prefix chars to get to forward
1081                       (test-char (next-character fwd-start) :lisp-syntax (or :prefix :prefix-dispatch))))
1082          (region bwd-start bwd-end))
1083        (if fwd
1084          (region fwd-start fwd-end))))))
1085
1086;;;; Table of special forms with special indenting requirements.
1087
1088(defhvar "Indent Defanything"
1089  "This is the number of special arguments implicitly assumed to be supplied
1090   in calls to functions whose names begin with \"DEF\".  If set to NIL, this
1091   feature is disabled."
1092  :value 2)
1093
1094(defhvar "Indent With-anything"
1095  "This is the number of special arguments implicitly assumed to be supplied
1096   in calls to functions whose names begin with \"WITH-\". If set to NIL, this
1097   feature is disabled."
1098  :value 1)
1099
1100(defvar *special-forms* (make-hash-table :test #'equal))
1101
1102(defun defindent (fname args)
1103  "Define Fname to have Args special arguments.  If args is null then remove
1104   any special arguments information."
1105  (check-type fname string)
1106  (let ((fname (string-upcase fname)))
1107    (cond ((null args) (remhash fname *special-forms*))
1108          (t
1109           (check-type args integer)
1110           (setf (gethash fname *special-forms*) args)))))
1111
1112
1113;;; Hemlock forms.
1114;;;
1115(defindent "defhvar" 1)
1116(defindent "hlet" 1)
1117(defindent "defcommand" 2)
1118(defindent "defattribute" 1)
1119(defindent "command-case" 1)
1120(defindent "do-strings" 1)
1121(defindent "save-for-undo" 1)
1122(defindent "do-alpha-chars" 1)
1123(defindent "do-headers-buffers" 1)
1124(defindent "do-headers-lines" 1)
1125(defindent "frob" 1) ;cover silly FLET and MACROLET names for Rob and Bill.
1126(defindent "modifying-buffer" 1)
1127
1128;;; Common Lisp forms.
1129;;;
1130(defindent "block" 1)
1131(defindent "case" 1)
1132(defindent "catch" 1)
1133(defindent "ccase" 1)                     
1134(defindent "compiler-let" 1)
1135(defindent "ctypecase" 1)
1136(defindent "defconstant" 1)
1137(defindent "define-compiler-macro" 2)
1138(defindent "define-setf-method" 2)
1139(defindent "destructuring-bind" 2)
1140(defindent "defmacro" 2)
1141(defindent "defpackage" 1)
1142(defindent "defparameter" 1)
1143(defindent "defstruct" 1)
1144(defindent "deftype" 2)
1145(defindent "defun" 2)
1146(defindent "defvar" 1)
1147(defindent "do" 2)
1148(defindent "do*" 2)
1149(defindent "do-all-symbols" 1)
1150(defindent "do-external-symbols" 1)
1151(defindent "do-symbols" 1)
1152(defindent "dolist" 1)
1153(defindent "dotimes" 1)
1154(defindent "ecase" 1)
1155(defindent "etypecase" 1)
1156(defindent "eval-when" 1)
1157(defindent "flet" 1)
1158(defindent "if" 1)
1159(defindent "labels" 1)
1160(defindent "lambda" 1)
1161(defindent "let" 1)
1162(defindent "let*" 1)
1163(defindent "locally" 0)
1164(defindent "loop" 0)
1165(defindent "macrolet" 1)
1166(defindent "multiple-value-bind" 2)
1167(defindent "multiple-value-call" 1)
1168(defindent "multiple-value-prog1" 1)
1169(defindent "multiple-value-setq" 1)
1170(defindent "prog" 1)
1171(defindent "prog*" 1)
1172(defindent "prog1" 1)
1173(defindent "progv" 2)
1174(defindent "progn" 0)
1175(defindent "typecase" 1)
1176(defindent "unless" 1)
1177(defindent "unwind-protect" 1)
1178(defindent "when" 1)
1179
1180;;; Error/condition system forms.
1181;;;
1182(defindent "define-condition" 2)
1183(defindent "handler-bind" 1)
1184(defindent "handler-case" 1)
1185(defindent "restart-bind" 1)
1186(defindent "restart-case" 1)
1187;;; These are for RESTART-CASE branch formatting.
1188(defindent "store-value" 1)
1189(defindent "use-value" 1)
1190(defindent "muffle-warning" 1)
1191(defindent "abort" 1)
1192(defindent "continue" 1)
1193
1194;;; Debug-internals forms.
1195;;;
1196(defindent "do-debug-function-blocks" 1)
1197(defindent "di:do-debug-function-blocks" 1)
1198(defindent "do-debug-function-variables" 1)
1199(defindent "di:do-debug-function-variables" 1)
1200(defindent "do-debug-block-locations" 1)
1201(defindent "di:do-debug-block-locations" 1)
1202;;;
1203;;; Debug-internals conditions
1204;;; (define these to make uses of HANDLER-CASE indent branches correctly.)
1205;;;
1206(defindent "debug-condition" 1)
1207(defindent "di:debug-condition" 1)
1208(defindent "no-debug-info" 1)
1209(defindent "di:no-debug-info" 1)
1210(defindent "no-debug-function-returns" 1)
1211(defindent "di:no-debug-function-returns" 1)
1212(defindent "no-debug-blocks" 1)
1213(defindent "di:no-debug-blocks" 1)
1214(defindent "lambda-list-unavailable" 1)
1215(defindent "di:lambda-list-unavailable" 1)
1216(defindent "no-debug-variables" 1)
1217(defindent "di:no-debug-variables" 1)
1218(defindent "invalid-value" 1)
1219(defindent "di:invalid-value" 1)
1220(defindent "ambiguous-variable-name" 1)
1221(defindent "di:ambiguous-variable-name" 1)
1222(defindent "debug-error" 1)
1223(defindent "di:debug-error" 1)
1224(defindent "unhandled-condition" 1)
1225(defindent "di:unhandled-condition" 1)
1226(defindent "unknown-code-location" 1)
1227(defindent "di:unknown-code-location" 1)
1228(defindent "unknown-debug-variable" 1)
1229(defindent "di:unknown-debug-variable" 1)
1230(defindent "invalid-control-stack-pointer" 1)
1231(defindent "di:invalid-control-stack-pointer" 1)
1232(defindent "frame-function-mismatch" 1)
1233(defindent "di:frame-function-mismatch" 1)
1234
1235
1236;;; CLOS forms.
1237;;;
1238(defindent "with-accessors" 2)
1239(defindent "defclass" 2)
1240(defindent "print-unreadable-object" 1)
1241(defindent "defmethod" 2)
1242(defindent "make-instance" 1)
1243
1244;;; System forms.
1245;;;
1246(defindent "rlet" 1)
1247
1248;;; Multiprocessing forms.
1249(defindent "process-wait" 1)
1250
1251
1252
1253;;;; Indentation.
1254
1255;;; LISP-INDENTATION -- Internal Interface.
1256
1257(defun strip-package-prefix (string)
1258  (let* ((p (position #\: string :from-end t)))
1259    (if p
1260      (subseq string (1+ p))
1261      string)))
1262;;;
1263(defun lisp-indentation (mark)
1264  "Compute number of spaces which mark should be indented according to
1265   local context and lisp grinding conventions.  This assumes mark is at the
1266   beginning of the line to be indented."
1267  (with-mark ((m mark)
1268              (temp mark))
1269    ;; See if we are in a quoted context.
1270    (unless (valid-spot m nil)
1271      (return-from lisp-indentation (lisp-generic-indentation m)))
1272    ;; Look for the paren that opens the containing form.
1273    (unless (backward-up-list m)
1274      (return-from lisp-indentation 0))
1275    ;; Move after the paren, save the start, and find the form name.
1276    (mark-after m)
1277    (with-mark ((start m))
1278      (unless (and (scan-char m :lisp-syntax
1279                              (not (or :space :prefix :prefix-dispatch :char-quote)))
1280                   (test-char (next-character m) :lisp-syntax :constituent))
1281        (return-from lisp-indentation (mark-column start)))
1282      (with-mark ((fstart m))
1283        (scan-char m :lisp-syntax (not :constituent))
1284        (let* ((fname (nstring-upcase
1285                       (strip-package-prefix (region-to-string (region fstart m)))))
1286               (special-args (or (gethash fname *special-forms*)
1287                                 (and (> (length fname) 2)
1288                                      (string= fname "DEF" :end1 3)
1289                                      (value indent-defanything))
1290                                 (and (> (length fname) 4)
1291                                      (string= fname "WITH-" :end1 5)
1292                                      (value indent-with-anything)))))
1293          (declare (simple-string fname))
1294          ;; Now that we have the form name, did it have special syntax?
1295          (cond (special-args
1296                 (with-mark ((spec m))
1297                   (cond ((and (form-offset spec special-args)
1298                               (mark<= spec mark))
1299                          (1+ (mark-column start)))
1300                         ((skip-valid-space m)
1301                          (mark-column m))
1302                         (t
1303                          (+ (mark-column start) 3)))))
1304                ;; See if the user seems to have altered the editor's
1305                ;; indentation, and if so, try to adhere to it.  This usually
1306                ;; happens when you type in a quoted list constant that line
1307                ;; wraps.  You want all the items on successive lines to fall
1308                ;; under the first character after the opening paren, not as if
1309                ;; you are calling a function.
1310                ((and (form-offset temp -1)
1311                      (or (blank-before-p temp) (not (same-line-p temp fstart)))
1312                      (not (same-line-p temp mark)))
1313                 (unless (blank-before-p temp)
1314                   (line-start temp)
1315                   (find-attribute temp :space #'zerop))
1316                 (mark-column temp))
1317                ;; Appears to be a normal form.  Is the first arg on the same
1318                ;; line as the form name?
1319                ((skip-valid-space m)
1320                 (or (lisp-indentation-check-for-local-def
1321                      mark temp fstart start t)
1322                     (mark-column m)))
1323                ;; Okay, fall under the first character after the opening paren.
1324                (t
1325                 (or (lisp-indentation-check-for-local-def
1326                      mark temp fstart start nil)
1327                     (mark-column start)))))))))
1328
1329(defhvar "Lisp Indentation Local Definers"
1330  "Forms with syntax like LABELS, MACROLET, etc."
1331  :value '("LABELS" "MACROLET" "FLET"))
1332
1333;;; LISP-INDENTATION-CHECK-FOR-LOCAL-DEF -- Internal.
1334;;;
1335;;; This is a temporary hack to see how it performs.  When we are indenting
1336;;; what appears to be a function call, let's look for FLET or MACROLET to see
1337;;; if we really are indenting a local definition.  If we are, return the
1338;;; indentation for a DEFUN; otherwise, nil
1339;;;
1340;;; Mark is the argument to LISP-INDENTATION.  Start is just inside the paren
1341;;; of what looks like a function call.  If we are in an FLET, arg-list
1342;;; indicates whether the local function's arg-list has been entered, that is,
1343;;; whether we need to normally indent for a DEFUN body or indent specially for
1344;;; the arg-list.
1345;;;
1346(defun lisp-indentation-check-for-local-def (mark temp1 temp2 start arg-list)
1347  ;; We know this succeeds from LISP-INDENTATION.
1348  (backward-up-list (move-mark temp1 mark)) ;Paren for local definition.
1349  (cond ((and (backward-up-list temp1)      ;Paren opening the list of defs
1350              (form-offset (move-mark temp2 temp1) -1)
1351              (mark-before temp2)
1352              (backward-up-list temp1)      ;Paren for FLET or MACROLET.
1353              (mark= temp1 temp2))          ;Must be in first arg form.
1354         ;; See if the containing form is named FLET or MACROLET.
1355         (mark-after temp1)
1356         (unless (and (scan-char temp1 :lisp-syntax
1357                                 (not (or :space :prefix :prefix-dispatch :char-quote)))
1358                      (test-char (next-character temp1) :lisp-syntax
1359                                 :constituent))
1360           (return-from lisp-indentation-check-for-local-def nil))
1361         (move-mark temp2 temp1)
1362         (scan-char temp2 :lisp-syntax (not :constituent))
1363         (let ((fname (nstring-upcase (region-to-string (region temp1 temp2)))))
1364           (cond ((not (member fname (value lisp-indentation-local-definers)
1365                               :test #'string=))
1366                  nil)
1367                 (arg-list
1368                  (1+ (mark-column start)))
1369                 (t
1370                  (+ (mark-column start) 3)))))))
1371
1372;;; LISP-GENERIC-INDENTATION -- Internal.
1373;;;
1374;;; LISP-INDENTATION calls this when mark is in a invalid spot, or quoted
1375;;; context.  If we are inside a string, we return the column one greater
1376;;; than the opening double quote.  Otherwise, we just use the indentation
1377;;; of the first preceding non-blank line.
1378;;;
1379(defun lisp-generic-indentation (mark)
1380  (with-mark ((m mark))
1381    (form-offset m -1)
1382    (cond ((eq (character-attribute :lisp-syntax (next-character m))
1383               :string-quote)
1384           (1+ (mark-column m)))
1385          (t
1386           (let* ((line (mark-line mark))
1387                  (prev (do ((line (line-previous line) (line-previous line)))
1388                            ((not (and line (blank-line-p line))) line))))
1389             (cond (prev
1390                    (line-start mark prev)
1391                    (find-attribute mark :space #'zerop)
1392                    (mark-column mark))
1393                   (t 0)))))))
1394
1395;;; Skip-Valid-Space  --  Internal
1396;;;
1397;;;    Skip over any space on the line Mark is on, stopping at the first valid
1398;;; non-space character.  If there is none on the line, return nil.
1399;;;
1400(defun skip-valid-space (mark)
1401  (loop
1402    (scan-char mark :lisp-syntax (not :space))
1403    (let ((val (character-attribute :lisp-syntax
1404                                    (next-character mark))))
1405      (cond ((eq val :newline) (return nil))
1406            ((valid-spot mark t) (return mark))))
1407    (mark-after mark)))
1408
1409;; (declaim (optimize (speed 0))); byte compile again
1410
1411
1412;;;; Indentation commands and hook functions.
1413
1414(defcommand "Defindent" (p)
1415  "Define the Lisp indentation for the current function.
1416  The indentation is a non-negative integer which is the number
1417  of special arguments for the form.  Examples: 2 for Do, 1 for Dolist.
1418  If a prefix argument is supplied, then delete the indentation information."
1419  "Do a defindent, man!"
1420  (with-mark ((m (current-point)))
1421    (pre-command-parse-check m)
1422    (unless (backward-up-list m) (editor-error))
1423    (mark-after m)
1424    (with-mark ((n m))
1425      (scan-char n :lisp-syntax (not :constituent))
1426      (let ((s (region-to-string (region m n))))
1427        (declare (simple-string s))
1428        (when (zerop (length s)) (editor-error))
1429        (if p
1430            (defindent s nil)
1431            (let ((i (prompt-for-integer
1432                      :prompt (format nil "Indentation for ~A: " s)
1433                      :help "Number of special arguments.")))
1434              (when (minusp i)
1435                (editor-error "Indentation must be non-negative."))
1436              (defindent s i))))))
1437  (indent-command nil))
1438
1439(defcommand "Indent Form" (p)
1440  "Indent Lisp code in the next form."
1441  "Indent Lisp code in the next form."
1442  (declare (ignore p))
1443  (let ((point (current-point)))
1444    (pre-command-parse-check point)
1445    (with-mark ((m point))
1446      (unless (form-offset m 1) (editor-error))
1447      (lisp-indent-region (region point m) "Indent Form"))))
1448
1449;;; LISP-INDENT-REGION -- Internal.
1450;;;
1451;;; This indents a region of Lisp code without doing excessive redundant
1452;;; computation.  We parse the entire region once, then scan through doing
1453;;; indentation on each line.  We forcibly reparse each line that we indent so
1454;;; that the list operations done to determine indentation of subsequent lines
1455;;; will work.  This is done undoably with save1, save2, buf-region, and
1456;;; undo-region.
1457;;;
1458(defun lisp-indent-region (region &optional (undo-text "Lisp region indenting"))
1459  (let* ((start (region-start region))
1460         (end (region-end region))
1461         (buffer (hi::line-%buffer (mark-line start))))
1462    (with-mark ((m1 start)
1463                (m2 end))
1464      (funcall (value parse-start-function) m1)
1465      (funcall (value parse-end-function) m2)
1466      (parse-over-block (mark-line m1) (mark-line m2)))
1467    (hi::check-buffer-modification buffer start)
1468    (hi::check-buffer-modification buffer end)
1469    (let* ((first-line (mark-line start))
1470              (last-line (mark-line end))
1471              (prev (line-previous first-line))
1472              (prev-line-info
1473               (and prev (getf (line-plist prev) 'lisp-info)))
1474              (save1 (line-start (copy-mark start :right-inserting)))
1475              (save2 (line-end (copy-mark end :left-inserting)))
1476              (buf-region (region save1 save2))
1477              (undo-region (copy-region buf-region)))
1478         (with-mark ((bol start :left-inserting))
1479           (do ((line first-line (line-next line)))
1480               (nil)
1481             (line-start bol line)
1482             (ensure-lisp-indentation bol)
1483             (let ((line-info (getf (line-plist line) 'lisp-info)))
1484               (parse-lisp-line-info bol line-info prev-line-info)
1485               (setq prev-line-info line-info))
1486             (when (eq line last-line) (return nil))))
1487         (make-region-undo :twiddle undo-text buf-region undo-region))))
1488
1489;;; INDENT-FOR-LISP -- Internal.
1490;;;
1491;;; This is the value of "Indent Function" for "Lisp" mode.
1492;;;
1493(defun indent-for-lisp (mark)
1494  (line-start mark)
1495  (pre-command-parse-check mark)
1496  (ensure-lisp-indentation mark))
1497
1498(defun count-leading-whitespace (mark)
1499  (with-mark ((m mark))
1500    (line-start m)
1501    (do* ((p 0)
1502          (q 0 (1+ q))
1503          (tab-width (value spaces-per-tab)))
1504         ()
1505      (case (next-character m)
1506        (#\space (incf p))
1507        (#\tab (setq p (* tab-width (ceiling (1+ p) tab-width))))
1508        (t (return (values p q))))
1509      (character-offset m 1))))
1510
1511;;; Don't do anything if M's line is already correctly indented.
1512(defun ensure-lisp-indentation (m)
1513  (let* ((col (lisp-indentation m)))
1514    (multiple-value-bind (curcol curpos) (count-leading-whitespace m)
1515      (cond ((= curcol col) (setf (mark-charpos m) curpos))
1516            (t
1517             (delete-horizontal-space m)
1518             (indent-to-column m col))))))
1519
1520
1521
1522
1523;;;; Most "Lisp" mode commands.
1524
1525(defcommand "Beginning of Defun" (p)
1526  "Move the point to the beginning of a top-level form, collapsing the selection.
1527  with an argument, skips the previous p top-level forms."
1528  "Move the point to the beginning of a top-level form, collapsing the selection."
1529  (let ((point (current-point-collapsing-selection))
1530        (count (or p 1)))
1531    (pre-command-parse-check point)
1532    (if (minusp count)
1533        (end-of-defun-command (- count))
1534        (unless (top-level-offset point (- count))
1535          (editor-error)))))
1536
1537(defcommand "Select to Beginning of Defun" (p)
1538  "Move the point to the beginning of a top-level form, extending the selection.
1539  with an argument, skips the previous p top-level forms."
1540  "Move the point to the beginning of a top-level form, extending the selection."
1541  (let ((point (current-point-for-selection-start))
1542        (count (or p 1)))
1543    (pre-command-parse-check point)
1544    (if (minusp count)
1545        (end-of-defun-command (- count))
1546        (unless (top-level-offset point (- count))
1547          (editor-error)))))
1548
1549;;; "End of Defun", with a positive p (the normal case), does something weird.
1550;;; Get a mark at the beginning of the defun, and then offset it forward one
1551;;; less top level form than we want.  This sets us up to use FORM-OFFSET which
1552;;; allows us to leave the point immediately after the defun.  If we used
1553;;; TOP-LEVEL-OFFSET one less than p on the mark at the end of the current
1554;;; defun, point would be left at the beginning of the p+1'st form instead of
1555;;; at the end of the p'th form.
1556;;;
1557(defcommand "End of Defun" (p)
1558  "Move the point to the end of a top-level form, collapsing the selection.
1559   With an argument, skips the next p top-level forms."
1560  "Move the point to the end of a top-level form, collapsing the selection."
1561  (let ((point (current-point-collapsing-selection))
1562        (count (or p 1)))
1563    (pre-command-parse-check point)
1564    (if (minusp count)
1565        (beginning-of-defun-command (- count))
1566        (with-mark ((m point)
1567                    (dummy point))
1568          (cond ((not (mark-top-level-form m dummy))
1569                 (editor-error "No current or next top level form."))
1570                (t 
1571                 (unless (top-level-offset m (1- count))
1572                   (editor-error "Not enough top level forms."))
1573                 ;; We might be one unparsed for away.
1574                 (pre-command-parse-check m)
1575                 (unless (form-offset m 1)
1576                   (editor-error "Not enough top level forms."))
1577                 (when (blank-after-p m) (line-offset m 1 0))
1578                 (move-mark point m)))))))
1579
1580(defcommand "Select to End of Defun" (p)
1581  "Move the point to the end of a top-level form, extending the selection.
1582   With an argument, skips the next p top-level forms."
1583  "Move the point to the end of a top-level form, extending the selection."
1584  (let ((point (current-point-for-selection-end))
1585        (count (or p 1)))
1586    (pre-command-parse-check point)
1587    (if (minusp count)
1588        (beginning-of-defun-command (- count))
1589        (with-mark ((m point)
1590                    (dummy point))
1591          (cond ((not (mark-top-level-form m dummy))
1592                 (editor-error "No current or next top level form."))
1593                (t 
1594                 (unless (top-level-offset m (1- count))
1595                   (editor-error "Not enough top level forms."))
1596                 ;; We might be one unparsed for away.
1597                 (pre-command-parse-check m)
1598                 (unless (form-offset m 1)
1599                   (editor-error "Not enough top level forms."))
1600                 (when (blank-after-p m) (line-offset m 1 0))
1601                 (move-mark point m)))))))
1602
1603(defcommand "Forward List" (p)
1604  "Skip over the next Lisp list, collapsing the selection.
1605  With argument, skips the next p lists."
1606  "Skip over the next Lisp list, collapsing the selection."
1607  (or (collapse-if-selection :direction :forward)
1608      (let ((point (current-point-collapsing-selection))
1609            (count (or p 1)))
1610        (pre-command-parse-check point)
1611        (unless (list-offset point count) (editor-error)))))
1612
1613(defcommand "Select Forward List" (p)
1614  "Skip over the next Lisp list, extending the selection.
1615  With argument, skips the next p lists."
1616  "Skip over the next Lisp list, extending the selection."
1617  (let ((point (current-point-for-selection-end))
1618        (count (or p 1)))
1619    (pre-command-parse-check point)
1620    (unless (list-offset point count) (editor-error))))
1621
1622(defcommand "Backward List" (p)
1623  "Skip over the previous Lisp list, collapsing the selection.
1624  With argument, skips the previous p lists."
1625  "Skip over the previous Lisp list, collapsing the selection."
1626  (or (collapse-if-selection :direction :backward)
1627   (let ((point (current-point-collapsing-selection))
1628        (count (- (or p 1))))
1629    (pre-command-parse-check point)
1630    (unless (list-offset point count) (editor-error)))))
1631
1632(defcommand "Select Backward List" (p)
1633  "Skip over the previous Lisp list, extending the selection.
1634  With argument, skips the previous p lists."
1635  "Skip over the previous Lisp list, extending the selection."
1636  (let ((point (current-point-for-selection-start))
1637        (count (- (or p 1))))
1638    (pre-command-parse-check point)
1639    (unless (list-offset point count) (editor-error))))
1640
1641(defcommand "Forward Form" (p)
1642    "Skip over the next Form, collapsing the selection.
1643  With argument, skips the next p Forms."
1644    "Skip over the next Form, collapsing the selection."
1645  (or (collapse-if-selection :direction :forward)
1646      (let ((point (current-point-collapsing-selection))
1647            (count (or p 1)))
1648        (pre-command-parse-check point)
1649        (unless (form-offset point count) (editor-error)))))
1650
1651(defcommand "Select Forward Form" (p)
1652  "Skip over the next Form, extending the selection.
1653  With argument, skips the next p Forms."
1654  "Skip over the next Form, extending the selection."
1655  (let ((point (current-point-for-selection-end))
1656        (count (or p 1)))
1657    (pre-command-parse-check point)
1658    (unless (form-offset point count) (editor-error))))
1659
1660(defcommand "Backward Form" (p)
1661    "Skip over the previous Form, collapsing the selection.
1662  With argument, skips the previous p Forms."
1663    "Skip over the previous Form, collaspsing the selection."
1664  (or (collapse-if-selection :direction :backward)
1665      (let ((point (current-point-collapsing-selection))
1666            (count (- (or p 1))))
1667        (pre-command-parse-check point)
1668        (unless (form-offset point count) (editor-error)))))
1669
1670(defcommand "Select Backward Form" (p)
1671  "Skip over the previous Form, extending the selection.
1672  With argument, skips the previous p Forms."
1673  "Skip over the previous Form, extending the selection."
1674  (let ((point (current-point-for-selection-start))
1675        (count (- (or p 1))))
1676    (pre-command-parse-check point)
1677    (unless (form-offset point count) (editor-error))))
1678
1679(defcommand "Mark Form" (p)
1680  "Set the mark at the end of the next Form.
1681   With a positive argument, set the mark after the following p
1682   Forms. With a negative argument, set the mark before
1683   the preceding -p Forms."
1684  "Set the mark at the end of the next Form."
1685  (with-mark ((m (current-point)))
1686    (pre-command-parse-check m)
1687    (let ((count (or p 1))
1688          (mark (push-new-buffer-mark m t)))
1689      (if (form-offset m count)
1690          (move-mark mark m)
1691          (editor-error)))))
1692
1693(defcommand "Mark Defun" (p)
1694  "Puts the region around the next or containing top-level form.
1695   The point is left before the form and the mark is placed immediately
1696   after it."
1697  "Puts the region around the next or containing top-level form."
1698  (declare (ignore p))
1699  (let ((point (current-point)))
1700    (pre-command-parse-check point)
1701    (with-mark ((start point)
1702                (end point))
1703      (cond ((not (mark-top-level-form start end))
1704             (editor-error "No current or next top level form."))
1705            (t
1706             (move-mark point start)
1707             (move-mark (push-new-buffer-mark point t) end))))))
1708
1709(defcommand "Forward Kill Form" (p)
1710  "Kill the next Form.
1711   With a positive argument, kills the next p Forms.
1712   Kills backward with a negative argument."
1713  "Kill the next Form."
1714  (with-mark ((m1 (current-point))
1715              (m2 (current-point)))
1716    (pre-command-parse-check m1)
1717    (let ((count (or p 1)))
1718      (unless (form-offset m1 count) (editor-error))
1719      (if (minusp count)
1720          (kill-region (region m1 m2) :kill-backward)
1721          (kill-region (region m2 m1) :kill-forward)))))
1722
1723(defcommand "Backward Kill Form" (p)
1724  "Kill the previous Form.
1725  With a positive argument, kills the previous p Forms.
1726  Kills forward with a negative argument."
1727  "Kill the previous Form."
1728  (forward-kill-form-command (- (or p 1))))
1729
1730(defcommand "Extract Form" (p)
1731  "Replace the current containing list with the next form.  The entire affected
1732   area is pushed onto the kill ring.  If an argument is supplied, that many
1733   upward levels of list nesting is replaced by the next form."
1734  "Replace the current containing list with the next form.  The entire affected
1735   area is pushed onto the kill ring.  If an argument is supplied, that many
1736   upward levels of list nesting is replaced by the next form."
1737  (let ((point (current-point)))
1738    (pre-command-parse-check point)
1739    (with-mark ((form-start point :right-inserting)
1740                (form-end point))
1741      (unless (form-offset form-end 1) (editor-error))
1742      (form-offset (move-mark form-start form-end) -1)
1743      (with-mark ((containing-start form-start :left-inserting)
1744                  (containing-end form-end :left-inserting))
1745        (dotimes (i (or p 1))
1746          (unless (and (forward-up-list containing-end)
1747                       (backward-up-list containing-start))
1748            (editor-error)))
1749        (let ((r (copy-region (region form-start form-end))))
1750          (ring-push (delete-and-save-region
1751                      (region containing-start containing-end))
1752                     *kill-ring*)
1753          (ninsert-region point r)
1754          (move-mark point form-start))))))
1755
1756(defcommand "Extract List" (p)
1757  "Extract the current list.
1758  The current list replaces the surrounding list.  The entire affected
1759  area is pushed on the kill-ring.  With prefix argument, remove that
1760  many surrounding lists."
1761  "Replace the P containing lists with the current one."
1762  (let ((point (current-point)))
1763    (pre-command-parse-check point)
1764    (with-mark ((lstart point :right-inserting)
1765                (lend point))
1766      (if (eq (character-attribute :lisp-syntax (next-character lstart))
1767              :open-paren)
1768          (mark-after lend)
1769          (unless (backward-up-list lstart) (editor-error)))
1770      (unless (forward-up-list lend) (editor-error))
1771      (with-mark ((rstart lstart)
1772                  (rend lend))
1773        (dotimes (i (or p 1))
1774          (unless (and (forward-up-list rend) (backward-up-list rstart))
1775            (editor-error)))
1776        (let ((r (copy-region (region lstart lend))))
1777          (ring-push (delete-and-save-region (region rstart rend))
1778                     *kill-ring*)
1779          (ninsert-region point r)
1780          (move-mark point lstart))))))
1781
1782(defcommand "Transpose Forms" (p)
1783  "Transpose Forms immediately preceding and following the point.
1784  With a zero argument, tranposes the Forms at the point and the mark.
1785  With a positive argument, transposes the Form preceding the point
1786  with the p-th one following it.  With a negative argument, transposes the
1787  Form following the point with the p-th one preceding it."
1788  "Transpose Forms immediately preceding and following the point."
1789  (let ((point (current-point))
1790        (count (or p 1)))
1791    (pre-command-parse-check point)
1792    (if (zerop count)
1793        (let ((mark (current-mark)))
1794          (with-mark ((s1 mark :left-inserting)
1795                      (s2 point :left-inserting))
1796            (scan-char s1 :whitespace nil)
1797            (scan-char s2 :whitespace nil)
1798            (with-mark ((e1 s1 :right-inserting)
1799                        (e2 s2 :right-inserting))
1800              (unless (form-offset e1 1) (editor-error))
1801              (unless (form-offset e2 1) (editor-error))
1802              (ninsert-region s1 (delete-and-save-region (region s2 e2)))
1803              (ninsert-region s2 (delete-and-save-region (region s1 e1))))))
1804        (let ((fcount (if (plusp count) count 1))
1805              (bcount (if (plusp count) 1 count)))
1806          (with-mark ((s1 point :left-inserting)
1807                      (e2 point :right-inserting))
1808            (dotimes (i bcount)
1809              (unless (form-offset s1 -1) (editor-error)))
1810            (dotimes (i fcount)
1811              (unless (form-offset e2 1) (editor-error)))
1812            (with-mark ((e1 s1 :right-inserting)
1813                        (s2 e2 :left-inserting))
1814              (unless (form-offset e1 1) (editor-error))
1815              (unless (form-offset s2 -1) (editor-error))
1816              (ninsert-region s1 (delete-and-save-region (region s2 e2)))
1817              (ninsert-region s2 (delete-and-save-region (region s1 e1)))
1818              (move-mark point s2)))))))
1819
1820
1821(defcommand "Insert ()" (count)
1822  "Insert a pair of parentheses ().  With positive argument, puts
1823   parentheses around the next COUNT Forms, or previous COUNT forms, if
1824   COUNT is negative.  The point is positioned after the open parenthesis."
1825  "Insert a pair of parentheses ()."
1826  ;; TODO Form navigation is broken, so this is broken too -- it is
1827  ;; possible to put parens around more forms than there are in current
1828  ;; expression.  It works by moving past as many forms as there is, and
1829  ;; then each delimiting paren also counts as a form.
1830  (let ((point (current-point)))
1831    (pre-command-parse-check point)
1832    (cond (count
1833           (when (minusp count)
1834             (form-offset point count)
1835             (setq count (- count)))
1836           (insert-character point #\()
1837           (with-mark ((m point))
1838             (unless (form-offset m count)
1839               (editor-error "Could not find that many forms."))
1840             (insert-character m #\))))
1841          ;; The simple case with no prefix argument
1842          (t
1843           (insert-character point #\()
1844           (insert-character point #\))
1845           (mark-before point)))))
1846
1847
1848(defcommand "Move Over )" (p)
1849  "Move past the next close parenthesis, and start a new line.  Any
1850   indentation preceding the preceding the parenthesis is deleted, and the
1851   new line is indented.  If there is only whitespace preceding the close
1852   paren, the paren is moved to the end of the previous line. With prefix
1853   argument, this command moves past next closing paren and inserts space."
1854  "Move past the next close parenthesis, and start a new line."
1855  ;; TODO This is still not complete, because SCAN-CHAR finds the next
1856  ;; close-paren, but we need to find the next paren that closes current
1857  ;; expression.  This will have to be updated when form navigation is
1858  ;; fixed.
1859  (let ((point (current-point)))
1860    (pre-command-parse-check point)
1861    (with-mark ((m point :right-inserting))
1862      (cond ((scan-char m :lisp-syntax :close-paren)
1863             (cond ((same-line-p point m)
1864                    (delete-horizontal-space m))
1865                   (t
1866                    (move-mark point m)
1867                    (reverse-find-attribute point :whitespace #'zerop)
1868                    (delete-region (region point m))))
1869             (cond ((not p)
1870                    ;; Move to the previous line if current is empty
1871                    (when (zerop (mark-charpos m))
1872                      (delete-characters m -1))
1873                    (mark-after m)
1874                    (move-mark point m)
1875                    (indent-new-line-command 1))
1876                   (t
1877                    (mark-after m)
1878                    (move-mark point m)
1879                    (insert-character m #\space))))
1880            (t 
1881             (editor-error "Could not find closing paren."))))))
1882
1883
1884(defcommand "Forward Up List" (p)
1885    "Move forward past a one containing )."
1886    "Move forward past a one containing )."
1887  (or (collapse-if-selection :direction :forward)
1888      (let ((point (current-point-collapsing-selection))
1889            (count (or p 1)))
1890        (pre-command-parse-check point)
1891        (if (minusp count)
1892            (backward-up-list-command (- count))
1893            (with-mark ((m point))
1894              (dotimes (i count (move-mark point m))
1895                (unless (forward-up-list m) (editor-error))))))))
1896
1897(defcommand "Backward Up List" (p)
1898    "Move backward past a one containing (."
1899    "Move backward past a one containing (."
1900  (or (collapse-if-selection :direction :backward)
1901      (let ((point (current-point-collapsing-selection))
1902            (count (or p 1)))
1903        (pre-command-parse-check point)
1904        (if (minusp count)
1905            (forward-up-list-command (- count))
1906            (with-mark ((m point))
1907              (dotimes (i count (move-mark point m))
1908                (unless (backward-up-list m) (editor-error))))))))
1909
1910
1911(defcommand "Down List" (p)
1912  "Move down a level in list structure.  With positive argument, moves down
1913   p levels.  With negative argument, moves down backward, but only one
1914   level."
1915  "Move down a level in list structure."
1916  (let ((point (current-point-collapsing-selection))
1917        (count (or p 1)))
1918    (pre-command-parse-check point)
1919    (with-mark ((m point))
1920      (cond ((plusp count)
1921             (loop repeat count
1922                   do (unless (and (scan-char m :lisp-syntax :open-paren)
1923                                   (mark-after m))
1924                        (editor-error))))
1925            (t
1926             (unless (and (rev-scan-char m :lisp-syntax :close-paren)
1927                          (mark-before m))
1928               (editor-error))))
1929      (move-mark point m))))
1930
1931
1932
1933;;;; Filling Lisp comments, strings, and indented text.
1934
1935(defhvar "Fill Lisp Comment Paragraph Confirm"
1936  "This determines whether \"Fill Lisp Comment Paragraph\" will prompt for
1937   confirmation to fill contiguous lines with the same initial whitespace when
1938   it is invoked outside of a comment or string."
1939  :value t)
1940
1941(defcommand "Fill Lisp Comment Paragraph" (p)
1942  "This fills a flushleft or indented Lisp comment.
1943   This also fills Lisp string literals using the proper indentation as a
1944   filling prefix.  When invoked outside of a comment or string, this tries
1945   to fill all contiguous lines beginning with the same initial, non-empty
1946   blankspace.  When filling a comment, the current line is used to determine a
1947   fill prefix by taking all the initial whitespace on the line, the semicolons,
1948   and any whitespace following the semicolons."
1949  "Fills a flushleft or indented Lisp comment."
1950  (declare (ignore p))
1951  (let ((point (current-point)))
1952    (pre-command-parse-check point)
1953    (with-mark ((start point)
1954                (end point)
1955                (m point))
1956      (let ((commentp (fill-lisp-comment-paragraph-prefix start end)))
1957        (cond (commentp
1958               (fill-lisp-comment-or-indented-text start end))
1959              ((and (not (valid-spot m nil))
1960                    (form-offset m -1)
1961                    (eq (character-attribute :lisp-syntax (next-character m))
1962                        :string-quote))
1963               (fill-lisp-string m))
1964              ((or (not (value fill-lisp-comment-paragraph-confirm))
1965                   (prompt-for-y-or-n
1966                    :prompt '("Not in a comment or string.  Fill contiguous ~
1967                               lines with the same initial whitespace? ")))
1968               (fill-lisp-comment-or-indented-text start end)))))))
1969
1970;;; FILL-LISP-STRING -- Internal.
1971;;;
1972;;; This fills the Lisp string containing mark as if it had been entered using
1973;;; Hemlock's Lisp string indentation, "Indent Function" for "Lisp" mode.  This
1974;;; assumes the area around mark has already been PRE-COMMAND-PARSE-CHECK'ed,
1975;;; and it ensures the string ends before doing any filling.  This function
1976;;; is undo'able.
1977;;;
1978(defun fill-lisp-string (mark)
1979  (with-mark ((end mark))
1980    (unless (form-offset end 1)
1981      (editor-error "Attempted to fill Lisp string, but it doesn't end?"))
1982    (let* ((mark (copy-mark mark :left-inserting))
1983           (end (copy-mark end :left-inserting))
1984           (string-region (region mark end))
1985           (undo-region (copy-region string-region))
1986           (hack (make-empty-region)))
1987      ;; Generate prefix.
1988      (indent-to-column (region-end hack) (1+ (mark-column mark)))
1989      ;; Skip opening double quote and fill string starting on its own line.
1990      (mark-after mark)
1991      (insert-character mark #\newline)
1992      (line-start mark)
1993      (setf (mark-kind mark) :right-inserting)
1994      (fill-region string-region (region-to-string hack))
1995      ;; Clean up inserted prefix on first line, delete inserted newline, and
1996      ;; move before the double quote for undo.
1997      (with-mark ((text mark :left-inserting))
1998        (find-attribute text :whitespace #'zerop)
1999        (delete-region (region mark text)))
2000      (delete-characters mark -1)
2001      (mark-before mark)
2002      ;; Save undo.
2003      (make-region-undo :twiddle "Fill Lisp Comment Paragraph"
2004                        string-region undo-region))))
2005
2006;;; FILL-LISP-COMMENT-OR-INDENTED-TEXT -- Internal.
2007;;;
2008;;; This fills all contiguous lines around start and end containing fill prefix
2009;;; designated by the region between start and end.  These marks can only be
2010;;; equal when there is no comment and no initial whitespace.  This is a bad
2011;;; situation since this function in that situation would fill the entire
2012;;; buffer into one paragraph.  This function is undo'able.
2013;;;
2014(defun fill-lisp-comment-or-indented-text (start end)
2015  (when (mark= start end)
2016    (editor-error "This command only fills Lisp comments, strings, or ~
2017                   indented text, but this line is flushleft."))
2018  ;;
2019  ;; Find comment block.
2020  (let* ((prefix (region-to-string (region start end)))
2021         (length (length prefix)))
2022    (declare (simple-string prefix))
2023    (flet ((frob (mark direction)
2024             (loop
2025               (let* ((line (line-string (mark-line mark)))
2026                      (line-len (length line)))
2027                 (declare (simple-string line))
2028                 (unless (string= line prefix :end1 (min line-len length))
2029                   (when (= direction -1)
2030                     (unless (same-line-p mark end) (line-offset mark 1 0)))
2031                   (return)))
2032               (unless (line-offset mark direction 0)
2033                 (when (= direction 1) (line-end mark))
2034                 (return)))))
2035      (frob start -1)
2036      (frob end 1))
2037    ;;
2038    ;; Do it undoable.
2039    (let* ((start1 (copy-mark start :right-inserting))
2040           (end2 (copy-mark end :left-inserting))
2041           (region (region start1 end2))
2042           (undo-region (copy-region region)))
2043      (fill-region region prefix)
2044      (make-region-undo :twiddle "Fill Lisp Comment Paragraph"
2045                        region undo-region))))
2046
2047;;; FILL-LISP-COMMENT-PARAGRAPH-PREFIX -- Internal.
2048;;;
2049;;; This sets start and end around the prefix to be used for filling.  We
2050;;; assume we are dealing with a comment.  If there is no ";", then we try to
2051;;; find some initial whitespace.  If there is a ";", we make sure the line is
2052;;; blank before it to eliminate ";"'s in the middle of a line of text.
2053;;; Finally, if we really have a comment instead of some indented text, we skip
2054;;; the ";"'s and any immediately following whitespace.  We allow initial
2055;;; whitespace, so we can fill strings with the same command.
2056;;;
2057(defun fill-lisp-comment-paragraph-prefix (start end)
2058  (line-start start)
2059  (let ((commentp t)) ; Assumes there's a comment.
2060    (unless (to-line-comment (line-start end) ";")
2061      (find-attribute end :whitespace #'zerop)
2062      #|(when (start-line-p end)
2063        (editor-error "No comment on line, and no initial whitespace."))|#
2064      (setf commentp nil))
2065    (when commentp
2066      (unless (blank-before-p end)
2067        (find-attribute (line-start end) :whitespace #'zerop)
2068        #|(when (start-line-p end)
2069          (editor-error "Semicolon preceded by unindented text."))|#
2070        (setf commentp nil)))
2071    (when commentp
2072      (find-attribute end :lisp-syntax #'(lambda (x) (not (eq x :comment))))
2073      (find-attribute end :whitespace #'zerop))
2074    commentp))
2075
2076
2077
2078;;;; "Lisp" mode.
2079
2080(defcommand "LISP Mode" (p)
2081  "Put current buffer in LISP mode." 
2082  "Put current buffer in LISP mode." 
2083  (declare (ignore p))
2084  (setf (buffer-major-mode (current-buffer)) "LISP"))
2085
2086
2087(defmode "Lisp" :major-p t :setup-function 'setup-lisp-mode)
2088
2089
2090(defun buffer-first-in-package-form (buffer)
2091  "Returns the package name referenced in the first apparent IN-PACKAGE
2092   form in buffer, or NIL if it can't find an IN-PACKAGE."
2093  (let* ((pattern (new-search-pattern :string-insensitive :forward "in-package" nil))
2094         (mark (copy-mark (buffer-start-mark buffer))))
2095    (with-mark ((start mark)
2096                (end mark))
2097      (loop
2098        (unless (find-pattern mark pattern)
2099          (return))
2100        (pre-command-parse-check mark)
2101        (when (valid-spot mark t)
2102          (move-mark end mark)
2103          (when (form-offset end 1)
2104            (move-mark start end)
2105            (when (backward-up-list start)
2106              (when (scan-char start :lisp-syntax :constituent)
2107                (let* ((s (nstring-upcase (region-to-string (region start end))))
2108                       (*package* (find-package "CL-USER")))
2109                  (unless (eq (ignore-errors (values (read-from-string s)))
2110                              'in-package)
2111                    (return)))
2112                (unless (form-offset end 1) (return))
2113                (move-mark start end)
2114                (form-offset start -1)
2115                (let* ((pkgname (ignore-errors (values (read-from-string (region-to-string (region start end)))))))
2116                  (return
2117                    (if pkgname
2118                      (values (ignore-errors (string pkgname))))))))))))))
2119
2120(defparameter *previous-in-package-search-pattern*
2121    (new-search-pattern :string-insensitive :backward "in-package" nil))
2122
2123(defun package-at-mark (start-mark)
2124  (let* ((pattern *previous-in-package-search-pattern*)
2125         (mark (copy-mark start-mark :temporary)))
2126    (with-mark ((start mark)
2127                (end mark)
2128                (list-end mark))
2129      (loop
2130        (unless (find-pattern mark pattern)
2131          (return))
2132        (pre-command-parse-check mark)
2133        (when (valid-spot mark t)
2134          (move-mark end mark)
2135          (when (form-offset end 1)
2136            (move-mark start end)
2137            (when (backward-up-list start)
2138              (move-mark list-end start)
2139              (unless (and (list-offset list-end 1)
2140                           (mark<= list-end start-mark))
2141                (return))
2142              (when (scan-char start :lisp-syntax :constituent)
2143                (unless (or (mark= mark start)
2144                            (let* ((s (nstring-upcase (region-to-string (region start end))))
2145                                   (*package* (find-package "CL-USER")))
2146                              (eq (ignore-errors (values (read-from-string s)))
2147                                  'in-package)))
2148                  (return))
2149                (unless (form-offset end 1) (format t "~& worse") (return 4))
2150                (move-mark start end)
2151                (form-offset start -1)
2152                (return
2153                  (if (eql (next-character start) #\")
2154                    (progn
2155                      (character-offset start 1)
2156                      (character-offset end -1)
2157                      (region-to-string (region start end)))
2158                    (let* ((pkgname (ignore-errors (values (read-from-string (region-to-string (region start end)))))))
2159                      (if pkgname
2160                        (values (ignore-errors (string pkgname)))))))))))))))
2161
2162(defun ensure-buffer-package (buffer)
2163  (or (variable-value 'current-package :buffer buffer)
2164      (setf (variable-value 'current-package :buffer buffer)
2165            (buffer-first-in-package-form buffer))))
2166
2167(defun buffer-package (buffer)
2168  (when (hemlock-bound-p 'current-package :buffer buffer)
2169    (let ((package-name (variable-value 'current-package :buffer buffer)))
2170      (find-package package-name))))
2171
2172(defun setup-lisp-mode (buffer)
2173  (unless (hemlock-bound-p 'current-package :buffer buffer)
2174    (defhvar "Current Package"
2175      "The package used for evaluation of Lisp in this buffer."
2176      :buffer buffer
2177      :value nil
2178      :hooks (list 'package-name-change-hook)))
2179  (unless (hemlock-bound-p 'default-package :buffer buffer)
2180    (defhvar "Default Package"
2181      "The package to use if the current package doesn't exist or isn't set."
2182      :buffer buffer
2183      :value (package-name *package*))))
2184
2185
2186
2187
2188
2189;;;; Some mode variables to coordinate with other stuff.
2190
2191(defhvar "Auto Fill Space Indent"
2192  "When non-nil, uses \"Indent New Comment Line\" to break lines instead of
2193   \"New Line\"."
2194  :mode "Lisp" :value t)
2195
2196(defhvar "Comment Start"
2197  "String that indicates the start of a comment."
2198  :mode "Lisp" :value ";")
2199
2200(defhvar "Comment Begin"
2201  "String that is inserted to begin a comment."
2202  :mode "Lisp" :value "; ")
2203
2204(defhvar "Indent Function"
2205  "Indentation function which is invoked by \"Indent\" command.
2206   It must take one argument that is the prefix argument."
2207  :value 'indent-for-lisp
2208  :mode "Lisp")
2209
2210(defun string-to-arglist (string buffer &optional quiet-if-unknown)
2211  (multiple-value-bind (name error)
2212      (let* ((*package* (or
2213                         (find-package
2214                          (variable-value 'current-package :buffer buffer))
2215                         *package*)))
2216        (ignore-errors (values (read-from-string string))))
2217    (unless error
2218      (when (typep name 'symbol)
2219        (multiple-value-bind (arglist win)
2220            (ccl::arglist-string name)
2221          (if (or win (not quiet-if-unknown))
2222            (format nil "~S : ~A" name (if win (or arglist "()") "(unknown)"))))))))
2223
2224(defcommand "Current Function Arglist" (p)
2225  "Show arglist of function whose name precedes point."
2226  "Show arglist of function whose name precedes point."
2227  (declare (ignore p))
2228  (let ((point (current-point)))
2229    (pre-command-parse-check point)
2230    (with-mark ((mark1 point)
2231                (mark2 point))
2232      (when (backward-up-list mark1)
2233        (when (form-offset (move-mark mark2 (mark-after mark1)) 1)
2234          (let* ((fun-name (region-to-string (region mark1 mark2)))
2235                 (arglist-string (string-to-arglist fun-name (current-buffer))))
2236            (when arglist-string
2237              (message "~a" arglist-string))))))))
2238
2239(defcommand "Arglist On Space" (p)
2240  "Insert a space, then show the current function's arglist."
2241  "Insert a space, then show the current function's arglist."
2242  (declare (ignore p))
2243  (let ((point (current-point)))
2244    (insert-character point #\Space)
2245    (pre-command-parse-check point)
2246    (with-mark ((mark1 point)
2247                (mark2 point))
2248      (when (backward-up-list mark1)
2249        (when (form-offset (move-mark mark2 (mark-after mark1)) 1)
2250          (with-mark ((mark3 mark2))
2251            (do* ()
2252                 ((mark= mark3 point)
2253                  (let* ((fun-name (region-to-string (region mark1 mark2)))
2254                         (arglist-string
2255                          (string-to-arglist fun-name (current-buffer) t)))
2256                    (when arglist-string
2257                      (message "~a" arglist-string))))
2258              (if (ccl::whitespacep (next-character mark3))
2259                (mark-after mark3)
2260                (return nil)))))))))
2261
2262(hi:defcommand "Show Callers" (p)
2263  "Display a scrolling list of the callers of the symbol at point.
2264   Double-click a row to go to the caller's definition."
2265  (declare (ignore p))
2266  (with-mark ((mark1 (current-point))
2267              (mark2 (current-point)))
2268    (mark-symbol mark1 mark2)
2269    (with-input-from-region (s (region mark1 mark2))
2270      (let* ((symbol (read s)))
2271        (hemlock-ext:open-sequence-dialog
2272         :title (format nil "Callers of ~a" symbol)
2273         :sequence (ccl::callers symbol)
2274         :action #'edit-definition)))))
2275
2276#||
2277(defcommand "Set Package Name" (p)
2278  (variable-value 'current-package :buffer buffer)
2279||#               
Note: See TracBrowser for help on using the repository browser.