source: branches/working-0711/ccl/lib/nfcomp.lisp @ 10194

Last change on this file since 10194 was 10194, checked in by gz, 12 years ago

Since I can't make it consistently measure coverage of toplevel forms,
try to consistently NOT measure toplevel forms, so as to make for more
useful statistics.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 81.2 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17(in-package "CCL")
18
19;; :lib:nfcomp.lisp - New fasl compiler.
20
21(eval-when (:compile-toplevel :load-toplevel :execute)
22   (require 'level-2))
23
24(require 'optimizers)
25(require 'hash)
26
27(eval-when (:compile-toplevel :execute)
28
29(require 'backquote)
30(require 'defstruct-macros)
31
32(defmacro short-fixnum-p (fixnum)
33  `(and (fixnump ,fixnum) (< (integer-length ,fixnum) 16)))
34
35(require "FASLENV" "ccl:xdump;faslenv")
36
37#+ppc32-target
38(require "PPC32-ARCH")
39#+ppc64-target
40(require "PPC64-ARCH")
41#+x8664-target
42(require "X8664-ARCH")
43) ;eval-when (:compile-toplevel :execute)
44
45;File compiler options.  Not all of these need to be exported/documented, but
46;they should be in the product just in case we need them for patches....
47(defvar *fasl-save-local-symbols* t)
48(defvar *fasl-deferred-warnings* nil)
49(defvar *fasl-non-style-warnings-signalled-p* nil)
50(defvar *fasl-warnings-signalled-p* nil)
51(defvar *compile-verbose* nil ; Might wind up getting called *compile-FILE-verbose*
52  "The default for the :VERBOSE argument to COMPILE-FILE.")
53(defvar *fasl-save-doc-strings*  t)
54(defvar *fasl-save-definitions* nil)
55(defvar *compile-file-pathname* nil
56  "The defaulted pathname of the file currently being compiled, or NIL if not
57  compiling.") ; pathname of src arg to COMPILE-FILE
58(defvar *compile-file-truename* nil
59  "The TRUENAME of the file currently being compiled, or NIL if not
60  compiling.") ; truename ...
61(defvar *compile-file-original-truename* nil
62  "The name to use for recording source locations. Should not be set
63directly, intsead use the :compile-file-original-truename parameter to
64cl:compile-file.")
65(defvar *compile-file-original-buffer-offset* nil
66  "Start offset to use for recording source locations. Should not be
67set directly, instead use the :compile-file-original-buffer-offset
68parameter to cl:compile-file.")
69(defvar *fasl-target* (backend-name *host-backend*))
70(defvar *fasl-backend* *host-backend*)
71(defvar *fasl-host-big-endian*
72  (arch::target-big-endian (backend-target-arch *host-backend*)))
73(defvar *fasl-target-big-endian* *fasl-host-big-endian*)
74(defvar *fcomp-external-format* :default)
75
76(defvar *fasl-break-on-program-errors* #+ccl-0711 nil #-ccl-0711 :defer
77  "Controls what happens when the compiler detects PROGRAM-ERROR's during file compilation.
78
79  If T, the compiler signals an error immediately when it detects the program-error.
80
81  If :DEFER, program errors are reported as compiler warnings, and in addition, an error
82    is signalled at the end of file compilation.  This allows all warnings for the file
83    to be reported, but prevents the creation of a fasl file.
84
85  If NIL, program errors are treated the same as any other error condition detected by
86   the compiler, i.e. they are reported as compiler warnings and do not cause any
87   error to be signalled at compile time.")
88 
89
90(defvar *compile-print* nil ; Might wind up getting called *compile-FILE-print*
91  "The default for the :PRINT argument to COMPILE-FILE.")
92
93;Note: errors need to rebind this to NIL if they do any reading without
94; unwinding the stack!
95(declaim (special *compiling-file*)) ; defined in l1-init.
96
97(defvar *fasl-source-file* nil "Name of file currently being read from.
98Will differ from *compiling-file* during an INCLUDE")
99
100(defparameter *fasl-package-qualified-symbols* '(*loading-file-source-file* set-package %define-package)
101  "These symbols are always fasdumped with full package qualification.")
102
103(defun setup-target-features (backend features)
104  (if (eq backend *host-backend*)
105    features
106    (let* ((new nil)
107           (nope (backend-target-specific-features *host-backend*)))
108      (dolist (f features)
109        (unless (memq f nope) (pushnew f new)))
110      (dolist (f (backend-target-specific-features backend)
111               (progn (pushnew :cross-compiling new) new))
112        (pushnew f new)))))
113
114(defun compile-file-pathname (pathname &rest ignore &key output-file &allow-other-keys)
115  "Return a pathname describing what file COMPILE-FILE would write to given
116   these arguments."
117  (declare (ignore ignore))
118  (setq pathname (merge-pathnames pathname))
119  (merge-pathnames (if output-file
120                     (merge-pathnames output-file *.fasl-pathname*)
121                     *.fasl-pathname*) 
122                   pathname))
123(defvar *fasl-save-source-locations* nil
124  "This controls whether we save source inforamiotn when
125  compiling. This variable should not be set directly, see
126  *save-source-locations*.")
127
128(defun compile-file (src &key output-file
129                         (verbose *compile-verbose*)
130                         (print *compile-print*)
131                         load
132                         features
133                         (target *fasl-target* target-p)
134                         (save-local-symbols *fasl-save-local-symbols*)
135                         (save-doc-strings *fasl-save-doc-strings*)
136                         (save-definitions *fasl-save-definitions*)
137                         (save-source-locations *save-source-locations*)
138                         (external-format :default)
139                         force
140                         compile-file-original-truename
141                         (compile-file-original-buffer-offset 0)
142                         (break-on-program-errors (if compile-file-original-truename
143                                                    t  ;; really SLIME being interactive...
144                                                    *fasl-break-on-program-errors*)))
145  "Compile INPUT-FILE, producing a corresponding fasl file and returning
146   its filename."
147  (let* ((backend *target-backend*))
148    (when (and target-p (not (setq backend (find-backend target))))
149      (warn "Unknown :TARGET : ~S.  Reverting to ~s ..." target *fasl-target*)
150      (setq target *fasl-target*  backend *target-backend*))
151    (loop
152        (restart-case
153         (return (%compile-file src output-file verbose print load features
154                                save-local-symbols save-doc-strings save-definitions
155                                save-source-locations break-on-program-errors
156                                force backend external-format
157                                compile-file-original-truename compile-file-original-buffer-offset))
158         (retry-compile-file ()
159                             :report (lambda (stream) (format stream "Retry compiling ~s" src))
160                             nil)
161         (skip-compile-file ()
162                            :report (lambda (stream) (format stream "Skip compiling ~s" src))
163                            (return))))))
164
165(defun %compile-file (src output-file verbose print load features
166                          save-local-symbols save-doc-strings save-definitions
167                          save-source-locations break-on-program-errors
168                          force target-backend external-format
169                          compile-file-original-truename compile-file-original-buffer-offset
170                          &aux orig-src)
171  (setq orig-src (merge-pathnames src))
172  (let* ((output-default-type (backend-target-fasl-pathname target-backend)))
173    (setq src (fcomp-find-file orig-src))
174    (let* ((newtype (pathname-type src)))
175      (when (and newtype (not (pathname-type orig-src)))
176        (setq orig-src (merge-pathnames orig-src (make-pathname :type newtype :defaults nil)))))
177    (setq output-file (merge-pathnames
178                       (if output-file ; full-pathname in case output-file is relative
179                         (full-pathname (merge-pathnames output-file output-default-type) :no-error nil) 
180                         output-default-type)
181                       orig-src))
182    ;; This should not be necessary, but it is.
183    (setq output-file (namestring output-file))
184    (when (physical-pathname-p orig-src) ; only back-translate to things likely to exist at load time
185      (setq orig-src (back-translate-pathname orig-src '("home" "ccl"))))
186    (let* ((*fasl-non-style-warnings-signalled-p* nil)
187           (*fasl-warnings-signalled-p* nil))
188      (when (and (not force)
189                 (probe-file output-file)
190                 (not (fasl-file-p output-file)))
191        (unless (y-or-n-p
192                 (format nil
193                         "Compile destination ~S is not ~A file!  Overwrite it?"
194                         output-file (pathname-type
195                                      (backend-target-fasl-pathname
196                                       *target-backend*))))
197        (return-from %compile-file nil)))
198      (let* ((*features* (append (if (listp features) features (list features)) (setup-target-features target-backend *features*)))
199             (*fasl-deferred-warnings* nil) ; !!! WITH-COMPILATION-UNIT ...
200             (*fasl-save-local-symbols* save-local-symbols)
201             (*fasl-save-source-locations* save-source-locations)
202             (*fasl-save-doc-strings* save-doc-strings)
203             (*fasl-save-definitions* save-definitions)
204             (*fasl-break-on-program-errors* break-on-program-errors)
205             (*fcomp-warnings-header* nil)
206             (*compile-file-pathname* orig-src)
207             (*compile-file-truename* (truename src))
208             (*compile-file-original-truename* compile-file-original-truename)
209             (*compile-file-original-buffer-offset* compile-file-original-buffer-offset)
210             (*package* *package*)
211             (*readtable* *readtable*)
212             (*compile-print* print)
213             (*compile-verbose* verbose)
214             (*fasl-target* (backend-name target-backend))
215             (*fasl-backend* target-backend)
216             (*fasl-target-big-endian* (arch::target-big-endian
217                                        (backend-target-arch target-backend)))
218             (*target-ftd* (backend-target-foreign-type-data target-backend))
219             (defenv (new-definition-environment))
220             (lexenv (new-lexical-environment defenv))
221             (*fcomp-external-format* external-format))
222        (let ((forms nil))
223          (let* ((*outstanding-deferred-warnings* (%defer-warnings nil)))
224            (rplacd (defenv.type defenv) *outstanding-deferred-warnings*)
225            (setq forms (fcomp-file src orig-src lexenv))
226            (setf (deferred-warnings.warnings *outstanding-deferred-warnings*) 
227                  (append *fasl-deferred-warnings* (deferred-warnings.warnings *outstanding-deferred-warnings*))
228                  (deferred-warnings.defs *outstanding-deferred-warnings*)
229                  (append (defenv.defined defenv) (deferred-warnings.defs *outstanding-deferred-warnings*)))
230            (when *compile-verbose* (fresh-line))
231            (multiple-value-bind (any harsh) (report-deferred-warnings)
232              (setq *fasl-warnings-signalled-p* (or *fasl-warnings-signalled-p* any)
233                    *fasl-non-style-warnings-signalled-p* (if (eq harsh :very) :very
234                                                              (or *fasl-non-style-warnings-signalled-p* harsh)))))
235          (when (and *fasl-break-on-program-errors* (eq *fasl-non-style-warnings-signalled-p* :very))
236            (cerror "create the output file despite the errors"
237                    "Serious errors encountered during compilation of ~s"
238                    src))
239          (fasl-scan-forms-and-dump-file forms output-file lexenv)))
240      (when load (load output-file :verbose (or verbose *load-verbose*)))
241      (values (truename (pathname output-file)) 
242              *fasl-warnings-signalled-p* 
243              (and *fasl-non-style-warnings-signalled-p* t)))))
244
245(defvar *fcomp-locked-hash-tables*)
246(defvar *fcomp-load-forms-environment* nil)
247
248; This is separated out so that dump-forms-to-file can use it
249(defun fasl-scan-forms-and-dump-file (forms output-file &optional env)
250  (let ((*fcomp-locked-hash-tables* nil)
251        (*fcomp-load-forms-environment* env))
252    (unwind-protect
253      (multiple-value-bind (hash gnames goffsets) (fasl-scan forms)
254        (fasl-dump-file gnames goffsets forms hash output-file))
255      (fasl-unlock-hash-tables))))
256
257#-bccl
258(defun nfcomp (src &optional dest &rest keys)
259  (when (keywordp dest) (setq keys (cons dest keys) dest nil))
260  (apply #'compile-file src :output-file dest keys))
261
262#-bccl
263(%fhave 'fcomp #'nfcomp)
264
265(defparameter *default-file-compilation-policy* (new-compiler-policy))
266
267(defun current-file-compiler-policy ()
268  *default-file-compilation-policy*)
269
270(defun set-current-file-compiler-policy (&optional new-policy)
271  (setq *default-file-compilation-policy* 
272        (if new-policy (require-type new-policy 'compiler-policy) (new-compiler-policy))))
273
274(defparameter *compile-time-evaluation-policy*
275  (new-compiler-policy :force-boundp-checks t))
276
277(defun %compile-time-eval (form env)
278  (let* ((*target-backend* *host-backend*))
279    ;; The HANDLER-BIND here is supposed to note WARNINGs that're
280    ;; signaled during (eval-when (:compile-toplevel) processing; this
281    ;; in turn is supposed to satisfy a pedantic interpretation of the
282    ;; spec's requirement that COMPILE-FILE's second and third return
283    ;; values reflect (all) conditions "detected by the compiler."
284    ;; (It's kind of sad that CL language design is influenced so
285    ;; strongly by the views of pedants these days.)
286    (handler-bind ((warning (lambda (c)
287                              (setq *fasl-warnings-signalled-p* t)
288                              (unless (typep c 'style-warning)
289                                (setq *fasl-non-style-warnings-signalled-p* t))
290                              (signal c))))
291      (funcall (compile-named-function
292                `(lambda () ,form)
293                :env env
294                :policy *compile-time-evaluation-policy*)))))
295
296
297;;; No methods by default, not even for structures.  This really sux.
298(defgeneric make-load-form (object &optional environment))
299
300;;; Well, no usable methods by default.  How this is better than
301;;; getting a NO-APPLICABLE-METHOD error frankly escapes me,
302(defun no-make-load-form-for (object)
303  (error "No ~S method is defined for ~s" 'make-load-form object))
304
305(defmethod make-load-form ((s standard-object) &optional environment)
306  (declare (ignore environment))
307  (no-make-load-form-for s))
308
309(defmethod make-load-form ((s structure-object) &optional environment)
310  (declare (ignore environment))
311  (no-make-load-form-for s))
312
313(defmethod make-load-form ((c condition) &optional environment)
314  (declare (ignore environment))
315  (no-make-load-form-for c))
316
317(defmethod make-load-form ((c class) &optional environment)
318  (let* ((name (class-name c))
319         (found (if name (find-class name nil environment))))
320    (if (eq found c)
321      `(find-class ',name)
322      (error "Class ~s does not have a proper name." c))))
323
324
325;;;;          FCOMP-FILE - read & compile file
326;;;;          Produces a list of (opcode . args) to run on loading, intermixed
327;;;;          with read packages.
328
329(defparameter *fasl-eof-forms* nil)
330
331(defparameter cfasl-load-time-eval-sym (make-symbol "LOAD-TIME-EVAL"))
332(%macro-have cfasl-load-time-eval-sym
333    #'(lambda (call env) (declare (ignore env)) (list 'eval (list 'quote call))))
334;Make it a constant so compiler will barf if try to bind it, e.g. (LET #,foo ...)
335(define-constant cfasl-load-time-eval-sym cfasl-load-time-eval-sym)
336
337
338(defparameter *reading-for-cfasl* nil "Used by the reader for #,")
339
340
341
342(declaim (special *nx-compile-time-types*
343;The following are the global proclaimed values.  Since compile-file binds
344;them, this means you can't ever globally proclaim these things from within a
345;file compile (e.g. from within eval-when compile, or loading a file) - the
346;proclamations get lost when compile-file exits.  This is sort of intentional
347;(or at least the set of things which fall in this category as opposed to
348;having a separate compile-time variable is sort of intentional).
349                    *nx-proclaimed-inline*    ; inline and notinline
350                    *nx-proclaimed-ignore*    ; ignore and unignore
351                    *nx-known-declarations*   ; declaration
352                    *nx-speed*                ; optimize speed
353                    *nx-space*                ; optimize space
354                    *nx-safety*               ; optimize safety
355                    *nx-cspeed*))             ; optimize compiler-speed
356
357(defvar *fcomp-load-time*)
358(defvar *fcomp-inside-eval-always* nil)
359(defvar *fcomp-eval-always-functions* nil)   ; used by the LISP package
360(defvar *fcomp-output-list*)
361(defvar *fcomp-toplevel-forms*)
362(defvar *fcomp-source-note-map* nil) ;; init to nil as might be ref'd outside read loop by load forms
363(defvar *fcomp-source-being-compiled* nil) ;; ditto
364(defvar *fcomp-warnings-header*)
365(defvar *fcomp-stream-position* nil)
366(defvar *fcomp-previous-position* nil)
367(defvar *fcomp-indentation*)
368(defvar *fcomp-print-handler-plist* nil)
369(defvar *fcomp-last-compile-print*
370  '(INCLUDE (NIL . T)
371    DEFSTRUCT ("Defstruct" . T) 
372    DEFCONSTANT "Defconstant" 
373    DEFSETF "Defsetf" 
374    DEFTYPE "Deftype" 
375    DEFCLASS "Defclass" 
376    DEFGENERIC "Defgeneric"
377    DEFMETHOD "Defmethod"
378    DEFMACRO "Defmacro" 
379    DEFPARAMETER "Defparameter" 
380    DEFVAR "Defvar" 
381    DEFUN ""))
382
383(setf (getf *fcomp-print-handler-plist* 'defun) ""
384      (getf *fcomp-print-handler-plist* 'defvar) "Defvar"
385      (getf *fcomp-print-handler-plist* 'defparameter) "Defparameter"
386      (getf *fcomp-print-handler-plist* 'defmacro) "Defmacro"
387      (getf *fcomp-print-handler-plist* 'defmethod) "Defmethod"  ; really want more than name (use the function option)
388      (getf *fcomp-print-handler-plist* 'defgeneric) "Defgeneric"
389      (getf *fcomp-print-handler-plist* 'defclass) "Defclass"
390      (getf *fcomp-print-handler-plist* 'deftype) "Deftype"
391      (getf *fcomp-print-handler-plist* 'defsetf) "Defsetf"
392      (getf *fcomp-print-handler-plist* 'defconstant) "Defconstant"
393      (getf *fcomp-print-handler-plist* 'defstruct) '("Defstruct" . t)
394      (getf *fcomp-print-handler-plist* 'include) '(nil . t))
395
396
397(defun fcomp-file (filename orig-file env)  ; orig-file is back-translated
398  (let* ((*package* *package*)
399         (*compiling-file* filename)
400         (*nx-compile-time-types* *nx-compile-time-types*)
401         (*nx-proclaimed-inline* *nx-proclaimed-inline*)
402         (*nx-known-declarations* *nx-known-declarations*)
403         (*nx-proclaimed-ignore* *nx-proclaimed-ignore*)
404         (*nx-speed* *nx-speed*)
405         (*nx-space* *nx-space*)
406         (*nx-debug* *nx-debug*)
407         (*nx-safety* *nx-safety*)
408         (*nx-cspeed* *nx-cspeed*)
409         (*fcomp-load-time* t)
410         (*fcomp-output-list* nil)
411         (*fcomp-indentation* 0)
412         (*fcomp-last-compile-print* (cons nil (cons nil nil))))
413    (push (list $fasl-platform (backend-target-platform *fasl-backend*)) *fcomp-output-list*)
414    (fcomp-read-loop filename orig-file env :not-compile-time)
415    (nreverse *fcomp-output-list*)))
416
417(defun fcomp-find-file (file &aux path)
418  (unless (or (setq path (probe-file file))
419              (setq path (probe-file (merge-pathnames file *.lisp-pathname*))))
420    (error 'file-error :pathname file :error-type "File ~S not found"))
421  (namestring path))
422
423;;; orig-file is back-translated when from fcomp-file
424;;; when from fcomp-include it's included filename merged with *compiling-file*
425;;; which is not back translated
426(defun fcomp-read-loop (filename orig-file env processing-mode)
427  (when *compile-verbose*
428    (format t "~&;~A ~S..."
429            (if (eq filename *compiling-file*) "Compiling" " Including")
430            filename))
431  (with-open-file (*fcomp-stream* filename
432                                  :element-type 'base-char
433                                  :external-format *fcomp-external-format*)
434    (let* ((old-file (and (neq filename *compiling-file*) *fasl-source-file*))           
435           (*fasl-source-file* filename)
436           (*fcomp-toplevel-forms* '())
437           (*loading-file-source-file* (namestring (or *compile-file-original-truename* orig-file)))
438           (*fcomp-file-source-note* (%make-source-note :file-name *loading-file-source-file*))
439           (*fcomp-source-note-map* (and (or *fasl-save-source-locations* *compile-code-coverage*)
440                                         (make-hash-table :test #'eq :shared nil)))
441           (*form-source-note-map* (and *fasl-save-source-locations* *fcomp-source-note-map*))
442           (*fcomp-source-being-compiled* nil)
443           (eofval (cons nil nil))
444           (read-package nil)
445           form)
446      (declare (special *fasl-eof-forms* *fcomp-toplevel-forms* *fasl-source-file* *fcomp-file-source-note*))
447      (fcomp-output-form $fasl-src env *loading-file-source-file*)
448      (let* ((*fcomp-previous-position* nil))
449        (loop
450          (let* ((*fcomp-stream-position* (file-position *fcomp-stream*))
451                 form)
452            (unless (eq read-package *package*)
453              (fcomp-compile-toplevel-forms env)
454              (setq read-package *package*))
455            (let ((*reading-for-cfasl*
456                   (and *fcomp-load-time* cfasl-load-time-eval-sym)))
457              (declare (special *reading-for-cfasl*))
458              (let ((pos (file-position *fcomp-stream*)))
459                (handler-bind
460                    ((error #'(lambda (c) ; we should distinguish read errors from others?
461                                (format *error-output* "~&Read error between positions ~a and ~a in ~a." pos (file-position *fcomp-stream*) filename)
462                                (signal c))))
463                  (multiple-value-setq (form *fcomp-source-being-compiled*)
464                    (read-recording-source *fcomp-stream*
465                                           :eofval eofval
466                                           :file-name *loading-file-source-file*
467                                           :start-offset (or *compile-file-original-buffer-offset* 0)
468                                           :map *fcomp-source-note-map*
469                                           :save-source-text (and *fasl-save-source-locations*
470                                                                  (neq *fasl-save-source-locations* :no-text)))))))
471            (when (eq eofval form)
472              (require-type *fcomp-source-being-compiled* 'null)
473              (return))
474            (fcomp-output-source-being-compiled env)
475            (fcomp-form form env processing-mode)
476            (setq *fcomp-previous-position* *fcomp-stream-position*))))
477      (when *compile-code-coverage*
478        (fcomp-compile-toplevel-forms env)
479        (let* ((fns (fcomp-code-covered-functions))
480               (v (nreverse (coerce fns 'vector))))
481          (map nil #'fcomp-digest-code-notes v)
482          (fcomp-random-toplevel-form `(register-code-covered-functions ',v) env)))
483      (while (setq form *fasl-eof-forms*)
484        (setq *fasl-eof-forms* nil)
485        (fcomp-form-list form env processing-mode))
486      (when old-file
487        (fcomp-output-form $fasl-src env (namestring *compile-file-pathname*)))
488      (fcomp-compile-toplevel-forms env))))
489
490(defun fcomp-code-covered-functions ()
491  (loop for op in *fcomp-output-list*
492        when (consp op)
493          nconc (if (eq (car op) $fasl-lfuncall)
494                  ;; Don't collect the toplevel lfun itself, it leads to spurious markings.
495                  ;; Instead, descend one level and collect any referenced fns.
496                  (destructuring-bind (fn) (cdr op)
497                    (lfunloop for imm in fn when (functionp imm) collect imm))
498                  (loop for arg in (cdr op) when (functionp arg) collect arg))))
499
500
501(defun fcomp-output-source-being-compiled (env)
502  (let ((effective-note (cond
503                          ((and *record-source-file* *fasl-save-source-locations*)
504                           *fcomp-source-being-compiled*)
505                          (*record-source-file*
506                           ;; we don't want the full source note, but we do want the file name
507                           (locally (declare (special *fcomp-file-source-note*))
508                             *fcomp-file-source-note*))
509                          (t 
510                           ;; output this so *loading-toplevel-location* gets reset after each form.
511                           nil))))
512    (fcomp-output-form $fasl-toplevel-location env effective-note)
513    effective-note))
514
515(defun fcomp-form (form env processing-mode
516                        &aux print-stuff 
517                        (load-time (and processing-mode (neq processing-mode :compile-time)))
518                        (compile-time-too (or (eq processing-mode :compile-time) 
519                                              (eq processing-mode :compile-time-too))))
520  (let* ((*fcomp-indentation* *fcomp-indentation*)
521         (*compile-print* *compile-print*))
522    (when *compile-print*
523      (cond ((and (consp form) (setq print-stuff (getf *fcomp-print-handler-plist* (car form))))
524             (rplaca (rplacd (cdr *fcomp-last-compile-print*) nil) nil)
525             (rplaca *fcomp-last-compile-print* nil)         
526             (let ((print-recurse nil))
527               (when (consp print-stuff)
528                 (setq print-recurse (cdr print-stuff) print-stuff (car print-stuff)))
529               (cond ((stringp print-stuff)
530                      (if (equal print-stuff "")
531                        (format t "~&~vT~S~%" *fcomp-indentation* (second form))
532                        (format t "~&~vT~S [~A]~%" *fcomp-indentation* (second form) print-stuff)))
533                     ((not (null print-stuff))
534                      (format t "~&~vT" *fcomp-indentation*)
535                      (funcall print-stuff form *standard-output*)
536                      (terpri *standard-output*)))
537               (if print-recurse
538                 (setq *fcomp-indentation* (+ *fcomp-indentation* 4))
539                 (setq *compile-print* nil))))
540            (t (unless (and (eq load-time (car *fcomp-last-compile-print*))
541                            (eq compile-time-too (cadr *fcomp-last-compile-print*))
542                            (eq *fcomp-indentation* (cddr *fcomp-last-compile-print*)))
543                 (rplaca *fcomp-last-compile-print* load-time)
544                 (rplaca (rplacd (cdr *fcomp-last-compile-print*) compile-time-too) *fcomp-indentation*)
545                 (format t "~&~vTToplevel Forms...~A~%"
546                         *fcomp-indentation*
547                         (if load-time
548                           (if compile-time-too
549                             "  (Compiletime, Loadtime)"
550                             "")
551                           (if compile-time-too
552                             "  (Compiletime)"
553                             "")))))))
554    (fcomp-form-1 form env processing-mode)))
555
556(defun fcomp-form-1 (form env processing-mode &aux sym body)
557  (if (consp form) (setq sym (%car form) body (%cdr form)))
558  (case sym
559    (progn
560      (fcomp-form-list body env processing-mode form))
561    (eval-when
562      (fcomp-eval-when form env processing-mode))
563    (compiler-let
564      (fcomp-compiler-let form env processing-mode))
565    (locally
566      (fcomp-locally form env processing-mode))
567    (macrolet
568      (fcomp-macrolet form env processing-mode))
569    (symbol-macrolet
570      (fcomp-symbol-macrolet form env processing-mode))
571    ((%include include) (fcomp-include form env processing-mode))
572    (t
573     ;;Need to macroexpand to see if get more progn's/eval-when's and so should
574     ;;stay at toplevel.  But don't expand if either the evaluator or the
575     ;;compiler might not - better safe than sorry...
576     ;; Good advice, but the hard part is knowing which is which.
577     (cond 
578       ((and (non-nil-symbol-p sym)
579             (macro-function sym env)
580             (not (compiler-macro-function sym env))
581             (not (eq sym '%defvar-init)) ;  a macro that we want to special-case
582             (multiple-value-bind (new win) (fcomp-macroexpand-1 form env)
583               (when win
584                 (setq form new))
585               win))
586        (fcomp-form form env processing-mode))
587       ((and (not *fcomp-inside-eval-always*)
588             (memq sym *fcomp-eval-always-functions*))
589        (let* ((*fcomp-inside-eval-always* t)
590               (new `(eval-when (:execute :compile-toplevel :load-toplevel) ,form)))
591          (fcomp-form-1 new env processing-mode)))
592       (t
593        (when (or (eq processing-mode :compile-time) (eq processing-mode :compile-time-too))
594          (%compile-time-eval form env))
595        (when (and processing-mode (neq processing-mode :compile-time))
596          (case sym
597            ((%defconstant) (fcomp-load-%defconstant form env))
598            ((%defparameter) (fcomp-load-%defparameter form env))
599            ((%defvar %defvar-init) (fcomp-load-defvar form env))
600            ((%defun) (fcomp-load-%defun form env))
601            ((set-package %define-package)
602             (fcomp-random-toplevel-form form env)
603             (fcomp-compile-toplevel-forms env))
604            ((%macro) (fcomp-load-%macro form env))
605            ;; ((%deftype) (fcomp-load-%deftype form))
606            ;; ((define-setf-method) (fcomp-load-define-setf-method form))
607            (t (fcomp-random-toplevel-form form env)))))))))
608
609(defun fcomp-form-list (forms env processing-mode &optional outer-form)
610  (let* ((*fcomp-source-being-compiled* (and *fcomp-source-note-map*
611                                             (let* ((old *fcomp-source-being-compiled*)
612                                                    (new (or (and outer-form
613                                                                  (gethash outer-form *fcomp-source-note-map*))
614                                                             old)))
615                                               (register-code-note-parent new old)
616                                               new))))
617    (fcomp-output-source-being-compiled env)
618    (dolist (form forms) (fcomp-form form env processing-mode))))
619
620(defun fcomp-compiler-let (form env processing-mode &aux vars varinits (body (%cdr form)))
621  (fcomp-compile-toplevel-forms env)
622  (dolist (pair (car body))
623    (push (nx-pair-name pair) vars)
624    (push (%compile-time-eval (nx-pair-initform pair) env) varinits))
625  (progv (nreverse vars) (nreverse varinits)
626    (fcomp-form-list (cdr body) env processing-mode form)
627    (fcomp-compile-toplevel-forms env)))
628
629(defun fcomp-locally (form env processing-mode &aux (body (%cdr form)))
630  (fcomp-compile-toplevel-forms env)
631  (multiple-value-bind (body decls) (parse-body body env)
632    (let* ((env (augment-environment env :declare (decl-specs-from-declarations decls))))
633      (fcomp-form-list body env processing-mode form)
634      (fcomp-compile-toplevel-forms env))))
635
636(defun fcomp-macrolet (form env processing-mode &aux (body (%cdr form)))
637  (fcomp-compile-toplevel-forms env)
638  (let ((outer-env (augment-environment env 
639                                        :macro
640                                        (mapcar #'(lambda (m)
641                                                    (destructuring-bind (name arglist &body body) m
642                                                      (list name (enclose (parse-macro name arglist body env)
643                                                                          env))))
644                                                (car body)))))
645    (multiple-value-bind (body decls) (parse-body (cdr body) outer-env)
646      (let* ((env (augment-environment 
647                   outer-env
648                   :declare (decl-specs-from-declarations decls))))
649        (fcomp-form-list body env processing-mode form)
650        (fcomp-compile-toplevel-forms env)))))
651
652(defun fcomp-symbol-macrolet (form env processing-mode &aux (body (%cdr form)))
653  (fcomp-compile-toplevel-forms env)
654  (let* ((outer-env (augment-environment env :symbol-macro (car body))))
655    (multiple-value-bind (body decls) (parse-body (cdr body) env)
656      (let* ((env (augment-environment outer-env 
657                                       :declare (decl-specs-from-declarations decls))))
658        (fcomp-form-list body env processing-mode form)
659        (fcomp-compile-toplevel-forms env)))))
660
661(defun fcomp-eval-when (form env processing-mode &aux (body (%cdr form)) (eval-times (pop body)))
662  (let* ((compile-time-too  (eq processing-mode :compile-time-too))
663         (compile-time-only (eq processing-mode :compile-time))
664         (at-compile-time nil)
665         (at-load-time nil)
666         (at-eval-time nil))
667    (dolist (when eval-times)
668      (if (or (eq when 'compile) (eq when :compile-toplevel))
669        (setq at-compile-time t)
670        (if (or (eq when 'eval) (eq when :execute))
671          (setq at-eval-time t)
672          (if (or (eq when 'load) (eq when :load-toplevel))
673            (setq at-load-time t)
674            (warn "Unknown EVAL-WHEN time ~s in ~S while compiling ~S."
675                  when eval-times *fasl-source-file*)))))
676    (fcomp-compile-toplevel-forms env)        ; always flush the suckers
677    (cond (compile-time-only
678           (if at-eval-time (fcomp-form-list body env :compile-time form)))
679          (at-load-time
680           (fcomp-form-list body env (if (or at-compile-time (and at-eval-time compile-time-too))
681                                       :compile-time-too
682                                       :not-compile-time)
683                            form))
684          ((or at-compile-time (and at-eval-time compile-time-too))
685           (fcomp-form-list body env :compile-time form))))
686  (fcomp-compile-toplevel-forms env))
687
688(defun fcomp-include (form env processing-mode &aux file)
689  (fcomp-compile-toplevel-forms env)
690  (verify-arg-count form 1 1)
691  (setq file (nx-transform (%cadr form) env))
692  (unless (constantp file) (report-bad-arg file '(or string pathname)))
693  (let ((actual (merge-pathnames (eval-constant file)
694                                 (directory-namestring *compiling-file*))))
695    (when *compile-print* (format t "~&~vTIncluding file ~A~%" *fcomp-indentation* actual))
696    (let ((*fcomp-indentation* (+ 4 *fcomp-indentation*))
697          (*package* *package*))
698      (fcomp-read-loop (fcomp-find-file actual) actual env processing-mode)
699      (fcomp-output-form $fasl-src env *loading-file-source-file*))
700    (when *compile-print* (format t "~&~vTFinished included file ~A~%" *fcomp-indentation* actual))))
701
702(defun define-compile-time-constant (symbol initform env)
703  (note-variable-info symbol t env)
704  (let ((definition-env (definition-environment env)))
705    (when definition-env
706      (multiple-value-bind (value error) 
707                           (ignore-errors (values (%compile-time-eval initform env) nil))
708        (when error
709          (warn "Compile-time evaluation of DEFCONSTANT initial value form for ~S while ~
710                 compiling ~S signalled the error: ~&~A" symbol *fasl-source-file* error))
711        (push (cons symbol (if error (%unbound-marker-8) value)) (defenv.constants definition-env))))
712    symbol))
713
714(defun fcomp-load-%defconstant (form env)
715  (destructuring-bind (sym valform &optional doc) (cdr form)
716    (unless *fasl-save-doc-strings*
717      (setq doc nil))
718    (if (quoted-form-p sym)
719      (setq sym (%cadr sym)))
720    (if (and (typep sym 'symbol) (or (quoted-form-p valform) (self-evaluating-p valform)))
721      (fcomp-output-form $fasl-defconstant env sym (eval-constant valform) (eval-constant doc))
722      (fcomp-random-toplevel-form form env))))
723
724(defun fcomp-load-%defparameter (form env)
725  (destructuring-bind (sym valform &optional doc) (cdr form)
726    (unless *fasl-save-doc-strings*
727      (setq doc nil))
728    (if (quoted-form-p sym)
729      (setq sym (%cadr sym)))
730    (let* ((sym-p (typep sym 'symbol))
731           (fn (and sym-p (fcomp-function-arg valform env form))))
732      (if (and sym-p (or fn (constantp valform)))
733        (fcomp-output-form $fasl-defparameter env sym (or fn (eval-constant valform)) (eval-constant doc))
734        (fcomp-random-toplevel-form form env)))))
735
736; Both the simple %DEFVAR and the initial-value case (%DEFVAR-INIT) come here.
737; Only try to dump this as a special fasl operator if the initform is missing
738;  or is "harmless" to evaluate whether needed or not (constant or function.)
739; Hairier initforms could be handled by another fasl operator that takes a thunk
740; and conditionally calls it.
741(defun fcomp-load-defvar (form env)
742  (destructuring-bind (sym &optional (valform nil val-p) doc) (cdr form)
743    (unless *fasl-save-doc-strings*
744      (setq doc nil))
745    (if (quoted-form-p sym)             ; %defvar quotes its arg, %defvar-init doesn't.
746      (setq sym (%cadr sym)))
747    (let* ((sym-p (typep sym 'symbol)))
748      (if (and sym-p (not val-p))
749        (fcomp-output-form $fasl-defvar env sym)
750        (let* ((fn (if sym-p (fcomp-function-arg valform env form))))
751          (if (and sym-p (or fn (constantp valform)))
752            (fcomp-output-form $fasl-defvar-init env sym (or fn (eval-constant valform)) (eval-constant doc))
753            (fcomp-random-toplevel-form form env)))))))
754     
755(defun define-compile-time-macro (name lambda-expression env)
756  (let ((definition-env (definition-environment env)))
757    (when definition-env
758      (push (list* name 
759                   'macro 
760                   (compile-named-function lambda-expression :name name :env env)) 
761            (defenv.functions definition-env))
762      (record-function-info name (list (cons nil 'macro)) env))
763    name))
764
765(defun define-compile-time-symbol-macro (name expansion env)
766  (let* ((definition-env (definition-environment env)))
767    (if definition-env
768      (push (cons name expansion) (defenv.symbol-macros definition-env)))
769    name))
770
771
772(defun fcomp-proclaim-type (type syms)
773  (dolist (sym syms)
774    (if (symbolp sym)
775    (push (cons sym type) *nx-compile-time-types*)
776      (warn "~S isn't a symbol in ~S type declaration while compiling ~S."
777            sym type *fasl-source-file*))))
778
779(defun compile-time-proclamation (specs env &aux  sym (defenv (definition-environment env)))
780  (when defenv
781    (dolist (spec specs)
782      (setq sym (pop spec))
783      (case sym
784        (type
785         (fcomp-proclaim-type (car spec) (cdr spec)))
786        (special
787         (dolist (sym spec)
788           (push (cons (require-type sym 'symbol) nil) (defenv.specials defenv))))
789        (notspecial
790         (let ((specials (defenv.specials defenv)))
791           (dolist (sym spec (setf (defenv.specials defenv) specials))
792             (let ((pair (assq sym specials)))
793               (when pair (setq specials (nremove pair specials)))))))
794        (optimize
795         (%proclaim-optimize spec))
796        (inline
797         (dolist (sym spec)
798           (push (cons (maybe-setf-function-name sym) (cons 'inline 'inline)) (lexenv.fdecls defenv))))
799        (notinline
800         (dolist (sym spec)
801           (unless (compiler-special-form-p sym)
802             (push (cons (maybe-setf-function-name sym) (cons 'inline 'notinline)) (lexenv.fdecls defenv)))))
803        (declaration
804         (dolist (sym spec)
805           (pushnew (require-type sym 'symbol) *nx-known-declarations*)))
806        (ignore
807         (dolist (sym spec)
808           (push (cons (require-type sym 'symbol) t) *nx-proclaimed-ignore*)))
809        (unignore
810         (dolist (sym spec)
811           (push (cons (require-type sym 'symbol) nil) *nx-proclaimed-ignore*)))
812        (ftype 
813         (let ((ftype (car spec))
814               (fnames (cdr spec)))
815           ;; ----- this part may be redundant, now that the lexenv.fdecls part is being done
816           (if (and (consp ftype)
817                    (consp fnames)
818                    (eq (%car ftype) 'function))
819             (dolist (fname fnames)
820               (note-function-info fname nil env)))
821           (dolist (fname fnames)
822             (push (list* (maybe-setf-function-name fname) sym ftype) (lexenv.fdecls defenv)))))
823        (otherwise
824         (if (memq (if (consp sym) (%car sym) sym) *cl-types*)
825           (fcomp-proclaim-type sym spec)       ; A post-cltl2 cleanup issue changes this
826           nil)                         ; ---- probably ought to complain
827         )))))
828
829(defun fcomp-load-%defun (form env)
830  (destructuring-bind (fn &optional doc) (cdr form)
831    (unless *fasl-save-doc-strings*
832      (if (consp doc)
833        (if (and (eq (car doc) 'quote) (consp (cadr doc)))
834          (setf (car (cadr doc)) nil))
835        (setq doc nil)))
836    (record-form-source-equivalent form fn)
837    (if (and (constantp doc)
838             (setq fn (fcomp-function-arg fn env form)))
839      (progn
840        (setq doc (eval-constant doc))
841        (fcomp-output-form $fasl-defun env fn doc))
842      (fcomp-random-toplevel-form form env))))
843
844(defun fcomp-load-%macro (form env &aux fn doc)
845  (verify-arg-count form 1 2)
846  (record-form-source-equivalent form (cadr form))
847  (if (and (constantp (setq doc (caddr form)))
848           (setq fn (fcomp-function-arg (cadr form) env form)))
849    (progn
850      (setq doc (eval-constant doc))
851      (fcomp-output-form $fasl-macro env fn doc))
852    (fcomp-random-toplevel-form form env)))
853
854(defun define-compile-time-structure (sd refnames predicate env)
855  (let ((defenv (definition-environment env)))
856    (when defenv
857      (when (non-nil-symbolp (sd-name sd))
858        (push (make-instance 'compile-time-class :name (sd-name sd))
859              (defenv.classes defenv)))
860      (setf (defenv.structures defenv) (alist-adjoin (sd-name sd) sd (defenv.structures defenv)))
861      (let* ((structrefs (defenv.structrefs defenv)))
862        (when (and (null (sd-type sd))
863                   predicate)
864          (setq structrefs (alist-adjoin predicate (sd-name sd) structrefs)))
865        (dolist (slot (sd-slots sd))
866          (unless (fixnump (ssd-name slot))
867            (setq structrefs
868                (alist-adjoin (if refnames (pop refnames) (ssd-name slot))
869                              (ssd-type-and-refinfo slot)
870                              structrefs))))
871        (setf (defenv.structrefs defenv) structrefs)))))
872
873(defun fcomp-note-source-transformation (original new)
874  (when (and *fcomp-source-note-map*
875             (gethash original *fcomp-source-note-map*)
876             (not (gethash new *fcomp-source-note-map*)))
877    (setf (gethash new *fcomp-source-note-map*)
878          (gethash original *fcomp-source-note-map*))))
879
880
881(defun fcomp-macroexpand-1 (form env)
882  (multiple-value-bind (new win) (macroexpand-1 form env)
883    (when win
884      (fcomp-note-source-transformation form new))
885    (values new win)))
886
887(defun fcomp-transform (form env)
888  (multiple-value-bind (new win) (nx-transform form env *fcomp-source-note-map*)
889    (when win
890      (fcomp-note-source-transformation form new))
891    (values new win)))
892
893
894(defun fcomp-random-toplevel-form (form env)
895  (unless (constantp form)
896    (unless (or (atom form)
897                (compiler-special-form-p (%car form)))
898      ;;Pre-compile any lfun args.  This is an efficiency hack, since compiler
899      ;;reentering itself for inner lambdas tends to be more expensive than
900      ;;top-level compiles.
901      ;;This assumes the form has been macroexpanded, or at least none of the
902      ;;non-evaluated macro arguments could look like functions.
903      (let (lfun (args (%cdr form)))
904        (while args
905          (record-form-source-equivalent form (first args))
906          (multiple-value-bind (arg win) (fcomp-transform (%car args) env)
907            (when (or (setq lfun (fcomp-function-arg arg env form))
908                      win)
909              (when lfun (setq arg `',lfun))
910              (labels ((subst-l (new ptr list)
911                         (if (eq ptr list) (cons new (cdr list))
912                           (cons (car list) (subst-l new ptr (%cdr list))))))
913                (setq form (subst-l arg args form))))
914            (setq args (%cdr args))))))
915    (push form *fcomp-toplevel-forms*)))
916
917(defun fcomp-function-arg (expr env &optional form)
918  (multiple-value-bind (lambda-expr name win)
919      (when (consp expr)
920        (cond ((and (eq (%car expr) 'nfunction)
921                    (lambda-expression-p (cadr (%cdr expr))))
922               (values (%caddr expr) (%cadr expr) t))
923              ((and (eq (%car expr) 'function)
924                    (lambda-expression-p (car (%cdr expr))))
925               (values (%cadr expr) nil t))))
926    (when win
927      (fcomp-named-function lambda-expr name env
928                            (and *fcomp-source-note-map*
929                                 (let* ((old *fcomp-source-being-compiled*)
930                                        (new (or (gethash expr *fcomp-source-note-map*)
931                                                 (gethash lambda-expr *fcomp-source-note-map*)
932                                                 (and form (gethash form *fcomp-source-note-map*))
933                                                 old)))
934                                   (register-code-note-parent new old)
935                                   new))))))
936
937(defun fcomp-compile-toplevel-forms (env)
938  (when *fcomp-toplevel-forms*
939    (let* ((forms (nreverse *fcomp-toplevel-forms*))
940           (*fcomp-stream-position* *fcomp-previous-position*)
941           (lambda (if (null (cdr forms))
942                     `(lambda () (progn ,@forms))
943                     `(lambda ()
944                        (macrolet ((load-time-value (value)
945                                     (declare (ignore value))
946                                     (compiler-function-overflow)))
947                          ,@forms)))))
948      (dolist (form forms)
949        (record-form-source-equivalent lambda form))
950      (setq *fcomp-toplevel-forms* '())
951      ;(format t "~& Random toplevel form: ~s" lambda)
952      (handler-case (fcomp-output-form
953                     $fasl-lfuncall
954                     env
955                     (fcomp-named-function lambda nil env))
956        (compiler-function-overflow ()
957          (if (null (cdr forms))
958            (error "Form ~s cannot be compiled - size exceeds compiler limitation"
959                   (%car forms))
960            ; else compile each half :
961            (progn
962              (dotimes (i (floor (length forms) 2))
963                (declare (fixnum i))
964                (push (pop forms) *fcomp-toplevel-forms*))
965              (fcomp-compile-toplevel-forms env)
966              (setq *fcomp-toplevel-forms* (nreverse forms))
967              (fcomp-compile-toplevel-forms env))))))))
968
969(defun fcomp-output-form (opcode env &rest args)
970  (when *fcomp-toplevel-forms* (fcomp-compile-toplevel-forms env))
971  (push (cons opcode args) *fcomp-output-list*))
972
973;;; Compile a lambda expression for the sole purpose of putting it in a fasl
974;;; file.  The result will not be funcalled.  This really shouldn't bother
975;;; making an lfun, but it's simpler this way...
976(defun fcomp-named-function (def name env &optional source-note)
977  (let* ((env (new-lexical-environment env))
978         (*nx-break-on-program-errors* (not (memq *fasl-break-on-program-errors* '(nil :defer)))))
979    (multiple-value-bind (lfun warnings)
980        (compile-named-function def
981                                :name name
982                                :env env
983                                :function-note source-note
984                                :keep-lambda *fasl-save-definitions*
985                                :keep-symbols *fasl-save-local-symbols*
986                                :policy *default-file-compilation-policy*
987                                :source-notes *fcomp-source-note-map*
988                                :load-time-eval-token cfasl-load-time-eval-sym
989                                :target *fasl-target*)
990      (fcomp-signal-or-defer-warnings warnings env)
991      lfun)))
992
993
994;; Convert parent-notes to immediate indices.  The reason this is necessary is to avoid hitting
995;; the fasdumper's 64K limit on multiply-referenced objects.  This removes the reference
996;; from parent slots, making notes less likely to be multiply-referenced.
997(defun fcomp-digest-code-notes (lfun &optional refs)
998  (unless (memq lfun refs)
999    (let* ((lfv (function-to-function-vector lfun))
1000           (start #+ppc-target 0 #+x86-target (%function-code-words lfun))
1001           (refs (cons lfun refs)))
1002      (declare (dynamic-extent refs))
1003      (loop for i from start below (uvsize lfv) as imm = (uvref lfv i)
1004            do (typecase imm
1005                 (code-note
1006                  (let* ((parent (code-note-parent-note imm))
1007                         (pos (when (code-note-p parent)
1008                                (loop for j from start below i
1009                                      do (when (eq parent (uvref lfv j)) (return j))))))
1010                    (when pos
1011                      (setf (code-note-parent-note imm) pos))))
1012                 (function
1013                  (fcomp-digest-code-notes imm refs)))))))
1014
1015; For now, defer only UNDEFINED-FUNCTION-REFERENCEs, signal all others via WARN.
1016; Well, maybe not WARN, exactly.
1017(defun fcomp-signal-or-defer-warnings (warnings env)
1018  (let ((init (null *fcomp-warnings-header*))
1019        (some *fasl-warnings-signalled-p*)
1020        (harsh *fasl-non-style-warnings-signalled-p*))
1021    (dolist (w warnings)
1022      (setf (compiler-warning-file-name w) *fasl-source-file*)
1023      (setf (compiler-warning-stream-position w) *fcomp-stream-position*)
1024      (if (and (typep w 'undefined-function-reference) 
1025               (eq w (setq w (macro-too-late-p w env))))
1026        (push w *fasl-deferred-warnings*)
1027        (progn
1028          (multiple-value-setq (harsh some *fcomp-warnings-header*)
1029                               (signal-compiler-warning w init *fcomp-warnings-header* harsh some))
1030          (setq init nil))))
1031    (setq *fasl-warnings-signalled-p* some
1032          *fasl-non-style-warnings-signalled-p* harsh)))
1033
1034; If W is an UNDEFINED-FUNCTION-REFERENCE which refers to a macro (either at compile-time in ENV
1035; or globally), cons up a MACRO-USED-BEFORE-DEFINITION warning and return it; else return W.
1036
1037(defun macro-too-late-p (w env)
1038  (let* ((args (compiler-warning-args w))
1039         (name (car args)))
1040    (if (or (macro-function name)
1041            (let* ((defenv (definition-environment env))
1042                   (info (if defenv (assq name (defenv.functions defenv)))))
1043              (and (consp (cdr info))
1044                   (eq 'macro (cadr info)))))
1045      (make-instance 'macro-used-before-definition
1046        :file-name (compiler-warning-file-name w)
1047        :function-name (compiler-warning-function-name w)
1048        :warning-type ':macro-used-before-definition
1049        :args args)
1050      w)))
1051
1052
1053             
1054;;;;          fasl-scan - dumping reference counting
1055;;;;
1056;;;;
1057;These should be constants, but it's too much trouble when need to change 'em.
1058(defparameter FASL-FILE-ID #xFF00)  ;Overall file format, shouldn't change much
1059(defparameter FASL-VERSION #xFF53)  ;Fasl block format.
1060
1061(defvar *fasdump-hash*)
1062(defvar *fasdump-read-package*)
1063(defvar *fasdump-global-offsets*)
1064(defvar *make-load-form-hash*)
1065
1066;;;Return a hash table containing subexp's which are referenced more than once.
1067(defun fasl-scan (forms)
1068  (let* ((*fasdump-hash* (make-hash-table :size (length forms)          ; Crude estimate
1069                                          :rehash-threshold 0.9
1070                                          :test 'eq
1071                                          :shared nil))
1072         (*make-load-form-hash* (make-hash-table :test 'eq :shared nil))
1073         (*fasdump-read-package* nil)
1074         (*fasdump-global-offsets* nil)
1075         (gsymbols nil))
1076    (dolist (op forms)
1077      (if (packagep op) ; old magic treatment of *package*
1078        (setq *fasdump-read-package* op)
1079        (dolist (arg (cdr op)) (fasl-scan-form arg))))
1080
1081    #-bccl (when (eq *compile-verbose* :debug)
1082             (format t "~&~S forms, ~S entries -> "
1083                     (length forms)
1084                     (hash-table-count *fasdump-hash*)))
1085    (maphash #'(lambda (key val)
1086                 (when (%izerop val) (remhash key *fasdump-hash*)))
1087             *fasdump-hash*)
1088    #-bccl (when (eq *compile-verbose* :debug)
1089             (format t "~S." (hash-table-count *fasdump-hash*)))
1090    (values *fasdump-hash*
1091            gsymbols
1092            *fasdump-global-offsets*)))
1093
1094;;; During scanning, *fasdump-hash* values are one of the following:
1095;;;  nil - form hasn't been referenced yet.
1096;;;   0 - form has been referenced exactly once
1097;;;   T - form has been referenced more than once
1098;;;  (load-form scanning-p referenced-p initform)
1099;;;     form should be replaced by load-form
1100;;;     scanning-p is true while we're scanning load-form
1101;;;     referenced-p is nil if unreferenced,
1102;;;                     T if referenced but not dumped yet,
1103;;;                     0 if dumped already (fasl-dump-form uses this)
1104;;;     initform is a compiled version of the user's initform
1105(defun fasl-scan-form (form)
1106  (when form
1107    (let ((info (gethash form *fasdump-hash*)))
1108      (cond ((null info)
1109             (fasl-scan-dispatch form))
1110            ((eql info 0)
1111             (puthash form *fasdump-hash* t))
1112            ((listp info)               ; a make-load-form form
1113             (when (cadr info)
1114               (error "Circularity in ~S for ~S" 'make-load-form form))
1115             (let ((referenced-cell (cddr info)))
1116               (setf (car referenced-cell) t)   ; referenced-p
1117               (setf (gethash (car info) *fasdump-hash*) t)))))))
1118
1119
1120
1121
1122(defun fasl-scan-dispatch (exp)
1123  (when exp
1124    (let ((type-code (typecode exp)))
1125      (declare (fixnum type-code))
1126      (case type-code
1127        (#.target::tag-fixnum
1128         (fasl-scan-fixnum exp))
1129        (#.target::fulltag-cons (fasl-scan-list exp))
1130        #+ppc32-target
1131        (#.ppc32::tag-imm)
1132        #+ppc64-target
1133        ((#.ppc64::fulltag-imm-0
1134          #.ppc64::fulltag-imm-1
1135          #.ppc64::fulltag-imm-2
1136          #.ppc64::fulltag-imm-3))
1137        #+x8664-target
1138        ((#.x8664::fulltag-imm-0
1139          #.x8664::fulltag-imm-1))
1140        (t
1141         (if
1142           #+ppc32-target
1143           (= (the fixnum (logand type-code ppc32::full-tag-mask)) ppc32::fulltag-immheader)
1144           #+ppc64-target
1145           (= (the fixnum (logand type-code ppc64::lowtagmask)) ppc64::lowtag-immheader)
1146           #+x8664-target
1147           (and (= (the fixnum (lisptag exp)) x8664::tag-misc)
1148                (logbitp (the (unsigned-byte 16) (logand type-code x8664::fulltagmask))
1149                         (logior (ash 1 x8664::fulltag-immheader-0)
1150                                 (ash 1 x8664::fulltag-immheader-1)
1151                                 (ash 1 x8664::fulltag-immheader-2))))
1152           (case type-code
1153             ((#.target::subtag-macptr #.target::subtag-dead-macptr) (unless (%null-ptr-p exp) (fasl-unknown exp)))
1154             (t (fasl-scan-ref exp)))
1155           (case type-code
1156             ((#.target::subtag-pool #.target::subtag-weak #.target::subtag-lock) (fasl-unknown exp))
1157             (#+ppc-target #.target::subtag-symbol
1158                           #+x86-target #.target::tag-symbol (fasl-scan-symbol exp))
1159             ((#.target::subtag-instance #.target::subtag-struct)
1160              (fasl-scan-user-form exp))
1161             (#.target::subtag-package (fasl-scan-ref exp))
1162             (#.target::subtag-istruct
1163              (if (memq (istruct-type-name exp)  *istruct-make-load-form-types*)
1164                (progn
1165                  (if (hash-table-p exp)
1166                    (fasl-lock-hash-table exp))
1167                  (fasl-scan-user-form exp))
1168                (fasl-scan-gvector exp)))
1169             #+x86-target
1170             (#.target::tag-function (fasl-scan-clfun exp))
1171             (t (fasl-scan-gvector exp)))))))))
1172             
1173
1174(defun fasl-scan-ref (form)
1175  (puthash form *fasdump-hash* 0))
1176
1177(defun fasl-scan-fixnum (fixnum)
1178  (unless (short-fixnum-p fixnum) (fasl-scan-ref fixnum)))
1179
1180(defparameter *istruct-make-load-form-types*
1181  '(lexical-environment shared-library-descriptor shared-library-entry-point
1182    external-entry-point foreign-variable
1183    ctype unknown-ctype class-ctype foreign-ctype union-ctype member-ctype 
1184    array-ctype numeric-ctype hairy-ctype named-ctype constant-ctype args-ctype
1185    hash-table package-ref type-cell class-cell slot-id))
1186
1187
1188
1189
1190(defun fasl-scan-gvector (vec)
1191  (fasl-scan-ref vec)
1192  (dotimes (i (uvsize vec)) 
1193    (declare (fixnum i))
1194    (fasl-scan-form (%svref vec i))))
1195
1196#+x86-target
1197(defun fasl-scan-clfun (f)
1198  (let* ((fv (%function-to-function-vector f))
1199         (size (uvsize fv))
1200         (ncode-words (%function-code-words f)))
1201    (fasl-scan-ref f)
1202    (do* ((k ncode-words (1+ k)))
1203         ((= k size))
1204      (fasl-scan-form (uvref fv k)))))
1205
1206(defun funcall-lfun-p (form)
1207  (and (listp form)
1208       (eq (%car form) 'funcall)
1209       (listp (%cdr form))
1210       (or (functionp (%cadr form))
1211           (eql (typecode (%cadr form)) target::subtag-xfunction))
1212       (null (%cddr form))))
1213
1214;;; We currently represent istruct-cells as conses.  That's not
1215;;; incredibly efficient (among other things, we have to do this
1216;;; check when scanning/dumping any list, but it's probably not
1217;;; worth burning a tag on them.  There are currently about 50
1218;;; entries on the *istruct-cells* list.
1219(defun istruct-cell-p (x)
1220  (and (consp x)
1221       (typep (%car x) 'symbol)
1222       (atom (%cdr x))
1223       (not (null (memq x *istruct-cells*)))))
1224
1225(defun fasl-scan-list (list)
1226  (cond ((eq (%car list) cfasl-load-time-eval-sym)
1227         (let ((form (car (%cdr list))))
1228           (fasl-scan-form (if (funcall-lfun-p form)
1229                             (%cadr form)
1230                             form))))
1231        ((istruct-cell-p list)
1232         (fasl-scan-form (%car list)))
1233        (t (when list
1234             (fasl-scan-ref list)
1235             (fasl-scan-form (%car list))
1236             (fasl-scan-form (%cdr list))))))
1237
1238(defun fasl-scan-user-form (form)
1239  (when (code-note-p form)
1240    (return-from fasl-scan-user-form (fasl-scan-gvector form)))
1241  (multiple-value-bind (load-form init-form) (make-load-form form *fcomp-load-forms-environment*)
1242    (labels ((simple-load-form (form)
1243               (or (atom form)
1244                   (let ((function (car form)))
1245                     (or (eq function 'quote)
1246                         (and (symbolp function)
1247                              ;; using fboundp instead of symbol-function
1248                              ;; see comments in symbol-function
1249                              (or (functionp (fboundp function))
1250                                  (eq function 'progn))
1251                              ;; (every #'simple-load-form (cdr form))
1252                              (dolist (arg (cdr form) t)
1253                                (unless (simple-load-form arg)
1254                                  (return nil))))))))
1255             (load-time-eval-form (load-form form type)
1256               (cond ((quoted-form-p load-form)
1257                      (%cadr load-form))
1258                     ((self-evaluating-p load-form)
1259                      load-form)
1260                     ((simple-load-form load-form)
1261                      `(,cfasl-load-time-eval-sym ,load-form))
1262                     (t (multiple-value-bind (lfun warnings)
1263                                             (or
1264                                              (gethash load-form *make-load-form-hash*)
1265                                              (fcomp-named-function `(lambda () ,load-form) nil nil))
1266                          (when warnings
1267                            (cerror "Ignore the warnings"
1268                                    "Compiling the ~s ~a form for~%~s~%produced warnings."
1269                                    'make-load-form type form))
1270                          (setf (gethash load-form *make-load-form-hash*) lfun)
1271                          `(,cfasl-load-time-eval-sym (funcall ,lfun)))))))
1272      (declare (dynamic-extent #'simple-load-form #'load-time-eval-form))
1273      (let* ((compiled-initform
1274              (and init-form (load-time-eval-form init-form form "initialization")))
1275             (info (list (load-time-eval-form load-form form "creation")
1276                         T              ; scanning-p
1277                         nil            ; referenced-p
1278                         compiled-initform  ;initform-info
1279                         )))
1280        (puthash form *fasdump-hash* info)
1281        (fasl-scan-form (%car info))
1282        (setf (cadr info) nil)        ; no longer scanning load-form
1283        (when init-form
1284          (fasl-scan-form compiled-initform))))))
1285
1286(defun fasl-scan-symbol (form)
1287  (fasl-scan-ref form)
1288  (fasl-scan-form (symbol-package form)))
1289 
1290
1291
1292;;;;          Pass 3 - dumping
1293;;;;
1294;;;;
1295(defvar *fasdump-epush*)
1296(defvar *fasdump-stream*)
1297(defvar *fasdump-eref*)
1298
1299(defun fasl-dump-file (gnames goffsets forms hash filename)
1300  (let ((opened? nil)
1301        (finished? nil))
1302    (unwind-protect
1303      (with-open-file (*fasdump-stream* filename :direction :output
1304                                        :element-type '(unsigned-byte 8)
1305                                        :if-exists :supersede
1306                                        :if-does-not-exist :create)
1307        (setq opened? t)
1308        (fasl-set-filepos 0)
1309        (fasl-out-word 0)             ;Will become the ID word
1310        (fasl-out-word 1)             ;One block in the file
1311        (fasl-out-long 12)            ;Block starts at file pos 12
1312        (fasl-out-long 0)             ;Length will go here
1313        (fasl-dump-block gnames goffsets forms hash)  ;Write the block
1314        (let ((pos (fasl-filepos)))
1315          (fasl-set-filepos 8)        ;Back to length longword
1316          (fasl-out-long (- pos 12))) ;Write length
1317        (fasl-set-filepos 0)          ;Seem to have won, make us legal
1318        (fasl-out-word FASL-FILE-ID)
1319        (setq finished? t)
1320        filename)
1321      (when (and opened? (not finished?))
1322        (delete-file filename)))))
1323
1324(defun fasl-dump-block (gnames goffsets forms hash)
1325  (let ((etab-size (hash-table-count hash)))
1326    (when (> etab-size 65535)
1327      (error "Too many multiply-referenced objects in fasl file.~%Limit is ~d. Were ~d." 65535 etab-size))
1328    (fasl-out-word FASL-VERSION)          ; Word 0
1329    (fasl-out-long  0)
1330    (fasl-out-byte $fasl-vetab-alloc)
1331    (fasl-out-count etab-size)
1332    (fasl-dump gnames goffsets forms hash)
1333    (fasl-out-byte $fasl-end)))
1334
1335(defun fasl-dump (gnames goffsets forms hash)
1336  (let* ((*fasdump-hash* hash)
1337         (*fasdump-read-package* nil)
1338         (*fasdump-epush* nil)
1339         (*fasdump-eref* -1)
1340         (*fasdump-global-offsets* goffsets))
1341    (when gnames
1342      (fasl-out-byte $fasl-globals)
1343      (fasl-dump-form gnames))
1344    (dolist (op forms)
1345      (if (packagep op)
1346        (setq *fasdump-read-package* op)
1347        (progn
1348          (fasl-out-byte (car op))
1349          (dolist (arg (cdr op)) (fasl-dump-form arg)))))))
1350
1351;;;During dumping, *fasdump-hash* values are one of the following:
1352;;;   nil - form has no load form, is referenced at most once.
1353;;;   fixnum - form has already been dumped, fixnum is the etab index.
1354;;;   T - form hasn't been dumped yet, is referenced more than once.
1355;;;  (load-form . nil) - form should be replaced by load-form.
1356(defun fasl-dump-form (form)
1357  (let ((info (gethash form *fasdump-hash*)))
1358    (cond ((fixnump info)
1359           (fasl-out-byte $fasl-veref)
1360           (fasl-out-count info))
1361          ((consp info)
1362           (fasl-dump-user-form form info))
1363          (t
1364           (setq *fasdump-epush* info)
1365           (fasl-dump-dispatch form)))))
1366
1367(defun fasl-dump-user-form (form info)
1368  (let* ((load-form (car info))
1369         (referenced-p (caddr info))
1370         (initform (cadddr info)))
1371    (when referenced-p
1372      (unless (gethash load-form *fasdump-hash*)
1373        (error "~s was not in ~s.  This shouldn't happen." 'load-form '*fasdump-hash*)))
1374    (when initform
1375      (fasl-out-byte $fasl-prog1))      ; ignore the initform
1376    (fasl-dump-form load-form)
1377    (when referenced-p
1378      (setf (gethash form *fasdump-hash*) (gethash load-form *fasdump-hash*)))
1379    (when initform
1380      (fasl-dump-form initform))))
1381
1382(defun fasl-out-opcode (opcode form)
1383  (if *fasdump-epush*
1384    (progn
1385      (setq *fasdump-epush* nil)
1386      (fasl-out-byte (fasl-epush-op opcode))
1387      (fasl-dump-epush form))
1388    (fasl-out-byte opcode)))
1389
1390(defun fasl-dump-epush (form)
1391  #-bccl (when (fixnump (gethash form *fasdump-hash*))
1392           (error "Bug! Duplicate epush for ~S" form))
1393  (puthash form *fasdump-hash* (setq *fasdump-eref* (1+ *fasdump-eref*))))
1394
1395
1396(defun fasl-dump-dispatch (exp)
1397  (etypecase exp
1398    ((signed-byte 16) (fasl-dump-s16 exp))
1399    ((signed-byte 32) (fasl-dump-s32 exp))
1400    ((signed-byte 64) (fasl-dump-s64 exp))
1401    (bignum (fasl-dump-32-bit-ivector exp $fasl-bignum32))
1402    (character (fasl-dump-char exp))
1403    (list (fasl-dump-list exp))
1404    (immediate (fasl-dump-t_imm exp))
1405    (double-float (fasl-dump-dfloat exp))
1406    (single-float (fasl-dump-sfloat exp))
1407    (simple-string (let* ((n (length exp)))
1408                     (fasl-out-opcode $fasl-nvstr exp)
1409                     (fasl-out-count n)
1410                     (fasl-out-simple-string exp 0 n)))
1411    (simple-bit-vector (fasl-dump-bit-vector exp))
1412    ((simple-array (unsigned-byte 8) (*))
1413     (fasl-dump-8-bit-ivector exp $fasl-u8-vector))
1414    ((simple-array (signed-byte 8) (*))
1415     (fasl-dump-8-bit-ivector exp $fasl-s8-vector))
1416    ((simple-array (unsigned-byte 16) (*))
1417     (fasl-dump-16-bit-ivector exp $fasl-u16-vector))
1418    ((simple-array (signed-byte 16) (*))
1419     (fasl-dump-16-bit-ivector exp $fasl-s16-vector))
1420    ((simple-array (unsigned-byte 32) (*))
1421     (fasl-dump-32-bit-ivector exp $fasl-u32-vector))
1422    ((simple-array (signed-byte 32) (*))
1423     (fasl-dump-32-bit-ivector exp $fasl-s32-vector))
1424    ((simple-array single-float (*))
1425     (fasl-dump-32-bit-ivector exp $fasl-single-float-vector))
1426    ((simple-array double-float (*))
1427     (fasl-dump-double-float-vector exp))
1428    (symbol (fasl-dump-symbol exp))
1429    (package (fasl-dump-package exp))
1430    (function (fasl-dump-function exp))
1431    (xfunction (fasl-dump-function exp))
1432    (code-vector (fasl-dump-codevector exp))
1433    (xcode-vector (fasl-dump-codevector exp))
1434    (simple-vector (fasl-dump-gvector exp $fasl-t-vector))
1435    (ratio (fasl-dump-ratio exp))
1436    (complex (fasl-dump-complex exp))
1437    #+(and 64-bit-target (not cross-compiling))
1438    ((simple-array (unsigned-byte 64) (*))
1439     (fasl-dump-64-bit-ivector exp $fasl-u64-vector))
1440    #+(and 64-bit-target (not cross-compiling))
1441    ((simple-array (signed-byte 64) (*))
1442     (fasl-dump-64-bit-ivector exp $fasl-s64-vector))
1443    (vector (fasl-dump-gvector exp $fasl-vector-header))
1444    (array (fasl-dump-gvector exp $fasl-array-header))
1445    (ivector
1446     (unless (eq (backend-target-arch-name *target-backend*)
1447                 (backend-target-arch-name *host-backend*))
1448       (error "can't cross-compile constant reference to ~s" exp))
1449     (let* ((typecode (typecode exp))
1450            (n (uvsize exp))
1451            (nb (subtag-bytes typecode n)))
1452       (declare (fixnum n nb typecode))
1453       (fasl-out-opcode $fasl-vivec exp)
1454       (fasl-out-byte typecode)
1455       (fasl-out-count n)
1456       (fasl-out-ivect exp 0 nb)))
1457    (gvector
1458     (if (= (typecode exp) target::subtag-istruct)
1459       (fasl-dump-gvector exp $fasl-istruct)
1460       (progn
1461         (unless (eq (backend-target-arch-name *target-backend*)
1462                     (backend-target-arch-name *host-backend*))
1463           (error "can't cross-compile constant reference to ~s" exp))
1464         (let* ((typecode (typecode exp))
1465                (n (uvsize exp)))
1466           (declare (fixnum n typecode))
1467           (fasl-out-opcode $fasl-vgvec exp)
1468           (fasl-out-byte typecode)
1469           (fasl-out-count n)
1470           (dotimes (i n)
1471             (fasl-dump-form (%svref exp i)))))))))
1472
1473(defun fasl-dump-gvector (v op)
1474  (let* ((n (uvsize v)))
1475    (fasl-out-opcode op v)
1476    (fasl-out-count n)
1477    (dotimes (i n)
1478      (fasl-dump-form (%svref v i)))))
1479
1480(defun fasl-dump-ratio (v)
1481  (fasl-out-opcode $fasl-ratio v)
1482  (fasl-dump-form (%svref v target::ratio.numer-cell))
1483  (fasl-dump-form (%svref v target::ratio.denom-cell)))
1484
1485(defun fasl-dump-complex (v)
1486  (fasl-out-opcode $fasl-complex v)
1487  (fasl-dump-form (%svref v target::complex.realpart-cell))
1488  (fasl-dump-form (%svref v target::complex.imagpart-cell)))
1489
1490(defun fasl-dump-bit-vector (v)
1491  (let* ((n (uvsize v)))
1492    (fasl-out-opcode $fasl-bit-vector v)
1493    (fasl-out-count n)
1494    (if (eq *fasl-host-big-endian* *fasl-target-big-endian*)
1495      (let* ((nb (ash (+ n 7) -3)))
1496        (fasl-out-ivect v 0 nb))
1497      (compiler-bug "need to byte-swap ~a" v))))
1498
1499(defun fasl-dump-8-bit-ivector (v op)
1500  (let* ((n (uvsize v)))
1501    (fasl-out-opcode op v)
1502    (fasl-out-count n)
1503    (let* ((nb n))
1504      (fasl-out-ivect v 0 nb))))
1505
1506(defun fasl-dump-16-bit-ivector (v op)
1507  (let* ((n (uvsize v)))
1508    (fasl-out-opcode op v)
1509    (fasl-out-count n)
1510    (if (eq *fasl-host-big-endian* *fasl-target-big-endian*)
1511      (let* ((nb (ash n 1)))
1512        (fasl-out-ivect v 0 nb))
1513      (dotimes (i n)
1514        (let* ((k (uvref v i)))
1515          (fasl-out-byte (ldb (byte 8 0) k))
1516          (fasl-out-byte (ldb (byte 8 8) k)))))))
1517
1518(defun fasl-dump-32-bit-ivector (v op)
1519  (let* ((n (uvsize v)))
1520    (fasl-out-opcode op v)
1521    (fasl-out-count n)
1522    (if (eq *fasl-host-big-endian* *fasl-target-big-endian*)
1523      (let* ((nb (ash n 2)))
1524        (fasl-out-ivect v 0 nb))
1525      (dotimes (i n)
1526        (let* ((k (uvref v i)))
1527          (fasl-out-byte (ldb (byte 8 0) k))
1528          (fasl-out-byte (ldb (byte 8 8) k))
1529          (fasl-out-byte (ldb (byte 8 16) k))
1530          (fasl-out-byte (ldb (byte 8 24) k)))))))
1531
1532
1533(defun fasl-dump-64-bit-ivector (v op)
1534  (let* ((n (uvsize v)))
1535    (fasl-out-opcode op v)
1536    (fasl-out-count n)
1537    (if (eq *fasl-host-big-endian* *fasl-target-big-endian*)
1538      (let* ((nb (ash n 3)))
1539        (fasl-out-ivect v 0 nb))
1540      (compiler-bug "need to byte-swap ~a" v))))
1541
1542(defun fasl-dump-double-float-vector (v)
1543  (let* ((n (uvsize v)))
1544    (fasl-out-opcode $fasl-double-float-vector v)
1545    (fasl-out-count n)
1546    (if (eq *fasl-host-big-endian* *fasl-target-big-endian*)
1547      (let* ((nb (ash n 3)))
1548        (fasl-out-ivect v (- target::misc-dfloat-offset
1549                             target::misc-data-offset) nb))
1550      (compiler-bug "need to byte-swap ~a" v))))
1551
1552;;; This is used to dump functions and "xfunctions".
1553;;; If we're cross-compiling, we shouldn't reference any
1554;;; (host) functions as constants; try to detect that
1555;;; case.
1556#-x86-target
1557(defun fasl-dump-function (f)
1558  (if (and (not (eq *fasl-backend* *host-backend*))
1559           (typep f 'function))
1560    (compiler-bug "Dumping a native function constant ~s during cross-compilation." f))
1561  (if (and (= (typecode f) target::subtag-xfunction)
1562           (= (typecode (uvref f 0)) target::subtag-u8-vector))
1563    (fasl-xdump-clfun f)
1564    (let* ((n (uvsize f)))
1565      (fasl-out-opcode $fasl-function f)
1566      (fasl-out-count n)
1567      (dotimes (i n)
1568        (fasl-dump-form (%svref f i))))))
1569
1570#+x86-target
1571(defun fasl-dump-function (f)
1572  (if (and (not (eq *fasl-backend* *host-backend*))
1573           (typep f 'function))
1574    (compiler-bug "Dumping a native function constant ~s during cross-compilation." f))
1575  (if (and (= (typecode f) target::subtag-xfunction)
1576           (= (typecode (uvref f 0)) target::subtag-u8-vector))
1577    (fasl-xdump-clfun f)
1578    (let* ((code-size (%function-code-words f))
1579           (function-vector (%function-to-function-vector f))
1580           (function-size (uvsize function-vector)))
1581      (fasl-out-opcode $fasl-clfun f)
1582      (fasl-out-count function-size)
1583      (fasl-out-count code-size)
1584      (fasl-out-ivect function-vector 0 (ash code-size 3))
1585      (do* ((k code-size (1+ k)))
1586           ((= k function-size))
1587        (declare (fixnum k))
1588        (fasl-dump-form (uvref function-vector k))))))
1589       
1590
1591 
1592
1593;;; Write a "concatenated function"; for now, assume that the target
1594;;; is x8664.
1595(defun fasl-xdump-clfun (f)
1596  (let* ((code (uvref f 0))
1597         (code-size (dpb (uvref code 3)
1598                         (byte 8 24)
1599                         (dpb (uvref code 2)
1600                              (byte 8 16)
1601                              (dpb (uvref code 1)
1602                                   (byte 8 8)
1603                                   (uvref code 0)))))
1604         (function-size (ash (uvsize code) -3)))
1605    (assert (= (- function-size code-size) (1- (uvsize f))))
1606    (fasl-out-opcode $fasl-clfun f)
1607    (fasl-out-count function-size)
1608    (fasl-out-count code-size)
1609    (fasl-out-ivect code 0 (ash code-size 3))
1610    (do* ((i 1 (1+ i))
1611          (n (uvsize f)))
1612         ((= i n))
1613      (declare (fixnum i n))
1614      (fasl-dump-form (%svref f i)))))
1615   
1616                         
1617
1618
1619
1620(defun fasl-dump-codevector (c)
1621  (if (and (not (eq *fasl-backend* *host-backend*))
1622           (typep c 'code-vector))
1623    (compiler-bug "Dumping a native code-vector constant ~s during cross-compilation." c))
1624  (let* ((n (uvsize c)))
1625    (fasl-out-opcode $fasl-code-vector c)
1626    (fasl-out-count n)
1627    (fasl-out-ivect c)))
1628
1629(defun fasl-dump-t_imm (imm)
1630  (fasl-out-opcode $fasl-timm imm)
1631  (fasl-out-long (%address-of imm)))
1632
1633(defun fasl-dump-char (char)     ; << maybe not
1634  (let ((code (%char-code char)))
1635    (fasl-out-opcode $fasl-char char)
1636    (fasl-out-count code)))
1637
1638;;; Always write big-endian.
1639(defun fasl-dump-s16 (s16)
1640  (fasl-out-opcode $fasl-word-fixnum s16)
1641  (fasl-out-word s16))
1642
1643;;; Always write big-endian
1644(defun fasl-dump-s32 (s32)
1645  (fasl-out-opcode $fasl-s32 s32)
1646  (fasl-out-word (ldb (byte 16 16) s32))
1647  (fasl-out-word (ldb (byte 16 0) s32)))
1648
1649;;; Always write big-endian
1650(defun fasl-dump-s64 (s64)
1651  (fasl-out-opcode $fasl-s64 s64)
1652  (fasl-out-word (ldb (byte 16 48) s64))
1653  (fasl-out-word (ldb (byte 16 32) s64))
1654  (fasl-out-word (ldb (byte 16 16) s64))
1655  (fasl-out-word (ldb (byte 16 0) s64)))
1656
1657
1658
1659(defun fasl-dump-dfloat (float)
1660  (fasl-out-opcode $fasl-dfloat float)
1661  (multiple-value-bind (high low) (double-float-bits float)
1662    (fasl-out-long high)
1663    (fasl-out-long low)))
1664
1665(defun fasl-dump-sfloat (float)
1666  (fasl-out-opcode $fasl-sfloat float)
1667  (fasl-out-long (single-float-bits float)))
1668
1669
1670(defun fasl-dump-package (pkg)
1671  (let ((name (package-name pkg)))
1672    (fasl-out-opcode $fasl-nvpkg pkg)
1673    (fasl-out-nvstring name)))
1674
1675
1676
1677(defun fasl-dump-list (list)
1678  (cond ((null list) (fasl-out-opcode $fasl-nil list))
1679        ((eq (%car list) cfasl-load-time-eval-sym)
1680         (let* ((form (car (%cdr list)))
1681                (opcode $fasl-eval))
1682           (when (funcall-lfun-p form)
1683             (setq opcode $fasl-lfuncall
1684                   form (%cadr form)))
1685           (if *fasdump-epush*
1686             (progn
1687               (fasl-out-byte (fasl-epush-op opcode))
1688               (fasl-dump-form form)
1689               (fasl-dump-epush list))
1690             (progn
1691               (fasl-out-byte opcode)
1692               (fasl-dump-form form)))))
1693        ((istruct-cell-p list)
1694         (fasl-out-opcode $fasl-istruct-cell (car list))
1695         (fasl-dump-symbol (car list)))
1696        (t (fasl-dump-cons list))))
1697
1698(defun fasl-dump-cons (cons &aux (end cons) (cdr-len 0))
1699  (declare (fixnum cdr-len))
1700  (while (and (consp (setq end (%cdr end)))
1701              (null (gethash end *fasdump-hash*)))
1702    (incf cdr-len))
1703  (if (eql 0 cdr-len)
1704    (fasl-out-opcode $fasl-cons cons)
1705    (progn
1706      (fasl-out-opcode (if end $fasl-vlist* $fasl-vlist) cons)
1707      (fasl-out-count cdr-len)))
1708  (dotimes (i (the fixnum (1+ cdr-len)))
1709    (fasl-dump-form (%car cons))
1710    (setq cons (%cdr cons)))
1711  (when (or (eql 0 cdr-len) end)      ;cons or list*
1712    (fasl-dump-form end)))
1713
1714
1715
1716(defun fasl-dump-symbol (sym)
1717  (let* ((pkg (symbol-package sym))
1718         (name (symbol-name sym))
1719         (idx (let* ((i (%svref (symptr->symvector (%symbol->symptr sym)) target::symbol.binding-index-cell)))
1720                (declare (fixnum i))
1721                (unless (zerop i) i))))
1722    (cond ((null pkg) 
1723           (progn 
1724             (fasl-out-opcode (if idx $fasl-nvmksym-special $fasl-nvmksym) sym)
1725             (fasl-out-nvstring name)))
1726          (*fasdump-epush*
1727           (progn
1728             (fasl-out-byte (fasl-epush-op (if idx
1729                                             $fasl-nvpkg-intern-special
1730                                             $fasl-nvpkg-intern)))
1731             (fasl-dump-form pkg)
1732             (fasl-dump-epush sym)
1733             (fasl-out-nvstring name)))
1734          (t
1735           (progn
1736             (fasl-out-byte (if idx
1737                              $fasl-nvpkg-intern-special
1738                              $fasl-nvpkg-intern))
1739             (fasl-dump-form pkg)
1740             (fasl-out-nvstring name))))))
1741
1742
1743(defun fasl-unknown (exp)
1744  (error "Can't dump ~S - unknown type" exp))
1745
1746(defun fasl-out-simple-string (str start end)
1747  (declare (simple-string str) (fixnum start end))
1748  (do* ((k start (1+ k)))
1749       ((= k end))
1750    (declare (fixnum k))
1751    (fasl-out-count (char-code (schar str k)))))
1752
1753(defun fasl-out-nvstring (str)
1754  (fasl-out-count (length str))
1755  (fasl-out-simple-string str 0 (length str)))
1756
1757(defun fasl-out-ivect (iv &optional 
1758                          (start 0) 
1759                          (nb 
1760                           (subtag-bytes (typecode iv) (uvsize iv))))
1761  (stream-write-ivector *fasdump-stream* iv start nb))
1762
1763
1764(defun fasl-out-long (long)
1765  (fasl-out-word (ash long -16))
1766  (fasl-out-word (logand long #xFFFF)))
1767
1768(defun fasl-out-word (word)
1769  (fasl-out-byte (ash word -8))
1770  (fasl-out-byte word))
1771
1772(defun fasl-out-byte (byte)
1773  (write-byte (%ilogand2 byte #xFF) *fasdump-stream*))
1774
1775;;; Write an unsigned integer in 7-bit chunks.
1776(defun fasl-out-count (val)
1777  (do* ((b (ldb (byte 7 0) val) (ldb (byte 7 0) val))
1778        (done nil))
1779       (done)
1780    (when (zerop (setq val (ash val -7)))
1781      (setq b (logior #x80 b) done t))
1782    (fasl-out-byte b)))
1783
1784(defun fasl-filepos ()
1785  (file-position *fasdump-stream*))
1786
1787(defun fasl-set-filepos (pos)
1788  (file-position *fasdump-stream* pos)
1789  #-bccl (unless (eq (file-position *fasdump-stream*) pos)
1790           (error "Unable to set file position to ~S" pos)))
1791
1792;;; Concatenate fasl files.
1793
1794;;; Format of a fasl file as expected by the fasloader.
1795;;;
1796;;; #xFF00         2 bytes - File version
1797;;; Block Count    2 bytes - Number of blocks in the file
1798;;; addr[0]        4 bytes - address of 0th block
1799;;; length[0]      4 bytes - length of 0th block
1800;;; addr[1]        4 bytes - address of 1st block
1801;;; length[1]      4 bytes - length of 1st block
1802;;; ...
1803;;; addr[n-1]      4 bytes
1804;;; length[n-1]    4 bytes
1805;;; length[0] + length[1] + ... + length [n-1] bytes of data
1806
1807;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1808;;
1809;; (fasl-concatenate out-file fasl-files &key :if-exists)
1810;;
1811;; out-file     name of file in which to store the concatenation
1812;; fasl-files   list of names of fasl files to concatenate
1813;; if-exists    as for OPEN, defaults to :error
1814;;
1815;; function result: pathname to the output file.
1816;; It works to use the output of one invocation of fasl-concatenate
1817;; as an input of another invocation.
1818;;
1819(defun fasl-concatenate (out-file fasl-files &key (if-exists :error))
1820  (%fasl-concatenate out-file fasl-files if-exists (pathname-type *.fasl-pathname*)))
1821
1822(defun %fasl-concatenate (out-file fasl-files if-exists file-ext)
1823  (let ((count 0)
1824        (created? nil)
1825        (finished? nil)
1826        (ext-pathname (make-pathname :type file-ext)))
1827    (declare (fixnum count))
1828    (flet ((fasl-read-halfword (f)
1829             (dpb (read-byte f) (byte 8 8) (read-byte f)))
1830           (fasl-write-halfword (h f)
1831             (write-byte (ldb (byte 8 8) h) f)
1832             (write-byte (ldb (byte 8 0) h) f)
1833             h))
1834      (flet ((fasl-read-fullword (f)
1835               (dpb (fasl-read-halfword f) (byte 16 16) (fasl-read-halfword f)))
1836             (fasl-write-fullword (w f)
1837               (fasl-write-halfword (ldb (byte 16 16) w) f)
1838               (fasl-write-halfword (ldb (byte 16 0) w) f)
1839               w))
1840        (dolist (file fasl-files)
1841          (setq file (merge-pathnames file ext-pathname))
1842          (unless (equal (pathname-type file) file-ext)
1843            (error "Not a ~A file: ~s" file-ext file))
1844          (with-open-file (instream file :element-type '(unsigned-byte 8))
1845            (unless (eql fasl-file-id (fasl-read-halfword instream))
1846              (error "Bad ~A file ID in ~s" file-ext file))
1847            (incf count (fasl-read-halfword instream))))
1848        (unwind-protect
1849             (with-open-file (outstream
1850                              (setq out-file (merge-pathnames out-file ext-pathname))
1851                              :element-type '(unsigned-byte 8)
1852                              :direction :output
1853                              :if-does-not-exist :create
1854                              :if-exists if-exists)
1855               (setq created? t)
1856               (let ((addr-address 4)
1857                     (data-address (+ 4 (* count 8))))
1858                 (fasl-write-halfword 0 outstream) ;  will be $fasl-id
1859                 (fasl-write-halfword count outstream)
1860                 (dotimes (i (* 2 count))
1861                   (fasl-write-fullword 0 outstream)) ; for addresses/lengths
1862                 (dolist (file fasl-files)
1863                   (with-open-file (instream (merge-pathnames file ext-pathname)
1864                                             :element-type '(unsigned-byte 8))
1865                     (fasl-read-halfword instream) ; skip ID
1866                     (let* ((fasl-count (fasl-read-halfword instream))
1867                            (addrs (make-array fasl-count))
1868                            (sizes (make-array fasl-count))
1869                            addr0)
1870                       (declare (fixnum fasl-count)
1871                                (dynamic-extent addrs sizes))
1872                       (dotimes (i fasl-count)
1873                         (setf (svref addrs i) (fasl-read-fullword instream)
1874                               (svref sizes i) (fasl-read-fullword instream)))
1875                       (setq addr0 (svref addrs 0))
1876                       (file-position outstream addr-address)
1877                       (dotimes (i fasl-count)
1878                         (fasl-write-fullword
1879                          (+ data-address (- (svref addrs i) addr0))
1880                          outstream)
1881                         (fasl-write-fullword (svref sizes i) outstream)
1882                         (incf addr-address 8))
1883                       (file-position outstream data-address)
1884                       (dotimes (i fasl-count)
1885                         (file-position instream (svref addrs i))
1886                         (let ((fasl-length (svref sizes i)))
1887                           (dotimes (j fasl-length)
1888                             (write-byte (read-byte instream) outstream))
1889                           (incf data-address fasl-length))))))
1890                 (stream-length outstream data-address)
1891                 (file-position outstream 0)
1892                 (fasl-write-halfword fasl-file-id outstream)
1893                 (setq finished? t)))
1894          (when (and created? (not finished?))
1895            (delete-file out-file))))
1896      out-file)))
1897
1898;;; Cross-compilation environment stuff.  Some of this involves
1899;;; setting up the TARGET and OS packages.
1900(defun ensure-package-nickname (name package)
1901  (let* ((old (find-package name)))
1902    (unless (eq old package)
1903      (rename-package old (package-name old) (delete name (package-nicknames old) :test #'string=))
1904      (rename-package package (package-name package) (cons name (package-nicknames package)))
1905      old)))
1906
1907(defmacro with-cross-compilation-package ((name target) &body body)
1908  (let* ((old-package (gensym))
1909         (name-var (gensym))
1910         (target-var (gensym)))
1911    `(let* ((,name-var ,name)
1912            (,target-var ,target)
1913            (,old-package (ensure-package-nickname ,name-var ,target-var)))
1914      (unwind-protect
1915           (progn ,@body)
1916        (when ,old-package (ensure-package-nickname ,name-var
1917                                                          ,old-package))))))
1918
1919(defun %with-cross-compilation-target (target thunk)
1920  (let* ((backend (find-backend target)))
1921    (if (null backend)
1922      (error "No known compilation target named ~s." target)
1923      (let* ((arch (backend-target-arch backend))
1924             (arch-package-name (arch::target-package-name arch))
1925             (ftd (backend-target-foreign-type-data backend))
1926             (ftd-package-name (ftd-interface-package-name ftd)))
1927        (or (find-package arch-package-name)
1928            (make-package arch-package-name))
1929        (or (find-package ftd-package-name)
1930            (make-package ftd-package-name :use "COMMON-LISP"))
1931        (with-cross-compilation-package ("OS" ftd-package-name)
1932          (with-cross-compilation-package ("TARGET" arch-package-name)
1933            (let* ((*target-ftd* ftd))
1934               (funcall thunk))))))))
1935
1936(defmacro with-cross-compilation-target ((target) &body body)
1937  `(%with-cross-compilation-target ,target #'(lambda () ,@body)))
1938             
1939
1940 
1941
1942(provide 'nfcomp)
1943
Note: See TracBrowser for help on using the repository browser.