source: trunk/ccl/lib/numbers.lisp @ 6012

Last change on this file since 6012 was 6012, checked in by gb, 14 years ago

printing random-state: don't shift seeds.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 29.8 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;; Lib;numbers.lisp - Lisp arithmetic code.
18
19(in-package "CCL")
20
21(eval-when (:compile-toplevel :execute)
22 (require :number-macros)
23 (require :number-case-macro)
24 #+(and cross-compiling 64-bit-target)
25 (declaim (ftype function %single-float-atanh %single-float-acosh
26                 %single-float-asinh %single-float-tanh
27                 %single-float-cosh %single-float-sinh)))
28
29
30
31(defconstant double-float-positive-infinity
32  #.(let* ((division-by-zero (get-fpu-mode  :division-by-zero)))
33      (declare (notinline /))
34      (unwind-protect
35           (progn
36             (ccl:set-fpu-mode :division-by-zero nil)
37             (/ 0d0))
38        (ccl:set-fpu-mode :division-by-zero division-by-zero))))
39
40(defconstant double-float-negative-infinity
41  #.(let* ((division-by-zero (get-fpu-mode  :division-by-zero)))
42      (declare (notinline /))
43      (unwind-protect
44           (progn
45             (ccl:set-fpu-mode :division-by-zero nil)
46             (/ -0d0))
47        (ccl:set-fpu-mode :division-by-zero division-by-zero))))
48
49
50
51(defun parse-float (str len off) 
52  ; we cant assume this really is a float but dont call with eg s1 or e1
53  (let ((integer 0)(expt 0)(sign 0)(done 0)(digits 0) point-pos type) 
54    (setq integer
55          (do ((n off (1+ n))
56               (first t nil)
57               (maxn  (+ off len)))
58              ((>= n maxn) integer)
59            (declare (fixnum n maxn))
60            (let ((c (%schar str n)))
61              (cond ((eq c #\.)
62                     (setq point-pos digits))
63                    ((and first (eq c #\+)))
64                    ((and first (eq c #\-))
65                     (setq sign -1))
66                    ((memq c '(#\s #\f #\S #\F))
67                     (setq type 'short-float)
68                     (return integer))
69                    ((memq c '(#\d #\l  #\D  #\L))
70                     (setq type 'double-float)
71                     (return integer))
72                    ((memq c '(#\e #\E))
73                     (return integer))
74                    ((setq c (digit-char-p c))
75                     (setq digits (1+ digits))
76                     (setq integer (+ c (* 10 integer))))                 
77                    (t (return-from parse-float nil)))
78              (setq done (1+ done)))))
79    (when point-pos
80      (setq expt  (%i- point-pos digits)))
81    (when (null type)
82      (setq type *read-default-float-format*))
83    (when (> len done)
84      (let ((eexp nil) (inf nil) (nan nil) (esign 1) c (xsign-n -1))
85        (do ((n (%i+ off done 1) (1+ n))
86             (first t nil))
87            ((>= n (+ off len)))
88          (declare (fixnum n))
89          (setq c (%schar str n))
90          (cond ((and first (or (eq c #\+)(eq c #\-)))
91                 (when (eq c #\-)(setq esign -1))
92                 (setq xsign-n (1+ n)))
93                ((and (= n xsign-n)
94                      (or (eq c #\+)(eq c #\-)))
95                 (if (eq c #\-)
96                     (setq nan t)
97                     (setq inf t)))
98                ((setq c (digit-char-p c))
99                 (setq eexp (+ c (* (or eexp 0) 10))))
100                (t (return-from parse-float nil))))
101        (when (not eexp)(return-from parse-float nil))
102        (cond 
103         (inf 
104          (return-from parse-float
105            (coerce (if (minusp sign)
106                        double-float-negative-infinity
107                        double-float-positive-infinity)
108                    type)))
109         (nan 
110          (return-from parse-float
111            (let* ((invalid (ccl:get-fpu-mode :invalid)))
112            (unwind-protect
113                (progn
114                  (ccl:set-fpu-mode :invalid nil)
115                  (coerce
116                   ;; we could also have used a double-float-nan
117                   ;; variable binding here:
118                   (+ double-float-positive-infinity
119                      double-float-positive-infinity)
120                   type))
121              (ccl:set-fpu-mode :invalid invalid)))))
122         (expt (setq expt (%i+ expt (* esign eexp))))
123         (t (return-from parse-float nil)))))
124    (fide sign integer expt (subtypep type 'short-float))))
125
126
127;; an interesting test case: 1.448997445238699
128;; The correct result is 6525704354437805 x 2^-52
129;; Incorrect is          6525704354437806 x 2^-52
130;; (from Will Clinger, "How to Read Floating Point Numbers Accurately",
131;;  ACM SIGPLAN'90 Conference on Programming Language Design and Implementation")
132;; Doug Curries numbers 214748.3646, 1073741823/5000
133
134
135;; Sane read losers
136;; 15871904747836473438871.0e-8
137;; 3123927307537977993905.0-13
138;; 17209940865514936528.0e-6
139;; "13.60447536e132" => adds some gratuitous drech
140;; "94824331561426550.889e182"
141;; "1166694.64175277e-150" => 1.1666946417527701E-144
142;; "3109973217844.55680988601e-173"
143;; "817332.e-184" => 8.173320000000001E-179
144;; "2695.13e-180" => 2.6951300000000002E-177
145;; "89.85345789e-183" => 8.985345789000001E-182
146;; "0864813880.29e140" => 8.648138802899999E+148
147;; "5221.e-193" => 5.2209999999999995E-190
148;; "7.15628e-175" => 7.156280000000001E-175
149
150(defparameter float-powers-of-5  nil)
151(defparameter integer-powers-of-5 nil)
152
153(defun 5-to-e (e)
154  (declare (fixnum e)(optimize (speed 3)(safety 0)))
155  (if (> e 335)
156    (* (5-to-e 335)(5-to-e (- e 335))) ; for the dude who types 200 digits and e-500
157    (if (< e 12)
158      (svref integer-powers-of-5 e)
159      (multiple-value-bind (q r) (truncate e 12) ; was floor
160        (declare (fixnum q r))       
161        (if (eql r 0)
162          (svref integer-powers-of-5 (%i+ q 11))
163          (* (svref integer-powers-of-5 r)
164             (svref integer-powers-of-5 (%i+ q 11))))))))
165
166(defun float-5-to-e (e)
167  (if (> e 22)  ; shouldnt happen
168    (expt 5.0d0 e)
169    (svref float-powers-of-5 e)))
170
171(defparameter a-short-float nil)
172
173(eval-when (:compile-toplevel :execute)
174  ; number of bits for mantissa before rounding
175  (defconstant *short-float-extended-precision* 28)
176  (defconstant *double-float-extended-precision* 60)
177  ; number of mantissa bits including hidden bit
178  (defconstant *double-float-precision* (1+ IEEE-double-float-mantissa-width))
179  (defconstant *short-float-precision* (1+ IEEE-single-float-mantissa-width))
180  (defconstant *double-float-bias* IEEE-double-float-bias)
181  (defconstant *double-float-max-exponent* (1+ IEEE-double-float-normal-exponent-max))
182  (defconstant *double-float-max-exact-power-of-5* 23)
183  ;(defconstant *short-float-max-exact-integer-length* 24)
184  (defconstant *double-float-max-exact-integer-length* 53)
185)
186
187
188
189
190(eval-when (:compile-toplevel :execute)
191  (defconstant *short-float-max-exact-power-of-5* 10)
192  (defconstant *short-float-bias* IEEE-single-float-bias)
193  (defconstant *short-float-max-exact-integer-length* 24)
194  (defconstant *short-float-max-exponent* (1+ IEEE-single-float-normal-exponent-max))
195)
196
197 
198;; this stuff  could be in a shared file
199
200(defun fide #|float-integer-with-decimal-exponent|# (sign integer power-of-10 &optional short)
201  ;; take care of the zero case
202  (when (zerop integer)
203    (return-from fide ;float-integer-with-decimal-exponent
204       (if short
205         (if (minusp sign) -0.0s0 0.0s0)
206         (if (minusp sign) -0.0d0 0.0d0))))
207  (let ((abs-power (abs power-of-10))
208        (integer-length (integer-length integer)))
209    ;; this doesn't work for the above example, so arithmetic must be done wrong
210    ;; This does work if set FPCR precision to double
211    ;; now see if the conversion can be done simply:
212    ;; if both the integer and the power of 10 can be floated exactly, then
213    ;; correct rounding can be done by the multiply or divide
214    (when (or;short
215           (and (<= integer-length 
216                    ;; was (if short 17 53) why 17? see above
217                    (if short *short-float-max-exact-integer-length* *double-float-max-exact-integer-length*)) 
218                ;; (integer-length (expt 5 23)) => 54
219                ;; was (if short 5 23)
220                (< abs-power  (if short 
221                                *short-float-max-exact-power-of-5*
222                                *double-float-max-exact-power-of-5*)))) ; we mean < 23 not <=
223      ;; if you care about consing, this could be done in assembly language or whatever,
224      ;; since all integers fit in 53 bits
225      (return-from fide ;float-integer-with-decimal-exponent
226        (let* ((signed-integer (prog1 (if (minusp sign) (- integer) integer)))
227               (float (float signed-integer (if short 0.0s0 0.0d0)))
228               (10-to-power (scale-float (float-5-to-e abs-power) abs-power)))
229          ;; coerce to short-float does not whine about undeflow, but does re overflow
230          (when short (setq 10-to-power (coerce 10-to-power 'short-float)))
231          (if (zerop abs-power)
232            float
233            (if (minusp power-of-10)
234              (/ float  10-to-power)
235              (* float  10-to-power))))))
236    (try-harder sign integer power-of-10 short)))
237
238
239(defun try-harder (sign integer power-of-10 short)
240  (flet ((ovf (&optional under)
241           (if under
242             (if (get-fpu-mode :underflow)
243               (error 'floating-point-underflow
244                      :operation 'scale
245                      :operands (list sign integer power-of-10)))
246             (if (get-fpu-mode :overflow)
247               (error 'floating-point-overflow
248                      :operation 'scale
249                      :operands (list sign integer power-of-10))))
250           (return-from try-harder
251             (if under
252               (if short
253                 (if (minusp sign) -0.0s0 0.0s0)                 
254                 (if (minusp sign) 0.0d0 0.0d0))
255               (if short
256                 (if (minusp sign) most-negative-short-float most-positive-short-float)             
257                 (if (minusp sign) most-negative-double-float most-positive-double-float))))))
258  (let* ((integer-length (integer-length integer)) new-int power-of-2)
259    (if (minusp power-of-10)
260      (progn 
261        ;; avoid creating enormous integers with 5-to-e only to error later
262        (when (< power-of-10 -335)
263          (let ((poo (+ (round integer-length 3.2) power-of-10)))
264            ;; overestimate digits in integer
265            (when (< poo -335) (ovf t))
266            ;; this case occurs if 600+ digits
267            (when (> poo 335) (ovf))))
268        (let* ((divisor (5-to-e (- power-of-10)))
269               ;; make sure we will have enough bits in the quotient
270               ;; (and a couple extra for rounding)
271               (shift-factor (+ (- (integer-length divisor) integer-length)
272                                (if short *short-float-extended-precision* *double-float-extended-precision*)))
273               (scaled-integer integer))
274          (if (plusp shift-factor)
275            (setq scaled-integer (ash integer shift-factor))
276            (setq divisor (ash divisor (- shift-factor))))
277          (multiple-value-bind (quotient remainder)(floor scaled-integer divisor)
278            (unless (zerop remainder) ; whats this - tells us there's junk below
279              (setq quotient (logior quotient 1)))
280            (setq new-int quotient)
281            (setq power-of-2  (- power-of-10 shift-factor)))))
282      (progn
283        (when (> power-of-10 335)(ovf))
284        (setq new-int (* integer (5-to-e power-of-10)))
285        (setq power-of-2 power-of-10)))
286    (float-and-scale-and-round sign new-int power-of-2 short))))
287
288
289(defun float-and-scale-and-round (sign integer power-of-2 short &optional result)
290  (let* ((length (integer-length integer))
291         (lowbits 0)
292         (prec (if short *short-float-precision* *double-float-precision*))
293         (ep (if short *short-float-extended-precision* *double-float-extended-precision*)))
294    (when (<= length prec)
295      ;; float can be done exactly, so do it the easy way
296      (return-from float-and-scale-and-round
297        (scale-float (float (if (minusp sign) (- integer) integer) (if short a-short-float))
298                     power-of-2)))   
299    (let* ((exponent (+ length power-of-2))
300           (biased-exponent (+ exponent (if short *short-float-bias* *double-float-bias*)))
301           (sticky-residue nil))
302      (cond
303       ((<= biased-exponent 0)
304        ;; denormalize the number
305        (setf sticky-residue (not (zerop (ldb integer (byte (- 1 biased-exponent) 0)))))
306        (setf integer (ash integer (- biased-exponent 1)))
307        (setf biased-exponent 0)))
308      (let ((lowest (min ep length)))
309        (when (and (> length ep)(not (zerop (ldb (byte (- length ep) 0) integer))))
310          (setq integer (logior integer (ash 1 (- length ep)))))
311        ; somewhere between 1 and (- ep prec) bits
312        (setq lowbits (ash (ldb (byte (- lowest prec) (- length lowest)) integer) (- ep lowest))))
313      (let* ((significand (ldb (byte (1- prec) (- length prec)) integer)))
314        (when (and (not (zerop (ldb (byte 1 (- length (1+ prec))) integer)))   ; round bit
315                   (or sticky-residue (oddp significand)
316                       (not (zerop (ldb (byte (- ep prec 1) 0) lowbits)))))
317          ;; round up
318          (setf significand (ldb (byte (1- prec) 0) (+ significand 1)))
319          (when (zerop significand)
320            (incf biased-exponent)))
321        (cond ((and (zerop biased-exponent)
322                    (zerop significand)
323                    (get-fpu-mode :underflow))
324               (error 'floating-point-underflow
325                      :operation 'scale
326                      :operands (list sign integer power-of-2)))
327              ((>= biased-exponent (if short *short-float-max-exponent* *double-float-max-exponent*))
328               (cond 
329                     (t
330                      (if (get-fpu-mode :overflow)
331                        (error 'floating-point-overflow
332                               :operation 'scale
333                               :operands (list sign integer power-of-2)))
334                      (setf significand 0)                     
335                      (setq biased-exponent (if short *short-float-max-exponent* *double-float-max-exponent*))))))
336        (values
337         (if short 
338           (make-short-float-from-fixnums (ldb (byte 23 0) significand)
339                                          biased-exponent
340                                          sign #-64-bit-target result)
341           (make-float-from-fixnums (ldb (byte 24 28) significand)
342                                    (ldb (byte 28 0) significand)
343                                    biased-exponent
344                                    sign result))
345         lowbits)))))
346
347
348
349
350(defparameter a-short-float 1.0s0)
351
352
353(defmethod print-object ((rs random-state) stream)
354  (format stream "#.(~S ~S ~S)"         ;>> #.GAG!!!
355          'ccl::initialize-random-state
356          (%svref rs 1)
357          (%svref rs 2)))
358
359
360
361(defun float-radix (float)
362  "Return (as an integer) the radix b of its floating-point argument."
363  (require-type float 'float)
364  2)
365
366(defun float-digits (float)
367  (if (typep (require-type float 'float) 'short-float)
368    IEEE-single-float-digits
369    IEEE-double-float-digits))
370
371(defun number-arg (arg)
372  (if (numberp arg) arg (%badarg arg 'number)))
373
374
375
376
377
378;==> Needs a transform...
379(defun logandc2 (integer1 integer2)
380  "Bitwise AND INTEGER1 with (LOGNOT INTEGER2)."
381  (logandc1 integer2 integer1))
382
383(defun logorc2 (integer1 integer2)
384  "Bitwise OR INTEGER1 with (LOGNOT INTEGER2)."
385  (logorc1 integer2 integer1))
386
387
388
389; Figure that the common (2-arg) case is caught by a compiler transform anyway.
390(defun gcd (&lexpr numbers)
391  "Return the greatest common divisor of the arguments, which must be
392  integers. Gcd with no arguments is defined to be 0."
393  (let* ((count (%lexpr-count numbers)))
394    (declare (fixnum count))   
395    (if (zerop count)
396      0
397      (let* ((n0 (%lexpr-ref numbers count 0)))
398        (if (= count 1)
399          (%integer-abs n0)
400          (do* ((i 1 (1+ i)))
401               ((= i count) n0)
402            (declare (fixnum i))
403            (setq n0 (gcd-2 n0 (%lexpr-ref numbers count i)))))))))
404
405(defun lcm-2 (n0 n1)
406  (or (typep n0 'integer) (report-bad-arg n0 'integer))
407  (or (typep n1 'integer) (report-bad-arg n1 'integer))
408  (locally (declare (integer n0 n1))
409    (if (zerop n0)
410      0
411      (if (zerop n1)
412        0
413        (let* ((small (if (< n0 n1) n0 n1))
414               (large (if (eq small n0) n1 n0)))
415          (values (truncate (abs (* n0 n1)) (gcd large small))))))))
416
417(defun lcm (&lexpr numbers)
418  "Return the least common multiple of one or more integers. LCM of no
419  arguments is defined to be 1."
420  (let* ((count (%lexpr-count numbers)))
421    (declare (fixnum count))   
422    (if (zerop count)
423      1
424      (let* ((n0 (%lexpr-ref numbers count 0)))
425        (if (= count 1)
426          (%integer-abs n0)
427          (if (= count 2)
428            (lcm-2 n0 (%lexpr-ref numbers count 1))
429            (do* ((i 1 (1+ i)))
430                 ((= i count) n0)
431              (declare (fixnum i))
432              (setq n0 (lcm-2 n0 (%lexpr-ref numbers count i))))))))))
433
434
435#|
436(defun rationalize (x)
437  (etypecase x
438    (rational x)
439    (real
440     (cond ((minusp x) (- (rationalize (- x))))
441           ((zerop x) 0)
442           (t
443            (let ((eps (etypecase x
444                         (single-float single-float-epsilon)
445                         (double-float double-float-epsilon)))
446                  (y ())
447                  (a ()))
448              (do ((xx x (setq y (/ (float 1.0 x) (- xx (float a x)))))
449                   (num (setq a (truncate x))
450                        (+ (* (setq a (truncate y)) num) onum))
451                   (den 1 (+ (* a den) oden))
452                   (onum 1 num)
453                   (oden 0 den))
454                  ((and (not (zerop den))
455                        (not (> (abs (/ (- x (/ (float num x)
456                                                (float den x)))
457                                        x))
458                                eps)))
459                   (integer-/-integer num den)))))))))
460|#
461
462(defun rationalize (number)
463  "Converts any REAL to a RATIONAL.  Floats are converted to a simple rational
464  representation exploiting the assumption that floats are only accurate to
465  their precision.  RATIONALIZE (and also RATIONAL) preserve the invariant:
466      (= x (float (rationalize x) x))"
467  (if (floatp number)
468    (labels ((simpler-rational (less-predicate lonum loden hinum hiden
469                                               &aux (trunc (if (eql less-predicate #'<=)
470                                                             #'ceiling
471                                                             #'(lambda (n d) (1+ (floor n d)))))
472                                               (term (funcall trunc lonum loden)))
473               ;(pprint (list lonum loden hinum hiden))
474               (if (funcall less-predicate (* term hiden) hinum)
475                 (values term 1)
476                 (multiple-value-bind 
477                   (num den)
478                   (simpler-rational less-predicate hiden (- hinum (* (1- term) hiden))
479                                     loden (- lonum (* (1- term) loden)))
480                   (values (+ den (* (1- term) num)) num)))))                           
481      (multiple-value-bind (fraction exponent sign) (integer-decode-float number)
482        ;; the first 2 tests may be unnecessary - I think the check
483        ;; for denormalized is compensating for a bug in 3.0 re
484        ;; floating a rational (in order to pass tests in
485        ;; ppc-test-arith).
486        (if (or (and (typep number 'double-float)  ; is it denormalized
487                     (eq exponent #.(nth-value 1 (integer-decode-float least-positive-double-float)))) ; aka -1074))
488                (eq exponent #.(nth-value 1 (integer-decode-float least-positive-short-float))) ; aka -149))
489                (zerop (logand fraction (1- fraction)))) ; or a power of two
490          (rational number)
491          (if (minusp exponent)
492            ;;less than 1
493            (let ((num (ash fraction 2))
494                  (den (ash 1 (- 2 exponent))))
495              (multiple-value-bind 
496                (n d)
497                (simpler-rational (if (evenp fraction) #'<= #'<)
498                                  (- num 2) ;(if (zerop (logand fraction (1- fraction))) 1 2))
499                                  den  (+ num 2) den)
500                (when (minusp sign)
501                  (setq n (- n)))
502                (/ n d)))
503            ;;greater than 1
504            (ash (if (minusp number) (- fraction) fraction) exponent)))))
505    (rational number)))
506#|
507(defun testrat (&optional (n 1000))
508  (dotimes (i n)
509    (let* (( numerator (random (ash 1 63)))
510          (denominator (random (ash 1 63)))
511          (sign  (if (zerop (random 2)) 1 -1))
512          (trial (float (/ (* sign numerator) denominator)))
513          (rat (rationalize trial)))
514      (when (not (= (float rat) trial))
515        (error "Rationalize failed. Input ~s Rational ~s Float ~s" trial rat (float rat))))))
516
517; smallest fails in 3.0 - powers of 2 - works here but we cheat a bit
518(defun testrat2 ()
519  (let ((f least-positive-double-float))
520    (dotimes (i 100)
521      (when (not (= (float (rationalize f)) f))
522        (cerror "a" "rat failed ~s ~s" f i))
523      (setq f (* f 2)))))
524
525; fails a lot in 3.0 - not powers of 2 - works here
526(defun testrat3 ()
527  (let ((f least-positive-double-float))
528    (dotimes (i 1000)
529      (let ((f2 (* (+ i i 1) f)))
530        (when (not (= (float (rationalize f2)) f2))
531          (cerror "a" "rat failed ~s ~s" f2 i)))))
532  (let ((f least-negative-double-float))
533    (dotimes (i 1000)
534      (let ((f2 (* (+ i i 1) f)))
535        (when (not (= (float (rationalize f2)) f2))
536          (cerror "a" "rat failed ~s ~s" f2 i))))))
537
538(defun testrat31 ()
539  (let ((f least-positive-short-float))
540    (dotimes (i 1000)
541      (let ((f2 (* (+ i i 1) f)))
542        (when (not (= (float (rationalize f2)) f2))
543          (cerror "a" "rat failed ~s ~s" f2 i)))))
544  (let ((f least-negative-short-float))
545    (dotimes (i 1000)
546      (let ((f2 (* (+ i i 1) f)))
547        (when (not (= (float (rationalize f2)) f2))
548          (cerror "a" "rat failed ~s ~s" f2 i))))))
549
550; works in 3.0 - and here
551(defun testrat4 ()
552  (let ((f least-positive-normalized-double-float))
553    (dotimes (i 1000)
554      (let ((f2 (* (+ i i 1) f)))
555        (when (not (= (float (rationalize f2)) f2))
556          (cerror "a" "rat failed ~s ~s" f2 i)))))
557  (let ((f least-negative-normalized-double-float))
558    (dotimes (i 100)
559      (let ((f2 (* (+ i i 1) f)))
560        (when (not (= (float (rationalize f2)) f2))
561          (cerror "a" "rat failed ~s ~s" f2 i))))))
562       
563   
564|#
565
566#| now in l1-numbers.lisp
567(defun logeqv (&lexpr numbers)
568  (let* ((count (%lexpr-count numbers)))
569    (declare (fixnum count))
570    (if (zerop count)
571      -1
572      (let* ((n0 (%lisp-word-ref numbers count)))
573        (if (= count 1)
574          (require-type n0 'integer)
575          (do* ((i 1 (1+ i)))
576               ((= i count) n0)
577            (declare (fixnum i))
578            (declare (optimize (speed 3) (safety 0)))
579            (setq n0 (logeqv-2 (%lexpr-ref numbers count i) n0))))))))
580|#
581
582
583(defparameter *boole-ops* 
584  (vector
585   #'(lambda (i1 i2) (declare (ignore i1 i2)) 0)
586   #'(lambda (i1 i2) (declare (ignore i1 i2)) -1)
587   #'(lambda (i1 i2) (declare (ignore i2)) i1)
588   #'(lambda (i1 i2) (declare (ignore i1)) i2)
589   #'(lambda (i1 i2) (declare (ignore i2)) (lognot i1))
590   #'(lambda (i1 i2) (declare (ignore i1)) (lognot i2))
591   #'(lambda (i1 i2) (logand i1 i2))
592   #'(lambda (i1 i2) (logior i1 i2))
593   #'(lambda (i1 i2) (logxor i1 i2))
594   #'(lambda (i1 i2) (logeqv i1 i2))
595   #'(lambda (i1 i2) (lognand i1 i2))
596   #'(lambda (i1 i2) (lognor i1 i2))
597   #'(lambda (i1 i2) (logandc1 i1 i2))
598   #'(lambda (i1 i2) (logandc2 i1 i2))
599   #'(lambda (i1 i2) (logorc1 i1 i2))
600   #'(lambda (i1 i2) (logorc2 i1 i2))))
601 
602
603
604;===> Change these constants to match maclisp!!
605(defun boole (op integer1 integer2)
606  "Bit-wise boolean function on two integers. Function chosen by OP:
607        0       BOOLE-CLR
608        1       BOOLE-SET
609        2       BOOLE-1
610        3       BOOLE-2
611        4       BOOLE-C1
612        5       BOOLE-C2
613        6       BOOLE-AND
614        7       BOOLE-IOR
615        8       BOOLE-XOR
616        9       BOOLE-EQV
617        10      BOOLE-NAND
618        11      BOOLE-NOR
619        12      BOOLE-ANDC1
620        13      BOOLE-ANDC2
621        14      BOOLE-ORC1
622        15      BOOLE-ORC2"
623  (unless (and (typep op 'fixnum)
624               (locally (declare (fixnum op))
625                 (and (>= op 0)
626                      (<= op 15))))
627    (report-bad-arg op '(integer 0 15)))
628  (funcall (%svref *boole-ops* op)
629           (require-type integer1 'integer)
630           (require-type integer2 'integer)))
631
632
633(defun %integer-power (b e)
634  (declare (type unsigned-byte e))
635  (if (zerop e)
636    (+ 1 (* b 0))
637    (if (eql b 2)
638      (ash 1 e)
639      (do* ((next (ash e -1) (ash e -1))
640            (oddexp (oddp e) (oddp e))
641            (total (if oddexp b 1) (if oddexp (* b total) total)))
642           ((zerop next) total)
643        (declare (type unsigned-byte next))
644        (setq b (* b b) e next)))))
645
646(defun signum (x)
647  "If NUMBER is zero, return NUMBER, else return (/ NUMBER (ABS NUMBER))."
648  (cond ((complexp x) (if (zerop x) x (/ x (abs x))))
649        ((rationalp x) (if (plusp x) 1 (if (zerop x) 0 -1)))
650        ((zerop x) (float 0.0 x))
651        (t (float-sign x))))
652
653
654
655; Thanks to d34676@tansei.cc.u-tokyo.ac.jp (Akira KURIHARA)
656(defun isqrt (n &aux n-len-quarter n-half n-half-isqrt
657                init-value iterated-value)
658  "Return the root of the nearest integer less than n which is a perfect
659   square.  Argument n must be a non-negative integer"
660  (cond
661   ((eql n 0) 0)
662   ; this fails sometimes - do we care? 70851992595801818865024053174 or #x80000000
663   ; maybe we do - its used by dotimes
664   ;((not (int>0-p n)) (report-bad-arg n '(integer 0))) ;'unsigned-byte)) ; Huh?
665   ((or (not (integerp n))(minusp n))(report-bad-arg n '(integer 0)))
666   ((> n 24)            ; theoretically (> n 7) ,i.e., n-len-quarter > 0
667    (setq n-len-quarter (ash (integer-length n) -2))
668    (setq n-half (ash n (- (ash n-len-quarter 1))))
669    (setq n-half-isqrt (isqrt n-half))
670    (setq init-value (ash (1+ n-half-isqrt) n-len-quarter))
671    (loop
672      (setq iterated-value (ash (+ init-value (floor n init-value)) -1))
673      (if (not (< iterated-value init-value))
674        (return init-value)
675        (setq init-value iterated-value))))
676   ((> n 15) 4)
677   ((> n  8) 3)
678   ((> n  3) 2)
679   (t 1)))
680
681
682(defun sinh (x)
683  "Return the hyperbolic sine of NUMBER."
684  (if (complexp x) 
685    (/ (- (exp x) (exp (- x))) 2)
686    (if (typep x 'double-float)
687      (%double-float-sinh! x (%make-dfloat))
688      #+32-bit-target
689      (ppc32::with-stack-short-floats ((sx x))
690        (%single-float-sinh! sx (%make-sfloat)))
691      #+64-bit-target
692        (%single-float-sinh (%short-float x)))))
693
694
695(defun cosh (x)
696  "Return the hyperbolic cosine of NUMBER."
697  (if (complexp x) 
698    (/ (+ (exp x) (exp (- x))) 2)
699    (if (typep x 'double-float)
700      (%double-float-cosh! x (%make-dfloat))
701      #+32-bit-target
702      (ppc32::with-stack-short-floats ((sx x))
703        (%single-float-cosh! sx (%make-sfloat)))
704      #+64-bit-target
705      (%single-float-cosh (%short-float x)))))
706
707(defun tanh (x)
708  "Return the hyperbolic tangent of NUMBER."
709  (if (complexp x) 
710    (/ (sinh x) (cosh x))
711    (if (typep x 'double-float)
712      (%double-float-tanh! x (%make-dfloat))
713      #+32-bit-target
714      (ppc32::with-stack-short-floats ((sx x))
715        (%single-float-tanh! sx (%make-sfloat)))
716      #+64-bit-target
717      (%single-float-tanh (%short-float x)))))
718
719(defun asinh (x)
720  "Return the hyperbolic arc sine of NUMBER."
721  (if (complexp x) 
722    (log (+ x (sqrt (+ 1 (* x x)))))
723    (if (typep x 'double-float)
724      (%double-float-asinh! x (%make-dfloat))
725      #+32-bit-target
726      (ppc32::with-stack-short-floats ((sx x))
727        (%single-float-asinh! sx (%make-sfloat)))
728      #+64-bit-target
729      (%single-float-asinh (%short-float x)))))
730
731(defun acosh (x)
732  "Return the hyperbolic arc cosine of NUMBER."
733  (if (and (realp x) (<= 1.0 x))
734    (if (typep x 'double-float)
735      (%double-float-acosh! x (%make-dfloat))
736      #+32-bit-target
737      (ppc32::with-stack-short-floats ((sx x))
738        (%single-float-acosh! sx (%make-sfloat)))
739      #+64-bit-target
740      (%single-float-acosh (%short-float x)))
741    (* 2 (log (+ (sqrt (/ (1+ x) 2)) (sqrt (/ (1- x) 2)))))))
742
743(defun atanh (x)
744  "Return the hyperbolic arc tangent of NUMBER."
745  (if (and (realp x) (<= -1.0 (setq x (float x)) 1.0))
746    (if (typep x 'double-float)
747      (%double-float-atanh! x (%make-dfloat))
748      #+32-bit-target
749      (%single-float-atanh! x (%make-sfloat))
750      #+64-bit-target
751      (%single-float-atanh x))
752    (/ (log (/ (+ 1 x) (- 1 x))) 2)))
753
754
755(defun ffloor (number &optional divisor)
756  "Same as FLOOR, but returns first value as a float."
757  (multiple-value-bind (q r) (floor number divisor)
758    (values (float q (if (floatp r) r 0.0)) r)))
759
760(defun fceiling (number &optional divisor)
761  "Same as CEILING, but returns first value as a float."
762  (multiple-value-bind (q r) (ceiling number divisor)
763    (values (float q (if (floatp r) r 0.0)) r)))
764
765(defun ftruncate (number &optional divisor)
766  "Same as TRUNCATE, but returns first value as a float."
767  (multiple-value-bind (q r) (truncate number divisor)
768    (values (float q (if (floatp r) r 0.0)) r)))
769
770(defun fround (number &optional divisor)
771  "Same as ROUND, but returns first value as a float."
772  (multiple-value-bind (q r) (round number divisor)
773    (values (float q (if (floatp r) r 0.0)) r)))
774
775(defun rational (number)
776  "RATIONAL produces a rational number for any real numeric argument. This is
777  more efficient than RATIONALIZE, but it assumes that floating-point is
778  completely accurate, giving a result that isn't as pretty."
779  (if (floatp number)
780    (multiple-value-bind (s e sign)
781        (number-case number
782          (short-float
783           (integer-decode-short-float number))
784          (double-float
785           (integer-decode-double-float number)))
786      (if (eq sign -1) (setq s (- s)))
787      (if (%iminusp e)
788        (/ s (ash 1 (%i- 0 e)))
789        (ash s e)))
790    (if (rationalp number)
791      number
792      (report-bad-arg number 'real))))
793
794; make power tables for floating point reader
795(progn
796  (setq float-powers-of-5 (make-array 23))
797  (let ((array float-powers-of-5))
798    (dotimes (i 23)
799      (setf (svref array i)  (float (expt 5 i) 0.0d0))))
800  (setq integer-powers-of-5 (make-array (+ 12 (floor 324 12))))
801  (let ((array integer-powers-of-5))
802    (dotimes (i 12)
803      (setf (svref array i)  (expt 5 i)))
804    (dotimes (i (floor 324 12))
805      (setf (svref array (+ i 12)) (expt 5 (* 12 (1+ i)))))))
806
807
808(provide 'numbers)
809
Note: See TracBrowser for help on using the repository browser.