source: trunk/ccl/lib/db-io.lisp @ 7470

Last change on this file since 7470 was 7470, checked in by gz, 14 years ago

Allow the possibility that headers can be stored somewhere other than "ccl:":
A new variable, *interfaces-root*, default "ccl:", can be set to change the
root headers directory.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 62.6 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2001 Clozure Associates
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;;; The "CDB" files used here are similar (but not identical) to those
18;;; used in the Unix CDB package <http://cr.yp.to/cdb.html>.  The primary
19;;; known & intentional differences are:
20;;;
21;;; a) key values, record positions, and other 32-bit metadata in the
22;;;    files are stored in native (vice little-endian) order.
23;;; b) hash values are always non-negative fixnums.
24;;;
25;;; I haven't thought of a compelling reason to attempt full compatibility.
26;;;
27;;; The basic idea is that the database files are created in a batch
28;;; process and are henceforth read-only (e.g., lookup is optimized by
29;;; making insertion & deletion impractical or impossible.)  That's
30;;; just about exactly what we want here.
31;;;
32;;; Those of you keeping score may notice that this is the third or forth
33;;; database format that OpenMCL has used for its interface database.
34;;; As always, this will hopefully be the last format change; the fact
35;;; that this code is self-contained (doesn't depend on any Unix database
36;;; library) should make it easier to port to other platforms.
37
38(in-package "CCL")
39
40(defparameter *interface-abi-version* 2)
41(defparameter *min-interface-abi-version* 1)
42
43(defconstant cdb-hash-mask (1- (ash 1 29)))
44
45(defun cdb-hash (buf len)
46  (declare (fixnum len))
47  (let* ((h 5381))
48    (declare (fixnum h))
49    (dotimes (i len (logand h cdb-hash-mask))
50      (setq h (+ h (the fixnum (logand cdb-hash-mask (ash h 5)))))
51      (setq h (logxor (the (unsigned-byte 8) (%get-unsigned-byte buf i)) h)))))
52
53(defconstant cdbm-hplist 1000)
54
55(defmacro hp-h (v n)
56  `(aref ,v (* ,n 2)))
57
58(defmacro hp-p (v n)
59  `(aref ,v (1+ (* ,n 2))))
60
61(defstruct cdbm-hplist
62  (hp (make-array (* 2 cdbm-hplist)
63                  :element-type '(unsigned-byte 32)
64                  :initial-element 0))
65  (next nil)
66  (num 0))
67
68
69
70
71
72#+openmcl
73(progn
74  ;;; Given a (possibly logical) PATHNAME, return a corresponding namestring
75  ;;; suitable for passing to an OS file-open call.
76  (defun cdb-native-namestring (pathname)
77    (native-translated-namestring pathname))
78 
79  ;;; Open the file specified by PATHNAME for output and return a
80  ;;; small integer "file id" (fid).
81  (defun fid-open-output (pathname)
82    (let ((dir (make-pathname :type nil :name nil :defaults pathname)))
83      (unless (probe-file dir)
84        (error "The directory ~S does not exist, cannot open/create ~S"
85               dir pathname)))
86    (let* ((id (fd-open (cdb-native-namestring pathname)
87                        (logior #$O_WRONLY #$O_CREAT #$O_TRUNC))))
88      (if (< id 0)
89        (%errno-disp id pathname)
90        id)))
91
92  ;;; Open the file specified by PATHNAME for input and return a
93  ;;; file id.
94  (defun fid-open-input (pathname)
95    (let* ((id (fd-open (cdb-native-namestring pathname) #$O_RDONLY)))
96      (if (< id 0)
97        (%errno-disp id pathname)
98        id)))
99 
100  ;;; Read N octets from FID into BUF.  Return #of octets read or error.
101  (defun fid-read (fid buf n)
102    (let* ((count (fd-read fid buf n)))
103      (if (< count 0)
104        (%errno-disp count "reading from file")
105        count)))
106
107  ;;; Write N octets to FID from BUF.  Return #of octets written or error.
108  (defun fid-write (fid buf n)
109    (let* ((count (fd-write fid buf n)))
110      (if (< count 0)
111        (%errno-disp count "writing to file")
112        count)))
113
114  ;;; Return the absolute (octet) position of FID.
115  (defun fid-pos (fid)
116    (fd-tell fid))
117
118  ;;; Return the current size of the file referenced by FID, in
119  ;;; octets.
120  (defun fid-size (fid)
121    (fd-size fid))
122 
123  ;;; Seek to specified position (relative to file start.)
124  (defun fid-seek (fid pos)
125    (fd-lseek fid pos #$SEEK_SET))
126
127  ;;; Guess what this does ?
128  (defun fid-close (fid)
129    (fd-close fid))
130
131  ;;; Allocate a block of size N bytes (via malloc, #_NewPtr, etc.)
132  (defun cdb-alloc (n)
133    (malloc n))
134
135  ;;; Free a block allocated by cdb-alloc.
136  (defun cdb-free (block)
137    (free block))
138  )
139
140;;; I suppose that if we wanted to store these things in little-endian
141;;; order this'd be the place to swap bytes ...
142(defun fid-write-u32 (fid val)
143  (%stack-block ((valptr 4))
144    (setf (%get-unsigned-long valptr) val)
145    (fid-write fid valptr 4)
146    val))
147
148(defun fid-read-u32 (fid)
149  (%stack-block ((valptr 4))
150    (fid-read fid valptr 4)
151    (%get-unsigned-long valptr)))
152
153
154
155;;; Write N elements of a vector of type (UNSIGNED-BYTE 32) to file-id
156;;; FID, starting at element START.  The vector should be a simple
157;;; (non-displaced) array.
158(defun fid-write-u32-vector (fid v n start)
159  (let* ((remaining-octets (* n 4))
160         (start-octet (* start 4))
161         (bufsize 2048))
162    (%stack-block ((buf bufsize))
163      (do* ()
164           ((zerop remaining-octets))
165        (let* ((chunksize (min remaining-octets bufsize)))
166          (%copy-ivector-to-ptr v start-octet buf 0 chunksize)
167          (fid-write fid buf chunksize)
168          (incf start-octet chunksize)
169          (decf remaining-octets chunksize))))))
170
171(defstruct cdbx
172  fid                                   ;a small integer denoting a file
173  pathname)                             ;that file's pathname
174
175;;; A CDBM is used to create a database.
176(defstruct (cdbm (:include cdbx))
177  (final (make-array (* 256 2)
178                     :element-type '(unsigned-byte 32)
179                     :initial-element 0))
180  (count (make-array 256 :element-type '(unsigned-byte 32) :initial-element 0))
181  (start (make-array 256 :element-type '(unsigned-byte 32) :initial-element 0))
182  (head nil)
183  (split nil)
184  (hash nil)
185  (numentries 0)
186  )
187
188(defun cdbm-open (pathname)
189  (let* ((fid (fid-open-output pathname))
190         (cdbm (make-cdbm :fid fid :pathname pathname))
191         (final (cdbm-final cdbm)))
192    ;;; Write the (empty) final table to the start of the file.  Twice.
193    (fid-write-u32-vector fid final (length final) 0)
194    (fid-write-u32-vector fid final (length final) 0)
195    cdbm))
196
197;;; Note a newly-added <key,value> pair's file position and hash code.
198(defun %cdbm-add-hash-pos (cdbm hash pos)
199  (let* ((head (cdbm-head cdbm)))
200    (when (or (null head)
201              (>= (cdbm-hplist-num head) cdbm-hplist))
202      (setq head (make-cdbm-hplist))
203      (setf (cdbm-hplist-next head) (cdbm-head cdbm)
204            (cdbm-head cdbm) head))
205    (let* ((num (cdbm-hplist-num head))
206           (hp (cdbm-hplist-hp head)))
207      (setf (hp-h hp num) hash
208            (hp-p hp num) pos))
209    (incf (cdbm-hplist-num head))
210    (incf (cdbm-numentries cdbm))))
211
212(defun cdbm-put (cdbm key data)
213  (let* ((fid (cdbm-fid cdbm))
214         (pos (fid-pos fid))
215         (keylen (pref key :cdb-datum.size))
216         (keyptr (pref key :cdb-datum.data))
217         (datalen (pref data :cdb-datum.size))
218         (hash (cdb-hash keyptr keylen)))
219    (fid-write-u32 fid keylen)
220    (fid-write-u32 fid datalen)
221    (fid-write fid keyptr keylen)
222    (fid-write fid (pref data :cdb-datum.data) datalen)
223    (%cdbm-add-hash-pos cdbm hash pos)))
224
225(defun %cdbm-split (cdbm)
226  (let* ((count (cdbm-count cdbm))
227         (start (cdbm-start cdbm))
228         (numentries (cdbm-numentries cdbm)))
229    (dotimes (i 256) (setf (aref count i) 0))
230    (do* ((x (cdbm-head cdbm) (cdbm-hplist-next x)))
231         ((null x))
232      (do* ((i (cdbm-hplist-num x))
233            (hp (cdbm-hplist-hp x)))
234           ((zerop i))
235        (decf i)
236        (incf (aref count (logand 255 (hp-h hp i))))))
237    (let* ((memsize 1))
238      (dotimes (i 256)
239        (let* ((u (* 2 (aref count i))))
240          (if (> u memsize)
241            (setq memsize u))))
242      (incf memsize numentries)
243      (let* ((split (make-array (the fixnum (* 2 memsize))
244                                :element-type '(unsigned-byte 32))))
245        (setf (cdbm-split cdbm) split)
246        (setf (cdbm-hash cdbm)
247              (make-array (- (* 2 memsize)
248                             (* 2 numentries))
249                          :element-type '(unsigned-byte 32)
250                          :displaced-to split
251                          :displaced-index-offset (* 2 numentries)))
252        (let* ((u 0))
253          (dotimes (i 256)
254            (incf u (aref count i))
255            (setf (aref start i) u)))
256
257        (do* ((x (cdbm-head cdbm) (cdbm-hplist-next x)))
258             ((null x))
259          (do* ((i (cdbm-hplist-num x))
260                (hp (cdbm-hplist-hp x)))
261               ((zerop i))
262            (decf i)
263            (let* ((idx (decf (aref start (logand 255 (hp-h hp i))))))
264              (setf (hp-h split idx) (hp-h hp i)
265                    (hp-p split idx) (hp-p hp i)))))))))
266
267(defun %cdbm-throw (cdbm pos b)
268  (let* ((count (aref (cdbm-count cdbm) b))
269         (len (* 2 count))
270         (hash (cdbm-hash cdbm))
271         (split (cdbm-split cdbm)))
272    (let* ((final (cdbm-final cdbm)))
273      (setf (aref final (* 2 b)) pos
274            (aref final (1+ (* 2 b))) len))
275    (unless (zerop len)
276      (dotimes (j len)
277        (setf (hp-h hash j) 0
278              (hp-p hash j) 0))
279      (let* ((hpi (aref (cdbm-start cdbm) b)))
280        (dotimes (j count)
281          (let* ((where (mod (ash (hp-h split hpi) -8) len)))
282            (do* ()
283                 ((zerop (hp-p hash where)))
284              (incf where)
285              (if (= where len)
286                (setq where 0)))
287            (setf (hp-p hash where) (hp-p split hpi)
288                  (hp-h hash where) (hp-h split hpi)
289                  hpi (1+ hpi))))))
290    len))
291
292;;; Write data structures to the file, then close the file.
293(defun cdbm-close (cdbm)
294  (when (cdbm-fid cdbm)
295    (%cdbm-split cdbm)
296    (let* ((hash (cdbm-hash cdbm))
297           (fid (cdbm-fid cdbm))
298           (pos (fid-pos fid)))
299      (dotimes (i 256)
300        (let* ((len (%cdbm-throw cdbm pos i)))
301          (dotimes (u len)
302            (fid-write-u32 fid (hp-h hash u))
303            (fid-write-u32 fid (hp-p hash u))
304            (incf pos 8))))
305      (write-cdbm-trailer cdbm)
306      (fid-seek fid (* 256 2 4)) ; skip the empty "final" table, write the new one
307      (let* ((final (cdbm-final cdbm)))
308        (fid-write-u32-vector fid final (length final) 0))
309      (fid-close fid)
310      (setf (cdbm-fid cdbm) nil))))
311
312(defun write-cdbm-trailer (cdbm)
313  (let* ((string (format nil "~s ~s ~d " "OpenMCL Interface File" (backend-name *target-backend*) *interface-abi-version*)))
314    (%stack-block ((buf 512))
315      (%cstr-pointer string buf)
316      (fid-write (cdbm-fid cdbm) buf 512))))
317
318     
319;;; A CDB is used to access a database.
320(defstruct (cdb (:include cdbx))
321  (lock (make-lock)))
322
323     
324;;; Do the bytes on disk match KEY ?
325(defun %cdb-match (fid key keylen)
326  (%stack-block ((buf keylen))
327    (fid-read fid buf keylen)
328    (dotimes (i keylen t)
329      (unless (= (the fixnum (%get-unsigned-byte key i))
330                 (the fixnum (%get-unsigned-byte buf i)))
331        (return)))))
332
333;;; Seek to file position of data associated with key.  Return length
334;;; of data (or NIL if no matching key.)
335(defun %cdb-seek (fid key keylen)
336  (let* ((hash (cdb-hash key keylen)))
337    (fid-seek fid (+ (* 256 2 4) (* 8 (logand hash 255))))
338    (let* ((pos (fid-read-u32 fid))
339           (lenhash (fid-read-u32 fid)))
340      (unless (zerop lenhash)
341        (let* ((h2 (mod (ash hash -8) lenhash)))
342          (dotimes (i lenhash)
343            (fid-seek fid (+ pos (* 8 h2)))
344            (let* ((hashed-key (fid-read-u32 fid))
345                   (poskd (fid-read-u32 fid)))
346              (when (zerop poskd)
347                (return-from %cdb-seek nil))
348              (when (= hashed-key hash)
349                (fid-seek fid poskd)
350                (let* ((hashed-key-len (fid-read-u32 fid))
351                       (data-len (fid-read-u32 fid)))
352                  (when (= hashed-key-len keylen)
353                    (if (%cdb-match fid key keylen)
354                      (return-from %cdb-seek data-len)))))
355              (if (= (incf h2) lenhash)
356                (setq h2 0)))))))))
357
358;;; This should only be called with the cdb-lock of the containing cdb
359;;; held.
360(defun %cdb-get (fid key value)
361  (setf (pref value :cdb-datum.size) 0
362        (pref value :cdb-datum.data) (%null-ptr))
363  (when fid
364    (let* ((datalen (%cdb-seek fid
365                               (pref key :cdb-datum.data)
366                               (pref key :cdb-datum.size))))
367      (when datalen
368        (let* ((buf (cdb-alloc datalen)))
369          (fid-read fid buf datalen)
370          (setf (pref value :cdb-datum.size) datalen
371                (pref value :cdb-datum.data) buf)))
372      value)))
373
374(defun cdb-get (cdb key value)
375  (with-lock-grabbed ((cdb-lock cdb))
376    (%cdb-get (cdb-fid cdb) key value)))
377
378(defun cdb-subdirectory-path (&optional (ftd *target-ftd*))
379  (let* ((ftd-name (ftd-interface-db-directory ftd))
380         (ftd-dir (pathname-directory ftd-name)))
381    (assert (equalp (pathname-host ftd-name) "ccl"))
382    (assert (eq (car ftd-dir) :absolute))
383    (cdr ftd-dir)))
384
385(defvar *interfaces-root* "ccl:")
386
387(defun open-interface-db-pathname (name d)
388  (let* ((db-path (make-pathname :host (pathname-host *interfaces-root*)
389                                 :directory (append
390                                             (or (pathname-directory *interfaces-root*)
391                                                 '(:absolute))
392                                             (cdb-subdirectory-path *target-ftd*))))
393         (path (merge-pathnames name
394                                (merge-pathnames (interface-dir-subdir d) db-path))))
395    (cdb-open path)))
396
397(defun cdb-open (pathname)
398  (if (probe-file pathname)
399    (let* ((cdb (make-cdb :fid (fid-open-input (cdb-native-namestring pathname))
400                          :pathname (namestring pathname))))
401      (cdb-check-trailer cdb))
402    (progn
403      (if (probe-file (make-pathname :name nil :type nil :defaults pathname))
404        (warn "Interface file ~s does not exist." pathname)
405        (warn "Interface file ~s does not exist, and the containing directory does not exist.~%This may mean that that the \"ccl:\" logical-pathname host has not been properly initialized. " (translate-logical-pathname pathname)))
406      (make-cdb :fid nil :pathname (namestring pathname)))))
407
408(defun cdb-check-trailer (cdb)
409  (flet ((error-with-cdb (string &rest args)
410           (error "Error in interface file at ~s: ~a"
411                  (cdb-pathname cdb) (apply #'format nil string args))))
412    (let* ((fid (cdb-fid cdb)))
413      (fid-seek fid (- (fid-size fid) 512))
414      (%stack-block ((buf 512))
415        (fid-read fid buf 512)
416        (let* ((string (make-string 512)))
417          (dotimes (i 512)
418            (setf (%scharcode string i) (%get-unsigned-byte buf i)))
419          (with-input-from-string (s string)
420            (let* ((sig (ignore-errors (read s)))
421                   (target (ignore-errors (read s)))
422                   (version (ignore-errors (read s))))
423              (if (equal sig "OpenMCL Interface File")
424                (if (eq target (backend-name *target-backend*))
425                  (if (and version
426                           (>= version *min-interface-abi-version*)
427                           (<=  version *interface-abi-version*))
428                    cdb
429                    (error-with-cdb "Wrong interface ABI version. Expected ~d, got ~d" *interface-abi-version* version))
430                  cdb #+nil(error-with-cdb "Wrong target."))
431                (error-with-cdb "Missing interface file signature.  Obsolete version?")))))))))
432
433                 
434   
435(defun cdb-close (cdb)
436  (let* ((fid (cdb-fid cdb)))
437    (setf (cdb-fid cdb) nil)
438    (when fid
439      (fid-close fid))
440    t))
441
442(defmethod print-object ((cdb cdbx) stream)
443  (print-unreadable-object (cdb stream :type t :identity t)
444    (let* ((fid (cdb-fid cdb)))
445      (format stream "~s [~a]" (cdb-pathname cdb) (or fid "closed")))))
446
447
448(defun cdb-enumerate-keys (cdb &optional (predicate #'true))
449  "Returns a list of all keys (strings) in the open .cdb file CDB which
450satisfy the optional predicate PREDICATE."
451  (with-lock-grabbed ((cdb-lock cdb))
452    (let* ((keys ())
453           (fid (cdb-fid cdb)))
454      (dotimes (i 256 keys)
455        (fid-seek fid (+ (* 256 2 4) (* 8 i)))
456        (let* ((pos (fid-read-u32 fid))
457               (n (fid-read-u32 fid)))
458          (dotimes (j n)
459            (fid-seek fid (+ pos (* 8 j) 4))
460            (let* ((posk (fid-read-u32 fid)))
461              (unless (zerop posk)
462                (fid-seek fid posk)
463                (let* ((hashed-key-len (fid-read-u32 fid)))
464                  ;; Skip hashed data length
465                  (fid-read-u32 fid)
466                  (let* ((string (make-string hashed-key-len)))
467                    (%stack-block ((buf hashed-key-len))
468                      (fid-read fid buf hashed-key-len)
469                      (dotimes (k hashed-key-len)
470                        (setf (schar string k)
471                              (code-char (%get-unsigned-byte buf k)))))
472                    (when (funcall predicate string)
473                      (push (copy-seq string) keys))))))))))))
474                                        ;
475                 
476
477
478(defstruct ffi-type
479  (ordinal nil)
480  (defined nil)
481  (string)
482  (name)                                ; a keyword, uppercased or NIL
483)
484
485(defmethod print-object ((x ffi-type) out)
486  (print-unreadable-object (x out :type t :identity t)
487    (format out "~a" (ffi-type-string x))))
488
489(defvar *ffi-prefix* "")
490
491(defstruct (ffi-mem-block (:include ffi-type))
492  fields
493  (anon-global-id )
494  (alt-alignment-bits nil))
495
496(defstruct (ffi-union (:include ffi-mem-block)
497                      (:constructor
498                       make-ffi-union (&key
499                                       string name
500                                       &aux
501                                       (anon-global-id
502                                        (unless name
503                                          (concatenate 'string
504                                                       *ffi-prefix*
505                                                       "-" string)))))))
506
507
508(defstruct (ffi-struct (:include ffi-mem-block)
509                       (:constructor
510                       make-ffi-struct (&key
511                                       string name
512                                       &aux
513                                       (anon-global-id
514                                        (unless name
515                                          (concatenate 'string
516                                                       *ffi-prefix*
517                                                       "-" string)))))))
518
519(defstruct (ffi-typedef (:include ffi-type))
520  (type))
521
522(defstruct (ffi-objc-class (:include ffi-type))
523  super-foreign-name
524  protocol-names
525  own-ivars
526  )
527
528(defstruct (ffi-objc-method)
529  class-name
530  arglist
531  result-type
532  flags)
533
534(defstruct (ffi-objc-message (:include ffi-type))
535  methods)
536                           
537
538(defun ffi-struct-reference (s)
539  (or (ffi-struct-name s) (ffi-struct-anon-global-id s)))
540
541(defun ffi-union-reference (u)
542  (or (ffi-union-name u) (ffi-union-anon-global-id u)))
543
544(defstruct (ffi-function (:include ffi-type))
545  arglist
546  return-value)
547   
548
549
550(defconstant db-string-constant 0)
551(defconstant db-read-string-constant 1)
552(defconstant db-s32-constant 2)
553(defconstant db-u32-constant 3)
554(defconstant db-float-constant 4)
555(defconstant db-double-constant 5)
556(defconstant db-char-constant 6)
557
558(defparameter *arg-spec-encoding*
559  '((#\Space . :void)
560    (#\a . :address)
561    (#\F . :signed-fullword)
562    (#\f . :unsigned-fullword)
563    (#\H . :signed-halfword)
564    (#\h . :unsigned-halfword)
565    (#\B . :signed-byte)
566    (#\b . :unsigned-byte)
567    (#\s . :single-float)
568    (#\d . :double-float)
569    (#\L . :signed-doubleword)
570    (#\l . :unsigned-doubleword)
571    (#\r . :record)))
572
573
574
575(defun decode-arguments (string)
576  (let* ((result nil))
577    (collect ((args))
578      (do* ((i 0 (1+ i)))
579           ((= i (length string)) (values (args) result))
580        (declare (fixnum i))
581        (let* ((ch (schar string i))
582               (val (if (or (eql ch #\r) (eql ch #\u) (eql ch #\t))
583                      (let* ((namelen (char-code (schar string (incf i))))
584                             (name (make-string namelen)))
585                        (dotimes (k namelen)
586                          (setf (schar name k)
587                                (schar string (incf i))))
588                        (setq name (escape-foreign-name name))
589                        (if (eql ch #\r)
590                          `(:struct ,name)
591                          (if (eql ch #\u)
592                            `(:union ,name)
593                            name)))
594                      (cdr (assoc ch *arg-spec-encoding*)))))
595          (if result
596            (args val)
597            (setq result val)))))))
598
599
600;;; encoded external function looks like:
601;;; byte min-args
602;;; byte name-length
603;;; name-length bytes of name
604;;; result+arg specs
605
606(defun extract-db-function (datum)
607  (let* ((val nil)
608         (dsize (pref datum :cdb-datum.size)))
609    (with-macptrs ((dptr))
610      (%setf-macptr dptr (pref datum :cdb-datum.data))
611      (unless (%null-ptr-p dptr)
612        (let* ((min-args (%get-byte dptr))
613               (name-len (%get-byte dptr 1))
614               (external-name (%str-from-ptr (%inc-ptr dptr 2) name-len))
615               (encoding-len (- dsize (+ 2 name-len)))
616               (encoding (make-string encoding-len)))
617          (declare (dynamic-extent encoding))
618          (%str-from-ptr (%inc-ptr dptr (+ 2 name-len)) encoding-len encoding)
619          (cdb-free (pref datum :cdb-datum.data))
620          (multiple-value-bind (args result)
621              (decode-arguments encoding)
622            (setq val (make-external-function-definition
623                       :entry-name external-name
624                       :arg-specs args
625                       :result-spec result
626                       :min-args min-args))))))
627    val))
628
629(defun db-lookup-function (cdb name)
630  (when cdb
631    (rletZ ((value :cdb-datum)
632            (key :cdb-datum))
633      (with-cstrs ((keyname (string name)))
634        (setf (pref key :cdb-datum.data) keyname
635              (pref key :cdb-datum.size) (length (string name))
636              (pref value :cdb-datum.data) (%null-ptr)
637              (pref value :cdb-datum.size) 0)
638        (cdb-get cdb key value)
639        (extract-db-function value)))))
640
641
642
643
644       
645(defun extract-db-constant-value (datum)
646  (let* ((val nil)
647         (dsize (pref datum :cdb-datum.size)))
648    (with-macptrs ((dptr))
649      (%setf-macptr dptr (pref datum :cdb-datum.data))
650      (unless (%null-ptr-p dptr)
651        (let* ((class (pref dptr :dbm-constant.class)))
652          (setq val
653                (ecase class
654                  ((#.db-string-constant #.db-read-string-constant)
655                   (let* ((str (%str-from-ptr (%inc-ptr dptr 4) (- dsize 4))))
656                     (if (eql class db-read-string-constant)
657                       (read-from-string str)
658                       str)))
659                  (#.db-s32-constant (pref dptr :dbm-constant.value.s32))
660                  (#.db-u32-constant (pref dptr :dbm-constant.value.u32))
661                  (#.db-float-constant (pref dptr :dbm-constant.value.single-float))
662                  (#.db-double-constant (pref dptr :dbm-constant.value.double-float))
663                  (#.db-char-constant (code-char (pref dptr :dbm-constant.value.u32)))))
664          (cdb-free (pref datum :cdb-datum.data)))))
665    val))
666
667
668
669(defun db-lookup-constant (cdb name)
670  (when cdb
671    (rletZ ((value :cdb-datum)
672            (key :cdb-datum))
673      (with-cstrs ((keyname (string name)))
674        (setf (pref key :cdb-datum.data) keyname
675              (pref key :cdb-datum.size) (length (string name))
676              (pref value :cdb-datum.data) (%null-ptr)
677              (pref value :cdb-datum.size) 0)
678        (cdb-get cdb key value)
679        (extract-db-constant-value value)))))
680   
681
682
683(defun db-define-string-constant (cdbm name val &optional (class db-string-constant))
684  (let* ((dsize (+ 4 (length val))))
685    (%stack-block ((valbuf dsize))
686      (dotimes (i (length val))
687        (setf (%get-unsigned-byte valbuf (the fixnum (+ 4 i)))
688              (%scharcode val i)))
689      (setf (%get-long valbuf) class)
690      (rletZ ((content :cdb-datum)
691              (key :cdb-datum))
692        (setf (pref content :cdb-datum.size) dsize
693              (pref content :cdb-datum.data) valbuf)
694        (with-cstrs ((keyname (string name)))
695          (setf (pref key :cdb-datum.size) (length (string name))
696                (pref key :cdb-datum.data) keyname)
697          (cdbm-put cdbm key content))))))
698     
699(defun db-define-constant (cdbm name val)
700  (typecase val
701    (string (db-define-string-constant cdbm name val))
702    ((or (unsigned-byte 32)
703         (signed-byte 32)
704         short-float
705         double-float
706         character)
707     (rletZ ((constant :dbm-constant)
708             (content :cdb-datum)
709             (key :cdb-datum))
710       (etypecase val
711         ((signed-byte 32)
712          (setf (pref constant :dbm-constant.value.s32) val)
713          (setf (pref constant :dbm-constant.class) db-s32-constant))
714         ((unsigned-byte 32)
715          (setf (pref constant :dbm-constant.value.u32) val)
716          (setf (pref constant :dbm-constant.class) db-u32-constant))
717         (short-float
718          (setf (pref constant :dbm-constant.value.single-float) val)
719          (setf (pref constant :dbm-constant.class) db-float-constant))
720         (double-float
721          (setf (pref constant :dbm-constant.value.double-float) val)
722          (setf (pref constant :dbm-constant.class) db-double-constant))
723         (character
724          (setf (pref constant :dbm-constant.value.u32) (char-code val))
725          (setf (pref constant :dbm-constant.class) db-char-constant)))
726       (setf (pref content :cdb-datum.data) constant
727             (pref content :cdb-datum.size) (record-length :dbm-constant))
728       (with-cstrs ((keyname (string name)))
729         (setf (pref key :cdb-datum.data) keyname
730               (pref key :cdb-datum.size) (length (string name)))
731         (cdbm-put cdbm key content))))
732    (t (db-define-string-constant cdbm name (format nil "~a" val) db-read-string-constant))))
733
734
735 
736
737(defmacro with-new-db-file ((var pathname) &body body)
738  (let* ((db (gensym)))
739    `(let* (,db)
740      (unwind-protect
741           (let* ((,var (setq ,db (cdbm-open ,pathname))))
742             ,@body)
743        (when ,db (cdbm-close ,db))))))
744
745
746
747(defun interface-db-pathname (name d &optional (ftd *target-ftd*))
748  (merge-pathnames name
749                   (merge-pathnames (interface-dir-subdir d)
750                                    (ftd-interface-db-directory ftd))))
751
752(def-ccl-pointers reset-db-files ()
753  (do-interface-dirs (d)
754    (setf (interface-dir-constants-interface-db-file d) nil
755          (interface-dir-functions-interface-db-file d) nil
756          (interface-dir-records-interface-db-file d) nil
757          (interface-dir-types-interface-db-file d) nil
758          (interface-dir-vars-interface-db-file d) nil
759          (interface-dir-objc-classes-interface-db-file d) nil
760          (interface-dir-objc-methods-interface-db-file d) nil)))
761
762(defun db-constants (dir)
763  (or (interface-dir-constants-interface-db-file dir)
764      (setf (interface-dir-constants-interface-db-file dir)
765            (open-interface-db-pathname "constants.cdb" dir))))
766
767(defun db-objc-classes (dir)
768  (or (interface-dir-objc-classes-interface-db-file dir)
769      (setf (interface-dir-objc-classes-interface-db-file dir)
770            (open-interface-db-pathname "objc-classes.cdb" dir))))
771
772(defun db-objc-methods (dir)
773  (or (interface-dir-objc-methods-interface-db-file dir)
774      (setf (interface-dir-objc-methods-interface-db-file dir)
775            (open-interface-db-pathname "objc-methods.cdb" dir))))
776
777(defun db-vars (dir)
778  (or (interface-dir-vars-interface-db-file dir)
779      (setf (interface-dir-vars-interface-db-file dir)
780            (open-interface-db-pathname "vars.cdb" dir))))
781
782(defun db-types (dir)
783  (or (interface-dir-types-interface-db-file dir)
784      (setf (interface-dir-types-interface-db-file dir)
785            (open-interface-db-pathname "types.cdb" dir))))
786
787(defun db-records (dir)
788  (or (interface-dir-records-interface-db-file dir)
789      (setf (interface-dir-records-interface-db-file dir)
790            (open-interface-db-pathname "records.cdb" dir))))
791
792(defun db-functions (dir)
793  (or (interface-dir-functions-interface-db-file dir)
794      (setf (interface-dir-functions-interface-db-file dir)
795            (open-interface-db-pathname "functions.cdb" dir))))
796
797(defun load-os-constant (sym &optional query)
798  (let* ((val (do-interface-dirs (d)
799                    (let* ((v (db-lookup-constant (db-constants d) sym)))
800                      (when v (return v))))))
801    (if query
802      (not (null val))
803      (if val
804        (let* ((*record-source-file* nil))
805          (%defconstant sym val)
806          val)
807        (error "Constant not found: ~s" sym)))))
808
809(defun %load-var (name &optional query-only)
810  (let* ((ftd *target-ftd*)
811         (string (if (getf (ftd-attributes ftd)
812                           :prepend-underscores)
813                   (concatenate 'string "_" (string name))
814                   (string name)))
815         (fv (gethash string (fvs))))
816    (unless fv
817      (with-cstrs ((cstring string))
818        (let* ((type
819                (do-interface-dirs (d)
820                  (let* ((vars (db-vars d)))
821                    (when vars
822                      (rletZ ((value :cdb-datum)
823                              (key :cdb-datum))
824                        (setf (pref key :cdb-datum.data) cstring
825                              (pref key :cdb-datum.size) (length string)
826                              (pref value :cdb-datum.data) (%null-ptr)
827                              (pref value :cdb-datum.size) 0)
828                        (cdb-get vars key value)
829                        (let* ((vartype (extract-db-type value ftd)))
830                          (when vartype (return vartype)))))))))
831          (when type
832            (setq fv (%cons-foreign-variable string type))
833            (resolve-foreign-variable fv nil)
834            (setf (gethash string (fvs)) fv)))))
835    (if query-only
836      (not (null fv))
837      (or fv (error "Foreign variable ~s not found" string)))))
838
839
840(set-dispatch-macro-character 
841 #\# #\&
842 (qlfun |#&-reader| (stream char arg)
843   (declare (ignore char arg))
844   (let* ((package (find-package (ftd-interface-package-name *target-ftd*))))
845     (multiple-value-bind (sym query)
846         (%read-symbol-preserving-case
847          stream
848          package)
849       (unless *read-suppress*
850         (let* ((fv (%load-var sym query)))
851           (if query
852             fv
853             (%foreign-access-form `(%reference-external-entry-point (load-time-value ,fv))
854                                   (fv.type fv)
855                                   0
856                                   nil))))))))
857
858
859             
860
861(defstruct objc-message-info
862  message-name
863  methods                               ; all methods
864  ambiguous-methods                     ; partitioned by signature
865  req-args
866  flags
867  protocol-methods
868  lisp-name
869  selector)
870
871
872
873   
874(defstruct objc-method-info
875  message-info
876  class-name
877  class-pointer                         ;canonical, in some sense
878  arglist
879  result-type
880  flags
881  signature
882  signature-info
883  )
884
885
886
887(defmethod print-object ((m objc-method-info) stream)
888  (print-unreadable-object (m stream :type t :identity t)
889    (format stream "~c[~a ~a]"
890            (if (getf (objc-method-info-flags m) :class)
891              #\+
892              #\-)
893            (let* ((name (objc-method-info-class-name m)))
894              (if (getf (objc-method-info-flags m) :protocol)
895                (format nil "<~a>" name)
896                name))
897            (objc-message-info-message-name
898                          (objc-method-info-message-info m)))))
899
900(defun extract-db-objc-message-info (datum message-name info &optional
901                                           (ftd *target-ftd*))
902  (with-macptrs ((buf))
903    (%setf-macptr buf (pref datum :cdb-datum.data))
904    (unless (%null-ptr-p buf)
905      (unless info
906        (setq info
907              (make-objc-message-info
908               :message-name (string message-name))))
909      (let* ((p 0)
910             (nmethods 0)
911             (nargs 0))
912        (multiple-value-setq (nmethods p) (%decode-uint buf p))
913        (multiple-value-setq (nargs p) (%decode-uint buf p))
914        (dotimes (i nmethods)
915          (let* ((flag-byte (prog1 (%get-unsigned-byte buf p)
916                              (incf p)))
917                 (is-class-method (logbitp 0 flag-byte))
918                 (is-protocol-method (logbitp 1 flag-byte))
919                 (class-name ())
920                 (result-type ())
921                 (arg-types ())
922                 (arg-type ()))
923            (multiple-value-setq (class-name p) (%decode-name buf p t))
924            (multiple-value-setq (result-type p) (%decode-type buf p ftd t))
925            (dotimes (i nargs)
926              (multiple-value-setq (arg-type p) (%decode-type buf p ftd t))
927              (push arg-type arg-types))
928            (unless (dolist (m (objc-message-info-methods info))
929                      (when (and (eq (getf (objc-method-info-flags m) :class)  is-class-method)
930                                 (string= (objc-method-info-class-name m)
931                                          class-name))
932                        (return t)))
933              (let* ((flags ()))
934                (if is-class-method
935                  (setf (getf flags :class) t))
936                (if is-protocol-method
937                  (setf (getf flags :protocol) t))
938                (push (make-objc-method-info
939                                     :message-info info
940                                     :class-name class-name
941                                     :arglist (nreverse arg-types)
942                                     :result-type result-type
943                                     :flags flags)
944                 (objc-message-info-methods info))))))
945        (cdb-free (pref datum :cdb-datum.data))))
946    info))
947
948(defun db-note-objc-method-info (cdb message-name message-info)
949  (when cdb
950    (rletZ ((value :cdb-datum)
951            (key :cdb-datum))
952      (with-cstrs ((keyname (string message-name)))
953        (setf (pref key :cdb-datum.data) keyname
954              (pref key :cdb-datum.size) (length (string message-name))
955              (pref value :cdb-datum.data) (%null-ptr)
956              (pref value :cdb-datum.size) 0)
957        (cdb-get cdb key value)
958        (extract-db-objc-message-info value message-name message-info)))))
959
960(defun lookup-objc-message-info (message-name &optional message-info)
961  (do-interface-dirs (d)
962    (setq message-info
963          (db-note-objc-method-info (db-objc-methods d) message-name message-info)))
964  message-info)
965
966(defun %find-objc-class-info (name)
967  (do-interface-dirs (d)
968    (let* ((info (db-lookup-objc-class (db-objc-classes d) name)))
969      (when info (return info)))))
970
971(defun load-external-function (sym query)
972  (let* ((def (or (do-interface-dirs (d)
973                    (let* ((f (db-lookup-function (db-functions d) sym)))
974                      (when f (return f))))
975                  (unless query
976                    (error "Foreign function not found: ~s" sym)))))
977    (if query
978      (not (null def))
979      (progn
980        (setf (gethash sym (ftd-external-function-definitions
981                            *target-ftd*)) def)
982        (setf (macro-function sym) #'%external-call-expander)
983        sym))))
984
985(defun %read-symbol-preserving-case (stream package)
986  (let* ((case (readtable-case *readtable*))
987         (query nil)
988         (error nil)
989         (sym nil))
990    (let* ((*package* package))
991      (unwind-protect
992           (progn
993             (setf (readtable-case *readtable*) :preserve)
994             (when (eq #\? (peek-char t stream nil nil))
995               (setq query t)
996               (read-char stream))
997             (multiple-value-setq (sym error)
998               (handler-case (read stream nil nil)
999                 (error (condition) (values nil condition)))))
1000        (setf (readtable-case *readtable*) case)))
1001    (when error
1002      (error error))
1003    (values sym query)))
1004
1005(set-dispatch-macro-character 
1006 #\# #\$
1007 (qlfun |#$-reader| (stream char arg)
1008   (declare (ignore char))
1009   (let* ((package (find-package (ftd-interface-package-name *target-ftd*))))
1010     (multiple-value-bind (sym query)
1011         (%read-symbol-preserving-case
1012            stream
1013            package)
1014       (unless *read-suppress*
1015         (etypecase sym
1016           (symbol
1017            (if query
1018              (load-os-constant sym query)
1019              (progn
1020                (when (eq (symbol-package sym) package)
1021                  (unless arg (setq arg 0))
1022                  (ecase arg
1023                    (0
1024                     (unless (and (constant-symbol-p sym)
1025                                  (not (eq (%sym-global-value sym)
1026                                           (%unbound-marker-8))))
1027                       (load-os-constant sym)))
1028                    (1 (makunbound sym) (load-os-constant sym))))
1029                sym)))
1030           (string
1031            (let* ((val 0)
1032                   (len (length sym)))
1033              (dotimes (i 4 val)
1034                (let* ((ch (if (< i len) (char sym i) #\space)))
1035                  (setq val (logior (ash val 8) (char-code ch)))))))))))))
1036
1037(set-dispatch-macro-character #\# #\_
1038  (qlfun |#_-reader| (stream char arg)
1039    (declare (ignore char))
1040    (unless arg (setq arg 0))
1041    (multiple-value-bind (sym query)
1042        (%read-symbol-preserving-case
1043                 stream
1044                 (find-package (ftd-interface-package-name *target-ftd*)))
1045      (unless *read-suppress*
1046        (unless (and sym (symbolp sym)) (report-bad-arg sym 'symbol))
1047        (if query
1048          (load-external-function sym t)
1049          (let* ((def (if (eql arg 0)
1050                        (gethash sym (ftd-external-function-definitions
1051                                      *target-ftd*)))))
1052            (if (and def (eq (macro-function sym) #'%external-call-expander))
1053              sym
1054              (load-external-function sym nil))))))))
1055
1056
1057
1058(eval-when (:compile-toplevel :execute)
1059  (defconstant encoded-type-void 0)
1060  (defconstant encoded-type-signed-32 1)
1061  (defconstant encoded-type-unsigned-32 2)
1062  (defconstant encoded-type-signed-8 3)
1063  (defconstant encoded-type-unsigned-8 4)
1064  (defconstant encoded-type-signed-16 5)
1065  (defconstant encoded-type-unsigned-16 6)
1066  (defconstant encoded-type-signed-n 7) ;N
1067  (defconstant encoded-type-unsigned-n 8) ;N
1068  (defconstant encoded-type-single-float 9)
1069  (defconstant encoded-type-double-float 10)
1070  (defconstant encoded-type-pointer 11) ; <type>
1071  (defconstant encoded-type-array 12) ; <size> <type>
1072  (defconstant encoded-type-named-struct-ref 13); <tag>
1073  (defconstant encoded-type-named-union-ref 14) ;<tag>
1074  (defconstant encoded-type-named-type-ref 15) ; <name>
1075  (defconstant encoded-type-anon-struct-ref 16) ; <tag>
1076  (defconstant encoded-type-anon-union-ref 17) ; <tag>
1077  (defconstant encoded-type-bitfield-marker 18) ; <nbits>
1078  )
1079
1080
1081(defconstant encoded-type-type-byte (byte 5 0))
1082(defconstant encoded-type-align-byte (byte 3 5)
1083  "alignment in octets, if other than \"natural\" alignment,")
1084
1085;;; Constants & function names get saved verbatim.
1086;;; Record, type, and field names get escaped.
1087
1088(defun encode-name (name &optional verbatim)
1089  (if (null name)
1090    (list 0)
1091    (let* ((string
1092            (if (and (typep name 'keyword)
1093                     (not verbatim))
1094              (unescape-foreign-name name)
1095              (string name)))
1096           (length (length string)))
1097      (cons length (map 'list #'char-code string)))))
1098
1099(defun encode-ffi-field (field)
1100  (destructuring-bind (name type offset width) field
1101  `(,@(encode-name name)
1102    ,@(encode-ffi-type type)
1103    ,@(encode-uint offset)
1104    ,@(encode-uint width))))
1105
1106(defun encode-ffi-field-list (fields)
1107  (let* ((len (length fields)))
1108    (labels ((encode-fields (fields)
1109               (if fields
1110                 `(,@(encode-ffi-field (car fields)) ,@(encode-fields (cdr fields))))))
1111      `(,@(encode-uint len) ,@(encode-fields fields)))))
1112
1113(defun encode-ffi-union (u)
1114  (let* ((name (ffi-union-name u))
1115         (alt-align-in-bytes-mask (ash (or (ffi-union-alt-alignment-bits u)
1116                                      0)
1117                                  (- 5 3))))
1118    (if name
1119      `(,(logior encoded-type-named-union-ref alt-align-in-bytes-mask)
1120        ,@(encode-name name)
1121        ,@(encode-ffi-field-list (ffi-union-fields u)))
1122      `(,(logior encoded-type-anon-union-ref alt-align-in-bytes-mask)
1123        ,@(encode-ffi-field-list (ffi-union-fields u))))))
1124
1125(defun encode-ffi-struct (s)
1126  (let* ((name (ffi-struct-name s))
1127         (alt-align-in-bytes-mask (ash (or (ffi-struct-alt-alignment-bits s)
1128                                           0)
1129                                       (- 5 3))))
1130    (if name
1131      `(,(logior encoded-type-named-struct-ref alt-align-in-bytes-mask)
1132        ,@(encode-name (ffi-struct-name s))
1133        ,@(encode-ffi-field-list (ffi-struct-fields s)))
1134      `(,(logior encoded-type-anon-struct-ref alt-align-in-bytes-mask)
1135        ,@(encode-ffi-field-list (ffi-struct-fields s))))))
1136
1137(defun encode-ffi-objc-class (c)
1138  (let* ((protocols (ffi-objc-class-protocol-names c)))
1139    (labels ((encode-name-list (names)
1140               (if names
1141                 `(,@(encode-name (car names) t)
1142                   ,@(encode-name-list (cdr names))))))
1143      `(,@(encode-name (ffi-objc-class-string c))
1144        ,@(encode-name (ffi-objc-class-super-foreign-name c))
1145        ,@(encode-uint (length protocols))
1146        ,@(encode-name-list protocols)
1147        ,@(encode-ffi-field-list (ffi-objc-class-own-ivars c))))))
1148
1149
1150(defstruct db-objc-class-info
1151  class-name
1152  superclass-name
1153  protocols
1154  ivars
1155  instance-methods
1156  class-methods
1157  )
1158
1159(defun extract-db-objc-class (datum &optional (ftd *target-ftd*))
1160  (let* ((val nil))
1161    (with-macptrs ((buf))
1162      (%setf-macptr buf (pref datum :cdb-datum.data))
1163      (unless (%null-ptr-p buf)
1164        (let* ((p 0)
1165               (protocol-count 0)
1166               (class-name ())
1167               (superclass-name ())
1168               (protocol-name ())
1169               (ivars ()))
1170          (collect ((protocols))
1171            (multiple-value-setq (class-name p) (%decode-name buf p t))
1172            (multiple-value-setq (superclass-name p) (%decode-name buf p t))
1173            (multiple-value-setq (protocol-count p) (%decode-uint buf p))
1174            (dotimes (i protocol-count)
1175              (multiple-value-setq (protocol-name p) (%decode-name buf p t))
1176              (protocols protocol-name))
1177            (setq ivars (%decode-field-list buf p ftd))
1178            (cdb-free (pref datum :cdb-datum.data))
1179            (setq val (make-db-objc-class-info
1180                       :class-name class-name
1181                       :superclass-name superclass-name
1182                       :ivars ivars
1183                       :protocols (protocols)
1184                     ))))))
1185    val))
1186
1187(defun db-lookup-objc-class (cdb name)
1188  (when cdb
1189    (rletZ ((value :cdb-datum)
1190            (key :cdb-datum))
1191      (with-cstrs ((keyname (string name)))
1192        (setf (pref key :cdb-datum.data) keyname
1193              (pref key :cdb-datum.size) (length (string name))
1194              (pref value :cdb-datum.data) (%null-ptr)
1195              (pref value :cdb-datum.size) 0)
1196        (cdb-get cdb key value)
1197        (extract-db-objc-class value)))))
1198
1199(defun encode-u32 (val)
1200  `(,(ldb (byte 8 24) val)
1201    ,(ldb (byte 8 16) val)
1202    ,(ldb (byte 8 8) val)
1203    ,(ldb (byte 8 0) val)))
1204
1205(defun encode-uint (val)
1206  (collect ((bytes))
1207    (do* ((b (ldb (byte 7 0) val) (ldb (byte 7 0) val))
1208          (done nil))
1209         (done (bytes))
1210      (when (zerop (setq val (ash val -7)))
1211        (setq b (logior #x80 b) done t))
1212      (bytes b))))
1213
1214   
1215
1216(defun encode-ffi-type (spec)
1217  (case (car spec)
1218    (:primitive
1219     (let ((primtype (cadr spec)))
1220       (if (atom primtype)
1221         (case primtype
1222           (:float `(,encoded-type-single-float))
1223           (:double `(,encoded-type-double-float))
1224           (:void `(,encoded-type-void))
1225           (:signed `(,encoded-type-signed-32))
1226           (:unsigned `(,encoded-type-unsigned-32))
1227           ((:long-double :complex-int
1228                        :complex-float :complex-double :complex-long-double)
1229            (encode-ffi-type `(:struct ,primtype))))
1230         (ecase (car primtype)
1231           (* `(,encoded-type-pointer ,@(encode-ffi-type
1232                                           (if (eq (cadr primtype) t)
1233                                             `(:primitive :void)
1234                                             (cadr primtype)))))
1235           (:signed
1236            (case (cadr primtype)
1237              (32 `(,encoded-type-signed-32))
1238              (16 `(,encoded-type-signed-16))
1239              (8 `(,encoded-type-signed-8))
1240              (t `(,encoded-type-signed-n ,(cadr primtype)))))
1241           (:unsigned
1242            (case (cadr primtype)
1243              (32 `(,encoded-type-unsigned-32))
1244              (16 `(,encoded-type-unsigned-16))
1245              (8 `(,encoded-type-unsigned-8))
1246              (t `(,encoded-type-unsigned-n ,(cadr primtype)))))))))
1247     (:struct
1248      (let* ((s (cadr spec))
1249             (name (ffi-struct-name s))
1250             (alt-align-bytes-mask (ash (or (ffi-struct-alt-alignment-bits s)
1251                                            0)
1252                                        (- 5 3))))
1253      `(,(if name
1254             (logior encoded-type-named-struct-ref alt-align-bytes-mask)
1255             (logior encoded-type-anon-struct-ref alt-align-bytes-mask))
1256        ,@(encode-name (ffi-struct-reference s)))))
1257     (:union
1258      (let* ((u (cadr spec))
1259             (name (ffi-union-name u))
1260             (alt-align-bytes-mask (ash (or (ffi-union-alt-alignment-bits u)
1261                                            0)
1262                                        (- 5 3)))            )
1263      `(,(if name
1264             (logior encoded-type-named-union-ref alt-align-bytes-mask)
1265             (logior encoded-type-anon-union-ref alt-align-bytes-mask))
1266        ,@(encode-name (ffi-union-reference u)))))
1267     (:typedef
1268      `(,encoded-type-named-type-ref ,@(encode-name (ffi-typedef-name (cadr spec)))))
1269     (:pointer
1270      `(,encoded-type-pointer ,@(encode-ffi-type
1271                                   (if (eq (cadr spec) t)
1272                                     '(:primitive :void)
1273                                     (cadr spec)))))
1274     (:array
1275      `(,encoded-type-array ,@(encode-uint (cadr spec)) ,@(encode-ffi-type (caddr spec))))
1276     (t
1277      (break "Type spec = ~s" spec))))
1278
1279(defun encode-ffi-arg-type (spec)
1280  (case (car spec)
1281    (:primitive
1282     (let ((primtype (cadr spec)))
1283       (if (atom primtype)
1284         (case primtype
1285           (:float `(#\s))
1286           (:double `(#\d))
1287           (:void `(#\Space))
1288           (:signed `(#\F))
1289           (:unsigned `(f))
1290           ((:long-double :complex-int
1291                          :complex-float :complex-double :complex-long-double)           
1292            #|(encode-ffi-arg-type `(:struct ,primtype))|#
1293            `(#\?)))
1294         (ecase (car primtype)
1295           (* `(#\a))
1296           (:signed
1297            (let* ((nbits (cadr primtype)))
1298              (if (<= nbits 8)
1299                '(#\B)
1300                (if (<= nbits 16)
1301                  '(#\H)
1302                  (if (<= nbits 32)
1303                    '(#\F)
1304                    (if (<= nbits 64)
1305                      `(#\L)
1306                      '(#\?)))))))
1307           (:unsigned
1308            (let* ((nbits (cadr primtype)))
1309              (if (<= nbits 8)
1310                '(#\b)
1311                (if (<= nbits 16)
1312                  '(#\h)
1313                  (if (<= nbits 32)
1314                    '(#\f)
1315                    (if (<= nbits 64)
1316                      `(#\l)
1317                      '(#\?)))))))))))
1318    ((:struct :union)
1319     `(,(if (eq (car spec) :struct)
1320                #\r
1321                #\u)
1322           ,@(encode-name (ffi-struct-reference (cadr spec)))))
1323    (:typedef
1324     `(#\t ,@(encode-name (ffi-typedef-name (cadr spec)))))
1325    (:pointer
1326      `(#\a))
1327    (:array
1328      `(#\?))))
1329
1330(defun encode-ffi-arg-list (args)
1331  (if args
1332    `(,@(encode-ffi-arg-type (car args)) ,@(encode-ffi-arg-list (cdr args)))))
1333
1334(defvar *prepend-underscores-to-ffi-function-names* nil)
1335
1336(defun encode-ffi-function (f)
1337  (let* ((args (ffi-function-arglist f))
1338         (string (ffi-function-string f))
1339         (name (if *prepend-underscores-to-ffi-function-names*
1340                 (concatenate 'string "_" string)
1341                 string))
1342         (min-args (length args))
1343         (result (ffi-function-return-value f)))
1344    `(,min-args
1345      ,@(encode-name name t)            ; verbatim
1346      ,@(encode-ffi-arg-type result)
1347      ,@(encode-ffi-arg-list args))))
1348
1349(defun encode-ffi-objc-method (m)
1350  (let* ((flag-byte (logior (if (getf (ffi-objc-method-flags m) :class) 1 0)
1351                            (if (getf (ffi-objc-method-flags m) :protocol) 2 0))))
1352  `(,flag-byte
1353    ,@(encode-name (ffi-objc-method-class-name m) t)
1354    ,@(encode-ffi-type (ffi-objc-method-result-type m))
1355    ,@(apply #'append (mapcar #'encode-ffi-type (ffi-objc-method-arglist m))))))
1356
1357(defun save-ffi-objc-message (cdbm message)
1358  (let* ((methods (ffi-objc-message-methods message))
1359         (nmethods (length methods))
1360         (nargs (length (ffi-objc-method-arglist (car methods)))))
1361    (labels ((encode-objc-method-list (ml)
1362               (when ml
1363                 `(,@(encode-ffi-objc-method (car ml))
1364                   ,@(encode-objc-method-list (cdr ml))))))
1365      (db-write-byte-list cdbm
1366                          (ffi-objc-message-string message)
1367                          `(,@(encode-uint nmethods)
1368                            ,@(encode-uint nargs)
1369                            ,@(encode-objc-method-list methods))
1370                          t))))
1371 
1372   
1373(defun save-byte-list (ptr l)
1374  (do* ((l l (cdr l))
1375        (i 0 (1+ i)))
1376       ((null l))
1377    (let* ((b (car l)))
1378      (if (typep b 'character)
1379        (setq b (char-code b)))
1380      (setf (%get-unsigned-byte ptr i) b))))
1381
1382(defun db-write-byte-list (cdbm keyname bytes &optional verbatim)
1383  (let* ((len (length bytes)))
1384    (%stack-block ((p len))
1385      (save-byte-list p bytes)
1386      (rletZ ((contents :cdb-datum)
1387              (key :cdb-datum))
1388        (let* ((foreign-name
1389                (if verbatim
1390                  keyname
1391                  (unescape-foreign-name keyname))))
1392          (with-cstrs ((keystring foreign-name))
1393            (setf (pref contents :cdb-datum.data) p
1394                  (pref contents :cdb-datum.size) len
1395                  (pref key :cdb-datum.data) keystring
1396                  (pref key :cdb-datum.size) (length foreign-name))
1397            (cdbm-put cdbm key contents)))))))
1398
1399(defun save-ffi-function (cdbm fun)
1400  (let* ((encoding (encode-ffi-function fun)))
1401    (db-write-byte-list cdbm
1402                        (ffi-function-string fun)
1403                        encoding
1404                        t)))
1405
1406(defun save-ffi-typedef (cdbm def)
1407  (db-write-byte-list cdbm
1408                       (ffi-typedef-string def)
1409                       (encode-ffi-type (ffi-typedef-type def))
1410                       t))
1411
1412(defun save-ffi-struct (cdbm s)
1413  (db-write-byte-list cdbm (ffi-struct-reference s) (encode-ffi-struct s)))
1414
1415(defun save-ffi-union (cdbm u)
1416  (db-write-byte-list cdbm (ffi-union-reference u) (encode-ffi-union u)))
1417
1418
1419
1420(defun db-define-var (cdbm name type)
1421  (db-write-byte-list cdbm
1422                      (if *prepend-underscores-to-ffi-function-names*
1423                        (concatenate 'string "_" name)
1424                        name)
1425  (encode-ffi-type type) t))
1426
1427(defun save-ffi-objc-class (cdbm c)
1428  (db-write-byte-list cdbm (ffi-objc-class-name c) (encode-ffi-objc-class c)))
1429
1430
1431;;; An "uppercase-sequence" is a maximal substring of a string that
1432;;; starts with an uppercase character and doesn't contain any
1433;;; lowercase characters.
1434(defun count-uppercase-sequences (string)
1435  (let* ((state :lower)
1436         (nupper 0))
1437    (declare (fixnum nupper))
1438    (dotimes (i (length string) nupper)
1439      (let* ((ch (char string i)))
1440        (case state
1441          (:lower 
1442           (when (upper-case-p ch)
1443             (incf nupper)
1444             (setq state :upper)))
1445          (:upper
1446           (when (lower-case-p ch)
1447             (setq state :lower))))))))
1448
1449(defun escape-foreign-name (in &optional
1450                               (count (count-uppercase-sequences in)))
1451  (intern
1452   (if (zerop count)
1453     (string-upcase in)
1454     (let* ((len (length in))
1455            (j 0)
1456            (out (make-string (+ len (* 2 count))))
1457            (state :lower))
1458       (flet ((outch (ch)
1459                (setf (schar out j) ch)
1460                (incf j)
1461                ch))
1462         (dotimes (i len (progn (if (eq state :upper) (outch #\>)) out))
1463           (let* ((ch (char in i)))
1464             (cond ((and (upper-case-p ch) (eq state :lower))
1465                    (outch #\<)
1466                    (setq state :upper))
1467                   ((and (lower-case-p ch) (eq state :upper))
1468                    (outch #\>)
1469                    (setq state :lower)))
1470             (outch (char-upcase ch)))))))
1471   *keyword-package*))
1472
1473(defun unescape-foreign-name (key)
1474  (let* ((string (if (typep key 'symbol)
1475                   (string-downcase key)
1476                   (string key)))
1477         (nleftbrackets (count #\< string))
1478         (nrightbrackets (count #\> string))
1479         (nbrackets (+ nleftbrackets nrightbrackets)))
1480    (declare (fixnum nleftbrackets nrightbrackets nbrackets))
1481    (if (zerop nbrackets)
1482      string
1483      (if (/= nleftbrackets nrightbrackets)
1484        (error "Mismatched brackets in ~s." key)
1485        (let* ((len (length string))
1486               (out (make-string (- len nbrackets)))
1487               (j 0)
1488               (state :lower))
1489          (dotimes (i len out)
1490            (let* ((ch (schar string i)))
1491              (if (or (and (eq ch #\<)
1492                           (eq state :upper))
1493                      (and (eq ch #\>)
1494                           (eq state :lower)))
1495                (error "Mismatched brackets in ~s." key))
1496              (case ch
1497                (#\< (setq state :upper))
1498                (#\> (setq state :lower))
1499                (t (setf (schar out j) (if (eq state :upper)
1500                                         (char-upcase ch)
1501                                         (char-downcase ch))
1502                         j (1+ j)))))))))))
1503
1504       
1505       
1506(defun %decode-name (buf p &optional verbatim)
1507  (declare (type macptr buf) (fixnum p))
1508  (let* ((n (%get-unsigned-byte buf p)))
1509    (declare (fixnum n))
1510    (if (zerop n)
1511      (values nil (1+ p))
1512      (let* ((pname (%str-from-ptr (%inc-ptr buf (1+ p)) n)))
1513        (values (if verbatim pname (escape-foreign-name pname))
1514                (+ p (1+ n)))))))
1515
1516(defun %decode-u32 (buf p)
1517  (declare (fixnum p) (type macptr buf))
1518  (values (dpb
1519           (%get-unsigned-byte buf p)
1520           (byte 8 24)
1521           (dpb
1522            (%get-unsigned-byte buf (+ p 1))
1523            (byte 8 16)
1524            (dpb
1525             (%get-unsigned-byte buf (+ p 2))
1526             (byte 8 8)
1527             (%get-unsigned-byte buf (+ p 3)))))
1528          (+ p 4)))
1529
1530(defun %decode-uint (buf p)
1531  (do* ((val 0)
1532        (p p (1+ p))
1533        (shift 0 (+ shift 7))
1534        (done nil))
1535       (done (values val p))
1536    (let* ((b (%get-unsigned-byte buf p)))
1537      (setq done (logbitp 7 b) val (logior val (ash (logand b #x7f) shift))))))
1538       
1539 
1540;; Should return a FOREIGN-TYPE structure.
1541(defun %decode-type (buf p ftd &optional suppress-typedef-expansion)
1542  (declare (type macptr buf) (fixnum p))
1543  (let* ((q (1+ p)))
1544    (ecase (ldb encoded-type-type-byte (%get-unsigned-byte buf p))
1545      (#.encoded-type-void (values (parse-foreign-type :void) q))
1546      (#.encoded-type-signed-32 (values (svref *signed-integer-types* 32) q))
1547      (#.encoded-type-unsigned-32 (values (svref *unsigned-integer-types* 32) q))
1548      (#.encoded-type-signed-8 (values (svref *signed-integer-types* 8) q))
1549      (#.encoded-type-unsigned-8 (values (svref *unsigned-integer-types* 8) q))
1550      (#.encoded-type-signed-16 (values (svref *signed-integer-types* 16) q))
1551      (#.encoded-type-unsigned-16 (values (svref *unsigned-integer-types* 16) q))
1552      (#.encoded-type-signed-n (values (let* ((bits (%get-unsigned-byte buf q)))
1553                                         (if (<= bits 32)
1554                                           (svref *signed-integer-types* bits)
1555                                           (make-foreign-integer-type
1556                                            :signed t
1557                                            :bits bits)))
1558                                         (1+ q)))
1559      (#.encoded-type-unsigned-n (values (let* ((bits (%get-unsigned-byte buf q)))
1560                                         (if (<= bits 32)
1561                                           (svref *unsigned-integer-types* bits)
1562                                           (make-foreign-integer-type
1563                                            :signed nil
1564                                            :bits bits)))
1565                                           (1+ q)))
1566      (#.encoded-type-single-float (values (parse-foreign-type :float) q))
1567      (#.encoded-type-double-float (values (parse-foreign-type :double) q))
1568      (#.encoded-type-pointer (multiple-value-bind (target qq)
1569                                  (%decode-type buf q ftd suppress-typedef-expansion)
1570                                (values (make-foreign-pointer-type
1571                                         :to target
1572                                         :bits (getf (ftd-attributes ftd)
1573                                                     :bits-per-word)
1574                                         )
1575                                          qq)))
1576      (#.encoded-type-array
1577       (multiple-value-bind (size qq) (%decode-uint buf q)
1578         (multiple-value-bind (target qqq) (%decode-type buf qq ftd)
1579           (let* ((type-alignment (foreign-type-alignment target))
1580                  (type-bits (foreign-type-bits target)))
1581             (values (make-foreign-array-type
1582                      :element-type target
1583                      :dimensions (list size)
1584                      :alignment type-alignment
1585                      :bits (if type-bits
1586                              (* (align-offset type-bits type-alignment) size)))
1587                     qqq)))))
1588      (#.encoded-type-named-type-ref
1589       (multiple-value-bind (name qq) (%decode-name buf q)         
1590         (values (if suppress-typedef-expansion
1591                   name
1592                   (%parse-foreign-type name))
1593                 qq)))
1594      (#.encoded-type-named-struct-ref
1595       (multiple-value-bind (name qq) (%decode-name buf q)
1596         (values (or (info-foreign-type-struct name)
1597                     (setf (info-foreign-type-struct name)
1598                           (make-foreign-record-type :kind :struct
1599                                                     :name name)))
1600                 qq)))
1601      (#.encoded-type-named-union-ref
1602       (multiple-value-bind (name qq) (%decode-name buf q)
1603         (values (or (info-foreign-type-union name)
1604                     (setf (info-foreign-type-union name)
1605                           (make-foreign-record-type :kind :union
1606                                                     :name name)))
1607                 qq)))
1608      ((#.encoded-type-anon-struct-ref #.encoded-type-anon-union-ref)
1609       (multiple-value-bind (tag qq) (%decode-name buf q t)
1610         (values (load-record tag) qq))))))
1611
1612(defun extract-db-type (datum ftd)
1613  (let* ((data (pref datum :cdb-datum.data)))
1614    (unless (%null-ptr-p data)
1615      (prog1
1616          (%decode-type data 0 ftd)
1617        (cdb-free data)))))
1618
1619(defun %load-foreign-type (cdb name ftd)
1620  (when cdb
1621    (with-cstrs ((string (string name)))
1622      (rletZ ((contents :cdb-datum)
1623              (key :cdb-datum))
1624        (setf (pref key :cdb-datum.size) (length (string name))
1625            (pref key :cdb-datum.data) string
1626            (pref contents :cdb-datum.data) (%null-ptr)
1627            (pref contents :cdb-datum.size) 0)
1628      (cdb-get cdb key contents)
1629      (let* ((type (extract-db-type contents ftd)))
1630        (if type
1631          (%def-foreign-type (escape-foreign-name name) type ftd)))))))
1632
1633(defun load-foreign-type (name &optional (ftd *target-ftd*))
1634  (let* ((name (unescape-foreign-name name)))
1635    (do-interface-dirs (d ftd)
1636      (let* ((type (%load-foreign-type (db-types d) name ftd)))
1637        (when type (return type))))))
1638
1639(defun %decode-field (buf p ftd)
1640  (declare (type macptr buf) (fixnum p))
1641  (multiple-value-bind (name p) (%decode-name buf p)
1642    (multiple-value-bind (type p) (%decode-type buf p ftd)
1643      (multiple-value-bind (offset p) (%decode-uint buf p)
1644        (multiple-value-bind (width p) (%decode-uint buf p)
1645          (values (make-foreign-record-field :type type
1646                                             :name name
1647                                             :bits width
1648                                             :offset offset)
1649                  p))))))
1650
1651(defun %decode-field-list (buf p ftd)
1652  (declare (type macptr buf) (fixnum p))
1653  (let* ((n nil)
1654         (fields nil))
1655    (multiple-value-setq (n p) (%decode-uint buf p))
1656    (dotimes (i n (values (nreverse fields) p))
1657      (multiple-value-bind (field q) (%decode-field buf p ftd)
1658        (push field fields)
1659        (setq p q)))))
1660
1661(defun %determine-record-attributes (rtype parsed-fields &optional alt-align)
1662  (let* ((total-bits 0)
1663         (overall-alignment 1)
1664         #+(and darwinppc-target ppc32-target)
1665         (first-field-p t)
1666         (kind (foreign-record-type-kind rtype)))
1667    (dolist (field parsed-fields)
1668      (let* ((field-type (foreign-record-field-type field))
1669             (bits (ensure-foreign-type-bits field-type))
1670             (natural-alignment (foreign-type-alignment field-type))
1671             (alignment (if alt-align
1672                          (min natural-alignment alt-align)
1673                          #+(and darwinppc-target ppc32-target)
1674                          (if first-field-p
1675                            (progn
1676                              (setq first-field-p nil)
1677                              natural-alignment)
1678                            (min 32 natural-alignment))
1679                          #-(and darwinppc-target ppc32-target)
1680                          natural-alignment)))
1681        (unless bits
1682          (error "Unknown size: ~S"
1683                 (unparse-foreign-type field-type)))
1684        (unless alignment
1685          (error "Unknown alignment: ~S"
1686                 (unparse-foreign-type field-type)))
1687        (setq overall-alignment (max overall-alignment (if (= alignment 1) 32 alignment)))
1688        (ecase kind
1689          (:struct (let* ((imported-offset (foreign-record-field-offset field))
1690                          (offset (or imported-offset (align-offset total-bits alignment))))
1691                     (unless imported-offset
1692                       (setf (foreign-record-field-offset field) offset))
1693                     (setq total-bits (+ offset bits))))
1694          (:union (setq total-bits (max total-bits bits))))))
1695    (setf (foreign-record-type-fields rtype) parsed-fields
1696          (foreign-record-type-alignment rtype) (or
1697                                                 alt-align
1698                                                 overall-alignment)
1699          (foreign-record-type-bits rtype) (align-offset
1700                                            total-bits
1701                                            (or alt-align overall-alignment))
1702          (foreign-record-type-alt-align rtype) alt-align)
1703    rtype))
1704
1705(defun %decode-record-type (buf p ftd already)
1706  (declare (type macptr buf) (fixnum p))
1707  (let* ((rbyte (%get-unsigned-byte buf p))
1708         (rcode (ldb encoded-type-type-byte rbyte))
1709         (ralign-in-bytes (ldb encoded-type-align-byte rbyte))
1710         (alt-align (unless (zerop ralign-in-bytes)
1711                      (the fixnum (ash ralign-in-bytes 3)))))
1712    (declare (fixnum rbyte rcode ralign-in-bytes))
1713    (multiple-value-bind (name q)
1714        (case rcode
1715          ((#.encoded-type-anon-struct-ref #.encoded-type-anon-union-ref)
1716           (values nil (1+ p)))
1717          (t
1718           (%decode-name buf (1+ p))))
1719      (%determine-record-attributes
1720       (or already
1721           (if name
1722             (if (eql rcode encoded-type-named-struct-ref)
1723               (or (info-foreign-type-struct name)
1724                   (setf (info-foreign-type-struct name)
1725                         (make-foreign-record-type :kind :struct :name name)))
1726               (or (info-foreign-type-union name)
1727                   (setf (info-foreign-type-union name)
1728                         (make-foreign-record-type :kind :union :name name))))
1729             (make-foreign-record-type
1730              :kind (if (eql rcode encoded-type-anon-struct-ref)
1731                      :struct
1732                      :union)
1733              :name name)))
1734       (%decode-field-list buf q ftd)
1735       alt-align))))
1736
1737(defun extract-db-record (datum ftd already)
1738  (let* ((data (pref datum :cdb-datum.data)))
1739    (unless (%null-ptr-p data)
1740      (prog1
1741          (%decode-record-type data 0 ftd already)
1742        (cdb-free data)))))
1743
1744
1745(defun %load-foreign-record (cdb name ftd already)
1746  (when cdb
1747    (with-cstrs ((string (string name)))
1748      (rlet ((contents :cdb-datum)
1749             (key :cdb-datum))
1750        (setf (pref key :cdb-datum.size) (length (string name))
1751              (pref key :cdb-datum.data) string
1752              (pref contents :cdb-datum.data) (%null-ptr)
1753              (pref contents :cdb-datum.size) 0)
1754        (cdb-get cdb key contents)
1755        (extract-db-record contents ftd already)))))
1756
1757(defun load-record (name &optional (ftd *target-ftd*))
1758  ;; Try to destructively modify any info we already have.  Use the
1759  ;; "escaped" name (keyword) for the lookup here.
1760  (let* ((already (or (info-foreign-type-struct name ftd)
1761                      (info-foreign-type-union name ftd)))
1762         (name (unescape-foreign-name name)))
1763    (do-interface-dirs (d)
1764      (let* ((r (%load-foreign-record (db-records d) name ftd already)))
1765        (when r (return r))))))
1766
1767
Note: See TracBrowser for help on using the repository browser.