source: release/1.6/source/level-1/l1-processes.lisp @ 14712

Last change on this file since 14712 was 14381, checked in by rme, 9 years ago

Merge trunk changes r14361 through r14380.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 26.1 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 2009 Clozure Associates
4;;;   Copyright (C) 1994-2001 Digitool, Inc
5;;;   This file is part of Clozure CL. 
6;;;
7;;;   Clozure CL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with Clozure CL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with Clozure CL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   Clozure CL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18
19;; L1-processes.lisp
20
21(cl:in-package "CCL")
22
23
24(let* ((all-processes ())
25       (shutdown-processes ())
26       (all-processes-lock (make-lock)))
27  (defun add-to-all-processes (p)
28    (with-lock-grabbed (all-processes-lock)
29      (pushnew p all-processes :test #'eq)
30      p))
31  (defun remove-from-all-processes (p)
32    (with-lock-grabbed (all-processes-lock)
33      (setq all-processes (delete p all-processes))
34      t))
35  (defun all-processes ()
36    "Obtain a fresh list of all known Lisp threads."
37    (with-lock-grabbed (all-processes-lock)
38      (copy-list all-processes)))
39  (defun shutdown-processes ()
40    (with-lock-grabbed (all-processes-lock)
41      (copy-list shutdown-processes)))
42  (defun %clear-shutdown-proceses ()
43    (setq shutdown-processes nil))
44  (defun add-to-shutdown-processes (p)
45    (with-lock-grabbed (all-processes-lock)
46      (pushnew p shutdown-processes :test #'eq))
47    t)
48  (defun pop-shutdown-processes ()
49    (with-lock-grabbed (all-processes-lock)
50      (pop shutdown-processes)))
51  (defun find-process (id)
52    (etypecase id
53      (process id)
54      (integer (with-lock-grabbed (all-processes-lock)
55                 (find id all-processes
56                       :key #'(lambda (p)
57                                (process-serial-number p)))))
58      (string (with-lock-grabbed (all-processes-lock)
59                (find id all-processes
60                      :key #'(lambda (p)
61                               (process-name p))
62                      :test #'equal))))))
63
64
65
66(defun not-in-current-process (p operation)
67  (if (eq p *current-process*)
68    (error "The current process (~s) can't perform the ~a operation on itself."
69           p operation)))
70
71(defun startup-shutdown-processes ()
72  (let* ((p))
73    (loop
74      (unless (setq p (pop-shutdown-processes)) (return))
75      (new-tcr-for-thread (process-thread p))
76      (%process-preset-internal p)
77      (process-enable p)
78      )))
79
80;;; Done with a queue-fixup so that it will be the last thing
81;;; that happens on startup.
82(queue-fixup
83 (pushnew 'startup-shutdown-processes *lisp-system-pointer-functions*))
84
85
86
87
88
89
90
91(defun wrap-initial-bindings (alist)
92  (mapcar #'(lambda (pair)
93              (destructuring-bind (symbol . valform) pair
94                (cons (require-type symbol 'symbol)
95                      (cond ((symbolp valform)
96                             (constantly (symbol-value valform)))
97                            ((typep valform 'function) valform)
98                            ((consp valform)
99                             (if (eq (car valform) 'quote)
100                               (constantly (cadr valform))
101                               #'(lambda () (apply (car valform) (cdr valform)))))
102                            (t
103                             (constantly valform))))))
104          alist))
105
106
107(defun valid-allocation-quantum-p (x)
108  (and (>= x *host-page-size*)
109       (<= x (default-allocation-quantum))
110       (= (logcount x) 1)))
111
112 
113(let* ((psn -1))
114  (defun %new-psn () (incf psn)))
115
116(defclass process ()
117    ((name :initform nil :initarg :name :accessor process-name)
118     (thread :initarg :thread :initform nil :accessor process-thread)
119     (initial-form :initform (cons nil nil) :reader process-initial-form)
120     (priority :initform 0 :initarg :priority :accessor process-priority)
121     (persistent :initform nil :initarg :persistent :reader process-persistent)
122     (splice :initform (cons nil nil) :accessor process-splice)
123     (initial-bindings :initform nil :initarg :initial-bindings
124                       :accessor process-initial-bindings)
125     (serial-number :initform (%new-psn) :accessor process-serial-number)
126     (creation-time :initform (get-tick-count) :reader process-creation-time)
127     (total-run-time :initform nil :accessor %process-total-run-time)
128     (ui-object :initform (application-ui-object *application*)
129                :accessor process-ui-object)
130     (termination-semaphore :initform nil
131                            :initarg :termination-semaphore
132                            :accessor process-termination-semaphore
133                            :type (or null semaphore))
134     (allocation-quantum :initform (default-allocation-quantum)
135                         :initarg :allocation-quantum
136                         :reader process-allocation-quantum
137                         :type (satisfies valid-allocation-quantum-p))
138     (dribble-stream :initform nil)
139     (dribble-saved-terminal-io :initform nil)
140     (result :initform (cons nil nil)
141             :reader process-result))
142  (:primary-p t))
143
144(defparameter *print-process-whostate* t "make it optional")
145
146(defmethod print-object ((p process) s)
147  (print-unreadable-object (p s :type t :identity t)
148    (format s "~a(~d)" (process-name p)
149            (process-serial-number p))
150    (when *print-process-whostate*
151      (format s " [~a]" (process-whostate p)))))
152
153(defvar *process-class* (find-class 'process))
154
155(defun processp (p)
156  (memq *process-class* (class-precedence-list (class-of p))))
157
158(set-type-predicate 'process 'processp)
159
160(defun make-process (name &key 
161                          thread
162                          persistent
163                          (priority 0)
164                          (stack-size *default-control-stack-size*)
165                          (vstack-size *default-value-stack-size*)
166                          (tstack-size *default-temp-stack-size*)
167                          (initial-bindings ())
168                          (use-standard-initial-bindings t)
169                          (class (find-class 'process))
170                          (termination-semaphore ())
171                          (allocation-quantum (default-allocation-quantum)))
172  "Create and return a new process."
173  (let* ((p (make-instance
174             class
175             :name name
176             :priority priority
177             :persistent persistent
178             :initial-bindings (append (if use-standard-initial-bindings
179                                         (standard-initial-bindings))
180                                       (wrap-initial-bindings
181                                        initial-bindings))
182             :termination-semaphore (or termination-semaphore
183                                        (make-semaphore))
184             :allocation-quantum allocation-quantum)))
185    (with-slots ((lisp-thread thread)) p
186      (unless lisp-thread
187        (setq lisp-thread
188              (or thread
189                  (new-thread name stack-size  vstack-size  tstack-size)))))
190    (add-to-all-processes p)
191    (setf (car (process-splice p)) p)
192    p))
193
194
195(defstatic *initial-process*
196    (let* ((p (make-process
197               "Initial"
198               :thread *initial-lisp-thread*
199               :priority 0)))
200      p))
201
202
203(defvar *current-process* *initial-process*
204  "Bound in each process, to that process itself.")
205
206(defstatic *interactive-abort-process* *initial-process*)
207
208
209
210
211(defun process-tcr (p)
212  (lisp-thread.tcr (process-thread p)))
213
214
215
216(defun process-exhausted-p (p)
217  (let* ((thread (process-thread p)))
218    (or (null thread)
219        (thread-exhausted-p thread))))
220 
221;;; This should be way more concerned about being correct and thread-safe
222;;; than about being quick: it's generally only called while printing
223;;; or debugging, and there are all kinds of subtle race conditions
224;;; here.
225(defun process-whostate (p)
226  "Return a string which describes the status of a specified process."
227    (let* ((ip *initial-process*))
228      (cond ((eq p *current-process*)
229             (if (%tcr-binding-location (%current-tcr) '*whostate*)
230               *whostate*
231               (if (eq p ip)
232                 "Active"
233                 "Reset")))
234            (t
235             (without-interrupts
236              (with-lock-grabbed (*kernel-exception-lock*)
237               (with-lock-grabbed (*kernel-tcr-area-lock*)
238                 (let* ((tcr (process-tcr p)))
239                   (if tcr
240                     (unwind-protect
241                          (let* ((loc nil))
242                            (%suspend-tcr tcr)
243                            (setq loc (%tcr-binding-location tcr '*whostate*))
244                            (if loc
245                              (%fixnum-ref loc)
246                              (if (eq p ip)
247                                "Active"
248                                "Reset")))
249                       (%resume-tcr tcr))
250                     "Exhausted")))))))))
251
252(defun (setf process-whostate) (new p)
253  (unless (process-exhausted-p p)
254    (setf (symbol-value-in-process '*whostate* p) new)))
255
256
257
258(defun process-total-run-time (p)
259  (or (%process-total-run-time p)
260      (thread-total-run-time (process-thread p))))
261
262
263
264
265(defun initial-bindings (alist)
266  (let* ((symbols ())
267         (values ()))
268    (dolist (a alist (values (nreverse symbols) (nreverse values)))
269      (push (car a) symbols)
270      (push (funcall (cdr a)) values))))
271
272
273                           
274(defun symbol-value-in-process (sym process)
275  (if (eq process *current-process*)
276    (symbol-value sym)
277    (let* ((val
278            (without-interrupts
279             (with-lock-grabbed (*kernel-exception-lock*)
280               (with-lock-grabbed (*kernel-tcr-area-lock*)
281                 (let* ((tcr (process-tcr process)))
282                   (if tcr
283                     (symbol-value-in-tcr sym tcr)
284                     (%sym-global-value sym))))))))
285      (if (eq val (%unbound-marker))
286        ;; This might want to be a CELL-ERROR.
287        (error "~S is unbound in ~S." sym process)
288        val))))
289
290(defun (setf symbol-value-in-process) (value sym process)
291  (if (eq process *current-process*)
292    (setf (symbol-value sym) value)
293    (with-lock-grabbed (*kernel-exception-lock*)
294      (with-lock-grabbed (*kernel-tcr-area-lock*)
295        (let* ((tcr (process-tcr process)))
296          (if tcr
297            (setf (symbol-value-in-tcr sym tcr) value)
298            (%set-sym-global-value sym value)))))))
299
300
301(defmethod process-enable ((p process) &optional (wait (* 60 60 24) wait-p))
302  "Begin executing the initial function of a specified process."
303  (not-in-current-process p 'process-enable)
304  (when wait-p
305    (check-type wait (unsigned-byte 32)))
306  (unless (car (process-initial-form p))
307    (error "Process ~s has not been preset.  Use PROCESS-PRESET to preset the process." p))
308  (let* ((thread (process-thread p)))
309    (do* ((total-wait wait (+ total-wait wait)))
310         ((thread-enable thread (process-termination-semaphore p) (1- (integer-length (process-allocation-quantum p)))  wait)
311          (process-tcr-enable p (lisp-thread.tcr thread))
312          p)
313      (cerror "Keep trying."
314              "Unable to enable process ~s; have been trying for ~s seconds."
315              p total-wait))))
316
317(defmethod process-tcr-enable ((process process) tcr)
318  (when (and tcr (not (eql 0 tcr)))
319    (%signal-semaphore-ptr (%fixnum-ref-macptr tcr target::tcr.activate))
320    ))
321
322
323
324(defun process-resume (p)
325  "Resume a specified process which had previously been suspended
326by process-suspend."
327  (setq p (require-type p 'process))
328  (let* ((tcr (process-tcr p)))
329    (and tcr (%resume-tcr tcr))))
330
331(defun process-suspend (p)
332  "Suspend a specified process."
333  (setq p (require-type p 'process))
334  (if (eq p *current-process*)
335    (error "Suspending the current process can't work.  ~&(If the documentation claims otherwise, it's incorrect.)")
336    (let* ((tcr (process-tcr p)))
337      (and tcr (%suspend-tcr tcr)))))
338
339(defun process-suspend-count (p)
340  "Return the number of currently-pending suspensions applicable to
341a given process."
342  (setq p (require-type p 'process))
343  (let* ((thread (process-thread p)))
344    (if thread
345      (lisp-thread-suspend-count thread))))
346
347(defun process-active-p (p)
348  (setq p (require-type p 'process))
349  (and (eql 0 (process-suspend-count p))
350       (not (process-exhausted-p p))))
351 
352;;; Used by process-run-function
353(defmethod process-preset ((p process) function &rest args)
354  "Set the initial function and arguments of a specified process."
355  (let* ((f (require-type function 'function))
356         (initial-form (process-initial-form p)))
357    (declare (type cons initial-form))
358    (not-in-current-process p 'process-preset)
359    ; Not quite right ...
360    (rplaca initial-form f)
361    (rplacd initial-form args)
362    (%process-preset-internal p)))
363
364(defmethod %process-preset-internal ((process process))
365   (let* ((initial-form (process-initial-form process))
366         (thread (process-thread process)))
367     (declare (type cons initial-form))
368     (thread-preset
369      thread
370      #'(lambda (process initial-form)
371          (let* ((*current-process* process))
372            (add-to-all-processes process)
373            (with-initial-bindings (process-initial-bindings process)
374              (setq *whostate* "Active")
375              (run-process-initial-form process initial-form))))
376      process
377      initial-form)
378     process))
379
380
381(defun run-process-initial-form (process initial-form)
382  (let* ((exited nil)
383         (kill (handler-case
384                   (restart-case
385                    (let ((values
386                           (multiple-value-list
387                            (apply (car initial-form)
388                                   (cdr (the list initial-form)))))
389                          (result (process-result process)))
390                      (setf (cdr result) values
391                            (car result) t)
392                      (setq exited t)
393                      nil)
394                    (abort-break () :report "Reset this thread")
395                    (abort () :report "Kill this thread" (setq exited t)))
396                 (process-reset (condition)
397                   (process-reset-kill condition)))))
398    ;; We either exited from the initial form normally, were told to
399    ;; exit prematurely, or are being reset and should enter the
400    ;; "awaiting preset" state.
401    (if (or kill exited) 
402      (unless (eq kill :toplevel)
403        (process-initial-form-exited process (or kill t)))
404      (progn
405        (thread-change-state (process-thread process) :run :reset)
406        (tcr-set-preset-state (process-tcr process))))
407    nil))
408
409;;; Separated from run-process-initial-form just so I can change it easily.
410(defun process-initial-form-exited (process kill)
411  (without-interrupts
412   (if (eq kill :shutdown)
413     (progn
414       (setq *whostate* "Shutdown")
415       (add-to-shutdown-processes process)))
416   (let* ((semaphore (process-termination-semaphore process)))
417     (when semaphore (signal-semaphore semaphore)))
418   (maybe-finish-process-kill process kill)))
419
420(defun maybe-finish-process-kill (process kill)
421  (when (and kill (neq kill :shutdown))
422    (setf (process-whostate process) "Dead")
423    (remove-from-all-processes process)
424    (let ((thread (process-thread process)))
425      (unless (or (eq thread *current-lisp-thread*)
426                  (thread-exhausted-p thread))
427        (kill-lisp-thread thread))))
428  nil)
429
430
431 
432
433(defun require-global-symbol (s &optional env)
434  (let* ((s (require-type s 'symbol))
435         (bits (%symbol-bits s)))
436    (unless (or (logbitp $sym_vbit_global bits)
437                (let* ((defenv (if env (definition-environment env))))
438                  (if defenv
439                    (eq :global (%cdr (assq s (defenv.specials defenv)))))))
440      (error "~s not defined with ~s" s 'defstatic))
441    s))
442
443
444(defmethod print-object ((s lock) stream)
445  (print-unreadable-object (s stream :type t :identity t)
446    (let* ((val (uvref s target::lock._value-cell))
447           (name (uvref s target::lock.name-cell)))
448      (when name
449        (format stream "~s " name))
450      (if (typep val 'macptr)
451        (format stream "[ptr @ #x~x]"
452                (%ptr-to-int val))))))
453
454(defun lockp (l)
455  (eq target::subtag-lock (typecode l)))
456
457(set-type-predicate 'lock 'lockp)
458
459(defun recursive-lock-p (l)
460  (and (eq target::subtag-lock (typecode l))
461       (eq 'recursive-lock (%svref l target::lock.kind-cell))))
462
463(defun read-write-lock-p (l)
464  (and (eq target::subtag-lock (typecode l))
465       (eq 'read-write-lock (%svref l target::lock.kind-cell))))
466
467(setf (type-predicate 'recursive-lock) 'recursive-lock-p
468      (type-predicate 'read-write-lock) 'read-write-lock-p)
469
470
471(defun grab-lock (lock &optional flag)
472  "Wait until a given lock can be obtained, then obtain it."
473  (%lock-recursive-lock-object lock flag))
474
475(defun release-lock (lock)
476  "Relinquish ownership of a given lock."
477  (%unlock-recursive-lock-object lock))
478
479(defun try-lock (lock &optional flag)
480  "Obtain the given lock, but only if it is not necessary to wait for it."
481  (%try-recursive-lock-object lock flag))
482
483(defun lock-acquisition-status (thing)
484  (if (istruct-typep thing 'lock-acquisition)
485    (lock-acquisition.status thing)
486    (report-bad-arg thing 'lock-acquisition)))
487
488(defun clear-lock-acquisition-status (thing)
489  (if (istruct-typep thing 'lock-acquisition)
490    (setf (lock-acquisition.status thing) nil)
491    (report-bad-arg thing 'lock-acquisition)))
492
493(defmethod print-object ((l lock-acquisition) stream)
494  (print-unreadable-object (l stream :type t :identity t)
495    (format stream "[status = ~s]" (lock-acquisition-status l))))
496
497(defun semaphore-notification-status (thing)
498  (if (istruct-typep thing 'semaphore-notification)
499    (semaphore-notification.status thing)
500    (report-bad-arg thing 'semaphore-notification)))
501
502(defun clear-semaphore-notification-status (thing)
503  (if (istruct-typep thing 'semaphore-notification)
504    (setf (semaphore-notification.status thing) nil)
505    (report-bad-arg thing 'semaphore-notification)))
506
507(defmethod print-object ((l semaphore-notification) stream)
508  (print-unreadable-object (l stream :type t :identity t)
509    (format stream "[status = ~s]" (semaphore-notification-status l))))
510
511(defun process-wait (whostate function &rest args)
512  "Causes the current lisp process (thread) to wait for a given
513predicate to return true."
514  (declare (dynamic-extent args))
515  (or (apply function args)
516      (with-process-whostate (whostate)
517        (loop
518          (when (apply function args)
519            (return))
520          ;; Sleep for a tick
521          #-windows-target
522          (%nanosleep 0 *ns-per-tick*)
523          #+windows-target
524          (%windows-sleep 5)))))
525
526
527
528(defun process-wait-with-timeout (whostate time function &rest args)
529  "Cause the current thread to wait for a given predicate to return true,
530or for a timeout to expire."
531  (declare (dynamic-extent args))
532  (cond ((null time)  (apply #'process-wait whostate function args) t)
533        (t (let* ((win nil)
534                  (when (+ (get-tick-count) time))
535                  (f #'(lambda () (let ((val (apply function args)))
536                                    (if val
537                                      (setq win val)
538                                      (> (get-tick-count) when))))))
539             (declare (dynamic-extent f))
540             (process-wait whostate f)
541             win))))
542
543
544(defmethod process-interrupt ((process process) function &rest args)
545  "Arrange for the target process to invoke a specified function at
546some point in the near future, and then return to what it was doing."
547  (let* ((p (require-type process 'process)))
548    (if (eq p *current-process*)
549      (progn
550        (apply function args)
551        t)
552      (thread-interrupt
553       (process-thread p)
554       process
555       #'apply
556       function args))))
557
558(defmethod process-debug-condition ((p process) condition frame-pointer)
559  (declare (ignore condition frame-pointer)))
560
561
562
563
564;;; This one is in the Symbolics documentation
565(defun process-allow-schedule ()
566  "Used for cooperative multitasking; probably never necessary."
567  (process-yield *current-process*))
568
569
570;;; something unique that users won't get their hands on
571(defun process-reset-tag (process)
572  (process-splice process))
573
574(defun process-run-function (name-or-keywords function &rest args)
575  "Create a process, preset it, and enable it."
576  (if (listp name-or-keywords)
577    (%process-run-function name-or-keywords function args)
578    (let ((keywords (list :name name-or-keywords)))
579      (declare (dynamic-extent keywords))
580      (%process-run-function keywords function args))))
581
582(defun %process-run-function (keywords function args)
583  (destructuring-bind (&key (name "Anonymous")
584                            (priority  0)
585                            (stack-size *default-control-stack-size*)
586                            (vstack-size *default-value-stack-size*)
587                            (tstack-size *default-temp-stack-size*)
588                            (initial-bindings ())
589                            (persistent nil)
590                            (use-standard-initial-bindings t)
591                            (termination-semaphore nil)
592                            (allocation-quantum (default-allocation-quantum)))
593                      keywords
594    (setq priority (require-type priority 'fixnum))
595    (let* ((process (make-process name
596                                  :priority priority
597                                  :stack-size stack-size
598                                  :vstack-size vstack-size
599                                  :tstack-size tstack-size
600                                  :persistent persistent
601                                  :use-standard-initial-bindings use-standard-initial-bindings
602                                  :initial-bindings initial-bindings
603                                  :termination-semaphore termination-semaphore
604                                  :allocation-quantum allocation-quantum)))
605      (process-preset process #'(lambda () (apply function args)))
606      (process-enable process)
607      process)))
608
609(defmethod process-reset ((process process) &optional kill)
610  "Cause a specified process to cleanly exit from any ongoing computation."
611  (setq process (require-type process 'process))
612  (unless (memq kill '(nil :kill :shutdown))
613    (setq kill (require-type kill '(member nil :kill :shutdown))))
614  (if (eq process *current-process*)
615    (%process-reset kill)
616    (if (process-exhausted-p process)
617      (maybe-finish-process-kill process kill)
618      (progn
619        (process-interrupt process '%process-reset kill)))))
620
621(defmethod process-yield ((p process))
622  #+windows-target (#_Sleep 0)
623  #-windows-target (#_sched_yield))
624
625
626(defun %process-reset (kill)
627  (signal 'process-reset :kill kill)
628  (maybe-finish-process-kill *current-process* kill))
629
630;;; By default, it's just fine with the current process
631;;; if the application/user wants to quit.
632(defmethod process-verify-quit ((process process))
633  t)
634
635(defmethod process-exit-application ((process process) thunk)
636  (when (eq process *initial-process*)
637    (with-standard-abort-handling "Exit Lisp"
638      (prepare-to-quit)
639      ;; We may have abruptly terminated a thread which owned the
640      ;; output lock on a stream we want to flush.  Don't block
641      ;; waiting on the lock if so.
642      (flet ((flush-stream (s)
643               (let* ((lock (ioblock-outbuf-lock (basic-stream-ioblock s)))
644                      (locked (make-lock-acquisition)))
645                 (declare (dynamic-extent locked))
646                 (when (or (null lock)
647                           (%try-recursive-lock-object lock locked))
648                   (unwind-protect
649                        (progn
650                          (fresh-line s)
651                          (finish-output s))
652                     (when (lock-acquisition.status locked)
653                       (release-lock lock)))))))
654        (flush-stream *stdout*)
655        (flush-stream *stderr*)))
656    (%set-toplevel thunk)
657    (toplevel)))
658
659
660
661(defmethod process-kill ((process process))
662  "Cause a specified process to cleanly exit from any ongoing
663computation, and then exit."
664  (and (process-interrupt process #'%process-reset :kill)
665       (setf (process-kill-issued process) t)))
666
667(defun process-abort (process &optional condition)
668  "Cause a specified process to process an abort condition, as if it
669had invoked abort."
670  (process-interrupt process
671                     #'(lambda ()
672                         (abort condition))))
673
674(defmethod process-reset-and-enable ((process process))
675  (not-in-current-process process 'process-reset-and-enable)
676  (process-reset process)
677  (process-enable process))
678
679(defmethod process-kill-issued ((process process))
680  (cdr (process-splice process)))
681
682(defmethod (setf process-kill-issued) (val (process process))
683  (setf (cdr (process-splice process)) val))
684
685(defun tcr->process (tcr)
686  (dolist (p (all-processes))
687    (when (eq tcr (process-tcr p))
688      (return p))))
689
690(defun current-process-allocation-quantum ()
691  (process-allocation-quantum *current-process*))
692
693(defun (setf current-process-allocation-quantum) (new)
694  (if (valid-allocation-quantum-p new)
695    (with-macptrs (tcrp)
696      (%setf-macptr-to-object tcrp (%current-tcr))
697      (setf (slot-value *current-process* 'allocation-quantum) new
698            (%get-natural tcrp target::tcr.log2-allocation-quantum)
699            (1- (integer-length new)))
700      new)
701    (report-bad-arg new '(satisfies valid-allocation-quantum-p))))
702
703
704(def-standard-initial-binding *backtrace-contexts* nil)
705
706(defmethod exit-interactive-process ((p process))
707  (unless (eq p *initial-process*)
708    (when (eq p *current-process*)
709      (process-kill p))))
710
711(defclass tty-listener (process)
712    ())
713
714(defmethod exit-interactive-process ((p tty-listener))
715  (when (eq p *current-process*)
716    (quit)))
717
718(defmethod process-stop-dribbling ((p process))
719  (with-slots (dribble-stream dribble-saved-terminal-io) p
720    (when dribble-stream
721      (close dribble-stream)
722      (setq dribble-stream nil))
723    (when dribble-saved-terminal-io
724      (setq *terminal-io* dribble-saved-terminal-io
725            dribble-saved-terminal-io nil))))
726
727(defmethod process-dribble ((p process) path)
728  (with-slots (dribble-stream dribble-saved-terminal-io) p
729    (process-stop-dribbling p)
730    (when path
731      (let* ((in (two-way-stream-input-stream *terminal-io*))
732             (out (two-way-stream-output-stream *terminal-io*))
733             (f (open path :direction :output :if-exists :append 
734                      :if-does-not-exist :create)))
735        (without-interrupts
736         (setq dribble-stream f
737               dribble-saved-terminal-io *terminal-io*
738               *terminal-io* (make-echoing-two-way-stream
739                              (make-echo-stream in f)
740                              (make-broadcast-stream out f)))))
741      path)))
742
743(defmethod join-process ((p process) &key default)
744  (wait-on-semaphore (process-termination-semaphore p) nil "join-process")
745  (let ((result (process-result p)))
746    (cond ((car result) (values-list (cdr result)))
747          (t default))))
748
749(defun call-in-process (f process)
750  (let* ((return-values nil)
751         (done (make-semaphore)))
752    (process-interrupt process
753                       #'(lambda ()
754                           (unwind-protect
755                                (progn
756                                  (setq return-values
757                                        (multiple-value-list (funcall f))))
758                             (signal-semaphore done))))
759    (wait-on-semaphore done)
760    (apply #'values return-values)))
761
762(defun call-in-initial-process (f)
763  (call-in-process f *initial-process*))
764
Note: See TracBrowser for help on using the repository browser.