source: branches/working-0711/ccl/lib/macros.lisp @ 11089

Last change on this file since 11089 was 11089, checked in by gz, 13 years ago

Merge/bootstrap assorted low level stuff from trunk - kernel, syscall stuff, lowmem-bias, formatting tweaks, a few bug fixes included

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 147.3 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17;;; Macros (and functions/constants used at macroexpand-time) ONLY.
18 
19(in-package "CCL")
20
21(eval-when (eval compile)
22  (require "LEVEL-2")
23  (require "BACKQUOTE")
24  (require "DEFSTRUCT-MACROS"))
25
26;; Constants
27
28(defmacro defconstant (sym val &optional (doc () doc-p) &environment env)
29  "Define a global constant, saying that the value is constant and may be
30  compiled into code. If the variable already has a value, and this is not
31  EQL to the new value, the code is not portable (undefined behavior). The
32  third argument is an optional documentation string for the variable."
33  (setq sym (require-type sym 'symbol)
34        doc (if doc-p (require-type doc 'string)))
35  `(progn
36     (eval-when (:compile-toplevel)
37       (define-compile-time-constant ',sym ',val ,env))
38     (eval-when (:load-toplevel :execute)
39       (%defconstant ',sym ,val ,@(if doc-p (list doc))))))
40
41;; Lists
42
43(defmacro %car (x)
44  `(car (the list ,x)))
45
46(defmacro set-%car (x y)
47  `(setf (car (the cons ,x)) ,y))
48
49(defmacro %cdr (x)
50  `(cdr (the list ,x)))
51
52(defmacro set-%cdr (x y)
53  `(setf (cdr (the cons ,x)) ,y))
54
55(defmacro %caar (x)
56 `(%car (%car ,x)))
57
58(defmacro %cadr (x)
59 `(%car (%cdr ,x)))
60
61(defmacro %cdar (x)
62 `(%cdr (%car ,x)))
63
64(defmacro %cddr (x)
65 `(%cdr (%cdr ,x)))
66
67(defmacro %caaar (x)
68 `(%car (%car (%car ,x))))
69
70(defmacro %caadr (x)
71 `(%car (%car (%cdr ,x))))
72
73(defmacro %cadar (x)
74 `(%car (%cdr (%car ,x))))
75
76(defmacro %caddr (x)
77 `(%car (%cdr (%cdr ,x))))
78
79(defmacro %cdaar (x)
80 `(%cdr (%car (%car ,x))))
81
82(defmacro %cdadr (x)
83 `(%cdr (%car (%cdr ,x))))
84
85(defmacro %cddar (x)
86 `(%cdr (%cdr (%car ,x))))
87
88(defmacro %cdddr (x)
89 `(%cdr (%cdr (%cdr ,x))))
90
91(defmacro %rplaca (x y)
92  `(rplaca (the cons ,x) ,y))
93
94(defmacro %rplacd (x y)
95  `(rplacd (the cons ,x) ,y))
96
97; These are open-coded by the compiler to isolate platform
98; dependencies.
99
100(defmacro %unbound-marker-8 ()
101  `(%unbound-marker))
102
103(defmacro %slot-missing-marker ()
104  `(%illegal-marker))
105
106
107
108
109(defmacro %null-ptr () '(%int-to-ptr 0))
110
111;;;Assorted useful macro definitions
112
113(defmacro def-accessors (ref &rest names)
114  (define-accessors ref names))
115
116(defmacro def-accessor-macros (ref &rest names)
117  (define-accessors ref names t))
118
119(defun define-accessors (ref names &optional no-constants
120                             &aux (arg (gensym)) (index 0) progn types)
121  (when (listp ref)
122    (setq types ref
123          ref (pop names)))
124  (dolist (name names)
125    (when name
126      (unless (listp name) (setq name (list name)))
127      (dolist (sym name)
128        (when sym
129          (push `(defmacro ,sym (,arg) (list ',ref ,arg ,index)) progn)
130          (unless no-constants
131            (push `(defconstant ,sym ,index) progn)))))
132    (setq index (1+ index)))
133 `(progn
134    ,.(nreverse progn)
135    ,@(if types `((add-accessor-types ',types ',names)))
136    ,index))
137
138(defmacro specialv (var)
139  `(locally (declare (special ,var)) ,var))
140
141
142(defmacro prog1 (valform &rest otherforms)
143 (let ((val (gensym)))
144 `(let ((,val ,valform))
145   ,@otherforms
146   ,val)))
147
148(defmacro prog2 (first second &rest others)
149 `(progn ,first (prog1 ,second ,@others)))
150
151(defmacro prog (inits &body body &environment env)
152  (multiple-value-bind (forms decls) (parse-body body env nil)
153    `(block nil
154       (let ,inits
155         ,@decls
156         (tagbody ,@forms)))))
157
158(defmacro prog* (inits &body body &environment env)
159  (multiple-value-bind (forms decls) (parse-body body env nil)
160    `(block nil
161       (let* ,inits
162         ,@decls
163         (tagbody ,@forms)))))
164
165
166(defmacro %stack-block ((&rest specs) &body forms &aux vars lets)
167  (dolist (spec specs)
168    (destructuring-bind (var ptr &key clear) spec
169      (push var vars)
170      (push `(,var (%new-ptr ,ptr ,clear)) lets)))
171  `(let* ,(nreverse lets)
172     (declare (dynamic-extent ,@vars))
173     (declare (type macptr ,@vars))
174     (declare (unsettable ,@vars))
175     ,@forms))
176
177(defmacro %vstack-block (spec &body forms)
178  `(%stack-block (,spec) ,@forms))
179
180(defmacro dolist ((varsym list &optional ret) &body body &environment env)
181  (if (not (symbolp varsym)) (signal-program-error $XNotSym varsym))
182  (let* ((toplab (gensym))
183         (tstlab (gensym))
184         (lstsym (gensym)))
185    (multiple-value-bind (forms decls) (parse-body body env nil)
186     `(block nil
187       (let* ((,lstsym ,list) ,varsym)
188        ,@decls
189          (tagbody
190            (go ,tstlab)
191            ,toplab
192            (setq ,lstsym (cdr (the list ,lstsym)))
193            ,@forms
194            ,tstlab
195            (setq ,varsym (car ,lstsym))
196            (if ,lstsym (go ,toplab)))
197          ,@(if ret `((progn  ,ret))))))))
198
199
200(defmacro dovector ((varsym vector &optional ret) &body body &environment env)
201  (if (not (symbolp varsym))(signal-program-error $XNotSym varsym))
202  (let* ((toplab (gensym))
203         (tstlab (gensym))
204         (lengthsym (gensym))
205         (indexsym (gensym))
206         (vecsym (gensym)))
207    (multiple-value-bind (forms decls) (parse-body body env nil)
208     `(let* ((,vecsym ,vector)
209             (,lengthsym (length ,vecsym))
210             (,indexsym 0)
211             ,varsym)
212        ,@decls
213        ,@(let ((type (nx-form-type vector env)))
214            (unless (eq type t)
215              `((declare (type ,type ,vecsym)))))
216        (block nil
217          (tagbody
218            (go ,tstlab)
219            ,toplab
220            (setq ,varsym (locally (declare (optimize (speed 3) (safety 0)))
221                            (aref ,vecsym ,indexsym))
222                  ,indexsym (%i+ ,indexsym 1))
223            ,@forms
224            ,tstlab
225            (if (%i< ,indexsym ,lengthsym) (go ,toplab)))
226          ,@(if ret `((progn (setq ,varsym nil) ,ret))))))))
227
228(defmacro report-bad-arg (&rest args)
229  `(values (%badarg ,@args)))
230
231(defmacro %cons-restart (name action report interactive test)
232 `(%istruct 'restart ,name ,action ,report ,interactive ,test))
233
234(defmacro restart-bind (clauses &body body)
235  "Executes forms in a dynamic context where the given restart bindings are
236   in effect. Users probably want to use RESTART-CASE. When clauses contain
237   the same restart name, FIND-RESTART will find the first such clause."
238  (let* ((restarts (mapcar #'(lambda (clause) 
239                               (list (make-symbol (symbol-name (require-type (car clause) 'symbol)))
240                                     `(%cons-restart nil nil nil nil nil)))
241                           clauses))
242         (bindings (mapcar #'(lambda (clause name)
243                              `(make-restart ,(car name) ',(car clause)
244                                             ,@(cdr clause)))
245                           clauses restarts))
246        (cluster (gensym)))
247    `(let* (,@restarts)
248       (declare (dynamic-extent ,@(mapcar #'car restarts)))
249       (let* ((,cluster (list ,@bindings))
250              (%restarts% (cons ,cluster %restarts%)))
251         (declare (dynamic-extent ,cluster %restarts%))
252         (progn
253           ,@body)))))
254
255(defmacro handler-bind (clauses &body body)
256  "(HANDLER-BIND ( {(type handler)}* )  body)
257   Executes body in a dynamic context where the given handler bindings are
258   in effect. Each handler must take the condition being signalled as an
259   argument. The bindings are searched first to last in the event of a
260   signalled condition."
261  (let* ((fns)
262         (decls)         
263         (bindings (mapcan #'(lambda (clause)
264                               (destructuring-bind (condition handler) clause
265                                 (if (and (consp handler)(eq (car handler) 'function)
266                                          (consp (cadr handler))(eq (car (cadr handler)) 'lambda))
267                                   (let ((fn (gensym)))
268                                     (push `(,fn ,handler) fns)
269                                     (push `(declare (dynamic-extent ,fn)) decls)
270                                     `(',condition ,fn))
271                                   (list `',condition
272                                         `,handler))))
273                           clauses))
274        (cluster (gensym)))   
275    (if (null bindings)
276      `(progn ,@body)
277      `(let* (,@fns
278              (,cluster (list ,@bindings))
279              (%handlers% (cons ,cluster %handlers%)))
280         (declare (dynamic-extent ,cluster %handlers%))
281         ,@decls
282         ,@body))))
283
284(defmacro restart-case (&environment env form &rest clauses)
285  "(RESTART-CASE form
286   {(case-name arg-list {keyword value}* body)}*)
287   The form is evaluated in a dynamic context where the clauses have special
288   meanings as points to which control may be transferred (see INVOKE-RESTART).
289   When clauses contain the same case-name, FIND-RESTART will find the first
290   such clause. If Expression is a call to SIGNAL, ERROR, CERROR or WARN (or
291   macroexpands into such) then the signalled condition will be associated with
292   the new restarts."
293  (let ((cluster nil))
294    (when clauses (setq cluster (gensym) form (restart-case-form form env cluster)))
295    (flet ((restart-case-1 (name arglist &rest forms)
296             (let (interactive report test)
297               (loop
298                 (case (car forms)
299                   (:interactive (setq interactive (cadr forms)))
300                   (:report (setq report (cadr forms)))
301                   (:test (setq test (cadr forms)))
302                   (t (return nil)))
303                 (setq forms (cddr forms)))
304               (when (and report (not (stringp report)))
305                 (setq report `#',report))
306               (when interactive
307                 (setq interactive `#',interactive))
308               (when test
309                 (setq test `#',test))
310               (values (require-type name 'symbol) arglist report interactive test forms))))
311      (cond ((null clauses) form)
312            ((and (null (cdr clauses)) (null (cadr (car clauses))))
313             (let ((block (gensym)) 
314                   (restart-name (gensym)))
315               (multiple-value-bind (name arglist report interactive test body)
316                                    (apply #'restart-case-1 (car clauses))
317                 (declare (ignore arglist))
318                 `(block ,block
319                    (let* ((,restart-name (%cons-restart ',name () ,report ,interactive ,test))
320                           (,cluster (list ,restart-name)))
321                      (declare (dynamic-extent ,restart-name ,cluster))
322                      (catch ,cluster
323                        (let ((%restarts% (cons ,cluster %restarts%)))
324                          (declare (dynamic-extent %restarts%))
325                          (return-from ,block ,form))))
326                    ,@body))))
327            (t
328             (let ((block (gensym)) (val (gensym))
329                   (index -1) restarts restart-names restart-name cases)
330               (while clauses
331                 (setq index (1+ index))
332                 (multiple-value-bind (name arglist report interactive test body)
333                                      (apply #'restart-case-1 (pop clauses))
334                   (push (setq restart-name (make-symbol (symbol-name name))) restart-names)
335                   (push (list restart-name `(%cons-restart ',name ,index ,report ,interactive ,test))
336                         restarts)
337                   (when (null clauses) (setq index t))
338                   (push `(,index (apply #'(lambda ,arglist ,@body) ,val))
339                         cases)))
340               `(block ,block
341                  (let ((,val (let* (,@restarts
342                                     (,cluster (list ,@(reverse restart-names))))
343                                (declare (dynamic-extent ,@restart-names ,cluster))
344                                (catch ,cluster
345                                  (let ((%restarts% (cons ,cluster %restarts%)))
346                                    (declare (dynamic-extent %restarts%))
347                                    (return-from ,block ,form))))))
348                    (case (pop ,val)
349                      ,@(nreverse cases))))))))))
350
351
352; Anything this hairy should die a slow and painful death.
353; Unless, of course, I grossly misunderstand...
354(defun restart-case-form (form env clustername)
355  (let ((expansion (macroexpand form env))
356        (head nil))
357    (if (and (listp expansion)          ; already an ugly hack, made uglier by %error case ...
358             (memq (setq head (pop expansion)) '(signal error cerror warn %error)))
359      (let ((condform nil)
360            (signalform nil)
361            (cname (gensym)))
362        (case head
363          (cerror
364           (destructuring-bind 
365             (continue cond &rest args) expansion
366             (setq condform `(condition-arg ,cond (list ,@args) 'simple-error)
367                   signalform `(cerror ,continue ,cname))))
368          ((signal error warn)
369           (destructuring-bind
370             (cond &rest args) expansion
371             (setq condform `(condition-arg ,cond (list ,@args) ,(if (eq head 'warning)
372                                                                   ''simple-warning
373                                                                   (if (eq head 'error)
374                                                                     ''simple-error
375                                                                     ''simple-condition)))
376                   signalform `(,head ,cname))))
377          (t ;%error
378           (destructuring-bind (cond args fp) expansion
379             (setq condform `(condition-arg ,cond ,args 'simple-error)
380                   signalform `(%error ,cname nil ,fp)))))
381        `(let ((,cname ,condform))
382           (with-condition-restarts ,cname ,clustername
383             ,signalform)))
384      form)))
385     
386
387(defmacro handler-case (form &rest clauses)
388  "(HANDLER-CASE form
389   { (type ([var]) body) }* )
390   Execute FORM in a context with handlers established for the condition
391   types. A peculiar property allows type to be :NO-ERROR. If such a clause
392   occurs, and form returns normally, all its values are passed to this clause
393   as if by MULTIPLE-VALUE-CALL.  The :NO-ERROR clause accepts more than one
394   var specification."
395  (let* ((no-error-clause (assoc :no-error clauses)))
396    (if no-error-clause
397      (let* ((normal-return (gensym))
398             (error-return (gensym)))
399        `(block ,error-return
400          (multiple-value-call #'(lambda ,@(cdr no-error-clause))
401            (block ,normal-return
402              (return-from ,error-return
403                (handler-case (return-from ,normal-return ,form)
404                  ,@(remove no-error-clause clauses)))))))
405      (flet ((handler-case (type var &rest body)
406               (when (eq type :no-error)
407                 (signal-program-error "Duplicate :no-error clause. "))
408           (values type var body)))
409        (cond ((null clauses) form)
410          ((null (cdr clauses))
411           (let ((block   (gensym))
412                 (cluster (gensym)))
413             (multiple-value-bind (type var body)
414                                  (apply #'handler-case (car clauses))
415               (if var
416                 `(block ,block
417                    ((lambda ,var ,@body)
418                      (let* ((,cluster (list ',type)))
419                        (declare (dynamic-extent ,cluster))
420                        (catch ,cluster
421                          (let ((%handlers% (cons ,cluster %handlers%)))
422                            (declare (dynamic-extent %handlers%))
423                            (return-from ,block ,form))))))
424                 `(block ,block
425                    (let* ((,cluster (list ',type)))
426                      (declare (dynamic-extent ,cluster))
427                      (catch ,cluster
428                        (let ((%handlers% (cons ,cluster %handlers%)))
429                          (declare (dynamic-extent %handlers%))
430                          (return-from ,block ,form)))
431                      (locally ,@body)))))))
432          (t (let ((block (gensym)) (cluster (gensym)) (val (gensym))
433                   (index -1) handlers cases)
434               (while clauses
435                 (setq index (1+ index))
436                 (multiple-value-bind (type var body)
437                                      (apply #'handler-case (pop clauses))                   
438                   (push `',type handlers)
439                   (push index handlers)
440                   (when (null clauses) (setq index t))
441                   (push (if var
442                           `(,index ((lambda ,var ,@body) ,val))
443                           `(,index (locally ,@body))) cases)))
444               `(block ,block
445                  (let ((,val (let* ((,cluster (list ,@(nreverse handlers))))
446                                (declare (dynamic-extent ,cluster))
447                                (catch ,cluster
448                                  (let ((%handlers% (cons ,cluster %handlers%)))
449                                    (declare (dynamic-extent %handlers%))
450                                    (return-from ,block ,form))))))
451                    (case (pop ,val)
452                      ,@(nreverse cases)))))))))))
453
454(defmacro with-simple-restart ((restart-name format-string &rest format-args)
455                               &body body
456                               &aux (cluster (gensym)) (temp (make-symbol (symbol-name restart-name))))
457  "(WITH-SIMPLE-RESTART (restart-name format-string format-arguments)
458   body)
459   If restart-name is not invoked, then all values returned by forms are
460   returned. If control is transferred to this restart, it immediately
461   returns the values NIL and T."
462  (unless (and (stringp format-string)
463               (null format-args)
464               (not (%str-member #\~ (ensure-simple-string format-string))))
465    (let ((stream (gensym)))
466      (setq format-string `#'(lambda (,stream) (format ,stream ,format-string ,@format-args)))))
467  `(let* ((,temp (%cons-restart ',restart-name
468                                'simple-restart
469                                ,format-string
470                                nil
471                                nil))
472          (,cluster (list ,temp)))
473     (declare (dynamic-extent ,temp ,cluster))
474     (catch ,cluster
475       (let ((%restarts% (cons ,cluster %restarts%)))
476         (declare (dynamic-extent %restarts%))
477         ,@body))))
478
479;Like with-simple-restart but takes a pre-consed restart.  Not CL.
480(defmacro with-restart (restart &body body &aux (cluster (gensym)))
481  `(let* ((,cluster (list ,restart)))
482     (declare (dynamic-extent ,cluster))
483     (catch ,cluster
484       (let ((%restarts% (cons ,cluster %restarts%)))
485         (declare (dynamic-extent %restarts%))
486         ,@body))))
487
488(defmacro ignore-errors (&rest forms)
489  "Execute FORMS handling ERROR conditions, returning the result of the last
490  form, or (VALUES NIL the-ERROR-that-was-caught) if an ERROR was handled."
491  `(handler-case (progn ,@forms)
492     (error (condition) (values nil condition))))
493
494(defmacro def-kernel-restart (&environment env errno name arglist &body body)
495  (multiple-value-bind (body decls)
496                       (parse-body body env)
497    `(let* ((fn (nfunction ,name (lambda ,arglist ,@decls (block ,name ,@body))))
498            (pair (assq ,errno ccl::*kernel-restarts*)))
499       (if pair
500         (rplacd pair fn)
501         (push (cons ,errno fn) ccl::*kernel-restarts*))
502       fn)))
503
504
505;;; Setf.
506
507;  If you change anything here, be sure to make the corresponding change
508;  in get-setf-method.
509(defmacro setf (&rest args &environment env)
510  "Takes pairs of arguments like SETQ. The first is a place and the second
511  is the value that is supposed to go into that place. Returns the last
512  value. The place argument may be any of the access forms for which SETF
513  knows a corresponding setting form."
514  (let ((temp (length args))
515        (accessor nil))
516    (cond ((eq temp 2)
517           (let* ((form (car args)) 
518                  (value (cadr args)))
519             ;This must match get-setf-method .
520             (if (atom form)
521               (progn
522                 (unless (symbolp form)(signal-program-error $XNotSym form))
523                 `(setq ,form ,value))
524               (multiple-value-bind (ftype local-p)
525                                    (function-information (setq accessor (car form)) ENV)
526                 (if local-p
527                   (if (eq ftype :function)
528                     ;Local function, so don't use global setf definitions.
529                     (default-setf form value env)
530                     `(setf ,(macroexpand-1 form env) ,value))
531                   (cond
532                    ((setq temp (%setf-method accessor))
533                     (if (symbolp temp)
534                       `(,temp ,@(cdar args) ,value)
535                       (multiple-value-bind (dummies vals storevars setter #|getter|#)
536                                            (funcall temp form env)
537                         (do* ((d dummies (cdr d))
538                               (v vals (cdr v))
539                               (let-list nil))
540                              ((null d)
541                               (setq let-list (nreverse let-list))
542                               `(let* ,let-list
543                                  (declare (ignorable ,@dummies))
544                                  (multiple-value-bind ,storevars ,value
545                                    #|,getter|#
546                                    ,setter)))
547                           (push (list (car d) (car v)) let-list)))))
548                    ((and (type-and-refinfo-p (setq temp (or (environment-structref-info accessor env)
549                                                             (and #-bccl (boundp '%structure-refs%)
550                                                                  (gethash accessor %structure-refs%)))))
551                          (not (refinfo-r/o (if (consp temp) (%cdr temp) temp))))
552                     (if (consp temp)
553                       ;; strip off type, but add in a require-type
554                       (let ((type (%car temp)))
555                         `(the ,type (setf ,(defstruct-ref-transform (%cdr temp) (%cdar args))
556                                           (require-type ,value ',type))))
557                       `(setf ,(defstruct-ref-transform temp (%cdar args))
558                              ,value)))
559                    (t
560                     (multiple-value-bind (res win)
561                                          (macroexpand-1 form env)
562                       (if win
563                         `(setf ,res ,value)
564                         (default-setf form value env))))))))))
565          ((oddp temp)
566           (signal-program-error "Odd number of args to SETF : ~s." args))
567          (t (do* ((a args (cddr a)) (l nil))
568                  ((null a) `(progn ,@(nreverse l)))
569               (push `(setf ,(car a) ,(cadr a)) l))))))
570
571
572(defun default-setf (setter value &optional env)
573  (let* ((reader (car setter))
574         (args (cdr setter))
575         (gensyms (mapcar #'(lambda (sym) (declare (ignore sym)) (gensym)) args))
576         types declares)
577    (flet ((form-type (form)
578             (nx-form-type form env)))
579      (declare (dynamic-extent #'form-type))
580      (setq types (mapcar #'form-type args)))
581    (dolist (sym gensyms)
582      (let ((sym-type (pop types)))
583        (unless (eq sym-type t)
584          (push `(type ,sym-type ,sym) declares))))
585    `(let ,(mapcar #'list gensyms args)
586       ,@(and declares (list `(declare ,@(nreverse declares))))
587       (funcall #'(setf ,reader) ,value ,@gensyms))))
588
589;; Establishing these setf-inverses is something that should
590;; happen at compile-time
591(defsetf elt set-elt)
592(defsetf car set-car)
593(defsetf %car set-%car)
594(defsetf first set-car)
595(defsetf cdr set-cdr)
596(defsetf %cdr set-%cdr)
597(defsetf rest set-cdr)
598(defsetf uvref uvset)
599(defsetf aref aset)
600(defsetf svref svset)
601(defsetf %svref %svset)
602(defsetf char set-char)
603(defsetf schar set-schar)
604(defsetf %scharcode %set-scharcode)
605(defsetf symbol-value set)
606(defsetf symbol-plist set-symbol-plist)
607(defsetf fill-pointer set-fill-pointer)
608
609; This sux; it calls the compiler twice (once to shove the macro in the
610; environment, once to dump it into the file.)
611(defmacro defmacro  (name arglist &body body &environment env)
612  (unless (symbolp name)(signal-program-error $XNotSym name))
613  (unless (listp arglist) (signal-program-error "~S is not a list." arglist))
614  (multiple-value-bind (lambda-form doc)
615                       (parse-macro-1 name arglist body env)
616    (let* ((normalized (normalize-lambda-list arglist t t))
617           (body-pos (position '&body normalized))
618           (argstring (let ((temp nil))
619                        (dolist (arg normalized)
620                          (if (eq arg '&aux)
621                            (return)
622                            (push arg temp)))
623                        (format nil "~:a" (nreverse temp)))))
624      (if (and body-pos (memq '&optional normalized)) (decf body-pos))
625      `(progn
626         (eval-when (:compile-toplevel)
627           (define-compile-time-macro ',name ',lambda-form ',env))
628         (eval-when (:load-toplevel :execute)
629           (%macro 
630            (nfunction ,name ,lambda-form)
631            '(,doc ,body-pos . ,argstring))
632           ',name)))))
633
634(defmacro define-symbol-macro (name expansion &environment env)
635  (unless (symbolp name)(signal-program-error $XNotSym name))
636  `(progn
637    (eval-when (:compile-toplevel)
638      (define-compile-time-symbol-macro ',name ',expansion ',env))
639    (eval-when (:load-toplevel :execute)
640      (%define-symbol-macro ',name ',expansion))))
641
642;; ---- allow inlining setf functions
643(defmacro defun (spec args &body body &environment env &aux global-name inline-spec)
644  "Define a function at top level."
645  (validate-function-name spec)
646  (setq args (require-type args 'list))
647  (setq body (require-type body 'list))
648  (multiple-value-bind (forms decls doc) (parse-body body env t)
649    (cond ((symbolp spec)
650           (setq global-name spec)
651           (setq inline-spec spec)
652           (setq body `(block ,spec ,@forms)))
653          ((and (consp spec) (eq 'setf (%car spec)))
654           (setq inline-spec spec)
655           (setq body `(block ,(cadr spec) ,@forms)))
656          (t (setq body `(progn ,@forms))))
657    (let* ((lambda-expression `(lambda ,args 
658                                ,@(if global-name
659                                    `((declare (global-function-name ,global-name))))
660                                ,@decls ,body))
661           (info (if (and inline-spec
662                          (or (null env)
663                              (definition-environment env t))
664                          (nx-declared-inline-p inline-spec env)
665                          (not (and (symbolp inline-spec)
666                                    (gethash inline-spec *NX1-ALPHATIZERS*))))
667                   (cons doc lambda-expression)
668                   doc)))
669      `(progn
670         (%defun (nfunction ,spec ,lambda-expression) ',info)
671         ',spec))))
672
673(defmacro %defvar-init (var initform doc)
674  `(unless (%defvar ',var ,doc)
675    (set ',var ,initform)))
676
677(defmacro defvar (&environment env var &optional (value () value-p) doc)
678  "Define a global variable at top level. Declare the variable
679  SPECIAL and, optionally, initialize it. If the variable already has a
680  value, the old value is not clobbered. The third argument is an optional
681  documentation string for the variable."
682  (if (and doc (not (stringp doc))) (report-bad-arg doc 'string))
683  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
684    (setq doc nil))
685 `(progn
686    (eval-when (:compile-toplevel)
687      (note-variable-info ',var ,value-p ,env))
688    ,(if value-p
689       `(%defvar-init ,var ,value ,doc)
690       `(%defvar ',var))
691    ',var))
692         
693(defmacro def-standard-initial-binding (name &optional (form name) (doc nil doc-p) &environment env)
694  `(progn
695    (eval-when (:compile-toplevel)
696      (note-variable-info ',name t ,env))   
697    (define-standard-initial-binding ',name #'(lambda () ,form))
698    ,@(when doc-p
699           `((set-documentation ',name 'variable ,doc)))
700    ',name))
701
702(defmacro defparameter (&environment env var value &optional doc)
703  "Define a parameter that is not normally changed by the program,
704  but that may be changed without causing an error. Declare the
705  variable special and sets its value to VAL, overwriting any
706  previous value. The third argument is an optional documentation
707  string for the parameter."
708  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
709  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
710    (setq doc nil))
711  `(progn
712     (eval-when (:compile-toplevel)
713       (note-variable-info ',var t ,env))
714     (%defparameter ',var ,value ,doc)))
715
716
717(defmacro defstatic (&environment env var value &optional doc)
718  "Syntax is like DEFPARAMETER.  Proclaims the symbol to be special,
719but also asserts that it will never be given a per-thread dynamic
720binding.  The value of the variable can be changed (via SETQ, etc.),
721but since all threads access the same static binding of the variable,
722such changes should be made with care."
723  (if (and doc (not (stringp doc))) (signal-program-error "~S is not a string." doc))
724  (if (and (compile-file-environment-p env) (not *fasl-save-doc-strings*))
725    (setq doc nil))
726  `(progn
727     (eval-when (:compile-toplevel)
728       (note-variable-info ',var :global ,env))
729     (%defglobal ',var ,value ,doc)))
730
731
732(defmacro defglobal (&rest args)
733  "Synonym for DEFSTATIC."
734  `(defstatic ,@args))
735
736
737(defmacro defloadvar (&environment env var value &optional doc)
738  `(progn
739     (defstatic ,var ,nil ,@(if doc `(,doc)))
740     (def-ccl-pointers ,var ()
741       (setq ,var ,value))
742     ',var))
743
744
745
746
747(defmacro qlfun (name args &body body)
748  `(nfunction ,name (lambda ,args ,@body)))
749
750(defmacro lfun-bits-known-function (f)
751  (let* ((temp (gensym)))
752    `(let* ((,temp (function-to-function-vector ,f)))
753      (%svref ,temp (the fixnum (1- (the fixnum (uvsize ,temp))))))))
754
755(defmacro lfunloop (for var in function &body loop-body)
756  "Loop over immediates in function"
757  (assert (and (or (equal (symbol-name for) "FOR") (equal (symbol-name for) "AS"))
758               (equal (symbol-name in) "IN")))
759  (let ((fn (gensym))
760        (lfv (gensym))
761        (i (gensym)))
762    `(loop with ,fn = ,function
763           with ,lfv = (function-to-function-vector ,fn)
764           for ,i from #+ppc-target 1 #+x86-target (%function-code-words ,fn) below (%i- (uvsize  ,lfv) 1)
765           as ,var = (%svref ,lfv ,i)
766           ,@loop-body)))
767
768(defmacro cond (&rest args &aux clause)
769  (when args
770     (setq clause (car args))
771     (if (cdr clause)         
772         `(if ,(car clause) (progn ,@(cdr clause)) (cond ,@(cdr args)))
773       (if (cdr args) `(or ,(car clause) (cond ,@(cdr args)))
774                      `(values ,(car clause))))))
775
776(defmacro and (&rest args)
777  "And Form*
778AND evaluates each form in sequence, from left to right.  If any form
779returns NIL, AND returns NIL; otherwise, AND returns the values(s) returned
780by the last form.  If there are no forms, AND returns T."
781  (if (null args) t
782    (if (null (cdr args)) (car args)
783      `(if ,(car args) (and ,@(cdr args))))))
784
785(defmacro or (&rest args)
786  "Or Form*
787OR evaluates each Form, in sequence, from left to right.
788If any Form but the last returns a non-NIL value, OR returns that
789single value (without evaluating any subsequent Forms.)  If OR evaluates
790the last Form, it returns all values returned by that Form.  If there
791are no Forms, OR returns NIL."
792  (if args
793    (if (cdr args)
794      (do* ((temp (gensym))
795            (handle (list nil))
796            (forms `(let ((,temp ,(pop args)))
797                     (if ,temp ,temp ,@handle))))
798           ((null (cdr args))
799            (%rplaca handle (%car args))
800            forms)
801        (%rplaca handle `(if (setq ,temp ,(%car args)) 
802                          ,temp 
803                          ,@(setq handle (list nil))))
804        (setq args (%cdr args)))
805      (%car args))))
806
807(defmacro case (key &body forms)
808  "CASE Keyform {({(Key*) | Key} Form*)}*
809  Evaluates the Forms in the first clause with a Key EQL to the value of
810  Keyform. If a singleton key is T then the clause is a default clause."
811   (let ((key-var (gensym)))
812     `(let ((,key-var ,key))
813        (declare (ignorable ,key-var))
814        (cond ,@(case-aux forms key-var nil nil)))))
815
816(defmacro ccase (keyplace &body forms)
817  "CCASE Keyform {({(Key*) | Key} Form*)}*
818  Evaluates the Forms in the first clause with a Key EQL to the value of
819  Keyform. If none of the keys matches then a correctable error is
820  signalled."
821  (let* ((key-var (gensym))
822         (tag (gensym)))
823    `(prog (,key-var)
824       ,tag
825       (setq ,key-var ,keyplace)
826       (return (cond ,@(case-aux forms key-var tag keyplace))))))
827
828(defmacro ecase (key &body forms)
829  "ECASE Keyform {({(Key*) | Key} Form*)}*
830  Evaluates the Forms in the first clause with a Key EQL to the value of
831  Keyform. If none of the keys matches then an error is signalled."
832  (let* ((key-var (gensym)))
833    `(let ((,key-var ,key))
834       (declare (ignorable ,key-var))
835       (cond ,@(case-aux forms key-var 'ecase nil)))))
836       
837(defun case-aux (clauses key-var e-c-p placename &optional (used-keys (list (list '%case-core))))
838  (if clauses
839    (let* ((key-list (caar clauses))
840           (stype (if e-c-p (if (eq e-c-p 'ecase) e-c-p 'ccase) 'case))
841           (test (cond ((and (not e-c-p)
842                             (or (eq key-list 't)
843                                 (eq key-list 'otherwise)))
844                        t)
845                       (key-list
846                        (cons 'or
847                              (case-key-testers key-var used-keys key-list stype)))))
848           (consequent-list (or (%cdar clauses) '(nil))))
849      (if (eq test t)
850        (progn
851          (when (%cdr clauses) (warn "~s or ~s clause in the middle of a ~s statement.  Subsequent clauses ignored."
852                                     't 'otherwise 'case))
853          (cons (cons t consequent-list) nil))
854        (cons (cons test consequent-list)
855              (case-aux (%cdr clauses) key-var e-c-p placename used-keys))))
856    (when e-c-p
857      (setq used-keys `(member ,@(mapcar #'car (cdr used-keys))))
858      (if (eq e-c-p 'ecase)
859        `((t (values (%err-disp #.$XWRONGTYPE ,key-var ',used-keys))))
860        `((t (setf ,placename (ensure-value-of-type ,key-var ',used-keys ',placename))
861           (go ,e-c-p)))))))
862
863
864;;; We don't want to descend list structure more than once (like this has
865;;; been doing for the last 18 years or so.)
866(defun case-key-testers (symbol used-keys atom-or-list statement-type &optional recursive)
867  (if (or recursive (atom atom-or-list))
868    (progn
869      (if (assoc atom-or-list used-keys)
870        (warn "Duplicate keyform ~s in ~s statement." atom-or-list statement-type)
871        (setq used-keys (nconc used-keys (list (cons atom-or-list t)))))
872      `((,(if (typep atom-or-list '(and number (not fixnum)))
873              'eql
874              'eq)
875         ,symbol ',atom-or-list)))
876    (nconc (case-key-testers symbol used-keys (car atom-or-list) statement-type t)
877           (when (cdr atom-or-list)
878             (case-key-testers symbol used-keys (%cdr atom-or-list) statement-type nil)))))
879
880
881; generate the COND body of a {C,E}TYPECASE form
882(defun typecase-aux (key-var clauses &optional e-c-p keyform)
883  (let* ((construct (if e-c-p (if (eq e-c-p 'etypecase) e-c-p 'ctypecase) 'typecase))
884         (types ())
885         (body ())
886         otherwise-seen-p)
887    (flet ((bad-clause (c) 
888             (signal-program-error "Invalid clause ~S in ~S form." c construct)))
889      (dolist (clause clauses)
890        (if (atom clause)
891            (bad-clause clause))
892        (if otherwise-seen-p
893            (signal-program-error "OTHERWISE must be final clause in ~S form." construct))
894        (destructuring-bind (typespec &body consequents) clause
895          (when (eq construct 'typecase)
896            (if (eq typespec 'otherwise)
897                (progn (setq typespec t)
898                       (setq otherwise-seen-p t))))
899          (unless
900              (dolist (already types nil)
901                (when (subtypep typespec already)
902                  (warn "Clause ~S ignored in ~S form - shadowed by ~S ." clause construct (assq already clauses))
903                  (return t)))
904            (push typespec types)
905            (setq typespec `(typep ,key-var ',typespec))
906            (push `(,typespec nil ,@consequents) body))))
907      (when e-c-p
908        (setq types `(or ,@(nreverse types)))
909        (if (eq construct 'etypecase)
910            (push `(t (values (%err-disp #.$XWRONGTYPE ,key-var ',types))) body)
911            (push `(t (setf ,keyform (ensure-value-of-type  ,key-var ',types ',keyform))
912                      (go ,e-c-p)) body))))
913    `(cond ,@(nreverse body))))
914
915(defmacro typecase (keyform &body clauses)
916  "TYPECASE Keyform {(Type Form*)}*
917  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
918  is true."
919  (let ((key-var (gensym)))
920    `(let ((,key-var ,keyform))
921       (declare (ignorable ,key-var))
922       ,(typecase-aux key-var clauses))))
923
924(defmacro etypecase (keyform &body clauses)
925  "ETYPECASE Keyform {(Type Form*)}*
926  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
927  is true. If no form is satisfied then an error is signalled."
928  (let ((key-var (gensym)))
929    `(let ((,key-var ,keyform))
930       (declare (ignorable ,key-var))
931       ,(typecase-aux key-var clauses 'etypecase))))
932
933(defmacro ctypecase (keyplace &body clauses)
934  "CTYPECASE Key {(Type Form*)}*
935  Evaluates the Forms in the first clause for which TYPEP of Keyform and Type
936  is true. If no form is satisfied then a correctable error is signalled."
937  (let ((key-var (gensym))
938        (tag (gensym)))
939    `(prog (,key-var)
940       ,tag
941       (setq ,key-var ,keyplace)
942       (return ,(typecase-aux key-var clauses tag keyplace)))))
943
944(defmacro destructuring-bind (lambda-list expression &body body)
945  "Bind the variables in LAMBDA-LIST to the contents of ARG-LIST."
946  (multiple-value-bind (bindings decls)
947      (%destructure-lambda-list  lambda-list expression nil nil)
948    `(let* ,(nreverse bindings)
949      ,@(when decls `((declare ,@decls)))
950      ,@body)))
951
952(defmacro make-destructure-state (tail whole lambda)
953  `(%istruct 'destructure-state ,tail ,whole ,lambda))
954
955
956; This is supposedly ANSI CL.
957(defmacro lambda (&whole lambda-expression (&rest paramlist) &body body)
958  (unless (lambda-expression-p lambda-expression)
959    (warn "Invalid lambda expression: ~s" lambda-expression))
960  `(function (lambda ,paramlist ,@body)))
961
962; This isn't
963(defmacro nlambda (name (&rest arglist) &body body)
964  `(nfunction ,name (lambda ,arglist ,@body)))
965
966(defmacro when (test &body body)
967  "If the first argument is true, the rest of the forms are
968  evaluated as a PROGN."
969 `(if ,test
970   (progn ,@body)))
971
972(defmacro unless (test &body body)
973  "If the first argument is not true, the rest of the forms are
974  evaluated as a PROGN."
975 `(if (not ,test)
976   (progn ,@body)))
977
978(defmacro return (&optional (form nil form-p))
979  `(return-from nil ,@(if form-p `(,form))))
980
981; since they use tagbody, while & until BOTH return NIL
982(defmacro while (test &body body)
983  (let ((testlab (gensym))
984        (toplab (gensym)))
985    `(tagbody
986       (go ,testlab)
987      ,toplab
988      (progn ,@body)
989      ,testlab
990      (when ,test (go ,toplab)))))
991
992(defmacro until (test &body body)
993  (let ((testlab (gensym))
994        (toplab (gensym)))
995    `(tagbody
996       (go ,testlab)
997      ,toplab
998      (progn ,@body)
999      ,testlab
1000      (if (not ,test)
1001        (go ,toplab)))))
1002
1003(defmacro psetq (&whole call &body pairs &environment env)
1004  "PSETQ {var value}*
1005   Set the variables to the values, like SETQ, except that assignments
1006   happen in parallel, i.e. no assignments take place until all the
1007   forms have been evaluated."
1008  (when pairs
1009   (if (evenp (length pairs))
1010     (do* ((l pairs (%cddr l))
1011           (sym (%car l) (%car l)))
1012          ((null l) (%pset pairs))
1013       (unless (symbolp sym) (report-bad-arg sym 'symbol))
1014       (when (nth-value 1 (macroexpand-1 sym env))
1015         (return `(psetf ,@pairs))))
1016     (signal-program-error "Uneven number of args in the call ~S" call))))
1017
1018; generates body for psetq.
1019; "pairs" is a proper list whose length is not odd.
1020(defun %pset (pairs)
1021 (when pairs
1022   (let (vars vals gensyms let-list var val sets)
1023      (loop
1024        (setq var (pop pairs)
1025              val (pop pairs))
1026        (if (null pairs) (return))
1027        (push var vars)
1028        (push val vals)
1029        (push (gensym) gensyms))
1030      (dolist (g gensyms)
1031        (push g sets)
1032        (push (pop vars) sets)
1033        (push (list g (pop vals)) let-list))
1034      (push val sets)
1035      (push var sets)
1036      `(progn
1037         (let ,let-list
1038           (setq ,@sets))
1039         nil))))
1040
1041
1042(eval-when (:compile-toplevel :load-toplevel :execute)
1043(defun do-loop (binder setter env var-init-steps end-test result body)
1044  (let ((toptag (gensym))
1045        (testtag (gensym)))
1046    (multiple-value-bind (forms decls) (parse-body body env nil)
1047      `(block nil
1048         (,binder ,(do-let-vars var-init-steps)
1049                  ,@decls
1050                  (tagbody ; crocks-r-us.
1051                    (go ,testtag)
1052                    ,toptag
1053                    (tagbody
1054                      ,@forms)
1055                    (,setter ,@(do-step-vars var-init-steps))
1056                    ,testtag
1057                    (unless ,end-test
1058                      (go ,toptag)))
1059                  ,@result)))))
1060)
1061
1062(defmacro do (&environment env var-init-steps (&optional end-test &rest result) &body body)
1063  "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1064  Iteration construct. Each Var is initialized in parallel to the value of the
1065  specified Init form. On subsequent iterations, the Vars are assigned the
1066  value of the Step form (if any) in parallel. The Test is evaluated before
1067  each evaluation of the body Forms. When the Test is true, the Exit-Forms
1068  are evaluated as a PROGN, with the result being the value of the DO. A block
1069  named NIL is established around the entire expansion, allowing RETURN to be
1070  used as an alternate exit mechanism."
1071  (do-loop 'let 'psetq env var-init-steps end-test result body))
1072
1073(defmacro do* (&environment env var-init-steps (&optional end-test &rest result) &body body)
1074  "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
1075  Iteration construct. Each Var is initialized sequentially (like LET*) to the
1076  value of the specified Init form. On subsequent iterations, the Vars are
1077  sequentially assigned the value of the Step form (if any). The Test is
1078  evaluated before each evaluation of the body Forms. When the Test is true,
1079  the Exit-Forms are evaluated as a PROGN, with the result being the value
1080  of the DO. A block named NIL is established around the entire expansion,
1081  allowing RETURN to be used as an laternate exit mechanism."
1082  (do-loop 'let* 'setq env var-init-steps end-test result body))
1083
1084
1085(defun do-let-vars (var-init-steps)
1086  (if var-init-steps
1087      (cons (list (do-let-vars-var (car var-init-steps))
1088                  (do-let-vars-init (car var-init-steps)))
1089             (do-let-vars (cdr var-init-steps)))))
1090
1091(defun do-let-vars-var (var-init-step)
1092  (if (consp var-init-step)
1093       (car var-init-step)
1094       var-init-step))
1095
1096(defun do-let-vars-init (var-init-step)
1097   (if (consp var-init-step)
1098        (cadr var-init-step)
1099        nil))
1100
1101(defun do-step-vars (var-init-steps)
1102    (if var-init-steps
1103        (if (do-step-vars-step? (car var-init-steps))
1104             (append (list (do-let-vars-var (car var-init-steps))
1105                           (do-step-vars-step (car var-init-steps)))
1106                     (do-step-vars (cdr var-init-steps)))
1107             (do-step-vars (cdr var-init-steps)))))
1108
1109(defun do-step-vars-step? (var-init-step)
1110  (if (consp var-init-step)
1111       (cddr var-init-step)))
1112
1113(defun do-step-vars-step (var-init-step)
1114  (if (consp var-init-step)
1115       (caddr var-init-step)))
1116
1117
1118(defmacro dotimes ((i n &optional result) &body body &environment env)
1119  (multiple-value-bind (forms decls)
1120                       (parse-body body env)
1121    (if (not (symbolp i))(signal-program-error $Xnotsym i))
1122    (let* ((toptag (gensym))
1123           (limit (gensym)))
1124      `(block nil
1125        (let ((,limit ,n) (,i 0))
1126         ,@decls
1127         (declare (unsettable ,i))
1128           (if (int>0-p ,limit)
1129             (tagbody
1130               ,toptag
1131               ,@forms
1132               (locally
1133                (declare (settable ,i))
1134                (setq ,i (1+ ,i)))
1135               (unless (eql ,i ,limit) (go ,toptag))))
1136           ,result)))))
1137 
1138(defun do-syms-result (var resultform)
1139  (unless (eq var resultform)
1140    (if (and (consp resultform) (not (quoted-form-p resultform)))
1141      `(progn (setq ,var nil) ,resultform)
1142      resultform)))
1143
1144(defun expand-package-iteration-macro (iteration-function var pkg-spec resultform body env)
1145  (multiple-value-bind (body decls) (parse-body body env nil)
1146    (let* ((ftemp (gensym))
1147           (vtemp (gensym))
1148           (ptemp (gensym))
1149           (result (do-syms-result var resultform)))
1150      `(block nil
1151        (let* ((,var nil)
1152               (,ptemp ,pkg-spec))
1153          ,@decls
1154           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1155             (declare (dynamic-extent #',ftemp))
1156             (,iteration-function ,ptemp #',ftemp))
1157           ,@(when result `(,result)))))))
1158
1159(defmacro do-symbols ((var &optional pkg result) &body body &environment env)
1160  "DO-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECLARATION}* {TAG | FORM}*
1161   Executes the FORMs at least once for each symbol accessible in the given
1162   PACKAGE with VAR bound to the current symbol."
1163  (expand-package-iteration-macro 'iterate-over-accessable-symbols var pkg result body env))
1164
1165(defmacro do-present-symbols ((var &optional pkg result) &body body &environment env)
1166  (expand-package-iteration-macro 'iterate-over-present-symbols var pkg result body env))
1167
1168(defmacro do-external-symbols ((var &optional pkg result) &body body &environment env)
1169  "DO-EXTERNAL-SYMBOLS (VAR [PACKAGE [RESULT-FORM]]) {DECL}* {TAG | FORM}*
1170   Executes the FORMs once for each external symbol in the given PACKAGE with
1171   VAR bound to the current symbol."
1172  (expand-package-iteration-macro 'iterate-over-external-symbols var pkg result body env))
1173
1174(defmacro do-all-symbols ((var &optional resultform)
1175                          &body body &environment env)
1176  "DO-ALL-SYMBOLS (VAR [RESULT-FORM]) {DECLARATION}* {TAG | FORM}*
1177   Executes the FORMs once for each symbol in every package with VAR bound
1178   to the current symbol."
1179  (multiple-value-bind (body decls) (parse-body body env nil)
1180    (let* ((ftemp (gensym))
1181           (vtemp (gensym))
1182           (result (do-syms-result var resultform)))
1183      `(block nil
1184        (let* ((,var nil))
1185         ,@decls
1186           (flet ((,ftemp (,vtemp) (declare (debugging-function-name nil)) (setq ,var ,vtemp) (tagbody ,@body)))
1187             (declare (dynamic-extent #',ftemp))
1188             (iterate-over-all-symbols #',ftemp))
1189           ,@(when result `(,result)))))))
1190
1191(defmacro multiple-value-list (form)
1192  `(multiple-value-call #'list ,form))
1193
1194
1195
1196
1197(defmacro %i> (x y)
1198  `(> (the fixnum ,x) (the fixnum ,y)))
1199
1200(defmacro %i< (x y)
1201  `(< (the fixnum ,x) (the fixnum ,y)))
1202
1203(defmacro %i<= (x y)
1204 `(not (%i> ,x ,y)))
1205
1206(defmacro %i>= (x y)
1207 `(not (%i< ,x ,y)))
1208
1209(defmacro bitset (bit number)
1210  `(logior (ash 1 ,bit) ,number))
1211
1212(defmacro bitclr (bit number)
1213  `(logand (lognot (ash 1 ,bit)) ,number))
1214
1215(defmacro bitopf ((op bit place) &environment env)
1216  (multiple-value-bind (vars vals stores store-form access-form)
1217                       (get-setf-method place env)
1218    (let* ((constant-bit-p (constantp bit))
1219           (bitvar (if constant-bit-p bit (gensym))))
1220      `(let ,(unless constant-bit-p `((,bitvar ,bit)))          ; compiler isn't smart enough
1221         (let* ,(mapcar #'list `(,@vars ,@stores) `(,@vals (,op ,bitvar ,access-form)))
1222           ,store-form)))))
1223
1224(defmacro bitsetf (bit place)
1225  `(bitopf (bitset ,bit ,place)))
1226
1227(defmacro bitclrf (bit place)
1228  `(bitopf (bitclr ,bit ,place)))
1229
1230(defmacro %svref (v i)
1231  (let* ((vtemp (make-symbol "VECTOR"))
1232           (itemp (make-symbol "INDEX")))
1233      `(let* ((,vtemp ,v)
1234              (,itemp ,i))
1235         (locally (declare (optimize (speed 3) (safety 0)))
1236           (svref ,vtemp ,itemp)))))
1237
1238(defmacro %svset (v i new &environment env)
1239  (let* ((vtemp (make-symbol "VECTOR"))
1240         (itemp (make-symbol "INDEX"))
1241         (ntemp (make-symbol "NEW")))
1242    `(let* ((,vtemp ,v)
1243            (,itemp ,i)
1244            (,ntemp ,new))
1245      (locally (declare (optimize (speed 3) (safety 0)))
1246        (setf (svref ,vtemp ,itemp) ,ntemp)))))
1247
1248
1249(defmacro %schar (v i)
1250  (let* ((vtemp (make-symbol "STRING"))
1251         (itemp (make-symbol "INDEX")))
1252    `(let* ((,vtemp ,v)
1253            (,itemp ,i))
1254       (locally (declare (optimize (speed 3) (safety 0)))
1255         (schar ,vtemp ,itemp)))))
1256
1257(defmacro %set-schar (v i new)
1258  (let* ((vtemp (make-symbol "STRING"))
1259         (itemp (make-symbol "INDEX"))
1260         (ntemp (make-symbol "NEW")))
1261      `(let* ((,vtemp ,v)
1262              (,itemp ,i)
1263              (,ntemp ,new))
1264         (locally (declare (optimize (speed 3) (safety 0)))
1265           (setf (schar ,vtemp ,itemp) ,ntemp)))))
1266
1267
1268
1269(defmacro %char-code (c) `(char-code (the character ,c)))
1270(defmacro %code-char (i) `(code-char (the (mod 256) ,i)))
1271
1272(defmacro %izerop (x) `(eq ,x 0))
1273(defmacro %iminusp (x) `(< (the fixnum ,x) 0))
1274(defmacro %i+ (&rest (&optional (n0 0) &rest others))
1275  (if others
1276    `(the fixnum (+ (the fixnum ,n0) (%i+ ,@others)))
1277    `(the fixnum ,n0)))
1278(defmacro %i- (x y &rest others) 
1279  (if (not others)
1280    `(the fixnum (- (the fixnum ,x) (the fixnum ,y)))
1281    `(the fixnum (- (the fixnum ,x) (the fixnum (%i+ ,y ,@others))))))
1282
1283
1284(defmacro %i* (x y) `(the fixnum (* (the fixnum ,x) (the fixnum ,y))))
1285
1286(defmacro %ilogbitp (b i)
1287  (target-word-size-case
1288   (32
1289    `(logbitp (the (integer 0 29) ,b) (the fixnum ,i)))
1290   (64
1291    `(logbitp (the (integer 0 60) ,b) (the fixnum ,i)))))
1292
1293;;; Seq-Dispatch does an efficient type-dispatch on the given Sequence.
1294
1295(defmacro seq-dispatch (sequence list-form array-form)
1296  `(if (sequence-type ,sequence)
1297       ,list-form
1298       ,array-form))
1299
1300
1301(defsetf %get-byte %set-byte)
1302(defsetf %get-unsigned-byte %set-unsigned-byte)
1303(defsetf %get-signed-byte %set-byte)
1304(defsetf %get-word %set-word)
1305(defsetf %get-signed-word %set-word)
1306(defsetf %get-unsigned-word %set-unsigned-word)
1307(defsetf %get-long %set-long)
1308(defsetf %get-signed-long %set-long)
1309(defsetf %get-unsigned-long %set-unsigned-long)
1310(defsetf %get-full-long %set-long)
1311(defsetf %get-point %set-long)
1312(defsetf %get-ptr %set-ptr)
1313(defsetf %get-double-float %set-double-float)
1314(defsetf %get-single-float %set-single-float)
1315(defsetf %get-bit %set-bit)
1316(defsetf %get-unsigned-long-long %set-unsigned-long-long)
1317(defsetf %%get-unsigned-longlong %%set-unsigned-longlong)
1318(defsetf %get-signed-long-long %set-signed-long-long)
1319(defsetf %%get-signed-longlong %%set-signed-longlong)
1320(defsetf %get-bitfield %set-bitfield)
1321
1322(defmacro %ilognot (int) `(%i- -1 ,int))
1323
1324(defmacro %ilogior2 (x y) 
1325  `(logior (the fixnum ,x) (the fixnum ,y)))
1326
1327(defmacro %ilogior (body &body args)
1328   (while args
1329     (setq body (list '%ilogior2 body (pop args))))
1330   body)
1331
1332(defmacro %ilogand2 (x y)
1333  `(logand (the fixnum ,x) (the fixnum ,y)))
1334
1335(defmacro %ilogand (body &body args)
1336   (while args
1337     (setq body (list '%ilogand2 body (pop args))))
1338   body)
1339
1340(defmacro %ilogxor2 (x y)
1341  `(logxor (the fixnum ,x) (the fixnum ,y)))
1342
1343(defmacro %ilogxor (body &body args)
1344   (while args
1345     (setq body (list '%ilogxor2 body (pop args))))
1346   body)
1347
1348(defmacro with-macptrs (varlist &rest body &environment env)
1349  (multiple-value-bind (body other-decls) (parse-body body env)
1350    (collect ((temp-bindings)
1351              (temp-decls)
1352              (bindings)
1353              (our-decls)
1354              (inits))
1355      (dolist (var varlist)
1356        (let* ((temp (gensym)))
1357          (temp-decls temp)
1358        (if (consp var)
1359          (progn
1360            (our-decls (car var))
1361            (temp-bindings `(,temp (%null-ptr)))
1362            (bindings `(,(car var) ,temp))
1363            (if (cdr var)
1364              (inits `(%setf-macptr ,temp ,@(cdr var)))))
1365          (progn
1366            (our-decls var)
1367            (temp-bindings  `(,temp  (%null-ptr)))
1368            (bindings `(,var ,temp))))))
1369  `(let* ,(temp-bindings)
1370    (declare (dynamic-extent ,@(temp-decls)))
1371    (declare (type macptr ,@(temp-decls)))
1372    ,@(inits)
1373    (let* ,(bindings)
1374      (declare (type macptr ,@(our-decls)))
1375      ,@other-decls
1376      ,@body)))))
1377
1378
1379(defmacro with-loading-file (filename &rest body)
1380   `(let ((*loading-files* (cons ,filename (locally (declare (special *loading-files*))
1381                                                    *loading-files*))))
1382      (declare (special *loading-files*))
1383      ,@body))
1384
1385(defmacro with-input-from-string ((var string &key index start end) &body forms &environment env)
1386  "Create an input string stream, provide an opportunity to perform
1387operations on the stream (returning zero or more values), and then close
1388the string stream.
1389
1390STRING is evaluated first, and VAR is bound to a character input string
1391stream that supplies characters from the subsequence of the resulting
1392string bounded by start and end. BODY is executed as an implicit progn."
1393  (multiple-value-bind (forms decls) (parse-body forms env nil)
1394    `(let ((,var
1395            ,(cond ((null end)
1396                    `(make-string-input-stream ,string ,(or start 0)))
1397                   ((symbolp end)
1398                    `(if ,end
1399                      (make-string-input-stream ,string ,(or start 0) ,end)
1400                      (make-string-input-stream ,string ,(or start 0))))
1401                   (t
1402                    `(make-string-input-stream ,string ,(or start 0) ,end)))))
1403      ,@decls
1404      (unwind-protect
1405           (multiple-value-prog1
1406               (progn ,@forms)
1407             ,@(if index `((setf ,index (string-input-stream-index ,var)))))
1408        (close ,var)))))
1409
1410(defmacro with-output-to-string ((var &optional string &key (element-type 'base-char element-type-p))
1411                                 &body body 
1412                                 &environment env)
1413  "Create a character output stream, perform a series of operations that
1414may send results to this stream, and then close the stream.  BODY is
1415executed as an implicit progn with VAR bound to an output string stream.
1416All output to that string stream is saved in a string."
1417  (let ((string-var (gensym "string")))
1418    (multiple-value-bind (forms decls) (parse-body body env nil)
1419      `(let* ((,string-var ,string)
1420              (,var (if ,string-var
1421                      ,@(if element-type-p
1422                            `((progn
1423                                ,element-type
1424                                (%make-string-output-stream ,string-var)))
1425                            `((%make-string-output-stream ,string-var)))
1426                      ,@(if element-type-p
1427                            `((make-string-output-stream :element-type ,element-type))
1428                            `((make-string-output-stream))))))
1429         ,@decls
1430         (unwind-protect
1431              (progn
1432                ,@forms
1433                ,@(if string () `((get-output-stream-string ,var))))
1434           (close ,var))))))
1435
1436(defmacro with-output-to-truncating-string-stream ((var len) &body body
1437                                                   &environment env)
1438  (multiple-value-bind (forms decls) (parse-body body env nil)
1439    `(let* ((,var (make-truncating-string-stream ,len)))
1440      ,@decls
1441      (unwind-protect
1442           (progn
1443             ,@forms
1444             (values (get-output-stream-string ,var)
1445                     (slot-value ,var 'truncated)))
1446        (close ,var)))))
1447
1448(defmacro with-open-file ((var . args) &body body &aux (stream (gensym))(done (gensym)))
1449  "Use open to create a file stream to file named by filespec. Filespec is
1450the name of the file to be opened. Options are used as keyword arguments
1451to open."
1452  `(let (,stream ,done)
1453     (unwind-protect
1454       (multiple-value-prog1
1455         (let ((,var (setq ,stream (open ,@args))))
1456           ,@body)
1457         (setq ,done t))
1458       (when ,stream (close ,stream :abort (null ,done))))))
1459
1460(defmacro with-compilation-unit ((&key override) &body body)
1461  "WITH-COMPILATION-UNIT ({Key Value}*) Form*
1462  This form affects compilations that take place within its dynamic extent. It
1463  is intended to be wrapped around the compilation of all files in the same
1464  system. These keywords are defined:
1465    :OVERRIDE Boolean-Form
1466        One of the effects of this form is to delay undefined warnings
1467        until the end of the form, instead of giving them at the end of each
1468        compilation. If OVERRIDE is NIL (the default), then the outermost
1469        WITH-COMPILATION-UNIT form grabs the undefined warnings. Specifying
1470        OVERRIDE true causes that form to grab any enclosed warnings, even if
1471        it is enclosed by another WITH-COMPILATION-UNIT."
1472  `(flet ((with-compilation-unit-body ()
1473            ,@body))
1474     (declare (dynamic-extent #'with-compilation-unit-body))
1475     (call-with-compilation-unit #'with-compilation-unit-body :override ,override)))
1476
1477; Yow! Another Done Fun.
1478(defmacro with-standard-io-syntax (&body body &environment env)
1479  "Bind the reader and printer control variables to values that enable READ
1480   to reliably read the results of PRINT. These values are:
1481       *PACKAGE*                        the COMMON-LISP-USER package
1482       *PRINT-ARRAY*                    T
1483       *PRINT-BASE*                     10
1484       *PRINT-CASE*                     :UPCASE
1485       *PRINT-CIRCLE*                   NIL
1486       *PRINT-ESCAPE*                   T
1487       *PRINT-GENSYM*                   T
1488       *PRINT-LENGTH*                   NIL
1489       *PRINT-LEVEL*                    NIL
1490       *PRINT-LINES*                    NIL
1491       *PRINT-MISER-WIDTH*              NIL
1492       *PRINT-PRETTY*                   NIL
1493       *PRINT-RADIX*                    NIL
1494       *PRINT-READABLY*                 T
1495       *PRINT-RIGHT-MARGIN*             NIL
1496       *READ-BASE*                      10
1497       *READ-DEFAULT-FLOAT-FORMAT*      SINGLE-FLOAT
1498       *READ-EVAL*                      T
1499       *READ-SUPPRESS*                  NIL
1500       *READTABLE*                      the standard readtable"
1501  (multiple-value-bind (decls body) (parse-body body env)
1502    `(let ((*package* (pkg-arg "COMMON-LISP-USER"))
1503           (*print-array* t)
1504           (*print-base* 10.)
1505           (*print-case* :upcase)
1506           (*print-circle* nil)
1507           (*print-escape* t)
1508           (*print-gensym* t)
1509           (*print-length* nil)
1510           (*print-level* nil)
1511           (*print-lines* nil) ; This doesn't exist as of 5/15/90 - does now
1512           (*print-miser-width* nil)
1513           (*print-pprint-dispatch* nil)
1514           (*print-pretty* nil)
1515           (*print-radix* nil)
1516           (*print-readably* t)
1517           (*print-right-margin* nil)
1518           (*read-base* 10.)
1519           (*read-default-float-format* 'single-float)
1520           (*read-eval* t) ; Also MIA as of 5/15/90
1521           (*read-suppress* nil)
1522           (*readtable* %initial-readtable%))
1523       ,@decls
1524       ,@body)))
1525
1526(defmacro with-self-bound-io-control-vars (&body body)
1527  `(let (
1528         (*print-array* *print-array*)
1529         (*print-base* *print-base*)
1530         (*print-case* *print-case*)
1531         (*print-circle* *print-circle*)
1532         (*print-escape* *print-escape*)
1533         (*print-gensym* *print-gensym*)
1534         (*print-length* *print-length*)
1535         (*print-level* *print-level*)
1536         (*print-lines* *print-lines*)
1537         (*print-miser-width* *print-miser-width*)
1538         (*print-pprint-dispatch* *print-pprint-dispatch*)
1539         (*print-pretty* *print-pretty*)
1540         (*print-radix* *print-radix*)
1541         (*print-readably* *print-readably*)
1542         (*print-right-margin* *print-right-margin*)
1543         (*read-base* *read-base*)
1544         (*read-default-float-format* *read-default-float-format*)
1545         (*read-eval* *read-eval*)
1546         (*read-suppress* *read-suppress*)
1547         (*readtable* *readtable*))
1548     ,@body))
1549
1550(defmacro print-unreadable-object (&environment env (object stream &key type identity) &body forms)
1551  "Output OBJECT to STREAM with \"#<\" prefix, \">\" suffix, optionally
1552  with object-type prefix and object-identity suffix, and executing the
1553  code in BODY to provide possible further output."
1554  (multiple-value-bind (body decls) (parse-body forms env)
1555    (if body
1556      (let ((thunk (gensym)))
1557        `(let ((,thunk #'(lambda () ,@decls ,@body)))
1558           (declare (dynamic-extent ,thunk))
1559          (%print-unreadable-object ,object ,stream ,type ,identity ,thunk)))
1560      `(%print-unreadable-object ,object ,stream ,type ,identity nil))))
1561;; Pointers and Handles
1562
1563;;Add function to lisp system pointer functions, and run it if it's not already
1564;; there.
1565(defmacro def-ccl-pointers (name arglist &body body &aux (old (gensym)))
1566  `(flet ((,name ,arglist ,@body))
1567     (let ((,old (member ',name *lisp-system-pointer-functions* :key #'function-name)))
1568       (if ,old
1569         (rplaca ,old #',name)
1570         (progn
1571           (push #',name *lisp-system-pointer-functions*)
1572           (,name))))))
1573
1574(defmacro def-load-pointers (name arglist &body body &aux (old (gensym)))
1575  `(flet ((,name ,arglist ,@body))
1576     (let ((,old (member ',name *lisp-user-pointer-functions* :key #'function-name)))
1577       (if ,old
1578         (rplaca ,old #',name)
1579         (progn
1580           (push #',name *lisp-user-pointer-functions*)
1581           (,name))))))
1582
1583;Queue up some code to run after ccl all loaded up, or, if ccl is already
1584;loaded up, just run it right now.
1585(defmacro queue-fixup (&rest body &aux (fn (gensym)))
1586  `(let ((,fn #'(lambda () ,@body)))
1587     (if (eq %lisp-system-fixups% T)
1588       (funcall ,fn)
1589       (push (cons ,fn *loading-file-source-file*) %lisp-system-fixups%))))
1590
1591(defmacro %incf-ptr (p &optional (by 1))
1592  (if (symbolp p)  ;once-only
1593    `(%setf-macptr (the macptr ,p) (%inc-ptr ,p ,by))
1594    (let ((var (gensym)))
1595      `(let ((,var ,p)) (%setf-macptr (the macptr ,var) (%inc-ptr ,var ,by))))))
1596
1597(defmacro with-string-from-cstring ((s ptr) &body body)
1598  (let* ((len (gensym))
1599         (p (gensym)))
1600    `(let* ((,p ,ptr)
1601            (,len (%cstrlen ,p))
1602            (,s (make-string ,len)))
1603      (declare (fixnum ,len))
1604      (%copy-ptr-to-ivector ,p 0 ,s 0 ,len)
1605      (locally
1606          ,@body))))
1607
1608
1609(defmacro with-cstr ((sym str &optional start end) &rest body &environment env)
1610  (multiple-value-bind (body decls) (parse-body body env nil)
1611    (if (and (base-string-p str) (null start) (null end))
1612      (let ((strlen (%i+ (length str) 1)))
1613        `(%stack-block ((,sym ,strlen))
1614           ,@decls
1615           (%cstr-pointer ,str ,sym)
1616           ,@body))
1617      (let ((strname (gensym))
1618            (start-name (gensym))
1619            (end-name (gensym)))
1620        `(let ((,strname ,str)
1621               ,@(if (or start end)
1622                   `((,start-name ,(or start 0))
1623                     (,end-name ,(or end `(length ,strname))))))
1624           (%vstack-block (,sym
1625                           (the fixnum
1626                             (1+
1627                              (the fixnum
1628                                ,(if (or start end)
1629                                     `(byte-length
1630                                       ,strname ,start-name ,end-name)
1631                                     `(length ,strname))))))
1632             ,@decls
1633             ,(if (or start end)
1634                `(%cstr-segment-pointer ,strname ,sym ,start-name ,end-name)
1635                `(%cstr-pointer ,strname ,sym))
1636             ,@body))))))
1637
1638(defmacro with-utf-8-cstr ((sym str) &body body)
1639  (let* ((data (gensym))
1640         (offset (gensym))
1641         (string (gensym))
1642         (len (gensym))
1643         (noctets (gensym))
1644         (end (gensym)))
1645    `(let* ((,string ,str)
1646            (,len (length ,string)))
1647      (multiple-value-bind (,data ,offset) (array-data-and-offset ,string)
1648        (let* ((,end (+ ,offset ,len))
1649               (,noctets (utf-8-octets-in-string ,data ,offset ,end)))
1650          (%stack-block ((,sym (1+ ,noctets)))
1651            (utf-8-memory-encode ,data ,sym 0 ,offset ,end)
1652            (setf (%get-unsigned-byte ,sym ,noctets) 0)
1653            ,@body))))))
1654
1655
1656
1657(defmacro with-native-utf-16-cstr ((sym str) &body body)
1658  (let* ((data (gensym))
1659         (offset (gensym))
1660         (string (gensym))
1661         (len (gensym))
1662         (noctets (gensym))
1663         (end (gensym)))
1664    `(let* ((,string ,str)
1665            (,len (length ,string)))
1666      (multiple-value-bind (,data ,offset) (array-data-and-offset ,string)
1667        (let* ((,end (+ ,offset ,len))
1668               (,noctets (utf-16-octets-in-string ,data ,offset ,end)))
1669          (%stack-block ((,sym (1+ ,noctets)))
1670            (native-utf-16-memory-encode ,data ,sym 0 ,offset ,end)
1671            (setf (%get-unsigned-word ,sym ,noctets) 0)
1672            ,@body))))))
1673
1674(defmacro with-pointers (speclist &body body)
1675   (with-specs-aux 'with-pointer speclist body))
1676
1677
1678
1679(defmacro with-cstrs (speclist &body body)
1680   (with-specs-aux 'with-cstr speclist body))
1681
1682(defmacro with-utf-8-cstrs (speclist &body body)
1683   (with-specs-aux 'with-utf-8-cstr speclist body))
1684
1685(defmacro with-native-utf-16-cstrs (speclist &body body)
1686  (with-specs-aux 'with-native-utf-16-cstr speclist body))
1687
1688(defmacro with-encoded-cstr ((encoding-name (sym string &optional start end))
1689                             &rest body &environment env)
1690  (let* ((encoding (gensym))
1691         (str (gensym)))
1692      (multiple-value-bind (body decls) (parse-body body env nil)
1693        `(let* ((,str ,string)
1694                (,encoding (get-character-encoding ,encoding-name)))
1695          (%stack-block ((,sym (cstring-encoded-length-in-bytes ,encoding ,str ,start ,end) :clear t))
1696            ,@decls
1697            (encode-string-to-memory ,encoding ,sym 0 ,str ,start ,end)
1698            ,@body)))))
1699
1700(defmacro with-encoded-cstrs (encoding-name bindings &body body)
1701  (with-specs-aux 'with-encoded-cstr (mapcar #'(lambda (b)
1702                                                 `(,encoding-name ,b))
1703                                             bindings) body))
1704
1705(defmacro with-filename-cstrs (&rest rest)
1706  `(,(case (target-os-name)
1707      (:darwin 'with-utf-8-cstrs)
1708      (:windows 'with-native-utf-16-cstrs)
1709      (t 'with-cstrs)) ,@rest))
1710
1711
1712(defun with-specs-aux (name spec-list original-body)
1713  (multiple-value-bind (body decls) (parse-body original-body nil)
1714    (when decls (signal-program-error "declarations not allowed in ~s" original-body))
1715    (setq body (cons 'progn body))
1716    (dolist (spec (reverse spec-list))
1717      (setq body (list name spec body)))
1718    body))
1719
1720
1721(defmacro type-predicate (type)
1722  `(get-type-predicate ,type))
1723
1724(defsetf type-predicate set-type-predicate)
1725
1726(defun adjust-defmethod-lambda-list (ll)
1727  ;; If the lambda list contains &key, ensure that it also contains
1728  ;; &allow-other-keys
1729  (if (or (not (memq '&key ll))
1730          (memq '&allow-other-keys ll))
1731    ll
1732    (if (memq '&aux ll)
1733      (let* ((ll (copy-list ll))
1734             (aux (memq '&aux ll)))
1735        (setf (car aux) '&allow-other-keys
1736              (cdr aux) (cons '&aux (cdr aux)))
1737        ll)
1738      (append ll '(&allow-other-keys)))))
1739
1740(defun encode-gf-lambda-list (lambda-list)
1741  (let* ((bits (encode-lambda-list lambda-list)))
1742    (declare (fixnum bits))
1743    (if (logbitp $lfbits-keys-bit bits)
1744      (logior bits (ash 1 $lfbits-aok-bit))
1745      bits)))
1746
1747(defmacro defmethod (name &rest args &environment env)
1748  (multiple-value-bind (function-form specializers-form qualifiers lambda-list documentation specializers)
1749      (parse-defmethod name args env)
1750    `(progn
1751       (eval-when (:compile-toplevel)
1752         (record-function-info ',(maybe-setf-function-name name)
1753                               ',(%cons-def-info 'defmethod (encode-gf-lambda-list lambda-list) nil nil
1754                                                 specializers qualifiers)
1755                               ,env))
1756       (compiler-let ((*nx-method-warning-name* '(,name ,@qualifiers ,specializers)))
1757         (ensure-method ',name ,specializers-form
1758                        :function ,function-form
1759                        :qualifiers ',qualifiers
1760                        :lambda-list ',lambda-list
1761                        ,@(if documentation `(:documentation ,documentation)))))))
1762
1763
1764(defun seperate-defmethod-decls (decls)
1765  (let (outer inner)
1766    (dolist (decl decls)
1767      (if (neq (car decl) 'declare)
1768        (push decl outer)
1769        (let (outer-list inner-list)
1770          (dolist (d (cdr decl))
1771            (if (and (listp d) (eq (car d) 'dynamic-extent))
1772              (let (in out)
1773                (dolist (fspec (cdr d))
1774                  (if (and (listp fspec)
1775                           (eq (car fspec) 'function)
1776                           (listp (cdr fspec))
1777                           (null (cddr fspec))
1778                           (memq (cadr fspec) '(call-next-method next-method-p)))
1779                    (push fspec in)
1780                    (push fspec out)))
1781                (when out
1782                  (push `(dynamic-extent ,@(nreverse out)) outer-list))
1783                (when in
1784                  (push `(dynamic-extent ,@(nreverse in)) inner-list)))
1785              (push d outer-list)))
1786          (when outer-list
1787            (push `(declare ,@(nreverse outer-list)) outer))
1788          (when inner-list
1789            (push `(declare ,@(nreverse inner-list)) inner)))))
1790    (values (nreverse outer) (nreverse inner))))
1791                   
1792
1793(defun parse-defmethod (name args env)
1794  (validate-function-name name)
1795  (let (qualifiers lambda-list parameters specializers specializers-form refs types temp)
1796    (until (listp (car args))
1797      (push (pop args) qualifiers))
1798    (setq lambda-list (pop args))
1799    (while (and lambda-list (not (memq (car lambda-list) lambda-list-keywords)))
1800      (let ((p (pop lambda-list)))
1801        (cond ((consp p)
1802               (unless (and (consp (%cdr p)) (null (%cddr p)))
1803                 (signal-program-error "Illegal arg ~S" p))
1804               (push (%car p) parameters)
1805               (push (%car p) refs)
1806               (setq p (%cadr p))
1807               (cond ((and (consp p) (eq (%car p) 'eql)
1808                           (consp (%cdr p)) (null (%cddr p)))
1809                      (push `(list 'eql ,(%cadr p)) specializers-form)
1810                      (push p specializers))
1811                     ((or (setq temp (non-nil-symbol-p p))
1812                          (specializer-p p))
1813                      (push `',p specializers-form)
1814                      (push p specializers)
1815                      (unless (or (eq p t) (not temp))
1816                        ;Should be `(guaranteed-type ...).
1817                        (push `(type ,p ,(%car parameters)) types)))
1818                     (t (signal-program-error "Illegal arg ~S" p))))
1819              (t
1820               (push p parameters)
1821               #+ccl-0711 (push p refs)
1822               (push t specializers-form)
1823               (push t specializers)))))
1824    (setq lambda-list (nreconc parameters lambda-list))
1825    (multiple-value-bind (body decls doc) (parse-body args env t)
1826      (multiple-value-bind (outer-decls inner-decls) 
1827                           (seperate-defmethod-decls decls)
1828        (let* ((methvar (make-symbol "NEXT-METHOD-CONTEXT"))
1829               (cnm-args (gensym))
1830               (lambda-form `(lambda ,(list* '&method methvar lambda-list)
1831                               (declare ;,@types
1832                                (ignorable ,@refs))
1833                               ,@outer-decls
1834                               (block ,(if (consp name) (cadr name) name)
1835                                 (flet ((call-next-method (&rest ,cnm-args)
1836                                          (declare (dynamic-extent ,cnm-args))
1837                                          (if ,cnm-args
1838                                            (apply #'%call-next-method-with-args ,methvar ,cnm-args)
1839                                            (%call-next-method ,methvar)))
1840                                        (next-method-p () (%next-method-p ,methvar)))
1841                                   (declare (inline call-next-method next-method-p))
1842                                   ,@inner-decls
1843                                   ,@body)))))
1844          (values
1845           (if name `(nfunction ,name ,lambda-form) `(function ,lambda-form))
1846           `(list ,@(nreverse specializers-form))
1847           (nreverse qualifiers)
1848           lambda-list
1849           doc
1850           (nreverse specializers)))))))
1851
1852(defmacro anonymous-method (name &rest args &environment env)
1853  (multiple-value-bind (function-form specializers-form qualifiers method-class documentation)
1854                       (parse-defmethod name args env)
1855   
1856    `(%anonymous-method
1857      ,function-form
1858      ,specializers-form
1859      ',qualifiers
1860      ,@(if (or method-class documentation) `(',method-class))
1861      ,@(if documentation `(,documentation)))))
1862
1863
1864
1865(defmacro defclass (class-name superclasses slots &rest class-options &environment env)
1866  (flet ((duplicate-options (where) (signal-program-error "Duplicate options in ~S" where))
1867         (illegal-option (option) (signal-program-error "Illegal option ~s" option))
1868         (make-initfunction (form)
1869           (cond ((or (eq form 't)
1870                      (equal form ''t))
1871                  '(function true))
1872                 ((or (eq form 'nil)
1873                      (equal form ''nil))
1874                  '(function false))
1875                 (t
1876                  `(function (lambda () ,form))))))
1877    (setq class-name (require-type class-name '(and symbol (not null))))
1878    (setq superclasses (mapcar #'(lambda (s) (require-type s 'symbol)) superclasses))
1879    (let* ((options-seen ())
1880           (signatures ())
1881           (slot-names))
1882      (flet ((canonicalize-defclass-option (option)
1883               (let* ((option-name (car option)))
1884                 (if (member option-name options-seen :test #'eq)
1885                   (duplicate-options class-options)
1886                   (push option-name options-seen))
1887                 (case option-name
1888                   (:default-initargs
1889                       (let ((canonical ())
1890                             (initargs-seen ()))
1891                         (let (key val (tail (cdr option)))
1892                           (loop (when (null tail) (return nil))
1893                              (setq key (pop tail)
1894                                    val (pop tail))
1895                              (when (memq key initargs-seen)
1896                                (SIGNAL-PROGRAM-error "Duplicate initialization argument name ~S in :DEFAULT-INITARGS of DEFCLASS ~S" key class-name))
1897                              (push key initargs-seen)
1898                              (push ``(,',key ,',val  ,,(make-initfunction val)) canonical))
1899                           `(':direct-default-initargs (list ,@(nreverse canonical))))))
1900                   (:metaclass
1901                    (unless (and (cadr option)
1902                                 (typep (cadr option) 'symbol))
1903                      (illegal-option option))
1904                    `(:metaclass  ',(cadr option)))
1905                   (:documentation
1906                    `(:documentation ',(cadr option)))
1907                   (t
1908                     (list `',option-name `',(cdr option))))))
1909             (canonicalize-slot-spec (slot)
1910               (if (null slot) (signal-program-error "Illegal slot NIL"))
1911               (if (not (listp slot)) (setq slot (list slot)))
1912               (let* ((slot-name (require-type (car slot) 'symbol))
1913                      (initargs nil)
1914                      (other-options ())
1915                      (initform nil)
1916                      (initform-p nil)
1917                      (initfunction nil)
1918                      (type nil)
1919                      (type-p nil)
1920                      (allocation nil)
1921                      (allocation-p nil)
1922                      (documentation nil)
1923                      (documentation-p nil)
1924                      (readers nil)
1925                      (writers nil)
1926                      (reader-info (%cons-def-info 'defmethod (dpb 1 $lfbits-numreq 0) nil nil (list class-name)))
1927                      (writer-info (%cons-def-info 'defmethod (dpb 2 $lfbits-numreq 0) nil nil (list t class-name))))
1928                 (when (memq slot-name slot-names)
1929                   (SIGNAL-PROGRAM-error "Multiple slots named ~S in DEFCLASS ~S" slot-name class-name))
1930                 (push slot-name slot-names)
1931                 (do ((options (cdr slot) (cddr options))
1932                      name)
1933                     ((null options))
1934                   (when (null (cdr options)) (signal-program-error "Illegal slot spec ~S" slot))
1935                   (case (car options)
1936                     (:reader
1937                      (setq name (cadr options))
1938                      (unless (memq name readers)
1939                        (push (cons name reader-info) signatures)
1940                        (push name readers)))
1941                     (:writer                     
1942                      (setq name (cadr options))
1943                      (unless (member name writers :test 'equal)
1944                        (push (cons name writer-info) signatures)
1945                        (push name writers)))
1946                     (:accessor
1947                      (setq name (cadr options))
1948                      (unless (memq name readers)
1949                        (push (cons name reader-info) signatures)
1950                        (push name readers))
1951                      (let ((setf-name `(setf ,name)))
1952                        (unless (member setf-name writers :test 'equal)
1953                          (push (cons (setf-function-name name) writer-info) signatures)
1954                          (push setf-name writers))))
1955                     (:initarg
1956                      (push (require-type (cadr options) 'symbol) initargs))
1957                     (:type
1958                      (if type-p
1959                        (duplicate-options slot)
1960                        (setq type-p t))
1961                      ;(when (null (cadr options)) (signal-program-error "Illegal options ~S" options))
1962                      (setq type (cadr options)))
1963                     (:initform
1964                      (if initform-p
1965                        (duplicate-options slot)
1966                        (setq initform-p t))
1967                      (let ((option (cadr options)))
1968                        (setq initform `',option
1969                              initfunction
1970                              (if (constantp option)
1971                                `(constantly ,option)
1972                                `#'(lambda () ,option)))))
1973                     (:allocation
1974                      (if allocation-p
1975                        (duplicate-options slot)
1976                        (setq allocation-p t))
1977                      (setq allocation (cadr options)))
1978                     (:documentation
1979                      (if documentation-p
1980                        (duplicate-options slot)
1981                        (setq documentation-p t))
1982                      (setq documentation (cadr options)))
1983                     (t
1984                      (let* ((pair (or (assq (car options) other-options)
1985                                       (car (push (list (car options)) other-options)))))
1986                        (push (cadr options) (cdr pair))))))
1987                 `(list :name ',slot-name
1988                   ,@(when allocation `(:allocation ',allocation))
1989                   ,@(when initform-p `(:initform ,initform
1990                                        :initfunction ,initfunction))
1991                   ,@(when initargs `(:initargs ',initargs))
1992                   ,@(when readers `(:readers ',readers))
1993                   ,@(when writers `(:writers ',writers))
1994                   ,@(when type-p `(:type ',type))
1995                   ,@(when documentation-p `(:documentation ,documentation))
1996                   ,@(mapcan #'(lambda (opt)
1997                                 `(',(car opt) ',(if (null (cddr opt))
1998                                                     (cadr opt)
1999                                                     (cdr opt)))) other-options)))))
2000        (let* ((direct-superclasses superclasses)
2001               (direct-slot-specs (mapcar #'canonicalize-slot-spec slots))
2002               (other-options (apply #'append (mapcar #'canonicalize-defclass-option class-options )))
2003               (keyvect (class-keyvect class-name other-options)))
2004          (when (vectorp keyvect)
2005            (let ((illegal (loop for arg in other-options by #'cddr
2006                              as key = (if (quoted-form-p arg) (%cadr arg) arg)
2007                              unless (or (eq key :metaclass) (find key keyvect)) collect key)))
2008              (when illegal
2009                (signal-program-error "Class option~p~{ ~s~} is not one of ~s"
2010                                      (length illegal) illegal keyvect))))
2011          `(progn
2012            (eval-when (:compile-toplevel)
2013              (%compile-time-defclass ',class-name ,env)
2014              (progn
2015                ,@(mapcar #'(lambda (sig) `(record-function-info ',(car sig) ',(cdr sig) ,env))
2016                          signatures)))
2017              (ensure-class-for-defclass ',class-name
2018                            :direct-superclasses ',direct-superclasses
2019                            :direct-slots ,`(list ,@direct-slot-specs)
2020                            ,@other-options)))))))
2021
2022(defmacro define-method-combination (name &rest rest &environment env)
2023  (setq name (require-type name 'symbol))
2024  (cond ((or (null rest) (and (car rest) (symbolp (car rest))))
2025         `(short-form-define-method-combination ',name ',rest))
2026        ((listp (car rest))
2027         (destructuring-bind (lambda-list method-group-specifiers . forms) rest
2028           (long-form-define-method-combination 
2029            name lambda-list method-group-specifiers forms env)))
2030        (t (%badarg (car rest) '(or (and null symbol) list)))))
2031
2032(defmacro defgeneric (function-name lambda-list &rest options-and-methods &environment env)
2033  (fboundp function-name)             ; type-check
2034  (multiple-value-bind (method-combination generic-function-class options methods)
2035      (parse-defgeneric function-name t lambda-list options-and-methods)
2036    (let ((gf (gensym)))
2037      `(progn
2038         (eval-when (:compile-toplevel)
2039           (record-function-info ',(maybe-setf-function-name function-name)
2040                                 ',(%cons-def-info 'defgeneric (encode-gf-lambda-list lambda-list))
2041                                 ,env))
2042         (let ((,gf (%defgeneric
2043                     ',function-name ',lambda-list ',method-combination ',generic-function-class 
2044                     ',(apply #'append options))))
2045           (%set-defgeneric-methods ,gf ,@methods)
2046           ,gf)))))
2047
2048
2049
2050(defun parse-defgeneric (function-name global-p lambda-list options-and-methods)
2051  (check-generic-function-lambda-list lambda-list)
2052  (let ((method-combination '(standard))
2053        (generic-function-class 'standard-generic-function)
2054        options declarations methods option-keywords method-class)
2055    (flet ((bad-option (o)
2056             (signal-program-error "Bad option: ~s to ~s." o 'defgeneric)))
2057      (dolist (o options-and-methods)
2058        (let ((keyword (car o))
2059              (defmethod (if global-p 'defmethod 'anonymous-method)))
2060          (if (eq keyword :method)
2061            (let ((defn `(,defmethod ,function-name ,@(%cdr o))))
2062              (note-source-transformation o defn)
2063              (push defn methods))
2064            (cond ((and (not (eq keyword 'declare))
2065                        (memq keyword (prog1 option-keywords (push keyword option-keywords))))             
2066                   (signal-program-error "Duplicate option: ~s to ~s" keyword 'defgeneric))
2067                  ((eq keyword :method-combination)
2068                   (unless (symbolp (cadr o))
2069                     (bad-option o))
2070                   (setq method-combination (cdr o)))
2071                  ((eq keyword :generic-function-class)
2072                   (unless (and (cdr o) (symbolp (cadr o)) (null (%cddr o)))
2073                     (bad-option o))
2074                   (setq generic-function-class (%cadr o)))
2075                  ((eq keyword 'declare)
2076                   (push (cadr o) declarations))
2077                  ((eq keyword :argument-precedence-order)
2078                   (dolist (arg (cdr o))
2079                     (unless (and (symbolp arg) (memq arg lambda-list))
2080                       (bad-option o)))
2081                   (push (list keyword (cdr o)) options))
2082                  ((eq keyword :method-class)
2083                   (push o options)
2084                   (when (or (cddr o) (not (symbolp (setq method-class (%cadr o)))))
2085                     (bad-option o)))
2086                  ((eq keyword :documentation)
2087                   (push o options)
2088                   (when (or (cddr o) (not (stringp (%cadr o))))
2089                     (bad-option o)))
2090                  (t (bad-option o)))))))
2091    (when method-class
2092      (dolist (m methods)
2093        (push `(:method-class ,method-class) (cddr m))))
2094    (when declarations
2095      (setq options `((:declarations ,declarations) ,@options)))
2096    (values method-combination generic-function-class options methods)))
2097
2098                 
2099(defmacro def-aux-init-functions (class &rest functions)
2100  `(set-aux-init-functions ',class (list ,@functions)))
2101
2102
2103
2104
2105
2106
2107;;; A powerful way of defining REPORT-CONDITION...
2108;;; Do they really expect that each condition type has a unique method on PRINT-OBJECT
2109;;; which tests *print-escape* ?  Scary if so ...
2110
2111(defmacro define-condition (name (&rest supers) (&rest slots) &body options)
2112  "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
2113   Define NAME as a condition type. This new type inherits slots and its
2114   report function from the specified PARENT-TYPEs. A slot spec is a list of:
2115     (slot-name :reader <rname> :initarg <iname> {Option Value}*
2116
2117   The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
2118   and :TYPE and the overall options :DEFAULT-INITARGS and
2119   [type] :DOCUMENTATION are also allowed.
2120
2121   The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
2122   a string or a two-argument lambda or function name. If a function, the
2123   function is called with the condition and stream to report the condition.
2124   If a string, the string is printed.
2125
2126   Condition types are classes, but (as allowed by ANSI and not as described in
2127   CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
2128   SLOT-VALUE may not be used on condition objects."
2129  ; If we could tell what environment we're being expanded in, we'd
2130  ; probably want to check to ensure that all supers name conditions
2131  ; in that environment.
2132  (let ((classopts nil)
2133        (duplicate nil)
2134        (docp nil)
2135        (default-initargs-p nil)
2136        (reporter nil))
2137    (dolist (option options)
2138      (unless (and (consp option)
2139                   (consp (%cdr option)))
2140        (signal-program-error "Invalid option ~s ." option))
2141      (ecase (%car option)
2142        (:default-initargs 
2143            (unless (plistp (cdr option)) 
2144              (signal-program-error "~S is not a plist." (%cdr option))) 
2145            (if default-initargs-p 
2146              (setq duplicate t) 
2147              (push (setq default-initargs-p option) classopts))) 
2148        (:documentation 
2149         (unless (null (%cddr option)) 
2150           (signal-program-error "Invalid option ~s ." option)) 
2151         (if docp
2152           (setq duplicate t)
2153           (push (setq docp option) classopts)))
2154        (:report 
2155         (unless (null (%cddr option)) 
2156           (signal-program-error "Invalid option ~s ." option)) 
2157         (if reporter
2158           (setq duplicate t)
2159           (progn
2160             (if (or (lambda-expression-p (setq reporter (%cadr option)))
2161                     (symbolp reporter))
2162               (setq reporter `(function ,reporter))
2163               (if (stringp reporter)
2164                 (setq reporter `(function (lambda (c s) (declare (ignore c)) (write-string ,reporter s))))
2165                 (signal-program-error "~a expression is not a string, symbol, or lambda expression ." (%car option))))
2166             (setq reporter `((defmethod report-condition ((c ,name) s)
2167                                (funcall ,reporter c s))))))))
2168      (if duplicate (signal-program-error "Duplicate option ~s ." option)))
2169    `(progn
2170       (defclass ,name ,(or supers '(condition)) ,slots ,@classopts)
2171       ,@reporter
2172       ',name)))
2173
2174(defmacro with-condition-restarts (&environment env condition restarts &body body)
2175  "Evaluates the BODY in a dynamic environment where the restarts in the list
2176   RESTARTS-FORM are associated with the condition returned by CONDITION-FORM.
2177   This allows FIND-RESTART, etc., to recognize restarts that are not related
2178   to the error currently being debugged. See also RESTART-CASE."
2179  (multiple-value-bind (body decls)
2180                       (parse-body body env)
2181    (let ((cond (gensym))
2182          (r (gensym)))
2183          `(let* ((*condition-restarts* *condition-restarts*))
2184             ,@decls
2185             (let ((,cond ,condition))
2186               (dolist (,r ,restarts) (push (cons ,r ,cond) *condition-restarts*))
2187               ,@body)))))
2188 
2189(defmacro setf-find-class (name arg1 &optional (arg2 () 2-p) (arg3 () 3-p))
2190  (cond (3-p ;might want to pass env (arg2) to find-class someday?
2191         `(set-find-class ,name (progn ,arg1 ,arg2 ,arg3)))
2192        (2-p
2193         `(set-find-class ,name (progn ,arg1 ,arg2)))
2194        (t `(set-find-class ,name ,arg1))))
2195
2196(defsetf find-class setf-find-class)
2197
2198(defmacro restoring-interrupt-level (var &body body)
2199  `(unwind-protect
2200    (progn ,@body)
2201    (restore-interrupt-level ,var)
2202    (%interrupt-poll)))
2203
2204(defmacro without-interrupts (&body body)
2205  "Evaluate its body in an environment in which process-interrupt
2206requests are deferred."
2207  `(let* ((*interrupt-level* -1))
2208    ,@body))
2209
2210(defmacro with-interrupts-enabled (&body body)
2211  "Evaluate its body in an environment in which process-interrupt
2212has immediate effect."
2213  `(let* ((*interrupt-level* 0))
2214    ,@body))
2215
2216;;; undoes the effect of one enclosing without-interrupts during execution of body.
2217(defmacro ignoring-without-interrupts (&body body)
2218  `(let* ((*interrupt-level* 0))
2219    ,@body))
2220
2221
2222
2223(defmacro error-ignoring-without-interrupts (format-string &rest format-args)
2224  `(ignoring-without-interrupts
2225    (error ,format-string ,@format-args)))
2226
2227
2228;init-list-default: if there is no init pair for <keyword>,
2229;    add a <keyword> <value> pair to init-list
2230(defmacro init-list-default (the-init-list &rest args)
2231  (let ((result)
2232       (init-list-sym (gensym)))
2233   (do ((args args (cddr args)))
2234       ((not args))
2235     (setq result 
2236           (cons `(if (eq '%novalue (getf ,init-list-sym ,(car args) 
2237                                          '%novalue))
2238                    (setq ,init-list-sym (cons ,(car args) 
2239                                               (cons ,(cadr args) 
2240                                                     ,init-list-sym))))
2241                 result)))                                                                               
2242   `(let ((,init-list-sym ,the-init-list))
2243      (progn ,@result)
2244      ,init-list-sym)
2245   ))
2246
2247; This can only be partially backward-compatible: even if only
2248; the "name" arg is supplied, the old function would create the
2249; package if it didn't exist.
2250; Should see how well this works & maybe flush the whole idea.
2251
2252(defmacro in-package (name)
2253  (let ((form nil))
2254    (when (quoted-form-p name)
2255      (warn "Unquoting argument ~S to ~S." name 'in-package )
2256      (setq name (cadr name)))   
2257    (setq form `(set-package ,(string name)))
2258    `(eval-when (:execute :load-toplevel :compile-toplevel)
2259      ,form)))
2260
2261(defmacro defpackage (name &rest options)
2262  "Defines a new package called PACKAGE. Each of OPTIONS should be one of the
2263   following:
2264    (NICKNAMES {package-name}*)
2265
2266    (SIZE <integer>)
2267    (SHADOW {symbol-name}*)
2268    (SHADOWING-IMPORT-FROM <package-name> {symbol-name}*)
2269    (USE {package-name}*)
2270    (IMPORT-FROM <package-name> {symbol-name}*)
2271    (INTERN {symbol-name}*)
2272    (EXPORT {symbol-name}*)
2273    (IMPLEMENT {package-name}*)
2274    (LOCK boolean)
2275    (DOCUMENTATION doc-string)
2276   All options except SIZE, LOCK, and :DOCUMENTATION can be used multiple
2277   times."
2278  (let* ((size nil)
2279         (all-names-size 0)
2280         (intern-export-size 0)
2281         (shadow-etc-size 0)
2282         (documentation nil)
2283         (all-names-hash (let ((all-options-alist nil))
2284                           (dolist (option options)
2285                             (let ((option-name (car option)))
2286                               (when (memq option-name
2287                                           '(:nicknames :shadow :shadowing-import-from
2288                                             :use :import-from :intern :export))
2289                                 (let ((option-size (length (cdr option)))
2290                                       (cell (assq option-name all-options-alist)))
2291                                   (declare (fixnum option-size))
2292                                   (if cell
2293                                     (incf (cdr cell) option-size)
2294                                     (push (cons option-name option-size) all-options-alist))
2295                                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2296                                     (incf shadow-etc-size option-size))
2297                                   (when (memq option-name '(:export :intern))
2298                                     (incf intern-export-size option-size))))))
2299                           (dolist (cell all-options-alist)
2300                             (let ((option-size (cdr cell)))
2301                               (when (> option-size all-names-size)
2302                                 (setq all-names-size option-size))))
2303                           (when (> all-names-size 0)
2304                             (make-hash-table :test 'equal :size all-names-size))))
2305         (intern-export-hash (when (> intern-export-size 0)
2306                               (make-hash-table :test 'equal :size intern-export-size)))
2307         (shadow-etc-hash (when (> shadow-etc-size 0)
2308                            (make-hash-table :test 'equal :size shadow-etc-size)))
2309         (external-size nil)
2310         (nicknames nil)
2311         (shadow nil)
2312         (shadowing-import-from-specs nil)
2313         (use :default)
2314         (import-from-specs nil)
2315         (intern nil)
2316         (export nil))
2317    (declare (fixnum all-names-size intern-export-size shadow-etc-size))
2318    (labels ((string-or-name (s) (string s))
2319             (duplicate-option (o)
2320               (signal-program-error "Duplicate ~S option in ~S ." o options))
2321             (duplicate-name (name option-name)
2322               (signal-program-error "Name ~s, used in ~s option, is already used in a conflicting option ." name option-name))
2323             (all-names (option-name tail already)
2324               (when (eq already :default) (setq already nil))
2325               (when all-names-hash
2326                 (clrhash all-names-hash))
2327               (dolist (name already)
2328                 (setf (gethash (string-or-name name) all-names-hash) t))
2329               (dolist (name tail already)
2330                 (setq name (string-or-name name))
2331                 (unless (gethash name all-names-hash)          ; Ok to repeat name in same option.
2332                   (when (memq option-name '(:shadow :shadowing-import-from :import-from :intern))
2333                     (if (gethash name shadow-etc-hash)
2334                       (duplicate-name name option-name))
2335                     (setf (gethash name shadow-etc-hash) t))
2336                   (when (memq option-name '(:export :intern))
2337                     (if (gethash name intern-export-hash)
2338                       (duplicate-name name option-name))
2339                     (setf (gethash name intern-export-hash) t))
2340                   (setf (gethash name all-names-hash) t)
2341                   (push name already)))))
2342      (dolist (option options)
2343        (let ((args (cdr option)))
2344          (ecase (%car option)
2345                 (:size 
2346                  (if size 
2347                    (duplicate-option :size) 
2348                    (setq size (car args))))             
2349                 (:external-size 
2350                  (if external-size 
2351                    (duplicate-option :external-size) 
2352                    (setq external-size (car args))))
2353                 (:nicknames (setq nicknames (all-names nil args nicknames)))
2354                 (:shadow (setq shadow (all-names :shadow args shadow)))
2355                 (:shadowing-import-from
2356                  (destructuring-bind (from &rest shadowing-imports) args
2357                    (push (cons (string-or-name from)
2358                                (all-names :shadowing-import-from shadowing-imports nil))
2359                          shadowing-import-from-specs)))
2360                 (:use (setq use (all-names nil args use)))
2361                 (:import-from
2362                  (destructuring-bind (from &rest imports) args
2363                    (push (cons (string-or-name from)
2364                                (all-names :import-from imports nil))
2365                          import-from-specs)))
2366                 (:intern (setq intern (all-names :intern args intern)))
2367                 (:export (setq export (all-names :export args export)))
2368                 (:documentation
2369                  (if documentation
2370                    (duplicate-option :documentation)
2371                    (setq documentation (cadr option)))))))
2372      `(eval-when (:execute :compile-toplevel :load-toplevel)
2373         (%define-package ',(string-or-name name)
2374          ',size 
2375          ',external-size 
2376          ',nicknames
2377          ',shadow
2378          ',shadowing-import-from-specs
2379          ',use
2380          ',import-from-specs
2381          ',intern
2382          ',export
2383          ',documentation)))))
2384
2385
2386
2387(defmacro with-package-iterator ((mname package-list first-type &rest other-types)
2388                                 &body body)
2389  "Within the lexical scope of the body forms, MNAME is defined via macrolet
2390   such that successive invocations of (MNAME) will return the symbols,
2391   one by one, from the packages in PACKAGE-LIST. SYMBOL-TYPES may be
2392   any of :INHERITED :EXTERNAL :INTERNAL."
2393  (setq mname (require-type mname 'symbol))
2394  (let ((state (make-symbol "WITH-PACKAGE-ITERATOR_STATE")))
2395    (dolist (type (push first-type other-types))
2396      (ecase type
2397        ((:external :internal :inherited))))
2398    `(let ((,state (%setup-pkg-iter-state ,package-list ',other-types)))
2399       (macrolet ((,mname () `(%pkg-iter-next ,',state)))
2400         ,@body))))
2401
2402; Does NOT evaluate the constructor, but DOES evaluate the destructor & initializer
2403(defmacro defresource (name &key constructor destructor initializer)
2404  `(defparameter ,name (make-resource #'(lambda () ,constructor)
2405                                      ,@(when destructor
2406                                          `(:destructor ,destructor))
2407                                      ,@(when initializer
2408                                          `(:initializer ,initializer)))))
2409
2410(defmacro using-resource ((var resource) &body body)
2411  (let ((resource-var (gensym)))
2412  `(let ((,resource-var ,resource)
2413         ,var)
2414     (unwind-protect
2415       (progn
2416         (setq ,var (allocate-resource ,resource-var))
2417         ,@body)
2418       (when ,var
2419         (free-resource ,resource-var ,var))))))
2420
2421;;; Bind per-thread specials which help with lock accounting.
2422(defmacro with-lock-context (&body body)
2423  #+lock-accounting
2424  `(let* ((*locks-held* *locks-held*)
2425          (*locks-pending* *locks-pending*)
2426          (*lock-conses* *lock-conses*))
2427    ,@body)
2428  #-lock-accounting
2429  `(progn ,@body))
2430
2431(defmacro with-lock-grabbed ((lock &optional
2432                                   (whostate "Lock"))
2433                             &body body)
2434  "Wait until a given lock can be obtained, then evaluate its body with
2435the lock held."
2436  (declare (ignore whostate))
2437    (let* ((locked (gensym))
2438           (l (gensym)))
2439      `  (with-lock-context
2440           (let ((,locked (make-lock-acquisition))
2441             (,l ,lock))
2442        (declare (dynamic-extent ,locked))
2443        (unwind-protect
2444             (progn
2445               (%lock-recursive-lock-object ,l ,locked )
2446               ,@body)
2447          (when (lock-acquisition.status ,locked) (%unlock-recursive-lock-object ,l)))))))
2448
2449(defmacro with-lock-grabbed-maybe ((lock &optional
2450                                         (whostate "Lock"))
2451                                   &body body)
2452  (declare (ignore whostate))
2453  (let* ((l (gensym)))
2454    `(with-lock-context
2455      (let* ((,l ,lock))
2456        (when (%try-recursive-lock-object ,l)
2457          (unwind-protect
2458               (progn ,@body)
2459            (%unlock-recursive-lock-object ,l)))))))
2460
2461(defmacro with-standard-abort-handling (abort-message &body body)
2462  (let ((stream (gensym)))
2463    `(restart-case
2464       (catch :abort
2465         (catch-cancel
2466           ,@body))
2467       (abort () ,@(when abort-message
2468                     `(:report (lambda (,stream)
2469                                 (write-string ,abort-message ,stream)))))
2470       (abort-break ()))))
2471       
2472
2473
2474
2475(defmacro %lexpr-count (l)
2476  `(%lisp-word-ref ,l 0))
2477
2478(defmacro %lexpr-ref (lexpr count i)
2479  `(%lisp-word-ref ,lexpr (%i- ,count ,i)))
2480
2481;;; args will be list if old style clos
2482(defmacro apply-with-method-context (magic function args)
2483  (let ((m (gensym))
2484        (f (gensym))
2485        (as (gensym)))
2486      `((lambda (,m ,f ,as)
2487          (if (listp ,as)
2488            (%apply-with-method-context ,m ,f ,as)
2489            (%apply-lexpr-with-method-context ,m ,f ,as))) ,magic ,function ,args)))
2490
2491(defmacro defcallback (name arglist &body body &environment env)
2492  "Proclaim name to be a special variable; sets its value to a MACPTR which,
2493when called by foreign code, calls a lisp function which expects foreign
2494arguments of the specified types and which returns a foreign value of the
2495specified result type. Any argument variables which correspond to foreign
2496arguments of type :ADDRESS are bound to stack-allocated MACPTRs.
2497
2498If name is already a callback function pointer, its value is not changed;
2499instead, it's arranged that an updated version of the lisp callback function
2500will be called. This feature allows for callback functions to be redefined
2501incrementally, just like Lisp functions are.
2502
2503defcallback returns the callback pointer, e.g., the value of name."
2504  (define-callback name arglist body env))
2505
2506(declare-arch-specific-macro %get-single-float-from-double-ptr)
2507
2508(declare-arch-specific-macro lfun-vector)
2509(declare-arch-specific-macro lfun-vector-lfun)
2510
2511(declare-arch-specific-macro symptr->symvector)
2512(declare-arch-specific-macro symvector->symptr)
2513
2514(declare-arch-specific-macro function-to-function-vector)
2515(declare-arch-specific-macro function-vector-to-function)
2516
2517(declare-arch-specific-macro with-ffcall-results)
2518
2519(defvar *trace-print-functions* nil)
2520(defun %trace-print-arg (stream arg val type)
2521  (format stream " ")
2522  (let ((fn (assoc type *trace-print-functions*)))
2523    (if fn
2524      (funcall (cdr fn) stream arg val)
2525      (progn
2526      (when arg
2527        (format stream "~A = " arg))
2528      (if (and type (not (eq type :void)))
2529          (format stream "[:~A] ~A~%" type val)
2530        (format stream ":VOID~%" val))))))
2531
2532(defun def-trace-print-function (type fn)
2533  (push (cons type fn) *trace-print-functions*))
2534
2535(defun define-callback (name args body env)
2536  (let* ((stack-word (gensym))
2537         (stack-ptr (gensym))
2538         (fp-args-ptr (gensym))
2539         (result-type-spec :void)
2540         (args args)
2541         (woi nil)
2542         (monitor nil)
2543         (need-struct-arg)
2544         (struct-return-arg-name)
2545         (error-return nil))
2546    (collect ((arg-names)
2547              (arg-specs))
2548      (let* ((spec (car (last args)))
2549             (rtype (ignore-errors (parse-foreign-type spec))))
2550        (setq need-struct-arg (typep rtype 'foreign-record-type))
2551        (if rtype
2552          (setq result-type-spec spec args (butlast args))))
2553      (loop
2554        (when (null args) (return))
2555        (if (eq (car args) :without-interrupts)
2556          (setq woi (cadr args) args (cddr args))
2557          (if (eq (car args) :monitor-exception-ports)
2558            (setq monitor (cadr args) args (cddr args))
2559           
2560            (if (eq (car args) :error-return)
2561              (setq error-return
2562                    (cadr args)                 
2563                    args (cddr args))
2564              (if need-struct-arg
2565                (setq struct-return-arg-name (pop args) need-struct-arg nil)
2566                (progn
2567                  (arg-specs (pop args))
2568                  (arg-names (pop args))))))))
2569      (multiple-value-bind (rlets lets dynamic-extent-names inits foreign-return-type fp-args-form error-return-offset)
2570          (funcall (ftd-callback-bindings-function *target-ftd*)
2571                   stack-ptr fp-args-ptr (arg-names) (arg-specs) result-type-spec struct-return-arg-name)
2572        (multiple-value-bind (body decls doc) (parse-body body env t)
2573          `(progn
2574            (declaim (special ,name))
2575            (define-callback-function
2576                (nfunction ,name
2577                 (lambda (,stack-word)
2578                   (declare (ignorable ,stack-word))
2579                   (block ,name
2580                     (with-macptrs ((,stack-ptr))
2581                       (%setf-macptr-to-object ,stack-ptr ,stack-word)
2582                       (with-macptrs (,@(when fp-args-form
2583                                              `((,fp-args-ptr ,fp-args-form))))
2584                         ,(defcallback-body stack-ptr
2585                                            fp-args-ptr
2586                                            lets
2587                                            rlets
2588                                            inits
2589                                            `(declare (dynamic-extent ,@dynamic-extent-names))
2590                                            decls
2591                                            body
2592                                            foreign-return-type
2593                                            struct-return-arg-name
2594                                            error-return
2595                                            error-return-offset
2596                                            ))))))
2597                ,doc
2598              ,woi
2599              ,monitor)))))))
2600
2601
2602(defun defcallback-body (&rest args)
2603  (declare (dynamic-extent args))
2604  (destructuring-bind (stack-ptr fp-args-ptr lets rlets inits dynamic-extent-decls other-decls body return-type struct-return-arg error-return error-delta) args
2605    (declare (ignorable dynamic-extent-decls))
2606    (let* ((result (gensym))
2607           (condition-name (if (atom error-return) 'error (car error-return)))
2608           (error-return-function (if (atom error-return) error-return (cadr error-return)))
2609           (body
2610            `(rlet ,rlets
2611              (let ,lets
2612                ,dynamic-extent-decls
2613                ,@other-decls
2614                ,@inits
2615                (let ((,result (progn ,@body)))
2616                  (declare (ignorable ,result)
2617                           (dynamic-extent ,result))
2618
2619                  ,(funcall (ftd-callback-return-value-function *target-ftd*)
2620                            stack-ptr
2621                            fp-args-ptr
2622                            result
2623                            return-type
2624                            struct-return-arg)
2625                  nil)))))
2626      (if error-return
2627        (let* ((cond (gensym))
2628               (block (gensym))
2629               (handler (gensym)))
2630          `(block ,block
2631            (let* ((,handler (lambda (,cond)
2632                                           (,error-return-function ,cond ,stack-ptr (%inc-ptr ,stack-ptr ,error-delta))
2633                                           (return-from ,block
2634                                             nil))))
2635              (declare (dynamic-extent ,handler))
2636            (handler-bind ((,condition-name ,handler))
2637              (values ,body)))))
2638        body))))
2639
2640
2641(defmacro errchk (form)
2642  (let* ((res (gensym)))
2643    `(let* ((,res ,form))
2644       (if (eql 0 ,res)
2645         0
2646         (signal-posix-error ,res)))))
2647
2648(defmacro define-toplevel-command (group-name name arglist &body body &environment env)
2649  (let* ((key (make-keyword name)))
2650    (multiple-value-bind (body decls doc) (parse-body body env)
2651      `(%define-toplevel-command ',group-name ,key ',name 
2652        (nfunction ,name (lambda ,arglist
2653                           ,@decls
2654                           (block ,name
2655                             ,@body)))
2656        ,doc
2657        ',(mapcar #'symbol-name arglist)))))
2658
2659(defmacro with-toplevel-commands (group-name &body body)
2660  `(let* ((*active-toplevel-commands* *active-toplevel-commands*))
2661    (progn
2662      (%use-toplevel-commands ',group-name)
2663      ,@body)))
2664
2665(defmacro assert (test-form &optional (places ()) string &rest args)
2666  "ASSERT Test-Form [(Place*) [String Arg*]]
2667  If the Test-Form is not true, then signal a correctable error.  If Places
2668  are specified, then new values are prompted for when the error is proceeded.
2669  String and Args are the format string and args to the error call."
2670  (let* ((TOP (gensym))
2671         (setf-places-p (not (null places))))
2672    `(without-compiling-code-coverage
2673      (tagbody
2674       ,TOP
2675       (unless ,test-form
2676         (%assertion-failure ,setf-places-p ',test-form ,string ,@args)
2677         ,@(if places
2678             `((write-line "Type expressions to set places to, or nothing to leave them alone."
2679                           *query-io*)
2680               ,@(mapcar #'(lambda (place &aux (new-val (gensym))
2681                                          (set-p (gensym)))
2682                             `(multiple-value-bind
2683                                (,new-val ,set-p)
2684                                (assertion-value-prompt ',place)
2685                                (when ,set-p (setf ,place (values-list ,new-val)))))
2686                         places)))
2687         (go ,TOP))))))
2688
2689
2690(defmacro check-type (place typespec &optional string)
2691  "CHECK-TYPE Place Typespec [String]
2692  Signal a restartable error of type TYPE-ERROR if the value of PLACE is
2693  not of the specified type. If an error is signalled and the restart is
2694  used to return, this can only return if the STORE-VALUE restart is
2695  invoked. In that case it will store into PLACE and start over."
2696  (let* ((val (gensym)))
2697    `(without-compiling-code-coverage
2698      (do* ((,val ,place ,place))
2699          ((typep ,val ',typespec))
2700        (setf ,place (ensure-value-of-type ,val ',typespec ',place ,string))))))
2701
2702
2703
2704
2705(defmacro with-hash-table-iterator ((mname hash-table) &body body &environment env)
2706  "WITH-HASH-TABLE-ITERATOR ((function hash-table) &body body)
2707   provides a method of manually looping over the elements of a hash-table.
2708   FUNCTION is bound to a generator-macro that, within the scope of the
2709   invocation, returns one or three values. The first value tells whether
2710   any objects remain in the hash table. When the first value is non-NIL,
2711   the second and third values are the key and the value of the next object."
2712  (let* ((hash (gensym))
2713         (keys (gensym))
2714         (values (gensym))
2715         (count (gensym))
2716         (state (gensym)))
2717    `(let* ((,hash ,hash-table)
2718            (,count (hash-table-count ,hash))
2719            (,keys (make-array ,count))
2720            (,values (make-array ,count))
2721            (,state (vector ,hash 0 ,keys ,values (enumerate-hash-keys-and-values ,hash ,keys ,values))))
2722      (declare (dynamic-extent ,keys ,state)
2723               (fixnum ,count))
2724      (macrolet ((,mname () `(next-hash-table-iteration-1 ,',state)))
2725        ,@body))))
2726
2727
2728(eval-when (compile load eval)
2729(defmacro pprint-logical-block ((stream-symbol list
2730                                 &key (prefix "" prefixp)
2731                                      (per-line-prefix "" per-line-prefix-p)
2732                                      (suffix "" suffixp))
2733                                &body body)
2734  (cond ((eq stream-symbol nil) (setq stream-symbol '*standard-output*))
2735        ((eq stream-symbol T) (setq stream-symbol '*terminal-io*)))
2736  (when (not (symbolp stream-symbol))
2737    (warn "STREAM-SYMBOL arg ~S to PPRINT-LOGICAL-BLOCK is not a bindable symbol"
2738          stream-symbol)
2739    (setq stream-symbol '*standard-output*))
2740  (when (and prefixp per-line-prefix-p)
2741    (warn "prefix ~S and per-line-prefix ~S cannot both be specified ~
2742           in PPRINT-LOGICAL-BLOCK")
2743    (setq per-line-prefix nil))
2744  `(let ((*logical-block-p* t))
2745     (maybe-initiate-xp-printing
2746      #'(lambda (,stream-symbol)
2747          (let ((+l ,list)
2748                (+p (or (and ,prefixp
2749                             (require-type ,prefix 'string))
2750                        (and ,per-line-prefix-p
2751                             (require-type ,per-line-prefix 'string))))
2752                (+s (require-type ,suffix 'string)))
2753            (pprint-logical-block+
2754                (,stream-symbol +l +p +s ,per-line-prefix-p T nil)
2755              ,@ body nil)))
2756      (decode-stream-arg ,stream-symbol))))
2757
2758
2759;Assumes var and args must be variables.  Other arguments must be literals or variables.
2760
2761(defmacro pprint-logical-block+ ((var args prefix suffix per-line? circle-check? atsign?)
2762                                 &body body)
2763  "Group some output into a logical block. STREAM-SYMBOL should be either a
2764   stream, T (for *TERMINAL-IO*), or NIL (for *STANDARD-OUTPUT*). The printer
2765   control variable *PRINT-LEVEL* is automatically handled."
2766  (when (and circle-check? atsign?)
2767    (setq circle-check? 'not-first-p))
2768  `(let ((*current-level* (1+ *current-level*))
2769         (*current-length* -1)
2770         ;(*parents* *parents*)
2771         ,@(if (and circle-check? atsign?) `((not-first-p (plusp *current-length*)))))
2772     (unless (check-block-abbreviation ,var ,args ,circle-check?)
2773       (start-block ,var ,prefix ,per-line? ,suffix)
2774       (when
2775         (catch 'line-limit-abbreviation-exit
2776           (block logical-block
2777             (macrolet ((pprint-pop () `(pprint-pop+ ,',args ,',var))
2778                        (pprint-exit-if-list-exhausted ()
2779                          `(if (null ,',args) (return-from logical-block nil))))
2780               ,@ body))
2781           (end-block ,var ,suffix)
2782           nil)
2783         (end-block ,var ,suffix)
2784         (throw 'line-limit-abbreviation-exit T)))))
2785) ; eval-when
2786
2787(defmacro %old-class-local-shared-slotds (class &optional default)
2788  (if default                           ; so setf works
2789    `(%class-get ,class '%old-class-local-shared-slotds ,default)
2790    `(%class-get ,class '%old-class-local-shared-slotds)))
2791
2792(defmacro with-slot-values (slot-entries instance-form &body body)
2793; Simplified form of with-slots.  Expands into a let instead of a symbol-macrolet
2794; Thus, you can access the slot values, but you can't setq them.
2795  (let ((instance (gensym)) var slot-name bindings)
2796    (dolist (slot-entry slot-entries)
2797      (cond ((symbolp slot-entry)
2798             (setq var slot-entry slot-name slot-entry))
2799            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2800                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2801             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2802            (t (signal-program-error "Malformed slot-entry: ~a to with-slot-values.~@
2803                                      Should be a symbol or a list of two symbols."
2804                                     slot-entry)))
2805      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2806    `(let ((,instance ,instance-form))
2807       (let ,(nreverse bindings)
2808         ,@body))))
2809
2810(defmacro with-slots (slot-entries instance-form &body body)
2811  "Establish a lexical environment for referring to the slots in the
2812instance named by the given slot-names as though they were variables.
2813Within such a context the value of the slot can be specified by using
2814its slot name, as if it were a lexically bound variable. Both setf and
2815setq can be used to set the value of the slot."
2816  (let ((instance (gensym)) var slot-name bindings)
2817    (dolist (slot-entry slot-entries)
2818      (cond ((symbolp slot-entry)
2819             (setq var slot-entry slot-name slot-entry))
2820            ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2821                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2822             (setq var (car slot-entry) slot-name (cadr slot-entry)))
2823            (t (signal-program-error "Malformed slot-entry: ~a to with-slots.~@
2824                                      Should be a symbol or a list of two symbols."
2825                                     slot-entry)))
2826      (push `(,var (slot-value ,instance ',slot-name)) bindings))
2827    `(let ((,instance ,instance-form))
2828       ,@(if bindings 
2829             (list `(declare (ignorable ,instance)))
2830             (list `(declare (ignore ,instance))))
2831       (symbol-macrolet ,(nreverse bindings)
2832         ,@body))))
2833
2834(defmacro with-accessors (slot-entries instance-form &body body)
2835  "Create a lexical environment in which the slots specified by slot-entry
2836are lexically available through their accessors as if they were variables.
2837The appropriate accessors are invoked to access the slots specified by
2838slot-entry. Both setf and setq can be used to set the value of the slot."
2839  (let ((instance (gensym)) var reader bindings)
2840    (dolist (slot-entry slot-entries)
2841      (cond ((and (listp slot-entry) (cdr slot-entry) (null (cddr slot-entry))
2842                  (symbolp (car slot-entry)) (symbolp (cadr slot-entry)))
2843             (setq var (car slot-entry) reader (cadr slot-entry)))
2844            (t (signal-program-error "Malformed slot-entry: ~a to with-accessors.~@
2845                                     Should be a list of two symbols."
2846                                     slot-entry)))
2847      (push `(,var (,reader ,instance)) bindings))
2848    `(let ((,instance ,instance-form))
2849       ,@(if bindings 
2850             (list `(declare (ignorable ,instance)))
2851             (list `(declare (ignore ,instance))))
2852       (symbol-macrolet ,(nreverse bindings)
2853         ,@body))))
2854
2855; I wanted to call this ":method"
2856(defmacro reference-method (gf &rest qualifiers-and-specializers)
2857  (let ((qualifiers (butlast qualifiers-and-specializers))
2858        (specializers (car (last qualifiers-and-specializers))))
2859    (if (null specializers) (report-bad-arg qualifiers-and-specializers '(not null)))
2860    `(find-method #',gf ',qualifiers (mapcar #'find-specializer ',specializers))))
2861
2862(defmacro time (form)
2863  "Execute FORM and print timing information on *TRACE-OUTPUT*."
2864  `(report-time ',form #'(lambda () (progn ,form))))
2865
2866(defmacro with-error-reentry-detection (&body body)
2867  (let ((thunk (gensym)))
2868    `(let ((,thunk #'(lambda () ,@body)))
2869       (declare (dynamic-extent ,thunk))
2870       (funcall-with-error-reentry-detection ,thunk))))
2871
2872(defmacro without-duplicate-definition-warnings (&body body)
2873  `(compiler-let ((*compiler-warn-on-duplicate-definitions* nil))
2874     ,@body))
2875
2876
2877#+ppc-target
2878(defmacro scan-for-instr (mask opcode fn pc-index &optional (tries *trap-lookup-tries*))
2879  `(%scan-for-instr ,mask ,opcode ,fn ,pc-index ,tries))
2880
2881
2882(declare-arch-specific-macro codevec-header-p)
2883
2884#+ppc-target
2885(defmacro match-instr (instr mask bits-to-match)
2886  `(eql (logand ,instr ,mask) ,bits-to-match))
2887
2888(defmacro with-xp-stack-frames ((xp trap-function &optional stack-frame) &body body)
2889  (let ((thunk (gensym))
2890        (sf (or stack-frame (gensym))))
2891    `(let ((,thunk #'(lambda (&optional ,sf)
2892                       ,@(unless stack-frame `((declare (ignore ,sf))))
2893                       ,@body)))
2894       (declare (dynamic-extent ,thunk))
2895       (funcall-with-xp-stack-frames ,xp ,trap-function ,thunk))))
2896
2897(defmacro signal-eof-error (stream)
2898  `(error 'end-of-file :stream ,stream))
2899
2900(defmacro check-eof (valform stream eof-error-p eof-value)
2901  (let* ((val (gensym)))
2902    `(let ((,val ,valform))
2903      (if (eq ,val :eof)
2904        (if ,eof-error-p
2905          (signal-eof-error ,stream)
2906          ,eof-value)
2907        ,val))))
2908
2909(defmacro designated-input-stream (input-stream)
2910  `(if ,input-stream
2911    (if (eq t ,input-stream)
2912      *terminal-io*
2913      ,input-stream)
2914    *standard-input*))
2915
2916(defmacro pref (pointer accessor)
2917  "Reference an instance of a foreign type (or a component of a foreign
2918type) accessible via ptr.
2919
2920Expand into code which references the indicated scalar type or component,
2921or returns a pointer to a composite type."
2922  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2923    (destructuring-bind (type-name &rest accessors) (decompose-record-accessor accessor)
2924      (%foreign-access-form pointer (%foreign-type-or-record type-name) 0 accessors))))
2925
2926(defmacro paref (pointer type-name index)
2927  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2928    (%foreign-array-access-form  pointer (%foreign-type-or-record type-name) index)))
2929
2930(defmacro rref (pointer accessor &key (storage :pointer storage-p))
2931  (when storage-p
2932    (warn "Use of :storage option ignored: ~a" storage))
2933  `(pref ,pointer ,accessor))
2934
2935(defmacro rlet (spec &body body)
2936  "Execute body in an environment in which each var is bound to a MACPTR
2937encapsulating the address of a stack-allocated foreign memory block,
2938allocated and initialized from typespec and initforms as per make-record.
2939Return whatever value(s) body returns."
2940  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2941    `(%stack-block ,(rlet-sizes spec)
2942      ,@(rlet-inits spec)
2943      ,@body)))
2944
2945(defmacro rletz (spec &body body)
2946  "Execute body in an environment in which each var is bound to a MACPTR
2947encapuslating the address of a stack-allocated foreign memory block,
2948allocated and initialized from typespec and initforms as per make-record.
2949Return whatever value(s) body returns.
2950
2951Unlike rlet, record fields that aren't explicitly initialized are set
2952to binary 0."
2953  (let* ((*target-ftd* (backend-target-foreign-type-data *target-backend*)))
2954    `(%stack-block ,(rlet-sizes spec t)
2955      ,@(rlet-inits spec)
2956      ,@body)))
2957
2958(defun rlet-sizes (inits &optional clear-p &aux result)
2959  (dolist (item inits (nreverse result))
2960    (push `(,(car item)
2961            ,(%foreign-type-or-record-size (cadr item) :bytes)
2962            ,@(if clear-p '(:clear t)))
2963          result)))
2964
2965(defun rlet-inits (inits &aux result)
2966  (dolist (item inits result)
2967    (let* ((name (car item))
2968           (record-name (cadr item))
2969           (inits (cddr item))
2970           (ftype (%foreign-type-or-record record-name))
2971           (ordinal (foreign-type-ordinal ftype))
2972           (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
2973                           ordinal
2974                           `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name))))))
2975      (when (eq *host-backend* *target-backend*)
2976        (setq result (nconc result `((%set-macptr-type ,name ,ordinal-form)))))
2977      (if (typep ftype 'foreign-record-type)
2978        (setq result
2979              (nconc result (%foreign-record-field-forms name ftype record-name inits)))
2980        (progn
2981          (when inits
2982            (if (and ftype (null (cdr inits)))
2983              (setq result
2984                    (nconc result
2985                           `((setf ,(%foreign-access-form name ftype 0 nil)
2986                              ,(car inits)))))
2987              (signal-program-error "Unexpected or malformed initialization forms: ~s in field type: ~s"
2988                                    inits record-name))))))))
2989
2990(defun %foreign-record-field-forms (ptr record-type record-name inits)
2991  (unless (evenp (length inits))
2992    (signal-program-error "Unexpected or malformed initialization forms: ~s in field type: ~s"
2993                          inits record-name))
2994  (let* ((result ()))
2995    (do* ()
2996         ((null inits)
2997          `((progn
2998              ;(%assert-macptr-ftype ,ptr ,record-type)
2999              ,@(nreverse result))))
3000      (let* ((accessor (decompose-record-accessor (pop inits)))
3001             (valform (pop inits)))
3002        (push `(setf ,(%foreign-access-form ptr record-type 0  accessor) ,valform)
3003              result)))))
3004 
3005(defmacro get-field-offset (accessor)
3006  (destructuring-bind (type-name field-name) (decompose-record-accessor accessor)
3007    (let* ((record-type (require-type (%foreign-type-or-record type-name) 'foreign-record-type))
3008           (field (%find-foreign-record-type-field record-type field-name))
3009           (bit-offset (foreign-record-field-offset field)))
3010      `(values ,(floor bit-offset 8) ,(foreign-record-field-type field) ,bit-offset))))
3011
3012(defmacro record-length (recname)
3013  (%foreign-type-or-record-size recname :bytes))
3014
3015(defun make-record-form (record-name allocator &rest initforms)
3016  (let* ((ftype (%foreign-type-or-record record-name))
3017         (ordinal (foreign-type-ordinal ftype))
3018         (ordinal-form (if (< ordinal max-canonical-foreign-type-ordinal)
3019                         ordinal
3020                         `(foreign-type-ordinal (load-time-value (%foreign-type-or-record ',record-name)))))
3021         (bits (ensure-foreign-type-bits ftype))
3022         (bytes (if bits
3023                  (ceiling bits 8)
3024                  (signal-program-error "Unknown size for foreign type ~S."
3025                                        (unparse-foreign-type ftype))))
3026         (p (gensym))
3027         (bzero (read-from-string "#_bzero")))   
3028    `(let* ((,p (,allocator ,bytes)))
3029      ,@(when (eq *host-backend* *target-backend*)
3030              `((%set-macptr-type ,p ,ordinal-form)))
3031      (,bzero ,p ,bytes)
3032      ,@(%foreign-record-field-forms p ftype record-name initforms)
3033      ,p)))
3034 
3035(defmacro make-record (record-name &rest initforms)
3036  "Expand into code which allocates and initalizes an instance of the type
3037denoted by typespec, on the foreign heap. The record is allocated using the
3038C function malloc, and the user of make-record must explicitly call the C
3039function free to deallocate the record, when it is no longer needed."
3040  (apply 'make-record-form record-name 'malloc initforms))
3041
3042(defmacro make-gcable-record (record-name &rest initforms)
3043  "Like MAKE-RECORD, only advises the GC that the foreign memory can
3044   be deallocated if the returned pointer becomes garbage."
3045  (apply 'make-record-form record-name '%new-gcable-ptr initforms))
3046
3047(defmacro copy-record (type source dest)
3048  (let* ((size (* (%foreign-type-or-record-size type :words) #+64-bit-target 1 #+32-bit-target 2))
3049         (src (gensym "SRC"))
3050         (dst (gensym "DST"))
3051         (accessor #+64-bit-target '%get-unsigned-long #+32-bit-target '%get-unsigned-word)
3052         (i (gensym "I"))
3053         (j (gensym "J")))
3054    `(with-macptrs ((,src ,source)
3055                    (,dst ,dest))
3056      (do* ((,i 0 (+ ,i #+64-bit-target 4 #+32-bit-target 2))
3057            (,j 0 (+ ,j 1)))
3058           ((= ,j ,size))
3059        (declare (fixnum ,i))
3060        (setf (,accessor ,dst ,i) (,accessor ,src ,i))))))
3061
3062(defmacro assert-pointer-type (pointer type)
3063  "Assert that the pointer points to an instance of the specified foreign type.
3064Return the pointer."
3065  (let* ((ptr (gensym)))
3066    `(let* ((,ptr ,pointer))
3067      (%set-macptr-type ,ptr (foreign-type-ordinal (load-time-value (parse-foreign-type ',type))))
3068      ,ptr)))
3069
3070   
3071
3072(defmacro with-terminal-input (&body body)
3073  "Execute body in an environment with exclusive read access to the terminal."
3074  (let* ((got-it (gensym)))
3075    `(let* ((,got-it (%request-terminal-input)))
3076      (unwind-protect
3077           (progn ,@body)
3078        (%restore-terminal-input ,got-it)))))
3079
3080
3081(defmacro with-process-whostate ((whostate) &body body)
3082  `(let* ((*whostate* ,whostate))
3083    ,@body))
3084
3085
3086
3087
3088
3089(defmacro with-read-lock ((lock) &body body)
3090  "Wait until a given lock is available for read-only access, then evaluate
3091its body with the lock held."
3092  (let* ((p (gensym)))
3093    `(with-lock-context
3094      (let* ((,p ,lock))
3095        (unwind-protect
3096             (progn
3097               (read-lock-rwlock ,p)
3098               ,@body)
3099          (unlock-rwlock ,p))))))
3100
3101
3102(defmacro with-write-lock ((lock) &body body)
3103  "Wait until the given lock is available for write access, then execute
3104its body with the lock held."
3105  (let* ((p (gensym)))
3106    `(with-lock-context
3107      (let* ((,p ,lock))
3108      (unwind-protect
3109           (progn
3110             (write-lock-rwlock ,p)
3111             ,@body)
3112        (unlock-rwlock ,p))))))
3113
3114
3115
3116(defmacro without-gcing (&body body)
3117  `(unwind-protect
3118    (progn
3119      (%lock-gc-lock)
3120      ,@body)
3121    (%unlock-gc-lock)))
3122
3123(defmacro with-deferred-gc (&body body)
3124  "Execute BODY without responding to the signal used to suspend
3125threads for GC.  BODY must be very careful not to do anything which
3126could cause an exception (note that attempting to allocate lisp memory
3127may cause an exception.)"
3128  `(let* ((*interrupt-level* -2))
3129    ,@body))
3130
3131(defmacro allowing-deferred-gc (&body body)
3132  "Within the extent of a surrounding WITH-DEFERRED-GC, allow GC."
3133  `(let* ((*interrupt-level* -1))
3134    (%check-deferred-gc)
3135    ,@body))
3136
3137(defmacro defer-gc ()
3138  `(setq *interrupt-level* -2))
3139
3140
3141(defmacro with-pointer-to-ivector ((ptr ivector) &body body)
3142  "Executes BODY with PTR bound to a pointer to the first byte of data
3143in IVECTOR.  The GC is disabled during execution of BODY; PTR has
3144has dynamic-extent (and the address it references may become invalid
3145after the BODY exits.)  IVECTOR should be a (SIMPLE-ARRAY (*)) whose
3146element-type is numeric."
3147  (let* ((v (gensym)))
3148    `(let* ((,v ,ivector))
3149       (unless (typep ,v 'ivector) (report-bad-arg ,v 'ivector))
3150       (without-gcing
3151         (with-macptrs ((,ptr))
3152           (%vect-data-to-macptr ,v ,ptr)
3153           ,@body)))))
3154     
3155
3156
3157(defmacro with-other-threads-suspended (&body body)
3158  `(unwind-protect
3159    (progn
3160      (%suspend-other-threads)
3161      ,@body)
3162    (%resume-other-threads)))
3163
3164(defmacro with-package-read-lock ((p) &body body)
3165  `(with-read-lock ((pkg.lock ,p)) ,@body))
3166
3167(defmacro with-package-write-lock ((p) &body body)
3168  `(with-write-lock ((pkg.lock ,p)) ,@body))
3169
3170(defmacro with-package-lock ((p) &body body)
3171  `(with-package-write-lock (,p) ,@body))
3172
3173;;; Lock %all-packages-lock%, for shared read access to %all-packages%
3174
3175(defmacro with-package-list-read-lock (&body body)
3176  `(with-read-lock (%all-packages-lock%) ,@body))
3177
3178;;; Lock %all-packages-lock%, to allow modification to %all-packages%
3179(defmacro with-package-list-write-lock (&body body)
3180  `(with-write-lock (%all-packages-lock%) ,@body))
3181
3182(defmacro atomic-incf-decf (place delta &environment env)
3183  (setq place (macroexpand place env))
3184  (if (consp place)
3185    (let* ((sym (car place))
3186           (struct-transform (or (environment-structref-info sym env)
3187                                 (gethash sym %structure-refs%))))
3188      (if struct-transform
3189        (setq place (defstruct-ref-transform struct-transform (cdr place))
3190              sym (car place)))
3191      (ecase sym
3192        (the `(the ,(cadr place) (atomic-incf-decf ,(caddr place) ,delta)))
3193         ;; Needed so can handle %svref (which macroexpands into a LET*)
3194         ((let let*) (multiple-value-bind (body decls) (parse-body (cddr place) env t)
3195                       (unless (eql (length body) 1)
3196                         (error "~S is not a valid atomic-incf/decf place" place))
3197                       `(,sym ,(cadr place) ,@decls (atomic-incf-decf ,@body ,delta))))
3198         ;; Ditto
3199         (locally (multiple-value-bind (body decls) (parse-body (cdr place) env t)
3200                    (unless (eql (length body) 1)
3201                      (error "~S is not a valid atomic-incf/decf place" place))
3202                    `(,sym ,@decls (atomic-incf-decf ,@body ,delta))))
3203        (car `(%atomic-incf-car ,(cadr place) ,delta))
3204        (cdr `(%atomic-incf-cdr ,(cadr place) ,delta))
3205        (svref `(%atomic-incf-gvector ,@(cdr place) ,delta))))
3206    (if (and (symbolp place) (eq :special (variable-information place env)))
3207      (let* ((base (gensym))
3208             (offset (gensym)))
3209        `(multiple-value-bind (,base ,offset)
3210          (%symbol-binding-address ',place)
3211          (%atomic-incf-node ,delta ,base ,offset)))
3212      (signal-program-error "~S is not a special variable"  place))))
3213   
3214(defmacro atomic-incf (place)
3215  `(atomic-incf-decf ,place 1))
3216
3217(defmacro atomic-decf (place)
3218  `(atomic-incf-decf ,place -1))
3219
3220; Some of these macros were stolen from CMUCL.  Sort of ...
3221
3222(defmacro iterate (name binds &body body)
3223  "Iterate Name ({(Var Initial-Value)}*) Declaration* Form*
3224  This is syntactic sugar for Labels.  It creates a local function Name with
3225  the specified Vars as its arguments and the Declarations and Forms as its
3226  body.  This function is then called with the Initial-Values, and the result
3227  of the call is return from the macro."
3228  (dolist (x binds)
3229    (unless (and (listp x)
3230                 (= (length x) 2))
3231      (signal-program-error "Malformed iterate variable spec: ~S." x)))
3232
3233  `(labels ((,name ,(mapcar #'first binds) ,@body))
3234     (,name ,@(mapcar #'second binds))))
3235
3236;;;; The Collect macro:
3237
3238;;; Collect-Normal-Expander  --  Internal
3239;;;
3240;;;    This function does the real work of macroexpansion for normal collection
3241;;; macros.  N-Value is the name of the variable which holds the current
3242;;; value.  Fun is the function which does collection.  Forms is the list of
3243;;; forms whose values we are supposed to collect.
3244;;;
3245(eval-when (:compile-toplevel :load-toplevel :execute)
3246
3247
3248(defun collect-normal-expander (n-value fun forms)
3249  `(progn
3250     ,@(mapcar #'(lambda (form) `(setq ,n-value (,fun ,form ,n-value))) forms)
3251     ,n-value))
3252
3253
3254)
3255
3256(defmacro once-only (specs &body body)
3257  "Once-Only ({(Var Value-Expression)}*) Form*
3258  Create a Let* which evaluates each Value-Expression, binding a temporary
3259  variable to the result, and wrapping the Let* around the result of the
3260  evaluation of Body.  Within the body, each Var is bound to the corresponding
3261  temporary variable."
3262  (iterate frob
3263           ((specs specs)
3264            (body body))
3265    (if (null specs)
3266      `(progn ,@body)
3267      (let ((spec (first specs)))
3268        (when (/= (length spec) 2)
3269          (signal-program-error "Malformed ~s binding spec: ~S." 'once-only spec))
3270        (let ((name (first spec))
3271              (exp-temp (gensym)))
3272          `(let ((,exp-temp ,(second spec))
3273                 (,name (gensym)))
3274             `(let ((,,name ,,exp-temp))
3275                ,,(frob (rest specs) body))))))))
3276
3277(eval-when (:compile-toplevel :load-toplevel :execute)
3278(defun form-symbol (first &rest others)
3279  (intern (apply #'concatenate 'simple-base-string (string first) (mapcar #'string others))))
3280)
3281
3282
3283;;; Collect-List-Expander  --  Internal
3284;;;
3285;;;    This function deals with the list collection case.  N-Tail is the pointer
3286;;; to the current tail of the list, which is NIL if the list is empty.
3287;;;
3288(defun collect-list-expander (n-value n-tail forms)
3289  (let ((n-res (gensym)))
3290    `(progn
3291       ,@(mapcar #'(lambda (form)
3292                     `(let ((,n-res (cons ,form nil)))
3293                        (cond (,n-tail
3294                               (setf (cdr ,n-tail) ,n-res)
3295                               (setq ,n-tail ,n-res))
3296                              (t
3297                               (setq ,n-tail ,n-res  ,n-value ,n-res)))))
3298                 forms)
3299       ,n-value)))
3300
3301;;;
3302;;;    The ultimate collection macro...
3303;;;
3304
3305(defmacro collect (collections &body body)
3306  "Collect ({(Name [Initial-Value] [Function])}*) {Form}*
3307  Collect some values somehow.  Each of the collections specifies a bunch of
3308  things which collected during the evaluation of the body of the form.  The
3309  name of the collection is used to define a local macro, a la MACROLET.
3310  Within the body, this macro will evaluate each of its arguments and collect
3311  the result, returning the current value after the collection is done.  The
3312  body is evaluated as a PROGN; to get the final values when you are done, just
3313  call the collection macro with no arguments.
3314
3315  Initial-Value is the value that the collection starts out with, which
3316  defaults to NIL.  Function is the function which does the collection.  It is
3317  a function which will accept two arguments: the value to be collected and the
3318  current collection.  The result of the function is made the new value for the
3319  collection.  As a totally magical special-case, the Function may be Collect,
3320  which tells us to build a list in forward order; this is the default.  If an
3321  Initial-Value is supplied for Collect, the stuff will be rplacd'd onto the
3322  end.  Note that Function may be anything that can appear in the functional
3323  position, including macros and lambdas."
3324 
3325 
3326  (let ((macros ())
3327        (binds ()))
3328    (dolist (spec collections)
3329      (unless (<= 1 (length spec) 3)
3330        (signal-program-error "Malformed collection specifier: ~S." spec))
3331      (let ((n-value (gensym))
3332            (name (first spec))
3333            (default (second spec))
3334            (kind (or (third spec) 'collect)))
3335       
3336        (push `(,n-value ,default) binds)
3337        (if (eq kind 'collect)
3338          (let ((n-tail (gensym)))
3339            (if default
3340              (push `(,n-tail (last ,n-value)) binds)
3341              (push n-tail binds))
3342            (push `(,name (&rest args)
3343                          (collect-list-expander ',n-value ',n-tail args))
3344                  macros))
3345          (push `(,name (&rest args)
3346                        (collect-normal-expander ',n-value ',kind args))
3347                macros))))
3348    `(macrolet ,macros (let* ,(nreverse binds) (declare (ignorable ,@binds)) ,@body))))
3349
3350
3351;;; DEFENUM -- Internal Interface.
3352;;;
3353(defmacro defenum ((&key (prefix "") (suffix "") (start 0) (step 1))
3354                   &rest identifiers)
3355  (let ((results nil)
3356        (index 0)
3357        (start (eval start))
3358        (step (eval step)))
3359    (dolist (id identifiers)
3360      (multiple-value-bind
3361        (root docs)
3362        (if (consp id)
3363          (values (car id) (cdr id))
3364          (values id nil))
3365        (push `(defconstant ,(intern (concatenate 'simple-base-string
3366                                                  (string prefix)
3367                                                  (string root)
3368                                                  (string suffix)))
3369                 ,(+ start (* step index))
3370                 ,@docs)
3371              results))
3372      (incf index))
3373    `(eval-when (:compile-toplevel :load-toplevel :execute)
3374       ,@(nreverse results))))
3375
3376
3377;;; This does something like special binding, but the "bindings" established
3378;;; aren't thread-specific.
3379
3380(defmacro let-globally ((&rest vars) &body body &environment env)
3381  (multiple-value-bind (body decls) (parse-body body env)
3382    (let* ((initforms nil)
3383           (psetform nil)
3384           (specvars nil)
3385           (restoreform nil))
3386      (flet ((pair-name-value (p)
3387               (if (atom p)
3388                 (values (require-global-symbol p env) nil)
3389                 (if (and (consp (%cdr p)) (null (%cddr p)))
3390                   (values (require-global-symbol (%car p) env) (%cadr p))
3391                   (signal-program-error "Invalid variable initialization form : ~s")))))
3392        (declare (inline pair-name-value))
3393        (dolist (v vars)
3394          (let* ((oldval (gensym))
3395                 (newval (gensym)))
3396            (multiple-value-bind (var valueform) (pair-name-value v)
3397              (push var specvars)
3398              (push var restoreform)
3399              (push oldval restoreform)
3400              (push `(,oldval (uvref (symptr->symvector ',var) #.target::symbol.vcell-cell)) initforms)
3401              (push `(,newval ,valueform) initforms)
3402              (push var psetform)
3403              (push newval psetform))))
3404        `(let ,(nreverse initforms)
3405           ,@decls
3406           (locally (declare (special ,@(nreverse specvars)))
3407             (unwind-protect
3408               (progn (psetq ,@(nreverse psetform)) ,@body)
3409               (psetq ,@(nreverse restoreform)))))))))
3410;;; From CLX.
3411
3412;;; The good news is that this uses an interlocked load/store sequence
3413;;; and is fairly efficient.
3414;;; The bad news is that it only handles a few types of "place" forms.
3415;;; The good news is that CLX only uses a few types of "place" forms.
3416
3417(defmacro conditional-store (place old-value new-value &environment env)
3418  (setq place (macroexpand place env))
3419  (if (atom place)
3420    ;; CLX uses special variables' value cells as place forms.
3421    (if (and (symbolp place)
3422             (eq :special (ccl::variable-information place env)))
3423      (let* ((base (gensym))
3424             (offset (gensym)))
3425        `(multiple-value-bind (,base ,offset)
3426          (ccl::%symbol-binding-address ',place)
3427          (ccl::%store-node-conditional ,offset ,base ,old-value ,new-value)))
3428      (signal-program-error "~s is not a special variable ." place))
3429    (let* ((sym (car place))
3430           (struct-transform (or (ccl::environment-structref-info sym env)
3431                                 (gethash sym ccl::%structure-refs%))))
3432      (if struct-transform
3433        (setq place (ccl::defstruct-ref-transform struct-transform (cdr place))
3434              sym (car place)))
3435      (if (member  sym '(svref ccl::%svref ccl::struct-ref))
3436        (let* ((v (gensym)))
3437          `(let* ((,v ,(cadr place)))
3438            (ccl::store-gvector-conditional ,(caddr place)
3439             ,v ,old-value ,new-value)))
3440        (signal-program-error "Don't know how to do conditional store to ~s" place)))))
3441
3442(defmacro step (form)
3443  "The form is evaluated with single stepping enabled. Function calls
3444outside the lexical scope of the form can be stepped into only if the
3445functions in question have been compiled with sufficient DEBUG policy
3446to be at least partially steppable."
3447  form)
3448
3449(defmacro target-arch-case (&rest clauses)
3450  `(case (backend-target-arch-name *target-backend*)
3451    ,@clauses))
3452
3453(defmacro target-os-case (&rest clauses)
3454  `(ecase (backend-target-os *target-backend*)
3455    ,@clauses))
3456
3457(defmacro target-word-size-case (&rest clauses)
3458  `(ecase (arch::target-nbits-in-word (backend-target-arch *target-backend*))
3459    ,@clauses))
3460
3461(defmacro %get-natural (&body body)
3462  "A free copy of the next OpenMCL release to anyone who remembers Flakey Foont"
3463  (target-word-size-case
3464   (32 `(%get-unsigned-long ,@body))
3465   (64 `(%%get-unsigned-longlong ,@body))))
3466
3467(defmacro %get-signed-natural (&body body)
3468  "And that's my final offer."
3469  (target-word-size-case
3470   (32 `(%get-signed-long ,@body))
3471   (64 `(%%get-signed-longlong ,@body))))
3472
3473(declare-arch-specific-macro %target-kernel-global)
3474
3475;;; This behaves like a function, but looks up the kernel global
3476;;; at compile time if possible. Probably should be done as a function
3477;;; and a compiler macro, but we can't define compiler macros yet,
3478;;; and I don't want to add it to "ccl:compiler;optimizers.lisp"
3479(declare-arch-specific-macro %get-kernel-global)
3480
3481(declare-arch-specific-macro %get-kernel-global-ptr)
3482
3483(declare-arch-specific-macro area-code)
3484
3485(declare-arch-specific-macro nth-immediate)
3486
3487(declare-arch-specific-macro set-nth-immediate)
3488
3489(defsetf nth-immediate set-nth-immediate)
3490
3491(defmacro do-consing-areas ((area) &body body)
3492  (let ((code (gensym)))
3493  `(do-gc-areas (,area)
3494     (let ((,code (%fixnum-ref ,area  (area-code))))
3495       (when (or (eql ,code area-readonly)
3496                 (eql ,code area-managed-static)
3497                 (eql ,code area-static)
3498                 (eql ,code area-dynamic))
3499         ,@body)))))
3500
3501(declare-arch-specific-macro area-succ)
3502
3503(defmacro with-ioblock-lock-grabbed ((lock)
3504                                       &body body)
3505  `(with-lock-grabbed (,lock)
3506    ,@body))
3507
3508(defmacro with-ioblock-lock-grabbed-maybe ((lock)
3509                                           &body body)
3510  `(with-lock-grabbed-maybe (,lock)
3511    ,@body))
3512
3513
3514(defmacro do-gc-areas ((area) &body body)
3515  (let ((initial-area (gensym)))
3516    `(let* ((,initial-area (%get-kernel-global 'all-areas))
3517            (,area ,initial-area))
3518       (declare (fixnum ,initial-area ,area))
3519       (loop
3520         (setq ,area (%fixnum-ref ,area (area-succ)))
3521         (when (eql ,area ,initial-area)
3522           (return))
3523         ,@body))))
3524
3525(defmacro with-ioblock-input-lock-grabbed ((ioblock) &body body)
3526  `(with-lock-grabbed ((ioblock-inbuf-lock ,ioblock))
3527    ,@body))
3528
3529(defmacro with-ioblock-output-lock-grabbed ((ioblock) &body body)
3530  `(with-lock-grabbed ((ioblock-outbuf-lock ,ioblock))
3531    ,@body))
3532 
3533
3534(defmacro with-stream-ioblock-input ((ioblock stream &key
3535                                             speedy)
3536                                  &body body)
3537  `(let ((,ioblock (stream-ioblock ,stream t)))
3538     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3539     (with-ioblock-input-locked (,ioblock) ,@body)))
3540
3541(defmacro with-stream-ioblock-output ((ioblock stream &key
3542                                             speedy)
3543                                  &body body)
3544  `(let ((,ioblock (stream-ioblock ,stream t)))
3545     ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3546     (with-ioblock-output-locked (,ioblock) ,@body)))
3547
3548(defmacro with-stream-ioblock-output-maybe ((ioblock stream &key
3549                                                     speedy)
3550                                            &body body)
3551  `(let ((,ioblock (stream-ioblock ,stream t)))
3552    ,@(when speedy `((declare (optimize (speed 3) (safety 0)))))
3553    (with-ioblock-output-locked-maybe (,ioblock) ,@body)))
3554
3555(defmacro with-ioblock-input-locked ((ioblock) &body body)
3556  (let* ((lock (gensym)))
3557    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3558                                  (ioblock-inbuf-lock ,ioblock))))
3559      (if ,lock
3560        (with-lock-grabbed (,lock)
3561          ,@body)
3562        (progn
3563          (check-ioblock-owner ,ioblock)
3564          ,@body)))))
3565
3566(defmacro with-ioblock-output-locked ((ioblock) &body body)
3567  (let* ((lock (gensym)))
3568    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3569                                  (ioblock-outbuf-lock ,ioblock))))
3570      (if ,lock
3571        (with-lock-grabbed (,lock)
3572          ,@body)
3573        (progn
3574          (check-ioblock-owner ,ioblock)
3575          ,@body)))))
3576
3577
3578
3579(defmacro with-ioblock-output-locked-maybe ((ioblock) &body body)
3580  (let* ((lock (gensym)))
3581    `(let* ((,lock (locally (declare (optimize (speed 3) (safety 0)))
3582                                  (ioblock-outbuf-lock ,ioblock))))
3583      (if ,lock
3584        (with-lock-grabbed-maybe (,lock)
3585          ,@body)
3586        (progn
3587          (check-ioblock-owner ,ioblock)
3588          ,@body)))))
3589
3590;;; Use this when it's possible that the fd might be in
3591;;; a non-blocking state.  Body must return a negative of
3592;;; the os error number on failure.
3593;;; The use of READ-FROM-STRING below is certainly ugly, but macros
3594;;; that expand into reader-macros don't generally trigger the reader-macro's
3595;;; side-effects.  (Besides, the reader-macro might return a different
3596;;; value when the macro function is expanded than it did when the macro
3597;;; function was defined; this can happen during cross-compilation.)
3598(defmacro with-eagain (fd direction &body body)
3599  (let* ((res (gensym))
3600         (eagain (symbol-value (read-from-string "#$EAGAIN"))))
3601   `(loop
3602      (let ((,res (progn ,@body)))
3603        (if (eql ,res (- ,eagain))
3604          (,(ecase direction
3605             (:input 'process-input-wait)
3606             (:output 'process-output-wait))
3607           ,fd)
3608          (return ,res))))))
3609
3610(defmacro ignoring-eintr (&body body)
3611  (let* ((res (gensym))
3612         (eintr (symbol-value (read-from-string "#$EINTR"))))
3613    `(loop
3614       (let* ((,res (progn ,@body)))
3615         (unless (eql ,res (- ,eintr))
3616           (return ,res))))))
3617
3618(defmacro ff-call-ignoring-eintr (&body body)
3619  (let* ((res (gensym))
3620         (eintr (symbol-value (read-from-string "#$EINTR"))))
3621    `(loop
3622       (let* ((,res (progn ,@body)))
3623         (declare (fixnum ,res))
3624         (when (< ,res 0)
3625           (setq ,res (%get-errno)))
3626         (unless (eql ,res (- ,eintr))
3627           (return ,res))))))
3628   
3629
3630(defmacro basic-stream-ioblock (s)
3631  `(or (basic-stream.state ,s)
3632    (stream-is-closed ,s)))
3633
3634(defsetf interrupt-level set-interrupt-level)
3635
3636(defmacro %swap-u16 (val)
3637  (let* ((arg (gensym)))
3638    `(let* ((,arg ,val))
3639      (declare (type (unsigned-byte 16) ,arg))
3640      (logand #xffff (the fixnum (logior (the fixnum (ash ,arg -8))
3641                                         (the fixnum (ash ,arg 8))))))))
3642
3643(defmacro %swap-u32 (val)
3644  (let* ((arg (gensym)))
3645    `(let ((,arg ,val))
3646      (declare (type (unsigned-byte 32) ,arg))
3647      (the (unsigned-byte 32) (logior (the (unsigned-byte 32)
3648                                        (ash (logand #xff ,arg) 24))
3649                                      (the (unsigned-byte 24)
3650                                        (logior
3651                                         (the (unsigned-byte 24) (ash (logand #xff00 ,arg) 8))
3652                                         (the (unsigned-byte 16)
3653                                           (logior
3654                                            (the (unsigned-byte 16) (ash (logand #xff0000 ,arg) -8))
3655                                            (the (unsigned-byte 8) (ash ,arg -24)))))))))))
3656   
3657
3658(defmacro multiple-value-bind (varlist values-form &body body &environment env)
3659  (multiple-value-bind (body decls)
3660                       (parse-body body env)
3661    (let ((ignore (make-symbol "IGNORE")))
3662      `(multiple-value-call #'(lambda (&optional ,@varlist &rest ,ignore)
3663                                (declare (ignore ,ignore))
3664                                ,@decls
3665                                ,@body)
3666                            ,values-form))))
3667
3668(defmacro multiple-value-setq (vars val)
3669  (if vars
3670    `(values (setf (values ,@(mapcar #'(lambda (s) (require-type s 'symbol)) vars))  ,val))
3671    `(prog1 ,val)))
3672
3673(defmacro nth-value (n form)
3674  "Evaluate FORM and return the Nth value (zero based). This involves no
3675  consing when N is a trivial constant integer."
3676  `(car (nthcdr ,n (multiple-value-list ,form))))
3677
3678
3679
3680(defmacro with-input-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3681  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3682stream-input-timeout set to TIMEOUT."
3683  (let* ((old-input-timeout (gensym))
3684         (stream (gensym)))
3685    `(let* ((,stream ,stream-form)
3686            (,stream-var ,stream)
3687            (,old-input-timeout (stream-input-timeout ,stream)))
3688      (unwind-protect
3689           (progn
3690             (setf (stream-input-timeout ,stream) ,timeout)
3691             ,@body)
3692        (setf (stream-input-timeout ,stream) ,old-input-timeout)))))
3693
3694(defmacro with-output-timeout (((stream-var &optional (stream-form stream-var)) timeout) &body body)
3695  "Execute body with STREAM-VAR bound to STREAM-FORM and with that stream's
3696stream-output-timeout set to TIMEOUT."
3697  (let* ((old-output-timeout (gensym))
3698         (stream (gensym)))
3699    `(let* ((,stream ,stream-form)
3700            (,stream-var ,stream)
3701            (,old-output-timeout (stream-output-timeout ,stream)))
3702      (unwind-protect
3703           (progn
3704             (setf (stream-output-timeout ,stream) ,timeout)
3705             ,@body)
3706        (setf (stream-output-timeout ,stream) ,old-output-timeout)))))
3707
3708;;; FORM returns a signed integer.  If it's non-negative, return that
3709;;; value, otherwise, return the (negative) errnor value returned by
3710;;; %GET-ERRNO
3711(defmacro int-errno-call (form)
3712  (let* ((value (gensym)))
3713    `(let* ((,value ,form))
3714      (if (< ,value 0)
3715        (%get-errno)
3716        ,value))))
3717
3718(defmacro int-errno-ffcall (entry &rest args)
3719  `(int-errno-call (ff-call ,entry ,@args)))
Note: See TracBrowser for help on using the repository browser.