source: branches/working-0711/ccl/level-1/sysutils.lisp @ 8769

Last change on this file since 8769 was 8769, checked in by gb, 13 years ago

Use an INDENTING-STRING-OUTPUT-STREAM in SIGNAL-COMPILER-WARNING.
to better deal with multiline output.

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 23.7 KB
Line 
1;;;-*-Mode: LISP; Package: CCL -*-
2;;;
3;;;   Copyright (C) 1994-2001 Digitool, Inc
4;;;   This file is part of OpenMCL. 
5;;;
6;;;   OpenMCL is licensed under the terms of the Lisp Lesser GNU Public
7;;;   License , known as the LLGPL and distributed with OpenMCL as the
8;;;   file "LICENSE".  The LLGPL consists of a preamble and the LGPL,
9;;;   which is distributed with OpenMCL as the file "LGPL".  Where these
10;;;   conflict, the preamble takes precedence. 
11;;;
12;;;   OpenMCL is referenced in the preamble as the "LIBRARY."
13;;;
14;;;   The LLGPL is also available online at
15;;;   http://opensource.franz.com/preamble.html
16
17
18;; sysutils.lisp - things which have outgrown l1-utils
19
20(in-package "CCL")
21
22(eval-when (:execute :compile-toplevel)
23  (require 'level-2)
24  (require 'optimizers)
25  (require 'backquote)
26  (require 'defstruct-macros)
27  )
28
29;;; things might be clearer if this stuff were in l1-typesys?
30;;; Translation from type keywords to specific predicates.
31(eval-when (:execute :compile-toplevel)
32
33(defconstant type-pred-pairs
34  '((array . arrayp)
35    (atom . atom)
36    (base-string . base-string-p)
37    (bignum . bignump)
38    (bit . bitp)
39    (bit-vector . bit-vector-p)
40    (character . characterp)
41    (compiled-function . compiled-function-p)
42    (complex . complexp)
43    (cons . consp)
44    (double-float . double-float-p)
45    (fixnum . fixnump) ;not cl
46    (float . floatp)
47    (function . functionp)
48    (hash-table . hash-table-p)
49    (integer . integerp)
50    (real . realp)
51    (keyword . keywordp)
52    (list . listp)
53    (long-float . double-float-p)
54    (nil . false)
55    (null . null)
56    (number . numberp)
57    (package . packagep)
58    (pathname . pathnamep)
59    (logical-pathname . logical-pathname-p)
60    (random-state . random-state-p)
61    (ratio . ratiop)
62    (rational . rationalp)
63    (readtable . readtablep)
64    (sequence . sequencep)
65    (short-float . short-float-p)
66    (signed-byte . integerp)
67    (simple-array . simple-array-p)
68    (simple-base-string . simple-base-string-p)
69    (simple-extended-string . simple-extended-string-p)
70    (simple-bit-vector . simple-bit-vector-p)
71    (simple-string . simple-string-p)
72    (simple-vector . simple-vector-p)
73    (single-float . short-float-p)
74    (stream . streamp)
75    (string . stringp)
76    (extended-string . extended-string-p)
77    (base-char . base-char-p)
78    (extended-char . extended-char-p)
79    (structure-object . structurep)
80    (symbol . symbolp)
81    (t . true)
82    (unsigned-byte . unsigned-byte-p)
83    (vector . vectorp)
84    ))
85
86(defmacro init-type-predicates ()
87  `(dolist (pair ',type-pred-pairs)
88     (setf (type-predicate (car pair)) (cdr pair))
89     (let ((ctype (info-type-builtin (car pair))))       
90       (if (typep ctype 'numeric-ctype)
91         (setf (numeric-ctype-predicate ctype) (cdr pair))))))
92
93)
94
95(init-type-predicates)
96
97(defun unsigned-byte-8-p (n)
98  (and (fixnump n)
99       (locally (declare (fixnum n))
100         (and 
101          (>= n 0)
102          (< n #x100)))))
103
104(defun signed-byte-8-p (n)
105  (and (fixnump n)
106       (locally (declare (fixnum n))
107         (and 
108          (>= n -128)
109          (<= n 127)))))
110
111(defun unsigned-byte-16-p (n)
112  (and (fixnump n)
113       (locally (declare (fixnum n))
114         (and 
115          (>= n 0)
116          (< n #x10000)))))
117
118(defun signed-byte-16-p (n)
119  (and (fixnump n)
120       (locally (declare (fixnum n))
121         (and 
122          (>= n -32768)
123          (<= n 32767)))))
124
125(defun unsigned-byte-32-p (n)
126  (and (integerp n)
127       (>= n 0)
128       (<= n #xffffffff)))
129
130(defun signed-byte-32-p (n)
131  (and (integerp n)
132       (>= n  -2147483648)
133       (<= n 2147483647)))
134
135(eval-when (:load-toplevel :execute)
136  (let ((more-pairs
137         '(((unsigned-byte 8) . unsigned-byte-8-p)
138           ((signed-byte 8) . signed-byte-8-p)
139           ((unsigned-byte 16) . unsigned-byte-16-p)
140           ((signed-byte 16) . signed-byte-16-p)
141           ((unsigned-byte 32) . unsigned-byte-32-p)
142           ((signed-byte 32) . signed-byte-32-p))))         
143    (dolist (pair more-pairs)
144      (let ((ctype (info-type-builtin (car pair))))       
145        (if (typep ctype 'numeric-ctype) (setf (numeric-ctype-predicate ctype) (cdr pair))))))
146  )
147
148
149(defun specifier-type-known (type) 
150  (let ((ctype (specifier-type type)))
151    (if (typep ctype 'unknown-ctype)
152      (error "Unknown type specifier ~s." type)
153      (if (and (typep ctype 'numeric-ctype) ; complexp??
154               (eq 'integer (numeric-ctype-class ctype))
155               (not (numeric-ctype-predicate ctype)))
156        (setf (numeric-ctype-predicate ctype)(make-numeric-ctype-predicate ctype))))
157    ctype))
158
159
160(defun find-builtin-cell (type  &optional (create t))
161  (let ((cell (gethash type %builtin-type-cells%)))
162    (or cell
163        (when create
164          (setf (gethash type %builtin-type-cells%)
165                (cons type (or (info-type-builtin type)(specifier-type-known type))))))))
166
167
168; for now only called for builtin types or car = unsigned-byte, signed-byte, mod or integer
169
170(defun builtin-typep (form cell)
171  (unless (listp cell)
172    (setq cell (require-type cell 'list)))
173  (locally (declare (type list cell))
174    (let ((ctype (cdr cell))
175          (name (car cell)))
176      (when (not ctype)
177        (setq ctype (or (info-type-builtin name)(specifier-type-known name)))
178        (when ctype (setf (gethash (car cell) %builtin-type-cells%) cell))
179        (rplacd cell ctype))
180      (if ctype 
181        (if (and (typep ctype 'numeric-ctype)
182                 (numeric-ctype-predicate ctype))
183          ; doing this inline is a winner - at least if true
184          (funcall (numeric-ctype-predicate ctype) form)
185          (%%typep form ctype))
186        (typep form name)))))
187
188#|
189(defvar %find-classes% (make-hash-table :test 'eq))
190
191(defun find-class-cell (name create?)
192  (let ((cell (gethash name %find-classes%)))
193    (or cell
194        (and create?
195             (setf (gethash name %find-classes%) (cons name nil))))))
196|#
197
198;(setq *type-system-initialized* t)
199
200
201;; Type-of, typep, and a bunch of other predicates.
202
203;;; Data type predicates.
204
205;;; things might be clearer if this stuff were in l1-typesys?
206;;; Translation from type keywords to specific predicates.
207
208
209
210
211;necessary since standard-char-p, by definition, errors if not passed a char.
212(setf (type-predicate 'standard-char)
213      #'(lambda (form) (and (characterp form) (standard-char-p form))))
214
215(defun type-of (form)
216  "Return the type of OBJECT."
217  (case form
218    ((t) 'boolean)
219    ((0 1) 'bit)
220    (t
221     (typecase form
222       (standard-char 'standard-char)
223       (keyword 'keyword)
224       ;; Partition integers so that the negative cases
225       ;; are SIGNED-BYTE and the positive are UNSIGNED-BYTE
226       (fixnum
227        (if (< (the fixnum form) 0)
228          'fixnum
229          '(integer 0 #.target::target-most-positive-fixnum)))
230       (bignum
231        (if (< form 0)
232          'bignum
233          '(integer  #.(1+ target::target-most-positive-fixnum))))
234       ((or array complex) (type-specifier (ctype-of form)))
235       (t
236        (if (eql (typecode form) target::subtag-istruct)
237          (%svref form 0)
238          (let* ((class (class-of form))
239                 (class-name (class-name class)))
240            (if (eq class (find-class class-name nil))
241              class-name
242              class))))))))
243
244;;; Create the list-style description of an array.
245
246;made more specific by fry. slisp used  (mod 2) , etc.
247;Oh.
248; As much fun as this has been, I think it'd be really neat if
249; it returned a type specifier.
250
251(defun describe-array (array)
252  (if (arrayp array)
253    (type-specifier
254     (specifier-type
255      `(,(if (simple-array-p array) 'simple-array 'array) 
256        ,(array-element-type array) 
257        ,(array-dimensions array))))
258    (report-bad-arg array 'array)))
259 
260
261;;;; TYPEP and auxiliary functions.
262
263
264
265(defun type-specifier-p (form &aux sym)
266  (cond ((symbolp form)
267         (or (type-predicate form)
268             (structure-class-p form)
269             (%deftype-expander form)
270             (find-class form nil)
271             ))
272        ((consp form)
273         (setq sym (%car form))
274         (or (type-specifier-p sym)
275             (memq sym '(member satisfies mod))
276             (and (memq sym '(and or not))
277                  (dolist (spec (%cdr form) t)
278                    (unless (type-specifier-p spec) (return nil))))))
279        (t (typep form 'class))))
280
281(defun built-in-type-p (type)
282  (if (symbolp type)
283    (or (type-predicate type)
284        (let ((class (find-class type nil)))
285          (and class (typep class 'built-in-class))))
286    (and (consp type)
287         (or (and (memq (%car type) '(and or not))
288                  (every #'built-in-type-p (%cdr type)))
289             (memq (%car type) '(array simple-array vector simple-vector
290                                 string simple-string bit-vector simple-bit-vector 
291                                 complex integer mod signed-byte unsigned-byte
292                                 rational float short-float single-float
293                                 double-float long-float real member))))))
294
295(defun typep (object type &optional env)
296  "Is OBJECT of type TYPE?"
297  (declare (ignore env))
298  (let* ((pred (if (symbolp type) (type-predicate type))))
299    (if pred
300      (funcall pred object)
301      (values (%typep object type)))))
302
303
304
305;;; This is like check-type, except it returns the value rather than setf'ing
306;;; anything, and so can be done entirely out-of-line.
307(defun require-type (arg type)
308  (multiple-value-bind (win sure)
309      (ctypep  arg (specifier-type type))
310    (if (or win (not sure))
311      arg
312      (%kernel-restart $xwrongtype arg type))))
313
314;;; Might want to use an inverted mapping instead of (satisfies ccl::obscurely-named)
315(defun %require-type (arg predsym)
316  (if (funcall predsym arg)
317    arg
318    (%kernel-restart $xwrongtype arg (type-for-predicate predsym))))
319
320(defun %require-type-builtin (arg type-cell) 
321  (if (builtin-typep arg type-cell)
322    arg
323    (%kernel-restart $xwrongtype arg (car type-cell))))
324
325
326
327;;; In lieu of an inverted mapping, at least try to find cases involving
328;;; builtin numeric types and predicates associated with them.
329(defun type-for-predicate (pred)
330  (or (block find
331        (maphash #'(lambda (type ctype) (when (and (typep ctype 'numeric-ctype)
332                                                   (eq (numeric-ctype-predicate ctype)
333                                                       pred))
334                                          (return-from find type)))
335                 *builtin-type-info*))
336      `(satisfies ,pred)))
337
338
339
340; Subtypep.
341
342(defun subtypep (type1 type2 &optional env)
343  (declare (ignore env))
344  "Return two values indicating the relationship between type1 and type2.
345  If values are T and T, type1 definitely is a subtype of type2.
346  If values are NIL and T, type1 definitely is not a subtype of type2.
347  If values are NIL and NIL, it couldn't be determined."
348  (csubtypep (specifier-type type1) (specifier-type type2)))
349
350
351
352
353(defun preload-all-functions ()
354  nil)
355
356
357 ; used by arglist
358(defun temp-cons (a b)
359  (cons a b))
360
361
362
363
364(defun copy-into-float (src dest)
365  (%copy-double-float src dest))
366
367(queue-fixup
368 (defun fmakunbound (name)
369   "Make NAME have no global function definition."
370   (let* ((fname (validate-function-name name)))
371     (remhash fname %structure-refs%)
372     (%unfhave fname))
373   name))
374
375(defun frozen-definition-p (name)
376  (if (symbolp name)
377    (%ilogbitp $sym_fbit_frozen (%symbol-bits name))))
378
379(defun redefine-kernel-function (name)
380  (when (and *warn-if-redefine-kernel*
381             (frozen-definition-p name)
382             (or (lfunp (fboundp name))
383                 (and (not (consp name)) (macro-function name)))
384             (or (and (consp name) (neq (car name) 'setf))
385                 (let ((pkg (symbol-package (if (consp name) (cadr name) name))))
386                   (or (eq *common-lisp-package* pkg) (eq *ccl-package* pkg)))))
387    (cerror "Replace the definition of ~S."
388            "The function ~S is predefined in OpenMCL." name)
389    (unless (consp name)
390      (proclaim-inline nil name))))
391
392(defun fset (name function)
393  (setq function (require-type function 'function))
394  (when (symbolp name)
395    (when (special-operator-p name)
396      (error "Can not redefine a special-form: ~S ." name))
397    (when (macro-function name)
398      (cerror "Redefine the macro ~S as a function"
399              "The macro ~S is being redefined as a function." name)))
400; This lets us redefine %FHAVE.  Big fun.
401  (let ((fhave #'%fhave))
402    (redefine-kernel-function name)
403    (fmakunbound name)
404    (funcall fhave name function)
405    function))
406
407(defsetf symbol-function fset)
408(defsetf fdefinition fset)
409
410(defun (setf macro-function) (macro-fun name &optional env)
411  (declare (ignore env))
412  (unless (typep macro-fun 'function)
413    (report-bad-arg macro-fun 'function))
414  (if (special-operator-p name)
415    (error "Can not redefine a special-form: ~S ." name))
416  (when (and (fboundp name) (not (macro-function name)))
417    (warn "The function ~S is being redefined as a macro." name))
418  (redefine-kernel-function name)
419  (fmakunbound name)
420  (%macro-have name macro-fun)
421  macro-fun)
422
423(defun set-macro-function (name def)
424  (setf (macro-function name) def))
425
426
427
428
429;;; Arrays and vectors, including make-array.
430
431
432
433
434
435
436
437(defun char (string index)
438  "Given a string and a non-negative integer index less than the length of
439  the string, returns the character object representing the character at
440  that position in the string."
441  (if (typep string 'simple-string)
442    (schar (the simple-string string) index)
443    (if (stringp string)
444      (multiple-value-bind (data offset) (array-data-and-offset string)
445        (schar (the simple-string data) (+ index offset)))
446      (report-bad-arg string 'string))))
447
448(defun set-char (string index new-el)
449  (if (typep string 'simple-string)
450    (setf (schar string index) new-el)
451    (if (stringp string)
452      (multiple-value-bind (data offset) (array-data-and-offset string)
453        (setf (schar (the simple-string data) (+ index offset)) new-el))
454      (report-bad-arg string 'string))))
455
456(defun equalp (x y)
457  "Just like EQUAL, but more liberal in several respects.
458  Numbers may be of different types, as long as the values are identical
459  after coercion.  Characters may differ in alphabetic case.  Vectors and
460  arrays must have identical dimensions and EQUALP elements, but may differ
461  in their type restriction.
462  If one of x or y is a pathname and one is a string with the name of the
463  pathname then this will return T."
464  (cond ((eql x y) t)
465        ((characterp x) (and (characterp y) (eq (char-upcase x) (char-upcase y))))
466        ((numberp x) (and (numberp y) (= x y)))
467        ((consp x)
468         (and (consp y)
469              (equalp (car x) (car y))
470              (equalp (cdr x) (cdr y))))       
471        ((pathnamep x) (equal x y))
472        ((vectorp x)
473         (and (vectorp y)
474              (let ((length (length x)))
475                (when (eq length (length y))
476                  (dotimes (i length t)
477                    (declare (fixnum i))
478                    (let ((x-el (aref x i))
479                          (y-el (aref y i)))
480                      (unless (or (eq x-el y-el) (equalp x-el y-el))
481                        (return nil))))))))
482        ((arrayp x)
483         (and (arrayp y)
484              (let ((rank (array-rank x)) x-el y-el)
485                (and (eq (array-rank y) rank)
486                     (if (%izerop rank) (equalp (aref x) (aref y))
487                         (and
488                          (dotimes (i rank t)
489                            (declare (fixnum i))
490                            (unless (eq (array-dimension x i)
491                                        (array-dimension y i))
492                              (return nil)))
493                          (multiple-value-bind (x0 i) (array-data-and-offset x)
494                            (multiple-value-bind (y0 j) (array-data-and-offset y)
495                              (dotimes (count (array-total-size x) t)
496                                (declare (fixnum count))
497                                (setq x-el (uvref x0 i) y-el (uvref y0 j))
498                                (unless (or (eq x-el y-el) (equalp x-el y-el))
499                                  (return nil))
500                                (setq i (%i+ i 1) j (%i+ j 1)))))))))))
501        ((and (structurep x) (structurep y))
502         (let ((size (uvsize x)))
503           (and (eq size (uvsize y))
504                (dotimes (i size t)
505                  (declare (fixnum i))
506                  (unless (equalp (uvref x i) (uvref y i))
507                    (return nil))))))
508        ((and (hash-table-p x) (hash-table-p y))
509         (%hash-table-equalp x y))
510        (t nil)))
511
512
513; The compiler (or some transforms) might want to do something more interesting
514; with these, but they have to exist as functions anyhow.
515
516
517
518(defun complement (function)
519  "Return a new function that returns T whenever FUNCTION returns NIL and
520   NIL whenever FUNCTION returns non-NIL."
521  (let ((f (coerce-to-function function))) ; keep poor compiler from consing value cell
522  #'(lambda (&rest args)
523      (declare (dynamic-extent args)) ; not tail-recursive anyway
524      (not (apply f args)))))
525
526; Special variables are evil, but I can't think of a better way to do this.
527
528(defparameter *outstanding-deferred-warnings* nil)
529(def-accessors (deferred-warnings) %svref
530  nil
531  deferred-warnings.parent
532  deferred-warnings.warnings
533  deferred-warnings.defs
534  deferred-warnings.flags ; might use to distinguish interactive case/compile-file
535)
536
537(defun %defer-warnings (override &optional flags)
538  (%istruct 'deferred-warnings (unless override *outstanding-deferred-warnings*) nil nil flags))
539
540(defun report-deferred-warnings ()
541  (let* ((current *outstanding-deferred-warnings*)
542         (parent (deferred-warnings.parent current))
543         (defs (deferred-warnings.defs current))
544         (warnings (deferred-warnings.warnings current))
545         (any nil)
546         (harsh nil))
547    (if parent
548      (setf (deferred-warnings.warnings parent) (append warnings (deferred-warnings.warnings parent))
549            (deferred-warnings.defs parent) (append defs (deferred-warnings.defs parent))
550            parent t)
551      (let* ((file nil)
552             (init t))
553        (dolist (w warnings)
554          (let ((wfname (car (compiler-warning-args w))))
555            (when (if (typep w 'undefined-function-reference)
556                    (not (or (fboundp wfname)
557                             (assq wfname defs))))
558              (multiple-value-setq (harsh any file) (signal-compiler-warning w init file harsh any))
559              (setq init nil))))))
560    (values any harsh parent)))
561
562(defun print-nested-name (name-list stream)
563  (if (null name-list)
564    (princ "a toplevel form" stream)
565    (progn
566      (if (car name-list)
567        (prin1 (%car name-list) stream)
568        (princ "an anonymous lambda form" stream))
569      (when (%cdr name-list)
570        (princ " inside " stream)
571        (print-nested-name (%cdr name-list) stream)))))
572
573(defparameter *suppress-compiler-warnings* nil)
574
575(defun signal-compiler-warning (w init-p last-w-file harsh-p any-p &optional eval-p)
576  (let ((muffled *suppress-compiler-warnings*)
577        (w-file (compiler-warning-file-name w))
578        (s *error-output*))
579    (unless muffled 
580      (restart-case (signal w)
581        (muffle-warning () (setq muffled t))))
582    (unless muffled
583      (setq any-p t)
584      (unless (typep w 'style-warning) (setq harsh-p t))
585      (when (or init-p (not (equalp w-file last-w-file)))
586        (format s "~&;~A warnings " (if (null eval-p) "Compiler" "Interpreter"))
587        (if w-file (format s "for ~S :" w-file) (princ ":" s)))
588      (let* ((indenting-stream (make-indenting-string-output-stream #\; 4)))
589        (format indenting-stream "~%~a" w)
590        (format s "~a" (get-output-stream-string indenting-stream))))
591    (values harsh-p any-p w-file)))
592
593;;;; Assorted mumble-P type predicates.
594;;;; No functions have been in the kernel for the last year or so.
595;;;; (Just thought you'd like to know.)
596
597(defun sequencep (form)
598  "Not CL. SLISP Returns T if form is a sequence, NIL otherwise."
599   (or (listp form) (vectorp form)))
600
601;;; The following are not defined at user level, but are necessary for
602;;; internal use by TYPEP.
603
604(defun bitp (form)
605  "Not CL. SLISP"
606  (or (eq form 0) (eq form 1)))
607
608(defun unsigned-byte-p (form)
609  (and (integerp form) (not (< form 0))))
610
611;This is false for internal structures.
612;;; ---- look at defenv.structures, not defenv.structrefs
613
614(defun structure-class-p (form &optional env)
615  (and (symbolp form)
616       (let ((sd (or (and env
617                          (let ((defenv (definition-environment env)))
618                            (and defenv
619                                 (%cdr (assq form (defenv.structures defenv))))))
620                     (gethash form %defstructs%))))
621         (and sd
622              (null (sd-type sd))
623              sd))))
624
625
626
627
628
629(defun type-keyword-code (type-keyword &optional target)
630  (let* ((backend (if target (find-backend target) *target-backend*))
631         (alist (arch::target-uvector-subtags (backend-target-arch backend)))
632         (entry (assq type-keyword alist)))
633    (if entry
634      (let* ((code (cdr entry)))
635        (or code (error "Vector type ~s invalid," type-keyword)))
636      (error "Unknown type-keyword ~s. " type-keyword))))
637
638
639(defstruct id-map
640  (vector (make-array 1 :initial-element nil))
641  (free 0)
642  (lock (make-lock)))
643
644;;; Caller owns the lock on the id-map.
645(defun id-map-grow (id-map)
646  (without-interrupts
647   (let* ((old-vector (id-map-vector id-map))
648          (old-size (length old-vector))
649          (new-size (+ old-size old-size))
650          (new-vector (make-array new-size)))
651     (declare (fixnum old-size new-size))
652     (dotimes (i old-size)
653       (setf (svref new-vector i) (svref old-vector i)))
654     (let* ((limit (1- new-size)))
655       (declare (fixnum limit))
656       (do* ((i old-size (1+ i)))
657            ((= i limit) (setf (svref new-vector i) nil))
658         (declare (fixnum i))
659         (setf (svref new-vector i) (the fixnum (1+ i)))))
660     (setf (id-map-vector id-map) new-vector
661           (id-map-free id-map) old-size))))
662
663;;; Map an object to a small fixnum ID in id-map.
664;;; Object can't be NIL or a fixnum itself.
665(defun assign-id-map-id (id-map object)
666  (if (or (null object) (typep object 'fixnum))
667    (setq object (require-type object '(not (or null fixnum)))))
668  (with-lock-grabbed ((id-map-lock id-map))
669    (let* ((free (or (id-map-free id-map) (id-map-grow id-map)))
670           (vector (id-map-vector id-map))
671           (newfree (svref vector free)))
672      (setf (id-map-free id-map) newfree
673            (svref vector free) object)
674      free)))
675     
676;;; Referemce the object with id ID in ID-MAP.  Leave the object in
677;;; the map.
678(defun id-map-object (id-map id)
679  (let* ((object (with-lock-grabbed ((id-map-lock id-map))
680                   (svref (id-map-vector id-map) id))))
681    (if (or (null object) (typep object 'fixnum))
682      (error "invalid index ~d for ~s" id id-map)
683      object)))
684
685;;; Referemce the object with id ID in ID-MAP.  Remove the object from
686;;; the map.
687(defun id-map-free-object (id-map id)
688  (with-lock-grabbed ((id-map-lock id-map))
689    (let* ((vector (id-map-vector id-map))
690           (object (svref vector id)))
691      (if (or (null object) (typep object 'fixnum))
692        (error "invalid index ~d for ~s" id id-map))
693      (setf (svref vector id) (id-map-free id-map)
694            (id-map-free id-map) id)
695      object)))
696
697(defun id-map-modify-object (id-map id old-value new-value)
698  (with-lock-grabbed ((id-map-lock id-map))
699    (let* ((vector (id-map-vector id-map))
700           (object (svref vector id)))
701      (if (or (null object) (typep object 'fixnum))
702        (error "invalid index ~d for ~s" id id-map))
703      (if (eq object old-value)
704        (setf (svref vector id) new-value)))))
705
706
707   
708
709(setq *type-system-initialized* t)
710
711#+count-gf-calls
712(progn
713;;; Call-counting for generic functions.  We overload the
714;;; (previously unused
715(defmethod generic-function-call-count ((gf generic-function))
716  (gf.hash gf))
717
718
719(defun (setf generic-function-call-count) (count gf)
720  (setf (gf.hash gf) (require-type count 'fixnum)))
721
722(defun clear-all-generic-function-call-counts ()
723  (dolist (gf (population.data %all-gfs%))
724    (setf (gf.hash gf) 0)))
725);#+count-gf-calls
726
727
Note: See TracBrowser for help on using the repository browser.