source: trunk/ccl/level-1/l1-aprims.lisp @ 6432

Last change on this file since 6432 was 6432, checked in by gb, 14 years ago

ELT, SET-ELT: don't assume that NTHCDR returns a CONS, signal the
right flavor of TYPE-ERROR if it doesn't.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 40.1 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;; L1-aprims.lisp
18
19
20(in-package "CCL")
21
22
23(let* ((standard-initial-bindings ())
24       (standard-initial-bindings-lock (make-read-write-lock)))
25
26  (defun standard-initial-bindings ()
27    (with-read-lock (standard-initial-bindings-lock)
28      (copy-list standard-initial-bindings)))
29
30  (defun define-standard-initial-binding (symbol initform)
31    (setq symbol (require-type symbol 'symbol))
32    (%proclaim-special symbol)
33    (unless (boundp symbol)
34      (set symbol (funcall initform)))
35    (with-write-lock (standard-initial-bindings-lock)
36      (let* ((pair (assoc symbol standard-initial-bindings)))
37        (if pair
38          (setf (cdr pair) initform)
39          (push (cons symbol initform) standard-initial-bindings))))
40    (record-source-file symbol 'variable)
41    symbol))
42
43(def-standard-initial-binding *package*)
44(def-standard-initial-binding *gensym-counter* 0)
45(def-standard-initial-binding *random-state* (initialize-random-state #xFBF1 9))
46
47
48(defun %badarg (arg type)
49  (%err-disp $XWRONGTYPE arg type))
50
51(defun atom (arg)
52  "Return true if OBJECT is an ATOM, and NIL otherwise."
53  (not (consp arg)))
54
55(defun list (&rest args)
56  "Return constructs and returns a list of its arguments."
57  args)
58
59(%fhave '%temp-list #'list)
60
61(defun list* (arg &rest others)
62  "Return a list of the arguments with last cons a dotted pair"
63  (cond ((null others) arg)
64        ((null (cdr others)) (cons arg (car others)))
65        (t (do ((x others (cdr x)))
66               ((null (cddr x)) (rplacd x (cadr x))))
67           (cons arg others))))
68
69
70
71(defun funcall (fn &rest args)
72  "Call FUNCTION with the given ARGUMENTS."
73  (declare (dynamic-extent args))
74  (apply fn args))
75
76
77(defun apply (function arg &rest args)
78  "Apply FUNCTION to a list of arguments produced by evaluating ARGUMENTS in
79   the manner of LIST*. That is, a list is made of the values of all but the
80   last argument, appended to the value of the last argument, which must be a
81   list."
82  (declare (dynamic-extent args))
83  (cond ((null args)
84         (apply function arg))
85        ((null (cdr args))
86         (apply function arg (car args)))
87        (t (do* ((a1 args a2)
88                 (a2 (cdr args) (cdr a2)))
89                ((atom (cdr a2))
90                 (rplacd a1 (car a2))
91                 (apply function arg args))))))
92
93
94;;; This is not fast, but it gets the functionality that
95;;; Wood and possibly other code depend on.
96(defun applyv (function arg &rest other-args)
97  (declare (dynamic-extent other-args))
98  (let* ((other-args (cons arg other-args))
99         (last-arg (car (last other-args)))
100         (last-arg-length (length last-arg))
101         (butlast-args (nbutlast other-args))
102         (rest-args (make-list last-arg-length))
103         (rest-args-tail rest-args))
104    (declare (dynamic-extent other-args rest-args))
105    (dotimes (i last-arg-length)
106      (setf (car rest-args-tail) (aref last-arg i))
107      (pop rest-args-tail))
108    (apply function (nconc butlast-args rest-args))))
109
110;;; This is slow, and since %apply-lexpr isn't documented either,
111;;; nothing in the world should depend on it.  This is just being
112;;; anal retentive.  VERY anal retentive.
113
114(defun %apply-lexpr (function arg &rest args)
115  (cond ((null args) (%apply-lexpr function arg))
116        (t (apply function arg (nconc (nbutlast args)
117                                      (collect-lexpr-args (car (last args)) 0))))))
118
119
120(defun values-list (arg)
121  "Return all of the elements of LIST, in order, as values."
122  (apply #'values arg))
123
124
125
126(defun make-list (size &key initial-element)
127  "Constructs a list with size elements each set to value"
128  (unless (and (typep size 'fixnum)
129               (>= (the fixnum size) 0))
130    (report-bad-arg size '(and fixnum unsigned-byte)))
131  (locally (declare (fixnum size))
132    (do* ((result '() (cons initial-element result)))
133        ((zerop size) result)
134      (decf size))))
135
136
137; copy-list
138
139(defun copy-list (list)
140  "Return a new list which is EQUAL to LIST."
141  (if list
142    (let ((result (cons (car list) '()) ))
143      (do ((x (cdr list) (cdr x))
144           (splice result
145                   (%cdr (%rplacd splice (cons (%car x) '() ))) ))
146          ((atom x) (unless (null x)
147                      (%rplacd splice x)) result)))))
148
149(defun alt-list-length (l)
150  "Detect (and complain about) cirucular lists; allow any atom to
151terminate the list"
152  (do* ((n 0 (1+ n))
153        (fast l)
154        (slow l))
155       ((atom fast) n)
156    (declare (fixnum n))
157    (setq fast (cdr fast))
158    (if (logbitp 0 n)
159      (if (eq (setq slow (cdr slow)) fast)
160        (%err-disp $XIMPROPERLIST l)))))
161
162
163(defun last (list &optional (n 1))
164  "Return the last N conses (not the last element!) of a list."
165  (if (and (typep n 'fixnum)
166           (>= (the fixnum n) 0))
167    (locally (declare (fixnum n))
168      (do* ((checked-list list (cdr checked-list))
169            (returned-list list)
170            (index 0 (1+ index)))
171           ((atom checked-list) returned-list)
172        (declare (type index index))
173        (if (>= index n)
174          (pop returned-list))))
175    (if (and (typep n 'bignum)
176             (> n 0))
177      (require-type list 'list)
178      (report-bad-arg  n 'unsigned-byte))))
179
180
181
182
183
184(defun nthcdr (index list)
185  "Performs the cdr function n times on a list."
186  (if (and (typep index 'fixnum)
187           (>= (the fixnum index) 0))
188      (locally (declare (fixnum index))
189        (dotimes (i index list)
190          (when (null (setq list (cdr list))) (return))))
191      (progn
192        (unless (typep index 'unsigned-byte)
193          (report-bad-arg index 'unsigned-byte))
194        (do* ((n index (- n most-positive-fixnum)))
195             ((typep n 'fixnum) (nthcdr n list))
196          (unless (setq list (nthcdr most-positive-fixnum list))
197            (return))))))
198
199
200(defun nth (index list)
201  "Return the nth object in a list where the car is the zero-th element."
202  (car (nthcdr index list)))
203
204
205(defun nconc (&rest lists)
206  (declare (dynamic-extent lists))
207  "Concatenates the lists given as arguments (by changing them)"
208  (do* ((top lists (cdr top)))
209       ((null top) nil)
210    (let* ((top-of-top (car top)))
211      (cond
212       ((consp top-of-top)
213        (let* ((result top-of-top)
214               (splice result))
215          (do* ((elements (cdr top) (cdr elements)))
216                 ((endp elements))
217            (let ((ele (car elements)))
218              (typecase ele
219                (cons (rplacd (last splice) ele)
220                      (setf splice ele))
221                (null (rplacd (last splice) nil))
222                (atom (if (cdr elements)
223                        (report-bad-arg ele 'list)
224                        (rplacd (last splice) ele)))
225                (t (report-bad-arg ele 'list)))))
226          (return result)))
227       ((null top-of-top) nil)
228       (t
229        (if (cdr top)
230          (report-bad-arg top-of-top 'list)
231          (return top-of-top)))))))
232
233
234(defvar %setf-function-names% (make-hash-table :weak t :test 'eq))
235
236(defun setf-function-name (sym)
237   (or (gethash sym %setf-function-names%)
238       (setf (gethash sym %setf-function-names%) (construct-setf-function-name sym))))
239
240
241
242                     
243
244(defconstant *setf-package* (or (find-package "SETF") (make-package "SETF" :use nil :external-size 1)))
245
246(defun construct-setf-function-name (sym)
247  (let ((pkg (symbol-package sym)))
248    (setq sym (symbol-name sym))
249    (if (null pkg)
250      (gentemp sym *setf-package*)
251      (values
252       (intern
253        ;I wonder, if we didn't check, would anybody report it as a bug?
254        (if (not (%str-member #\: (setq pkg (package-name pkg))))
255          (%str-cat pkg "::" sym)
256          (%str-cat (prin1-to-string pkg) "::" (princ-to-string sym)))
257        *setf-package*)))))
258
259(defun setf-function-name-p (name)
260  (and (consp name)
261             (consp (%cdr name))
262             (null (%cddr name))
263             (symbolp (%cadr name))
264             (eq (car name) 'setf)))
265
266(defun valid-function-name-p (name)
267  (if (symbolp name)                    ; Nil is a valid function name.  I guess.
268    (values t name)
269    (if (setf-function-name-p name)
270      (values t (setf-function-name (%cadr name)))
271      ; What other kinds of function names do we care to support ?
272      (values nil nil))))
273
274;;; Why isn't this somewhere else ?
275(defun ensure-valid-function-name (name)
276  (multiple-value-bind (valid-p nm) (valid-function-name-p name)
277    (if valid-p nm (error "Invalid function name ~s." name))))
278
279
280;;; Returns index if char appears in string, else nil.
281
282(defun %str-member (char string &optional start end)
283  (let* ((base-string-p (typep string 'simple-base-string)))
284    (unless base-string-p
285      (setq string (require-type string 'simple-string)))
286    (unless (characterp char)
287      (setq char (require-type char 'character)))
288    (do* ((i (or start 0) (1+ i))
289            (n (or end (uvsize string))))
290           ((= i n))
291        (declare (fixnum i n) (optimize (speed 3) (safety 0)))
292        (if (eq (schar (the simple-base-string string) i) char)
293          (return i)))))
294
295
296
297;;; Returns index of elt in vector, or nil if it's not there.
298(defun %vector-member (elt vector)
299  (unless (typep vector 'simple-vector)
300    (report-bad-arg vector 'simple-vector))
301  (dotimes (i (the fixnum (length vector)))
302    (when (eq elt (%svref vector i)) (return i))))
303
304(defun logical-pathname-p (thing) (istruct-typep thing 'logical-pathname))
305
306(progn
307;;; It's back ...
308(defun list-nreverse (list)
309  (nreconc list nil))
310
311;;; We probably want to make this smarter so that less boxing
312;;; (and bignum/double-float consing!) takes place.
313
314(defun vector-nreverse (v)
315  (let* ((len (length v))
316         (middle (ash (the fixnum len) -1)))
317    (declare (fixnum middle len))
318    (do* ((left 0 (1+ left))
319          (right (1- len) (1- right)))
320         ((= left middle) v)
321      (declare (fixnum left right))
322      (rotatef (aref v left) (aref v right)))))
323   
324(defun nreverse (seq)
325  "Return a sequence of the same elements in reverse order; the argument
326   is destroyed."
327  (when seq
328    (seq-dispatch seq
329                  (list-nreverse seq)
330                  (vector-nreverse seq)))))
331
332(defun nreconc (x y)
333  "Return (NCONC (NREVERSE X) Y)."
334  (do ((1st (cdr x) (if (endp 1st) 1st (cdr 1st)))
335       (2nd x 1st)              ;2nd follows first down the list.
336       (3rd y 2nd))             ;3rd follows 2nd down the list.
337      ((atom 2nd) 3rd)
338    (rplacd 2nd 3rd)))
339
340;;; The two-arg case is maybe a bit faster.  We -don't- want to
341;;; do the two-arg case repeatedly to implement the N-arg case.
342(defun append (&rest lists)
343  (declare (dynamic-extent lists))
344  "Construct a new list by concatenating the list arguments"
345  (if lists
346    (let* ((head (cons nil nil))
347           (tail head))
348      (declare (dynamic-extent head)
349               (cons head tail))
350      (do* ()
351           ((null lists) (cdr head))
352        (let* ((list (pop lists)))
353          (if (null lists)
354            (rplacd tail list)
355            (dolist (element list)
356                (setq tail (cdr (rplacd tail (cons element nil)))))))))))
357
358
359
360                     
361
362
363
364
365
366
367
368(progn
369(defun list-reverse (l)
370  (do* ((new ()))
371       ((null l) new)
372    (push (pop l) new)))
373
374; Again, it's worth putting more work into this when the dust settles.
375(defun vector-reverse (v)
376  (let* ((len (length v))
377         (new (make-array (the fixnum len) :element-type (array-element-type v))))   ; a LOT more work ...
378    (declare (fixnum len))
379    (do* ((left 0 (1+ left))
380          (right (1- len) (1- right)))
381         ((= left len) new)
382      (declare (fixnum left right))
383      (setf (uvref new left)
384            (aref v right)))))
385
386(defun reverse (seq)
387  "Return a new sequence containing the same elements but in reverse order."
388  (seq-dispatch seq (list-reverse seq) (vector-reverse seq)))
389)
390
391(defun check-sequence-bounds (seq start end)
392  (let* ((length (length seq)))
393    (declare (fixnum length))
394    (if (not end)
395      (setq end length)
396      (unless (typep end 'fixnum)
397        (report-bad-arg end 'fixnum)))
398    (unless (typep start 'fixnum)
399      (report-bad-arg start 'fixnum))
400    (locally (declare (fixnum start end))
401      (cond ((> end length)
402             (report-bad-arg end `(integer 0 (,length))))
403            ((< start 0)
404             (report-bad-arg start `(integer 0)))
405            ((< end 0)
406             (report-bad-arg end `(integer 0 (,length))))
407            ((> start end)
408             (report-bad-arg start `(integer 0 ,end)))
409            (t end)))))
410 
411
412(defun byte-length (string &optional  (start 0) end)
413  (setq end (check-sequence-bounds string start end))
414  (- end start))
415
416
417
418(defun make-cstring (string)
419  (let* ((len (length string)))
420    (declare (fixnum len))
421    (let* ((s (malloc (the fixnum (1+ len)))))
422      (setf (%get-byte s len) 0)
423      (multiple-value-bind (data offset) (array-data-and-offset string)
424        (dotimes (i len s)
425          (setf (%get-unsigned-byte s i) (%scharcode data (+ offset i))))
426        s))))
427
428
429(defun extended-string-p (thing)
430  (declare (ignore thing)))
431
432(defun simple-extended-string-p (thing)
433  (declare (ignore thing)))
434
435
436
437(defun move-string-bytes (source dest off1 off2 n)
438  (declare (fixnum off1 off2 n)
439           (simple-base-string source dest)
440           (optimize (speed 3) (safety 0)))
441  (dotimes (i n dest)
442    (setf (schar dest off2) (schar source off1))
443    (incf off1)
444    (incf off2)))
445
446
447(defun %str-cat (s1 s2 &rest more)
448  (declare (dynamic-extent more))
449  (require-type s1 'simple-string)
450  (require-type s2 'simple-string)
451  (let* ((len1 (length s1))
452         (len2 (length s2))
453         (len (%i+ len2 len1)))
454    (declare (optimize (speed 3)(safety 0)))
455    (dolist (s more)
456      (require-type s 'simple-string)
457      (setq len (+ len (length s))))
458    (let ((new-string (make-string len :element-type 'base-char)))
459      (move-string-bytes s1 new-string 0 0 len1)
460      (move-string-bytes s2 new-string 0 len1 len2)
461      (dolist (s more)
462        (setq len2 (%i+ len1 len2))
463        (move-string-bytes s new-string 0 len2 (setq len1 (length s))))
464      new-string)))
465
466
467(defun %substr (str start end)
468  (require-type start 'fixnum)
469  (require-type end 'fixnum)
470  (require-type str 'string)
471  (let ((len (length str)))
472    (multiple-value-bind (str strb)(array-data-and-offset str)
473      (let ((newlen (%i- end start)))
474        (when (%i> end len)(error "End ~S exceeds length ~S." end len))
475        (when (%i< start 0)(error "Negative start"))
476        (let ((new (make-string newlen)))
477          (do* ((i 0 (1+ i))
478                (pos (%i+ start strb) (1+ pos)))
479               ((= i newlen) new)
480            (declare (fixnum i pos))
481            (setf (schar new i) (schar str pos))))))))
482
483
484
485;;; 3 callers
486(defun %list-to-uvector (subtype list)   ; subtype may be nil (meaning simple-vector
487  (let* ((n (length list))
488         (new (%alloc-misc n (or subtype target::subtag-simple-vector))))  ; yech
489    (dotimes (i n)
490      (declare (fixnum i))
491      (uvset new i (%car list))
492      (setq list (%cdr list)))
493    new))
494
495
496; appears to be unused
497(defun upgraded-array-element-type (type &optional env)
498  "Return the element type that will actually be used to implement an array
499   with the specifier :ELEMENT-TYPE Spec."
500  (declare (ignore env))
501  (element-subtype-type (element-type-subtype type)))
502
503(defun upgraded-complex-part-type (type &optional env)
504  (declare (ignore env))
505  (declare (ignore type))               ; Ok, ok.  So (upgraded-complex-part-type 'bogus) is 'REAL. So ?
506  'real)
507
508
509#+ppc32-target
510(progn
511  (defparameter array-element-subtypes
512    #(single-float 
513      (unsigned-byte 32)
514      (signed-byte 32)
515      fixnum
516      base-char                         ;ucs4
517      (unsigned-byte 8)
518      (signed-byte 8)
519      base-char
520      (unsigned-byte 16)
521      (signed-byte 16)
522      double-float
523      bit))
524 
525  ;; given uvector subtype - what is the corresponding element-type
526  (defun element-subtype-type (subtype)
527    (declare (fixnum subtype))
528    (if  (= subtype ppc32::subtag-simple-vector) t
529        (svref array-element-subtypes 
530               (ash (- subtype ppc32::min-cl-ivector-subtag) (- ppc32::ntagbits)))))
531  )
532
533#+ppc64-target
534(progn
535
536(defparameter array-element-subtypes
537  #(bogus
538    bogus
539    bogus
540    bogus
541    (signed-byte 8)
542    (signed-byte 16)
543    (signed-byte 32)
544    (signed-byte 64)
545    (unsigned-byte 8)
546    (unsigned-byte 16)
547    (unsigned-byte 32)
548    (unsigned-byte 64)
549    bogus
550    bogus
551    single-float
552    fixnum
553    bogus
554    bogus
555    bogus
556    double-float
557    bogus
558    bogus
559    base-char
560    bogus
561    bogus
562    bogus
563    bogus
564    bogus
565    bogus
566    bit
567    bogus
568    bogus)) 
569
570 
571  ;;; given uvector subtype - what is the corresponding element-type
572  (defun element-subtype-type (subtype)
573    (declare (fixnum subtype))
574    (if  (= subtype ppc64::subtag-simple-vector)
575      t
576      (svref array-element-subtypes 
577             (ash (- subtype 128) -2))))
578  )
579
580#+x8664-target
581(progn
582
583  ;;; 1, 8, 16-bit element types
584  (defparameter *immheader-0-array-element-types*
585    #(bogus
586      bogus
587      bogus
588      bogus
589      bogus
590      bogus
591      bogus
592      bogus
593      bogus
594      bogus
595      (signed-byte 16)
596      (unsigned-byte 16)
597      base-char
598      (signed-byte 8)
599      (unsigned-byte 8)
600      bit))
601
602  ;;; 32-bit element types
603  (defparameter *immheader-1-array-element-types*
604    #(bogus
605      bogus
606      bogus
607      bogus
608      bogus
609      bogus
610      bogus
611      bogus
612      bogus
613      bogus
614      bogus
615      bogus
616      base-char
617      (signed-byte 32)
618      (unsigned-byte 32)
619      single-float))
620
621  ;;; 64-bit element types
622  (defparameter *immheader-2-array-element-types*
623    #(bogus
624      bogus
625      bogus
626      bogus
627      bogus
628      bogus
629      bogus
630      bogus
631      bogus
632      bogus
633      bogus
634      bogus
635      fixnum
636      (signed-byte 64)
637      (unsigned-byte 64)
638      double-float)) 
639     
640 
641  (defun element-subtype-type (subtype)
642    (declare (type (unsigned-byte 8) subtype))
643    (if (= subtype x8664::subtag-simple-vector)
644      t
645      (let* ((class (ash subtype (- x8664::ntagbits)))
646             (tag (logand subtype x8664::fulltagmask)))
647        (declare (type (unsigned-byte 4) class tag))
648        (cond ((= tag x8664::fulltag-immheader-0)
649               (%svref *immheader-0-array-element-types* class))
650              ((= tag x8664::fulltag-immheader-1)
651               (%svref *immheader-1-array-element-types* class))
652              ((= tag x8664::fulltag-immheader-2)
653               (%svref *immheader-2-array-element-types* class))
654              (t 'bogus)))))
655  )
656
657
658;;; %make-displaced-array assumes the following
659
660(eval-when (:compile-toplevel)
661  (assert (eql target::arrayH.flags-cell target::vectorH.flags-cell))
662  (assert (eql target::arrayH.displacement-cell target::vectorH.displacement-cell))
663  (assert (eql target::arrayH.data-vector-cell target::vectorH.data-vector-cell)))
664
665
666(defun %make-displaced-array (dimensions displaced-to
667                                         &optional fill adjustable
668                                         offset explicitp)
669  (if offset 
670    (unless (and (fixnump offset) (>= (the fixnum offset) 0))
671      (setq offset (require-type offset '(and fixnum (integer 0 *)))))
672    (setq offset 0))
673  (locally (declare (fixnum offset))
674    (let* ((disp-size (array-total-size displaced-to))
675           (rank (if (listp dimensions)(length dimensions) 1))
676           (new-size (if (fixnump dimensions)
677                       dimensions
678                       (if (listp dimensions)
679                         (if (eql rank 1)
680                           (car dimensions)
681                           (if (eql rank 0) 1 ; why not 0?
682                           (apply #'* dimensions))))))
683           (vect-subtype (typecode displaced-to))
684           (target displaced-to)
685           (real-offset offset)
686           (flags 0))
687      (declare (fixnum disp-size rank flags vect-subtype real-offset))
688      (when explicitp
689        (setq flags (bitset $arh_exp_disp_bit flags)))
690      (if (not (fixnump new-size))(error "Bad array dimensions ~s." dimensions)) 
691      (locally (declare (fixnum new-size))
692        ; (when (> (+ offset new-size) disp-size) ...), but don't cons bignums
693        (when (or (> new-size disp-size)
694                  (let ((max-offset (- disp-size new-size)))
695                    (declare (fixnum max-offset))
696                    (> offset max-offset)))
697          (%err-disp $err-disp-size displaced-to))
698        (if adjustable  (setq flags (bitset $arh_adjp_bit flags)))
699        (when fill
700          (if (eq fill t)
701            (setq fill new-size)
702            (unless (and (eql rank 1)
703                         (fixnump fill)
704                         (locally (declare (fixnum fill))
705                           (and (>= fill 0) (<= fill new-size))))
706              (error "Bad fill pointer ~s" fill)))
707          (setq flags (bitset $arh_fill_bit flags))))
708      ; If displaced-to is an array or vector header and is either
709      ; adjustable or its target is a header, then we need to set the
710      ; $arh_disp_bit. If displaced-to is not adjustable, then our
711      ; target can be its target instead of itself.
712      (when (or (eql vect-subtype target::subtag-arrayH)
713                (eql vect-subtype target::subtag-vectorH))
714        (let ((dflags (%svref displaced-to target::arrayH.flags-cell)))
715          (declare (fixnum dflags))
716          (when (or (logbitp $arh_adjp_bit dflags)
717                    t
718                    (progn
719                      #+nope
720                      (setq target (%svref displaced-to target::arrayH.data-vector-cell)
721                            real-offset (+ offset (%svref displaced-to target::arrayH.displacement-cell)))
722                      (logbitp $arh_disp_bit dflags)
723                      #-nope t))
724            (setq flags (bitset $arh_disp_bit flags))))
725        (setq vect-subtype (%array-header-subtype displaced-to)))
726      ; assumes flags is low byte
727      (setq flags (dpb vect-subtype target::arrayH.flags-cell-subtag-byte flags))
728      (if (eq rank 1)
729        (%gvector target::subtag-vectorH 
730                      (if (fixnump fill) fill new-size)
731                      new-size
732                      target
733                      real-offset
734                      flags)
735        (let ((val (%alloc-misc (+ target::arrayh.dim0-cell rank) target::subtag-arrayH)))
736          (setf (%svref val target::arrayH.rank-cell) rank)
737          (setf (%svref val target::arrayH.physsize-cell) new-size)
738          (setf (%svref val target::arrayH.data-vector-cell) target)
739          (setf (%svref val target::arrayH.displacement-cell) real-offset)
740          (setf (%svref val target::arrayH.flags-cell) flags)
741          (do* ((dims dimensions (cdr dims))
742                (i 0 (1+ i)))             
743               ((null dims))
744            (declare (fixnum i)(list dims))
745            (setf (%svref val (%i+ target::arrayH.dim0-cell i)) (car dims)))
746          val)))))
747
748(defun make-array (dims &key (element-type t element-type-p)
749                        displaced-to
750                        displaced-index-offset
751                        adjustable
752                        fill-pointer
753                        (initial-element nil initial-element-p)
754                        (initial-contents nil initial-contents-p))
755  (when (and initial-element-p initial-contents-p)
756        (error "Cannot specify both ~S and ~S" :initial-element-p :initial-contents-p))
757  (make-array-1 dims element-type element-type-p
758                displaced-to
759                displaced-index-offset
760                adjustable
761                fill-pointer
762                initial-element initial-element-p
763                initial-contents initial-contents-p
764                nil))
765
766
767
768
769
770(defun vector-pop (vector)
771  "Decrease the fill pointer by 1 and return the element pointed to by the
772  new fill pointer."
773  (let* ((fill (fill-pointer vector)))
774    (declare (fixnum fill))
775    (if (zerop fill)
776      (error "Fill pointer of ~S is 0 ." vector)
777      (progn
778        (decf fill)
779        (%set-fill-pointer vector fill)
780        (aref vector fill)))))
781
782
783
784
785(defun elt (sequence idx)
786  "Return the element of SEQUENCE specified by INDEX."
787  (seq-dispatch
788   sequence
789   (let* ((cell (nthcdr idx sequence)))
790     (if (consp cell)
791       (car (the cons cell))
792       (if cell
793         (report-bad-arg sequence '(satisfies proper-list-p))
794         (%err-disp $XACCESSNTH idx sequence))))
795       
796   (progn
797     (unless (and (typep idx 'fixnum) (>= (the fixnum idx) 0))
798       (report-bad-arg idx 'unsigned-byte))
799     (locally 
800       (if (>= idx (length sequence))
801         (%err-disp $XACCESSNTH idx sequence)
802         (aref sequence idx))))))
803
804
805
806
807(defun set-elt (sequence idx value)
808  (seq-dispatch
809   sequence
810   (let* ((cell (nthcdr idx sequence)))
811     (if (consp cell)
812       (setf (car (the cons cell)) value)
813       (if cell
814         (report-bad-arg sequence '(satisfies proper-list-p))
815         (%err-disp $XACCESSNTH idx sequence))))
816   (progn
817     (unless (and (typep idx 'fixnum) (>= (the fixnum idx) 0))
818       (report-bad-arg idx 'unsigned-byte))
819     (locally 
820       (declare (fixnum idx))
821       (if (>= idx (length sequence))
822         (%err-disp $XACCESSNTH idx sequence)
823         (setf (aref sequence idx) value))))))
824
825
826
827
828(%fhave 'equalp #'equal)                ; bootstrapping
829
830(defun copy-tree (tree)
831  "Recursively copy trees of conses."
832  (if (atom tree)
833    tree
834    (locally (declare (type cons tree))
835      (do* ((tail (cdr tree) (cdr tail))
836            (result (cons (copy-tree (car tree)) nil))
837            (ptr result (cdr ptr)))
838           ((atom tail)
839            (setf (cdr ptr) tail)
840            result)
841        (declare (type cons ptr result))
842        (locally 
843          (declare (type cons tail))
844          (setf (cdr ptr) (cons (copy-tree (car tail)) nil)))))))
845
846
847
848
849(defvar *periodic-task-interval* 0.3)
850(defvar *periodic-task-seconds* 0)
851(defvar *periodic-task-nanoseconds* 300000000)
852
853(defun set-periodic-task-interval (n)
854  (multiple-value-setq (*periodic-task-seconds* *periodic-task-nanoseconds*)
855    (nanoseconds n))
856  (setq *periodic-task-interval* n))
857
858(defun periodic-task-interval ()
859  *periodic-task-interval*)
860
861
862
863(defun char-downcase (c)
864  "Return CHAR converted to lower-case if that is possible."
865  (let* ((code (char-code c)))
866    (if (and (%i>= code (char-code #\A))(%i<= code (char-code #\Z)))
867      (%code-char (%i+ code #.(- (char-code #\a)(char-code #\A))))
868    c)))
869
870
871
872(defun digit-char-p (char &optional radix)
873  "If char is a digit in the specified radix, returns the fixnum for
874  which that digit stands, else returns NIL."
875  (let* ((code (char-code char))
876         (r (if radix (if (and (typep radix 'fixnum)
877                               (%i>= radix 2)
878                               (%i<= radix 36))
879                        radix
880                        (%validate-radix radix)) 10))
881         (weight (if (and (<= code (char-code #\9))
882                          (>= code (char-code #\0)))
883                   (the fixnum (- code (char-code #\0)))
884                   (if (and (<= code (char-code #\Z))
885                            (>= code (char-code #\A)))
886                     (the fixnum (+ 10 (the fixnum (- code (char-code #\A)))))
887                   (if (and (<= code (char-code #\z))
888                            (>= code (char-code #\a)))
889                     (the fixnum (+ 10 (the fixnum (- code (char-code #\a))))))))))
890    (declare (fixnum code r))
891    (and weight (< (the fixnum weight) r) weight)))
892
893
894
895
896
897(defun char-upcase (c)
898  "Return CHAR converted to upper-case if that is possible.  Don't convert
899   lowercase eszet (U+DF)."
900  (let* ((code (char-code c)))
901    (if (and (%i>= code (char-code #\a))(%i<= code (char-code #\z)))
902      (%code-char (%i- code #.(- (char-code #\a)(char-code #\A))))
903      c)))
904
905
906
907(defun string-start-end (string start end)
908  (setq string (string string))
909  (let ((len (length (the string string))))
910    (flet ((are (a i)(error "Array index ~S out of bounds for ~S." i a)))   
911      (if (and end (> end len))(are string end))
912      (if (and start (or (< start 0)(> start len)))(are string start))
913      (setq start (or start 0) end (or end len))
914      (if (%i> start end)
915        (error "Start ~S exceeds end ~S." start end))
916      (if (typep string 'simple-string)
917        (values string start end)
918        (multiple-value-bind (str off)(array-data-and-offset string)
919          (values str (%i+ off start)(%i+ off end)))))))
920
921(defun get-properties (place indicator-list)
922  "Like GETF, except that INDICATOR-LIST is a list of indicators which will
923  be looked for in the property list stored in PLACE. Three values are
924  returned, see manual for details."
925  (do ((plist place (cddr plist)))
926      ((null plist) (values nil nil nil))
927    (cond ((atom (cdr plist))
928           (report-bad-arg place '(satisfies proper-list-p)))
929          ((memq (car plist) indicator-list) ;memq defined in kernel
930           (return (values (car plist) (cadr plist) plist))))))
931
932(defun string= (string1 string2 &key start1 end1 start2 end2)
933  "Given two strings (string1 and string2), and optional integers start1,
934  start2, end1 and end2, compares characters in string1 to characters in
935  string2 (using char=)."
936    (locally (declare (optimize (speed 3)(safety 0)))
937      (if (and (simple-string-p string1)(null start1)(null end1))
938        (setq start1 0 end1 (length string1))
939        (multiple-value-setq (string1 start1 end1)(string-start-end string1 start1 end1)))
940      (if (and (simple-string-p string2)(null start2)(null end2))
941        (setq start2 0 end2 (length string2))
942        (multiple-value-setq (string2 start2 end2)(string-start-end string2 start2 end2)))   
943      (%simple-string= string1 string2 start1 start2 end1 end2)))
944
945
946(defun lfun-keyvect (lfun)
947  (let ((bits (lfun-bits lfun)))
948    (declare (fixnum bits))
949    (and (logbitp $lfbits-keys-bit bits)
950         (or (logbitp $lfbits-method-bit bits)
951             (and (not (logbitp $lfbits-gfn-bit bits))
952                  (not (logbitp $lfbits-cm-bit bits))))
953         (nth-immediate lfun 1))))
954
955
956
957(defun function-lambda-expression (fn)
958  "Return (VALUES DEFINING-LAMBDA-EXPRESSION CLOSURE-P NAME), where
959  DEFINING-LAMBDA-EXPRESSION is NIL if unknown, or a suitable argument
960  to COMPILE otherwise, CLOSURE-P is non-NIL if the function's definition
961  might have been enclosed in some non-null lexical environment, and
962  NAME is some name (for debugging only) or NIL if there is no name."
963  ;(declare (values def env-p name))
964  (let* ((bits (lfun-bits (setq fn (require-type fn 'function)))))
965    (declare (fixnum bits))
966    (if (logbitp $lfbits-trampoline-bit bits)
967      (function-lambda-expression (nth-immediate fn 1))
968      (values (uncompile-function fn)
969              (logbitp $lfbits-nonnullenv-bit bits)
970              (function-name fn)))))
971
972; env must be a lexical-environment or NIL.
973; If env contains function or variable bindings or SPECIAL declarations, return t.
974; Else return nil
975(defun %non-empty-environment-p (env)
976  (loop
977    (when (or (null env) (istruct-typep env 'definition-environment))
978      (return nil))
979    (when (or (consp (lexenv.variables env))
980              (consp (lexenv.functions env))
981              (dolist (vdecl (lexenv.vdecls env))
982                (when (eq (cadr vdecl) 'special)
983                  (return t))))
984      (return t))
985    (setq env (lexenv.parent-env env))))
986
987;(coerce object 'compiled-function)
988(defun coerce-to-compiled-function (object)
989  (setq object (coerce-to-function object))
990  (unless (typep object 'compiled-function)
991    (multiple-value-bind (def envp) (function-lambda-expression object)
992      (when (or envp (null def))
993        (%err-disp $xcoerce object 'compiled-function))
994      (setq object (compile-user-function def nil))))
995  object)
996
997
998
999(defun %set-toplevel (&optional (fun nil fun-p))
1000  ;(setq fun (require-type fun '(or symbol function)))
1001  (let* ((tcr (%current-tcr)))
1002    (prog1 (%tcr-toplevel-function tcr)
1003      (when fun-p
1004        (%set-tcr-toplevel-function tcr fun)))))
1005
1006
1007(defun gccounts ()
1008  (let* ((total (%get-gc-count))
1009         (full (full-gccount))
1010         (g2-count 0)
1011         (g1-count 0)
1012         (g0-count 0))
1013    (when (egc-enabled-p)
1014      (let* ((a (%active-dynamic-area)))
1015        (setq g0-count (%fixnum-ref a target::area.gc-count) a (%fixnum-ref a target::area.older))
1016        (setq g1-count (%fixnum-ref a target::area.gc-count) a (%fixnum-ref a target::area.older))
1017        (setq g2-count (%fixnum-ref a target::area.gc-count))))
1018    (values total full g2-count g1-count g0-count)))
1019
1020     
1021
1022
1023
1024(defstatic %pascal-functions%
1025    #(NIL NIL NIL NIL NIL NIL NIL NIL
1026      NIL NIL NIL NIL NIL NIL NIL NIL
1027      NIL NIL NIL NIL NIL NIL NIL NIL
1028      NIL NIL NIL NIL NIL NIL NIL NIL))
1029
1030
1031(defun gc-retain-pages (arg)
1032  "Try to influence the GC to retain/recycle the pages allocated between
1033GCs if arg is true, and to release them otherwise. This is generally a
1034gtradeoff between paging and other VM considerations."
1035  (setq *gc-event-status-bits*
1036        (if arg
1037          (bitset $gc-retain-pages-bit *gc-event-status-bits*)
1038          (bitclr $gc-retain-pages-bit *gc-event-status-bits*)))
1039  (not (null arg)))
1040
1041(defun gc-retaining-pages ()
1042  "Return T if the GC tries to retain pages between full GCs and NIL if
1043it's trying to release them to improve VM paging performance."
1044  (logbitp $gc-retain-pages-bit *gc-event-status-bits*)) 
1045
1046
1047(defun gc-verbose (on-full-gc &optional (egc-too on-full-gc))
1048  "If the first (required) argument is non-NIL, configures the GC to print
1049informational messages on entry and exit to each full GC; if the first argument
1050is NIL, suppresses those messages.  The second (optional) argument controls printing of messages on entry and exit to an ephemeral GC.  Returns values as per GC-VERBOSE-P."
1051  (let* ((bits *gc-event-status-bits*))
1052    (if on-full-gc
1053      (bitsetf $gc-verbose-bit bits)
1054      (bitclrf $gc-verbose-bit bits))
1055    (if egc-too
1056      (bitsetf $egc-verbose-bit bits)
1057      (bitclrf $egc-verbose-bit bits))
1058    (setq *gc-event-status-bits* bits)
1059    (values on-full-gc egc-too)))
1060
1061
1062(defun gc-verbose-p ()
1063  "Returns two values: the first is true if the GC is configured to
1064print messages on each full GC; the second is true if the GC is configured
1065to print messages on each ephemeral GC."
1066  (let* ((bits *gc-event-status-bits*))
1067    (values (logbitp $gc-verbose-bit bits)
1068            (logbitp $egc-verbose-bit bits))))
1069
1070(defun egc-active-p ()
1071  "Return T if the EGC was active at the time of the call, NIL otherwise.
1072Since this is generally a volatile piece of information, it's not clear
1073whether this function serves a useful purpose when native threads are
1074involved."
1075  (and (egc-enabled-p)
1076       (not (eql 0 (%get-kernel-global 'oldest-ephemeral)))))
1077
1078; this IS effectively a passive way of inquiring about enabled status.
1079(defun egc-enabled-p ()
1080  "Return T if the EGC was enabled at the time of the call, NIL otherwise."
1081  (not (eql 0 (%fixnum-ref (%active-dynamic-area) target::area.older))))
1082
1083(defun egc-configuration ()
1084  "Return as multiple values the sizes in kilobytes of the thresholds
1085associated with the youngest ephemeral generation, the middle ephemeral
1086generation, and the oldest ephemeral generation."
1087  (let* ((ta (%get-kernel-global 'tenured-area))
1088         (g2 (%fixnum-ref ta target::area.younger))
1089         (g1 (%fixnum-ref g2 target::area.younger))
1090         (g0 (%fixnum-ref g1 target::area.younger)))
1091    (values (ash (the fixnum (%fixnum-ref g0 target::area.threshold)) -8)
1092            (ash (the fixnum (%fixnum-ref g1 target::area.threshold)) -8)
1093            (ash (the fixnum (%fixnum-ref g2 target::area.threshold)) -8))))
1094
1095
1096(defun configure-egc (e0size e1size e2size)
1097  "If the EGC is currently disabled, put the indicated threshold sizes in
1098effect and returns T, otherwise, returns NIL. (The provided threshold sizes
1099are rounded up to a multiple of 64Kbytes in OpenMCL 0.14 and to a multiple
1100of 32KBytes in earlier versions.)"
1101  (unless (egc-active-p)
1102    (setq e2size (logand (lognot #xffff) (+ #xffff (ash (require-type e2size '(unsigned-byte 18)) 10)))
1103          e1size (logand (lognot #xffff) (+ #xffff (ash (require-type e1size '(unsigned-byte 18)) 10)))
1104          e0size (logand (lognot #xffff) (+ #xffff (ash (require-type e0size '(integer 1 #.(ash 1 18))) 10))))
1105    (%configure-egc e0size e1size e2size)))
1106
1107
1108
1109(defun macptr-flags (macptr)
1110  (if (eql (uvsize (setq macptr (require-type macptr 'macptr))) 1)
1111    0
1112    (uvref macptr TARGET::XMACPTR.FLAGS-CELL)))
1113
1114
1115; This doesn't really make the macptr be gcable (now has to be
1116; on linked list), but we might have other reasons for setting
1117; other flag bits.
1118(defun set-macptr-flags (macptr value) 
1119  (unless (eql (uvsize (setq macptr (require-type macptr 'macptr))) 1)
1120    (setf (%svref macptr TARGET::XMACPTR.FLAGS-CELL) value)
1121    value))
1122
1123(defun %new-gcable-ptr (size &optional clear-p)
1124  (let ((p (make-gcable-macptr $flags_DisposPtr)))
1125    (%setf-macptr p (malloc size))
1126    (if clear-p
1127      (#_bzero p size))
1128    p))
1129
1130(defun %gcable-ptr-p (p)
1131  (and (typep p 'macptr)
1132       (= (uvsize p) target::xmacptr.element-count)))
1133
1134
1135;True for a-z.
1136(defun lower-case-p (c)
1137  "The argument must be a character object; LOWER-CASE-P returns T if the
1138   argument is a lower-case character, NIL otherwise."
1139  (let ((code (char-code c)))
1140    (and (>= code (char-code #\a))
1141         (<= code (char-code #\z)))))
1142
1143;True for a-z A-Z
1144
1145
1146(defun alpha-char-p (c)
1147  "The argument must be a character object. ALPHA-CHAR-P returns T if the
1148   argument is an alphabetic character, A-Z or a-z; otherwise NIL."
1149  (let* ((code (char-code c)))
1150    (declare (fixnum code))
1151    (or (and (>= code (char-code #\A)) (<= code (char-code #\Z)))
1152        (and (>= code (char-code #\a)) (<= code (char-code #\z))))))
1153
1154
1155
1156
1157; def-accessors type-tracking stuff.  Used by inspector
1158(defvar *def-accessor-types* nil)
1159
1160(defun add-accessor-types (types names)
1161  (dolist (type types)
1162    (let ((cell (or (assq type *def-accessor-types*)
1163                    (car (push (cons type nil) *def-accessor-types*)))))
1164      (setf (cdr cell) (if (vectorp names) names (%list-to-uvector nil names))))))
1165
1166
1167;;; Some simple explicit storage management for cons cells
1168
1169(def-standard-initial-binding *cons-pool* (%cons-pool nil))
1170
1171(defun cheap-cons (car cdr)
1172  (let* ((pool *cons-pool*)
1173         (cons (pool.data pool)))
1174    (if cons
1175      (locally (declare (type cons cons))
1176        (setf (pool.data pool) (cdr cons)
1177              (car cons) car
1178              (cdr cons) cdr)
1179        cons)
1180      (cons car cdr))))
1181
1182(defun free-cons (cons)
1183  (when (consp cons)
1184    (locally (declare (type cons cons))
1185      (setf (car cons) nil
1186            (cdr cons) nil)
1187      (let* ((pool *cons-pool*)
1188             (freelist (pool.data pool)))
1189        (setf (pool.data pool) cons
1190              (cdr cons) freelist)))))
1191
1192(defun cheap-copy-list (list)
1193  (let ((l list)
1194        res)
1195    (loop
1196      (when (atom l)
1197        (return (nreconc res l)))
1198      (setq res (cheap-cons (pop l) res)))))
1199
1200(defun cheap-list (&rest args)
1201  (declare (dynamic-extent args))
1202  (cheap-copy-list args))
1203
1204;;; Works for dotted lists
1205(defun cheap-free-list (list)
1206  (let ((l list)
1207        next-l)
1208    (loop
1209      (setq next-l (cdr l))
1210      (free-cons l)
1211      (when (atom (setq l next-l))
1212        (return)))))
1213
1214(defmacro pop-and-free (place)
1215  (setq place (require-type place 'symbol))     ; all I need for now.
1216  (let ((list (gensym))
1217        (cdr (gensym)))
1218    `(let* ((,list ,place)
1219            (,cdr (cdr ,list)))
1220       (prog1
1221         (car ,list)
1222         (setf ,place ,cdr)
1223         (free-cons ,list)))))
1224
1225;;; Support for defresource & using-resource macros
1226(defun make-resource (constructor &key destructor initializer)
1227  (%cons-resource constructor destructor initializer))
1228
1229(defun allocate-resource (resource)
1230  (setq resource (require-type resource 'resource))
1231  (with-lock-grabbed ((resource.lock resource))
1232    (let ((pool (resource.pool resource))
1233          res)
1234      (let ((data (pool.data pool)))
1235        (when data
1236          (setf res (car data)
1237                (pool.data pool) (cdr (the cons data)))
1238          (free-cons data)))
1239      (if res
1240        (let ((initializer (resource.initializer resource)))
1241          (when initializer
1242            (funcall initializer res)))
1243        (setq res (funcall (resource.constructor resource))))
1244      res)))
1245
1246(defun free-resource (resource instance)
1247  (setq resource (require-type resource 'resource))
1248  (with-lock-grabbed ((resource.lock resource))
1249    (let ((pool (resource.pool resource))
1250          (destructor (resource.destructor resource)))
1251      (when destructor
1252        (funcall destructor instance))
1253      (setf (pool.data pool)
1254            (cheap-cons instance (pool.data pool)))))
1255  resource)
1256
1257
1258
1259
1260(defpackage #.(ftd-interface-package-name
1261               (backend-target-foreign-type-data *target-backend*))
1262  (:nicknames "OS")
1263  (:use "COMMON-LISP"))
1264
1265
1266
Note: See TracBrowser for help on using the repository browser.