source: branches/working-0711/ccl/lib/pathnames.lisp @ 12248

Last change on this file since 12248 was 12248, checked in by gz, 10 years ago

r11996 from trunk

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 21.2 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   Portions copyright (C) 2001 Clozure Associates
5;;;   This file is part of OpenMCL. 
6;;;
7;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
8;;;   License , known as the LLGPL and distributed with OpenMCL as the
9;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
10;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
11;;;   conflict, the preamble takes precedence. 
12;;;
13;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
14;;;
15;;;   The LLGPL is also available online at
16;;;   http://opensource.franz.com/preamble.html
17
18;;pathnames.lisp Pathnames for Coral Common LISP
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require 'level-2)
23  (require 'backquote)
24)
25;(defconstant $accessDenied -5000) ; put this with other errnos
26(defconstant $afpAccessDenied -5000) ; which name to use?
27
28
29
30;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
31;ANSI CL logical pathnames
32
33
34(defvar *pathname-translations-pathname*
35  (make-pathname :host "ccl" :type "pathname-translations"))
36
37(defun load-logical-pathname-translations (host)
38  ;(setq host (verify-logical-host-name host))
39  (when (not (%str-assoc host %logical-host-translations%))
40    (setf (logical-pathname-translations host)
41          (with-open-file (file (merge-pathnames (make-pathname :name host :defaults nil)
42                                                 *pathname-translations-pathname*)
43                                :element-type 'base-char)
44            (read file)))
45    T))
46
47(defun back-translate-pathname (path &optional hosts)
48  (let ((newpath (back-translate-pathname-1 path hosts)))
49    (cond ((equalp path newpath)
50           ;; (fcomp-standard-source path)
51           (namestring (pathname path)))
52          (t newpath))))
53
54
55(defun back-translate-pathname-1 (path &optional hosts)
56  (dolist (host %logical-host-translations%)
57    (when (or (null hosts) (member (car host) hosts :test 'string-equal))
58      (dolist (trans (cdr host))
59        (when (pathname-match-p path (cadr trans))
60          (let* (newpath)         
61            (setq newpath (translate-pathname path (cadr trans) (car trans) :reversible t))
62            (return-from back-translate-pathname-1 
63              (if  (equalp path newpath) path (back-translate-pathname-1 newpath hosts))))))))
64  path)
65
66
67
68; must be after back-translate-pathname
69(defun physical-pathname-p (path)
70  (let* ((path (pathname path))
71         (dir (pathname-directory path)))
72    (and dir
73         (or (not (logical-pathname-p path))
74             (not (null (memq (pathname-host path) '(nil :unspecific))))))))
75
76
77
78;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
79;File or directory Manipulations
80
81(defun unix-rename (old-name new-name)
82  (with-cstrs ((old old-name)
83               (new new-name))
84    #+windows-target
85    (#__unlink new)
86    (let* ((res (#_rename old new)))
87      (declare (fixnum res))
88      (if (zerop res)
89        (values t nil)
90        (values nil (%get-errno))))))
91
92(defun rename-file (file new-name &key (if-exists :error))
93  "Rename FILE to have the specified NEW-NAME. If FILE is a stream open to a
94  file, then the associated file is renamed."
95  (let* ((original (truename file))
96         (original-namestring (native-translated-namestring original))
97         (new-name (merge-pathnames new-name original))
98         (new-namestring (native-translated-namestring new-name)))
99    (unless new-namestring
100      (error "~S can't be created." new-name))
101    (unless (and (probe-file new-name)
102                 (not (if-exists if-exists new-name)))
103      (multiple-value-bind (res error)
104                           (unix-rename original-namestring
105                                        new-namestring)
106        (unless res
107          (error "Failed to rename ~A to ~A: ~A"
108                 original new-name error))
109        (when (streamp file)
110          (setf (stream-filename file)
111                (namestring (native-to-pathname new-namestring))))
112        (values new-name original (truename new-name))))))
113
114(defun copy-file (source-path dest-path &key (if-exists :error) (if-does-not-exist :create)
115                              (preserve-attributes nil))
116  (let* ((original (truename source-path))
117         (new-name (merge-pathnames dest-path original))
118         (buffer (make-array 4096 :element-type '(unsigned-byte 8))))
119    (with-open-file (in original :direction :input
120                        :element-type '(unsigned-byte 8))
121      (with-open-file (out new-name :direction :output
122                           :if-exists if-exists
123                           :if-does-not-exist if-does-not-exist
124                           :element-type '(unsigned-byte 8))
125        (loop
126          as n = (stream-read-vector in buffer 0 4096) until (eql n 0)
127          do (stream-write-vector out buffer 0 n))))
128    (when preserve-attributes
129      (copy-file-attributes original new-name))
130    (values new-name original (truename new-name))))
131
132(defun recursive-copy-directory (source-path dest-path &key test (if-exists :error))
133  ;; TODO: Support :if-exists :supersede to blow away any files not in source dir
134  (assert (directoryp source-path)(source-path)
135          "source-path is not a directory in RECURSIVE-COPY-DIRECTORY")
136  (setq if-exists (require-type if-exists '(member :overwrite :error)))
137  (setq dest-path (ensure-directory-pathname dest-path))
138  (when (eq if-exists :error)
139    (when (probe-file dest-path)
140      (if-exists if-exists dest-path))
141    ;; Skip the probe-file in recursive calls, we already know it's ok.
142    (setq if-exists :overwrite))
143  (let* ((source-dir (ensure-directory-pathname source-path))
144         (pattern (make-pathname :name :wild :type :wild :defaults source-dir))
145         (source-files (directory pattern :test test :directories t :files t)))
146    (ensure-directories-exist dest-path)
147    (dolist (f source-files)
148      (when (or (null test) (funcall test f))
149        (if (directory-pathname-p f)
150            (let ((dest-file (make-pathname :name (first (last (pathname-directory f)))
151                                            :defaults dest-path)))
152              (recursive-copy-directory f dest-file :test test :if-exists if-exists))
153            (let* ((dest-file (make-pathname :name (pathname-name f)
154                                             :type (pathname-type f)
155                                             :defaults dest-path)))
156              (copy-file f dest-file :if-exists :supersede :preserve-attributes t)))))))
157
158;;; use with caution!
159;;; blows away a directory and all its contents
160(defun recursive-delete-directory (path &key (if-does-not-exist :error))
161  (setq path (ensure-directory-pathname path))
162  (setq if-does-not-exist (require-type if-does-not-exist '(member :error nil)))
163  (when (eq if-does-not-exist :error)
164    (unless (probe-file path)
165      (if-does-not-exist if-does-not-exist path)))
166  (when (probe-file path)
167      (if (directoryp path)
168          ;; it's a directory: blow it away
169          (let* ((pattern (make-pathname :name :wild :type :wild :defaults path))
170                 (files (directory pattern :directories nil :files t))
171                 (subdirs (directory pattern :directories t :files nil))
172                 (target-pathname (native-translated-namestring path)))
173            (dolist (f files)
174              (delete-file f))
175            (dolist (d subdirs)
176              (recursive-delete-directory d :if-does-not-exist if-does-not-exist))
177            (%rmdir target-pathname))
178          ;; it's not a directory: for safety's sake, signal an error
179          (error "Pathname '~A' is not a directory" path))))
180
181;;; It's not clear that we can support anything stronger than
182;;; "advisory" ("you pretend the file's locked & I will too") file
183;;; locking under Darwin.
184
185
186
187
188(defun create-directory (path &key (mode #o777))
189  (let* ((pathname (translate-logical-pathname (merge-pathnames path)))
190         (created-p nil)
191         (parent-dirs (let* ((pd (pathname-directory pathname)))
192                        (if (eq (car pd) :relative)
193                          (pathname-directory (merge-pathnames
194                                               pathname
195                                               (mac-default-directory)))
196                          pd)))
197         (nparents (length parent-dirs)))
198    (when (wild-pathname-p pathname)
199      (error 'file-error :error-type "Inappropriate use of wild pathname ~s"
200             :pathname pathname))
201    (do* ((i 1 (1+ i)))
202         ((> i nparents) (values pathname created-p))
203      (declare (fixnum i))
204      (let* ((parent (make-pathname
205                      :name :unspecific
206                      :type :unspecific
207                      :host (pathname-host pathname)
208                      :device (pathname-device pathname)
209                      :directory (subseq parent-dirs 0 i)))
210             (parent-name (native-translated-namestring parent))
211             (parent-kind (%unix-file-kind parent-name)))
212
213        (if parent-kind
214          (unless (eq parent-kind :directory)
215            (error 'simple-file-error
216                   :error-type "Can't create directory ~s, since file ~a exists and is not a directory"
217                   :pathname pathname
218                   :format-arguments (list parent-name)))
219          (let* ((result (%mkdir parent-name mode)))
220            (declare (fixnum result))
221            (if (< result 0)
222              (signal-file-error result parent-name)
223              (setq created-p t))))))))
224
225
226(defun ensure-directories-exist (pathspec &key verbose (mode #o777))
227  "Test whether the directories containing the specified file
228  actually exist, and attempt to create them if they do not.
229  The MODE argument is an extension to control the Unix permission
230  bits.  Portable programs should avoid using the :MODE keyword
231  argument."
232  (let ((pathname (let ((pathspec (translate-logical-pathname (merge-pathnames pathspec))))
233                    (make-directory-pathname :device (pathname-device pathspec)
234                                             :directory (pathname-directory pathspec))))
235        (created-p nil))
236    (when (wild-pathname-p pathname)
237      (error 'file-error
238             :error-type "Inappropriate use of wild pathname ~s"
239             :pathname pathname))
240    (let ((dir (pathname-directory pathname)))
241      (if (eq (car dir) :relative)
242        (setq dir (pathname-directory (merge-pathnames
243                                       pathname
244                                       (mac-default-directory)))))
245      (loop for i from 1 upto (length dir)
246            do (let ((newpath (make-pathname
247                               :name :unspecific
248                               :type :unspecific
249                               :host (pathname-host pathname)
250                               :device (pathname-device pathname)
251                               :directory (subseq dir 0 i))))
252                 (unless (probe-file newpath)
253                   (let ((namestring (native-translated-namestring newpath)))
254                     (when verbose
255                       (format *standard-output* "~&Creating directory: ~A~%"
256                               namestring))
257                     (%mkdir namestring mode)
258                     (unless (probe-file newpath)
259                       (error 'file-error
260                              :pathname namestring
261                              :error-type "Can't create directory ~S."))
262                     (setf created-p t)))))
263      (values pathspec created-p))))
264
265(defun dirpath-to-filepath (path)
266  (setq path (translate-logical-pathname (merge-pathnames path)))
267  (let* ((dir (pathname-directory path))
268         (super (butlast dir))
269         (name (car (last dir))))
270    (when (eq name :up)
271      (setq dir (remove-up (copy-list dir)))
272      (setq super (butlast dir))
273      (setq name (car (last dir))))
274    (when (null super)
275      (signal-file-error $xnocreate path))
276    (setq path (make-pathname :directory super :name name :defaults nil))))
277
278(defun filepath-to-dirpath (path)
279  (let* ((dir (pathname-directory path))
280         (rest (file-namestring path)))
281    (make-pathname :directory (append dir (list rest)) :defaults nil)))
282 
283
284
285;Takes a pathname, returns the truename of the directory if the pathname
286;names a directory, NIL if it names an ordinary file, error otherwise.
287;E.g. (directoryp "ccl;:foo:baz") might return #P"hd:mumble:foo:baz:" if baz
288;is a dir. - should we doc this - its exported?
289(defun directoryp (path)
290  (let* ((native (native-translated-namestring path))
291         (realpath (%realpath native)))
292    (if realpath (eq (%unix-file-kind realpath) :directory))))
293         
294
295;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
296;Wildcards
297
298
299
300 
301;-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_-_
302;Directory Traversing
303
304(defun %path-cat (device dir subdir)
305  (if device
306      (%str-cat device ":" dir subdir)
307    (%str-cat dir subdir)))
308
309(defmacro with-open-dir ((dirent device dir) &body body)
310  `(let ((,dirent (%open-dir (native-translated-namestring (make-pathname :device ,device :directory ,dir :defaults nil)))))
311     (when ,dirent
312       (unwind-protect
313           (progn ,@body)
314         (close-dir ,dirent)))))
315
316(defun directory (path &key (directories nil) ;; include subdirectories
317                            (files t)         ;; include files
318                            (all t)           ;; include Unix dot files (other than dot and dot dot)
319                            (directory-pathnames t) ;; return directories as directory-pathname-p's.
320                            (include-emacs-lockfiles nil) ;; inculde .#foo
321                            test              ;; Only return pathnames matching test
322                            (follow-links t)) ;; return truename's of matching files.
323  "Return a list of PATHNAMEs, each the TRUENAME of a file that matched the
324   given pathname. Note that the interaction between this ANSI-specified
325   TRUENAMEing and the semantics of the Unix filesystem (symbolic links..)
326   means this function can sometimes return files which don't have the same
327   directory as PATHNAME."
328  (let* ((keys (list :directories directories ;list defaulted key values
329                     :files files
330                     :all all
331                     :directory-pathnames directory-pathnames
332                     :test test
333                     :include-emacs-lockfiles include-emacs-lockfiles
334                     :follow-links follow-links))
335         (path (full-pathname (merge-pathnames path) :no-error nil))
336         (dir (directory-namestring path)))
337    (declare (dynamic-extent keys))
338    (if (null (pathname-directory path))
339      (setq dir (directory-namestring (setq path
340                                            (merge-pathnames path
341                                                             (mac-default-directory))))))
342    (assert (eq (car (pathname-directory path)) :absolute) ()
343            "full-pathname returned relative path ~s??" path)
344    ;; return sorted in alphabetical order, target-Xload-level-0 depends
345    ;; on this.
346    (nreverse
347     (delete-duplicates (%directory "/" dir path '(:absolute) keys) :test #'equal))))
348
349(defun %directory (dir rest path so-far keys)
350  (multiple-value-bind (sub-dir wild rest) (%split-dir rest)
351    (%some-specific dir sub-dir wild rest path so-far keys)))
352
353(defun %some-specific (dir sub-dir wild rest path so-far keys)
354  (let* ((start 1)
355         (end (length sub-dir))
356         (full-dir (if (eq start end) dir (%str-cat dir (%substr sub-dir start end)))))
357    (while (neq start end)
358      (let ((pos (position #\/ sub-dir :start start :end end)))
359        (push (%path-std-quotes (%substr sub-dir start pos) nil "/:;*") so-far)
360        (setq start (%i+ 1 pos))))
361    (cond ((null wild)
362           (%files-in-directory full-dir path so-far keys))
363          ((string= wild "**")
364           (%all-directories full-dir rest path so-far keys))
365          (t (%one-wild full-dir wild rest path so-far keys)))))
366
367; for a * or *x*y
368(defun %one-wild (dir wild rest path so-far keys)
369  (let ((result ())
370        (device (pathname-device path))
371        (all (getf keys :all))
372        name)
373    (with-open-dir (dirent device dir)
374      (while (setq name (%read-dir dirent))
375        (when (and (or all (neq (%schar name 0) #\.))
376                   (not (string= name "."))
377                   (not (string= name ".."))
378                   (%path-pstr*= wild name)
379                   (eq (%unix-file-kind (%path-cat device dir name) t) :directory))
380          (let ((subdir (%path-cat nil dir name))
381                (so-far (cons (%path-std-quotes name nil "/;:*") so-far)))
382            (declare (dynamic-extent so-far))
383            (setq result
384                  (nconc (%directory (%str-cat subdir "/") rest path so-far keys) result))))))
385    result))
386
387(defun %files-in-directory (dir path so-far keys)
388  (let ((device (pathname-device path))
389        (name (pathname-name path))
390        (type (pathname-type path))
391        (directories (getf keys :directories))
392        (files (getf keys :files))
393        (directory-pathnames (getf keys :directory-pathnames))
394        (test (getf keys :test))
395        (follow-links (getf keys :follow-links))
396        (all (getf keys :all))
397        (include-emacs-lockfiles (getf keys :include-emacs-lockfiles))
398        (result ())
399        sub dir-list ans)
400    (if (not (or name type))
401      (let (full-path)
402        (when (and directories
403                   (eq (%unix-file-kind (namestring (setq full-path (%cons-pathname (reverse so-far) nil nil nil device)))
404                                        t)
405                       :directory))
406          (setq ans (if directory-pathnames full-path
407                      (%cons-pathname (reverse (cdr so-far)) (car so-far) nil nil device)))
408          (when (and ans (or (null test) (funcall test ans)))
409            (setq result (list ans)))))
410      (with-open-dir (dirent (pathname-device path) dir)
411        (while (setq sub (%read-dir dirent))
412          (when (and (or all (neq (%schar sub 0) #\.))
413                     (or include-emacs-lockfiles
414                         (< (length sub) 2)
415                         (not (string= sub ".#" :end1 2)))
416                     (not (string= sub "."))
417                     (not (string= sub ".."))
418                     (%file*= name type sub))
419            (setq ans
420                  (if (eq (%unix-file-kind (%path-cat device dir sub) t) :directory)
421                    (when directories
422                      (let* ((std-sub (%path-std-quotes sub nil "/;:*")))
423                        (if directory-pathnames
424                          (%cons-pathname (reverse (cons std-sub so-far)) nil nil nil device)
425                          (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) std-sub nil nil device))))
426                    (when files
427                      (multiple-value-bind (name type) (%std-name-and-type sub)
428                        (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type nil device)))))
429            (when (and ans (or (null test) (funcall test ans)))
430              (push (if follow-links (or (probe-file ans) ans) ans) result))))))
431    result))
432
433(defun %all-directories (dir rest path so-far keys)
434  (let ((do-files nil)
435        (do-dirs nil)
436        (result nil)
437        (device (pathname-device path))
438        (name (pathname-name path))
439        (type (pathname-type path))
440        (all (getf keys :all))
441        (test (getf keys :test))
442        (directory-pathnames (getf keys :directory-pathnames))
443        (follow-links (getf keys :follow-links))
444        sub dir-list ans)
445    ;; First process the case that the ** stands for 0 components
446    (multiple-value-bind (next-dir next-wild next-rest) (%split-dir rest)
447      (while (and next-wild ; Check for **/**/ which is the same as **/
448                  (string= next-dir "/")
449                  (string= next-wild "**"))
450        (setq rest next-rest)
451        (multiple-value-setq (next-dir next-wild next-rest) (%split-dir rest)))
452      (cond ((not (string= next-dir "/"))
453             (setq result
454                   (%some-specific dir next-dir next-wild next-rest path so-far keys)))
455            (next-wild
456             (setq result
457                   (%one-wild dir next-wild next-rest path so-far keys)))
458            ((or name type)
459             (when (getf keys :files) (setq do-files t))
460             (when (getf keys :directories) (setq do-dirs t)))
461            (t (when (getf keys :directories)
462                 (setq sub (if directory-pathnames
463                             (%cons-pathname (setq dir-list (reverse so-far)) nil nil nil device)
464                             (%cons-pathname (reverse (cdr so-far)) (car so-far) nil nil device)))
465                 (when (or (null test) (funcall test sub))
466                   (setq result (list (if follow-links (truename sub) sub))))))))
467    ; now descend doing %all-dirs on dirs and collecting files & dirs if do-x is t
468    (with-open-dir (dirent device dir)
469      (while (setq sub (%read-dir dirent))
470        (when (and (or all (neq (%schar sub 0) #\.))
471                   (not (string= sub "."))
472                   (not (string= sub "..")))
473          (if (eq (%unix-file-kind (%path-cat device dir sub) t) :directory)
474            (let* ((subfile (%path-cat nil dir sub))
475                   (std-sub (%path-std-quotes sub nil "/;:*"))
476                   (so-far (cons std-sub so-far))
477                   (subdir (%str-cat subfile "/")))
478              (declare (dynamic-extent so-far))
479              (when (and do-dirs (%file*= name type sub))
480                (setq ans (if directory-pathnames
481                            (%cons-pathname (reverse so-far) nil nil nil device)
482                            (%cons-pathname (or dir-list (setq dir-list (reverse (cdr so-far))))
483                                            std-sub nil nil device)))
484                (when (or (null test) (funcall test ans))
485                  (push (if follow-links (truename ans) ans) result)))
486              (setq result (nconc (%all-directories subdir rest path so-far keys) result)))
487            (when (and do-files (%file*= name type sub))
488              (multiple-value-bind (name type) (%std-name-and-type sub)
489                (setq ans (%cons-pathname (or dir-list (setq dir-list (reverse so-far))) name type))
490                (when (or (null test) (funcall test ans))
491                  (push (if follow-links (truename ans) ans) result))))))))
492    result))
493
494(defun %split-dir (dir &aux pos)                 ; dir ends in a "/".
495  ;"/foo/bar/../x*y/baz/../z*t/"  ->  "/foo/bar/../" "x*y" "/baz/../z*t/"
496  (if (null (setq pos (%path-mem "*" dir)))
497    (values dir nil nil)
498    (let (epos (len (length dir)))
499      (setq pos (if (setq pos (%path-mem-last "/" dir 0 pos)) (%i+ pos 1) 0)
500            epos (%path-mem "/" dir pos len))
501      (when (%path-mem-last-quoted "/" dir 0 pos)
502        (signal-file-error $xbadfilenamechar dir #\/))
503      (values (unless (%izerop pos) (namestring-unquote (%substr dir 0 pos)))
504              (%substr dir pos epos)
505              (%substr dir epos len)))))
506
507(defun %path-pstr*= (pattern pstr &optional (p-start 0))
508  (assert (eq p-start 0))
509  (%path-str*= pstr pattern))
510
511(defun %file*= (name-pat type-pat pstr)
512  (if (eq name-pat :wild) (setq name-pat "*"))
513  (if (eq type-pat :wild) (setq type-pat "*"))
514  (when (and (null name-pat) (null type-pat))
515    (return-from %file*= T))
516  (let* ((end (length pstr))
517         (pos (position #\. pstr :from-end t))
518         (type (and pos (%substr pstr (%i+ pos 1) end)))
519         (name (unless (eq (or pos end) 0) (if pos (%substr pstr 0 pos) pstr))))
520    (and (cond ((or (eq name-pat :unspecific) (null name-pat)) (null name))
521               (t (%path-pstr*= name-pat (or name ""))))
522         (cond ((or (null type-pat) (eq type-pat :unspecific)) (null type))
523               (t (%path-pstr*= type-pat (or type "")))))))
524
525(provide "PATHNAMES")
Note: See TracBrowser for help on using the repository browser.