source: trunk/source/cocoa-ide/cocoa-utils.lisp @ 15030

Last change on this file since 15030 was 15030, checked in by gz, 8 years ago

Add new-listener convenience function

File size: 18.6 KB
Line 
1; -*- Mode: Lisp; Package: GUI -*-
2
3(in-package "GUI")
4
5(defmethod list-from-ns-array (thing) (error "~S is not an instance of NS:NS-ARRAY" thing))
6(defmethod list-from-ns-array ((nsa ns:ns-array))
7  (let ((result (list))
8        (c (#/count nsa)))
9    (dotimes (i c) (setf result (push (#/objectAtIndex: nsa i) result)))
10    (reverse result)))
11
12(defclass key-select-table-view (ns:ns-table-view)
13  ()
14  (:metaclass ns:+ns-object))
15
16(objc:defmethod (#/keyDown: :void) ((self key-select-table-view) event)
17  (let* ((code (#/keyCode event)))
18    (if (and (>= (#/selectedRow self) 0)
19             (= code 36)) ; return key
20      (#/sendAction:to:from: *NSApp* (#/doubleAction self) (#/target self) self)
21      (call-next-method event))))
22
23(defclass sequence-window-controller (ns:ns-window-controller)
24    ((table-view :foreign-type :id :reader sequence-window-controller-table-view)
25     (sequence :initform nil :initarg :sequence :type sequence :reader sequence-window-controller-sequence)
26     (result-callback :initarg :result-callback)
27     (display :initform #'(lambda (item stream) (prin1 item stream)) :initarg :display)
28     (title :initform "Sequence dialog" :initarg :title))
29  (:metaclass ns:+ns-object))
30
31
32(objc:defmethod #/init ((self sequence-window-controller))
33  (call-next-method)
34  (let* ((w (new-cocoa-window :activate nil))
35         (contentview (#/contentView w))
36         (contentframe (#/frame contentview))
37         (scrollview (make-instance 'ns:ns-scroll-view :with-frame contentframe)))
38    (#/setWindow: self w)
39    (#/setDelegate: w self)
40    (#/setWindowController: w self)
41    (#/setHasVerticalScroller: scrollview t)
42    (#/setHasHorizontalScroller: scrollview t)
43    (#/setAutohidesScrollers: scrollview t)
44    (#/setRulersVisible: scrollview nil)
45    (#/setAutoresizingMask: scrollview (logior
46                                        #$NSViewWidthSizable
47                                        #$NSViewHeightSizable))
48    (#/setAutoresizesSubviews: (#/contentView scrollview) t)
49    (let* ((table-view (make-instance 'key-select-table-view)))
50      (#/setDocumentView: scrollview table-view)
51      (#/release table-view)
52      #-cocotron
53      (#/setColumnAutoresizingStyle: table-view #$NSTableViewUniformColumnAutoresizingStyle)
54      (setf (slot-value self 'table-view) table-view)
55      (let* ((column (make-instance 'ns:ns-table-column :with-identifier #@"")))
56        (#/setEditable: column nil)
57        #-cocotron
58        (#/setResizingMask: column #$NSTableColumnAutoresizingMask)
59        (#/addTableColumn: table-view column)
60        (#/release column))
61      (#/setAutoresizingMask: table-view (logior
62                                          #$NSViewWidthSizable
63                                          #$NSViewHeightSizable))
64      (#/sizeToFit table-view)
65      (#/setDataSource: table-view self)
66      (#/setTarget: table-view self)
67      (#/setHeaderView: table-view +null-ptr+)
68      (#/setUsesAlternatingRowBackgroundColors: table-view t)
69      (#/setDoubleAction: table-view (@selector #/sequenceDoubleClick:))
70      (#/addSubview: contentview scrollview)
71      (#/release scrollview)
72      self)))
73
74(objc:defmethod (#/dealloc :void) ((self sequence-window-controller))
75  (call-next-method))
76
77(objc:defmethod (#/windowWillClose: :void) ((self sequence-window-controller)
78                                            notification)
79  (declare (ignore notification))
80  (#/setDataSource: (slot-value self 'table-view) +null-ptr+)
81  (#/autorelease self))
82
83(objc:defmethod (#/sequenceDoubleClick: :void)
84    ((self sequence-window-controller) sender)
85  (let* ((n (#/selectedRow sender)))
86    (when (>= n 0)
87      (with-slots (sequence result-callback) self
88        (funcall result-callback (elt sequence n))))))
89
90(objc:defmethod (#/numberOfRowsInTableView: :<NSI>nteger)
91    ((self sequence-window-controller) view)
92  (declare (ignore view))
93  (length (slot-value self 'sequence)))
94
95
96(objc:defmethod #/tableView:objectValueForTableColumn:row:
97    ((self sequence-window-controller) view column (row :<NSI>nteger))
98  (declare (ignore column view))
99  (with-slots (display sequence) self
100    (#/autorelease
101     (%make-nsstring (with-output-to-string (s)
102                       (funcall display (elt sequence row) s))))))
103
104(defmethod initialize-instance :after ((self sequence-window-controller) &key &allow-other-keys)
105  (let* ((window (#/window self)))
106    (with-slots (title) self
107      (when title (#/setTitle: window (%make-nsstring title))))
108    (#/reloadData (sequence-window-controller-table-view self))
109    (#/performSelectorOnMainThread:withObject:waitUntilDone:
110     self
111     (@selector #/showWindow:)
112     +null-ptr+
113     nil)))
114
115;;; Looks like a "util" to me ...
116(defun pathname-to-url (pathname)
117  (make-instance 'ns:ns-url
118                 :file-url-with-path
119                 (%make-nsstring (native-translated-namestring pathname))))
120
121(defun cgfloat (number)
122  (float number ccl::+cgfloat-zero+))
123
124(defun color-values-to-nscolor (red green blue &optional alpha)
125  (#/retain (#/colorWithCalibratedRed:green:blue:alpha: ns:ns-color
126                                                       (cgfloat red)
127                                                       (cgfloat green)
128                                                       (cgfloat blue)
129                                                       (cgfloat (or alpha 1.0)))))
130
131(defun map-windows (fn)
132  (let ((win-arr (#/orderedWindows *NSApp*)))
133    (dotimes (i (#/count win-arr))
134      (funcall fn (#/objectAtIndex: win-arr i)))))
135
136(defun windows ()
137  (let* ((ret nil))
138    (map-windows #'(lambda (w) (push w ret)))
139    (nreverse ret)))
140
141(defun front-window ()
142  (map-windows #'(lambda (win) (return-from front-window win))))
143
144(defun target ()
145  "Returns the second window in the list returned by (windows)."
146  (let ((first? nil))
147    (map-windows #'(lambda (win)
148                     (if first?
149                       (return-from target win)
150                       (setf first? t))))))
151
152(defun first-window-satisfying-predicate (pred)
153  (block foo
154    (map-windows #'(lambda (w) (when (funcall pred w)
155                                 (return-from foo w)))))) 
156
157(defun first-window-with-controller-type (controller-type)
158  (first-window-satisfying-predicate #'(lambda (w) (typep (#/windowController w) controller-type))))
159
160
161(defun new-listener ()
162  (let ((wptr (execute-in-gui (lambda ()
163                                (declare (special hemlock-listener-document))
164                                (#/newListener: (#/delegate *NSApp*) (%null-ptr))
165                                (let ((doc (#/topListener hemlock-listener-document)))
166                                  (unless (%null-ptr-p doc)
167                                    (#/window (#/lastObject (#/windowControllers doc)))))))))
168    (when wptr (hemlock-view wptr))))
169
170;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
171;;
172
173(defvar *log-callback-errors* :backtrace)
174
175(defun maybe-log-callback-error (condition)
176  (when *log-callback-errors*
177    ;; Put these in separate ignore-errors, so at least some of it can get thru
178    (let ((emsg (ignore-errors (princ-to-string condition))))
179      (ignore-errors (clear-output *debug-io*))
180      (ignore-errors (format *debug-io* "~&Lisp error: ~s" (or emsg condition)))
181      (when (eq *log-callback-errors* :backtrace)
182        (let* ((err (nth-value 1 (ignore-errors (ccl:print-call-history :detailed-p t)))))
183          (when err
184            (ignore-errors (format *debug-io* "~&Error printing call history - "))
185            (ignore-errors (print err *debug-io*))
186            (ignore-errors (princ err *debug-io*))
187            (ignore-errors (force-output *debug-io*))))))))
188
189(defmacro with-callback-context (description &body body)
190  (let ((saved-debug-io (gensym)))
191    `(ccl::with-standard-abort-handling ,(format nil "Abort ~a" description)
192       (let ((,saved-debug-io *debug-io*))
193         (handler-bind ((error #'(lambda (condition)
194                                   (let ((*debug-io* ,saved-debug-io))
195                                     (maybe-log-callback-error condition)
196                                     (abort)))))
197           ,@body)))))
198
199;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
200;;
201;; utilities for executing in the cocoa event thread
202
203(defstatic *cocoa-thread-arg-id-map* (make-id-map))
204
205;; This is for debugging, it's preserved across queue-for-gui and bound
206;; so it can be seen in backtraces.
207(defvar *invoking-event-context* "unknown")
208(defvar *invoking-event-process* nil)
209
210(defun register-cocoa-thread-function (thunk result-handler context)
211  (assign-id-map-id *cocoa-thread-arg-id-map* (list* thunk
212                                                     result-handler
213                                                     (or context *invoking-event-context*)
214                                                     *current-process*)))
215
216(objc:defmethod (#/invokeLispFunction: :void) ((self ns:ns-application) id)
217  (invoke-lisp-function self id))
218
219(defmethod invoke-lisp-function ((self ns:ns-application) id)
220  (destructuring-bind (thunk result-handler context . invoking-process)
221                      (id-map-free-object *cocoa-thread-arg-id-map* (if (numberp id) id (#/longValue id)))
222    (handle-invoking-lisp-function thunk result-handler context invoking-process)))
223
224(defun execute-in-gui (thunk &key context)
225  "Execute thunk in the main cocoa thread, return whatever values it returns"
226  (if (typep *current-process* 'appkit-process)
227    (handle-invoking-lisp-function thunk nil context)
228    (if (or (not *nsapp*) (not (#/isRunning *nsapp*)))
229      (error "cocoa thread not available")
230      (with-autorelease-pool 
231          (let* ((return-values nil)
232                 (result-handler #'(lambda (&rest values) (setq return-values values)))
233                 (arg (make-instance 'ns:ns-number
234                                     :with-long (register-cocoa-thread-function thunk result-handler context))))
235            (#/performSelectorOnMainThread:withObject:waitUntilDone:
236             *nsapp*
237             (@selector #/invokeLispFunction:)
238             arg
239             t)
240            (#/release arg)
241            (apply #'values return-values))))))
242
243
244(defconstant $lisp-function-event-subtype 17)
245
246(defclass lisp-application (ns:ns-application)
247    ((termp :foreign-type :<BOOL>)
248     (console :foreign-type :id :accessor console))
249  (:metaclass ns:+ns-object))
250
251(defmethod current-event-modifier-p (modifier-mask)
252  (let* ((event (#/currentEvent *nsapp*))
253         (modifiers (#/modifierFlags event)))
254    (logtest modifier-mask modifiers)))
255
256(defun current-event-command-key-p ()
257  (current-event-modifier-p #$NSCommandKeyMask))
258
259;;; I'm not sure if there's another way to recognize events whose
260;;; type is #$NSApplicationDefined.
261(objc:defmethod (#/sendEvent: :void) ((self lisp-application) e)
262  (declare (dynamic-extent self e))
263  (if (and (eql (#/type e) #$NSApplicationDefined)
264           (eql (#/subtype e) $lisp-function-event-subtype))
265    (invoke-lisp-function self (#/data1 e))
266    (call-next-method e)))
267
268;; This queues an event rather than just doing performSelectorOnMainThread, so that the
269;; action is deferred until the event thread is idle.
270(defun queue-for-gui (thunk &key result-handler context at-start)
271  "Queue thunk for execution in main cocoa thread and return immediately."
272  (execute-in-gui
273   #'(lambda () 
274       (let* ((e (#/otherEventWithType:location:modifierFlags:timestamp:windowNumber:context:subtype:data1:data2:
275                  ns:ns-event
276                  #$NSApplicationDefined
277                  (ns:make-ns-point 0 0)
278                  0
279                  0.0d0
280                  0
281                  +null-ptr+
282                  $lisp-function-event-subtype
283                  (register-cocoa-thread-function thunk result-handler context)
284                  0)))
285         ;(#/retain e)
286         (#/postEvent:atStart: *nsapp* e (not (null at-start)))))))
287
288(defun handle-invoking-lisp-function (thunk result-handler context &optional (invoking-process *current-process*))
289  ;; TODO: the point is to execute result-handler in the original process, but this will do for now.
290  (let* ((*invoking-event-process* invoking-process)
291         (*invoking-event-context* context))
292    (if result-handler
293      (multiple-value-call result-handler (funcall thunk))
294      (funcall thunk))))
295
296(defun choose-directory-dialog ()
297  (execute-in-gui #'(lambda ()
298                      (let ((op (#/openPanel ns:ns-open-panel)))
299                        (#/setAllowsMultipleSelection: op nil)
300                        (#/setCanChooseDirectories: op t)
301                        (#/setCanChooseFiles: op nil)
302                        (when (eql (#/runModalForTypes: op +null-ptr+) #$NSOKButton)
303                          ;; #/stringByStandardizingPath seems to strip trailing slashes
304                         (let* ((path (#/retain (#/stringByAppendingString:
305                                        (#/stringByStandardizingPath
306                                         (#/objectAtIndex: (#/filenames op) 0))
307                                        #@"/"))))
308                            path))))))
309
310
311;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
312;;
313;; debugging
314
315(defun double-%-in (string)
316  ;; Replace any % characters in string with %%, to keep them from
317  ;; being treated as printf directives.
318  (let* ((%pos (position #\% string)))
319    (if %pos
320      (concatenate 'string (subseq string 0 %pos) "%%" (double-%-in (subseq string (1+ %pos))))
321      string)))
322
323(defun log-debug (format-string &rest args)
324  (let ((string (apply #'format nil format-string args)))
325    (#_NSLog (ccl::%make-nsstring (double-%-in string)))))
326
327(pushnew '(log-debug . 0) ccl::*format-arg-functions* :test #'equal)
328
329(defun nslog-condition (c &optional (msg "Error in event loop: "))
330  (let* ((rep (format nil "~a" c)))
331    (with-cstrs ((str rep)
332                 (msg-str msg))
333      (with-nsstr (nsstr str (length rep))
334        (with-nsstr (nsmsg msg-str (length msg))
335         (#_NSLog #@"%@: %@" :address nsmsg :address nsstr))))))
336
337(defun nsstring-for-lisp-condition (cond)
338  (%make-nsstring (double-%-in (or (ignore-errors (princ-to-string cond))
339                                   "#<error printing error message>"))))
340
341
342
343(defun assume-cocoa-thread ()
344  (assert (eq *current-process* ccl::*initial-process*)))
345
346(defmethod assume-not-editing ((whatever t)))
347
348;;; -----------------------------------------------------------------
349;;; utility to display a Cocoa alert window
350;;; -----------------------------------------------------------------
351;;; TODO: Currently this form gives no indication which button was clicked. Probably it should do so.
352(defun alert-window (&key 
353                     (title "Alert")
354                     (message "Something happened.")
355                     (default-button "Okay")
356                     alternate-button
357                     other-button)
358  (let ((nstitle (%make-nsstring title))
359        (nsmessage (%make-nsstring message))
360        (ns-default-button (%make-nsstring default-button))
361        (ns-alternate-button (or (and alternate-button (%make-nsstring alternate-button))
362                                 +null-ptr+))
363        (ns-other-button (or (and other-button (%make-nsstring other-button))
364                             +null-ptr+)))
365    (#_NSRunAlertPanel nstitle nsmessage ns-default-button ns-alternate-button ns-other-button)
366    (#/release nstitle)
367    (#/release nsmessage)
368    (#/release ns-default-button)
369    (unless (eql ns-alternate-button +null-ptr+)
370      (#/release ns-alternate-button))
371    (unless (eql ns-other-button +null-ptr+)
372      (#/release ns-other-button))))
373
374;;; -----------------------------------------------------------------
375;;; utility to display a Cocoa progress window
376;;; -----------------------------------------------------------------
377
378(defparameter *progress-window-controller* nil)
379
380(defclass progress-window-controller (ns:ns-window-controller)
381    ((progress-window :foreign-type :id :reader progress-window)
382     (message-field :foreign-type :id :reader progress-window-message-field)
383     (progress-bar :foreign-type :id :reader progress-window-progress-bar))
384  (:metaclass ns:+ns-object))
385
386(defun get-progress-window ()
387  (unless *progress-window-controller*
388    (setf *progress-window-controller* 
389          (make-instance 'progress-window-controller))
390    (#/initWithWindowNibName: *progress-window-controller* #@"ProgressWindow"))
391  (unless (#/isWindowLoaded *progress-window-controller*)
392    (#/loadWindow *progress-window-controller*))
393  (let ((window (progress-window *progress-window-controller*)))
394    (if (or (null window)
395            (%null-ptr-p window))
396        nil
397        window)))
398
399(defmacro with-modal-progress-dialog (title message &body body)
400  `(let* ((nstitle (%make-nsstring ,title))
401          (nsmessage (%make-nsstring ,message))
402          (window (get-progress-window))
403          (progress-bar (progress-window-progress-bar *progress-window-controller*))
404          (message-field (progress-window-message-field *progress-window-controller*)))
405     (unwind-protect 
406          (if window
407              (progn
408                (#/setTitle: window nstitle)
409                (#/setIndeterminate: progress-bar #$YES)
410                (#/setUsesThreadedAnimation: progress-bar #$YES)
411                (#/setStringValue: message-field nsmessage)
412                (#/makeKeyAndOrderFront: window +null-ptr+)
413                (let ((modal-session (#/beginModalSessionForWindow: ccl::*nsapp* window)))
414                  (#/startAnimation: progress-bar +null-ptr+)
415                  (let ((result (progn ,@body)))
416                    (#/stopAnimation: progress-bar +null-ptr+)
417                    (#/orderOut: window +null-ptr+)
418                    (#/endModalSession: ccl::*nsapp* modal-session)
419                    result)))
420              (progn
421                (alert-window :title "Failure"
422                            :message "Unable to load the modal progress window")
423                nil))
424       (#/release nstitle)
425       (#/release nsmessage))))
426
427(defun post-tiger-p ()
428  #+cocotron t
429  #-cocotron 
430  (rlet ((p :int))
431    (#_Gestalt #$gestaltSystemVersion p)
432    (>= (%get-long p) #x1050)))
433
434
435;; This works even if an event loop is not running.
436
437#+windows-target
438(defun shift-key-now-p ()
439  (logbitp 15 (#_GetAsyncKeyState #$VK_SHIFT)))
440
441#+darwin-target
442(defun shift-key-now-p ()
443  (let* ((event (#_CGEventCreate +null-ptr+))
444         (flags (#_CGEventGetFlags event)))
445    (prog1
446        (logtest flags #$kCGEventFlagMaskShift)
447      (#_CFRelease event))))
448
449;;; I would remove this, but I think that people use it...
450
451(defclass abstract-ns-lisp-string (ns:ns-string)
452    ()
453  (:metaclass ns:+ns-object))
454
455(defgeneric ns-lisp-string-string (abstract-ns-lisp-string)
456  (:method ((self abstract-ns-lisp-string)) nil))
457
458(objc:defmethod (#/length :<NSUI>nteger) ((self abstract-ns-lisp-string))
459    (length (ns-lisp-string-string self)))
460
461(objc:defmethod (#/characterAtIndex: :unichar) ((self abstract-ns-lisp-string) (index :<NSUI>nteger))
462  (char-code (char (ns-lisp-string-string self) index)))
463
464(defclass ns-lisp-string (abstract-ns-lisp-string)
465  ((lisp-string :initarg :string :reader ns-lisp-string-string))
466  (:metaclass ns:+ns-object))
Note: See TracBrowser for help on using the repository browser.