source: trunk/source/cocoa-ide/cocoa-utils.lisp @ 12526

Last change on this file since 12526 was 12526, checked in by gb, 11 years ago

Cocotron changes.

File size: 16.7 KB
Line 
1; -*- Mode: Lisp; Package: GUI -*-
2
3(in-package "GUI")
4
5(defmethod list-from-ns-array (thing) (error "~S is not an instance of NS:NS-ARRAY" thing))
6(defmethod list-from-ns-array ((nsa ns:ns-array))
7  (let ((result (list))
8        (c (#/count nsa)))
9    (dotimes (i c) (setf result (push (#/objectAtIndex: nsa i) result)))
10    (reverse result)))
11
12(defclass key-select-table-view (ns:ns-table-view)
13  ()
14  (:metaclass ns:+ns-object))
15
16(objc:defmethod (#/keyDown: :void) ((self key-select-table-view) event)
17  (let* ((code (#/keyCode event)))
18    (if (and (>= (#/selectedRow self) 0)
19             (= code 36)) ; return key
20      (#/sendAction:to:from: *NSApp* (#/doubleAction self) (#/target self) self)
21      (call-next-method event))))
22
23(defclass sequence-window-controller (ns:ns-window-controller)
24    ((table-view :foreign-type :id :reader sequence-window-controller-table-view)
25     (sequence :initform nil :initarg :sequence :type sequence :reader sequence-window-controller-sequence)
26     (result-callback :initarg :result-callback)
27     (display :initform #'(lambda (item stream) (prin1 item stream)) :initarg :display)
28     (title :initform "Sequence dialog" :initarg :title))
29  (:metaclass ns:+ns-object))
30
31
32(objc:defmethod #/init ((self sequence-window-controller))
33  (call-next-method)
34  (let* ((w (new-cocoa-window :activate nil))
35         (contentview (#/contentView w))
36         (contentframe (#/frame contentview))
37         (scrollview (make-instance 'ns:ns-scroll-view :with-frame contentframe)))
38    (#/setWindow: self w)
39    (#/setDelegate: w self)
40    (#/setWindowController: w self)
41    (#/setHasVerticalScroller: scrollview t)
42    (#/setHasHorizontalScroller: scrollview t)
43    (#/setAutohidesScrollers: scrollview t)
44    (#/setRulersVisible: scrollview nil)
45    (#/setAutoresizingMask: scrollview (logior
46                                        #$NSViewWidthSizable
47                                        #$NSViewHeightSizable))
48    (#/setAutoresizesSubviews: (#/contentView scrollview) t)
49    (let* ((table-view (make-instance 'key-select-table-view)))
50      (#/setDocumentView: scrollview table-view)
51      (#/release table-view)
52      #-cocotron
53      (#/setColumnAutoresizingStyle: table-view #$NSTableViewUniformColumnAutoresizingStyle)
54      (setf (slot-value self 'table-view) table-view)
55      (let* ((column (make-instance 'ns:ns-table-column :with-identifier #@"")))
56        (#/setEditable: column nil)
57        #-cocotron
58        (#/setResizingMask: column #$NSTableColumnAutoresizingMask)
59        (#/addTableColumn: table-view column)
60        (#/release column))
61      (#/setAutoresizingMask: table-view (logior
62                                          #$NSViewWidthSizable
63                                          #$NSViewHeightSizable))
64      (#/sizeToFit table-view)
65      (#/setDataSource: table-view self)
66      (#/setTarget: table-view self)
67      (#/setHeaderView: table-view +null-ptr+)
68      (#/setUsesAlternatingRowBackgroundColors: table-view t)
69      (#/setDoubleAction: table-view (@selector #/sequenceDoubleClick:))
70      (#/addSubview: contentview scrollview)
71      (#/release scrollview)
72      self)))
73
74(objc:defmethod (#/dealloc :void) ((self sequence-window-controller))
75  (call-next-method))
76
77(objc:defmethod (#/windowWillClose: :void) ((self sequence-window-controller)
78                                            notification)
79  (declare (ignore notification))
80  (#/setDataSource: (slot-value self 'table-view) +null-ptr+)
81  (#/autorelease self))
82
83(objc:defmethod (#/sequenceDoubleClick: :void)
84    ((self sequence-window-controller) sender)
85  (let* ((n (#/selectedRow sender)))
86    (when (>= n 0)
87      (with-slots (sequence result-callback) self
88        (funcall result-callback (elt sequence n))))))
89
90(objc:defmethod (#/numberOfRowsInTableView: :<NSI>nteger)
91    ((self sequence-window-controller) view)
92  (declare (ignore view))
93  (length (slot-value self 'sequence)))
94
95
96(objc:defmethod #/tableView:objectValueForTableColumn:row:
97    ((self sequence-window-controller) view column (row :<NSI>nteger))
98  (declare (ignore column view))
99  (with-slots (display sequence) self
100    (#/autorelease
101     (%make-nsstring (with-output-to-string (s)
102                       (funcall display (elt sequence row) s))))))
103
104(defmethod initialize-instance :after ((self sequence-window-controller) &key &allow-other-keys)
105  (let* ((window (#/window self)))
106    (with-slots (title) self
107      (when title (#/setTitle: window (%make-nsstring title))))
108    (#/reloadData (sequence-window-controller-table-view self))
109    (#/performSelectorOnMainThread:withObject:waitUntilDone:
110     self
111     (@selector #/showWindow:)
112     +null-ptr+
113     nil)))
114
115;;; Looks like a "util" to me ...
116(defun pathname-to-url (pathname)
117  (make-instance 'ns:ns-url
118                 :file-url-with-path
119                 (%make-nsstring (native-translated-namestring pathname))))
120
121(defun cgfloat (number)
122  (float number ccl::+cgfloat-zero+))
123
124(defun color-values-to-nscolor (red green blue &optional alpha)
125  (#/retain (#/colorWithCalibratedRed:green:blue:alpha: ns:ns-color
126                                                       (cgfloat red)
127                                                       (cgfloat green)
128                                                       (cgfloat blue)
129                                                       (cgfloat (or alpha 1.0)))))
130
131(defun map-windows (fn)
132  (let ((win-arr (#/orderedWindows *NSApp*)))
133    (dotimes (i (#/count win-arr))
134      (funcall fn (#/objectAtIndex: win-arr i)))))
135
136(defun windows ()
137  (let* ((ret nil))
138    (map-windows #'(lambda (w) (push w ret)))
139    (nreverse ret)))
140
141(defun first-window-satisfying-predicate (pred)
142  (block foo
143    (map-windows #'(lambda (w) (when (funcall pred w)
144                                 (return-from foo w)))))) 
145
146(defun first-window-with-controller-type (controller-type)
147  (first-window-satisfying-predicate #'(lambda (w) (typep (#/windowController w) controller-type))))
148
149;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
150;;
151
152(defvar *log-callback-errors* :backtrace)
153
154(defun maybe-log-callback-error (condition)
155  (when *log-callback-errors*
156    ;; Put these in separate ignore-errors, so at least some of it can get thru
157    (let ((emsg (ignore-errors (princ-to-string condition))))
158      (ignore-errors (clear-output *debug-io*))
159      (ignore-errors (format *debug-io* "~&Lisp error: ~s" (or emsg condition)))
160      (when (eq *log-callback-errors* :backtrace)
161        (let* ((err (nth-value 1 (ignore-errors (ccl:print-call-history :detailed-p t)))))
162          (when err
163            (ignore-errors (format *debug-io* "~&Error printing call history - "))
164            (ignore-errors (print err *debug-io*))
165            (ignore-errors (princ err *debug-io*))
166            (ignore-errors (force-output *debug-io*))))))))
167
168(defmacro with-callback-context (description &body body)
169  (let ((saved-debug-io (gensym)))
170    `(ccl::with-standard-abort-handling ,(format nil "Abort ~a" description)
171       (let ((,saved-debug-io *debug-io*))
172         (handler-bind ((error #'(lambda (condition)
173                                   (let ((*debug-io* ,saved-debug-io))
174                                     (maybe-log-callback-error condition)
175                                     (abort)))))
176           ,@body)))))
177
178;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
179;;
180;; utilities for executing in the cocoa event thread
181
182(defstatic *cocoa-thread-arg-id-map* (make-id-map))
183
184;; This is for debugging, it's preserved across queue-for-gui and bound
185;; so it can be seen in backtraces.
186(defvar *invoking-event-context* "unknown")
187(defvar *invoking-event-process* nil)
188
189(defun register-cocoa-thread-function (thunk result-handler context)
190  (assign-id-map-id *cocoa-thread-arg-id-map* (list* thunk
191                                                     result-handler
192                                                     (or context *invoking-event-context*)
193                                                     *current-process*)))
194
195(objc:defmethod (#/invokeLispFunction: :void) ((self ns:ns-application) id)
196  (invoke-lisp-function self id))
197
198(defmethod invoke-lisp-function ((self ns:ns-application) id)
199  (destructuring-bind (thunk result-handler context . invoking-process)
200                      (id-map-free-object *cocoa-thread-arg-id-map* (if (numberp id) id (#/longValue id)))
201    (handle-invoking-lisp-function thunk result-handler context invoking-process)))
202
203(defun execute-in-gui (thunk &key context)
204  "Execute thunk in the main cocoa thread, return whatever values it returns"
205  (if (typep *current-process* 'appkit-process)
206    (handle-invoking-lisp-function thunk nil context)
207    (if (or (not *nsapp*) (not (#/isRunning *nsapp*)))
208      (error "cocoa thread not available")
209      (with-autorelease-pool 
210          (let* ((return-values nil)
211                 (result-handler #'(lambda (&rest values) (setq return-values values)))
212                 (arg (make-instance 'ns:ns-number
213                                     :with-long (register-cocoa-thread-function thunk result-handler context))))
214            (#/performSelectorOnMainThread:withObject:waitUntilDone:
215             *nsapp*
216             (@selector #/invokeLispFunction:)
217             arg
218             t)
219            (apply #'values return-values))))))
220
221
222(defconstant $lisp-function-event-subtype 17)
223
224(defclass lisp-application (ns:ns-application)
225    ((termp :foreign-type :<BOOL>)
226     (console :foreign-type :id :accessor console))
227  (:metaclass ns:+ns-object))
228
229(defmethod current-event-modifier-p (modifier-mask)
230  (let* ((event (#/currentEvent *nsapp*))
231         (modifiers (#/modifierFlags event)))
232    (logtest modifier-mask modifiers)))
233
234(defun current-event-command-key-p ()
235  (current-event-modifier-p #$NSCommandKeyMask))
236
237;;; I'm not sure if there's another way to recognize events whose
238;;; type is #$NSApplicationDefined.
239(objc:defmethod (#/sendEvent: :void) ((self lisp-application) e)
240  (if (and (eql (#/type e) #$NSApplicationDefined)
241           (eql (#/subtype e) $lisp-function-event-subtype))
242    (invoke-lisp-function self (#/data1 e))
243    (call-next-method e)))
244
245;; This queues an event rather than just doing performSelectorOnMainThread, so that the
246;; action is deferred until the event thread is idle.
247(defun queue-for-gui (thunk &key result-handler context at-start)
248  "Queue thunk for execution in main cocoa thread and return immediately."
249  (execute-in-gui
250   #'(lambda () 
251       (let* ((e (#/otherEventWithType:location:modifierFlags:timestamp:windowNumber:context:subtype:data1:data2:
252                  ns:ns-event
253                  #$NSApplicationDefined
254                  (ns:make-ns-point 0 0)
255                  0
256                  0.0d0
257                  0
258                  +null-ptr+
259                  $lisp-function-event-subtype
260                  (register-cocoa-thread-function thunk result-handler context)
261                  0)))
262         ;(#/retain e)
263         (#/postEvent:atStart: *nsapp* e (not (null at-start)))))))
264
265(defun handle-invoking-lisp-function (thunk result-handler context &optional (invoking-process *current-process*))
266  ;; TODO: the point is to execute result-handler in the original process, but this will do for now.
267  (let* ((*invoking-event-process* invoking-process)
268         (*invoking-event-context* context))
269    (if result-handler
270      (multiple-value-call result-handler (funcall thunk))
271      (funcall thunk))))
272
273(defun choose-directory-dialog ()
274  (execute-in-gui #'(lambda ()
275                      (let ((op (#/openPanel ns:ns-open-panel)))
276                        (#/setAllowsMultipleSelection: op nil)
277                        (#/setCanChooseDirectories: op t)
278                        (#/setCanChooseFiles: op nil)
279                        (when (eql (#/runModalForTypes: op +null-ptr+) #$NSOKButton)
280                          ;; #/stringByStandardizingPath seems to strip trailing slashes
281                         (let* ((path (#/retain (#/stringByAppendingString:
282                                        (#/stringByStandardizingPath
283                                         (#/objectAtIndex: (#/filenames op) 0))
284                                        #@"/"))))
285                            path))))))
286
287
288;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
289;;
290;; debugging
291
292(defun double-%-in (string)
293  ;; Replace any % characters in string with %%, to keep them from
294  ;; being treated as printf directives.
295  (let* ((%pos (position #\% string)))
296    (if %pos
297      (concatenate 'string (subseq string 0 %pos) "%%" (double-%-in (subseq string (1+ %pos))))
298      string)))
299
300(defun log-debug (format-string &rest args)
301  (let ((string (apply #'format nil format-string args)))
302    (#_NSLog (ccl::%make-nsstring (double-%-in string)))))
303
304(pushnew '(log-debug . 0) ccl::*format-arg-functions* :test #'equal)
305
306(defun nslog-condition (c &optional (msg "Error in event loop: "))
307  (let* ((rep (format nil "~a" c)))
308    (with-cstrs ((str rep)
309                 (msg-str msg))
310      (with-nsstr (nsstr str (length rep))
311        (with-nsstr (nsmsg msg-str (length msg))
312         (#_NSLog #@"%@: %@" :address nsmsg :address nsstr))))))
313
314(defun nsstring-for-lisp-condition (cond)
315  (%make-nsstring (double-%-in (or (ignore-errors (princ-to-string cond))
316                                   "#<error printing error message>"))))
317
318
319
320(defun assume-cocoa-thread ()
321  (assert (eq *current-process* ccl::*initial-process*)))
322
323(defmethod assume-not-editing ((whatever t)))
324
325;;; -----------------------------------------------------------------
326;;; utility to display a Cocoa alert window
327;;; -----------------------------------------------------------------
328;;; TODO: Currently this form gives no indication which button was clicked. Probably it should do so.
329(defun alert-window (&key 
330                     (title "Alert")
331                     (message "Something happened.")
332                     (default-button "Okay")
333                     alternate-button
334                     other-button)
335  (let ((nstitle (%make-nsstring title))
336        (nsmessage (%make-nsstring message))
337        (ns-default-button (%make-nsstring default-button))
338        (ns-alternate-button (or (and alternate-button (%make-nsstring alternate-button))
339                                 +null-ptr+))
340        (ns-other-button (or (and other-button (%make-nsstring other-button))
341                             +null-ptr+)))
342    (#_NSRunAlertPanel nstitle nsmessage ns-default-button ns-alternate-button ns-other-button)
343    (#/release nstitle)
344    (#/release nsmessage)
345    (#/release ns-default-button)
346    (unless (eql ns-alternate-button +null-ptr+)
347      (#/release ns-alternate-button))
348    (unless (eql ns-other-button +null-ptr+)
349      (#/release ns-other-button))))
350
351;;; -----------------------------------------------------------------
352;;; utility to display a Cocoa progress window
353;;; -----------------------------------------------------------------
354
355(defparameter *progress-window-controller* nil)
356
357(defclass progress-window-controller (ns:ns-window-controller)
358    ((progress-window :foreign-type :id :reader progress-window)
359     (message-field :foreign-type :id :reader progress-window-message-field)
360     (progress-bar :foreign-type :id :reader progress-window-progress-bar))
361  (:metaclass ns:+ns-object))
362
363(defun get-progress-window ()
364  (unless *progress-window-controller*
365    (setf *progress-window-controller* 
366          (make-instance 'progress-window-controller))
367    (#/initWithWindowNibName: *progress-window-controller* #@"ProgressWindow"))
368  (unless (#/isWindowLoaded *progress-window-controller*)
369    (#/loadWindow *progress-window-controller*))
370  (let ((window (progress-window *progress-window-controller*)))
371    (if (or (null window)
372            (%null-ptr-p window))
373        nil
374        window)))
375
376(defmacro with-modal-progress-dialog (title message &body body)
377  `(let* ((nstitle (%make-nsstring ,title))
378          (nsmessage (%make-nsstring ,message))
379          (window (get-progress-window))
380          (progress-bar (progress-window-progress-bar *progress-window-controller*))
381          (message-field (progress-window-message-field *progress-window-controller*)))
382     (unwind-protect 
383          (if window
384              (progn
385                (#/setTitle: window nstitle)
386                (#/setIndeterminate: progress-bar #$YES)
387                (#/setUsesThreadedAnimation: progress-bar #$YES)
388                (#/setStringValue: message-field nsmessage)
389                (#/makeKeyAndOrderFront: window +null-ptr+)
390                (let ((modal-session (#/beginModalSessionForWindow: ccl::*nsapp* window)))
391                  (#/startAnimation: progress-bar +null-ptr+)
392                  (let ((result (progn ,@body)))
393                    (#/stopAnimation: progress-bar +null-ptr+)
394                    (#/orderOut: window +null-ptr+)
395                    (#/endModalSession: ccl::*nsapp* modal-session)
396                    result)))
397              (progn
398                (alert-window :title "Failure"
399                            :message "Unable to load the modal progress window")
400                nil))
401       (#/release nstitle)
402       (#/release nsmessage))))
403
404(defun post-tiger-p ()
405  #+cocotron t
406  #-cocotron 
407  (rlet ((p :int))
408    (#_Gestalt #$gestaltSystemVersion p)
409    (>= (%get-long p) #x1050)))
410
411
Note: See TracBrowser for help on using the repository browser.