source: trunk/ccl/hemlock/src/htext2.lisp @ 2064

Last change on this file since 2064 was 2064, checked in by gb, 14 years ago

Don't modify buffer if doing so would change a protected region.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 18.2 KB
Line 
1;;; -*- Log: hemlock.log; Package: Hemlock-Internals -*-
2;;;
3;;; **********************************************************************
4;;; This code was written as part of the CMU Common Lisp project at
5;;; Carnegie Mellon University, and has been placed in the public domain.
6;;;
7#+CMU (ext:file-comment
8  "$Header$")
9;;;
10;;; **********************************************************************
11;;;
12;;; More Hemlock Text-Manipulation functions.
13;;; Written by Skef Wholey.
14;;;
15;;; The code in this file implements the non-insert/delete functions in the
16;;; "Doing Stuff and Going Places" chapter of the Hemlock Design document.
17;;;
18
19(in-package :hemlock-internals)
20
21
22   
23         
24
25(defun region-to-string (region)
26  "Returns a string containing the characters in the given Region."
27  (close-line)
28  (let* ((dst-length (count-characters region))
29         (string (make-string dst-length))
30         (start-mark (region-start region))
31         (end-mark (region-end region))
32         (start-line (mark-line start-mark))
33         (end-line (mark-line end-mark))
34         (start-charpos (mark-charpos start-mark)))
35    (declare (simple-string string))
36    (if (eq start-line end-line)
37        (%sp-byte-blt (line-chars start-line) start-charpos string 0
38                      dst-length)
39        (let ((index ()))
40          (let* ((line-chars (line-chars start-line))
41                 (dst-end (- (length line-chars) start-charpos)))
42            (declare (simple-string line-chars))
43            (%sp-byte-blt line-chars start-charpos string 0 dst-end)
44            (setf (char string dst-end) #\newline)
45            (setq index (1+ dst-end)))
46          (do* ((line (line-next start-line) (line-next line))
47                (chars (line-chars line) (line-chars line)))
48               ((eq line end-line)
49                (%sp-byte-blt (line-chars line) 0 string index dst-length))
50            (declare (simple-string chars))
51            (%sp-byte-blt (line-chars line) 0 string index
52                          (incf index (length chars)))
53            (setf (char string index) #\newline)
54            (setq index (1+ index)))))
55    string))
56
57(defun string-to-region (string)
58  "Returns a region containing the characters in the given String."
59  (let* ((string (if (simple-string-p string)
60                     string (coerce string 'simple-string)))
61         (end (length string)))
62    (declare (simple-string string))
63    (do* ((index 0)
64          (buffer (incf *disembodied-buffer-counter*))
65          (previous-line)
66          (line (make-line :%buffer buffer))
67          (first-line line))
68         (())
69      (let ((right-index (%sp-find-character string index end #\newline)))
70        (cond (right-index
71               (let* ((length (- right-index index))
72                      (chars (make-string length)))
73                 (%sp-byte-blt string index chars 0 length)
74                 (setf (line-chars line) chars))
75               (setq index (1+ right-index))
76               (setq previous-line line)
77               (setq line (make-line :%buffer buffer))
78               (setf (line-next previous-line) line)
79               (setf (line-previous line) previous-line))
80              (t
81               (let* ((length (- end index))
82                      (chars (make-string length)))
83                 (%sp-byte-blt string index chars 0 length)
84                 (setf (line-chars line) chars))
85               (return (renumber-region
86                        (internal-make-region
87                         (mark first-line 0 :right-inserting)
88                         (mark line (length (line-chars line))
89                               :left-inserting))))))))))
90
91(defun line-to-region (line)
92  "Returns a region containing the specified line."
93  (internal-make-region (mark line 0 :right-inserting)
94                        (mark line (line-length* line) :left-inserting)))
95
96(defun previous-character (mark)
97  "Returns the character immediately before the given Mark."
98  (let ((line (mark-line mark))
99        (charpos (mark-charpos mark)))
100    (if (= charpos 0)
101        (if (line-previous line)
102            #\newline
103            nil)
104        (if (eq line *open-line*)
105            (char (the simple-string *open-chars*)
106                  (if (<= charpos *left-open-pos*)
107                      (1- charpos)
108                      (1- (+ *right-open-pos* (- charpos *left-open-pos*)))))
109            (schar (line-chars line) (1- charpos))))))
110
111(defun next-character (mark)
112  "Returns the character immediately after the given Mark."
113  (let ((line (mark-line mark))
114        (charpos (mark-charpos mark)))
115    (if (eq line *open-line*)
116        (if (= charpos (- *line-cache-length* (- *right-open-pos* *left-open-pos*)))
117            (if (line-next line)
118                #\newline
119                nil)
120            (schar *open-chars*
121                   (if (< charpos *left-open-pos*)
122                       charpos
123                       (+ *right-open-pos* (- charpos *left-open-pos*)))))
124        (let ((chars (line-chars line)))
125          (if (= charpos (strlen chars))
126              (if (line-next line)
127                  #\newline
128                  nil)
129              (schar chars charpos))))))
130
131;;; %Set-Next-Character  --  Internal
132;;;
133;;;    This is the setf form for Next-Character.  Since we may change a
134;;; character to or from a newline, we must be prepared to split and
135;;; join lines.  We cannot just delete  a character and insert the new one
136;;; because the marks would not be right.
137;;;
138(defun %set-next-character (mark character)
139  (let* ((line (mark-line mark))
140         (next (line-next line))
141         (buffer (line-%buffer line)))
142    (check-buffer-modification buffer mark)
143    (modifying-buffer buffer
144      (modifying-line line mark)
145      (cond ((= (mark-charpos mark)
146                (- *line-cache-length* (- *right-open-pos* *left-open-pos*)))
147             ;; The mark is at the end of the line.
148             (unless next
149               (error "~S has no next character, so it cannot be set." mark))
150             (unless (char= character #\newline)
151               ;; If the character is no longer a newline then mash two
152               ;; lines together.
153               (let ((chars (line-chars next)))
154                 (declare (simple-string chars))
155                 (setq *right-open-pos* (- *line-cache-length* (length chars)))
156                 (when (<= *right-open-pos* *left-open-pos*)
157                   (grow-open-chars (* (+ (length chars) *left-open-pos* 1) 2)))
158                 (%sp-byte-blt chars 0 *open-chars* *right-open-pos* 
159                               *line-cache-length*)
160                 (setf (schar *open-chars* *left-open-pos*) character)
161                 (incf *left-open-pos*))
162               (move-some-marks (charpos next line) 
163                                (+ charpos *left-open-pos*))
164               (setq next (line-next next))
165               (setf (line-next line) next)
166               (when next (setf (line-previous next) line))))
167            ((char= character #\newline)
168             ;; The char is being changed to a newline, so we must split lines.
169             (incf *right-open-pos*)
170             (let* ((len (- *line-cache-length* *right-open-pos*))         
171                    (chars (make-string len))
172                    (new (make-line :chars chars  :previous line 
173                                    :next next  :%buffer buffer)))
174               (%sp-byte-blt *open-chars* *right-open-pos* chars 0 len)
175               (maybe-move-some-marks* (charpos line new) *left-open-pos*
176                                       (- charpos *left-open-pos* 1))
177               (setf (line-next line) new)
178               (when next (setf (line-previous next) new))
179               (setq *right-open-pos* *line-cache-length*)
180               (number-line new)))
181            (t
182             (setf (char (the simple-string *open-chars*) *right-open-pos*)
183                   character)
184             (hi::buffer-note-modification buffer mark 1)))))
185  character)
186
187;;; %Set-Previous-Character  --  Internal
188;;;
189;;;    The setf form for Previous-Character.  We just Temporarily move the
190;;; mark back one and call %Set-Next-Character.
191;;;
192(defun %set-previous-character (mark character)
193  (unless (mark-before mark)
194    (error "~S has no previous character, so it cannot be set." mark))
195  (%set-next-character mark character)
196  (mark-after mark)
197  character)
198
199(defun count-lines (region)
200  "Returns the number of lines in the region, first and last lines inclusive."
201  (do ((line (mark-line (region-start region)) (line-next line))
202       (count 1 (1+ count))
203       (last-line (mark-line (region-end region))))
204      ((eq line last-line) count)))
205
206(defun count-characters (region)
207  "Returns the number of characters in the region."
208  (let* ((start (region-start region))
209         (end (region-end region))
210         (first-line (mark-line start))
211         (last-line (mark-line end)))
212    (if (eq first-line last-line)
213        (- (mark-charpos end) (mark-charpos start))
214        (do ((line (line-next first-line) (line-next line))
215             (count (1+ (- (line-length* first-line) (mark-charpos start)))))
216            ((eq line last-line)
217             (+ count (mark-charpos end)))
218          (setq count (+ 1 count (line-length* line)))))))
219
220(defun line-start (mark &optional line)
221  "Changes the Mark to point to the beginning of the Line and returns it.
222  Line defaults to the line Mark is on."
223  (when line
224    (change-line mark line))
225  (setf (mark-charpos mark) 0)
226  mark)
227
228(defun line-end (mark &optional line)
229  "Changes the Mark to point to the end of the line and returns it.
230  Line defaults to the line Mark is on."
231  (if line
232      (change-line mark line)
233      (setq line (mark-line mark)))
234  (setf (mark-charpos mark) (line-length* line))
235  mark)
236
237(defun buffer-start (mark &optional (buffer (line-buffer (mark-line mark))))
238  "Change Mark to point to the beginning of Buffer, which defaults to
239  the buffer Mark is currently in."
240  (unless buffer (error "Mark ~S does not point into a buffer."))
241  (move-mark mark (buffer-start-mark buffer)))
242
243(defun buffer-end (mark &optional (buffer (line-buffer (mark-line mark))))
244  "Change Mark to point to the end of Buffer, which defaults to
245  the buffer Mark is currently in."
246  (unless buffer (error "Mark ~S does not point into a buffer."))
247  (move-mark mark (buffer-end-mark buffer)))
248
249(defun move-mark (mark new-position)
250  "Changes the Mark to point to the same position as New-Position."
251  (let* ((line (mark-line new-position)))
252    (change-line mark line))
253  (setf (mark-charpos mark) (mark-charpos new-position))
254  mark)
255
256
257(defun mark-before (mark)
258  "Changes the Mark to point one character before where it currently points.
259  NIL is returned if there is no previous character."
260  (let ((charpos (mark-charpos mark)))
261    (cond ((zerop charpos)
262           (let ((prev (line-previous (mark-line mark))))
263             (when prev
264               (always-change-line mark prev)
265               (setf (mark-charpos mark) (line-length* prev))
266               mark)))
267          (t
268           (setf (mark-charpos mark) (1- charpos))
269           mark))))
270
271(defun mark-after (mark)
272  "Changes the Mark to point one character after where it currently points.
273  NIL is returned if there is no previous character."
274  (let ((line (mark-line mark))
275        (charpos (mark-charpos mark)))
276    (cond ((= charpos (line-length* line))
277           (let ((next (line-next line)))
278             (when next
279               (always-change-line mark next)
280               (setf (mark-charpos mark) 0)
281               mark)))
282          (t
283           (setf (mark-charpos mark) (1+ charpos))
284           mark))))
285
286(defun character-offset (mark n)
287  "Changes the Mark to point N characters after (or -N before if N is negative)
288  where it currently points.  If there aren't N characters before (or after)
289  the mark, Nil is returned."
290  (let* ((charpos (mark-charpos mark)))
291    (if (< n 0)
292      (let ((n (- n)))
293        (if (< charpos n)
294          (do ((line (line-previous (mark-line mark)) (line-previous line))
295               (n (- n charpos 1)))
296              ((null line) nil)
297            (let ((length (line-length* line)))
298              (cond ((<= n length)
299                     (always-change-line mark line)
300                     (setf (mark-charpos mark) (- length n))
301                     (return mark))
302                    (t
303                     (setq n (- n (1+ length)))))))
304          (progn (setf (mark-charpos mark) (- charpos n))
305                 mark)))
306      (let* ((line (mark-line mark))
307             (length (line-length* line)))
308        (if (> (+ charpos n) length)
309          (do ((line (line-next line) (line-next line))
310               (n (- n (1+ (- length charpos)))))
311              ((null line) nil)
312            (let ((length (line-length* line)))
313              (cond ((<= n length)
314                     (always-change-line mark line)
315                     (setf (mark-charpos mark) n)
316                     (return mark))
317                    (t
318                     (setq n (- n (1+ length)))))))
319          (progn (setf (mark-charpos mark) (+ charpos n))
320                 mark))))))
321
322(defun line-offset (mark n &optional charpos)
323  "Changes to Mark to point N lines after (-N before if N is negative) where
324  it currently points.  If there aren't N lines after (or before) the Mark,
325  Nil is returned."
326    (if (< n 0)
327            (do ((line (mark-line mark) (line-previous line))
328                 (n n (1+ n)))
329                ((null line) nil)
330              (when (= n 0)
331                (always-change-line mark line)
332                (setf (mark-charpos mark)
333                      (if charpos
334                        (min (line-length line) charpos)
335                        (min (line-length line) (mark-charpos mark))))
336                (return mark)))
337            (do ((line (mark-line mark) (line-next line))
338                 (n n (1- n)))
339                ((null line) nil)
340              (when (= n 0)
341                (change-line mark line)
342                (setf (mark-charpos mark)
343                      (if charpos
344                        (min (line-length line) charpos)
345                        (min (line-length line) (mark-charpos mark))))
346                (return mark)))))
347
348;;; region-bounds  --  Public
349;;;
350(defun region-bounds (region)
351  "Return as multiple-value the start and end of Region."
352  (values (region-start region) (region-end region)))
353
354(defun set-region-bounds (region start end)
355  "Set the start and end of Region to the marks Start and End."
356  (let ((sl (mark-line start))
357        (el (mark-line end)))
358    (when (or (neq (line-%buffer sl) (line-%buffer el))
359              (> (line-number sl) (line-number el))
360              (and (eq sl el) (> (mark-charpos start) (mark-charpos end))))
361      (error "Marks ~S and ~S cannot be made into a region." start end))
362    (setf (region-start region) start  (region-end region) end))
363  region)
364
365
366;;;; Debugging stuff.
367
368(defun slf (string)
369  "For a good time, figure out what this function does, and why it was written."
370  (delete #\linefeed (the simple-string string)))
371
372(defun %print-whole-line (structure stream)
373  (cond ((eq structure *open-line*)
374         (write-string *open-chars* stream :end *left-open-pos*)
375         (write-string *open-chars* stream :start *right-open-pos*
376                       :end *line-cache-length*))
377        (t
378         (write-string (line-chars structure) stream))))
379
380(defun %print-before-mark (mark stream)
381  (if (mark-line mark)
382      (let* ((line (mark-line mark))
383             (chars (line-chars line))
384             (charpos (mark-charpos mark))
385             (length (line-length line)))
386        (declare (simple-string chars))
387        (cond ((or (> charpos length) (< charpos 0))
388               (write-string "{bad mark}" stream))
389              ((eq line *open-line*)
390               (cond ((< charpos *left-open-pos*)
391                      (write-string *open-chars* stream :end charpos))
392                     (t
393                      (write-string *open-chars* stream :end *left-open-pos*)
394                      (let ((p (+ charpos (- *right-open-pos* *left-open-pos*))))
395                        (write-string *open-chars* stream  :start *right-open-pos*
396                                      :end p)))))
397              (t
398               (write-string chars stream :end charpos))))
399      (write-string "{deleted mark}" stream)))
400
401
402(defun %print-after-mark (mark stream)
403  (if (mark-line mark)
404      (let* ((line (mark-line mark))
405             (chars (line-chars line))
406             (charpos (mark-charpos mark))
407             (length (line-length line)))
408        (declare (simple-string chars))
409        (cond ((or (> charpos length) (< charpos 0))
410               (write-string "{bad mark}" stream))
411              ((eq line *open-line*)
412               (cond ((< charpos *left-open-pos*)
413                      (write-string *open-chars* stream  :start charpos
414                                    :end *left-open-pos*)
415                      (write-string *open-chars* stream  :start *right-open-pos*
416                                    :end *line-cache-length*))
417                     (t
418                      (let ((p (+ charpos (- *right-open-pos* *left-open-pos*))))
419                        (write-string *open-chars* stream :start p
420                                      :end *line-cache-length*)))))
421              (t
422               (write-string chars stream  :start charpos  :end length))))
423      (write-string "{deleted mark}" stream)))
424
425(defun %print-hline (structure stream d)
426  (declare (ignore d))
427  (write-string "#<Hemlock Line \"" stream)
428  (%print-whole-line structure stream)
429  (write-string "\">" stream))
430
431(defun %print-hmark (structure stream d)
432  (declare (ignore d))
433  (write-string "#<Hemlock Mark \"" stream)
434  (%print-before-mark structure stream)
435  (write-string "^" stream)
436  (%print-after-mark structure stream)
437  (write-string "\">" stream)) 
438
439(defvar *print-region* 10
440  "The number of lines to print out of a region, or NIL if none.")
441
442(defun %print-hregion (region stream d)
443  (declare (ignore d))
444  (write-string "#<Hemlock Region \"" stream)
445  (let* ((start (region-start region))
446         (end (region-end region))
447         (first-line (mark-line start))
448         (last-line (mark-line end)))
449    (cond
450     ((not (and (linep first-line) (linep last-line)
451                (eq (line-%buffer first-line) (line-%buffer last-line))
452                (mark<= start end)))
453      (write-string "{bad region}" stream))
454     (*print-region*
455      (cond ((eq first-line last-line)
456             (let ((cs (mark-charpos start))
457                   (ce (mark-charpos end))
458                   (len (line-length first-line)))
459               (cond
460                ((or (< cs 0) (> ce len))
461                 (write-string "{bad region}" stream))
462                ((eq first-line *open-line*)
463                 (let ((gap (- *right-open-pos* *left-open-pos*)))
464                   (cond
465                    ((<= ce *left-open-pos*)
466                     (write-string *open-chars* stream  :start cs  :end ce))
467                    ((>= cs *left-open-pos*)
468                     (write-string *open-chars* stream  :start (+ cs gap)
469                                   :end (+ ce gap)))
470                    (t
471                     (write-string *open-chars* stream :start cs
472                                   :end *left-open-pos*)
473                     (write-string *open-chars* stream :start *right-open-pos*
474                                   :end (+ gap ce))))))
475                (t
476                 (write-string (line-chars first-line) stream  :start cs
477                               :end ce)))))
478            (t
479             (%print-after-mark start stream)
480             (write-char #\/ stream)
481             (do ((line (line-next first-line) (line-next line))
482                  (last-line (mark-line end))
483                  (cnt *print-region* (1- cnt)))
484                 ((or (eq line last-line)
485                      (when (zerop cnt) (write-string "..." stream) t))
486                  (%print-before-mark end stream))
487               (%print-whole-line line stream)
488               (write-char #\/ stream)))))
489     (t
490      (write-string "{mumble}" stream))))
491  (write-string "\">" stream))
492
493(defun %print-hbuffer (structure stream d)
494  (declare (ignore d))
495  (write-string "#<Hemlock Buffer \"" stream)
496  (write-string (buffer-name structure) stream)
497  (write-string "\">" stream))
498
499(defun check-buffer-modification (buffer mark)
500  (when (typep buffer 'buffer)
501    (let* ((protected-region (buffer-protected-region buffer)))
502      (when protected-region
503        (let* ((prot-start (region-start protected-region))
504               (prot-end (region-end protected-region)))
505         
506          (when (and (mark>= mark prot-start)
507                     (mark< mark prot-end))
508            (editor-error "Can't modify protected buffer region.")))))))
Note: See TracBrowser for help on using the repository browser.