source: release/1.3/source/compiler/nx-basic.lisp @ 11928

Last change on this file since 11928 was 11928, checked in by rme, 11 years ago

Merge trunk changes r11900 through r11919.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 28.8 KB
Line 
1;;;-*- Mode: Lisp; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; used by compiler and eval - stuff here is not excised with rest of compiler
19
20
21(in-package :ccl)
22
23#|| Note: when MCL-AppGen 4.0 is built, the following form will need to be included in it:
24; for compiler-special-form-p, called by cheap-eval-in-environment
25(defparameter *nx1-compiler-special-forms*
26  `(%DEFUN %FUNCTION %NEW-PTR %NEWGOTAG %PRIMITIVE %VREFLET BLOCK CATCH COMPILER-LET DEBIND
27    DECLARE EVAL-WHEN FBIND FLET FUNCTION GO IF LABELS LAP LAP-INLINE LET LET* LOAD-TIME-VALUE
28    LOCALLY MACRO-BIND MACROLET MAKE-LIST MULTIPLE-VALUE-BIND MULTIPLE-VALUE-CALL
29    MULTIPLE-VALUE-LIST MULTIPLE-VALUE-PROG1 NEW-LAP NEW-LAP-INLINE NFUNCTION OLD-LAP
30    OLD-LAP-INLINE OR PROG1 PROGN PROGV QUOTE RETURN-FROM SETQ STRUCT-REF STRUCT-SET
31    SYMBOL-MACROLET TAGBODY THE THROW UNWIND-PROTECT WITH-STACK-DOUBLE-FLOATS WITHOUT-INTERRUPTS))
32||#
33
34(eval-when (:compile-toplevel)
35  (require 'nxenv))
36
37(defvar *lisp-compiler-version* 666 "I lost count.")
38
39(defvar *nx-compile-time-types* nil)
40(defvar *nx-proclaimed-types* nil)
41(defvar *nx-method-warning-name* nil)
42
43(defvar *nx-current-code-note*)
44
45;; In lieu of a slot in acode.  Don't reference this variable elsewhere because I'm
46;; hoping to make it go away.
47(defparameter *nx-acode-note-map* nil)
48
49(defun acode-note (acode &aux (hash *nx-acode-note-map*))
50  (and hash (gethash acode hash)))
51
52(defun (setf acode-note) (note acode)
53  (when note
54    (assert *nx-acode-note-map*)
55    (setf (gethash acode *nx-acode-note-map*) note)))
56
57
58(defstruct (code-note (:constructor %make-code-note))
59  ;; Code coverage state.  This MUST be the first slot - see nx2-code-coverage.
60  code-coverage
61  ;; The actual source form - useful for debugging, otherwise unused.
62  #+debug-code-notes form
63  ;; The source note of this form, or NIL if random code form (no file info,
64  ;; generated by macros or other source transform)
65  source-note
66  ;; the note that was being compiled when this note was emitted.
67  parent-note)
68
69(defun make-code-note (&key form source-note parent-note)
70  (declare (ignorable form))
71  (let ((note (%make-code-note
72               :source-note source-note
73               :parent-note parent-note)))
74    #+debug-code-notes
75    (when form
76      ;; Unfortunately, recording the macroexpanded form is problematic, since they
77      ;; can have references to non-dumpable forms, see e.g. loop.
78      (setf (code-note-form note)
79            (with-output-to-string (s) (let ((*print-circle* t)) (prin1 form s)))))
80    note))
81
82(defun nx-ensure-code-note (form &optional parent-note)
83  (let* ((parent-note (or parent-note *nx-current-code-note*))
84         (source-note (nx-source-note form)))
85    (unless (and source-note
86                 ;; Look out for a case like a lambda macro that turns (lambda ...)
87                 ;; into (FUNCTION (lambda ...)) which then has (lambda ...)
88                 ;; as a child.  Create a fresh note for the child, to avoid ambiguity.
89                 ;; Another case is forms wrapping THE around themselves.
90                 (neq source-note (code-note-source-note parent-note))
91                 ;; Don't use source notes from a different toplevel form, which could
92                 ;; happen due to inlining etc.  The result then is that the source note
93                 ;; appears in multiple places, and shows partial coverage (from the
94                 ;; other reference) in code that's never executed.
95                 (loop for p = parent-note then (code-note-parent-note p)
96                       when (null p) return t
97                       when (code-note-source-note p)
98                       return (eq (loop for n = source-note then s
99                                        as s = (source-note-source n)
100                                        unless (source-note-p s) return n)
101                                  (loop for n = (code-note-source-note p) then s
102                                        as s = (source-note-source n)
103                                        unless (source-note-p s) return n))))
104      (setq source-note nil))
105    (make-code-note :form form :source-note source-note :parent-note parent-note)))
106
107(defun nx-note-source-transformation (original new &aux (source-notes *nx-source-note-map*) sn)
108  (when (and source-notes
109             (setq sn (gethash original source-notes))
110             (not (gethash new source-notes)))
111    (setf (gethash new source-notes) sn)))
112
113
114(defvar *nx1-alphatizers* (make-hash-table :size 180 :test #'eq))
115
116(let ((policy (%istruct 'compiler-policy
117               #'(lambda (env)
118                   #+ccl-0711 (< (debug-optimize-quantity env) 2)
119                   #-ccl-0711 (neq (debug-optimize-quantity env) 3))   ;  allow-tail-recursion-elimination
120               #'(lambda (env)
121                   (declare (ignorable env))
122                   #+ccl-0711 nil
123                   #-ccl-0711 (eq (debug-optimize-quantity env) 3))   ; inhibit-register-allocation
124               #'(lambda (env)
125                   (let* ((safety (safety-optimize-quantity env)))
126                     (and (< safety 3)
127                          (>= (speed-optimize-quantity env)
128                              safety)))) ; trust-declarations
129               #'(lambda (env)
130                   #+ccl-0711 (> (speed-optimize-quantity env)
131                                 (space-optimize-quantity env))
132                   #-ccl-0711 (>= (speed-optimize-quantity env)
133                                  (+ (space-optimize-quantity env) 2))) ; open-code-inline
134               #'(lambda (env)
135                   (and (eq (speed-optimize-quantity env) 3) 
136                        (eq (safety-optimize-quantity env) 0)))   ; inhibit-safety-checking
137               #'(lambda (env)
138                   (let* ((safety (safety-optimize-quantity env)))
139                     (or (eq safety 3)
140                         (> safety (speed-optimize-quantity env)))))          ;the-typechecks
141               #'(lambda (env)
142                   (neq (debug-optimize-quantity env) 3))   ; inline-self-calls
143               #'(lambda (env)
144                   (and (neq (compilation-speed-optimize-quantity env) 3)
145                        (neq (safety-optimize-quantity env) 3)
146                        #+ccl-0711 (neq (speed-optimize-quantity env) 0)
147                        (neq (debug-optimize-quantity env) 3))) ; allow-transforms
148               #'(lambda (var env)       ; force-boundp-checks
149                   (declare (ignore var))
150                   (eq (safety-optimize-quantity env) 3))
151               #'(lambda (var val env)       ; allow-constant-substitution
152                   (declare (ignore var val env))
153                   t)
154               nil           ; extensions
155               )))
156  (defun new-compiler-policy (&key (allow-tail-recursion-elimination nil atr-p)
157                                   (inhibit-register-allocation nil ira-p)
158                                   (trust-declarations nil td-p)
159                                   (open-code-inline nil oci-p)
160                                   (inhibit-safety-checking nil ischeck-p)
161                                   (inline-self-calls nil iscall-p)
162                                   (allow-transforms nil at-p)
163                                   (force-boundp-checks nil fb-p)
164                                   (allow-constant-substitution nil acs-p)
165                                   (the-typechecks nil tt-p))
166    (let ((p (copy-uvector policy)))
167      (if atr-p (setf (policy.allow-tail-recursion-elimination p) allow-tail-recursion-elimination))
168      (if ira-p (setf (policy.inhibit-register-allocation p) inhibit-register-allocation))
169      (if td-p (setf (policy.trust-declarations p) trust-declarations))
170      (if oci-p (setf (policy.open-code-inline p) open-code-inline))
171      (if ischeck-p (setf (policy.inhibit-safety-checking p) inhibit-safety-checking))
172      (if iscall-p (setf (policy.inline-self-calls p) inline-self-calls))
173      (if at-p (setf (policy.allow-transforms p) allow-transforms))
174      (if fb-p (setf (policy.force-boundp-checks p) force-boundp-checks))
175      (if acs-p (setf (policy.allow-constant-substitution p) allow-constant-substitution))
176      (if tt-p (setf (policy.the-typechecks p) the-typechecks))
177      p))
178  (defun %default-compiler-policy () policy))
179
180(%include "ccl:compiler;lambda-list.lisp")
181
182
183
184;Syntactic Environment Access.
185
186(defun declaration-information (decl-name &optional env)
187  (if (and env (not (istruct-typep env 'lexical-environment)))
188    (report-bad-arg env 'lexical-environment))
189; *** This needs to deal with things defined with DEFINE-DECLARATION ***
190  (case decl-name
191    (optimize
192     (list 
193      (list 'speed (speed-optimize-quantity env))
194      (list 'safety (safety-optimize-quantity env))
195      (list 'compilation-speed (compilation-speed-optimize-quantity env))
196      (list 'space (space-optimize-quantity env))
197      (list 'debug (debug-optimize-quantity env))))
198    (declaration
199     *nx-known-declarations*)))
200
201(defun function-information (name &optional env &aux decls)
202  (let ((name (ensure-valid-function-name name)))
203    (if (and env (not (istruct-typep env 'lexical-environment)))
204      (report-bad-arg env 'lexical-environment))
205    (if (special-operator-p name)
206      (values :special-form nil nil)
207      (flet ((process-new-fdecls (fdecls)
208                                 (dolist (fdecl fdecls)
209                                   (when (eq (car fdecl) name)
210                                     (let ((decl-type (cadr fdecl)))
211                                       (when (and (memq decl-type '(dynamic-extent inline ftype))
212                                                  (not (assq decl-type decls)))
213                                         (push (cdr fdecl) decls)))))))
214        (declare (dynamic-extent #'process-new-fdecls))
215        (do* ((root t)
216              (contour env (when root (lexenv.parent-env contour))))
217             ((null contour)
218              (if (macro-function name)
219                (values :macro nil nil)
220                (if (fboundp name)
221                  (values :function 
222                          nil 
223                          (if (assq 'inline decls)
224                            decls
225                            (if (proclaimed-inline-p name)
226                              (push '(inline . inline) decls)
227                                (if (proclaimed-notinline-p name)
228                                  (push '(inline . notinline) decls)))))
229                  (values nil nil decls))))
230          (if (istruct-typep contour 'definition-environment)
231            (if (assq name (defenv.functions contour))
232              (return (values :macro nil nil))
233              (progn (setq root nil) (process-new-fdecls (defenv.fdecls contour))))
234            (progn
235              (process-new-fdecls (lexenv.fdecls contour))
236              (let ((found (assq name (lexenv.functions contour))))
237                (when found
238                  (return
239                   (if (and (consp (cdr found))(eq (%cadr found) 'macro))
240                     (values :macro t nil)
241                     (values :function t decls))))))))))))
242
243(defun variable-information (var &optional env)
244  (setq var (require-type var 'symbol))
245  (if (and env (not (istruct-typep env 'lexical-environment)))
246    (report-bad-arg env 'lexical-environment))
247  (let* ((vartype nil)
248         (boundp nil)
249         (envtype nil)
250         (typedecls (nx-declared-type var env)) ; should grovel nested/shadowed special decls for us.
251         (decls (if (and typedecls (neq t typedecls)) (list (cons 'type typedecls)))))
252    (loop
253      (cond ((null env)
254             (if (constant-symbol-p var)
255               (setq vartype :constant decls nil)
256               (if (proclaimed-special-p var)
257                 (setq vartype :special)
258                 (let* ((not-a-symbol-macro (cons nil nil)))
259                   (declare (dynamic-extent not-a-symbol-macro))
260                   (unless (eq (gethash var *symbol-macros* not-a-symbol-macro)
261                               not-a-symbol-macro)
262                     (setq vartype :symbol-macro)))))
263             (return))
264            ((eq (setq envtype (istruct-type-name env)) 'definition-environment)
265             (cond ((assq var (defenv.constants env))
266                    (setq vartype :constant)
267                    (return))
268                   ((assq var (defenv.symbol-macros env))
269                    (setq vartype :symbol-macro)
270                    (return))
271                   ((assq var (defenv.specials env))
272                    (setq vartype :special)
273                    (return))))
274            (t
275             (dolist (vdecl (lexenv.vdecls env))
276               (when (eq (car vdecl) var)
277                 (let ((decltype (cadr vdecl)))
278                   (unless (assq decltype decls)
279                     (case decltype
280                       (special (setq vartype :special))
281                       ((type dynamic-extent ignore) (push (cdr vdecl) decls)))))))
282             (let ((vars (lexenv.variables env)))
283               (unless (atom vars)
284                 (dolist (v vars)
285                   (when (eq (var-name v) var)
286                     (setq boundp t)
287                     (if (and (consp (var-ea v))
288                              (eq :symbol-macro (car (var-ea v))))
289                       (setq vartype :symbol-macro)
290                       (unless vartype (setq vartype
291                                             (let* ((bits (var-bits v)))
292                                               (if (and (typep bits 'integer)
293                                                        (logbitp $vbitspecial bits))
294                                                 :special
295                                                 :lexical)))))
296                     (return)))
297                 (when vartype (return))))))
298      (setq env (if (eq envtype 'lexical-environment) (lexenv.parent-env env))))
299    (values vartype boundp decls)))
300
301(defun nx-target-type (typespec)
302  ;; Could do a lot more here
303  (if (or (eq *host-backend* *target-backend*)
304          (not (eq typespec 'fixnum)))
305    typespec
306    (target-word-size-case
307     (32 '(signed-byte 30))
308     (64 '(signed-byte 61)))))
309
310; Type declarations affect all references.
311(defun nx-declared-type (sym &optional (env *nx-lexical-environment*))
312  (loop
313    (when (or (null env) (istruct-typep env 'definition-environment)) (return))
314    (dolist (decl (lexenv.vdecls env))
315      (if (and (eq (car decl) sym)
316               (eq (cadr decl) 'type))
317               (return-from nx-declared-type (nx-target-type (cddr decl)))))
318    (let ((vars (lexenv.variables env)))
319      (when (and (consp vars) 
320                 (dolist (var vars) 
321                   (when (eq (var-name var) sym) 
322                     (return t))))
323        (return-from nx-declared-type t)))
324    (setq env (lexenv.parent-env env)))
325  (let ((decl (or (assq sym *nx-compile-time-types*)
326                     (assq sym *nx-proclaimed-types*))))
327    (if decl (%cdr decl) t)))
328
329(defmacro define-declaration (decl-name lambda-list &body body &environment env)
330  (multiple-value-bind (body decls)
331                       (parse-body body env)
332    (let ((fn `(nfunction (define-declaration ,decl-name)
333                          (lambda ,lambda-list
334                            ,@decls
335                            (block ,decl-name
336                              ,@body)))))
337      `(progn
338         (proclaim '(declaration ,decl-name))
339         (setf (getf *declaration-handlers* ',decl-name) ,fn)))))
340
341(defun check-environment-args (variable symbol-macro function macro)
342  (flet ((check-all-pairs (pairlist argname)
343          (dolist (pair pairlist)
344            (unless (and (consp pair) (consp (%cdr pair)) (null (%cddr pair)) (symbolp (%car pair)))
345              (signal-simple-program-error "Malformed ~s argument: ~s is not of the form (~S ~S) in ~S" 
346                                           argname
347                                           pair
348                                           'name
349                                           'definition
350                                           pairlist))))
351         (check-all-symbols (symlist argname pairs pairsname)
352          (dolist (v symlist)
353            (unless (symbolp v) 
354              (signal-simple-program-error "Malformed ~S list: ~S is not a symbol in ~S." argname v symlist))
355            (when (assq v pairs) 
356              (signal-simple-program-error "~S ~S conflicts with ~S ~S" argname v pairsname (assq v pairs))))))
357    (check-all-pairs symbol-macro :symbol-macro)
358    (check-all-pairs macro :macro)
359    (check-all-symbols variable :variable symbol-macro :symbol-macro)
360    (check-all-symbols function :function macro :macro)))
361
362
363;; This -isn't- PARSE-DECLARATIONS.  It can't work; neither can this ...
364(defun process-declarations (env decls symbol-macros)
365  (let ((vdecls nil)
366        (fdecls nil)
367        (mdecls nil))
368    (flet ((add-type-decl (spec)
369            (destructuring-bind (typespec &rest vars) spec
370              (dolist (var vars)
371                (when (non-nil-symbol-p var)
372                  (push (list* var 
373                               'type
374                               (let ((already (assq 'type (nth-value 2 (variable-information var env)))))
375                                 (if already
376                                   (let ((oldtype (%cdr already)))
377                                     (if oldtype
378                                       (if (subtypep oldtype typespec)
379                                         oldtype
380                                         (if (subtypep typespec oldtype)
381                                           typespec))))
382                                   typespec)))
383                        vdecls))))))
384      ; do SPECIAL declarations first - this approximates the right thing, but doesn't quite make it.
385      (dolist (decl decls)
386        (when (eq (car decl) 'special)
387          (dolist (spec (%cdr decl))
388            (when (non-nil-symbol-p spec)
389              (if (assq spec symbol-macros)
390                (signal-program-error "Special declaration cannot be applied to symbol-macro ~S" spec))
391              (push (list* spec 'special t) vdecls)))))
392      (dolist (decl decls)
393        (let ((decltype (car decl)))
394          (case decltype
395              ((inline notinline)
396               (dolist (spec (%cdr decl))
397               (let ((fname nil))
398                 (if (non-nil-symbol-p spec)
399                   (setq fname spec)
400                   (if (and (consp spec) (eq (%car spec) 'setf))
401                     (setq fname (setf-function-name (cadr spec)))))
402                 (if fname
403                   (push (list* fname decltype t) fdecls)))))
404              (optimize
405               (dolist (spec (%cdr decl))
406                 (let ((val 3)
407                       (quantity spec))
408                   (if (consp spec)
409                     (setq quantity (car spec) val (cadr spec)))
410                 (if (and (fixnump val) (<= 0 val 3) (memq quantity '(debug speed space safety compilation-speed)))
411                   (push (cons quantity val) mdecls)))))
412              (dynamic-extent
413               (dolist (spec (%cdr decl))
414               (if (non-nil-symbol-p spec)
415                 (push (list* spec decltype t) vdecls)
416                 (if (and (consp spec) (eq (%car spec) 'function))
417                   (let ((fname (cadr spec)))
418                     (if (not (non-nil-symbol-p fname))
419                       (setq fname 
420                             (if (and (consp fname) (eq (%car fname) 'setf))
421                               (setf-function-name (cadr fname)))))
422                     (if fname (push (list* fname decltype t) fdecls)))))))
423              (type (add-type-decl (cdr decl)))
424              (ftype (destructuring-bind (typespec &rest fnames) (%cdr decl)
425                       (dolist (name fnames)
426                         (let ((fname name))
427                           (if (not (non-nil-symbol-p fname))
428                             (setq fname 
429                                   (if (and (consp fname) (eq (%car fname) 'setf))
430                                     (setf-function-name (cadr fname)))))
431                           (if fname (push (list* fname decltype typespec) fdecls))))))
432              (special)
433              (t
434               (if (memq decltype *cl-types*)
435                 (add-type-decl decl)
436                 (let ((handler (getf *declaration-handlers* decltype)))
437                   (when handler
438                     (multiple-value-bind (type info) (funcall handler decl)
439                       (ecase type
440                         (:variable
441                          (dolist (v info) (push (apply #'list* v) vdecls)))
442                         (:function
443                          (dolist (f info) (push (apply #'list* f) fdecls)))
444                         (:declare  ;; N.B. CLtL/2 semantics
445                          (push info mdecls)))))))))))
446      (setf (lexenv.vdecls env) (nconc vdecls (lexenv.vdecls env))
447            (lexenv.fdecls env) (nconc fdecls (lexenv.fdecls env))
448            (lexenv.mdecls env) (nconc mdecls (lexenv.mdecls env))))))
449
450 
451(defun cons-var (name &optional (bits 0))
452  (%istruct 'var name bits nil nil nil nil nil))
453
454
455(defun augment-environment (env &key variable symbol-macro function macro declare)
456  (if (and env (not (istruct-typep env 'lexical-environment)))
457    (report-bad-arg env 'lexical-environment))
458  (check-environment-args variable symbol-macro function macro)
459  (let* ((vars (mapcar #'cons-var variable))
460         (symbol-macros (mapcar #'(lambda (s)
461                                    (let* ((sym (car s)))
462                                      (unless (and (symbolp sym)
463                                                   (not (constantp sym env))
464                                                   (not (eq (variable-information sym env) :special)))
465                                        (signal-program-error "~S can't by bound as a SYMBOL-MACRO" sym))
466                                      (let ((v (cons-var (car s)))) 
467                                        (setf (var-expansion v) (cons :symbol-macro (cadr s)))
468                                        v)))
469                                symbol-macro))
470         (macros (mapcar #'(lambda (m) (list* (car m) 'macro (cadr m))) macro))
471         (functions (mapcar #'(lambda (f) (list* f 'function nil)) function))
472         (new-env (new-lexical-environment env)))
473    (setf (lexenv.variables new-env) (nconc vars symbol-macros)
474          (lexenv.functions new-env) (nconc functions macros))
475    (process-declarations new-env declare symbol-macro)
476    new-env))
477
478(defun enclose (lambda-expression &optional env)
479  (if (and env (not (istruct-typep env 'lexical-environment)))
480    (report-bad-arg env 'lexical-environment))
481  (unless (lambda-expression-p lambda-expression)
482    (error "Invalid lambda-expression ~S." lambda-expression))
483  (%make-function nil lambda-expression env))
484
485#|| Might be nicer to do %declaim
486(defmacro declaim (&rest decl-specs &environment env)
487  `(progn
488     (eval-when (:load-toplevel :execute)
489       (proclaim ',@decl-specs))
490     (eval-when (:compile-toplevel)
491       (%declaim ',@decl-specs ,env))))
492||#
493
494(defmacro declaim (&environment env &rest decl-specs)
495  "DECLAIM Declaration*
496  Do a declaration or declarations for the global environment."
497  (let* ((body (mapcar #'(lambda (spec) `(proclaim ',spec)) decl-specs)))
498  `(progn
499     (eval-when (:compile-toplevel)
500       (compile-time-proclamation ',decl-specs ,env))
501     (eval-when (:load-toplevel :execute)
502       ,@body))))
503
504;;; If warnings have more than a single entry on their
505;;; args slot, don't merge them.
506(defun merge-compiler-warnings (old-warnings)
507  (let ((warnings nil))
508    (dolist (w old-warnings)
509      (let* ((w-args (compiler-warning-args w)))
510        (if
511          (or (cdr w-args)
512              (dolist (w1 warnings t) 
513                (let ((w1-args (compiler-warning-args w1)))
514                  (when (and (eq (compiler-warning-warning-type w)
515                                 (compiler-warning-warning-type w1))
516                             w1-args
517                             (null (cdr w1-args))
518                             (eq (%car w-args)
519                                 (%car w1-args)))
520                    (incf (compiler-warning-nrefs w1))
521                    (return)))))
522          (push w warnings))))
523    warnings))
524
525;;; This is called by, e.g., note-function-info & so can't be -too- funky ...
526;;; don't call proclaimed-inline-p or proclaimed-notinline-p with alphatized crap
527
528(defun nx-declared-inline-p (sym env)
529  (setq sym (maybe-setf-function-name sym))
530  (loop
531    (when (listp env)
532      (return (and (symbolp sym)
533                   (proclaimed-inline-p sym))))
534    (dolist (decl (lexenv.fdecls env))
535      (when (and (eq (car decl) sym)
536                 (eq (cadr decl) 'inline))
537        (return-from nx-declared-inline-p (eq (cddr decl) 'inline))))
538    (setq env (lexenv.parent-env env))))
539
540(defun report-compile-time-argument-mismatch (condition stream)
541  (destructuring-bind (callee reason args spread-p)
542      (compiler-warning-args condition)
543    (format stream "In the ~a ~s with arguments ~:s,~%  "
544            (if spread-p "application of" "call to")
545            callee
546            args)
547    (case (car reason)
548      (:toomany
549       (destructuring-bind (provided max)
550           (cdr reason)
551         (format stream "~d argument~p were provided, but at most ~d ~a accepted~&  by " provided provided max (if (eql max 1) "is" "are"))))
552      (:toofew
553       (destructuring-bind (provided min)
554           (cdr reason)
555         (format stream "~d argument~p were provided, but at least ~d ~a required~&  by " provided provided min (if (eql min 1) "is" "are") )))
556      (:odd-keywords
557       (let* ((tail (cadr reason)))
558         (format stream "the variable portion of the argument list ~s contains an odd number~&  of arguments and so can't be used to initialize keyword parameters~&  for " tail)))
559      (:unknown-keyword
560       (destructuring-bind (badguy goodguys)
561           (cdr reason)
562         (format stream "the keyword argument ~s is not one of ~s, which are recognized~&  by " badguy goodguys))))
563    (format stream
564            (ecase (compiler-warning-warning-type condition)       
565              (:global-mismatch "the current global definition of ~s")
566              (:environment-mismatch "the definition of ~s visible in the current compilation unit.")
567              (:lexical-mismatch "the lexically visible definition of ~s"))
568            callee)))
569
570(defparameter *compiler-warning-formats*
571  '((:special . "Undeclared free variable ~S")
572    (:unused . "Unused lexical variable ~S")
573    (:ignore . "Variable ~S not ignored.")
574    (:undefined-function . "Undefined function ~S")
575    (:unknown-declaration . "Unknown declaration ~S")
576    (:unknown-type-declaration . "Unknown type ~S")
577    (:unknown-declaration-variable . "~s declaration for unknown variable ~s")
578    (:macro-used-before-definition . "Macro function ~S was used before it was defined.")
579    (:unsettable . "Shouldn't assign to variable ~S")
580    (:global-mismatch . report-compile-time-argument-mismatch)
581    (:environment-mismatch . report-compile-time-argument-mismatch)
582    (:lexical-mismatch . report-compile-time-argument-mismatch)   
583    (:type . "Type declarations violated in ~S")
584    (:type-conflict . "Conflicting type declarations for ~S")
585    (:special-fbinding . "Attempt to bind compiler special name: ~s. Result undefined.")
586    (:lambda . "Suspicious lambda-list: ~s")
587    (:result-ignored . "Function result ignored in call to ~s")
588    (:duplicate-definition . report-compile-time-duplicate-definition)
589    (:format-error . "~:{~@?~%~}")
590    (:program-error . "~a")
591    (:unsure . "Nonspecific warning")))
592
593(defun report-compile-time-duplicate-definition (condition stream)
594  (destructuring-bind (name old-file new-file &optional from to) (compiler-warning-args condition)
595    (format stream
596            "Duplicate definitions of ~s~:[~*~;~:* (as a ~a and a ~a)~]~:[~;, in this file~:[~; and in ~s~]~]"
597            (maybe-setf-name name) from to
598            (and old-file new-file)
599            (neq old-file new-file)
600            old-file)))
601
602(defun adjust-compiler-warning-args (warning-type args)
603  (case warning-type
604    ((:undefined-function :result-ignored) (mapcar #'maybe-setf-name args))
605    (t args)))
606
607
608(defun report-compiler-warning (condition stream)
609  (let* ((warning-type (compiler-warning-warning-type condition))
610         (format-string (cdr (assq warning-type *compiler-warning-formats*)))
611         (name (reverse (compiler-warning-function-name condition))))
612    (format stream "In ")
613    (print-nested-name name stream)
614    (when (every #'null name)
615      (let ((position (compiler-warning-stream-position condition)))
616        (when position (format stream " at position ~s" position))))
617    (format stream ": ")
618    (if (typep format-string 'string)
619      (apply #'format stream format-string (adjust-compiler-warning-args warning-type (compiler-warning-args condition)))
620      (funcall format-string condition stream))
621    ;(format stream ".")
622    (let ((nrefs (compiler-warning-nrefs condition)))
623      (when (and nrefs (neq nrefs 1))
624        (format stream " (~D references)" nrefs)))))
625
626(defun environment-structref-info (name env)
627  (let ((defenv (definition-environment env)))
628    (when defenv
629      (cdr (assq name (defenv.structrefs defenv))))))
630
631; end
Note: See TracBrowser for help on using the repository browser.